configure.ac

   1 AC_INIT(version.h)
   2 AC_PREREQ(2.69)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_HEADERS([lib/config.h])
   5 AH_BOTTOM([#include <dirpaths.h>])
   6 MCONFIG=./MCONFIG
   7 AC_SUBST_FILE(MCONFIG)
   8 BINARY_TYPE=bin
   9 dnl
  10 dnl This is to figure out the version number and the date....
  11 dnl
  12 E2FSPROGS_VERSION=`grep E2FSPROGS_VERSION ${srcdir}/version.h  \
  13         | awk '{print $3}' | tr \" " " | awk '{print $1}'`
  14 E2FSPROGS_DATE=`grep E2FSPROGS_DATE ${srcdir}/version.h | awk '{print $3}' \
  15         | tr \" " " | awk '{print $1}'`
  16 E2FSPROGS_DAY=$(echo $E2FSPROGS_DATE | awk -F- '{print $1}' | sed -e '/^[[1-9]]$/s/^/0/')
  17 MONTH=`echo $E2FSPROGS_DATE | awk -F- '{print $2}'`
  18 YEAR=`echo $E2FSPROGS_DATE | awk -F- '{print $3}'`
  19
  20 if expr $YEAR ">" 1900 > /dev/null ; then
  21         E2FSPROGS_YEAR=$YEAR
  22 elif expr $YEAR ">" 90 >/dev/null ; then
  23         E2FSPROGS_YEAR=19$YEAR
  24 else
  25         E2FSPROGS_YEAR=20$YEAR
  26 fi
  27
  28 case $MONTH in
  29 Jan)    MONTH_NUM=01; E2FSPROGS_MONTH="January" ;;
  30 Feb)    MONTH_NUM=02; E2FSPROGS_MONTH="February" ;;
  31 Mar)    MONTH_NUM=03; E2FSPROGS_MONTH="March" ;;
  32 Apr)    MONTH_NUM=04; E2FSPROGS_MONTH="April" ;;
  33 May)    MONTH_NUM=05; E2FSPROGS_MONTH="May" ;;
  34 Jun)    MONTH_NUM=06; E2FSPROGS_MONTH="June" ;;
  35 Jul)    MONTH_NUM=07; E2FSPROGS_MONTH="July" ;;
  36 Aug)    MONTH_NUM=08; E2FSPROGS_MONTH="August" ;;
  37 Sep)    MONTH_NUM=09; E2FSPROGS_MONTH="September" ;;
  38 Oct)    MONTH_NUM=10; E2FSPROGS_MONTH="October" ;;
  39 Nov)    MONTH_NUM=11; E2FSPROGS_MONTH="November" ;;
  40 Dec)    MONTH_NUM=12; E2FSPROGS_MONTH="December" ;;
  41 *)      AC_MSG_WARN([Unknown month $MONTH??]) ;;
  42 esac
  43
  44 base_ver=`echo $E2FSPROGS_VERSION | \
  45                sed -e 's/-WIP//' -e 's/pre-//' -e 's/-PLUS//'`
  46
  47 date_spec=${E2FSPROGS_YEAR}.${MONTH_NUM}.${E2FSPROGS_DAY}
  48
  49 case $E2FSPROGS_VERSION in
  50 *-WIP|pre-*)
  51         E2FSPROGS_PKGVER="$base_ver~WIP.$date_spec"
  52         ;;
  53 *)
  54         E2FSPROGS_PKGVER="$base_ver"
  55         ;;
  56 esac
  57
  58 unset DATE MONTH YEAR base_ver pre_vers date_spec
  59 AC_MSG_RESULT([Generating configuration file for e2fsprogs version $E2FSPROGS_VERSION])
  60 AC_MSG_RESULT([Release date is ${E2FSPROGS_MONTH}, ${E2FSPROGS_YEAR}])
  61 AC_SUBST(E2FSPROGS_YEAR)
  62 AC_SUBST(E2FSPROGS_MONTH)
  63 AC_SUBST(E2FSPROGS_DAY)
  64 AC_SUBST(E2FSPROGS_VERSION)
  65 AC_SUBST(E2FSPROGS_PKGVER)
  66 AC_SUBST(E2FSPROGS_DATE)
  67 dnl
  68 dnl Use diet libc
  69 dnl
  70 WITH_DIET_LIBC=
  71 AC_ARG_WITH([diet-libc],
  72 AS_HELP_STRING([--with-diet-libc],[use diet libc]),
  73 CC="diet cc -nostdinc"
  74 WITH_DIET_LIBC=yes
  75 if test -z "$LIBS"
  76 then
  77         LIBS="-lcompat"
  78 else
  79         LIBS="$LIBS -lcompat"
  80 fi
  81 AC_MSG_RESULT(CC=$CC))dnl
  82 dnl
  83 AC_CANONICAL_HOST
  84 dnl
  85 dnl Check to see if libdl exists for the sake of dlopen
  86 dnl
  87 DLOPEN_LIB=''
  88 AC_CHECK_LIB(dl, dlopen,DLOPEN_LIB=-ldl)
  89 AC_SUBST(DLOPEN_LIB)
  90 dnl
  91 AC_ARG_WITH([cc],
  92 AS_HELP_STRING([--with-cc],[no longer supported, use CC= instead]),
  93 AC_MSG_ERROR([--with-cc no longer supported; use CC= instead]))
  94 dnl
  95 AC_ARG_WITH([ccopts],
  96 AS_HELP_STRING([--with-ccopts],[no longer supported, use CFLAGS= instead]),
  97 AC_MSG_ERROR([--with-ccopts no longer supported; use CFLAGS= instead]))
  98 dnl
  99 AC_ARG_WITH([ldopts],
 100 AS_HELP_STRING([--with-ldopts],[no longer supported, use LDFLAGS= instead]),
 101 AC_MSG_ERROR([--with-ldopts no longer supported; use LDFLAGS= instead]))
 102 dnl
 103 AC_PROG_CC
 104 if test "$GCC" = yes; then
 105    RDYNAMIC="-rdynamic"
 106    AC_SUBST(RDYNAMIC)
 107 fi
 108 AC_PROG_CPP
 109 dnl
 110 dnl Alpha computers use fast and imprecise floating point code that may
 111 dnl miss exceptions by default. Force sane options if we're using GCC.
 112 AC_MSG_CHECKING(for additional special compiler flags)
 113 if test "$GCC" = yes
 114 then
 115     case "$host_cpu" in
 116         alpha)          addcflags="-mieee" ;;
 117     esac
 118 fi
 119 if test "x$addcflags" != x
 120 then
 121     AC_MSG_RESULT($addcflags)
 122     CFLAGS="$addcflags $CFLAGS"
 123 else
 124     AC_MSG_RESULT([[(none)]])
 125 fi
 126 AC_USE_SYSTEM_EXTENSIONS
 127 dnl
 128 dnl Set default values for library extensions.  Will be dealt with after
 129 dnl parsing configuration options, which may modify these
 130 dnl
 131 LIB_EXT=.a
 132 STATIC_LIB_EXT=.a
 133 PROFILED_LIB_EXT=.a
 134 dnl
 135 dnl Allow separate `root_prefix' to be specified
 136 dnl
 137 AC_ARG_WITH([root-prefix],
 138 AS_HELP_STRING([--with-root-prefix=PREFIX],[override prefix variable for files to be placed in the root]),
 139 root_prefix=$withval,
 140 root_prefix=NONE)dnl
 141 dnl
 142 dnl handle --enable-maintainer-mode
 143 dnl
 144 AC_ARG_ENABLE([maintainer-mode],
 145 AS_HELP_STRING([--enable-maintainer-mode],[enable makefile rules useful for maintainers]),
 146 if test "$enableval" = "no"
 147 then
 148         MAINTAINER_CMT=#
 149         AC_MSG_RESULT([Disabling maintainer mode])
 150 else
 151         MAINTAINER_CMT=
 152         AC_MSG_RESULT([Enabling maintainer mode])
 153 fi
 154 ,
 155 MAINTAINER_CMT=#
 156 AC_MSG_RESULT([Disabling maintainer mode by default])
 157 )
 158 AC_SUBST(MAINTAINER_CMT)
 159 dnl
 160 dnl handle --enable-symlink-install
 161 dnl
 162 AC_ARG_ENABLE([symlink-install],
 163 AS_HELP_STRING([--enable-symlink-install],[use symlinks when installing instead of hard links]),
 164 if test "$enableval" = "no"
 165 then
 166         LINK_INSTALL_FLAGS=-f
 167         AC_MSG_RESULT([Disabling symlinks for install])
 168 else
 169         LINK_INSTALL_FLAGS=-sf
 170         AC_MSG_RESULT([Enabling symlinks for install])
 171 fi
 172 ,
 173 LINK_INSTALL_FLAGS=-f
 174 AC_MSG_RESULT([Disabling symlinks for install by default])
 175 )
 176 AC_SUBST(LINK_INSTALL_FLAGS)
 177 dnl
 178 dnl handle --enable-relative-symlinks
 179 dnl
 180 relative_symlink_defined=
 181 AC_ARG_ENABLE([relative-symlinks],
 182 AS_HELP_STRING([--enable-relative-symlinks],[use relative symlinks when installing]),
 183 if test "$enableval" = "no"
 184 then
 185         SYMLINK_RELATIVE=
 186         relative_symlink_defined=yes
 187         AC_MSG_RESULT([Disabling relative symlinks for install])
 188 else
 189         SYMLINK_RELATIVE=--relative
 190         relative_symlink_defined=yes
 191         AC_MSG_RESULT([Enabling relative symlinks for install])
 192 fi)
 193 AC_ARG_ENABLE([symlink-relative-symlinks],,
 194 if test "$enableval" = "no"
 195 then
 196         SYMLINK_RELATIVE=yes
 197         AC_MSG_RESULT([Disabling relative symlinks for install])
 198 else
 199         SYMLINK_RELATIVE=--relative
 200         AC_MSG_RESULT([Enabling relative symlinks for install])
 201 fi
 202 ,
 203 if test -z "$relative_symlink_defined"
 204 then
 205         SYMLINK_RELATIVE=
 206 AC_MSG_RESULT([Disabling relative symlinks for install by default])
 207 fi
 208 )
 209 AC_SUBST(SYMLINK_RELATIVE)
 210 dnl
 211 dnl handle --enable-symlink-build
 212 dnl
 213 AC_ARG_ENABLE([symlink-build],
 214 AS_HELP_STRING([--enable-symlink-build],[use symlinks while building instead of hard links]),
 215 if test "$enableval" = "no"
 216 then
 217         LINK_BUILD_FLAGS=
 218         AC_MSG_RESULT([Disabling symlinks for build])
 219 else
 220         LINK_BUILD_FLAGS=-s
 221         AC_MSG_RESULT([Enabling symlinks for build])
 222 fi
 223 ,
 224 LINK_BUILD_FLAGS=
 225 AC_MSG_RESULT([Disabling symlinks for build by default])
 226 )
 227 AC_SUBST(LINK_BUILD_FLAGS)
 228 dnl
 229 dnl handle --enable-verbose-makecmds
 230 dnl
 231 AC_ARG_ENABLE([verbose-makecmds],
 232 AS_HELP_STRING([--enable-verbose-makecmds],[enable verbose make command output]),
 233 if test "$enableval" = "no"
 234 then
 235         AC_MSG_RESULT([Disabling verbose make commands])
 236         E=@echo
 237         ES=echo
 238         Q=@
 239 else
 240         AC_MSG_RESULT([Enabling verbose make commands])
 241         E=@\\#
 242         ES=\\#
 243         Q=
 244 fi
 245 ,
 246 AC_MSG_RESULT([Disabling verbose make commands])
 247 E=@echo
 248 ES=echo
 249 Q=@
 250 )
 251 AC_SUBST(E)
 252 AC_SUBST(ES)
 253 AC_SUBST(Q)
 254 dnl
 255 dnl This needs to be before all of the --enable-*-shlibs options
 256 dnl
 257 E2_PKG_CONFIG_STATIC=--static
 258 LDFLAG_DYNAMIC=
 259 PRIVATE_LIBS_CMT=
 260 dnl
 261 dnl handle --enable-elf-shlibs
 262 dnl
 263 AC_ARG_ENABLE([elf-shlibs],
 264 AS_HELP_STRING([--enable-elf-shlibs],[select ELF shared libraries]),
 265 if test "$enableval" = "no"
 266 then
 267         ELF_CMT=#
 268         MAKEFILE_ELF=/dev/null
 269         AC_MSG_RESULT([Disabling ELF shared libraries])
 270 else
 271         E2_PKG_CONFIG_STATIC=
 272         ELF_CMT=
 273         MAKEFILE_ELF=$srcdir/lib/Makefile.elf-lib
 274         [case "$host_os" in
 275         solaris2.*)
 276                 MAKEFILE_ELF=$srcdir/lib/Makefile.solaris-lib
 277         ;;
 278         esac]
 279         BINARY_TYPE=elfbin
 280         LIB_EXT=.so
 281         PRIVATE_LIBS_CMT=#
 282         LDFLAG_DYNAMIC=['-Wl,-rpath-link,$(top_builddir)/lib']
 283         AC_MSG_RESULT([Enabling ELF shared libraries])
 284 fi
 285 ,
 286 MAKEFILE_ELF=/dev/null
 287 ELF_CMT=#
 288 AC_MSG_RESULT([Disabling ELF shared libraries by default])
 289 )
 290 AC_SUBST(ELF_CMT)
 291 AC_SUBST_FILE(MAKEFILE_ELF)
 292 dnl
 293 dnl handle --enable-bsd-shlibs
 294 dnl
 295 AC_ARG_ENABLE([bsd-shlibs],
 296 AS_HELP_STRING([--enable-bsd-shlibs],[select BSD shared libraries]),
 297 if test "$enableval" = "no"
 298 then
 299         BSDLIB_CMT=#
 300         MAKEFILE_BSDLIB=/dev/null
 301         AC_MSG_RESULT([Disabling BSD shared libraries])
 302 else
 303         E2_PKG_CONFIG_STATIC=
 304         BSDLIB_CMT=
 305         MAKEFILE_BSDLIB=$srcdir/lib/Makefile.bsd-lib
 306         LIB_EXT=.so
 307         [case "$host_os" in
 308         darwin*)
 309                 MAKEFILE_BSDLIB=$srcdir/lib/Makefile.darwin-lib
 310                 LIB_EXT=.dylib
 311         ;;
 312         esac]
 313         AC_MSG_RESULT([Enabling BSD shared libraries])
 314 fi
 315 ,
 316 MAKEFILE_BSDLIB=/dev/null
 317 BSDLIB_CMT=#
 318 AC_MSG_RESULT([Disabling BSD shared libraries by default])
 319 )
 320 AC_SUBST(BSDLIB_CMT)
 321 AC_SUBST_FILE(MAKEFILE_BSDLIB)
 322 dnl
 323 dnl handle --enable-profile
 324 dnl
 325 AC_ARG_ENABLE([profile],
 326 AS_HELP_STRING([--enable-profile],[build profiling libraries]),
 327 if test "$enableval" = "no"
 328 then
 329         PROFILE_CMT=#
 330         MAKEFILE_PROFILE=/dev/null
 331         AC_MSG_RESULT([Disabling profiling libraries])
 332 else
 333         PROFILE_CMT=
 334         MAKEFILE_PROFILE=$srcdir/lib/Makefile.profile
 335         PROFILED_LIB_EXT=_p.a
 336         AC_MSG_RESULT([Building profiling libraries])
 337 fi
 338 ,
 339 PROFILE_CMT=#
 340 MAKEFILE_PROFILE=/dev/null
 341 AC_MSG_RESULT([Disabling profiling libraries by default])
 342 )
 343 AC_SUBST(PROFILE_CMT)
 344 AC_SUBST_FILE(MAKEFILE_PROFILE)
 345 dnl
 346 dnl handle --enable-gcov
 347 dnl
 348 AC_ARG_ENABLE([gcov],
 349 AS_HELP_STRING([--enable-gcov],[build for coverage testing using gcov]),
 350 if test "$enableval" = "yes"
 351 then
 352         CFLAGS="-g -fprofile-arcs -ftest-coverage"
 353         LDFLAGS="-fprofile-arcs -ftest-coverage"
 354         AC_MSG_RESULT([Enabling gcov support])
 355 fi
 356 )
 357 dnl
 358 dnl handle --enable-hardening
 359 dnl
 360 CFLAGS_SHLIB="${CFLAGS_SHLIB:-$CFLAGS}"
 361 CFLAGS_STLIB="${CFLAGS_STLIB:-$CFLAGS}"
 362 LDFLAGS_SHLIB=${LDFLAGS_SHLIB:-$LDFLAGS}
 363 LDFLAGS_STATIC=${LDFLAGS_STATIC:-$LDFLAGS}
 364 AC_ARG_ENABLE([hardening],
 365 AS_HELP_STRING([--enable-hardening],[build for coverage testing using gcov]),
 366 if test "$enableval" = "yes"
 367 then
 368         HARDEN_CFLAGS="-D_FORTIFY_SOURCE=2 -fstack-protector-strong"
 369         HARDEN_LDFLAGS=["-Wl,-z,relro -Wl,-z,now"]
 370         CFLAGS="$CFLAGS $HARDEN_CFLAGS -fPIE"
 371         CFLAGS_SHLIB="$CFLAGS_SHLIB $HARDEN_CFLAGS"
 372         CFLAGS_STLIB="$CFLAGS_STLIB $HARDEN_CFLAGS -fPIE"
 373         LDFLAGS="$LDFLAGS $HARDEN_LDFLAGS -fPIE -pie"
 374         LDFLAGS_STATIC="$LDFLAGS_STATIC $HARDEN_LDFLAGS"
 375         LDFLAGS_SHLIB="$LDFLAGS_SHLIB $HARDEN_LDFLAGS"
 376         AC_MSG_RESULT([Enabling hardening support])
 377 fi
 378 )
 379 dnl
 380 dnl Substitute library extensions
 381 dnl
 382 AC_SUBST(LIB_EXT)
 383 AC_SUBST(STATIC_LIB_EXT)
 384 AC_SUBST(PROFILED_LIB_EXT)
 385 AC_SUBST(LDFLAG_DYNAMIC)
 386 AC_SUBST(PRIVATE_LIBS_CMT)
 387 dnl
 388 dnl handle --enable-jbd-debug
 389 dnl
 390 AC_ARG_ENABLE([jbd-debug],
 391 AS_HELP_STRING([--enable-jbd-debug],[enable journal debugging]),
 392 if test "$enableval" = "no"
 393 then
 394         AC_MSG_RESULT([Disabling journal debugging])
 395 else
 396         AC_DEFINE(CONFIG_JBD_DEBUG, 1,
 397                 [Define to 1 if debugging ext3/4 journal code])
 398         AC_MSG_RESULT([Enabling journal debugging])
 399 fi
 400 ,
 401 AC_MSG_RESULT([Disabling journal debugging by default])
 402 )
 403 dnl
 404 dnl handle --enable-blkid-debug
 405 dnl
 406 AC_ARG_ENABLE([blkid-debug],
 407 AS_HELP_STRING([--enable-blkid-debug],[enable blkid debugging]),
 408 if test "$enableval" = "no"
 409 then
 410         AC_MSG_RESULT([Disabling blkid debugging])
 411 else
 412         AC_DEFINE(CONFIG_BLKID_DEBUG, 1,
 413                 [Define to 1 if debugging the blkid library])
 414         AC_MSG_RESULT([Enabling blkid debugging])
 415 fi
 416 ,
 417 AC_MSG_RESULT([Disabling blkid debugging by default])
 418 )
 419 dnl
 420 dnl handle --enable-testio-debug
 421 dnl
 422 AC_ARG_ENABLE([testio-debug],
 423 AS_HELP_STRING([--disable-testio-debug],[disable the use of the test I/O manager for debugging]),
 424 AH_TEMPLATE([CONFIG_TESTIO_DEBUG],
 425         [Define to 1 if the testio I/O manager should be enabled])
 426 if test "$enableval" = "no"
 427 then
 428         AC_MSG_RESULT([Disabling testio debugging])
 429         TEST_IO_CMT="#"
 430 else
 431         TEST_IO_CMT=
 432         AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 433         AC_MSG_RESULT([Enabling testio debugging])
 434 fi
 435 ,
 436 AC_MSG_RESULT([Enabling testio debugging by default])
 437 AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 438 TEST_IO_CMT=
 439 )
 440 AC_SUBST(TEST_IO_CMT)
 441 dnl
 442 dnl handle --enable-developer-features
 443 dnl
 444 AC_ARG_ENABLE([developer-features],
 445 AS_HELP_STRING([--enable-developer-features],[enable features for use by ext4 developers]),
 446 AH_TEMPLATE([CONFIG_DEVELOPER_FEATURES],
 447         [Define to 1 for features for use by ext4 developers])
 448 if test "$enableval" = "yes"
 449 then
 450         DEV_FEATURES_CMT=
 451         AC_DEFINE(CONFIG_DEVELOPER_FEATURES, 1)
 452         AC_MSG_RESULT([Enabling ext4 developer features])
 453 else
 454         AC_MSG_RESULT([Disabling ext4 developer features])
 455         DEV_FEATURES_CMT="#"
 456 fi
 457 ,
 458 AC_MSG_RESULT([Disabling ext4 developer features by default])
 459 DEV_FEATURES_CMT=
 460 )
 461 AC_SUBST(DEV_FEATURES_CMT)
 462 dnl
 463 dnl handle --disable-libuuid
 464 dnl
 465 PKG_PROG_PKG_CONFIG
 466 LIBUUID=
 467 DEPLIBUUID=
 468 STATIC_LIBUUID=
 469 DEPSTATIC_LIBUUID=
 470 PROFILED_LIBUUID=
 471 DEPPROFILED_LIBUUID=
 472 UUID_CMT=
 473 AC_ARG_ENABLE([libuuid],
 474 AS_HELP_STRING([--enable-libuuid],[build and use private uuid library]),
 475 if test "$enableval" = "no"
 476 then
 477         if test -z "$PKG_CONFIG"; then
 478                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 479         fi
 480
 481         AC_CHECK_LIB(uuid, uuid_generate,
 482                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 483                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`],
 484                 [AC_MSG_ERROR([external uuid library not found])])
 485         PROFILED_LIBUUID=$LIBUUID
 486         UUID_CMT=#
 487         AC_MSG_RESULT([Disabling private uuid library])
 488 else
 489         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 490         DEPLIBUUID=$LIBUUID
 491         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 492         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 493         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 494         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 495         AC_MSG_RESULT([Enabling private uuid library])
 496 fi
 497 ,
 498 if test -n "$PKG_CONFIG"; then
 499         AC_CHECK_LIB(uuid, uuid_generate,
 500                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 501                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`])
 502 fi
 503 if test -n "$LIBUUID"; then
 504         PROFILED_LIBUUID=$LIBUUID
 505         UUID_CMT=#
 506         AC_MSG_RESULT([Using system uuid by default])
 507 else
 508         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 509         DEPLIBUUID=$LIBUUID
 510         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 511         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 512         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 513         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 514         AC_MSG_RESULT([Enabling private uuid library by default])
 515 fi
 516 )
 517 AC_SUBST(LIBUUID)
 518 AC_SUBST(DEPLIBUUID)
 519 AC_SUBST(STATIC_LIBUUID)
 520 AC_SUBST(DEPSTATIC_LIBUUID)
 521 AC_SUBST(PROFILED_LIBUUID)
 522 AC_SUBST(DEPPROFILED_LIBUUID)
 523 AC_SUBST(UUID_CMT)
 524 dnl
 525 dnl handle --disable-libblkid
 526 dnl
 527 PKG_PROG_PKG_CONFIG
 528 LIBBLKID=
 529 DEPLIBBLKID=
 530 STATIC_LIBBLKID=
 531 DEPSTATIC_LIBBLKID=
 532 PROFILED_LIBBLKID=
 533 DEPPROFILED_LIBBLKID=
 534 BLKID_CMT=
 535 AH_TEMPLATE([CONFIG_BUILD_FINDFS], [Define to 1 to compile findfs])
 536 AC_ARG_ENABLE([libblkid],
 537 AS_HELP_STRING([--enable-libblkid],[build and use private blkid library]),
 538 if test "$enableval" = "no"
 539 then
 540         if test -z "$PKG_CONFIG"; then
 541                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 542         fi
 543
 544         AC_CHECK_LIB(blkid, blkid_get_cache,
 545                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 546                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`],
 547                 [AC_MSG_ERROR([external blkid library not found])], -luuid)
 548         BLKID_CMT=#
 549         PROFILED_LIBBLKID=$LIBBLKID
 550         AC_MSG_RESULT([Disabling private blkid library])
 551 else
 552         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 553         DEPLIBBLKID=$LIBBLKID
 554         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 555         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 556         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 557         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 558         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 559         AC_MSG_RESULT([Enabling private blkid library])
 560 fi
 561 ,
 562 if test -n "$PKG_CONFIG"; then
 563         AC_CHECK_LIB(blkid, blkid_get_cache,
 564                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 565                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`])
 566 fi
 567 if test -n "$LIBBLKID"; then
 568         BLKID_CMT=#
 569         PROFILED_LIBBLKID=$LIBBLKID
 570         AC_MSG_RESULT([Using system blkid library by default])
 571 else
 572         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 573         DEPLIBBLKID=$LIBBLKID
 574         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 575         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 576         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 577         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 578         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 579         AC_MSG_RESULT([Enabling private blkid library by default])
 580 fi
 581 )
 582 AC_SUBST(LIBBLKID)
 583 AC_SUBST(DEPLIBBLKID)
 584 AC_SUBST(STATIC_LIBBLKID)
 585 AC_SUBST(DEPSTATIC_LIBBLKID)
 586 AC_SUBST(PROFILED_LIBBLKID)
 587 AC_SUBST(DEPPROFILED_LIBBLKID)
 588 AC_SUBST(BLKID_CMT)
 589 dnl
 590 dnl handle --enable-subset
 591 dnl
 592 ALL_CMT=
 593 SUBSET_CMT=
 594 AC_ARG_ENABLE([subset],
 595 AS_HELP_STRING([--enable-subset],[enable subset-only build]),
 596 if test "$enableval" = "no"
 597 then
 598         SUBSET_CMT=#
 599         AC_MSG_RESULT([Disabling subset-only build])
 600 else
 601         ALL_CMT=#
 602         AC_MSG_RESULT([Enabling subset-only-build])
 603 fi
 604 ,)
 605 AC_SUBST(ALL_CMT)
 606 AC_SUBST(SUBSET_CMT)
 607 dnl
 608 dnl handle --disable-backtrace
 609 dnl
 610 AH_TEMPLATE([DISABLE_BACKTRACE], [Define to 1 to disable use of backtrace])
 611 AC_ARG_ENABLE([backtrace],
 612 AS_HELP_STRING([--disable-backtrace],[disable use backtrace]),
 613 if test "$enableval" = "no"
 614 then
 615         AC_MSG_RESULT([Disabling use of backtrace])
 616         AC_DEFINE(DISABLE_BACKTRACE, 1)
 617 else
 618         AC_MSG_RESULT([Enabling use of backtrace])
 619 fi
 620 ,
 621 AC_MSG_RESULT([Enabling use of backtrace by default])
 622 )
 623 dnl
 624 dnl handle --enable-debugfs
 625 dnl
 626 AC_ARG_ENABLE([debugfs],
 627 AS_HELP_STRING([--disable-debugfs],[disable support of debugfs program]),
 628 if test "$enableval" = "no"
 629 then
 630         AC_MSG_RESULT([Disabling debugfs support])
 631         DEBUGFS_CMT="#"
 632 else
 633         DEBUGFS_CMT=
 634         AC_MSG_RESULT([Enabling debugfs support])
 635 fi
 636 ,
 637 AC_MSG_RESULT([Enabling debugfs support by default])
 638 DEBUGFS_CMT=
 639 )
 640 AC_SUBST(DEBUGFS_CMT)
 641 dnl
 642 dnl handle --enable-imager
 643 dnl
 644 AC_ARG_ENABLE([imager],
 645 AS_HELP_STRING([--disable-imager],[disable support of e2image program]),
 646 if test "$enableval" = "no"
 647 then
 648         AC_MSG_RESULT([Disabling e2image support])
 649         IMAGER_CMT="#"
 650 else
 651         IMAGER_CMT=
 652         AC_MSG_RESULT([Enabling e2image support])
 653 fi
 654 ,
 655 AC_MSG_RESULT([Enabling e2image support by default])
 656 IMAGER_CMT=
 657 )
 658 AC_SUBST(IMAGER_CMT)
 659 dnl
 660 dnl handle --enable-resizer
 661 dnl
 662 AC_ARG_ENABLE([resizer],
 663 AS_HELP_STRING([--disable-resizer],[disable support of e2resize program]),
 664 if test "$enableval" = "no"
 665 then
 666         AC_MSG_RESULT([Disabling e2resize support])
 667         RESIZER_CMT="#"
 668 else
 669         RESIZER_CMT=
 670         AC_MSG_RESULT([Enabling e2resize support])
 671 fi
 672 ,
 673 AC_MSG_RESULT([Enabling e2resize support by default])
 674 RESIZER_CMT=
 675 )
 676 AC_SUBST(RESIZER_CMT)
 677 dnl
 678 dnl handle --enable-defrag
 679 dnl
 680 AC_ARG_ENABLE([defrag],
 681 AS_HELP_STRING([--disable-defrag],[disable support of e4defrag program]),
 682 if test "$enableval" = "no"
 683 then
 684         AC_MSG_RESULT([Disabling e4defrag support])
 685         DEFRAG_CMT="#"
 686 else
 687         DEFRAG_CMT=
 688         AC_MSG_RESULT([Enabling e4defrag support])
 689 fi
 690 ,
 691 if test -z "$WITH_DIET_LIBC"
 692 then
 693         AC_MSG_RESULT([Enabling e4defrag support by default])
 694         DEFRAG_CMT=
 695 else
 696         AC_MSG_RESULT([Disabling e4defrag support by default])
 697         DEFRAG_CMT="#"
 698 fi
 699 )
 700 AC_SUBST(DEFRAG_CMT)
 701 dnl
 702 dnl See whether to install the `fsck' wrapper program (that calls e2fsck)
 703 dnl
 704 AC_ARG_ENABLE([fsck],
 705 AS_HELP_STRING([--enable-fsck],[build fsck wrapper program]),
 706 [if test "$enableval" = "no"
 707 then
 708         FSCK_PROG='' FSCK_MAN=''
 709         AC_MSG_RESULT([Not building fsck wrapper])
 710 else
 711         FSCK_PROG=fsck FSCK_MAN=fsck.8
 712         AC_MSG_RESULT([Building fsck wrapper])
 713 fi]
 714 ,
 715 [case "$host_os" in
 716   gnu*)
 717     FSCK_PROG='' FSCK_MAN=''
 718     AC_MSG_RESULT([Not building fsck wrapper by default])
 719     ;;
 720   *)
 721     FSCK_PROG=fsck FSCK_MAN=fsck.8
 722     AC_MSG_RESULT([Building fsck wrapper by default])
 723 esac]
 724 )
 725 AC_SUBST(FSCK_PROG)
 726 AC_SUBST(FSCK_MAN)
 727 dnl
 728 dnl See whether to install the `e2initrd-helper' program
 729 dnl
 730 AC_ARG_ENABLE([e2initrd-helper],
 731 AS_HELP_STRING([--enable-e2initrd-helper],[build e2initrd-helper program]),
 732 [if test "$enableval" = "no"
 733 then
 734         E2INITRD_PROG='' E2INITRD_MAN=''
 735         AC_MSG_RESULT([Not building e2initrd helper])
 736 else
 737         E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 738         AC_MSG_RESULT([Building e2initrd helper])
 739 fi]
 740 ,
 741 E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 742 AC_MSG_RESULT([Building e2initrd helper by default])
 743 )
 744 AC_SUBST(E2INITRD_PROG)
 745 AC_SUBST(E2INITRD_MAN)
 746 dnl
 747 dnl
 748 dnl
 749 AC_ARG_ENABLE([tls],
 750 AS_HELP_STRING([--disable-tls],[disable use of thread local support]),
 751 [if test "$enableval" = "no"
 752 then
 753         try_tls=""
 754         AC_MSG_RESULT([Disabling thread local support])
 755 else
 756         try_tls="yes"
 757         AC_MSG_RESULT([Enabling thread local support])
 758 fi]
 759 ,
 760 if test -n "$WITH_DIET_LIBC"
 761 then
 762         try_tls=""
 763         AC_MSG_RESULT([Diet libc does not support thread local support])
 764 else
 765         try_tls="yes"
 766         AC_MSG_RESULT([Try using thread local support by default])
 767 fi
 768 )
 769 if test "$try_tls" = "yes"
 770 then
 771 AX_TLS
 772 fi
 773 dnl
 774 dnl
 775 dnl
 776 AC_ARG_WITH([pthread],
 777 AS_HELP_STRING([--without-pthread],[disable use of pthread support]),
 778 [if test "$withval" = "no"
 779 then
 780         try_pthread=""
 781         AC_MSG_RESULT([Disabling pthread support])
 782 else
 783         try_pthread="yes"
 784         AC_MSG_RESULT([Testing for pthread support])
 785 fi]
 786 ,
 787 try_pthread="yes"
 788 AC_MSG_RESULT([Try testing for pthread support by default])
 789 )
 790 if test "$try_pthread" = "yes"
 791 then
 792 AX_PTHREAD
 793 else
 794 test -n "$PTHREAD_CC" || PTHREAD_CC="$CC"
 795 AC_SUBST([PTHREAD_CC])
 796 fi
 797 dnl
 798 dnl
 799 dnl
 800 AH_TEMPLATE([USE_UUIDD], [Define to 1 to build uuidd])
 801 AC_ARG_ENABLE([uuidd],
 802 AS_HELP_STRING([--disable-uuidd],[disable building the uuid daemon]),
 803 [if test "$enableval" = "no"
 804 then
 805         AC_MSG_RESULT([Not building uuidd])
 806         UUIDD_CMT="#"
 807 else
 808         AC_DEFINE(USE_UUIDD, 1)
 809         UUIDD_CMT=""
 810         AC_MSG_RESULT([Building uuidd])
 811 fi]
 812 ,
 813 AC_DEFINE(USE_UUIDD, 1)
 814 if test -z "$UUID_CMT"
 815 then
 816         UUIDD_CMT=""
 817         AC_MSG_RESULT([Building uuidd by default])
 818 else
 819         UUIDD_CMT="#"
 820         AC_MSG_RESULT([Disabling uuidd by default])
 821 fi
 822 )
 823 AC_SUBST(UUIDD_CMT)
 824 dnl
 825 dnl handle --disable-mmp
 826 dnl
 827 AH_TEMPLATE([CONFIG_MMP], [Define to 1 to enable mmp support])
 828 AC_ARG_ENABLE([mmp],
 829 AS_HELP_STRING([--disable-mmp],[disable support mmp, Multi Mount Protection]),
 830 if test "$enableval" = "no"
 831 then
 832         AC_MSG_RESULT([Disabling mmp support])
 833 else
 834         AC_MSG_RESULT([Enabling mmp support])
 835         AC_DEFINE(CONFIG_MMP, 1)
 836 fi
 837 ,
 838 AC_MSG_RESULT([Enabling mmp support by default])
 839 AC_DEFINE(CONFIG_MMP, 1)
 840 )
 841 dnl
 842 dnl handle --disable-tdb
 843 dnl
 844 AH_TEMPLATE([CONFIG_TDB], [Define to 1 to enable tdb support])
 845 AC_ARG_ENABLE([tdb],
 846 AS_HELP_STRING([--disable-tdb],[disable tdb support]),
 847 if test "$enableval" = "no"
 848 then
 849         AC_MSG_RESULT([Disabling tdb support])
 850         TDB_CMT="#"
 851         TDB_MAN_COMMENT='.\"'
 852 else
 853         AC_MSG_RESULT([Enabling tdb support])
 854         AC_DEFINE(CONFIG_TDB, 1)
 855         TDB_CMT=""
 856         TDB_MAN_COMMENT=""
 857 fi
 858 ,
 859 AC_MSG_RESULT([Enabling mmp support by default])
 860 AC_DEFINE(CONFIG_TDB, 1)
 861 TDB_CMT=""
 862 TDB_MAN_COMMENT=""
 863 )
 864 AC_SUBST(TDB_CMT)
 865 AC_SUBST(TDB_MAN_COMMENT)
 866 dnl
 867 dnl handle --disable-bmap-stats
 868 dnl
 869 AH_TEMPLATE([ENABLE_BMAP_STATS], [Define to 1 to enable bitmap stats.])
 870 AC_ARG_ENABLE([bmap-stats],
 871 AS_HELP_STRING([--disable-bmap-stats],[disable collection of bitmap stats]),
 872 if test "$enableval" = "no"
 873 then
 874         AC_MSG_RESULT([Disabling bitmap statistics support])
 875 else
 876         AC_MSG_RESULT([Enabling bitmap statistics support])
 877         AC_DEFINE(ENABLE_BMAP_STATS, 1)
 878 fi
 879 ,
 880 AC_MSG_RESULT([Enabling bitmap statistics support by default])
 881 AC_DEFINE(ENABLE_BMAP_STATS, 1)
 882 )
 883 dnl
 884 dnl handle --enable-bmap-stats-ops
 885 dnl
 886 AH_TEMPLATE([ENABLE_BMAP_STATS_OPS], [Define to 1 to enable bitmap stats.])
 887 AC_ARG_ENABLE([bmap-stats-ops],
 888 AS_HELP_STRING([--enable-bmap-stats-ops],[enable collection of additional bitmap stats]),
 889 if test "$enableval" = "no"
 890 then
 891         AC_MSG_RESULT([Disabling additional bitmap statistics])
 892 else
 893         dnl There has to be a better way!
 894         AS_IF([test "x${enable_bmap_stats}" = "xno"],
 895          AC_MSG_FAILURE([Error --enable-bmap-stats-ops requires bmap-stats]))
 896
 897         AC_MSG_RESULT([Enabling additional bitmap statistics])
 898         AC_DEFINE(ENABLE_BMAP_STATS_OPS, 1)
 899 fi
 900 ,
 901 AC_MSG_RESULT([Disabling additional bitmap statistics by default])
 902 )
 903 dnl
 904 dnl
 905 dnl
 906 MAKEFILE_LIBRARY=$srcdir/lib/Makefile.library
 907 AC_SUBST_FILE(MAKEFILE_LIBRARY)
 908 dnl
 909 dnl Add internationalization support, using gettext.
 910 dnl
 911 GETTEXT_PACKAGE=e2fsprogs
 912 PACKAGE=e2fsprogs
 913 VERSION="$E2FSPROGS_VERSION"
 914 VERSION=0.14.1
 915 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [package name for gettext])
 916 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [version for gettext])
 917 AC_SUBST(GETTEXT_PACKAGE)
 918 AC_SUBST(PACKAGE)
 919 AC_SUBST(VERSION)
 920
 921 AM_GNU_GETTEXT([external])
 922 dnl
 923 dnl End of configuration options
 924 dnl
 925 AC_SUBST(BINARY_TYPE)
 926 AC_PROG_MAKE_SET
 927 CHECK_GNU_MAKE
 928 AC_PATH_PROG(LN, ln, ln)
 929 AC_PROG_MKDIR_P
 930 dnl
 931 dnl @mkdir_p@ is used by po's Makefile.in
 932 dnl
 933 mkdir_p=$MKDIR_P
 934 AC_SUBST(mkdir_p)
 935 AC_PROG_LN_S
 936 AC_PATH_PROG(MV, mv, mv)
 937 AC_PATH_PROG(CP, cp, cp)
 938 AC_PATH_PROG(RM, rm, rm)
 939 AC_PATH_PROG(CHMOD, chmod, :)
 940 AC_PROG_AWK
 941 AC_PROG_EGREP
 942 AC_PATH_PROG(SED, sed, sed)
 943 AC_PATH_PROG(PERL, perl, perl)
 944 AC_PATH_PROG(LDCONFIG, ldconfig, :)
 945 AC_CHECK_TOOL(AR, ar, ar)
 946 AC_CHECK_TOOL(RANLIB, ranlib, :)
 947 AC_CHECK_TOOL(STRIP, strip, :)
 948 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
 949 if test "_$MAKEINFO" = "_"; then
 950     MAKEINFO="echo Makeinfo is missing. Info documentation will not be built."
 951 else
 952     case "$MAKEINFO" in
 953       */missing.*)
 954         AC_MSG_WARN([
 955 *** Makeinfo is missing. Info documentation will not be built.])
 956         ;;
 957       *)
 958         ;;
 959     esac
 960 fi
 961 AC_SUBST(MAKEINFO)
 962 AC_PROG_INSTALL
 963 # See if we need a separate native compiler.
 964 if test $cross_compiling = no; then
 965   BUILD_CC="$CC"
 966   AC_SUBST(BUILD_CC)
 967 else
 968   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 969 fi
 970 AC_CHECK_HEADERS(m4_flatten([
 971         dirent.h
 972         errno.h
 973         execinfo.h
 974         getopt.h
 975         malloc.h
 976         mntent.h
 977         paths.h
 978         pthread.h
 979         semaphore.h
 980         setjmp.h
 981         signal.h
 982         stdarg.h
 983         stdint.h
 984         stdlib.h
 985         termios.h
 986         termio.h
 987         unistd.h
 988         utime.h
 989         attr/xattr.h
 990         linux/falloc.h
 991         linux/fd.h
 992         linux/fsmap.h
 993         linux/major.h
 994         linux/loop.h
 995         linux/types.h
 996         net/if_dl.h
 997         netinet/in.h
 998         sys/acl.h
 999         sys/disklabel.h
1000         sys/disk.h
1001         sys/file.h
1002         sys/ioctl.h
1003         sys/key.h
1004         sys/mkdev.h
1005         sys/mman.h
1006         sys/mount.h
1007         sys/prctl.h
1008         sys/random.h
1009         sys/resource.h
1010         sys/select.h
1011         sys/socket.h
1012         sys/sockio.h
1013         sys/stat.h
1014         sys/syscall.h
1015         sys/sysmacros.h
1016         sys/time.h
1017         sys/types.h
1018         sys/un.h
1019         sys/wait.h
1020         sys/xattr.h
1021 ]))
1022 dnl Check where to find a dd(1) that supports iflag=fullblock
1023 dnl and oflag=append
1024 AC_MSG_CHECKING([for a dd(1) program that supports iflag=fullblock])
1025 DD=
1026 for i in dd gdd ; do
1027         if "$i" if=/dev/null of=/dev/null count=1 bs=10k 2>/dev/null iflag=fullblock oflag=append ; then
1028                 DD=$i
1029                 break
1030         fi
1031 done
1032 if test -n "$DD" ; then
1033         AC_MSG_RESULT([$DD])
1034 else
1035         AC_MSG_RESULT([not found, using dd])
1036         DD=dd
1037         AC_MSG_WARN([No GNU-compatible dd(1) program found, expect some self-test failures.])
1038 fi
1039 AC_SUBST([DD])
1040
1041 AC_CHECK_HEADERS(net/if.h,,,
1042 [[
1043 #if HAVE_SYS_TYPES_H
1044 #include <sys/types.h>
1045 #endif
1046 #if HAVE_SYS_SOCKET
1047 #include <sys/socket.h>
1048 #endif
1049 ]])
1050 AC_FUNC_VPRINTF
1051 dnl Check to see if dirent has member d_reclen. On cygwin those d_reclen
1052 dnl is not declared.
1053 AC_CHECK_MEMBER(struct dirent.d_reclen,[AC_DEFINE(HAVE_RECLEN_DIRENT, 1,
1054                        [Define to 1 if dirent has d_reclen])],,
1055                 [#include <dirent.h>])
1056 AC_CHECK_MEMBERS([struct stat.st_atim])
1057 dnl Check to see if ssize_t was declared
1058 AC_CHECK_TYPE(ssize_t,[AC_DEFINE(HAVE_TYPE_SSIZE_T, 1,
1059                 [Define to 1 if ssize_t declared])],,
1060               [#include <sys/types.h>])
1061 dnl
1062 dnl Check to see if llseek() is declared in unistd.h.  On some libc's
1063 dnl it is, and on others it isn't..... Thank you glibc developers....
1064 dnl
1065 AC_CHECK_DECL(llseek,[AC_DEFINE(HAVE_LLSEEK_PROTOTYPE, 1,
1066                         [Define to 1 if llseek declared in unistd.h])],,
1067               [#include <unistd.h>])
1068 dnl
1069 dnl Check to see if lseek64() is declared in unistd.h.  Glibc's header files
1070 dnl are so convoluted that I can't tell whether it will always be defined,
1071 dnl and if it isn't defined while lseek64 is defined in the library,
1072 dnl disaster will strike.
1073 dnl
1074 dnl Warning!  Use of --enable-gcc-wall may throw off this test.
1075 dnl
1076 dnl
1077 AC_CHECK_DECL(lseek64,[AC_DEFINE(HAVE_LSEEK64_PROTOTYPE, 1,
1078                         [Define to 1 if lseek64 declared in unistd.h])],,
1079                 [#define _LARGEFILE_SOURCE
1080                  #define _LARGEFILE64_SOURCE
1081                  #include <unistd.h>])
1082 dnl
1083 dnl Word sizes...
1084 dnl
1085 AC_CHECK_SIZEOF(short)
1086 AC_CHECK_SIZEOF(int)
1087 AC_CHECK_SIZEOF(long)
1088 AC_CHECK_SIZEOF(long long)
1089 AC_CHECK_SIZEOF(off_t)
1090 AC_CHECK_SIZEOF(time_t)
1091 SIZEOF_SHORT=$ac_cv_sizeof_short
1092 SIZEOF_INT=$ac_cv_sizeof_int
1093 SIZEOF_LONG=$ac_cv_sizeof_long
1094 SIZEOF_LONG_LONG=$ac_cv_sizeof_long_long
1095 SIZEOF_OFF_T=$ac_cv_sizeof_off_t
1096 SIZEOF_TIME_T=$ac_cv_sizeof_time_t
1097 AC_SUBST(SIZEOF_SHORT)
1098 AC_SUBST(SIZEOF_INT)
1099 AC_SUBST(SIZEOF_LONG)
1100 AC_SUBST(SIZEOF_LONG_LONG)
1101 AC_SUBST(SIZEOF_OFF_T)
1102 AC_SUBST(SIZEOF_TIME_T)
1103 AC_C_BIGENDIAN
1104 if test $cross_compiling = no; then
1105   BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
1106 else
1107   CROSS_COMPILE="1" BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
1108 fi
1109 ASM_TYPES_HEADER=./asm_types.h
1110 AC_SUBST_FILE(ASM_TYPES_HEADER)
1111 dnl
1112 dnl Save the configuration #defines needed for the public ext2fs.h
1113 dnl header file
1114 dnl
1115 echo "/* These defines are needed for the public ext2fs.h header file */" \
1116      > public_config.h
1117 if grep HAVE_SYS_TYPES_H confdefs.h > tmp_config.$$; then
1118   uniq tmp_config.$$ >> public_config.h
1119 else
1120   echo "#undef HAVE_SYS_TYPES_H" >> public_config.h
1121 fi
1122 if grep WORDS_BIGENDIAN confdefs.h > tmp_config.$$; then
1123   uniq tmp_config.$$ >> public_config.h
1124 else
1125   echo "#undef WORDS_BIGENDIAN" >> public_config.h
1126 fi
1127 rm -f tmp_config.$$
1128 PUBLIC_CONFIG_HEADER=./public_config.h
1129 AC_SUBST_FILE(PUBLIC_CONFIG_HEADER)
1130 dnl
1131 dnl See if we have inttypes.h and if intptr_t is defined
1132 dnl
1133 AC_CHECK_HEADERS([inttypes.h])
1134 AC_CHECK_TYPES(intptr_t)
1135 dnl
1136 dnl See if struct stat has a st_flags field, in which case we can get file
1137 dnl flags somewhat portably.  Also check for the analogous setter, chflags().
1138 dnl
1139 AC_MSG_CHECKING(whether struct stat has a st_flags field)
1140 AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags,
1141         AC_TRY_COMPILE([#include <sys/stat.h>],
1142                 [struct stat stat; stat.st_flags = 0;],
1143                 [e2fsprogs_cv_struct_st_flags=yes],
1144                 [e2fsprogs_cv_struct_st_flags=no]))
1145 AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags)
1146 if test "$e2fsprogs_cv_struct_st_flags" = yes; then
1147   AC_MSG_CHECKING(whether st_flags field is useful)
1148   AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags_immut,
1149         AC_TRY_COMPILE([#include <sys/stat.h>],
1150                 [struct stat stat; stat.st_flags |= UF_IMMUTABLE;],
1151                 [e2fsprogs_cv_struct_st_flags_immut=yes],
1152                 [e2fsprogs_cv_struct_st_flags_immut=no]))
1153   AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags_immut)
1154   if test "$e2fsprogs_cv_struct_st_flags_immut" = yes; then
1155           AC_DEFINE(HAVE_STAT_FLAGS, 1,
1156                 [Define to 1 if struct stat has st_flags])
1157   fi
1158 fi
1159 dnl
1160 dnl Check for the presence of SA_LEN
1161 dnl
1162 AC_CHECK_MEMBER(struct sockaddr.sa_len,
1163                 AC_DEFINE_UNQUOTED(HAVE_SA_LEN,1,
1164                         [Define to 1 if if struct sockaddr contains sa_len]),,
1165         [#include <sys/types.h>
1166          #include <sys/socket.h>])
1167 dnl
1168 dnl If we are using the system-provided blkid library, check for
1169 dnl the functions added after migrating that library to util-linux
1170 dnl
1171 if test -n "$BLKID_CMT"; then
1172   AC_CHECK_LIB(blkid, blkid_probe_get_topology,
1173                       AC_DEFINE(HAVE_BLKID_PROBE_GET_TOPOLOGY, 1,
1174                                 [Define to 1 if blkid has blkid_probe_get_topology]))
1175   AC_CHECK_LIB(blkid, blkid_topology_get_dax,
1176                       AC_DEFINE(HAVE_BLKID_TOPOLOGY_GET_DAX, 1,
1177                                 [Define to 1 if blkid has blkid_topology_get_dax]))
1178   AC_CHECK_LIB(blkid, blkid_probe_enable_partitions,
1179                       AC_DEFINE(HAVE_BLKID_PROBE_ENABLE_PARTITIONS, 1,
1180                                 [Define to 1 if blkid has blkid_probe_enable_partitions]))
1181 fi
1182 dnl
1183 if test -n "$DLOPEN_LIB" ; then
1184    ac_cv_func_dlopen=yes
1185 fi
1186 AC_CHECK_FUNCS(m4_flatten([
1187         __secure_getenv
1188         add_key
1189         backtrace
1190         chflags
1191         dlopen
1192         fadvise64
1193         fallocate
1194         fallocate64
1195         fchown
1196         fcntl
1197         fdatasync
1198         fstat64
1199         fsync
1200         ftruncate64
1201         futimes
1202         getcwd
1203         getdtablesize
1204         getentropy
1205         gethostname
1206         getmntinfo
1207         getpwuid_r
1208         getrandom
1209         getrlimit
1210         getrusage
1211         jrand48
1212         keyctl
1213         llistxattr
1214         llseek
1215         lseek64
1216         mallinfo
1217         mallinfo2
1218         mbstowcs
1219         memalign
1220         mempcpy
1221         mmap
1222         msync
1223         nanosleep
1224         open64
1225         pathconf
1226         posix_fadvise
1227         posix_fadvise64
1228         posix_memalign
1229         prctl
1230         pread
1231         pwrite
1232         pread64
1233         pwrite64
1234         secure_getenv
1235         setmntent
1236         setresgid
1237         setresuid
1238         snprintf
1239         srandom
1240         stpcpy
1241         strcasecmp
1242         strdup
1243         strnlen
1244         strptime
1245         strtoull
1246         sync_file_range
1247         sysconf
1248         usleep
1249         utime
1250         utimes
1251         valloc
1252 ]))
1253 dnl
1254 dnl Check to see if -lsocket is required (solaris) to make something
1255 dnl that uses socket() to compile; this is needed for the UUID library
1256 dnl
1257 SOCKET_LIB=''
1258 AC_CHECK_LIB(socket, socket, [SOCKET_LIB=-lsocket])
1259 AC_SUBST(SOCKET_LIB)
1260 dnl
1261 dnl See if libmagic exists
1262 dnl
1263 AC_CHECK_LIB(magic, magic_file, [MAGIC_LIB=-lmagic
1264 AC_CHECK_HEADERS([magic.h])])
1265 if test "$ac_cv_func_dlopen" = yes ; then
1266    MAGIC_LIB=$DLOPEN_LIB
1267 fi
1268 AC_SUBST(MAGIC_LIB)
1269 dnl
1270 dnl Check to see if librt is required for clock_gettime() (glibc < 2.17)
1271 dnl
1272 AC_CHECK_LIB(rt, clock_gettime, [CLOCK_GETTIME_LIB=-lrt])
1273 AC_SUBST(CLOCK_GETTIME_LIB)
1274 dnl
1275 dnl Check to see if the FUSE library is -lfuse or -losxfuse
1276 dnl
1277 FUSE_CMT=
1278 FUSE_LIB=
1279 dnl osxfuse.dylib supersedes fuselib.dylib
1280 AC_ARG_ENABLE([fuse2fs],
1281 AS_HELP_STRING([--disable-fuse2fs],[do not build fuse2fs]),
1282 if test "$enableval" = "no"
1283 then
1284         FUSE_CMT="#"
1285         AC_MSG_RESULT([Disabling fuse2fs])
1286 else
1287         AC_CHECK_HEADERS([pthread.h fuse.h], [],
1288 [AC_MSG_FAILURE([Cannot find fuse2fs headers.])],
1289 [#define _FILE_OFFSET_BITS      64
1290 #define FUSE_USE_VERSION 29])
1291
1292         AC_PREPROC_IFELSE(
1293 [AC_LANG_PROGRAM([[#define FUSE_USE_VERSION 29
1294 #ifdef __linux__
1295 #include <linux/fs.h>
1296 #include <linux/falloc.h>
1297 #include <linux/xattr.h>
1298 #endif
1299 ]], [])], [], [AC_MSG_FAILURE([Cannot find fuse2fs Linux headers.])])
1300
1301         AC_CHECK_LIB(osxfuse, fuse_main, [FUSE_LIB=-losxfuse],
1302                 [AC_CHECK_LIB(fuse, fuse_main, [FUSE_LIB=-lfuse],
1303                               [AC_MSG_FAILURE([Cannot find fuse library.])])])
1304         AC_MSG_RESULT([Enabling fuse2fs])
1305 fi
1306 ,
1307 AC_CHECK_HEADERS([pthread.h fuse.h], [], [FUSE_CMT="#"],
1308 [#define _FILE_OFFSET_BITS      64
1309 #define FUSE_USE_VERSION 29
1310 #ifdef __linux__
1311 # include <linux/fs.h>
1312 # include <linux/falloc.h>
1313 # include <linux/xattr.h>
1314 #endif])
1315 if test -z "$FUSE_CMT"
1316 then
1317         AC_CHECK_LIB(osxfuse, fuse_main, [FUSE_LIB=-losxfuse],
1318 [AC_CHECK_LIB(fuse, fuse_main, [FUSE_LIB=-lfuse], [FUSE_CMT="#"])])
1319 fi
1320 if test -z "$FUSE_CMT"
1321 then
1322         AC_MSG_RESULT([Enabling fuse2fs by default.])
1323 fi
1324 )
1325 AC_SUBST(FUSE_LIB)
1326 AC_SUBST(FUSE_CMT)
1327 dnl
1328 dnl See if optreset exists
1329 dnl
1330 AC_MSG_CHECKING(for optreset)
1331 AC_CACHE_VAL(ac_cv_have_optreset,
1332 [AC_EGREP_HEADER(optreset, unistd.h,
1333   ac_cv_have_optreset=yes, ac_cv_have_optreset=no)])dnl
1334 AC_MSG_RESULT($ac_cv_have_optreset)
1335 if test $ac_cv_have_optreset = yes; then
1336   AC_DEFINE(HAVE_OPTRESET, 1, [Define to 1 if optreset for getopt is present])
1337 fi
1338 dnl
1339 dnl Test for sem_init, and which library it might require:
1340 dnl
1341 AH_TEMPLATE([HAVE_SEM_INIT], [Define to 1 if sem_init() exists])
1342 SEM_INIT_LIB=''
1343 echo GL_THREADS_API: ${gl_threads_api}
1344 if test "${gl_threads_api}" != none
1345 then
1346   AC_CHECK_FUNC(sem_init, ,
1347     AC_CHECK_LIB(pthread, sem_init,
1348         AC_DEFINE(HAVE_SEM_INIT, 1)
1349         SEM_INIT_LIB=-lpthread,
1350     AC_CHECK_LIB(rt, sem_init,
1351         AC_DEFINE(HAVE_SEM_INIT, 1)
1352         SEM_INIT_LIB=-lrt,
1353     AC_CHECK_LIB(posix4, sem_init,
1354         AC_DEFINE(HAVE_SEM_INIT, 1)
1355         SEM_INIT_LIB=-lposix4))))dnl
1356 fi
1357 AC_SUBST(SEM_INIT_LIB)
1358 dnl
1359 dnl Check for unified diff
1360 dnl
1361 AC_MSG_CHECKING(for unified diff option)
1362 if diff -u $0 $0 > /dev/null 2>&1 ; then
1363    UNI_DIFF_OPTS=-u
1364 else
1365    UNI_DIFF_OPTS=-c
1366 fi
1367 AC_MSG_RESULT($UNI_DIFF_OPTS)
1368 AC_SUBST(UNI_DIFF_OPTS)
1369 dnl
1370 dnl We use the EXT2 ioctls only under Linux
1371 dnl
1372 case "$host_os" in
1373 linux*)
1374         AC_DEFINE(HAVE_EXT2_IOCTLS, 1, [Define to 1 if Ext2 ioctls present])
1375         ;;
1376 esac
1377 dnl
1378 dnl Check the available mount options
1379 dnl
1380 AX_CHECK_MOUNT_OPT(nosuid)
1381 AX_CHECK_MOUNT_OPT(nodev)
1382 dnl Enable LTO for all packages
1383 dnl
1384 AC_ARG_ENABLE([lto],
1385 AS_HELP_STRING([--enable-lto],[enable link time optimization]),,
1386 enable_lto=no)
1387 if test "$enable_lto" = "yes" || test "$enable_lto" = "probe"; then
1388         AC_MSG_CHECKING([if C compiler supports LTO])
1389         OLD_CFLAGS="$CFLAGS"
1390         OLD_LDFLAGS="$LDFLAGS"
1391         LTO_FLAGS="-g -flto -ffat-lto-objects"
1392         CFLAGS="$CFLAGS $LTO_FLAGS"
1393         LDFLAGS="$LDFLAGS $LTO_FLAGS"
1394         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1395                 [AC_MSG_RESULT([yes])]
1396                 [lto_cflags=$LTO_FLAGS]
1397                 [lto_ldflags=$LTO_FLAGS]
1398                 [AC_PATH_PROG(gcc_ar, gcc-ar,,)]
1399                 [AC_PATH_PROG(gcc_ranlib, gcc-ranlib,,)],
1400                 [AC_MSG_RESULT([no])])
1401         if test -x "$gcc_ar" && test -x "$gcc_ranlib"; then
1402                 have_lto=yes
1403                 AR="${gcc_ar}"
1404                 RANLIB="${gcc_ranlib}"
1405         fi
1406         CFLAGS="${OLD_CFLAGS}"
1407         LDFLAGS="${OLD_LDFLAGS}"
1408         AC_SUBST(have_lto)
1409         AC_SUBST(lto_cflags)
1410         AC_SUBST(lto_ldflags)
1411 fi
1412 if test "$enable_lto" = "yes" && test "$have_lto" != "yes"; then
1413         AC_MSG_ERROR([LTO not supported by compiler.])
1414 fi
1415 dnl
1416 dnl Enable UBSAN for all packages
1417 dnl
1418 AC_ARG_ENABLE([ubsan],
1419 AS_HELP_STRING([--enable-ubsan],[enable undefined behavior sanitizer]),,
1420 enable_ubsan=no)
1421 if test "$enable_ubsan" = "yes" || test "$enable_ubsan" = "probe"; then
1422         AC_MSG_CHECKING([if C compiler supports UBSAN])
1423         OLD_CFLAGS="$CFLAGS"
1424         OLD_LDFLAGS="$LDFLAGS"
1425         UBSAN_FLAGS="-fsanitize=undefined"
1426         CFLAGS="$CFLAGS $UBSAN_FLAGS"
1427         LDFLAGS="$LDFLAGS $UBSAN_FLAGS"
1428         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1429                 [AC_MSG_RESULT([yes])]
1430                 [ubsan_cflags=$UBSAN_FLAGS]
1431                 [ubsan_ldflags=$UBSAN_FLAGS]
1432                 [have_ubsan=yes],
1433                 [AC_MSG_RESULT([no])])
1434         CFLAGS="${OLD_CFLAGS}"
1435         LDFLAGS="${OLD_LDFLAGS}"
1436         AC_SUBST(have_ubsan)
1437         AC_SUBST(ubsan_cflags)
1438         AC_SUBST(ubsan_ldflags)
1439 fi
1440 if test "$enable_ubsan" = "yes" && test "$have_ubsan" != "yes"; then
1441         AC_MSG_ERROR([UBSAN not supported by compiler.])
1442 fi
1443 dnl
1444 dnl Enable ADDRSAN for all packages
1445 dnl
1446 AC_ARG_ENABLE([addrsan],
1447 AS_HELP_STRING([--enable-addrsan],[enable address sanitizer]),,
1448 enable_addrsan=no)
1449 if test "$enable_addrsan" = "yes" || test "$enable_addrsan" = "probe"; then
1450         AC_MSG_CHECKING([if C compiler supports ADDRSAN])
1451         OLD_CFLAGS="$CFLAGS"
1452         OLD_LDFLAGS="$LDFLAGS"
1453         ADDRSAN_FLAGS="-fsanitize=address"
1454         CFLAGS="$CFLAGS $ADDRSAN_FLAGS"
1455         LDFLAGS="$LDFLAGS $ADDRSAN_FLAGS"
1456         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1457                 [AC_MSG_RESULT([yes])]
1458                 [addrsan_cflags=$ADDRSAN_FLAGS]
1459                 [addrsan_ldflags=$ADDRSAN_FLAGS]
1460                 [have_addrsan=yes],
1461                 [AC_MSG_RESULT([no])])
1462         CFLAGS="${OLD_CFLAGS}"
1463         LDFLAGS="${OLD_LDFLAGS}"
1464         AC_SUBST(have_addrsan)
1465         AC_SUBST(addrsan_cflags)
1466         AC_SUBST(addrsan_ldflags)
1467 fi
1468 if test "$enable_addrsan" = "yes" && test "$have_addrsan" != "yes"; then
1469         AC_MSG_ERROR([ADDRSAN not supported by compiler.])
1470 fi
1471 dnl
1472 dnl Enable THREADSAN for all packages
1473 dnl
1474 AC_ARG_ENABLE([threadsan],
1475 AS_HELP_STRING([--enable-threadsan],[enable thread sanitizer]),,
1476 enable_threadsan=no)
1477 if test "$enable_threadsan" = "yes" || test "$enable_threadsan" = "probe"; then
1478         AC_MSG_CHECKING([if C compiler supports THREADSAN])
1479         OLD_CFLAGS="$CFLAGS"
1480         OLD_LDFLAGS="$LDFLAGS"
1481         THREADSAN_FLAGS="-fsanitize=thread"
1482         CFLAGS="$CFLAGS $THREADSAN_FLAGS"
1483         LDFLAGS="$LDFLAGS $THREADSAN_FLAGS"
1484         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1485                 [AC_MSG_RESULT([yes])]
1486                 [threadsan_cflags=$THREADSAN_FLAGS]
1487                 [threadsan_ldflags=$THREADSAN_FLAGS]
1488                 [have_threadsan=yes],
1489                 [AC_MSG_RESULT([no])])
1490         CFLAGS="${OLD_CFLAGS}"
1491         LDFLAGS="${OLD_LDFLAGS}"
1492         AC_SUBST(have_threadsan)
1493         AC_SUBST(threadsan_cflags)
1494         AC_SUBST(threadsan_ldflags)
1495 fi
1496 if test "$enable_threadsan" = "yes" && test "$have_threadsan" != "yes"; then
1497         AC_MSG_ERROR([THREADSAN not supported by compiler.])
1498 fi
1499 if test "$have_threadsan" = "yes" && test "$have_addrsan" = "yes"; then
1500         AC_MSG_WARN([ADDRSAN and THREADSAN are not known to work together.])
1501 fi
1502 dnl
1503 dnl OS-specific uncomment control
1504 dnl
1505 LINUX_CMT="#"
1506 CYGWIN_CMT="#"
1507 UNIX_CMT=
1508 case "$host_os" in
1509 linux*)
1510         LINUX_CMT=
1511         ;;
1512 cygwin)
1513         CYGWIN_CMT=
1514         UNIX_CMT="#"
1515         ;;
1516 esac
1517 AC_SUBST(LINUX_CMT)
1518 AC_SUBST(CYGWIN_CMT)
1519 AC_SUBST(UNIX_CMT)
1520 dnl
1521 dnl e2scrub only builds on linux
1522 dnl
1523 E2SCRUB_CMT="$LINUX_CMT"
1524 AC_SUBST(E2SCRUB_CMT)
1525 dnl
1526 dnl Linux and Hurd places root files in the / by default
1527 dnl
1528 case "$host_os" in
1529 linux* | gnu* | k*bsd*-gnu)
1530         if test "$prefix" = NONE -a "$root_prefix" = NONE ; then
1531                 root_prefix="";
1532                 AC_MSG_RESULT([On $host_os systems, root_prefix defaults to ''])
1533         fi
1534         ;;
1535 esac
1536 dnl
1537 dnl On Linux/hurd, force the prefix to be /usr
1538 dnl
1539 case "$host_os" in
1540 linux* | gnu* | k*bsd*-gnu)
1541         if test "$prefix" = NONE ; then
1542                 prefix="/usr";
1543                 AC_MSG_RESULT([On $host_os systems, prefix defaults to /usr])
1544                 if test "$mandir" = '${prefix}/man' ; then
1545                         AC_MSG_RESULT([...and mandir defaults to /usr/share/man])
1546                         mandir=/usr/share/man
1547                 fi
1548         fi
1549 ;;
1550 esac
1551 if test "$root_prefix" = NONE ; then
1552         if test "$prefix" = NONE ; then
1553                 root_prefix="$ac_default_prefix"
1554         else
1555                 root_prefix="$prefix"
1556         fi
1557         root_bindir=$bindir
1558         root_sbindir=$sbindir
1559         root_libdir=$libdir
1560         root_sysconfdir=$sysconfdir
1561 else
1562         root_bindir='${root_prefix}/bin'
1563         root_sbindir='${root_prefix}/sbin'
1564         root_libdir='${root_prefix}/lib'
1565         root_sysconfdir='${root_prefix}/etc'
1566 fi
1567 if test "$bindir" != '${exec_prefix}/bin'; then
1568     root_bindir=$bindir
1569     AC_MSG_RESULT([Setting root_bindir to $root_bindir])
1570 fi
1571 if test "$sbindir" != '${exec_prefix}/sbin'; then
1572     root_sbindir=$sbindir
1573     AC_MSG_RESULT([Setting root_sbindir to $root_sbindir])
1574 fi
1575 if test "$libdir" != '${exec_prefix}/lib'; then
1576     root_libdir=$libdir
1577     AC_MSG_RESULT([Setting root_libdir to $root_libdir])
1578 fi
1579 if test "$sysconfdir" != '${prefix}/etc'; then
1580     root_sysconfdir=$sysconfdir
1581     AC_MSG_RESULT([Setting root_sysconfdir to $root_sysconfdir])
1582 fi
1583 AC_SUBST(root_prefix)
1584 AC_SUBST(root_bindir)
1585 AC_SUBST(root_sbindir)
1586 AC_SUBST(root_libdir)
1587 AC_SUBST(root_sysconfdir)
1588 dnl
1589 dnl Allow specification of the multiarch arch
1590 dnl
1591 AC_ARG_WITH([multiarch],
1592 AS_HELP_STRING([--with-multiarch=ARCH],[specify the multiarch triplet]),
1593 if test "$withval" = "lib64"; then
1594     libdir=/usr/lib64
1595     root_libdir=/lib64
1596 else
1597     libdir=$libdir/$withval
1598     root_libdir=$root_libdir/$withval
1599 fi
1600 )
1601 dnl
1602 dnl
1603 dnl See if -static works.  This could fail if the linker does not
1604 dnl support -static, or if required external libraries are not available
1605 dnl in static form.
1606 dnl
1607 AC_MSG_CHECKING([whether we can link with -static])
1608 AC_CACHE_VAL(ac_cv_e2fsprogs_use_static,
1609 [SAVE_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS_STATIC -static"
1610 AC_TRY_LINK([#include <stdio.h>],[fflush(stdout);],
1611  ac_cv_e2fsprogs_use_static=yes, ac_cv_e2fsprogs_use_static=no)
1612 LDFLAGS=$SAVE_LDFLAGS])
1613 dnl
1614 dnl Regardless of how the test turns out, Solaris doesn't handle -static
1615 dnl This is caused by the socket library requiring the nsl library, which
1616 dnl requires the -dl library, which only works for dynamically linked
1617 dnl programs.  It basically means you can't have statically linked programs
1618 dnl which use the network under Solaris.
1619 dnl
1620 case "$host_os" in
1621 solaris2.*)
1622         ac_cv_e2fsprogs_use_static=no
1623 ;;
1624 esac
1625 AC_MSG_RESULT($ac_cv_e2fsprogs_use_static)
1626 if test $ac_cv_e2fsprogs_use_static = yes; then
1627         LDFLAGS_STATIC="$LDFLAGS_STATIC -static"
1628 fi
1629 AC_SUBST(LDFLAGS_STATIC)
1630 dnl
1631 dnl Work around mysterious Darwin / GNU libintl problem
1632 dnl (__asm__ redirection doesn't work for some mysterious reason.  Looks like
1633 dnl Apple hacked gcc somehow?)
1634 dnl
1635 case "$host_os" in
1636 darwin*)
1637         AC_MSG_RESULT([Using Apple Darwin / GNU libintl workaround])
1638         AC_DEFINE(_INTL_REDIRECT_MACROS, 1,
1639                 [Define to 1 if Apple Darwin libintl workaround is needed])
1640         ;;
1641 esac
1642 dnl
1643 dnl Only try to run the test suite if we're not cross compiling.
1644 dnl
1645 if test "$cross_compiling" = yes ; then
1646   DO_TEST_SUITE=
1647 else
1648   DO_TEST_SUITE=check
1649 fi
1650 AC_SUBST(DO_TEST_SUITE)
1651 dnl
1652 dnl Only include the intl include files if we're building with them
1653 dnl
1654 INCLUDES='-I. -I$(top_builddir)/lib -I$(top_srcdir)/lib'
1655 if test -n "$CPPFLAGS" ; then
1656         INCLUDES="$INCLUDES $CPPFLAGS"
1657 fi
1658 if test "$USE_INCLUDED_LIBINTL" = "yes" ; then
1659         INCLUDES=$INCLUDES' -I$(top_builddir)/intl -I$(top_srcdir)/intl'
1660 fi
1661 if test -n "$WITH_DIET_LIBC" ; then
1662         INCLUDES="$INCLUDES -D_REENTRANT"
1663 fi
1664 AC_SUBST(INCLUDES)
1665 dnl
1666 dnl Build CFLAGS
1667 dnl
1668 if test $cross_compiling = no; then
1669    BUILD_CFLAGS="$CFLAGS $CPPFLAGS $INCLUDES -DHAVE_CONFIG_H"
1670    BUILD_LDFLAGS="$LDFLAGS"
1671 fi
1672 AC_SUBST(BUILD_CFLAGS)
1673 AC_SUBST(BUILD_LDFLAGS)
1674 dnl
1675 dnl Define CFLAGS and LDFLAGS for shared libraries
1676 dnl
1677 CFLAGS_SHLIB=${CFLAGS_SHLIB:-$CFLAGS}
1678 CFLAGS_STLIB=${CFLAGS_STLIB:-$CFLAGS}
1679 LDFLAGS_SHLIB=${LDFLAGS_SHLIB:-$LDFLAGS}
1680 AC_SUBST(CFLAGS_SHLIB)
1681 AC_SUBST(CFLAGS_STLIB)
1682 AC_SUBST(LDFLAGS_SHLIB)
1683
1684 dnl
1685 dnl Where do udev rules go?
1686 dnl
1687 AC_ARG_WITH([udev_rules_dir],
1688   [AS_HELP_STRING([--with-udev-rules-dir@<:@=DIR@:>@],
1689         [Install udev rules into DIR.])],
1690   [],
1691   [with_udev_rules_dir=yes])
1692 AS_IF([test "x${with_udev_rules_dir}" != "xno"],
1693   [
1694         AS_IF([test "x${with_udev_rules_dir}" = "xyes"],
1695           [
1696                 PKG_CHECK_MODULES([udev], [udev],
1697                   [
1698                         with_udev_rules_dir="$($PKG_CONFIG --variable=udevdir udev)/rules.d"
1699                   ], [
1700                         with_udev_rules_dir=""
1701                   ])
1702           ])
1703         AC_MSG_CHECKING([for udev rules dir])
1704         pkg_udev_rules_dir="${with_udev_rules_dir}"
1705         AS_IF([test -n "${pkg_udev_rules_dir}"],
1706           [
1707                 AC_MSG_RESULT(${pkg_udev_rules_dir})
1708                 have_udev="yes"
1709           ],
1710           [
1711                 AC_MSG_RESULT(no)
1712                 have_udev="no"
1713           ])
1714   ],
1715   [
1716         have_udev="disabled"
1717   ])
1718 AC_SUBST(have_udev)
1719 AC_SUBST(pkg_udev_rules_dir)
1720
1721 dnl
1722 dnl Where do cron jobs go?
1723 dnl
1724 AC_ARG_WITH([crond_dir],
1725   [AS_HELP_STRING([--with-crond-dir@<:@=DIR@:>@],
1726         [Install system crontabs into DIR.])],
1727   [],
1728   [with_crond_dir=yes])
1729 AS_IF([test "x${with_crond_dir}" != "xno"],
1730   [
1731         AS_IF([test "x${with_crond_dir}" = "xyes"],
1732           [
1733                 AS_IF([test -d "/etc/cron.d"],
1734                   [with_crond_dir="/etc/cron.d"],
1735                   [have_crond="no"; with_crond_dir=""])
1736           ])
1737         AC_MSG_CHECKING([for system crontab dir])
1738         crond_dir="${with_crond_dir}"
1739         AS_IF([test -n "${crond_dir}"],
1740           [
1741                 AC_MSG_RESULT(${crond_dir})
1742                 have_crond="yes"
1743           ],
1744           [
1745                 AC_MSG_RESULT(no)
1746                 have_crond="no"
1747           ])
1748   ],
1749   [
1750         have_crond="disabled"
1751   ])
1752 AC_SUBST(have_crond)
1753 AC_SUBST(crond_dir)
1754
1755 dnl
1756 dnl Where do systemd services go?
1757 dnl
1758 AC_ARG_WITH([systemd_unit_dir],
1759   [AS_HELP_STRING([--with-systemd-unit-dir@<:@=DIR@:>@],
1760         [Install systemd system units into DIR.])],
1761   [],
1762   [with_systemd_unit_dir=yes])
1763 AS_IF([test "x${with_systemd_unit_dir}" != "xno"],
1764   [
1765         AS_IF([test "x${with_systemd_unit_dir}" = "xyes"],
1766           [
1767                 PKG_CHECK_MODULES([systemd], [systemd],
1768                   [
1769                         with_systemd_unit_dir="$($PKG_CONFIG --variable=systemdsystemunitdir systemd)"
1770                   ], [
1771                         with_systemd_unit_dir=""
1772                   ])
1773                 m4_pattern_allow([^PKG_(MAJOR|MINOR|BUILD|REVISION)$])
1774           ])
1775         AC_MSG_CHECKING([for systemd system unit dir])
1776         systemd_system_unit_dir="${with_systemd_unit_dir}"
1777         AS_IF([test -n "${systemd_system_unit_dir}"],
1778           [
1779                 AC_MSG_RESULT(${systemd_system_unit_dir})
1780                 have_systemd="yes"
1781           ],
1782           [
1783                 AC_MSG_RESULT(no)
1784                 have_systemd="no"
1785           ])
1786   ],
1787   [
1788         have_systemd="disabled"
1789   ])
1790 AC_SUBST(have_systemd)
1791 AC_SUBST(systemd_system_unit_dir)
1792 dnl Adjust the compiled files if we are on windows vs everywhere else
1793 dnl
1794 OS_IO_FILE=""
1795 [case "$host_os" in
1796   cigwin*|mingw*|msys*)
1797     OS_IO_FILE=windows_io
1798   ;;
1799   *)
1800     OS_IO_FILE=unix_io
1801   ;;
1802 esac]
1803 AC_SUBST(OS_IO_FILE)
1804 dnl
1805 dnl Make our output files, being sure that we create the some miscellaneous
1806 dnl directories
1807 dnl
1808 test -d lib || mkdir lib
1809 test -d include || mkdir include
1810 test -d include/linux || mkdir include/linux
1811 test -d include/asm || mkdir include/asm
1812 if test -z "$UUID_CMT" ; then
1813         uuid_out_list="lib/uuid/Makefile lib/uuid/uuid.pc \
1814                 lib/uuid/uuid_types.h"
1815 fi
1816 if test -z "$BLKID_CMT" ; then
1817         blkid_out_list="lib/blkid/Makefile lib/blkid/blkid.pc \
1818                 lib/blkid/blkid_types.h"
1819 fi
1820 for i in MCONFIG Makefile \
1821         util/Makefile util/subst.conf util/gen-tarball util/install-symlink \
1822         lib/et/Makefile lib/ss/Makefile lib/e2p/Makefile \
1823         lib/ext2fs/Makefile lib/ext2fs/ext2_types.h \
1824         $uuid_out_list $blkid_out_list lib/support/Makefile \
1825         lib/ss/ss.pc lib/et/com_err.pc lib/e2p/e2p.pc lib/ext2fs/ext2fs.pc \
1826         misc/Makefile ext2ed/Makefile e2fsck/Makefile \
1827         debugfs/Makefile tests/Makefile tests/progs/Makefile \
1828         resize/Makefile doc/Makefile po/Makefile.in scrub/Makefile; do
1829         if test -d `dirname ${srcdir}/$i` ; then
1830                 outlist="$outlist $i"
1831         fi
1832 done
1833 AC_OUTPUT($outlist)
1834 if test -f util/gen-tarball; then chmod +x util/gen-tarball; fi