lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD],
   7 [AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                        [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19         AC_DEFINE_UNQUOTED(LNET_MAX_PAYLOAD, $LNET_MAX_PAYLOAD,
  20                            [Max LNET payload])
  21 ])
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION],
  29 [AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ])
  43
  44 #
  45 # LN_CONFIG_AFFINITY
  46 #
  47 # check if cpu affinity is available/wanted
  48 #
  49 AC_DEFUN([LN_CONFIG_AFFINITY],
  50 [AC_ARG_ENABLE([affinity],
  51         AC_HELP_STRING([--disable-affinity],
  52                        [disable process/irq affinity]),
  53         [],[enable_affinity='yes'])
  54
  55 AC_MSG_CHECKING([for CPU affinity support])
  56 if test x$enable_affinity = xno ; then
  57         AC_MSG_RESULT([no (by request)])
  58 else
  59         LB_LINUX_TRY_COMPILE([
  60                 #include <linux/sched.h>
  61         ],[
  62                 struct task_struct t;
  63                 #if HAVE_CPUMASK_T
  64                 cpumask_t     m;
  65                 #else
  66                 unsigned long m;
  67                 #endif
  68                 set_cpus_allowed(&t, m);
  69         ],[
  70                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
  71                 AC_MSG_RESULT([yes])
  72         ],[
  73                 AC_MSG_RESULT([no (no kernel support)])
  74         ])
  75 fi
  76 ])
  77
  78 #
  79 # LN_CONFIG_PORTALS
  80 #
  81 # configure support for Portals
  82 #
  83 AC_DEFUN([LN_CONFIG_PORTALS],
  84 [AC_MSG_CHECKING([for portals])
  85 AC_ARG_WITH([portals],
  86         AC_HELP_STRING([--with-portals=path],
  87                        [set path to portals]),
  88         [
  89                 case $with_portals in
  90                         no)     ENABLEPORTALS=0
  91                                 ;;
  92                         *)      PORTALS="${with_portals}"
  93                                 ENABLEPORTALS=1
  94                                 ;;
  95                 esac
  96         ], [
  97                 ENABLEPORTALS=0
  98         ])
  99 PTLLNDCPPFLAGS=""
 100 if test $ENABLEPORTALS -eq 0; then
 101         AC_MSG_RESULT([no])
 102 elif test ! \( -f ${PORTALS}/include/portals/p30.h \); then
 103         AC_MSG_RESULT([no])
 104         AC_MSG_ERROR([bad --with-portals path])
 105 else
 106         AC_MSG_RESULT([$PORTALS])
 107         PTLLNDCPPFLAGS="-I${PORTALS}/include"
 108 fi
 109 AC_SUBST(PTLLNDCPPFLAGS)
 110 ])
 111
 112 #
 113 # LN_CONFIG_BACKOFF
 114 #
 115 # check if tunable tcp backoff is available/wanted
 116 #
 117 AC_DEFUN([LN_CONFIG_BACKOFF],
 118 [AC_MSG_CHECKING([for tunable backoff TCP support])
 119 AC_ARG_ENABLE([backoff],
 120        AC_HELP_STRING([--disable-backoff],
 121                       [disable socknal tunable backoff]),
 122        [],[enable_backoff='yes'])
 123 if test x$enable_backoff = xno ; then
 124        AC_MSG_RESULT([no (by request)])
 125 else
 126        BOCD="`grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h`"
 127        if test "$BOCD" != 0 ; then
 128                AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
 129                AC_MSG_RESULT(yes)
 130                if grep rto_max $LINUX/include/linux/tcp.h|grep -q __u16; then
 131                    AC_DEFINE(SOCKNAL_BACKOFF_MS, 1, [tunable backoff TCP in ms])
 132                fi
 133        else
 134                AC_MSG_RESULT([no (no kernel support)])
 135        fi
 136 fi
 137 ])
 138
 139
 140 #
 141 # LN_CONFIG_PTLLND
 142 #
 143 # configure support for Portals LND
 144 #
 145 AC_DEFUN([LN_CONFIG_PTLLND],
 146 [
 147 if test -z "$ENABLEPORTALS"; then
 148         LN_CONFIG_PORTALS
 149 fi
 150
 151 AC_MSG_CHECKING([whether to build the kernel portals LND])
 152
 153 PTLLND=""
 154 if test $ENABLEPORTALS -ne 0; then
 155         AC_MSG_RESULT([yes])
 156         PTLLND="ptllnd"
 157 else
 158         AC_MSG_RESULT([no])
 159 fi
 160 AC_SUBST(PTLLND)
 161 ])
 162
 163 #
 164 # LN_CONFIG_UPTLLND
 165 #
 166 # configure support for Portals LND
 167 #
 168 AC_DEFUN([LN_CONFIG_UPTLLND],
 169 [
 170 if test -z "$ENABLEPORTALS"; then
 171         LN_CONFIG_PORTALS
 172 fi
 173
 174 AC_MSG_CHECKING([whether to build the userspace portals LND])
 175
 176 UPTLLND=""
 177 if test $ENABLEPORTALS -ne 0; then
 178         AC_MSG_RESULT([yes])
 179         UPTLLND="ptllnd"
 180 else
 181         AC_MSG_RESULT([no])
 182 fi
 183 AC_SUBST(UPTLLND)
 184 ])
 185
 186 #
 187 # LN_CONFIG_USOCKLND
 188 #
 189 # configure support for userspace TCP/IP LND
 190 #
 191 AC_DEFUN([LN_CONFIG_USOCKLND],
 192 [AC_MSG_CHECKING([whether to build usocklnd])
 193 AC_ARG_ENABLE([usocklnd],
 194         AC_HELP_STRING([--disable-usocklnd],
 195                         [disable usocklnd]),
 196         [],[enable_usocklnd='yes'])
 197
 198 if test x$enable_usocklnd = xyes ; then
 199         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 200                 AC_MSG_RESULT([yes])
 201                 USOCKLND="usocklnd"
 202         else
 203                 AC_MSG_RESULT([no (libpthread not present or disabled)])
 204                 USOCKLND=""
 205         fi
 206 else
 207         AC_MSG_RESULT([no (disabled explicitly)])
 208         USOCKLND=""
 209 fi
 210 AC_SUBST(USOCKLND)
 211 ])
 212
 213 #
 214 # LN_CONFIG_QUADRICS
 215 #
 216 # check if quadrics support is in this kernel
 217 #
 218 AC_DEFUN([LN_CONFIG_QUADRICS],
 219 [AC_MSG_CHECKING([for QsNet sources])
 220 AC_ARG_WITH([qsnet],
 221         AC_HELP_STRING([--with-qsnet=path],
 222                        [set path to qsnet source (default=$LINUX)]),
 223         [QSNET=$with_qsnet],
 224         [QSNET=$LINUX])
 225 AC_MSG_RESULT([$QSNET])
 226
 227 AC_MSG_CHECKING([if quadrics kernel headers are present])
 228 if test -d $QSNET/drivers/net/qsnet ; then
 229         AC_MSG_RESULT([yes])
 230         QSWLND="qswlnd"
 231         AC_MSG_CHECKING([for multirail EKC])
 232         if test -f $QSNET/include/elan/epcomms.h; then
 233                 AC_MSG_RESULT([supported])
 234                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 235         else
 236                 AC_MSG_RESULT([not supported])
 237                 AC_MSG_ERROR([Need multirail EKC])
 238         fi
 239
 240         if test x$QSNET = x$LINUX ; then
 241                 LB_LINUX_CONFIG([QSNET],[],[
 242                         LB_LINUX_CONFIG([QSNET_MODULE],[],[
 243                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
 244                                 QSWLND=""
 245                                 QSWCPPFLAGS=""
 246                         ])
 247                 ])
 248         fi
 249 else
 250         AC_MSG_RESULT([no])
 251         QSWLND=""
 252         QSWCPPFLAGS=""
 253 fi
 254 AC_SUBST(QSWCPPFLAGS)
 255 AC_SUBST(QSWLND)
 256 ])
 257
 258 #
 259 # LN_CONFIG_GM
 260 #
 261 # check if GM support is available
 262 #
 263 AC_DEFUN([LN_CONFIG_GM],[
 264 AC_MSG_CHECKING([whether to enable GM support])
 265 AC_ARG_WITH([gm],
 266         AC_HELP_STRING([--with-gm=path-to-gm-source-tree],
 267                        [build gmlnd against path]),
 268         [
 269                 case $with_gm in
 270                 no)    ENABLE_GM=0
 271                        ;;
 272                 *)     ENABLE_GM=1
 273                        GM_SRC="$with_gm"
 274                        ;;
 275                 esac
 276         ],[
 277                 ENABLE_GM=0
 278         ])
 279 AC_ARG_WITH([gm-install],
 280         AC_HELP_STRING([--with-gm-install=path-to-gm-install-tree],
 281                        [say where GM has been installed]),
 282         [
 283                 GM_INSTALL=$with_gm_install
 284         ],[
 285                 GM_INSTALL="/opt/gm"
 286         ])
 287 if test $ENABLE_GM -eq 0; then
 288         AC_MSG_RESULT([no])
 289 else
 290         AC_MSG_RESULT([yes])
 291
 292         GMLND="gmlnd"
 293         GMCPPFLAGS="-I$GM_SRC/include -I$GM_SRC/drivers -I$GM_SRC/drivers/linux/gm"
 294
 295         if test -f $GM_INSTALL/lib/libgm.a -o \
 296                 -f $GM_INSTALL/lib64/libgm.a; then
 297                 GMLIBS="-L$GM_INSTALL/lib -L$GM_INSTALL/lib64"
 298         else
 299                 AC_MSG_ERROR([Cant find GM libraries under $GM_INSTALL])
 300         fi
 301
 302         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 303         EXTRA_KCFLAGS="$GMCPPFLAGS -DGM_KERNEL $EXTRA_KCFLAGS"
 304
 305         AC_MSG_CHECKING([that code using GM compiles with given path])
 306         LB_LINUX_TRY_COMPILE([
 307                 #define GM_STRONG_TYPES 1
 308                 #ifdef VERSION
 309                 #undef VERSION
 310                 #endif
 311                 #include "gm.h"
 312                 #include "gm_internal.h"
 313         ],[
 314                 struct gm_port *port = NULL;
 315                 gm_recv_event_t *rxevent = gm_blocking_receive_no_spin(port);
 316                 return 0;
 317         ],[
 318                 AC_MSG_RESULT([yes])
 319         ],[
 320                 AC_MSG_RESULT([no])
 321                 AC_MSG_ERROR([Bad --with-gm path])
 322         ])
 323
 324         AC_MSG_CHECKING([that GM has gm_register_memory_ex_phys()])
 325         LB_LINUX_TRY_COMPILE([
 326                 #define GM_STRONG_TYPES 1
 327                 #ifdef VERSION
 328                 #undef VERSION
 329                 #endif
 330                 #include "gm.h"
 331                 #include "gm_internal.h"
 332         ],[
 333                 gm_status_t     gmrc;
 334                 struct gm_port *port = NULL;
 335                 gm_u64_t        phys = 0;
 336                 gm_up_t         pvma = 0;
 337
 338                 gmrc = gm_register_memory_ex_phys(port, phys, 100, pvma);
 339                 return 0;
 340         ],[
 341                 AC_MSG_RESULT([yes])
 342         ],[
 343                 AC_MSG_RESULT([no.
 344 Please patch the GM sources as follows...
 345     cd $GM_SRC
 346     patch -p0 < $PWD/lnet/klnds/gmlnd/gm-reg-phys.patch
 347 ...then rebuild and re-install them])
 348                 AC_MSG_ERROR([Can't build GM without gm_register_memory_ex_phys()])
 349         ])
 350
 351         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 352 fi
 353 AC_SUBST(GMCPPFLAGS)
 354 AC_SUBST(GMLIBS)
 355 AC_SUBST(GMLND)
 356 ])
 357
 358
 359 #
 360 # LN_CONFIG_MX
 361 #
 362 AC_DEFUN([LN_CONFIG_MX],
 363 [AC_MSG_CHECKING([whether to enable Myrinet MX support])
 364 # set default
 365 MXPATH="/opt/mx"
 366 AC_ARG_WITH([mx],
 367        AC_HELP_STRING([--with-mx=path],
 368                       [build mxlnd against path]),
 369        [
 370                case $with_mx in
 371                yes)    ENABLEMX=2
 372                        ;;
 373                no)     ENABLEMX=0
 374                        ;;
 375                *)      MXPATH=$with_mx
 376                        ENABLEMX=3
 377                        ;;
 378                esac
 379        ],[
 380                ENABLEMX=1
 381        ])
 382 if test $ENABLEMX -eq 0; then
 383        AC_MSG_RESULT([disabled])
 384 elif test ! \( -f ${MXPATH}/include/myriexpress.h -a \
 385               -f ${MXPATH}/include/mx_kernel_api.h -a \
 386               -f ${MXPATH}/include/mx_pin.h \); then
 387        AC_MSG_RESULT([no])
 388        case $ENABLEMX in
 389        1) ;;
 390        2) AC_MSG_ERROR([Myrinet MX kernel headers not present]);;
 391        3) AC_MSG_ERROR([bad --with-mx path]);;
 392        *) AC_MSG_ERROR([internal error]);;
 393        esac
 394 else
 395        MXCPPFLAGS="-I$MXPATH/include"
 396        EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 397        EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
 398        MXLIBS="-L$MXPATH/lib"
 399        LB_LINUX_TRY_COMPILE([
 400                #define MX_KERNEL 1
 401                #include <mx_extensions.h>
 402                #include <myriexpress.h>
 403        ],[
 404                mx_endpoint_t   end;
 405                mx_status_t     status;
 406                mx_request_t    request;
 407                int             result;
 408
 409                mx_init();
 410                mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
 411                mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
 412                mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
 413                mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
 414                return 0;
 415        ],[
 416                AC_MSG_RESULT([yes])
 417                MXLND="mxlnd"
 418        ],[
 419                AC_MSG_RESULT([no])
 420                case $ENABLEMX in
 421                1) ;;
 422                2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]);;
 423                3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]);;
 424                *) AC_MSG_ERROR([internal error]);;
 425                esac
 426                MXLND=""
 427                MXCPPFLAGS=""
 428        ])
 429        EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 430 fi
 431 AC_SUBST(MXCPPFLAGS)
 432 AC_SUBST(MXLIBS)
 433 AC_SUBST(MXLND)
 434 ])
 435
 436
 437
 438 #
 439 # LN_CONFIG_O2IB
 440 #
 441 AC_DEFUN([LN_CONFIG_O2IB],[
 442 AC_MSG_CHECKING([whether to enable OpenIB gen2 support])
 443 # set default
 444 AC_ARG_WITH([o2ib],
 445         AC_HELP_STRING([--with-o2ib=path],
 446                        [build o2iblnd against path]),
 447         [
 448                 case $with_o2ib in
 449                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 450                         ENABLEO2IB=2
 451                         ;;
 452                 no)     ENABLEO2IB=0
 453                         ;;
 454                 *)      O2IBPATHS=$with_o2ib
 455                         ENABLEO2IB=3
 456                         ;;
 457                 esac
 458         ],[
 459                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 460                 ENABLEO2IB=1
 461         ])
 462 if test $ENABLEO2IB -eq 0; then
 463         AC_MSG_RESULT([disabled])
 464 else
 465         o2ib_found=false
 466         for O2IBPATH in $O2IBPATHS; do
 467                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 468                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 469                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 470                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 471                         o2ib_found=true
 472                         break
 473                 fi
 474         done
 475         if ! $o2ib_found; then
 476                 AC_MSG_RESULT([no])
 477                 case $ENABLEO2IB in
 478                         1) ;;
 479                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 480                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 481                         *) AC_MSG_ERROR([internal error]);;
 482                 esac
 483         else
 484                 # figure out whether the kernel has an infiniband stack
 485                 # configured
 486                 LB_LINUX_CONFIG_IM([INFINIBAND],[
 487                         CONFIG_INFINIBAND_MODULE_defined=true
 488                 ],[
 489                         CONFIG_INFINIBAND_MODULE_defined=false
 490                 ])
 491                 # at this point we know that the user either explicitly
 492                 # requested o2ib support or didn't explicitly disable it so
 493                 # make sure the kernel's CONFIG_INFINIBAND variable is set
 494                 # appropriately.
 495                 #
 496                 # possible error conditions are:
 497                 # 1) --with-o2ib[=yes] (implies in kernel since no path was
 498                 #    given) and kernel not configured for IB
 499                 # 2) --with-o2ib=/path and kernel is configured for IB
 500                 #
 501                 if test "$O2IBPATH" = "$LINUX" -o "$O2IBPATH" = "$LINUX/drivers/infiniband"; then
 502                         # infiniband stack is in the kernel
 503                         if test $ENABLEO2IB -eq 1 -o $ENABLEO2IB -eq 2 && ! $CONFIG_INFINIBAND_MODULE_defined; then
 504                                 # case #1
 505                                 AC_MSG_ERROR([Kernel supplied OFED drivers are being requested however the kernel is NOT configured to build OFED modules.  Please specify --with-o2ib=<path_to_ofed> or rebuild the kernel with Infiniband enabled.])
 506                         fi
 507                 else
 508                         # had to be a specified path with --with-o2ib=/path
 509                         if $CONFIG_INFINIBAND_MODULE_defined; then
 510                                 # case #2
 511                                 AC_MSG_ERROR([External OFED source has been specified but the kernel is configured to build OFED modules as well.  Remove --with-o2ib from the configuration or rebuild the kernel without Infiniband.])
 512                         fi
 513                 fi
 514                 if $o2ib_found; then
 515                         O2IBCPPFLAGS="-I$O2IBPATH/include"
 516                         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 517                         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $O2IBCPPFLAGS"
 518                         EXTRA_LNET_INCLUDE="$O2IBCPPFLAGS $EXTRA_LNET_INCLUDE"
 519                         LB_LINUX_TRY_COMPILE([
 520                                 #include <linux/version.h>
 521                                 #include <linux/pci.h>
 522                                 #if !HAVE_GFP_T
 523                                 typedef int gfp_t;
 524                                 #endif
 525                                 #include <rdma/rdma_cm.h>
 526                                 #include <rdma/ib_cm.h>
 527                                 #include <rdma/ib_verbs.h>
 528                                 #include <rdma/ib_fmr_pool.h>
 529                         ],[
 530                                 struct rdma_cm_id          *cm_id;
 531                                 struct rdma_conn_param      conn_param;
 532                                 struct ib_device_attr       device_attr;
 533                                 struct ib_qp_attr           qp_attr;
 534                                 struct ib_pool_fmr          pool_fmr;
 535                                 enum   ib_cm_rej_reason     rej_reason;
 536
 537                                 cm_id = rdma_create_id(NULL, NULL, RDMA_PS_TCP);
 538                                 return PTR_ERR(cm_id);
 539                         ],[
 540                                 AC_MSG_RESULT([yes])
 541                                 O2IBLND="o2iblnd"
 542                         ],[
 543                                 AC_MSG_RESULT([no])
 544                                 case $ENABLEO2IB in
 545                                         1) ;;
 546                                         2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]);;
 547                                         3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]);;
 548                                         *) AC_MSG_ERROR([internal error]);;
 549                                 esac
 550                                 O2IBLND=""
 551                                 O2IBCPPFLAGS=""
 552                         ])
 553                         # we know at this point that the found OFED source is good
 554                         O2IB_SYMVER=""
 555                         if test $ENABLEO2IB -eq 3 ; then
 556                                 # OFED default rpm not handle sles10 Modules.symvers name
 557                                 for name in Module.symvers Modules.symvers; do
 558                                         if test -f $O2IBPATH/$name; then
 559                                                 O2IB_SYMVER=$name;
 560                                                 break;
 561                                         fi
 562                                 done
 563                                 if test -n $O2IB_SYMVER ; then
 564                                         AC_MSG_NOTICE([adding $O2IBPATH/$O2IB_SYMVER to $PWD/$SYMVERFILE])
 565                                         # strip out the existing symbols versions first
 566                                         egrep -v $(echo $(awk '{ print $2 }' $O2IBPATH/$O2IB_SYMVER) | tr ' ' '|') $PWD/$SYMVERFILE > $PWD/$SYMVERFILE.old
 567                                         cat $PWD/$SYMVERFILE.old $O2IBPATH/$O2IB_SYMVER > $PWD/$SYMVERFILE
 568                                 else
 569                                         AC_MSG_ERROR([an external source tree was specified for o2iblnd however I could not find a $O2IBPATH/Module.symvers there])
 570                                 fi
 571                         fi
 572
 573                         LB_LINUX_TRY_COMPILE([
 574                                 #include <linux/version.h>
 575                                 #include <linux/pci.h>
 576                                 #if !HAVE_GFP_T
 577                                 typedef int gfp_t;
 578                                 #endif
 579                                 #include <rdma/ib_verbs.h>
 580                         ],[
 581                                 ib_dma_map_single(NULL, NULL, 0, 0);
 582                                 return 0;
 583                         ],[
 584                                 AC_MSG_RESULT(yes)
 585                                 AC_DEFINE(HAVE_OFED_IB_DMA_MAP, 1,
 586                                           [ib_dma_map_single defined])
 587                         ],[
 588                                 AC_MSG_RESULT(NO)
 589                         ])
 590
 591                         LB_LINUX_TRY_COMPILE([
 592                                 #include <linux/version.h>
 593                                 #include <linux/pci.h>
 594                                 #if !HAVE_GFP_T
 595                                 typedef int gfp_t;
 596                                 #endif
 597                                 #include <rdma/ib_verbs.h>
 598                         ],[
 599                                 ib_create_cq(NULL, NULL, NULL, NULL, 0, 0);
 600                                 return 0;
 601                         ],[
 602                                 AC_MSG_RESULT(yes)
 603                                 AC_DEFINE(HAVE_OFED_IB_COMP_VECTOR, 1,
 604                                           [has completion vector])
 605                         ],[
 606                                 AC_MSG_RESULT(NO)
 607                         ])
 608
 609                         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 610                 fi
 611         fi
 612 fi
 613
 614 AC_SUBST(EXTRA_LNET_INCLUDE)
 615 AC_SUBST(O2IBCPPFLAGS)
 616 AC_SUBST(O2IBLND)
 617 ])
 618
 619 #
 620 # LN_CONFIG_OPENIB
 621 #
 622 # check for OpenIB in the kernel
 623 AC_DEFUN([LN_CONFIG_OPENIB],[
 624 AC_MSG_CHECKING([whether to enable OpenIB support])
 625 # set default
 626 OPENIBPATH="$LINUX/drivers/infiniband"
 627 AC_ARG_WITH([openib],
 628         AC_HELP_STRING([--with-openib=path],
 629                        [build openiblnd against path]),
 630         [
 631                 case $with_openib in
 632                 yes)    ENABLEOPENIB=2
 633                         ;;
 634                 no)     ENABLEOPENIB=0
 635                         ;;
 636                 *)      OPENIBPATH="$with_openib"
 637                         ENABLEOPENIB=3
 638                         ;;
 639                 esac
 640         ],[
 641                 ENABLEOPENIB=1
 642         ])
 643 if test $ENABLEOPENIB -eq 0; then
 644         AC_MSG_RESULT([disabled])
 645 elif test ! \( -f ${OPENIBPATH}/include/ts_ib_core.h -a \
 646                -f ${OPENIBPATH}/include/ts_ib_cm.h -a \
 647                -f ${OPENIBPATH}/include/ts_ib_sa_client.h \); then
 648         AC_MSG_RESULT([no])
 649         case $ENABLEOPENIB in
 650         1) ;;
 651         2) AC_MSG_ERROR([kernel OpenIB headers not present]);;
 652         3) AC_MSG_ERROR([bad --with-openib path]);;
 653         *) AC_MSG_ERROR([internal error]);;
 654         esac
 655 else
 656         case $ENABLEOPENIB in
 657         1|2) OPENIBCPPFLAGS="-I$OPENIBPATH/include -DIN_TREE_BUILD";;
 658         3)   OPENIBCPPFLAGS="-I$OPENIBPATH/include";;
 659         *)   AC_MSG_RESULT([no])
 660              AC_MSG_ERROR([internal error]);;
 661         esac
 662         OPENIBCPPFLAGS="$OPENIBCPPFLAGS -DIB_NTXRXPARAMS=4"
 663         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 664         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $OPENIBCPPFLAGS"
 665         LB_LINUX_TRY_COMPILE([
 666                 #include <ts_ib_core.h>
 667                 #include <ts_ib_cm.h>
 668                 #include <ts_ib_sa_client.h>
 669         ],[
 670                 struct ib_device_properties dev_props;
 671                 struct ib_cm_active_param   cm_active_params;
 672                 tTS_IB_CLIENT_QUERY_TID     tid;
 673                 int                         enum1 = IB_QP_ATTRIBUTE_STATE;
 674                 int                         enum2 = IB_ACCESS_LOCAL_WRITE;
 675                 int                         enum3 = IB_CQ_CALLBACK_INTERRUPT;
 676                 int                         enum4 = IB_CQ_PROVIDER_REARM;
 677                 return 0;
 678         ],[
 679                 AC_MSG_RESULT([yes])
 680                 OPENIBLND="openiblnd"
 681         ],[
 682                 AC_MSG_RESULT([no])
 683                 case $ENABLEOPENIB in
 684                 1) ;;
 685                 2) AC_MSG_ERROR([can't compile with kernel OpenIB headers]);;
 686                 3) AC_MSG_ERROR([can't compile with OpenIB headers under $OPENIBPATH]);;
 687                 *) AC_MSG_ERROR([internal error]);;
 688                 esac
 689                 OPENIBLND=""
 690                 OPENIBCPPFLAGS=""
 691         ])
 692         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 693 fi
 694 AC_SUBST(OPENIBCPPFLAGS)
 695 AC_SUBST(OPENIBLND)
 696 ])
 697
 698 #
 699 # LN_CONFIG_CIBLND
 700 #
 701 AC_DEFUN([LN_CONFIG_CIB],[
 702 AC_MSG_CHECKING([whether to enable Cisco/TopSpin IB support])
 703 # set default
 704 CIBPATH=""
 705 CIBLND=""
 706 AC_ARG_WITH([cib],
 707         AC_HELP_STRING([--with-cib=path],
 708                        [build ciblnd against path]),
 709         [
 710                 case $with_cib in
 711                 no)     AC_MSG_RESULT([no]);;
 712                 *)      CIBPATH="$with_cib"
 713                         if test -d "$CIBPATH"; then
 714                                 AC_MSG_RESULT([yes])
 715                         else
 716                                 AC_MSG_RESULT([no])
 717                                 AC_MSG_ERROR([No directory $CIBPATH])
 718                         fi;;
 719                 esac
 720         ],[
 721                 AC_MSG_RESULT([no])
 722         ])
 723 if test -n "$CIBPATH"; then
 724         CIBCPPFLAGS="-I${CIBPATH}/ib/ts_api_ng/include -I${CIBPATH}/all/kernel_services/include -DUSING_TSAPI"
 725         CIBCPPFLAGS="$CIBCPPFLAGS -DIB_NTXRXPARAMS=3"
 726         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 727         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $CIBCPPFLAGS"
 728         LB_LINUX_TRY_COMPILE([
 729                 #include <ts_ib_core.h>
 730                 #include <ts_ib_cm.h>
 731                 #include <ts_ib_sa_client.h>
 732         ],[
 733                 struct ib_device_properties dev_props;
 734                 struct ib_cm_active_param   cm_active_params;
 735                 tTS_IB_CLIENT_QUERY_TID     tid;
 736                 int                         enum1 = TS_IB_QP_ATTRIBUTE_STATE;
 737                 int                         enum2 = TS_IB_ACCESS_LOCAL_WRITE;
 738                 int                         enum3 = TS_IB_CQ_CALLBACK_INTERRUPT;
 739                 int                         enum4 = TS_IB_CQ_PROVIDER_REARM;
 740                 return 0;
 741         ],[
 742                 CIBLND="ciblnd"
 743         ],[
 744                 AC_MSG_ERROR([can't compile ciblnd with given path])
 745                 CIBCPPFLAGS=""
 746         ])
 747         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 748 fi
 749 AC_SUBST(CIBCPPFLAGS)
 750 AC_SUBST(CIBLND)
 751 ])
 752
 753 #
 754 # LN_CONFIG_IIB
 755 #
 756 # check for infinicon infiniband support
 757 #
 758 AC_DEFUN([LN_CONFIG_IIB],[
 759 AC_MSG_CHECKING([whether to enable Infinicon support])
 760 # set default
 761 IIBPATH="/usr/include"
 762 AC_ARG_WITH([iib],
 763         AC_HELP_STRING([--with-iib=path],
 764                        [build iiblnd against path]),
 765         [
 766                 case $with_iib in
 767                 yes)    ENABLEIIB=2
 768                         ;;
 769                 no)     ENABLEIIB=0
 770                         ;;
 771                 *)      IIBPATH="${with_iib}/include"
 772                         ENABLEIIB=3
 773                         ;;
 774                 esac
 775         ],[
 776                 ENABLEIIB=1
 777         ])
 778 if test $ENABLEIIB -eq 0; then
 779         AC_MSG_RESULT([disabled])
 780 elif test ! \( -f ${IIBPATH}/linux/iba/ibt.h \); then
 781         AC_MSG_RESULT([no])
 782         case $ENABLEIIB in
 783         1) ;;
 784         2) AC_MSG_ERROR([default Infinicon headers not present]);;
 785         3) AC_MSG_ERROR([bad --with-iib path]);;
 786         *) AC_MSG_ERROR([internal error]);;
 787         esac
 788 else
 789         IIBCPPFLAGS="-I$IIBPATH"
 790         if test $IIBPATH != "/usr/include"; then
 791                 # we need /usr/include come what may
 792                 IIBCPPFLAGS="$IIBCPPFLAGS -I/usr/include"
 793         fi
 794         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 795         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $IIBCPPFLAGS"
 796         LB_LINUX_TRY_COMPILE([
 797                 #include <linux/iba/ibt.h>
 798         ],[
 799                 IBT_INTERFACE_UNION interfaces;
 800                 FSTATUS             rc;
 801
 802                  rc = IbtGetInterfaceByVersion(IBT_INTERFACE_VERSION_2,
 803                                                &interfaces);
 804
 805                 return rc == FSUCCESS ? 0 : 1;
 806         ],[
 807                 AC_MSG_RESULT([yes])
 808                 IIBLND="iiblnd"
 809         ],[
 810                 AC_MSG_RESULT([no])
 811                 case $ENABLEIIB in
 812                 1) ;;
 813                 2) AC_MSG_ERROR([can't compile with default Infinicon headers]);;
 814                 3) AC_MSG_ERROR([can't compile with Infinicon headers under $IIBPATH]);;
 815                 *) AC_MSG_ERROR([internal error]);;
 816                 esac
 817                 IIBLND=""
 818                 IIBCPPFLAGS=""
 819         ])
 820         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 821 fi
 822 AC_SUBST(IIBCPPFLAGS)
 823 AC_SUBST(IIBLND)
 824 ])
 825
 826 #
 827 # LN_CONFIG_VIB
 828 #
 829 # check for Voltaire infiniband support
 830 #
 831 AC_DEFUN([LN_CONFIG_VIB],
 832 [AC_MSG_CHECKING([whether to enable Voltaire IB support])
 833 VIBPATH=""
 834 AC_ARG_WITH([vib],
 835         AC_HELP_STRING([--with-vib=path],
 836                        [build viblnd against path]),
 837         [
 838                 case $with_vib in
 839                 no)     AC_MSG_RESULT([no]);;
 840                 *)      VIBPATH="${with_vib}/src/nvigor/ib-code"
 841                         if test -d "$with_vib" -a -d "$VIBPATH"; then
 842                                 AC_MSG_RESULT([yes])
 843                         else
 844                                 AC_MSG_RESULT([no])
 845                                 AC_MSG_ERROR([No directory $VIBPATH])
 846                         fi;;
 847                 esac
 848         ],[
 849                 AC_MSG_RESULT([no])
 850         ])
 851 if test -z "$VIBPATH"; then
 852         VIBLND=""
 853 else
 854         VIBCPPFLAGS="-I${VIBPATH}/include -I${VIBPATH}/cm"
 855         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 856         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 857         LB_LINUX_TRY_COMPILE([
 858                 #include <linux/list.h>
 859                 #include <asm/byteorder.h>
 860                 #ifdef __BIG_ENDIAN
 861                 # define CPU_BE 1
 862                 # define CPU_LE 0
 863                 #endif
 864                 #ifdef __LITTLE_ENDIAN
 865                 # define CPU_BE 0
 866                 # define CPU_LE 1
 867                 #endif
 868                 #include <vverbs.h>
 869                 #include <ib-cm.h>
 870                 #include <ibat.h>
 871         ],[
 872                 vv_hca_h_t       kib_hca;
 873                 vv_return_t      vvrc;
 874                 cm_cep_handle_t  cep;
 875                 ibat_arp_data_t  arp_data;
 876                 ibat_stat_t      ibatrc;
 877
 878                 vvrc = vv_hca_open("ANY_HCA", NULL, &kib_hca);
 879                 cep = cm_create_cep(cm_cep_transp_rc);
 880                 ibatrc = ibat_get_ib_data((uint32_t)0, (uint32_t)0,
 881                                           ibat_paths_primary, &arp_data,
 882                                           (ibat_get_ib_data_reply_fn_t)NULL,
 883                                           NULL, 0);
 884                 return 0;
 885         ],[
 886                 VIBLND="viblnd"
 887         ],[
 888                 AC_MSG_ERROR([can't compile viblnd with given path])
 889         ])
 890         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 891 fi
 892 if test -n "$VIBLND"; then
 893         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 894         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 895         AC_MSG_CHECKING([if Voltaire still uses void * sg addresses])
 896         LB_LINUX_TRY_COMPILE([
 897                 #include <linux/list.h>
 898                 #include <asm/byteorder.h>
 899                 #ifdef __BIG_ENDIAN
 900                 # define CPU_BE 1
 901                 # define CPU_LE 0
 902                 #endif
 903                 #ifdef __LITTLE_ENDIAN
 904                 # define CPU_BE 0
 905                 # define CPU_LE 1
 906                 #endif
 907                 #include <vverbs.h>
 908                 #include <ib-cm.h>
 909                 #include <ibat.h>
 910         ],[
 911                 vv_scatgat_t  sg;
 912
 913                 return &sg.v_address[3] == NULL;
 914         ],[
 915                 AC_MSG_RESULT([yes])
 916                 VIBCPPFLAGS="$VIBCPPFLAGS -DIBNAL_VOIDSTAR_SGADDR=1"
 917         ],[
 918                 AC_MSG_RESULT([no])
 919         ])
 920         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 921 fi
 922 AC_SUBST(VIBCPPFLAGS)
 923 AC_SUBST(VIBLND)
 924 ])
 925
 926 #
 927 # LN_CONFIG_RALND
 928 #
 929 # check whether to use the RapidArray lnd
 930 #
 931 AC_DEFUN([LN_CONFIG_RALND],
 932 [#### Rapid Array
 933 AC_MSG_CHECKING([if RapidArray kernel headers are present])
 934 # placeholder
 935 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 936 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 937 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 938 LB_LINUX_TRY_COMPILE([
 939         #include <linux/types.h>
 940         #include <rapl.h>
 941 ],[
 942         RAP_RETURN          rc;
 943         RAP_PVOID           dev_handle;
 944
 945         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 946
 947         return rc == RAP_SUCCESS ? 0 : 1;
 948 ],[
 949         AC_MSG_RESULT([yes])
 950         RALND="ralnd"
 951 ],[
 952         AC_MSG_RESULT([no])
 953         RALND=""
 954         RACPPFLAGS=""
 955 ])
 956 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 957 AC_SUBST(RACPPFLAGS)
 958 AC_SUBST(RALND)
 959 ])
 960
 961
 962
 963 #
 964 # LN_PROG_LINUX
 965 #
 966 # LNet linux kernel checks
 967 #
 968 AC_DEFUN([LN_PROG_LINUX],
 969 [
 970 LN_CONFIG_AFFINITY
 971 LN_CONFIG_BACKOFF
 972 LN_CONFIG_QUADRICS
 973 LN_CONFIG_GM
 974 LN_CONFIG_OPENIB
 975 LN_CONFIG_CIB
 976 LN_CONFIG_VIB
 977 LN_CONFIG_IIB
 978 LN_CONFIG_O2IB
 979 LN_CONFIG_RALND
 980 LN_CONFIG_PTLLND
 981 LN_CONFIG_MX
 982 ])
 983
 984 #
 985 # LN_PROG_DARWIN
 986 #
 987 # Darwin checks
 988 #
 989 AC_DEFUN([LN_PROG_DARWIN],
 990 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 991 ])
 992
 993 #
 994 # LN_PATH_DEFAULTS
 995 #
 996 # default paths for installed files
 997 #
 998 AC_DEFUN([LN_PATH_DEFAULTS],
 999 [
1000 ])
1001
1002 #
1003 # LN_CONFIGURE
1004 #
1005 # other configure checks
1006 #
1007 AC_DEFUN([LN_CONFIGURE],
1008 [# lnet/utils/portals.c
1009 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
1010 AC_CHECK_FUNCS([gethostbyname socket connect])
1011
1012 # lnet/utils/debug.c
1013 AC_CHECK_HEADERS([linux/version.h])
1014
1015 AC_CHECK_TYPE([spinlock_t],
1016         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
1017         [],
1018         [#include <linux/spinlock.h>])
1019
1020 # lnet/utils/wirecheck.c
1021 AC_CHECK_FUNCS([strnlen])
1022
1023 # --------  Check for required packages  --------------
1024
1025 #
1026 # LC_CONFIG_READLINE
1027 #
1028 # Build with readline
1029 #
1030 AC_MSG_CHECKING([whether to enable readline support])
1031 AC_ARG_ENABLE(readline,
1032         AC_HELP_STRING([--disable-readline],
1033                         [disable readline support]),
1034         [],[enable_readline='yes'])
1035 AC_MSG_RESULT([$enable_readline])
1036
1037 # -------- check for readline if enabled ----
1038 if test x$enable_readline = xyes ; then
1039         LIBS_save="$LIBS"
1040         LIBS="-lncurses $LIBS"
1041         AC_CHECK_LIB([readline],[readline],[
1042         LIBREADLINE="-lreadline -lncurses"
1043         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
1044         ],[
1045         LIBREADLINE=""
1046         ])
1047         LIBS="$LIBS_save"
1048 else
1049         LIBREADLINE=""
1050 fi
1051 AC_SUBST(LIBREADLINE)
1052
1053 # -------- enable acceptor libwrap (TCP wrappers) support? -------
1054 AC_MSG_CHECKING([if libwrap support is requested])
1055 AC_ARG_ENABLE([libwrap],
1056         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
1057         [case "${enableval}" in
1058                 yes) enable_libwrap=yes ;;
1059                 no) enable_libwrap=no ;;
1060                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
1061         esac],[enable_libwrap=no])
1062 AC_MSG_RESULT([$enable_libwrap])
1063 if test x$enable_libwrap = xyes ; then
1064         LIBWRAP="-lwrap"
1065         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
1066 else
1067         LIBWRAP=""
1068 fi
1069 AC_SUBST(LIBWRAP)
1070
1071 # ----------------------------------------
1072 # some tests for catamount-like systems
1073 # ----------------------------------------
1074 AC_ARG_ENABLE([sysio_init],
1075         AC_HELP_STRING([--disable-sysio-init],
1076                 [call sysio init functions when initializing liblustre]),
1077         [],[enable_sysio_init=yes])
1078 AC_MSG_CHECKING([whether to initialize libsysio])
1079 AC_MSG_RESULT([$enable_sysio_init])
1080 if test x$enable_sysio_init != xno ; then
1081         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
1082 fi
1083
1084 AC_ARG_ENABLE([urandom],
1085         AC_HELP_STRING([--disable-urandom],
1086                 [disable use of /dev/urandom for liblustre]),
1087         [],[enable_urandom=yes])
1088 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
1089 AC_MSG_RESULT([$enable_urandom])
1090 if test x$enable_urandom != xno ; then
1091         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
1092 fi
1093
1094 # -------- check for -lcap support ----
1095 if test x$enable_liblustre = xyes ; then
1096         AC_CHECK_LIB([cap], [cap_get_proc],
1097                 [
1098                         CAP_LIBS="-lcap"
1099                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
1100                 ],
1101                 [
1102                         CAP_LIBS=""
1103                 ])
1104         AC_SUBST(CAP_LIBS)
1105
1106 fi
1107
1108 LN_CONFIG_MAX_PAYLOAD
1109 LN_CONFIG_UPTLLND
1110 LN_CONFIG_USOCKLND
1111 ])
1112
1113 #
1114 # LN_CONDITIONALS
1115 #
1116 # AM_CONDITOINAL defines for lnet
1117 #
1118 AC_DEFUN([LN_CONDITIONALS],
1119 [AM_CONDITIONAL(BUILD_QSWLND, test x$QSWLND = "xqswlnd")
1120 AM_CONDITIONAL(BUILD_GMLND, test x$GMLND = "xgmlnd")
1121 AM_CONDITIONAL(BUILD_MXLND, test x$MXLND = "xmxlnd")
1122 AM_CONDITIONAL(BUILD_O2IBLND, test x$O2IBLND = "xo2iblnd")
1123 AM_CONDITIONAL(BUILD_OPENIBLND, test x$OPENIBLND = "xopeniblnd")
1124 AM_CONDITIONAL(BUILD_CIBLND, test x$CIBLND = "xciblnd")
1125 AM_CONDITIONAL(BUILD_IIBLND, test x$IIBLND = "xiiblnd")
1126 AM_CONDITIONAL(BUILD_VIBLND, test x$VIBLND = "xviblnd")
1127 AM_CONDITIONAL(BUILD_RALND, test x$RALND = "xralnd")
1128 AM_CONDITIONAL(BUILD_PTLLND, test x$PTLLND = "xptllnd")
1129 AM_CONDITIONAL(BUILD_UPTLLND, test x$UPTLLND = "xptllnd")
1130 AM_CONDITIONAL(BUILD_USOCKLND, test x$USOCKLND = "xusocklnd")
1131 ])
1132
1133 #
1134 # LN_CONFIG_FILES
1135 #
1136 # files that should be generated with AC_OUTPUT
1137 #
1138 AC_DEFUN([LN_CONFIG_FILES],
1139 [AC_CONFIG_FILES([
1140 lnet/Kernelenv
1141 lnet/Makefile
1142 lnet/autoMakefile
1143 lnet/autoconf/Makefile
1144 lnet/doc/Makefile
1145 lnet/include/Makefile
1146 lnet/include/lnet/Makefile
1147 lnet/include/lnet/linux/Makefile
1148 lnet/klnds/Makefile
1149 lnet/klnds/autoMakefile
1150 lnet/klnds/gmlnd/Makefile
1151 lnet/klnds/mxlnd/autoMakefile
1152 lnet/klnds/mxlnd/Makefile
1153 lnet/klnds/gmlnd/autoMakefile
1154 lnet/klnds/openiblnd/Makefile
1155 lnet/klnds/openiblnd/autoMakefile
1156 lnet/klnds/o2iblnd/Makefile
1157 lnet/klnds/o2iblnd/autoMakefile
1158 lnet/klnds/ciblnd/Makefile
1159 lnet/klnds/ciblnd/autoMakefile
1160 lnet/klnds/iiblnd/Makefile
1161 lnet/klnds/iiblnd/autoMakefile
1162 lnet/klnds/viblnd/Makefile
1163 lnet/klnds/viblnd/autoMakefile
1164 lnet/klnds/qswlnd/Makefile
1165 lnet/klnds/qswlnd/autoMakefile
1166 lnet/klnds/ralnd/Makefile
1167 lnet/klnds/ralnd/autoMakefile
1168 lnet/klnds/socklnd/Makefile
1169 lnet/klnds/socklnd/autoMakefile
1170 lnet/klnds/ptllnd/Makefile
1171 lnet/klnds/ptllnd/autoMakefile
1172 lnet/lnet/Makefile
1173 lnet/lnet/autoMakefile
1174 lnet/selftest/Makefile
1175 lnet/selftest/autoMakefile
1176 lnet/ulnds/Makefile
1177 lnet/ulnds/autoMakefile
1178 lnet/ulnds/socklnd/Makefile
1179 lnet/ulnds/ptllnd/Makefile
1180 lnet/utils/Makefile
1181 ])
1182 case $lb_target_os in
1183         darwin)
1184                 AC_CONFIG_FILES([
1185 lnet/include/lnet/darwin/Makefile
1186 ])
1187                 ;;
1188 esac
1189 ])