lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD],
   7 [AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                        [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19         AC_DEFINE_UNQUOTED(LNET_MAX_PAYLOAD, $LNET_MAX_PAYLOAD,
  20                            [Max LNET payload])
  21 ])
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION],
  29 [AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ])
  43
  44 #
  45 # LN_FUNC_DEV_GET_BY_NAME_2ARG
  46 #
  47 AC_DEFUN([LN_FUNC_DEV_GET_BY_NAME_2ARG],
  48 [AC_MSG_CHECKING([if dev_get_by_name has two args])
  49 LB_LINUX_TRY_COMPILE([
  50         #include <linux/netdevice.h>
  51 ],[
  52         dev_get_by_name(NULL, NULL);
  53 ],[
  54         AC_MSG_RESULT([yes])
  55         AC_DEFINE(HAVE_DEV_GET_BY_NAME_2ARG, 1, [dev_get_by_name has 2 args])
  56 ],[
  57         AC_MSG_RESULT([no])
  58 ])
  59 ])
  60
  61 #
  62 # LN_CONFIG_AFFINITY
  63 #
  64 # check if cpu affinity is available/wanted
  65 #
  66 AC_DEFUN([LN_CONFIG_AFFINITY],
  67 [AC_ARG_ENABLE([affinity],
  68         AC_HELP_STRING([--disable-affinity],
  69                        [disable process/irq affinity]),
  70         [],[enable_affinity='yes'])
  71
  72 AC_MSG_CHECKING([for CPU affinity support])
  73 if test x$enable_affinity = xno ; then
  74         AC_MSG_RESULT([no (by request)])
  75 else
  76         LB_LINUX_TRY_COMPILE([
  77                 #include <linux/sched.h>
  78         ],[
  79                 struct task_struct t;
  80                 #if HAVE_CPUMASK_T
  81                 cpumask_t     m;
  82                 #else
  83                 unsigned long m;
  84                 #endif
  85                 set_cpus_allowed(&t, m);
  86         ],[
  87                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
  88                 AC_MSG_RESULT([yes])
  89         ],[
  90                 AC_MSG_RESULT([no (no kernel support)])
  91         ])
  92 fi
  93 ])
  94
  95 #
  96 # LN_CONFIG_PORTALS
  97 #
  98 # configure support for Portals
  99 #
 100 AC_DEFUN([LN_CONFIG_PORTALS],
 101 [AC_MSG_CHECKING([for portals])
 102 AC_ARG_WITH([portals],
 103         AC_HELP_STRING([--with-portals=path],
 104                        [set path to portals]),
 105         [
 106                 case $with_portals in
 107                         no)     ENABLEPORTALS=0
 108                                 ;;
 109                         *)      PORTALS="${with_portals}"
 110                                 ENABLEPORTALS=1
 111                                 ;;
 112                 esac
 113         ], [
 114                 ENABLEPORTALS=0
 115         ])
 116 PTLLNDCPPFLAGS=""
 117 if test $ENABLEPORTALS -eq 0; then
 118         AC_MSG_RESULT([no])
 119 elif test ! \( -f ${PORTALS}/include/portals/p30.h \); then
 120         AC_MSG_RESULT([no])
 121         AC_MSG_ERROR([bad --with-portals path])
 122 else
 123         AC_MSG_RESULT([$PORTALS])
 124         PTLLNDCPPFLAGS="-I${PORTALS}/include"
 125 fi
 126 AC_SUBST(PTLLNDCPPFLAGS)
 127 ])
 128
 129 #
 130 # LN_CONFIG_BACKOFF
 131 #
 132 # check if tunable tcp backoff is available/wanted
 133 #
 134 AC_DEFUN([LN_CONFIG_BACKOFF],
 135 [AC_MSG_CHECKING([for tunable backoff TCP support])
 136 AC_ARG_ENABLE([backoff],
 137        AC_HELP_STRING([--disable-backoff],
 138                       [disable socknal tunable backoff]),
 139        [],[enable_backoff='yes'])
 140 if test x$enable_backoff = xno ; then
 141        AC_MSG_RESULT([no (by request)])
 142 else
 143        BOCD="`grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h`"
 144        if test "$BOCD" != 0 ; then
 145                AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
 146                AC_MSG_RESULT(yes)
 147                if grep rto_max $LINUX/include/linux/tcp.h|grep -q __u16; then
 148                    AC_DEFINE(SOCKNAL_BACKOFF_MS, 1, [tunable backoff TCP in ms])
 149                fi
 150        else
 151                AC_MSG_RESULT([no (no kernel support)])
 152        fi
 153 fi
 154 ])
 155
 156
 157 #
 158 # LN_CONFIG_PTLLND
 159 #
 160 # configure support for Portals LND
 161 #
 162 AC_DEFUN([LN_CONFIG_PTLLND],
 163 [
 164 if test -z "$ENABLEPORTALS"; then
 165         LN_CONFIG_PORTALS
 166 fi
 167
 168 AC_MSG_CHECKING([whether to build the kernel portals LND])
 169
 170 PTLLND=""
 171 if test $ENABLEPORTALS -ne 0; then
 172         AC_MSG_RESULT([yes])
 173         PTLLND="ptllnd"
 174 else
 175         AC_MSG_RESULT([no])
 176 fi
 177 AC_SUBST(PTLLND)
 178 ])
 179
 180 #
 181 # LN_CONFIG_UPTLLND
 182 #
 183 # configure support for Portals LND
 184 #
 185 AC_DEFUN([LN_CONFIG_UPTLLND],
 186 [
 187 if test -z "$ENABLEPORTALS"; then
 188         LN_CONFIG_PORTALS
 189 fi
 190
 191 AC_MSG_CHECKING([whether to build the userspace portals LND])
 192
 193 UPTLLND=""
 194 if test $ENABLEPORTALS -ne 0; then
 195         AC_MSG_RESULT([yes])
 196         UPTLLND="ptllnd"
 197 else
 198         AC_MSG_RESULT([no])
 199 fi
 200 AC_SUBST(UPTLLND)
 201 ])
 202
 203 #
 204 # LN_CONFIG_USOCKLND
 205 #
 206 # configure support for userspace TCP/IP LND
 207 #
 208 AC_DEFUN([LN_CONFIG_USOCKLND],
 209 [AC_MSG_CHECKING([whether to build usocklnd])
 210 AC_ARG_ENABLE([usocklnd],
 211         AC_HELP_STRING([--disable-usocklnd],
 212                         [disable usocklnd]),
 213         [],[enable_usocklnd='yes'])
 214
 215 if test x$enable_usocklnd = xyes ; then
 216         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 217                 AC_MSG_RESULT([yes])
 218                 USOCKLND="usocklnd"
 219         else
 220                 AC_MSG_RESULT([no (libpthread not present or disabled)])
 221                 USOCKLND=""
 222         fi
 223 else
 224         AC_MSG_RESULT([no (disabled explicitly)])
 225         USOCKLND=""
 226 fi
 227 AC_SUBST(USOCKLND)
 228 ])
 229
 230 #
 231 # LN_CONFIG_QUADRICS
 232 #
 233 # check if quadrics support is in this kernel
 234 #
 235 AC_DEFUN([LN_CONFIG_QUADRICS],
 236 [AC_MSG_CHECKING([for QsNet sources])
 237 AC_ARG_WITH([qsnet],
 238         AC_HELP_STRING([--with-qsnet=path],
 239                        [set path to qsnet source (default=$LINUX)]),
 240         [QSNET=$with_qsnet],
 241         [QSNET=$LINUX])
 242 AC_MSG_RESULT([$QSNET])
 243
 244 AC_MSG_CHECKING([if quadrics kernel headers are present])
 245 if test -d $QSNET/drivers/net/qsnet ; then
 246         AC_MSG_RESULT([yes])
 247         QSWLND="qswlnd"
 248         AC_MSG_CHECKING([for multirail EKC])
 249         if test -f $QSNET/include/elan/epcomms.h; then
 250                 AC_MSG_RESULT([supported])
 251                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 252         else
 253                 AC_MSG_RESULT([not supported])
 254                 AC_MSG_ERROR([Need multirail EKC])
 255         fi
 256
 257         if test x$QSNET = x$LINUX ; then
 258                 LB_LINUX_CONFIG([QSNET],[],[
 259                         LB_LINUX_CONFIG([QSNET_MODULE],[],[
 260                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
 261                                 QSWLND=""
 262                                 QSWCPPFLAGS=""
 263                         ])
 264                 ])
 265         fi
 266 else
 267         AC_MSG_RESULT([no])
 268         QSWLND=""
 269         QSWCPPFLAGS=""
 270 fi
 271 AC_SUBST(QSWCPPFLAGS)
 272 AC_SUBST(QSWLND)
 273 ])
 274
 275
 276 #
 277 # LN_CONFIG_MX
 278 #
 279 AC_DEFUN([LN_CONFIG_MX],
 280 [AC_MSG_CHECKING([whether to enable Myrinet MX support])
 281 # set default
 282 MXPATH="/opt/mx"
 283 AC_ARG_WITH([mx],
 284        AC_HELP_STRING([--with-mx=path],
 285                       [build mxlnd against path]),
 286        [
 287                case $with_mx in
 288                yes)    ENABLEMX=2
 289                        ;;
 290                no)     ENABLEMX=0
 291                        ;;
 292                *)      MXPATH=$with_mx
 293                        ENABLEMX=3
 294                        ;;
 295                esac
 296        ],[
 297                ENABLEMX=1
 298        ])
 299 if test $ENABLEMX -eq 0; then
 300        AC_MSG_RESULT([disabled])
 301 elif test ! \( -f ${MXPATH}/include/myriexpress.h -a \
 302               -f ${MXPATH}/include/mx_kernel_api.h -a \
 303               -f ${MXPATH}/include/mx_pin.h \); then
 304        AC_MSG_RESULT([no])
 305        case $ENABLEMX in
 306        1) ;;
 307        2) AC_MSG_ERROR([Myrinet MX kernel headers not present]);;
 308        3) AC_MSG_ERROR([bad --with-mx path]);;
 309        *) AC_MSG_ERROR([internal error]);;
 310        esac
 311 else
 312        MXCPPFLAGS="-I$MXPATH/include"
 313        EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 314        EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
 315        MXLIBS="-L$MXPATH/lib"
 316        LB_LINUX_TRY_COMPILE([
 317                #define MX_KERNEL 1
 318                #include <mx_extensions.h>
 319                #include <myriexpress.h>
 320        ],[
 321                mx_endpoint_t   end;
 322                mx_status_t     status;
 323                mx_request_t    request;
 324                int             result;
 325
 326                mx_init();
 327                mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
 328                mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
 329                mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
 330                mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
 331                return 0;
 332        ],[
 333                AC_MSG_RESULT([yes])
 334                MXLND="mxlnd"
 335        ],[
 336                AC_MSG_RESULT([no])
 337                case $ENABLEMX in
 338                1) ;;
 339                2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]);;
 340                3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]);;
 341                *) AC_MSG_ERROR([internal error]);;
 342                esac
 343                MXLND=""
 344                MXCPPFLAGS=""
 345        ])
 346        EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 347 fi
 348 AC_SUBST(MXCPPFLAGS)
 349 AC_SUBST(MXLIBS)
 350 AC_SUBST(MXLND)
 351 ])
 352
 353
 354
 355 #
 356 # LN_CONFIG_O2IB
 357 #
 358 AC_DEFUN([LN_CONFIG_O2IB],[
 359
 360 AC_MSG_CHECKING([whether to enable OpenIB gen2 support])
 361 # set default
 362 AC_ARG_WITH([o2ib],
 363         AC_HELP_STRING([--with-o2ib=path],
 364                        [build o2iblnd against path]),
 365         [
 366                 case $with_o2ib in
 367                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 368                         ENABLEO2IB=2
 369                         ;;
 370                 no)     ENABLEO2IB=0
 371                         ;;
 372                 *)      O2IBPATHS=$with_o2ib
 373                         ENABLEO2IB=3
 374                         ;;
 375                 esac
 376         ],[
 377                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 378                 ENABLEO2IB=1
 379         ])
 380 if test $ENABLEO2IB -eq 0; then
 381         AC_MSG_RESULT([disabled])
 382 else
 383         o2ib_found=false
 384         for O2IBPATH in $O2IBPATHS; do
 385                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 386                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 387                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 388                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 389                         if test \( -d ${O2IBPATH}/kernel_patches -a \
 390                                    -f ${O2IBPATH}/Makefile \); then
 391                                 AC_MSG_RESULT([no])
 392                                 AC_MSG_ERROR([you appear to be trying to use the OFED distribution's source directory (${O2IBPATH}) rather than the "development/headers" directory which is likely in ${O2IBPATH%-*}])
 393                         fi
 394                         o2ib_found=true
 395                         break
 396                 fi
 397         done
 398         if ! $o2ib_found; then
 399                 AC_MSG_RESULT([no])
 400                 case $ENABLEO2IB in
 401                         1) ;;
 402                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 403                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 404                         *) AC_MSG_ERROR([internal error]);;
 405                 esac
 406         else
 407                 O2IBCPPFLAGS="-I$O2IBPATH/include"
 408                 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 409                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $O2IBCPPFLAGS"
 410                 EXTRA_LNET_INCLUDE="$EXTRA_LNET_INCLUDE $O2IBCPPFLAGS"
 411
 412                 LB_LINUX_TRY_COMPILE([
 413                         #include <linux/version.h>
 414                         #include <linux/pci.h>
 415                         #if !HAVE_GFP_T
 416                         typedef int gfp_t;
 417                         #endif
 418                         #include <rdma/rdma_cm.h>
 419                         #include <rdma/ib_cm.h>
 420                         #include <rdma/ib_verbs.h>
 421                         #include <rdma/ib_fmr_pool.h>
 422                 ],[
 423                         struct rdma_cm_id          *cm_id;
 424                         struct rdma_conn_param      conn_param;
 425                         struct ib_device_attr       device_attr;
 426                         struct ib_qp_attr           qp_attr;
 427                         struct ib_pool_fmr          pool_fmr;
 428                         enum   ib_cm_rej_reason     rej_reason;
 429
 430                         rdma_destroy_id(NULL);
 431                 ],[
 432                         AC_MSG_RESULT([yes])
 433                         O2IBLND="o2iblnd"
 434                 ],[
 435                         AC_MSG_RESULT([no])
 436                         case $ENABLEO2IB in
 437                         1) ;;
 438                         2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]);;
 439                         3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]);;
 440                         *) AC_MSG_ERROR([internal error]);;
 441                         esac
 442                         O2IBLND=""
 443                         O2IBCPPFLAGS=""
 444                 ])
 445                 # we know at this point that the found OFED source is good
 446                 O2IB_SYMVER=""
 447                 if test $ENABLEO2IB -eq 3 ; then
 448                         # OFED default rpm not handle sles10 Modules.symvers name
 449                         for name in Module.symvers Modules.symvers; do
 450                                 if test -f $O2IBPATH/$name; then
 451                                         O2IB_SYMVER=$name;
 452                                         break;
 453                                 fi
 454                         done
 455                         if test -n "$O2IB_SYMVER"; then
 456                                 AC_MSG_NOTICE([adding $O2IBPATH/$O2IB_SYMVER to $PWD/$SYMVERFILE])
 457                                 # strip out the existing symbols versions first
 458                                 if test -f $PWD/$SYMVERFILE; then
 459                                 egrep -v $(echo $(awk '{ print $2 }' $O2IBPATH/$O2IB_SYMVER) | tr ' ' '|') $PWD/$SYMVERFILE > $PWD/$SYMVERFILE.old
 460                                 else
 461                                     touch $PWD/$SYMVERFILE.old
 462                                 fi
 463                                 cat $PWD/$SYMVERFILE.old $O2IBPATH/$O2IB_SYMVER > $PWD/$SYMVERFILE
 464                                 rm $PWD/$SYMVERFILE.old
 465                         else
 466                                 AC_MSG_ERROR([an external source tree was specified for o2iblnd however I could not find a $O2IBPATH/Module.symvers there])
 467                         fi
 468                 fi
 469
 470                 LN_CONFIG_OFED_SPEC
 471                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 472         fi
 473 fi
 474
 475 AC_SUBST(EXTRA_LNET_INCLUDE)
 476 AC_SUBST(O2IBCPPFLAGS)
 477 AC_SUBST(O2IBLND)
 478
 479 # In RHEL 6.2, rdma_create_id() takes the queue-pair type as a fourth argument
 480 if test $ENABLEO2IB -ne 0; then
 481         AC_MSG_CHECKING([if rdma_create_id wants four args])
 482         LB_LINUX_TRY_COMPILE([
 483                 #include <rdma/rdma_cm.h>
 484         ],[
 485                 rdma_create_id(NULL, NULL, 0, 0);
 486         ],[
 487                 AC_MSG_RESULT([yes])
 488                 AC_DEFINE(HAVE_RDMA_CREATE_ID_4ARG, 1,
 489                         [rdma_create_id wants 4 args])
 490         ],[
 491                 AC_MSG_RESULT([no])
 492         ])
 493 fi
 494 ])
 495
 496 #
 497 # LN_CONFIG_RALND
 498 #
 499 # check whether to use the RapidArray lnd
 500 #
 501 AC_DEFUN([LN_CONFIG_RALND],
 502 [#### Rapid Array
 503 AC_MSG_CHECKING([if RapidArray kernel headers are present])
 504 # placeholder
 505 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 506 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 507 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 508 LB_LINUX_TRY_COMPILE([
 509         #include <linux/types.h>
 510         #include <rapl.h>
 511 ],[
 512         RAP_RETURN          rc;
 513         RAP_PVOID           dev_handle;
 514
 515         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 516
 517         return rc == RAP_SUCCESS ? 0 : 1;
 518 ],[
 519         AC_MSG_RESULT([yes])
 520         RALND="ralnd"
 521 ],[
 522         AC_MSG_RESULT([no])
 523         RALND=""
 524         RACPPFLAGS=""
 525 ])
 526 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 527 AC_SUBST(RACPPFLAGS)
 528 AC_SUBST(RALND)
 529 ])
 530
 531
 532
 533 #
 534 #
 535 # LN_CONFIG_USERSPACE
 536 #
 537 # This is defined but empty because it is called from
 538 # build/autconf/lustre-build.m4 which is shared by all branches.
 539 #
 540 AC_DEFUN([LN_CONFIG_USERSPACE],
 541 [
 542 ])
 543
 544 # See if sysctl proc_handler wants only 5 arguments (since 2.6.32)
 545 AC_DEFUN([LN_5ARGS_SYSCTL_PROC_HANDLER],
 546 [AC_MSG_CHECKING([if sysctl proc_handler wants 5 args])
 547 LB_LINUX_TRY_COMPILE([
 548         #include <linux/sysctl.h>
 549 ],[
 550         struct ctl_table *table = NULL;
 551         int write = 1;
 552         void __user *buffer = NULL;
 553         size_t *lenp = NULL;
 554         loff_t *ppos = NULL;
 555
 556         proc_handler *proc_handler;
 557         proc_handler(table, write, buffer, lenp, ppos);
 558
 559 ],[
 560         AC_MSG_RESULT(yes)
 561         AC_DEFINE(HAVE_5ARGS_SYSCTL_PROC_HANDLER, 1,
 562                   [sysctl proc_handler wants 5 args])
 563 ],[
 564         AC_MSG_RESULT(no)
 565 ])
 566 ])
 567
 568 #
 569 # 2.6.36 tcp_sendpage() first parameter is 'struct sock' instead of 'struct socket'.
 570 #
 571 AC_DEFUN([LN_CONFIG_TCP_SENDPAGE],
 572 [AC_MSG_CHECKING([if tcp_sendpage first parameter is socket])
 573 tmp_flags="$EXTRA_KCFLAGS"
 574 EXTRA_KCFLAGS="-Werror"
 575 LB_LINUX_TRY_COMPILE([
 576         #include <linux/net.h>
 577         #include <net/tcp.h>
 578 ],[
 579         tcp_sendpage((struct socket*)0, NULL, 0, 0, 0);
 580 ],[
 581         AC_MSG_RESULT(yes)
 582         AC_DEFINE(HAVE_TCP_SENDPAGE_USE_SOCKET, 1,
 583                   [tcp_sendpage use socket as first parameter])
 584 ],[
 585         AC_MSG_RESULT(no)
 586 ])
 587 EXTRA_KCFLAGS="$tmp_flags"
 588 ])
 589
 590 #
 591 # LN_PROG_LINUX
 592 #
 593 # LNet linux kernel checks
 594 #
 595 AC_DEFUN([LN_PROG_LINUX],
 596 [
 597 LN_FUNC_DEV_GET_BY_NAME_2ARG
 598 LN_CONFIG_AFFINITY
 599 LN_CONFIG_BACKOFF
 600 LN_CONFIG_QUADRICS
 601 LN_CONFIG_O2IB
 602 LN_CONFIG_RALND
 603 LN_CONFIG_PTLLND
 604 LN_CONFIG_MX
 605 # 2.6.32
 606 LN_5ARGS_SYSCTL_PROC_HANDLER
 607 # 2.6.36
 608 LN_CONFIG_TCP_SENDPAGE
 609 ])
 610
 611 #
 612 # LN_PROG_DARWIN
 613 #
 614 # Darwin checks
 615 #
 616 AC_DEFUN([LN_PROG_DARWIN],
 617 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 618 ])
 619
 620 #
 621 # LN_PATH_DEFAULTS
 622 #
 623 # default paths for installed files
 624 #
 625 AC_DEFUN([LN_PATH_DEFAULTS],
 626 [
 627 ])
 628
 629 #
 630 # LN_CONFIGURE
 631 #
 632 # other configure checks
 633 #
 634 AC_DEFUN([LN_CONFIGURE],
 635 [# lnet/utils/portals.c
 636 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
 637 AC_CHECK_FUNCS([gethostbyname socket connect])
 638
 639 # lnet/utils/debug.c
 640 AC_CHECK_HEADERS([linux/version.h])
 641
 642 AC_CHECK_TYPE([spinlock_t],
 643         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
 644         [],
 645         [#include <linux/spinlock.h>])
 646
 647 # lnet/utils/wirecheck.c
 648 AC_CHECK_FUNCS([strnlen])
 649
 650 # --------  Check for required packages  --------------
 651
 652 #
 653 # LC_CONFIG_READLINE
 654 #
 655 # Build with readline
 656 #
 657 AC_MSG_CHECKING([whether to enable readline support])
 658 AC_ARG_ENABLE(readline,
 659         AC_HELP_STRING([--disable-readline],
 660                         [disable readline support]),
 661         [],[enable_readline='yes'])
 662 AC_MSG_RESULT([$enable_readline])
 663
 664 # -------- check for readline if enabled ----
 665 if test x$enable_readline = xyes ; then
 666         LIBS_save="$LIBS"
 667         LIBS="-lncurses $LIBS"
 668         AC_CHECK_LIB([readline],[readline],[
 669         LIBREADLINE="-lreadline -lncurses"
 670         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
 671         ],[
 672         LIBREADLINE=""
 673         ])
 674         LIBS="$LIBS_save"
 675 else
 676         LIBREADLINE=""
 677 fi
 678 AC_SUBST(LIBREADLINE)
 679
 680 # -------- enable acceptor libwrap (TCP wrappers) support? -------
 681 AC_MSG_CHECKING([if libwrap support is requested])
 682 AC_ARG_ENABLE([libwrap],
 683         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
 684         [case "${enableval}" in
 685                 yes) enable_libwrap=yes ;;
 686                 no) enable_libwrap=no ;;
 687                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
 688         esac],[enable_libwrap=no])
 689 AC_MSG_RESULT([$enable_libwrap])
 690 if test x$enable_libwrap = xyes ; then
 691         LIBWRAP="-lwrap"
 692         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
 693 else
 694         LIBWRAP=""
 695 fi
 696 AC_SUBST(LIBWRAP)
 697
 698 # ----------------------------------------
 699 # some tests for catamount-like systems
 700 # ----------------------------------------
 701 AC_ARG_ENABLE([sysio_init],
 702         AC_HELP_STRING([--disable-sysio-init],
 703                 [call sysio init functions when initializing liblustre]),
 704         [],[enable_sysio_init=yes])
 705 AC_MSG_CHECKING([whether to initialize libsysio])
 706 AC_MSG_RESULT([$enable_sysio_init])
 707 if test x$enable_sysio_init != xno ; then
 708         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
 709 fi
 710
 711 AC_ARG_ENABLE([urandom],
 712         AC_HELP_STRING([--disable-urandom],
 713                 [disable use of /dev/urandom for liblustre]),
 714         [],[enable_urandom=yes])
 715 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
 716 AC_MSG_RESULT([$enable_urandom])
 717 if test x$enable_urandom != xno ; then
 718         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
 719 fi
 720
 721 # -------- check for -lcap support ----
 722 if test x$enable_liblustre = xyes ; then
 723         AC_CHECK_LIB([cap], [cap_get_proc],
 724                 [
 725                         CAP_LIBS="-lcap"
 726                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
 727                 ],
 728                 [
 729                         CAP_LIBS=""
 730                 ])
 731         AC_SUBST(CAP_LIBS)
 732
 733 fi
 734
 735 LN_CONFIG_MAX_PAYLOAD
 736 LN_CONFIG_UPTLLND
 737 LN_CONFIG_USOCKLND
 738 ])
 739
 740 #
 741 # LN_CONDITIONALS
 742 #
 743 # AM_CONDITOINAL defines for lnet
 744 #
 745 AC_DEFUN([LN_CONDITIONALS],
 746 [AM_CONDITIONAL(BUILD_QSWLND, test x$QSWLND = "xqswlnd")
 747 AM_CONDITIONAL(BUILD_MXLND, test x$MXLND = "xmxlnd")
 748 AM_CONDITIONAL(BUILD_O2IBLND, test x$O2IBLND = "xo2iblnd")
 749 AM_CONDITIONAL(BUILD_RALND, test x$RALND = "xralnd")
 750 AM_CONDITIONAL(BUILD_PTLLND, test x$PTLLND = "xptllnd")
 751 AM_CONDITIONAL(BUILD_UPTLLND, test x$UPTLLND = "xptllnd")
 752 AM_CONDITIONAL(BUILD_USOCKLND, test x$USOCKLND = "xusocklnd")
 753 ])
 754
 755 #
 756 # LN_CONFIG_FILES
 757 #
 758 # files that should be generated with AC_OUTPUT
 759 #
 760 AC_DEFUN([LN_CONFIG_FILES],
 761 [AC_CONFIG_FILES([
 762 lnet/Kernelenv
 763 lnet/Makefile
 764 lnet/autoMakefile
 765 lnet/autoconf/Makefile
 766 lnet/doc/Makefile
 767 lnet/include/Makefile
 768 lnet/include/lnet/Makefile
 769 lnet/include/lnet/linux/Makefile
 770 lnet/klnds/Makefile
 771 lnet/klnds/autoMakefile
 772 lnet/klnds/mxlnd/autoMakefile
 773 lnet/klnds/mxlnd/Makefile
 774 lnet/klnds/o2iblnd/Makefile
 775 lnet/klnds/o2iblnd/autoMakefile
 776 lnet/klnds/qswlnd/Makefile
 777 lnet/klnds/qswlnd/autoMakefile
 778 lnet/klnds/ralnd/Makefile
 779 lnet/klnds/ralnd/autoMakefile
 780 lnet/klnds/socklnd/Makefile
 781 lnet/klnds/socklnd/autoMakefile
 782 lnet/klnds/ptllnd/Makefile
 783 lnet/klnds/ptllnd/autoMakefile
 784 lnet/lnet/Makefile
 785 lnet/lnet/autoMakefile
 786 lnet/selftest/Makefile
 787 lnet/selftest/autoMakefile
 788 lnet/ulnds/Makefile
 789 lnet/ulnds/autoMakefile
 790 lnet/ulnds/socklnd/Makefile
 791 lnet/ulnds/ptllnd/Makefile
 792 lnet/utils/Makefile
 793 lnet/include/lnet/darwin/Makefile
 794 ])
 795 ])