lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD],
   7 [AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                        [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19         AC_DEFINE_UNQUOTED(LNET_MAX_PAYLOAD, $LNET_MAX_PAYLOAD,
  20                            [Max LNET payload])
  21 ])
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION],
  29 [AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ])
  43
  44 #
  45 # LN_CONFIG_AFFINITY
  46 #
  47 # check if cpu affinity is available/wanted
  48 #
  49 AC_DEFUN([LN_CONFIG_AFFINITY],
  50 [AC_ARG_ENABLE([affinity],
  51         AC_HELP_STRING([--disable-affinity],
  52                        [disable process/irq affinity]),
  53         [],[enable_affinity='yes'])
  54
  55 AC_MSG_CHECKING([for CPU affinity support])
  56 if test x$enable_affinity = xno ; then
  57         AC_MSG_RESULT([no (by request)])
  58 else
  59         LB_LINUX_TRY_COMPILE([
  60                 #include <linux/sched.h>
  61         ],[
  62                 struct task_struct t;
  63                 #if HAVE_CPUMASK_T
  64                 cpumask_t     m;
  65                 #else
  66                 unsigned long m;
  67                 #endif
  68                 set_cpus_allowed(&t, m);
  69         ],[
  70                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
  71                 AC_MSG_RESULT([yes])
  72         ],[
  73                 AC_MSG_RESULT([no (no kernel support)])
  74         ])
  75 fi
  76 ])
  77
  78 #
  79 # LN_CONFIG_PORTALS
  80 #
  81 # configure support for Portals
  82 #
  83 AC_DEFUN([LN_CONFIG_PORTALS],
  84 [AC_MSG_CHECKING([for portals])
  85 AC_ARG_WITH([portals],
  86         AC_HELP_STRING([--with-portals=path],
  87                        [set path to portals]),
  88         [
  89                 case $with_portals in
  90                         no)     ENABLEPORTALS=0
  91                                 ;;
  92                         *)      PORTALS="${with_portals}"
  93                                 ENABLEPORTALS=1
  94                                 ;;
  95                 esac
  96         ], [
  97                 ENABLEPORTALS=0
  98         ])
  99 PTLLNDCPPFLAGS=""
 100 if test $ENABLEPORTALS -eq 0; then
 101         AC_MSG_RESULT([no])
 102 elif test ! \( -f ${PORTALS}/include/portals/p30.h \); then
 103         AC_MSG_RESULT([no])
 104         AC_MSG_ERROR([bad --with-portals path])
 105 else
 106         AC_MSG_RESULT([$PORTALS])
 107         PTLLNDCPPFLAGS="-I${PORTALS}/include"
 108 fi
 109 AC_SUBST(PTLLNDCPPFLAGS)
 110 ])
 111
 112 #
 113 # LN_CONFIG_BACKOFF
 114 #
 115 # check if tunable tcp backoff is available/wanted
 116 #
 117 AC_DEFUN([LN_CONFIG_BACKOFF],
 118 [AC_MSG_CHECKING([for tunable backoff TCP support])
 119 AC_ARG_ENABLE([backoff],
 120        AC_HELP_STRING([--disable-backoff],
 121                       [disable socknal tunable backoff]),
 122        [],[enable_backoff='yes'])
 123 if test x$enable_backoff = xno ; then
 124        AC_MSG_RESULT([no (by request)])
 125 else
 126        BOCD="`grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h`"
 127        if test "$BOCD" != 0 ; then
 128                AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
 129                AC_MSG_RESULT(yes)
 130                if grep rto_max $LINUX/include/linux/tcp.h|grep -q __u16; then
 131                    AC_DEFINE(SOCKNAL_BACKOFF_MS, 1, [tunable backoff TCP in ms])
 132                fi
 133        else
 134                AC_MSG_RESULT([no (no kernel support)])
 135        fi
 136 fi
 137 ])
 138
 139
 140 #
 141 # LN_CONFIG_PTLLND
 142 #
 143 # configure support for Portals LND
 144 #
 145 AC_DEFUN([LN_CONFIG_PTLLND],
 146 [
 147 if test -z "$ENABLEPORTALS"; then
 148         LN_CONFIG_PORTALS
 149 fi
 150
 151 AC_MSG_CHECKING([whether to build the kernel portals LND])
 152
 153 PTLLND=""
 154 if test $ENABLEPORTALS -ne 0; then
 155         AC_MSG_RESULT([yes])
 156         PTLLND="ptllnd"
 157 else
 158         AC_MSG_RESULT([no])
 159 fi
 160 AC_SUBST(PTLLND)
 161 ])
 162
 163 #
 164 # LN_CONFIG_UPTLLND
 165 #
 166 # configure support for Portals LND
 167 #
 168 AC_DEFUN([LN_CONFIG_UPTLLND],
 169 [
 170 if test -z "$ENABLEPORTALS"; then
 171         LN_CONFIG_PORTALS
 172 fi
 173
 174 AC_MSG_CHECKING([whether to build the userspace portals LND])
 175
 176 UPTLLND=""
 177 if test $ENABLEPORTALS -ne 0; then
 178         AC_MSG_RESULT([yes])
 179         UPTLLND="ptllnd"
 180 else
 181         AC_MSG_RESULT([no])
 182 fi
 183 AC_SUBST(UPTLLND)
 184 ])
 185
 186 #
 187 # LN_CONFIG_USOCKLND
 188 #
 189 # configure support for userspace TCP/IP LND
 190 #
 191 AC_DEFUN([LN_CONFIG_USOCKLND],
 192 [AC_MSG_CHECKING([whether to build usocklnd])
 193 AC_ARG_ENABLE([usocklnd],
 194         AC_HELP_STRING([--disable-usocklnd],
 195                         [disable usocklnd]),
 196         [],[enable_usocklnd='yes'])
 197
 198 if test x$enable_usocklnd = xyes ; then
 199         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 200                 AC_MSG_RESULT([yes])
 201                 USOCKLND="usocklnd"
 202         else
 203                 AC_MSG_RESULT([no (libpthread not present or disabled)])
 204                 USOCKLND=""
 205         fi
 206 else
 207         AC_MSG_RESULT([no (disabled explicitly)])
 208         USOCKLND=""
 209 fi
 210 AC_SUBST(USOCKLND)
 211 ])
 212
 213 #
 214 # LN_CONFIG_QUADRICS
 215 #
 216 # check if quadrics support is in this kernel
 217 #
 218 AC_DEFUN([LN_CONFIG_QUADRICS],
 219 [AC_MSG_CHECKING([for QsNet sources])
 220 AC_ARG_WITH([qsnet],
 221         AC_HELP_STRING([--with-qsnet=path],
 222                        [set path to qsnet source (default=$LINUX)]),
 223         [QSNET=$with_qsnet],
 224         [QSNET=$LINUX])
 225 AC_MSG_RESULT([$QSNET])
 226
 227 AC_MSG_CHECKING([if quadrics kernel headers are present])
 228 if test -d $QSNET/drivers/net/qsnet ; then
 229         AC_MSG_RESULT([yes])
 230         QSWLND="qswlnd"
 231         AC_MSG_CHECKING([for multirail EKC])
 232         if test -f $QSNET/include/elan/epcomms.h; then
 233                 AC_MSG_RESULT([supported])
 234                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 235         else
 236                 AC_MSG_RESULT([not supported])
 237                 AC_MSG_ERROR([Need multirail EKC])
 238         fi
 239
 240         if test x$QSNET = x$LINUX ; then
 241                 LB_LINUX_CONFIG([QSNET],[],[
 242                         LB_LINUX_CONFIG([QSNET_MODULE],[],[
 243                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
 244                                 QSWLND=""
 245                                 QSWCPPFLAGS=""
 246                         ])
 247                 ])
 248         fi
 249 else
 250         AC_MSG_RESULT([no])
 251         QSWLND=""
 252         QSWCPPFLAGS=""
 253 fi
 254 AC_SUBST(QSWCPPFLAGS)
 255 AC_SUBST(QSWLND)
 256 ])
 257
 258
 259 #
 260 # LN_CONFIG_MX
 261 #
 262 AC_DEFUN([LN_CONFIG_MX],
 263 [AC_MSG_CHECKING([whether to enable Myrinet MX support])
 264 # set default
 265 MXPATH="/opt/mx"
 266 AC_ARG_WITH([mx],
 267        AC_HELP_STRING([--with-mx=path],
 268                       [build mxlnd against path]),
 269        [
 270                case $with_mx in
 271                yes)    ENABLEMX=2
 272                        ;;
 273                no)     ENABLEMX=0
 274                        ;;
 275                *)      MXPATH=$with_mx
 276                        ENABLEMX=3
 277                        ;;
 278                esac
 279        ],[
 280                ENABLEMX=1
 281        ])
 282 if test $ENABLEMX -eq 0; then
 283        AC_MSG_RESULT([disabled])
 284 elif test ! \( -f ${MXPATH}/include/myriexpress.h -a \
 285               -f ${MXPATH}/include/mx_kernel_api.h -a \
 286               -f ${MXPATH}/include/mx_pin.h \); then
 287        AC_MSG_RESULT([no])
 288        case $ENABLEMX in
 289        1) ;;
 290        2) AC_MSG_ERROR([Myrinet MX kernel headers not present]);;
 291        3) AC_MSG_ERROR([bad --with-mx path]);;
 292        *) AC_MSG_ERROR([internal error]);;
 293        esac
 294 else
 295        MXCPPFLAGS="-I$MXPATH/include"
 296        EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 297        EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
 298        MXLIBS="-L$MXPATH/lib"
 299        LB_LINUX_TRY_COMPILE([
 300                #define MX_KERNEL 1
 301                #include <mx_extensions.h>
 302                #include <myriexpress.h>
 303        ],[
 304                mx_endpoint_t   end;
 305                mx_status_t     status;
 306                mx_request_t    request;
 307                int             result;
 308
 309                mx_init();
 310                mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
 311                mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
 312                mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
 313                mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
 314                return 0;
 315        ],[
 316                AC_MSG_RESULT([yes])
 317                MXLND="mxlnd"
 318        ],[
 319                AC_MSG_RESULT([no])
 320                case $ENABLEMX in
 321                1) ;;
 322                2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]);;
 323                3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]);;
 324                *) AC_MSG_ERROR([internal error]);;
 325                esac
 326                MXLND=""
 327                MXCPPFLAGS=""
 328        ])
 329        EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 330 fi
 331 AC_SUBST(MXCPPFLAGS)
 332 AC_SUBST(MXLIBS)
 333 AC_SUBST(MXLND)
 334 ])
 335
 336
 337
 338 #
 339 # LN_CONFIG_O2IB
 340 #
 341 AC_DEFUN([LN_CONFIG_O2IB],[
 342 AC_MSG_CHECKING([whether to enable OpenIB gen2 support])
 343 # set default
 344 AC_ARG_WITH([o2ib],
 345         AC_HELP_STRING([--with-o2ib=path],
 346                        [build o2iblnd against path]),
 347         [
 348                 case $with_o2ib in
 349                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 350                         ENABLEO2IB=2
 351                         ;;
 352                 no)     ENABLEO2IB=0
 353                         ;;
 354                 *)      O2IBPATHS=$with_o2ib
 355                         ENABLEO2IB=3
 356                         ;;
 357                 esac
 358         ],[
 359                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 360                 ENABLEO2IB=1
 361         ])
 362 if test $ENABLEO2IB -eq 0; then
 363         AC_MSG_RESULT([disabled])
 364 else
 365         o2ib_found=false
 366         for O2IBPATH in $O2IBPATHS; do
 367                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 368                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 369                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 370                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 371                         if test \( -d ${O2IBPATH}/kernel_patches -a \
 372                                    -f ${O2IBPATH}/Makefile \); then
 373                                 AC_MSG_RESULT([no])
 374                                 AC_MSG_ERROR([you appear to be trying to use the OFED distribution's source directory (${O2IBPATH}) rather than the "development/headers" directory which is likely in ${O2IBPATH%-*}])
 375                         fi
 376                         o2ib_found=true
 377                         break
 378                 fi
 379         done
 380         if ! $o2ib_found; then
 381                 AC_MSG_RESULT([no])
 382                 case $ENABLEO2IB in
 383                         1) ;;
 384                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 385                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 386                         *) AC_MSG_ERROR([internal error]);;
 387                 esac
 388         else
 389                 O2IBCPPFLAGS="-I$O2IBPATH/include"
 390                 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 391                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $O2IBCPPFLAGS"
 392                 EXTRA_LNET_INCLUDE="$EXTRA_LNET_INCLUDE $O2IBCPPFLAGS"
 393
 394                 LB_LINUX_TRY_COMPILE([
 395                         #include <linux/version.h>
 396                         #include <linux/pci.h>
 397                         #if !HAVE_GFP_T
 398                         typedef int gfp_t;
 399                         #endif
 400                         #include <rdma/rdma_cm.h>
 401                         #include <rdma/ib_cm.h>
 402                         #include <rdma/ib_verbs.h>
 403                         #include <rdma/ib_fmr_pool.h>
 404                 ],[
 405                         struct rdma_cm_id          *cm_id;
 406                         struct rdma_conn_param      conn_param;
 407                         struct ib_device_attr       device_attr;
 408                         struct ib_qp_attr           qp_attr;
 409                         struct ib_pool_fmr          pool_fmr;
 410                         enum   ib_cm_rej_reason     rej_reason;
 411
 412                         cm_id = rdma_create_id(NULL, NULL, RDMA_PS_TCP);
 413                         return PTR_ERR(cm_id);
 414                 ],[
 415                         AC_MSG_RESULT([yes])
 416                         O2IBLND="o2iblnd"
 417                 ],[
 418                         AC_MSG_RESULT([no])
 419                         case $ENABLEO2IB in
 420                         1) ;;
 421                         2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]);;
 422                         3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]);;
 423                         *) AC_MSG_ERROR([internal error]);;
 424                         esac
 425                         O2IBLND=""
 426                         O2IBCPPFLAGS=""
 427                 ])
 428                 # we know at this point that the found OFED source is good
 429                 O2IB_SYMVER=""
 430                 if test $ENABLEO2IB -eq 3 ; then
 431                         # OFED default rpm not handle sles10 Modules.symvers name
 432                         for name in Module.symvers Modules.symvers; do
 433                                 if test -f $O2IBPATH/$name; then
 434                                         O2IB_SYMVER=$name;
 435                                         break;
 436                                 fi
 437                         done
 438                         if test -n "$O2IB_SYMVER"; then
 439                                 AC_MSG_NOTICE([adding $O2IBPATH/$O2IB_SYMVER to $PWD/$SYMVERFILE])
 440                                 # strip out the existing symbols versions first
 441                                 if test -f $PWD/$SYMVERFILE; then
 442                                 egrep -v $(echo $(awk '{ print $2 }' $O2IBPATH/$O2IB_SYMVER) | tr ' ' '|') $PWD/$SYMVERFILE > $PWD/$SYMVERFILE.old
 443                                 else
 444                                     touch $PWD/$SYMVERFILE.old
 445                                 fi
 446                                 cat $PWD/$SYMVERFILE.old $O2IBPATH/$O2IB_SYMVER > $PWD/$SYMVERFILE
 447                                 rm $PWD/$SYMVERFILE.old
 448                         else
 449                                 AC_MSG_ERROR([an external source tree was specified for o2iblnd however I could not find a $O2IBPATH/Module.symvers there])
 450                         fi
 451                 fi
 452
 453                 LN_CONFIG_OFED_SPEC
 454                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 455         fi
 456 fi
 457
 458 AC_SUBST(EXTRA_LNET_INCLUDE)
 459 AC_SUBST(O2IBCPPFLAGS)
 460 AC_SUBST(O2IBLND)
 461 ])
 462
 463 #
 464 # LN_CONFIG_RALND
 465 #
 466 # check whether to use the RapidArray lnd
 467 #
 468 AC_DEFUN([LN_CONFIG_RALND],
 469 [#### Rapid Array
 470 AC_MSG_CHECKING([if RapidArray kernel headers are present])
 471 # placeholder
 472 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 473 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 474 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 475 LB_LINUX_TRY_COMPILE([
 476         #include <linux/types.h>
 477         #include <rapl.h>
 478 ],[
 479         RAP_RETURN          rc;
 480         RAP_PVOID           dev_handle;
 481
 482         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 483
 484         return rc == RAP_SUCCESS ? 0 : 1;
 485 ],[
 486         AC_MSG_RESULT([yes])
 487         RALND="ralnd"
 488 ],[
 489         AC_MSG_RESULT([no])
 490         RALND=""
 491         RACPPFLAGS=""
 492 ])
 493 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 494 AC_SUBST(RACPPFLAGS)
 495 AC_SUBST(RALND)
 496 ])
 497
 498
 499
 500 #
 501 #
 502 # LN_CONFIG_USERSPACE
 503 #
 504 # This is defined but empty because it is called from
 505 # build/autconf/lustre-build.m4 which is shared by all branches.
 506 #
 507 AC_DEFUN([LN_CONFIG_USERSPACE],
 508 [
 509 ])
 510
 511 # See if sysctl proc_handler wants only 5 arguments (since 2.6.32)
 512 AC_DEFUN([LN_5ARGS_SYSCTL_PROC_HANDLER],
 513 [AC_MSG_CHECKING([if sysctl proc_handler wants 5 args])
 514 LB_LINUX_TRY_COMPILE([
 515        #include <linux/sysctl.h>
 516 ],[
 517         struct ctl_table *table = NULL;
 518        int write = 1;
 519        void __user *buffer = NULL;
 520        size_t *lenp = NULL;
 521        loff_t *ppos = NULL;
 522
 523        proc_handler *proc_handler;
 524        proc_handler(table, write, buffer, lenp, ppos);
 525
 526 ],[
 527         AC_MSG_RESULT(yes)
 528         AC_DEFINE(HAVE_5ARGS_SYSCTL_PROC_HANDLER, 1,
 529                   [sysctl proc_handler wants 5 args])
 530 ],[
 531         AC_MSG_RESULT(no)
 532 ])
 533 ])
 534
 535 #
 536 # LN_PROG_LINUX
 537 #
 538 # LNet linux kernel checks
 539 #
 540 AC_DEFUN([LN_PROG_LINUX],
 541 [
 542 LN_CONFIG_AFFINITY
 543 LN_CONFIG_BACKOFF
 544 LN_CONFIG_QUADRICS
 545 LN_CONFIG_O2IB
 546 LN_CONFIG_RALND
 547 LN_CONFIG_PTLLND
 548 LN_CONFIG_MX
 549 # 2.6.32
 550 LN_5ARGS_SYSCTL_PROC_HANDLER
 551 ])
 552
 553 #
 554 # LN_PROG_DARWIN
 555 #
 556 # Darwin checks
 557 #
 558 AC_DEFUN([LN_PROG_DARWIN],
 559 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 560 ])
 561
 562 #
 563 # LN_PATH_DEFAULTS
 564 #
 565 # default paths for installed files
 566 #
 567 AC_DEFUN([LN_PATH_DEFAULTS],
 568 [
 569 ])
 570
 571 #
 572 # LN_CONFIGURE
 573 #
 574 # other configure checks
 575 #
 576 AC_DEFUN([LN_CONFIGURE],
 577 [# lnet/utils/portals.c
 578 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
 579 AC_CHECK_FUNCS([gethostbyname socket connect])
 580
 581 # lnet/utils/debug.c
 582 AC_CHECK_HEADERS([linux/version.h])
 583
 584 AC_CHECK_TYPE([spinlock_t],
 585         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
 586         [],
 587         [#include <linux/spinlock.h>])
 588
 589 # lnet/utils/wirecheck.c
 590 AC_CHECK_FUNCS([strnlen])
 591
 592 # --------  Check for required packages  --------------
 593
 594 #
 595 # LC_CONFIG_READLINE
 596 #
 597 # Build with readline
 598 #
 599 AC_MSG_CHECKING([whether to enable readline support])
 600 AC_ARG_ENABLE(readline,
 601         AC_HELP_STRING([--disable-readline],
 602                         [disable readline support]),
 603         [],[enable_readline='yes'])
 604 AC_MSG_RESULT([$enable_readline])
 605
 606 # -------- check for readline if enabled ----
 607 if test x$enable_readline = xyes ; then
 608         LIBS_save="$LIBS"
 609         LIBS="-lncurses $LIBS"
 610         AC_CHECK_LIB([readline],[readline],[
 611         LIBREADLINE="-lreadline -lncurses"
 612         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
 613         ],[
 614         LIBREADLINE=""
 615         ])
 616         LIBS="$LIBS_save"
 617 else
 618         LIBREADLINE=""
 619 fi
 620 AC_SUBST(LIBREADLINE)
 621
 622 # -------- enable acceptor libwrap (TCP wrappers) support? -------
 623 AC_MSG_CHECKING([if libwrap support is requested])
 624 AC_ARG_ENABLE([libwrap],
 625         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
 626         [case "${enableval}" in
 627                 yes) enable_libwrap=yes ;;
 628                 no) enable_libwrap=no ;;
 629                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
 630         esac],[enable_libwrap=no])
 631 AC_MSG_RESULT([$enable_libwrap])
 632 if test x$enable_libwrap = xyes ; then
 633         LIBWRAP="-lwrap"
 634         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
 635 else
 636         LIBWRAP=""
 637 fi
 638 AC_SUBST(LIBWRAP)
 639
 640 # ----------------------------------------
 641 # some tests for catamount-like systems
 642 # ----------------------------------------
 643 AC_ARG_ENABLE([sysio_init],
 644         AC_HELP_STRING([--disable-sysio-init],
 645                 [call sysio init functions when initializing liblustre]),
 646         [],[enable_sysio_init=yes])
 647 AC_MSG_CHECKING([whether to initialize libsysio])
 648 AC_MSG_RESULT([$enable_sysio_init])
 649 if test x$enable_sysio_init != xno ; then
 650         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
 651 fi
 652
 653 AC_ARG_ENABLE([urandom],
 654         AC_HELP_STRING([--disable-urandom],
 655                 [disable use of /dev/urandom for liblustre]),
 656         [],[enable_urandom=yes])
 657 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
 658 AC_MSG_RESULT([$enable_urandom])
 659 if test x$enable_urandom != xno ; then
 660         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
 661 fi
 662
 663 # -------- check for -lcap support ----
 664 if test x$enable_liblustre = xyes ; then
 665         AC_CHECK_LIB([cap], [cap_get_proc],
 666                 [
 667                         CAP_LIBS="-lcap"
 668                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
 669                 ],
 670                 [
 671                         CAP_LIBS=""
 672                 ])
 673         AC_SUBST(CAP_LIBS)
 674
 675 fi
 676
 677 LN_CONFIG_MAX_PAYLOAD
 678 LN_CONFIG_UPTLLND
 679 LN_CONFIG_USOCKLND
 680 ])
 681
 682 #
 683 # LN_CONDITIONALS
 684 #
 685 # AM_CONDITOINAL defines for lnet
 686 #
 687 AC_DEFUN([LN_CONDITIONALS],
 688 [AM_CONDITIONAL(BUILD_QSWLND, test x$QSWLND = "xqswlnd")
 689 AM_CONDITIONAL(BUILD_MXLND, test x$MXLND = "xmxlnd")
 690 AM_CONDITIONAL(BUILD_O2IBLND, test x$O2IBLND = "xo2iblnd")
 691 AM_CONDITIONAL(BUILD_RALND, test x$RALND = "xralnd")
 692 AM_CONDITIONAL(BUILD_PTLLND, test x$PTLLND = "xptllnd")
 693 AM_CONDITIONAL(BUILD_UPTLLND, test x$UPTLLND = "xptllnd")
 694 AM_CONDITIONAL(BUILD_USOCKLND, test x$USOCKLND = "xusocklnd")
 695 ])
 696
 697 #
 698 # LN_CONFIG_FILES
 699 #
 700 # files that should be generated with AC_OUTPUT
 701 #
 702 AC_DEFUN([LN_CONFIG_FILES],
 703 [AC_CONFIG_FILES([
 704 lnet/Kernelenv
 705 lnet/Makefile
 706 lnet/autoMakefile
 707 lnet/autoconf/Makefile
 708 lnet/doc/Makefile
 709 lnet/include/Makefile
 710 lnet/include/lnet/Makefile
 711 lnet/include/lnet/linux/Makefile
 712 lnet/klnds/Makefile
 713 lnet/klnds/autoMakefile
 714 lnet/klnds/mxlnd/autoMakefile
 715 lnet/klnds/mxlnd/Makefile
 716 lnet/klnds/o2iblnd/Makefile
 717 lnet/klnds/o2iblnd/autoMakefile
 718 lnet/klnds/qswlnd/Makefile
 719 lnet/klnds/qswlnd/autoMakefile
 720 lnet/klnds/ralnd/Makefile
 721 lnet/klnds/ralnd/autoMakefile
 722 lnet/klnds/socklnd/Makefile
 723 lnet/klnds/socklnd/autoMakefile
 724 lnet/klnds/ptllnd/Makefile
 725 lnet/klnds/ptllnd/autoMakefile
 726 lnet/lnet/Makefile
 727 lnet/lnet/autoMakefile
 728 lnet/selftest/Makefile
 729 lnet/selftest/autoMakefile
 730 lnet/ulnds/Makefile
 731 lnet/ulnds/autoMakefile
 732 lnet/ulnds/socklnd/Makefile
 733 lnet/ulnds/ptllnd/Makefile
 734 lnet/utils/Makefile
 735 lnet/include/lnet/darwin/Makefile
 736 ])
 737 ])