lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LP_CHECK_GCC_VERSION
   3 #
   4 # Check compiler version
   5 #
   6 AC_DEFUN([LP_CHECK_GCC_VERSION],
   7 [AC_MSG_CHECKING([compiler version])
   8 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
   9 PTL_MIN_CC_VERSION="3.2.3"
  10 v2n() {
  11         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  12 }
  13 if test -z "$PTL_CC_VERSION" -o \
  14         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
  15         AC_MSG_RESULT([ok])
  16 else
  17         AC_MSG_RESULT([Buggy compiler found])
  18         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  19 fi
  20 ])
  21
  22 #
  23 # LP_CONFIG_ZEROCOPY
  24 #
  25 # check if zerocopy is available/wanted
  26 #
  27 AC_DEFUN([LP_CONFIG_ZEROCOPY],
  28 [AC_MSG_CHECKING([for zero-copy TCP support])
  29 AC_ARG_ENABLE([zerocopy],
  30         AC_HELP_STRING([--disable-zerocopy],
  31                        [disable socknal zerocopy]),
  32         [],[enable_zerocopy='yes'])
  33 if test x$enable_zerocopy = xno ; then
  34         AC_MSG_RESULT([no (by request)])
  35 else
  36         ZCCD="`grep -c zccd $LINUX/include/linux/skbuff.h`"
  37         if test "$ZCCD" != 0 ; then
  38                 AC_DEFINE(SOCKNAL_ZC, 1, [use zero-copy TCP])
  39                 AC_MSG_RESULT(yes)
  40         else
  41                 AC_MSG_RESULT([no (no kernel support)])
  42         fi
  43 fi
  44 ])
  45
  46 #
  47 # LP_CONFIG_AFFINITY
  48 #
  49 # check if cpu affinity is available/wanted
  50 #
  51 AC_DEFUN([LP_CONFIG_AFFINITY],
  52 [AC_ARG_ENABLE([affinity],
  53         AC_HELP_STRING([--disable-affinity],
  54                        [disable process/irq affinity]),
  55         [],[enable_affinity='yes'])
  56
  57 AC_MSG_CHECKING([for CPU affinity support])
  58 if test x$enable_affinity = xno ; then
  59         AC_MSG_RESULT([no (by request)])
  60 else
  61         LB_LINUX_TRY_COMPILE([
  62                 #include <linux/sched.h>
  63         ],[
  64                 struct task_struct t;
  65                 #ifdef CPU_ARRAY_SIZE
  66                 cpumask_t m;
  67                 #else
  68                 unsigned long m;
  69                 #endif
  70                 set_cpus_allowed(&t, m);
  71         ],[
  72                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
  73                 AC_MSG_RESULT([yes])
  74         ],[
  75                 AC_MSG_RESULT([no (no kernel support)])
  76         ])
  77 fi
  78 ])
  79
  80 #
  81 # LP_CONFIG_QUADRICS
  82 #
  83 # check if quadrics support is in this kernel
  84 #
  85 AC_DEFUN([LP_CONFIG_QUADRICS],
  86 [AC_MSG_CHECKING([if quadrics kernel headers are present])
  87 if test -d $LINUX/drivers/net/qsnet ; then
  88         AC_MSG_RESULT([yes])
  89         QSWNAL="qswnal"
  90         AC_MSG_CHECKING([for multirail EKC])
  91         if test -f $LINUX/include/elan/epcomms.h; then
  92                 AC_MSG_RESULT([supported])
  93                 QSWCPPFLAGS="-DMULTIRAIL_EKC=1"
  94         else
  95                 AC_MSG_RESULT([not supported])
  96                 if test -d $LINUX/drivers/net/qsnet/include; then
  97                         QSWCPPFLAGS="-I$LINUX/drivers/net/qsnet/include"
  98                 else
  99                         QSWCPPFLAGS="-I$LINUX/include/linux"
 100                 fi
 101         fi
 102 else
 103         AC_MSG_RESULT([no])
 104         QSWNAL=""
 105         QSWCPPFLAGS=""
 106 fi
 107 AC_SUBST(QSWCPPFLAGS)
 108 AC_SUBST(QSWNAL)
 109 ])
 110
 111 #
 112 # LP_CONFIG_GM
 113 #
 114 # check if GM support is available
 115 #
 116 AC_DEFUN([LP_CONFIG_GM],
 117 [LB_ARG_LIBS_INCLUDES([Myrinet],[gm])
 118 if test x$gm_includes != x ; then
 119         GMCPPFLAGS="-I$gm_includes"
 120         if test -d "$gm/drivers" ; then
 121                 GMCPPFLAGS="$GMCPPFLAGS -I$gm/drivers -I$gm/drivers/linux/gm"
 122         fi
 123 fi
 124 AC_SUBST(GMCPPFLAGS)
 125
 126 if test x$gm_libs != x ; then
 127         GMLIBS="-L$gm_libs"
 128 fi
 129 AC_SUBST(GMLIBS)
 130
 131 ENABLE_GM=0
 132 if test x$gm != x ; then
 133         GMNAL="gmnal"
 134         ENABLE_GM=1
 135 fi
 136 AC_SUBST(GMNAL)
 137 AC_SUBST(ENABLE_GM)
 138 ])
 139
 140 #
 141 # LP_CONFIG_OPENIB
 142 #
 143 # check for OpenIB in the kernel
 144 AC_DEFUN([LP_CONFIG_OPENIB],[
 145 AC_MSG_CHECKING([whether to enable OpenIB support])
 146 # set default
 147 OPENIBPATH="$LINUX/drivers/infiniband"
 148 AC_ARG_WITH([openib],
 149         AC_HELP_STRING([--with-openib=path],
 150                        [build openibnal against path]),
 151         [
 152                 case $with_openib in
 153                 yes)    ENABLEOPENIB=2
 154                         ;;
 155                 no)     ENABLEOPENIB=0
 156                         ;;
 157                 *)      OPENIBPATH="$with_openib"
 158                         ENABLEOPENIB=3
 159                         ;;
 160                 esac
 161         ],[
 162                 ENABLEOPENIB=1
 163         ])
 164 if test $ENABLEOPENIB -eq 0; then
 165         AC_MSG_RESULT([disabled])
 166 elif test ! \( -f ${OPENIBPATH}/include/ts_ib_core.h -a \
 167                -f ${OPENIBPATH}/include/ts_ib_cm.h -a\
 168                -f ${OPENIBPATH}/include/ts_ib_sa_client.h \); then
 169         AC_MSG_RESULT([no])
 170         case $ENABLEOPENIB in
 171         1) ;;
 172         2) AC_MSG_ERROR([kernel OpenIB headers not present]);;
 173         3) AC_MSG_ERROR([bad --with-openib path]);;
 174         *) AC_MSG_ERROR([internal error]);;
 175         esac
 176 else
 177         case $ENABLEOPENIB in
 178         1|2) OPENIBCPPFLAGS="-I$OPENIBPATH/include -DIN_TREE_BUILD";;
 179         3)   OPENIBCPPFLAGS="-I$OPENIBPATH/include";;
 180         *)   AC_MSG_RESULT([no])
 181              AC_MSG_ERROR([internal error]);;
 182         esac
 183         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 184         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $OPENIBCPPFLAGS"
 185         LB_LINUX_TRY_COMPILE([
 186                 #include <ts_ib_core.h>
 187                 #include <ts_ib_cm.h>
 188                 #include <ts_ib_sa_client.h>
 189         ],[
 190                 struct ib_device_properties dev_props;
 191                 struct ib_cm_active_param   cm_active_params;
 192                 tTS_IB_CLIENT_QUERY_TID     tid;
 193                 int                         enum1 = IB_QP_ATTRIBUTE_STATE;
 194                 int                         enum2 = IB_ACCESS_LOCAL_WRITE;
 195                 int                         enum3 = IB_CQ_CALLBACK_INTERRUPT;
 196                 int                         enum4 = IB_CQ_PROVIDER_REARM;
 197                 return 0;
 198         ],[
 199                 AC_MSG_RESULT([yes])
 200                 OPENIBNAL="openibnal"
 201         ],[
 202                 AC_MSG_RESULT([no])
 203                 case $ENABLEOPENIB in
 204                 1) ;;
 205                 2) AC_MSG_ERROR([can't compile with kernel OpenIB headers]);;
 206                 3) AC_MSG_ERROR([can't compile with OpenIB headers under $OPENIBPATH]);;
 207                 *) AC_MSG_ERROR([internal error]);;
 208                 esac
 209                 OPENIBNAL=""
 210                 OPENIBCPPFLAGS=""
 211         ])
 212         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 213 fi
 214 AC_SUBST(OPENIBCPPFLAGS)
 215 AC_SUBST(OPENIBNAL)
 216 ])
 217
 218 #
 219 # LP_CONFIG_IIB
 220 #
 221 # check for infinicon infiniband support
 222 #
 223 AC_DEFUN([LP_CONFIG_IIB],
 224 [AC_MSG_CHECKING([if Infinicon IB kernel headers are present])
 225 # for how the only infinicon ib build has headers in /usr/include/iba
 226 IIBCPPFLAGS="-I/usr/include -DIN_TREE_BUILD"
 227 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 228 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $IIBCPPFLAGS"
 229 LB_LINUX_TRY_COMPILE([
 230         #include <linux/iba/ibt.h>
 231 ],[
 232         IBT_INTERFACE_UNION interfaces;
 233         FSTATUS             rc;
 234
 235          rc = IbtGetInterfaceByVersion(IBT_INTERFACE_VERSION_2,
 236                                        &interfaces);
 237
 238         return rc == FSUCCESS ? 0 : 1;
 239 ],[
 240         AC_MSG_RESULT([yes])
 241         IIBNAL="iibnal"
 242 ],[
 243         AC_MSG_RESULT([no])
 244         IIBNAL=""
 245         IIBCPPFLAGS=""
 246 ])
 247 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 248 AC_SUBST(IIBCPPFLAGS)
 249 AC_SUBST(IIBNAL)
 250 ])
 251
 252 #
 253 # LP_CONFIG_VIB
 254 #
 255 # check for Voltaire infiniband support
 256 #
 257 AC_DEFUN([LP_CONFIG_VIB],
 258 [AC_MSG_CHECKING([whether to enable Voltaire IB support])
 259 VIBPATH=""
 260 AC_ARG_WITH([vib],
 261         AC_HELP_STRING([--with-vib=path],
 262                        [build vibnal against path]),
 263         [
 264                 case $with_vib in
 265                 no)     AC_MSG_RESULT([no]);;
 266                 *)      VIBPATH="${with_vib}/src/nvigor/ib-code"
 267                         if test -d "$with_vib" -a -d "$VIBPATH"; then
 268                                 AC_MSG_RESULT([yes])
 269                         else
 270                                 AC_MSG_RESULT([no])
 271                                 AC_MSG_ERROR([No directory $VIBPATH])
 272                         fi;;
 273                 esac
 274         ],[
 275                 AC_MSG_RESULT([no])
 276         ])
 277 if test -z "$VIBPATH"; then
 278         VIBNAL=""
 279 else
 280         VIBCPPFLAGS="-I${VIBPATH}/include -I${VIBPATH}/cm"
 281         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 282         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 283         LB_LINUX_TRY_COMPILE([
 284                 #include <linux/list.h>
 285                 #include <asm/byteorder.h>
 286                 #ifdef __BIG_ENDIAN
 287                 # define CPU_BE 1
 288                 # define CPU_LE 0
 289                 #endif
 290                 #ifdef __LITTLE_ENDIAN
 291                 # define CPU_BE 0
 292                 # define CPU_LE 1
 293                 #endif
 294                 #include <vverbs.h>
 295                 #include <ib-cm.h>
 296                 #include <ibat.h>
 297         ],[
 298                 vv_hca_h_t       kib_hca;
 299                 vv_return_t      vvrc;
 300                 cm_cep_handle_t  cep;
 301                 ibat_arp_data_t  arp_data;
 302                 ibat_stat_t      ibatrc;
 303
 304                 vvrc = vv_hca_open("ANY_HCA", NULL, &kib_hca);
 305                 cep = cm_create_cep(cm_cep_transp_rc);
 306                 ibatrc = ibat_get_ib_data((uint32_t)0, (uint32_t)0,
 307                                           ibat_paths_primary, &arp_data,
 308                                           (ibat_get_ib_data_reply_fn_t)NULL,
 309                                           NULL, 0);
 310                 return 0;
 311         ],[
 312                 VIBNAL="vibnal"
 313         ],[
 314                 AC_MSG_ERROR([can't compile vibnal with given path])
 315         ])
 316         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 317 fi
 318 AC_SUBST(VIBCPPFLAGS)
 319 AC_SUBST(VIBNAL)
 320 ])
 321
 322 #
 323 # LP_CONFIG_RANAL
 324 #
 325 # check whether to use the RapidArray nal
 326 #
 327 AC_DEFUN([LP_CONFIG_RANAL],
 328 [#### Rapid Array
 329 AC_MSG_CHECKING([if RapidArray kernel headers are present])
 330 # placeholder
 331 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 332 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 333 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 334 LB_LINUX_TRY_COMPILE([
 335         #include <linux/types.h>
 336         #include <rapl.h>
 337 ],[
 338         RAP_RETURN          rc;
 339         RAP_PVOID           dev_handle;
 340
 341         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 342
 343         return rc == RAP_SUCCESS ? 0 : 1;
 344 ],[
 345         AC_MSG_RESULT([yes])
 346         RANAL="ranal"
 347 ],[
 348         AC_MSG_RESULT([no])
 349         RANAL=""
 350         RACPPFLAGS=""
 351 ])
 352 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 353 AC_SUBST(RACPPFLAGS)
 354 AC_SUBST(RANAL)
 355 ])
 356
 357 #
 358 # LP_STRUCT_PAGE_LIST
 359 #
 360 # 2.6.4 no longer has page->list
 361 #
 362 AC_DEFUN([LP_STRUCT_PAGE_LIST],
 363 [AC_MSG_CHECKING([if struct page has a list field])
 364 LB_LINUX_TRY_COMPILE([
 365         #include <linux/mm.h>
 366 ],[
 367         struct page page;
 368         &page.list;
 369 ],[
 370         AC_MSG_RESULT([yes])
 371         AC_DEFINE(HAVE_PAGE_LIST, 1, [struct page has a list field])
 372 ],[
 373         AC_MSG_RESULT([no])
 374 ])
 375 ])
 376
 377 #
 378 # LP_STRUCT_SIGHAND
 379 #
 380 # red hat 2.4 adds sighand to struct task_struct
 381 #
 382 AC_DEFUN([LP_STRUCT_SIGHAND],
 383 [AC_MSG_CHECKING([if task_struct has a sighand field])
 384 LB_LINUX_TRY_COMPILE([
 385         #include <linux/sched.h>
 386 ],[
 387         struct task_struct p;
 388         p.sighand = NULL;
 389 ],[
 390         AC_DEFINE(CONFIG_RH_2_4_20, 1, [this kernel contains Red Hat 2.4.20 patches])
 391         AC_MSG_RESULT([yes])
 392 ],[
 393         AC_MSG_RESULT([no])
 394 ])
 395 ])
 396
 397 #
 398 # LP_FUNC_CPU_ONLINE
 399 #
 400 # cpu_online is different in rh 2.4, vanilla 2.4, and 2.6
 401 #
 402 AC_DEFUN([LP_FUNC_CPU_ONLINE],
 403 [AC_MSG_CHECKING([if kernel defines cpu_online()])
 404 LB_LINUX_TRY_COMPILE([
 405         #include <linux/sched.h>
 406 ],[
 407         cpu_online(0);
 408 ],[
 409         AC_MSG_RESULT([yes])
 410         AC_DEFINE(HAVE_CPU_ONLINE, 1, [cpu_online found])
 411 ],[
 412         AC_MSG_RESULT([no])
 413 ])
 414 ])
 415
 416 #
 417 # LP_TYPE_CPUMASK_T
 418 #
 419 # same goes for cpumask_t
 420 #
 421 AC_DEFUN([LP_TYPE_CPUMASK_T],
 422 [AC_MSG_CHECKING([if kernel defines cpumask_t])
 423 LB_LINUX_TRY_COMPILE([
 424         #include <linux/sched.h>
 425 ],[
 426         return sizeof (cpumask_t);
 427 ],[
 428         AC_MSG_RESULT([yes])
 429         AC_DEFINE(HAVE_CPUMASK_T, 1, [cpumask_t found])
 430 ],[
 431         AC_MSG_RESULT([no])
 432 ])
 433 ])
 434
 435 #
 436 # LP_FUNC_SHOW_TASK
 437 #
 438 # we export show_task(), but not all kernels have it (yet)
 439 #
 440 AC_DEFUN([LP_FUNC_SHOW_TASK],
 441 [AC_MSG_CHECKING([if kernel exports show_task])
 442 have_show_task=0
 443 for file in ksyms sched ; do
 444         if grep -q "EXPORT_SYMBOL(show_task)" \
 445                  "$LINUX/kernel/$file.c" 2>/dev/null ; then
 446                 have_show_task=1
 447                 break
 448         fi
 449 done
 450 if test x$have_show_task = x1 ; then
 451         AC_DEFINE(HAVE_SHOW_TASK, 1, [show_task is exported])
 452         AC_MSG_RESULT([yes])
 453 else
 454         AC_MSG_RESULT([no])
 455 fi
 456 ])
 457
 458 #
 459 # LP_PROG_LINUX
 460 #
 461 # Portals linux kernel checks
 462 #
 463 AC_DEFUN([LP_PROG_LINUX],
 464 [LP_CHECK_GCC_VERSION
 465
 466 LP_CONFIG_ZEROCOPY
 467 LP_CONFIG_AFFINITY
 468 LP_CONFIG_QUADRICS
 469 LP_CONFIG_GM
 470 LP_CONFIG_OPENIB
 471 LP_CONFIG_VIB
 472 LP_CONFIG_IIB
 473 LP_CONFIG_RANAL
 474
 475 LP_STRUCT_PAGE_LIST
 476 LP_STRUCT_SIGHAND
 477 LP_FUNC_CPU_ONLINE
 478 LP_TYPE_CPUMASK_T
 479 LP_FUNC_SHOW_TASK
 480 ])
 481
 482 #
 483 # LP_PROG_DARWIN
 484 #
 485 # Darwin checks
 486 #
 487 AC_DEFUN([LP_PROG_DARWIN],
 488 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 489 ])
 490
 491 #
 492 # LP_PATH_DEFAULTS
 493 #
 494 # default paths for installed files
 495 #
 496 AC_DEFUN([LP_PATH_DEFAULTS],
 497 [
 498 ])
 499
 500 #
 501 # LP_CONFIGURE
 502 #
 503 # other configure checks
 504 #
 505 AC_DEFUN([LP_CONFIGURE],
 506 [# portals/utils/portals.c
 507 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h])
 508 AC_CHECK_FUNCS([gethostbyname socket connect])
 509
 510 # portals/utils/debug.c
 511 AC_CHECK_HEADERS([linux/version.h])
 512
 513 AC_CHECK_TYPE([spinlock_t],
 514         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
 515         [],
 516         [#include <linux/spinlock.h>])
 517
 518 # portals/utils/wirecheck.c
 519 AC_CHECK_FUNCS([strnlen])
 520
 521 # --------  Check for required packages  --------------
 522
 523 LIBS_save="$LIBS"
 524 LIBS="-lncurses $LIBS"
 525 AC_CHECK_LIB([readline],[readline],[
 526         LIBREADLINE="-lreadline -lncurses"
 527         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
 528 ],[
 529         LIBREADLINE=""
 530 ])
 531 LIBS="$LIBS_save"
 532 AC_SUBST(LIBREADLINE)
 533
 534 AC_MSG_CHECKING([if efence debugging support is requested])
 535 AC_ARG_ENABLE(efence,
 536         AC_HELP_STRING([--enable-efence],
 537                         [use efence library]),
 538         [],[enable_efence='no'])
 539 AC_MSG_RESULT([$enable_efence])
 540 if test "$enable_efence" = "yes" ; then
 541         LIBEFENCE="-lefence"
 542         AC_DEFINE(HAVE_LIBEFENCE, 1, [libefence support is requested])
 543 else
 544         LIBEFENCE=""
 545 fi
 546 AC_SUBST(LIBEFENCE)
 547
 548 # -------- enable acceptor libwrap (TCP wrappers) support? -------
 549 AC_MSG_CHECKING([if libwrap support is requested])
 550 AC_ARG_ENABLE([libwrap],
 551         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
 552         [case "${enableval}" in
 553                 yes) enable_libwrap=yes ;;
 554                 no) enable_libwrap=no ;;
 555                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
 556         esac],[enable_libwrap=no])
 557 AC_MSG_RESULT([$enable_libwrap])
 558 if test x$enable_libwrap = xyes ; then
 559         LIBWRAP="-lwrap"
 560         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
 561 else
 562         LIBWRAP=""
 563 fi
 564 AC_SUBST(LIBWRAP)
 565
 566 # ----------------------------------------
 567 # some tests for catamount-like systems
 568 # ----------------------------------------
 569 AC_ARG_ENABLE([sysio_init],
 570         AC_HELP_STRING([--disable-sysio-init],
 571                 [call sysio init functions when initializing liblustre]),
 572         [],[enable_sysio_init=yes])
 573 AC_MSG_CHECKING([whether to initialize libsysio])
 574 AC_MSG_RESULT([$enable_sysio_init])
 575 if test x$enable_sysio_init != xno ; then
 576         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
 577 fi
 578
 579 AC_ARG_ENABLE([urandom],
 580         AC_HELP_STRING([--disable-urandom],
 581                 [disable use of /dev/urandom for liblustre]),
 582         [],[enable_urandom=yes])
 583 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
 584 AC_MSG_RESULT([$enable_urandom])
 585 if test x$enable_urandom != xno ; then
 586         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
 587 fi
 588
 589 # -------- check for -lcap and -lpthread ----
 590 if test x$enable_liblustre = xyes ; then
 591         AC_CHECK_LIB([cap], [cap_get_proc],
 592                 [
 593                         CAP_LIBS="-lcap"
 594                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
 595                 ],
 596                 [CAP_LIBS=""])
 597         AC_SUBST(CAP_LIBS)
 598         AC_CHECK_LIB([pthread], [pthread_create],
 599                 [
 600                         PTHREAD_LIBS="-lpthread"
 601                         AC_DEFINE([HAVE_LIBPTHREAD], 1, [use libpthread])
 602                 ],
 603                 [PTHREAD_LIBS=""])
 604         AC_SUBST(PTHREAD_LIBS)
 605 fi
 606 ])
 607
 608 #
 609 # LP_CONDITIONALS
 610 #
 611 # AM_CONDITOINAL defines for portals
 612 #
 613 AC_DEFUN([LP_CONDITIONALS],
 614 [AM_CONDITIONAL(BUILD_QSWNAL, test x$QSWNAL = "xqswnal")
 615 AM_CONDITIONAL(BUILD_GMNAL, test x$GMNAL = "xgmnal")
 616 AM_CONDITIONAL(BUILD_OPENIBNAL, test x$OPENIBNAL = "xopenibnal")
 617 AM_CONDITIONAL(BUILD_IIBNAL, test x$IIBNAL = "xiibnal")
 618 AM_CONDITIONAL(BUILD_VIBNAL, test x$VIBNAL = "xvibnal")
 619 AM_CONDITIONAL(BUILD_RANAL, test x$RANAL = "xranal")
 620 ])
 621
 622 #
 623 # LP_CONFIG_FILES
 624 #
 625 # files that should be generated with AC_OUTPUT
 626 #
 627 AC_DEFUN([LP_CONFIG_FILES],
 628 [AC_CONFIG_FILES([
 629 portals/Kernelenv
 630 portals/Makefile
 631 portals/autoMakefile
 632 portals/autoconf/Makefile
 633 portals/doc/Makefile
 634 portals/include/Makefile
 635 portals/include/libcfs/Makefile
 636 portals/include/libcfs/linux/Makefile
 637 portals/include/portals/Makefile
 638 portals/include/portals/linux/Makefile
 639 portals/knals/Makefile
 640 portals/knals/autoMakefile
 641 portals/knals/gmnal/Makefile
 642 portals/knals/gmnal/autoMakefile
 643 portals/knals/openibnal/Makefile
 644 portals/knals/openibnal/autoMakefile
 645 portals/knals/iibnal/Makefile
 646 portals/knals/iibnal/autoMakefile
 647 portals/knals/vibnal/Makefile
 648 portals/knals/vibnal/autoMakefile
 649 portals/knals/lonal/Makefile
 650 portals/knals/lonal/autoMakefile
 651 portals/knals/qswnal/Makefile
 652 portals/knals/qswnal/autoMakefile
 653 portals/knals/ranal/Makefile
 654 portals/knals/ranal/autoMakefile
 655 portals/knals/socknal/Makefile
 656 portals/knals/socknal/autoMakefile
 657 portals/libcfs/Makefile
 658 portals/libcfs/autoMakefile
 659 portals/libcfs/linux/Makefile
 660 portals/portals/Makefile
 661 portals/portals/autoMakefile
 662 portals/router/Makefile
 663 portals/router/autoMakefile
 664 portals/tests/Makefile
 665 portals/tests/autoMakefile
 666 portals/unals/Makefile
 667 portals/utils/Makefile
 668 ])
 669 case $lb_target_os in
 670         darwin)
 671                 AC_CONFIG_FILES([
 672 portals/include/libcfs/darwin/Makefile
 673 portals/include/portals/darwin/Makefile
 674 portals/libcfs/darwin/Makefile
 675 ])
 676                 ;;
 677 esac
 678 ])