lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD], [
   7 AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                 [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 CONFIG_LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 CONFIG_LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 CONFIG_LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19 AC_DEFINE_UNQUOTED(CONFIG_LNET_MAX_PAYLOAD, $CONFIG_LNET_MAX_PAYLOAD,
  20         [Max LNET payload])
  21 ]) # LN_CONFIG_MAX_PAYLOAD
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION], [
  29 AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         $(echo $PTL_CC_VERSION | v2n) -ge $(echo $PTL_MIN_CC_VERSION | v2n); then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ]) # LN_CHECK_GCC_VERSION
  43
  44 #
  45 # LN_CONFIG_AFFINITY
  46 #
  47 # check if cpu affinity is available/wanted
  48 #
  49 AC_DEFUN([LN_CONFIG_AFFINITY], [
  50 AC_MSG_CHECKING([whether to enable CPU affinity support])
  51 AC_ARG_ENABLE([affinity],
  52         AC_HELP_STRING([--disable-affinity],
  53                 [disable process/irq affinity]),
  54         [], [enable_affinity="yes"])
  55 AC_MSG_RESULT([$enable_affinity])
  56 AS_IF([test "x$enable_affinity" = xyes], [
  57         LB_CHECK_COMPILE([if Linux kernel has cpu affinity support],
  58         set_cpus_allowed_ptr, [
  59                 #include <linux/sched.h>
  60         ],[
  61                 struct task_struct *t;
  62                 #if HAVE_CPUMASK_T
  63                 cpumask_t     m;
  64                 #else
  65                 unsigned long m;
  66                 #endif
  67                 set_cpus_allowed_ptr(t, &m);
  68         ],[
  69                 AC_DEFINE(CPU_AFFINITY, 1,
  70                         [kernel has cpu affinity support])
  71         ])
  72 ])
  73 ]) # LN_CONFIG_AFFINITY
  74
  75 #
  76 # LN_CONFIG_BACKOFF
  77 #
  78 # check if tunable tcp backoff is available/wanted
  79 #
  80 AC_DEFUN([LN_CONFIG_BACKOFF], [
  81 AC_MSG_CHECKING([whether to enable tunable backoff TCP support])
  82 AC_ARG_ENABLE([backoff],
  83         AC_HELP_STRING([--disable-backoff],
  84                 [disable socknal tunable backoff]),
  85         [], [enable_backoff="yes"])
  86 AC_MSG_RESULT([$enable_backoff])
  87 AS_IF([test "x$enable_backoff" = xyes], [
  88         AC_MSG_CHECKING([if Linux kernel has tunable backoff TCP support])
  89         AS_IF([grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h >/dev/null], [
  90                 AC_MSG_RESULT([yes])
  91                 AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
  92                 AS_IF([grep rto_max $LINUX/include/linux/tcp.h | grep -q __u16 >/dev/null],
  93                         [AC_DEFINE(SOCKNAL_BACKOFF_MS, 1,
  94                                 [tunable backoff TCP in ms])])
  95         ], [
  96                 AC_MSG_RESULT([no])
  97         ])
  98 ])
  99 ]) # LN_CONFIG_BACKOFF
 100
 101 #
 102 # LN_CONFIG_DLC
 103 #
 104 # Configure dlc if enabled
 105 #
 106 # if libyaml is set (IE libyaml installed) and enable_dlc = yes then build
 107 # dlc other wise (IE if libyaml is not set or enable_dlc = no) then don't
 108 # build dlc.
 109 #
 110 AC_DEFUN([LN_CONFIG_DLC], [
 111         AC_CHECK_LIB([yaml],  [yaml_parser_initialize],[
 112                 LIBYAML="libyaml"],[
 113                 LIBYAML=""],[-lm])
 114         AC_MSG_CHECKING([whether to enable dlc])
 115         AC_ARG_ENABLE([dlc],
 116                 AC_HELP_STRING([--disable-dlc],
 117                         [disable building dlc]),
 118                         [], [enable_dlc="yes"])
 119         USE_DLC=""
 120         AS_IF([test "x$enable_dlc" = xyes],
 121                 [AS_IF([test "x$LIBYAML" = xlibyaml], [
 122                         USE_DLC="yes"
 123                         AC_MSG_RESULT([yes])
 124                 ], [
 125                         AC_MSG_RESULT([no (libyaml not present)])
 126                 ])
 127         ], [
 128                 AC_MSG_RESULT([no])
 129         ])
 130         AC_SUBST(USE_DLC)
 131 ])
 132
 133 #
 134 # LN_CONFIG_O2IB
 135 #
 136 # If current OFED installed (assume with "ofed_info") and devel
 137 # headers are not found, error because we assume OFED infiniband
 138 # driver needs to be used and we must configure/build with it.
 139 # Current OFED headers detection mechanism allow for non-standard
 140 # prefix but relies on "ofed_info" command and on "%prefix/openib"
 141 # link (both are ok for 1.5.x and 3.x versions), and should work
 142 # for both source and DKMS builds.
 143 #
 144 AC_DEFUN([LN_CONFIG_O2IB], [
 145 AC_MSG_CHECKING([whether to use Compat RDMA])
 146 AC_ARG_WITH([o2ib],
 147         AC_HELP_STRING([--with-o2ib=[yes|no|<path>]],
 148                 [build o2iblnd against path]),
 149         [], [with_o2ib="yes"])
 150
 151 case $with_o2ib in
 152         yes)    AS_IF([which ofed_info 2>/dev/null], [
 153                         AS_IF([test x$uses_dpkg = xyes], [
 154                                 OFED_INFO="ofed_info | awk '{print \[$]2}'"
 155                                 LSPKG="dpkg --listfiles"
 156                         ], [
 157                                 OFED_INFO="ofed_info"
 158                                 LSPKG="rpm -ql"
 159                         ])
 160                         O2IBPATHS=$(eval $OFED_INFO | egrep -w 'mlnx-ofed-kernel-dkms|mlnx-ofa_kernel-devel|compat-rdma-devel|kernel-ib-devel|ofa_kernel-devel' | xargs $LSPKG | grep '\(/openib\|/ofa_kernel/default\)$' | head -n1)
 161                         AS_IF([test -z "$O2IBPATHS"], [
 162                                 AC_MSG_ERROR([
 163 You seem to have an OFED installed but have not installed it's devel package.
 164 If you still want to build Lustre for your OFED I/B stack, you need to install its devel headers RPM.
 165 Instead, if you want to build Lustre for your kernel's built-in I/B stack rather than your installed OFED stack, either remove the OFED package(s) or use --with-o2ib=no.
 166                                              ])
 167                         ])
 168                         AS_IF([test $(echo $O2IBPATHS | wc -w) -ge 2], [
 169                                 AC_MSG_ERROR([
 170 It appears that you have multiple OFED versions installed.
 171 If you still want to build Lustre for your OFED I/B stack, you need to install a single version with its devel headers RPM.
 172 Instead, if you want to build Lustre for your kernel's built-in I/B stack rather than your installed OFED stack, either remove the OFED package(s) or use --with-o2ib=no.
 173                                              ])
 174                         ])
 175                         OFED="yes"
 176                 ], [
 177                         O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 178                 ])
 179                 ENABLEO2IB="yes"
 180                 ;;
 181         no)     ENABLEO2IB="no"
 182                 ;;
 183         *)      O2IBPATHS=$with_o2ib
 184                 ENABLEO2IB="withpath"
 185                 OFED="yes"
 186                 ;;
 187 esac
 188
 189 AS_IF([test $ENABLEO2IB = "no"], [
 190         AC_MSG_RESULT([no])
 191 ], [
 192         o2ib_found=false
 193         for O2IBPATH in $O2IBPATHS; do
 194                 AS_IF([test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 195                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 196                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 197                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \)], [
 198                         o2ib_found=true
 199                         break
 200                 ])
 201         done
 202         if ! $o2ib_found; then
 203                 AC_MSG_RESULT([no])
 204                 case $ENABLEO2IB in
 205                         "yes") AC_MSG_ERROR([no OFED nor kernel OpenIB gen2 headers present]) ;;
 206                         "withpath") AC_MSG_ERROR([bad --with-o2ib path]) ;;
 207                         *) AC_MSG_ERROR([internal error]) ;;
 208                 esac
 209         else
 210                 COMPAT_AUTOCONF=""
 211                 compatrdma_found=false
 212                 if test -f ${O2IBPATH}/include/linux/compat-2.6.h; then
 213                         AC_MSG_RESULT([yes])
 214                         compatrdma_found=true
 215                         AC_DEFINE(HAVE_COMPAT_RDMA, 1, [compat rdma found])
 216                         EXTRA_OFED_CONFIG="$EXTRA_OFED_CONFIG -include ${O2IBPATH}/include/linux/compat-2.6.h"
 217                         if test -f "$O2IBPATH/include/linux/compat_autoconf.h"; then
 218                                 COMPAT_AUTOCONF="$O2IBPATH/include/linux/compat_autoconf.h"
 219                         fi
 220                 else
 221                         AC_MSG_RESULT([no])
 222                 fi
 223                 if ! $compatrdma_found; then
 224                         if test -f "$O2IBPATH/config.mk"; then
 225                                 . "$O2IBPATH/config.mk"
 226                         elif test -f "$O2IBPATH/ofed_patch.mk"; then
 227                                 . "$O2IBPATH/ofed_patch.mk"
 228                         fi
 229                 elif test -z "$COMPAT_AUTOCONF"; then
 230                         # Depreciated checks
 231                         if test "x$RHEL_KERNEL" = xyes; then
 232                                 RHEL_MAJOR=$(awk '/ RHEL_MAJOR / { print [$]3 }' $LINUX_OBJ/include/$VERSION_HDIR/version.h)
 233                                 I=$(awk '/ RHEL_MINOR / { print [$]3 }' $LINUX_OBJ/include/$VERSION_HDIR/version.h)
 234                                 while test "$I" -ge 0; do
 235                                         EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_RHEL_${RHEL_MAJOR}_$I"
 236                                         I=$(($I-1))
 237                                 done
 238                         elif test "x$SUSE_KERNEL" = xyes; then
 239                                 SP=$(grep PATCHLEVEL /etc/SuSE-release | sed -e 's/.*= *//')
 240                                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_SLES_11_$SP"
 241                         fi
 242                 fi
 243
 244                 AC_MSG_CHECKING([whether to use any OFED backport headers])
 245                 if test -n "$BACKPORT_INCLUDES"; then
 246                         AC_MSG_RESULT([yes])
 247                         OFED_BACKPORT_PATH="$O2IBPATH/${BACKPORT_INCLUDES/*\/kernel_addons/kernel_addons}/"
 248                         EXTRA_OFED_INCLUDE="-I$OFED_BACKPORT_PATH $EXTRA_OFED_INCLUDE"
 249                 else
 250                         AC_MSG_RESULT([no])
 251                 fi
 252
 253                 O2IBLND=""
 254                 O2IBPATH=$(readlink --canonicalize $O2IBPATH)
 255                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -I$O2IBPATH/include"
 256                 EXTRA_CHECK_INCLUDE="$EXTRA_OFED_CONFIG $EXTRA_OFED_INCLUDE"
 257                 LB_CHECK_COMPILE([whether to enable OpenIB gen2 support],
 258                 openib_gen2_support, [
 259                         #ifdef HAVE_COMPAT_RDMA
 260                         #undef PACKAGE_NAME
 261                         #undef PACKAGE_TARNAME
 262                         #undef PACKAGE_VERSION
 263                         #undef PACKAGE_STRING
 264                         #undef PACKAGE_BUGREPORT
 265                         #undef PACKAGE_URL
 266                         #include <linux/compat-2.6.h>
 267                         #endif
 268                         #include <linux/version.h>
 269                         #include <linux/pci.h>
 270                         #include <linux/gfp.h>
 271                         #include <rdma/rdma_cm.h>
 272                         #include <rdma/ib_cm.h>
 273                         #include <rdma/ib_verbs.h>
 274                         #include <rdma/ib_fmr_pool.h>
 275                 ],[
 276                         struct rdma_cm_id      *cm_idi __attribute__ ((unused));
 277                         struct rdma_conn_param  conn_param __attribute__ ((unused));
 278                         struct ib_device_attr   device_attr __attribute__ ((unused));
 279                         struct ib_qp_attr       qp_attr __attribute__ ((unused));
 280                         struct ib_pool_fmr      pool_fmr __attribute__ ((unused));
 281                         enum   ib_cm_rej_reason rej_reason __attribute__ ((unused));
 282                         rdma_destroy_id(NULL);
 283                 ],[
 284                         O2IBLND="o2iblnd"
 285                 ],[
 286                         case $ENABLEO2IB in
 287                         "yes") AC_MSG_ERROR([can't compile with OpenIB gen2 headers]) ;;
 288                         "withpath") AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]) ;;
 289                         *) AC_MSG_ERROR([internal error]) ;;
 290                         esac
 291                 ])
 292                 # we know at this point that the found OFED source is good
 293                 O2IB_SYMVER=""
 294                 if test $ENABLEO2IB = "withpath" -o "x$OFED" = "xyes" ; then
 295                         # OFED default rpm not handle sles10 Modules.symvers name
 296                         for name in Module.symvers Modules.symvers; do
 297                                 if test -f $O2IBPATH/$name; then
 298                                         O2IB_SYMVER=$name;
 299                                         break;
 300                                 fi
 301                         done
 302                         if test -n "$O2IB_SYMVER"; then
 303                                 AC_MSG_NOTICE([adding $O2IBPATH/$O2IB_SYMVER to Symbol Path])
 304                                 EXTRA_SYMBOLS="$EXTRA_SYMBOLS $O2IBPATH/$O2IB_SYMVER"
 305                                 AC_SUBST(EXTRA_SYMBOLS)
 306                         else
 307                                 AC_MSG_ERROR([an external source tree was, either specified or detected, for o2iblnd however I could not find a $O2IBPATH/Module.symvers there])
 308                         fi
 309                 fi
 310
 311                 LB_CHECK_COMPILE([if Linux kernel has kthread_worker],
 312                 linux_kthread_worker, [
 313                         #ifdef HAVE_COMPAT_RDMA
 314                         #undef PACKAGE_NAME
 315                         #undef PACKAGE_TARNAME
 316                         #undef PACKAGE_VERSION
 317                         #undef PACKAGE_STRING
 318                         #undef PACKAGE_BUGREPORT
 319                         #undef PACKAGE_URL
 320                         #include <linux/compat-2.6.h>
 321                         #endif
 322                         #include <linux/kthread.h>
 323                 ],[
 324                         struct kthread_work     *kth_wrk __attribute__ ((unused));
 325                         flush_kthread_work(kth_wrk);
 326                 ],[
 327                         AC_DEFINE(HAVE_KTHREAD_WORK, 1, [kthread_worker found])
 328                         if test -z "$COMPAT_AUTOCONF"; then
 329                                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_IS_KTHREAD"
 330                         fi
 331                 ])
 332                 EXTRA_CHECK_INCLUDE=""
 333         fi
 334 ])
 335 AC_SUBST(EXTRA_OFED_CONFIG)
 336 AC_SUBST(EXTRA_OFED_INCLUDE)
 337 AC_SUBST(O2IBLND)
 338 AC_SUBST(O2IBPATH)
 339 AC_SUBST(ENABLEO2IB)
 340
 341 AS_IF([test $ENABLEO2IB != "no"], [
 342         EXTRA_CHECK_INCLUDE="$EXTRA_OFED_CONFIG $EXTRA_OFED_INCLUDE"
 343         # In RHEL 6.2, rdma_create_id() takes the queue-pair type as a fourth argument
 344         LB_CHECK_COMPILE([if 'rdma_create_id' wants four args],
 345         rdma_create_id_4args, [
 346                 #ifdef HAVE_COMPAT_RDMA
 347                 #undef PACKAGE_NAME
 348                 #undef PACKAGE_TARNAME
 349                 #undef PACKAGE_VERSION
 350                 #undef PACKAGE_STRING
 351                 #undef PACKAGE_BUGREPORT
 352                 #undef PACKAGE_URL
 353                 #include <linux/compat-2.6.h>
 354                 #endif
 355                 #include <rdma/rdma_cm.h>
 356         ],[
 357                 rdma_create_id(NULL, NULL, 0, 0);
 358         ],[
 359                 AC_DEFINE(HAVE_RDMA_CREATE_ID_4ARG, 1,
 360                         [rdma_create_id wants 4 args])
 361         ])
 362
 363         # 4.4 added network namespace parameter for rdma_create_id()
 364         LB_CHECK_COMPILE([if 'rdma_create_id' wants five args],
 365         rdma_create_id_5args, [
 366                 #ifdef HAVE_COMPAT_RDMA
 367                 #undef PACKAGE_NAME
 368                 #undef PACKAGE_TARNAME
 369                 #undef PACKAGE_VERSION
 370                 #undef PACKAGE_STRING
 371                 #undef PACKAGE_BUGREPORT
 372                 #undef PACKAGE_URL
 373                 #include <linux/compat-2.6.h>
 374                 #endif
 375                 #include <rdma/rdma_cm.h>
 376         ],[
 377                 rdma_create_id(NULL, NULL, NULL, 0, 0);
 378         ],[
 379                 AC_DEFINE(HAVE_RDMA_CREATE_ID_5ARG, 1,
 380                         [rdma_create_id wants 5 args])
 381         ])
 382
 383         # 4.2 introduced struct ib_cq_init_attr which is used
 384         # by ib_create_cq(). Note some OFED stacks only keep
 385         # their headers in sync with latest kernels but not
 386         # the functionality which means for infiniband testing
 387         # we need to always test functionality testings.
 388         LB_CHECK_COMPILE([if 'struct ib_cq_init_attr' is used],
 389         ib_cq_init_attr, [
 390                 #ifdef HAVE_COMPAT_RDMA
 391                 #undef PACKAGE_NAME
 392                 #undef PACKAGE_TARNAME
 393                 #undef PACKAGE_VERSION
 394                 #undef PACKAGE_STRING
 395                 #undef PACKAGE_BUGREPORT
 396                 #undef PACKAGE_URL
 397                 #include <linux/compat-2.6.h>
 398                 #endif
 399                 #include <rdma/ib_verbs.h>
 400         ],[
 401                 struct ib_cq_init_attr cq_attr;
 402
 403                 ib_create_cq(NULL, NULL, NULL, NULL, &cq_attr);
 404         ],[
 405                 AC_DEFINE(HAVE_IB_CQ_INIT_ATTR, 1,
 406                         [struct ib_cq_init_attr is used by ib_create_cq])
 407         ])
 408
 409         # 4.3 removed ib_alloc_fast_reg_mr()
 410         LB_CHECK_COMPILE([if 'ib_alloc_fast_reg_mr' exists],
 411         ib_alloc_fast_reg_mr, [
 412                 #ifdef HAVE_COMPAT_RDMA
 413                 #undef PACKAGE_NAME
 414                 #undef PACKAGE_TARNAME
 415                 #undef PACKAGE_VERSION
 416                 #undef PACKAGE_STRING
 417                 #undef PACKAGE_BUGREPORT
 418                 #undef PACKAGE_URL
 419                 #include <linux/compat-2.6.h>
 420                 #endif
 421                 #include <rdma/ib_verbs.h>
 422         ],[
 423                 ib_alloc_fast_reg_mr(NULL, 0);
 424         ],[
 425                 AC_DEFINE(HAVE_IB_ALLOC_FAST_REG_MR, 1,
 426                         [ib_alloc_fast_reg_mr is defined])
 427         ])
 428
 429         # In v4.4 Linux kernel,
 430         # commit e622f2f4ad2142d2a613a57fb85f8cf737935ef5
 431         # split up struct ib_send_wr so that all non-trivial verbs
 432         # use their own structure which embedds struct ib_send_wr.
 433         LB_CHECK_COMPILE([if 'struct ib_rdma_wr' is defined],
 434         ib_rdma_wr, [
 435                 #ifdef HAVE_COMPAT_RDMA
 436                 #undef PACKAGE_NAME
 437                 #undef PACKAGE_TARNAME
 438                 #undef PACKAGE_VERSION
 439                 #undef PACKAGE_STRING
 440                 #undef PACKAGE_BUGREPORT
 441                 #undef PACKAGE_URL
 442                 #include <linux/compat-2.6.h>
 443                 #endif
 444                 #include <rdma/ib_verbs.h>
 445         ],[
 446                 struct ib_rdma_wr *wr __attribute__ ((unused));
 447
 448                 wr = rdma_wr(NULL);
 449         ],[
 450                 AC_DEFINE(HAVE_IB_RDMA_WR, 1,
 451                         [struct ib_rdma_wr is defined])
 452         ])
 453
 454         # new fast registration API introduced in 4.4
 455         LB_CHECK_COMPILE([if 'ib_map_mr_sg' exists],
 456         ib_map_mr_sg, [
 457                 #ifdef HAVE_COMPAT_RDMA
 458                 #undef PACKAGE_NAME
 459                 #undef PACKAGE_TARNAME
 460                 #undef PACKAGE_VERSION
 461                 #undef PACKAGE_STRING
 462                 #undef PACKAGE_BUGREPORT
 463                 #undef PACKAGE_URL
 464                 #include <linux/compat-2.6.h>
 465                 #endif
 466                 #include <rdma/ib_verbs.h>
 467         ],[
 468                 ib_map_mr_sg(NULL, NULL, 0, 0);
 469         ],[
 470                 AC_DEFINE(HAVE_IB_MAP_MR_SG, 1,
 471                         [ib_map_mr_sg exists])
 472         ])
 473         EXTRA_CHECK_INCLUDE=""
 474 ]) # ENABLEO2IB != "no"
 475 ]) # LN_CONFIG_O2IB
 476
 477 #
 478 # LN_CONFIG_GNILND
 479 #
 480 # check whether to use the Gemini Network Interface lnd
 481 #
 482 AC_DEFUN([LN_CONFIG_GNILND], [
 483 AC_MSG_CHECKING([whether to enable GNI lnd])
 484 AC_ARG_ENABLE([gni],
 485         AC_HELP_STRING([--enable-gni],
 486                 [enable GNI lnd]),
 487         [], [enable_gni="no"])
 488 AC_MSG_RESULT([$enable_gni])
 489
 490 AS_IF([test "x$enable_gni" = xyes], [
 491         # GNICPPFLAGS was set in spec file
 492         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 493         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $GNICPPFLAGS"
 494         LB_CHECK_COMPILE([if GNI kernel headers are present],
 495         GNI_header, [
 496                 #include <linux/types.h>
 497                 #include <gni_pub.h>
 498         ],[
 499                 gni_cdm_handle_t kgni_domain;
 500                 gni_return_t     rc;
 501                 int              rrc;
 502                 rc = gni_cdm_create(0, 1, 1, 0, &kgni_domain);
 503                 rrc = (rc == GNI_RC_SUCCESS) ? 0 : 1;
 504                 return rrc;
 505         ],[
 506                 GNILND="gnilnd"
 507         ],[
 508                 AC_MSG_ERROR([can't compile gnilnd with given GNICPPFLAGS: $GNICPPFLAGS])
 509         ])
 510         # at this point, we have gnilnd basic support,
 511         # now check for extra features
 512         LB_CHECK_COMPILE([to use RCA in gnilnd],
 513         RCA_gnilnd, [
 514                 #include <linux/types.h>
 515                 #include <gni_pub.h>
 516                 #include <krca_lib.h>
 517         ],[
 518                 gni_cdm_handle_t kgni_domain;
 519                 gni_return_t     rc;
 520                 krca_ticket_t    ticket = KRCA_NULL_TICKET;
 521                 int              rrc;
 522                 __u32            nid = 0, nic_addr;
 523                 rc = gni_cdm_create(0, 1, 1, 0, &kgni_domain);
 524                 rrc = (rc == GNI_RC_SUCCESS) ? 0 : 1;
 525                 rrc += krca_nid_to_nicaddrs(nid, 1, &nic_addr);
 526                 rrc += krca_register(&ticket, RCA_MAKE_SERVICE_INDEX(RCA_IO_CLASS, 9), 99, 0);
 527                 return rrc;
 528         ],[
 529                 GNICPPFLAGS="$GNICPPFLAGS -DGNILND_USE_RCA=1"
 530         ])
 531         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 532 ])
 533 AC_SUBST(GNICPPFLAGS)
 534 AC_SUBST(GNILND)
 535 ]) # LN_CONFIG_GNILND
 536
 537 #
 538 # LN_CONFIG_SK_SLEEP
 539 #
 540 # 2.6.35 kernel has sk_sleep function
 541 #
 542 AC_DEFUN([LN_CONFIG_SK_SLEEP], [
 543 LB_CHECK_COMPILE([if Linux kernel has 'sk_sleep'],
 544 sk_sleep, [
 545         #ifdef HAVE_COMPAT_RDMA
 546         #undef PACKAGE_NAME
 547         #undef PACKAGE_TARNAME
 548         #undef PACKAGE_VERSION
 549         #undef PACKAGE_STRING
 550         #undef PACKAGE_BUGREPORT
 551         #undef PACKAGE_URL
 552         #include <linux/compat-2.6.h>
 553         #endif
 554         #include <net/sock.h>
 555 ],[
 556         sk_sleep(NULL);
 557 ],[
 558         AC_DEFINE(HAVE_SK_SLEEP, 1,
 559                   [kernel has sk_sleep])
 560 ])
 561 ]) # LN_CONFIG_SK_SLEEP
 562
 563 #
 564 # LN_CONFIG_TCP_SENDPAGE
 565 #
 566 # 2.6.36 tcp_sendpage() first parameter is 'struct sock' instead of 'struct socket'.
 567 #
 568 AC_DEFUN([LN_CONFIG_TCP_SENDPAGE], [
 569 tmp_flags="$EXTRA_KCFLAGS"
 570 EXTRA_KCFLAGS="-Werror"
 571 LB_CHECK_COMPILE([if 'tcp_sendpage' first parameter is socket],
 572 tcp_sendpage_socket, [
 573         #ifdef HAVE_COMPAT_RDMA
 574         #undef PACKAGE_NAME
 575         #undef PACKAGE_TARNAME
 576         #undef PACKAGE_VERSION
 577         #undef PACKAGE_STRING
 578         #undef PACKAGE_BUGREPORT
 579         #undef PACKAGE_URL
 580         #include <linux/compat-2.6.h>
 581         #endif
 582         #include <linux/net.h>
 583         #include <net/tcp.h>
 584 ],[
 585         tcp_sendpage((struct socket*)0, NULL, 0, 0, 0);
 586 ],[
 587         AC_DEFINE(HAVE_TCP_SENDPAGE_USE_SOCKET, 1,
 588                 [tcp_sendpage use socket as first parameter])
 589 ])
 590 EXTRA_KCFLAGS="$tmp_flags"
 591 ]) # LN_CONFIG_TCP_SENDPAGE
 592
 593 #
 594 # LN_CONFIG_SK_DATA_READY
 595 #
 596 # 3.15 for struct sock the *sk_data_ready() field only takes one argument now
 597 #
 598 AC_DEFUN([LN_CONFIG_SK_DATA_READY], [
 599 tmp_flags="$EXTRA_KCFLAGS"
 600 EXTRA_KCFLAGS="-Werror"
 601 LB_CHECK_COMPILE([if 'sk_data_ready' takes only one argument],
 602 sk_data_ready, [
 603         #ifdef HAVE_COMPAT_RDMA
 604         #undef PACKAGE_NAME
 605         #undef PACKAGE_TARNAME
 606         #undef PACKAGE_VERSION
 607         #undef PACKAGE_STRING
 608         #undef PACKAGE_BUGREPORT
 609         #undef PACKAGE_URL
 610         #include <linux/compat-2.6.h>
 611         #endif
 612         #include <linux/net.h>
 613         #include <net/sock.h>
 614 ],[
 615         ((struct sock *)0)->sk_data_ready(NULL);
 616 ],[
 617         AC_DEFINE(HAVE_SK_DATA_READY_ONE_ARG, 1,
 618                 [sk_data_ready uses only one argument])
 619 ])
 620 EXTRA_KCFLAGS="$tmp_flags"
 621 ]) # LN_CONFIG_SK_DATA_READY
 622
 623 #
 624 # LN_CONFIG_IB_INC_RKEY
 625 #
 626 AC_DEFUN([LN_CONFIG_IB_INC_RKEY], [
 627 tmp_flags="$EXTRA_KCFLAGS"
 628 EXTRA_KCFLAGS="-Werror"
 629 LB_CHECK_COMPILE([if function 'ib_inc_rkey' is defined],
 630 ib_inc_rkey, [
 631         #ifdef HAVE_COMPAT_RDMA
 632         #undef PACKAGE_NAME
 633         #undef PACKAGE_TARNAME
 634         #undef PACKAGE_VERSION
 635         #undef PACKAGE_STRING
 636         #undef PACKAGE_BUGREPORT
 637         #undef PACKAGE_URL
 638         #include <linux/compat-2.6.h>
 639         #endif
 640         #include <rdma/ib_verbs.h>
 641 ],[
 642         (void)ib_inc_rkey(0);
 643 ],[
 644         AC_DEFINE(HAVE_IB_INC_RKEY, 1,
 645                   [function ib_inc_rkey exist])
 646 ])
 647 EXTRA_KCFLAGS="$tmp_flags"
 648 ]) # LN_CONFIG_IB_INC_RKEY
 649
 650 #
 651 # LN_PROG_LINUX
 652 #
 653 # LNet linux kernel checks
 654 #
 655 AC_DEFUN([LN_PROG_LINUX], [
 656 AC_MSG_NOTICE([LNet kernel checks
 657 ==============================================================================])
 658
 659 LN_CONFIG_AFFINITY
 660 LN_CONFIG_BACKOFF
 661 LN_CONFIG_O2IB
 662 LN_CONFIG_GNILND
 663 # OFED checks, so add extra OFED include
 664 EXTRA_CHECK_INCLUDE="$EXTRA_OFED_CONFIG $EXTRA_OFED_INCLUDE"
 665 # 2.6.35
 666 LN_CONFIG_SK_SLEEP
 667 # 2.6.36
 668 LN_CONFIG_TCP_SENDPAGE
 669 # 3.8.1
 670 LN_CONFIG_IB_INC_RKEY
 671 # 3.15
 672 LN_CONFIG_SK_DATA_READY
 673 # remove extra include for none OFED code
 674 EXTRA_CHECK_INCLUDE=""
 675 ]) # LN_PROG_LINUX
 676
 677 #
 678 # LN_PATH_DEFAULTS
 679 #
 680 # default paths for installed files
 681 #
 682 AC_DEFUN([LN_PATH_DEFAULTS], [
 683 ]) # LN_PATH_DEFAULTS
 684
 685 #
 686 # LN_CONFIGURE
 687 #
 688 # other configure checks
 689 #
 690 AC_DEFUN([LN_CONFIGURE], [
 691 AC_MSG_NOTICE([LNet core checks
 692 ==============================================================================])
 693
 694 # lnet/utils/portals.c
 695 AC_CHECK_HEADERS([netdb.h])
 696 AC_CHECK_FUNCS([gethostbyname])
 697
 698 # lnet/utils/wirecheck.c
 699 AC_CHECK_FUNCS([strnlen])
 700
 701 # --------  Check for required packages  --------------
 702
 703 AC_MSG_CHECKING([whether to enable 'efence' debugging support])
 704 AC_ARG_ENABLE(efence,
 705         AC_HELP_STRING([--enable-efence],
 706                 [use efence library]),
 707         [], [enable_efence="no"])
 708 AC_MSG_RESULT([$enable_efence])
 709
 710 LIBEFENCE=""
 711 AS_IF([test "$enable_efence" = yes], [
 712         LIBEFENCE="-lefence"
 713         AC_DEFINE(HAVE_LIBEFENCE, 1,
 714                 [libefence support is requested])
 715 ])
 716 AC_SUBST(LIBEFENCE)
 717
 718 LN_CONFIG_MAX_PAYLOAD
 719 LN_CONFIG_DLC
 720 ]) # LN_CONFIGURE
 721
 722 #
 723 # LN_CONDITIONALS
 724 #
 725 # AM_CONDITIONAL defines for lnet
 726 #
 727 AC_DEFUN([LN_CONDITIONALS], [
 728 AM_CONDITIONAL(BUILD_O2IBLND,    test x$O2IBLND = "xo2iblnd")
 729 AM_CONDITIONAL(BUILD_GNILND,     test x$GNILND  = "xgnilnd")
 730 AM_CONDITIONAL(BUILD_DLC,        test x$USE_DLC = "xyes")
 731 ]) # LN_CONDITIONALS
 732
 733 #
 734 # LN_CONFIG_FILES
 735 #
 736 # files that should be generated with AC_OUTPUT
 737 #
 738 AC_DEFUN([LN_CONFIG_FILES], [
 739 AC_CONFIG_FILES([
 740 lnet/Makefile
 741 lnet/autoMakefile
 742 lnet/autoconf/Makefile
 743 lnet/doc/Makefile
 744 lnet/include/Makefile
 745 lnet/include/lnet/Makefile
 746 lnet/klnds/Makefile
 747 lnet/klnds/autoMakefile
 748 lnet/klnds/o2iblnd/Makefile
 749 lnet/klnds/o2iblnd/autoMakefile
 750 lnet/klnds/gnilnd/Makefile
 751 lnet/klnds/gnilnd/autoMakefile
 752 lnet/klnds/socklnd/Makefile
 753 lnet/klnds/socklnd/autoMakefile
 754 lnet/lnet/Makefile
 755 lnet/lnet/autoMakefile
 756 lnet/selftest/Makefile
 757 lnet/selftest/autoMakefile
 758 lnet/utils/Makefile
 759 lnet/utils/lnetconfig/Makefile
 760 ])
 761 ]) # LN_CONFIG_FILES