lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD],
   7 [AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                        [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19         AC_DEFINE_UNQUOTED(LNET_MAX_PAYLOAD, $LNET_MAX_PAYLOAD,
  20                            [Max LNET payload])
  21 ])
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION],
  29 [AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ])
  43
  44 #
  45 # LN_CONFIG_AFFINITY
  46 #
  47 # check if cpu affinity is available/wanted
  48 #
  49 AC_DEFUN([LN_CONFIG_AFFINITY],
  50 [AC_ARG_ENABLE([affinity],
  51         AC_HELP_STRING([--disable-affinity],
  52                        [disable process/irq affinity]),
  53         [],[enable_affinity='yes'])
  54
  55 AC_MSG_CHECKING([for CPU affinity support])
  56 if test x$enable_affinity = xno ; then
  57         AC_MSG_RESULT([no (by request)])
  58 else
  59         LB_LINUX_TRY_COMPILE([
  60                 #include <linux/sched.h>
  61         ],[
  62                 struct task_struct t;
  63                 #if HAVE_CPUMASK_T
  64                 cpumask_t     m;
  65                 #else
  66                 unsigned long m;
  67                 #endif
  68                 set_cpus_allowed(&t, m);
  69         ],[
  70                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
  71                 AC_MSG_RESULT([yes])
  72         ],[
  73                 AC_MSG_RESULT([no (no kernel support)])
  74         ])
  75 fi
  76 ])
  77
  78 #
  79 # LN_CONFIG_PORTALS
  80 #
  81 # configure support for Portals
  82 #
  83 AC_DEFUN([LN_CONFIG_PORTALS],
  84 [AC_MSG_CHECKING([for portals])
  85 AC_ARG_WITH([portals],
  86         AC_HELP_STRING([--with-portals=path],
  87                        [set path to portals]),
  88         [
  89                 case $with_portals in
  90                         no)     ENABLEPORTALS=0
  91                                 ;;
  92                         *)      PORTALS="${with_portals}"
  93                                 ENABLEPORTALS=1
  94                                 ;;
  95                 esac
  96         ], [
  97                 ENABLEPORTALS=0
  98         ])
  99 PTLLNDCPPFLAGS=""
 100 if test $ENABLEPORTALS -eq 0; then
 101         AC_MSG_RESULT([no])
 102 elif test ! \( -f ${PORTALS}/include/portals/p30.h \); then
 103         AC_MSG_RESULT([no])
 104         AC_MSG_ERROR([bad --with-portals path])
 105 else
 106         AC_MSG_RESULT([$PORTALS])
 107         PTLLNDCPPFLAGS="-I${PORTALS}/include"
 108 fi
 109 AC_SUBST(PTLLNDCPPFLAGS)
 110 ])
 111
 112 #
 113 # LN_CONFIG_BACKOFF
 114 #
 115 # check if tunable tcp backoff is available/wanted
 116 #
 117 AC_DEFUN([LN_CONFIG_BACKOFF],
 118 [AC_MSG_CHECKING([for tunable backoff TCP support])
 119 AC_ARG_ENABLE([backoff],
 120        AC_HELP_STRING([--disable-backoff],
 121                       [disable socknal tunable backoff]),
 122        [],[enable_backoff='yes'])
 123 if test x$enable_backoff = xno ; then
 124        AC_MSG_RESULT([no (by request)])
 125 else
 126        BOCD="`grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h`"
 127        if test "$BOCD" != 0 ; then
 128                AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
 129                AC_MSG_RESULT(yes)
 130                if grep rto_max $LINUX/include/linux/tcp.h|grep -q __u16; then
 131                    AC_DEFINE(SOCKNAL_BACKOFF_MS, 1, [tunable backoff TCP in ms])
 132                fi
 133        else
 134                AC_MSG_RESULT([no (no kernel support)])
 135        fi
 136 fi
 137 ])
 138
 139
 140 #
 141 # LN_CONFIG_PTLLND
 142 #
 143 # configure support for Portals LND
 144 #
 145 AC_DEFUN([LN_CONFIG_PTLLND],
 146 [
 147 if test -z "$ENABLEPORTALS"; then
 148         LN_CONFIG_PORTALS
 149 fi
 150
 151 AC_MSG_CHECKING([whether to build the kernel portals LND])
 152
 153 PTLLND=""
 154 if test $ENABLEPORTALS -ne 0; then
 155         AC_MSG_RESULT([yes])
 156         PTLLND="ptllnd"
 157 else
 158         AC_MSG_RESULT([no])
 159 fi
 160 AC_SUBST(PTLLND)
 161 ])
 162
 163 #
 164 # LN_CONFIG_UPTLLND
 165 #
 166 # configure support for Portals LND
 167 #
 168 AC_DEFUN([LN_CONFIG_UPTLLND],
 169 [
 170 if test -z "$ENABLEPORTALS"; then
 171         LN_CONFIG_PORTALS
 172 fi
 173
 174 AC_MSG_CHECKING([whether to build the userspace portals LND])
 175
 176 UPTLLND=""
 177 if test $ENABLEPORTALS -ne 0; then
 178         AC_MSG_RESULT([yes])
 179         UPTLLND="ptllnd"
 180 else
 181         AC_MSG_RESULT([no])
 182 fi
 183 AC_SUBST(UPTLLND)
 184 ])
 185
 186 #
 187 # LN_CONFIG_USOCKLND
 188 #
 189 # configure support for userspace TCP/IP LND
 190 #
 191 AC_DEFUN([LN_CONFIG_USOCKLND],
 192 [AC_MSG_CHECKING([whether to build usocklnd])
 193 AC_ARG_ENABLE([usocklnd],
 194         AC_HELP_STRING([--disable-usocklnd],
 195                         [disable usocklnd]),
 196         [],[enable_usocklnd='yes'])
 197
 198 if test x$enable_usocklnd = xyes ; then
 199         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 200                 AC_MSG_RESULT([yes])
 201                 USOCKLND="usocklnd"
 202         else
 203                 AC_MSG_RESULT([no (libpthread not present or disabled)])
 204                 USOCKLND=""
 205         fi
 206 else
 207         AC_MSG_RESULT([no (disabled explicitly)])
 208         USOCKLND=""
 209 fi
 210 AC_SUBST(USOCKLND)
 211 ])
 212
 213 #
 214 # LN_CONFIG_QUADRICS
 215 #
 216 # check if quadrics support is in this kernel
 217 #
 218 AC_DEFUN([LN_CONFIG_QUADRICS],
 219 [AC_MSG_CHECKING([for QsNet sources])
 220 AC_ARG_WITH([qsnet],
 221         AC_HELP_STRING([--with-qsnet=path],
 222                        [set path to qsnet source (default=$LINUX)]),
 223         [QSNET=$with_qsnet],
 224         [QSNET=$LINUX])
 225 AC_MSG_RESULT([$QSNET])
 226
 227 AC_MSG_CHECKING([if quadrics kernel headers are present])
 228 if test -d $QSNET/drivers/net/qsnet ; then
 229         AC_MSG_RESULT([yes])
 230         QSWLND="qswlnd"
 231         AC_MSG_CHECKING([for multirail EKC])
 232         if test -f $QSNET/include/elan/epcomms.h; then
 233                 AC_MSG_RESULT([supported])
 234                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 235         else
 236                 AC_MSG_RESULT([not supported])
 237                 AC_MSG_ERROR([Need multirail EKC])
 238         fi
 239
 240         if test x$QSNET = x$LINUX ; then
 241                 LB_LINUX_CONFIG([QSNET],[],[
 242                         LB_LINUX_CONFIG([QSNET_MODULE],[],[
 243                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
 244                                 QSWLND=""
 245                                 QSWCPPFLAGS=""
 246                         ])
 247                 ])
 248         fi
 249 else
 250         AC_MSG_RESULT([no])
 251         QSWLND=""
 252         QSWCPPFLAGS=""
 253 fi
 254 AC_SUBST(QSWCPPFLAGS)
 255 AC_SUBST(QSWLND)
 256 ])
 257
 258 #
 259 # LN_CONFIG_GM
 260 #
 261 # check if GM support is available
 262 #
 263 AC_DEFUN([LN_CONFIG_GM],[
 264 AC_MSG_CHECKING([whether to enable GM support])
 265 AC_ARG_WITH([gm],
 266         AC_HELP_STRING([--with-gm=path-to-gm-source-tree],
 267                        [build gmlnd against path]),
 268         [
 269                 case $with_gm in
 270                 no)    ENABLE_GM=0
 271                        ;;
 272                 *)     ENABLE_GM=1
 273                        GM_SRC="$with_gm"
 274                        ;;
 275                 esac
 276         ],[
 277                 ENABLE_GM=0
 278         ])
 279 AC_ARG_WITH([gm-install],
 280         AC_HELP_STRING([--with-gm-install=path-to-gm-install-tree],
 281                        [say where GM has been installed]),
 282         [
 283                 GM_INSTALL=$with_gm_install
 284         ],[
 285                 GM_INSTALL="/opt/gm"
 286         ])
 287 if test $ENABLE_GM -eq 0; then
 288         AC_MSG_RESULT([no])
 289 else
 290         AC_MSG_RESULT([yes])
 291
 292         GMLND="gmlnd"
 293         GMCPPFLAGS="-I$GM_SRC/include -I$GM_SRC/drivers -I$GM_SRC/drivers/linux/gm"
 294
 295         if test -f $GM_INSTALL/lib/libgm.a -o \
 296                 -f $GM_INSTALL/lib64/libgm.a; then
 297                 GMLIBS="-L$GM_INSTALL/lib -L$GM_INSTALL/lib64"
 298         else
 299                 AC_MSG_ERROR([Cant find GM libraries under $GM_INSTALL])
 300         fi
 301
 302         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 303         EXTRA_KCFLAGS="$GMCPPFLAGS -DGM_KERNEL $EXTRA_KCFLAGS"
 304
 305         AC_MSG_CHECKING([that code using GM compiles with given path])
 306         LB_LINUX_TRY_COMPILE([
 307                 #define GM_STRONG_TYPES 1
 308                 #ifdef VERSION
 309                 #undef VERSION
 310                 #endif
 311                 #include "gm.h"
 312                 #include "gm_internal.h"
 313         ],[
 314                 struct gm_port *port = NULL;
 315                 gm_recv_event_t *rxevent = gm_blocking_receive_no_spin(port);
 316                 return 0;
 317         ],[
 318                 AC_MSG_RESULT([yes])
 319         ],[
 320                 AC_MSG_RESULT([no])
 321                 AC_MSG_ERROR([Bad --with-gm path])
 322         ])
 323
 324         AC_MSG_CHECKING([that GM has gm_register_memory_ex_phys()])
 325         LB_LINUX_TRY_COMPILE([
 326                 #define GM_STRONG_TYPES 1
 327                 #ifdef VERSION
 328                 #undef VERSION
 329                 #endif
 330                 #include "gm.h"
 331                 #include "gm_internal.h"
 332         ],[
 333                 gm_status_t     gmrc;
 334                 struct gm_port *port = NULL;
 335                 gm_u64_t        phys = 0;
 336                 gm_up_t         pvma = 0;
 337
 338                 gmrc = gm_register_memory_ex_phys(port, phys, 100, pvma);
 339                 return 0;
 340         ],[
 341                 AC_MSG_RESULT([yes])
 342         ],[
 343                 AC_MSG_RESULT([no.
 344 Please patch the GM sources as follows...
 345     cd $GM_SRC
 346     patch -p0 < $PWD/lnet/klnds/gmlnd/gm-reg-phys.patch
 347 ...then rebuild and re-install them])
 348                 AC_MSG_ERROR([Can't build GM without gm_register_memory_ex_phys()])
 349         ])
 350
 351         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 352 fi
 353 AC_SUBST(GMCPPFLAGS)
 354 AC_SUBST(GMLIBS)
 355 AC_SUBST(GMLND)
 356 ])
 357
 358
 359 #
 360 # LN_CONFIG_MX
 361 #
 362 AC_DEFUN([LN_CONFIG_MX],
 363 [AC_MSG_CHECKING([whether to enable Myrinet MX support])
 364 # set default
 365 MXPATH="/opt/mx"
 366 AC_ARG_WITH([mx],
 367        AC_HELP_STRING([--with-mx=path],
 368                       [build mxlnd against path]),
 369        [
 370                case $with_mx in
 371                yes)    ENABLEMX=2
 372                        ;;
 373                no)     ENABLEMX=0
 374                        ;;
 375                *)      MXPATH=$with_mx
 376                        ENABLEMX=3
 377                        ;;
 378                esac
 379        ],[
 380                ENABLEMX=1
 381        ])
 382 if test $ENABLEMX -eq 0; then
 383        AC_MSG_RESULT([disabled])
 384 elif test ! \( -f ${MXPATH}/include/myriexpress.h -a \
 385               -f ${MXPATH}/include/mx_kernel_api.h -a \
 386               -f ${MXPATH}/include/mx_pin.h \); then
 387        AC_MSG_RESULT([no])
 388        case $ENABLEMX in
 389        1) ;;
 390        2) AC_MSG_ERROR([Myrinet MX kernel headers not present]);;
 391        3) AC_MSG_ERROR([bad --with-mx path]);;
 392        *) AC_MSG_ERROR([internal error]);;
 393        esac
 394 else
 395        MXCPPFLAGS="-I$MXPATH/include"
 396        EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 397        EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
 398        MXLIBS="-L$MXPATH/lib"
 399        LB_LINUX_TRY_COMPILE([
 400                #define MX_KERNEL 1
 401                #include <mx_extensions.h>
 402                #include <myriexpress.h>
 403        ],[
 404                mx_endpoint_t   end;
 405                mx_status_t     status;
 406                mx_request_t    request;
 407                int             result;
 408
 409                mx_init();
 410                mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
 411                mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
 412                mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
 413                mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
 414                return 0;
 415        ],[
 416                AC_MSG_RESULT([yes])
 417                MXLND="mxlnd"
 418        ],[
 419                AC_MSG_RESULT([no])
 420                case $ENABLEMX in
 421                1) ;;
 422                2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]);;
 423                3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]);;
 424                *) AC_MSG_ERROR([internal error]);;
 425                esac
 426                MXLND=""
 427                MXCPPFLAGS=""
 428        ])
 429        EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 430 fi
 431 AC_SUBST(MXCPPFLAGS)
 432 AC_SUBST(MXLIBS)
 433 AC_SUBST(MXLND)
 434 ])
 435
 436
 437
 438 #
 439 # LN_CONFIG_O2IB
 440 #
 441 AC_DEFUN([LN_CONFIG_O2IB],[
 442 AC_MSG_CHECKING([whether to enable OpenIB gen2 support])
 443 # set default
 444 AC_ARG_WITH([o2ib],
 445         AC_HELP_STRING([--with-o2ib=path],
 446                        [build o2iblnd against path]),
 447         [
 448                 case $with_o2ib in
 449                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 450                         ENABLEO2IB=2
 451                         ;;
 452                 no)     ENABLEO2IB=0
 453                         ;;
 454                 *)      O2IBPATHS=$with_o2ib
 455                         ENABLEO2IB=3
 456                         ;;
 457                 esac
 458         ],[
 459                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 460                 ENABLEO2IB=1
 461         ])
 462 if test $ENABLEO2IB -eq 0; then
 463         AC_MSG_RESULT([disabled])
 464 else
 465         o2ib_found=false
 466
 467         for O2IBPATH in $O2IBPATHS; do
 468                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 469                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 470                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 471                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 472                         o2ib_found=true
 473                         break
 474                 fi
 475         done
 476
 477         if ! $o2ib_found; then
 478                 AC_MSG_RESULT([no])
 479                 case $ENABLEO2IB in
 480                         1) ;;
 481                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 482                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 483                         *) AC_MSG_ERROR([internal error]);;
 484                 esac
 485         else
 486                 O2IBCPPFLAGS="-I$O2IBPATH/include"
 487                 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 488                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $O2IBCPPFLAGS"
 489                 EXTRA_LNET_INCLUDE="$O2IBCPPFLAGS $EXTRA_LNET_INCLUDE"
 490                 LB_LINUX_TRY_COMPILE([
 491                         #include <linux/version.h>
 492                         #include <linux/pci.h>
 493                         #if !HAVE_GFP_T
 494                         typedef int gfp_t;
 495                         #endif
 496                         #include <rdma/rdma_cm.h>
 497                         #include <rdma/ib_cm.h>
 498                         #include <rdma/ib_verbs.h>
 499                         #include <rdma/ib_fmr_pool.h>
 500                 ],[
 501                         struct rdma_cm_id          *cm_id;
 502                         struct rdma_conn_param      conn_param;
 503                         struct ib_device_attr       device_attr;
 504                         struct ib_qp_attr           qp_attr;
 505                         struct ib_pool_fmr          pool_fmr;
 506                         enum   ib_cm_rej_reason     rej_reason;
 507
 508                         cm_id = rdma_create_id(NULL, NULL, RDMA_PS_TCP);
 509                         return PTR_ERR(cm_id);
 510                 ],[
 511                         AC_MSG_RESULT([yes])
 512                         O2IBLND="o2iblnd"
 513                 ],[
 514                         AC_MSG_RESULT([no])
 515                         case $ENABLEO2IB in
 516                         1) ;;
 517                         2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]);;
 518                         3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]);;
 519                         *) AC_MSG_ERROR([internal error]);;
 520                         esac
 521                         O2IBLND=""
 522                         O2IBCPPFLAGS=""
 523                 ])
 524                 # we know at this point that the found OFED source is good
 525                 O2IB_SYMVER=""
 526                 if test $ENABLEO2IB -eq 3 ; then
 527                         # OFED default rpm not handle sles10 Modules.symvers name
 528                         for name in Module.symvers Modules.symvers; do
 529                                 if test -f $O2IBPATH/$name; then
 530                                         O2IB_SYMVER=$name;
 531                                         break;
 532                                 fi
 533                         done
 534                         if test -n $O2IB_SYMVER ; then
 535                                 AC_MSG_NOTICE([adding $O2IBPATH/$O2IB_SYMVER to $PWD/$SYMVERFILE])
 536                                 # strip out the existing symbols versions first
 537                                 egrep -v $(echo $(awk '{ print $2 }' $O2IBPATH/$O2IB_SYMVER) | tr ' ' '|') $PWD/$SYMVERFILE > $PWD/$SYMVERFILE.old
 538                                 cat $PWD/$SYMVERFILE.old $O2IBPATH/$O2IB_SYMVER > $PWD/$SYMVERFILE
 539                         else
 540                                 AC_MSG_ERROR([an external source tree was specified for o2iblnd however I could not find a $O2IBPATH/Module.symvers there])
 541                         fi
 542                 fi
 543
 544                 LB_LINUX_TRY_COMPILE([
 545                         #include <linux/version.h>
 546                         #include <linux/pci.h>
 547                         #if !HAVE_GFP_T
 548                         typedef int gfp_t;
 549                         #endif
 550                         #include <rdma/ib_verbs.h>
 551                 ],[
 552                         ib_dma_map_single(NULL, NULL, 0, 0);
 553                         return 0;
 554                 ],[
 555                         AC_MSG_RESULT(yes)
 556                         AC_DEFINE(HAVE_OFED_IB_DMA_MAP, 1,
 557                                   [ib_dma_map_single defined])
 558                 ],[
 559                         AC_MSG_RESULT(NO)
 560                 ])
 561
 562                 LB_LINUX_TRY_COMPILE([
 563                         #include <linux/version.h>
 564                         #include <linux/pci.h>
 565                         #if !HAVE_GFP_T
 566                         typedef int gfp_t;
 567                         #endif
 568                         #include <rdma/ib_verbs.h>
 569                 ],[
 570                         ib_create_cq(NULL, NULL, NULL, NULL, 0, 0);
 571                         return 0;
 572                 ],[
 573                         AC_MSG_RESULT(yes)
 574                         AC_DEFINE(HAVE_OFED_IB_COMP_VECTOR, 1,
 575                                   [has completion vector])
 576                 ],[
 577                         AC_MSG_RESULT(NO)
 578                 ])
 579
 580                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 581         fi
 582 fi
 583
 584 AC_SUBST(EXTRA_LNET_INCLUDE)
 585 AC_SUBST(O2IBCPPFLAGS)
 586 AC_SUBST(O2IBLND)
 587 ])
 588
 589 #
 590 # LN_CONFIG_OPENIB
 591 #
 592 # check for OpenIB in the kernel
 593 AC_DEFUN([LN_CONFIG_OPENIB],[
 594 AC_MSG_CHECKING([whether to enable OpenIB support])
 595 # set default
 596 OPENIBPATH="$LINUX/drivers/infiniband"
 597 AC_ARG_WITH([openib],
 598         AC_HELP_STRING([--with-openib=path],
 599                        [build openiblnd against path]),
 600         [
 601                 case $with_openib in
 602                 yes)    ENABLEOPENIB=2
 603                         ;;
 604                 no)     ENABLEOPENIB=0
 605                         ;;
 606                 *)      OPENIBPATH="$with_openib"
 607                         ENABLEOPENIB=3
 608                         ;;
 609                 esac
 610         ],[
 611                 ENABLEOPENIB=1
 612         ])
 613 if test $ENABLEOPENIB -eq 0; then
 614         AC_MSG_RESULT([disabled])
 615 elif test ! \( -f ${OPENIBPATH}/include/ts_ib_core.h -a \
 616                -f ${OPENIBPATH}/include/ts_ib_cm.h -a \
 617                -f ${OPENIBPATH}/include/ts_ib_sa_client.h \); then
 618         AC_MSG_RESULT([no])
 619         case $ENABLEOPENIB in
 620         1) ;;
 621         2) AC_MSG_ERROR([kernel OpenIB headers not present]);;
 622         3) AC_MSG_ERROR([bad --with-openib path]);;
 623         *) AC_MSG_ERROR([internal error]);;
 624         esac
 625 else
 626         case $ENABLEOPENIB in
 627         1|2) OPENIBCPPFLAGS="-I$OPENIBPATH/include -DIN_TREE_BUILD";;
 628         3)   OPENIBCPPFLAGS="-I$OPENIBPATH/include";;
 629         *)   AC_MSG_RESULT([no])
 630              AC_MSG_ERROR([internal error]);;
 631         esac
 632         OPENIBCPPFLAGS="$OPENIBCPPFLAGS -DIB_NTXRXPARAMS=4"
 633         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 634         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $OPENIBCPPFLAGS"
 635         LB_LINUX_TRY_COMPILE([
 636                 #include <ts_ib_core.h>
 637                 #include <ts_ib_cm.h>
 638                 #include <ts_ib_sa_client.h>
 639         ],[
 640                 struct ib_device_properties dev_props;
 641                 struct ib_cm_active_param   cm_active_params;
 642                 tTS_IB_CLIENT_QUERY_TID     tid;
 643                 int                         enum1 = IB_QP_ATTRIBUTE_STATE;
 644                 int                         enum2 = IB_ACCESS_LOCAL_WRITE;
 645                 int                         enum3 = IB_CQ_CALLBACK_INTERRUPT;
 646                 int                         enum4 = IB_CQ_PROVIDER_REARM;
 647                 return 0;
 648         ],[
 649                 AC_MSG_RESULT([yes])
 650                 OPENIBLND="openiblnd"
 651         ],[
 652                 AC_MSG_RESULT([no])
 653                 case $ENABLEOPENIB in
 654                 1) ;;
 655                 2) AC_MSG_ERROR([can't compile with kernel OpenIB headers]);;
 656                 3) AC_MSG_ERROR([can't compile with OpenIB headers under $OPENIBPATH]);;
 657                 *) AC_MSG_ERROR([internal error]);;
 658                 esac
 659                 OPENIBLND=""
 660                 OPENIBCPPFLAGS=""
 661         ])
 662         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 663 fi
 664 AC_SUBST(OPENIBCPPFLAGS)
 665 AC_SUBST(OPENIBLND)
 666 ])
 667
 668 #
 669 # LN_CONFIG_CIBLND
 670 #
 671 AC_DEFUN([LN_CONFIG_CIB],[
 672 AC_MSG_CHECKING([whether to enable Cisco/TopSpin IB support])
 673 # set default
 674 CIBPATH=""
 675 CIBLND=""
 676 AC_ARG_WITH([cib],
 677         AC_HELP_STRING([--with-cib=path],
 678                        [build ciblnd against path]),
 679         [
 680                 case $with_cib in
 681                 no)     AC_MSG_RESULT([no]);;
 682                 *)      CIBPATH="$with_cib"
 683                         if test -d "$CIBPATH"; then
 684                                 AC_MSG_RESULT([yes])
 685                         else
 686                                 AC_MSG_RESULT([no])
 687                                 AC_MSG_ERROR([No directory $CIBPATH])
 688                         fi;;
 689                 esac
 690         ],[
 691                 AC_MSG_RESULT([no])
 692         ])
 693 if test -n "$CIBPATH"; then
 694         CIBCPPFLAGS="-I${CIBPATH}/ib/ts_api_ng/include -I${CIBPATH}/all/kernel_services/include -DUSING_TSAPI"
 695         CIBCPPFLAGS="$CIBCPPFLAGS -DIB_NTXRXPARAMS=3"
 696         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 697         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $CIBCPPFLAGS"
 698         LB_LINUX_TRY_COMPILE([
 699                 #include <ts_ib_core.h>
 700                 #include <ts_ib_cm.h>
 701                 #include <ts_ib_sa_client.h>
 702         ],[
 703                 struct ib_device_properties dev_props;
 704                 struct ib_cm_active_param   cm_active_params;
 705                 tTS_IB_CLIENT_QUERY_TID     tid;
 706                 int                         enum1 = TS_IB_QP_ATTRIBUTE_STATE;
 707                 int                         enum2 = TS_IB_ACCESS_LOCAL_WRITE;
 708                 int                         enum3 = TS_IB_CQ_CALLBACK_INTERRUPT;
 709                 int                         enum4 = TS_IB_CQ_PROVIDER_REARM;
 710                 return 0;
 711         ],[
 712                 CIBLND="ciblnd"
 713         ],[
 714                 AC_MSG_ERROR([can't compile ciblnd with given path])
 715                 CIBCPPFLAGS=""
 716         ])
 717         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 718 fi
 719 AC_SUBST(CIBCPPFLAGS)
 720 AC_SUBST(CIBLND)
 721 ])
 722
 723 #
 724 # LN_CONFIG_IIB
 725 #
 726 # check for infinicon infiniband support
 727 #
 728 AC_DEFUN([LN_CONFIG_IIB],[
 729 AC_MSG_CHECKING([whether to enable Infinicon support])
 730 # set default
 731 IIBPATH="/usr/include"
 732 AC_ARG_WITH([iib],
 733         AC_HELP_STRING([--with-iib=path],
 734                        [build iiblnd against path]),
 735         [
 736                 case $with_iib in
 737                 yes)    ENABLEIIB=2
 738                         ;;
 739                 no)     ENABLEIIB=0
 740                         ;;
 741                 *)      IIBPATH="${with_iib}/include"
 742                         ENABLEIIB=3
 743                         ;;
 744                 esac
 745         ],[
 746                 ENABLEIIB=1
 747         ])
 748 if test $ENABLEIIB -eq 0; then
 749         AC_MSG_RESULT([disabled])
 750 elif test ! \( -f ${IIBPATH}/linux/iba/ibt.h \); then
 751         AC_MSG_RESULT([no])
 752         case $ENABLEIIB in
 753         1) ;;
 754         2) AC_MSG_ERROR([default Infinicon headers not present]);;
 755         3) AC_MSG_ERROR([bad --with-iib path]);;
 756         *) AC_MSG_ERROR([internal error]);;
 757         esac
 758 else
 759         IIBCPPFLAGS="-I$IIBPATH"
 760         if test $IIBPATH != "/usr/include"; then
 761                 # we need /usr/include come what may
 762                 IIBCPPFLAGS="$IIBCPPFLAGS -I/usr/include"
 763         fi
 764         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 765         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $IIBCPPFLAGS"
 766         LB_LINUX_TRY_COMPILE([
 767                 #include <linux/iba/ibt.h>
 768         ],[
 769                 IBT_INTERFACE_UNION interfaces;
 770                 FSTATUS             rc;
 771
 772                  rc = IbtGetInterfaceByVersion(IBT_INTERFACE_VERSION_2,
 773                                                &interfaces);
 774
 775                 return rc == FSUCCESS ? 0 : 1;
 776         ],[
 777                 AC_MSG_RESULT([yes])
 778                 IIBLND="iiblnd"
 779         ],[
 780                 AC_MSG_RESULT([no])
 781                 case $ENABLEIIB in
 782                 1) ;;
 783                 2) AC_MSG_ERROR([can't compile with default Infinicon headers]);;
 784                 3) AC_MSG_ERROR([can't compile with Infinicon headers under $IIBPATH]);;
 785                 *) AC_MSG_ERROR([internal error]);;
 786                 esac
 787                 IIBLND=""
 788                 IIBCPPFLAGS=""
 789         ])
 790         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 791 fi
 792 AC_SUBST(IIBCPPFLAGS)
 793 AC_SUBST(IIBLND)
 794 ])
 795
 796 #
 797 # LN_CONFIG_VIB
 798 #
 799 # check for Voltaire infiniband support
 800 #
 801 AC_DEFUN([LN_CONFIG_VIB],
 802 [AC_MSG_CHECKING([whether to enable Voltaire IB support])
 803 VIBPATH=""
 804 AC_ARG_WITH([vib],
 805         AC_HELP_STRING([--with-vib=path],
 806                        [build viblnd against path]),
 807         [
 808                 case $with_vib in
 809                 no)     AC_MSG_RESULT([no]);;
 810                 *)      VIBPATH="${with_vib}/src/nvigor/ib-code"
 811                         if test -d "$with_vib" -a -d "$VIBPATH"; then
 812                                 AC_MSG_RESULT([yes])
 813                         else
 814                                 AC_MSG_RESULT([no])
 815                                 AC_MSG_ERROR([No directory $VIBPATH])
 816                         fi;;
 817                 esac
 818         ],[
 819                 AC_MSG_RESULT([no])
 820         ])
 821 if test -z "$VIBPATH"; then
 822         VIBLND=""
 823 else
 824         VIBCPPFLAGS="-I${VIBPATH}/include -I${VIBPATH}/cm"
 825         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 826         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 827         LB_LINUX_TRY_COMPILE([
 828                 #include <linux/list.h>
 829                 #include <asm/byteorder.h>
 830                 #ifdef __BIG_ENDIAN
 831                 # define CPU_BE 1
 832                 # define CPU_LE 0
 833                 #endif
 834                 #ifdef __LITTLE_ENDIAN
 835                 # define CPU_BE 0
 836                 # define CPU_LE 1
 837                 #endif
 838                 #include <vverbs.h>
 839                 #include <ib-cm.h>
 840                 #include <ibat.h>
 841         ],[
 842                 vv_hca_h_t       kib_hca;
 843                 vv_return_t      vvrc;
 844                 cm_cep_handle_t  cep;
 845                 ibat_arp_data_t  arp_data;
 846                 ibat_stat_t      ibatrc;
 847
 848                 vvrc = vv_hca_open("ANY_HCA", NULL, &kib_hca);
 849                 cep = cm_create_cep(cm_cep_transp_rc);
 850                 ibatrc = ibat_get_ib_data((uint32_t)0, (uint32_t)0,
 851                                           ibat_paths_primary, &arp_data,
 852                                           (ibat_get_ib_data_reply_fn_t)NULL,
 853                                           NULL, 0);
 854                 return 0;
 855         ],[
 856                 VIBLND="viblnd"
 857         ],[
 858                 AC_MSG_ERROR([can't compile viblnd with given path])
 859         ])
 860         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 861 fi
 862 if test -n "$VIBLND"; then
 863         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 864         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 865         AC_MSG_CHECKING([if Voltaire still uses void * sg addresses])
 866         LB_LINUX_TRY_COMPILE([
 867                 #include <linux/list.h>
 868                 #include <asm/byteorder.h>
 869                 #ifdef __BIG_ENDIAN
 870                 # define CPU_BE 1
 871                 # define CPU_LE 0
 872                 #endif
 873                 #ifdef __LITTLE_ENDIAN
 874                 # define CPU_BE 0
 875                 # define CPU_LE 1
 876                 #endif
 877                 #include <vverbs.h>
 878                 #include <ib-cm.h>
 879                 #include <ibat.h>
 880         ],[
 881                 vv_scatgat_t  sg;
 882
 883                 return &sg.v_address[3] == NULL;
 884         ],[
 885                 AC_MSG_RESULT([yes])
 886                 VIBCPPFLAGS="$VIBCPPFLAGS -DIBNAL_VOIDSTAR_SGADDR=1"
 887         ],[
 888                 AC_MSG_RESULT([no])
 889         ])
 890         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 891 fi
 892 AC_SUBST(VIBCPPFLAGS)
 893 AC_SUBST(VIBLND)
 894 ])
 895
 896 #
 897 # LN_CONFIG_RALND
 898 #
 899 # check whether to use the RapidArray lnd
 900 #
 901 AC_DEFUN([LN_CONFIG_RALND],
 902 [#### Rapid Array
 903 AC_MSG_CHECKING([if RapidArray kernel headers are present])
 904 # placeholder
 905 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 906 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 907 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 908 LB_LINUX_TRY_COMPILE([
 909         #include <linux/types.h>
 910         #include <rapl.h>
 911 ],[
 912         RAP_RETURN          rc;
 913         RAP_PVOID           dev_handle;
 914
 915         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 916
 917         return rc == RAP_SUCCESS ? 0 : 1;
 918 ],[
 919         AC_MSG_RESULT([yes])
 920         RALND="ralnd"
 921 ],[
 922         AC_MSG_RESULT([no])
 923         RALND=""
 924         RACPPFLAGS=""
 925 ])
 926 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 927 AC_SUBST(RACPPFLAGS)
 928 AC_SUBST(RALND)
 929 ])
 930
 931
 932
 933 #
 934 # LN_PROG_LINUX
 935 #
 936 # LNet linux kernel checks
 937 #
 938 AC_DEFUN([LN_PROG_LINUX],
 939 [
 940 LN_CONFIG_AFFINITY
 941 LN_CONFIG_BACKOFF
 942 LN_CONFIG_QUADRICS
 943 LN_CONFIG_GM
 944 LN_CONFIG_OPENIB
 945 LN_CONFIG_CIB
 946 LN_CONFIG_VIB
 947 LN_CONFIG_IIB
 948 LN_CONFIG_O2IB
 949 LN_CONFIG_RALND
 950 LN_CONFIG_PTLLND
 951 LN_CONFIG_MX
 952 ])
 953
 954 #
 955 # LN_PROG_DARWIN
 956 #
 957 # Darwin checks
 958 #
 959 AC_DEFUN([LN_PROG_DARWIN],
 960 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 961 ])
 962
 963 #
 964 # LN_PATH_DEFAULTS
 965 #
 966 # default paths for installed files
 967 #
 968 AC_DEFUN([LN_PATH_DEFAULTS],
 969 [
 970 ])
 971
 972 #
 973 # LN_CONFIGURE
 974 #
 975 # other configure checks
 976 #
 977 AC_DEFUN([LN_CONFIGURE],
 978 [# lnet/utils/portals.c
 979 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
 980 AC_CHECK_FUNCS([gethostbyname socket connect])
 981
 982 # lnet/utils/debug.c
 983 AC_CHECK_HEADERS([linux/version.h])
 984
 985 AC_CHECK_TYPE([spinlock_t],
 986         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
 987         [],
 988         [#include <linux/spinlock.h>])
 989
 990 # lnet/utils/wirecheck.c
 991 AC_CHECK_FUNCS([strnlen])
 992
 993 # --------  Check for required packages  --------------
 994
 995 #
 996 # LC_CONFIG_READLINE
 997 #
 998 # Build with readline
 999 #
1000 AC_MSG_CHECKING([whether to enable readline support])
1001 AC_ARG_ENABLE(readline,
1002         AC_HELP_STRING([--disable-readline],
1003                         [disable readline support]),
1004         [],[enable_readline='yes'])
1005 AC_MSG_RESULT([$enable_readline])
1006
1007 # -------- check for readline if enabled ----
1008 if test x$enable_readline = xyes ; then
1009         LIBS_save="$LIBS"
1010         LIBS="-lncurses $LIBS"
1011         AC_CHECK_LIB([readline],[readline],[
1012         LIBREADLINE="-lreadline -lncurses"
1013         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
1014         ],[
1015         LIBREADLINE=""
1016         ])
1017         LIBS="$LIBS_save"
1018 else
1019         LIBREADLINE=""
1020 fi
1021 AC_SUBST(LIBREADLINE)
1022
1023 # -------- enable acceptor libwrap (TCP wrappers) support? -------
1024 AC_MSG_CHECKING([if libwrap support is requested])
1025 AC_ARG_ENABLE([libwrap],
1026         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
1027         [case "${enableval}" in
1028                 yes) enable_libwrap=yes ;;
1029                 no) enable_libwrap=no ;;
1030                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
1031         esac],[enable_libwrap=no])
1032 AC_MSG_RESULT([$enable_libwrap])
1033 if test x$enable_libwrap = xyes ; then
1034         LIBWRAP="-lwrap"
1035         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
1036 else
1037         LIBWRAP=""
1038 fi
1039 AC_SUBST(LIBWRAP)
1040
1041 # ----------------------------------------
1042 # some tests for catamount-like systems
1043 # ----------------------------------------
1044 AC_ARG_ENABLE([sysio_init],
1045         AC_HELP_STRING([--disable-sysio-init],
1046                 [call sysio init functions when initializing liblustre]),
1047         [],[enable_sysio_init=yes])
1048 AC_MSG_CHECKING([whether to initialize libsysio])
1049 AC_MSG_RESULT([$enable_sysio_init])
1050 if test x$enable_sysio_init != xno ; then
1051         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
1052 fi
1053
1054 AC_ARG_ENABLE([urandom],
1055         AC_HELP_STRING([--disable-urandom],
1056                 [disable use of /dev/urandom for liblustre]),
1057         [],[enable_urandom=yes])
1058 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
1059 AC_MSG_RESULT([$enable_urandom])
1060 if test x$enable_urandom != xno ; then
1061         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
1062 fi
1063
1064 # -------- check for -lcap support ----
1065 if test x$enable_liblustre = xyes ; then
1066         AC_CHECK_LIB([cap], [cap_get_proc],
1067                 [
1068                         CAP_LIBS="-lcap"
1069                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
1070                 ],
1071                 [
1072                         CAP_LIBS=""
1073                 ])
1074         AC_SUBST(CAP_LIBS)
1075
1076 fi
1077
1078 LN_CONFIG_MAX_PAYLOAD
1079 LN_CONFIG_UPTLLND
1080 LN_CONFIG_USOCKLND
1081 ])
1082
1083 #
1084 # LN_CONDITIONALS
1085 #
1086 # AM_CONDITOINAL defines for lnet
1087 #
1088 AC_DEFUN([LN_CONDITIONALS],
1089 [AM_CONDITIONAL(BUILD_QSWLND, test x$QSWLND = "xqswlnd")
1090 AM_CONDITIONAL(BUILD_GMLND, test x$GMLND = "xgmlnd")
1091 AM_CONDITIONAL(BUILD_MXLND, test x$MXLND = "xmxlnd")
1092 AM_CONDITIONAL(BUILD_O2IBLND, test x$O2IBLND = "xo2iblnd")
1093 AM_CONDITIONAL(BUILD_OPENIBLND, test x$OPENIBLND = "xopeniblnd")
1094 AM_CONDITIONAL(BUILD_CIBLND, test x$CIBLND = "xciblnd")
1095 AM_CONDITIONAL(BUILD_IIBLND, test x$IIBLND = "xiiblnd")
1096 AM_CONDITIONAL(BUILD_VIBLND, test x$VIBLND = "xviblnd")
1097 AM_CONDITIONAL(BUILD_RALND, test x$RALND = "xralnd")
1098 AM_CONDITIONAL(BUILD_PTLLND, test x$PTLLND = "xptllnd")
1099 AM_CONDITIONAL(BUILD_UPTLLND, test x$UPTLLND = "xptllnd")
1100 AM_CONDITIONAL(BUILD_USOCKLND, test x$USOCKLND = "xusocklnd")
1101 ])
1102
1103 #
1104 # LN_CONFIG_FILES
1105 #
1106 # files that should be generated with AC_OUTPUT
1107 #
1108 AC_DEFUN([LN_CONFIG_FILES],
1109 [AC_CONFIG_FILES([
1110 lnet/Kernelenv
1111 lnet/Makefile
1112 lnet/autoMakefile
1113 lnet/autoconf/Makefile
1114 lnet/doc/Makefile
1115 lnet/include/Makefile
1116 lnet/include/lnet/Makefile
1117 lnet/include/lnet/linux/Makefile
1118 lnet/klnds/Makefile
1119 lnet/klnds/autoMakefile
1120 lnet/klnds/gmlnd/Makefile
1121 lnet/klnds/mxlnd/autoMakefile
1122 lnet/klnds/mxlnd/Makefile
1123 lnet/klnds/gmlnd/autoMakefile
1124 lnet/klnds/openiblnd/Makefile
1125 lnet/klnds/openiblnd/autoMakefile
1126 lnet/klnds/o2iblnd/Makefile
1127 lnet/klnds/o2iblnd/autoMakefile
1128 lnet/klnds/ciblnd/Makefile
1129 lnet/klnds/ciblnd/autoMakefile
1130 lnet/klnds/iiblnd/Makefile
1131 lnet/klnds/iiblnd/autoMakefile
1132 lnet/klnds/viblnd/Makefile
1133 lnet/klnds/viblnd/autoMakefile
1134 lnet/klnds/qswlnd/Makefile
1135 lnet/klnds/qswlnd/autoMakefile
1136 lnet/klnds/ralnd/Makefile
1137 lnet/klnds/ralnd/autoMakefile
1138 lnet/klnds/socklnd/Makefile
1139 lnet/klnds/socklnd/autoMakefile
1140 lnet/klnds/ptllnd/Makefile
1141 lnet/klnds/ptllnd/autoMakefile
1142 lnet/lnet/Makefile
1143 lnet/lnet/autoMakefile
1144 lnet/selftest/Makefile
1145 lnet/selftest/autoMakefile
1146 lnet/ulnds/Makefile
1147 lnet/ulnds/autoMakefile
1148 lnet/ulnds/socklnd/Makefile
1149 lnet/ulnds/ptllnd/Makefile
1150 lnet/utils/Makefile
1151 ])
1152 case $lb_target_os in
1153         darwin)
1154                 AC_CONFIG_FILES([
1155 lnet/include/lnet/darwin/Makefile
1156 ])
1157                 ;;
1158 esac
1159 ])