lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD],
   7 [AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                        [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19         AC_DEFINE_UNQUOTED(LNET_MAX_PAYLOAD, $LNET_MAX_PAYLOAD,
  20                            [Max LNET payload])
  21 ])
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION],
  29 [AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ])
  43
  44 #
  45 # LN_FUNC_DEV_GET_BY_NAME_2ARG
  46 #
  47 AC_DEFUN([LN_FUNC_DEV_GET_BY_NAME_2ARG],
  48 [AC_MSG_CHECKING([if dev_get_by_name has two args])
  49 LB_LINUX_TRY_COMPILE([
  50         #include <linux/netdevice.h>
  51 ],[
  52         dev_get_by_name(NULL, NULL);
  53 ],[
  54         AC_MSG_RESULT([yes])
  55         AC_DEFINE(HAVE_DEV_GET_BY_NAME_2ARG, 1, [dev_get_by_name has 2 args])
  56 ],[
  57         AC_MSG_RESULT([no])
  58 ])
  59 ])
  60
  61 #
  62 # LN_CONFIG_AFFINITY
  63 #
  64 # check if cpu affinity is available/wanted
  65 #
  66 AC_DEFUN([LN_CONFIG_AFFINITY],
  67 [AC_ARG_ENABLE([affinity],
  68         AC_HELP_STRING([--disable-affinity],
  69                        [disable process/irq affinity]),
  70         [],[enable_affinity='yes'])
  71
  72 AC_MSG_CHECKING([for CPU affinity support])
  73 if test x$enable_affinity = xno ; then
  74         AC_MSG_RESULT([no (by request)])
  75 else
  76         LB_LINUX_TRY_COMPILE([
  77                 #include <linux/sched.h>
  78         ],[
  79                 struct task_struct t;
  80                 #if HAVE_CPUMASK_T
  81                 cpumask_t     m;
  82                 #else
  83                 unsigned long m;
  84                 #endif
  85                 set_cpus_allowed(&t, m);
  86         ],[
  87                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
  88                 AC_MSG_RESULT([yes])
  89         ],[
  90                 AC_MSG_RESULT([no (no kernel support)])
  91         ])
  92 fi
  93 ])
  94
  95 #
  96 # LN_CONFIG_PORTALS
  97 #
  98 # configure support for Portals
  99 #
 100 AC_DEFUN([LN_CONFIG_PORTALS],
 101 [AC_MSG_CHECKING([for portals])
 102 AC_ARG_WITH([portals],
 103         AC_HELP_STRING([--with-portals=path],
 104                        [set path to portals]),
 105         [
 106                 case $with_portals in
 107                         no)     ENABLEPORTALS=0
 108                                 ;;
 109                         *)      PORTALS="${with_portals}"
 110                                 ENABLEPORTALS=1
 111                                 ;;
 112                 esac
 113         ], [
 114                 ENABLEPORTALS=0
 115         ])
 116 PTLLNDCPPFLAGS=""
 117 if test $ENABLEPORTALS -eq 0; then
 118         AC_MSG_RESULT([no])
 119 elif test ! \( -f ${PORTALS}/include/portals/p30.h \); then
 120         AC_MSG_RESULT([no])
 121         AC_MSG_ERROR([bad --with-portals path])
 122 else
 123         AC_MSG_RESULT([$PORTALS])
 124         PTLLNDCPPFLAGS="-I${PORTALS}/include"
 125 fi
 126 AC_SUBST(PTLLNDCPPFLAGS)
 127 ])
 128
 129 #
 130 # LN_CONFIG_BACKOFF
 131 #
 132 # check if tunable tcp backoff is available/wanted
 133 #
 134 AC_DEFUN([LN_CONFIG_BACKOFF],
 135 [AC_MSG_CHECKING([for tunable backoff TCP support])
 136 AC_ARG_ENABLE([backoff],
 137        AC_HELP_STRING([--disable-backoff],
 138                       [disable socknal tunable backoff]),
 139        [],[enable_backoff='yes'])
 140 if test x$enable_backoff = xno ; then
 141        AC_MSG_RESULT([no (by request)])
 142 else
 143        BOCD="`grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h`"
 144        if test "$BOCD" != 0 ; then
 145                AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
 146                AC_MSG_RESULT(yes)
 147                if grep rto_max $LINUX/include/linux/tcp.h|grep -q __u16; then
 148                    AC_DEFINE(SOCKNAL_BACKOFF_MS, 1, [tunable backoff TCP in ms])
 149                fi
 150        else
 151                AC_MSG_RESULT([no (no kernel support)])
 152        fi
 153 fi
 154 ])
 155
 156
 157 #
 158 # LN_CONFIG_PTLLND
 159 #
 160 # configure support for Portals LND
 161 #
 162 AC_DEFUN([LN_CONFIG_PTLLND],
 163 [
 164 if test -z "$ENABLEPORTALS"; then
 165         LN_CONFIG_PORTALS
 166 fi
 167
 168 AC_MSG_CHECKING([whether to build the kernel portals LND])
 169
 170 PTLLND=""
 171 if test $ENABLEPORTALS -ne 0; then
 172         AC_MSG_RESULT([yes])
 173         PTLLND="ptllnd"
 174 else
 175         AC_MSG_RESULT([no])
 176 fi
 177 AC_SUBST(PTLLND)
 178 ])
 179
 180 #
 181 # LN_CONFIG_UPTLLND
 182 #
 183 # configure support for Portals LND
 184 #
 185 AC_DEFUN([LN_CONFIG_UPTLLND],
 186 [
 187 if test -z "$ENABLEPORTALS"; then
 188         LN_CONFIG_PORTALS
 189 fi
 190
 191 AC_MSG_CHECKING([whether to build the userspace portals LND])
 192
 193 UPTLLND=""
 194 if test $ENABLEPORTALS -ne 0; then
 195         AC_MSG_RESULT([yes])
 196         UPTLLND="ptllnd"
 197 else
 198         AC_MSG_RESULT([no])
 199 fi
 200 AC_SUBST(UPTLLND)
 201 ])
 202
 203 #
 204 # LN_CONFIG_USOCKLND
 205 #
 206 # configure support for userspace TCP/IP LND
 207 #
 208 AC_DEFUN([LN_CONFIG_USOCKLND],
 209 [AC_MSG_CHECKING([whether to build usocklnd])
 210 AC_ARG_ENABLE([usocklnd],
 211         AC_HELP_STRING([--disable-usocklnd],
 212                         [disable usocklnd]),
 213         [],[enable_usocklnd='yes'])
 214
 215 if test x$enable_usocklnd = xyes ; then
 216         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 217                 AC_MSG_RESULT([yes])
 218                 USOCKLND="usocklnd"
 219         else
 220                 AC_MSG_RESULT([no (libpthread not present or disabled)])
 221                 USOCKLND=""
 222         fi
 223 else
 224         AC_MSG_RESULT([no (disabled explicitly)])
 225         USOCKLND=""
 226 fi
 227 AC_SUBST(USOCKLND)
 228 ])
 229
 230 #
 231 # LN_CONFIG_QUADRICS
 232 #
 233 # check if quadrics support is in this kernel
 234 #
 235 AC_DEFUN([LN_CONFIG_QUADRICS],
 236 [AC_MSG_CHECKING([for QsNet sources])
 237 AC_ARG_WITH([qsnet],
 238         AC_HELP_STRING([--with-qsnet=path],
 239                        [set path to qsnet source (default=$LINUX)]),
 240         [QSNET=$with_qsnet],
 241         [QSNET=$LINUX])
 242 AC_MSG_RESULT([$QSNET])
 243
 244 AC_MSG_CHECKING([if quadrics kernel headers are present])
 245 if test -d $QSNET/drivers/net/qsnet ; then
 246         AC_MSG_RESULT([yes])
 247         QSWLND="qswlnd"
 248         AC_MSG_CHECKING([for multirail EKC])
 249         if test -f $QSNET/include/elan/epcomms.h; then
 250                 AC_MSG_RESULT([supported])
 251                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 252         else
 253                 AC_MSG_RESULT([not supported])
 254                 AC_MSG_ERROR([Need multirail EKC])
 255         fi
 256
 257         if test x$QSNET = x$LINUX ; then
 258                 LB_LINUX_CONFIG([QSNET],[],[
 259                         LB_LINUX_CONFIG([QSNET_MODULE],[],[
 260                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
 261                                 QSWLND=""
 262                                 QSWCPPFLAGS=""
 263                         ])
 264                 ])
 265         fi
 266 else
 267         AC_MSG_RESULT([no])
 268         QSWLND=""
 269         QSWCPPFLAGS=""
 270 fi
 271 AC_SUBST(QSWCPPFLAGS)
 272 AC_SUBST(QSWLND)
 273 ])
 274
 275
 276 #
 277 # LN_CONFIG_MX
 278 #
 279 AC_DEFUN([LN_CONFIG_MX],
 280 [AC_MSG_CHECKING([whether to enable Myrinet MX support])
 281 # set default
 282 MXPATH="/opt/mx"
 283 AC_ARG_WITH([mx],
 284        AC_HELP_STRING([--with-mx=path],
 285                       [build mxlnd against path]),
 286        [
 287                case $with_mx in
 288                yes)    ENABLEMX=2
 289                        ;;
 290                no)     ENABLEMX=0
 291                        ;;
 292                *)      MXPATH=$with_mx
 293                        ENABLEMX=3
 294                        ;;
 295                esac
 296        ],[
 297                ENABLEMX=1
 298        ])
 299 if test $ENABLEMX -eq 0; then
 300        AC_MSG_RESULT([disabled])
 301 elif test ! \( -f ${MXPATH}/include/myriexpress.h -a \
 302               -f ${MXPATH}/include/mx_kernel_api.h -a \
 303               -f ${MXPATH}/include/mx_pin.h \); then
 304        AC_MSG_RESULT([no])
 305        case $ENABLEMX in
 306        1) ;;
 307        2) AC_MSG_ERROR([Myrinet MX kernel headers not present]);;
 308        3) AC_MSG_ERROR([bad --with-mx path]);;
 309        *) AC_MSG_ERROR([internal error]);;
 310        esac
 311 else
 312        MXCPPFLAGS="-I$MXPATH/include"
 313        EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 314        EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
 315        MXLIBS="-L$MXPATH/lib"
 316        LB_LINUX_TRY_COMPILE([
 317                #define MX_KERNEL 1
 318                #include <mx_extensions.h>
 319                #include <myriexpress.h>
 320        ],[
 321                mx_endpoint_t   end;
 322                mx_status_t     status;
 323                mx_request_t    request;
 324                int             result;
 325
 326                mx_init();
 327                mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
 328                mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
 329                mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
 330                mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
 331                return 0;
 332        ],[
 333                AC_MSG_RESULT([yes])
 334                MXLND="mxlnd"
 335        ],[
 336                AC_MSG_RESULT([no])
 337                case $ENABLEMX in
 338                1) ;;
 339                2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]);;
 340                3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]);;
 341                *) AC_MSG_ERROR([internal error]);;
 342                esac
 343                MXLND=""
 344                MXCPPFLAGS=""
 345        ])
 346        EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 347 fi
 348 AC_SUBST(MXCPPFLAGS)
 349 AC_SUBST(MXLIBS)
 350 AC_SUBST(MXLND)
 351 ])
 352
 353
 354
 355 #
 356 # LN_CONFIG_O2IB
 357 #
 358 AC_DEFUN([LN_CONFIG_O2IB],[
 359
 360 # In RHEL 6.2, rdma_create_id() takes the queue-pair type as a fourth argument
 361 AC_MSG_CHECKING([if rdma_create_id wants four args])
 362 LB_LINUX_TRY_COMPILE([
 363         #include <rdma/rdma_cm.h>
 364 ],[
 365         rdma_create_id(NULL, NULL, 0, 0);
 366 ],[
 367         AC_MSG_RESULT([yes])
 368         AC_DEFINE(HAVE_RDMA_CREATE_ID_4ARG, 1, [rdma_create_id wants 4 args])
 369 ],[
 370         AC_MSG_RESULT([no])
 371 ])
 372
 373 AC_MSG_CHECKING([whether to enable OpenIB gen2 support])
 374 # set default
 375 AC_ARG_WITH([o2ib],
 376         AC_HELP_STRING([--with-o2ib=path],
 377                        [build o2iblnd against path]),
 378         [
 379                 case $with_o2ib in
 380                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 381                         ENABLEO2IB=2
 382                         ;;
 383                 no)     ENABLEO2IB=0
 384                         ;;
 385                 *)      O2IBPATHS=$with_o2ib
 386                         ENABLEO2IB=3
 387                         ;;
 388                 esac
 389         ],[
 390                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 391                 ENABLEO2IB=1
 392         ])
 393 if test $ENABLEO2IB -eq 0; then
 394         AC_MSG_RESULT([disabled])
 395 else
 396         o2ib_found=false
 397         for O2IBPATH in $O2IBPATHS; do
 398                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 399                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 400                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 401                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 402                         if test \( -d ${O2IBPATH}/kernel_patches -a \
 403                                    -f ${O2IBPATH}/Makefile \); then
 404                                 AC_MSG_RESULT([no])
 405                                 AC_MSG_ERROR([you appear to be trying to use the OFED distribution's source directory (${O2IBPATH}) rather than the "development/headers" directory which is likely in ${O2IBPATH%-*}])
 406                         fi
 407                         o2ib_found=true
 408                         break
 409                 fi
 410         done
 411         if ! $o2ib_found; then
 412                 AC_MSG_RESULT([no])
 413                 case $ENABLEO2IB in
 414                         1) ;;
 415                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 416                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 417                         *) AC_MSG_ERROR([internal error]);;
 418                 esac
 419         else
 420                 O2IBCPPFLAGS="-I$O2IBPATH/include"
 421                 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 422                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $O2IBCPPFLAGS"
 423                 EXTRA_LNET_INCLUDE="$EXTRA_LNET_INCLUDE $O2IBCPPFLAGS"
 424
 425                 LB_LINUX_TRY_COMPILE([
 426                         #include <linux/version.h>
 427                         #include <linux/pci.h>
 428                         #if !HAVE_GFP_T
 429                         typedef int gfp_t;
 430                         #endif
 431                         #include <rdma/rdma_cm.h>
 432                         #include <rdma/ib_cm.h>
 433                         #include <rdma/ib_verbs.h>
 434                         #include <rdma/ib_fmr_pool.h>
 435                 ],[
 436                         struct rdma_cm_id          *cm_id;
 437                         struct rdma_conn_param      conn_param;
 438                         struct ib_device_attr       device_attr;
 439                         struct ib_qp_attr           qp_attr;
 440                         struct ib_pool_fmr          pool_fmr;
 441                         enum   ib_cm_rej_reason     rej_reason;
 442
 443                         #ifdef HAVE_RDMA_CREATE_ID_4ARG
 444                         cm_id = rdma_create_id(NULL, NULL, RDMA_PS_TCP, 0);
 445                         #else
 446                         cm_id = rdma_create_id(NULL, NULL, RDMA_PS_TCP);
 447                         #endif
 448                         return PTR_ERR(cm_id);
 449                 ],[
 450                         AC_MSG_RESULT([yes])
 451                         O2IBLND="o2iblnd"
 452                 ],[
 453                         AC_MSG_RESULT([no])
 454                         case $ENABLEO2IB in
 455                         1) ;;
 456                         2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]);;
 457                         3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]);;
 458                         *) AC_MSG_ERROR([internal error]);;
 459                         esac
 460                         O2IBLND=""
 461                         O2IBCPPFLAGS=""
 462                 ])
 463                 # we know at this point that the found OFED source is good
 464                 O2IB_SYMVER=""
 465                 if test $ENABLEO2IB -eq 3 ; then
 466                         # OFED default rpm not handle sles10 Modules.symvers name
 467                         for name in Module.symvers Modules.symvers; do
 468                                 if test -f $O2IBPATH/$name; then
 469                                         O2IB_SYMVER=$name;
 470                                         break;
 471                                 fi
 472                         done
 473                         if test -n "$O2IB_SYMVER"; then
 474                                 AC_MSG_NOTICE([adding $O2IBPATH/$O2IB_SYMVER to $PWD/$SYMVERFILE])
 475                                 # strip out the existing symbols versions first
 476                                 if test -f $PWD/$SYMVERFILE; then
 477                                 egrep -v $(echo $(awk '{ print $2 }' $O2IBPATH/$O2IB_SYMVER) | tr ' ' '|') $PWD/$SYMVERFILE > $PWD/$SYMVERFILE.old
 478                                 else
 479                                     touch $PWD/$SYMVERFILE.old
 480                                 fi
 481                                 cat $PWD/$SYMVERFILE.old $O2IBPATH/$O2IB_SYMVER > $PWD/$SYMVERFILE
 482                                 rm $PWD/$SYMVERFILE.old
 483                         else
 484                                 AC_MSG_ERROR([an external source tree was specified for o2iblnd however I could not find a $O2IBPATH/Module.symvers there])
 485                         fi
 486                 fi
 487
 488                 LN_CONFIG_OFED_SPEC
 489                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 490         fi
 491 fi
 492
 493 AC_SUBST(EXTRA_LNET_INCLUDE)
 494 AC_SUBST(O2IBCPPFLAGS)
 495 AC_SUBST(O2IBLND)
 496 ])
 497
 498 #
 499 # LN_CONFIG_RALND
 500 #
 501 # check whether to use the RapidArray lnd
 502 #
 503 AC_DEFUN([LN_CONFIG_RALND],
 504 [#### Rapid Array
 505 AC_MSG_CHECKING([if RapidArray kernel headers are present])
 506 # placeholder
 507 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 508 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 509 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 510 LB_LINUX_TRY_COMPILE([
 511         #include <linux/types.h>
 512         #include <rapl.h>
 513 ],[
 514         RAP_RETURN          rc;
 515         RAP_PVOID           dev_handle;
 516
 517         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 518
 519         return rc == RAP_SUCCESS ? 0 : 1;
 520 ],[
 521         AC_MSG_RESULT([yes])
 522         RALND="ralnd"
 523 ],[
 524         AC_MSG_RESULT([no])
 525         RALND=""
 526         RACPPFLAGS=""
 527 ])
 528 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 529 AC_SUBST(RACPPFLAGS)
 530 AC_SUBST(RALND)
 531 ])
 532
 533
 534
 535 #
 536 #
 537 # LN_CONFIG_USERSPACE
 538 #
 539 # This is defined but empty because it is called from
 540 # build/autconf/lustre-build.m4 which is shared by all branches.
 541 #
 542 AC_DEFUN([LN_CONFIG_USERSPACE],
 543 [
 544 ])
 545
 546 # See if sysctl proc_handler wants only 5 arguments (since 2.6.32)
 547 AC_DEFUN([LN_5ARGS_SYSCTL_PROC_HANDLER],
 548 [AC_MSG_CHECKING([if sysctl proc_handler wants 5 args])
 549 LB_LINUX_TRY_COMPILE([
 550         #include <linux/sysctl.h>
 551 ],[
 552         struct ctl_table *table = NULL;
 553         int write = 1;
 554         void __user *buffer = NULL;
 555         size_t *lenp = NULL;
 556         loff_t *ppos = NULL;
 557
 558         proc_handler *proc_handler;
 559         proc_handler(table, write, buffer, lenp, ppos);
 560
 561 ],[
 562         AC_MSG_RESULT(yes)
 563         AC_DEFINE(HAVE_5ARGS_SYSCTL_PROC_HANDLER, 1,
 564                   [sysctl proc_handler wants 5 args])
 565 ],[
 566         AC_MSG_RESULT(no)
 567 ])
 568 ])
 569
 570 #
 571 # 2.6.36 tcp_sendpage() first parameter is 'struct sock' instead of 'struct socket'.
 572 #
 573 AC_DEFUN([LN_CONFIG_TCP_SENDPAGE],
 574 [AC_MSG_CHECKING([if tcp_sendpage first parameter is socket])
 575 tmp_flags="$EXTRA_KCFLAGS"
 576 EXTRA_KCFLAGS="-Werror"
 577 LB_LINUX_TRY_COMPILE([
 578         #include <linux/net.h>
 579         #include <net/tcp.h>
 580 ],[
 581         tcp_sendpage((struct socket*)0, NULL, 0, 0, 0);
 582 ],[
 583         AC_MSG_RESULT(yes)
 584         AC_DEFINE(HAVE_TCP_SENDPAGE_USE_SOCKET, 1,
 585                   [tcp_sendpage use socket as first parameter])
 586 ],[
 587         AC_MSG_RESULT(no)
 588 ])
 589 EXTRA_KCFLAGS="$tmp_flags"
 590 ])
 591
 592 #
 593 # LN_PROG_LINUX
 594 #
 595 # LNet linux kernel checks
 596 #
 597 AC_DEFUN([LN_PROG_LINUX],
 598 [
 599 LN_FUNC_DEV_GET_BY_NAME_2ARG
 600 LN_CONFIG_AFFINITY
 601 LN_CONFIG_BACKOFF
 602 LN_CONFIG_QUADRICS
 603 LN_CONFIG_O2IB
 604 LN_CONFIG_RALND
 605 LN_CONFIG_PTLLND
 606 LN_CONFIG_MX
 607 # 2.6.32
 608 LN_5ARGS_SYSCTL_PROC_HANDLER
 609 # 2.6.36
 610 LN_CONFIG_TCP_SENDPAGE
 611 ])
 612
 613 #
 614 # LN_PROG_DARWIN
 615 #
 616 # Darwin checks
 617 #
 618 AC_DEFUN([LN_PROG_DARWIN],
 619 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 620 ])
 621
 622 #
 623 # LN_PATH_DEFAULTS
 624 #
 625 # default paths for installed files
 626 #
 627 AC_DEFUN([LN_PATH_DEFAULTS],
 628 [
 629 ])
 630
 631 #
 632 # LN_CONFIGURE
 633 #
 634 # other configure checks
 635 #
 636 AC_DEFUN([LN_CONFIGURE],
 637 [# lnet/utils/portals.c
 638 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
 639 AC_CHECK_FUNCS([gethostbyname socket connect])
 640
 641 # lnet/utils/debug.c
 642 AC_CHECK_HEADERS([linux/version.h])
 643
 644 AC_CHECK_TYPE([spinlock_t],
 645         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
 646         [],
 647         [#include <linux/spinlock.h>])
 648
 649 # lnet/utils/wirecheck.c
 650 AC_CHECK_FUNCS([strnlen])
 651
 652 # --------  Check for required packages  --------------
 653
 654 #
 655 # LC_CONFIG_READLINE
 656 #
 657 # Build with readline
 658 #
 659 AC_MSG_CHECKING([whether to enable readline support])
 660 AC_ARG_ENABLE(readline,
 661         AC_HELP_STRING([--disable-readline],
 662                         [disable readline support]),
 663         [],[enable_readline='yes'])
 664 AC_MSG_RESULT([$enable_readline])
 665
 666 # -------- check for readline if enabled ----
 667 if test x$enable_readline = xyes ; then
 668         LIBS_save="$LIBS"
 669         LIBS="-lncurses $LIBS"
 670         AC_CHECK_LIB([readline],[readline],[
 671         LIBREADLINE="-lreadline -lncurses"
 672         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
 673         ],[
 674         LIBREADLINE=""
 675         ])
 676         LIBS="$LIBS_save"
 677 else
 678         LIBREADLINE=""
 679 fi
 680 AC_SUBST(LIBREADLINE)
 681
 682 # -------- enable acceptor libwrap (TCP wrappers) support? -------
 683 AC_MSG_CHECKING([if libwrap support is requested])
 684 AC_ARG_ENABLE([libwrap],
 685         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
 686         [case "${enableval}" in
 687                 yes) enable_libwrap=yes ;;
 688                 no) enable_libwrap=no ;;
 689                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
 690         esac],[enable_libwrap=no])
 691 AC_MSG_RESULT([$enable_libwrap])
 692 if test x$enable_libwrap = xyes ; then
 693         LIBWRAP="-lwrap"
 694         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
 695 else
 696         LIBWRAP=""
 697 fi
 698 AC_SUBST(LIBWRAP)
 699
 700 # ----------------------------------------
 701 # some tests for catamount-like systems
 702 # ----------------------------------------
 703 AC_ARG_ENABLE([sysio_init],
 704         AC_HELP_STRING([--disable-sysio-init],
 705                 [call sysio init functions when initializing liblustre]),
 706         [],[enable_sysio_init=yes])
 707 AC_MSG_CHECKING([whether to initialize libsysio])
 708 AC_MSG_RESULT([$enable_sysio_init])
 709 if test x$enable_sysio_init != xno ; then
 710         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
 711 fi
 712
 713 AC_ARG_ENABLE([urandom],
 714         AC_HELP_STRING([--disable-urandom],
 715                 [disable use of /dev/urandom for liblustre]),
 716         [],[enable_urandom=yes])
 717 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
 718 AC_MSG_RESULT([$enable_urandom])
 719 if test x$enable_urandom != xno ; then
 720         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
 721 fi
 722
 723 # -------- check for -lcap support ----
 724 if test x$enable_liblustre = xyes ; then
 725         AC_CHECK_LIB([cap], [cap_get_proc],
 726                 [
 727                         CAP_LIBS="-lcap"
 728                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
 729                 ],
 730                 [
 731                         CAP_LIBS=""
 732                 ])
 733         AC_SUBST(CAP_LIBS)
 734
 735 fi
 736
 737 LN_CONFIG_MAX_PAYLOAD
 738 LN_CONFIG_UPTLLND
 739 LN_CONFIG_USOCKLND
 740 ])
 741
 742 #
 743 # LN_CONDITIONALS
 744 #
 745 # AM_CONDITOINAL defines for lnet
 746 #
 747 AC_DEFUN([LN_CONDITIONALS],
 748 [AM_CONDITIONAL(BUILD_QSWLND, test x$QSWLND = "xqswlnd")
 749 AM_CONDITIONAL(BUILD_MXLND, test x$MXLND = "xmxlnd")
 750 AM_CONDITIONAL(BUILD_O2IBLND, test x$O2IBLND = "xo2iblnd")
 751 AM_CONDITIONAL(BUILD_RALND, test x$RALND = "xralnd")
 752 AM_CONDITIONAL(BUILD_PTLLND, test x$PTLLND = "xptllnd")
 753 AM_CONDITIONAL(BUILD_UPTLLND, test x$UPTLLND = "xptllnd")
 754 AM_CONDITIONAL(BUILD_USOCKLND, test x$USOCKLND = "xusocklnd")
 755 ])
 756
 757 #
 758 # LN_CONFIG_FILES
 759 #
 760 # files that should be generated with AC_OUTPUT
 761 #
 762 AC_DEFUN([LN_CONFIG_FILES],
 763 [AC_CONFIG_FILES([
 764 lnet/Kernelenv
 765 lnet/Makefile
 766 lnet/autoMakefile
 767 lnet/autoconf/Makefile
 768 lnet/doc/Makefile
 769 lnet/include/Makefile
 770 lnet/include/lnet/Makefile
 771 lnet/include/lnet/linux/Makefile
 772 lnet/klnds/Makefile
 773 lnet/klnds/autoMakefile
 774 lnet/klnds/mxlnd/autoMakefile
 775 lnet/klnds/mxlnd/Makefile
 776 lnet/klnds/o2iblnd/Makefile
 777 lnet/klnds/o2iblnd/autoMakefile
 778 lnet/klnds/qswlnd/Makefile
 779 lnet/klnds/qswlnd/autoMakefile
 780 lnet/klnds/ralnd/Makefile
 781 lnet/klnds/ralnd/autoMakefile
 782 lnet/klnds/socklnd/Makefile
 783 lnet/klnds/socklnd/autoMakefile
 784 lnet/klnds/ptllnd/Makefile
 785 lnet/klnds/ptllnd/autoMakefile
 786 lnet/lnet/Makefile
 787 lnet/lnet/autoMakefile
 788 lnet/selftest/Makefile
 789 lnet/selftest/autoMakefile
 790 lnet/ulnds/Makefile
 791 lnet/ulnds/autoMakefile
 792 lnet/ulnds/socklnd/Makefile
 793 lnet/ulnds/ptllnd/Makefile
 794 lnet/utils/Makefile
 795 lnet/include/lnet/darwin/Makefile
 796 ])
 797 ])