libcfs/autoconf/lustre-libcfs.m4

   1 #
   2 # LN_CONFIG_CDEBUG
   3 #
   4 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
   5 #
   6 AC_DEFUN([LN_CONFIG_CDEBUG], [
   7 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
   8 AC_ARG_ENABLE([libcfs_cdebug],
   9         AC_HELP_STRING([--disable-libcfs-cdebug],
  10                 [disable libcfs CDEBUG, CWARN]),
  11         [], [enable_libcfs_cdebug="yes"])
  12 AC_MSG_RESULT([$enable_libcfs_cdebug])
  13 AS_IF([test "x$enable_libcfs_cdebug" = xyes],
  14         [AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])])
  15
  16 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
  17 AC_ARG_ENABLE([libcfs_trace],
  18         AC_HELP_STRING([--disable-libcfs-trace],
  19                 [disable libcfs ENTRY/EXIT]),
  20         [], [enable_libcfs_trace="yes"])
  21 AC_MSG_RESULT([$enable_libcfs_trace])
  22 AS_IF([test "x$enable_libcfs_trace" = xyes],
  23         [AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])])
  24
  25 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
  26 AC_ARG_ENABLE([libcfs_assert],
  27         AC_HELP_STRING([--disable-libcfs-assert],
  28                 [disable libcfs LASSERT, LASSERTF]),
  29         [], [enable_libcfs_assert="yes"])
  30 AC_MSG_RESULT([$enable_libcfs_assert])
  31 AS_IF([test x$enable_libcfs_assert = xyes],
  32         [AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])])
  33 ]) # LN_CONFIG_CDEBUG
  34
  35 #
  36 # LIBCFS_CONFIG_PANIC_DUMPLOG
  37 #
  38 # check if tunable panic_dumplog is wanted
  39 #
  40 AC_DEFUN([LIBCFS_CONFIG_PANIC_DUMPLOG], [
  41 AC_MSG_CHECKING([whether to use tunable 'panic_dumplog' support])
  42 AC_ARG_ENABLE([panic_dumplog],
  43         AC_HELP_STRING([--enable-panic_dumplog],
  44                 [enable panic_dumplog]),
  45         [], [enable_panic_dumplog="no"])
  46 AC_MSG_RESULT([$enable_panic_dumplog])
  47 AS_IF([test "x$enable_panic_dumplog" = xyes],
  48         [AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])])
  49 ]) # LIBCFS_CONFIG_PANIC_DUMPLOG
  50
  51 #
  52 # LIBCFS_U64_LONG_LONG_LINUX
  53 #
  54 # check kernel __u64 type
  55 #
  56 AC_DEFUN([LIBCFS_U64_LONG_LONG_LINUX], [
  57 tmp_flags="$EXTRA_KCFLAGS"
  58 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -Werror"
  59 LB_CHECK_COMPILE([if Linux kernel '__u64' is 'long long' type],
  60 kernel_u64_long_long, [
  61         #include <linux/types.h>
  62         #include <linux/stddef.h>
  63 ],[
  64         unsigned long long *data;
  65         data = (__u64*)sizeof(data);
  66 ],[
  67         AC_DEFINE(HAVE_KERN__U64_LONG_LONG, 1,
  68                 [Linux kernel __u64 is long long type])
  69 ])
  70 EXTRA_KCFLAGS="$tmp_flags"
  71 ]) # LIBCFS_U64_LONG_LONG_LINUX
  72
  73 #
  74 # LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK
  75 #
  76 # 2.6.32-30.el6 adds a new 'walk_stack' field in 'struct stacktrace_ops'
  77 #
  78 AC_DEFUN([LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK], [
  79 LB_CHECK_COMPILE([if 'struct stacktrace_ops' has 'walk_stack' field],
  80 stacktrace_ops_walk_stack, [
  81         #include <asm/stacktrace.h>
  82 ],[
  83         ((struct stacktrace_ops *)0)->walk_stack(NULL, NULL, 0, NULL, NULL, NULL, NULL);
  84 ],[
  85         AC_DEFINE(STACKTRACE_OPS_HAVE_WALK_STACK, 1,
  86                 ['struct stacktrace_ops' has 'walk_stack' field])
  87 ])
  88 ]) # LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK
  89
  90 #
  91 # LIBCFS_STACKTRACE_WARNING
  92 #
  93 # 3.0 removes stacktrace_ops warning* functions
  94 #
  95 AC_DEFUN([LIBCFS_STACKTRACE_WARNING], [
  96 LB_CHECK_COMPILE([if 'stacktrace_ops.warning' is exist],
  97 stacktrace_ops_warning, [
  98         struct task_struct;
  99         struct pt_regs;
 100         #include <asm/stacktrace.h>
 101 ],[
 102         ((struct stacktrace_ops *)0)->warning(NULL, NULL);
 103 ],[
 104         AC_DEFINE(HAVE_STACKTRACE_WARNING, 1,
 105                 [stacktrace_ops.warning is exist])
 106 ])
 107 ]) # LIBCFS_STACKTRACE_WARNING
 108
 109 #
 110 # LC_SHRINKER_WANT_SHRINK_PTR
 111 #
 112 # RHEL6/2.6.32 want to have pointer to shrinker self pointer in handler function
 113 #
 114 AC_DEFUN([LC_SHRINKER_WANT_SHRINK_PTR], [
 115 LB_CHECK_COMPILE([if 'shrinker' want self pointer in handler],
 116 shrink_self_pointer, [
 117         #include <linux/mm.h>
 118 ],[
 119         struct shrinker *tmp = NULL;
 120         tmp->shrink(tmp, 0, 0);
 121 ],[
 122         AC_DEFINE(HAVE_SHRINKER_WANT_SHRINK_PTR, 1,
 123                 [shrinker want self pointer in handler])
 124 ])
 125 ]) # LC_SHRINKER_WANT_SHRINK_PTR
 126
 127 #
 128 # LIBCFS_SYSCTL_CTLNAME
 129 #
 130 # 2.6.33 no longer has ctl_name & strategy field in struct ctl_table.
 131 #
 132 AC_DEFUN([LIBCFS_SYSCTL_CTLNAME], [
 133 LB_CHECK_COMPILE([if 'ctl_table' has a 'ctl_name' field],
 134 ctl_table_ctl_name, [
 135         #include <linux/sysctl.h>
 136 ],[
 137         struct ctl_table ct;
 138         ct.ctl_name = sizeof(ct);
 139 ],[
 140         AC_DEFINE(HAVE_SYSCTL_CTLNAME, 1,
 141                 [ctl_table has ctl_name field])
 142 ])
 143 ]) # LIBCFS_SYSCTL_CTLNAME
 144
 145 #
 146 # LIBCFS_ADD_WAIT_QUEUE_EXCLUSIVE
 147 #
 148 # 2.6.34 adds __add_wait_queue_exclusive
 149 #
 150 AC_DEFUN([LIBCFS_ADD_WAIT_QUEUE_EXCLUSIVE], [
 151 LB_CHECK_COMPILE([if '__add_wait_queue_exclusive' exists],
 152 __add_wait_queue_exclusive, [
 153         #include <linux/wait.h>
 154 ],[
 155         wait_queue_head_t queue;
 156         wait_queue_t      wait;
 157         __add_wait_queue_exclusive(&queue, &wait);
 158 ],[
 159         AC_DEFINE(HAVE___ADD_WAIT_QUEUE_EXCLUSIVE, 1,
 160                 [__add_wait_queue_exclusive exists])
 161 ])
 162 ]) # LIBCFS_ADD_WAIT_QUEUE_EXCLUSIVE
 163
 164 #
 165 # LC_SK_SLEEP
 166 #
 167 # 2.6.35 kernel has sk_sleep function
 168 #
 169 AC_DEFUN([LC_SK_SLEEP], [
 170 LB_CHECK_COMPILE([if Linux kernel has 'sk_sleep'],
 171 sk_sleep, [
 172         #include <net/sock.h>
 173 ],[
 174         sk_sleep(NULL);
 175 ],[
 176         AC_DEFINE(HAVE_SK_SLEEP, 1,
 177                 [kernel has sk_sleep])
 178 ])
 179 ]) # LC_SK_SLEEP
 180
 181 #
 182 # LIBCFS_DUMP_TRACE_ADDRESS
 183 #
 184 # 2.6.39 adds a base pointer address argument to dump_trace
 185 #
 186 AC_DEFUN([LIBCFS_DUMP_TRACE_ADDRESS], [
 187 LB_CHECK_COMPILE([if 'dump_trace' want address],
 188 dump_trace_address, [
 189         struct task_struct;
 190         struct pt_regs;
 191         #include <asm/stacktrace.h>
 192 ],[
 193         dump_trace(NULL, NULL, NULL, 0, NULL, NULL);
 194 ],[
 195         AC_DEFINE(HAVE_DUMP_TRACE_ADDRESS, 1,
 196                 [dump_trace want address argument])
 197 ])
 198 ]) # LIBCFS_DUMP_TRACE_ADDRESS
 199
 200 #
 201 # LC_SHRINK_CONTROL
 202 #
 203 # FC15 2.6.40-5 backported the "shrink_control" parameter to the memory
 204 # pressure shrinker from Linux 3.0
 205 #
 206 AC_DEFUN([LC_SHRINK_CONTROL], [
 207 LB_CHECK_COMPILE([if 'shrink_control' is present],
 208 shrink_control, [
 209         #include <linux/mm.h>
 210 ],[
 211         struct shrink_control tmp = {0};
 212         tmp.nr_to_scan = sizeof(tmp);
 213 ],[
 214         AC_DEFINE(HAVE_SHRINK_CONTROL, 1,
 215                 [shrink_control is present])
 216 ])
 217 ]) # LC_SHRINK_CONTROL
 218
 219 #
 220 # LIBCFS_PROCESS_NAMESPACE
 221 #
 222 # 3.5 introduced process namespace
 223 AC_DEFUN([LIBCFS_PROCESS_NAMESPACE], [
 224 LB_CHECK_LINUX_HEADER([linux/uidgid.h], [
 225         AC_DEFINE(HAVE_UIDGID_HEADER, 1,
 226                 [uidgid.h is present])])
 227 ]) # LIBCFS_PROCESS_NAMESPACE
 228
 229 #
 230 # LIBCFS_I_UID_READ
 231 #
 232 # 3.5 added helpers to read the new uid/gid types from VFS structures
 233 # SLE11 SP3 has uidgid.h but not the helpers
 234 #
 235 AC_DEFUN([LIBCFS_I_UID_READ], [
 236 LB_CHECK_COMPILE([if 'i_uid_read' is present],
 237 i_uid_read, [
 238         #include <linux/fs.h>
 239 ],[
 240         i_uid_read(NULL);
 241 ],[
 242         AC_DEFINE(HAVE_I_UID_READ, 1, [i_uid_read is present])
 243 ])
 244 ]) # LIBCFS_I_UID_READ
 245
 246 #
 247 # LIBCFS_SOCK_ALLOC_FILE
 248 #
 249 # FC18 3.7.2-201 unexport sock_map_fd() change to
 250 # use sock_alloc_file().
 251 # upstream commit 56b31d1c9f1e6a3ad92e7bfe252721e05d92b285
 252 #
 253 AC_DEFUN([LIBCFS_SOCK_ALLOC_FILE], [
 254 LB_CHECK_EXPORT([sock_alloc_file], [net/socket.c], [
 255         LB_CHECK_COMPILE([if 'sock_alloc_file' takes 3 arguments],
 256         sock_alloc_file_3args, [
 257                 #include <linux/net.h>
 258         ],[
 259                 sock_alloc_file(NULL, 0, NULL);
 260         ],[
 261                 AC_DEFINE(HAVE_SOCK_ALLOC_FILE_3ARGS, 1,
 262                         [sock_alloc_file takes 3 arguments])
 263         ],[
 264                 AC_DEFINE(HAVE_SOCK_ALLOC_FILE, 1,
 265                         [sock_alloc_file is exported])
 266         ])
 267 ])
 268 ]) # LIBCFS_SOCK_ALLOC_FILE
 269
 270 #
 271 # LIBCFS_HAVE_CRC32
 272 #
 273 AC_DEFUN([LIBCFS_HAVE_CRC32], [
 274 LB_CHECK_CONFIG_IM([CRC32],
 275         [have_crc32="yes"], [have_crc32="no"])
 276 AS_IF([test "x$have_crc32" = xyes],
 277         [AC_DEFINE(HAVE_CRC32, 1,
 278                 [kernel compiled with CRC32 functions])])
 279 ]) # LIBCFS_HAVE_CRC32
 280
 281 #
 282 # LIBCFS_ENABLE_CRC32_ACCEL
 283 #
 284 AC_DEFUN([LIBCFS_ENABLE_CRC32_ACCEL], [
 285 LB_CHECK_CONFIG_IM([CRYPTO_CRC32_PCLMUL],
 286         [enable_crc32_crypto="no"], [enable_crc32_crypto="yes"])
 287 AS_IF([test "x$have_crc32" = xyes -a "x$enable_crc32_crypto" = xyes], [
 288         AC_DEFINE(NEED_CRC32_ACCEL, 1, [need pclmulqdq based crc32])
 289         AC_MSG_WARN([
 290
 291 No crc32 pclmulqdq crypto api found, enable internal pclmulqdq based crc32
 292 ])])
 293 ]) # LIBCFS_ENABLE_CRC32_ACCEL
 294
 295 #
 296 # LIBCFS_ENABLE_CRC32C_ACCEL
 297 #
 298 AC_DEFUN([LIBCFS_ENABLE_CRC32C_ACCEL], [
 299 LB_CHECK_CONFIG_IM([CRYPTO_CRC32C_INTEL],
 300         [enable_crc32c_crypto="no"], [enable_crc32c_crypto="yes"])
 301 AS_IF([test "x$enable_crc32c_crypto" = xyes], [
 302         AC_DEFINE(NEED_CRC32C_ACCEL, 1, [need pclmulqdq based crc32c])
 303         AC_MSG_WARN([
 304
 305 No crc32c pclmulqdq crypto api found, enable internal pclmulqdq based crc32c
 306 ])])
 307 ]) # LIBCFS_ENABLE_CRC32C_ACCEL
 308
 309 #
 310 # FC19 3.12 kernel struct shrinker change
 311 #
 312 AC_DEFUN([LIBCFS_SHRINKER_COUNT],[
 313 LB_CHECK_COMPILE([shrinker has 'count_objects'],
 314 shrinker_count_objects, [
 315         #include <linux/mmzone.h>
 316         #include <linux/shrinker.h>
 317 ],[
 318         ((struct shrinker*)0)->count_objects(NULL, NULL);
 319 ],[
 320         AC_DEFINE(HAVE_SHRINKER_COUNT, 1,
 321                 [shrinker has count_objects memeber])
 322 ])
 323 ])
 324
 325 #
 326 # LIBCFS_PROG_LINUX
 327 #
 328 # LibCFS linux kernel checks
 329 #
 330 AC_DEFUN([LIBCFS_PROG_LINUX], [
 331 AC_MSG_NOTICE([LibCFS kernel checks
 332 ==============================================================================])
 333 LIBCFS_CONFIG_PANIC_DUMPLOG
 334
 335 LIBCFS_U64_LONG_LONG_LINUX
 336 # 2.6.32
 337 LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK
 338 LC_SHRINKER_WANT_SHRINK_PTR
 339 # 2.6.33
 340 LIBCFS_SYSCTL_CTLNAME
 341 # 2.6.34
 342 LIBCFS_ADD_WAIT_QUEUE_EXCLUSIVE
 343 # 2.6.35
 344 LC_SK_SLEEP
 345 # 2.6.39
 346 LIBCFS_DUMP_TRACE_ADDRESS
 347 # 2.6.40 fc15
 348 LC_SHRINK_CONTROL
 349 # 3.0
 350 LIBCFS_STACKTRACE_WARNING
 351 # 3.5
 352 LIBCFS_PROCESS_NAMESPACE
 353 LIBCFS_I_UID_READ
 354 # 3.7
 355 LIBCFS_SOCK_ALLOC_FILE
 356 # 3.8
 357 LIBCFS_HAVE_CRC32
 358 LIBCFS_ENABLE_CRC32_ACCEL
 359 # 3.10
 360 LIBCFS_ENABLE_CRC32C_ACCEL
 361 # 3.12
 362 LIBCFS_SHRINKER_COUNT
 363 ]) # LIBCFS_PROG_LINUX
 364
 365 #
 366 # LIBCFS_PROG_DARWIN
 367 #
 368 # Darwin checks
 369 #
 370 AC_DEFUN([LIBCFS_PROG_DARWIN], [
 371 LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 372 ]) # LIBCFS_PROG_DARWIN
 373
 374 #
 375 # LIBCFS_PATH_DEFAULTS
 376 #
 377 # default paths for installed files
 378 #
 379 AC_DEFUN([LIBCFS_PATH_DEFAULTS], [
 380 ]) # LIBCFS_PATH_DEFAULTS
 381
 382 #
 383 # LIBCFS_CONFIGURE
 384 #
 385 # other configure checks
 386 #
 387 AC_DEFUN([LIBCFS_CONFIGURE], [
 388 AC_MSG_NOTICE([LibCFS core checks
 389 ==============================================================================])
 390
 391 # lnet/utils/portals.c
 392 AC_CHECK_HEADERS([asm/types.h endian.h sys/ioctl.h])
 393
 394 # lnet/utils/debug.c
 395 AC_CHECK_HEADERS([linux/version.h])
 396
 397 AC_CHECK_TYPE([spinlock_t],
 398         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
 399         [],
 400         [#include <linux/spinlock.h>])
 401
 402 # lnet/utils/wirecheck.c
 403 AC_CHECK_FUNCS([strnlen])
 404
 405 # lnet/libcfs/user-prim.c, missing for RHEL5 and earlier userspace
 406 AC_CHECK_FUNCS([strlcpy])
 407
 408 # libcfs/libcfs/user-prim.c, missing for RHEL5 and earlier userspace
 409 AC_CHECK_FUNCS([strlcat])
 410
 411 # --------  Check for required packages  --------------
 412
 413 AC_MSG_NOTICE([LibCFS required packages checks
 414 ==============================================================================])
 415
 416 AC_MSG_CHECKING([whether to enable 'efence' debugging support])
 417 AC_ARG_ENABLE(efence,
 418         AC_HELP_STRING([--enable-efence],
 419                 [use efence library]),
 420         [], [enable_efence="no"])
 421 AC_MSG_RESULT([$enable_efence])
 422 AS_IF([test "$enable_efence" = yes], [
 423         LIBEFENCE="-lefence"
 424         AC_DEFINE(HAVE_LIBEFENCE, 1, [libefence support is requested])
 425 ], [
 426         LIBEFENCE=""
 427 ])
 428 AC_SUBST(LIBEFENCE)
 429
 430 # -------- check for -lpthread support ----
 431
 432 AC_MSG_CHECKING([whether to use libpthread for libcfs library])
 433 AC_ARG_ENABLE([libpthread],
 434         AC_HELP_STRING([--disable-libpthread],
 435                 [disable libpthread]),
 436         [], [enable_libpthread="yes"])
 437 AC_MSG_RESULT([$enable_libpthread])
 438 AS_IF([test "x$enable_libpthread" = xyes], [
 439         AC_CHECK_LIB([pthread], [pthread_create],
 440                 [ENABLE_LIBPTHREAD="yes"],
 441                 [ENABLE_LIBPTHREAD="no"])
 442         AS_IF([test "$ENABLE_LIBPTHREAD" = yes], [
 443                 PTHREAD_LIBS="-lpthread"
 444                 AC_DEFINE([HAVE_LIBPTHREAD], 1, [use libpthread])
 445         ], [
 446                 PTHREAD_LIBS=""
 447         ])
 448         AC_SUBST(PTHREAD_LIBS)
 449 ], [
 450         AC_MSG_WARN([Using libpthread for libcfs library is disabled explicitly])
 451         ENABLE_LIBPTHREAD="no"
 452 ])
 453 AC_SUBST(ENABLE_LIBPTHREAD)
 454 ]) # LIBCFS_CONFIGURE
 455
 456 #
 457 # LIBCFS_CONDITIONALS
 458 #
 459 AC_DEFUN([LIBCFS_CONDITIONALS], [
 460 AM_CONDITIONAL(HAVE_CRC32, [test "x$have_crc32" = xyes])
 461 AM_CONDITIONAL(NEED_PCLMULQDQ_CRC32,  [test "x$have_crc32" = xyes -a "x$enable_crc32_crypto" = xyes])
 462 AM_CONDITIONAL(NEED_PCLMULQDQ_CRC32C, [test "x$enable_crc32c_crypto" = xyes])
 463 ]) # LIBCFS_CONDITIONALS
 464
 465 #
 466 # LIBCFS_CONFIG_FILES
 467 #
 468 # files that should be generated with AC_OUTPUT
 469 #
 470 AC_DEFUN([LIBCFS_CONFIG_FILES], [
 471 AC_CONFIG_FILES([
 472 libcfs/Kernelenv
 473 libcfs/Makefile
 474 libcfs/autoMakefile
 475 libcfs/autoconf/Makefile
 476 libcfs/include/Makefile
 477 libcfs/include/libcfs/Makefile
 478 libcfs/include/libcfs/linux/Makefile
 479 libcfs/include/libcfs/posix/Makefile
 480 libcfs/include/libcfs/util/Makefile
 481 libcfs/libcfs/Makefile
 482 libcfs/libcfs/autoMakefile
 483 libcfs/libcfs/linux/Makefile
 484 libcfs/libcfs/posix/Makefile
 485 libcfs/libcfs/util/Makefile
 486 libcfs/include/libcfs/darwin/Makefile
 487 libcfs/libcfs/darwin/Makefile
 488 ])
 489 ]) # LIBCFS_CONFIG_FILES