libcfs/autoconf/lustre-libcfs.m4

   1 #
   2 # LIBCFS_CONFIG_CDEBUG
   3 #
   4 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
   5 #
   6 AC_DEFUN([LIBCFS_CONFIG_CDEBUG], [
   7 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
   8 AC_ARG_ENABLE([libcfs_cdebug],
   9         AC_HELP_STRING([--disable-libcfs-cdebug],
  10                 [disable libcfs CDEBUG, CWARN]),
  11         [], [enable_libcfs_cdebug="yes"])
  12 AC_MSG_RESULT([$enable_libcfs_cdebug])
  13 AS_IF([test "x$enable_libcfs_cdebug" = xyes],
  14         [AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])])
  15
  16 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
  17 AC_ARG_ENABLE([libcfs_trace],
  18         AC_HELP_STRING([--disable-libcfs-trace],
  19                 [disable libcfs ENTRY/EXIT]),
  20         [], [enable_libcfs_trace="yes"])
  21 AC_MSG_RESULT([$enable_libcfs_trace])
  22 AS_IF([test "x$enable_libcfs_trace" = xyes],
  23         [AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])])
  24
  25 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
  26 AC_ARG_ENABLE([libcfs_assert],
  27         AC_HELP_STRING([--disable-libcfs-assert],
  28                 [disable libcfs LASSERT, LASSERTF]),
  29         [], [enable_libcfs_assert="yes"])
  30 AC_MSG_RESULT([$enable_libcfs_assert])
  31 AS_IF([test x$enable_libcfs_assert = xyes],
  32         [AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])])
  33 ]) # LIBCFS_CONFIG_CDEBUG
  34
  35 #
  36 # LIBCFS_CONFIG_PANIC_DUMPLOG
  37 #
  38 # check if tunable panic_dumplog is wanted
  39 #
  40 AC_DEFUN([LIBCFS_CONFIG_PANIC_DUMPLOG], [
  41 AC_MSG_CHECKING([whether to use tunable 'panic_dumplog' support])
  42 AC_ARG_ENABLE([panic_dumplog],
  43         AC_HELP_STRING([--enable-panic_dumplog],
  44                 [enable panic_dumplog]),
  45         [], [enable_panic_dumplog="no"])
  46 AC_MSG_RESULT([$enable_panic_dumplog])
  47 AS_IF([test "x$enable_panic_dumplog" = xyes],
  48         [AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])])
  49 ]) # LIBCFS_CONFIG_PANIC_DUMPLOG
  50
  51 #
  52 # Kernel version 3.11 introduced ktime_get_ts64
  53 #
  54 AC_DEFUN([LIBCFS_KTIME_GET_TS64],[
  55 LB_CHECK_COMPILE([does function 'ktime_get_ts64' exist],
  56 ktime_get_ts64, [
  57         #include <linux/hrtimer.h>
  58         #include <linux/ktime.h>
  59 ],[
  60         struct timespec64 *ts = NULL;
  61
  62         ktime_get_ts64(ts);
  63 ],[
  64         AC_DEFINE(HAVE_KTIME_GET_TS64, 1,
  65                 ['ktime_get_ts64' is available])
  66 ])
  67 ]) # LIBCFS_KTIME_GET_TS64
  68
  69 #
  70 # Kernel version 3.12-rc4 commit c2d816443ef30 added prepare_to_wait_event()
  71 #
  72 AC_DEFUN([LIBCFS_PREPARE_TO_WAIT_EVENT],[
  73 LB_CHECK_COMPILE([does function 'prepare_to_wait_event' exist],
  74 prepare_to_wait_event, [
  75         #include <linux/wait.h>
  76 ],[
  77         prepare_to_wait_event(NULL, NULL, 0);
  78 ],[
  79         AC_DEFINE(HAVE_PREPARE_TO_WAIT_EVENT, 1,
  80                 ['prepare_to_wait_event' is available])
  81 ])
  82 ]) # LIBCFS_PREPARE_TO_WAIT_EVENT
  83
  84 #
  85 # Linux kernel 3.12 introduced struct kernel_param_ops
  86 # This has been backported to all lustre supported
  87 # clients except RHEL6. We have to handle the differences.
  88 #
  89 AC_DEFUN([LIBCFS_KERNEL_PARAM_OPS],[
  90 LB_CHECK_COMPILE([does 'struct kernel_param_ops' exist],
  91 kernel_param_ops, [
  92         #include <linux/module.h>
  93 ],[
  94         struct kernel_param_ops ops;
  95
  96         ops.set = NULL;
  97 ],[
  98         AC_DEFINE(HAVE_KERNEL_PARAM_OPS, 1,
  99                 ['struct kernel_param_ops' is available])
 100 ])
 101 ]) # LIBCFS_KERNEL_PARAM_OPS
 102
 103 #
 104 # Kernel version 3.12 introduced ktime_add
 105 #
 106 AC_DEFUN([LIBCFS_KTIME_ADD],[
 107 LB_CHECK_COMPILE([does function 'ktime_add' exist],
 108 ktime_add, [
 109         #include <linux/hrtimer.h>
 110         #include <linux/ktime.h>
 111 ],[
 112         ktime_t start = ktime_set(0, 0);
 113         ktime_t end = start;
 114         ktime_t total;
 115
 116         total = ktime_add(start, end);
 117 ],[
 118         AC_DEFINE(HAVE_KTIME_ADD, 1,
 119                 [ktime_add is available])
 120 ])
 121 ]) # LIBCFS_KTIME_ADD
 122
 123 #
 124 # Kernel version 3.12 introduced ktime_after
 125 #
 126 AC_DEFUN([LIBCFS_KTIME_AFTER],[
 127 LB_CHECK_COMPILE([does function 'ktime_after' exist],
 128 ktime_after, [
 129         #include <linux/hrtimer.h>
 130         #include <linux/ktime.h>
 131 ],[
 132         ktime_t start = ktime_set(0, 0);
 133         ktime_t end = start;
 134
 135         ktime_after(start, end);
 136 ],[
 137         AC_DEFINE(HAVE_KTIME_AFTER, 1,
 138                 [ktime_after is available])
 139 ])
 140 ]) # LIBCFS_KTIME_AFTER
 141
 142 #
 143 # Kernel version 3.12 introduced ktime_before
 144 # See linux commit 67cb9366ff5f99868100198efba5ca88aaa6ad25
 145 #
 146 AC_DEFUN([LIBCFS_KTIME_BEFORE],[
 147 LB_CHECK_COMPILE([does function 'ktime_before' exist],
 148 ktime_before, [
 149         #include <linux/hrtimer.h>
 150         #include <linux/ktime.h>
 151 ],[
 152         ktime_t start = ktime_set(0, 0);
 153         ktime_t end = start;
 154
 155         ktime_before(start, end);
 156 ],[
 157         AC_DEFINE(HAVE_KTIME_BEFORE, 1,
 158                 [ktime_before is available])
 159 ])
 160 ]) # LIBCFS_KTIME_BEFORE
 161
 162 #
 163 # Kernel version 3.12 introduced ktime_compare
 164 #
 165 AC_DEFUN([LIBCFS_KTIME_COMPARE],[
 166 LB_CHECK_COMPILE([does function 'ktime_compare' exist],
 167 ktime_compare, [
 168         #include <linux/hrtimer.h>
 169         #include <linux/ktime.h>
 170 ],[
 171         ktime_t start = ktime_set(0, 0);
 172         ktime_t end = start;
 173
 174         ktime_compare(start, end);
 175 ],[
 176         AC_DEFINE(HAVE_KTIME_COMPARE, 1,
 177                 [ktime_compare is available])
 178 ])
 179 ]) # LIBCFS_KTIME_COMPARE
 180
 181 #
 182 # FC19 3.12 kernel struct shrinker change
 183 #
 184 AC_DEFUN([LIBCFS_SHRINKER_COUNT],[
 185 LB_CHECK_COMPILE([shrinker has 'count_objects'],
 186 shrinker_count_objects, [
 187         #include <linux/mmzone.h>
 188         #include <linux/shrinker.h>
 189 ],[
 190         struct shrinker shrinker;
 191
 192         shrinker.count_objects = NULL;
 193 ],[
 194         AC_DEFINE(HAVE_SHRINKER_COUNT, 1,
 195                 [shrinker has count_objects member])
 196 ])
 197 ]) # LIBCFS_SHRINKER_COUNT
 198
 199 #
 200 # LIBCFS_HAVE_MAPPING_AS_EXITING_FLAG
 201 #
 202 # v3.14-7405-g91b0abe36a7b added AS_EXITING flag with
 203 # mapping_exiting() and mapping_set_exiting()
 204 #
 205 AC_DEFUN([LIBCFS_HAVE_MAPPING_AS_EXITING_FLAG], [
 206 m4_pattern_allow([AS_EXITING])
 207 tmp_flags="$EXTRA_KCFLAGS"
 208 EXTRA_KCFLAGS="-Werror"
 209 LB_CHECK_COMPILE([if enum mapping_flags has AS_EXITING flag],
 210 mapping_exiting_exists, [
 211         #include <linux/pagemap.h>
 212 ],[
 213         enum mapping_flags flag = AS_EXITING;
 214         (void)flag;
 215 ],[
 216         AC_DEFINE(HAVE_MAPPING_AS_EXITING_FLAG, 1,
 217                 [enum mapping_flags has AS_EXITING flag])
 218 ])
 219 EXTRA_KCFLAGS="$tmp_flags"
 220 ]) # LIBCFS_HAVE_MAPPING_AS_EXITING_FLAG
 221
 222 #
 223 # LIBCFS_IOV_ITER_HAS_TYPE
 224 #
 225 # kernel 3.15-rc4 commit 71d8e532b1549a478e6a6a8a44f309d050294d00
 226 # start adding the tag to iov_iter
 227 #
 228 AC_DEFUN([LIBCFS_IOV_ITER_HAS_TYPE], [
 229 tmp_flags="$EXTRA_KCFLAGS"
 230 EXTRA_KCFLAGS="-Werror"
 231 LB_CHECK_COMPILE([if iov_iter has member type],
 232 iov_iter_has_type_member, [
 233         #include <linux/uio.h>
 234 ],[
 235         struct iov_iter iter = { .type = ITER_KVEC };
 236         (void)iter;
 237 ],[
 238         AC_DEFINE(HAVE_IOV_ITER_HAS_TYPE_MEMBER, 1,
 239                 [if iov_iter has member type])
 240 ])
 241 EXTRA_KCFLAGS="$tmp_flags"
 242 ]) # LIBCFS_IOV_ITER_HAS_TYPE
 243
 244 #
 245 # LIBCFS_HAVE_NS_TO_TIMESPEC64
 246 #
 247 # Kernel version 4.16-rc3 commit a84d1169164b274f13b97a23ff235c000efe3b49
 248 # introduced struct __kernel_old_timeval
 249 #
 250 AC_DEFUN([LIBCFS_HAVE_NS_TO_TIMESPEC64],[
 251 LB_CHECK_COMPILE([does 'ns_to_timespec64()' exist],
 252 kernel_old_timeval, [
 253         #include <linux/time.h>
 254 ],[
 255         struct timespec64 kts;
 256
 257         kts = ns_to_timespec64(0);
 258 ],[
 259         AC_DEFINE(HAVE_NS_TO_TIMESPEC64, 1,
 260                 [ns_to_timespec64() is available])
 261 ])
 262 ]) # LIBCFS_HAVE_NS_TO_TIMESPEC64
 263
 264 #
 265 # Kernel version 3.17 changed hlist_add_after to
 266 # hlist_add_behind
 267 #
 268 AC_DEFUN([LIBCFS_HLIST_ADD_AFTER],[
 269 LB_CHECK_COMPILE([does function 'hlist_add_after' exist],
 270 hlist_add_after, [
 271         #include <linux/list.h>
 272 ],[
 273         hlist_add_after(NULL, NULL);
 274 ],[
 275         AC_DEFINE(HAVE_HLIST_ADD_AFTER, 1,
 276                 [hlist_add_after is available])
 277 ])
 278 ]) # LIBCFS_HLIST_ADD_AFTER
 279
 280 #
 281 # Kernel version 3.17 introduced struct timespec64
 282 #
 283 AC_DEFUN([LIBCFS_TIMESPEC64],[
 284 LB_CHECK_COMPILE([does 'struct timespec64' exist],
 285 timespec64, [
 286         #include <linux/time.h>
 287 ],[
 288         struct timespec64 ts;
 289
 290         ts.tv_sec = 0;
 291         ts.tv_nsec = 0;
 292 ],[
 293         AC_DEFINE(HAVE_TIMESPEC64, 1,
 294                 ['struct timespec64' is available])
 295 ])
 296 ]) # LIBCFS_TIMESPEC64
 297
 298 #
 299 # Kernel version 3.17 introduced ktime_get_real_ts64
 300 #
 301 AC_DEFUN([LIBCFS_KTIME_GET_REAL_TS64],[
 302 LB_CHECK_COMPILE([does function 'ktime_get_real_ts64' exist],
 303 ktime_get_real_ts64, [
 304         #include <linux/ktime.h>
 305 ],[
 306         struct timespec64 *ts = NULL;
 307
 308         ktime_get_real_ts64(ts);
 309 ],[
 310         AC_DEFINE(HAVE_KTIME_GET_REAL_TS64, 1,
 311                 ['ktime_get_real_ts64' is available])
 312 ])
 313 ]) # LIBCFS_KTIME_GET_REAL_TS64
 314
 315 #
 316 # Kernel version 3.17 introduced ktime_get_real_seconds
 317 #
 318 AC_DEFUN([LIBCFS_KTIME_GET_REAL_SECONDS],[
 319 LB_CHECK_COMPILE([does function 'ktime_get_real_seconds' exist],
 320 ktime_get_real_seconds, [
 321         #include <linux/hrtimer.h>
 322         #include <linux/ktime.h>
 323 ],[
 324         time64_t now;
 325
 326         now = ktime_get_real_seconds();
 327 ],[
 328         AC_DEFINE(HAVE_KTIME_GET_REAL_SECONDS, 1,
 329                 ['ktime_get_real_seconds' is available])
 330 ])
 331 ]) # LIBCFS_KTIME_GET_REAL_SECONDS
 332
 333 #
 334 # Kernel version 3.17 created ktime_get_ns wrapper
 335 #
 336 AC_DEFUN([LIBCFS_KTIME_GET_NS],[
 337 LB_CHECK_COMPILE([does function 'ktime_get_ns' exist],
 338 ktime_get_ns, [
 339         #include <linux/hrtimer.h>
 340         #include <linux/ktime.h>
 341 ],[
 342         u64 nanoseconds;
 343
 344         nanoseconds = ktime_get_ns();
 345 ],[],[
 346         AC_DEFINE(NEED_KTIME_GET_NS, 1,
 347                 ['ktime_get_ns' is not available])
 348 ])
 349 ]) # LIBCFS_KTIME_GET_NS
 350
 351 #
 352 # Kernel version 3.17 created ktime_get_real_ns wrapper
 353 #
 354 AC_DEFUN([LIBCFS_KTIME_GET_REAL_NS],[
 355 LB_CHECK_COMPILE([does function 'ktime_get_real_ns' exist],
 356 ktime_get_real_ns, [
 357         #include <linux/hrtimer.h>
 358         #include <linux/ktime.h>
 359 ],[
 360         u64 nanoseconds;
 361
 362         nanoseconds = ktime_get_real_ns();
 363 ],[],[
 364         AC_DEFINE(NEED_KTIME_GET_REAL_NS, 1,
 365                 ['ktime_get_real_ns' is not available])
 366 ])
 367 ]) # LIBCFS_KTIME_GET_REAL_NS
 368
 369 #
 370 # Kernel version 3.17 introduced ktime_to_timespec64
 371 #
 372 AC_DEFUN([LIBCFS_KTIME_TO_TIMESPEC64],[
 373 LB_CHECK_COMPILE([does function 'ktime_to_timespec64' exist],
 374 ktime_to_timespec64, [
 375         #include <linux/hrtimer.h>
 376         #include <linux/ktime.h>
 377 ],[
 378         ktime_t now = ktime_set(0, 0);
 379         struct timespec64 ts;
 380
 381         ts = ktime_to_timespec64(now);
 382 ],[
 383         AC_DEFINE(HAVE_KTIME_TO_TIMESPEC64, 1,
 384                 ['ktime_to_timespec64' is available])
 385 ])
 386 ]) # LIBCFS_KTIME_TO_TIMESPEC64
 387
 388 #
 389 # Kernel version 3.17 introduced timespec64_sub
 390 #
 391 AC_DEFUN([LIBCFS_TIMESPEC64_SUB],[
 392 LB_CHECK_COMPILE([does function 'timespec64_sub' exist],
 393 timespec64_sub, [
 394         #include <linux/time.h>
 395 ],[
 396         struct timespec64 later = { }, earlier = { }, diff;
 397
 398         diff = timespec64_sub(later, earlier);
 399 ],[
 400         AC_DEFINE(HAVE_TIMESPEC64_SUB, 1,
 401                 ['timespec64_sub' is available])
 402 ])
 403 ]) # LIBCFS_TIMESPEC64_SUB
 404
 405 #
 406 # Kernel version 3.17 introduced timespec64_to_ktime
 407 #
 408 AC_DEFUN([LIBCFS_TIMESPEC64_TO_KTIME],[
 409 LB_CHECK_COMPILE([does function 'timespec64_to_ktime' exist],
 410 timespec64_to_ktime, [
 411         #include <linux/ktime.h>
 412 ],[
 413         struct timespec64 ts;
 414         ktime_t now;
 415
 416         now = timespec64_to_ktime(ts);
 417 ],[
 418         AC_DEFINE(HAVE_TIMESPEC64_TO_KTIME, 1,
 419                 ['timespec64_to_ktime' is available])
 420 ])
 421 ]) # LIBCFS_TIMESPEC64_TO_KTIME
 422
 423 #
 424 # Kernel version 3.19 introduced ktime_get_seconds
 425 #
 426 AC_DEFUN([LIBCFS_KTIME_GET_SECONDS],[
 427 LB_CHECK_COMPILE([does function 'ktime_get_seconds' exist],
 428 ktime_get_seconds, [
 429         #include <linux/ktime.h>
 430 ],[
 431         time64_t now;
 432
 433         now = ktime_get_seconds();
 434 ],[
 435         AC_DEFINE(HAVE_KTIME_GET_SECONDS, 1,
 436                 ['ktime_get_seconds' is available])
 437 ])
 438 ]) # LIBCFS_KTIME_GET_SECONDS
 439
 440 #
 441 # Kernel version 4.0 commit 41fbf3b39d5eca01527338b4d0ee15ee1ae1023c
 442 # introduced the helper function ktime_ms_delta.
 443 #
 444 AC_DEFUN([LIBCFS_KTIME_MS_DELTA],[
 445 LB_CHECK_COMPILE([does function 'ktime_ms_delta' exist],
 446 ktime_ms_delta, [
 447         #include <linux/ktime.h>
 448 ],[
 449         ktime_t start = ktime_set(0, 0);
 450         ktime_t end = start;
 451
 452         ktime_ms_delta(start, end);
 453 ],[
 454         AC_DEFINE(HAVE_KTIME_MS_DELTA, 1,
 455                 ['ktime_ms_delta' is available])
 456 ])
 457 ]) # LIBCFS_KTIME_MS_DELTA
 458
 459 #
 460 # Kernel version 4.1 commit b51d23e4e9fea6f264d39535c2a62d1f51e7ccc3
 461 # create per module locks which added kernel_param_[un]lock(). Older
 462 # kernels you have to use __kernel_param_[un]lock(). In that case its
 463 # a global lock for all modules but that is okay since its a rare event.
 464 #
 465 AC_DEFUN([LIBCFS_KERNEL_PARAM_LOCK],[
 466 LB_CHECK_COMPILE([does function 'kernel_param_[un]lock' exist],
 467 kernel_param_lock, [
 468         #include <linux/moduleparam.h>
 469 ],[
 470         kernel_param_lock(NULL);
 471         kernel_param_unlock(NULL);
 472 ],[
 473         AC_DEFINE(HAVE_KERNEL_PARAM_LOCK, 1,
 474                 ['kernel_param_[un]lock' is available])
 475 ])
 476 ]) # LIBCFS_KERNEL_PARAM_LOCK
 477
 478 #
 479 # Kernel version 4.2 changed topology_thread_cpumask
 480 # to topology_sibling_cpumask
 481 #
 482 AC_DEFUN([LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK],[
 483 LB_CHECK_COMPILE([does function 'topology_sibling_cpumask' exist],
 484 topology_sibling_cpumask, [
 485         #include <linux/topology.h>
 486 ],[
 487         const struct cpumask *mask;
 488
 489         mask = topology_sibling_cpumask(0);
 490 ],[
 491         AC_DEFINE(HAVE_TOPOLOGY_SIBLING_CPUMASK, 1,
 492                 [topology_sibling_cpumask is available])
 493 ])
 494 ]) # LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK
 495
 496 #
 497 # Kernel version 4.4 commit ef951599074ba4fad2d0efa0a977129b41e6d203
 498 # introduced kstrtobool and kstrtobool_from_user.
 499 #
 500 AC_DEFUN([LIBCFS_KSTRTOBOOL_FROM_USER], [
 501 LB_CHECK_COMPILE([if Linux kernel has 'kstrtobool_from_user'],
 502 kstrtobool_from_user, [
 503         #include <linux/kernel.h>
 504 ],[
 505         bool result;
 506         return kstrtobool_from_user(NULL, 0, &result);
 507 ],[
 508         AC_DEFINE(HAVE_KSTRTOBOOL_FROM_USER, 1,
 509                 [kernel has kstrtobool_from_user])
 510 ])
 511 ]) # LIBCFS_KSTRTOBOOL_FROM_USER
 512
 513 #
 514 # LIBCFS_NETLINK_CALLBACK_START
 515 #
 516 # Kernel version 4.4-rc3 commit fc9e50f5a5a4e1fa9ba2756f745a13e693cf6a06
 517 # added a start function callback for struct netlink_callback
 518 #
 519 AC_DEFUN([LIBCFS_NETLINK_CALLBACK_START], [
 520 LB_CHECK_COMPILE([if struct genl_ops has start callback],
 521 cb_start, [
 522         #include <net/genetlink.h>
 523 ],[
 524         struct genl_ops ops;
 525
 526         ops.start = NULL;
 527 ],[
 528         AC_DEFINE(HAVE_NETLINK_CALLBACK_START, 1,
 529                 [struct genl_ops has 'start' callback])
 530 ])
 531 ]) # LIBCFS_NETLINK_CALLBACK_START
 532
 533 #
 534 # Kernel version 4.5-rc1 commit d12481bc58fba89427565f8592e88446ec084a24
 535 # added crypto hash helpers
 536 #
 537 AC_DEFUN([LIBCFS_CRYPTO_HASH_HELPERS], [
 538 LB_CHECK_COMPILE([does crypto hash helper functions exist],
 539 crypto_hash_helpers, [
 540         #include <crypto/hash.h>
 541 ],[
 542         crypto_ahash_alg_name(NULL);
 543         crypto_ahash_driver_name(NULL);
 544 ],[
 545         AC_DEFINE(HAVE_CRYPTO_HASH_HELPERS, 1,
 546                 [crypto hash helper functions are available])
 547 ])
 548 ]) # LIBCFS_CRYPTO_HASH_HELPERS
 549
 550 #
 551 # Kernel version 4.5-rc1 commit 3502cad73c4bbf8f6365d539e814159275252c59
 552 # introduced rhashtable_replace_fast
 553 #
 554 AC_DEFUN([LIBCFS_RHASHTABLE_REPLACE], [
 555 LB_CHECK_COMPILE([if 'rhashtable_replace_fast' exists],
 556 rhashtable_replace_fast, [
 557         #include <linux/rhashtable.h>
 558 ],[
 559         const struct rhashtable_params params = { 0 };
 560
 561         rhashtable_replace_fast(NULL, NULL, NULL, params);
 562 ],[
 563         AC_DEFINE(HAVE_RHASHTABLE_REPLACE, 1,
 564                 [rhashtable_replace_fast() is available])
 565 ])
 566 ]) # LIBCFS_RHASHTABLE_REPLACE
 567
 568 #
 569 # Kernel version 4.5-rc3 commit 2fe829aca9d7bed5fd6b49c6a1452e5e486b6cc3dd
 570 # made kset_find_obj() exportable to modules
 571 #
 572 AC_DEFUN([LIBCFS_EXPORT_KSET_FIND_OBJ], [
 573 LB_CHECK_EXPORT([kset_find_obj], [lib/kobject.c],
 574         [AC_DEFINE(HAVE_KSET_FIND_OBJ, 1,
 575                 [kset_find_obj is exported by the kernel])])
 576 ]) # LIBCFS_EXPORT_KSET_FIND_OBJ
 577
 578 #
 579 # Kernel version 4.6+ commit ef703f49a6c5b909a85149bb6625c4ed0d697186
 580 # fixed the brokenness of hash_64(). The fix removed GOLDEN_RATIO_PRIME_64
 581 # since it was a poor prime value.
 582 #
 583 AC_DEFUN([LIBCFS_BROKEN_HASH_64], [
 584 LB_CHECK_COMPILE([kernel has fixed hash_64()],
 585 broken_hash_64, [
 586         #include <linux/hash.h>
 587 ],[
 588         int tmp = GOLDEN_RATIO_PRIME_64;
 589 ],[
 590         AC_DEFINE(HAVE_BROKEN_HASH_64, 1, [kernel hash_64() is broken])
 591 ])
 592 ]) # LIBCFS_BROKEN_HASH_64
 593
 594 #
 595 # LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
 596 #
 597 # linux 4.6 kernel changed stacktrace_ops address to return an int
 598 #
 599 AC_DEFUN([LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT], [
 600 LB_CHECK_COMPILE([if 'struct stacktrace_ops' address function returns an int],
 601 stacktrace_ops_address_return_int, [
 602         #include <asm/stacktrace.h>
 603 ],[
 604         int rc;
 605
 606         rc = ((struct stacktrace_ops *)0)->address(NULL, 0, 0);
 607 ],[
 608         AC_DEFINE(STACKTRACE_OPS_ADDRESS_RETURN_INT, 1,
 609                 ['struct stacktrace_ops' address function returns an int])
 610 ])
 611 ]) # LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
 612
 613 #
 614 # Kernel version 4.6 removed both struct task_struct and struct mm_struct
 615 # arguments to get_user_pages
 616 #
 617 AC_DEFUN([LIBCFS_GET_USER_PAGES_6ARG], [
 618 LB_CHECK_COMPILE([if 'get_user_pages()' takes 6 arguments],
 619 get_user_pages_6arg, [
 620         #include <linux/mm.h>
 621 ],[
 622         int rc;
 623
 624         rc = get_user_pages(0, 0, 0, 0, NULL, NULL);
 625 ],[
 626         AC_DEFINE(HAVE_GET_USER_PAGES_6ARG, 1,
 627                 [get_user_pages takes 6 arguments])
 628 ])
 629 ]) # LIBCFS_GET_USER_PAGES_6ARG
 630
 631 #
 632 # LIBCFS_STRINGHASH
 633 #
 634 # 4.6 kernel created stringhash.h which moved stuff out of dcache.h
 635 # commit f4bcbe792b8f434e32487cff9d9e30ab45a3ce02
 636 #
 637 AC_DEFUN([LIBCFS_STRINGHASH], [
 638 LB_CHECK_LINUX_HEADER([linux/stringhash.h], [
 639         AC_DEFINE(HAVE_STRINGHASH, 1,
 640                 [stringhash.h is present])])
 641 ]) # LIBCFS_STRINGHASH
 642
 643 #
 644 # LIBCFS_RHASHTABLE_INSERT_FAST
 645 #
 646 # 4.7+ kernel commit 5ca8cc5bf11faed257c762018aea9106d529232f
 647 # changed __rhashtable_insert_fast to support the new function
 648 # rhashtable_lookup_get_insert_key().
 649 #
 650 AC_DEFUN([LIBCFS_RHASHTABLE_INSERT_FAST], [
 651 tmp_flags="$EXTRA_KCFLAGS"
 652 EXTRA_KCFLAGS="-Werror"
 653 LB_CHECK_COMPILE([if internal '__rhashtable_insert_fast()' returns int],
 654 rhashtable_insert_fast, [
 655         #include <linux/rhashtable.h>
 656 ],[
 657         const struct rhashtable_params params = { 0 };
 658         int rc;
 659
 660         rc = __rhashtable_insert_fast(NULL, NULL, NULL, params);
 661 ],[
 662         AC_DEFINE(HAVE_HASHTABLE_INSERT_FAST_RETURN_INT, 1,
 663                   ['__rhashtable_insert_fast()' returns int])
 664 ])
 665 EXTRA_KCFLAGS="$tmp_flags"
 666 ]) # LIBCFS_RHASHTABLE_INSERT_FAST
 667
 668 #
 669 # Kernel version 4.7-rc1 commit 8f6fd83c6c5ec66a4a70c728535ddcdfef4f3697
 670 # added 3rd arg to rhashtable_walk_init
 671 #
 672 AC_DEFUN([LIBCFS_RHASHTABLE_WALK_INIT_3ARG], [
 673 LB_CHECK_COMPILE([if 'rhashtable_walk_init' has 3 args],
 674 rhashtable_walk_init, [
 675         #include <linux/gfp.h>
 676         #include <linux/rhashtable.h>
 677 ],[
 678         rhashtable_walk_init(NULL, NULL, GFP_KERNEL);
 679 ],[
 680         AC_DEFINE(HAVE_3ARG_RHASHTABLE_WALK_INIT, 1,
 681                 [rhashtable_walk_init() has 3 args])
 682 ])
 683 ]) # LIBCFS_RHASHTABLE_WALK_INIT_3ARG
 684
 685 #
 686 # Kernel version 4.8-rc6 commit ca26893f05e86497a86732768ec53cd38c0819ca
 687 # introduced rhashtable_lookup
 688 #
 689 AC_DEFUN([LIBCFS_RHASHTABLE_LOOKUP], [
 690 LB_CHECK_COMPILE([if 'rhashtable_lookup' exist],
 691 rhashtable_lookup, [
 692         #include <linux/rhashtable.h>
 693 ],[
 694         const struct rhashtable_params params = { 0 };
 695         void *ret;
 696
 697         ret = rhashtable_lookup(NULL, NULL, params);
 698 ],[
 699         AC_DEFINE(HAVE_RHASHTABLE_LOOKUP, 1,
 700                 [rhashtable_lookup() is available])
 701 ])
 702 ]) # LIBCFS_RHASHTABLE_LOOKUP
 703
 704 #
 705 # LIBCFS_RHLTABLE
 706 # Kernel version 4.8-rc6 commit ca26893f05e86497a86732768ec53cd38c0819ca
 707 # created the rhlist interface to allow inserting duplicate objects
 708 # into the same table.
 709 #
 710 AC_DEFUN([LIBCFS_RHLTABLE], [
 711 LB_CHECK_COMPILE([does 'struct rhltable' exist],
 712 rhtable, [
 713         #include <linux/rhashtable.h>
 714 ],[
 715         struct rhltable *hlt;
 716
 717         rhltable_destroy(hlt);
 718 ],[
 719         AC_DEFINE(HAVE_RHLTABLE, 1,
 720                   [struct rhltable exist])
 721 ])
 722 ]) # LIBCFS_RHLTABLE
 723
 724 #
 725 # LIBCFS_STACKTRACE_OPS
 726 #
 727 # Kernel version 4.8 commit c8fe4609827aedc9c4b45de80e7cdc8ccfa8541b
 728 # removed both struct stacktrace_ops and dump_trace() function
 729 #
 730 AC_DEFUN([LIBCFS_STACKTRACE_OPS], [
 731 LB_CHECK_COMPILE([if 'struct stacktrace_ops' exists],
 732 stacktrace_ops, [
 733         struct task_struct;
 734         struct pt_regs;
 735         #include <asm/stacktrace.h>
 736 ],[
 737         struct stacktrace_ops ops;
 738         ops.stack = NULL;
 739 ],[
 740         AC_DEFINE(HAVE_STACKTRACE_OPS, 1,
 741                 [struct stacktrace_ops exists])
 742 ])
 743 ]) # LIBCFS_STACKTRACE_OPS
 744
 745 #
 746 # Kernel version 4.9-rc1 commit 246779dd090bd1b74d2652b3a6ca7759f593b27a
 747 # introduced rhashtable_walk_enter
 748 #
 749 AC_DEFUN([LIBCFS_RHASHTABLE_WALK_ENTER], [
 750 LB_CHECK_COMPILE([if 'rhashtable_walk_enter' exists],
 751 rhashtable_walk_enter, [
 752         #include <linux/rhashtable.h>
 753 ],[
 754         rhashtable_walk_enter(NULL, NULL);
 755 ],[
 756         AC_DEFINE(HAVE_RHASHTABLE_WALK_ENTER, 1,
 757                 [rhashtable_walk_enter() is available])
 758 ])
 759 ]) # LIBCFS_RHASHTABLE_WALK_ENTER
 760
 761 #
 762 # Kernel version 4.9 commit 768ae309a96103ed02eb1e111e838c87854d8b51
 763 # mm: replace get_user_pages() write/force parameters with gup_flags
 764 #
 765 AC_DEFUN([LIBCFS_GET_USER_PAGES_GUP_FLAGS], [
 766 LB_CHECK_COMPILE([if 'get_user_pages()' takes gup_flags in arguments],
 767 get_user_pages_gup_flags, [
 768         #include <linux/mm.h>
 769 ],[
 770         int rc;
 771         rc = get_user_pages(0, 0, FOLL_WRITE, NULL, NULL);
 772 ],[
 773         AC_DEFINE(HAVE_GET_USER_PAGES_GUP_FLAGS, 1,
 774                 [get_user_pages takes gup_flags in arguments])
 775 ])
 776 ]) # LIBCFS_GET_USER_PAGES_GUP_FLAGS
 777
 778 #
 779 # Kernel version 4.10 commit 7b737965b33188bd3dbb44e938535c4006d97fbb
 780 # libcfs: Convert to hotplug state machine
 781 #
 782 AC_DEFUN([LIBCFS_HOTPLUG_STATE_MACHINE], [
 783 LB_CHECK_COMPILE([if libcfs supports CPU hotplug state machine],
 784 cpu_hotplug_state_machine, [
 785         #include <linux/cpuhotplug.h>
 786 ],[
 787         cpuhp_remove_state(CPUHP_LUSTRE_CFS_DEAD);
 788 ],[
 789         AC_DEFINE(HAVE_HOTPLUG_STATE_MACHINE, 1,
 790                 [hotplug state machine is supported])
 791 ])
 792 ]) # LIBCFS_HOTPLUG_STATE_MACHINE
 793
 794 #
 795 # Kernel version 4.10-rc3 commit f405df5de3170c00e5c54f8b7cf4766044a032ba
 796 # introduced refcount_t which is atomic_t plus over flow guards.
 797 #
 798 AC_DEFUN([LIBCFS_REFCOUNT_T], [
 799 tmp_flags="$EXTRA_KCFLAGS"
 800 EXTRA_KCFLAGS="-Werror"
 801 LB_CHECK_LINUX_HEADER([linux/refcount.h], [
 802         AC_DEFINE(HAVE_REFCOUNT_T, 1,
 803                 [refcount_t is supported])
 804 ])
 805 EXTRA_KCFLAGS="$tmp_flags"
 806 ]) # LIBCFS_REFCOUNT_T
 807
 808 #
 809 # Kernel version 4.12 commit 499118e966f1d2150bd66647c8932343c4e9a0b8
 810 # introduce memalloc_noreclaim_{save,restore}
 811 #
 812 AC_DEFUN([LIBCFS_MEMALLOC_NORECLAIM], [
 813 LB_CHECK_COMPILE([if memalloc_noreclaim_{save,restore} exist],
 814 memalloc_noreclaim, [
 815         #include <linux/sched/mm.h>
 816 ],[
 817         int flag = memalloc_noreclaim_save();
 818         memalloc_noreclaim_restore(flag);
 819 ],[
 820         AC_DEFINE(HAVE_MEMALLOC_RECLAIM, 1,
 821                 [memalloc_noreclaim_{save,restore}() is supported])
 822 ])
 823 ]) # LIBCFS_MEMALLOC_NORECLAIM
 824
 825 #
 826 # LIBCFS_SCHED_HEADERS
 827 #
 828 # 4.11 has broken up sched.h into more headers.
 829 #
 830 AC_DEFUN([LIBCFS_SCHED_HEADERS], [
 831 LB_CHECK_LINUX_HEADER([linux/sched/signal.h], [
 832         AC_DEFINE(HAVE_SCHED_HEADERS, 1,
 833                 [linux/sched header directory exist])])
 834 ]) # LIBCFS_SCHED_HEADERS
 835
 836 #
 837 # Kernel version 4.11-rc1 commit 2c935bc57221cc2edc787c72ea0e2d30cdcd3d5e
 838 # introduce kref_read
 839 #
 840 AC_DEFUN([LIBCFS_KREF_READ], [
 841 LB_CHECK_COMPILE([if 'kref_read' exists],
 842 kref_read, [
 843         #include <linux/kref.h>
 844 ],[
 845         kref_read(NULL);
 846 ],[
 847         AC_DEFINE(HAVE_KREF_READ, 1,
 848                 [kref_read() is available])
 849 ])
 850 ]) # LIBCFS_KREF_READ
 851
 852 #
 853 # Kernel version 4.11-rc1 commit da20420f83ea0fbcf3d03afda08d971ea1d8a356
 854 # introduced rht_bucket_var
 855 #
 856 AC_DEFUN([LIBCFS_RHT_BUCKET_VAR], [
 857 LB_CHECK_COMPILE([if 'rht_bucket_var' exists],
 858 rht_bucket_var, [
 859         #include <linux/rhashtable.h>
 860 ],[
 861
 862         rht_bucket_var(NULL, 0);
 863 ],[
 864         AC_DEFINE(HAVE_RHT_BUCKET_VAR, 1,
 865                 [rht_bucket_var() is available])
 866 ])
 867 ]) # LIBCFS_RHT_BUCKET_VAR
 868
 869 #
 870 # Kernel version 4.11-rc5 commit fceb6435e85298f747fee938415057af837f5a8a
 871 # began the enhanchement of Netlink with extended ACK struct for advanced
 872 # error handling. By commit 7ab606d1609dd6dfeae9c8ad0a8a4e051d831e46 we
 873 # had full support for this new feature.
 874 #
 875 AC_DEFUN([LIBCFS_NL_EXT_ACK], [
 876 LB_CHECK_COMPILE([if Netlink supports netlink_ext_ack],
 877 netlink_ext_ack, [
 878         #include <net/genetlink.h>
 879 ],[
 880         struct genl_info info;
 881
 882         info.extack = NULL;
 883 ],[
 884         AC_DEFINE(HAVE_NL_PARSE_WITH_EXT_ACK, 1,
 885                 [netlink_ext_ack is an argument to nla_parse type function])
 886 ])
 887 ]) # LIBCFS_NL_EXT_ACK
 888
 889 #
 890 # Kernel version 4.11 commit f9fe1c12d126f9887441fa5bb165046f30ddd4b5
 891 # introduced rhashtable_lookup_get_insert_fast
 892 #
 893 AC_DEFUN([LIBCFS_RHASHTABLE_LOOKUP_GET_INSERT_FAST], [
 894 LB_CHECK_COMPILE([if 'rhashtable_lookup_get_insert_fast' exist],
 895 rhashtable_lookup_get_insert_fast, [
 896         #include <linux/rhashtable.h>
 897 ],[
 898         const struct rhashtable_params params = { 0 };
 899         void *ret;
 900
 901         ret = rhashtable_lookup_get_insert_fast(NULL, NULL, params);
 902 ],[
 903         AC_DEFINE(HAVE_RHASHTABLE_LOOKUP_GET_INSERT_FAST, 1,
 904                 [rhashtable_lookup_get_insert_fast() is available])
 905 ])
 906 ]) # LIBCFS_RHASHTABLE_LOOKUP_GET_INSERT_FAST
 907
 908 #
 909 # Kernel version 4.12-rc2 8f553c498e1772cccb39a114da4a498d22992758
 910 # provide proper CPU hotplug locking
 911 #
 912 AC_DEFUN([LIBCFS_CPUS_READ_LOCK], [
 913 LB_CHECK_COMPILE([if 'cpus_read_[un]lock' exist],
 914 cpu_read_lock, [
 915         #include <linux/cpu.h>
 916 ],[
 917         cpus_read_lock();
 918         cpus_read_unlock();
 919 ],[
 920         AC_DEFINE(HAVE_CPUS_READ_LOCK, 1, ['cpus_read_lock' exist])
 921 ])
 922 ]) # LIBCFS_CPUS_READ_LOCK
 923
 924 #
 925 # Kernel version 4.12-rc3 f9727a17db9bab71ddae91f74f11a8a2f9a0ece6
 926 # renamed uuid_be to uuid_t
 927 #
 928 AC_DEFUN([LIBCFS_UUID_T], [
 929 LB_CHECK_COMPILE([if 'uuid_t' exist],
 930 uuid_t, [
 931         #include <linux/uuid.h>
 932 ],[
 933         uuid_t uuid;
 934
 935         memset(uuid.b, 0, 16);
 936 ],[
 937         AC_DEFINE(HAVE_UUID_T, 1, ['uuid_t' exist])
 938 ])
 939 ]) # LIBCFS_UUID_T
 940
 941 #
 942 # Kernel version 4.12-rc3 commit fd851a3cdc196bfc1d229b5f22369069af532bf8
 943 # introduce processor.h
 944 #
 945 AC_DEFUN([LIBCFS_HAVE_PROCESSOR_HEADER], [
 946 tmp_flags="$EXTRA_KCFLAGS"
 947 EXTRA_KCFLAGS="-Werror"
 948 LB_CHECK_LINUX_HEADER([linux/processor.h], [
 949         AC_DEFINE(HAVE_PROCESSOR_H, 1,
 950                 [processor.h is present])
 951 ])
 952 EXTRA_KCFLAGS="$tmp_flags"
 953 ]) # LIBCFS_HAVE_PROCESSOR_HEADER
 954
 955 #
 956 # Kernel verison 4.12-rc6 commit 5dd43ce2f69d42a71dcacdb13d17d8c0ac1fe8f7
 957 # created wait_bit.h
 958 #
 959 AC_DEFUN([LIBCFS_HAVE_WAIT_BIT_HEADER], [
 960 LB_CHECK_LINUX_HEADER([linux/wait_bit.h], [
 961         AC_DEFINE(HAVE_WAIT_BIT_HEADER_H, 1,
 962                 [wait_bit.h is present])])
 963 ]) # LIBCFS_HAVE_WAIT_BIT_HEADER
 964
 965 #
 966 # Kernel version 4.12-rc6 commmit 2055da97389a605c8a00d163d40903afbe413921
 967 # changed:
 968 #       struct wait_queue_head::task_list       => ::head
 969 #       struct wait_queue_entry::task_list      => ::entry
 970 #
 971 AC_DEFUN([LIBCFS_WAIT_QUEUE_TASK_LIST_RENAME], [
 972 LB_CHECK_COMPILE([if linux wait_queue_head list_head is named head],
 973 wait_queue_task_list, [
 974         #include <linux/wait.h>
 975 ],[
 976         wait_queue_head_t e;
 977
 978         INIT_LIST_HEAD(&e.head);
 979 ],[
 980         AC_DEFINE(HAVE_WAIT_QUEUE_ENTRY_LIST, 1,
 981                 [linux wait_queue_head_t list_head is name head])
 982 ])
 983 ]) # LIBCFS_WAIT_QUEUE_TASK_LIST_RENAME
 984
 985 #
 986 # LIBCFS_NLA_STRDUP
 987 #
 988 # Kernel version 4.13-rc1 commit 2cf0c8b3e6942ecafe6ebb1a6d0328a81641bf39
 989 # created nla_strdup(). This is needed since push strings can be
 990 # any size.
 991 #
 992 AC_DEFUN([LIBCFS_NLA_STRDUP], [
 993 LB_CHECK_COMPILE([if 'nla_strdup()' exists],
 994 nla_strdup, [
 995         #include <net/netlink.h>
 996 ],[
 997         char *tmp = nla_strdup(NULL, GFP_KERNEL);
 998 ],[
 999         AC_DEFINE(HAVE_NLA_STRDUP, 1,
1000                 ['nla_strdup' is available])
1001 ])
1002 ]) # LIBCFS_NLA_STRDUP
1003
1004 #
1005 # LIBCFS_WAIT_QUEUE_ENTRY
1006 #
1007 # Kernel version 4.13 ac6424b981bce1c4bc55675c6ce11bfe1bbfa64f
1008 # Rename wait_queue_t => wait_queue_entry_t
1009 #
1010 AC_DEFUN([LIBCFS_WAIT_QUEUE_ENTRY], [
1011 LB_CHECK_COMPILE([if 'wait_queue_entry_t' exists],
1012 wait_queue_entry, [
1013         #include <linux/wait.h>
1014 ],[
1015         wait_queue_entry_t e;
1016
1017         e.flags = 0;
1018 ],[
1019         AC_DEFINE(HAVE_WAIT_QUEUE_ENTRY, 1,
1020                 ['wait_queue_entry_t' is available])
1021 ])
1022 ]) # LIBCFS_WAIT_QUEUE_ENTRY
1023
1024 #
1025 # LIBCFS_NEW_KERNEL_WRITE
1026 #
1027 # Kernel version 4.14 e13ec939e96b13e664bb6cee361cc976a0ee621a
1028 # changed kernel_write prototype to make is plug compatible
1029 # with the unexported vfs_write()
1030 #
1031 AC_DEFUN([LIBCFS_NEW_KERNEL_WRITE], [
1032 tmp_flags="$EXTRA_KCFLAGS"
1033 EXTRA_KCFLAGS="-Werror"
1034 LB_CHECK_COMPILE([if 'kernel_write' matches other read/write helpers],
1035 kernel_write_match, [
1036         #include <linux/fs.h>
1037 ],[
1038         const void *buf = NULL;
1039         loff_t pos = 0;
1040         return kernel_write(NULL, buf, 0, &pos);
1041 ],[
1042         AC_DEFINE(HAVE_NEW_KERNEL_WRITE, 1,
1043                 ['kernel_write' aligns with read/write helpers])
1044 ])
1045 EXTRA_KCFLAGS="$tmp_flags"
1046 ]) # LIBCFS_NEW_KERNEL_WRITE
1047
1048 #
1049 # LIBCFS_MM_TOTALRAM_PAGES_FUNC
1050 #
1051 # kernel 5.0 commit ca79b0c211af63fa3276f0e3fd7dd9ada2439839
1052 # mm: convert totalram_pages and totalhigh_pages variables to atomic
1053 #
1054 AC_DEFUN([LIBCFS_MM_TOTALRAM_PAGES_FUNC], [
1055 tmp_flags="$EXTRA_KCFLAGS"
1056 EXTRA_KCFLAGS="-Werror"
1057 LB_CHECK_COMPILE([if totalram_pages is a function],
1058 totalram_pages, [
1059         #include <linux/mm.h>
1060 ],[
1061         totalram_pages_inc();
1062 ],[
1063         AC_DEFINE(HAVE_TOTALRAM_PAGES_AS_FUNC, 1,
1064                 [if totalram_pages is a function])
1065 ])
1066 EXTRA_KCFLAGS="$tmp_flags"
1067 ]) # LIBCFS_MM_TOTALRAM_PAGES_FUNC
1068
1069 #
1070 # LIBCFS_NEW_KERNEL_READ
1071 #
1072 # 4.14 commit bdd1d2d3d251c65b74ac4493e08db18971c09240 changed
1073 # the signature of kernel_read to match other read/write helpers
1074 # and place offset last.
1075 #
1076 AC_DEFUN([LIBCFS_NEW_KERNEL_READ], [
1077 tmp_flags="$EXTRA_KCFLAGS"
1078 EXTRA_KCFLAGS="-Werror"
1079 LB_CHECK_COMPILE([if 'kernel_read()' has loff_t *pos as last parameter],
1080 kernel_read, [
1081         #include <linux/fs.h>
1082         ],[
1083         loff_t pos = 0;
1084         kernel_read(NULL, NULL, 0, &pos);
1085 ],[
1086         AC_DEFINE(HAVE_KERNEL_READ_LAST_POSP, 1,
1087                 [kernel_read() signature ends with loff_t *pos])
1088 ])
1089 EXTRA_KCFLAGS="$tmp_flags"
1090 ]) # LIBCFS_NEW_KERNEL_READ
1091
1092 #
1093 # LIBCFS_DEFINE_TIMER
1094 #
1095 # Kernel version 4.14 commit 1d27e3e2252ba9d949ca82fbdb73cde102cb2067
1096 # remove expires and data arguments from DEFINE_TIMER. Also the callback
1097 # when from using unsigned long argument to using struct timer_list pointer.
1098 #
1099 AC_DEFUN([LIBCFS_DEFINE_TIMER], [
1100 LB_CHECK_COMPILE([if DEFINE_TIMER takes only 2 arguments],
1101 define_timer, [
1102         #include <linux/timer.h>
1103 ],[
1104         static DEFINE_TIMER(my_timer, NULL);
1105 ],[
1106         AC_DEFINE(HAVE_NEW_DEFINE_TIMER, 1,
1107                 [DEFINE_TIMER uses only 2 arguements])
1108 ])
1109 ]) # LIBCFS_DEFINE_TIMER
1110
1111 #
1112 # LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK
1113 #
1114 # Kernel 2.6.27 commit 8594698ebddeef5443b7da8258ae33b3eaca61d5
1115 # exported save_stack_trace_tsk for x86.
1116 # Kernel 2.6.27 commit 01f4b8b8b8db09b88be7df7e51192e4e678b69d3
1117 # exported save_stack_trace_tsk for powerpc
1118 # Kernel 4.13 commit e27c7fa015d61c8be6a2c32b2144aad2ae6ec975
1119 # exported save_stack_trace_tsk for arm64
1120 # Kernel 4.14 commit 9a3dc3186fc3795e076a4122da9e0258651a9631
1121 # exported save_stack_trace_tsk for arm
1122 #
1123 AC_DEFUN([LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK], [
1124 LB_CHECK_EXPORT([save_stack_trace_tsk], [arch/$SUBARCH/kernel/stacktrace.c],
1125         [AC_DEFINE(HAVE_SAVE_STACK_TRACE_TSK, 1,
1126                 [save_stack_trace_tsk is exported])])
1127 ]) # LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK
1128
1129 #
1130 # LIBCFS_LOCKDEP_IS_HELD
1131 #
1132 # Kernel v4.15-rc8-106-g08f36ff64234
1133 # lockdep: Make lockdep checking constant
1134 #
1135 AC_DEFUN([LIBCFS_LOCKDEP_IS_HELD], [
1136 tmp_flags="$EXTRA_KCFLAGS"
1137 EXTRA_KCFLAGS="-Werror"
1138 LB_CHECK_COMPILE([if 'lockdep_is_held()' uses const argument],
1139 lockdep_is_held, [
1140         #include <linux/lockdep.h>
1141 ],[
1142 #ifdef CONFIG_LOCKDEP
1143         const struct spinlock *lock = NULL;
1144
1145         lockdep_is_held(lock);
1146 #endif
1147 ],[],[
1148         AC_DEFINE(NEED_LOCKDEP_IS_HELD_DISCARD_CONST, 1,
1149                 [lockdep_is_held() argument is const])
1150 ])
1151 EXTRA_KCFLAGS="$tmp_flags"
1152 ]) # LIBCFS_LOCKDEP_IS_HELD
1153
1154 #
1155 # LIBCFS_TIMER_SETUP
1156 #
1157 # Kernel version 4.15 commit e99e88a9d2b067465adaa9c111ada99a041bef9a
1158 # setup_timer() was replaced by timer_setup(), where the callback
1159 # argument is the structure already holding the struct timer_list.
1160 #
1161 AC_DEFUN([LIBCFS_TIMER_SETUP], [
1162 LB_CHECK_COMPILE([if setup_timer has been replaced with timer_setup],
1163 timer_setup, [
1164         #include <linux/timer.h>
1165 ],[
1166         timer_setup(NULL, NULL, 0);
1167 ],[
1168         AC_DEFINE(HAVE_TIMER_SETUP, 1,
1169                 [timer_setup has replaced setup_timer])
1170 ])
1171 ]) # LIBCFS_TIMER_SETUP
1172
1173 #
1174 # LIBCFS_WAIT_VAR_EVENT
1175 #
1176 # Kernel version 4.16-rc4 commit 6b2bb7265f0b62605e8caee3613449ed0db270b9
1177 # added wait_var_event()
1178 #
1179 AC_DEFUN([LIBCFS_WAIT_VAR_EVENT], [
1180 LB_CHECK_COMPILE([if 'wait_var_event' exist],
1181 wait_var_event, [
1182         #ifdef HAVE_WAIT_BIT_HEADER_H
1183         #include <linux/wait_bit.h>
1184         #endif
1185         #include <linux/wait.h>
1186 ],[
1187         wake_up_var(NULL);
1188 ],[
1189         AC_DEFINE(HAVE_WAIT_VAR_EVENT, 1,
1190                 ['wait_var_event' is available])
1191 ])
1192 ]) # LIBCFS_WAIT_VAR_EVENT
1193
1194 #
1195 # LIBCFS_BITMAP_ALLOC
1196 #
1197 # Kernel version 4.17 commit c42b65e363ce97a828f81b59033c3558f8fa7f70
1198 # added bitmap memory allocation handling.
1199 #
1200 AC_DEFUN([LIBCFS_BITMAP_ALLOC], [
1201 LB_CHECK_COMPILE([if Linux bitmap memory management exist],
1202 bitmap_alloc, [
1203         #include <linux/bitmap.h>
1204 ],[
1205         unsigned long *map = bitmap_alloc(1, GFP_KERNEL);
1206 ],[
1207         AC_DEFINE(HAVE_BITMAP_ALLOC, 1,
1208                 [Linux bitmap can be allocated])
1209 ])
1210 ]) # LIBCFS_BITMAP_ALLOC
1211
1212 #
1213 # LIBCFS_CLEAR_AND_WAKE_UP_BIT
1214 #
1215 # Kernel version 4.17-rc2 commit 8236b0ae31c837d2b3a2565c5f8d77f637e824cc
1216 # added clear_and_wake_up_bit()
1217 #
1218 AC_DEFUN([LIBCFS_CLEAR_AND_WAKE_UP_BIT], [
1219 LB_CHECK_COMPILE([if 'clear_and_wake_up_bit' exist],
1220 clear_and_wake_up_bit, [
1221         #ifdef HAVE_WAIT_BIT_HEADER_H
1222         #include <linux/wait_bit.h>
1223         #endif
1224         #include <linux/wait.h>
1225 ],[
1226         clear_and_wake_up_bit(0, NULL);
1227 ],[
1228         AC_DEFINE(HAVE_CLEAR_AND_WAKE_UP_BIT, 1,
1229                 ['clear_and_wake_up_bit' is available])
1230 ])
1231 ]) # LIBCFS_CLEAR_AND_WAKE_UP_BIT
1232
1233 #
1234 # LIBCFS_TCP_SOCK_SET_NODELAY
1235 #
1236 # kernel 4.18.0-293.el8
1237 # tcp_sock_set_nodelay() was added
1238 AC_DEFUN([LIBCFS_TCP_SOCK_SET_NODELAY], [
1239 tmp_flags="$EXTRA_KCFLAGS"
1240 EXTRA_KCFLAGS="-Werror"
1241 LB_CHECK_COMPILE([if 'tcp_sock_set_nodelay()' exists],
1242 tcp_sock_set_nodelay_exists, [
1243         #include <linux/tcp.h>
1244 ],[
1245         tcp_sock_set_nodelay(NULL);
1246 ],[
1247         AC_DEFINE(HAVE_TCP_SOCK_SET_NODELAY, 1,
1248                 ['tcp_sock_set_nodelay()' exists])
1249 ])
1250 EXTRA_KCFLAGS="$tmp_flags"
1251 ]) # LIBCFS_TCP_SOCK_SET_NODELAY
1252
1253 #
1254 # LIBCFS_TCP_SOCK_SET_KEEPIDLE
1255 #
1256 # kernel 4.18.0-293.el8
1257 # tcp_sock_set_keepidle() was added
1258 AC_DEFUN([LIBCFS_TCP_SOCK_SET_KEEPIDLE], [
1259 tmp_flags="$EXTRA_KCFLAGS"
1260 EXTRA_KCFLAGS="-Werror"
1261 LB_CHECK_COMPILE([if 'tcp_sock_set_keepidle()' exists],
1262 tcp_sock_set_keepidle_exists, [
1263         #include <linux/tcp.h>
1264 ],[
1265         tcp_sock_set_keepidle(NULL, 0);
1266 ],[
1267         AC_DEFINE(HAVE_TCP_SOCK_SET_KEEPIDLE, 1,
1268                 ['tcp_sock_set_keepidle()' exists])
1269 ])
1270 EXTRA_KCFLAGS="$tmp_flags"
1271 ]) # LIBCFS_TCP_SOCK_SET_KEEPIDLE
1272
1273 #
1274 # LIBCFS_TCP_SOCK_SET_QUICKACK
1275 # kernel v5.7-rc6-2504-gddd061b8daed
1276 #   tcp: add tcp_sock_set_quickack
1277 #
1278 AC_DEFUN([LIBCFS_TCP_SOCK_SET_QUICKACK], [
1279 tmp_flags="$EXTRA_KCFLAGS"
1280 EXTRA_KCFLAGS="-Werror"
1281 LB_CHECK_COMPILE([if 'tcp_sock_set_quickack()' exists],
1282 tcp_sock_set_quickack_exists, [
1283         #include <linux/tcp.h>
1284 ],[
1285         tcp_sock_set_quickack(NULL, 0);
1286 ],[
1287         AC_DEFINE(HAVE_TCP_SOCK_SET_QUICKACK, 1,
1288                 ['tcp_sock_set_quickack()' exists])
1289 ])
1290 EXTRA_KCFLAGS="$tmp_flags"
1291 ]) # LIBCFS_TCP_SOCK_SET_QUICKACK
1292
1293 #
1294 # LIBCFS_TCP_SOCK_SET_KEEPINTVL
1295 # v5.7-rc6-2508-gd41ecaac903c
1296 # tcp: add tcp_sock_set_keepintvl
1297 #
1298 AC_DEFUN([LIBCFS_TCP_SOCK_SET_KEEPINTVL], [
1299 tmp_flags="$EXTRA_KCFLAGS"
1300 EXTRA_KCFLAGS="-Werror"
1301 LB_CHECK_COMPILE([if 'tcp_sock_set_keepintvl()' exists],
1302 tcp_sock_set_keepintvl_exists, [
1303         #include <linux/tcp.h>
1304 ],[
1305         tcp_sock_set_keepintvl(NULL, 0);
1306 ],[
1307         AC_DEFINE(HAVE_TCP_SOCK_SET_KEEPINTVL, 1,
1308                 ['tcp_sock_set_keepintvl()' exists])
1309 ])
1310 EXTRA_KCFLAGS="$tmp_flags"
1311 ]) # LIBCFS_TCP_SOCK_SET_KEEPINTVL
1312
1313 #
1314 # LIBCFS_TCP_SOCK_SET_KEEPCNT
1315 # v5.7-rc6-2509-g480aeb9639d6
1316 # tcp: add tcp_sock_set_keepcnt
1317 #
1318 AC_DEFUN([LIBCFS_TCP_SOCK_SET_KEEPCNT], [
1319 tmp_flags="$EXTRA_KCFLAGS"
1320 EXTRA_KCFLAGS="-Werror"
1321 LB_CHECK_COMPILE([if 'tcp_sock_set_keepcnt()' exists],
1322 tcp_sock_set_keepcnt_exists, [
1323         #include <linux/tcp.h>
1324 ],[
1325         tcp_sock_set_keepcnt(NULL, 0);
1326 ],[
1327         AC_DEFINE(HAVE_TCP_SOCK_SET_KEEPCNT, 1,
1328                 ['tcp_sock_set_keepcnt()' exists])
1329 ])
1330 EXTRA_KCFLAGS="$tmp_flags"
1331 ]) # LIBCFS_TCP_SOCK_SET_KEEPCNT
1332
1333 #
1334 # LIBCFS_XARRAY_SUPPORT
1335 #
1336 # 4.19-rc5 kernel commit 3159f943aafdbacb2f94c38fdaadabf2bbde2a14
1337 # replaced the radix tree implementation with Xarrays. This change
1338 # introduced functionaly needed for general Xarray support
1339 #
1340 AC_DEFUN([LIBCFS_XARRAY_SUPPORT], [
1341 tmp_flags="$EXTRA_KCFLAGS"
1342 EXTRA_KCFLAGS="-Werror"
1343 LB_CHECK_COMPILE([if page cache uses Xarray],
1344 xarray_support, [
1345         #include <linux/xarray.h>
1346 ],[
1347         xa_is_value(NULL);
1348 ],[
1349         AC_DEFINE(HAVE_XARRAY_SUPPORT, 1,
1350                 [kernel Xarray implementation lacks 'xa_is_value'])
1351 ])
1352 EXTRA_KCFLAGS="$tmp_flags"
1353 ]) # LIBCFS_XARRAY_SUPPORT
1354
1355 #
1356 # Kernel version 4.19-rc6 commit 4a19edb60d0203cd5bf95a8b46ea8f63fd41194c
1357 # added extended ACK handling to Netlink dump handlers
1358 #
1359 AC_DEFUN([LIBCFS_NL_DUMP_EXT_ACK], [
1360 LB_CHECK_COMPILE([if Netlink dump handlers support ext_ack],
1361 netlink_dump_ext_ack, [
1362         #include <net/netlink.h>
1363 ],[
1364         struct netlink_callback *cb = NULL;
1365         cb->extack = NULL;
1366 ],[
1367         AC_DEFINE(HAVE_NL_DUMP_WITH_EXT_ACK, 1,
1368                 [netlink_ext_ack is handled for Netlink dump handlers])
1369 ])
1370 ]) # LIBCFS_NL_DUMP_EXT_ACK
1371
1372 #
1373 # LIBCFS_HAVE_IOV_ITER_TYPE
1374 #
1375 # kernel 4.20 commit 00e23707442a75b404392cef1405ab4fd498de6b
1376 # iov_iter: Use accessor functions to access an iterator's type and direction.
1377 #
1378 AC_DEFUN([LIBCFS_HAVE_IOV_ITER_TYPE], [
1379 tmp_flags="$EXTRA_KCFLAGS"
1380 EXTRA_KCFLAGS="-Werror"
1381 LB_CHECK_COMPILE([if iov_iter_type exists],
1382 macro_iov_iter_type_exists, [
1383         #include <linux/uio.h>
1384 ],[
1385         struct iov_iter iter = { .type = ITER_KVEC };
1386         enum iter_type type = iov_iter_type(&iter);
1387         (void)type;
1388 ],[
1389         AC_DEFINE(HAVE_IOV_ITER_TYPE, 1,
1390                 [if iov_iter_type exists])
1391 ])
1392 EXTRA_KCFLAGS="$tmp_flags"
1393 ]) # LIBCFS_HAVE_IOV_ITER_TYPE
1394
1395 #
1396 # LIBCFS_GET_REQUEST_KEY_AUTH
1397 #
1398 # kernel 5.0 commit 822ad64d7e46a8e2c8b8a796738d7b657cbb146d
1399 # keys: Fix dependency loop between construction record and auth key
1400 #
1401 # Added <keys/request_key_auth-type.h> and get_request_key_auth()
1402 # which was propagated to stable
1403 #
1404 AC_DEFUN([LIBCFS_GET_REQUEST_KEY_AUTH], [
1405 tmp_flags="$EXTRA_KCFLAGS"
1406 EXTRA_KCFLAGS="-Werror"
1407 LB_CHECK_COMPILE([if get_request_key_auth() is available],
1408 get_request_key_auth_exported, [
1409         #include <linux/key.h>
1410         #include <linux/keyctl.h>
1411         #include <keys/request_key_auth-type.h>
1412 ],[
1413         struct key *ring;
1414         const struct key *key = NULL;
1415         struct request_key_auth *rka = get_request_key_auth(key);
1416
1417         ring = key_get(rka->dest_keyring);
1418 ],[
1419         AC_DEFINE(HAVE_GET_REQUEST_KEY_AUTH, 1,
1420                 [get_request_key_auth() is available])
1421 ])
1422 EXTRA_KCFLAGS="$tmp_flags"
1423 ]) # LIBCFS_GET_REQUEST_KEY_AUTH
1424
1425 #
1426 # LIBCFS_LOOKUP_USER_KEY
1427 #
1428 # kernel 5.3 commit 3cf5d076fb4d48979f382bc9452765bf8b79e740
1429 # signal: Remove task parameter from force_sig
1430 #
1431 AC_DEFUN([LIBCFS_LOOKUP_USER_KEY], [
1432 tmp_flags="$EXTRA_KCFLAGS"
1433 EXTRA_KCFLAGS="-Werror"
1434 LB_CHECK_COMPILE([if lookup_user_key() is available],
1435 lookup_user_key_exported, [
1436         #include <linux/key.h>
1437         #include <linux/keyctl.h>
1438 ],[
1439         lookup_user_key(KEY_SPEC_USER_KEYRING, 0, 0);
1440 ],[
1441         AC_DEFINE(HAVE_LOOKUP_USER_KEY, 1,
1442                 [lookup_user_key() is available])
1443 ])
1444 EXTRA_KCFLAGS="$tmp_flags"
1445 ]) # LIBCFS_LOOKUP_USER_KEY
1446
1447 #
1448 # LIBCFS_FORCE_SIG_WITH_TASK
1449 #
1450 # kernel 5.3 commit 3cf5d076fb4d48979f382bc9452765bf8b79e740
1451 # signal: Remove task parameter from force_sig
1452 #
1453 AC_DEFUN([LIBCFS_FORCE_SIG_WITH_TASK], [
1454 tmp_flags="$EXTRA_KCFLAGS"
1455 EXTRA_KCFLAGS="-Werror"
1456 LB_CHECK_COMPILE([if force_sig has task parameter],
1457 force_sig_with_task, [
1458         #include <linux/sched/signal.h>
1459 ],[
1460         force_sig(SIGINT, NULL);
1461 ],[
1462         AC_DEFINE(HAVE_FORCE_SIG_WITH_TASK, 1,
1463                 [force_sig() has task parameter])
1464 ])
1465 EXTRA_KCFLAGS="$tmp_flags"
1466 ]) # LIBCFS_FORCE_SIG_WITH_TASK
1467
1468 #
1469 # LIBCFS_CACHE_DETAIL_WRITERS
1470 #
1471 # kernel v5.3-rc2-1-g64a38e840ce5
1472 # SUNRPC: Track writers of the 'channel' file to improve cache_listeners_exist
1473 #
1474 AC_DEFUN([LIBCFS_CACHE_DETAIL_WRITERS], [
1475 tmp_flags="$EXTRA_KCFLAGS"
1476 EXTRA_KCFLAGS="-Werror"
1477 LB_CHECK_COMPILE([if struct cache_detail has writers],
1478 cache_detail_writers_atomic, [
1479         #include <linux/sunrpc/cache.h>
1480
1481         static struct cache_detail rsi_cache;
1482 ],[
1483         atomic_set(&rsi_cache.writers, 0);
1484 ],[
1485         AC_DEFINE(HAVE_CACHE_DETAIL_WRITERS, 1,
1486                 [struct cache_detail has writers])
1487 ])
1488 EXTRA_KCFLAGS="$tmp_flags"
1489 ]) # LIBCFS_CACHE_DETAIL_WRITERS
1490
1491 #
1492 # LIBCFS_KALLSYMS_LOOKUP
1493 #
1494 # kernel v5.6-11591-g0bd476e6c671
1495 # kallsyms: unexport kallsyms_lookup_name() and kallsyms_on_each_symbol()
1496 AC_DEFUN([LIBCFS_KALLSYMS_LOOKUP], [
1497 LB_CHECK_EXPORT([kallsyms_lookup_name], [kernel/kallsyms.c],
1498         [AC_DEFINE(HAVE_KALLSYMS_LOOKUP_NAME, 1,
1499                 [kallsyms_lookup_name is exported by kernel])])
1500 ]) # LIBCFS_KALLSYMS_LOOKUP
1501
1502 #
1503 # v5.5-8862-gd56c0d45f0e2
1504 # proc: decouple proc from VFS with "struct proc_ops"
1505 #
1506 AC_DEFUN([LIBCFS_SRC_HAVE_PROC_OPS], [
1507         LB2_LINUX_TEST_SRC([proc_ops], [
1508                 #include <linux/proc_fs.h>
1509
1510                 static struct proc_ops *my_proc;
1511         ],[
1512                 my_proc->proc_lseek = NULL;
1513         ],[-Werror])
1514 ]) # LIBCFS_SRC_HAVE_PROC_OPS
1515 AC_DEFUN([LIBCFS_HAVE_PROC_OPS], [
1516         AC_MSG_CHECKING([if struct proc_ops exists])
1517         LB2_LINUX_TEST_RESULT([proc_ops], [
1518                 AC_DEFINE(HAVE_PROC_OPS, 1,
1519                         [struct proc_ops exists])
1520                 AC_MSG_RESULT(yes)
1521         ],[
1522                 AC_MSG_RESULT(no)
1523         ])
1524 ]) # LIBCFS_HAVE_PROC_OPS
1525
1526 #
1527 # LIBCFS_VMALLOC_2ARGS
1528 #
1529 # kernel v5.8-rc1~201^2~19
1530 # mm: remove the pgprot argument to __vmalloc
1531 AC_DEFUN([LIBCFS_VMALLOC_2ARGS], [
1532 LB_CHECK_COMPILE([if __vmalloc has 2 args],
1533 vmalloc_2args, [
1534         #include <linux/vmalloc.h>
1535 ],[
1536         __vmalloc(0, 0);
1537 ],[
1538         AC_DEFINE(HAVE_VMALLOC_2ARGS, 1,
1539                 [__vmalloc only takes 2 args.])
1540 ])
1541 ]) # LIBCFS_VMALLOC_2ARGS
1542
1543 #
1544 # LIBCFS_HAVE_NR_UNSTABLE_NFS
1545 #
1546 # kernel v5.8-rc1~201^2~75
1547 # mm/writeback: discard NR_UNSTABLE_NFS, use NR_WRITEBACK instead
1548 #
1549 AC_DEFUN([LIBCFS_HAVE_NR_UNSTABLE_NFS], [
1550 tmp_flags="$EXTRA_KCFLAGS"
1551 EXTRA_KCFLAGS="-Werror"
1552 LB_CHECK_COMPILE([if NR_UNSTABLE_NFS still in use],
1553 nr_unstable_nfs_exists, [
1554         #include <linux/mm.h>
1555
1556         int i;
1557 ],[
1558         i = NR_UNSTABLE_NFS;
1559 ],[
1560         AC_DEFINE(HAVE_NR_UNSTABLE_NFS, 1,
1561                 [NR_UNSTABLE_NFS is still in use.])
1562 ])
1563 EXTRA_KCFLAGS="$tmp_flags"
1564 ]) # LIBCFS_HAVE_NR_UNSTABLE_NFS
1565
1566 #
1567 # LIBCFS_HAVE_MMAP_LOCK
1568 #
1569 # kernel v5.8-rc1~83^2~24
1570 # mmap locking API: rename mmap_sem to mmap_lock
1571 #
1572 AC_DEFUN([LIBCFS_HAVE_MMAP_LOCK], [
1573 LB_CHECK_COMPILE([if mmap_lock API is available],
1574 mmap_write_lock, [
1575         #include <linux/mm.h>
1576 ],[
1577         mmap_write_lock(NULL);
1578 ],[
1579         AC_DEFINE(HAVE_MMAP_LOCK, 1,
1580                 [mmap_lock API is available.])
1581 ])
1582 ]) # LIBCFS_HAVE_MMAP_LOCK
1583
1584 #
1585 # LIBCFS_KERNEL_SETSOCKOPT
1586 #
1587 # kernel v5.8-rc1~165^2~59^2
1588 # net: remove kernel_setsockopt
1589 AC_DEFUN([LIBCFS_KERNEL_SETSOCKOPT], [
1590 tmp_flags="$EXTRA_KCFLAGS"
1591 EXTRA_KCFLAGS="-Werror"
1592 LB_CHECK_COMPILE([if kernel_setsockopt still in use],
1593 kernel_setsockopt_exists, [
1594         #include <linux/net.h>
1595 ],[
1596         kernel_setsockopt(NULL, 0, 0, NULL, 0);
1597 ],[
1598         AC_DEFINE(HAVE_KERNEL_SETSOCKOPT, 1,
1599                 [kernel_setsockopt still in use])
1600 ])
1601 EXTRA_KCFLAGS="$tmp_flags"
1602 ]) # LIBCFS_KERNEL_SETSOCKOPT
1603
1604 #
1605 # LIBCFS_SEC_RELEASE_SECCTX
1606 #
1607 # kernel linux-hwe-5.8 (5.8.0-22.23~20.04.1)
1608 # LSM: Use lsmcontext in security_release_secctx
1609 AC_DEFUN([LIBCFS_SEC_RELEASE_SECCTX], [
1610 LB_CHECK_COMPILE([if security_release_secctx has 1 arg],
1611 security_release_secctx_1arg, [
1612         #include <linux/security.h>
1613 ],[
1614         security_release_secctx(NULL);
1615 ],[
1616         AC_DEFINE(HAVE_SEC_RELEASE_SECCTX_1ARG, 1,
1617                 [security_release_secctx has 1 arg.])
1618 ])
1619 ]) # LIBCFS_SEC_RELEASE_SECCTX
1620
1621 #
1622 # LIBCFS_HAVE_KFREE_SENSITIVE
1623 #
1624 # kernel v5.10-rc1~3
1625 # mm: remove kzfree() compatibility definition
1626 #
1627 AC_DEFUN([LIBCFS_HAVE_KFREE_SENSITIVE], [
1628 LB_CHECK_COMPILE([if kfree_sensitive() is available],
1629 kfree_sensitive_exists, [
1630         #include <linux/slab.h>
1631
1632 ],[
1633         kfree_sensitive(NULL);
1634 ],[
1635         AC_DEFINE(HAVE_KFREE_SENSITIVE, 1,
1636                 [kfree_sensitive() is available.])
1637 ])
1638 EXTRA_KCFLAGS="$tmp_flags"
1639 ]) # LIBCFS_HAVE_KFREE_SENSITIVE
1640
1641 #
1642 # LIBCFS_HAVE_CRYPTO_SHA2_HEADER
1643 #
1644 # Kernel v5.10-rc1-114-ga24d22b225ce
1645 # crypto: sha - split sha.h into sha1.h and sha2.h
1646 #
1647 AC_DEFUN([LIBCFS_HAVE_CRYPTO_SHA2_HEADER], [
1648 LB_CHECK_LINUX_HEADER([crypto/sha2.h], [
1649         AC_DEFINE(HAVE_CRYPTO_SHA2_HEADER, 1,
1650                 [crypto/sha2.h is present])])
1651 ]) # LIBCFS_HAVE_CRYPTO_SHA2_HEADER
1652
1653 AC_DEFUN([LIBCFS_PROG_LINUX_SRC], [
1654         LIBCFS_SRC_HAVE_PROC_OPS
1655
1656         AC_MSG_CHECKING([for available kernel interfaces to libcfs])
1657         LB2_LINUX_TEST_COMPILE_ALL([libcfs])
1658         AC_MSG_RESULT([done])
1659 ])
1660 AC_DEFUN([LIBCFS_PROG_LINUX_RESULTS], [
1661         # 5.6
1662         LIBCFS_HAVE_PROC_OPS
1663 ])
1664
1665 #
1666 # LIBCFS_PROG_LINUX
1667 #
1668 # LibCFS linux kernel checks
1669 #
1670 AC_DEFUN([LIBCFS_PROG_LINUX], [
1671 AC_MSG_NOTICE([LibCFS kernel checks
1672 ==============================================================================])
1673 LIBCFS_CONFIG_PANIC_DUMPLOG
1674
1675 # 3.11
1676 LIBCFS_KTIME_GET_TS64
1677 # 3.12
1678 LIBCFS_PREPARE_TO_WAIT_EVENT
1679 LIBCFS_KERNEL_PARAM_OPS
1680 LIBCFS_KTIME_ADD
1681 LIBCFS_KTIME_AFTER
1682 LIBCFS_KTIME_BEFORE
1683 LIBCFS_KTIME_COMPARE
1684 LIBCFS_SHRINKER_COUNT
1685 # 3.15
1686 LIBCFS_HAVE_MAPPING_AS_EXITING_FLAG
1687 LIBCFS_IOV_ITER_HAS_TYPE
1688 # 3.16
1689 LIBCFS_HAVE_NS_TO_TIMESPEC64
1690 # 3.17
1691 LIBCFS_HLIST_ADD_AFTER
1692 LIBCFS_TIMESPEC64
1693 LIBCFS_KTIME_GET_NS
1694 LIBCFS_KTIME_GET_REAL_TS64
1695 LIBCFS_KTIME_GET_REAL_SECONDS
1696 LIBCFS_KTIME_GET_REAL_NS
1697 LIBCFS_KTIME_TO_TIMESPEC64
1698 LIBCFS_TIMESPEC64_SUB
1699 LIBCFS_TIMESPEC64_TO_KTIME
1700 # 3.19
1701 LIBCFS_KTIME_GET_SECONDS
1702 # 4.0
1703 LIBCFS_KTIME_MS_DELTA
1704 # 4.1
1705 LIBCFS_KERNEL_PARAM_LOCK
1706 # 4.2
1707 LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK
1708 # 4.4
1709 LIBCFS_KSTRTOBOOL_FROM_USER
1710 LIBCFS_NETLINK_CALLBACK_START
1711 # 4.5
1712 LIBCFS_CRYPTO_HASH_HELPERS
1713 LIBCFS_EXPORT_KSET_FIND_OBJ
1714 LIBCFS_RHASHTABLE_REPLACE
1715 # 4.6
1716 LIBCFS_BROKEN_HASH_64
1717 LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
1718 LIBCFS_GET_USER_PAGES_6ARG
1719 LIBCFS_STRINGHASH
1720 # 4.7
1721 LIBCFS_RHASHTABLE_INSERT_FAST
1722 LIBCFS_RHASHTABLE_WALK_INIT_3ARG
1723 # 4.8
1724 LIBCFS_RHASHTABLE_LOOKUP
1725 LIBCFS_RHLTABLE
1726 LIBCFS_STACKTRACE_OPS
1727 # 4.9
1728 LIBCFS_GET_USER_PAGES_GUP_FLAGS
1729 LIBCFS_RHASHTABLE_WALK_ENTER
1730 # 4.10
1731 LIBCFS_HOTPLUG_STATE_MACHINE
1732 LIBCFS_REFCOUNT_T
1733 # 4.11
1734 LIBCFS_RHASHTABLE_LOOKUP_GET_INSERT_FAST
1735 LIBCFS_SCHED_HEADERS
1736 LIBCFS_KREF_READ
1737 LIBCFS_RHT_BUCKET_VAR
1738 # 4.12
1739 LIBCFS_HAVE_PROCESSOR_HEADER
1740 LIBCFS_HAVE_WAIT_BIT_HEADER
1741 LIBCFS_MEMALLOC_NORECLAIM
1742 LIBCFS_NL_EXT_ACK
1743 LIBCFS_WAIT_QUEUE_TASK_LIST_RENAME
1744 LIBCFS_CPUS_READ_LOCK
1745 LIBCFS_UUID_T
1746 # 4.13
1747 LIBCFS_NLA_STRDUP
1748 LIBCFS_WAIT_QUEUE_ENTRY
1749 # 4.14
1750 LIBCFS_DEFINE_TIMER
1751 LIBCFS_NEW_KERNEL_WRITE
1752 LIBCFS_NEW_KERNEL_READ
1753 LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK
1754 # 4.15
1755 LIBCFS_LOCKDEP_IS_HELD
1756 LIBCFS_TIMER_SETUP
1757 # 4.16
1758 LIBCFS_WAIT_VAR_EVENT
1759 # 4.17
1760 LIBCFS_BITMAP_ALLOC
1761 LIBCFS_CLEAR_AND_WAKE_UP_BIT
1762 # 4.18
1763 LIBCFS_TCP_SOCK_SET_NODELAY
1764 LIBCFS_TCP_SOCK_SET_KEEPIDLE
1765 # 4.19
1766 LIBCFS_XARRAY_SUPPORT
1767 LIBCFS_NL_DUMP_EXT_ACK
1768 # 4.20
1769 LIBCFS_HAVE_IOV_ITER_TYPE
1770 # 5.0
1771 LIBCFS_MM_TOTALRAM_PAGES_FUNC
1772 LIBCFS_GET_REQUEST_KEY_AUTH
1773 # 5.3
1774 LIBCFS_LOOKUP_USER_KEY
1775 LIBCFS_FORCE_SIG_WITH_TASK
1776 LIBCFS_CACHE_DETAIL_WRITERS
1777 LIBCFS_HAVE_NR_UNSTABLE_NFS
1778 # 5.7
1779 LIBCFS_KALLSYMS_LOOKUP
1780 LIBCFS_TCP_SOCK_SET_QUICKACK
1781 LIBCFS_TCP_SOCK_SET_KEEPINTVL
1782 LIBCFS_TCP_SOCK_SET_KEEPCNT
1783 # 5.8
1784 LIBCFS_HAVE_MMAP_LOCK
1785 LIBCFS_KERNEL_SETSOCKOPT
1786 LIBCFS_VMALLOC_2ARGS
1787 LIBCFS_SEC_RELEASE_SECCTX
1788 # 5.10
1789 LIBCFS_HAVE_KFREE_SENSITIVE
1790 LIBCFS_HAVE_CRYPTO_SHA2_HEADER
1791 ]) # LIBCFS_PROG_LINUX
1792
1793 #
1794 # LIBCFS_PATH_DEFAULTS
1795 #
1796 # default paths for installed files
1797 #
1798 AC_DEFUN([LIBCFS_PATH_DEFAULTS], [
1799 ]) # LIBCFS_PATH_DEFAULTS
1800
1801 #
1802 # LIBCFS_CONFIGURE
1803 #
1804 # other configure checks
1805 #
1806 AC_DEFUN([LIBCFS_CONFIGURE], [
1807 AC_MSG_NOTICE([LibCFS core checks
1808 ==============================================================================])
1809
1810 # libcfs/libcfs/util/nidstrings.c
1811 AC_CHECK_HEADERS([netdb.h asm/types.h endian.h])
1812 AC_CHECK_FUNCS([gethostbyname])
1813
1814 # --------  Check for required packages  --------------
1815
1816 AC_MSG_NOTICE([LibCFS required packages checks
1817 ==============================================================================])
1818
1819 AC_MSG_CHECKING([whether to enable readline support])
1820 AC_ARG_ENABLE(readline,
1821         AC_HELP_STRING([--disable-readline],
1822                 [disable readline support]),
1823         [], [enable_readline="yes"])
1824 AC_MSG_RESULT([$enable_readline])
1825
1826 LIBREADLINE=""
1827 AS_IF([test "x$enable_readline" = xyes], [
1828         AC_CHECK_LIB([readline], [readline], [
1829                 LIBREADLINE="-lreadline"
1830                 AC_DEFINE(HAVE_LIBREADLINE, 1,
1831                         [readline library is available])
1832         ])
1833 ])
1834 AC_SUBST(LIBREADLINE)
1835
1836 AC_MSG_CHECKING([whether to use libpthread for libcfs library])
1837 AC_ARG_ENABLE([libpthread],
1838         AC_HELP_STRING([--disable-libpthread],
1839                 [disable libpthread]),
1840         [], [enable_libpthread="yes"])
1841 AC_MSG_RESULT([$enable_libpthread])
1842
1843 PTHREAD_LIBS=""
1844 AS_IF([test "x$enable_libpthread" = xyes], [
1845         AC_CHECK_LIB([pthread], [pthread_create], [
1846                 PTHREAD_LIBS="-lpthread"
1847                 AC_DEFINE([HAVE_LIBPTHREAD], 1,
1848                         [use libpthread for libcfs library])
1849         ])
1850 ], [
1851         AC_MSG_WARN([Using libpthread for libcfs library is disabled explicitly])
1852 ])
1853 AC_SUBST(PTHREAD_LIBS)
1854 ]) # LIBCFS_CONFIGURE
1855
1856 #
1857 # LIBCFS_CONFIG_FILES
1858 #
1859 # files that should be generated with AC_OUTPUT
1860 #
1861 AC_DEFUN([LIBCFS_CONFIG_FILES], [
1862 AC_CONFIG_FILES([
1863 libcfs/Makefile
1864 libcfs/autoMakefile
1865 libcfs/autoconf/Makefile
1866 libcfs/include/Makefile
1867 libcfs/include/libcfs/Makefile
1868 libcfs/include/uapi/Makefile
1869 libcfs/include/libcfs/linux/Makefile
1870 libcfs/include/libcfs/util/Makefile
1871 libcfs/include/libcfs/crypto/Makefile
1872 libcfs/include/uapi/linux/Makefile
1873 libcfs/libcfs/Makefile
1874 libcfs/libcfs/autoMakefile
1875 libcfs/libcfs/linux/Makefile
1876 libcfs/libcfs/util/Makefile
1877 libcfs/libcfs/crypto/Makefile
1878 ])
1879 ]) # LIBCFS_CONFIG_FILES