config/lustre-build-linux.m4

   1 #
   2 # LB_LINUX_VERSION
   3 #
   4 # Set things accordingly for a linux kernel
   5 #
   6 AC_DEFUN([LB_LINUX_VERSION],[
   7 KMODEXT=".ko"
   8
   9 MODULE_TARGET="SUBDIRS"
  10 makerule="$PWD/build"
  11 AC_MSG_CHECKING([for external module build support])
  12 rm -f build/conftest.i
  13 LB_LINUX_TRY_MAKE([],[],
  14         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  15         [test -s build/conftest.i],
  16         [
  17                 AC_MSG_RESULT([no])
  18         ],[
  19                 makerule="_module_$makerule"
  20                 MODULE_TARGET="M"
  21                 LB_LINUX_TRY_MAKE([],[],
  22                         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  23                         [test -s build/conftest.i],
  24                         [
  25                                 AC_MSG_RESULT([yes])
  26                         ],[
  27                                 AC_MSG_ERROR([unknown; check config.log for details])
  28                         ])
  29         ])
  30
  31 AC_SUBST(MODULE_TARGET)
  32 AC_SUBST(KMODEXT)
  33 ])
  34
  35 #
  36 # LB_LINUX_RELEASE
  37 #
  38 # get the release version of linux
  39 #
  40 AC_DEFUN([LB_LINUX_RELEASE],
  41 [LINUXRELEASE=
  42 rm -f build/conftest.i
  43 AC_MSG_CHECKING([for Linux release])
  44 if test -s $LINUX_OBJ/include/$AUTOCONF_HDIR/utsrelease.h ; then
  45         LINUXRELEASEHEADER=$AUTOCONF_HDIR/utsrelease.h
  46 else
  47         LINUXRELEASEHEADER=linux/version.h
  48 fi
  49 LB_LINUX_TRY_MAKE([
  50         #include <$LINUXRELEASEHEADER>
  51 ],[
  52         char *LINUXRELEASE;
  53         LINUXRELEASE=UTS_RELEASE;
  54 ],[
  55         $makerule LUSTRE_KERNEL_TEST=conftest.i
  56 ],[
  57         test -s build/conftest.i
  58 ],[
  59         # LINUXRELEASE="UTS_RELEASE"
  60         eval $(grep "LINUXRELEASE=" build/conftest.i)
  61 ],[
  62         AC_MSG_RESULT([unknown])
  63         AC_MSG_ERROR([Could not preprocess test program.  Consult config.log for details.])
  64 ])
  65 rm -f build/conftest.i
  66 if test x$LINUXRELEASE = x ; then
  67         AC_MSG_RESULT([unknown])
  68         AC_MSG_ERROR([Could not determine Linux release version from linux/version.h.])
  69 fi
  70 AC_MSG_RESULT([$LINUXRELEASE])
  71 AC_SUBST(LINUXRELEASE)
  72
  73 moduledir='$(CROSS_PATH)/lib/modules/$(LINUXRELEASE)/updates/kernel'
  74 AC_SUBST(moduledir)
  75
  76 modulefsdir='$(moduledir)/fs/$(PACKAGE)'
  77 AC_SUBST(modulefsdir)
  78
  79 modulenetdir='$(moduledir)/net/$(PACKAGE)'
  80 AC_SUBST(modulenetdir)
  81
  82 # ------------ RELEASE --------------------------------
  83 AC_MSG_CHECKING([for Lustre release])
  84 AC_ARG_WITH([release],
  85         AC_HELP_STRING([--with-release=string],
  86                        [set the release string (default=$kvers_YYYYMMDDhhmm)]),
  87         [RELEASE=$withval],
  88         RELEASE=""
  89         if test -n "$DOWNSTREAM_RELEASE"; then
  90                 RELEASE="${DOWNSTREAM_RELEASE}_"
  91         fi
  92         RELEASE="$RELEASE`echo ${LINUXRELEASE} | tr '-' '_'`_$BUILDID")
  93 AC_MSG_RESULT($RELEASE)
  94 AC_SUBST(RELEASE)
  95
  96 # check is redhat/suse kernels
  97 AC_MSG_CHECKING([for RedHat kernel version])
  98         AS_IF([fgrep -q RHEL_RELEASE ${LINUX_OBJ}/include/linux/version.h], [
  99                 RHEL_KERNEL="yes"
 100                 RHEL_RELEASE=$(expr 0$(awk -F \" '/ RHEL_RELEASE / { print [$]2 }' \
 101                                ${LINUX_OBJ}/include/linux/version.h) + 1)
 102                 KERNEL_VERSION=$(sed -e 's/\(@<:@23@:>@\.@<:@0-9@:>@*\.@<:@0-9@:>@*\).*/\1/' <<< ${LINUXRELEASE})
 103                 RHEL_KERNEL_VERSION=${KERNEL_VERSION}-${RHEL_RELEASE}
 104                 AC_SUBST(RHEL_KERNEL_VERSION)
 105                 AC_MSG_RESULT([${RHEL_KERNEL_VERSION}])
 106         ], [
 107                 AC_MSG_RESULT([not found])
 108                 LB_LINUX_CONFIG([SUSE_KERNEL],[SUSE_KERNEL="yes"],[])
 109         ])
 110 ])
 111
 112 # LB_ARG_REPLACE_PATH(PACKAGE, PATH)
 113 AC_DEFUN([LB_ARG_REPLACE_PATH],[
 114         new_configure_args=
 115         eval "set x $ac_configure_args"
 116         shift
 117         for arg; do
 118                 case $arg in
 119                         --with-[$1]=*)
 120                                 arg=--with-[$1]=[$2]
 121                                 ;;
 122                         *\'*)
 123                                 arg=$(printf %s\n ["$arg"] | \
 124                                       sed "s/'/'\\\\\\\\''/g")
 125                                 ;;
 126                 esac
 127                 dnl AS_VAR_APPEND([new_configure_args], [" '$arg'"])
 128                 new_configure_args="$new_configure_args \"$arg\""
 129         done
 130         ac_configure_args=$new_configure_args
 131 ])
 132
 133 # this is the work-horse of the next function
 134 AC_DEFUN([__LB_ARG_CANON_PATH], [
 135         [$3]=$(readlink -f $with_$2)
 136         LB_ARG_REPLACE_PATH([$1], $[$3])
 137 ])
 138
 139 # a front-end for the above function that transforms - and . in the
 140 # PACKAGE portion of --with-PACKAGE into _ suitable for variable names
 141 AC_DEFUN([LB_ARG_CANON_PATH], [
 142         __LB_ARG_CANON_PATH([$1], m4_translit([$1], [-.], [__]), [$2])
 143 ])
 144
 145 #
 146 #
 147 # LB_LINUX_PATH
 148 #
 149 # Find paths for linux, handling kernel-source rpms
 150 #
 151 AC_DEFUN([LB_LINUX_PATH],
 152 [# prep some default values
 153 for DEFAULT_LINUX in /lib/modules/$(uname -r)/{source,build} /usr/src/linux; do
 154         if readlink -q -e $DEFAULT_LINUX; then
 155                 break
 156         fi
 157 done
 158 if test "$DEFAULT_LINUX" = "/lib/modules/$(uname -r)/source"; then
 159         PATHS="/lib/modules/$(uname -r)/build"
 160 fi
 161 PATHS+=" $DEFAULT_LINUX"
 162 for DEFAULT_LINUX_OBJ in $PATHS; do
 163         if readlink -q -e $DEFAULT_LINUX_OBJ; then
 164                 break
 165         fi
 166 done
 167 AC_MSG_CHECKING([for Linux sources])
 168 AC_ARG_WITH([linux],
 169         AC_HELP_STRING([--with-linux=path],
 170                        [set path to Linux source (default=/lib/modules/$(uname -r)/{source,build},/usr/src/linux)]),
 171         [LB_ARG_CANON_PATH([linux], [LINUX])
 172         DEFAULT_LINUX_OBJ=$LINUX],
 173         [LINUX=$DEFAULT_LINUX])
 174 AC_MSG_RESULT([$LINUX])
 175 AC_SUBST(LINUX)
 176
 177 # -------- check for linux --------
 178 LB_CHECK_FILE([$LINUX],[],
 179         [AC_MSG_ERROR([Kernel source $LINUX could not be found.])])
 180
 181 # -------- linux objects (for 2.6) --
 182 AC_MSG_CHECKING([for Linux objects dir])
 183 AC_ARG_WITH([linux-obj],
 184         AC_HELP_STRING([--with-linux-obj=path],
 185                         [set path to Linux objects dir (default=/lib/modules/$(uname -r)/build,/usr/src/linux)]),
 186         [LB_ARG_CANON_PATH([linux-obj], [LINUX_OBJ])],
 187         [LINUX_OBJ=$DEFAULT_LINUX_OBJ])
 188
 189 AC_MSG_RESULT([$LINUX_OBJ])
 190 AC_SUBST(LINUX_OBJ)
 191
 192 # -------- check for .config --------
 193 AC_ARG_WITH([linux-config],
 194         [AC_HELP_STRING([--with-linux-config=path],
 195                         [set path to Linux .conf (default=$LINUX_OBJ/.config)])],
 196         [LB_ARG_CANON_PATH([linux-config], [LINUX_CONFIG])],
 197         [LINUX_CONFIG=$LINUX_OBJ/.config])
 198 AC_SUBST(LINUX_CONFIG)
 199
 200 LB_CHECK_FILE([/boot/kernel.h],
 201         [KERNEL_SOURCE_HEADER='/boot/kernel.h'],
 202         [LB_CHECK_FILE([/var/adm/running-kernel.h],
 203                 [KERNEL_SOURCE_HEADER='/var/adm/running-kernel.h'])])
 204
 205 AC_ARG_WITH([kernel-source-header],
 206         AC_HELP_STRING([--with-kernel-source-header=path],
 207                         [Use a different kernel version header.  Consult build/README.kernel-source for details.]),
 208         [LB_ARG_CANON_PATH([kernel-source-header], [KERNEL_SOURCE_HEADER])])
 209
 210 # ------------ .config exists ----------------
 211 LB_CHECK_FILE([$LINUX_CONFIG],[],
 212         [AC_MSG_ERROR([Kernel config could not be found.  If you are building from a kernel-source rpm consult build/README.kernel-source])])
 213
 214 # ----------- make dep run? ------------------
 215 # at 2.6.19 # $LINUX/include/linux/config.h is removed
 216 # and at more old has only one line
 217 # include <autoconf.h>
 218 LB_CHECK_FILE([$LINUX_OBJ/include/generated/autoconf.h],[AUTOCONF_HDIR=generated],
 219         [LB_CHECK_FILE([$LINUX_OBJ/include/linux/autoconf.h],[AUTOCONF_HDIR=linux],
 220         [AC_MSG_ERROR([Run make config in $LINUX.])])])
 221         AC_SUBST(AUTOCONF_HDIR)
 222 LB_CHECK_FILE([$LINUX_OBJ/include/linux/version.h],[],
 223         [AC_MSG_ERROR([Run make config in $LINUX.])])
 224
 225 # ----------- kconfig.h exists ---------------
 226 # kernel 3.1, $LINUX/include/linux/kconfig.h is added
 227 # see kernel commit 2a11c8ea20bf850b3a2c60db8c2e7497d28aba99
 228 LB_CHECK_FILE([$LINUX_OBJ/include/linux/kconfig.h],
 229               [CONFIG_INCLUDE=include/linux/kconfig.h],
 230               [CONFIG_INCLUDE=include/$AUTOCONF_HDIR/autoconf.h])
 231         AC_SUBST(CONFIG_INCLUDE)
 232
 233 # ------------ rhconfig.h includes runtime-generated bits --
 234 # red hat kernel-source checks
 235
 236 # we know this exists after the check above.  if the user
 237 # tarred up the tree and ran make dep etc. in it, then
 238 # version.h gets overwritten with a standard linux one.
 239
 240 if grep rhconfig $LINUX_OBJ/include/linux/version.h >/dev/null ; then
 241         # This is a clean kernel-source tree, we need to
 242         # enable extensive workarounds to get this to build
 243         # modules
 244         LB_CHECK_FILE([$KERNEL_SOURCE_HEADER],
 245                 [if test $KERNEL_SOURCE_HEADER = '/boot/kernel.h' ; then
 246                         AC_MSG_WARN([Using /boot/kernel.h from RUNNING kernel.])
 247                         AC_MSG_WARN([If this is not what you want, use --with-kernel-source-header.])
 248                         AC_MSG_WARN([Consult build/README.kernel-source for details.])
 249                 fi],
 250                 [AC_MSG_ERROR([$KERNEL_SOURCE_HEADER not found.  Consult build/README.kernel-source for details.])])
 251         EXTRA_KCFLAGS="-include $KERNEL_SOURCE_HEADER $EXTRA_KCFLAGS"
 252 fi
 253
 254 # this is needed before we can build modules
 255 LB_LINUX_CROSS
 256 LB_LINUX_VERSION
 257
 258 # --- check that we can build modules at all
 259 AC_MSG_CHECKING([that modules can be built at all])
 260 LB_LINUX_TRY_COMPILE([],[],[
 261         AC_MSG_RESULT([yes])
 262 ],[
 263         AC_MSG_RESULT([no])
 264         AC_MSG_WARN([Consult config.log for details.])
 265         AC_MSG_WARN([If you are trying to build with a kernel-source rpm, consult build/README.kernel-source])
 266         AC_MSG_ERROR([Kernel modules cannot be built.])
 267 ])
 268
 269 LB_LINUX_RELEASE
 270 ]) # end of LB_LINUX_PATH
 271
 272 # LB_LINUX_SYMVERFILE
 273 # SLES 9 uses a different name for this file - unsure about vanilla kernels
 274 # around this version, but it matters for servers only.
 275 AC_DEFUN([LB_LINUX_SYMVERFILE],
 276         [AC_MSG_CHECKING([name of module symbol version file])
 277         if grep -q Modules.symvers $LINUX/scripts/Makefile.modpost ; then
 278                 SYMVERFILE=Modules.symvers
 279         else
 280                 SYMVERFILE=Module.symvers
 281         fi
 282         AC_MSG_RESULT($SYMVERFILE)
 283         AC_SUBST(SYMVERFILE)
 284 ])
 285
 286 #
 287 # LB_LINUX_CROSS
 288 #
 289 # check for cross compilation
 290 #
 291 AC_DEFUN([LB_LINUX_CROSS],
 292         [AC_MSG_CHECKING([for cross compilation])
 293 CROSS_VARS=
 294 CROSS_PATH=
 295 case $target_vendor in
 296         # The K1OM architecture is an extension of the x86 architecture.
 297         # So, the $target_arch is x86_64.
 298         k1om)
 299                 AC_MSG_RESULT([Intel(R) Xeon Phi(TM)])
 300                 CC_TARGET_ARCH=`$CC -v 2>&1 | grep Target: | sed -e 's/Target: //'`
 301                 if test $CC_TARGET_ARCH != x86_64-$target_vendor-linux ; then
 302                         AC_MSG_ERROR([Cross compiler not found in PATH.])
 303                 fi
 304                 CROSS_VARS="ARCH=$target_vendor CROSS_COMPILE=x86_64-$target_vendor-linux-"
 305                 CROSS_PATH=${CROSS_PATH:=/opt/intel/mic/lustre/device-k1om}
 306                 CCAS=$CC
 307                 # need to produce special section for debuginfo extraction
 308                 LDFLAGS="${LDFLAGS} -Wl,--build-id"
 309                 EXTRA_KLDFLAGS="${EXTRA_KLDFLAGS} -Wl,--build-id"
 310                 if test x$enable_server = xyes ; then
 311                         AC_MSG_WARN([Disabling server (not supported for x86_64-$target_vendor-linux).])
 312                         enable_server='no'
 313                 fi
 314                 ;;
 315         *)
 316                 AC_MSG_RESULT([no])
 317                 ;;
 318 esac
 319 AC_SUBST(CROSS_VARS)
 320 AC_SUBST(CROSS_PATH)
 321 ])
 322
 323 # these are like AC_TRY_COMPILE, but try to build modules against the
 324 # kernel, inside the build directory
 325
 326 # LB_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 327 # --------------------------------------
 328 m4_define([LB_LANG_PROGRAM],
 329 [
 330 #include <linux/kernel.h>
 331 $1
 332 int
 333 main (void)
 334 {
 335 dnl Do *not* indent the following line: there may be CPP directives.
 336 dnl Don't move the `;' right after for the same reason.
 337 $2
 338   ;
 339   return 0;
 340 }])
 341
 342 #
 343 # LB_LINUX_COMPILE_IFELSE
 344 #
 345 # like AC_COMPILE_IFELSE
 346 #
 347 AC_DEFUN([LB_LINUX_COMPILE_IFELSE],
 348 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
 349 rm -f build/conftest.o build/conftest.mod.c build/conftest.ko
 350 AS_IF([AC_TRY_COMMAND(cp conftest.c build && make -d [$2] ${LD:+"LD=$LD"} CC="$CC" -f $PWD/build/Makefile LUSTRE_LINUX_CONFIG=$LINUX_CONFIG LINUXINCLUDE="$EXTRA_LNET_INCLUDE -I$LINUX/arch/`echo $target_cpu|sed -e 's/powerpc64/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include -I$LINUX/arch/`echo $target_cpu|sed -e 's/ppc.*/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include/generated -I$LINUX_OBJ/include -I$LINUX/include -I$LINUX_OBJ/include2 -include $CONFIG_INCLUDE" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $CROSS_VARS $MODULE_TARGET=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 351         [$4],
 352         [_AC_MSG_LOG_CONFTEST
 353 m4_ifvaln([$5],[$5])dnl])
 354 rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
 355 ])
 356
 357 #
 358 # LB_LINUX_ARCH
 359 #
 360 # Determine the kernel's idea of the current architecture
 361 #
 362 AC_DEFUN([LB_LINUX_ARCH],
 363          [AC_MSG_CHECKING([Linux kernel architecture])
 364           AS_IF([rm -f $PWD/build/arch
 365                  make -s --no-print-directory echoarch -f $PWD/build/Makefile \
 366                      LUSTRE_LINUX_CONFIG=$LINUX_CONFIG -C $LINUX $CROSS_VARS  \
 367                      ARCHFILE=$PWD/build/arch && LINUX_ARCH=`cat $PWD/build/arch`],
 368                 [AC_MSG_RESULT([$LINUX_ARCH])],
 369                 [AC_MSG_ERROR([Could not determine the kernel architecture.])])
 370           rm -f build/arch])
 371
 372 #
 373 # LB_LINUX_TRY_COMPILE
 374 #
 375 # like AC_TRY_COMPILE
 376 #
 377 AC_DEFUN([LB_LINUX_TRY_COMPILE],
 378 [LB_LINUX_COMPILE_IFELSE(
 379         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 380         [modules],
 381         [test -s build/conftest.o],
 382         [$3], [$4])])
 383
 384 #
 385 # LB_LINUX_CONFIG
 386 #
 387 # check if a given config option is defined
 388 #
 389 AC_DEFUN([LB_LINUX_CONFIG],[
 390         AC_MSG_CHECKING([if Linux was built with CONFIG_$1])
 391         LB_LINUX_TRY_COMPILE([
 392                 #include <$AUTOCONF_HDIR/autoconf.h>
 393         ],[
 394                 #ifndef CONFIG_$1
 395                 #error CONFIG_$1 not #defined
 396                 #endif
 397         ],[
 398                 AC_MSG_RESULT([yes])
 399                 $2
 400         ],[
 401                 AC_MSG_RESULT([no])
 402                 $3
 403         ])
 404 ])
 405
 406 #
 407 # LB_LINUX_CONFIG_IM
 408 #
 409 # check if a given config option is builtin or as module
 410 #
 411 AC_DEFUN([LB_LINUX_CONFIG_IM],[
 412         AC_MSG_CHECKING([if Linux was built with CONFIG_$1 in or as module])
 413         LB_LINUX_TRY_COMPILE([
 414                 #include <$AUTOCONF_HDIR/autoconf.h>
 415         ],[
 416                 #if !(defined(CONFIG_$1) || defined(CONFIG_$1_MODULE))
 417                 #error CONFIG_$1 and CONFIG_$1_MODULE not #defined
 418                 #endif
 419         ],[
 420                 AC_MSG_RESULT([yes])
 421                 $2
 422         ],[
 423                 AC_MSG_RESULT([no])
 424                 $3
 425         ])
 426 ])
 427
 428 #
 429 # LB_LINUX_TRY_MAKE
 430 #
 431 # like LB_LINUX_TRY_COMPILE, but with different arguments
 432 #
 433 AC_DEFUN([LB_LINUX_TRY_MAKE],
 434         [LB_LINUX_COMPILE_IFELSE(
 435                 [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 436                 [$3], [$4], [$5], [$6]
 437         )]
 438 )
 439
 440 #
 441 # LB_CONFIG_COMPAT_RDMA
 442 #
 443 AC_DEFUN([LB_CONFIG_COMPAT_RDMA],
 444 [AC_MSG_CHECKING([whether to use Compat RDMA])
 445 # set default
 446 AC_ARG_WITH([o2ib],
 447         AC_HELP_STRING([--with-o2ib=path],
 448                        [build o2iblnd against path]),
 449         [
 450                 case $with_o2ib in
 451                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 452                         ENABLEO2IB=2
 453                         ;;
 454                 no)     ENABLEO2IB=0
 455                         ;;
 456                 *)      O2IBPATHS=$with_o2ib
 457                         ENABLEO2IB=3
 458                         ;;
 459                 esac
 460         ],[
 461                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 462                 ENABLEO2IB=1
 463         ])
 464 if test $ENABLEO2IB -eq 0; then
 465         AC_MSG_RESULT([no])
 466 else
 467         o2ib_found=false
 468         for O2IBPATH in $O2IBPATHS; do
 469                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 470                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 471                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 472                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 473                         o2ib_found=true
 474                         break
 475                 fi
 476         done
 477         compatrdma_found=false
 478         if $o2ib_found; then
 479                 if test \( -f ${O2IBPATH}/include/linux/compat-2.6.h \); then
 480                         compatrdma_found=true
 481                         AC_MSG_RESULT([yes])
 482                         AC_DEFINE(HAVE_COMPAT_RDMA, 1, [compat rdma found])
 483                 else
 484                         AC_MSG_RESULT([no])
 485                 fi
 486         fi
 487 fi
 488 ])
 489
 490 #
 491 # LB_CONFIG_OFED_BACKPORTS
 492 #
 493 # include any OFED backport headers in all compile commands
 494 # NOTE: this does only include the backport paths, not the OFED headers
 495 #       adding the OFED headers is done in the lnet portion
 496 AC_DEFUN([LB_CONFIG_OFED_BACKPORTS],
 497 [AC_MSG_CHECKING([whether to use any OFED backport headers])
 498 if test $ENABLEO2IB -eq 0; then
 499         AC_MSG_RESULT([no])
 500 else
 501         if ! $o2ib_found; then
 502                 AC_MSG_RESULT([no])
 503                 case $ENABLEO2IB in
 504                         1) ;;
 505                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 506                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 507                         *) AC_MSG_ERROR([internal error]);;
 508                 esac
 509         else
 510                 if ! $compatrdma_found; then
 511                         if test -f $O2IBPATH/config.mk; then
 512                                 . $O2IBPATH/config.mk
 513                         elif test -f $O2IBPATH/ofed_patch.mk; then
 514                                 . $O2IBPATH/ofed_patch.mk
 515                         fi
 516                 else
 517                         case $RHEL_KERNEL_VERSION in
 518                                 2.6.32-358*)
 519                                         EXTRA_LNET_INCLUDE="$EXTRA_LNET_INCLUDE -DCONFIG_COMPAT_RHEL_6_4";;
 520                         esac
 521                 fi
 522                 if test -n "$BACKPORT_INCLUDES"; then
 523                         OFED_BACKPORT_PATH="$O2IBPATH/${BACKPORT_INCLUDES/*\/kernel_addons/kernel_addons}/"
 524                         EXTRA_LNET_INCLUDE="-I$OFED_BACKPORT_PATH $EXTRA_LNET_INCLUDE"
 525                         AC_MSG_RESULT([yes])
 526                 else
 527                         AC_MSG_RESULT([no])
 528                 fi
 529         fi
 530 fi
 531 ])
 532
 533 # LC_MODULE_LOADING
 534 # after 2.6.28 CONFIG_KMOD is removed, and only CONFIG_MODULES remains
 535 # so we test if request_module is implemented or not
 536 AC_DEFUN([LC_MODULE_LOADING],
 537 [AC_MSG_CHECKING([if kernel module loading is possible])
 538 LB_LINUX_TRY_MAKE([
 539         #include <linux/kmod.h>
 540 ],[
 541         int myretval=ENOSYS ;
 542         return myretval;
 543 ],[
 544         $makerule LUSTRE_KERNEL_TEST=conftest.i
 545 ],[dnl
 546         grep request_module build/conftest.i |dnl
 547                 grep -v `grep "int myretval=" build/conftest.i |dnl
 548                         cut -d= -f2 | cut -d" "  -f1`dnl
 549                 >/dev/null dnl
 550 ],[
 551         AC_MSG_RESULT(yes)
 552         AC_DEFINE(HAVE_MODULE_LOADING_SUPPORT, 1,
 553                   [kernel module loading is possible])
 554 ],[
 555         AC_MSG_RESULT(no)
 556         AC_MSG_WARN([])
 557         AC_MSG_WARN([Kernel module loading support is highly recommended.])
 558         AC_MSG_WARN([])
 559 ])
 560 ])
 561
 562 #
 563 # LB_PROG_LINUX
 564 #
 565 # linux tests
 566 #
 567 AC_DEFUN([LB_PROG_LINUX],
 568 [LB_LINUX_PATH
 569 LB_LINUX_ARCH
 570 LB_LINUX_SYMVERFILE
 571
 572
 573 LB_LINUX_CONFIG([MODULES],[],[
 574         AC_MSG_ERROR([module support is required to build Lustre kernel modules.])
 575 ])
 576
 577 LB_LINUX_CONFIG([MODVERSIONS])
 578
 579 LB_LINUX_CONFIG([KALLSYMS],[],[
 580         AC_MSG_ERROR([Lustre requires that CONFIG_KALLSYMS is enabled in your kernel.])
 581 ])
 582
 583 # 2.6.28
 584 LC_MODULE_LOADING
 585
 586 LB_CONFIG_COMPAT_RDMA
 587
 588 # it's ugly to be doing anything with OFED outside of the lnet module, but
 589 # this has to be done here so that the backports path is set before all of
 590 # the LN_PROG_LINUX checks are done
 591 LB_CONFIG_OFED_BACKPORTS
 592 ])
 593
 594 #
 595 # LB_CHECK_SYMBOL_EXPORT
 596 # check symbol exported or not
 597 # $1 - symbol
 598 # $2 - file(s) for find.
 599 # $3 - do 'yes'
 600 # $4 - do 'no'
 601 #
 602 # 2.6 based kernels - put modversion info into $LINUX/Module.modvers
 603 # or check
 604 AC_DEFUN([LB_CHECK_SYMBOL_EXPORT],
 605 [AC_MSG_CHECKING([if Linux was built with symbol $1 exported])
 606 grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX/$SYMVERFILE 2>/dev/null
 607 rc=$?
 608 if test $rc -ne 0; then
 609         export=0
 610         for file in $2; do
 611                 grep -q -E "EXPORT_SYMBOL.*\($1\)" "$LINUX/$file" 2>/dev/null
 612                 rc=$?
 613                 if test $rc -eq 0; then
 614                         export=1
 615                         break;
 616                 fi
 617         done
 618         if test $export -eq 0; then
 619                 AC_MSG_RESULT([no])
 620                 $4
 621         else
 622                 AC_MSG_RESULT([yes])
 623                 $3
 624         fi
 625 else
 626         AC_MSG_RESULT([yes])
 627         $3
 628 fi
 629 ])
 630
 631 #
 632 # Like AC_CHECK_HEADER but checks for a kernel-space header
 633 #
 634 m4_define([LB_CHECK_LINUX_HEADER],
 635 [AS_VAR_PUSHDEF([ac_Header], [ac_cv_header_$1])dnl
 636 AC_CACHE_CHECK([for $1], ac_Header,
 637                [LB_LINUX_COMPILE_IFELSE([LB_LANG_PROGRAM([@%:@include <$1>])],
 638                                   [modules],
 639                                   [test -s build/conftest.o],
 640                                   [AS_VAR_SET(ac_Header, [yes])],
 641                                   [AS_VAR_SET(ac_Header, [no])])])
 642 AS_IF([test AS_VAR_GET(ac_Header) = yes], [$2], [$3])[]dnl
 643 AS_VAR_POPDEF([ac_Header])dnl
 644 ])
 645
 646 #
 647 # LB_USES_DPKG
 648 #
 649 # Determine if the target is a dpkg system or rpm
 650 #
 651 AC_DEFUN([LB_USES_DPKG],
 652 [
 653 AC_MSG_CHECKING([if this distro uses dpkg])
 654 case `lsb_release -i -s 2>/dev/null` in
 655         Ubuntu | Debian)
 656                 AC_MSG_RESULT([yes])
 657                 uses_dpkg=yes
 658                 ;;
 659         *)
 660                 AC_MSG_RESULT([no])
 661                 uses_dpkg=no
 662                 ;;
 663 esac
 664 ])