config/lustre-build-linux.m4

   1 #
   2 # LB_LINUX_VERSION
   3 #
   4 # Set things accordingly for a linux kernel
   5 #
   6 AC_DEFUN([LB_LINUX_VERSION],[
   7 KMODEXT=".ko"
   8
   9 MODULE_TARGET="SUBDIRS"
  10 makerule="$PWD/build"
  11 AC_MSG_CHECKING([for external module build support])
  12 rm -f build/conftest.i
  13 LB_LINUX_TRY_MAKE([],[],
  14         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  15         [test -s build/conftest.i],
  16         [
  17                 AC_MSG_RESULT([no])
  18         ],[
  19                 makerule="_module_$makerule"
  20                 MODULE_TARGET="M"
  21                 LB_LINUX_TRY_MAKE([],[],
  22                         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  23                         [test -s build/conftest.i],
  24                         [
  25                                 AC_MSG_RESULT([yes])
  26                         ],[
  27                                 AC_MSG_ERROR([unknown; check config.log for details])
  28                         ])
  29         ])
  30
  31 AC_SUBST(MODULE_TARGET)
  32 AC_SUBST(KMODEXT)
  33 ])
  34
  35 #
  36 # LB_LINUX_RELEASE
  37 #
  38 # get the release version of linux
  39 #
  40 AC_DEFUN([LB_LINUX_RELEASE],
  41 [LINUXRELEASE=
  42 rm -f build/conftest.i
  43 AC_MSG_CHECKING([for Linux release])
  44 if test -s $LINUX_OBJ/include/$AUTOCONF_HDIR/utsrelease.h ; then
  45         LINUXRELEASEHEADER=$AUTOCONF_HDIR/utsrelease.h
  46 else
  47         LINUXRELEASEHEADER=linux/version.h
  48 fi
  49 LB_LINUX_TRY_MAKE([
  50         #include <$LINUXRELEASEHEADER>
  51 ],[
  52         char *LINUXRELEASE;
  53         LINUXRELEASE=UTS_RELEASE;
  54 ],[
  55         $makerule LUSTRE_KERNEL_TEST=conftest.i
  56 ],[
  57         test -s build/conftest.i
  58 ],[
  59         # LINUXRELEASE="UTS_RELEASE"
  60         eval $(grep "LINUXRELEASE=" build/conftest.i)
  61 ],[
  62         AC_MSG_RESULT([unknown])
  63         AC_MSG_ERROR([Could not preprocess test program.  Consult config.log for details.])
  64 ])
  65 rm -f build/conftest.i
  66 if test x$LINUXRELEASE = x ; then
  67         AC_MSG_RESULT([unknown])
  68         AC_MSG_ERROR([Could not determine Linux release version from linux/version.h.])
  69 fi
  70 AC_MSG_RESULT([$LINUXRELEASE])
  71 AC_SUBST(LINUXRELEASE)
  72
  73 moduledir='$(CROSS_PATH)/lib/modules/$(LINUXRELEASE)/updates/kernel'
  74 AC_SUBST(moduledir)
  75
  76 modulefsdir='$(moduledir)/fs/$(PACKAGE)'
  77 AC_SUBST(modulefsdir)
  78
  79 modulenetdir='$(moduledir)/net/$(PACKAGE)'
  80 AC_SUBST(modulenetdir)
  81
  82 # ------------ RELEASE --------------------------------
  83 AC_MSG_CHECKING([for Lustre release])
  84 AC_ARG_WITH([release],
  85         AC_HELP_STRING([--with-release=string],
  86                        [set the release string (default=$kvers_YYYYMMDDhhmm)]),
  87         [RELEASE=$withval],
  88         RELEASE=""
  89         if test -n "$DOWNSTREAM_RELEASE"; then
  90                 RELEASE="${DOWNSTREAM_RELEASE}_"
  91         fi
  92         RELEASE="$RELEASE`echo ${LINUXRELEASE} | tr '-' '_'`_$BUILDID")
  93 AC_MSG_RESULT($RELEASE)
  94 AC_SUBST(RELEASE)
  95
  96 # check is redhat/suse kernels
  97 AC_MSG_CHECKING([that RedHat kernel])
  98 LB_LINUX_TRY_COMPILE([
  99                 #include <linux/version.h>
 100         ],[
 101                 #ifndef RHEL_RELEASE_CODE
 102                 #error "not redhat kernel"
 103                 #endif
 104         ],[
 105                 RHEL_KERNEL="yes"
 106                 AC_MSG_RESULT([yes])
 107         ],[
 108                 AC_MSG_RESULT([no])
 109 ])
 110
 111 LB_LINUX_CONFIG([SUSE_KERNEL],[SUSE_KERNEL="yes"],[])
 112
 113 ])
 114
 115 # LB_ARG_REPLACE_PATH(PACKAGE, PATH)
 116 AC_DEFUN([LB_ARG_REPLACE_PATH],[
 117         new_configure_args=
 118         eval "set x $ac_configure_args"
 119         shift
 120         for arg; do
 121                 case $arg in
 122                         --with-[$1]=*)
 123                                 arg=--with-[$1]=[$2]
 124                                 ;;
 125                         *\'*)
 126                                 arg=$(printf %s\n ["$arg"] | \
 127                                       sed "s/'/'\\\\\\\\''/g")
 128                                 ;;
 129                 esac
 130                 dnl AS_VAR_APPEND([new_configure_args], [" '$arg'"])
 131                 new_configure_args="$new_configure_args \"$arg\""
 132         done
 133         ac_configure_args=$new_configure_args
 134 ])
 135
 136 # this is the work-horse of the next function
 137 AC_DEFUN([__LB_ARG_CANON_PATH], [
 138         [$3]=$(readlink -f $with_$2)
 139         LB_ARG_REPLACE_PATH([$1], $[$3])
 140 ])
 141
 142 # a front-end for the above function that transforms - and . in the
 143 # PACKAGE portion of --with-PACKAGE into _ suitable for variable names
 144 AC_DEFUN([LB_ARG_CANON_PATH], [
 145         __LB_ARG_CANON_PATH([$1], m4_translit([$1], [-.], [__]), [$2])
 146 ])
 147
 148 #
 149 #
 150 # LB_LINUX_PATH
 151 #
 152 # Find paths for linux, handling kernel-source rpms
 153 #
 154 AC_DEFUN([LB_LINUX_PATH],
 155 [# prep some default values
 156 for DEFAULT_LINUX in /lib/modules/$(uname -r)/{source,build} /usr/src/linux; do
 157         if readlink -q -e $DEFAULT_LINUX; then
 158                 break
 159         fi
 160 done
 161 if test "$DEFAULT_LINUX" = "/lib/modules/$(uname -r)/source"; then
 162         PATHS="/lib/modules/$(uname -r)/build"
 163 fi
 164 PATHS+=" $DEFAULT_LINUX"
 165 for DEFAULT_LINUX_OBJ in $PATHS; do
 166         if readlink -q -e $DEFAULT_LINUX_OBJ; then
 167                 break
 168         fi
 169 done
 170 AC_MSG_CHECKING([for Linux sources])
 171 AC_ARG_WITH([linux],
 172         AC_HELP_STRING([--with-linux=path],
 173                        [set path to Linux source (default=/lib/modules/$(uname -r)/{source,build},/usr/src/linux)]),
 174         [LB_ARG_CANON_PATH([linux], [LINUX])
 175         DEFAULT_LINUX_OBJ=$LINUX],
 176         [LINUX=$DEFAULT_LINUX])
 177 AC_MSG_RESULT([$LINUX])
 178 AC_SUBST(LINUX)
 179
 180 # -------- check for linux --------
 181 LB_CHECK_FILE([$LINUX],[],
 182         [AC_MSG_ERROR([Kernel source $LINUX could not be found.])])
 183
 184 # -------- linux objects (for 2.6) --
 185 AC_MSG_CHECKING([for Linux objects dir])
 186 AC_ARG_WITH([linux-obj],
 187         AC_HELP_STRING([--with-linux-obj=path],
 188                         [set path to Linux objects dir (default=/lib/modules/$(uname -r)/build,/usr/src/linux)]),
 189         [LB_ARG_CANON_PATH([linux-obj], [LINUX_OBJ])],
 190         [LINUX_OBJ=$DEFAULT_LINUX_OBJ])
 191
 192 AC_MSG_RESULT([$LINUX_OBJ])
 193 AC_SUBST(LINUX_OBJ)
 194
 195 # -------- check for .config --------
 196 AC_ARG_WITH([linux-config],
 197         [AC_HELP_STRING([--with-linux-config=path],
 198                         [set path to Linux .conf (default=$LINUX_OBJ/.config)])],
 199         [LB_ARG_CANON_PATH([linux-config], [LINUX_CONFIG])],
 200         [LINUX_CONFIG=$LINUX_OBJ/.config])
 201 AC_SUBST(LINUX_CONFIG)
 202
 203 LB_CHECK_FILE([/boot/kernel.h],
 204         [KERNEL_SOURCE_HEADER='/boot/kernel.h'],
 205         [LB_CHECK_FILE([/var/adm/running-kernel.h],
 206                 [KERNEL_SOURCE_HEADER='/var/adm/running-kernel.h'])])
 207
 208 AC_ARG_WITH([kernel-source-header],
 209         AC_HELP_STRING([--with-kernel-source-header=path],
 210                         [Use a different kernel version header.  Consult build/README.kernel-source for details.]),
 211         [LB_ARG_CANON_PATH([kernel-source-header], [KERNEL_SOURCE_HEADER])])
 212
 213 # ------------ .config exists ----------------
 214 LB_CHECK_FILE([$LINUX_CONFIG],[],
 215         [AC_MSG_ERROR([Kernel config could not be found.  If you are building from a kernel-source rpm consult build/README.kernel-source])])
 216
 217 # ----------- make dep run? ------------------
 218 # at 2.6.19 # $LINUX/include/linux/config.h is removed
 219 # and at more old has only one line
 220 # include <autoconf.h>
 221 LB_CHECK_FILE([$LINUX_OBJ/include/generated/autoconf.h],[AUTOCONF_HDIR=generated],
 222         [LB_CHECK_FILE([$LINUX_OBJ/include/linux/autoconf.h],[AUTOCONF_HDIR=linux],
 223         [AC_MSG_ERROR([Run make config in $LINUX.])])])
 224         AC_SUBST(AUTOCONF_HDIR)
 225 LB_CHECK_FILE([$LINUX_OBJ/include/linux/version.h],[],
 226         [AC_MSG_ERROR([Run make config in $LINUX.])])
 227
 228 # ----------- kconfig.h exists ---------------
 229 # kernel 3.1, $LINUX/include/linux/kconfig.h is added
 230 # see kernel commit 2a11c8ea20bf850b3a2c60db8c2e7497d28aba99
 231 LB_CHECK_FILE([$LINUX_OBJ/include/linux/kconfig.h],
 232               [CONFIG_INCLUDE=include/linux/kconfig.h],
 233               [CONFIG_INCLUDE=include/$AUTOCONF_HDIR/autoconf.h])
 234         AC_SUBST(CONFIG_INCLUDE)
 235
 236 # ------------ rhconfig.h includes runtime-generated bits --
 237 # red hat kernel-source checks
 238
 239 # we know this exists after the check above.  if the user
 240 # tarred up the tree and ran make dep etc. in it, then
 241 # version.h gets overwritten with a standard linux one.
 242
 243 if grep rhconfig $LINUX_OBJ/include/linux/version.h >/dev/null ; then
 244         # This is a clean kernel-source tree, we need to
 245         # enable extensive workarounds to get this to build
 246         # modules
 247         LB_CHECK_FILE([$KERNEL_SOURCE_HEADER],
 248                 [if test $KERNEL_SOURCE_HEADER = '/boot/kernel.h' ; then
 249                         AC_MSG_WARN([Using /boot/kernel.h from RUNNING kernel.])
 250                         AC_MSG_WARN([If this is not what you want, use --with-kernel-source-header.])
 251                         AC_MSG_WARN([Consult build/README.kernel-source for details.])
 252                 fi],
 253                 [AC_MSG_ERROR([$KERNEL_SOURCE_HEADER not found.  Consult build/README.kernel-source for details.])])
 254         EXTRA_KCFLAGS="-include $KERNEL_SOURCE_HEADER $EXTRA_KCFLAGS"
 255 fi
 256
 257 # this is needed before we can build modules
 258 LB_LINUX_CROSS
 259 LB_LINUX_VERSION
 260
 261 # --- check that we can build modules at all
 262 AC_MSG_CHECKING([that modules can be built at all])
 263 LB_LINUX_TRY_COMPILE([],[],[
 264         AC_MSG_RESULT([yes])
 265 ],[
 266         AC_MSG_RESULT([no])
 267         AC_MSG_WARN([Consult config.log for details.])
 268         AC_MSG_WARN([If you are trying to build with a kernel-source rpm, consult build/README.kernel-source])
 269         AC_MSG_ERROR([Kernel modules cannot be built.])
 270 ])
 271
 272 LB_LINUX_RELEASE
 273 ]) # end of LB_LINUX_PATH
 274
 275 # LB_LINUX_SYMVERFILE
 276 # SLES 9 uses a different name for this file - unsure about vanilla kernels
 277 # around this version, but it matters for servers only.
 278 AC_DEFUN([LB_LINUX_SYMVERFILE],
 279         [AC_MSG_CHECKING([name of module symbol version file])
 280         if grep -q Modules.symvers $LINUX/scripts/Makefile.modpost ; then
 281                 SYMVERFILE=Modules.symvers
 282         else
 283                 SYMVERFILE=Module.symvers
 284         fi
 285         AC_MSG_RESULT($SYMVERFILE)
 286         AC_SUBST(SYMVERFILE)
 287 ])
 288
 289 #
 290 # LB_LINUX_CROSS
 291 #
 292 # check for cross compilation
 293 #
 294 AC_DEFUN([LB_LINUX_CROSS],
 295         [AC_MSG_CHECKING([for cross compilation])
 296 CROSS_VARS=
 297 CROSS_PATH=
 298 case $target_vendor in
 299         # The K1OM architecture is an extension of the x86 architecture.
 300         # So, the $target_arch is x86_64.
 301         k1om)
 302                 AC_MSG_RESULT([Intel(R) Xeon Phi(TM)])
 303                 CC_TARGET_ARCH=`$CC -v 2>&1 | grep Target: | sed -e 's/Target: //'`
 304                 if test $CC_TARGET_ARCH != x86_64-$target_vendor-linux ; then
 305                         AC_MSG_ERROR([Cross compiler not found in PATH.])
 306                 fi
 307                 CROSS_VARS="ARCH=$target_vendor CROSS_COMPILE=x86_64-$target_vendor-linux-"
 308                 CROSS_PATH=${CROSS_PATH:=/opt/intel/mic/lustre/device-k1om}
 309                 CCAS=$CC
 310                 # need to produce special section for debuginfo extraction
 311                 LDFLAGS="${LDFLAGS} -Wl,--build-id"
 312                 EXTRA_KLDFLAGS="${EXTRA_KLDFLAGS} -Wl,--build-id"
 313                 if test x$enable_server = xyes ; then
 314                         AC_MSG_WARN([Disabling server (not supported for x86_64-$target_vendor-linux).])
 315                         enable_server='no'
 316                 fi
 317                 ;;
 318         *)
 319                 AC_MSG_RESULT([no])
 320                 ;;
 321 esac
 322 AC_SUBST(CROSS_VARS)
 323 AC_SUBST(CROSS_PATH)
 324 ])
 325
 326 # these are like AC_TRY_COMPILE, but try to build modules against the
 327 # kernel, inside the build directory
 328
 329 # LB_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 330 # --------------------------------------
 331 m4_define([LB_LANG_PROGRAM],
 332 [
 333 #include <linux/kernel.h>
 334 $1
 335 int
 336 main (void)
 337 {
 338 dnl Do *not* indent the following line: there may be CPP directives.
 339 dnl Don't move the `;' right after for the same reason.
 340 $2
 341   ;
 342   return 0;
 343 }])
 344
 345 #
 346 # LB_LINUX_COMPILE_IFELSE
 347 #
 348 # like AC_COMPILE_IFELSE
 349 #
 350 AC_DEFUN([LB_LINUX_COMPILE_IFELSE],
 351 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
 352 rm -f build/conftest.o build/conftest.mod.c build/conftest.ko
 353 AS_IF([AC_TRY_COMMAND(cp conftest.c build && make -d [$2] ${LD:+"LD=$LD"} CC="$CC" -f $PWD/build/Makefile LUSTRE_LINUX_CONFIG=$LINUX_CONFIG LINUXINCLUDE="$EXTRA_LNET_INCLUDE -I$LINUX/arch/`echo $target_cpu|sed -e 's/powerpc64/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include -I$LINUX/arch/`echo $target_cpu|sed -e 's/ppc.*/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include/generated -I$LINUX_OBJ/include -I$LINUX/include -I$LINUX_OBJ/include2 -include $CONFIG_INCLUDE" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $CROSS_VARS $MODULE_TARGET=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 354         [$4],
 355         [_AC_MSG_LOG_CONFTEST
 356 m4_ifvaln([$5],[$5])dnl])
 357 rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
 358 ])
 359
 360 #
 361 # LB_LINUX_ARCH
 362 #
 363 # Determine the kernel's idea of the current architecture
 364 #
 365 AC_DEFUN([LB_LINUX_ARCH],
 366          [AC_MSG_CHECKING([Linux kernel architecture])
 367           AS_IF([rm -f $PWD/build/arch
 368                  make -s --no-print-directory echoarch -f $PWD/build/Makefile \
 369                      LUSTRE_LINUX_CONFIG=$LINUX_CONFIG -C $LINUX $CROSS_VARS  \
 370                      ARCHFILE=$PWD/build/arch && LINUX_ARCH=`cat $PWD/build/arch`],
 371                 [AC_MSG_RESULT([$LINUX_ARCH])],
 372                 [AC_MSG_ERROR([Could not determine the kernel architecture.])])
 373           rm -f build/arch])
 374
 375 #
 376 # LB_LINUX_TRY_COMPILE
 377 #
 378 # like AC_TRY_COMPILE
 379 #
 380 AC_DEFUN([LB_LINUX_TRY_COMPILE],
 381 [LB_LINUX_COMPILE_IFELSE(
 382         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 383         [modules],
 384         [test -s build/conftest.o],
 385         [$3], [$4])])
 386
 387 #
 388 # LB_LINUX_CONFIG
 389 #
 390 # check if a given config option is defined
 391 #
 392 AC_DEFUN([LB_LINUX_CONFIG],[
 393         AC_MSG_CHECKING([if Linux was built with CONFIG_$1])
 394         LB_LINUX_TRY_COMPILE([
 395                 #include <$AUTOCONF_HDIR/autoconf.h>
 396         ],[
 397                 #ifndef CONFIG_$1
 398                 #error CONFIG_$1 not #defined
 399                 #endif
 400         ],[
 401                 AC_MSG_RESULT([yes])
 402                 $2
 403         ],[
 404                 AC_MSG_RESULT([no])
 405                 $3
 406         ])
 407 ])
 408
 409 #
 410 # LB_LINUX_CONFIG_IM
 411 #
 412 # check if a given config option is builtin or as module
 413 #
 414 AC_DEFUN([LB_LINUX_CONFIG_IM],[
 415         AC_MSG_CHECKING([if Linux was built with CONFIG_$1 in or as module])
 416         LB_LINUX_TRY_COMPILE([
 417                 #include <$AUTOCONF_HDIR/autoconf.h>
 418         ],[
 419                 #if !(defined(CONFIG_$1) || defined(CONFIG_$1_MODULE))
 420                 #error CONFIG_$1 and CONFIG_$1_MODULE not #defined
 421                 #endif
 422         ],[
 423                 AC_MSG_RESULT([yes])
 424                 $2
 425         ],[
 426                 AC_MSG_RESULT([no])
 427                 $3
 428         ])
 429 ])
 430
 431 #
 432 # LB_LINUX_TRY_MAKE
 433 #
 434 # like LB_LINUX_TRY_COMPILE, but with different arguments
 435 #
 436 AC_DEFUN([LB_LINUX_TRY_MAKE],
 437         [LB_LINUX_COMPILE_IFELSE(
 438                 [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 439                 [$3], [$4], [$5], [$6]
 440         )]
 441 )
 442
 443 #
 444 # LB_CONFIG_COMPAT_RDMA
 445 #
 446 AC_DEFUN([LB_CONFIG_COMPAT_RDMA],
 447 [AC_MSG_CHECKING([whether to use Compat RDMA])
 448 # set default
 449 AC_ARG_WITH([o2ib],
 450         AC_HELP_STRING([--with-o2ib=path],
 451                        [build o2iblnd against path]),
 452         [
 453                 case $with_o2ib in
 454                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 455                         ENABLEO2IB=2
 456                         ;;
 457                 no)     ENABLEO2IB=0
 458                         ;;
 459                 *)      O2IBPATHS=$with_o2ib
 460                         ENABLEO2IB=3
 461                         ;;
 462                 esac
 463         ],[
 464                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 465                 ENABLEO2IB=1
 466         ])
 467 if test $ENABLEO2IB -eq 0; then
 468         AC_MSG_RESULT([no])
 469 else
 470         o2ib_found=false
 471         for O2IBPATH in $O2IBPATHS; do
 472                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 473                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 474                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 475                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 476                         o2ib_found=true
 477                         break
 478                 fi
 479         done
 480         compatrdma_found=false
 481         if $o2ib_found; then
 482                 if test \( -f ${O2IBPATH}/include/linux/compat-2.6.h \); then
 483                         compatrdma_found=true
 484                         AC_MSG_RESULT([yes])
 485                         AC_DEFINE(HAVE_COMPAT_RDMA, 1, [compat rdma found])
 486                 else
 487                         AC_MSG_RESULT([no])
 488                 fi
 489         fi
 490 fi
 491 ])
 492
 493 #
 494 # LB_CONFIG_OFED_BACKPORTS
 495 #
 496 # include any OFED backport headers in all compile commands
 497 # NOTE: this does only include the backport paths, not the OFED headers
 498 #       adding the OFED headers is done in the lnet portion
 499 AC_DEFUN([LB_CONFIG_OFED_BACKPORTS],
 500 [AC_MSG_CHECKING([whether to use any OFED backport headers])
 501 if test $ENABLEO2IB -eq 0; then
 502         AC_MSG_RESULT([no])
 503 else
 504         if ! $o2ib_found; then
 505                 AC_MSG_RESULT([no])
 506                 case $ENABLEO2IB in
 507                         1) ;;
 508                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 509                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 510                         *) AC_MSG_ERROR([internal error]);;
 511                 esac
 512         else
 513                 if ! $compatrdma_found; then
 514                         if test -f $O2IBPATH/config.mk; then
 515                                 . $O2IBPATH/config.mk
 516                         elif test -f $O2IBPATH/ofed_patch.mk; then
 517                                 . $O2IBPATH/ofed_patch.mk
 518                         fi
 519                 fi
 520                 if test -n "$BACKPORT_INCLUDES"; then
 521                         OFED_BACKPORT_PATH="$O2IBPATH/${BACKPORT_INCLUDES/*\/kernel_addons/kernel_addons}/"
 522                         EXTRA_LNET_INCLUDE="-I$OFED_BACKPORT_PATH $EXTRA_LNET_INCLUDE"
 523                         AC_MSG_RESULT([yes])
 524                 else
 525                         AC_MSG_RESULT([no])
 526                 fi
 527         fi
 528 fi
 529 ])
 530
 531 # LC_MODULE_LOADING
 532 # after 2.6.28 CONFIG_KMOD is removed, and only CONFIG_MODULES remains
 533 # so we test if request_module is implemented or not
 534 AC_DEFUN([LC_MODULE_LOADING],
 535 [AC_MSG_CHECKING([if kernel module loading is possible])
 536 LB_LINUX_TRY_MAKE([
 537         #include <linux/kmod.h>
 538 ],[
 539         int myretval=ENOSYS ;
 540         return myretval;
 541 ],[
 542         $makerule LUSTRE_KERNEL_TEST=conftest.i
 543 ],[dnl
 544         grep request_module build/conftest.i |dnl
 545                 grep -v `grep "int myretval=" build/conftest.i |dnl
 546                         cut -d= -f2 | cut -d" "  -f1`dnl
 547                 >/dev/null dnl
 548 ],[
 549         AC_MSG_RESULT(yes)
 550         AC_DEFINE(HAVE_MODULE_LOADING_SUPPORT, 1,
 551                   [kernel module loading is possible])
 552 ],[
 553         AC_MSG_RESULT(no)
 554         AC_MSG_WARN([])
 555         AC_MSG_WARN([Kernel module loading support is highly recommended.])
 556         AC_MSG_WARN([])
 557 ])
 558 ])
 559
 560 #
 561 # LB_PROG_LINUX
 562 #
 563 # linux tests
 564 #
 565 AC_DEFUN([LB_PROG_LINUX],
 566 [LB_LINUX_PATH
 567 LB_LINUX_ARCH
 568 LB_LINUX_SYMVERFILE
 569
 570
 571 LB_LINUX_CONFIG([MODULES],[],[
 572         AC_MSG_ERROR([module support is required to build Lustre kernel modules.])
 573 ])
 574
 575 LB_LINUX_CONFIG([MODVERSIONS])
 576
 577 LB_LINUX_CONFIG([KALLSYMS],[],[
 578         AC_MSG_ERROR([Lustre requires that CONFIG_KALLSYMS is enabled in your kernel.])
 579 ])
 580
 581 # 2.6.28
 582 LC_MODULE_LOADING
 583
 584 LB_CONFIG_COMPAT_RDMA
 585
 586 # it's ugly to be doing anything with OFED outside of the lnet module, but
 587 # this has to be done here so that the backports path is set before all of
 588 # the LN_PROG_LINUX checks are done
 589 LB_CONFIG_OFED_BACKPORTS
 590 ])
 591
 592 #
 593 # LB_CHECK_SYMBOL_EXPORT
 594 # check symbol exported or not
 595 # $1 - symbol
 596 # $2 - file(s) for find.
 597 # $3 - do 'yes'
 598 # $4 - do 'no'
 599 #
 600 # 2.6 based kernels - put modversion info into $LINUX/Module.modvers
 601 # or check
 602 AC_DEFUN([LB_CHECK_SYMBOL_EXPORT],
 603 [AC_MSG_CHECKING([if Linux was built with symbol $1 exported])
 604 grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX/$SYMVERFILE 2>/dev/null
 605 rc=$?
 606 if test $rc -ne 0; then
 607         export=0
 608         for file in $2; do
 609                 grep -q -E "EXPORT_SYMBOL.*\($1\)" "$LINUX/$file" 2>/dev/null
 610                 rc=$?
 611                 if test $rc -eq 0; then
 612                         export=1
 613                         break;
 614                 fi
 615         done
 616         if test $export -eq 0; then
 617                 AC_MSG_RESULT([no])
 618                 $4
 619         else
 620                 AC_MSG_RESULT([yes])
 621                 $3
 622         fi
 623 else
 624         AC_MSG_RESULT([yes])
 625         $3
 626 fi
 627 ])
 628
 629 #
 630 # Like AC_CHECK_HEADER but checks for a kernel-space header
 631 #
 632 m4_define([LB_CHECK_LINUX_HEADER],
 633 [AS_VAR_PUSHDEF([ac_Header], [ac_cv_header_$1])dnl
 634 AC_CACHE_CHECK([for $1], ac_Header,
 635                [LB_LINUX_COMPILE_IFELSE([LB_LANG_PROGRAM([@%:@include <$1>])],
 636                                   [modules],
 637                                   [test -s build/conftest.o],
 638                                   [AS_VAR_SET(ac_Header, [yes])],
 639                                   [AS_VAR_SET(ac_Header, [no])])])
 640 AS_IF([test AS_VAR_GET(ac_Header) = yes], [$2], [$3])[]dnl
 641 AS_VAR_POPDEF([ac_Header])dnl
 642 ])
 643
 644 #
 645 # LB_USES_DPKG
 646 #
 647 # Determine if the target is a dpkg system or rpm
 648 #
 649 AC_DEFUN([LB_USES_DPKG],
 650 [
 651 AC_MSG_CHECKING([if this distro uses dpkg])
 652 case `lsb_release -i -s 2>/dev/null` in
 653         Ubuntu | Debian)
 654                 AC_MSG_RESULT([yes])
 655                 uses_dpkg=yes
 656                 ;;
 657         *)
 658                 AC_MSG_RESULT([no])
 659                 uses_dpkg=no
 660                 ;;
 661 esac
 662 ])