config/lustre-build-ldiskfs.m4

   1 #
   2 # LDISKFS_LINUX_SERIES
   3 #
   4 AC_DEFUN([LDISKFS_LINUX_SERIES], [
   5 AC_MSG_CHECKING([which ldiskfs series to use])
   6 case x$LDISKFS_SERIES in
   7         x)                      # not set
   8                 ;;
   9         *.series)               # set externally
  10                 ;;
  11         *) LDISKFS_SERIES=
  12 esac
  13 AS_IF([test -z "$LDISKFS_SERIES"], [
  14 AS_IF([test x$RHEL_KERNEL = xyes], [
  15         case $RHEL_RELEASE_NO in
  16         83)     LDISKFS_SERIES="4.18-rhel8.3.series"    ;;
  17         82)     LDISKFS_SERIES="4.18-rhel8.2.series"    ;;
  18         81)     LDISKFS_SERIES="4.18-rhel8.1.series"    ;;
  19         80)     LDISKFS_SERIES="4.18-rhel8.series"      ;;
  20         79)     LDISKFS_SERIES="3.10-rhel7.9.series"    ;;
  21         78)     LDISKFS_SERIES="3.10-rhel7.8.series"    ;;
  22         77)     LDISKFS_SERIES="3.10-rhel7.7.series"    ;;
  23         76)     LDISKFS_SERIES="3.10-rhel7.6.series"    ;;
  24         esac
  25 ], [test x$SUSE_KERNEL = xyes], [
  26         AS_VERSION_COMPARE([$LINUXRELEASE],[5.3.18],[
  27         AS_VERSION_COMPARE([$LINUXRELEASE],[4.12.14],[], [], [
  28                 suse_conf=$LINUX_OBJ/include/generated/uapi/linux/suse_version.h
  29                 suse_vers=$(awk '[$]2 == "SUSE_VERSION" {print [$]3 }' $suse_conf)
  30                 suse_patchlevel=$(awk '[$]2 == "SUSE_PATCHLEVEL" {print [$]3 }' $suse_conf)
  31                 echo "$suse_conf $suse_vers $suse_patchlevel  ${suse_vers}sp$suse_patchlevel" >> /tmp/log-nb
  32                 case ${suse_vers}sp$suse_patchlevel in # (
  33                 15sp0 ) LDISKFS_SERIES="4.12-sles15.series"
  34                         if test ! -f $LINUX/arch/x86/kernel/cpu/hygon.c ; then
  35                                 # This file was added shortly after -150.22 so
  36                                 # this must be 150.22 or earlier
  37                                 LDISKFS_SERIES="4.12-sles15-22.series"
  38                         fi
  39                         ;; # (
  40                 15sp1 ) LDISKFS_SERIES="4.12-sles15sp1.series"
  41                         if test ! -f $LINUX/arch/x86/kernel/cpu/umwait.c ; then
  42                                 # This file was added after -197.7 so
  43                                 # this must be -197.7 or earlier
  44                                 LDISKFS_SERIES="4.12-sles15sp1-7.series"
  45                         fi
  46                         ;;
  47                 esac
  48         ]
  49         )], [LDISKFS_SERIES="5.4.21-ml.series"],
  50             [LDISKFS_SERIES="5.4.21-ml.series"])
  51 ], [test x$UBUNTU_KERNEL = xyes], [
  52         AS_VERSION_COMPARE([$LINUXRELEASE],[5.4.0],[
  53         AS_VERSION_COMPARE([$LINUXRELEASE],[5.0.0],[
  54         AS_VERSION_COMPARE([$LINUXRELEASE],[4.15.0],[
  55         AS_VERSION_COMPARE([$LINUXRELEASE],[4.4.0], [],
  56         [
  57                 KPLEV=$(echo $LINUXRELEASE | sed -n 's/.*-\([0-9]\+\).*/\1/p')
  58                 AS_IF(
  59                         [test -z "$KPLEV"], [
  60                                 AC_MSG_WARN([Failed to determine Kernel patch level. Assume latest.])
  61                                 LDISKFS_SERIES="4.4.0-73-ubuntu14+16.series"
  62                         ],
  63                         [test $KPLEV -ge 73], [LDISKFS_SERIES="4.4.0-73-ubuntu14+16.series"],
  64                         [test $KPLEV -ge 62], [LDISKFS_SERIES="4.4.0-62-ubuntu14+16.series"],
  65                         [test $KPLEV -ge 49], [LDISKFS_SERIES="4.4.0-49-ubuntu14+16.series"],
  66                         [LDISKFS_SERIES="4.4.0-45-ubuntu14+16.series"]
  67                 )
  68         ],
  69         [LDISKFS_SERIES="4.4.0-73-ubuntu14+16.series"])],
  70         [
  71                 KPLEV=$(echo $LINUXRELEASE | sed -n 's/.*-\([0-9]\+\).*/\1/p')
  72                 AS_IF(
  73                         [test -z "$KPLEV"], [
  74                                 AC_MSG_WARN([Failed to determine Kernel patch level. Assume latest.])
  75                                 LDISKFS_SERIES="4.15.0-24-ubuntu18.series"
  76                         ],
  77                         [test $KPLEV -ge 24], [LDISKFS_SERIES="4.15.0-24-ubuntu18.series"],
  78                         [test $KPLEV -ge 20], [LDISKFS_SERIES="4.15.0-20-ubuntu18.series"]
  79                 )
  80         ],
  81         [LDISKFS_SERIES="4.15.0-24-ubuntu18.series"])],
  82         [LDISKFS_SERIES="5.0.0-13-ubuntu19.series"],
  83         [LDISKFS_SERIES="5.0.0-13-ubuntu19.series"])],
  84         [LDISKFS_SERIES="5.4.0-42-ubuntu20.series"],
  85         [LDISKFS_SERIES="5.4.0-42-ubuntu20.series"],
  86         [LDISKFS_SERIES="5.4.0-ml.series"])
  87 ])
  88 ])
  89 # Not RHEL/SLES or Ubuntu .. probably mainline
  90 AS_IF([test -z "$LDISKFS_SERIES"],
  91         [
  92         AS_VERSION_COMPARE([$LINUXRELEASE],[5.4.0],[],
  93         [LDISKFS_SERIES="5.4.0-ml.series"],[
  94         AS_VERSION_COMPARE([$LINUXRELEASE],[5.4.21],
  95                 [LDISKFS_SERIES="5.4.0-ml.series"],  # lt
  96                 [LDISKFS_SERIES="5.4.21-ml.series"], # eq
  97                 [LDISKFS_SERIES="5.4.21-ml.series"]  # gt
  98                 )])
  99         ],
 100 [])
 101 AS_IF([test -z "$LDISKFS_SERIES"],
 102         [AC_MSG_RESULT([failed to identify series])],
 103         [AC_MSG_RESULT([$LDISKFS_SERIES for $LINUXRELEASE])])
 104 AC_SUBST(LDISKFS_SERIES)
 105 ]) # LDISKFS_LINUX_SERIES
 106
 107 #
 108 # LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 109 #
 110 # 2.6.32-rc7 ext4_free_blocks requires struct buffer_head
 111 # Note that RHEL6 is pre 2.6.32-rc7 so this check is still needed.
 112 #
 113 AC_DEFUN([LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD], [
 114 LB_CHECK_COMPILE([if 'ext4_free_blocks' needs 'struct buffer_head'],
 115 ext4_free_blocks_with_buffer_head, [
 116         #include <linux/fs.h>
 117         #include "$EXT4_SRC_DIR/ext4.h"
 118 ],[
 119         ext4_free_blocks(NULL, NULL, NULL, 0, 0, 0);
 120 ],[
 121         AC_DEFINE(HAVE_EXT_FREE_BLOCK_WITH_BUFFER_HEAD, 1,
 122                 [ext4_free_blocks do not require struct buffer_head])
 123 ])
 124 ]) # LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 125
 126 #
 127 # LB_EXT4_JOURNAL_START_3ARGS
 128 #
 129 # 3.9 added a type argument to ext4_journal_start and friends
 130 #
 131 AC_DEFUN([LB_EXT4_JOURNAL_START_3ARGS], [
 132 LB_CHECK_COMPILE([if ext4_journal_start takes 3 arguments],
 133 ext4_journal_start, [
 134         #include <linux/fs.h>
 135         #include "$EXT4_SRC_DIR/ext4_jbd2.h"
 136 ],[
 137         ext4_journal_start(NULL, 0, 0);
 138 ],[
 139         AC_DEFINE(JOURNAL_START_HAS_3ARGS, 1, [ext4_journal_start takes 3 arguments])
 140 ])
 141 ]) # LB_EXT4_JOURNAL_START_3ARGS
 142
 143 #
 144 # LB_EXT4_BREAD_4ARGS
 145 #
 146 # 3.18 ext4_bread has 4 arguments
 147 # NOTE: It may not be exported for modules, use a positive compiler test here.
 148 #
 149 AC_DEFUN([LB_EXT4_BREAD_4ARGS], [
 150 LB_CHECK_COMPILE([if ext4_bread takes 4 arguments],
 151 ext4_bread, [
 152         #include <linux/fs.h>
 153         #include "$EXT4_SRC_DIR/ext4.h"
 154
 155         struct buffer_head *ext4_bread(handle_t *handle, struct inode *inode,
 156                                        ext4_lblk_t block, int map_flags)
 157         {
 158                 struct buffer_head *bh = NULL;
 159                 (void)handle;
 160                 (void)inode;
 161                 (void)block;
 162                 (void)map_flags;
 163                 return bh;
 164         }
 165 ],[
 166         ext4_bread(NULL, NULL, 0, 0);
 167 ],[
 168         AC_DEFINE(HAVE_EXT4_BREAD_4ARGS, 1, [ext4_bread takes 4 arguments])
 169 ])
 170 ]) # LB_EXT4_BREAD_4ARGS
 171
 172 #
 173 # LB_EXT4_HAVE_INFO_DQUOT
 174 #
 175 # in linux 4.4 i_dqout is in ext4_inode_info, not in struct inode
 176 #
 177 AC_DEFUN([LB_EXT4_HAVE_INFO_DQUOT], [
 178 LB_CHECK_COMPILE([if i_dquot is in ext4_inode_info],
 179 ext4_info_dquot, [
 180         #include <linux/fs.h>
 181         #include <linux/quota.h>
 182         #include "$EXT4_SRC_DIR/ext4.h"
 183 ],[
 184         struct ext4_inode_info in;
 185         struct dquot *dq;
 186
 187         dq = in.i_dquot[0];
 188 ],[
 189         AC_DEFINE(HAVE_EXT4_INFO_DQUOT, 1, [i_dquot is in ext4_inode_info])
 190 ])
 191 ]) # LB_EXT4_HAVE_INFO_DQUOT
 192
 193 #
 194 # LB_EXT4_HAVE_I_CRYPT_INFO
 195 #
 196 # in linux 4.8 i_crypt_info moved from ext4_inode_info to struct inode
 197 #
 198 # Determine if we need to enable CONFIG_LDISKFS_FS_ENCRYPTION.
 199 # If we have i_crypt_info in ext4_inode_info, the config option
 200 # should be enabled to make the ldiskfs module compilation happy.
 201 # Otherwise i_crypy_info is in struct inode, we need to check kernel
 202 # config option to determine that.
 203 #
 204 AC_DEFUN([LB_EXT4_HAVE_I_CRYPT_INFO], [
 205 LB_CHECK_COMPILE([if i_crypt_info is in ext4_inode_info],
 206 ext4_i_crypt_info, [
 207         #define CONFIG_EXT4_FS_ENCRYPTION 1
 208         #include <linux/fs.h>
 209         #include "$EXT4_SRC_DIR/ext4.h"
 210 ],[
 211         struct ext4_inode_info in;
 212
 213         in.i_crypt_info = NULL;
 214 ],[
 215         AC_DEFINE(
 216                 CONFIG_LDISKFS_FS_ENCRYPTION, 1,
 217                 [enable encryption for ldiskfs]
 218         )
 219 ],[
 220         LB_CHECK_CONFIG([EXT4_FS_ENCRYPTION],[
 221                 AC_DEFINE(
 222                         CONFIG_LDISKFS_FS_ENCRYPTION, 1,
 223                         [enable encryption for ldiskfs]
 224                 )
 225         ])
 226 ])
 227 ]) # LB_EXT4_HAVE_I_CRYPT_INFO
 228
 229 #
 230 # LB_LDISKFS_JOURNAL_ENSURE_CREDITS
 231 #
 232 # kernel 4.18.0-240.1.1.el8 and
 233 # kernel 5.4 commit a413036791d040e33badcc634453a4d0c0705499
 234 #
 235 # ext4_journal_ensure_credits was introduced to ensure given handle
 236 # has at least requested amount of credits available, and possibly
 237 # restarting transaction if needed.
 238 #
 239 AC_DEFUN([LB_LDISKFS_JOURNAL_ENSURE_CREDITS], [
 240 tmp_flags="$EXTRA_KCFLAGS"
 241 EXTRA_KCFLAGS="-Werror"
 242 LB_CHECK_COMPILE([if 'ext4_journal_ensure_credits' exists],
 243 ext4_journal_ensure_credits, [
 244         #include "$EXT4_SRC_DIR/ext4_jbd2.h"
 245 ],[
 246         ext4_journal_ensure_credits(NULL, 0, 0);
 247 ],[
 248         AC_DEFINE(HAVE_LDISKFS_JOURNAL_ENSURE_CREDITS, 1,
 249                 ['ext4_journal_ensure_credits' exists])
 250 ])
 251 EXTRA_KCFLAGS="$tmp_flags"
 252 ]) # LB_LDISKFS_JOURNAL_ENSURE_CREDITS
 253
 254 #
 255 # LB_LDISKFS_IGET_HAS_FLAGS_ARG
 256 #
 257 # kernel 4.19 commit 8a363970d1dc38c4ec4ad575c862f776f468d057
 258 # ext4_iget changed to a macro with 3 args was function with 2 args
 259 #
 260 AC_DEFUN([LB_LDISKFS_IGET_HAS_FLAGS_ARG], [
 261 tmp_flags="$EXTRA_KCFLAGS"
 262 EXTRA_KCFLAGS="-Werror"
 263 LB_CHECK_COMPILE([if ldiskfs_iget takes a flags argument],
 264 ext4_iget_3args, [
 265         #include <linux/fs.h>
 266         #include "$EXT4_SRC_DIR/ext4.h"
 267 ],[
 268         int f = EXT4_IGET_SPECIAL;
 269         (void)f;
 270 ],[
 271         AC_DEFINE(HAVE_LDISKFS_IGET_WITH_FLAGS, 1,
 272                 [if ldiskfs_iget takes a flags argument])
 273 ])
 274 EXTRA_KCFLAGS="$tmp_flags"
 275 ]) # LB_LDISKFS_IGET_HAS_FLAGS_ARG
 276
 277 #
 278 # LDISKFS_AC_PATCH_PROGRAM
 279 #
 280 # Determine which program should be used to apply the patches to
 281 # the ext4 source code to produce the ldiskfs source code.
 282 #
 283 AC_DEFUN([LDISKFS_AC_PATCH_PROGRAM], [
 284         AC_ARG_ENABLE([quilt],
 285                 [AC_HELP_STRING([--disable-quilt],
 286                         [disable use of quilt for ldiskfs])],
 287                 [AS_IF([test "x$enableval" = xno],
 288                         [use_quilt=no],
 289                         [use_quilt=maybe])],
 290                 [use_quilt=maybe]
 291         )
 292
 293         AS_IF([test x$use_quilt = xmaybe], [
 294                 AC_PATH_PROG([quilt_avail], [quilt], [no])
 295                 AS_IF([test x$quilt_avail = xno], [
 296                         use_quilt=no
 297                 ], [
 298                         use_quilt=yes
 299                 ])
 300         ])
 301
 302         AS_IF([test x$use_quilt = xno], [
 303                 AC_PATH_PROG([patch_avail], [patch], [no])
 304                 AS_IF([test x$patch_avail = xno], [
 305                         AC_MSG_ERROR([*** Need "quilt" or "patch" command])
 306                 ])
 307         ])
 308 ]) # LDISKFS_AC_PATCH_PROGRAM
 309
 310 #
 311 # LB_LDISKFS_FIND_ENTRY_LOCKED_EXISTS
 312 #
 313 # kernel 5.2 commit 8a363970d1dc38c4ec4ad575c862f776f468d057
 314 # ext4: avoid declaring fs inconsistent due to invalid file handles
 315 # __ext4_find_entry became a helper function for ext4_find_entry
 316 # conflicting with previous ldiskfs patches.
 317 # ldiskfs patches map ext4_find_entry to ldiskfs_find_entry_locked to
 318 # avoid conflicting with __ext4_find_entry
 319 #
 320 # When the following check succeeds __ext4_find_entry helper is not
 321 # used.
 322 #
 323 AC_DEFUN([LB_LDISKFS_FIND_ENTRY_LOCKED_EXISTS], [
 324 tmp_flags="$EXTRA_KCFLAGS"
 325 EXTRA_KCFLAGS="-Werror"
 326 LB_CHECK_COMPILE([if __ldiskfs_find_entry is available],
 327 ldiskfs_find_entry_locked, [
 328         #include <linux/fs.h>
 329         #include "$EXT4_SRC_DIR/ext4.h"
 330         #include "$EXT4_SRC_DIR/namei.c"
 331
 332         static int __ext4_find_entry(void) { return 0; }
 333 ],[
 334         int x = __ext4_find_entry();
 335         (void)x;
 336 ],[
 337         AC_DEFINE(HAVE___LDISKFS_FIND_ENTRY, 1,
 338                 [if __ldiskfs_find_entry is available])
 339 ])
 340 EXTRA_KCFLAGS="$tmp_flags"
 341 ]) # LB_LDISKFS_FIND_ENTRY_LOCKED_EXISTS
 342
 343 #
 344 # LB_LDISKFSFS_DIRHASH_WANTS_DIR
 345 #
 346 # kernel 5.2 commit 8a363970d1dc38c4ec4ad575c862f776f468d057
 347 # ext4fs_dirhash UNICODE support
 348 #
 349 AC_DEFUN([LB_LDISKFSFS_DIRHASH_WANTS_DIR], [
 350 tmp_flags="$EXTRA_KCFLAGS"
 351 EXTRA_KCFLAGS="-Werror"
 352 LB_CHECK_COMPILE([if ldiskfsfs_dirhash takes an inode argument],
 353 ext4fs_dirhash, [
 354         #include <linux/fs.h>
 355         #include "$EXT4_SRC_DIR/ext4.h"
 356
 357         int ext4fs_dirhash(const struct inode *dir, const char *name, int len,
 358                           struct dx_hash_info *hinfo)
 359         {
 360                 (void)dir;
 361                 (void)name;
 362                 (void)len;
 363                 (void)hinfo;
 364                 return 0;
 365         }
 366 ],[
 367         int f = ext4fs_dirhash(NULL, NULL, 0, NULL);
 368         (void)f;
 369 ],[
 370         AC_DEFINE(HAVE_LDISKFSFS_GETHASH_INODE_ARG, 1,
 371                 [ldiskfsfs_dirhash takes an inode argument])
 372 ])
 373 EXTRA_KCFLAGS="$tmp_flags"
 374 ]) # LB_LDISKFSFS_DIRHASH_WANTS_DIR
 375
 376 #
 377 # LB_JBD2_H_TOTAL_CREDITS
 378 #
 379 # kernel 5.5 commit 933f1c1e0b75bbc29730eef07c9e196c6dfd37e5
 380 # jbd2: Reserve space for revoke descriptor blocks
 381 #
 382 AC_DEFUN([LB_JBD2_H_TOTAL_CREDITS], [
 383 tmp_flags="$EXTRA_KCFLAGS"
 384 EXTRA_KCFLAGS="-Werror"
 385 LB_CHECK_COMPILE([if struct jbd2_journal_handle has h_total_credits member],
 386 handle_t_h_revoke_credits, [
 387         #include <linux/jbd2.h>
 388 ],[
 389         int x = offsetof(struct jbd2_journal_handle, h_total_credits);
 390         (void)x;
 391 ],[
 392         AC_DEFINE(HAVE_JOURNAL_TOTAL_CREDITS, 1,
 393                 [struct jbd2_journal_handle has h_total_credits member])
 394 ])
 395 EXTRA_KCFLAGS="$tmp_flags"
 396 ]) # LB_JBD2_H_TOTAL_CREDITS
 397
 398 #
 399 # LB_CONFIG_LDISKFS
 400 #
 401 AC_DEFUN([LB_CONFIG_LDISKFS], [
 402 # --with-ldiskfs is deprecated now that ldiskfs is fully merged with lustre.
 403 # However we continue to support this option through Lustre 2.5.
 404 AC_ARG_WITH([ldiskfs],
 405         [],
 406         [AC_MSG_WARN([--with-ldiskfs is deprecated, please use --enable-ldiskfs])
 407         AS_IF([test x$withval != xyes -a x$withval != xno],
 408                 [AC_MSG_ERROR([
 409
 410 The ldiskfs option is deprecated,
 411 and no longer supports paths to external ldiskfs source
 412 ])])
 413 ])
 414
 415 AC_ARG_ENABLE([ldiskfs],
 416         [AS_HELP_STRING([--disable-ldiskfs],
 417                 [disable ldiskfs osd (default is enable)])],
 418         [AS_IF([test x$enable_ldiskfs != xyes -a x$enable_ldiskfs != xno],
 419                 [AC_MSG_ERROR([ldiskfs valid options are "yes" or "no"])])],
 420         [AS_IF([test "${with_ldiskfs+set}" = set],
 421                 [enable_ldiskfs=$with_ldiskfs],
 422                 [enable_ldiskfs=maybe])
 423 ])
 424
 425 AS_IF([test x$enable_server = xno],
 426         [AS_CASE([$enable_ldiskfs],
 427                 [maybe], [enable_ldiskfs=no],
 428                 [yes], [AC_MSG_ERROR([cannot build ldiskfs when servers are disabled])]
 429         )])
 430
 431 AS_IF([test x$enable_ldiskfs != xno],[
 432         # In the future, we chould change enable_ldiskfs from maybe to
 433         # either yes or no based on additional tests, e.g.  whether a patch
 434         # set is available for the detected kernel.  For now, we just always
 435         # set it to "yes".
 436         AS_IF([test x$enable_ldiskfs = xmaybe], [enable_ldiskfs=yes])
 437         AC_SUBST(ENABLE_LDISKFS, yes)
 438
 439         LDISKFS_LINUX_SERIES
 440         LDISKFS_AC_PATCH_PROGRAM
 441         LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 442         LB_EXT4_JOURNAL_START_3ARGS
 443         LB_EXT4_BREAD_4ARGS
 444         LB_EXT4_HAVE_INFO_DQUOT
 445         LB_EXT4_HAVE_I_CRYPT_INFO
 446         LB_LDISKFS_JOURNAL_ENSURE_CREDITS
 447         LB_LDISKFS_IGET_HAS_FLAGS_ARG
 448         LB_LDISKFS_FIND_ENTRY_LOCKED_EXISTS
 449         LB_LDISKFSFS_DIRHASH_WANTS_DIR
 450         LB_JBD2_H_TOTAL_CREDITS
 451         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [posix acls for ldiskfs])
 452         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [fs security for ldiskfs])
 453         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [extened attributes for ldiskfs])
 454         AC_DEFINE(CONFIG_LDISKFS_FS_RW, 1, [enable rw access for ldiskfs])
 455         AC_SUBST(LDISKFS_SUBDIR, ldiskfs)
 456         AC_DEFINE(HAVE_LDISKFS_OSD, 1, Enable ldiskfs osd)
 457 ], [
 458         AC_SUBST(ENABLE_LDISKFS, no)
 459 ])
 460
 461 AC_MSG_CHECKING([whether to build ldiskfs])
 462 AC_MSG_RESULT([$enable_ldiskfs])
 463
 464 AM_CONDITIONAL([LDISKFS_ENABLED], [test x$enable_ldiskfs = xyes])
 465 ]) # LB_CONFIG_LDISKFS
 466
 467
 468 AC_DEFUN([LB_EXT4_SRC_DIR_SRC], [])
 469 AC_DEFUN([LB_EXT4_SRC_DIR_RESULTS], [])
 470
 471 #
 472 # LB_VALIDATE_EXT4_SRC_DIR
 473 #
 474 # Spot check the existence of several source files common to ext4.
 475 # Detecting this at configure time allows us to avoid a potential build
 476 # failure and provide a useful error message to explain what is wrong.
 477 #
 478 AC_DEFUN([LB_VALIDATE_EXT4_SRC_DIR], [
 479 enable_ldiskfs_build="no"
 480 AS_IF([test -n "$EXT4_SRC_DIR"], [
 481         enable_ldiskfs_build="yes"
 482         LB_CHECK_FILE([$EXT4_SRC_DIR/dir.c], [], [
 483                 enable_ldiskfs_build="no"
 484                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 485         ])
 486         LB_CHECK_FILE([$EXT4_SRC_DIR/file.c], [], [
 487                 enable_ldiskfs_build="no"
 488                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 489         ])
 490         LB_CHECK_FILE([$EXT4_SRC_DIR/inode.c], [], [
 491                 enable_ldiskfs_build="no"
 492                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 493         ])
 494         LB_CHECK_FILE([$EXT4_SRC_DIR/super.c], [], [
 495                 enable_ldiskfs_build="no"
 496                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 497         ])
 498 ])
 499
 500 AS_IF([test "x$enable_ldiskfs_build" = xno], [
 501         enable_ldiskfs="no"
 502
 503         AC_MSG_WARN([
 504
 505 Disabling ldiskfs support because complete ext4 source does not exist.
 506
 507 If you are building using kernel-devel packages and require ldiskfs
 508 server support then ensure that the matching kernel-debuginfo-common
 509 and kernel-debuginfo-common-<arch> packages are installed.
 510 ])
 511 ])
 512 ]) # LB_VALIDATE_EXT4_SRC_DIR
 513
 514 #
 515 # LB_EXT4_SRC_DIR
 516 #
 517 # Determine the location of the ext4 source code.  It it required
 518 # for several configure tests and to build ldiskfs.
 519 #
 520 AC_DEFUN([LB_EXT4_SRC_DIR], [
 521 AC_MSG_CHECKING([ext4 source directory])
 522 # Kernel ext source located with devel headers
 523 linux_src=$LINUX
 524 AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 525         EXT4_SRC_DIR="$linux_src/fs/ext4"
 526 ], [
 527         # Kernel ext source provided by kernel-debuginfo-common package
 528         # that extracted to $LINUX
 529         linux_src=$(ls -1d $linux_src/../../debug/*/linux-${LINUXRELEASE%.*}* \
 530                 2>/dev/null | tail -1)
 531         AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 532                 EXT4_SRC_DIR="$linux_src/fs/ext4"
 533         ], [
 534                 # Kernel ext source provided by kernel-debuginfo-common package
 535                 linux_src=$(ls -1d /usr/src/debug/*/linux-${LINUXRELEASE%.*}* \
 536                         2>/dev/null | tail -1)
 537                 AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 538                         EXT4_SRC_DIR="$linux_src/fs/ext4"
 539                 ], [
 540                         EXT4_SRC_DIR=""
 541                 ])
 542         ])
 543 ])
 544 AC_MSG_RESULT([$EXT4_SRC_DIR])
 545 AC_SUBST(EXT4_SRC_DIR)
 546
 547 LB_VALIDATE_EXT4_SRC_DIR
 548 ]) # LB_EXT4_SRC_DIR
 549
 550 #
 551 # LB_DEFINE_E2FSPROGS_NAMES
 552 #
 553 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 554 #
 555 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES], [
 556 AC_MSG_CHECKING([whether to use alternate names for e2fsprogs])
 557 AC_ARG_WITH([ldiskfsprogs],
 558         AC_HELP_STRING([--with-ldiskfsprogs],
 559                 [use alternate names for ldiskfs-enabled e2fsprogs]),
 560         [], [withval="no"])
 561
 562 AS_IF([test "x$withval" = xyes], [
 563         AC_MSG_RESULT([enabled])
 564         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 565         E2FSPROGS="ldiskfsprogs"
 566         MKE2FS="mkfs.ldiskfs"
 567         DEBUGFS="debugfs.ldiskfs"
 568         TUNE2FS="tunefs.ldiskfs"
 569         E2LABEL="label.ldiskfs"
 570         DUMPE2FS="dumpfs.ldiskfs"
 571         E2FSCK="fsck.ldiskfs"
 572         PFSCK="pfsck.ldiskfs"
 573 ], [
 574         AC_MSG_RESULT([disabled])
 575         E2FSPROGS="e2fsprogs"
 576         MKE2FS="mke2fs"
 577         DEBUGFS="debugfs"
 578         TUNE2FS="tune2fs"
 579         E2LABEL="e2label"
 580         DUMPE2FS="dumpe2fs"
 581         E2FSCK="e2fsck"
 582         PFSCK="fsck"
 583 ])
 584
 585 AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 586 AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 587 AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 588 AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 589 AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 590 AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 591 AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 592 AC_DEFINE_UNQUOTED(PFSCK, "$PFSCK", [name of parallel fsck program])
 593
 594 AC_SUBST([E2FSPROGS], [$E2FSPROGS])
 595 AC_SUBST([MKE2FS], [$MKE2FS])
 596 AC_SUBST([DEBUGFS], [$DEBUGFS])
 597 AC_SUBST([TUNE2FS], [$TUNE2FS])
 598 AC_SUBST([E2LABEL], [$E2LABEL])
 599 AC_SUBST([DUMPE2FS], [$DUMPE2FS])
 600 AC_SUBST([E2FSCK], [$E2FSCK])
 601 AC_SUBST([PFSCK], [$PFSCK])
 602 ]) # LB_DEFINE_E2FSPROGS_NAMES