config/lustre-build-ldiskfs.m4

   1 #
   2 # LDISKFS_LINUX_SERIES
   3 #
   4 AC_DEFUN([LDISKFS_LINUX_SERIES], [
   5 AC_MSG_CHECKING([which ldiskfs series to use])
   6 case x$LDISKFS_SERIES in
   7         x)                      # not set
   8                 ;;
   9         *.series)               # set externally
  10                 ;;
  11         *) LDISKFS_SERIES=
  12 esac
  13 AS_IF([test -z "$LDISKFS_SERIES"], [
  14 AS_IF([test x$RHEL_KERNEL = xyes], [
  15         case $RHEL_RELEASE_NO in
  16         85)     LDISKFS_SERIES="4.18-rhel8.5.series"    ;;
  17         84)     LDISKFS_SERIES="4.18-rhel8.4.series"    ;;
  18         83)     LDISKFS_SERIES="4.18-rhel8.3.series"    ;;
  19         82)     LDISKFS_SERIES="4.18-rhel8.2.series"    ;;
  20         81)     LDISKFS_SERIES="4.18-rhel8.1.series"    ;;
  21         80)     LDISKFS_SERIES="4.18-rhel8.series"      ;;
  22         79)     LDISKFS_SERIES="3.10-rhel7.9.series"    ;;
  23         78)     LDISKFS_SERIES="3.10-rhel7.8.series"    ;;
  24         77)     LDISKFS_SERIES="3.10-rhel7.7.series"    ;;
  25         76)     LDISKFS_SERIES="3.10-rhel7.6.series"    ;;
  26         esac
  27 ], [test x$SUSE_KERNEL = xyes], [
  28         AS_VERSION_COMPARE([$LINUXRELEASE],[5.3.18],[
  29         AS_VERSION_COMPARE([$LINUXRELEASE],[4.12.14],[], [], [
  30                 suse_conf=$LINUX_OBJ/include/generated/uapi/linux/suse_version.h
  31                 suse_vers=$(awk '[$]2 == "SUSE_VERSION" {print [$]3 }' $suse_conf)
  32                 suse_patchlevel=$(awk '[$]2 == "SUSE_PATCHLEVEL" {print [$]3 }' $suse_conf)
  33                 echo "$suse_conf $suse_vers $suse_patchlevel  ${suse_vers}sp$suse_patchlevel" >> /tmp/log-nb
  34                 case ${suse_vers}sp$suse_patchlevel in # (
  35                 15sp0 ) LDISKFS_SERIES="4.12-sles15.series"
  36                         if test ! -f $LINUX/arch/x86/kernel/cpu/hygon.c ; then
  37                                 # This file was added shortly after -150.22 so
  38                                 # this must be 150.22 or earlier
  39                                 LDISKFS_SERIES="4.12-sles15-22.series"
  40                         fi
  41                         ;; # (
  42                 15sp1 ) LDISKFS_SERIES="4.12-sles15sp1.series"
  43                         if test ! -f $LINUX/arch/x86/kernel/cpu/umwait.c ; then
  44                                 # This file was added after -197.7 so
  45                                 # this must be -197.7 or earlier
  46                                 LDISKFS_SERIES="4.12-sles15sp1-7.series"
  47                         fi
  48                         ;;
  49                 esac
  50         ]
  51         )], [LDISKFS_SERIES="5.4.21-ml.series"],
  52             [
  53                 suse_conf=$LINUX_OBJ/include/generated/uapi/linux/suse_version.h
  54                 suse_vers=$(awk '[$]2 == "SUSE_VERSION" {print [$]3 }' $suse_conf)
  55                 suse_patchlevel=$(awk '[$]2 == "SUSE_PATCHLEVEL" {print [$]3 }' $suse_conf)
  56                 echo "$suse_conf $suse_vers $suse_patchlevel  ${suse_vers}sp$suse_patchlevel" >> /tmp/log-nb
  57
  58                 case ${suse_vers}sp${suse_patchlevel} in # (
  59                 15sp2 ) LDISKFS_SERIES="5.4.21-ml.series"
  60                         grep -A3 ext4_update_dx_flag $LINUX/fs/ext4/ext4.h \
  61                           | grep ext4_test_inode_flag
  62                         if test $? -eq 0; then
  63                                 LDISKFS_SERIES="5.4.0-66-ubuntu20.series"
  64                         fi
  65                         ;; # (
  66                 15sp3 ) LDISKFS_SERIES="5.3.18-sles15sp3.series"
  67                         ;;
  68                 esac
  69             ])
  70 ], [test x$UBUNTU_KERNEL = xyes], [
  71         AS_VERSION_COMPARE([$LINUXRELEASE],[5.8.0],[
  72         AS_VERSION_COMPARE([$LINUXRELEASE],[5.4.0],[
  73         AS_VERSION_COMPARE([$LINUXRELEASE],[5.0.0],[
  74         AS_VERSION_COMPARE([$LINUXRELEASE],[4.15.0],[
  75         AS_VERSION_COMPARE([$LINUXRELEASE],[4.4.0], [],
  76         [
  77                 KPLEV=$(echo $LINUXRELEASE | sed -n 's/.*-\([0-9]\+\).*/\1/p')
  78                 AS_IF(
  79                         [test -z "$KPLEV"], [
  80                                 AC_MSG_WARN([Failed to determine Kernel patch level. Assume latest.])
  81                                 LDISKFS_SERIES="4.4.0-73-ubuntu14+16.series"
  82                         ],
  83                         [test $KPLEV -ge 73], [LDISKFS_SERIES="4.4.0-73-ubuntu14+16.series"],
  84                         [test $KPLEV -ge 62], [LDISKFS_SERIES="4.4.0-62-ubuntu14+16.series"],
  85                         [test $KPLEV -ge 49], [LDISKFS_SERIES="4.4.0-49-ubuntu14+16.series"],
  86                         [LDISKFS_SERIES="4.4.0-45-ubuntu14+16.series"]
  87                 )
  88         ],
  89         [LDISKFS_SERIES="4.4.0-73-ubuntu14+16.series"])],
  90         [
  91                 KPLEV=$(echo $LINUXRELEASE | sed -n 's/.*-\([0-9]\+\).*/\1/p')
  92                 AS_IF(
  93                         [test -z "$KPLEV"], [
  94                                 AC_MSG_WARN([Failed to determine Kernel patch level. Assume latest.])
  95                                 LDISKFS_SERIES="4.15.0-24-ubuntu18.series"
  96                         ],
  97                         [test $KPLEV -ge 24], [LDISKFS_SERIES="4.15.0-24-ubuntu18.series"],
  98                         [test $KPLEV -ge 20], [LDISKFS_SERIES="4.15.0-20-ubuntu18.series"]
  99                 )
 100         ],
 101         [LDISKFS_SERIES="4.15.0-24-ubuntu18.series"])],
 102         [LDISKFS_SERIES="5.0.0-13-ubuntu19.series"],
 103         [LDISKFS_SERIES="5.0.0-13-ubuntu19.series"])],
 104         [LDISKFS_SERIES="5.4.0-42-ubuntu20.series"],
 105         [
 106                 KPLEV=$(echo $LINUXRELEASE | cut -d'-' -f2)
 107                 AS_IF(
 108                         [test -z "$KPLEV"], [
 109                                 AC_MSG_WARN([Failed to determine Kernel patch level. Assume latest.])
 110                                 LDISKFS_SERIES="5.4.0-90-ubuntu20.series"
 111                         ],
 112                         [test $KPLEV -eq 1007], [LDISKFS_SERIES="5.4.0-42-ubuntu20.series"],
 113                         [test $KPLEV -ge 90], [LDISKFS_SERIES="5.4.0-90-ubuntu20.series"],
 114                         [test $KPLEV -ge 80], [LDISKFS_SERIES="5.4.0-80-ubuntu20.series"],
 115                         [test $KPLEV -ge 66], [LDISKFS_SERIES="5.4.0-66-ubuntu20.series"],
 116                         [LDISKFS_SERIES="5.4.0-42-ubuntu20.series"]
 117                 )
 118         ],
 119         [LDISKFS_SERIES="5.4.0-ml.series"])],
 120         [LDISKFS_SERIES="5.8.0-53-ubuntu20.series"],
 121         [LDISKFS_SERIES="5.8.0-63-ubuntu20.series"],
 122         [LDISKFS_SERIES="5.8.0-ml.series"])
 123 ])
 124 ])
 125 # Not RHEL/SLES or Ubuntu .. probably mainline
 126 AS_IF([test -z "$LDISKFS_SERIES"],
 127         [
 128         AS_VERSION_COMPARE([$LINUXRELEASE],[5.4.0],[],
 129         [LDISKFS_SERIES="5.4.0-ml.series"],[
 130         AS_VERSION_COMPARE([$LINUXRELEASE],[5.4.21],
 131           [LDISKFS_SERIES="5.4.0-ml.series"],  # lt
 132           [LDISKFS_SERIES="5.4.21-ml.series"], # eq
 133           [AS_VERSION_COMPARE([$LINUXRELEASE],[5.8.0],
 134             [LDISKFS_SERIES="5.4.136-ml.series"], # lt
 135             [LDISKFS_SERIES="5.8.0-ml.series"],  # eq
 136             [AS_VERSION_COMPARE([$LINUXRELEASE],[5.9.0],
 137               [LDISKFS_SERIES="5.8.0-ml.series"],  # lt
 138               [LDISKFS_SERIES="5.9.0-ml.series"],  # eq
 139               [AS_VERSION_COMPARE([$LINUXRELEASE],[5.10.0],
 140                 [LDISKFS_SERIES="5.9.0-ml.series"],  # lt
 141                 [LDISKFS_SERIES="5.10.0-ml.series"],  # eq
 142                 [LDISKFS_SERIES="5.10.0-ml.series"],  # gt
 143               )]
 144             )]
 145           )]
 146                 )])
 147         ],
 148 [])
 149 AS_IF([test -z "$LDISKFS_SERIES"],
 150         [AC_MSG_RESULT([failed to identify series])],
 151         [AC_MSG_RESULT([$LDISKFS_SERIES for $LINUXRELEASE])])
 152 AC_SUBST(LDISKFS_SERIES)
 153 ]) # LDISKFS_LINUX_SERIES
 154
 155 #
 156 # LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 157 #
 158 # 2.6.32-rc7 ext4_free_blocks requires struct buffer_head
 159 # Note that RHEL6 is pre 2.6.32-rc7 so this check is still needed.
 160 #
 161 AC_DEFUN([LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD], [
 162 LB_CHECK_COMPILE([if 'ext4_free_blocks' needs 'struct buffer_head'],
 163 ext4_free_blocks_with_buffer_head, [
 164         #include <linux/fs.h>
 165         #include "$EXT4_SRC_DIR/ext4.h"
 166 ],[
 167         ext4_free_blocks(NULL, NULL, NULL, 0, 0, 0);
 168 ],[
 169         AC_DEFINE(HAVE_EXT_FREE_BLOCK_WITH_BUFFER_HEAD, 1,
 170                 [ext4_free_blocks do not require struct buffer_head])
 171 ])
 172 ]) # LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 173
 174 #
 175 # LB_EXT4_JOURNAL_START_3ARGS
 176 #
 177 # 3.9 added a type argument to ext4_journal_start and friends
 178 #
 179 AC_DEFUN([LB_EXT4_JOURNAL_START_3ARGS], [
 180 LB_CHECK_COMPILE([if ext4_journal_start takes 3 arguments],
 181 ext4_journal_start, [
 182         #include <linux/fs.h>
 183         #include "$EXT4_SRC_DIR/ext4_jbd2.h"
 184 ],[
 185         ext4_journal_start(NULL, 0, 0);
 186 ],[
 187         AC_DEFINE(JOURNAL_START_HAS_3ARGS, 1, [ext4_journal_start takes 3 arguments])
 188 ])
 189 ]) # LB_EXT4_JOURNAL_START_3ARGS
 190
 191 #
 192 # LB_EXT4_BREAD_4ARGS
 193 #
 194 # 3.18 ext4_bread has 4 arguments
 195 # NOTE: It may not be exported for modules, use a positive compiler test here.
 196 #
 197 AC_DEFUN([LB_EXT4_BREAD_4ARGS], [
 198 LB_CHECK_COMPILE([if ext4_bread takes 4 arguments],
 199 ext4_bread, [
 200         #include <linux/fs.h>
 201         #include "$EXT4_SRC_DIR/ext4.h"
 202
 203         struct buffer_head *ext4_bread(handle_t *handle, struct inode *inode,
 204                                        ext4_lblk_t block, int map_flags)
 205         {
 206                 struct buffer_head *bh = NULL;
 207                 (void)handle;
 208                 (void)inode;
 209                 (void)block;
 210                 (void)map_flags;
 211                 return bh;
 212         }
 213 ],[
 214         ext4_bread(NULL, NULL, 0, 0);
 215 ],[
 216         AC_DEFINE(HAVE_EXT4_BREAD_4ARGS, 1, [ext4_bread takes 4 arguments])
 217 ])
 218 ]) # LB_EXT4_BREAD_4ARGS
 219
 220 #
 221 # LB_EXT4_HAVE_INFO_DQUOT
 222 #
 223 # in linux 4.4 i_dqout is in ext4_inode_info, not in struct inode
 224 #
 225 AC_DEFUN([LB_EXT4_HAVE_INFO_DQUOT], [
 226 LB_CHECK_COMPILE([if i_dquot is in ext4_inode_info],
 227 ext4_info_dquot, [
 228         #include <linux/fs.h>
 229         #include <linux/quota.h>
 230         #include "$EXT4_SRC_DIR/ext4.h"
 231 ],[
 232         struct ext4_inode_info in;
 233         struct dquot *dq;
 234
 235         dq = in.i_dquot[0];
 236 ],[
 237         AC_DEFINE(HAVE_EXT4_INFO_DQUOT, 1, [i_dquot is in ext4_inode_info])
 238 ])
 239 ]) # LB_EXT4_HAVE_INFO_DQUOT
 240
 241 #
 242 # LB_EXT4_HAVE_I_CRYPT_INFO
 243 #
 244 # in linux 4.8 i_crypt_info moved from ext4_inode_info to struct inode
 245 #
 246 # Determine if we need to enable CONFIG_LDISKFS_FS_ENCRYPTION.
 247 # If we have i_crypt_info in ext4_inode_info, the config option
 248 # should be enabled to make the ldiskfs module compilation happy.
 249 # Otherwise i_crypy_info is in struct inode, we need to check kernel
 250 # config option to determine that.
 251 #
 252 AC_DEFUN([LB_EXT4_HAVE_I_CRYPT_INFO], [
 253 LB_CHECK_COMPILE([if i_crypt_info is in ext4_inode_info],
 254 ext4_i_crypt_info, [
 255         #define CONFIG_EXT4_FS_ENCRYPTION 1
 256         #include <linux/fs.h>
 257         #include "$EXT4_SRC_DIR/ext4.h"
 258 ],[
 259         struct ext4_inode_info in;
 260
 261         in.i_crypt_info = NULL;
 262 ],[
 263         AC_DEFINE(
 264                 CONFIG_LDISKFS_FS_ENCRYPTION, 1,
 265                 [enable encryption for ldiskfs]
 266         )
 267 ],[
 268         LB_CHECK_CONFIG([EXT4_FS_ENCRYPTION],[
 269                 AC_DEFINE(
 270                         CONFIG_LDISKFS_FS_ENCRYPTION, 1,
 271                         [enable encryption for ldiskfs]
 272                 )
 273         ])
 274 ])
 275 ]) # LB_EXT4_HAVE_I_CRYPT_INFO
 276
 277 #
 278 # LB_LDISKFS_JOURNAL_ENSURE_CREDITS
 279 #
 280 # kernel 4.18.0-240.1.1.el8 and
 281 # kernel 5.4 commit a413036791d040e33badcc634453a4d0c0705499
 282 #
 283 # ext4_journal_ensure_credits was introduced to ensure given handle
 284 # has at least requested amount of credits available, and possibly
 285 # restarting transaction if needed.
 286 #
 287 AC_DEFUN([LB_LDISKFS_JOURNAL_ENSURE_CREDITS], [
 288 tmp_flags="$EXTRA_KCFLAGS"
 289 EXTRA_KCFLAGS="-Werror"
 290 LB_CHECK_COMPILE([if 'ext4_journal_ensure_credits' exists],
 291 ext4_journal_ensure_credits, [
 292         #include "$EXT4_SRC_DIR/ext4_jbd2.h"
 293         int __ext4_journal_ensure_credits(handle_t *handle, int check_cred,
 294                 int extend_cred, int revoke_cred) { return 0; }
 295 ],[
 296         ext4_journal_ensure_credits(NULL, 0, 0);
 297 ],[
 298         AC_DEFINE(HAVE_LDISKFS_JOURNAL_ENSURE_CREDITS, 1,
 299                 ['ext4_journal_ensure_credits' exists])
 300 ])
 301 EXTRA_KCFLAGS="$tmp_flags"
 302 ]) # LB_LDISKFS_JOURNAL_ENSURE_CREDITS
 303
 304 #
 305 # LB_LDISKFS_IGET_HAS_FLAGS_ARG
 306 #
 307 # kernel 4.19 commit 8a363970d1dc38c4ec4ad575c862f776f468d057
 308 # ext4_iget changed to a macro with 3 args was function with 2 args
 309 #
 310 AC_DEFUN([LB_LDISKFS_IGET_HAS_FLAGS_ARG], [
 311 tmp_flags="$EXTRA_KCFLAGS"
 312 EXTRA_KCFLAGS="-Werror"
 313 LB_CHECK_COMPILE([if ldiskfs_iget takes a flags argument],
 314 ext4_iget_3args, [
 315         #include <linux/fs.h>
 316         #include "$EXT4_SRC_DIR/ext4.h"
 317 ],[
 318         int f = EXT4_IGET_SPECIAL;
 319         (void)f;
 320 ],[
 321         AC_DEFINE(HAVE_LDISKFS_IGET_WITH_FLAGS, 1,
 322                 [if ldiskfs_iget takes a flags argument])
 323 ])
 324 EXTRA_KCFLAGS="$tmp_flags"
 325 ]) # LB_LDISKFS_IGET_HAS_FLAGS_ARG
 326
 327 #
 328 # LDISKFS_AC_PATCH_PROGRAM
 329 #
 330 # Determine which program should be used to apply the patches to
 331 # the ext4 source code to produce the ldiskfs source code.
 332 #
 333 AC_DEFUN([LDISKFS_AC_PATCH_PROGRAM], [
 334         AC_ARG_ENABLE([quilt],
 335                 [AC_HELP_STRING([--disable-quilt],
 336                         [disable use of quilt for ldiskfs])],
 337                 [AS_IF([test "x$enableval" = xno],
 338                         [use_quilt=no],
 339                         [use_quilt=maybe])],
 340                 [use_quilt=maybe]
 341         )
 342
 343         AS_IF([test x$use_quilt = xmaybe], [
 344                 AC_PATH_PROG([quilt_avail], [quilt], [no])
 345                 AS_IF([test x$quilt_avail = xno], [
 346                         use_quilt=no
 347                 ], [
 348                         use_quilt=yes
 349                 ])
 350         ])
 351
 352         AS_IF([test x$use_quilt = xno], [
 353                 AC_PATH_PROG([patch_avail], [patch], [no])
 354                 AS_IF([test x$patch_avail = xno], [
 355                         AC_MSG_ERROR([*** Need "quilt" or "patch" command])
 356                 ])
 357         ])
 358 ]) # LDISKFS_AC_PATCH_PROGRAM
 359
 360 #
 361 # LB_LDISKFS_FIND_ENTRY_LOCKED_EXISTS
 362 #
 363 # kernel 5.2 commit 8a363970d1dc38c4ec4ad575c862f776f468d057
 364 # ext4: avoid declaring fs inconsistent due to invalid file handles
 365 # __ext4_find_entry became a helper function for ext4_find_entry
 366 # conflicting with previous ldiskfs patches.
 367 # ldiskfs patches map ext4_find_entry to ldiskfs_find_entry_locked to
 368 # avoid conflicting with __ext4_find_entry
 369 #
 370 # When the following check succeeds __ext4_find_entry helper is not
 371 # used.
 372 #
 373 AC_DEFUN([LB_LDISKFS_FIND_ENTRY_LOCKED_EXISTS], [
 374 tmp_flags="$EXTRA_KCFLAGS"
 375 EXTRA_KCFLAGS="-Werror"
 376 LB_CHECK_COMPILE([if __ldiskfs_find_entry is available],
 377 ldiskfs_find_entry_locked, [
 378         #include <linux/fs.h>
 379         #include "$EXT4_SRC_DIR/ext4.h"
 380         #include "$EXT4_SRC_DIR/namei.c"
 381
 382         static int __ext4_find_entry(void) { return 0; }
 383 ],[
 384         int x = __ext4_find_entry();
 385         (void)x;
 386 ],[
 387         AC_DEFINE(HAVE___LDISKFS_FIND_ENTRY, 1,
 388                 [if __ldiskfs_find_entry is available])
 389 ])
 390 EXTRA_KCFLAGS="$tmp_flags"
 391 ]) # LB_LDISKFS_FIND_ENTRY_LOCKED_EXISTS
 392
 393 #
 394 # LB_LDISKFSFS_DIRHASH_WANTS_DIR
 395 #
 396 # kernel 5.2 commit 8a363970d1dc38c4ec4ad575c862f776f468d057
 397 # ext4fs_dirhash UNICODE support
 398 #
 399 AC_DEFUN([LB_LDISKFSFS_DIRHASH_WANTS_DIR], [
 400 tmp_flags="$EXTRA_KCFLAGS"
 401 EXTRA_KCFLAGS="-Werror"
 402 LB_CHECK_COMPILE([if ldiskfsfs_dirhash takes an inode argument],
 403 ext4fs_dirhash, [
 404         #include <linux/fs.h>
 405         #include "$EXT4_SRC_DIR/ext4.h"
 406
 407         int ext4fs_dirhash(const struct inode *dir, const char *name, int len,
 408                           struct dx_hash_info *hinfo)
 409         {
 410                 (void)dir;
 411                 (void)name;
 412                 (void)len;
 413                 (void)hinfo;
 414                 return 0;
 415         }
 416 ],[
 417         int f = ext4fs_dirhash(NULL, NULL, 0, NULL);
 418         (void)f;
 419 ],[
 420         AC_DEFINE(HAVE_LDISKFSFS_GETHASH_INODE_ARG, 1,
 421                 [ldiskfsfs_dirhash takes an inode argument])
 422 ])
 423 EXTRA_KCFLAGS="$tmp_flags"
 424 ]) # LB_LDISKFSFS_DIRHASH_WANTS_DIR
 425
 426 #
 427 # LB_JBD2_H_TOTAL_CREDITS
 428 #
 429 # kernel 5.5 commit 933f1c1e0b75bbc29730eef07c9e196c6dfd37e5
 430 # jbd2: Reserve space for revoke descriptor blocks
 431 #
 432 AC_DEFUN([LB_JBD2_H_TOTAL_CREDITS], [
 433 tmp_flags="$EXTRA_KCFLAGS"
 434 EXTRA_KCFLAGS="-Werror"
 435 LB_CHECK_COMPILE([if struct jbd2_journal_handle has h_total_credits member],
 436 handle_t_h_revoke_credits, [
 437         #include <linux/jbd2.h>
 438 ],[
 439         int x = offsetof(struct jbd2_journal_handle, h_total_credits);
 440         (void)x;
 441 ],[
 442         AC_DEFINE(HAVE_JOURNAL_TOTAL_CREDITS, 1,
 443                 [struct jbd2_journal_handle has h_total_credits member])
 444 ])
 445 EXTRA_KCFLAGS="$tmp_flags"
 446 ]) # LB_JBD2_H_TOTAL_CREDITS
 447
 448 #
 449 # LB_EXT4_GET_BLOCKS_KEEP_SIZE
 450 #
 451 # kernel 5.6-rc4 commit 9e52484c713321e84e8834803a44ca0a001376d2
 452 # ext4: remove EXT4_GET_BLOCKS_KEEP_SIZE flag
 453 #
 454 AC_DEFUN([LB_EXT4_GET_BLOCKS_KEEP_SIZE], [
 455 tmp_flags="$EXTRA_KCFLAGS"
 456 EXTRA_KCFLAGS="-Werror"
 457 LB_CHECK_COMPILE([if EXT4_GET_BLOCKS_KEEP_SIZE exists],
 458 ext4_get_blocks_keep_size, [
 459         #include <linux/fs.h>
 460         #include "$EXT4_SRC_DIR/ext4.h"
 461 ],[
 462         int f = EXT4_IGET_SPECIAL;
 463         (void)f;
 464 ],[
 465         AC_DEFINE(HAVE_LDISKFS_GET_BLOCKS_KEEP_SIZE, 1,
 466                 [EXT4_GET_BLOCKS_KEEP_SIZE exists])
 467 ])
 468 EXTRA_KCFLAGS="$tmp_flags"
 469 ]) # LB_EXT4_GET_BLOCKS_KEEP_SIZE
 470
 471 #
 472 # LB_EXT4_INC_DEC_COUNT_2ARGS
 473 #
 474 # Linux v5.9-rc7-8-g15ed2851b0f4
 475 # ext4: remove unused argument from ext4_(inc|dec)_count
 476 #
 477 AC_DEFUN([LB_EXT4_INC_DEC_COUNT_2ARGS], [
 478         AC_MSG_CHECKING([if ext4_(inc|dec)_count() have 2 arguments])
 479         AS_IF([grep -q -E 'void ext4_inc_count.handle_t \*handle' $EXT4_SRC_DIR/namei.c],[
 480                 AC_DEFINE(HAVE_EXT4_INC_DEC_COUNT_2ARGS, 1,
 481                         [ext4_(inc|dec)_count() has 2 arguments])
 482                 AC_MSG_RESULT(yes)
 483         ],[
 484                 AC_MSG_RESULT(no)
 485         ])
 486 ]) # LB_EXT4_INC_DEC_COUNT_2ARGS
 487
 488 #
 489 # LB_CONFIG_LDISKFS
 490 #
 491 AC_DEFUN([LB_CONFIG_LDISKFS], [
 492 # --with-ldiskfs is deprecated now that ldiskfs is fully merged with lustre.
 493 # However we continue to support this option through Lustre 2.5.
 494 AC_ARG_WITH([ldiskfs],
 495         [],
 496         [AC_MSG_WARN([--with-ldiskfs is deprecated, please use --enable-ldiskfs])
 497         AS_IF([test x$withval != xyes -a x$withval != xno],
 498                 [AC_MSG_ERROR([
 499
 500 The ldiskfs option is deprecated,
 501 and no longer supports paths to external ldiskfs source
 502 ])])
 503 ])
 504
 505 AC_ARG_ENABLE([ldiskfs],
 506         [AS_HELP_STRING([--disable-ldiskfs],
 507                 [disable ldiskfs osd (default is enable)])],
 508         [AS_IF([test x$enable_ldiskfs != xyes -a x$enable_ldiskfs != xno],
 509                 [AC_MSG_ERROR([ldiskfs valid options are "yes" or "no"])])],
 510         [AS_IF([test "${with_ldiskfs+set}" = set],
 511                 [enable_ldiskfs=$with_ldiskfs],
 512                 [enable_ldiskfs=maybe])
 513 ])
 514
 515 AS_IF([test x$enable_server = xno],
 516         [AS_CASE([$enable_ldiskfs],
 517                 [maybe], [enable_ldiskfs=no],
 518                 [yes], [AC_MSG_ERROR([cannot build ldiskfs when servers are disabled])]
 519         )])
 520
 521 AS_IF([test x$enable_ldiskfs != xno],[
 522         # In the future, we chould change enable_ldiskfs from maybe to
 523         # either yes or no based on additional tests, e.g.  whether a patch
 524         # set is available for the detected kernel.  For now, we just always
 525         # set it to "yes".
 526         AS_IF([test x$enable_ldiskfs = xmaybe], [enable_ldiskfs=yes])
 527         AC_SUBST(ENABLE_LDISKFS, yes)
 528
 529         LDISKFS_LINUX_SERIES
 530         LDISKFS_AC_PATCH_PROGRAM
 531         LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 532         LB_EXT4_JOURNAL_START_3ARGS
 533         LB_EXT4_BREAD_4ARGS
 534         LB_EXT4_HAVE_INFO_DQUOT
 535         LB_EXT4_HAVE_I_CRYPT_INFO
 536         LB_LDISKFS_JOURNAL_ENSURE_CREDITS
 537         LB_LDISKFS_IGET_HAS_FLAGS_ARG
 538         LB_LDISKFS_FIND_ENTRY_LOCKED_EXISTS
 539         LB_LDISKFSFS_DIRHASH_WANTS_DIR
 540         LB_JBD2_H_TOTAL_CREDITS
 541         LB_EXT4_GET_BLOCKS_KEEP_SIZE
 542         LB_EXT4_INC_DEC_COUNT_2ARGS
 543         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [posix acls for ldiskfs])
 544         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [fs security for ldiskfs])
 545         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [extened attributes for ldiskfs])
 546         AC_DEFINE(CONFIG_LDISKFS_FS_RW, 1, [enable rw access for ldiskfs])
 547         AC_SUBST(LDISKFS_SUBDIR, ldiskfs)
 548         AC_DEFINE(HAVE_LDISKFS_OSD, 1, Enable ldiskfs osd)
 549 ], [
 550         AC_SUBST(ENABLE_LDISKFS, no)
 551 ])
 552
 553 AC_MSG_CHECKING([whether to build ldiskfs])
 554 AC_MSG_RESULT([$enable_ldiskfs])
 555
 556 AM_CONDITIONAL([LDISKFS_ENABLED], [test x$enable_ldiskfs = xyes])
 557 ]) # LB_CONFIG_LDISKFS
 558
 559
 560 AC_DEFUN([LB_EXT4_SRC_DIR_SRC], [])
 561 AC_DEFUN([LB_EXT4_SRC_DIR_RESULTS], [])
 562
 563 #
 564 # LB_VALIDATE_EXT4_SRC_DIR
 565 #
 566 # Spot check the existence of several source files common to ext4.
 567 # Detecting this at configure time allows us to avoid a potential build
 568 # failure and provide a useful error message to explain what is wrong.
 569 #
 570 AC_DEFUN([LB_VALIDATE_EXT4_SRC_DIR], [
 571 enable_ldiskfs_build="no"
 572 AS_IF([test -n "$EXT4_SRC_DIR"], [
 573         enable_ldiskfs_build="yes"
 574         LB_CHECK_FILE([$EXT4_SRC_DIR/dir.c], [], [
 575                 enable_ldiskfs_build="no"
 576                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 577         ])
 578         LB_CHECK_FILE([$EXT4_SRC_DIR/file.c], [], [
 579                 enable_ldiskfs_build="no"
 580                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 581         ])
 582         LB_CHECK_FILE([$EXT4_SRC_DIR/inode.c], [], [
 583                 enable_ldiskfs_build="no"
 584                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 585         ])
 586         LB_CHECK_FILE([$EXT4_SRC_DIR/super.c], [], [
 587                 enable_ldiskfs_build="no"
 588                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 589         ])
 590 ])
 591
 592 AS_IF([test "x$enable_ldiskfs_build" = xno], [
 593         enable_ldiskfs="no"
 594
 595         AC_MSG_WARN([
 596
 597 Disabling ldiskfs support because complete ext4 source does not exist.
 598
 599 If you are building using kernel-devel packages and require ldiskfs
 600 server support then ensure that the matching kernel-debuginfo-common
 601 and kernel-debuginfo-common-<arch> packages are installed.
 602 ])
 603 ])
 604 ]) # LB_VALIDATE_EXT4_SRC_DIR
 605
 606 #
 607 # LB_EXT4_SRC_DIR
 608 #
 609 # Determine the location of the ext4 source code.  It it required
 610 # for several configure tests and to build ldiskfs.
 611 #
 612 AC_DEFUN([LB_EXT4_SRC_DIR], [
 613 AC_MSG_CHECKING([ext4 source directory])
 614 # Kernel ext source located with devel headers
 615 linux_src=$LINUX
 616 AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 617         EXT4_SRC_DIR="$linux_src/fs/ext4"
 618 ], [
 619         # Kernel ext source provided by kernel-debuginfo-common package
 620         # that extracted to $LINUX
 621         linux_src=$(ls -1d $linux_src/../../debug/*/linux-${LINUXRELEASE%.*}* \
 622                 2>/dev/null | tail -1)
 623         AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 624                 EXT4_SRC_DIR="$linux_src/fs/ext4"
 625         ], [
 626                 # Kernel ext source provided by kernel-debuginfo-common package
 627                 linux_src=$(ls -1d /usr/src/debug/*/linux-${LINUXRELEASE%.*}* \
 628                         2>/dev/null | tail -1)
 629                 AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 630                         EXT4_SRC_DIR="$linux_src/fs/ext4"
 631                 ], [
 632                         EXT4_SRC_DIR=""
 633                 ])
 634         ])
 635 ])
 636 AC_MSG_RESULT([$EXT4_SRC_DIR])
 637 AC_SUBST(EXT4_SRC_DIR)
 638
 639 LB_VALIDATE_EXT4_SRC_DIR
 640 ]) # LB_EXT4_SRC_DIR
 641
 642 #
 643 # LB_DEFINE_E2FSPROGS_NAMES
 644 #
 645 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 646 #
 647 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES], [
 648 AC_MSG_CHECKING([whether to use alternate names for e2fsprogs])
 649 AC_ARG_WITH([ldiskfsprogs],
 650         AC_HELP_STRING([--with-ldiskfsprogs],
 651                 [use alternate names for ldiskfs-enabled e2fsprogs]),
 652         [], [withval="no"])
 653
 654 AS_IF([test "x$withval" = xyes], [
 655         AC_MSG_RESULT([enabled])
 656         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 657         E2FSPROGS="ldiskfsprogs"
 658         MKE2FS="mkfs.ldiskfs"
 659         DEBUGFS="debugfs.ldiskfs"
 660         TUNE2FS="tunefs.ldiskfs"
 661         E2LABEL="label.ldiskfs"
 662         DUMPE2FS="dumpfs.ldiskfs"
 663         E2FSCK="fsck.ldiskfs"
 664         PFSCK="pfsck.ldiskfs"
 665 ], [
 666         AC_MSG_RESULT([disabled])
 667         E2FSPROGS="e2fsprogs"
 668         MKE2FS="mke2fs"
 669         DEBUGFS="debugfs"
 670         TUNE2FS="tune2fs"
 671         E2LABEL="e2label"
 672         DUMPE2FS="dumpe2fs"
 673         E2FSCK="e2fsck"
 674         PFSCK="fsck"
 675 ])
 676
 677 AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 678 AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 679 AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 680 AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 681 AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 682 AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 683 AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 684 AC_DEFINE_UNQUOTED(PFSCK, "$PFSCK", [name of parallel fsck program])
 685
 686 AC_SUBST([E2FSPROGS], [$E2FSPROGS])
 687 AC_SUBST([MKE2FS], [$MKE2FS])
 688 AC_SUBST([DEBUGFS], [$DEBUGFS])
 689 AC_SUBST([TUNE2FS], [$TUNE2FS])
 690 AC_SUBST([E2LABEL], [$E2LABEL])
 691 AC_SUBST([DUMPE2FS], [$DUMPE2FS])
 692 AC_SUBST([E2FSCK], [$E2FSCK])
 693 AC_SUBST([PFSCK], [$PFSCK])
 694 ]) # LB_DEFINE_E2FSPROGS_NAMES