config/lustre-build-ldiskfs.m4

   1 #
   2 # LDISKFS_LINUX_SERIES
   3 #
   4 AC_DEFUN([LDISKFS_LINUX_SERIES], [
   5 AC_MSG_CHECKING([which ldiskfs series to use])
   6 case x$LDISKFS_SERIES in
   7         x)                      # not set
   8                 ;;
   9         *.series)               # set externally
  10                 ;;
  11         *) LDISKFS_SERIES=
  12 esac
  13 AS_IF([test -z "$LDISKFS_SERIES"], [
  14 AS_IF([test x$RHEL_KERNEL = xyes], [
  15         case $RHEL_RELEASE_NO in
  16         72)     LDISKFS_SERIES="3.10-rhel7.2.series"    ;;
  17         71)     LDISKFS_SERIES="3.10-rhel7.series"      ;;
  18         68)     LDISKFS_SERIES="2.6-rhel6.8.series"     ;;
  19         67)     LDISKFS_SERIES="2.6-rhel6.7.series"     ;;
  20         66)     LDISKFS_SERIES="2.6-rhel6.6.series"     ;;
  21         65)     LDISKFS_SERIES="2.6-rhel6.5.series"     ;;
  22         64)     LDISKFS_SERIES="2.6-rhel6.4.series"     ;;
  23         6[0-3]) LDISKFS_SERIES="2.6-rhel6.series"       ;;
  24         esac
  25 ], [test x$SUSE_KERNEL = xyes], [
  26         AS_VERSION_COMPARE([$LINUXRELEASE],[3.12.0],[
  27         AS_VERSION_COMPARE([$LINUXRELEASE],[3.0.0],[
  28         AS_VERSION_COMPARE([$LINUXRELEASE],[2.6.32], [],
  29         [LDISKFS_SERIES="2.6-sles11.series"],[LDISKFS_SERIES="2.6-sles11.series"])],
  30         [LDISKFS_SERIES="3.0-sles11.series"],[
  31                 PLEV=$(grep PATCHLEVEL /etc/SuSE-release | sed -e 's/.*= *//')
  32                 case $PLEV in
  33                 2) LDISKFS_SERIES="3.0-sles11.series"
  34                         ;;
  35                 3|4) LDISKFS_SERIES="3.0-sles11sp3.series"
  36                         ;;
  37                 esac
  38         ])],[LDISKFS_SERIES="3.12-sles12.series"],[
  39                 PLEV=$(grep PATCHLEVEL /etc/SuSE-release | sed -e 's/.*= *//')
  40                 case $PLEV in
  41                 1) LDISKFS_SERIES="3.12-sles12sp1.series"
  42                         ;;
  43                 *) LDISKFS_SERIES="3.12-sles12.series"
  44                         ;;
  45                 esac
  46         ])
  47 ])
  48 ])
  49 AS_IF([test -z "$LDISKFS_SERIES"],
  50         [AC_MSG_WARN([Unknown kernel version $LDISKFS_VERSIONRELEASE])])
  51 AC_MSG_RESULT([$LDISKFS_SERIES])
  52 AC_SUBST(LDISKFS_SERIES)
  53 ]) # LDISKFS_LINUX_SERIES
  54
  55 #
  56 # LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
  57 #
  58 # 2.6.32-rc7 ext4_free_blocks requires struct buffer_head
  59 # Note that RHEL6 is pre 2.6.32-rc7 so this check is still needed.
  60 #
  61 AC_DEFUN([LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD], [
  62 LB_CHECK_COMPILE([if 'ext4_free_blocks' needs 'struct buffer_head'],
  63 ext4_free_blocks_with_buffer_head, [
  64         #include <linux/fs.h>
  65         #include "$EXT4_SRC_DIR/ext4.h"
  66 ],[
  67         ext4_free_blocks(NULL, NULL, NULL, 0, 0, 0);
  68 ],[
  69         AC_DEFINE(HAVE_EXT_FREE_BLOCK_WITH_BUFFER_HEAD, 1,
  70                 [ext4_free_blocks do not require struct buffer_head])
  71 ])
  72 ]) # LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
  73
  74 #
  75 # LB_EXT_PBLOCK
  76 #
  77 # 2.6.35 renamed ext_pblock to ext4_ext_pblock(ex)
  78 #
  79 AC_DEFUN([LB_EXT_PBLOCK], [
  80 LB_CHECK_COMPILE([if Linux kernel has 'ext_pblock'],
  81 ext_pblock, [
  82         #include <linux/fs.h>
  83         #include "$EXT4_SRC_DIR/ext4_extents.h"
  84 ],[
  85         ext_pblock(NULL);
  86 ],[
  87         AC_DEFINE(HAVE_EXT_PBLOCK, 1, [Linux kernel has ext_pblock])
  88 ])
  89 ]) # LB_EXT_PBLOCK
  90
  91 #
  92 # LB_EXT4_JOURNAL_START_3ARGS
  93 #
  94 # 3.9 added a type argument to ext4_journal_start and friends
  95 #
  96 AC_DEFUN([LB_EXT4_JOURNAL_START_3ARGS], [
  97 LB_CHECK_COMPILE([if ext4_journal_start takes 3 arguments],
  98 ext4_journal_start, [
  99         #include <linux/fs.h>
 100         #include "$EXT4_SRC_DIR/ext4_jbd2.h"
 101 ],[
 102         ext4_journal_start(NULL, 0, 0);
 103 ],[
 104         AC_DEFINE(JOURNAL_START_HAS_3ARGS, 1, [ext4_journal_start takes 3 arguments])
 105 ])
 106 ]) # LB_EXT4_JOURNAL_START_3ARGS
 107
 108 #
 109 # LB_LDISKFS_MAP_BLOCKS
 110 #
 111 # Since 2.6.35 brought ext4_map_blocks() for IO.
 112 # We just check this function whether existed.
 113 # it must be exported by ldiskfs patches.
 114 #
 115 AC_DEFUN([LB_LDISKFS_MAP_BLOCKS], [
 116 LB_CHECK_COMPILE([if kernel has ext4_map_blocks],
 117 ext4_map_blocks, [
 118         #include <linux/fs.h>
 119         #include "$EXT4_SRC_DIR/ext4.h"
 120 ],[
 121         ext4_map_blocks(NULL, NULL, NULL, 0);
 122 ],[
 123         AC_DEFINE(HAVE_LDISKFS_MAP_BLOCKS, 1, [kernel has ext4_map_blocks])
 124 ])
 125 ])
 126
 127 #
 128 # LDISKFS_AC_PATCH_PROGRAM
 129 #
 130 # Determine which program should be used to apply the patches to
 131 # the ext4 source code to produce the ldiskfs source code.
 132 #
 133 AC_DEFUN([LDISKFS_AC_PATCH_PROGRAM], [
 134         AC_ARG_ENABLE([quilt],
 135                 [AC_HELP_STRING([--disable-quilt],
 136                         [disable use of quilt for ldiskfs])],
 137                 [AS_IF([test "x$enableval" = xno],
 138                         [use_quilt=no],
 139                         [use_quilt=maybe])],
 140                 [use_quilt=maybe]
 141         )
 142
 143         AS_IF([test x$use_quilt = xmaybe], [
 144                 AC_PATH_PROG([quilt_avail], [quilt], [no])
 145                 AS_IF([test x$quilt_avail = xno], [
 146                         use_quilt=no
 147                 ], [
 148                         use_quilt=yes
 149                 ])
 150         ])
 151
 152         AS_IF([test x$use_quilt = xno], [
 153                 AC_PATH_PROG([patch_avail], [patch], [no])
 154                 AS_IF([test x$patch_avail = xno], [
 155                         AC_MSG_ERROR([*** Need "quilt" or "patch" command])
 156                 ])
 157         ])
 158 ]) # LDISKFS_AC_PATCH_PROGRAM
 159
 160 #
 161 # LB_CONFIG_LDISKFS
 162 #
 163 AC_DEFUN([LB_CONFIG_LDISKFS], [
 164 # --with-ldiskfs is deprecated now that ldiskfs is fully merged with lustre.
 165 # However we continue to support this option through Lustre 2.5.
 166 AC_ARG_WITH([ldiskfs],
 167         [],
 168         [AC_MSG_WARN([--with-ldiskfs is deprecated, please use --enable-ldiskfs])
 169         AS_IF([test x$withval != xyes -a x$withval != xno],
 170                 [AC_MSG_ERROR([
 171
 172 The ldiskfs option is deprecated,
 173 and no longer supports paths to external ldiskfs source
 174 ])])
 175 ])
 176
 177 AC_ARG_ENABLE([ldiskfs],
 178         [AS_HELP_STRING([--disable-ldiskfs],
 179                 [disable ldiskfs osd (default is enable)])],
 180         [AS_IF([test x$enable_ldiskfs != xyes -a x$enable_ldiskfs != xno],
 181                 [AC_MSG_ERROR([ldiskfs valid options are "yes" or "no"])])],
 182         [AS_IF([test "${with_ldiskfs+set}" = set],
 183                 [enable_ldiskfs=$with_ldiskfs],
 184                 [enable_ldiskfs=maybe])
 185 ])
 186
 187 AS_IF([test x$enable_server = xno],
 188         [AS_CASE([$enable_ldiskfs],
 189                 [maybe], [enable_ldiskfs=no],
 190                 [yes], [AC_MSG_ERROR([cannot build ldiskfs when servers are disabled])]
 191         )])
 192
 193 AS_IF([test x$enable_ldiskfs != xno],[
 194         # In the future, we chould change enable_ldiskfs from maybe to
 195         # either yes or no based on additional tests, e.g.  whether a patch
 196         # set is available for the detected kernel.  For now, we just always
 197         # set it to "yes".
 198         AS_IF([test x$enable_ldiskfs = xmaybe], [enable_ldiskfs=yes])
 199
 200         LDISKFS_LINUX_SERIES
 201         LDISKFS_AC_PATCH_PROGRAM
 202         LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 203         LB_EXT_PBLOCK
 204         LB_EXT4_JOURNAL_START_3ARGS
 205         LB_LDISKFS_MAP_BLOCKS
 206         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [posix acls for ldiskfs])
 207         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [fs security for ldiskfs])
 208         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [extened attributes for ldiskfs])
 209         AC_DEFINE(CONFIG_LDISKFS_FS_RW, 1, [enable rw access for ldiskfs])
 210         AC_SUBST(LDISKFS_SUBDIR, ldiskfs)
 211         AC_DEFINE(HAVE_LDISKFS_OSD, 1, Enable ldiskfs osd)
 212 ])
 213
 214 AC_MSG_CHECKING([whether to build ldiskfs])
 215 AC_MSG_RESULT([$enable_ldiskfs])
 216
 217 AM_CONDITIONAL([LDISKFS_ENABLED], [test x$enable_ldiskfs = xyes])
 218 ]) # LB_CONFIG_LDISKFS
 219
 220 #
 221 # LB_VALIDATE_EXT4_SRC_DIR
 222 #
 223 # Spot check the existence of several source files common to ext4.
 224 # Detecting this at configure time allows us to avoid a potential build
 225 # failure and provide a useful error message to explain what is wrong.
 226 #
 227 AC_DEFUN([LB_VALIDATE_EXT4_SRC_DIR], [
 228 enable_ldiskfs_build="no"
 229 AS_IF([test -n "$EXT4_SRC_DIR"], [
 230         enable_ldiskfs_build="yes"
 231         LB_CHECK_FILE([$EXT4_SRC_DIR/dir.c], [], [
 232                 enable_ldiskfs_build="no"
 233                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 234         ])
 235         LB_CHECK_FILE([$EXT4_SRC_DIR/file.c], [], [
 236                 enable_ldiskfs_build="no"
 237                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 238         ])
 239         LB_CHECK_FILE([$EXT4_SRC_DIR/inode.c], [], [
 240                 enable_ldiskfs_build="no"
 241                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 242         ])
 243         LB_CHECK_FILE([$EXT4_SRC_DIR/super.c], [], [
 244                 enable_ldiskfs_build="no"
 245                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 246         ])
 247 ])
 248
 249 AS_IF([test "x$enable_ldiskfs_build" = xno], [
 250         enable_ldiskfs="no"
 251
 252         AC_MSG_WARN([
 253
 254 Disabling ldiskfs support because complete ext4 source does not exist.
 255
 256 If you are building using kernel-devel packages and require ldiskfs
 257 server support then ensure that the matching kernel-debuginfo-common
 258 and kernel-debuginfo-common-<arch> packages are installed.
 259 ])
 260 ])
 261 ]) # LB_VALIDATE_EXT4_SRC_DIR
 262
 263 #
 264 # LB_EXT4_SRC_DIR
 265 #
 266 # Determine the location of the ext4 source code.  It it required
 267 # for several configure tests and to build ldiskfs.
 268 #
 269 AC_DEFUN([LB_EXT4_SRC_DIR], [
 270 AC_MSG_CHECKING([ext4 source directory])
 271 # Kernel ext source located with devel headers
 272 linux_src=$LINUX
 273 AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 274         EXT4_SRC_DIR="$linux_src/fs/ext4"
 275 ], [
 276         # Kernel ext source provided by kernel-debuginfo-common package
 277         linux_src=$(ls -1d /usr/src/debug/*/linux-$LINUXRELEASE \
 278                 2>/dev/null | tail -1)
 279         AS_IF([test -e "$linux_src/fs/ext4/super.c"],
 280                 [EXT4_SRC_DIR="$linux_src/fs/ext4"],
 281                 [EXT4_SRC_DIR=""])
 282 ])
 283 AC_MSG_RESULT([$EXT4_SRC_DIR])
 284 AC_SUBST(EXT4_SRC_DIR)
 285
 286 LB_VALIDATE_EXT4_SRC_DIR
 287 ]) # LB_EXT4_SRC_DIR
 288
 289 #
 290 # LB_DEFINE_E2FSPROGS_NAMES
 291 #
 292 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 293 #
 294 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES], [
 295 AC_MSG_CHECKING([whether to use alternate names for e2fsprogs])
 296 AC_ARG_WITH([ldiskfsprogs],
 297         AC_HELP_STRING([--with-ldiskfsprogs],
 298                 [use alternate names for ldiskfs-enabled e2fsprogs]),
 299         [], [withval="no"])
 300
 301 AS_IF([test "x$withval" = xyes], [
 302         AC_MSG_RESULT([enabled])
 303         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 304         E2FSPROGS="ldiskfsprogs"
 305         MKE2FS="mkfs.ldiskfs"
 306         DEBUGFS="debugfs.ldiskfs"
 307         TUNE2FS="tunefs.ldiskfs"
 308         E2LABEL="label.ldiskfs"
 309         DUMPE2FS="dumpfs.ldiskfs"
 310         E2FSCK="fsck.ldiskfs"
 311         PFSCK="pfsck.ldiskfs"
 312 ], [
 313         AC_MSG_RESULT([disabled])
 314         E2FSPROGS="e2fsprogs"
 315         MKE2FS="mke2fs"
 316         DEBUGFS="debugfs"
 317         TUNE2FS="tune2fs"
 318         E2LABEL="e2label"
 319         DUMPE2FS="dumpe2fs"
 320         E2FSCK="e2fsck"
 321         PFSCK="fsck"
 322 ])
 323
 324 AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 325 AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 326 AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 327 AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 328 AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 329 AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 330 AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 331 AC_DEFINE_UNQUOTED(PFSCK, "$PFSCK", [name of parallel fsck program])
 332
 333 AC_SUBST([E2FSPROGS], [$E2FSPROGS])
 334 AC_SUBST([MKE2FS], [$MKE2FS])
 335 AC_SUBST([DEBUGFS], [$DEBUGFS])
 336 AC_SUBST([TUNE2FS], [$TUNE2FS])
 337 AC_SUBST([E2LABEL], [$E2LABEL])
 338 AC_SUBST([DUMPE2FS], [$DUMPE2FS])
 339 AC_SUBST([E2FSCK], [$E2FSCK])
 340 AC_SUBST([PFSCK], [$PFSCK])
 341 ]) # LB_DEFINE_E2FSPROGS_NAMES