config/lustre-build-ldiskfs.m4

   1 #
   2 # LDISKFS_LINUX_SERIES
   3 #
   4 AC_DEFUN([LDISKFS_LINUX_SERIES], [
   5 AC_MSG_CHECKING([which ldiskfs series to use])
   6 case x$LDISKFS_SERIES in
   7         x)                      # not set
   8                 ;;
   9         *.series)               # set externally
  10                 ;;
  11         *) LDISKFS_SERIES=
  12 esac
  13 AS_IF([test -z "$LDISKFS_SERIES"], [
  14 AS_IF([test x$RHEL_KERNEL = xyes], [
  15         case $RHEL_RELEASE_NO in
  16         76)     LDISKFS_SERIES="3.10-rhel7.6.series"    ;;
  17         75)     LDISKFS_SERIES="3.10-rhel7.5.series"    ;;
  18         74)     LDISKFS_SERIES="3.10-rhel7.4.series"    ;;
  19         73)     LDISKFS_SERIES="3.10-rhel7.3.series"    ;;
  20         72)     LDISKFS_SERIES="3.10-rhel7.2.series"    ;;
  21         71)     LDISKFS_SERIES="3.10-rhel7.series"      ;;
  22         69)     LDISKFS_SERIES="2.6-rhel6.9.series"     ;;
  23         68)     LDISKFS_SERIES="2.6-rhel6.8.series"     ;;
  24         67)     LDISKFS_SERIES="2.6-rhel6.7.series"     ;;
  25         66)     LDISKFS_SERIES="2.6-rhel6.6.series"     ;;
  26         65)     LDISKFS_SERIES="2.6-rhel6.5.series"     ;;
  27         64)     LDISKFS_SERIES="2.6-rhel6.4.series"     ;;
  28         6[0-3]) LDISKFS_SERIES="2.6-rhel6.series"       ;;
  29         esac
  30 ], [test x$SUSE_KERNEL = xyes], [
  31         AS_VERSION_COMPARE([$LINUXRELEASE],[4.4.82],[
  32         AS_VERSION_COMPARE([$LINUXRELEASE],[4.4.0],[
  33         AS_VERSION_COMPARE([$LINUXRELEASE],[3.12.0],[
  34         AS_VERSION_COMPARE([$LINUXRELEASE],[3.0.0],[
  35         AS_VERSION_COMPARE([$LINUXRELEASE],[2.6.32], [],
  36         [LDISKFS_SERIES="2.6-sles11.series"],[LDISKFS_SERIES="2.6-sles11.series"])],
  37         [LDISKFS_SERIES="3.0-sles11.series"],[
  38                 PLEV=$(grep PATCHLEVEL /etc/SuSE-release | sed -e 's/.*= *//')
  39                 case $PLEV in
  40                 2) LDISKFS_SERIES="3.0-sles11.series"
  41                         ;;
  42                 3) LDISKFS_SERIES="3.0-sles11sp3.series"
  43                         ;;
  44                 4) LDISKFS_SERIES="3.0-sles11sp4.series"
  45                         ;;
  46                 esac
  47         ])],[LDISKFS_SERIES="3.12-sles12.series"],[
  48                 PLEV=$(grep PATCHLEVEL /etc/SuSE-release | sed -e 's/.*= *//')
  49                 case $PLEV in
  50                 1) LDISKFS_SERIES="3.12-sles12sp1.series"
  51                         ;;
  52                 *) LDISKFS_SERIES="3.12-sles12.series"
  53                         ;;
  54                 esac
  55         ])],[LDISKFS_SERIES="4.4-sles12sp2.series"],
  56             [LDISKFS_SERIES="4.4-sles12sp2.series"]
  57         )], [LDISKFS_SERIES="4.4-sles12sp3.series"],
  58             [LDISKFS_SERIES="4.4-sles12sp3.series"])
  59 ], [test x$UBUNTU_KERNEL = xyes], [
  60         AS_VERSION_COMPARE([$LINUXRELEASE],[4.15.0],[
  61         AS_VERSION_COMPARE([$LINUXRELEASE],[4.4.0], [],
  62         [
  63                 KPLEV=$(echo $LINUXRELEASE | sed -n 's/.*-\([0-9]\+\).*/\1/p')
  64                 AS_IF(
  65                         [test -z "$KPLEV"], [
  66                                 AC_MSG_WARN([Failed to determine Kernel patch level. Assume latest.])
  67                                 LDISKFS_SERIES="4.4.0-73-ubuntu14+16.series"
  68                         ],
  69                         [test $KPLEV -ge 73], [LDISKFS_SERIES="4.4.0-73-ubuntu14+16.series"],
  70                         [test $KPLEV -ge 62], [LDISKFS_SERIES="4.4.0-62-ubuntu14+16.series"],
  71                         [test $KPLEV -ge 49], [LDISKFS_SERIES="4.4.0-49-ubuntu14+16.series"],
  72                         [LDISKFS_SERIES="4.4.0-45-ubuntu14+16.series"]
  73                 )
  74         ],
  75         [LDISKFS_SERIES="4.4.0-73-ubuntu14+16.series"])],
  76         [
  77                 KPLEV=$(echo $LINUXRELEASE | sed -n 's/.*-\([0-9]\+\).*/\1/p')
  78                 AS_IF(
  79                         [test -z "$KPLEV"], [
  80                                 AC_MSG_WARN([Failed to determine Kernel patch level. Assume latest.])
  81                                 LDISKFS_SERIES="4.15.0-20-ubuntu18.series"
  82                         ],
  83                         [test $KPLEV -ge 20], [LDISKFS_SERIES="4.15.0-20-ubuntu18.series"]
  84                 )
  85         ],
  86         [LDISKFS_SERIES="4.15.0-20-ubuntu18.series"])
  87 ])
  88 ])
  89 AS_IF([test -z "$LDISKFS_SERIES"],
  90         [AC_MSG_RESULT([failed to identify series])],
  91         [AC_MSG_RESULT([$LDISKFS_SERIES])])
  92 AC_SUBST(LDISKFS_SERIES)
  93 ]) # LDISKFS_LINUX_SERIES
  94
  95 #
  96 # LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
  97 #
  98 # 2.6.32-rc7 ext4_free_blocks requires struct buffer_head
  99 # Note that RHEL6 is pre 2.6.32-rc7 so this check is still needed.
 100 #
 101 AC_DEFUN([LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD], [
 102 LB_CHECK_COMPILE([if 'ext4_free_blocks' needs 'struct buffer_head'],
 103 ext4_free_blocks_with_buffer_head, [
 104         #include <linux/fs.h>
 105         #include "$EXT4_SRC_DIR/ext4.h"
 106 ],[
 107         ext4_free_blocks(NULL, NULL, NULL, 0, 0, 0);
 108 ],[
 109         AC_DEFINE(HAVE_EXT_FREE_BLOCK_WITH_BUFFER_HEAD, 1,
 110                 [ext4_free_blocks do not require struct buffer_head])
 111 ])
 112 ]) # LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 113
 114 #
 115 # LB_EXT_PBLOCK
 116 #
 117 # 2.6.35 renamed ext_pblock to ext4_ext_pblock(ex)
 118 #
 119 AC_DEFUN([LB_EXT_PBLOCK], [
 120 LB_CHECK_COMPILE([if Linux kernel has 'ext_pblock'],
 121 ext_pblock, [
 122         #include <linux/fs.h>
 123         #include "$EXT4_SRC_DIR/ext4_extents.h"
 124 ],[
 125         ext_pblock(NULL);
 126 ],[
 127         AC_DEFINE(HAVE_EXT_PBLOCK, 1, [Linux kernel has ext_pblock])
 128 ])
 129 ]) # LB_EXT_PBLOCK
 130
 131 #
 132 # LB_EXT4_JOURNAL_START_3ARGS
 133 #
 134 # 3.9 added a type argument to ext4_journal_start and friends
 135 #
 136 AC_DEFUN([LB_EXT4_JOURNAL_START_3ARGS], [
 137 LB_CHECK_COMPILE([if ext4_journal_start takes 3 arguments],
 138 ext4_journal_start, [
 139         #include <linux/fs.h>
 140         #include "$EXT4_SRC_DIR/ext4_jbd2.h"
 141 ],[
 142         ext4_journal_start(NULL, 0, 0);
 143 ],[
 144         AC_DEFINE(JOURNAL_START_HAS_3ARGS, 1, [ext4_journal_start takes 3 arguments])
 145 ])
 146 ]) # LB_EXT4_JOURNAL_START_3ARGS
 147
 148 #
 149 # LB_LDISKFS_MAP_BLOCKS
 150 #
 151 # Since 2.6.35 brought ext4_map_blocks() for IO.
 152 # We just check this function whether existed.
 153 # it must be exported by ldiskfs patches.
 154 #
 155 AC_DEFUN([LB_LDISKFS_MAP_BLOCKS], [
 156 LB_CHECK_COMPILE([if kernel has ext4_map_blocks],
 157 ext4_map_blocks, [
 158         #include <linux/fs.h>
 159         #include "$EXT4_SRC_DIR/ext4.h"
 160 ],[
 161         ext4_map_blocks(NULL, NULL, NULL, 0);
 162 ],[
 163         AC_DEFINE(HAVE_LDISKFS_MAP_BLOCKS, 1, [kernel has ext4_map_blocks])
 164 ])
 165 ])
 166
 167 #
 168 # LB_EXT4_BREAD_4ARGS
 169 #
 170 # 3.18 ext4_bread has 4 arguments
 171 #
 172 AC_DEFUN([LB_EXT4_BREAD_4ARGS], [
 173 LB_CHECK_COMPILE([if ext4_bread takes 4 arguments],
 174 ext4_bread, [
 175         #include <linux/fs.h>
 176         #include "$EXT4_SRC_DIR/ext4.h"
 177 ],[
 178         ext4_bread(NULL, NULL, 0, 0);
 179 ],[
 180         AC_DEFINE(HAVE_EXT4_BREAD_4ARGS, 1, [ext4_bread takes 4 arguments])
 181 ])
 182 ]) # LB_EXT4_BREAD_4ARGS
 183
 184 #
 185 # LB_EXT4_HAVE_INFO_DQUOT
 186 #
 187 # in linux 4.4 i_dqout is in ext4_inode_info, not in struct inode
 188 #
 189 AC_DEFUN([LB_EXT4_HAVE_INFO_DQUOT], [
 190 LB_CHECK_COMPILE([if i_dquot is in ext4_inode_info],
 191 ext4_info_dquot, [
 192         #include <linux/fs.h>
 193         #include <linux/quota.h>
 194         #include "$EXT4_SRC_DIR/ext4.h"
 195 ],[
 196         struct ext4_inode_info in;
 197         struct dquot *dq;
 198
 199         dq = in.i_dquot[0];
 200 ],[
 201         AC_DEFINE(HAVE_EXT4_INFO_DQUOT, 1, [i_dquot is in ext4_inode_info])
 202 ])
 203 ]) # LB_EXT4_HAVE_INFO_DQUOT
 204
 205 #
 206 # LDISKFS_AC_PATCH_PROGRAM
 207 #
 208 # Determine which program should be used to apply the patches to
 209 # the ext4 source code to produce the ldiskfs source code.
 210 #
 211 AC_DEFUN([LDISKFS_AC_PATCH_PROGRAM], [
 212         AC_ARG_ENABLE([quilt],
 213                 [AC_HELP_STRING([--disable-quilt],
 214                         [disable use of quilt for ldiskfs])],
 215                 [AS_IF([test "x$enableval" = xno],
 216                         [use_quilt=no],
 217                         [use_quilt=maybe])],
 218                 [use_quilt=maybe]
 219         )
 220
 221         AS_IF([test x$use_quilt = xmaybe], [
 222                 AC_PATH_PROG([quilt_avail], [quilt], [no])
 223                 AS_IF([test x$quilt_avail = xno], [
 224                         use_quilt=no
 225                 ], [
 226                         use_quilt=yes
 227                 ])
 228         ])
 229
 230         AS_IF([test x$use_quilt = xno], [
 231                 AC_PATH_PROG([patch_avail], [patch], [no])
 232                 AS_IF([test x$patch_avail = xno], [
 233                         AC_MSG_ERROR([*** Need "quilt" or "patch" command])
 234                 ])
 235         ])
 236 ]) # LDISKFS_AC_PATCH_PROGRAM
 237
 238 #
 239 # LB_CONFIG_LDISKFS
 240 #
 241 AC_DEFUN([LB_CONFIG_LDISKFS], [
 242 # --with-ldiskfs is deprecated now that ldiskfs is fully merged with lustre.
 243 # However we continue to support this option through Lustre 2.5.
 244 AC_ARG_WITH([ldiskfs],
 245         [],
 246         [AC_MSG_WARN([--with-ldiskfs is deprecated, please use --enable-ldiskfs])
 247         AS_IF([test x$withval != xyes -a x$withval != xno],
 248                 [AC_MSG_ERROR([
 249
 250 The ldiskfs option is deprecated,
 251 and no longer supports paths to external ldiskfs source
 252 ])])
 253 ])
 254
 255 AC_ARG_ENABLE([ldiskfs],
 256         [AS_HELP_STRING([--disable-ldiskfs],
 257                 [disable ldiskfs osd (default is enable)])],
 258         [AS_IF([test x$enable_ldiskfs != xyes -a x$enable_ldiskfs != xno],
 259                 [AC_MSG_ERROR([ldiskfs valid options are "yes" or "no"])])],
 260         [AS_IF([test "${with_ldiskfs+set}" = set],
 261                 [enable_ldiskfs=$with_ldiskfs],
 262                 [enable_ldiskfs=maybe])
 263 ])
 264
 265 AS_IF([test x$enable_server = xno],
 266         [AS_CASE([$enable_ldiskfs],
 267                 [maybe], [enable_ldiskfs=no],
 268                 [yes], [AC_MSG_ERROR([cannot build ldiskfs when servers are disabled])]
 269         )])
 270
 271 AS_IF([test x$enable_ldiskfs != xno],[
 272         # In the future, we chould change enable_ldiskfs from maybe to
 273         # either yes or no based on additional tests, e.g.  whether a patch
 274         # set is available for the detected kernel.  For now, we just always
 275         # set it to "yes".
 276         AS_IF([test x$enable_ldiskfs = xmaybe], [enable_ldiskfs=yes])
 277         AC_SUBST(ENABLE_LDISKFS, yes)
 278
 279         LDISKFS_LINUX_SERIES
 280         LDISKFS_AC_PATCH_PROGRAM
 281         LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 282         LB_EXT_PBLOCK
 283         LB_EXT4_JOURNAL_START_3ARGS
 284         LB_LDISKFS_MAP_BLOCKS
 285         LB_EXT4_BREAD_4ARGS
 286         LB_EXT4_HAVE_INFO_DQUOT
 287         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [posix acls for ldiskfs])
 288         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [fs security for ldiskfs])
 289         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [extened attributes for ldiskfs])
 290         AC_DEFINE(CONFIG_LDISKFS_FS_RW, 1, [enable rw access for ldiskfs])
 291         AC_DEFINE(CONFIG_LDISKFS_FS_ENCRYPTION, 1, [enable encryption for ldiskfs])
 292         AC_SUBST(LDISKFS_SUBDIR, ldiskfs)
 293         AC_DEFINE(HAVE_LDISKFS_OSD, 1, Enable ldiskfs osd)
 294 ], [
 295         AC_SUBST(ENABLE_LDISKFS, no)
 296 ])
 297
 298 AC_MSG_CHECKING([whether to build ldiskfs])
 299 AC_MSG_RESULT([$enable_ldiskfs])
 300
 301 AM_CONDITIONAL([LDISKFS_ENABLED], [test x$enable_ldiskfs = xyes])
 302 ]) # LB_CONFIG_LDISKFS
 303
 304 #
 305 # LB_VALIDATE_EXT4_SRC_DIR
 306 #
 307 # Spot check the existence of several source files common to ext4.
 308 # Detecting this at configure time allows us to avoid a potential build
 309 # failure and provide a useful error message to explain what is wrong.
 310 #
 311 AC_DEFUN([LB_VALIDATE_EXT4_SRC_DIR], [
 312 enable_ldiskfs_build="no"
 313 AS_IF([test -n "$EXT4_SRC_DIR"], [
 314         enable_ldiskfs_build="yes"
 315         LB_CHECK_FILE([$EXT4_SRC_DIR/dir.c], [], [
 316                 enable_ldiskfs_build="no"
 317                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 318         ])
 319         LB_CHECK_FILE([$EXT4_SRC_DIR/file.c], [], [
 320                 enable_ldiskfs_build="no"
 321                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 322         ])
 323         LB_CHECK_FILE([$EXT4_SRC_DIR/inode.c], [], [
 324                 enable_ldiskfs_build="no"
 325                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 326         ])
 327         LB_CHECK_FILE([$EXT4_SRC_DIR/super.c], [], [
 328                 enable_ldiskfs_build="no"
 329                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 330         ])
 331 ])
 332
 333 AS_IF([test "x$enable_ldiskfs_build" = xno], [
 334         enable_ldiskfs="no"
 335
 336         AC_MSG_WARN([
 337
 338 Disabling ldiskfs support because complete ext4 source does not exist.
 339
 340 If you are building using kernel-devel packages and require ldiskfs
 341 server support then ensure that the matching kernel-debuginfo-common
 342 and kernel-debuginfo-common-<arch> packages are installed.
 343 ])
 344 ])
 345 ]) # LB_VALIDATE_EXT4_SRC_DIR
 346
 347 #
 348 # LB_EXT4_SRC_DIR
 349 #
 350 # Determine the location of the ext4 source code.  It it required
 351 # for several configure tests and to build ldiskfs.
 352 #
 353 AC_DEFUN([LB_EXT4_SRC_DIR], [
 354 AC_MSG_CHECKING([ext4 source directory])
 355 # Kernel ext source located with devel headers
 356 linux_src=$LINUX
 357 AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 358         EXT4_SRC_DIR="$linux_src/fs/ext4"
 359 ], [
 360         # Kernel ext source provided by kernel-debuginfo-common package
 361         # that extracted to $LINUX
 362         linux_src=$(ls -1d $linux_src/../../debug/*/linux-${LINUXRELEASE%.*}* \
 363                 2>/dev/null | tail -1)
 364         AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 365                 EXT4_SRC_DIR="$linux_src/fs/ext4"
 366         ], [
 367                 # Kernel ext source provided by kernel-debuginfo-common package
 368                 linux_src=$(ls -1d /usr/src/debug/*/linux-${LINUXRELEASE%.*}* \
 369                         2>/dev/null | tail -1)
 370                 AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 371                         EXT4_SRC_DIR="$linux_src/fs/ext4"
 372                 ], [
 373                         EXT4_SRC_DIR=""
 374                 ])
 375         ])
 376 ])
 377 AC_MSG_RESULT([$EXT4_SRC_DIR])
 378 AC_SUBST(EXT4_SRC_DIR)
 379
 380 LB_VALIDATE_EXT4_SRC_DIR
 381 ]) # LB_EXT4_SRC_DIR
 382
 383 #
 384 # LB_DEFINE_E2FSPROGS_NAMES
 385 #
 386 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 387 #
 388 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES], [
 389 AC_MSG_CHECKING([whether to use alternate names for e2fsprogs])
 390 AC_ARG_WITH([ldiskfsprogs],
 391         AC_HELP_STRING([--with-ldiskfsprogs],
 392                 [use alternate names for ldiskfs-enabled e2fsprogs]),
 393         [], [withval="no"])
 394
 395 AS_IF([test "x$withval" = xyes], [
 396         AC_MSG_RESULT([enabled])
 397         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 398         E2FSPROGS="ldiskfsprogs"
 399         MKE2FS="mkfs.ldiskfs"
 400         DEBUGFS="debugfs.ldiskfs"
 401         TUNE2FS="tunefs.ldiskfs"
 402         E2LABEL="label.ldiskfs"
 403         DUMPE2FS="dumpfs.ldiskfs"
 404         E2FSCK="fsck.ldiskfs"
 405         PFSCK="pfsck.ldiskfs"
 406 ], [
 407         AC_MSG_RESULT([disabled])
 408         E2FSPROGS="e2fsprogs"
 409         MKE2FS="mke2fs"
 410         DEBUGFS="debugfs"
 411         TUNE2FS="tune2fs"
 412         E2LABEL="e2label"
 413         DUMPE2FS="dumpe2fs"
 414         E2FSCK="e2fsck"
 415         PFSCK="fsck"
 416 ])
 417
 418 AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 419 AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 420 AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 421 AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 422 AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 423 AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 424 AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 425 AC_DEFINE_UNQUOTED(PFSCK, "$PFSCK", [name of parallel fsck program])
 426
 427 AC_SUBST([E2FSPROGS], [$E2FSPROGS])
 428 AC_SUBST([MKE2FS], [$MKE2FS])
 429 AC_SUBST([DEBUGFS], [$DEBUGFS])
 430 AC_SUBST([TUNE2FS], [$TUNE2FS])
 431 AC_SUBST([E2LABEL], [$E2LABEL])
 432 AC_SUBST([DUMPE2FS], [$DUMPE2FS])
 433 AC_SUBST([E2FSCK], [$E2FSCK])
 434 AC_SUBST([PFSCK], [$PFSCK])
 435 ]) # LB_DEFINE_E2FSPROGS_NAMES