build/autoconf/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION],
   7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
   8         AC_MSG_ERROR([This script was not built with a version number.])
   9 fi
  10 ])
  11
  12 #
  13 # LB_CANONICAL_SYSTEM
  14 #
  15 # fixup $target_os for use in other places
  16 #
  17 AC_DEFUN([LB_CANONICAL_SYSTEM],
  18 [case $target_os in
  19         linux*)
  20                 lb_target_os="linux"
  21                 ;;
  22         darwin*)
  23                 lb_target_os="darwin"
  24                 ;;
  25         solaris2.11*)
  26                 lb_target_os="SunOS"
  27                 ;;esac
  28 AC_SUBST(lb_target_os)
  29 ])
  30
  31 #
  32 # LB_CHECK_FILE
  33 #
  34 # Check for file existance even when cross compiling
  35 #
  36 AC_DEFUN([LB_CHECK_FILE],
  37 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
  38 AC_CACHE_CHECK([for $1], lb_File,
  39 [if test -r "$1"; then
  40   AS_VAR_SET(lb_File, yes)
  41 else
  42   AS_VAR_SET(lb_File, no)
  43 fi])
  44 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
  45 AS_VAR_POPDEF([lb_File])dnl
  46 ])# LB_CHECK_FILE
  47
  48 #
  49 # LB_CHECK_FILES
  50 #
  51 # LB_CHECK_FILE over multiple files
  52 #
  53 AC_DEFUN([LB_CHECK_FILES],
  54 [AC_FOREACH([AC_FILE_NAME], [$1],
  55   [LB_CHECK_FILE(AC_FILE_NAME,
  56                  [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]AC_FILE_NAME), 1,
  57                                     [Define to 1 if you have the
  58                                      file `]AC_File['.])
  59 $2],
  60                  [$3])])])
  61
  62 #
  63 # LB_ARG_LIBS_INCLUDES
  64 #
  65 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
  66 # a single magical macro
  67 #
  68 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
  69 [lb_pathvar="m4_bpatsubst([$2], -, _)"
  70 AC_MSG_CHECKING([for $1])
  71 AC_ARG_WITH([$2],
  72         AC_HELP_STRING([--with-$2=path],
  73                 [path to $1]),
  74         [],[withval=$4])
  75
  76 if test x$withval = xyes ; then
  77         eval "$lb_pathvar='$3'"
  78 else
  79         eval "$lb_pathvar='$withval'"
  80 fi
  81 AC_MSG_RESULT([${!lb_pathvar:-no}])
  82
  83 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
  84         AC_MSG_CHECKING([for $1 includes])
  85         AC_ARG_WITH([$2-includes],
  86                 AC_HELP_STRING([--with-$2-includes=path],
  87                         [path to $1 includes]),
  88                 [],[withval='yes'])
  89
  90         lb_includevar="${lb_pathvar}_includes"
  91         if test x$withval = xyes ; then
  92                 eval "${lb_includevar}='${!lb_pathvar}/include'"
  93         else
  94                 eval "${lb_includevar}='$withval'"
  95         fi
  96         AC_MSG_RESULT([${!lb_includevar}])
  97
  98         AC_MSG_CHECKING([for $1 libs])
  99         AC_ARG_WITH([$2-libs],
 100                 AC_HELP_STRING([--with-$2-libs=path],
 101                         [path to $1 libs]),
 102                 [],[withval='yes'])
 103
 104         lb_libvar="${lb_pathvar}_libs"
 105         if test x$withval = xyes ; then
 106                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
 107         else
 108                 eval "${lb_libvar}='$withval'"
 109         fi
 110         AC_MSG_RESULT([${!lb_libvar}])
 111 fi
 112 ])
 113 ])
 114
 115 #
 116 # LB_PATH_LIBSYSIO
 117 #
 118 # Handle internal/external libsysio
 119 #
 120 AC_DEFUN([LB_PATH_LIBSYSIO],
 121 [AC_ARG_WITH([sysio],
 122         AC_HELP_STRING([--with-sysio=path],
 123                         [set path to libsysio source (default is included libsysio)]),
 124         [],[
 125                 case $lb_target_os in
 126                         linux)
 127                                 with_sysio='yes'
 128                                 ;;
 129                         *)
 130                                 with_sysio='no'
 131                                 ;;
 132                 esac
 133         ])
 134 AC_MSG_CHECKING([location of libsysio])
 135 enable_sysio="$with_sysio"
 136 case x$with_sysio in
 137         xyes)
 138                 AC_MSG_RESULT([internal])
 139                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
 140                         AC_MSG_ERROR([A complete internal libsysio was not found.])
 141                 ])
 142                 LIBSYSIO_SUBDIR="libsysio"
 143                 SYSIO="$PWD/libsysio"
 144                 ;;
 145         xno)
 146                 AC_MSG_RESULT([disabled])
 147                 ;;
 148         *)
 149                 AC_MSG_RESULT([$with_sysio])
 150                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
 151                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
 152                 ])
 153                 SYSIO=$with_sysio
 154                 with_sysio="yes"
 155                 ;;
 156 esac
 157
 158 # We have to configure even if we don't build here for make dist to work
 159 AC_CONFIG_SUBDIRS(libsysio)
 160 ])
 161
 162 #
 163 # LB_PATH_LDISKFS
 164 #
 165 # Handle internal/external ldiskfs
 166 #
 167 AC_DEFUN([LB_PATH_LDISKFS],
 168 [AC_ARG_WITH([ldiskfs],
 169         AC_HELP_STRING([--with-ldiskfs=path],
 170                         [set path to ldiskfs source (default is included ldiskfs)]),
 171         [],[
 172                 if test x$linux25$enable_server = xyesyes ; then
 173                         with_ldiskfs=yes
 174                 else
 175                         with_ldiskfs=no
 176                 fi
 177         ])
 178 AC_MSG_CHECKING([location of ldiskfs])
 179 case x$with_ldiskfs in
 180         xyes)
 181                 AC_MSG_RESULT([internal])
 182                 LB_CHECK_FILE([$srcdir/ldiskfs/lustre-ldiskfs.spec.in],[],[
 183                         AC_MSG_ERROR([A complete internal ldiskfs was not found.])
 184                 ])
 185                 LDISKFS_SUBDIR="ldiskfs"
 186                 LDISKFS_DIR="$PWD/ldiskfs"
 187                 ;;
 188         xno)
 189                 AC_MSG_RESULT([disabled])
 190                 ;;
 191         *)
 192                 AC_MSG_RESULT([$with_ldiskfs])
 193                 LB_CHECK_FILE([$with_ldiskfs/ldiskfs/linux/ldiskfs_fs.h],[],[
 194                         AC_MSG_ERROR([A complete (built) external ldiskfs was not found.])
 195                 ])
 196                 LDISKFS_DIR=$with_ldiskfs
 197                 ;;
 198 esac
 199 AC_SUBST(LDISKFS_DIR)
 200 AC_SUBST(LDISKFS_SUBDIR)
 201
 202 # We have to configure even if we don't build here for make dist to work
 203 AC_CONFIG_SUBDIRS(ldiskfs)
 204 ])
 205
 206 #
 207 # LB_DEFINE_LDISKFS_OPTIONS
 208 #
 209 # Enable config options related to ldiskfs.  These are used both by ldiskfs
 210 # and lvfs (which includes ldiskfs headers.)
 211 #
 212 AC_DEFUN([LB_DEFINE_LDISKFS_OPTIONS],
 213 [
 214         AC_DEFINE(CONFIG_LDISKFS_FS_MODULE, 1, [build ldiskfs as a module])
 215         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [enable extended attributes for ldiskfs])
 216         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [enable posix acls for ldiskfs])
 217         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [enable fs security for ldiskfs])
 218 ])
 219
 220 #
 221 # LB_CONFIG_CRAY_XT3
 222 #
 223 # Enable Cray XT3 features
 224 #
 225 AC_DEFUN([LB_CONFIG_CRAY_XT3],
 226 [AC_MSG_CHECKING([whether to build Cray XT3 features])
 227 AC_ARG_ENABLE([cray_xt3],
 228         AC_HELP_STRING([--enable-cray-xt3],
 229                         [enable building of Cray XT3 features]),
 230         [enable_cray_xt3='yes'],[enable_cray_xt3='no'])
 231 AC_MSG_RESULT([$enable_cray_xt3])
 232 if test x$enable_cray_xt3 != xno; then
 233         AC_DEFINE(CRAY_XT3, 1, Enable Cray XT3 Features)
 234 fi
 235 ])
 236
 237 #
 238 # LB_CONFIG_BGL
 239 #
 240 # Enable BGL features
 241 #
 242 AC_DEFUN([LB_CONFIG_BGL],
 243 [AC_MSG_CHECKING([whether to build BGL features])
 244 AC_ARG_ENABLE([bgl],
 245         AC_HELP_STRING([--enable-bgl],
 246                         [enable building of BGL features]),
 247         [enable_bgl='yes'],[enable_bgl='no'])
 248 AC_MSG_RESULT([$enable_bgl])
 249 if test x$enable_bgl != xno; then
 250         AC_DEFINE(BGL_SUPPORT, 1, Enable BGL Features)
 251         enable_doc='no'
 252         enable_tests='no'
 253         enable_server='no'
 254         enable_liblustre='no'
 255         enable_libreadline='no'
 256 fi
 257 ])
 258
 259
 260 #
 261 # LB_CONFIG_UOSS
 262 #
 263 #
 264 AC_DEFUN([LB_CONFIG_UOSS],
 265 [AC_MSG_CHECKING([whether to build user-level oss])
 266 AC_ARG_ENABLE([uoss],
 267         AC_HELP_STRING([--enable-uoss],
 268                         [enable building of user-level oss]),
 269         [enable_uoss='yes'],[enable_uoss='no'])
 270 AC_MSG_RESULT([$enable_uoss])
 271 if test x$enable_uoss != xno; then
 272         AC_DEFINE(UOSS_SUPPORT, 1, Enable user-level OSS)
 273         AC_DEFINE(LUSTRE_ULEVEL_MT, 1, Multi-threaded user-level lustre port)
 274         enable_ulevel_mt='yes'
 275         enable_modules='no'
 276         enable_client='no'
 277         enable_tests='no'
 278         enable_liblustre='no'
 279         with_ldiskfs=no
 280 fi
 281 ])
 282
 283 #
 284 # LB_PATH_DMU
 285 # Support for --with-dmu
 286 #
 287 AC_DEFUN([LB_PATH_DMU],
 288 [AC_ARG_WITH([dmu],
 289         AC_HELP_STRING([--with-dmu=path],
 290                        [set path to a built dmu]),
 291         [
 292                 DMU_SRC=$with_dmu
 293                 enable_dmu_osd=yes
 294         ],
 295         [
 296                 enable_dmu_osd=no
 297                 DMU_SRC=""
 298         ])
 299 AC_MSG_RESULT([$dmu])
 300 if test x$enable_dmu_osd != xno; then
 301         AC_DEFINE(ENABLE_DMU, 1, Enable POSIX OSD)
 302         AC_DEFINE(DMU_OSD, 1, Enable POSIX OSD)
 303         enable_ulevel_mt='yes'
 304         enable_modules='no'
 305         enable_client='no'
 306         enable_tests='no'
 307         enable_liblustre='no'
 308         with_ldiskfs=no
 309 fi
 310 AC_SUBST(DMU_SRC)
 311 ])
 312
 313 #
 314 # Support for --enable-posix-dmu
 315 #
 316 AC_DEFUN([LB_POSIX_OSD],
 317 [AC_MSG_CHECKING([whether to posix osd])
 318 AC_ARG_ENABLE([posix-osd],
 319         AC_HELP_STRING([--enable-posix-osd],
 320                         [enable using of posix osd]),
 321         [enable_posix_osd='yes'],[enable_posix_osd='no'])
 322 AC_MSG_RESULT([$enable_posix_osd])
 323 if test x$enable_posix_osd != xno; then
 324         AC_DEFINE(POSIX_OSD, 1, Enable POSIX OSD)
 325         AC_DEFINE(LUSTRE_ULEVEL_MT, 1, Multi-threaded user-level lustre port)
 326         enable_ulevel_mt='yes'
 327         enable_modules='no'
 328         enable_client='no'
 329         enable_tests='no'
 330         enable_liblustre='no'
 331         with_ldiskfs=no
 332 fi
 333 ])
 334
 335 #
 336 # LB_PATH_SNMP
 337 #
 338 # check for in-tree snmp support
 339 #
 340 AC_DEFUN([LB_PATH_SNMP],
 341 [LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c],[SNMP_DIST_SUBDIR="snmp"])
 342 AC_SUBST(SNMP_DIST_SUBDIR)
 343 AC_SUBST(SNMP_SUBDIR)
 344 ])
 345
 346 #
 347 # LB_CONFIG_MODULES
 348 #
 349 # Build kernel modules?
 350 #
 351 AC_DEFUN([LB_CONFIG_MODULES],
 352 [AC_MSG_CHECKING([whether to build kernel modules])
 353 AC_ARG_ENABLE([modules],
 354         AC_HELP_STRING([--disable-modules],
 355                         [disable building of Lustre kernel modules]),
 356         [],[
 357                 LC_TARGET_SUPPORTED([
 358                         enable_modules='yes'
 359                 ],[
 360                         enable_modules='no'
 361                 ])
 362         ])
 363 AC_MSG_RESULT([$enable_modules ($target_os)])
 364
 365 if test x$enable_modules = xyes ; then
 366         case $target_os in
 367                 linux*)
 368                         LB_PROG_LINUX
 369                         LN_PROG_LINUX
 370                         LC_PROG_LINUX
 371                         ;;
 372                 darwin*)
 373                         LB_PROG_DARWIN
 374                         ;;
 375                 *)
 376                         # This is strange - Lustre supports a target we don't
 377                         AC_MSG_ERROR([Modules are not supported on $target_os])
 378                         ;;
 379         esac
 380 fi
 381 ])
 382
 383 #
 384 # LB_CONFIG_UTILS
 385 #
 386 # Build utils?
 387 #
 388 AC_DEFUN([LB_CONFIG_UTILS],
 389 [AC_MSG_CHECKING([whether to build utilities])
 390 AC_ARG_ENABLE([utils],
 391         AC_HELP_STRING([--disable-utils],
 392                         [disable building of Lustre utility programs]),
 393         [],[enable_utils='yes'])
 394 AC_MSG_RESULT([$enable_utils])
 395 if test x$enable_utils = xyes ; then
 396         LB_CONFIG_INIT_SCRIPTS
 397 fi
 398 ])
 399
 400 #
 401 # LB_CONFIG_TESTS
 402 #
 403 # Build tests?
 404 #
 405 AC_DEFUN([LB_CONFIG_TESTS],
 406 [AC_MSG_CHECKING([whether to build Lustre tests])
 407 AC_ARG_ENABLE([tests],
 408         AC_HELP_STRING([--disable-tests],
 409                         [disable building of Lustre tests]),
 410         [],
 411         [
 412                 enable_tests='yes'
 413         ])
 414 AC_MSG_RESULT([$enable_tests])
 415 ])
 416
 417 #
 418 # LB_CONFIG_DOCS
 419 #
 420 # Build docs?
 421 #
 422 AC_DEFUN([LB_CONFIG_DOCS],
 423 [AC_MSG_CHECKING([whether to build docs])
 424 AC_ARG_ENABLE(doc,
 425         AC_HELP_STRING([--disable-doc],
 426                         [skip creation of pdf documentation]),
 427         [
 428                 if test x$enable_doc = xyes ; then
 429                     ENABLE_DOC=1
 430                 else
 431                     ENABLE_DOC=0
 432                 fi
 433         ],[
 434                 ENABLE_DOC=0
 435                 enable_doc='no'
 436         ])
 437 AC_MSG_RESULT([$enable_doc])
 438 AC_SUBST(ENABLE_DOC)
 439 ])
 440
 441 #
 442 # LB_CONFIG_INIT_SCRIPTS
 443 #
 444 # our init scripts only work on red hat linux
 445 #
 446 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
 447 [ENABLE_INIT_SCRIPTS=0
 448 if test x$enable_utils = xyes ; then
 449         AC_MSG_CHECKING([whether to install init scripts])
 450         # our scripts only work on red hat systems
 451         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
 452                 ENABLE_INIT_SCRIPTS=1
 453                 AC_MSG_RESULT([yes])
 454         else
 455                 AC_MSG_RESULT([no])
 456         fi
 457 fi
 458 AC_SUBST(ENABLE_INIT_SCRIPTS)
 459 ])
 460
 461 #
 462 # LB_CONFIG_HEADERS
 463 #
 464 # add -include config.h
 465 #
 466 AC_DEFUN([LB_CONFIG_HEADERS],
 467 [AC_CONFIG_HEADERS([config.h])
 468 CPPFLAGS="-include \$(top_builddir)/config.h $CPPFLAGS"
 469 EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 470 AC_SUBST(EXTRA_KCFLAGS)
 471 ])
 472
 473 #
 474 # LB_INCLUDE_RULES
 475 #
 476 # defines for including the toplevel Rules
 477 #
 478 AC_DEFUN([LB_INCLUDE_RULES],
 479 [INCLUDE_RULES="include $PWD/Rules"
 480 AC_SUBST(INCLUDE_RULES)
 481 ])
 482
 483 #
 484 # LB_PATH_DEFAULTS
 485 #
 486 # 'fixup' default paths
 487 #
 488 AC_DEFUN([LB_PATH_DEFAULTS],
 489 [# directories for binaries
 490 AC_PREFIX_DEFAULT([/usr])
 491
 492 sysconfdir='/etc'
 493 AC_SUBST(sysconfdir)
 494
 495 # Directories for documentation and demos.
 496 docdir='${datadir}/doc/$(PACKAGE)'
 497 AC_SUBST(docdir)
 498
 499 LN_PATH_DEFAULTS
 500 LC_PATH_DEFAULTS
 501
 502 ])
 503
 504 #
 505 # LB_PROG_CC
 506 #
 507 # checks on the C compiler
 508 #
 509 AC_DEFUN([LB_PROG_CC],
 510 [AC_PROG_RANLIB
 511 AC_MSG_CHECKING([for buggy compiler])
 512 CC_VERSION=`$CC -v 2>&1 | grep "^gcc version"`
 513 bad_cc() {
 514         AC_MSG_RESULT([buggy compiler found!])
 515         echo
 516         echo "   '$CC_VERSION'"
 517         echo "  has been known to generate bad code, "
 518         echo "  please get an updated compiler."
 519         AC_MSG_ERROR([sorry])
 520 }
 521 case "$CC_VERSION" in
 522         "gcc version 2.95"*)
 523                 bad_cc
 524                 ;;
 525         # ost_pack_niobuf putting 64bit NTOH temporaries on the stack
 526         # without "sub    $0xc,%esp" to protect the stack from being
 527         # stomped on by interrupts (bug 606)
 528         "gcc version 2.96 20000731 (Red Hat Linux 7.1 2.96-98)")
 529                 bad_cc
 530                 ;;
 531         # mandrake's similar sub 0xc compiler bug
 532         # http://marc.theaimsgroup.com/?l=linux-kernel&m=104748366226348&w=2
 533         "gcc version 2.96 20000731 (Mandrake Linux 8.1 2.96-0.62mdk)")
 534                 bad_cc
 535                 ;;
 536         *)
 537                 AC_MSG_RESULT([no known problems])
 538                 ;;
 539 esac
 540
 541 # ---------  unsigned long long sane? -------
 542 AC_CHECK_SIZEOF(unsigned long long, 0)
 543 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
 544 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
 545 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
 546         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.  Tell phil@clusterfs.com])
 547 fi
 548
 549 # FIXME
 550 AC_CHECK_DECL([__i386__], [], [
 551
 552 if test x$enable_bgl != xyes; then
 553 AC_MSG_CHECKING([if $CC accepts -m64])
 554 CC_save="$CC"
 555 CC="$CC -m64"
 556 AC_TRY_COMPILE([],[],[
 557         AC_MSG_RESULT([yes])
 558 ],[
 559         AC_MSG_RESULT([no])
 560         CC="$CC_save"
 561 ])
 562 fi
 563
 564 ])
 565
 566 CPPFLAGS="-I\$(top_builddir)/lnet/include -I\$(top_srcdir)/lnet/include -I\$(top_builddir)/lustre/include -I\$(top_srcdir)/lustre/include $CPPFLAGS"
 567
 568 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
 569 AC_SUBST(LLCPPFLAGS)
 570
 571 LLCFLAGS="-g -Wall -fPIC"
 572 AC_SUBST(LLCFLAGS)
 573
 574 # everyone builds against lnet and lustre
 575 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/lnet/include -I$PWD/lustre/include"
 576 AC_SUBST(EXTRA_KCFLAGS)
 577 ])
 578
 579 #
 580 # LB_CONTITIONALS
 581 #
 582 # AM_CONDITIONAL instances for everything
 583 # (so that portals/lustre can disable some if needed)
 584 AC_DEFUN([LB_CONDITIONALS],
 585 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
 586 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
 587 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
 588 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
 589 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
 590 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
 591 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
 592 AM_CONDITIONAL(CRAY_XT3, test x$enable_cray_xt3 = "xyes")
 593 AM_CONDITIONAL(SUNOS, test x$lb_target_os = "xSunOS")
 594
 595 # this lets lustre cancel libsysio, per-branch or if liblustre is
 596 # disabled
 597 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
 598         if test "x$with_sysio" != xyes ; then
 599                 SYSIO=""
 600                 LIBSYSIO_SUBDIR=""
 601         fi
 602 fi
 603 AC_SUBST(LIBSYSIO_SUBDIR)
 604 AC_SUBST(SYSIO)
 605
 606 LB_LINUX_CONDITIONALS
 607 LB_DARWIN_CONDITIONALS
 608
 609 LN_CONDITIONALS
 610 LC_CONDITIONALS
 611 ])
 612
 613 #
 614 # LB_CONFIG_FILES
 615 #
 616 # build-specific config files
 617 #
 618 AC_DEFUN([LB_CONFIG_FILES],
 619 [
 620 AC_CONFIG_FILES(
 621 [Makefile
 622 autoMakefile
 623 ]
 624 [Rules:build/Rules.in]
 625 AC_PACKAGE_TARNAME[.spec]
 626 )
 627 ])
 628
 629 #
 630 # LB_CONFIGURE
 631 #
 632 # main configure steps
 633 #
 634 AC_DEFUN([LB_CONFIGURE],
 635 [LB_CANONICAL_SYSTEM
 636
 637 LB_INCLUDE_RULES
 638
 639 LB_CONFIG_CRAY_XT3
 640 LB_CONFIG_BGL
 641 LB_PATH_DEFAULTS
 642
 643 LB_PROG_CC
 644
 645 LB_PATH_DMU
 646 LB_CONFIG_UOSS
 647 LB_POSIX_OSD
 648
 649 LB_CONFIG_DOCS
 650 LB_CONFIG_UTILS
 651 LB_CONFIG_TESTS
 652 LC_CONFIG_CLIENT_SERVER
 653
 654 # three macros for cmd3
 655 LC_CONFIG_SPLIT
 656 LC_CONFIG_LDISKFS
 657 LN_CONFIG_CDEBUG
 658
 659 LB_CONFIG_MODULES
 660
 661 LB_PATH_LIBSYSIO
 662 LB_PATH_SNMP
 663 LB_PATH_LDISKFS
 664
 665 LC_CONFIG_LIBLUSTRE
 666 LN_CONFIGURE
 667
 668 LC_CONFIGURE
 669
 670 if test "$SNMP_DIST_SUBDIR" ; then
 671         LS_CONFIGURE
 672 fi
 673
 674 LB_CONDITIONALS
 675 LB_CONFIG_HEADERS
 676
 677 LB_CONFIG_FILES
 678 LN_CONFIG_FILES
 679 LC_CONFIG_FILES
 680 if test "$SNMP_DIST_SUBDIR" ; then
 681         LS_CONFIG_FILES
 682 fi
 683
 684 AC_SUBST(ac_configure_args)
 685
 686 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.*'
 687 AC_SUBST(MOSTLYCLEANFILES)
 688
 689 AC_OUTPUT
 690
 691 cat <<_ACEOF
 692
 693 CC:            $CC
 694 LD:            $LD
 695 CPPFLAGS:      $CPPFLAGS
 696 LLCPPFLAGS:    $LLCPPFLAGS
 697 CFLAGS:        $CFLAGS
 698 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 699 LLCFLAGS:      $LLCFLAGS
 700
 701 Type 'make' to build Lustre.
 702 _ACEOF
 703 ])