build/autoconf/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION],
   7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
   8         AC_MSG_ERROR([This script was not built with a version number.])
   9 fi
  10 ])
  11
  12 #
  13 # LB_CANONICAL_SYSTEM
  14 #
  15 # fixup $target_os for use in other places
  16 #
  17 AC_DEFUN([LB_CANONICAL_SYSTEM],
  18 [case $target_os in
  19         linux*)
  20                 lb_target_os="linux"
  21                 ;;
  22         darwin*)
  23                 lb_target_os="darwin"
  24                 ;;
  25 esac
  26 AC_SUBST(lb_target_os)
  27 ])
  28
  29 #
  30 # LB_CHECK_FILE
  31 #
  32 # Check for file existance even when cross compiling
  33 #
  34 AC_DEFUN([LB_CHECK_FILE],
  35 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
  36 AC_CACHE_CHECK([for $1], lb_File,
  37 [if test -r "$1"; then
  38   AS_VAR_SET(lb_File, yes)
  39 else
  40   AS_VAR_SET(lb_File, no)
  41 fi])
  42 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
  43 AS_VAR_POPDEF([lb_File])dnl
  44 ])# LB_CHECK_FILE
  45
  46 #
  47 # LB_CHECK_FILES
  48 #
  49 # LB_CHECK_FILE over multiple files
  50 #
  51 AC_DEFUN([LB_CHECK_FILES],
  52 [AC_FOREACH([AC_FILE_NAME], [$1],
  53   [LB_CHECK_FILE(AC_FILE_NAME,
  54                  [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]AC_FILE_NAME), 1,
  55                                     [Define to 1 if you have the
  56                                      file `]AC_File['.])
  57 $2],
  58                  [$3])])])
  59
  60 #
  61 # LB_ARG_LIBS_INCLUDES
  62 #
  63 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
  64 # a single magical macro
  65 #
  66 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
  67 [lb_pathvar="m4_bpatsubst([$2], -, _)"
  68 AC_MSG_CHECKING([for $1])
  69 AC_ARG_WITH([$2],
  70         AC_HELP_STRING([--with-$2=path],
  71                 [path to $1]),
  72         [],[withval=$4])
  73
  74 if test x$withval = xyes ; then
  75         eval "$lb_pathvar='$3'"
  76 else
  77         eval "$lb_pathvar='$withval'"
  78 fi
  79 AC_MSG_RESULT([${!lb_pathvar:-no}])
  80
  81 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
  82         AC_MSG_CHECKING([for $1 includes])
  83         AC_ARG_WITH([$2-includes],
  84                 AC_HELP_STRING([--with-$2-includes=path],
  85                         [path to $1 includes]),
  86                 [],[withval='yes'])
  87
  88         lb_includevar="${lb_pathvar}_includes"
  89         if test x$withval = xyes ; then
  90                 eval "${lb_includevar}='${!lb_pathvar}/include'"
  91         else
  92                 eval "${lb_includevar}='$withval'"
  93         fi
  94         AC_MSG_RESULT([${!lb_includevar}])
  95
  96         AC_MSG_CHECKING([for $1 libs])
  97         AC_ARG_WITH([$2-libs],
  98                 AC_HELP_STRING([--with-$2-libs=path],
  99                         [path to $1 libs]),
 100                 [],[withval='yes'])
 101
 102         lb_libvar="${lb_pathvar}_libs"
 103         if test x$withval = xyes ; then
 104                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
 105         else
 106                 eval "${lb_libvar}='$withval'"
 107         fi
 108         AC_MSG_RESULT([${!lb_libvar}])
 109 fi
 110 ])
 111 ])
 112
 113 #
 114 # LB_PATH_LIBSYSIO
 115 #
 116 # Handle internal/external libsysio
 117 #
 118 AC_DEFUN([LB_PATH_LIBSYSIO],
 119 [AC_ARG_WITH([sysio],
 120         AC_HELP_STRING([--with-sysio=path],
 121                         [set path to libsysio source (default is included libsysio)]),
 122         [],[
 123                 case $lb_target_os in
 124                         linux)
 125                                 with_sysio='yes'
 126                                 ;;
 127                         *)
 128                                 with_sysio='no'
 129                                 ;;
 130                 esac
 131         ])
 132 AC_MSG_CHECKING([location of libsysio])
 133 enable_sysio="$with_sysio"
 134 case x$with_sysio in
 135         xyes)
 136                 AC_MSG_RESULT([internal])
 137                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
 138                         AC_MSG_ERROR([A complete internal libsysio was not found.])
 139                 ])
 140                 LIBSYSIO_SUBDIR="libsysio"
 141                 SYSIO="$PWD/libsysio"
 142                 ;;
 143         xno)
 144                 AC_MSG_RESULT([disabled])
 145                 ;;
 146         *)
 147                 AC_MSG_RESULT([$with_sysio])
 148                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
 149                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
 150                 ])
 151                 SYSIO=$with_sysio
 152                 with_sysio="yes"
 153                 ;;
 154 esac
 155
 156 # We have to configure even if we don't build here for make dist to
 157 # work
 158 AC_CONFIG_SUBDIRS(libsysio)
 159 ])
 160
 161 #
 162 # LB_PATH_CRAY_PORTALS
 163 #
 164 # Support for external Cray portals
 165 #
 166 AC_DEFUN([LB_PATH_CRAY_PORTALS],
 167 [LB_ARG_LIBS_INCLUDES([Cray Portals],[cray-portals])
 168
 169 if test x$cray_portals_includes != x ; then
 170         if test ! -r $cray_portals_includes/portals/api.h ; then
 171                 AC_MSG_ERROR([Cray portals headers were not found in $cray_portals_includes.  Please check the paths passed to --with-cray-portals or --with-cray-portals-includes.])
 172         fi
 173 fi
 174 if test x$cray_portals_libs != x ; then
 175         if test ! -r $cray_portals_libs/libportals.a ; then
 176                 AC_MSG_ERROR([Cray portals libraries were not found in $cray_portals_libs.  Please check the paths passed to --with-cray-portals or --with-cray-portals-libs.])
 177         fi
 178 fi
 179
 180 if test x$cray_portals_includes != x -a x$cray_portals_libs != x ; then
 181         cray_portals=yes
 182         AC_DEFINE(CRAY_PORTALS, 1, [Building with Cray Portals])
 183         CPPFLAGS="-I$cray_portals_includes $CPPFLAGS"
 184         EXTRA_KCFLAGS="-I$cray_portals_includes $EXTRA_KCFLAGS"
 185         # for liblustre + b_cray
 186         CRAY_PORTALS_LIBS="$cray_portals_libs"
 187         AC_SUBST(CRAY_PORTALS_LIBS)
 188 else
 189         cray_portals=no
 190 fi
 191 ])
 192
 193 #
 194 # LB_CONFIG_MODULES
 195 #
 196 # Build kernel modules?
 197 #
 198 AC_DEFUN([LB_CONFIG_MODULES],
 199 [AC_MSG_CHECKING([whether to build kernel modules])
 200 AC_ARG_ENABLE([modules],
 201         AC_HELP_STRING([--disable-modules],
 202                         [disable building of Lustre kernel modules]),
 203         [],[
 204                 LC_TARGET_SUPPORTED([
 205                         enable_modules='yes'
 206                 ],[
 207                         enable_modules='no'
 208                 ])
 209         ])
 210 AC_MSG_RESULT([$enable_modules ($target_os)])
 211
 212 if test x$enable_modules = xyes ; then
 213         case $target_os in
 214                 linux*)
 215                         LB_PROG_LINUX
 216                         ;;
 217                 darwin*)
 218                         LB_PROG_DARWIN
 219                         ;;
 220                 *)
 221                         # This is strange - Lustre supports a target we don't
 222                         AC_MSG_ERROR([Modules are not supported on $target_os])
 223                         ;;
 224         esac
 225 fi
 226 ])
 227
 228 #
 229 # LB_CONFIG_UTILS
 230 #
 231 # Build utils?
 232 #
 233 AC_DEFUN([LB_CONFIG_UTILS],
 234 [AC_MSG_CHECKING([whether to build utilities])
 235 AC_ARG_ENABLE([utils],
 236         AC_HELP_STRING([--disable-utils],
 237                         [disable building of Lustre utility programs]),
 238         [],[enable_utils='yes'])
 239 if test x$cray_portals = xyes ; then
 240         enable_utils='no'
 241 fi
 242 AC_MSG_RESULT([$enable_utils])
 243 if test x$enable_utils = xyes ; then
 244         LB_CONFIG_INIT_SCRIPTS
 245 fi
 246 ])
 247
 248 #
 249 # LB_CONFIG_TESTS
 250 #
 251 # Build tests?
 252 #
 253 AC_DEFUN([LB_CONFIG_TESTS],
 254 [AC_MSG_CHECKING([whether to build Lustre tests])
 255 AC_ARG_ENABLE([tests],
 256         AC_HELP_STRING([--disable-tests],
 257                         [disable building of Lustre tests]),
 258         [],[enable_tests='yes'])
 259 if test x$cray_portals = xyes ; then
 260         enable_tests='no'
 261 fi
 262 AC_MSG_RESULT([$enable_tests])
 263 ])
 264
 265 #
 266 # LB_CONFIG_DOCS
 267 #
 268 # Build docs?
 269 #
 270 AC_DEFUN([LB_CONFIG_DOCS],
 271 [AC_MSG_CHECKING([whether to build docs])
 272 AC_ARG_ENABLE(doc,
 273         AC_HELP_STRING([--disable-doc],
 274                         [skip creation of pdf documentation]),
 275         [
 276                 if test x$enable_doc = xyes ; then
 277                     ENABLE_DOC=1
 278                 else
 279                     ENABLE_DOC=0
 280                 fi
 281         ],[
 282                 ENABLE_DOC=0
 283                 enable_doc='no'
 284         ])
 285 AC_MSG_RESULT([$enable_doc])
 286 AC_SUBST(ENABLE_DOC)
 287 ])
 288
 289 #
 290 # LB_CONFIG_INIT_SCRIPTS
 291 #
 292 # our init scripts only work on red hat linux
 293 #
 294 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
 295 [ENABLE_INIT_SCRIPTS=0
 296 if test x$enable_utils = xyes ; then
 297         AC_MSG_CHECKING([whether to install init scripts])
 298         # our scripts only work on red hat systems
 299         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
 300                 ENABLE_INIT_SCRIPTS=1
 301                 AC_MSG_RESULT([yes])
 302         else
 303                 AC_MSG_RESULT([no])
 304         fi
 305 fi
 306 AC_SUBST(ENABLE_INIT_SCRIPTS)
 307 ])
 308
 309 #
 310 # LB_CONFIG_HEADERS
 311 #
 312 # add -include config.h
 313 #
 314 AC_DEFUN([LB_CONFIG_HEADERS],
 315 [AC_CONFIG_HEADERS([config.h])
 316 CPPFLAGS="-include \$(top_builddir)/config.h $CPPFLAGS"
 317 EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 318 AC_SUBST(EXTRA_KCFLAGS)
 319 ])
 320
 321 #
 322 # LB_INCLUDE_RULES
 323 #
 324 # defines for including the toplevel Rules
 325 #
 326 AC_DEFUN([LB_INCLUDE_RULES],
 327 [INCLUDE_RULES="include $PWD/build/Rules"
 328 AC_SUBST(INCLUDE_RULES)
 329 ])
 330
 331 #
 332 # LB_PATH_DEFAULTS
 333 #
 334 # 'fixup' default paths
 335 #
 336 AC_DEFUN([LB_PATH_DEFAULTS],
 337 [# directories for binaries
 338 AC_PREFIX_DEFAULT([/usr])
 339
 340 sysconfdir='/etc'
 341 AC_SUBST(sysconfdir)
 342
 343 # Directories for documentation and demos.
 344 docdir='${datadir}/doc/$(PACKAGE)'
 345 AC_SUBST(docdir)
 346
 347 LP_PATH_DEFAULTS
 348 LC_PATH_DEFAULTS
 349 ])
 350
 351 #
 352 # LB_PROG_CC
 353 #
 354 # checks on the C compiler
 355 #
 356 AC_DEFUN([LB_PROG_CC],
 357 [AC_PROG_RANLIB
 358 AC_MSG_CHECKING([for buggy compiler])
 359 CC_VERSION=`$CC -v 2>&1 | grep "^gcc version"`
 360 bad_cc() {
 361         AC_MSG_RESULT([buggy compiler found!])
 362         echo
 363         echo "   '$CC_VERSION'"
 364         echo "  has been known to generate bad code, "
 365         echo "  please get an updated compiler."
 366         AC_MSG_ERROR([sorry])
 367 }
 368 case "$CC_VERSION" in
 369         "gcc version 2.95"*)
 370                 bad_cc
 371                 ;;
 372         # ost_pack_niobuf putting 64bit NTOH temporaries on the stack
 373         # without "sub    $0xc,%esp" to protect the stack from being
 374         # stomped on by interrupts (bug 606)
 375         "gcc version 2.96 20000731 (Red Hat Linux 7.1 2.96-98)")
 376                 bad_cc
 377                 ;;
 378         # mandrake's similar sub 0xc compiler bug
 379         # http://marc.theaimsgroup.com/?l=linux-kernel&m=104748366226348&w=2
 380         "gcc version 2.96 20000731 (Mandrake Linux 8.1 2.96-0.62mdk)")
 381                 bad_cc
 382                 ;;
 383         *)
 384                 AC_MSG_RESULT([no known problems])
 385                 ;;
 386 esac
 387
 388 # ---------  unsigned long long sane? -------
 389 AC_CHECK_SIZEOF(unsigned long long, 0)
 390 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
 391 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
 392 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
 393         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.  Tell phil@clusterfs.com])
 394 fi
 395
 396 AC_MSG_CHECKING([if $CC accepts -m64])
 397 CC_save="$CC"
 398 CC="$CC -m64"
 399 AC_TRY_COMPILE([],[],[
 400         AC_MSG_RESULT([yes])
 401 ],[
 402         AC_MSG_RESULT([no])
 403         CC="$CC_save"
 404 ])
 405
 406 CPPFLAGS="-I\$(top_builddir)/portals/include -I\$(top_srcdir)/portals/include -I\$(top_builddir)/lustre/include -I\$(top_srcdir)/lustre/include $CPPFLAGS"
 407
 408 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
 409 AC_SUBST(LLCPPFLAGS)
 410
 411 LLCFLAGS="-g -Wall -fPIC"
 412 AC_SUBST(LLCFLAGS)
 413
 414 # everyone builds against portals and lustre
 415 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/portals/include -I$PWD/lustre/include"
 416 AC_SUBST(EXTRA_KCFLAGS)
 417 ])
 418
 419 #
 420 # LB_CONTITIONALS
 421 #
 422 # AM_CONDITIONAL instances for everything
 423 # (so that portals/lustre can disable some if needed)
 424 AC_DEFUN([LB_CONDITIONALS],
 425 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
 426 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
 427 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
 428 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
 429 AM_CONDITIONAL(CRAY_PORTALS, test x$cray_portals != xno)
 430 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
 431 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
 432 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
 433
 434 # this lets lustre cancel libsysio, per-branch or if liblustre is
 435 # disabled
 436 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
 437         if test "x$with_sysio" != xyes ; then
 438                 SYSIO=""
 439                 LIBSYSIO_SUBDIR=""
 440         fi
 441 fi
 442 AC_SUBST(LIBSYSIO_SUBDIR)
 443 AC_SUBST(SYSIO)
 444
 445 LB_LINUX_CONDITIONALS
 446 LB_DARWIN_CONDITIONALS
 447
 448 LP_CONDITIONALS
 449 LC_CONDITIONALS
 450 ])
 451
 452 #
 453 # LB_CONFIGURE
 454 #
 455 # main configure steps
 456 #
 457 AC_DEFUN([LB_CONFIGURE],
 458 [LB_CANONICAL_SYSTEM
 459
 460 LB_INCLUDE_RULES
 461
 462 LB_PATH_DEFAULTS
 463
 464 LB_PROG_CC
 465
 466 LB_PATH_LIBSYSIO
 467 LB_PATH_CRAY_PORTALS
 468
 469 LB_CONFIG_DOCS
 470 LB_CONFIG_UTILS
 471 LB_CONFIG_TESTS
 472
 473 LB_CONFIG_MODULES
 474
 475 LC_CONFIG_LIBLUSTRE
 476
 477 LP_CONFIGURE
 478 LC_CONFIGURE
 479
 480 LB_CONDITIONALS
 481 LB_CONFIG_HEADERS
 482
 483 AC_CONFIG_FILES(
 484 [Makefile:build/Makefile.in.toplevel]
 485 [autoMakefile
 486 build/autoMakefile
 487 build/autoconf/Makefile
 488 build/Rules
 489 build/lustre.spec
 490 ])
 491
 492 LP_CONFIG_FILES
 493 LC_CONFIG_FILES
 494
 495 AC_OUTPUT
 496
 497 cat <<_ACEOF
 498
 499 CC:            $CC
 500 LD:            $LD
 501 CPPFLAGS:      $CPPFLAGS
 502 LLCPPFLAGS:    $LLCPPFLAGS
 503 CFLAGS:        $CFLAGS
 504 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 505 LLCFLAGS:      $LLCFLAGS
 506
 507 Type 'make' to build Lustre.
 508 _ACEOF
 509 ])