build/autoconf/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION],
   7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
   8         AC_MSG_ERROR([This script was not built with a version number.])
   9 fi
  10 ])
  11
  12 #
  13 # LB_CANONICAL_SYSTEM
  14 #
  15 # fixup $target_os for use in other places
  16 #
  17 AC_DEFUN([LB_CANONICAL_SYSTEM],
  18 [case $target_os in
  19         linux*)
  20                 lb_target_os="linux"
  21                 ;;
  22         darwin*)
  23                 lb_target_os="darwin"
  24                 ;;
  25         solaris*)
  26                 lb_target_os="SunOS"
  27                 ;;esac
  28 AC_SUBST(lb_target_os)
  29 ])
  30
  31 #
  32 # LB_CHECK_FILE
  33 #
  34 # Check for file existance even when cross compiling
  35 #
  36 AC_DEFUN([LB_CHECK_FILE],
  37 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
  38 AC_CACHE_CHECK([for $1], lb_File,
  39 [if test -r "$1"; then
  40   AS_VAR_SET(lb_File, yes)
  41 else
  42   AS_VAR_SET(lb_File, no)
  43 fi])
  44 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
  45 AS_VAR_POPDEF([lb_File])dnl
  46 ])# LB_CHECK_FILE
  47
  48 #
  49 # LB_CHECK_FILES
  50 #
  51 # LB_CHECK_FILE over multiple files
  52 #
  53 AC_DEFUN([LB_CHECK_FILES],
  54 [AC_FOREACH([AC_FILE_NAME], [$1],
  55   [LB_CHECK_FILE(AC_FILE_NAME,
  56                  [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]AC_FILE_NAME), 1,
  57                                     [Define to 1 if you have the
  58                                      file `]AC_File['.])
  59 $2],
  60                  [$3])])])
  61
  62 #
  63 # LB_ARG_LIBS_INCLUDES
  64 #
  65 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
  66 # a single magical macro
  67 #
  68 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
  69 [lb_pathvar="m4_bpatsubst([$2], -, _)"
  70 AC_MSG_CHECKING([for $1])
  71 AC_ARG_WITH([$2],
  72         AC_HELP_STRING([--with-$2=path],
  73                 [path to $1]),
  74         [],[withval=$4])
  75
  76 if test x$withval = xyes ; then
  77         eval "$lb_pathvar='$3'"
  78 else
  79         eval "$lb_pathvar='$withval'"
  80 fi
  81 AC_MSG_RESULT([${!lb_pathvar:-no}])
  82
  83 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
  84         AC_MSG_CHECKING([for $1 includes])
  85         AC_ARG_WITH([$2-includes],
  86                 AC_HELP_STRING([--with-$2-includes=path],
  87                         [path to $1 includes]),
  88                 [],[withval='yes'])
  89
  90         lb_includevar="${lb_pathvar}_includes"
  91         if test x$withval = xyes ; then
  92                 eval "${lb_includevar}='${!lb_pathvar}/include'"
  93         else
  94                 eval "${lb_includevar}='$withval'"
  95         fi
  96         AC_MSG_RESULT([${!lb_includevar}])
  97
  98         AC_MSG_CHECKING([for $1 libs])
  99         AC_ARG_WITH([$2-libs],
 100                 AC_HELP_STRING([--with-$2-libs=path],
 101                         [path to $1 libs]),
 102                 [],[withval='yes'])
 103
 104         lb_libvar="${lb_pathvar}_libs"
 105         if test x$withval = xyes ; then
 106                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
 107         else
 108                 eval "${lb_libvar}='$withval'"
 109         fi
 110         AC_MSG_RESULT([${!lb_libvar}])
 111 fi
 112 ])
 113 ])
 114
 115 #
 116 # LB_PATH_LIBSYSIO
 117 #
 118 # Handle internal/external libsysio
 119 #
 120 AC_DEFUN([LB_PATH_LIBSYSIO],
 121 [AC_ARG_WITH([sysio],
 122         AC_HELP_STRING([--with-sysio=path],
 123                         [set path to libsysio source (default is included libsysio)]),
 124         [],[
 125                 case $lb_target_os in
 126                         linux)
 127                                 with_sysio='yes'
 128                                 ;;
 129                         *)
 130                                 with_sysio='no'
 131                                 ;;
 132                 esac
 133         ])
 134 AC_MSG_CHECKING([location of libsysio])
 135 enable_sysio="$with_sysio"
 136 case x$with_sysio in
 137         xyes)
 138                 AC_MSG_RESULT([internal])
 139                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
 140                         AC_MSG_ERROR([A complete internal libsysio was not found.])
 141                 ])
 142                 LIBSYSIO_SUBDIR="libsysio"
 143                 SYSIO="$PWD/libsysio"
 144                 ;;
 145         xno)
 146                 AC_MSG_RESULT([disabled])
 147                 ;;
 148         *)
 149                 AC_MSG_RESULT([$with_sysio])
 150                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
 151                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
 152                 ])
 153                 SYSIO=$with_sysio
 154                 with_sysio="yes"
 155                 ;;
 156 esac
 157
 158 # We have to configure even if we don't build here for make dist to work
 159 AC_CONFIG_SUBDIRS(libsysio)
 160 ])
 161
 162 #
 163 # LB_PATH_LUSTREIOKIT
 164 #
 165 # Handle internal/external lustre-iokit
 166 #
 167 AC_DEFUN([LB_PATH_LUSTREIOKIT],
 168 [AC_ARG_WITH([],
 169         AC_HELP_STRING([--with-lustre-iokit=path],
 170                         [set path to lustre-iokit source (default is included lustre-iokit)]),
 171         [],[
 172                         with_lustre_iokit='yes'
 173         ])
 174 AC_MSG_CHECKING([location of lustre-iokit])
 175 enable_lustre_iokit="$with_lustre_iokit"
 176 case x$with_lustre_iokit in
 177         xyes)
 178                 AC_MSG_RESULT([internal])
 179                 LB_CHECK_FILE([$srcdir/lustre-iokit/ior-survey/ior-survey],[],[
 180                         AC_MSG_ERROR([A complete internal lustre-iokit was not found.])
 181                 ])
 182                 LUSTREIOKIT_SUBDIR="lustre-iokit"
 183                 LUSTREIOKIT="$PWD/lustre-iokit"
 184                 ;;
 185         xno)
 186                 AC_MSG_RESULT([disabled])
 187                 ;;
 188         *)
 189                 AC_MSG_RESULT([$with_lustre_iokit])
 190                 LB_CHECK_FILE([$with_lustre_iokit/ior-survey/ior_survey],[],[
 191                         AC_MSG_ERROR([A complete (built) external lustre-iokit was not found.])
 192                 ])
 193                 LUSTREIOKIT="$with_lustre_iokit"
 194                 with_lustre_iokit="yes"
 195                 ;;
 196 esac
 197 AC_SUBST(LUSTREIOKIT_SUBDIR)
 198 # We have to configure even if we don't build here for make dist to work
 199 AC_CONFIG_SUBDIRS(lustre-iokit)
 200 ])
 201
 202 #
 203 # LB_PATH_LDISKFS
 204 #
 205 # Handle internal/external ldiskfs
 206 #
 207 AC_DEFUN([LB_PATH_LDISKFS],
 208 [AC_ARG_WITH([ldiskfs],
 209         AC_HELP_STRING([--with-ldiskfs=path],
 210                         [set path to ldiskfs source (default is included ldiskfs)]),
 211         [],[
 212                 if test x$linux25$enable_server = xyesyes ; then
 213                         with_ldiskfs=yes
 214                 else
 215                         with_ldiskfs=no
 216                 fi
 217         ])
 218 AC_MSG_CHECKING([location of ldiskfs])
 219 case x$with_ldiskfs in
 220         xyes)
 221                 AC_MSG_RESULT([internal])
 222                 LB_CHECK_FILE([$srcdir/ldiskfs/lustre-ldiskfs.spec.in],[],[
 223                         AC_MSG_ERROR([A complete internal ldiskfs was not found.])
 224                 ])
 225                 LDISKFS_SUBDIR="ldiskfs"
 226                 LDISKFS_DIR="$PWD/ldiskfs"
 227                 ;;
 228         xno)
 229                 AC_MSG_RESULT([disabled])
 230                 ;;
 231         *)
 232                 AC_MSG_RESULT([$with_ldiskfs])
 233                 LB_CHECK_FILE([$with_ldiskfs/ldiskfs/linux/ldiskfs_fs.h],[],[
 234                         AC_MSG_ERROR([A complete (built) external ldiskfs was not found.])
 235                 ])
 236                 LDISKFS_DIR=$with_ldiskfs
 237                 ;;
 238 esac
 239 AC_SUBST(LDISKFS_DIR)
 240 AC_SUBST(LDISKFS_SUBDIR)
 241 AM_CONDITIONAL(LDISKFS_ENABLED, test x$with_ldiskfs != xno)
 242
 243 # We have to configure even if we don't build here for make dist to work
 244 AC_CONFIG_SUBDIRS(ldiskfs)
 245 ])
 246
 247 #
 248 # LB_DEFINE_LDISKFS_OPTIONS
 249 #
 250 # Enable config options related to ldiskfs.  These are used both by ldiskfs
 251 # and lvfs (which includes ldiskfs headers.)
 252 #
 253 AC_DEFUN([LB_DEFINE_LDISKFS_OPTIONS],
 254 [
 255         AC_DEFINE(CONFIG_LDISKFS_FS_MODULE, 1, [build ldiskfs as a module])
 256         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [enable extended attributes for ldiskfs])
 257         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [enable posix acls for ldiskfs])
 258         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [enable fs security for ldiskfs])
 259 ])
 260
 261 #
 262 # LB_CONFIG_CRAY_XT3
 263 #
 264 # Enable Cray XT3 features
 265 #
 266 AC_DEFUN([LB_CONFIG_CRAY_XT3],
 267 [AC_MSG_CHECKING([whether to build Cray XT3 features])
 268 AC_ARG_ENABLE([cray_xt3],
 269         AC_HELP_STRING([--enable-cray-xt3],
 270                         [enable building of Cray XT3 features]),
 271         [enable_cray_xt3='yes'],[enable_cray_xt3='no'])
 272 AC_MSG_RESULT([$enable_cray_xt3])
 273 if test x$enable_cray_xt3 != xno; then
 274         AC_DEFINE(CRAY_XT3, 1, Enable Cray XT3 Features)
 275 fi
 276 ])
 277
 278 #
 279 # LB_CONFIG_BGL
 280 #
 281 # Enable BGL features
 282 #
 283 AC_DEFUN([LB_CONFIG_BGL],
 284 [AC_MSG_CHECKING([whether to build BGL features])
 285 AC_ARG_ENABLE([bgl],
 286         AC_HELP_STRING([--enable-bgl],
 287                         [enable building of BGL features]),
 288         [enable_bgl='yes'],[enable_bgl='no'])
 289 AC_MSG_RESULT([$enable_bgl])
 290 if test x$enable_bgl != xno; then
 291         AC_DEFINE(BGL_SUPPORT, 1, Enable BGL Features)
 292         enable_doc='no'
 293         enable_tests='no'
 294         enable_server='no'
 295         enable_liblustre='no'
 296         enable_libreadline='no'
 297 fi
 298 ])
 299
 300 #
 301 # Support for --enable-uoss
 302 #
 303 AC_DEFUN([LB_UOSS],
 304 [AC_MSG_CHECKING([whether to enable uoss])
 305 AC_ARG_ENABLE([uoss],
 306         AC_HELP_STRING([--enable-uoss],
 307                         [enable userspace OSS]),
 308         [enable_uoss='yes'],[enable_uoss='no'])
 309 AC_MSG_RESULT([$enable_uoss])
 310 if test x$enable_uoss = xyes; then
 311         AC_DEFINE(UOSS_SUPPORT, 1, Enable user-level OSS)
 312         AC_DEFINE(LUSTRE_ULEVEL_MT, 1, Multi-threaded user-level lustre port)
 313         enable_uoss='yes'
 314         enable_ulevel_mt='yes'
 315         enable_modules='no'
 316         enable_client='no'
 317         enable_tests='no'
 318         enable_liblustre='no'
 319         with_ldiskfs='no'
 320 fi
 321 AC_SUBST(enable_uoss)
 322 ])
 323
 324 #
 325 # Support for --enable-posix-osd
 326 #
 327 AC_DEFUN([LB_POSIX_OSD],
 328 [AC_MSG_CHECKING([whether to enable posix osd])
 329 AC_ARG_ENABLE([posix-osd],
 330         AC_HELP_STRING([--enable-posix-osd],
 331                         [enable using of posix osd]),
 332         [enable_posix_osd='yes'],[enable_posix_osd='no'])
 333 AC_MSG_RESULT([$enable_posix_osd])
 334 if test x$enable_uoss = xyes -a x$enable_posix_osd = xyes ; then
 335         AC_DEFINE(POSIX_OSD, 1, Enable POSIX OSD)
 336         posix_osd='yes'
 337 fi
 338 AM_CONDITIONAL(POSIX_OSD_ENABLED, test x$posix_osd = xyes)
 339 ])
 340
 341 #
 342 # LB_PATH_DMU
 343 # Support for --with-dmu
 344 #
 345 AC_DEFUN([LB_PATH_DMU],
 346 [AC_MSG_CHECKING([whether to enable DMU])
 347 AC_ARG_WITH([dmu],
 348         AC_HELP_STRING([--with-dmu=path],
 349                        [set path to a DMU tree (default is included zfs-lustre)]),
 350         [
 351                 DMU_SRC=$with_dmu
 352         ],
 353         [
 354                 DMU_SRC="$PWD/zfs-lustre"
 355         ])
 356 if test x$enable_uoss = xyes -a x$enable_posix_osd != xyes; then
 357         AC_DEFINE(DMU_OSD, 1, Enable DMU OSD)
 358         AC_MSG_RESULT([yes])
 359         LB_CHECK_FILE([$DMU_SRC/src/.patched],[],[
 360                 AC_MSG_ERROR([A complete (patched) DMU tree was not found.])
 361         ])
 362         AC_CONFIG_SUBDIRS(zfs-lustre)
 363         dmu_osd='yes'
 364 else
 365         AC_MSG_RESULT([no])
 366 fi
 367 AC_SUBST(DMU_SRC)
 368 AM_CONDITIONAL(DMU_OSD_ENABLED, test x$dmu_osd = xyes)
 369 ])
 370
 371 #
 372 # LB_PATH_SNMP
 373 #
 374 # check for in-tree snmp support
 375 #
 376 AC_DEFUN([LB_PATH_SNMP],
 377 [LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c],[SNMP_DIST_SUBDIR="snmp"])
 378 AC_SUBST(SNMP_DIST_SUBDIR)
 379 AC_SUBST(SNMP_SUBDIR)
 380 ])
 381
 382 #
 383 # LB_CONFIG_MODULES
 384 #
 385 # Build kernel modules?
 386 #
 387 AC_DEFUN([LB_CONFIG_MODULES],
 388 [AC_MSG_CHECKING([whether to build kernel modules])
 389 AC_ARG_ENABLE([modules],
 390         AC_HELP_STRING([--disable-modules],
 391                         [disable building of Lustre kernel modules]),
 392         [],[
 393                 LC_TARGET_SUPPORTED([
 394                         enable_modules='yes'
 395                 ],[
 396                         enable_modules='no'
 397                 ])
 398         ])
 399 AC_MSG_RESULT([$enable_modules ($target_os)])
 400
 401 if test x$enable_modules = xyes ; then
 402         case $target_os in
 403                 linux*)
 404                         LB_PROG_LINUX
 405                         LIBCFS_PROG_LINUX
 406                         LN_PROG_LINUX
 407                         LC_PROG_LINUX
 408                         ;;
 409                 darwin*)
 410                         LB_PROG_DARWIN
 411                         LIBCFS_PROG_DARWIN
 412                         ;;
 413                 *)
 414                         # This is strange - Lustre supports a target we don't
 415                         AC_MSG_ERROR([Modules are not supported on $target_os])
 416                         ;;
 417         esac
 418 fi
 419 ])
 420
 421 #
 422 # LB_CONFIG_UTILS
 423 #
 424 # Build utils?
 425 #
 426 AC_DEFUN([LB_CONFIG_UTILS],
 427 [AC_MSG_CHECKING([whether to build utilities])
 428 AC_ARG_ENABLE([utils],
 429         AC_HELP_STRING([--disable-utils],
 430                         [disable building of Lustre utility programs]),
 431         [],[enable_utils='yes'])
 432 AC_MSG_RESULT([$enable_utils])
 433 if test x$enable_utils = xyes ; then
 434         LB_CONFIG_INIT_SCRIPTS
 435 fi
 436 ])
 437
 438 #
 439 # LB_CONFIG_TESTS
 440 #
 441 # Build tests?
 442 #
 443 AC_DEFUN([LB_CONFIG_TESTS],
 444 [AC_MSG_CHECKING([whether to build Lustre tests])
 445 AC_ARG_ENABLE([tests],
 446         AC_HELP_STRING([--disable-tests],
 447                         [disable building of Lustre tests]),
 448         [],
 449         [
 450                 enable_tests='yes'
 451         ])
 452 AC_MSG_RESULT([$enable_tests])
 453 ])
 454
 455 #
 456 # LB_CONFIG_DOCS
 457 #
 458 # Build docs?
 459 #
 460 AC_DEFUN([LB_CONFIG_DOCS],
 461 [AC_MSG_CHECKING([whether to build docs])
 462 AC_ARG_ENABLE(doc,
 463         AC_HELP_STRING([--disable-doc],
 464                         [skip creation of pdf documentation]),
 465         [
 466                 if test x$enable_doc = xyes ; then
 467                     ENABLE_DOC=1
 468                 else
 469                     ENABLE_DOC=0
 470                 fi
 471         ],[
 472                 ENABLE_DOC=0
 473                 enable_doc='no'
 474         ])
 475 AC_MSG_RESULT([$enable_doc])
 476 AC_SUBST(ENABLE_DOC)
 477 ])
 478
 479 #
 480 # LB_CONFIG_INIT_SCRIPTS
 481 #
 482 # our init scripts only work on red hat linux
 483 #
 484 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
 485 [ENABLE_INIT_SCRIPTS=0
 486 if test x$enable_utils = xyes ; then
 487         AC_MSG_CHECKING([whether to install init scripts])
 488         # our scripts only work on red hat systems
 489         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
 490                 ENABLE_INIT_SCRIPTS=1
 491                 AC_MSG_RESULT([yes])
 492         else
 493                 AC_MSG_RESULT([no])
 494         fi
 495 fi
 496 AC_SUBST(ENABLE_INIT_SCRIPTS)
 497 ])
 498
 499 #
 500 # LB_CONFIG_HEADERS
 501 #
 502 # add -include config.h
 503 #
 504 AC_DEFUN([LB_CONFIG_HEADERS],
 505 [AC_CONFIG_HEADERS([config.h])
 506 CPPFLAGS="-include \$(top_builddir)/config.h $CPPFLAGS"
 507 EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 508 AC_SUBST(EXTRA_KCFLAGS)
 509 ])
 510
 511 #
 512 # LB_INCLUDE_RULES
 513 #
 514 # defines for including the toplevel Rules
 515 #
 516 AC_DEFUN([LB_INCLUDE_RULES],
 517 [INCLUDE_RULES="include $PWD/Rules"
 518 AC_SUBST(INCLUDE_RULES)
 519 ])
 520
 521 #
 522 # LB_PATH_DEFAULTS
 523 #
 524 # 'fixup' default paths
 525 #
 526 AC_DEFUN([LB_PATH_DEFAULTS],
 527 [# directories for binaries
 528 AC_PREFIX_DEFAULT([/usr])
 529
 530 sysconfdir='/etc'
 531 AC_SUBST(sysconfdir)
 532
 533 # Directories for documentation and demos.
 534 docdir='${datadir}/doc/$(PACKAGE)'
 535 AC_SUBST(docdir)
 536
 537 LIBCFS_PATH_DEFAULTS
 538 LN_PATH_DEFAULTS
 539 LC_PATH_DEFAULTS
 540
 541 ])
 542
 543 #
 544 # LB_PROG_CC
 545 #
 546 # checks on the C compiler
 547 #
 548 AC_DEFUN([LB_PROG_CC],
 549 [AC_PROG_RANLIB
 550 AC_MSG_CHECKING([for buggy compiler])
 551 CC_VERSION=`$CC -v 2>&1 | grep "^gcc version"`
 552 bad_cc() {
 553         AC_MSG_RESULT([buggy compiler found!])
 554         echo
 555         echo "   '$CC_VERSION'"
 556         echo "  has been known to generate bad code, "
 557         echo "  please get an updated compiler."
 558         AC_MSG_ERROR([sorry])
 559 }
 560 case "$CC_VERSION" in
 561         "gcc version 2.95"*)
 562                 bad_cc
 563                 ;;
 564         # ost_pack_niobuf putting 64bit NTOH temporaries on the stack
 565         # without "sub    $0xc,%esp" to protect the stack from being
 566         # stomped on by interrupts (bug 606)
 567         "gcc version 2.96 20000731 (Red Hat Linux 7.1 2.96-98)")
 568                 bad_cc
 569                 ;;
 570         # mandrake's similar sub 0xc compiler bug
 571         # http://marc.theaimsgroup.com/?l=linux-kernel&m=104748366226348&w=2
 572         "gcc version 2.96 20000731 (Mandrake Linux 8.1 2.96-0.62mdk)")
 573                 bad_cc
 574                 ;;
 575         *)
 576                 AC_MSG_RESULT([no known problems])
 577                 ;;
 578 esac
 579
 580 # ---------  unsigned long long sane? -------
 581 AC_CHECK_SIZEOF(unsigned long long, 0)
 582 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
 583 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
 584 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
 585         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.  Tell phil@clusterfs.com])
 586 fi
 587
 588 CPPFLAGS="-I\$(top_builddir)/libcfs/include -I\$(top_srcdir)/libcfs/include -I\$(top_builddir)/lnet/include -I\$(top_srcdir)/lnet/include -I\$(top_builddir)/lustre/include -I\$(top_srcdir)/lustre/include $CPPFLAGS"
 589
 590 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
 591 AC_SUBST(LLCPPFLAGS)
 592
 593 LLCFLAGS="-g -Wall -fPIC"
 594 AC_SUBST(LLCFLAGS)
 595
 596 # everyone builds against lnet and lustre
 597 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/libcfs/include -I$PWD/lnet/include -I$PWD/lustre/include"
 598 AC_SUBST(EXTRA_KCFLAGS)
 599 ])
 600
 601 #
 602 # LB_CONTITIONALS
 603 #
 604 # AM_CONDITIONAL instances for everything
 605 # (so that portals/lustre can disable some if needed)
 606 AC_DEFUN([LB_CONDITIONALS],
 607 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
 608 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
 609 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
 610 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
 611 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
 612 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
 613 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
 614 AM_CONDITIONAL(CRAY_XT3, test x$enable_cray_xt3 = "xyes")
 615 AM_CONDITIONAL(SUNOS, test x$lb_target_os = "xSunOS")
 616
 617 # this lets lustre cancel libsysio, per-branch or if liblustre is
 618 # disabled
 619 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
 620         if test "x$with_sysio" != xyes ; then
 621                 SYSIO=""
 622                 LIBSYSIO_SUBDIR=""
 623         fi
 624 fi
 625 AC_SUBST(LIBSYSIO_SUBDIR)
 626 AC_SUBST(SYSIO)
 627
 628 LB_LINUX_CONDITIONALS
 629 LB_DARWIN_CONDITIONALS
 630
 631 LIBCFS_CONDITIONALS
 632 LN_CONDITIONALS
 633 LC_CONDITIONALS
 634 ])
 635
 636 #
 637 # LB_CONFIG_FILES
 638 #
 639 # build-specific config files
 640 #
 641 AC_DEFUN([LB_CONFIG_FILES],
 642 [
 643 AC_CONFIG_FILES(
 644 [Makefile
 645 autoMakefile
 646 ]
 647 [Rules:build/Rules.in]
 648 AC_PACKAGE_TARNAME[.spec]
 649 )
 650 ])
 651
 652 #
 653 # LB_CONFIGURE
 654 #
 655 # main configure steps
 656 #
 657 AC_DEFUN([LB_CONFIGURE],
 658 [LB_CANONICAL_SYSTEM
 659
 660 LB_INCLUDE_RULES
 661
 662 LB_CONFIG_CRAY_XT3
 663 LB_CONFIG_BGL
 664 LB_PATH_DEFAULTS
 665
 666 LB_PROG_CC
 667
 668 LB_UOSS
 669 LB_POSIX_OSD
 670 LB_PATH_DMU
 671
 672 LB_CONFIG_DOCS
 673 LB_CONFIG_UTILS
 674 LB_CONFIG_TESTS
 675 LC_CONFIG_CLIENT_SERVER
 676
 677 # three macros for cmd3
 678 LC_CONFIG_SPLIT
 679 LC_CONFIG_LDISKFS
 680 LIBCFS_CONFIG_CDEBUG
 681
 682 LB_CONFIG_MODULES
 683
 684 LB_PATH_LIBSYSIO
 685 LB_PATH_SNMP
 686 LB_PATH_LDISKFS
 687 LB_PATH_LUSTREIOKIT
 688
 689 LC_CONFIG_LIBLUSTRE
 690 LIBCFS_CONFIGURE
 691 LN_CONFIGURE
 692
 693 LC_CONFIGURE
 694
 695 if test "$SNMP_DIST_SUBDIR" ; then
 696         LS_CONFIGURE
 697 fi
 698
 699 LB_CONDITIONALS
 700 LB_CONFIG_HEADERS
 701
 702 LIBCFS_CONFIG_FILES
 703 LB_CONFIG_FILES
 704 LN_CONFIG_FILES
 705 LC_CONFIG_FILES
 706 if test "$SNMP_DIST_SUBDIR" ; then
 707         LS_CONFIG_FILES
 708 fi
 709
 710 AC_SUBST(ac_configure_args)
 711
 712 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
 713 AC_SUBST(MOSTLYCLEANFILES)
 714
 715 AC_OUTPUT
 716
 717 cat <<_ACEOF
 718
 719 CC:            $CC
 720 LD:            $LD
 721 CPPFLAGS:      $CPPFLAGS
 722 LLCPPFLAGS:    $LLCPPFLAGS
 723 CFLAGS:        $CFLAGS
 724 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 725 LLCFLAGS:      $LLCFLAGS
 726
 727 Type 'make' to build Lustre.
 728 _ACEOF
 729 ])