build/autoconf/lustre-build-linux.m4

   1 #
   2 # LB_LINUX_VERSION
   3 #
   4 # Set things accordingly for a linux kernel
   5 #
   6 AC_DEFUN([LB_LINUX_VERSION],[
   7 KMODEXT=".ko"
   8
   9 MODULE_TARGET="SUBDIRS"
  10 makerule="$PWD/build"
  11 AC_MSG_CHECKING([for external module build support])
  12 rm -f build/conftest.i
  13 LB_LINUX_TRY_MAKE([],[],
  14         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  15         [test -s build/conftest.i],
  16         [
  17                 AC_MSG_RESULT([no])
  18         ],[
  19                 makerule="_module_$makerule"
  20                 MODULE_TARGET="M"
  21                 LB_LINUX_TRY_MAKE([],[],
  22                         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  23                         [test -s build/conftest.i],
  24                         [
  25                                 AC_MSG_RESULT([yes])
  26                         ],[
  27                                 AC_MSG_ERROR([unknown; check config.log for details])
  28                         ])
  29         ])
  30
  31 AC_SUBST(MODULE_TARGET)
  32 AC_SUBST(KMODEXT)
  33 ])
  34
  35 #
  36 # LB_LINUX_RELEASE
  37 #
  38 # get the release version of linux
  39 #
  40 AC_DEFUN([LB_LINUX_RELEASE],
  41 [LINUXRELEASE=
  42 rm -f build/conftest.i
  43 AC_MSG_CHECKING([for Linux release])
  44 if test -s $LINUX_OBJ/include/$AUTOCONF_HDIR/utsrelease.h ; then
  45         LINUXRELEASEHEADER=$AUTOCONF_HDIR/utsrelease.h
  46 else
  47         LINUXRELEASEHEADER=linux/version.h
  48 fi
  49 LB_LINUX_TRY_MAKE([
  50         #include <$LINUXRELEASEHEADER>
  51 ],[
  52         char *LINUXRELEASE;
  53         LINUXRELEASE=UTS_RELEASE;
  54 ],[
  55         $makerule LUSTRE_KERNEL_TEST=conftest.i
  56 ],[
  57         test -s build/conftest.i
  58 ],[
  59         # LINUXRELEASE="UTS_RELEASE"
  60         eval $(grep "LINUXRELEASE=" build/conftest.i)
  61 ],[
  62         AC_MSG_RESULT([unknown])
  63         AC_MSG_ERROR([Could not preprocess test program.  Consult config.log for details.])
  64 ])
  65 rm -f build/conftest.i
  66 if test x$LINUXRELEASE = x ; then
  67         AC_MSG_RESULT([unknown])
  68         AC_MSG_ERROR([Could not determine Linux release version from linux/version.h.])
  69 fi
  70 AC_MSG_RESULT([$LINUXRELEASE])
  71 AC_SUBST(LINUXRELEASE)
  72
  73 moduledir='/lib/modules/'$LINUXRELEASE/updates/kernel
  74 AC_SUBST(moduledir)
  75
  76 modulefsdir='$(moduledir)/fs/$(PACKAGE)'
  77 AC_SUBST(modulefsdir)
  78
  79 modulenetdir='$(moduledir)/net/$(PACKAGE)'
  80 AC_SUBST(modulenetdir)
  81
  82 # ------------ RELEASE --------------------------------
  83 AC_MSG_CHECKING([for Lustre release])
  84 AC_ARG_WITH([release],
  85         AC_HELP_STRING([--with-release=string],
  86                        [set the release string (default=$kvers_YYYYMMDDhhmm)]),
  87         [RELEASE=$withval],
  88         RELEASE=""
  89         if test -n "$DOWNSTREAM_RELEASE"; then
  90                 RELEASE="${DOWNSTREAM_RELEASE}_"
  91         fi
  92         RELEASE="$RELEASE`echo ${LINUXRELEASE} | tr '-' '_'`_$BUILDID")
  93 AC_MSG_RESULT($RELEASE)
  94 AC_SUBST(RELEASE)
  95
  96 # check is redhat/suse kernels
  97 AC_MSG_CHECKING([that RedHat kernel])
  98 LB_LINUX_TRY_COMPILE([
  99                 #include <linux/version.h>
 100         ],[
 101                 #ifndef RHEL_RELEASE_CODE
 102                 #error "not redhat kernel"
 103                 #endif
 104         ],[
 105                 RHEL_KERNEL="yes"
 106                 AC_MSG_RESULT([yes])
 107         ],[
 108                 AC_MSG_RESULT([no])
 109 ])
 110
 111 LB_LINUX_CONFIG([SUSE_KERNEL],[SUSE_KERNEL="yes"],[])
 112
 113 ])
 114
 115 # LB_ARG_REPLACE_PATH(PACKAGE, PATH)
 116 AC_DEFUN([LB_ARG_REPLACE_PATH],[
 117         new_configure_args=
 118         eval "set x $ac_configure_args"
 119         shift
 120         for arg; do
 121                 case $arg in
 122                         --with-[$1]=*)
 123                                 arg=--with-[$1]=[$2]
 124                                 ;;
 125                         *\'*)
 126                                 arg=$(printf %s\n ["$arg"] | \
 127                                       sed "s/'/'\\\\\\\\''/g")
 128                                 ;;
 129                 esac
 130                 dnl AS_VAR_APPEND([new_configure_args], [" '$arg'"])
 131                 new_configure_args="$new_configure_args \"$arg\""
 132         done
 133         ac_configure_args=$new_configure_args
 134 ])
 135
 136 # this is the work-horse of the next function
 137 AC_DEFUN([__LB_ARG_CANON_PATH], [
 138         [$3]=$(readlink -f $with_$2)
 139         LB_ARG_REPLACE_PATH([$1], $[$3])
 140 ])
 141
 142 # a front-end for the above function that transforms - and . in the
 143 # PACKAGE portion of --with-PACKAGE into _ suitable for variable names
 144 AC_DEFUN([LB_ARG_CANON_PATH], [
 145         __LB_ARG_CANON_PATH([$1], m4_translit([$1], [-.], [__]), [$2])
 146 ])
 147
 148 #
 149 #
 150 # LB_LINUX_PATH
 151 #
 152 # Find paths for linux, handling kernel-source rpms
 153 #
 154 AC_DEFUN([LB_LINUX_PATH],
 155 [# prep some default values
 156 for DEFAULT_LINUX in /lib/modules/$(uname -r)/{source,build} /usr/src/linux; do
 157         if readlink -q -e $DEFAULT_LINUX; then
 158                 break
 159         fi
 160 done
 161 if test "$DEFAULT_LINUX" = "/lib/modules/$(uname -r)/source"; then
 162         PATHS="/lib/modules/$(uname -r)/build"
 163 fi
 164 PATHS+=" $DEFAULT_LINUX"
 165 for DEFAULT_LINUX_OBJ in $PATHS; do
 166         if readlink -q -e $DEFAULT_LINUX_OBJ; then
 167                 break
 168         fi
 169 done
 170 AC_MSG_CHECKING([for Linux sources])
 171 AC_ARG_WITH([linux],
 172         AC_HELP_STRING([--with-linux=path],
 173                        [set path to Linux source (default=/lib/modules/$(uname -r)/{source,build},/usr/src/linux)]),
 174         [LB_ARG_CANON_PATH([linux], [LINUX])
 175         DEFAULT_LINUX_OBJ=$LINUX],
 176         [LINUX=$DEFAULT_LINUX])
 177 AC_MSG_RESULT([$LINUX])
 178 AC_SUBST(LINUX)
 179
 180 # -------- check for linux --------
 181 LB_CHECK_FILE([$LINUX],[],
 182         [AC_MSG_ERROR([Kernel source $LINUX could not be found.])])
 183
 184 # -------- linux objects (for 2.6) --
 185 AC_MSG_CHECKING([for Linux objects dir])
 186 AC_ARG_WITH([linux-obj],
 187         AC_HELP_STRING([--with-linux-obj=path],
 188                         [set path to Linux objects dir (default=/lib/modules/$(uname -r)/build,/usr/src/linux)]),
 189         [LB_ARG_CANON_PATH([linux-obj], [LINUX_OBJ])],
 190         [LINUX_OBJ=$DEFAULT_LINUX_OBJ])
 191
 192 AC_MSG_RESULT([$LINUX_OBJ])
 193 AC_SUBST(LINUX_OBJ)
 194
 195 # -------- check for .config --------
 196 AC_ARG_WITH([linux-config],
 197         [AC_HELP_STRING([--with-linux-config=path],
 198                         [set path to Linux .conf (default=$LINUX_OBJ/.config)])],
 199         [LB_ARG_CANON_PATH([linux-config], [LINUX_CONFIG])],
 200         [LINUX_CONFIG=$LINUX_OBJ/.config])
 201 AC_SUBST(LINUX_CONFIG)
 202
 203 LB_CHECK_FILE([/boot/kernel.h],
 204         [KERNEL_SOURCE_HEADER='/boot/kernel.h'],
 205         [LB_CHECK_FILE([/var/adm/running-kernel.h],
 206                 [KERNEL_SOURCE_HEADER='/var/adm/running-kernel.h'])])
 207
 208 AC_ARG_WITH([kernel-source-header],
 209         AC_HELP_STRING([--with-kernel-source-header=path],
 210                         [Use a different kernel version header.  Consult build/README.kernel-source for details.]),
 211         [LB_ARG_CANON_PATH([kernel-source-header], [KERNEL_SOURCE_HEADER])])
 212
 213 # ------------ .config exists ----------------
 214 LB_CHECK_FILE([$LINUX_CONFIG],[],
 215         [AC_MSG_ERROR([Kernel config could not be found.  If you are building from a kernel-source rpm consult build/README.kernel-source])])
 216
 217 # ----------- make dep run? ------------------
 218 # at 2.6.19 # $LINUX/include/linux/config.h is removed
 219 # and at more old has only one line
 220 # include <autoconf.h>
 221 LB_CHECK_FILE([$LINUX_OBJ/include/generated/autoconf.h],[AUTOCONF_HDIR=generated],
 222         [LB_CHECK_FILE([$LINUX_OBJ/include/linux/autoconf.h],[AUTOCONF_HDIR=linux],
 223         [AC_MSG_ERROR([Run make config in $LINUX.])])])
 224         AC_SUBST(AUTOCONF_HDIR)
 225 LB_CHECK_FILE([$LINUX_OBJ/include/linux/version.h],[],
 226         [AC_MSG_ERROR([Run make config in $LINUX.])])
 227
 228 # ----------- kconfig.h exists ---------------
 229 # kernel 3.1, $LINUX/include/linux/kconfig.h is added
 230 # see kernel commit 2a11c8ea20bf850b3a2c60db8c2e7497d28aba99
 231 LB_CHECK_FILE([$LINUX_OBJ/include/linux/kconfig.h],
 232               [CONFIG_INCLUDE=include/linux/kconfig.h],
 233               [CONFIG_INCLUDE=include/$AUTOCONF_HDIR/autoconf.h])
 234         AC_SUBST(CONFIG_INCLUDE)
 235
 236 # ------------ rhconfig.h includes runtime-generated bits --
 237 # red hat kernel-source checks
 238
 239 # we know this exists after the check above.  if the user
 240 # tarred up the tree and ran make dep etc. in it, then
 241 # version.h gets overwritten with a standard linux one.
 242
 243 if grep rhconfig $LINUX_OBJ/include/linux/version.h >/dev/null ; then
 244         # This is a clean kernel-source tree, we need to
 245         # enable extensive workarounds to get this to build
 246         # modules
 247         LB_CHECK_FILE([$KERNEL_SOURCE_HEADER],
 248                 [if test $KERNEL_SOURCE_HEADER = '/boot/kernel.h' ; then
 249                         AC_MSG_WARN([Using /boot/kernel.h from RUNNING kernel.])
 250                         AC_MSG_WARN([If this is not what you want, use --with-kernel-source-header.])
 251                         AC_MSG_WARN([Consult build/README.kernel-source for details.])
 252                 fi],
 253                 [AC_MSG_ERROR([$KERNEL_SOURCE_HEADER not found.  Consult build/README.kernel-source for details.])])
 254         EXTRA_KCFLAGS="-include $KERNEL_SOURCE_HEADER $EXTRA_KCFLAGS"
 255 fi
 256
 257 # this is needed before we can build modules
 258 LB_LINUX_VERSION
 259
 260 # --- check that we can build modules at all
 261 AC_MSG_CHECKING([that modules can be built at all])
 262 LB_LINUX_TRY_COMPILE([],[],[
 263         AC_MSG_RESULT([yes])
 264 ],[
 265         AC_MSG_RESULT([no])
 266         AC_MSG_WARN([Consult config.log for details.])
 267         AC_MSG_WARN([If you are trying to build with a kernel-source rpm, consult build/README.kernel-source])
 268         AC_MSG_ERROR([Kernel modules cannot be built.])
 269 ])
 270
 271 LB_LINUX_RELEASE
 272 ]) # end of LB_LINUX_PATH
 273
 274 # LB_LINUX_SYMVERFILE
 275 # SLES 9 uses a different name for this file - unsure about vanilla kernels
 276 # around this version, but it matters for servers only.
 277 AC_DEFUN([LB_LINUX_SYMVERFILE],
 278         [AC_MSG_CHECKING([name of module symbol version file])
 279         if grep -q Modules.symvers $LINUX/scripts/Makefile.modpost ; then
 280                 SYMVERFILE=Modules.symvers
 281         else
 282                 SYMVERFILE=Module.symvers
 283         fi
 284         AC_MSG_RESULT($SYMVERFILE)
 285         AC_SUBST(SYMVERFILE)
 286 ])
 287
 288 #
 289 #
 290 # LB_LINUX_MODPOST
 291 #
 292 # Find modpost and check it
 293 #
 294 AC_DEFUN([LB_LINUX_MODPOST],
 295 [
 296 # Find the modpost utility
 297 LB_CHECK_FILE([$LINUX_OBJ/scripts/mod/modpost],
 298         [MODPOST=$LINUX_OBJ/scripts/mod/modpost],
 299         [LB_CHECK_FILE([$LINUX_OBJ/scripts/modpost],
 300                 [MODPOST=$LINUX_OBJ/scripts/modpost],
 301                 AC_MSG_ERROR([modpost not found.])
 302         )]
 303 )
 304 AC_SUBST(MODPOST)
 305
 306 # Ensure it can run
 307 AC_MSG_CHECKING([if modpost can be run])
 308 if $MODPOST ; then
 309         AC_MSG_RESULT([yes])
 310 else
 311         AC_MSG_ERROR([modpost can not be run.])
 312 fi
 313
 314 # Check if modpost supports (and therefore requires) -m
 315 AC_MSG_CHECKING([if modpost supports -m])
 316 if $MODPOST -m 2>/dev/null ; then
 317         AC_MSG_RESULT([yes])
 318         MODPOST_ARGS=-m
 319 else
 320         AC_MSG_RESULT([no])
 321         MODPOST_ARGS=""
 322 fi
 323 AC_SUBST(MODPOST_ARGS)
 324 ])
 325
 326 # these are like AC_TRY_COMPILE, but try to build modules against the
 327 # kernel, inside the build directory
 328
 329 # LB_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 330 # --------------------------------------
 331 m4_define([LB_LANG_PROGRAM],
 332 [
 333 #include <linux/kernel.h>
 334 $1
 335 int
 336 main (void)
 337 {
 338 dnl Do *not* indent the following line: there may be CPP directives.
 339 dnl Don't move the `;' right after for the same reason.
 340 $2
 341   ;
 342   return 0;
 343 }])
 344
 345 #
 346 # LB_LINUX_COMPILE_IFELSE
 347 #
 348 # like AC_COMPILE_IFELSE
 349 #
 350 AC_DEFUN([LB_LINUX_COMPILE_IFELSE],
 351 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
 352 rm -f build/conftest.o build/conftest.mod.c build/conftest.ko
 353 AS_IF([AC_TRY_COMMAND(cp conftest.c build && make -d [$2] ${LD:+"LD=$LD"} CC="$CC" -f $PWD/build/Makefile LUSTRE_LINUX_CONFIG=$LINUX_CONFIG LINUXINCLUDE="$EXTRA_LNET_INCLUDE -I$LINUX/arch/`echo $target_cpu|sed -e 's/powerpc64/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include -I$LINUX/arch/`echo $target_cpu|sed -e 's/ppc.*/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include/generated -I$LINUX_OBJ/include -I$LINUX/include -I$LINUX_OBJ/include2 -include $CONFIG_INCLUDE" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $MODULE_TARGET=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 354         [$4],
 355         [_AC_MSG_LOG_CONFTEST
 356 m4_ifvaln([$5],[$5])dnl])
 357 rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
 358 ])
 359
 360 #
 361 # LB_LINUX_ARCH
 362 #
 363 # Determine the kernel's idea of the current architecture
 364 #
 365 AC_DEFUN([LB_LINUX_ARCH],
 366          [AC_MSG_CHECKING([Linux kernel architecture])
 367           AS_IF([rm -f $PWD/build/arch
 368                  make -s --no-print-directory echoarch -f $PWD/build/Makefile \
 369                      LUSTRE_LINUX_CONFIG=$LINUX_CONFIG -C $LINUX \
 370                      ARCHFILE=$PWD/build/arch && LINUX_ARCH=`cat $PWD/build/arch`],
 371                 [AC_MSG_RESULT([$LINUX_ARCH])],
 372                 [AC_MSG_ERROR([Could not determine the kernel architecture.])])
 373           rm -f build/arch])
 374
 375 #
 376 # LB_LINUX_TRY_COMPILE
 377 #
 378 # like AC_TRY_COMPILE
 379 #
 380 AC_DEFUN([LB_LINUX_TRY_COMPILE],
 381 [LB_LINUX_COMPILE_IFELSE(
 382         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 383         [modules],
 384         [test -s build/conftest.o],
 385         [$3], [$4])])
 386
 387 #
 388 # LB_LINUX_CONFIG
 389 #
 390 # check if a given config option is defined
 391 #
 392 AC_DEFUN([LB_LINUX_CONFIG],[
 393         AC_MSG_CHECKING([if Linux was built with CONFIG_$1])
 394         LB_LINUX_TRY_COMPILE([
 395                 #include <$AUTOCONF_HDIR/autoconf.h>
 396         ],[
 397                 #ifndef CONFIG_$1
 398                 #error CONFIG_$1 not #defined
 399                 #endif
 400         ],[
 401                 AC_MSG_RESULT([yes])
 402                 $2
 403         ],[
 404                 AC_MSG_RESULT([no])
 405                 $3
 406         ])
 407 ])
 408
 409 #
 410 # LB_LINUX_CONFIG_IM
 411 #
 412 # check if a given config option is builtin or as module
 413 #
 414 AC_DEFUN([LB_LINUX_CONFIG_IM],[
 415         AC_MSG_CHECKING([if Linux was built with CONFIG_$1 in or as module])
 416         LB_LINUX_TRY_COMPILE([
 417                 #include <$AUTOCONF_HDIR/autoconf.h>
 418         ],[
 419                 #if !(defined(CONFIG_$1) || defined(CONFIG_$1_MODULE))
 420                 #error CONFIG_$1 and CONFIG_$1_MODULE not #defined
 421                 #endif
 422         ],[
 423                 AC_MSG_RESULT([yes])
 424                 $2
 425         ],[
 426                 AC_MSG_RESULT([no])
 427                 $3
 428         ])
 429 ])
 430
 431 #
 432 # LB_LINUX_TRY_MAKE
 433 #
 434 # like LB_LINUX_TRY_COMPILE, but with different arguments
 435 #
 436 AC_DEFUN([LB_LINUX_TRY_MAKE],
 437         [LB_LINUX_COMPILE_IFELSE(
 438                 [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 439                 [$3], [$4], [$5], [$6]
 440         )]
 441 )
 442
 443 #
 444 # LB_CONFIG_OFED_BACKPORTS
 445 #
 446 # include any OFED backport headers in all compile commands
 447 # NOTE: this does only include the backport paths, not the OFED headers
 448 #       adding the OFED headers is done in the lnet portion
 449 AC_DEFUN([LB_CONFIG_OFED_BACKPORTS],
 450 [AC_MSG_CHECKING([whether to use any OFED backport headers])
 451 # set default
 452 AC_ARG_WITH([o2ib],
 453         AC_HELP_STRING([--with-o2ib=path],
 454                        [build o2iblnd against path]),
 455         [
 456                 case $with_o2ib in
 457                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 458                         ENABLEO2IB=2
 459                         ;;
 460                 no)     ENABLEO2IB=0
 461                         ;;
 462                 *)      O2IBPATHS=$with_o2ib
 463                         ENABLEO2IB=3
 464                         ;;
 465                 esac
 466         ],[
 467                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 468                 ENABLEO2IB=1
 469         ])
 470 if test $ENABLEO2IB -eq 0; then
 471         AC_MSG_RESULT([no])
 472 else
 473         o2ib_found=false
 474         for O2IBPATH in $O2IBPATHS; do
 475                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 476                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 477                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 478                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 479                         o2ib_found=true
 480                         break
 481                 fi
 482         done
 483         if ! $o2ib_found; then
 484                 AC_MSG_RESULT([no])
 485                 case $ENABLEO2IB in
 486                         1) ;;
 487                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 488                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 489                         *) AC_MSG_ERROR([internal error]);;
 490                 esac
 491         else
 492                 if test -f $O2IBPATH/config.mk; then
 493                         . $O2IBPATH/config.mk
 494                 elif test -f $O2IBPATH/ofed_patch.mk; then
 495                         . $O2IBPATH/ofed_patch.mk
 496                 fi
 497                 if test -n "$BACKPORT_INCLUDES"; then
 498                         OFED_BACKPORT_PATH="$O2IBPATH/${BACKPORT_INCLUDES/*\/kernel_addons/kernel_addons}/"
 499                         EXTRA_LNET_INCLUDE="-I$OFED_BACKPORT_PATH $EXTRA_LNET_INCLUDE"
 500                         AC_MSG_RESULT([yes])
 501                 else
 502                         AC_MSG_RESULT([no])
 503                 fi
 504         fi
 505 fi
 506 ])
 507
 508 # LC_MODULE_LOADING
 509 # after 2.6.28 CONFIG_KMOD is removed, and only CONFIG_MODULES remains
 510 # so we test if request_module is implemented or not
 511 AC_DEFUN([LC_MODULE_LOADING],
 512 [AC_MSG_CHECKING([if kernel module loading is possible])
 513 LB_LINUX_TRY_MAKE([
 514         #include <linux/kmod.h>
 515 ],[
 516         int myretval=ENOSYS ;
 517         return myretval;
 518 ],[
 519         $makerule LUSTRE_KERNEL_TEST=conftest.i
 520 ],[dnl
 521         grep request_module build/conftest.i |dnl
 522                 grep -v `grep "int myretval=" build/conftest.i |dnl
 523                         cut -d= -f2 | cut -d" "  -f1`dnl
 524                 >/dev/null dnl
 525 ],[
 526         AC_MSG_RESULT(yes)
 527         AC_DEFINE(HAVE_MODULE_LOADING_SUPPORT, 1,
 528                   [kernel module loading is possible])
 529 ],[
 530         AC_MSG_RESULT(no)
 531         AC_MSG_WARN([])
 532         AC_MSG_WARN([Kernel module loading support is highly recommended.])
 533         AC_MSG_WARN([])
 534 ])
 535 ])
 536
 537 #
 538 # LB_PROG_LINUX
 539 #
 540 # linux tests
 541 #
 542 AC_DEFUN([LB_PROG_LINUX],
 543 [LB_LINUX_PATH
 544 LB_LINUX_ARCH
 545 LB_LINUX_SYMVERFILE
 546
 547
 548 LB_LINUX_CONFIG([MODULES],[],[
 549         AC_MSG_ERROR([module support is required to build Lustre kernel modules.])
 550 ])
 551
 552 LB_LINUX_CONFIG([MODVERSIONS])
 553
 554 LB_LINUX_CONFIG([KALLSYMS],[],[
 555         AC_MSG_ERROR([Lustre requires that CONFIG_KALLSYMS is enabled in your kernel.])
 556 ])
 557
 558 # 2.6.28
 559 LC_MODULE_LOADING
 560
 561 # it's ugly to be doing anything with OFED outside of the lnet module, but
 562 # this has to be done here so that the backports path is set before all of
 563 # the LN_PROG_LINUX checks are done
 564 LB_CONFIG_OFED_BACKPORTS
 565 ])
 566
 567 #
 568 # LB_CHECK_SYMBOL_EXPORT
 569 # check symbol exported or not
 570 # $1 - symbol
 571 # $2 - file(s) for find.
 572 # $3 - do 'yes'
 573 # $4 - do 'no'
 574 #
 575 # 2.6 based kernels - put modversion info into $LINUX/Module.modvers
 576 # or check
 577 AC_DEFUN([LB_CHECK_SYMBOL_EXPORT],
 578 [AC_MSG_CHECKING([if Linux was built with symbol $1 exported])
 579 grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX/$SYMVERFILE 2>/dev/null
 580 rc=$?
 581 if test $rc -ne 0; then
 582         export=0
 583         for file in $2; do
 584                 grep -q -E "EXPORT_SYMBOL.*\($1\)" "$LINUX/$file" 2>/dev/null
 585                 rc=$?
 586                 if test $rc -eq 0; then
 587                         export=1
 588                         break;
 589                 fi
 590         done
 591         if test $export -eq 0; then
 592                 AC_MSG_RESULT([no])
 593                 $4
 594         else
 595                 AC_MSG_RESULT([yes])
 596                 $3
 597         fi
 598 else
 599         AC_MSG_RESULT([yes])
 600         $3
 601 fi
 602 ])
 603
 604 #
 605 # Like AC_CHECK_HEADER but checks for a kernel-space header
 606 #
 607 m4_define([LB_CHECK_LINUX_HEADER],
 608 [AS_VAR_PUSHDEF([ac_Header], [ac_cv_header_$1])dnl
 609 AC_CACHE_CHECK([for $1], ac_Header,
 610                [LB_LINUX_COMPILE_IFELSE([LB_LANG_PROGRAM([@%:@include <$1>])],
 611                                   [modules],
 612                                   [test -s build/conftest.o],
 613                                   [AS_VAR_SET(ac_Header, [yes])],
 614                                   [AS_VAR_SET(ac_Header, [no])])])
 615 AS_IF([test AS_VAR_GET(ac_Header) = yes], [$2], [$3])[]dnl
 616 AS_VAR_POPDEF([ac_Header])dnl
 617 ])
 618
 619 #
 620 # LB_USES_DPKG
 621 #
 622 # Determine if the target is a dpkg system or rpm
 623 #
 624 AC_DEFUN([LB_USES_DPKG],
 625 [
 626 AC_MSG_CHECKING([if this distro uses dpkg])
 627 case `lsb_release -i -s 2>/dev/null` in
 628         Ubuntu | Debian)
 629                 AC_MSG_RESULT([yes])
 630                 uses_dpkg=yes
 631                 ;;
 632         *)
 633                 AC_MSG_RESULT([no])
 634                 uses_dpkg=no
 635                 ;;
 636 esac
 637 ])