build/autoconf/lustre-build-linux.m4

   1 #
   2 # LB_LINUX_VERSION
   3 #
   4 # Set things accordingly for a 2.5 kernel
   5 #
   6 AC_DEFUN([LB_LINUX_VERSION],
   7 [LB_CHECK_FILE([$LINUX/include/linux/namei.h],
   8         [
   9                 linux25="yes"
  10                 KMODEXT=".ko"
  11         ],[
  12                 KMODEXT=".o"
  13                 linux25="no"
  14         ])
  15 AC_MSG_CHECKING([if you are using Linux 2.6])
  16 AC_MSG_RESULT([$linux25])
  17
  18 MODULE_TARGET="SUBDIRS"
  19 if test $linux25 = "yes" ; then
  20         makerule="$PWD/build"
  21         AC_MSG_CHECKING([for external module build support])
  22         rm -f build/conftest.i
  23         LB_LINUX_TRY_MAKE([],[],
  24                 [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  25                 [test -s build/conftest.i],
  26                 [
  27                         AC_MSG_RESULT([no])
  28                 ],[
  29                         makerule="_module_$makerule"
  30                         MODULE_TARGET="M"
  31                         LB_LINUX_TRY_MAKE([],[],
  32                                 [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  33                                 [test -s build/conftest.i],
  34                                 [
  35                                         AC_MSG_RESULT([yes])
  36                                 ],[
  37                                         AC_MSG_ERROR([unknown; check config.log for details])
  38                                 ])
  39                 ])
  40 else
  41         makerule="_dir_$PWD/build"
  42 fi
  43
  44 AC_SUBST(MODULE_TARGET)
  45 AC_SUBST(linux25)
  46 AC_SUBST(KMODEXT)
  47 ])
  48
  49 #
  50 # LB_LINUX_RELEASE
  51 #
  52 # get the release version of linux
  53 #
  54 AC_DEFUN([LB_LINUX_RELEASE],
  55 [LINUXRELEASE=
  56 rm -f build/conftest.i
  57 AC_MSG_CHECKING([for Linux release])
  58 if test -s $LINUX_OBJ/include/linux/utsrelease.h ; then
  59         LINUXRELEASEHEADER=utsrelease.h
  60 else
  61         LINUXRELEASEHEADER=version.h
  62 fi
  63 LB_LINUX_TRY_MAKE([
  64         #include <linux/$LINUXRELEASEHEADER>
  65 ],[
  66         char *LINUXRELEASE;
  67         LINUXRELEASE=UTS_RELEASE;
  68 ],[
  69         $makerule LUSTRE_KERNEL_TEST=conftest.i
  70 ],[
  71         test -s build/conftest.i
  72 ],[
  73         # LINUXRELEASE="UTS_RELEASE"
  74         eval $(grep "LINUXRELEASE=" build/conftest.i)
  75 ],[
  76         AC_MSG_RESULT([unknown])
  77         AC_MSG_ERROR([Could not preprocess test program.  Consult config.log for details.])
  78 ])
  79 rm -f build/conftest.i
  80 if test x$LINUXRELEASE = x ; then
  81         AC_MSG_RESULT([unknown])
  82         AC_MSG_ERROR([Could not determine Linux release version from linux/version.h.])
  83 fi
  84 AC_MSG_RESULT([$LINUXRELEASE])
  85 AC_SUBST(LINUXRELEASE)
  86
  87 moduledir='/lib/modules/'$LINUXRELEASE/kernel
  88 AC_SUBST(moduledir)
  89
  90 modulefsdir='$(moduledir)/fs/$(PACKAGE)'
  91 AC_SUBST(modulefsdir)
  92
  93 modulenetdir='$(moduledir)/net/$(PACKAGE)'
  94 AC_SUBST(modulenetdir)
  95
  96 # ------------ RELEASE --------------------------------
  97 AC_MSG_CHECKING([for Lustre release])
  98 RELEASE="`echo ${LINUXRELEASE} | tr '-' '_'`_`date +%Y%m%d%H%M`"
  99 AC_MSG_RESULT($RELEASE)
 100 AC_SUBST(RELEASE)
 101 ])
 102
 103 #
 104 #
 105 # LB_LINUX_PATH
 106 #
 107 # Find paths for linux, handling kernel-source rpms
 108 #
 109 AC_DEFUN([LB_LINUX_PATH],
 110 [AC_MSG_CHECKING([for Linux sources])
 111 AC_ARG_WITH([linux],
 112         AC_HELP_STRING([--with-linux=path],
 113                        [set path to Linux source (default=/usr/src/linux)]),
 114         [LINUX=$with_linux],
 115         [LINUX=/usr/src/linux])
 116 AC_MSG_RESULT([$LINUX])
 117 AC_SUBST(LINUX)
 118
 119 # -------- check for linux --------
 120 LB_CHECK_FILE([$LINUX],[],
 121         [AC_MSG_ERROR([Kernel source $LINUX could not be found.])])
 122
 123 # -------- linux objects (for 2.6) --
 124 AC_MSG_CHECKING([for Linux objects dir])
 125 AC_ARG_WITH([linux-obj],
 126         AC_HELP_STRING([--with-linux-obj=path],
 127                         [set path to Linux objects dir (default=$LINUX)]),
 128         [LINUX_OBJ=$with_linux_obj],
 129         [LINUX_OBJ=$LINUX])
 130 AC_MSG_RESULT([$LINUX_OBJ])
 131 AC_SUBST(LINUX_OBJ)
 132
 133 # -------- check for .config --------
 134 AC_ARG_WITH([linux-config],
 135         [AC_HELP_STRING([--with-linux-config=path],
 136                         [set path to Linux .conf (default=$LINUX_OBJ/.config)])],
 137         [LINUX_CONFIG=$with_linux_config],
 138         [LINUX_CONFIG=$LINUX_OBJ/.config])
 139 AC_SUBST(LINUX_CONFIG)
 140
 141 LB_CHECK_FILE([/boot/kernel.h],
 142         [KERNEL_SOURCE_HEADER='/boot/kernel.h'],
 143         [LB_CHECK_FILE([/var/adm/running-kernel.h],
 144                 [KERNEL_SOURCE_HEADER='/var/adm/running-kernel.h'])])
 145
 146 AC_ARG_WITH([kernel-source-header],
 147         AC_HELP_STRING([--with-kernel-source-header=path],
 148                         [Use a different kernel version header.  Consult build/README.kernel-source for details.]),
 149         [KERNEL_SOURCE_HEADER=$with_kernel_source_header])
 150
 151 # ------------ .config exists ----------------
 152 LB_CHECK_FILE([$LINUX_CONFIG],[],
 153         [AC_MSG_ERROR([Kernel config could not be found.  If you are building from a kernel-source rpm consult build/README.kernel-source])])
 154
 155 # ----------- make dep run? ------------------
 156 # at 2.6.19 # $LINUX/include/linux/config.h is removed
 157 # and at more old has only one line
 158 # include <autoconf.h>
 159 LB_CHECK_FILES([$LINUX_OBJ/include/linux/autoconf.h
 160                 $LINUX_OBJ/include/linux/version.h
 161                 ],[],
 162         [AC_MSG_ERROR([Run make config in $LINUX.])])
 163 #
 164 LB_CHECK_FILE([$LINUX_OBJ/include/linux/config.h],
 165         [ AC_DEFINE(HAVE_KERNEL_CONFIG_H, 1,
 166                 [kernel modules need to include config.h])
 167         ]
 168 )
 169
 170 # ------------ rhconfig.h includes runtime-generated bits --
 171 # red hat kernel-source checks
 172
 173 # we know this exists after the check above.  if the user
 174 # tarred up the tree and ran make dep etc. in it, then
 175 # version.h gets overwritten with a standard linux one.
 176
 177 if grep rhconfig $LINUX_OBJ/include/linux/version.h >/dev/null ; then
 178         # This is a clean kernel-source tree, we need to
 179         # enable extensive workarounds to get this to build
 180         # modules
 181         LB_CHECK_FILE([$KERNEL_SOURCE_HEADER],
 182                 [if test $KERNEL_SOURCE_HEADER = '/boot/kernel.h' ; then
 183                         AC_MSG_WARN([Using /boot/kernel.h from RUNNING kernel.])
 184                         AC_MSG_WARN([If this is not what you want, use --with-kernel-source-header.])
 185                         AC_MSG_WARN([Consult build/README.kernel-source for details.])
 186                 fi],
 187                 [AC_MSG_ERROR([$KERNEL_SOURCE_HEADER not found.  Consult build/README.kernel-source for details.])])
 188         EXTRA_KCFLAGS="-include $KERNEL_SOURCE_HEADER $EXTRA_KCFLAGS"
 189 fi
 190
 191 # Find the modpost utility
 192 AC_CHECK_FILE([$LINUX_OBJ/scripts/mod/modpost],
 193         [MODPOST=$LINUX_OBJ/scripts/mod/modpost],
 194         [AC_CHECK_FILE([$LINUX_OBJ/scripts/modpost],
 195                 [MODPOST=$LINUX_OBJ/scripts/modpost],
 196                 AC_MSG_ERROR([modpost not found.])
 197         )]
 198 )
 199 AC_SUBST(MODPOST)
 200
 201 # this is needed before we can build modules
 202 LB_LINUX_UML
 203 LB_LINUX_VERSION
 204
 205 # --- check that we can build modules at all
 206 AC_MSG_CHECKING([that modules can be built at all])
 207 LB_LINUX_TRY_COMPILE([],[],[
 208         AC_MSG_RESULT([yes])
 209 ],[
 210         AC_MSG_RESULT([no])
 211         AC_MSG_WARN([Consult config.log for details.])
 212         AC_MSG_WARN([If you are trying to build with a kernel-source rpm, consult build/README.kernel-source])
 213         AC_MSG_ERROR([Kernel modules cannot be built.])
 214 ])
 215
 216 LB_LINUX_RELEASE
 217 ]) # end of LB_LINUX_PATH
 218
 219 #
 220 # LB_LINUX_UML
 221 #
 222 # check for a uml kernel
 223 #
 224 AC_DEFUN([LB_LINUX_UML],
 225 [ARCH_UM=
 226 UML_CFLAGS=
 227
 228 AC_MSG_CHECKING([if you are running user mode linux for $target_cpu])
 229 if test -e $LINUX/include/asm-um ; then
 230         if test  X`ls -id $LINUX/include/asm/ 2>/dev/null | awk '{print [$]1}'` = X`ls -id $LINUX/include/asm-um 2>/dev/null | awk '{print [$]1}'` ; then
 231                 ARCH_UM='ARCH=um'
 232                 # see notes in Rules.in
 233                 UML_CFLAGS='-O0'
 234                 AC_MSG_RESULT(yes)
 235         else
 236                 AC_MSG_RESULT([no (asm doesn't point at asm-um)])
 237         fi
 238 else
 239         AC_MSG_RESULT([no (asm-um missing)])
 240 fi
 241 AC_SUBST(ARCH_UM)
 242 AC_SUBST(UML_CFLAGS)
 243 ])
 244
 245 # these are like AC_TRY_COMPILE, but try to build modules against the
 246 # kernel, inside the build directory
 247
 248 #
 249 # LB_LINUX_CONFTEST
 250 #
 251 # create a conftest.c file
 252 #
 253 AC_DEFUN([LB_LINUX_CONFTEST],
 254 [cat >conftest.c <<_ACEOF
 255 $1
 256 _ACEOF
 257 ])
 258
 259
 260 # LB_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 261 # --------------------------------------
 262 m4_define([LB_LANG_PROGRAM],
 263 [$1
 264 int
 265 main (void)
 266 {
 267 dnl Do *not* indent the following line: there may be CPP directives.
 268 dnl Don't move the `;' right after for the same reason.
 269 $2
 270   ;
 271   return 0;
 272 }])
 273
 274 #
 275 # LB_LINUX_COMPILE_IFELSE
 276 #
 277 # like AC_COMPILE_IFELSE
 278 #
 279 AC_DEFUN([LB_LINUX_COMPILE_IFELSE],
 280 [m4_ifvaln([$1], [LB_LINUX_CONFTEST([$1])])dnl
 281 rm -f build/conftest.o build/conftest.mod.c build/conftest.ko
 282 AS_IF([AC_TRY_COMMAND(cp conftest.c build && make [$2] CC="$CC" -f $PWD/build/Makefile LUSTRE_LINUX_CONFIG=$LINUX_CONFIG LINUXINCLUDE="$EXTRA_LNET_INCLUDE -Iinclude -include include/linux/autoconf.h" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM $MODULE_TARGET=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 283         [$4],
 284         [_AC_MSG_LOG_CONFTEST
 285 m4_ifvaln([$5],[$5])dnl])dnl
 286 rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
 287 ])
 288
 289 #
 290 # LB_LINUX_TRY_COMPILE
 291 #
 292 # like AC_TRY_COMPILE
 293 #
 294 AC_DEFUN([LB_LINUX_TRY_COMPILE],
 295 [LB_LINUX_COMPILE_IFELSE(
 296         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 297         [modules],
 298         [test -s build/conftest.o],
 299         [$3], [$4])])
 300
 301 #
 302 # LB_LINUX_CONFIG
 303 #
 304 # check if a given config option is defined
 305 #
 306 AC_DEFUN([LB_LINUX_CONFIG],
 307 [AC_MSG_CHECKING([if Linux was built with CONFIG_$1])
 308 LB_LINUX_TRY_COMPILE([
 309 #ifdef HAVE_KERNEL_CONFIG_H
 310 #include <linux/config.h>
 311 #endif
 312 ],[
 313 #ifndef CONFIG_$1
 314 #error CONFIG_$1 not #defined
 315 #endif
 316 ],[
 317 AC_MSG_RESULT([yes])
 318 $2
 319 ],[
 320 AC_MSG_RESULT([no])
 321 $3
 322 ])
 323 ])
 324
 325 #
 326 # LB_LINUX_CONFIG_IM
 327 #
 328 # check if a given config option is builtin or as module
 329 #
 330 AC_DEFUN([LB_LINUX_CONFIG_IM],
 331 [AC_MSG_CHECKING([if Linux was built with CONFIG_$1 in or as module])
 332 LB_LINUX_TRY_COMPILE([#include <linux/config.h>],[
 333 #if !(defined(CONFIG_$1) || defined(CONFIG_$1_MODULE))
 334 #error CONFIG_$1 and CONFIG_$1_MODULE not #defined
 335 #endif
 336 ],[
 337 AC_MSG_RESULT([yes])
 338 $2
 339 ],[
 340 AC_MSG_RESULT([no])
 341 $3
 342 ])
 343 ])
 344
 345 #
 346 # LB_LINUX_TRY_MAKE
 347 #
 348 # like LB_LINUX_TRY_COMPILE, but with different arguments
 349 #
 350 AC_DEFUN([LB_LINUX_TRY_MAKE],
 351 [LB_LINUX_COMPILE_IFELSE([AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])], [$3], [$4], [$5], [$6])])
 352
 353 #
 354 # LB_LINUX_CONFIG_BIG_STACK
 355 #
 356 # check for big stack patch
 357 #
 358 AC_DEFUN([LB_LINUX_CONFIG_BIG_STACK],
 359 [if test "x$ARCH_UM" = "x" -a "x$linux25" = "xno" ; then
 360         case $target_cpu in
 361                 i?86 | x86_64)
 362                         LB_LINUX_CONFIG([STACK_SIZE_16KB],[],[
 363                                 LB_LINUX_CONFIG([STACK_SIZE_32KB],[],[
 364                                         LB_LINUX_CONFIG([STACK_SIZE_64KB],[],[
 365                                                 AC_MSG_ERROR([Lustre requires that Linux is configured with at least a 16KB stack.])
 366                                         ])
 367                                 ])
 368                         ])
 369                         ;;
 370         esac
 371 fi
 372 ])
 373
 374 #
 375 # LB_PROG_LINUX
 376 #
 377 # linux tests
 378 #
 379 AC_DEFUN([LB_PROG_LINUX],
 380 [LB_LINUX_PATH
 381
 382 LB_LINUX_CONFIG([MODULES],[],[
 383         AC_MSG_ERROR([module support is required to build Lustre kernel modules.])
 384 ])
 385
 386 LB_LINUX_CONFIG([MODVERSIONS])
 387
 388 LB_LINUX_CONFIG([PREEMPT],[
 389         AC_MSG_ERROR([Lustre does not support kernels with preempt enabled.])
 390 ])
 391
 392 LB_LINUX_CONFIG([KALLSYMS],[],[
 393 if test "x$ARCH_UM" = "x" ; then
 394         AC_MSG_ERROR([Lustre requires that CONFIG_KALLSYMS is enabled in your kernel.])
 395 fi
 396 ])
 397
 398 LB_LINUX_CONFIG([KMOD],[],[
 399         AC_MSG_WARN([])
 400         AC_MSG_WARN([Kernel module loading support is highly recommended.])
 401         AC_MSG_WARN([])
 402 ])
 403
 404 #LB_LINUX_CONFIG_BIG_STACK
 405
 406 ])
 407
 408 #
 409 # LB_LINUX_CONDITIONALS
 410 #
 411 # AM_CONDITIONALS for linux
 412 #
 413 AC_DEFUN([LB_LINUX_CONDITIONALS],
 414 [AM_CONDITIONAL(LINUX25, test x$linux25 = xyes)
 415 ])
 416
 417
 418 #
 419 # LB_CHECK_SYMBOL_EXPORT
 420 # check symbol exported or not
 421 # $1 - symbol
 422 # $2 - file(s) for find.
 423 # $3 - do 'yes'
 424 # $4 - do 'no'
 425 #
 426 # 2.6 based kernels - put modversion info into $LINUX/Module.modvers
 427 # or check
 428 AC_DEFUN([LB_CHECK_SYMBOL_EXPORT],
 429 [AC_MSG_CHECKING([if Linux was built with symbol $1 is exported])
 430 grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX/Module.symvers 2>/dev/null
 431 rc=$?
 432 if test $rc -ne 0; then
 433     export=0
 434     for file in $2; do
 435         grep -q -E "EXPORT_SYMBOL.*($1)" "$LINUX/$file" 2>/dev/null
 436         rc=$?
 437         if test $rc -eq 0; then
 438                 export=1
 439                 break;
 440         fi
 441     done
 442     if test $export -eq 0; then
 443         AC_MSG_RESULT([no])
 444         $4
 445     else
 446         AC_MSG_RESULT([yes])
 447         $3
 448     fi
 449 else
 450     AC_MSG_RESULT([yes])
 451     $3
 452 fi
 453 ])