build/autoconf/lustre-build-linux.m4

   1 #
   2 # LB_LINUX_VERSION
   3 #
   4 # Set things accordingly for a linux kernel
   5 #
   6 AC_DEFUN([LB_LINUX_VERSION],[
   7 KMODEXT=".ko"
   8
   9 MODULE_TARGET="SUBDIRS"
  10 makerule="$PWD/build"
  11 AC_MSG_CHECKING([for external module build support])
  12 rm -f build/conftest.i
  13 LB_LINUX_TRY_MAKE([],[],
  14         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  15         [test -s build/conftest.i],
  16         [
  17                 AC_MSG_RESULT([no])
  18         ],[
  19                 makerule="_module_$makerule"
  20                 MODULE_TARGET="M"
  21                 LB_LINUX_TRY_MAKE([],[],
  22                         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  23                         [test -s build/conftest.i],
  24                         [
  25                                 AC_MSG_RESULT([yes])
  26                         ],[
  27                                 AC_MSG_ERROR([unknown; check config.log for details])
  28                         ])
  29         ])
  30
  31 AC_SUBST(MODULE_TARGET)
  32 AC_SUBST(KMODEXT)
  33 ])
  34
  35 #
  36 # LB_LINUX_RELEASE
  37 #
  38 # get the release version of linux
  39 #
  40 AC_DEFUN([LB_LINUX_RELEASE],
  41 [LINUXRELEASE=
  42 rm -f build/conftest.i
  43 AC_MSG_CHECKING([for Linux release])
  44 if test -s $LINUX_OBJ/include/$AUTOCONF_HDIR/utsrelease.h ; then
  45         LINUXRELEASEHEADER=$AUTOCONF_HDIR/utsrelease.h
  46 else
  47         LINUXRELEASEHEADER=linux/version.h
  48 fi
  49 LB_LINUX_TRY_MAKE([
  50         #include <$LINUXRELEASEHEADER>
  51 ],[
  52         char *LINUXRELEASE;
  53         LINUXRELEASE=UTS_RELEASE;
  54 ],[
  55         $makerule LUSTRE_KERNEL_TEST=conftest.i
  56 ],[
  57         test -s build/conftest.i
  58 ],[
  59         # LINUXRELEASE="UTS_RELEASE"
  60         eval $(grep "LINUXRELEASE=" build/conftest.i)
  61 ],[
  62         AC_MSG_RESULT([unknown])
  63         AC_MSG_ERROR([Could not preprocess test program.  Consult config.log for details.])
  64 ])
  65 rm -f build/conftest.i
  66 if test x$LINUXRELEASE = x ; then
  67         AC_MSG_RESULT([unknown])
  68         AC_MSG_ERROR([Could not determine Linux release version from linux/version.h.])
  69 fi
  70 AC_MSG_RESULT([$LINUXRELEASE])
  71 AC_SUBST(LINUXRELEASE)
  72
  73 moduledir='/lib/modules/'$LINUXRELEASE/updates/kernel
  74 AC_SUBST(moduledir)
  75
  76 modulefsdir='$(moduledir)/fs/$(PACKAGE)'
  77 AC_SUBST(modulefsdir)
  78
  79 modulenetdir='$(moduledir)/net/$(PACKAGE)'
  80 AC_SUBST(modulenetdir)
  81
  82 # ------------ RELEASE --------------------------------
  83 AC_MSG_CHECKING([for Lustre release])
  84 AC_ARG_WITH([release],
  85         AC_HELP_STRING([--with-release=string],
  86                        [set the release string (default=$kvers_YYYYMMDDhhmm)]),
  87         [RELEASE=$withval],
  88         RELEASE=""
  89         if test -n "$DOWNSTREAM_RELEASE"; then
  90                 RELEASE="${DOWNSTREAM_RELEASE}_"
  91         fi
  92         RELEASE="$RELEASE`echo ${LINUXRELEASE} | tr '-' '_'`_$BUILDID")
  93 AC_MSG_RESULT($RELEASE)
  94 AC_SUBST(RELEASE)
  95
  96 # check is redhat/suse kernels
  97 AC_MSG_CHECKING([that RedHat kernel])
  98 LB_LINUX_TRY_COMPILE([
  99                 #include <linux/version.h>
 100         ],[
 101                 #ifndef RHEL_RELEASE_CODE
 102                 #error "not redhat kernel"
 103                 #endif
 104         ],[
 105                 RHEL_KERNEL="yes"
 106                 AC_MSG_RESULT([yes])
 107         ],[
 108                 AC_MSG_RESULT([no])
 109 ])
 110
 111 LB_LINUX_CONFIG([SUSE_KERNEL],[SUSE_KERNEL="yes"],[])
 112
 113 ])
 114
 115 # LB_ARG_REPLACE_PATH(PACKAGE, PATH)
 116 AC_DEFUN([LB_ARG_REPLACE_PATH],[
 117         new_configure_args=
 118         eval "set x $ac_configure_args"
 119         shift
 120         for arg; do
 121                 case $arg in
 122                         --with-[$1]=*)
 123                                 arg=--with-[$1]=[$2]
 124                                 ;;
 125                         *\'*)
 126                                 arg=$(printf %s\n ["$arg"] | \
 127                                       sed "s/'/'\\\\\\\\''/g")
 128                                 ;;
 129                 esac
 130                 dnl AS_VAR_APPEND([new_configure_args], [" '$arg'"])
 131                 new_configure_args="$new_configure_args \"$arg\""
 132         done
 133         ac_configure_args=$new_configure_args
 134 ])
 135
 136 # this is the work-horse of the next function
 137 AC_DEFUN([__LB_ARG_CANON_PATH], [
 138         [$3]=$(readlink -f $with_$2)
 139         LB_ARG_REPLACE_PATH([$1], $[$3])
 140 ])
 141
 142 # a front-end for the above function that transforms - and . in the
 143 # PACKAGE portion of --with-PACKAGE into _ suitable for variable names
 144 AC_DEFUN([LB_ARG_CANON_PATH], [
 145         __LB_ARG_CANON_PATH([$1], m4_translit([$1], [-.], [__]), [$2])
 146 ])
 147
 148 #
 149 #
 150 # LB_LINUX_PATH
 151 #
 152 # Find paths for linux, handling kernel-source rpms
 153 #
 154 AC_DEFUN([LB_LINUX_PATH],
 155 [# prep some default values
 156 for DEFAULT_LINUX in /lib/modules/$(uname -r)/{source,build} /usr/src/linux; do
 157         if readlink -q -e $DEFAULT_LINUX; then
 158                 break
 159         fi
 160 done
 161 if test "$DEFAULT_LINUX" = "/lib/modules/$(uname -r)/source"; then
 162         PATHS="/lib/modules/$(uname -r)/build"
 163 fi
 164 PATHS+=" $DEFAULT_LINUX"
 165 for DEFAULT_LINUX_OBJ in $PATHS; do
 166         if readlink -q -e $DEFAULT_LINUX_OBJ; then
 167                 break
 168         fi
 169 done
 170 AC_MSG_CHECKING([for Linux sources])
 171 AC_ARG_WITH([linux],
 172         AC_HELP_STRING([--with-linux=path],
 173                        [set path to Linux source (default=/lib/modules/$(uname -r)/{source,build},/usr/src/linux)]),
 174         [LB_ARG_CANON_PATH([linux], [LINUX])
 175         DEFAULT_LINUX_OBJ=$LINUX],
 176         [LINUX=$DEFAULT_LINUX])
 177 AC_MSG_RESULT([$LINUX])
 178 AC_SUBST(LINUX)
 179
 180 # -------- check for linux --------
 181 LB_CHECK_FILE([$LINUX],[],
 182         [AC_MSG_ERROR([Kernel source $LINUX could not be found.])])
 183
 184 # -------- linux objects (for 2.6) --
 185 AC_MSG_CHECKING([for Linux objects dir])
 186 AC_ARG_WITH([linux-obj],
 187         AC_HELP_STRING([--with-linux-obj=path],
 188                         [set path to Linux objects dir (default=/lib/modules/$(uname -r)/build,/usr/src/linux)]),
 189         [LB_ARG_CANON_PATH([linux-obj], [LINUX_OBJ])],
 190         [LINUX_OBJ=$DEFAULT_LINUX_OBJ])
 191
 192 AC_MSG_RESULT([$LINUX_OBJ])
 193 AC_SUBST(LINUX_OBJ)
 194
 195 # -------- check for .config --------
 196 AC_ARG_WITH([linux-config],
 197         [AC_HELP_STRING([--with-linux-config=path],
 198                         [set path to Linux .conf (default=$LINUX_OBJ/.config)])],
 199         [LB_ARG_CANON_PATH([linux-config], [LINUX_CONFIG])],
 200         [LINUX_CONFIG=$LINUX_OBJ/.config])
 201 AC_SUBST(LINUX_CONFIG)
 202
 203 LB_CHECK_FILE([/boot/kernel.h],
 204         [KERNEL_SOURCE_HEADER='/boot/kernel.h'],
 205         [LB_CHECK_FILE([/var/adm/running-kernel.h],
 206                 [KERNEL_SOURCE_HEADER='/var/adm/running-kernel.h'])])
 207
 208 AC_ARG_WITH([kernel-source-header],
 209         AC_HELP_STRING([--with-kernel-source-header=path],
 210                         [Use a different kernel version header.  Consult build/README.kernel-source for details.]),
 211         [LB_ARG_CANON_PATH([kernel-source-header], [KERNEL_SOURCE_HEADER])])
 212
 213 # ------------ .config exists ----------------
 214 LB_CHECK_FILE([$LINUX_CONFIG],[],
 215         [AC_MSG_ERROR([Kernel config could not be found.  If you are building from a kernel-source rpm consult build/README.kernel-source])])
 216
 217 # ----------- make dep run? ------------------
 218 # at 2.6.19 # $LINUX/include/linux/config.h is removed
 219 # and at more old has only one line
 220 # include <autoconf.h>
 221 LB_CHECK_FILE([$LINUX_OBJ/include/generated/autoconf.h],[AUTOCONF_HDIR=generated],
 222         [LB_CHECK_FILE([$LINUX_OBJ/include/linux/autoconf.h],[AUTOCONF_HDIR=linux],
 223         [AC_MSG_ERROR([Run make config in $LINUX.])])])
 224         AC_SUBST(AUTOCONF_HDIR)
 225 LB_CHECK_FILE([$LINUX_OBJ/include/linux/version.h],[],
 226         [AC_MSG_ERROR([Run make config in $LINUX.])])
 227
 228 # ----------- kconfig.h exists ---------------
 229 # kernel 3.1, $LINUX/include/linux/kconfig.h is added
 230 # see kernel commit 2a11c8ea20bf850b3a2c60db8c2e7497d28aba99
 231 LB_CHECK_FILE([$LINUX_OBJ/include/linux/kconfig.h],
 232               [CONFIG_INCLUDE=include/linux/kconfig.h],
 233               [CONFIG_INCLUDE=include/$AUTOCONF_HDIR/autoconf.h])
 234         AC_SUBST(CONFIG_INCLUDE)
 235
 236 # ------------ rhconfig.h includes runtime-generated bits --
 237 # red hat kernel-source checks
 238
 239 # we know this exists after the check above.  if the user
 240 # tarred up the tree and ran make dep etc. in it, then
 241 # version.h gets overwritten with a standard linux one.
 242
 243 if grep rhconfig $LINUX_OBJ/include/linux/version.h >/dev/null ; then
 244         # This is a clean kernel-source tree, we need to
 245         # enable extensive workarounds to get this to build
 246         # modules
 247         LB_CHECK_FILE([$KERNEL_SOURCE_HEADER],
 248                 [if test $KERNEL_SOURCE_HEADER = '/boot/kernel.h' ; then
 249                         AC_MSG_WARN([Using /boot/kernel.h from RUNNING kernel.])
 250                         AC_MSG_WARN([If this is not what you want, use --with-kernel-source-header.])
 251                         AC_MSG_WARN([Consult build/README.kernel-source for details.])
 252                 fi],
 253                 [AC_MSG_ERROR([$KERNEL_SOURCE_HEADER not found.  Consult build/README.kernel-source for details.])])
 254         EXTRA_KCFLAGS="-include $KERNEL_SOURCE_HEADER $EXTRA_KCFLAGS"
 255 fi
 256
 257 # this is needed before we can build modules
 258 LB_LINUX_UML
 259 LB_LINUX_VERSION
 260
 261 # --- check that we can build modules at all
 262 AC_MSG_CHECKING([that modules can be built at all])
 263 LB_LINUX_TRY_COMPILE([],[],[
 264         AC_MSG_RESULT([yes])
 265 ],[
 266         AC_MSG_RESULT([no])
 267         AC_MSG_WARN([Consult config.log for details.])
 268         AC_MSG_WARN([If you are trying to build with a kernel-source rpm, consult build/README.kernel-source])
 269         AC_MSG_ERROR([Kernel modules cannot be built.])
 270 ])
 271
 272 LB_LINUX_RELEASE
 273 ]) # end of LB_LINUX_PATH
 274
 275 # LB_LINUX_SYMVERFILE
 276 # SLES 9 uses a different name for this file - unsure about vanilla kernels
 277 # around this version, but it matters for servers only.
 278 AC_DEFUN([LB_LINUX_SYMVERFILE],
 279         [AC_MSG_CHECKING([name of module symbol version file])
 280         if grep -q Modules.symvers $LINUX/scripts/Makefile.modpost ; then
 281                 SYMVERFILE=Modules.symvers
 282         else
 283                 SYMVERFILE=Module.symvers
 284         fi
 285         AC_MSG_RESULT($SYMVERFILE)
 286         AC_SUBST(SYMVERFILE)
 287 ])
 288
 289 #
 290 #
 291 # LB_LINUX_MODPOST
 292 #
 293 # Find modpost and check it
 294 #
 295 AC_DEFUN([LB_LINUX_MODPOST],
 296 [
 297 # Find the modpost utility
 298 LB_CHECK_FILE([$LINUX_OBJ/scripts/mod/modpost],
 299         [MODPOST=$LINUX_OBJ/scripts/mod/modpost],
 300         [LB_CHECK_FILE([$LINUX_OBJ/scripts/modpost],
 301                 [MODPOST=$LINUX_OBJ/scripts/modpost],
 302                 AC_MSG_ERROR([modpost not found.])
 303         )]
 304 )
 305 AC_SUBST(MODPOST)
 306
 307 # Ensure it can run
 308 AC_MSG_CHECKING([if modpost can be run])
 309 if $MODPOST ; then
 310         AC_MSG_RESULT([yes])
 311 else
 312         AC_MSG_ERROR([modpost can not be run.])
 313 fi
 314
 315 # Check if modpost supports (and therefore requires) -m
 316 AC_MSG_CHECKING([if modpost supports -m])
 317 if $MODPOST -m 2>/dev/null ; then
 318         AC_MSG_RESULT([yes])
 319         MODPOST_ARGS=-m
 320 else
 321         AC_MSG_RESULT([no])
 322         MODPOST_ARGS=""
 323 fi
 324 AC_SUBST(MODPOST_ARGS)
 325 ])
 326
 327 #
 328 # LB_LINUX_UML
 329 #
 330 # check for a uml kernel
 331 #
 332 AC_DEFUN([LB_LINUX_UML],
 333 [ARCH_UM=
 334 UML_CFLAGS=
 335
 336 AC_MSG_CHECKING([if you are running user mode linux for $target_cpu])
 337 if test -e $LINUX/include/asm-um ; then
 338         if test  X`ls -id $LINUX/include/asm/ 2>/dev/null | awk '{print [$]1}'` = X`ls -id $LINUX/include/asm-um 2>/dev/null | awk '{print [$]1}'` ; then
 339                 ARCH_UM='ARCH=um'
 340                 # see notes in Rules.in
 341                 UML_CFLAGS='-O0'
 342                 AC_MSG_RESULT(yes)
 343         else
 344                 AC_MSG_RESULT([no])
 345         fi
 346 else
 347         AC_MSG_RESULT([no (asm-um missing)])
 348 fi
 349 AC_SUBST(ARCH_UM)
 350 AC_SUBST(UML_CFLAGS)
 351 ])
 352
 353 # these are like AC_TRY_COMPILE, but try to build modules against the
 354 # kernel, inside the build directory
 355
 356 # LB_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 357 # --------------------------------------
 358 m4_define([LB_LANG_PROGRAM],
 359 [
 360 #include <linux/kernel.h>
 361 $1
 362 int
 363 main (void)
 364 {
 365 dnl Do *not* indent the following line: there may be CPP directives.
 366 dnl Don't move the `;' right after for the same reason.
 367 $2
 368   ;
 369   return 0;
 370 }])
 371
 372 #
 373 # LB_LINUX_COMPILE_IFELSE
 374 #
 375 # like AC_COMPILE_IFELSE
 376 #
 377 AC_DEFUN([LB_LINUX_COMPILE_IFELSE],
 378 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
 379 rm -f build/conftest.o build/conftest.mod.c build/conftest.ko
 380 AS_IF([AC_TRY_COMMAND(cp conftest.c build && make -d [$2] ${LD:+"LD=$LD"} CC="$CC" -f $PWD/build/Makefile LUSTRE_LINUX_CONFIG=$LINUX_CONFIG LINUXINCLUDE="$EXTRA_LNET_INCLUDE -I$LINUX/arch/`echo $target_cpu|sed -e 's/powerpc64/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include -I$LINUX/arch/`echo $target_cpu|sed -e 's/ppc.*/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include/generated -I$LINUX_OBJ/include -I$LINUX/include -I$LINUX_OBJ/include2 -include $CONFIG_INCLUDE" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM $MODULE_TARGET=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 381         [$4],
 382         [_AC_MSG_LOG_CONFTEST
 383 m4_ifvaln([$5],[$5])dnl])
 384 rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
 385 ])
 386
 387 #
 388 # LB_LINUX_ARCH
 389 #
 390 # Determine the kernel's idea of the current architecture
 391 #
 392 AC_DEFUN([LB_LINUX_ARCH],
 393          [AC_MSG_CHECKING([Linux kernel architecture])
 394           AS_IF([rm -f $PWD/build/arch
 395                  make -s --no-print-directory echoarch -f $PWD/build/Makefile \
 396                      LUSTRE_LINUX_CONFIG=$LINUX_CONFIG -C $LINUX $ARCH_UM \
 397                      ARCHFILE=$PWD/build/arch && LINUX_ARCH=`cat $PWD/build/arch`],
 398                 [AC_MSG_RESULT([$LINUX_ARCH])],
 399                 [AC_MSG_ERROR([Could not determine the kernel architecture.])])
 400           rm -f build/arch])
 401
 402 #
 403 # LB_LINUX_TRY_COMPILE
 404 #
 405 # like AC_TRY_COMPILE
 406 #
 407 AC_DEFUN([LB_LINUX_TRY_COMPILE],
 408 [LB_LINUX_COMPILE_IFELSE(
 409         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 410         [modules],
 411         [test -s build/conftest.o],
 412         [$3], [$4])])
 413
 414 #
 415 # LB_LINUX_CONFIG
 416 #
 417 # check if a given config option is defined
 418 #
 419 AC_DEFUN([LB_LINUX_CONFIG],[
 420         AC_MSG_CHECKING([if Linux was built with CONFIG_$1])
 421         LB_LINUX_TRY_COMPILE([
 422                 #include <$AUTOCONF_HDIR/autoconf.h>
 423         ],[
 424                 #ifndef CONFIG_$1
 425                 #error CONFIG_$1 not #defined
 426                 #endif
 427         ],[
 428                 AC_MSG_RESULT([yes])
 429                 $2
 430         ],[
 431                 AC_MSG_RESULT([no])
 432                 $3
 433         ])
 434 ])
 435
 436 #
 437 # LB_LINUX_CONFIG_IM
 438 #
 439 # check if a given config option is builtin or as module
 440 #
 441 AC_DEFUN([LB_LINUX_CONFIG_IM],[
 442         AC_MSG_CHECKING([if Linux was built with CONFIG_$1 in or as module])
 443         LB_LINUX_TRY_COMPILE([
 444                 #include <$AUTOCONF_HDIR/autoconf.h>
 445         ],[
 446                 #if !(defined(CONFIG_$1) || defined(CONFIG_$1_MODULE))
 447                 #error CONFIG_$1 and CONFIG_$1_MODULE not #defined
 448                 #endif
 449         ],[
 450                 AC_MSG_RESULT([yes])
 451                 $2
 452         ],[
 453                 AC_MSG_RESULT([no])
 454                 $3
 455         ])
 456 ])
 457
 458 #
 459 # LB_LINUX_TRY_MAKE
 460 #
 461 # like LB_LINUX_TRY_COMPILE, but with different arguments
 462 #
 463 AC_DEFUN([LB_LINUX_TRY_MAKE],
 464         [LB_LINUX_COMPILE_IFELSE(
 465                 [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 466                 [$3], [$4], [$5], [$6]
 467         )]
 468 )
 469
 470 #
 471 # LB_CONFIG_OFED_BACKPORTS
 472 #
 473 # include any OFED backport headers in all compile commands
 474 # NOTE: this does only include the backport paths, not the OFED headers
 475 #       adding the OFED headers is done in the lnet portion
 476 AC_DEFUN([LB_CONFIG_OFED_BACKPORTS],
 477 [AC_MSG_CHECKING([whether to use any OFED backport headers])
 478 # set default
 479 AC_ARG_WITH([o2ib],
 480         AC_HELP_STRING([--with-o2ib=path],
 481                        [build o2iblnd against path]),
 482         [
 483                 case $with_o2ib in
 484                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 485                         ENABLEO2IB=2
 486                         ;;
 487                 no)     ENABLEO2IB=0
 488                         ;;
 489                 *)      O2IBPATHS=$with_o2ib
 490                         ENABLEO2IB=3
 491                         ;;
 492                 esac
 493         ],[
 494                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 495                 ENABLEO2IB=1
 496         ])
 497 if test $ENABLEO2IB -eq 0; then
 498         AC_MSG_RESULT([no])
 499 else
 500         o2ib_found=false
 501         for O2IBPATH in $O2IBPATHS; do
 502                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 503                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 504                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 505                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 506                         o2ib_found=true
 507                         break
 508                 fi
 509         done
 510         if ! $o2ib_found; then
 511                 AC_MSG_RESULT([no])
 512                 case $ENABLEO2IB in
 513                         1) ;;
 514                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 515                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 516                         *) AC_MSG_ERROR([internal error]);;
 517                 esac
 518         else
 519                 if test -f $O2IBPATH/config.mk; then
 520                         . $O2IBPATH/config.mk
 521                 elif test -f $O2IBPATH/ofed_patch.mk; then
 522                         . $O2IBPATH/ofed_patch.mk
 523                 fi
 524                 if test -n "$BACKPORT_INCLUDES"; then
 525                         OFED_BACKPORT_PATH="$O2IBPATH/${BACKPORT_INCLUDES/*\/kernel_addons/kernel_addons}/"
 526                         EXTRA_LNET_INCLUDE="-I$OFED_BACKPORT_PATH $EXTRA_LNET_INCLUDE"
 527                         AC_MSG_RESULT([yes])
 528                 else
 529                         AC_MSG_RESULT([no])
 530                 fi
 531         fi
 532 fi
 533 ])
 534
 535 # LC_MODULE_LOADING
 536 # after 2.6.28 CONFIG_KMOD is removed, and only CONFIG_MODULES remains
 537 # so we test if request_module is implemented or not
 538 AC_DEFUN([LC_MODULE_LOADING],
 539 [AC_MSG_CHECKING([if kernel module loading is possible])
 540 LB_LINUX_TRY_MAKE([
 541         #include <linux/kmod.h>
 542 ],[
 543         int myretval=ENOSYS ;
 544         return myretval;
 545 ],[
 546         $makerule LUSTRE_KERNEL_TEST=conftest.i
 547 ],[dnl
 548         grep request_module build/conftest.i |dnl
 549                 grep -v `grep "int myretval=" build/conftest.i |dnl
 550                         cut -d= -f2 | cut -d" "  -f1`dnl
 551                 >/dev/null dnl
 552 ],[
 553         AC_MSG_RESULT(yes)
 554         AC_DEFINE(HAVE_MODULE_LOADING_SUPPORT, 1,
 555                   [kernel module loading is possible])
 556 ],[
 557         AC_MSG_RESULT(no)
 558         AC_MSG_WARN([])
 559         AC_MSG_WARN([Kernel module loading support is highly recommended.])
 560         AC_MSG_WARN([])
 561 ])
 562 ])
 563
 564 #
 565 # LB_PROG_LINUX
 566 #
 567 # linux tests
 568 #
 569 AC_DEFUN([LB_PROG_LINUX],
 570 [LB_LINUX_PATH
 571 LB_LINUX_ARCH
 572 LB_LINUX_SYMVERFILE
 573
 574
 575 LB_LINUX_CONFIG([MODULES],[],[
 576         AC_MSG_ERROR([module support is required to build Lustre kernel modules.])
 577 ])
 578
 579 LB_LINUX_CONFIG([MODVERSIONS])
 580
 581 LB_LINUX_CONFIG([KALLSYMS],[],[
 582 if test "x$ARCH_UM" = "x" ; then
 583         AC_MSG_ERROR([Lustre requires that CONFIG_KALLSYMS is enabled in your kernel.])
 584 fi
 585 ])
 586
 587 # 2.6.28
 588 LC_MODULE_LOADING
 589
 590 # it's ugly to be doing anything with OFED outside of the lnet module, but
 591 # this has to be done here so that the backports path is set before all of
 592 # the LN_PROG_LINUX checks are done
 593 LB_CONFIG_OFED_BACKPORTS
 594 ])
 595
 596 #
 597 # LB_CHECK_SYMBOL_EXPORT
 598 # check symbol exported or not
 599 # $1 - symbol
 600 # $2 - file(s) for find.
 601 # $3 - do 'yes'
 602 # $4 - do 'no'
 603 #
 604 # 2.6 based kernels - put modversion info into $LINUX/Module.modvers
 605 # or check
 606 AC_DEFUN([LB_CHECK_SYMBOL_EXPORT],
 607 [AC_MSG_CHECKING([if Linux was built with symbol $1 exported])
 608 grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX/$SYMVERFILE 2>/dev/null
 609 rc=$?
 610 if test $rc -ne 0; then
 611         export=0
 612         for file in $2; do
 613                 grep -q -E "EXPORT_SYMBOL.*\($1\)" "$LINUX/$file" 2>/dev/null
 614                 rc=$?
 615                 if test $rc -eq 0; then
 616                         export=1
 617                         break;
 618                 fi
 619         done
 620         if test $export -eq 0; then
 621                 AC_MSG_RESULT([no])
 622                 $4
 623         else
 624                 AC_MSG_RESULT([yes])
 625                 $3
 626         fi
 627 else
 628         AC_MSG_RESULT([yes])
 629         $3
 630 fi
 631 ])
 632
 633 #
 634 # Like AC_CHECK_HEADER but checks for a kernel-space header
 635 #
 636 m4_define([LB_CHECK_LINUX_HEADER],
 637 [AS_VAR_PUSHDEF([ac_Header], [ac_cv_header_$1])dnl
 638 AC_CACHE_CHECK([for $1], ac_Header,
 639                [LB_LINUX_COMPILE_IFELSE([LB_LANG_PROGRAM([@%:@include <$1>])],
 640                                   [modules],
 641                                   [test -s build/conftest.o],
 642                                   [AS_VAR_SET(ac_Header, [yes])],
 643                                   [AS_VAR_SET(ac_Header, [no])])])
 644 AS_IF([test AS_VAR_GET(ac_Header) = yes], [$2], [$3])[]dnl
 645 AS_VAR_POPDEF([ac_Header])dnl
 646 ])
 647
 648 #
 649 # LB_USES_DPKG
 650 #
 651 # Determine if the target is a dpkg system or rpm
 652 #
 653 AC_DEFUN([LB_USES_DPKG],
 654 [
 655 AC_MSG_CHECKING([if this distro uses dpkg])
 656 case `lsb_release -i -s 2>/dev/null` in
 657         Ubuntu | Debian)
 658                 AC_MSG_RESULT([yes])
 659                 uses_dpkg=yes
 660                 ;;
 661         *)
 662                 AC_MSG_RESULT([no])
 663                 uses_dpkg=no
 664                 ;;
 665 esac
 666 ])