Whamcloud - gitweb
LU-1952 tests: fix sanity test_51b on small MDTs
[fs/lustre-release.git] / build / autoconf / lustre-build-ldiskfs.m4
1 #
2 # LB_PATH_LDISKFS
3 #
4 # --without-ldiskfs   - Disable ldiskfs support.
5 # --with-ldiskfs=no
6 #
7 # --with-ldiskfs      - Enable ldiskfs support and attempt to autodetect the
8 # --with-ldiskfs=yes    headers in one of the following places in this order:
9 #                       * ./ldiskfs
10 #                       * /usr/src/ldiskfs-*/$LINUXRELEASE
11 #                       * ../ldiskfs
12 #
13 # --with-ldiskfs=path - Enable ldiskfs support and use the headers in the
14 #                       provided path.  No autodetection is performed.
15 #
16 # --with-ldiskfs-obj  - When ldiskfs support is enabled the object directory
17 #                       will be based on the --with-ldiskfs directory.  If
18 #                       this is detected incorrectly it can be explicitly
19 #                       specified using this option.
20 #
21 # NOTE: As with all external packages ldiskfs is expected to already be
22 # configured and built.  However, if the ldiskfs tree is located in-tree
23 # (./ldiskfs) then it will be configured and built recursively as part of
24 # the lustre build system.
25 #
26 # NOTE: The lustre and in-tree ldiskfs build systems both make use these
27 # macros.  This is undesirable and confusing at best, it is potentially
28 # danagerous at worst.  The ldiskfs build system should be entirely stand
29 # alone without dependency on the lustre build system.
30 #
31 AC_DEFUN([LB_PATH_LDISKFS],
32 [
33 AC_ARG_WITH([ldiskfs],
34         AC_HELP_STRING([--with-ldiskfs=path], [set path to ldiskfs source]),
35         [],[
36                 if test x$enable_server = xyes && test x$enable_dist = xno; then
37                         with_ldiskfs='yes'
38                 else
39                         with_ldiskfs='no'
40                 fi
41         ])
42
43 case x$with_ldiskfs in
44         xno)
45                 LDISKFS_DIR=
46                 ;;
47         xyes)
48                 LDISKFS_DIR=
49
50                 # Check ./ldiskfs
51                 ldiskfs_src=$PWD/ldiskfs
52                 if test -e "$ldiskfs_src"; then
53                         LDISKFS_DIR=$(readlink -f $ldiskfs_src)
54                 else
55                         # Check /usr/src/ldiskfs-*/$LINUXRELEASE
56                         ldiskfs_src=$(ls -1d \
57                                 /usr/src/ldiskfs-*/$LINUXRELEASE \
58                                 2>/dev/null | tail -1)
59                         if test -e "$ldiskfs_src"; then
60                                 LDISKFS_DIR=$(readlink -f $ldiskfs_src)
61                         else
62                                 # Check ../ldiskfs
63                                 ldiskfs_src=$PWD/../ldiskfs
64                                 if test -e "$ldiskfs_src"; then
65                                         LDISKFS_DIR=$(readlink -f $ldiskfs_src)
66                                 else
67                                         # Disable ldiskfs failed to detect
68                                         with_ldiskfs='no'
69                                 fi
70                         fi
71                 fi
72
73                 ;;
74         *)
75                 LDISKFS_DIR=$(readlink -f $with_ldiskfs)
76                 with_ldiskfs='yes'
77                 ;;
78 esac
79
80 AC_MSG_CHECKING([whether to enable ldiskfs])
81 AC_MSG_RESULT([$with_ldiskfs])
82
83 AC_ARG_WITH([ldiskfs-obj],
84         AC_HELP_STRING([--with-ldiskfs-obj=path],[set path to ldiskfs objects]),
85         [
86                 if test x$with_ldiskfs = xyes; then
87                         LDISKFS_OBJ="$withval"
88                 fi
89         ],[
90                 if test x$with_ldiskfs = xyes; then
91                         LDISKFS_OBJ=$LDISKFS_DIR
92                 fi
93         ])
94
95 if test x$with_ldiskfs = xyes; then
96         AC_MSG_CHECKING([ldiskfs source directory])
97         AC_MSG_RESULT([$LDISKFS_DIR])
98         AC_SUBST(LDISKFS_DIR)
99
100         AC_MSG_CHECKING([ldiskfs object directory])
101         AC_MSG_RESULT([$LDISKFS_OBJ])
102         AC_SUBST(LDISKFS_OBJ)
103
104         LB_LDISKFS_SYMVERS
105         LB_LDISKFS_RELEASE
106         LB_LDISKFS_EXT_DIR
107         LB_LDISKFS_BUILD
108         LB_LDISKFS_DEFINE_OPTIONS
109 fi
110
111 #
112 # LDISKFS_DEVEL is required because when using the ldiskfs-devel package the
113 # ext4 source will be fully patched to ldiskfs.  When building with the
114 # in-tree ldiskfs this patching this will occur after the configure step.
115 # We needed a way to determine if we should check the patched or unpatched
116 # source files.
117 #
118 # Longer term this could be removed by moving the ldiskfs patching in to
119 # the configure phase.  Or better yet ldiskfs could be updated to generate
120 # a ldiskfs_config.h which clearly defines how it was built.  This can
121 # then be directly included by Lustre to avoid all the autoconf guess work.
122 # For an example of this behavior consult the lustre/zfs build integration.
123 #
124 AM_CONDITIONAL(LDISKFS_DEVEL, \
125         test x$LDISKFS_DIR = x$(readlink -f $PWD/ldiskfs) || \
126         test x$LDISKFS_DIR = x$(readlink -f $PWD/../ldiskfs))
127
128 AM_CONDITIONAL(LDISKFS_BUILD, test x$enable_ldiskfs_build = xyes)
129 AM_CONDITIONAL(LDISKFS_ENABLED, test x$with_ldiskfs = xyes)
130
131 if test -e "$PWD/ldiskfs"; then
132         LDISKFS_DIST_SUBDIR="ldiskfs"
133         AC_SUBST(LDISKFS_DIST_SUBDIR)
134         AC_CONFIG_SUBDIRS("ldiskfs")
135 fi
136 ])
137
138 #
139 # LB_LDISKFS_EXT_DIR
140 #
141 # Determine the location of the ext3/ext4 source code.  It it required
142 # for several configure tests and to build ldiskfs.
143 #
144 AC_DEFUN([LB_LDISKFS_EXT_DIR],
145 [
146 # Kernel ext source located with devel headers
147 linux_src=$LINUX
148 if test -e "$linux_src/fs/ext4/super.c"; then
149         EXT_DIR=$linux_src/fs/ext4
150 else
151         # Kernel ext source provided by kernel-debuginfo-common package
152         linux_src=$(ls -1d /usr/src/debug/*/linux-$LINUXRELEASE \
153                 2>/dev/null | tail -1)
154         if test -e "$linux_src/fs/ext4/super.c"; then
155                 EXT_DIR=$linux_src/fs/ext4
156         else
157                 EXT_DIR=
158         fi
159 fi
160
161 AC_MSG_CHECKING([ext4 source directory])
162 AC_MSG_RESULT([$EXT_DIR])
163 AC_SUBST(EXT_DIR)
164 ])
165
166 #
167 # LB_LDISKFS_EXT_SOURCE
168 #
169 # Spot check the existance of several source files common to ext3/ext4.
170 # Detecting this at configure time allows us to avoid a potential build
171 # failure and provide a useful error message to explain what is wrong.
172 #
173 AC_DEFUN([LB_LDISKFS_EXT_SOURCE],
174 [
175 if test x$EXT_DIR = x; then
176         enable_ldiskfs_build='no'
177 else
178         LB_CHECK_FILE([$EXT_DIR/dir.c], [], [
179                 enable_ldiskfs_build='no'
180                 AC_MSG_WARN([ext4 must exist for ldiskfs build])])
181         LB_CHECK_FILE([$EXT_DIR/file.c], [], [
182                 enable_ldiskfs_build='no'
183                 AC_MSG_WARN([ext4 must exist for ldiskfs build])])
184         LB_CHECK_FILE([$EXT_DIR/inode.c], [], [
185                 enable_ldiskfs_build='no'
186                 AC_MSG_WARN([ext4 must exist for ldiskfs build])])
187         LB_CHECK_FILE([$EXT_DIR/super.c], [], [
188                 enable_ldiskfs_build='no'
189                 AC_MSG_WARN([ext4 must exist for ldiskfs build])])
190 fi
191
192 if test x$enable_ldiskfs_build = xno; then
193         enable_server='no'
194         enable_ldiskfs_build='no'
195         with_ldiskfs='no'
196         LDISKFS_SUBDIR=
197
198         AC_MSG_WARN([
199
200 Disabling server because complete ext4 source does not exist.
201
202 If you are building using kernel-devel packages and require ldiskfs
203 server support then ensure that the matching kernel-debuginfo-common
204 and kernel-debuginfo-common-<arch> packages are installed.
205
206 ])
207
208 fi
209 ])
210
211 #
212 # LB_LDISKFS_DEFINE_OPTIONS
213 #
214 # Enable config options related to ldiskfs.  These are used by ldiskfs,
215 # lvfs, and the osd-ldiskfs code (which includes ldiskfs headers.)
216 #
217 AC_DEFUN([LB_LDISKFS_DEFINE_OPTIONS],
218 [
219 AC_DEFINE(HAVE_LDISKFS_OSD, 1, Enable ldiskfs osd)
220
221 with_ldiskfs_pdo=no
222 case $LINUXRELEASE in
223 2.6.32*)
224         if test x$RHEL_KERNEL = xyes; then
225                 with_ldiskfs_pdo=yes
226                 AC_DEFINE(HAVE_LDISKFS_PDO, 1, [have ldiskfs PDO patch])
227         fi
228         if test x$SUSE_KERNEL = xyes; then
229                 with_ldiskfs_pdo=yes
230                 AC_DEFINE(HAVE_LDISKFS_PDO, 1, [have ldiskfs PDO patch])
231         fi
232         ;;
233 esac
234 LB_LDISKFS_JBD2_JOURNAL_CALLBACK_SET
235
236 AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1,
237         [enable extended attributes for ldiskfs])
238 AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1,
239         [enable posix acls for ldiskfs])
240 AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1,
241         [enable fs security for ldiskfs])
242 AC_DEFINE(CONFIG_LDISKFSDEV_FS_POSIX_ACL, 1,
243         [enable posix acls for ldiskfs])
244 AC_DEFINE(CONFIG_LDISKFSDEV_FS_XATTR, 1,
245         [enable extented attributes for ldiskfs])
246 AC_DEFINE(CONFIG_LDISKFSDEV_FS_SECURITY, 1,
247         [enable fs security for ldiskfs])
248 ])
249
250 #
251 # Check for jbd2_journal_callback_set(), which is needed for commit
252 # callbacks.  When LU-433 lands jbd2_journal_callback_set() will only
253 # remain for legacy reasons and AC_MSG_ERROR can be removed.
254 #
255 # 2.6.18 with ext3 still uses journal_callback_set() for commit callbacks.
256 #
257 AC_DEFUN([LB_LDISKFS_JBD2_JOURNAL_CALLBACK_SET],
258 [
259         LB_CHECK_SYMBOL_EXPORT([jbd2_journal_callback_set],
260         [fs/jbd2/journal.c],
261         [AC_DEFINE(HAVE_JBD2_JOURNAL_CALLBACK_SET, 1,
262                 [kernel exports jbd2_journal_callback_set])],
263         [LB_CHECK_SYMBOL_EXPORT([journal_callback_set],
264                 [fs/jbd/journal.c],
265                 [AC_DEFINE(HAVE_JOURNAL_CALLBACK_SET, 1,
266                         [kernel exports journal_callback_set])])])
267 ])
268
269 #
270 # Optionally configure/make the ldiskfs sources.  If the sources are
271 # determined to reside in-tree this feature will automatically be
272 # enabled.  If the sources are not in-tree it will be disabled.
273 # Use --enable-ldiskfs-build or --disable-ldiskfs-build if you need
274 # to override this behavior.
275 #
276 AC_DEFUN([LB_LDISKFS_BUILD],
277 [
278 AC_ARG_ENABLE([ldiskfs-build],
279         AC_HELP_STRING([--enable-ldiskfs-build],
280                 [enable ldiskfs configure/make]),
281         [], [
282                 LDISKFS_DIR_INTREE=$(readlink -f $PWD/ldiskfs)
283                 if test x$LDISKFS_DIR = x$LDISKFS_DIR_INTREE; then
284                         enable_ldiskfs_build='yes'
285                 else
286                         enable_ldiskfs_build='no'
287                 fi
288         ])
289
290 AC_MSG_CHECKING([whether to build ldiskfs])
291 if test x$enable_ldiskfs_build = xyes; then
292         AC_MSG_RESULT([$enable_ldiskfs_build])
293         LDISKFS_SUBDIR="ldiskfs"
294
295         LB_CHECK_FILE([$LDISKFS_DIR/configure], [], [
296                 AC_MSG_ERROR([Complete ldiskfs build system must exist])])
297         LB_LDISKFS_EXT_SOURCE
298
299         AC_SUBST(LDISKFS_SUBDIR)
300 else
301         enable_ldiskfs_build='no'
302         AC_MSG_RESULT([$enable_ldiskfs_build])
303 fi
304 ])
305
306 AC_DEFUN([LB_LDISKFS_SYMVERS],
307 [
308 AC_MSG_CHECKING([ldiskfs module symbols])
309 if test -r $LDISKFS_OBJ/Module.symvers; then
310         LDISKFS_SYMBOLS=Module.symvers
311 elif test -r $LDISKFS_OBJ/Modules.symvers; then
312         LDISKFS_SYMBOLS=Modules.symvers
313 elif test -r $LDISKFS_OBJ/ldiskfs/Module.symvers; then
314         LDISKFS_SYMBOLS=Module.symvers
315 elif test -r $LDISKFS_OBJ/ldiskfs/Modules.symvers; then
316         LDISKFS_SYMBOLS=Modules.symvers
317 else
318         LDISKFS_SYMBOLS=$SYMVERFILE
319 fi
320
321 AC_MSG_RESULT([$LDISKFS_SYMBOLS])
322 AC_SUBST(LDISKFS_SYMBOLS)
323 ])
324
325 AC_DEFUN([LB_LDISKFS_RELEASE],
326 [
327 AC_MSG_CHECKING([ldiskfs source release])
328 if test -r $LDISKFS_OBJ/config.h; then
329         tmp_flags="$EXTRA_KCFLAGS"
330         EXTRA_KCFLAGS="-I$LDISKFS_DIR $EXTRA_KCFLAGS"
331         LB_LINUX_TRY_MAKE([
332                 #undef PACKAGE_NAME
333                 #undef PACKAGE_TARNAME
334                 #undef PACKAGE_VERSION
335                 #undef PACKAGE_STRING
336                 #undef PACKAGE_BUGREPORT
337                 #undef PACKAGE
338                 #undef VERSION
339                 #undef STDC_HEADERS
340
341                 #include <$LDISKFS_OBJ/config.h>
342         ],[
343                 char *LDISKFS_RELEASE;
344                 LDISKFS_RELEASE=VERSION;
345         ],[
346                 $makerule LUSTRE_KERNEL_TEST=conftest.i
347         ],[
348                 test -s build/conftest.i
349         ],[
350                 eval $(grep "LDISKFS_RELEASE=" build/conftest.i)
351         ],[
352                 AC_MSG_RESULT([unknown])
353                 AC_MSG_ERROR([Could not preprocess test program.])
354         ])
355         EXTRA_KCFLAGS="$tmp_flags"
356         rm build/conftest.i
357 elif test -r $LDISKFS_DIR/configure.ac; then
358         LDISKFS_RELEASE=$(awk '/AC\_INIT/ { print [$]3 }' \
359                  $LDISKFS_DIR/configure.ac | tr ',' '\n')
360 else
361         AC_MSG_RESULT([unknown])
362         AC_MSG_ERROR([Could not locate config.h, META, or configure.ac to check release.])
363 fi
364
365 if test x$LDISKFS_RELEASE = x; then
366         AC_MSG_RESULT([unknown])
367         AC_MSG_ERROR([Could not determine ldiskfs release.])
368 fi
369
370 AC_MSG_RESULT([$LDISKFS_RELEASE])
371 AC_SUBST(LDISKFS_RELEASE)
372 ])
373
374 #
375 # LB_DEFINE_E2FSPROGS_NAMES
376 #
377 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
378 #
379 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES],
380 [
381 AC_ARG_WITH([ldiskfsprogs],
382         AC_HELP_STRING([--with-ldiskfsprogs],
383                        [use alternate names for ldiskfs-enabled e2fsprogs]),
384         [],[withval='no'])
385
386 AC_MSG_CHECKING([whether to use alternate names for e2fsprogs])
387 if test x$withval = xyes ; then
388         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
389         E2FSPROGS="ldiskfsprogs"
390         MKE2FS="mkfs.ldiskfs"
391         DEBUGFS="debugfs.ldiskfs"
392         TUNE2FS="tunefs.ldiskfs"
393         E2LABEL="label.ldiskfs"
394         DUMPE2FS="dumpfs.ldiskfs"
395         E2FSCK="fsck.ldiskfs"
396         PFSCK="pfsck.ldiskfs"
397         AC_MSG_RESULT([enabled])
398 else
399         E2FSPROGS="e2fsprogs"
400         MKE2FS="mke2fs"
401         DEBUGFS="debugfs"
402         TUNE2FS="tune2fs"
403         E2LABEL="e2label"
404         DUMPE2FS="dumpe2fs"
405         E2FSCK="e2fsck"
406         PFSCK="fsck"
407         AC_MSG_RESULT([disabled])
408 fi
409
410 AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
411 AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
412 AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
413 AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
414 AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
415 AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
416 AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
417 AC_DEFINE_UNQUOTED(PFSCK, "$PFSCK", [name of parallel fsck program])
418
419 AC_SUBST([E2FSPROGS], [$E2FSPROGS])
420 AC_SUBST([MKE2FS], [$MKE2FS])
421 AC_SUBST([DEBUGFS], [$DEBUGFS])
422 AC_SUBST([TUNE2FS], [$TUNE2FS])
423 AC_SUBST([E2LABEL], [$E2LABEL])
424 AC_SUBST([DUMPE2FS], [$DUMPE2FS])
425 AC_SUBST([E2FSCK], [$E2FSCK])
426 AC_SUBST([PFSCK], [$PFSCK])
427 ])
428
429 AC_DEFUN([LB_LDISKFS_SERIES],
430 [
431 if $1; then
432         AC_MSG_CHECKING([which ldiskfs series to use])
433         case $LINUXRELEASE in
434         2.6.18*)
435                 if test x$RHEL_KERNEL = xyes; then
436                         LDISKFS_SERIES="2.6-rhel5-ext4.series"
437                 fi
438                 ;;
439         2.6.32*)
440                 if test x$RHEL_KERNEL = xyes; then
441                         LDISKFS_SERIES="2.6-rhel6.series"
442                 fi
443                 if test x$SUSE_KERNEL = xyes; then
444                         LDISKFS_SERIES="2.6-sles11.series"
445                 fi
446                 ;;
447         *)
448                 AC_MSG_WARN([Unknown kernel version $LINUXRELEASE])
449                 LDISKFS_SERIES=
450                 ;;
451         esac
452         AC_MSG_RESULT([$LDISKFS_SERIES])
453 else
454         LDISKFS_SERIES=
455 fi
456 AC_SUBST(LDISKFS_SERIES)
457 ])