configure.in

   1 AC_INIT(version.h)
   2 AC_PREREQ(2.54)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_HEADERS([lib/config.h])
   5 AH_BOTTOM([#include "dirpaths.h"])
   6 MCONFIG=./MCONFIG
   7 AC_SUBST_FILE(MCONFIG)
   8 BINARY_TYPE=bin
   9 dnl
  10 dnl This is to figure out the version number and the date....
  11 dnl
  12 E2FSPROGS_VERSION=`grep E2FSPROGS_VERSION ${srcdir}/version.h  \
  13         | awk '{print $3}' | tr \" " " | awk '{print $1}'`
  14 DATE=`grep E2FSPROGS_DATE ${srcdir}/version.h | awk '{print $3}' \
  15         | tr \" " "`
  16 E2FSPROGS_DAY=`echo $DATE | awk -F- '{print $1}'`
  17 MONTH=`echo $DATE | awk -F- '{print $2}'`
  18 YEAR=`echo $DATE | awk -F- '{print $3}'`
  19
  20 if expr $YEAR ">" 1900 > /dev/null ; then
  21         E2FSPROGS_YEAR=$YEAR
  22 elif expr $YEAR ">" 90 >/dev/null ; then
  23         E2FSPROGS_YEAR=19$YEAR
  24 else
  25         E2FSPROGS_YEAR=20$YEAR
  26 fi
  27
  28 case $MONTH in
  29 Jan)    MONTH_NUM=01; E2FSPROGS_MONTH="January" ;;
  30 Feb)    MONTH_NUM=02; E2FSPROGS_MONTH="February" ;;
  31 Mar)    MONTH_NUM=03; E2FSPROGS_MONTH="March" ;;
  32 Apr)    MONTH_NUM=04; E2FSPROGS_MONTH="April" ;;
  33 May)    MONTH_NUM=05; E2FSPROGS_MONTH="May" ;;
  34 Jun)    MONTH_NUM=06; E2FSPROGS_MONTH="June" ;;
  35 Jul)    MONTH_NUM=07; E2FSPROGS_MONTH="July" ;;
  36 Aug)    MONTH_NUM=08; E2FSPROGS_MONTH="August" ;;
  37 Sep)    MONTH_NUM=09; E2FSPROGS_MONTH="September" ;;
  38 Oct)    MONTH_NUM=10; E2FSPROGS_MONTH="October" ;;
  39 Nov)    MONTH_NUM=11; E2FSPROGS_MONTH="November" ;;
  40 Dec)    MONTH_NUM=12; E2FSPROGS_MONTH="December" ;;
  41 *)      AC_MSG_WARN([Unknown month $MONTH??]) ;;
  42 esac
  43
  44 base_ver=`echo $E2FSPROGS_VERSION | \
  45                sed -e 's/-WIP//' -e 's/pre-//' -e 's/-PLUS//'`
  46
  47 date_spec=${E2FSPROGS_YEAR}.${MONTH_NUM}.${E2FSPROGS_DAY}
  48
  49 case $E2FSPROGS_VERSION in
  50 *-WIP|pre-*)
  51         E2FSPROGS_PKGVER="$base_ver~WIP-$E2FSPROGS_YEAR-$MONTH_NUM-$E2FSPROGS_DAY"
  52         ;;
  53 *)
  54         E2FSPROGS_PKGVER="$base_ver"
  55         ;;
  56 esac
  57
  58 unset DATE MONTH YEAR base_ver pre_vers date_spec
  59 AC_MSG_RESULT([Generating configuration file for e2fsprogs version $E2FSPROGS_VERSION])
  60 AC_MSG_RESULT([Release date is ${E2FSPROGS_MONTH}, ${E2FSPROGS_YEAR}])
  61 AC_SUBST(E2FSPROGS_YEAR)
  62 AC_SUBST(E2FSPROGS_MONTH)
  63 AC_SUBST(E2FSPROGS_DAY)
  64 AC_SUBST(E2FSPROGS_VERSION)
  65 AC_SUBST(E2FSPROGS_PKGVER)
  66 AC_CANONICAL_HOST
  67 dnl
  68 dnl Check to see if libdl exists for the sake of dlopen
  69 dnl
  70 DLOPEN_LIB=''
  71 AC_CHECK_LIB(dl, dlopen,
  72 [DLOPEN_LIB=-ldl
  73 AC_DEFINE(HAVE_DLOPEN, 1, [Define to 1 if dlopen/libdl exists])])
  74 AC_SUBST(DLOPEN_LIB)
  75 dnl
  76 dnl Use diet libc
  77 dnl
  78 WITH_DIET_LIBC=
  79 AC_ARG_WITH([diet-libc],
  80 [  --with-diet-libc        use diet libc],
  81 CC="diet cc -nostdinc"
  82 WITH_DIET_LIBC=yes
  83 AC_MSG_RESULT(CC=$CC))dnl
  84 dnl
  85 AC_ARG_WITH([cc],
  86 AC_HELP_STRING([--with-cc],[no longer supported, use CC= instead]),
  87 AC_MSG_ERROR([--with-cc no longer supported; use CC= instead]))
  88 dnl
  89 AC_ARG_WITH([ccopts],
  90 AC_HELP_STRING([--with-ccopts],[no longer supported, use CFLAGS= instead]),
  91 AC_MSG_ERROR([--with-ccopts no longer supported; use CFLAGS= instead]))
  92 dnl
  93 AC_ARG_WITH([ldopts],
  94 AC_HELP_STRING([--with-ldopts],[no longer supported, use LDFLAGS= instead]),
  95 AC_MSG_ERROR([--with-ldopts no longer supported; use LDFLAGS= instead]))
  96 dnl
  97 AC_PROG_CC
  98 if test "$GCC" = yes; then
  99    RDYNAMIC="-rdynamic"
 100    AC_SUBST(RDYNAMIC)
 101 fi
 102 AC_PROG_CPP
 103 dnl
 104 dnl Alpha computers use fast and imprecise floating point code that may
 105 dnl miss exceptions by default. Force sane options if we're using GCC.
 106 AC_MSG_CHECKING(for additional special compiler flags)
 107 if test "$GCC" = yes
 108 then
 109     case "$host_cpu" in
 110         alpha)          addcflags="-mieee" ;;
 111     esac
 112 fi
 113 if test "x$addcflags" != x
 114 then
 115     AC_MSG_RESULT($addcflags)
 116     CFLAGS="$addcflags $CFLAGS"
 117 else
 118     AC_MSG_RESULT([[(none)]])
 119 fi
 120 dnl
 121 dnl Set default values for library extentions.  Will be dealt with after
 122 dnl parsing configuration opions, which may modify these
 123 dnl
 124 LIB_EXT=.a
 125 STATIC_LIB_EXT=.a
 126 PROFILED_LIB_EXT=.a
 127 dnl
 128 dnl Allow separate `root_prefix' to be specified
 129 dnl
 130 AC_ARG_WITH([root-prefix],
 131 [  --with-root-prefix=PREFIX override prefix variable for files to be placed in the root],
 132 root_prefix=$withval,
 133 root_prefix=NONE)dnl
 134 dnl
 135 dnl handle --enable-maintainer-mode
 136 dnl
 137 AC_ARG_ENABLE([maintainer-mode],
 138 [  --enable-maintainer-mode enable makefile rules useful for maintainers],
 139 if test "$enableval" = "no"
 140 then
 141         MAINTAINER_CMT=#
 142         AC_MSG_RESULT([Disabling maintainer mode])
 143 else
 144         MAINTAINER_CMT=
 145         AC_MSG_RESULT([Enabling maintainer mode])
 146 fi
 147 ,
 148 MAINTAINER_CMT=#
 149 AC_MSG_RESULT([Disabling maintainer mode by default])
 150 )
 151 AC_SUBST(MAINTAINER_CMT)
 152 dnl
 153 dnl handle --enable-symlink-install
 154 dnl
 155 AC_ARG_ENABLE([symlink-install],
 156 [  --enable-symlink-install use symlinks when installing instead of hard links],
 157 if test "$enableval" = "no"
 158 then
 159         LINK_INSTALL_FLAGS=-f
 160         AC_MSG_RESULT([Disabling symlinks for install])
 161 else
 162         LINK_INSTALL_FLAGS=-sf
 163         AC_MSG_RESULT([Enabling symlinks for install])
 164 fi
 165 ,
 166 LINK_INSTALL_FLAGS=-f
 167 AC_MSG_RESULT([Disabling symlinks for install by default])
 168 )
 169 AC_SUBST(LINK_INSTALL_FLAGS)
 170 dnl
 171 dnl handle --enable-relative-symlinks
 172 dnl
 173 relative_symlink_defined=
 174 AC_ARG_ENABLE([relative-symlinks],
 175 [  --enable-relative-symlinks use relative symlinks when installing],
 176 if test "$enableval" = "no"
 177 then
 178         SYMLINK_RELATIVE=
 179         relative_symlink_defined=yes
 180         AC_MSG_RESULT([Disabling relative symlinks for install])
 181 else
 182         SYMLINK_RELATIVE=--relative
 183         relative_symlink_defined=yes
 184         AC_MSG_RESULT([Enabling relative symlinks for install])
 185 fi)
 186 AC_ARG_ENABLE([symlink-relative-symlinks],,
 187 if test "$enableval" = "no"
 188 then
 189         SYMLINK_RELATIVE=yes
 190         AC_MSG_RESULT([Disabling relative symlinks for install])
 191 else
 192         SYMLINK_RELATIVE=--relative
 193         AC_MSG_RESULT([Enabling relative symlinks for install])
 194 fi
 195 ,
 196 if test -z "$relative_symlink_defined"
 197 then
 198         SYMLINK_RELATIVE=
 199 AC_MSG_RESULT([Disabling relative symlinks for install by default])
 200 fi
 201 )
 202 AC_SUBST(SYMLINK_RELATIVE)
 203 dnl
 204 dnl handle --enable-symlink-build
 205 dnl
 206 AC_ARG_ENABLE([symlink-build],
 207 [  --enable-symlink-build  use symlinks while building instead of hard links],
 208 if test "$enableval" = "no"
 209 then
 210         LINK_BUILD_FLAGS=
 211         AC_MSG_RESULT([Disabling symlinks for build])
 212 else
 213         LINK_BUILD_FLAGS=-s
 214         AC_MSG_RESULT([Enabling symlinks for build])
 215 fi
 216 ,
 217 LINK_BUILD_FLAGS=
 218 AC_MSG_RESULT([Disabling symlinks for build by default])
 219 )
 220 AC_SUBST(LINK_BUILD_FLAGS)
 221 dnl
 222 dnl handle --enable-verbose-makecmds
 223 dnl
 224 AC_ARG_ENABLE([verbose-makecmds],
 225 [  --enable-verbose-makecmds enable verbose make command output],
 226 if test "$enableval" = "no"
 227 then
 228         AC_MSG_RESULT([Disabling verbose make commands])
 229         E=@echo
 230         ES=echo
 231         Q=@
 232 else
 233         AC_MSG_RESULT([Enabling verbose make commands])
 234         E=@\\#
 235         ES=\\#
 236         Q=
 237 fi
 238 ,
 239 AC_MSG_RESULT([Disabling verbose make commands])
 240 E=@echo
 241 ES=echo
 242 Q=@
 243 )
 244 AC_SUBST(E)
 245 AC_SUBST(ES)
 246 AC_SUBST(Q)
 247 dnl
 248 dnl handle --enable-compression
 249 dnl
 250 AC_ARG_ENABLE([compression],
 251 [  --enable-compression   enable EXPERIMENTAL compression support],
 252 if test "$enableval" = "no"
 253 then
 254         AC_MSG_RESULT([Disabling compression support])
 255 else
 256         AC_DEFINE(ENABLE_COMPRESSION, 1,
 257                 [Define to 1 if ext2 compression enabled])
 258         AC_MSG_RESULT([Enabling compression support])
 259         AC_MSG_WARN([Compression support is experimental])
 260 fi
 261 ,
 262 AC_MSG_RESULT([Disabling compression support by default])
 263 )
 264 dnl
 265 dnl handle --enable-htree
 266 dnl
 267 AH_TEMPLATE([ENABLE_HTREE], [Define to 1 if ext3/4 htree support enabled])
 268 AC_ARG_ENABLE([htree],
 269 [  --enable-htree         enable EXPERIMENTAL htree directory support],
 270 if test "$enableval" = "no"
 271 then
 272         HTREE_CMT=#
 273         AC_MSG_RESULT([Disabling htree directory support])
 274 else
 275         HTREE_CMT=
 276         AC_DEFINE(ENABLE_HTREE, 1)
 277         AC_MSG_RESULT([Enabling htree directory support])
 278 fi
 279 ,
 280 HTREE_CMT=
 281 AC_DEFINE(ENABLE_HTREE, 1)
 282 AC_MSG_RESULT([Enabling htree directory support by default])
 283 )
 284 AC_SUBST(HTREE_CMT)
 285 dnl
 286 dnl This needs to be before all of the --enable-*-shlibs options
 287 dnl
 288 E2_PKG_CONFIG_STATIC=--static
 289 LDFLAG_DYNAMIC=
 290 PRIVATE_LIBS_CMT=
 291 dnl
 292 dnl handle --enable-elf-shlibs
 293 dnl
 294 AC_ARG_ENABLE([elf-shlibs],
 295 [  --enable-elf-shlibs    select ELF shared libraries],
 296 if test "$enableval" = "no"
 297 then
 298         ELF_CMT=#
 299         MAKEFILE_ELF=/dev/null
 300         AC_MSG_RESULT([Disabling ELF shared libraries])
 301 else
 302         E2_PKG_CONFIG_STATIC=
 303         ELF_CMT=
 304         MAKEFILE_ELF=$srcdir/lib/Makefile.elf-lib
 305         [case "$host_os" in
 306         solaris2.*)
 307                 MAKEFILE_ELF=$srcdir/lib/Makefile.solaris-lib
 308         ;;
 309         esac]
 310         BINARY_TYPE=elfbin
 311         LIB_EXT=.so
 312         PRIVATE_LIBS_CMT=#
 313         LDFLAG_DYNAMIC=['-Wl,-rpath-link,$(top_builddir)/lib']
 314         AC_MSG_RESULT([Enabling ELF shared libraries])
 315 fi
 316 ,
 317 MAKEFILE_ELF=/dev/null
 318 ELF_CMT=#
 319 AC_MSG_RESULT([Disabling ELF shared libraries by default])
 320 )
 321 AC_SUBST(ELF_CMT)
 322 AC_SUBST_FILE(MAKEFILE_ELF)
 323 dnl
 324 dnl handle --enable-bsd-shlibs
 325 dnl
 326 AC_ARG_ENABLE([bsd-shlibs],
 327 [  --enable-bsd-shlibs    select BSD shared libraries],
 328 if test "$enableval" = "no"
 329 then
 330         BSDLIB_CMT=#
 331         MAKEFILE_BSDLIB=/dev/null
 332         AC_MSG_RESULT([Disabling BSD shared libraries])
 333 else
 334         E2_PKG_CONFIG_STATIC=
 335         BSDLIB_CMT=
 336         MAKEFILE_BSDLIB=$srcdir/lib/Makefile.bsd-lib
 337         LIB_EXT=.so
 338         [case "$host_os" in
 339         darwin*)
 340                 MAKEFILE_BSDLIB=$srcdir/lib/Makefile.darwin-lib
 341                 LIB_EXT=.dylib
 342         ;;
 343         esac]
 344         AC_MSG_RESULT([Enabling BSD shared libraries])
 345 fi
 346 ,
 347 MAKEFILE_BSDLIB=/dev/null
 348 BSDLIB_CMT=#
 349 AC_MSG_RESULT([Disabling BSD shared libraries by default])
 350 )
 351 AC_SUBST(BSDLIB_CMT)
 352 AC_SUBST_FILE(MAKEFILE_BSDLIB)
 353 dnl
 354 dnl handle --enable-profile
 355 dnl
 356 AC_ARG_ENABLE([profile],
 357 [  --enable-profile       build profiling libraries],
 358 if test "$enableval" = "no"
 359 then
 360         PROFILE_CMT=#
 361         MAKEFILE_PROFILE=/dev/null
 362         AC_MSG_RESULT([Disabling profiling libraries])
 363 else
 364         PROFILE_CMT=
 365         MAKEFILE_PROFILE=$srcdir/lib/Makefile.profile
 366         PROFILED_LIB_EXT=_p.a
 367         AC_MSG_RESULT([Building profiling libraries])
 368 fi
 369 ,
 370 PROFILE_CMT=#
 371 MAKEFILE_PROFILE=/dev/null
 372 AC_MSG_RESULT([Disabling profiling libraries by default])
 373 )
 374 AC_SUBST(PROFILE_CMT)
 375 AC_SUBST_FILE(MAKEFILE_PROFILE)
 376 dnl
 377 dnl handle --enable-checker
 378 dnl
 379 AC_ARG_ENABLE([checker],
 380 [  --enable-checker       build checker libraries],
 381 if test "$enableval" = "no"
 382 then
 383         CHECKER_CMT=#
 384         MAKEFILE_CHECKER=/dev/null
 385         AC_MSG_RESULT([Disabling checker libraries])
 386 else
 387         CHECKER_CMT=
 388         MAKEFILE_CHECKER=$srcdir/lib/Makefile.checker
 389         AC_MSG_RESULT([Building checker libraries])
 390 fi
 391 ,
 392 CHECKER_CMT=#
 393 MAKEFILE_CHECKER=/dev/null
 394 AC_MSG_RESULT([Disabling checker libraries by default])
 395 )
 396 AC_SUBST(CHECKER_CMT)
 397 AC_SUBST_FILE(MAKEFILE_CHECKER)
 398 dnl
 399 dnl Substitute library extensions
 400 dnl
 401 AC_SUBST(LIB_EXT)
 402 AC_SUBST(STATIC_LIB_EXT)
 403 AC_SUBST(PROFILED_LIB_EXT)
 404 AC_SUBST(LDFLAG_DYNAMIC)
 405 AC_SUBST(PRIVATE_LIBS_CMT)
 406 dnl
 407 dnl handle --enable-jbd-debug
 408 dnl
 409 AC_ARG_ENABLE([jbd-debug],
 410 [  --enable-jbd-debug     enable journal debugging],
 411 if test "$enableval" = "no"
 412 then
 413         AC_MSG_RESULT([Disabling journal debugging])
 414 else
 415         AC_DEFINE(CONFIG_JBD_DEBUG, 1,
 416                 [Define to 1 if debugging ext3/4 journal code])
 417         AC_MSG_RESULT([Enabling journal debugging])
 418 fi
 419 ,
 420 AC_MSG_RESULT([Disabling journal debugging by default])
 421 )
 422 dnl
 423 dnl handle --enable-blkid-debug
 424 dnl
 425 AC_ARG_ENABLE([blkid-debug],
 426 [  --enable-blkid-debug    enable blkid debugging],
 427 if test "$enableval" = "no"
 428 then
 429         AC_MSG_RESULT([Disabling blkid debugging])
 430 else
 431         AC_DEFINE(CONFIG_BLKID_DEBUG, 1,
 432                 [Define to 1 if debugging the blkid library])
 433         AC_MSG_RESULT([Enabling blkid debugging])
 434 fi
 435 ,
 436 AC_MSG_RESULT([Disabling blkid debugging by default])
 437 )
 438 dnl
 439 dnl handle --enable-testio-debug
 440 dnl
 441 AC_ARG_ENABLE([testio-debug],
 442 [  --disable-testio-debug  disable the use of the test I/O manager for debugging],
 443 AH_TEMPLATE([CONFIG_TESTIO_DEBUG],
 444         [Define to 1 if the testio I/O manager should be enabled])
 445 if test "$enableval" = "no"
 446 then
 447         AC_MSG_RESULT([Disabling testio debugging])
 448         TEST_IO_CMT="#"
 449 else
 450         TEST_IO_CMT=
 451         AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 452         AC_MSG_RESULT([Enabling testio debugging])
 453 fi
 454 ,
 455 AC_MSG_RESULT([Enabling testio debugging by default])
 456 AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 457 TEST_IO_CMT=
 458 )
 459 AC_SUBST(TEST_IO_CMT)
 460 dnl
 461 dnl handle --disable-libuuid
 462 dnl
 463 PKG_PROG_PKG_CONFIG
 464 LIBUUID=
 465 DEPLIBUUID=
 466 STATIC_LIBUUID=
 467 DEPSTATIC_LIBUUID=
 468 PROFILED_LIBUUID=
 469 DEPPROFILED_LIBUUID=
 470 UUID_CMT=
 471 AC_ARG_ENABLE([libuuid],
 472 [  --disable-libuuid      do not build private uuid library],
 473 if test "$enableval" = "no"
 474 then
 475         if test -z "$PKG_CONFIG"; then
 476                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 477         fi
 478
 479         AC_CHECK_LIB(uuid, uuid_generate,
 480                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 481                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`],
 482                 [AC_MSG_ERROR([external uuid library not found])],
 483                 [$LIBUUID])
 484         UUID_CMT=#
 485         AC_MSG_RESULT([Disabling private uuid library])
 486 else
 487         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 488         DEPLIBUUID=$LIBUUID
 489         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 490         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 491         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 492         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 493         AC_MSG_RESULT([Enabling private uuid library])
 494 fi
 495 ,
 496 LIBUUID='$(LIB)/libuuid'$LIB_EXT
 497 DEPLIBUUID=$LIBUUID
 498 STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 499 DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 500 PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 501 DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 502 AC_MSG_RESULT([Enabling private uuid library by default])
 503 )
 504 AC_SUBST(LIBUUID)
 505 AC_SUBST(DEPLIBUUID)
 506 AC_SUBST(STATIC_LIBUUID)
 507 AC_SUBST(DEPSTATIC_LIBUUID)
 508 AC_SUBST(PROFILED_LIBUUID)
 509 AC_SUBST(DEPPROFILED_LIBUUID)
 510 AC_SUBST(UUID_CMT)
 511 dnl
 512 dnl handle --disable-libblkid
 513 dnl
 514 PKG_PROG_PKG_CONFIG
 515 LIBBLKID=
 516 DEPLIBBLKID=
 517 STATIC_LIBBLKID=
 518 DEPSTATIC_LIBBLKID=
 519 PROFILED_LIBBLKID=
 520 DEPPROFILED_LIBBLKID=
 521 BLKID_CMT=
 522 AH_TEMPLATE([CONFIG_BUILD_FINDFS], [Define to 1 to compile findfs])
 523 AC_ARG_ENABLE([libblkid],
 524 [  --disable-libblkid     do not build private blkid library],
 525 if test "$enableval" = "no"
 526 then
 527         if test -z "$PKG_CONFIG"; then
 528                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 529         fi
 530
 531         AC_CHECK_LIB(blkid, blkid_get_cache,
 532                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 533                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`],
 534                 [AC_MSG_ERROR([external blkid library not found])],
 535                 [$LIBBLKID])
 536         BLKID_CMT=#
 537         AC_MSG_RESULT([Disabling private blkid library])
 538 else
 539         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 540         DEPLIBBLKID=$LIBBLKID
 541         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 542         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 543         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 544         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 545         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 546         AC_MSG_RESULT([Enabling private blkid library])
 547 fi
 548 ,
 549 LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 550 DEPLIBBLKID=$LIBBLKID
 551 STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 552 DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 553 PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 554 DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 555 AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 556 AC_MSG_RESULT([Enabling private blkid library by default])
 557 )
 558 AC_SUBST(LIBBLKID)
 559 AC_SUBST(DEPLIBBLKID)
 560 AC_SUBST(STATIC_LIBBLKID)
 561 AC_SUBST(DEPSTATIC_LIBBLKID)
 562 AC_SUBST(PROFILED_LIBBLKID)
 563 AC_SUBST(DEPPROFILED_LIBBLKID)
 564 AC_SUBST(BLKID_CMT)
 565 dnl
 566 dnl handle --enable-quota
 567 dnl
 568 PKG_PROG_PKG_CONFIG
 569 AH_TEMPLATE([CONFIG_QUOTA], [Define to 1 to enable quota support])
 570 AC_ARG_ENABLE([quota],
 571 [  --enable-quota         enable quota support],
 572 if test "$enableval" = "no"
 573 then
 574         AC_MSG_RESULT([Disabling quota support])
 575 else
 576         AC_DEFINE(CONFIG_QUOTA, 1)
 577         AC_MSG_RESULT([Enabling quota support])
 578 fi
 579 ,
 580 AC_MSG_RESULT([Disabling quota support by default])
 581 )
 582 dnl
 583 dnl Define stuff expected for quota library
 584 dnl
 585 LIBQUOTA='$(LIB)/libquota'$LIB_EXT
 586 DEPLIBQUOTA=$LIBQUOTA
 587 STATIC_LIBQUOTA='$(LIB)/libquota'$STATIC_LIB_EXT
 588 DEPSTATIC_LIBQUOTA=$STATIC_LIBQUOTA
 589 PROFILED_LIBQUOTA='$(LIB)/libquota'$PROFILED_LIB_EXT
 590 DEPPROFILED_LIBQUOTA=$PROFILED_LIBQUOTA
 591 AC_SUBST(LIBQUOTA)
 592 AC_SUBST(DEPLIBQUOTA)
 593 AC_SUBST(STATIC_LIBQUOTA)
 594 AC_SUBST(DEPSTATIC_LIBQUOTA)
 595 AC_SUBST(PROFILED_LIBQUOTA)
 596 AC_SUBST(DEPPROFILED_LIBQUOTA)
 597 AC_SUBST(QUOTA_CMT)
 598 dnl
 599 dnl handle --disable-backtrace
 600 dnl
 601 AH_TEMPLATE([DISABLE_BACKTRACE], [Define to 1 to disable use of backtrace])
 602 AC_ARG_ENABLE([backtrace],
 603 [  --disable-backtrace    disable use backtrace],
 604 if test "$enableval" = "no"
 605 then
 606         AC_MSG_RESULT([Disabling use of backtrace])
 607         AC_DEFINE(DISABLE_BACKTRACE, 1)
 608 else
 609         AC_MSG_RESULT([Enabling use of backtrace])
 610 fi
 611 ,
 612 AC_MSG_RESULT([Enabling use of backtrace by default])
 613 )
 614 dnl
 615 dnl handle --enable-debugfs
 616 dnl
 617 AC_ARG_ENABLE([debugfs],
 618 [  --disable-debugfs      disable support of debugfs program],
 619 if test "$enableval" = "no"
 620 then
 621         AC_MSG_RESULT([Disabling debugfs support])
 622         DEBUGFS_CMT="#"
 623 else
 624         DEBUGFS_CMT=
 625         AC_MSG_RESULT([Enabling debugfs support])
 626 fi
 627 ,
 628 AC_MSG_RESULT([Enabling debugfs support by default])
 629 DEBUGFS_CMT=
 630 )
 631 AC_SUBST(DEBUGFS_CMT)
 632 dnl
 633 dnl handle --enable-imager
 634 dnl
 635 AC_ARG_ENABLE([imager],
 636 [  --disable-imager       disable support of e2image program],
 637 if test "$enableval" = "no"
 638 then
 639         AC_MSG_RESULT([Disabling e2image support])
 640         IMAGER_CMT="#"
 641 else
 642         IMAGER_CMT=
 643         AC_MSG_RESULT([Enabling e2image support])
 644 fi
 645 ,
 646 AC_MSG_RESULT([Enabling e2image support by default])
 647 IMAGER_CMT=
 648 )
 649 AC_SUBST(IMAGER_CMT)
 650 dnl
 651 dnl handle --enable-resizer
 652 dnl
 653 AC_ARG_ENABLE([resizer],
 654 [  --disable-resizer      disable support of e2resize program],
 655 if test "$enableval" = "no"
 656 then
 657         AC_MSG_RESULT([Disabling e2resize support])
 658         RESIZER_CMT="#"
 659 else
 660         RESIZER_CMT=
 661         AC_MSG_RESULT([Enabling e2resize support])
 662 fi
 663 ,
 664 AC_MSG_RESULT([Enabling e2resize support by default])
 665 RESIZER_CMT=
 666 )
 667 AC_SUBST(RESIZER_CMT)
 668 dnl
 669 dnl handle --enable-defrag
 670 dnl
 671 AC_ARG_ENABLE([defrag],
 672 [  --disable-defrag       disable support of e4defrag program],
 673 if test "$enableval" = "no"
 674 then
 675         AC_MSG_RESULT([Disabling e4defrag support])
 676         DEFRAG_CMT="#"
 677 else
 678         DEFRAG_CMT=
 679         AC_MSG_RESULT([Enabling e4defrag support])
 680 fi
 681 ,
 682 AC_MSG_RESULT([Enabling e4defrag support by default])
 683 DEFRAG_CMT=
 684 )
 685 AC_SUBST(DEFRAG_CMT)
 686 dnl
 687 dnl See whether to install the `fsck' wrapper program (that calls e2fsck)
 688 dnl
 689 AC_ARG_ENABLE([fsck],
 690 [  --enable-fsck           build fsck wrapper program],
 691 [if test "$enableval" = "no"
 692 then
 693         FSCK_PROG='' FSCK_MAN=''
 694         AC_MSG_RESULT([Not building fsck wrapper])
 695 else
 696         FSCK_PROG=fsck FSCK_MAN=fsck.8
 697         AC_MSG_RESULT([Building fsck wrapper])
 698 fi]
 699 ,
 700 [case "$host_os" in
 701   gnu*)
 702     FSCK_PROG='' FSCK_MAN=''
 703     AC_MSG_RESULT([Not building fsck wrapper by default])
 704     ;;
 705   *)
 706     FSCK_PROG=fsck FSCK_MAN=fsck.8
 707     AC_MSG_RESULT([Building fsck wrapper by default])
 708 esac]
 709 )
 710 AC_SUBST(FSCK_PROG)
 711 AC_SUBST(FSCK_MAN)
 712 dnl
 713 dnl See whether to install the `e2initrd-helper' program
 714 dnl
 715 AC_ARG_ENABLE([e2initrd-helper],
 716 [  --enable-e2initrd-helper build e2initrd-helper program],
 717 [if test "$enableval" = "no"
 718 then
 719         E2INITRD_PROG='' E2INITRD_MAN=''
 720         AC_MSG_RESULT([Not building e2initrd helper])
 721 else
 722         E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 723         AC_MSG_RESULT([Building e2initrd helper])
 724 fi]
 725 ,
 726 E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 727 AC_MSG_RESULT([Building e2initrd helper by default])
 728 )
 729 AC_SUBST(E2INITRD_PROG)
 730 AC_SUBST(E2INITRD_MAN)
 731 dnl
 732 dnl
 733 dnl
 734 AC_ARG_ENABLE([tls],
 735 [  --disable-tls           disable use of thread local support],
 736 [if test "$enableval" = "no"
 737 then
 738         try_tls=""
 739         AC_MSG_RESULT([Disabling thread local support])
 740 else
 741         try_tls="yes"
 742         AC_MSG_RESULT([Enabling thread local support])
 743 fi]
 744 ,
 745 if test -n "$WITH_DIET_LIBC"
 746 then
 747         try_tls=""
 748         AC_MSG_RESULT([Diet libc does not support thread local support])
 749 else
 750         try_tls="yes"
 751         AC_MSG_RESULT([Try using thread local support by default])
 752 fi
 753 )
 754 if test "$try_tls" = "yes"
 755 then
 756 AX_TLS
 757 fi
 758 dnl
 759 dnl
 760 dnl
 761 AH_TEMPLATE([USE_UUIDD], [Define to 1 to build uuidd])
 762 AC_ARG_ENABLE([uuidd],
 763 [  --disable-uuidd         disable building the uuid daemon],
 764 [if test "$enableval" = "no"
 765 then
 766         AC_MSG_RESULT([Not building uuidd])
 767         UUIDD_CMT="#"
 768 else
 769         AC_DEFINE(USE_UUIDD, 1)
 770         UUIDD_CMT=""
 771         AC_MSG_RESULT([Building uuidd])
 772 fi]
 773 ,
 774 AC_DEFINE(USE_UUIDD, 1)
 775 UUIDD_CMT=""
 776 AC_MSG_RESULT([Building uuidd by default])
 777 )
 778 AC_SUBST(UUIDD_CMT)
 779 dnl
 780 dnl
 781 dnl
 782 MAKEFILE_LIBRARY=$srcdir/lib/Makefile.library
 783 AC_SUBST_FILE(MAKEFILE_LIBRARY)
 784 dnl
 785 dnl Add internationalization support, using gettext.
 786 dnl
 787 GETTEXT_PACKAGE=e2fsprogs
 788 PACKAGE=e2fsprogs
 789 VERSION="$E2FSPROGS_VERSION"
 790 VERSION=0.14.1
 791 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [package name for gettext])
 792 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [version for gettext])
 793 AC_SUBST(GETTEXT_PACKAGE)
 794 AC_SUBST(PACKAGE)
 795 AC_SUBST(VERSION)
 796
 797 AM_GNU_GETTEXT
 798 dnl
 799 dnl End of configuration options
 800 dnl
 801 AC_SUBST(BINARY_TYPE)
 802 AC_PROG_MAKE_SET
 803 CHECK_GNU_MAKE
 804 AC_PATH_PROG(LN, ln, ln)
 805 AC_PROG_LN_S
 806 AC_PATH_PROG(MV, mv, mv)
 807 AC_PATH_PROG(CP, cp, cp)
 808 AC_PATH_PROG(RM, rm, rm)
 809 AC_PATH_PROG(CHMOD, chmod, :)
 810 AC_PROG_AWK
 811 AC_PROG_EGREP
 812 AC_PATH_PROG(SED, sed, sed)
 813 AC_PATH_PROG(PERL, perl, perl)
 814 AC_PATH_PROG(LDCONFIG, ldconfig, :)
 815 AC_CHECK_TOOL(AR, ar, ar)
 816 AC_CHECK_TOOL(RANLIB, ranlib, :)
 817 AC_CHECK_TOOL(STRIP, strip, :)
 818 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
 819 if test "_$MAKEINFO" = "_"; then
 820     MAKEINFO="@echo Makeinfo is missing. Info documentation will not be built.;true"
 821 else
 822     case "$MAKEINFO" in
 823       */missing.*)
 824         AC_MSG_WARN([
 825 *** Makeinfo is missing. Info documentation will not be built.])
 826         ;;
 827       *)
 828         ;;
 829     esac
 830 fi
 831 AC_SUBST(MAKEINFO)
 832 AC_PROG_INSTALL
 833 # See if we need a separate native compiler.
 834 if test $cross_compiling = no; then
 835   BUILD_CC="$CC"
 836   AC_SUBST(BUILD_CC)
 837 else
 838   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 839 fi
 840 AC_CHECK_HEADERS(m4_flatten([
 841         dirent.h
 842         errno.h
 843         execinfo.h
 844         getopt.h
 845         malloc.h
 846         mntent.h
 847         paths.h
 848         semaphore.h
 849         setjmp.h
 850         signal.h
 851         stdarg.h
 852         stdint.h
 853         stdlib.h
 854         termios.h
 855         termio.h
 856         unistd.h
 857         utime.h
 858         linux/falloc.h
 859         linux/fd.h
 860         linux/major.h
 861         net/if_dl.h
 862         netinet/in.h
 863         sys/disklabel.h
 864         sys/file.h
 865         sys/ioctl.h
 866         sys/mkdev.h
 867         sys/mman.h
 868         sys/prctl.h
 869         sys/queue.h
 870         sys/resource.h
 871         sys/select.h
 872         sys/socket.h
 873         sys/sockio.h
 874         sys/stat.h
 875         sys/syscall.h
 876         sys/sysmacros.h
 877         sys/time.h
 878         sys/types.h
 879         sys/un.h
 880         sys/wait.h
 881 ]))
 882 AC_CHECK_HEADERS(sys/disk.h sys/mount.h,,,
 883 [[
 884 #if HAVE_SYS_QUEUE_H
 885 #include <sys/queue.h>
 886 #endif
 887 ]])
 888 AC_CHECK_HEADERS(net/if.h,,,
 889 [[
 890 #if HAVE_SYS_TYPES_H
 891 #include <sys/types.h>
 892 #endif
 893 #if HAVE_SYS_SOCKET
 894 #include <sys/socket.h>
 895 #endif
 896 ]])
 897 AC_FUNC_VPRINTF
 898 dnl Check to see if dirent has member d_reclen. On cygwin those d_reclen
 899 dnl is not decleared.
 900 AC_CHECK_MEMBER(struct dirent.d_reclen,[AC_DEFINE(HAVE_RECLEN_DIRENT, 1,
 901                        [Define to 1 if dirent has d_reclen])],,
 902                 [#include <dirent.h>])
 903 dnl Check to see if ssize_t was declared
 904 AC_CHECK_TYPE(ssize_t,[AC_DEFINE(HAVE_TYPE_SSIZE_T, 1,
 905                 [Define to 1 if ssize_t declared])],,
 906               [#include <sys/types.h>])
 907 dnl
 908 dnl Check to see if llseek() is declared in unistd.h.  On some libc's
 909 dnl it is, and on others it isn't..... Thank you glibc developers....
 910 dnl
 911 AC_CHECK_DECL(llseek,[AC_DEFINE(HAVE_LLSEEK_PROTOTYPE, 1,
 912                         [Define to 1 if llseek declared in unistd.h])],,
 913               [#include <unistd.h>])
 914 dnl
 915 dnl Check to see if lseek64() is declared in unistd.h.  Glibc's header files
 916 dnl are so convoluted that I can't tell whether it will always be defined,
 917 dnl and if it isn't defined while lseek64 is defined in the library,
 918 dnl disaster will strike.
 919 dnl
 920 dnl Warning!  Use of --enable-gcc-wall may throw off this test.
 921 dnl
 922 dnl
 923 AC_CHECK_DECL(lseek64,[AC_DEFINE(HAVE_LSEEK64_PROTOTYPE, 1,
 924                         [Define to 1 if lseek64 declared in unistd.h])],,
 925                 [#define _LARGEFILE_SOURCE
 926                  #define _LARGEFILE64_SOURCE
 927                  #include <unistd.h>])
 928 dnl
 929 dnl Word sizes...
 930 dnl
 931 AC_CHECK_SIZEOF(short)
 932 AC_CHECK_SIZEOF(int)
 933 AC_CHECK_SIZEOF(long)
 934 AC_CHECK_SIZEOF(long long)
 935 AC_CHECK_SIZEOF(off_t)
 936 SIZEOF_SHORT=$ac_cv_sizeof_short
 937 SIZEOF_INT=$ac_cv_sizeof_int
 938 SIZEOF_LONG=$ac_cv_sizeof_long
 939 SIZEOF_LONG_LONG=$ac_cv_sizeof_long_long
 940 SIZEOF_OFF_T=$ac_cv_sizeof_off_t
 941 AC_SUBST(SIZEOF_SHORT)
 942 AC_SUBST(SIZEOF_INT)
 943 AC_SUBST(SIZEOF_LONG)
 944 AC_SUBST(SIZEOF_LONG_LONG)
 945 AC_SUBST(SIZEOF_OFF_T)
 946 AC_C_BIGENDIAN
 947 BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
 948 ASM_TYPES_HEADER=./asm_types.h
 949 AC_SUBST_FILE(ASM_TYPES_HEADER)
 950 dnl
 951 dnl Save the configuration #defines needed for the public ext2fs.h
 952 dnl header file
 953 dnl
 954 echo "/* These defines are needed for the public ext2fs.h header file */" \
 955      > public_config.h
 956 if grep HAVE_SYS_TYPES_H confdefs.h > tmp_config.$$; then
 957   uniq tmp_config.$$ >> public_config.h
 958 else
 959   echo "#undef HAVE_SYS_TYPES_H" >> public_config.h
 960 fi
 961 if grep WORDS_BIGENDIAN confdefs.h > tmp_config.$$; then
 962   uniq tmp_config.$$ >> public_config.h
 963 else
 964   echo "#undef WORDS_BIGENDIAN" >> public_config.h
 965 fi
 966 rm -f tmp_config.$$
 967 PUBLIC_CONFIG_HEADER=./public_config.h
 968 AC_SUBST_FILE(PUBLIC_CONFIG_HEADER)
 969 dnl
 970 dnl See if we have inttypes.h and if intptr_t is defined
 971 dnl
 972 AC_CHECK_HEADERS([inttypes.h])
 973 AC_CHECK_TYPES(intptr_t)
 974 dnl
 975 dnl See if struct stat has a st_flags field, in which case we can get file
 976 dnl flags somewhat portably.  Also check for the analogous setter, chflags().
 977 dnl
 978 AC_MSG_CHECKING(whether struct stat has a st_flags field)
 979 AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags,
 980         AC_TRY_COMPILE([#include <sys/stat.h>],
 981                 [struct stat stat; stat.st_flags = 0;],
 982                 [e2fsprogs_cv_struct_st_flags=yes],
 983                 [e2fsprogs_cv_struct_st_flags=no]))
 984 AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags)
 985 if test "$e2fsprogs_cv_struct_st_flags" = yes; then
 986   AC_MSG_CHECKING(whether st_flags field is useful)
 987   AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags_immut,
 988         AC_TRY_COMPILE([#include <sys/stat.h>],
 989                 [struct stat stat; stat.st_flags |= UF_IMMUTABLE;],
 990                 [e2fsprogs_cv_struct_st_flags_immut=yes],
 991                 [e2fsprogs_cv_struct_st_flags_immut=no]))
 992   AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags_immut)
 993   if test "$e2fsprogs_cv_struct_st_flags_immut" = yes; then
 994           AC_DEFINE(HAVE_STAT_FLAGS, 1,
 995                 [Define to 1 if struct stat has st_flags])
 996   fi
 997 fi
 998 dnl
 999 dnl Check for the presence of SA_LEN
1000 dnl
1001 AC_CHECK_MEMBER(struct sockaddr.sa_len,
1002                 AC_DEFINE_UNQUOTED(HAVE_SA_LEN,1,
1003                         [Define to 1 if if struct sockaddr contains sa_len]),,
1004         [#include <sys/types.h>
1005          #include <sys/socket.h>])
1006 dnl
1007 dnl This will add -lblkid to the AC_CHECK_FUNCS search if we are using
1008 dnl the system-provided blkid library
1009 dnl
1010 if test -n "$BLKID_CMT"; then
1011   AC_SEARCH_LIBS([blkid_probe_all], [blkid])
1012 fi
1013 dnl
1014 AC_CHECK_FUNCS(m4_flatten([
1015         __secure_getenv
1016         backtrace
1017         blkid_probe_get_topology
1018         chflags
1019         fallocate
1020         fallocate64
1021         fchown
1022         fdatasync
1023         fstat64
1024         ftruncate64
1025         getdtablesize
1026         getmntinfo
1027         getpwuid_r
1028         getrlimit
1029         getrusage
1030         jrand48
1031         llseek
1032         lseek64
1033         mallinfo
1034         mbstowcs
1035         memalign
1036         mmap
1037         msync
1038         nanosleep
1039         open64
1040         pathconf
1041         posix_fadvise
1042         posix_memalign
1043         prctl
1044         secure_getenv
1045         setmntent
1046         setresgid
1047         setresuid
1048         srandom
1049         strcasecmp
1050         strdup
1051         strnlen
1052         strptime
1053         strtoull
1054         sync_file_range
1055         sysconf
1056         usleep
1057         utime
1058         valloc
1059 ]))
1060 dnl
1061 dnl Check to see if -lsocket is required (solaris) to make something
1062 dnl that uses socket() to compile; this is needed for the UUID library
1063 dnl
1064 SOCKET_LIB=''
1065 AC_CHECK_LIB(socket, socket, [SOCKET_LIB=-lsocket])
1066 AC_SUBST(SOCKET_LIB)
1067 dnl
1068 dnl See if optreset exists
1069 dnl
1070 AC_MSG_CHECKING(for optreset)
1071 AC_CACHE_VAL(ac_cv_have_optreset,
1072 [AC_EGREP_HEADER(optreset, unistd.h,
1073   ac_cv_have_optreset=yes, ac_cv_have_optreset=no)])dnl
1074 AC_MSG_RESULT($ac_cv_have_optreset)
1075 if test $ac_cv_have_optreset = yes; then
1076   AC_DEFINE(HAVE_OPTRESET, 1, [Define to 1 if optreset for getopt is present])
1077 fi
1078 dnl
1079 dnl Test for sem_init, and which library it might require:
1080 dnl
1081 AH_TEMPLATE([HAVE_SEM_INIT], [Define to 1 if sem_init() exists])
1082 SEM_INIT_LIB=''
1083 AC_CHECK_FUNC(sem_init, ,
1084   AC_CHECK_LIB(pthread, sem_init,
1085         AC_DEFINE(HAVE_SEM_INIT, 1)
1086         SEM_INIT_LIB=-lpthread,
1087   AC_CHECK_LIB(rt, sem_init,
1088         AC_DEFINE(HAVE_SEM_INIT, 1)
1089         SEM_INIT_LIB=-lrt,
1090   AC_CHECK_LIB(posix4, sem_init,
1091         AC_DEFINE(HAVE_SEM_INIT, 1)
1092         SEM_INIT_LIB=-lposix4))))dnl
1093 AC_SUBST(SEM_INIT_LIB)
1094 dnl
1095 dnl Check for unified diff
1096 dnl
1097 AC_MSG_CHECKING(for unified diff option)
1098 if diff -u $0 $0 > /dev/null 2>&1 ; then
1099    UNI_DIFF_OPTS=-u
1100 else
1101    UNI_DIFF_OPTS=-c
1102 fi
1103 AC_MSG_RESULT($UNI_DIFF_OPTS)
1104 AC_SUBST(UNI_DIFF_OPTS)
1105 dnl
1106 dnl We use the EXT2 ioctls only under Linux
1107 dnl
1108 case "$host_os" in
1109 linux*)
1110         AC_DEFINE(HAVE_EXT2_IOCTLS, 1, [Define to 1 if Ext2 ioctls present])
1111         ;;
1112 esac
1113 dnl
1114 dnl OS-specific uncomment control
1115 dnl
1116 LINUX_CMT="#"
1117 CYGWIN_CMT="#"
1118 UNIX_CMT=
1119 case "$host_os" in
1120 linux*)
1121         LINUX_CMT=
1122         ;;
1123 cygwin)
1124         CYGWIN_CMT=
1125         UNIX_CMT="#"
1126         ;;
1127 esac
1128 AC_SUBST(LINUX_CMT)
1129 AC_SUBST(CYGWIN_CMT)
1130 AC_SUBST(UNIX_CMT)
1131 dnl
1132 dnl Linux and Hurd places root files in the / by default
1133 dnl
1134 case "$host_os" in
1135 linux* | gnu* | k*bsd*-gnu)
1136         if test "$prefix" = NONE -a "$root_prefix" = NONE ; then
1137                 root_prefix="";
1138                 AC_MSG_RESULT([On $host_os systems, root_prefix defaults to ''])
1139         fi
1140         ;;
1141 esac
1142 dnl
1143 dnl On Linux/hurd, force the prefix to be /usr
1144 dnl
1145 case "$host_os" in
1146 linux* | gnu* | k*bsd*-gnu)
1147         if test "$prefix" = NONE ; then
1148                 prefix="/usr";
1149                 AC_MSG_RESULT([On $host_os systems, prefix defaults to /usr])
1150                 if test "$mandir" = '${prefix}/man' ; then
1151                         AC_MSG_RESULT([...and mandir defaults to /usr/share/man])
1152                         mandir=/usr/share/man
1153                 fi
1154         fi
1155 ;;
1156 esac
1157 if test "$root_prefix" = NONE ; then
1158         if test "$prefix" = NONE ; then
1159                 root_prefix="$ac_default_prefix"
1160         else
1161                 root_prefix="$prefix"
1162         fi
1163         root_bindir=$bindir
1164         root_sbindir=$sbindir
1165         root_libdir=$libdir
1166         root_sysconfdir=$sysconfdir
1167 else
1168         root_bindir='${root_prefix}/bin'
1169         root_sbindir='${root_prefix}/sbin'
1170         root_libdir='${root_prefix}/lib'
1171         root_sysconfdir='${root_prefix}/etc'
1172 fi
1173 if test "$bindir" != '${exec_prefix}/bin'; then
1174     root_bindir=$bindir
1175     AC_MSG_RESULT([Setting root_bindir to $root_bindir])
1176 fi
1177 if test "$sbindir" != '${exec_prefix}/sbin'; then
1178     root_sbindir=$sbindir
1179     AC_MSG_RESULT([Setting root_sbindir to $root_sbindir])
1180 fi
1181 if test "$libdir" != '${exec_prefix}/lib'; then
1182     root_libdir=$libdir
1183     AC_MSG_RESULT([Setting root_libdir to $root_libdir])
1184 fi
1185 if test "$sysconfdir" != '${prefix}/etc'; then
1186     root_sysconfdir=$sysconfdir
1187     AC_MSG_RESULT([Setting root_sysconfdir to $root_sysconfdir])
1188 fi
1189 AC_SUBST(root_prefix)
1190 AC_SUBST(root_bindir)
1191 AC_SUBST(root_sbindir)
1192 AC_SUBST(root_libdir)
1193 AC_SUBST(root_sysconfdir)
1194 dnl
1195 dnl Allow specification of the multiarch arch
1196 dnl
1197 AC_ARG_WITH([multiarch],
1198 [  --with-multiarch=ARCH specify the multiarch triplet],
1199 libdir=$libdir/$withval
1200 root_libdir=$root_libdir/$withval
1201 )dnl
1202 dnl
1203 dnl See if -static works.  This could fail if the linker does not
1204 dnl support -static, or if required external libraries are not available
1205 dnl in static form.
1206 dnl
1207 AC_MSG_CHECKING([whether we can link with -static])
1208 AC_CACHE_VAL(ac_cv_e2fsprogs_use_static,
1209 [SAVE_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -static"
1210 AC_TRY_LINK([#include <stdio.h>],[fflush(stdout);],
1211  ac_cv_e2fsprogs_use_static=yes, ac_cv_e2fsprogs_use_static=no)
1212 LDFLAGS=$SAVE_LDFLAGS])
1213 dnl
1214 dnl Regardless of how the test turns out, Solaris doesn't handle -static
1215 dnl This is caused by the socket library requiring the nsl library, which
1216 dnl requires the -dl library, which only works for dynamically linked
1217 dnl programs.  It basically means you can't have statically linked programs
1218 dnl which use the network under Solaris.
1219 dnl
1220 case "$host_os" in
1221 solaris2.*)
1222         ac_cv_e2fsprogs_use_static=no
1223 ;;
1224 esac
1225 AC_MSG_RESULT($ac_cv_e2fsprogs_use_static)
1226 LDFLAG_STATIC=
1227 if test $ac_cv_e2fsprogs_use_static = yes; then
1228         LDFLAG_STATIC=-static
1229 fi
1230 AC_SUBST(LDFLAG_STATIC)
1231 dnl
1232 dnl Work around mysterious Darwin / GNU libintl problem
1233 dnl (__asm__ redirection doesn't work for some mysterious reason.  Looks like
1234 dnl Apple hacked gcc somehow?)
1235 dnl
1236 case "$host_os" in
1237 darwin*)
1238         AC_MSG_RESULT([Using Apple Darwin / GNU libintl workaround])
1239         AC_DEFINE(_INTL_REDIRECT_MACROS, 1,
1240                 [Define to 1 if Apple Darwin libintl workaround is needed])
1241         ;;
1242 esac
1243 dnl
1244 dnl Make the ss and et directories work correctly.
1245 dnl
1246 SS_DIR=`cd ${srcdir}/lib/ss; pwd`
1247 ET_DIR=`cd ${srcdir}/lib/et; pwd`
1248 AC_SUBST(SS_DIR)
1249 AC_SUBST(ET_DIR)
1250 dnl
1251 dnl Only try to run the test suite if we're not cross compiling.
1252 dnl
1253 if test "$cross_compiling" = yes ; then
1254   DO_TEST_SUITE=
1255 else
1256   DO_TEST_SUITE=check
1257 fi
1258 AC_SUBST(DO_TEST_SUITE)
1259 dnl
1260 dnl Only include the intl include files if we're building with them
1261 dnl
1262 INCLUDES='-I. -I$(top_builddir)/lib -I$(top_srcdir)/lib'
1263 if test -n "$CPPFLAGS" ; then
1264         INCLUDES="$INCLUDES $CPPFLAGS"
1265 fi
1266 if test "$USE_INCLUDED_LIBINTL" = "yes" ; then
1267         INCLUDES=$INCLUDES' -I$(top_builddir)/intl -I$(top_srcdir)/intl'
1268 fi
1269 AC_SUBST(INCLUDES)
1270 dnl
1271 dnl Build CFLAGS
1272 dnl
1273 if test $cross_compiling = no; then
1274    BUILD_CFLAGS="$CFLAGS $CPPFLAGS"
1275    BUILD_LDFLAGS="$LDFLAGS"
1276 else
1277    BUILD_CFLAGS=
1278    BUILD_LDFLAGS=
1279 fi
1280 AC_SUBST(BUILD_CFLAGS)
1281 AC_SUBST(BUILD_LDFLAGS)
1282 dnl
1283 dnl Make our output files, being sure that we create the some miscellaneous
1284 dnl directories
1285 dnl
1286 test -d lib || mkdir lib
1287 test -d include || mkdir include
1288 test -d include/linux || mkdir include/linux
1289 test -d include/asm || mkdir include/asm
1290 for i in MCONFIG Makefile e2fsprogs.spec \
1291         util/Makefile util/subst.conf util/gen-tarball util/install-symlink \
1292         lib/et/Makefile lib/ss/Makefile lib/e2p/Makefile \
1293         lib/ext2fs/Makefile lib/ext2fs/ext2_types.h \
1294         lib/uuid/Makefile lib/uuid/uuid_types.h \
1295         lib/blkid/Makefile lib/blkid/blkid_types.h lib/quota/Makefile \
1296         lib/ss/ss.pc lib/uuid/uuid.pc lib/et/com_err.pc \
1297         lib/e2p/e2p.pc lib/blkid/blkid.pc lib/ext2fs/ext2fs.pc \
1298         misc/Makefile ext2ed/Makefile e2fsck/Makefile \
1299         debugfs/Makefile tests/Makefile tests/progs/Makefile \
1300         resize/Makefile doc/Makefile intl/Makefile \
1301         intl/libgnuintl.h po/Makefile.in ; do
1302         if test -d `dirname ${srcdir}/$i` ; then
1303                 outlist="$outlist $i"
1304         fi
1305 done
1306 AC_OUTPUT($outlist)
1307 if test -f util/gen-tarball; then chmod +x util/gen-tarball; fi