configure.in

   1 AC_INIT(version.h)
   2 AC_PREREQ(2.54)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_HEADERS([lib/config.h])
   5 AH_BOTTOM([#include "dirpaths.h"])
   6 MCONFIG=./MCONFIG
   7 AC_SUBST_FILE(MCONFIG)
   8 BINARY_TYPE=bin
   9 dnl
  10 dnl This is to figure out the version number and the date....
  11 dnl
  12 E2FSPROGS_VERSION=`grep E2FSPROGS_VERSION ${srcdir}/version.h  \
  13         | awk '{print $3}' | tr \" " " | awk '{print $1}'`
  14 DATE=`grep E2FSPROGS_DATE ${srcdir}/version.h | awk '{print $3}' \
  15         | tr \" " "`
  16 E2FSPROGS_DAY=`echo $DATE | awk -F- '{print $1}'`
  17 MONTH=`echo $DATE | awk -F- '{print $2}'`
  18 YEAR=`echo $DATE | awk -F- '{print $3}'`
  19
  20 if expr $YEAR ">" 1900 > /dev/null ; then
  21         E2FSPROGS_YEAR=$YEAR
  22 elif expr $YEAR ">" 90 >/dev/null ; then
  23         E2FSPROGS_YEAR=19$YEAR
  24 else
  25         E2FSPROGS_YEAR=20$YEAR
  26 fi
  27
  28 case $MONTH in
  29 Jan)    MONTH_NUM=01; E2FSPROGS_MONTH="January" ;;
  30 Feb)    MONTH_NUM=02; E2FSPROGS_MONTH="February" ;;
  31 Mar)    MONTH_NUM=03; E2FSPROGS_MONTH="March" ;;
  32 Apr)    MONTH_NUM=04; E2FSPROGS_MONTH="April" ;;
  33 May)    MONTH_NUM=05; E2FSPROGS_MONTH="May" ;;
  34 Jun)    MONTH_NUM=06; E2FSPROGS_MONTH="June" ;;
  35 Jul)    MONTH_NUM=07; E2FSPROGS_MONTH="July" ;;
  36 Aug)    MONTH_NUM=08; E2FSPROGS_MONTH="August" ;;
  37 Sep)    MONTH_NUM=09; E2FSPROGS_MONTH="September" ;;
  38 Oct)    MONTH_NUM=10; E2FSPROGS_MONTH="October" ;;
  39 Nov)    MONTH_NUM=11; E2FSPROGS_MONTH="November" ;;
  40 Dec)    MONTH_NUM=12; E2FSPROGS_MONTH="December" ;;
  41 *)      AC_MSG_WARN([Unknown month $MONTH??]) ;;
  42 esac
  43
  44 base_ver=`echo $E2FSPROGS_VERSION | \
  45                sed -e 's/-WIP//' -e 's/pre-//' -e 's/-PLUS//'`
  46
  47 date_spec=${E2FSPROGS_YEAR}.${MONTH_NUM}.${E2FSPROGS_DAY}
  48
  49 case $E2FSPROGS_VERSION in
  50 *-WIP|pre-*)
  51         E2FSPROGS_PKGVER="$base_ver~WIP-$E2FSPROGS_YEAR-$MONTH_NUM-$E2FSPROGS_DAY"
  52         ;;
  53 *)
  54         E2FSPROGS_PKGVER="$base_ver"
  55         ;;
  56 esac
  57
  58 unset DATE MONTH YEAR base_ver pre_vers date_spec
  59 AC_MSG_RESULT([Generating configuration file for e2fsprogs version $E2FSPROGS_VERSION])
  60 AC_MSG_RESULT([Release date is ${E2FSPROGS_MONTH}, ${E2FSPROGS_YEAR}])
  61 AC_SUBST(E2FSPROGS_YEAR)
  62 AC_SUBST(E2FSPROGS_MONTH)
  63 AC_SUBST(E2FSPROGS_DAY)
  64 AC_SUBST(E2FSPROGS_VERSION)
  65 AC_SUBST(E2FSPROGS_PKGVER)
  66 AC_CANONICAL_HOST
  67 dnl
  68 dnl Check to see if libdl exists for the sake of dlopen
  69 dnl
  70 DLOPEN_LIB=''
  71 AC_CHECK_LIB(dl, dlopen,
  72 [DLOPEN_LIB=-ldl
  73 AC_DEFINE(HAVE_DLOPEN, 1, [Define to 1 if dlopen/libdl exists])])
  74 AC_SUBST(DLOPEN_LIB)
  75 dnl
  76 dnl Use diet libc
  77 dnl
  78 WITH_DIET_LIBC=
  79 AC_ARG_WITH([diet-libc],
  80 [  --with-diet-libc        use diet libc],
  81 CC="diet cc -nostdinc"
  82 WITH_DIET_LIBC=yes
  83 AC_MSG_RESULT(CC=$CC))dnl
  84 dnl
  85 AC_ARG_WITH([cc],
  86 AC_HELP_STRING([--with-cc],[no longer supported, use CC= instead]),
  87 AC_MSG_ERROR([--with-cc no longer supported; use CC= instead]))
  88 dnl
  89 AC_ARG_WITH([ccopts],
  90 AC_HELP_STRING([--with-ccopts],[no longer supported, use CFLAGS= instead]),
  91 AC_MSG_ERROR([--with-ccopts no longer supported; use CFLAGS= instead]))
  92 dnl
  93 AC_ARG_WITH([ldopts],
  94 AC_HELP_STRING([--with-ldopts],[no longer supported, use LDFLAGS= instead]),
  95 AC_MSG_ERROR([--with-ldopts no longer supported; use LDFLAGS= instead]))
  96 dnl
  97 AC_PROG_CC
  98 if test "$GCC" = yes; then
  99    RDYNAMIC="-rdynamic"
 100    AC_SUBST(RDYNAMIC)
 101 fi
 102 AC_PROG_CPP
 103 dnl
 104 dnl Alpha computers use fast and imprecise floating point code that may
 105 dnl miss exceptions by default. Force sane options if we're using GCC.
 106 AC_MSG_CHECKING(for additional special compiler flags)
 107 if test "$GCC" = yes
 108 then
 109     case "$host_cpu" in
 110         alpha)          addcflags="-mieee" ;;
 111     esac
 112 fi
 113 if test "x$addcflags" != x
 114 then
 115     AC_MSG_RESULT($addcflags)
 116     CFLAGS="$addcflags $CFLAGS"
 117 else
 118     AC_MSG_RESULT([[(none)]])
 119 fi
 120 dnl
 121 dnl Set default values for library extentions.  Will be dealt with after
 122 dnl parsing configuration opions, which may modify these
 123 dnl
 124 LIB_EXT=.a
 125 STATIC_LIB_EXT=.a
 126 PROFILED_LIB_EXT=.a
 127 dnl
 128 dnl Allow separate `root_prefix' to be specified
 129 dnl
 130 AC_ARG_WITH([root-prefix],
 131 [  --with-root-prefix=PREFIX override prefix variable for files to be placed in the root],
 132 root_prefix=$withval,
 133 root_prefix=NONE)dnl
 134 dnl
 135 dnl handle --enable-maintainer-mode
 136 dnl
 137 AC_ARG_ENABLE([maintainer-mode],
 138 [  --enable-maintainer-mode enable makefile rules useful for maintainers],
 139 if test "$enableval" = "no"
 140 then
 141         MAINTAINER_CMT=#
 142         AC_MSG_RESULT([Disabling maintainer mode])
 143 else
 144         MAINTAINER_CMT=
 145         AC_MSG_RESULT([Enabling maintainer mode])
 146 fi
 147 ,
 148 MAINTAINER_CMT=#
 149 AC_MSG_RESULT([Disabling maintainer mode by default])
 150 )
 151 AC_SUBST(MAINTAINER_CMT)
 152 dnl
 153 dnl handle --enable-symlink-install
 154 dnl
 155 AC_ARG_ENABLE([symlink-install],
 156 [  --enable-symlink-install use symlinks when installing instead of hard links],
 157 if test "$enableval" = "no"
 158 then
 159         LINK_INSTALL_FLAGS=-f
 160         AC_MSG_RESULT([Disabling symlinks for install])
 161 else
 162         LINK_INSTALL_FLAGS=-sf
 163         AC_MSG_RESULT([Enabling symlinks for install])
 164 fi
 165 ,
 166 LINK_INSTALL_FLAGS=-f
 167 AC_MSG_RESULT([Disabling symlinks for install by default])
 168 )
 169 AC_SUBST(LINK_INSTALL_FLAGS)
 170 dnl
 171 dnl handle --enable-relative-symlinks
 172 dnl
 173 relative_symlink_defined=
 174 AC_ARG_ENABLE([relative-symlinks],
 175 [  --enable-relative-symlinks use relative symlinks when installing],
 176 if test "$enableval" = "no"
 177 then
 178         SYMLINK_RELATIVE=
 179         relative_symlink_defined=yes
 180         AC_MSG_RESULT([Disabling relative symlinks for install])
 181 else
 182         SYMLINK_RELATIVE=--relative
 183         relative_symlink_defined=yes
 184         AC_MSG_RESULT([Enabling relative symlinks for install])
 185 fi)
 186 AC_ARG_ENABLE([symlink-relative-symlinks],,
 187 if test "$enableval" = "no"
 188 then
 189         SYMLINK_RELATIVE=yes
 190         AC_MSG_RESULT([Disabling relative symlinks for install])
 191 else
 192         SYMLINK_RELATIVE=--relative
 193         AC_MSG_RESULT([Enabling relative symlinks for install])
 194 fi
 195 ,
 196 if test -z "$relative_symlink_defined"
 197 then
 198         SYMLINK_RELATIVE=
 199 AC_MSG_RESULT([Disabling relative symlinks for install by default])
 200 fi
 201 )
 202 AC_SUBST(SYMLINK_RELATIVE)
 203 dnl
 204 dnl handle --enable-symlink-build
 205 dnl
 206 AC_ARG_ENABLE([symlink-build],
 207 [  --enable-symlink-build  use symlinks while building instead of hard links],
 208 if test "$enableval" = "no"
 209 then
 210         LINK_BUILD_FLAGS=
 211         AC_MSG_RESULT([Disabling symlinks for build])
 212 else
 213         LINK_BUILD_FLAGS=-s
 214         AC_MSG_RESULT([Enabling symlinks for build])
 215 fi
 216 ,
 217 LINK_BUILD_FLAGS=
 218 AC_MSG_RESULT([Disabling symlinks for build by default])
 219 )
 220 AC_SUBST(LINK_BUILD_FLAGS)
 221 dnl
 222 dnl handle --enable-verbose-makecmds
 223 dnl
 224 AC_ARG_ENABLE([verbose-makecmds],
 225 [  --enable-verbose-makecmds enable verbose make command output],
 226 if test "$enableval" = "no"
 227 then
 228         AC_MSG_RESULT([Disabling verbose make commands])
 229         E=@echo
 230         ES=echo
 231         Q=@
 232 else
 233         AC_MSG_RESULT([Enabling verbose make commands])
 234         E=@\\#
 235         ES=\\#
 236         Q=
 237 fi
 238 ,
 239 AC_MSG_RESULT([Disabling verbose make commands])
 240 E=@echo
 241 ES=echo
 242 Q=@
 243 )
 244 AC_SUBST(E)
 245 AC_SUBST(ES)
 246 AC_SUBST(Q)
 247 dnl
 248 dnl handle --enable-compression
 249 dnl
 250 AC_ARG_ENABLE([compression],
 251 [  --enable-compression   enable EXPERIMENTAL compression support],
 252 if test "$enableval" = "no"
 253 then
 254         AC_MSG_RESULT([Disabling compression support])
 255 else
 256         AC_DEFINE(ENABLE_COMPRESSION, 1,
 257                 [Define to 1 if ext2 compression enabled])
 258         AC_MSG_RESULT([Enabling compression support])
 259         AC_MSG_WARN([Compression support is experimental])
 260 fi
 261 ,
 262 AC_MSG_RESULT([Disabling compression support by default])
 263 )
 264 dnl
 265 dnl handle --enable-htree
 266 dnl
 267 AH_TEMPLATE([ENABLE_HTREE], [Define to 1 if ext3/4 htree support enabled])
 268 AC_ARG_ENABLE([htree],
 269 [  --enable-htree         enable EXPERIMENTAL htree directory support],
 270 if test "$enableval" = "no"
 271 then
 272         HTREE_CMT=#
 273         AC_MSG_RESULT([Disabling htree directory support])
 274 else
 275         HTREE_CMT=
 276         AC_DEFINE(ENABLE_HTREE, 1)
 277         AC_MSG_RESULT([Enabling htree directory support])
 278 fi
 279 ,
 280 HTREE_CMT=
 281 AC_DEFINE(ENABLE_HTREE, 1)
 282 AC_MSG_RESULT([Enabling htree directory support by default])
 283 )
 284 AC_SUBST(HTREE_CMT)
 285 dnl
 286 dnl This needs to be before all of the --enable-*-shlibs options
 287 dnl
 288 E2_PKG_CONFIG_STATIC=--static
 289 LDFLAG_DYNAMIC=
 290 PRIVATE_LIBS_CMT=
 291 dnl
 292 dnl handle --enable-elf-shlibs
 293 dnl
 294 AC_ARG_ENABLE([elf-shlibs],
 295 [  --enable-elf-shlibs    select ELF shared libraries],
 296 if test "$enableval" = "no"
 297 then
 298         ELF_CMT=#
 299         MAKEFILE_ELF=/dev/null
 300         AC_MSG_RESULT([Disabling ELF shared libraries])
 301 else
 302         E2_PKG_CONFIG_STATIC=
 303         ELF_CMT=
 304         MAKEFILE_ELF=$srcdir/lib/Makefile.elf-lib
 305         [case "$host_os" in
 306         solaris2.*)
 307                 MAKEFILE_ELF=$srcdir/lib/Makefile.solaris-lib
 308         ;;
 309         esac]
 310         BINARY_TYPE=elfbin
 311         LIB_EXT=.so
 312         PRIVATE_LIBS_CMT=#
 313         LDFLAG_DYNAMIC=['-Wl,-rpath-link,$(top_builddir)/lib']
 314         AC_MSG_RESULT([Enabling ELF shared libraries])
 315 fi
 316 ,
 317 MAKEFILE_ELF=/dev/null
 318 ELF_CMT=#
 319 AC_MSG_RESULT([Disabling ELF shared libraries by default])
 320 )
 321 AC_SUBST(ELF_CMT)
 322 AC_SUBST_FILE(MAKEFILE_ELF)
 323 dnl
 324 dnl handle --enable-bsd-shlibs
 325 dnl
 326 AC_ARG_ENABLE([bsd-shlibs],
 327 [  --enable-bsd-shlibs    select BSD shared libraries],
 328 if test "$enableval" = "no"
 329 then
 330         BSDLIB_CMT=#
 331         MAKEFILE_BSDLIB=/dev/null
 332         AC_MSG_RESULT([Disabling BSD shared libraries])
 333 else
 334         E2_PKG_CONFIG_STATIC=
 335         BSDLIB_CMT=
 336         MAKEFILE_BSDLIB=$srcdir/lib/Makefile.bsd-lib
 337         LIB_EXT=.so
 338         [case "$host_os" in
 339         darwin*)
 340                 MAKEFILE_BSDLIB=$srcdir/lib/Makefile.darwin-lib
 341                 LIB_EXT=.dylib
 342         ;;
 343         esac]
 344         AC_MSG_RESULT([Enabling BSD shared libraries])
 345 fi
 346 ,
 347 MAKEFILE_BSDLIB=/dev/null
 348 BSDLIB_CMT=#
 349 AC_MSG_RESULT([Disabling BSD shared libraries by default])
 350 )
 351 AC_SUBST(BSDLIB_CMT)
 352 AC_SUBST_FILE(MAKEFILE_BSDLIB)
 353 dnl
 354 dnl handle --enable-profile
 355 dnl
 356 AC_ARG_ENABLE([profile],
 357 [  --enable-profile       build profiling libraries],
 358 if test "$enableval" = "no"
 359 then
 360         PROFILE_CMT=#
 361         MAKEFILE_PROFILE=/dev/null
 362         AC_MSG_RESULT([Disabling profiling libraries])
 363 else
 364         PROFILE_CMT=
 365         MAKEFILE_PROFILE=$srcdir/lib/Makefile.profile
 366         PROFILED_LIB_EXT=_p.a
 367         AC_MSG_RESULT([Building profiling libraries])
 368 fi
 369 ,
 370 PROFILE_CMT=#
 371 MAKEFILE_PROFILE=/dev/null
 372 AC_MSG_RESULT([Disabling profiling libraries by default])
 373 )
 374 AC_SUBST(PROFILE_CMT)
 375 AC_SUBST_FILE(MAKEFILE_PROFILE)
 376 dnl
 377 dnl handle --enable-checker
 378 dnl
 379 AC_ARG_ENABLE([checker],
 380 [  --enable-checker       build checker libraries],
 381 if test "$enableval" = "no"
 382 then
 383         CHECKER_CMT=#
 384         MAKEFILE_CHECKER=/dev/null
 385         AC_MSG_RESULT([Disabling checker libraries])
 386 else
 387         CHECKER_CMT=
 388         MAKEFILE_CHECKER=$srcdir/lib/Makefile.checker
 389         AC_MSG_RESULT([Building checker libraries])
 390 fi
 391 ,
 392 CHECKER_CMT=#
 393 MAKEFILE_CHECKER=/dev/null
 394 AC_MSG_RESULT([Disabling checker libraries by default])
 395 )
 396 AC_SUBST(CHECKER_CMT)
 397 AC_SUBST_FILE(MAKEFILE_CHECKER)
 398 dnl
 399 dnl Substitute library extensions
 400 dnl
 401 AC_SUBST(LIB_EXT)
 402 AC_SUBST(STATIC_LIB_EXT)
 403 AC_SUBST(PROFILED_LIB_EXT)
 404 AC_SUBST(LDFLAG_DYNAMIC)
 405 AC_SUBST(PRIVATE_LIBS_CMT)
 406 dnl
 407 dnl handle --enable-jbd-debug
 408 dnl
 409 AC_ARG_ENABLE([jbd-debug],
 410 [  --enable-jbd-debug     enable journal debugging],
 411 if test "$enableval" = "no"
 412 then
 413         AC_MSG_RESULT([Disabling journal debugging])
 414 else
 415         AC_DEFINE(CONFIG_JBD_DEBUG, 1,
 416                 [Define to 1 if debugging ext3/4 journal code])
 417         AC_MSG_RESULT([Enabling journal debugging])
 418 fi
 419 ,
 420 AC_MSG_RESULT([Disabling journal debugging by default])
 421 )
 422 dnl
 423 dnl handle --enable-blkid-debug
 424 dnl
 425 AC_ARG_ENABLE([blkid-debug],
 426 [  --enable-blkid-debug    enable blkid debugging],
 427 if test "$enableval" = "no"
 428 then
 429         AC_MSG_RESULT([Disabling blkid debugging])
 430 else
 431         AC_DEFINE(CONFIG_BLKID_DEBUG, 1,
 432                 [Define to 1 if debugging the blkid library])
 433         AC_MSG_RESULT([Enabling blkid debugging])
 434 fi
 435 ,
 436 AC_MSG_RESULT([Disabling blkid debugging by default])
 437 )
 438 dnl
 439 dnl handle --enable-testio-debug
 440 dnl
 441 AC_ARG_ENABLE([testio-debug],
 442 [  --disable-testio-debug  disable the use of the test I/O manager for debugging],
 443 AH_TEMPLATE([CONFIG_TESTIO_DEBUG],
 444         [Define to 1 if the testio I/O manager should be enabled])
 445 if test "$enableval" = "no"
 446 then
 447         AC_MSG_RESULT([Disabling testio debugging])
 448         TEST_IO_CMT="#"
 449 else
 450         TEST_IO_CMT=
 451         AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 452         AC_MSG_RESULT([Enabling testio debugging])
 453 fi
 454 ,
 455 AC_MSG_RESULT([Enabling testio debugging by default])
 456 AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 457 TEST_IO_CMT=
 458 )
 459 AC_SUBST(TEST_IO_CMT)
 460 dnl
 461 dnl handle --disable-libuuid
 462 dnl
 463 PKG_PROG_PKG_CONFIG
 464 LIBUUID=
 465 DEPLIBUUID=
 466 STATIC_LIBUUID=
 467 DEPSTATIC_LIBUUID=
 468 PROFILED_LIBUUID=
 469 DEPPROFILED_LIBUUID=
 470 UUID_CMT=
 471 AC_ARG_ENABLE([libuuid],
 472 [  --disable-libuuid      do not build private uuid library],
 473 if test "$enableval" = "no"
 474 then
 475         if test -z "$PKG_CONFIG"; then
 476                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 477         fi
 478
 479         AC_CHECK_LIB(uuid, uuid_generate,
 480                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 481                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`],
 482                 [AC_MSG_ERROR([external uuid library not found])],
 483                 [$LIBUUID])
 484         UUID_CMT=#
 485         AC_MSG_RESULT([Disabling private uuid library])
 486 else
 487         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 488         DEPLIBUUID=$LIBUUID
 489         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 490         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 491         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 492         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 493         AC_MSG_RESULT([Enabling private uuid library])
 494 fi
 495 ,
 496 LIBUUID='$(LIB)/libuuid'$LIB_EXT
 497 DEPLIBUUID=$LIBUUID
 498 STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 499 DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 500 PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 501 DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 502 AC_MSG_RESULT([Enabling private uuid library by default])
 503 )
 504 AC_SUBST(LIBUUID)
 505 AC_SUBST(DEPLIBUUID)
 506 AC_SUBST(STATIC_LIBUUID)
 507 AC_SUBST(DEPSTATIC_LIBUUID)
 508 AC_SUBST(PROFILED_LIBUUID)
 509 AC_SUBST(DEPPROFILED_LIBUUID)
 510 AC_SUBST(UUID_CMT)
 511 dnl
 512 dnl handle --disable-libblkid
 513 dnl
 514 PKG_PROG_PKG_CONFIG
 515 LIBBLKID=
 516 DEPLIBBLKID=
 517 STATIC_LIBBLKID=
 518 DEPSTATIC_LIBBLKID=
 519 PROFILED_LIBBLKID=
 520 DEPPROFILED_LIBBLKID=
 521 BLKID_CMT=
 522 AH_TEMPLATE([CONFIG_BUILD_FINDFS], [Define to 1 to compile findfs])
 523 AC_ARG_ENABLE([libblkid],
 524 [  --disable-libblkid     do not build private blkid library],
 525 if test "$enableval" = "no"
 526 then
 527         if test -z "$PKG_CONFIG"; then
 528                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 529         fi
 530
 531         AC_CHECK_LIB(blkid, blkid_get_cache,
 532                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 533                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`],
 534                 [AC_MSG_ERROR([external blkid library not found])],
 535                 [$LIBBLKID])
 536         BLKID_CMT=#
 537         AC_MSG_RESULT([Disabling private blkid library])
 538 else
 539         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 540         DEPLIBBLKID=$LIBBLKID
 541         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 542         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 543         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 544         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 545         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 546         AC_MSG_RESULT([Enabling private blkid library])
 547 fi
 548 ,
 549 LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 550 DEPLIBBLKID=$LIBBLKID
 551 STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 552 DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 553 PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 554 DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 555 AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 556 AC_MSG_RESULT([Enabling private blkid library by default])
 557 )
 558 AC_SUBST(LIBBLKID)
 559 AC_SUBST(DEPLIBBLKID)
 560 AC_SUBST(STATIC_LIBBLKID)
 561 AC_SUBST(DEPSTATIC_LIBBLKID)
 562 AC_SUBST(PROFILED_LIBBLKID)
 563 AC_SUBST(DEPPROFILED_LIBBLKID)
 564 AC_SUBST(BLKID_CMT)
 565 dnl
 566 dnl handle --enable-quota
 567 dnl
 568 PKG_PROG_PKG_CONFIG
 569 AH_TEMPLATE([CONFIG_QUOTA], [Define to 1 to enable quota support])
 570 AC_ARG_ENABLE([quota],
 571 [  --enable-quota         enable quota support],
 572 if test "$enableval" = "no"
 573 then
 574         AC_MSG_RESULT([Disabling quota support])
 575 else
 576         AC_DEFINE(CONFIG_QUOTA, 1)
 577         AC_MSG_RESULT([Enabling quota support])
 578 fi
 579 ,
 580 AC_MSG_RESULT([Disabling quota support by default])
 581 )
 582 dnl
 583 dnl Define stuff expected for quota library
 584 dnl
 585 LIBQUOTA='$(LIB)/libquota'$LIB_EXT
 586 DEPLIBQUOTA=$LIBQUOTA
 587 STATIC_LIBQUOTA='$(LIB)/libquota'$STATIC_LIB_EXT
 588 DEPSTATIC_LIBQUOTA=$STATIC_LIBQUOTA
 589 PROFILED_LIBQUOTA='$(LIB)/libquota'$PROFILED_LIB_EXT
 590 DEPPROFILED_LIBQUOTA=$PROFILED_LIBQUOTA
 591 AC_SUBST(LIBQUOTA)
 592 AC_SUBST(DEPLIBQUOTA)
 593 AC_SUBST(STATIC_LIBQUOTA)
 594 AC_SUBST(DEPSTATIC_LIBQUOTA)
 595 AC_SUBST(PROFILED_LIBQUOTA)
 596 AC_SUBST(DEPPROFILED_LIBQUOTA)
 597 AC_SUBST(QUOTA_CMT)
 598 dnl
 599 dnl handle --enable-debugfs
 600 dnl
 601 AC_ARG_ENABLE([debugfs],
 602 [  --disable-debugfs      disable support of debugfs program],
 603 if test "$enableval" = "no"
 604 then
 605         AC_MSG_RESULT([Disabling debugfs support])
 606         DEBUGFS_CMT="#"
 607 else
 608         DEBUGFS_CMT=
 609         AC_MSG_RESULT([Enabling debugfs support])
 610 fi
 611 ,
 612 AC_MSG_RESULT([Enabling debugfs support by default])
 613 DEBUGFS_CMT=
 614 )
 615 AC_SUBST(DEBUGFS_CMT)
 616 dnl
 617 dnl handle --enable-imager
 618 dnl
 619 AC_ARG_ENABLE([imager],
 620 [  --disable-imager       disable support of e2image program],
 621 if test "$enableval" = "no"
 622 then
 623         AC_MSG_RESULT([Disabling e2image support])
 624         IMAGER_CMT="#"
 625 else
 626         IMAGER_CMT=
 627         AC_MSG_RESULT([Enabling e2image support])
 628 fi
 629 ,
 630 AC_MSG_RESULT([Enabling e2image support by default])
 631 IMAGER_CMT=
 632 )
 633 AC_SUBST(IMAGER_CMT)
 634 dnl
 635 dnl handle --enable-resizer
 636 dnl
 637 AC_ARG_ENABLE([resizer],
 638 [  --disable-resizer      disable support of e2resize program],
 639 if test "$enableval" = "no"
 640 then
 641         AC_MSG_RESULT([Disabling e2resize support])
 642         RESIZER_CMT="#"
 643 else
 644         RESIZER_CMT=
 645         AC_MSG_RESULT([Enabling e2resize support])
 646 fi
 647 ,
 648 AC_MSG_RESULT([Enabling e2resize support by default])
 649 RESIZER_CMT=
 650 )
 651 AC_SUBST(RESIZER_CMT)
 652 dnl
 653 dnl handle --enable-defrag
 654 dnl
 655 AC_ARG_ENABLE([defrag],
 656 [  --disable-defrag       disable support of e4defrag program],
 657 if test "$enableval" = "no"
 658 then
 659         AC_MSG_RESULT([Disabling e4defrag support])
 660         DEFRAG_CMT="#"
 661 else
 662         DEFRAG_CMT=
 663         AC_MSG_RESULT([Enabling e4defrag support])
 664 fi
 665 ,
 666 AC_MSG_RESULT([Enabling e4defrag support by default])
 667 DEFRAG_CMT=
 668 )
 669 AC_SUBST(DEFRAG_CMT)
 670 dnl
 671 dnl See whether to install the `fsck' wrapper program (that calls e2fsck)
 672 dnl
 673 AC_ARG_ENABLE([fsck],
 674 [  --enable-fsck           build fsck wrapper program],
 675 [if test "$enableval" = "no"
 676 then
 677         FSCK_PROG='' FSCK_MAN=''
 678         AC_MSG_RESULT([Not building fsck wrapper])
 679 else
 680         FSCK_PROG=fsck FSCK_MAN=fsck.8
 681         AC_MSG_RESULT([Building fsck wrapper])
 682 fi]
 683 ,
 684 [case "$host_os" in
 685   gnu*)
 686     FSCK_PROG='' FSCK_MAN=''
 687     AC_MSG_RESULT([Not building fsck wrapper by default])
 688     ;;
 689   *)
 690     FSCK_PROG=fsck FSCK_MAN=fsck.8
 691     AC_MSG_RESULT([Building fsck wrapper by default])
 692 esac]
 693 )
 694 AC_SUBST(FSCK_PROG)
 695 AC_SUBST(FSCK_MAN)
 696 dnl
 697 dnl See whether to install the `e2initrd-helper' program
 698 dnl
 699 AC_ARG_ENABLE([e2initrd-helper],
 700 [  --enable-e2initrd-helper build e2initrd-helper program],
 701 [if test "$enableval" = "no"
 702 then
 703         E2INITRD_PROG='' E2INITRD_MAN=''
 704         AC_MSG_RESULT([Not building e2initrd helper])
 705 else
 706         E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 707         AC_MSG_RESULT([Building e2initrd helper])
 708 fi]
 709 ,
 710 E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 711 AC_MSG_RESULT([Building e2initrd helper by default])
 712 )
 713 AC_SUBST(E2INITRD_PROG)
 714 AC_SUBST(E2INITRD_MAN)
 715 dnl
 716 dnl
 717 dnl
 718 AC_ARG_ENABLE([tls],
 719 [  --disable-tls           disable use of thread local support],
 720 [if test "$enableval" = "no"
 721 then
 722         try_tls=""
 723         AC_MSG_RESULT([Disabling thread local support])
 724 else
 725         try_tls="yes"
 726         AC_MSG_RESULT([Enabling thread local support])
 727 fi]
 728 ,
 729 if test -n "$WITH_DIET_LIBC"
 730 then
 731         try_tls=""
 732         AC_MSG_RESULT([Diet libc does not support thread local support])
 733 else
 734         try_tls="yes"
 735         AC_MSG_RESULT([Try using thread local support by default])
 736 fi
 737 )
 738 if test "$try_tls" = "yes"
 739 then
 740 AX_TLS
 741 fi
 742 dnl
 743 dnl
 744 dnl
 745 AH_TEMPLATE([USE_UUIDD], [Define to 1 to build uuidd])
 746 AC_ARG_ENABLE([uuidd],
 747 [  --disable-uuidd         disable building the uuid daemon],
 748 [if test "$enableval" = "no"
 749 then
 750         AC_MSG_RESULT([Not building uuidd])
 751         UUIDD_CMT="#"
 752 else
 753         AC_DEFINE(USE_UUIDD, 1)
 754         UUIDD_CMT=""
 755         AC_MSG_RESULT([Building uuidd])
 756 fi]
 757 ,
 758 AC_DEFINE(USE_UUIDD, 1)
 759 UUIDD_CMT=""
 760 AC_MSG_RESULT([Building uuidd by default])
 761 )
 762 AC_SUBST(UUIDD_CMT)
 763 dnl
 764 dnl
 765 dnl
 766 MAKEFILE_LIBRARY=$srcdir/lib/Makefile.library
 767 AC_SUBST_FILE(MAKEFILE_LIBRARY)
 768 dnl
 769 dnl Add internationalization support, using gettext.
 770 dnl
 771 GETTEXT_PACKAGE=e2fsprogs
 772 PACKAGE=e2fsprogs
 773 VERSION="$E2FSPROGS_VERSION"
 774 VERSION=0.14.1
 775 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [package name for gettext])
 776 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [version for gettext])
 777 AC_SUBST(GETTEXT_PACKAGE)
 778 AC_SUBST(PACKAGE)
 779 AC_SUBST(VERSION)
 780
 781 AM_GNU_GETTEXT
 782 dnl
 783 dnl End of configuration options
 784 dnl
 785 AC_SUBST(BINARY_TYPE)
 786 AC_PROG_MAKE_SET
 787 CHECK_GNU_MAKE
 788 AC_PATH_PROG(LN, ln, ln)
 789 AC_PROG_LN_S
 790 AC_PATH_PROG(MV, mv, mv)
 791 AC_PATH_PROG(CP, cp, cp)
 792 AC_PATH_PROG(RM, rm, rm)
 793 AC_PATH_PROG(CHMOD, chmod, :)
 794 AC_PROG_AWK
 795 AC_PROG_EGREP
 796 AC_PATH_PROG(SED, sed, sed)
 797 AC_PATH_PROG(PERL, perl, perl)
 798 AC_PATH_PROG(LDCONFIG, ldconfig, :)
 799 AC_CHECK_TOOL(AR, ar, ar)
 800 AC_CHECK_TOOL(RANLIB, ranlib, :)
 801 AC_CHECK_TOOL(STRIP, strip, :)
 802 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
 803 if test "_$MAKEINFO" = "_"; then
 804     MAKEINFO="@echo Makeinfo is missing. Info documentation will not be built.;true"
 805 else
 806     case "$MAKEINFO" in
 807       */missing.*)
 808         AC_MSG_WARN([
 809 *** Makeinfo is missing. Info documentation will not be built.])
 810         ;;
 811       *)
 812         ;;
 813     esac
 814 fi
 815 AC_SUBST(MAKEINFO)
 816 AC_PROG_INSTALL
 817 # See if we need a separate native compiler.
 818 if test $cross_compiling = no; then
 819   BUILD_CC="$CC"
 820   AC_SUBST(BUILD_CC)
 821 else
 822   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 823 fi
 824 AC_CHECK_HEADERS(m4_flatten([
 825         dirent.h
 826         errno.h
 827         execinfo.h
 828         getopt.h
 829         malloc.h
 830         mntent.h
 831         paths.h
 832         semaphore.h
 833         setjmp.h
 834         signal.h
 835         stdarg.h
 836         stdint.h
 837         stdlib.h
 838         termios.h
 839         termio.h
 840         unistd.h
 841         utime.h
 842         linux/falloc.h
 843         linux/fd.h
 844         linux/major.h
 845         net/if_dl.h
 846         netinet/in.h
 847         sys/disklabel.h
 848         sys/file.h
 849         sys/ioctl.h
 850         sys/mkdev.h
 851         sys/mman.h
 852         sys/prctl.h
 853         sys/queue.h
 854         sys/resource.h
 855         sys/select.h
 856         sys/socket.h
 857         sys/sockio.h
 858         sys/stat.h
 859         sys/syscall.h
 860         sys/sysmacros.h
 861         sys/time.h
 862         sys/types.h
 863         sys/un.h
 864         sys/wait.h
 865 ]))
 866 AC_CHECK_HEADERS(sys/disk.h sys/mount.h,,,
 867 [[
 868 #if HAVE_SYS_QUEUE_H
 869 #include <sys/queue.h>
 870 #endif
 871 ]])
 872 AC_CHECK_HEADERS(net/if.h,,,
 873 [[
 874 #if HAVE_SYS_TYPES_H
 875 #include <sys/types.h>
 876 #endif
 877 #if HAVE_SYS_SOCKET
 878 #include <sys/socket.h>
 879 #endif
 880 ]])
 881 AC_FUNC_VPRINTF
 882 dnl Check to see if dirent has member d_reclen. On cygwin those d_reclen
 883 dnl is not decleared.
 884 AC_CHECK_MEMBER(struct dirent.d_reclen,[AC_DEFINE(HAVE_RECLEN_DIRENT, 1,
 885                        [Define to 1 if dirent has d_reclen])],,
 886                 [#include <dirent.h>])
 887 dnl Check to see if ssize_t was declared
 888 AC_CHECK_TYPE(ssize_t,[AC_DEFINE(HAVE_TYPE_SSIZE_T, 1,
 889                 [Define to 1 if ssize_t declared])],,
 890               [#include <sys/types.h>])
 891 dnl
 892 dnl Check to see if llseek() is declared in unistd.h.  On some libc's
 893 dnl it is, and on others it isn't..... Thank you glibc developers....
 894 dnl
 895 AC_CHECK_DECL(llseek,[AC_DEFINE(HAVE_LLSEEK_PROTOTYPE, 1,
 896                         [Define to 1 if llseek declared in unistd.h])],,
 897               [#include <unistd.h>])
 898 dnl
 899 dnl Check to see if lseek64() is declared in unistd.h.  Glibc's header files
 900 dnl are so convoluted that I can't tell whether it will always be defined,
 901 dnl and if it isn't defined while lseek64 is defined in the library,
 902 dnl disaster will strike.
 903 dnl
 904 dnl Warning!  Use of --enable-gcc-wall may throw off this test.
 905 dnl
 906 dnl
 907 AC_CHECK_DECL(lseek64,[AC_DEFINE(HAVE_LSEEK64_PROTOTYPE, 1,
 908                         [Define to 1 if lseek64 declared in unistd.h])],,
 909                 [#define _LARGEFILE_SOURCE
 910                  #define _LARGEFILE64_SOURCE
 911                  #include <unistd.h>])
 912 dnl
 913 dnl Word sizes...
 914 dnl
 915 AC_CHECK_SIZEOF(short)
 916 AC_CHECK_SIZEOF(int)
 917 AC_CHECK_SIZEOF(long)
 918 AC_CHECK_SIZEOF(long long)
 919 AC_CHECK_SIZEOF(off_t)
 920 SIZEOF_SHORT=$ac_cv_sizeof_short
 921 SIZEOF_INT=$ac_cv_sizeof_int
 922 SIZEOF_LONG=$ac_cv_sizeof_long
 923 SIZEOF_LONG_LONG=$ac_cv_sizeof_long_long
 924 SIZEOF_OFF_T=$ac_cv_sizeof_off_t
 925 AC_SUBST(SIZEOF_SHORT)
 926 AC_SUBST(SIZEOF_INT)
 927 AC_SUBST(SIZEOF_LONG)
 928 AC_SUBST(SIZEOF_LONG_LONG)
 929 AC_SUBST(SIZEOF_OFF_T)
 930 AC_C_BIGENDIAN
 931 BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
 932 ASM_TYPES_HEADER=./asm_types.h
 933 AC_SUBST_FILE(ASM_TYPES_HEADER)
 934 dnl
 935 dnl Save the configuration #defines needed for the public ext2fs.h
 936 dnl header file
 937 dnl
 938 echo "/* These defines are needed for the public ext2fs.h header file */" \
 939      > public_config.h
 940 if grep HAVE_SYS_TYPES_H confdefs.h > tmp_config.$$; then
 941   uniq tmp_config.$$ >> public_config.h
 942 else
 943   echo "#undef HAVE_SYS_TYPES_H" >> public_config.h
 944 fi
 945 if grep WORDS_BIGENDIAN confdefs.h > tmp_config.$$; then
 946   uniq tmp_config.$$ >> public_config.h
 947 else
 948   echo "#undef WORDS_BIGENDIAN" >> public_config.h
 949 fi
 950 rm -f tmp_config.$$
 951 PUBLIC_CONFIG_HEADER=./public_config.h
 952 AC_SUBST_FILE(PUBLIC_CONFIG_HEADER)
 953 dnl
 954 dnl See if we have inttypes.h and if intptr_t is defined
 955 dnl
 956 AC_CHECK_HEADERS([inttypes.h])
 957 AC_CHECK_TYPES(intptr_t)
 958 dnl
 959 dnl See if struct stat has a st_flags field, in which case we can get file
 960 dnl flags somewhat portably.  Also check for the analogous setter, chflags().
 961 dnl
 962 AC_MSG_CHECKING(whether struct stat has a st_flags field)
 963 AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags,
 964         AC_TRY_COMPILE([#include <sys/stat.h>],
 965                 [struct stat stat; stat.st_flags = 0;],
 966                 [e2fsprogs_cv_struct_st_flags=yes],
 967                 [e2fsprogs_cv_struct_st_flags=no]))
 968 AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags)
 969 if test "$e2fsprogs_cv_struct_st_flags" = yes; then
 970   AC_MSG_CHECKING(whether st_flags field is useful)
 971   AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags_immut,
 972         AC_TRY_COMPILE([#include <sys/stat.h>],
 973                 [struct stat stat; stat.st_flags |= UF_IMMUTABLE;],
 974                 [e2fsprogs_cv_struct_st_flags_immut=yes],
 975                 [e2fsprogs_cv_struct_st_flags_immut=no]))
 976   AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags_immut)
 977   if test "$e2fsprogs_cv_struct_st_flags_immut" = yes; then
 978           AC_DEFINE(HAVE_STAT_FLAGS, 1,
 979                 [Define to 1 if struct stat has st_flags])
 980   fi
 981 fi
 982 dnl
 983 dnl Check for the presence of SA_LEN
 984 dnl
 985 AC_CHECK_MEMBER(struct sockaddr.sa_len,
 986                 AC_DEFINE_UNQUOTED(HAVE_SA_LEN,1,
 987                         [Define to 1 if if struct sockaddr contains sa_len]),,
 988         [#include <sys/types.h>
 989          #include <sys/socket.h>])
 990 dnl
 991 dnl This will add -lblkid to the AC_CHECK_FUNCS search if we are using
 992 dnl the system-provided blkid library
 993 dnl
 994 if test -n "$BLKID_CMT"; then
 995   AC_SEARCH_LIBS([blkid_probe_all], [blkid])
 996 fi
 997 dnl
 998 AC_CHECK_FUNCS(m4_flatten([
 999         __secure_getenv
1000         backtrace
1001         blkid_probe_get_topology
1002         chflags
1003         fallocate
1004         fallocate64
1005         fchown
1006         fdatasync
1007         fstat64
1008         ftruncate64
1009         getdtablesize
1010         getmntinfo
1011         getpwuid_r
1012         getrlimit
1013         getrusage
1014         jrand48
1015         llseek
1016         lseek64
1017         mallinfo
1018         mbstowcs
1019         memalign
1020         mmap
1021         msync
1022         nanosleep
1023         open64
1024         pathconf
1025         posix_fadvise
1026         posix_memalign
1027         prctl
1028         setmntent
1029         setresgid
1030         setresuid
1031         srandom
1032         strcasecmp
1033         strdup
1034         strnlen
1035         strptime
1036         strtoull
1037         sync_file_range
1038         sysconf
1039         usleep
1040         utime
1041         valloc
1042 ]))
1043 dnl
1044 dnl Check to see if -lsocket is required (solaris) to make something
1045 dnl that uses socket() to compile; this is needed for the UUID library
1046 dnl
1047 SOCKET_LIB=''
1048 AC_CHECK_LIB(socket, socket, [SOCKET_LIB=-lsocket])
1049 AC_SUBST(SOCKET_LIB)
1050 dnl
1051 dnl See if optreset exists
1052 dnl
1053 AC_MSG_CHECKING(for optreset)
1054 AC_CACHE_VAL(ac_cv_have_optreset,
1055 [AC_EGREP_HEADER(optreset, unistd.h,
1056   ac_cv_have_optreset=yes, ac_cv_have_optreset=no)])dnl
1057 AC_MSG_RESULT($ac_cv_have_optreset)
1058 if test $ac_cv_have_optreset = yes; then
1059   AC_DEFINE(HAVE_OPTRESET, 1, [Define to 1 if optreset for getopt is present])
1060 fi
1061 dnl
1062 dnl Test for sem_init, and which library it might require:
1063 dnl
1064 AH_TEMPLATE([HAVE_SEM_INIT], [Define to 1 if sem_init() exists])
1065 SEM_INIT_LIB=''
1066 AC_CHECK_FUNC(sem_init, ,
1067   AC_CHECK_LIB(pthread, sem_init,
1068         AC_DEFINE(HAVE_SEM_INIT, 1)
1069         SEM_INIT_LIB=-lpthread,
1070   AC_CHECK_LIB(rt, sem_init,
1071         AC_DEFINE(HAVE_SEM_INIT, 1)
1072         SEM_INIT_LIB=-lrt,
1073   AC_CHECK_LIB(posix4, sem_init,
1074         AC_DEFINE(HAVE_SEM_INIT, 1)
1075         SEM_INIT_LIB=-lposix4))))dnl
1076 AC_SUBST(SEM_INIT_LIB)
1077 dnl
1078 dnl Check for unified diff
1079 dnl
1080 AC_MSG_CHECKING(for unified diff option)
1081 if diff -u $0 $0 > /dev/null 2>&1 ; then
1082    UNI_DIFF_OPTS=-u
1083 else
1084    UNI_DIFF_OPTS=-c
1085 fi
1086 AC_MSG_RESULT($UNI_DIFF_OPTS)
1087 AC_SUBST(UNI_DIFF_OPTS)
1088 dnl
1089 dnl We use the EXT2 ioctls only under Linux
1090 dnl
1091 case "$host_os" in
1092 linux*)
1093         AC_DEFINE(HAVE_EXT2_IOCTLS, 1, [Define to 1 if Ext2 ioctls present])
1094         ;;
1095 esac
1096 dnl
1097 dnl OS-specific uncomment control
1098 dnl
1099 LINUX_CMT="#"
1100 CYGWIN_CMT="#"
1101 UNIX_CMT=
1102 case "$host_os" in
1103 linux*)
1104         LINUX_CMT=
1105         ;;
1106 cygwin)
1107         CYGWIN_CMT=
1108         UNIX_CMT="#"
1109         ;;
1110 esac
1111 AC_SUBST(LINUX_CMT)
1112 AC_SUBST(CYGWIN_CMT)
1113 AC_SUBST(UNIX_CMT)
1114 dnl
1115 dnl Linux and Hurd places root files in the / by default
1116 dnl
1117 case "$host_os" in
1118 linux* | gnu* | k*bsd*-gnu)
1119         if test "$prefix" = NONE -a "$root_prefix" = NONE ; then
1120                 root_prefix="";
1121                 AC_MSG_RESULT([On $host_os systems, root_prefix defaults to ''])
1122         fi
1123         ;;
1124 esac
1125 dnl
1126 dnl On Linux/hurd, force the prefix to be /usr
1127 dnl
1128 case "$host_os" in
1129 linux* | gnu* | k*bsd*-gnu)
1130         if test "$prefix" = NONE ; then
1131                 prefix="/usr";
1132                 AC_MSG_RESULT([On $host_os systems, prefix defaults to /usr])
1133                 if test "$mandir" = '${prefix}/man' ; then
1134                         AC_MSG_RESULT([...and mandir defaults to /usr/share/man])
1135                         mandir=/usr/share/man
1136                 fi
1137         fi
1138 ;;
1139 esac
1140 if test "$root_prefix" = NONE ; then
1141         if test "$prefix" = NONE ; then
1142                 root_prefix="$ac_default_prefix"
1143         else
1144                 root_prefix="$prefix"
1145         fi
1146         root_bindir=$bindir
1147         root_sbindir=$sbindir
1148         root_libdir=$libdir
1149         root_sysconfdir=$sysconfdir
1150 else
1151         root_bindir='${root_prefix}/bin'
1152         root_sbindir='${root_prefix}/sbin'
1153         root_libdir='${root_prefix}/lib'
1154         root_sysconfdir='${root_prefix}/etc'
1155 fi
1156 if test "$bindir" != '${exec_prefix}/bin'; then
1157     root_bindir=$bindir
1158     AC_MSG_RESULT([Setting root_bindir to $root_bindir])
1159 fi
1160 if test "$sbindir" != '${exec_prefix}/sbin'; then
1161     root_sbindir=$sbindir
1162     AC_MSG_RESULT([Setting root_sbindir to $root_sbindir])
1163 fi
1164 if test "$libdir" != '${exec_prefix}/lib'; then
1165     root_libdir=$libdir
1166     AC_MSG_RESULT([Setting root_libdir to $root_libdir])
1167 fi
1168 if test "$sysconfdir" != '${prefix}/etc'; then
1169     root_sysconfdir=$sysconfdir
1170     AC_MSG_RESULT([Setting root_sysconfdir to $root_sysconfdir])
1171 fi
1172 AC_SUBST(root_prefix)
1173 AC_SUBST(root_bindir)
1174 AC_SUBST(root_sbindir)
1175 AC_SUBST(root_libdir)
1176 AC_SUBST(root_sysconfdir)
1177 dnl
1178 dnl Allow specification of the multiarch arch
1179 dnl
1180 AC_ARG_WITH([multiarch],
1181 [  --with-multiarch=ARCH specify the multiarch triplet],
1182 libdir=$libdir/$withval
1183 root_libdir=$root_libdir/$withval
1184 )dnl
1185 dnl
1186 dnl See if -static works.  This could fail if the linker does not
1187 dnl support -static, or if required external libraries are not available
1188 dnl in static form.
1189 dnl
1190 AC_MSG_CHECKING([whether we can link with -static])
1191 AC_CACHE_VAL(ac_cv_e2fsprogs_use_static,
1192 [SAVE_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -static"
1193 AC_TRY_LINK([#include <stdio.h>],[fflush(stdout);],
1194  ac_cv_e2fsprogs_use_static=yes, ac_cv_e2fsprogs_use_static=no)
1195 LDFLAGS=$SAVE_LDFLAGS])
1196 dnl
1197 dnl Regardless of how the test turns out, Solaris doesn't handle -static
1198 dnl This is caused by the socket library requiring the nsl library, which
1199 dnl requires the -dl library, which only works for dynamically linked
1200 dnl programs.  It basically means you can't have statically linked programs
1201 dnl which use the network under Solaris.
1202 dnl
1203 case "$host_os" in
1204 solaris2.*)
1205         ac_cv_e2fsprogs_use_static=no
1206 ;;
1207 esac
1208 AC_MSG_RESULT($ac_cv_e2fsprogs_use_static)
1209 LDFLAG_STATIC=
1210 if test $ac_cv_e2fsprogs_use_static = yes; then
1211         LDFLAG_STATIC=-static
1212 fi
1213 AC_SUBST(LDFLAG_STATIC)
1214 dnl
1215 dnl Work around mysterious Darwin / GNU libintl problem
1216 dnl (__asm__ redirection doesn't work for some mysterious reason.  Looks like
1217 dnl Apple hacked gcc somehow?)
1218 dnl
1219 case "$host_os" in
1220 darwin*)
1221         AC_MSG_RESULT([Using Apple Darwin / GNU libintl workaround])
1222         AC_DEFINE(_INTL_REDIRECT_MACROS, 1,
1223                 [Define to 1 if Apple Darwin libintl workaround is needed])
1224         ;;
1225 esac
1226 dnl
1227 dnl Make the ss and et directories work correctly.
1228 dnl
1229 SS_DIR=`cd ${srcdir}/lib/ss; pwd`
1230 ET_DIR=`cd ${srcdir}/lib/et; pwd`
1231 AC_SUBST(SS_DIR)
1232 AC_SUBST(ET_DIR)
1233 dnl
1234 dnl Only try to run the test suite if we're not cross compiling.
1235 dnl
1236 if test "$cross_compiling" = yes ; then
1237   DO_TEST_SUITE=
1238 else
1239   DO_TEST_SUITE=check
1240 fi
1241 AC_SUBST(DO_TEST_SUITE)
1242 dnl
1243 dnl Only include the intl include files if we're building with them
1244 dnl
1245 INCLUDES='-I. -I$(top_builddir)/lib -I$(top_srcdir)/lib'
1246 if test -n "$CPPFLAGS" ; then
1247         INCLUDES="$INCLUDES $CPPFLAGS"
1248 fi
1249 if test "$USE_INCLUDED_LIBINTL" = "yes" ; then
1250         INCLUDES=$INCLUDES' -I$(top_builddir)/intl -I$(top_srcdir)/intl'
1251 fi
1252 AC_SUBST(INCLUDES)
1253 dnl
1254 dnl Build CFLAGS
1255 dnl
1256 if test $cross_compiling = no; then
1257    BUILD_CFLAGS="$CFLAGS $CPPFLAGS"
1258    BUILD_LDFLAGS="$LDFLAGS"
1259 else
1260    BUILD_CFLAGS=
1261    BUILD_LDFLAGS=
1262 fi
1263 AC_SUBST(BUILD_CFLAGS)
1264 AC_SUBST(BUILD_LDFLAGS)
1265 dnl
1266 dnl Make our output files, being sure that we create the some miscellaneous
1267 dnl directories
1268 dnl
1269 test -d lib || mkdir lib
1270 test -d include || mkdir include
1271 test -d include/linux || mkdir include/linux
1272 test -d include/asm || mkdir include/asm
1273 for i in MCONFIG Makefile e2fsprogs.spec \
1274         util/Makefile util/subst.conf util/gen-tarball util/install-symlink \
1275         lib/et/Makefile lib/ss/Makefile lib/e2p/Makefile \
1276         lib/ext2fs/Makefile lib/ext2fs/ext2_types.h \
1277         lib/uuid/Makefile lib/uuid/uuid_types.h \
1278         lib/blkid/Makefile lib/blkid/blkid_types.h lib/quota/Makefile \
1279         lib/ss/ss.pc lib/uuid/uuid.pc lib/et/com_err.pc \
1280         lib/e2p/e2p.pc lib/blkid/blkid.pc lib/ext2fs/ext2fs.pc \
1281         misc/Makefile ext2ed/Makefile e2fsck/Makefile \
1282         debugfs/Makefile tests/Makefile tests/progs/Makefile \
1283         resize/Makefile doc/Makefile intl/Makefile \
1284         intl/libgnuintl.h po/Makefile.in ; do
1285         if test -d `dirname ${srcdir}/$i` ; then
1286                 outlist="$outlist $i"
1287         fi
1288 done
1289 AC_OUTPUT($outlist)
1290 if test -f util/gen-tarball; then chmod +x util/gen-tarball; fi