configure.in

   1 AC_INIT(version.h)
   2 AC_PREREQ(2.54)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_HEADERS([lib/config.h])
   5 AH_BOTTOM([#include <dirpaths.h>])
   6 MCONFIG=./MCONFIG
   7 AC_SUBST_FILE(MCONFIG)
   8 BINARY_TYPE=bin
   9 dnl
  10 dnl This is to figure out the version number and the date....
  11 dnl
  12 E2FSPROGS_VERSION=`grep E2FSPROGS_VERSION ${srcdir}/version.h  \
  13         | awk '{print $3}' | tr \" " " | awk '{print $1}'`
  14 DATE=`grep E2FSPROGS_DATE ${srcdir}/version.h | awk '{print $3}' \
  15         | tr \" " "`
  16 E2FSPROGS_DAY=`echo $DATE | awk -F- '{print $1}'`
  17 MONTH=`echo $DATE | awk -F- '{print $2}'`
  18 YEAR=`echo $DATE | awk -F- '{print $3}'`
  19
  20 if expr $YEAR ">" 1900 > /dev/null ; then
  21         E2FSPROGS_YEAR=$YEAR
  22 elif expr $YEAR ">" 90 >/dev/null ; then
  23         E2FSPROGS_YEAR=19$YEAR
  24 else
  25         E2FSPROGS_YEAR=20$YEAR
  26 fi
  27
  28 case $MONTH in
  29 Jan)    MONTH_NUM=01; E2FSPROGS_MONTH="January" ;;
  30 Feb)    MONTH_NUM=02; E2FSPROGS_MONTH="February" ;;
  31 Mar)    MONTH_NUM=03; E2FSPROGS_MONTH="March" ;;
  32 Apr)    MONTH_NUM=04; E2FSPROGS_MONTH="April" ;;
  33 May)    MONTH_NUM=05; E2FSPROGS_MONTH="May" ;;
  34 Jun)    MONTH_NUM=06; E2FSPROGS_MONTH="June" ;;
  35 Jul)    MONTH_NUM=07; E2FSPROGS_MONTH="July" ;;
  36 Aug)    MONTH_NUM=08; E2FSPROGS_MONTH="August" ;;
  37 Sep)    MONTH_NUM=09; E2FSPROGS_MONTH="September" ;;
  38 Oct)    MONTH_NUM=10; E2FSPROGS_MONTH="October" ;;
  39 Nov)    MONTH_NUM=11; E2FSPROGS_MONTH="November" ;;
  40 Dec)    MONTH_NUM=12; E2FSPROGS_MONTH="December" ;;
  41 *)      AC_MSG_WARN([Unknown month $MONTH??]) ;;
  42 esac
  43
  44 base_ver=`echo $E2FSPROGS_VERSION | \
  45                sed -e 's/-WIP//' -e 's/pre-//' -e 's/-PLUS//'`
  46
  47 date_spec=${E2FSPROGS_YEAR}.${MONTH_NUM}.${E2FSPROGS_DAY}
  48
  49 case $E2FSPROGS_VERSION in
  50 *-WIP|pre-*)
  51         E2FSPROGS_PKGVER="$base_ver~WIP-$E2FSPROGS_YEAR-$MONTH_NUM-$E2FSPROGS_DAY"
  52         ;;
  53 *)
  54         E2FSPROGS_PKGVER="$base_ver"
  55         ;;
  56 esac
  57
  58 unset DATE MONTH YEAR base_ver pre_vers date_spec
  59 AC_MSG_RESULT([Generating configuration file for e2fsprogs version $E2FSPROGS_VERSION])
  60 AC_MSG_RESULT([Release date is ${E2FSPROGS_MONTH}, ${E2FSPROGS_YEAR}])
  61 AC_SUBST(E2FSPROGS_YEAR)
  62 AC_SUBST(E2FSPROGS_MONTH)
  63 AC_SUBST(E2FSPROGS_DAY)
  64 AC_SUBST(E2FSPROGS_VERSION)
  65 AC_SUBST(E2FSPROGS_PKGVER)
  66 dnl
  67 dnl Use diet libc
  68 dnl
  69 WITH_DIET_LIBC=
  70 AC_ARG_WITH([diet-libc],
  71 [  --with-diet-libc        use diet libc],
  72 CC="diet cc -nostdinc"
  73 WITH_DIET_LIBC=yes
  74 if test -z "$LIBS"
  75 then
  76         LIBS="-lcompat"
  77 else
  78         LIBS="$LIBS -lcompat"
  79 fi
  80 AC_MSG_RESULT(CC=$CC))dnl
  81 dnl
  82 AC_CANONICAL_HOST
  83 dnl
  84 dnl Check to see if libdl exists for the sake of dlopen
  85 dnl
  86 DLOPEN_LIB=''
  87 AC_CHECK_LIB(dl, dlopen,
  88 [DLOPEN_LIB=-ldl
  89 AC_DEFINE(HAVE_DLOPEN, 1, [Define to 1 if dlopen/libdl exists])])
  90 AC_SUBST(DLOPEN_LIB)
  91 dnl
  92 AC_ARG_WITH([cc],
  93 AC_HELP_STRING([--with-cc],[no longer supported, use CC= instead]),
  94 AC_MSG_ERROR([--with-cc no longer supported; use CC= instead]))
  95 dnl
  96 AC_ARG_WITH([ccopts],
  97 AC_HELP_STRING([--with-ccopts],[no longer supported, use CFLAGS= instead]),
  98 AC_MSG_ERROR([--with-ccopts no longer supported; use CFLAGS= instead]))
  99 dnl
 100 AC_ARG_WITH([ldopts],
 101 AC_HELP_STRING([--with-ldopts],[no longer supported, use LDFLAGS= instead]),
 102 AC_MSG_ERROR([--with-ldopts no longer supported; use LDFLAGS= instead]))
 103 dnl
 104 AC_PROG_CC
 105 if test "$GCC" = yes; then
 106    RDYNAMIC="-rdynamic"
 107    AC_SUBST(RDYNAMIC)
 108 fi
 109 AC_PROG_CPP
 110 dnl
 111 dnl Alpha computers use fast and imprecise floating point code that may
 112 dnl miss exceptions by default. Force sane options if we're using GCC.
 113 AC_MSG_CHECKING(for additional special compiler flags)
 114 if test "$GCC" = yes
 115 then
 116     case "$host_cpu" in
 117         alpha)          addcflags="-mieee" ;;
 118     esac
 119 fi
 120 if test "x$addcflags" != x
 121 then
 122     AC_MSG_RESULT($addcflags)
 123     CFLAGS="$addcflags $CFLAGS"
 124 else
 125     AC_MSG_RESULT([[(none)]])
 126 fi
 127 AC_USE_SYSTEM_EXTENSIONS
 128 dnl
 129 dnl Set default values for library extentions.  Will be dealt with after
 130 dnl parsing configuration opions, which may modify these
 131 dnl
 132 LIB_EXT=.a
 133 STATIC_LIB_EXT=.a
 134 PROFILED_LIB_EXT=.a
 135 dnl
 136 dnl Allow separate `root_prefix' to be specified
 137 dnl
 138 AC_ARG_WITH([root-prefix],
 139 [  --with-root-prefix=PREFIX override prefix variable for files to be placed in the root],
 140 root_prefix=$withval,
 141 root_prefix=NONE)dnl
 142 dnl
 143 dnl handle --enable-maintainer-mode
 144 dnl
 145 AC_ARG_ENABLE([maintainer-mode],
 146 [  --enable-maintainer-mode enable makefile rules useful for maintainers],
 147 if test "$enableval" = "no"
 148 then
 149         MAINTAINER_CMT=#
 150         AC_MSG_RESULT([Disabling maintainer mode])
 151 else
 152         MAINTAINER_CMT=
 153         AC_MSG_RESULT([Enabling maintainer mode])
 154 fi
 155 ,
 156 MAINTAINER_CMT=#
 157 AC_MSG_RESULT([Disabling maintainer mode by default])
 158 )
 159 AC_SUBST(MAINTAINER_CMT)
 160 dnl
 161 dnl handle --enable-symlink-install
 162 dnl
 163 AC_ARG_ENABLE([symlink-install],
 164 [  --enable-symlink-install use symlinks when installing instead of hard links],
 165 if test "$enableval" = "no"
 166 then
 167         LINK_INSTALL_FLAGS=-f
 168         AC_MSG_RESULT([Disabling symlinks for install])
 169 else
 170         LINK_INSTALL_FLAGS=-sf
 171         AC_MSG_RESULT([Enabling symlinks for install])
 172 fi
 173 ,
 174 LINK_INSTALL_FLAGS=-f
 175 AC_MSG_RESULT([Disabling symlinks for install by default])
 176 )
 177 AC_SUBST(LINK_INSTALL_FLAGS)
 178 dnl
 179 dnl handle --enable-relative-symlinks
 180 dnl
 181 relative_symlink_defined=
 182 AC_ARG_ENABLE([relative-symlinks],
 183 [  --enable-relative-symlinks use relative symlinks when installing],
 184 if test "$enableval" = "no"
 185 then
 186         SYMLINK_RELATIVE=
 187         relative_symlink_defined=yes
 188         AC_MSG_RESULT([Disabling relative symlinks for install])
 189 else
 190         SYMLINK_RELATIVE=--relative
 191         relative_symlink_defined=yes
 192         AC_MSG_RESULT([Enabling relative symlinks for install])
 193 fi)
 194 AC_ARG_ENABLE([symlink-relative-symlinks],,
 195 if test "$enableval" = "no"
 196 then
 197         SYMLINK_RELATIVE=yes
 198         AC_MSG_RESULT([Disabling relative symlinks for install])
 199 else
 200         SYMLINK_RELATIVE=--relative
 201         AC_MSG_RESULT([Enabling relative symlinks for install])
 202 fi
 203 ,
 204 if test -z "$relative_symlink_defined"
 205 then
 206         SYMLINK_RELATIVE=
 207 AC_MSG_RESULT([Disabling relative symlinks for install by default])
 208 fi
 209 )
 210 AC_SUBST(SYMLINK_RELATIVE)
 211 dnl
 212 dnl handle --enable-symlink-build
 213 dnl
 214 AC_ARG_ENABLE([symlink-build],
 215 [  --enable-symlink-build  use symlinks while building instead of hard links],
 216 if test "$enableval" = "no"
 217 then
 218         LINK_BUILD_FLAGS=
 219         AC_MSG_RESULT([Disabling symlinks for build])
 220 else
 221         LINK_BUILD_FLAGS=-s
 222         AC_MSG_RESULT([Enabling symlinks for build])
 223 fi
 224 ,
 225 LINK_BUILD_FLAGS=
 226 AC_MSG_RESULT([Disabling symlinks for build by default])
 227 )
 228 AC_SUBST(LINK_BUILD_FLAGS)
 229 dnl
 230 dnl handle --enable-verbose-makecmds
 231 dnl
 232 AC_ARG_ENABLE([verbose-makecmds],
 233 [  --enable-verbose-makecmds enable verbose make command output],
 234 if test "$enableval" = "no"
 235 then
 236         AC_MSG_RESULT([Disabling verbose make commands])
 237         E=@echo
 238         ES=echo
 239         Q=@
 240 else
 241         AC_MSG_RESULT([Enabling verbose make commands])
 242         E=@\\#
 243         ES=\\#
 244         Q=
 245 fi
 246 ,
 247 AC_MSG_RESULT([Disabling verbose make commands])
 248 E=@echo
 249 ES=echo
 250 Q=@
 251 )
 252 AC_SUBST(E)
 253 AC_SUBST(ES)
 254 AC_SUBST(Q)
 255 dnl
 256 dnl handle --enable-compression
 257 dnl
 258 AC_ARG_ENABLE([compression],
 259 [  --enable-compression   enable EXPERIMENTAL compression support],
 260 if test "$enableval" = "no"
 261 then
 262         AC_MSG_RESULT([Disabling compression support])
 263 else
 264         AC_DEFINE(ENABLE_COMPRESSION, 1,
 265                 [Define to 1 if ext2 compression enabled])
 266         AC_MSG_RESULT([Enabling compression support])
 267         AC_MSG_WARN([Compression support is experimental])
 268 fi
 269 ,
 270 AC_MSG_RESULT([Disabling compression support by default])
 271 )
 272 dnl
 273 dnl handle --enable-htree
 274 dnl
 275 AH_TEMPLATE([ENABLE_HTREE], [Define to 1 if ext3/4 htree support enabled])
 276 AC_ARG_ENABLE([htree],
 277 [  --enable-htree         enable EXPERIMENTAL htree directory support],
 278 if test "$enableval" = "no"
 279 then
 280         HTREE_CMT=#
 281         AC_MSG_RESULT([Disabling htree directory support])
 282 else
 283         HTREE_CMT=
 284         AC_DEFINE(ENABLE_HTREE, 1)
 285         AC_MSG_RESULT([Enabling htree directory support])
 286 fi
 287 ,
 288 HTREE_CMT=
 289 AC_DEFINE(ENABLE_HTREE, 1)
 290 AC_MSG_RESULT([Enabling htree directory support by default])
 291 )
 292 AC_SUBST(HTREE_CMT)
 293 dnl
 294 dnl This needs to be before all of the --enable-*-shlibs options
 295 dnl
 296 E2_PKG_CONFIG_STATIC=--static
 297 LDFLAG_DYNAMIC=
 298 PRIVATE_LIBS_CMT=
 299 dnl
 300 dnl handle --enable-elf-shlibs
 301 dnl
 302 AC_ARG_ENABLE([elf-shlibs],
 303 [  --enable-elf-shlibs    select ELF shared libraries],
 304 if test "$enableval" = "no"
 305 then
 306         ELF_CMT=#
 307         MAKEFILE_ELF=/dev/null
 308         AC_MSG_RESULT([Disabling ELF shared libraries])
 309 else
 310         E2_PKG_CONFIG_STATIC=
 311         ELF_CMT=
 312         MAKEFILE_ELF=$srcdir/lib/Makefile.elf-lib
 313         [case "$host_os" in
 314         solaris2.*)
 315                 MAKEFILE_ELF=$srcdir/lib/Makefile.solaris-lib
 316         ;;
 317         esac]
 318         BINARY_TYPE=elfbin
 319         LIB_EXT=.so
 320         PRIVATE_LIBS_CMT=#
 321         LDFLAG_DYNAMIC=['-Wl,-rpath-link,$(top_builddir)/lib']
 322         AC_MSG_RESULT([Enabling ELF shared libraries])
 323 fi
 324 ,
 325 MAKEFILE_ELF=/dev/null
 326 ELF_CMT=#
 327 AC_MSG_RESULT([Disabling ELF shared libraries by default])
 328 )
 329 AC_SUBST(ELF_CMT)
 330 AC_SUBST_FILE(MAKEFILE_ELF)
 331 dnl
 332 dnl handle --enable-bsd-shlibs
 333 dnl
 334 AC_ARG_ENABLE([bsd-shlibs],
 335 [  --enable-bsd-shlibs    select BSD shared libraries],
 336 if test "$enableval" = "no"
 337 then
 338         BSDLIB_CMT=#
 339         MAKEFILE_BSDLIB=/dev/null
 340         AC_MSG_RESULT([Disabling BSD shared libraries])
 341 else
 342         E2_PKG_CONFIG_STATIC=
 343         BSDLIB_CMT=
 344         MAKEFILE_BSDLIB=$srcdir/lib/Makefile.bsd-lib
 345         LIB_EXT=.so
 346         [case "$host_os" in
 347         darwin*)
 348                 MAKEFILE_BSDLIB=$srcdir/lib/Makefile.darwin-lib
 349                 LIB_EXT=.dylib
 350         ;;
 351         esac]
 352         AC_MSG_RESULT([Enabling BSD shared libraries])
 353 fi
 354 ,
 355 MAKEFILE_BSDLIB=/dev/null
 356 BSDLIB_CMT=#
 357 AC_MSG_RESULT([Disabling BSD shared libraries by default])
 358 )
 359 AC_SUBST(BSDLIB_CMT)
 360 AC_SUBST_FILE(MAKEFILE_BSDLIB)
 361 dnl
 362 dnl handle --enable-profile
 363 dnl
 364 AC_ARG_ENABLE([profile],
 365 [  --enable-profile       build profiling libraries],
 366 if test "$enableval" = "no"
 367 then
 368         PROFILE_CMT=#
 369         MAKEFILE_PROFILE=/dev/null
 370         AC_MSG_RESULT([Disabling profiling libraries])
 371 else
 372         PROFILE_CMT=
 373         MAKEFILE_PROFILE=$srcdir/lib/Makefile.profile
 374         PROFILED_LIB_EXT=_p.a
 375         AC_MSG_RESULT([Building profiling libraries])
 376 fi
 377 ,
 378 PROFILE_CMT=#
 379 MAKEFILE_PROFILE=/dev/null
 380 AC_MSG_RESULT([Disabling profiling libraries by default])
 381 )
 382 AC_SUBST(PROFILE_CMT)
 383 AC_SUBST_FILE(MAKEFILE_PROFILE)
 384 dnl
 385 dnl handle --enable-gcov
 386 dnl
 387 AC_ARG_ENABLE([gcov],
 388 [  --enable-gcov                  build for coverage testing using gcov],
 389 if test "$enableval" = "yes"
 390 then
 391         CFLAGS="-g -fprofile-arcs -ftest-coverage"
 392         LDFLAGS="-fprofile-arcs -ftest-coverage"
 393         AC_MSG_RESULT([Enabling gcov support])
 394 fi
 395 )
 396
 397 dnl
 398 dnl Substitute library extensions
 399 dnl
 400 AC_SUBST(LIB_EXT)
 401 AC_SUBST(STATIC_LIB_EXT)
 402 AC_SUBST(PROFILED_LIB_EXT)
 403 AC_SUBST(LDFLAG_DYNAMIC)
 404 AC_SUBST(PRIVATE_LIBS_CMT)
 405 dnl
 406 dnl handle --enable-jbd-debug
 407 dnl
 408 AC_ARG_ENABLE([jbd-debug],
 409 [  --enable-jbd-debug     enable journal debugging],
 410 if test "$enableval" = "no"
 411 then
 412         AC_MSG_RESULT([Disabling journal debugging])
 413 else
 414         AC_DEFINE(CONFIG_JBD_DEBUG, 1,
 415                 [Define to 1 if debugging ext3/4 journal code])
 416         AC_MSG_RESULT([Enabling journal debugging])
 417 fi
 418 ,
 419 AC_MSG_RESULT([Disabling journal debugging by default])
 420 )
 421 dnl
 422 dnl handle --enable-blkid-debug
 423 dnl
 424 AC_ARG_ENABLE([blkid-debug],
 425 [  --enable-blkid-debug    enable blkid debugging],
 426 if test "$enableval" = "no"
 427 then
 428         AC_MSG_RESULT([Disabling blkid debugging])
 429 else
 430         AC_DEFINE(CONFIG_BLKID_DEBUG, 1,
 431                 [Define to 1 if debugging the blkid library])
 432         AC_MSG_RESULT([Enabling blkid debugging])
 433 fi
 434 ,
 435 AC_MSG_RESULT([Disabling blkid debugging by default])
 436 )
 437 dnl
 438 dnl handle --enable-testio-debug
 439 dnl
 440 AC_ARG_ENABLE([testio-debug],
 441 [  --disable-testio-debug  disable the use of the test I/O manager for debugging],
 442 AH_TEMPLATE([CONFIG_TESTIO_DEBUG],
 443         [Define to 1 if the testio I/O manager should be enabled])
 444 if test "$enableval" = "no"
 445 then
 446         AC_MSG_RESULT([Disabling testio debugging])
 447         TEST_IO_CMT="#"
 448 else
 449         TEST_IO_CMT=
 450         AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 451         AC_MSG_RESULT([Enabling testio debugging])
 452 fi
 453 ,
 454 AC_MSG_RESULT([Enabling testio debugging by default])
 455 AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 456 TEST_IO_CMT=
 457 )
 458 AC_SUBST(TEST_IO_CMT)
 459 dnl
 460 dnl handle --disable-libuuid
 461 dnl
 462 PKG_PROG_PKG_CONFIG
 463 LIBUUID=
 464 DEPLIBUUID=
 465 STATIC_LIBUUID=
 466 DEPSTATIC_LIBUUID=
 467 PROFILED_LIBUUID=
 468 DEPPROFILED_LIBUUID=
 469 UUID_CMT=
 470 AC_ARG_ENABLE([libuuid],
 471 [  --disable-libuuid      do not build private uuid library],
 472 if test "$enableval" = "no"
 473 then
 474         if test -z "$PKG_CONFIG"; then
 475                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 476         fi
 477
 478         AC_CHECK_LIB(uuid, uuid_generate,
 479                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 480                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`],
 481                 [AC_MSG_ERROR([external uuid library not found])])
 482         PROFILED_LIBUUID=$LIBUUID
 483         UUID_CMT=#
 484         AC_MSG_RESULT([Disabling private uuid library])
 485 else
 486         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 487         DEPLIBUUID=$LIBUUID
 488         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 489         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 490         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 491         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 492         AC_MSG_RESULT([Enabling private uuid library])
 493 fi
 494 ,
 495 LIBUUID='$(LIB)/libuuid'$LIB_EXT
 496 DEPLIBUUID=$LIBUUID
 497 STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 498 DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 499 PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 500 DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 501 AC_MSG_RESULT([Enabling private uuid library by default])
 502 )
 503 AC_SUBST(LIBUUID)
 504 AC_SUBST(DEPLIBUUID)
 505 AC_SUBST(STATIC_LIBUUID)
 506 AC_SUBST(DEPSTATIC_LIBUUID)
 507 AC_SUBST(PROFILED_LIBUUID)
 508 AC_SUBST(DEPPROFILED_LIBUUID)
 509 AC_SUBST(UUID_CMT)
 510 dnl
 511 dnl handle --disable-libblkid
 512 dnl
 513 PKG_PROG_PKG_CONFIG
 514 LIBBLKID=
 515 DEPLIBBLKID=
 516 STATIC_LIBBLKID=
 517 DEPSTATIC_LIBBLKID=
 518 PROFILED_LIBBLKID=
 519 DEPPROFILED_LIBBLKID=
 520 BLKID_CMT=
 521 AH_TEMPLATE([CONFIG_BUILD_FINDFS], [Define to 1 to compile findfs])
 522 AC_ARG_ENABLE([libblkid],
 523 [  --disable-libblkid     do not build private blkid library],
 524 if test "$enableval" = "no"
 525 then
 526         if test -z "$PKG_CONFIG"; then
 527                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 528         fi
 529
 530         AC_CHECK_LIB(blkid, blkid_get_cache,
 531                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 532                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`],
 533                 [AC_MSG_ERROR([external blkid library not found])], -luuid)
 534         BLKID_CMT=#
 535         PROFILED_LIBBLKID=$LIBBLKID
 536         AC_MSG_RESULT([Disabling private blkid library])
 537 else
 538         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 539         DEPLIBBLKID=$LIBBLKID
 540         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 541         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 542         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 543         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 544         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 545         AC_MSG_RESULT([Enabling private blkid library])
 546 fi
 547 ,
 548 LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 549 DEPLIBBLKID=$LIBBLKID
 550 STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 551 DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 552 PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 553 DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 554 AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 555 AC_MSG_RESULT([Enabling private blkid library by default])
 556 )
 557 AC_SUBST(LIBBLKID)
 558 AC_SUBST(DEPLIBBLKID)
 559 AC_SUBST(STATIC_LIBBLKID)
 560 AC_SUBST(DEPSTATIC_LIBBLKID)
 561 AC_SUBST(PROFILED_LIBBLKID)
 562 AC_SUBST(DEPPROFILED_LIBBLKID)
 563 AC_SUBST(BLKID_CMT)
 564 dnl
 565 dnl handle --enable-quota
 566 dnl
 567 QUOTA_MAN_COMMENT='.\"'
 568 QUOTA_CMT=
 569 AC_SUBST(QUOTA_MAN_COMMENT)
 570 PKG_PROG_PKG_CONFIG
 571 AH_TEMPLATE([CONFIG_QUOTA], [Define to 1 to enable quota support])
 572 AC_ARG_ENABLE([quota],
 573 [  --enable-quota         enable quota support],
 574 if test "$enableval" = "no"
 575 then
 576         QUOTA_CMT=#
 577         AC_MSG_RESULT([Disabling quota support])
 578 else
 579         QUOTA_CMT=
 580         AC_DEFINE(CONFIG_QUOTA, 1)
 581         AC_MSG_RESULT([Enabling quota support])
 582         QUOTA_MAN_COMMENT=""
 583         AC_SUBST(QUOTA_MAN_COMMENT)
 584 fi
 585 ,
 586 QUOTA_CMT=#
 587 AC_MSG_RESULT([Disabling quota support by default])
 588 )
 589 dnl
 590 dnl Define stuff expected for quota library
 591 dnl
 592 LIBQUOTA='$(LIB)/libquota'$LIB_EXT
 593 DEPLIBQUOTA=$LIBQUOTA
 594 STATIC_LIBQUOTA='$(LIB)/libquota'$STATIC_LIB_EXT
 595 DEPSTATIC_LIBQUOTA=$STATIC_LIBQUOTA
 596 PROFILED_LIBQUOTA='$(LIB)/libquota'$PROFILED_LIB_EXT
 597 DEPPROFILED_LIBQUOTA=$PROFILED_LIBQUOTA
 598 AC_SUBST(LIBQUOTA)
 599 AC_SUBST(DEPLIBQUOTA)
 600 AC_SUBST(STATIC_LIBQUOTA)
 601 AC_SUBST(DEPSTATIC_LIBQUOTA)
 602 AC_SUBST(PROFILED_LIBQUOTA)
 603 AC_SUBST(DEPPROFILED_LIBQUOTA)
 604 AC_SUBST(QUOTA_CMT)
 605 dnl
 606 dnl handle --disable-backtrace
 607 dnl
 608 AH_TEMPLATE([DISABLE_BACKTRACE], [Define to 1 to disable use of backtrace])
 609 AC_ARG_ENABLE([backtrace],
 610 [  --disable-backtrace    disable use backtrace],
 611 if test "$enableval" = "no"
 612 then
 613         AC_MSG_RESULT([Disabling use of backtrace])
 614         AC_DEFINE(DISABLE_BACKTRACE, 1)
 615 else
 616         AC_MSG_RESULT([Enabling use of backtrace])
 617 fi
 618 ,
 619 AC_MSG_RESULT([Enabling use of backtrace by default])
 620 )
 621 dnl
 622 dnl handle --enable-debugfs
 623 dnl
 624 AC_ARG_ENABLE([debugfs],
 625 [  --disable-debugfs      disable support of debugfs program],
 626 if test "$enableval" = "no"
 627 then
 628         AC_MSG_RESULT([Disabling debugfs support])
 629         DEBUGFS_CMT="#"
 630 else
 631         DEBUGFS_CMT=
 632         AC_MSG_RESULT([Enabling debugfs support])
 633 fi
 634 ,
 635 AC_MSG_RESULT([Enabling debugfs support by default])
 636 DEBUGFS_CMT=
 637 )
 638 AC_SUBST(DEBUGFS_CMT)
 639 dnl
 640 dnl handle --enable-imager
 641 dnl
 642 AC_ARG_ENABLE([imager],
 643 [  --disable-imager       disable support of e2image program],
 644 if test "$enableval" = "no"
 645 then
 646         AC_MSG_RESULT([Disabling e2image support])
 647         IMAGER_CMT="#"
 648 else
 649         IMAGER_CMT=
 650         AC_MSG_RESULT([Enabling e2image support])
 651 fi
 652 ,
 653 AC_MSG_RESULT([Enabling e2image support by default])
 654 IMAGER_CMT=
 655 )
 656 AC_SUBST(IMAGER_CMT)
 657 dnl
 658 dnl handle --enable-resizer
 659 dnl
 660 AC_ARG_ENABLE([resizer],
 661 [  --disable-resizer      disable support of e2resize program],
 662 if test "$enableval" = "no"
 663 then
 664         AC_MSG_RESULT([Disabling e2resize support])
 665         RESIZER_CMT="#"
 666 else
 667         RESIZER_CMT=
 668         AC_MSG_RESULT([Enabling e2resize support])
 669 fi
 670 ,
 671 AC_MSG_RESULT([Enabling e2resize support by default])
 672 RESIZER_CMT=
 673 )
 674 AC_SUBST(RESIZER_CMT)
 675 dnl
 676 dnl handle --enable-defrag
 677 dnl
 678 AC_ARG_ENABLE([defrag],
 679 [  --disable-defrag       disable support of e4defrag program],
 680 if test "$enableval" = "no"
 681 then
 682         AC_MSG_RESULT([Disabling e4defrag support])
 683         DEFRAG_CMT="#"
 684 else
 685         DEFRAG_CMT=
 686         AC_MSG_RESULT([Enabling e4defrag support])
 687 fi
 688 ,
 689 if test -z "$WITH_DIET_LIBC"
 690 then
 691         AC_MSG_RESULT([Enabling e4defrag support by default])
 692         DEFRAG_CMT=
 693 else
 694         AC_MSG_RESULT([Disabling e4defrag support by default])
 695         DEFRAG_CMT="#"
 696 fi
 697 )
 698 AC_SUBST(DEFRAG_CMT)
 699 dnl
 700 dnl See whether to install the `fsck' wrapper program (that calls e2fsck)
 701 dnl
 702 AC_ARG_ENABLE([fsck],
 703 [  --enable-fsck           build fsck wrapper program],
 704 [if test "$enableval" = "no"
 705 then
 706         FSCK_PROG='' FSCK_MAN=''
 707         AC_MSG_RESULT([Not building fsck wrapper])
 708 else
 709         FSCK_PROG=fsck FSCK_MAN=fsck.8
 710         AC_MSG_RESULT([Building fsck wrapper])
 711 fi]
 712 ,
 713 [case "$host_os" in
 714   gnu*)
 715     FSCK_PROG='' FSCK_MAN=''
 716     AC_MSG_RESULT([Not building fsck wrapper by default])
 717     ;;
 718   *)
 719     FSCK_PROG=fsck FSCK_MAN=fsck.8
 720     AC_MSG_RESULT([Building fsck wrapper by default])
 721 esac]
 722 )
 723 AC_SUBST(FSCK_PROG)
 724 AC_SUBST(FSCK_MAN)
 725 dnl
 726 dnl See whether to install the `e2initrd-helper' program
 727 dnl
 728 AC_ARG_ENABLE([e2initrd-helper],
 729 [  --enable-e2initrd-helper build e2initrd-helper program],
 730 [if test "$enableval" = "no"
 731 then
 732         E2INITRD_PROG='' E2INITRD_MAN=''
 733         AC_MSG_RESULT([Not building e2initrd helper])
 734 else
 735         E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 736         AC_MSG_RESULT([Building e2initrd helper])
 737 fi]
 738 ,
 739 E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 740 AC_MSG_RESULT([Building e2initrd helper by default])
 741 )
 742 AC_SUBST(E2INITRD_PROG)
 743 AC_SUBST(E2INITRD_MAN)
 744 dnl
 745 dnl
 746 dnl
 747 AC_ARG_ENABLE([tls],
 748 [  --disable-tls           disable use of thread local support],
 749 [if test "$enableval" = "no"
 750 then
 751         try_tls=""
 752         AC_MSG_RESULT([Disabling thread local support])
 753 else
 754         try_tls="yes"
 755         AC_MSG_RESULT([Enabling thread local support])
 756 fi]
 757 ,
 758 if test -n "$WITH_DIET_LIBC"
 759 then
 760         try_tls=""
 761         AC_MSG_RESULT([Diet libc does not support thread local support])
 762 else
 763         try_tls="yes"
 764         AC_MSG_RESULT([Try using thread local support by default])
 765 fi
 766 )
 767 if test "$try_tls" = "yes"
 768 then
 769 AX_TLS
 770 fi
 771 dnl
 772 dnl
 773 dnl
 774 AH_TEMPLATE([USE_UUIDD], [Define to 1 to build uuidd])
 775 AC_ARG_ENABLE([uuidd],
 776 [  --disable-uuidd         disable building the uuid daemon],
 777 [if test "$enableval" = "no"
 778 then
 779         AC_MSG_RESULT([Not building uuidd])
 780         UUIDD_CMT="#"
 781 else
 782         AC_DEFINE(USE_UUIDD, 1)
 783         UUIDD_CMT=""
 784         AC_MSG_RESULT([Building uuidd])
 785 fi]
 786 ,
 787 AC_DEFINE(USE_UUIDD, 1)
 788 if test -z "$UUID_CMT"
 789 then
 790         UUIDD_CMT=""
 791         AC_MSG_RESULT([Building uuidd by default])
 792 else
 793         UUIDD_CMT="#"
 794         AC_MSG_RESULT([Disabling uuidd by default])
 795 fi
 796 )
 797 AC_SUBST(UUIDD_CMT)
 798 dnl
 799 dnl handle --disable-mmp
 800 dnl
 801 AH_TEMPLATE([CONFIG_MMP], [Define to 1 to enable mmp support])
 802 AC_ARG_ENABLE([mmp],
 803 [  --disable-mmp           disable support mmp, Multi Mount Protection],
 804 if test "$enableval" = "no"
 805 then
 806         AC_MSG_RESULT([Disabling mmp support])
 807 else
 808         AC_MSG_RESULT([Enabling mmp support])
 809         AC_DEFINE(CONFIG_MMP, 1)
 810 fi
 811 ,
 812 AC_MSG_RESULT([Enabling mmp support by default])
 813 AC_DEFINE(CONFIG_MMP, 1)
 814 )
 815 dnl
 816 dnl handle --disable-bmap-stats
 817 dnl
 818 AH_TEMPLATE([ENABLE_BMAP_STATS], [Define to 1 to enable bitmap stats.])
 819 AC_ARG_ENABLE([bmap-stats],
 820 [  --disable-bmap-stats    disable collection of bitmap stats.],
 821 if test "$enableval" = "no"
 822 then
 823         AC_MSG_RESULT([Disabling bitmap statistics support])
 824 else
 825         AC_MSG_RESULT([Enabling bitmap statistics support])
 826         AC_DEFINE(ENABLE_BMAP_STATS, 1)
 827 fi
 828 ,
 829 AC_MSG_RESULT([Enabling bitmap statistics support by default])
 830 AC_DEFINE(ENABLE_BMAP_STATS, 1)
 831 )
 832 dnl
 833 dnl handle --enable-bmap-stats-ops
 834 dnl
 835 AH_TEMPLATE([ENABLE_BMAP_STATS_OPS], [Define to 1 to enable bitmap stats.])
 836 AC_ARG_ENABLE([bmap-stats-ops],
 837 [  --enable-bmap-stats-ops enable collection of additional bitmap stats],
 838 if test "$enableval" = "no"
 839 then
 840         AC_MSG_RESULT([Disabling additional bitmap statistics])
 841 else
 842         dnl There has to be a better way!
 843         AS_IF([test "x${enable_bmap_stats}" = "xno"],
 844          AC_MSG_FAILURE([Error --enable-bmap-stats-ops requires bmap-stats]))
 845
 846         AC_MSG_RESULT([Enabling additional bitmap statistics])
 847         AC_DEFINE(ENABLE_BMAP_STATS_OPS, 1)
 848 fi
 849 ,
 850 AC_MSG_RESULT([Disabling additional bitmap statistics by default])
 851 )
 852 dnl
 853 dnl
 854 dnl
 855 MAKEFILE_LIBRARY=$srcdir/lib/Makefile.library
 856 AC_SUBST_FILE(MAKEFILE_LIBRARY)
 857 dnl
 858 dnl Add internationalization support, using gettext.
 859 dnl
 860 GETTEXT_PACKAGE=e2fsprogs
 861 PACKAGE=e2fsprogs
 862 VERSION="$E2FSPROGS_VERSION"
 863 VERSION=0.14.1
 864 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [package name for gettext])
 865 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [version for gettext])
 866 AC_SUBST(GETTEXT_PACKAGE)
 867 AC_SUBST(PACKAGE)
 868 AC_SUBST(VERSION)
 869
 870 AM_GNU_GETTEXT
 871 dnl
 872 dnl End of configuration options
 873 dnl
 874 AC_SUBST(BINARY_TYPE)
 875 AC_PROG_MAKE_SET
 876 CHECK_GNU_MAKE
 877 AC_PATH_PROG(LN, ln, ln)
 878 AC_PROG_LN_S
 879 AC_PATH_PROG(MV, mv, mv)
 880 AC_PATH_PROG(CP, cp, cp)
 881 AC_PATH_PROG(RM, rm, rm)
 882 AC_PATH_PROG(CHMOD, chmod, :)
 883 AC_PROG_AWK
 884 AC_PROG_EGREP
 885 AC_PATH_PROG(SED, sed, sed)
 886 AC_PATH_PROG(PERL, perl, perl)
 887 AC_PATH_PROG(LDCONFIG, ldconfig, :)
 888 AC_CHECK_TOOL(AR, ar, ar)
 889 AC_CHECK_TOOL(RANLIB, ranlib, :)
 890 AC_CHECK_TOOL(STRIP, strip, :)
 891 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
 892 if test "_$MAKEINFO" = "_"; then
 893     MAKEINFO="@echo Makeinfo is missing. Info documentation will not be built.;true"
 894 else
 895     case "$MAKEINFO" in
 896       */missing.*)
 897         AC_MSG_WARN([
 898 *** Makeinfo is missing. Info documentation will not be built.])
 899         ;;
 900       *)
 901         ;;
 902     esac
 903 fi
 904 AC_SUBST(MAKEINFO)
 905 AC_PROG_INSTALL
 906 # See if we need a separate native compiler.
 907 if test $cross_compiling = no; then
 908   BUILD_CC="$CC"
 909   AC_SUBST(BUILD_CC)
 910 else
 911   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 912 fi
 913 AC_CHECK_HEADERS(m4_flatten([
 914         dirent.h
 915         errno.h
 916         execinfo.h
 917         getopt.h
 918         malloc.h
 919         mntent.h
 920         paths.h
 921         semaphore.h
 922         setjmp.h
 923         signal.h
 924         stdarg.h
 925         stdint.h
 926         stdlib.h
 927         termios.h
 928         termio.h
 929         unistd.h
 930         utime.h
 931         attr/xattr.h
 932         linux/falloc.h
 933         linux/fd.h
 934         linux/major.h
 935         linux/loop.h
 936         net/if_dl.h
 937         netinet/in.h
 938         sys/disklabel.h
 939         sys/disk.h
 940         sys/file.h
 941         sys/ioctl.h
 942         sys/mkdev.h
 943         sys/mman.h
 944         sys/mount.h
 945         sys/prctl.h
 946         sys/resource.h
 947         sys/select.h
 948         sys/socket.h
 949         sys/sockio.h
 950         sys/stat.h
 951         sys/syscall.h
 952         sys/sysmacros.h
 953         sys/time.h
 954         sys/types.h
 955         sys/un.h
 956         sys/wait.h
 957 ]))
 958 AC_CHECK_HEADERS(net/if.h,,,
 959 [[
 960 #if HAVE_SYS_TYPES_H
 961 #include <sys/types.h>
 962 #endif
 963 #if HAVE_SYS_SOCKET
 964 #include <sys/socket.h>
 965 #endif
 966 ]])
 967 AC_FUNC_VPRINTF
 968 dnl Check to see if dirent has member d_reclen. On cygwin those d_reclen
 969 dnl is not decleared.
 970 AC_CHECK_MEMBER(struct dirent.d_reclen,[AC_DEFINE(HAVE_RECLEN_DIRENT, 1,
 971                        [Define to 1 if dirent has d_reclen])],,
 972                 [#include <dirent.h>])
 973 AC_CHECK_MEMBERS([struct stat.st_atim])
 974 dnl Check to see if ssize_t was declared
 975 AC_CHECK_TYPE(ssize_t,[AC_DEFINE(HAVE_TYPE_SSIZE_T, 1,
 976                 [Define to 1 if ssize_t declared])],,
 977               [#include <sys/types.h>])
 978 dnl
 979 dnl Check to see if llseek() is declared in unistd.h.  On some libc's
 980 dnl it is, and on others it isn't..... Thank you glibc developers....
 981 dnl
 982 AC_CHECK_DECL(llseek,[AC_DEFINE(HAVE_LLSEEK_PROTOTYPE, 1,
 983                         [Define to 1 if llseek declared in unistd.h])],,
 984               [#include <unistd.h>])
 985 dnl
 986 dnl Check to see if lseek64() is declared in unistd.h.  Glibc's header files
 987 dnl are so convoluted that I can't tell whether it will always be defined,
 988 dnl and if it isn't defined while lseek64 is defined in the library,
 989 dnl disaster will strike.
 990 dnl
 991 dnl Warning!  Use of --enable-gcc-wall may throw off this test.
 992 dnl
 993 dnl
 994 AC_CHECK_DECL(lseek64,[AC_DEFINE(HAVE_LSEEK64_PROTOTYPE, 1,
 995                         [Define to 1 if lseek64 declared in unistd.h])],,
 996                 [#define _LARGEFILE_SOURCE
 997                  #define _LARGEFILE64_SOURCE
 998                  #include <unistd.h>])
 999 dnl
1000 dnl Word sizes...
1001 dnl
1002 AC_CHECK_SIZEOF(short)
1003 AC_CHECK_SIZEOF(int)
1004 AC_CHECK_SIZEOF(long)
1005 AC_CHECK_SIZEOF(long long)
1006 AC_CHECK_SIZEOF(off_t)
1007 SIZEOF_SHORT=$ac_cv_sizeof_short
1008 SIZEOF_INT=$ac_cv_sizeof_int
1009 SIZEOF_LONG=$ac_cv_sizeof_long
1010 SIZEOF_LONG_LONG=$ac_cv_sizeof_long_long
1011 SIZEOF_OFF_T=$ac_cv_sizeof_off_t
1012 AC_SUBST(SIZEOF_SHORT)
1013 AC_SUBST(SIZEOF_INT)
1014 AC_SUBST(SIZEOF_LONG)
1015 AC_SUBST(SIZEOF_LONG_LONG)
1016 AC_SUBST(SIZEOF_OFF_T)
1017 AC_C_BIGENDIAN
1018 if test $cross_compiling = no; then
1019   BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
1020 else
1021   CROSS_COMPILE="1" BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
1022 fi
1023 ASM_TYPES_HEADER=./asm_types.h
1024 AC_SUBST_FILE(ASM_TYPES_HEADER)
1025 dnl
1026 dnl Save the configuration #defines needed for the public ext2fs.h
1027 dnl header file
1028 dnl
1029 echo "/* These defines are needed for the public ext2fs.h header file */" \
1030      > public_config.h
1031 if grep HAVE_SYS_TYPES_H confdefs.h > tmp_config.$$; then
1032   uniq tmp_config.$$ >> public_config.h
1033 else
1034   echo "#undef HAVE_SYS_TYPES_H" >> public_config.h
1035 fi
1036 if grep WORDS_BIGENDIAN confdefs.h > tmp_config.$$; then
1037   uniq tmp_config.$$ >> public_config.h
1038 else
1039   echo "#undef WORDS_BIGENDIAN" >> public_config.h
1040 fi
1041 rm -f tmp_config.$$
1042 PUBLIC_CONFIG_HEADER=./public_config.h
1043 AC_SUBST_FILE(PUBLIC_CONFIG_HEADER)
1044 dnl
1045 dnl See if we have inttypes.h and if intptr_t is defined
1046 dnl
1047 AC_CHECK_HEADERS([inttypes.h])
1048 AC_CHECK_TYPES(intptr_t)
1049 dnl
1050 dnl See if struct stat has a st_flags field, in which case we can get file
1051 dnl flags somewhat portably.  Also check for the analogous setter, chflags().
1052 dnl
1053 AC_MSG_CHECKING(whether struct stat has a st_flags field)
1054 AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags,
1055         AC_TRY_COMPILE([#include <sys/stat.h>],
1056                 [struct stat stat; stat.st_flags = 0;],
1057                 [e2fsprogs_cv_struct_st_flags=yes],
1058                 [e2fsprogs_cv_struct_st_flags=no]))
1059 AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags)
1060 if test "$e2fsprogs_cv_struct_st_flags" = yes; then
1061   AC_MSG_CHECKING(whether st_flags field is useful)
1062   AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags_immut,
1063         AC_TRY_COMPILE([#include <sys/stat.h>],
1064                 [struct stat stat; stat.st_flags |= UF_IMMUTABLE;],
1065                 [e2fsprogs_cv_struct_st_flags_immut=yes],
1066                 [e2fsprogs_cv_struct_st_flags_immut=no]))
1067   AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags_immut)
1068   if test "$e2fsprogs_cv_struct_st_flags_immut" = yes; then
1069           AC_DEFINE(HAVE_STAT_FLAGS, 1,
1070                 [Define to 1 if struct stat has st_flags])
1071   fi
1072 fi
1073 dnl
1074 dnl Check for the presence of SA_LEN
1075 dnl
1076 AC_CHECK_MEMBER(struct sockaddr.sa_len,
1077                 AC_DEFINE_UNQUOTED(HAVE_SA_LEN,1,
1078                         [Define to 1 if if struct sockaddr contains sa_len]),,
1079         [#include <sys/types.h>
1080          #include <sys/socket.h>])
1081 dnl
1082 dnl This will add -lblkid to the AC_CHECK_FUNCS search if we are using
1083 dnl the system-provided blkid library
1084 dnl
1085 if test -n "$BLKID_CMT"; then
1086   AC_SEARCH_LIBS([blkid_probe_all], [blkid])
1087 fi
1088 dnl
1089 AC_CHECK_FUNCS(m4_flatten([
1090         __secure_getenv
1091         backtrace
1092         blkid_probe_get_topology
1093         blkid_probe_enable_partitions
1094         chflags
1095         fadvise64
1096         fallocate
1097         fallocate64
1098         fchown
1099         fdatasync
1100         fstat64
1101         ftruncate64
1102         futimes
1103         getcwd
1104         getdtablesize
1105         getmntinfo
1106         getpwuid_r
1107         getrlimit
1108         getrusage
1109         jrand48
1110         llistxattr
1111         llseek
1112         lseek64
1113         mallinfo
1114         mbstowcs
1115         memalign
1116         mempcpy
1117         mmap
1118         msync
1119         nanosleep
1120         open64
1121         pathconf
1122         posix_fadvise
1123         posix_fadvise64
1124         posix_memalign
1125         prctl
1126         pread
1127         pwrite
1128         pread64
1129         pwrite64
1130         secure_getenv
1131         setmntent
1132         setresgid
1133         setresuid
1134         snprintf
1135         srandom
1136         stpcpy
1137         strcasecmp
1138         strdup
1139         strnlen
1140         strptime
1141         strtoull
1142         sync_file_range
1143         sysconf
1144         usleep
1145         utime
1146         valloc
1147 ]))
1148 dnl
1149 dnl Check to see if -lsocket is required (solaris) to make something
1150 dnl that uses socket() to compile; this is needed for the UUID library
1151 dnl
1152 SOCKET_LIB=''
1153 AC_CHECK_LIB(socket, socket, [SOCKET_LIB=-lsocket])
1154 AC_SUBST(SOCKET_LIB)
1155 dnl
1156 dnl See if optreset exists
1157 dnl
1158 AC_MSG_CHECKING(for optreset)
1159 AC_CACHE_VAL(ac_cv_have_optreset,
1160 [AC_EGREP_HEADER(optreset, unistd.h,
1161   ac_cv_have_optreset=yes, ac_cv_have_optreset=no)])dnl
1162 AC_MSG_RESULT($ac_cv_have_optreset)
1163 if test $ac_cv_have_optreset = yes; then
1164   AC_DEFINE(HAVE_OPTRESET, 1, [Define to 1 if optreset for getopt is present])
1165 fi
1166 dnl
1167 dnl Test for sem_init, and which library it might require:
1168 dnl
1169 AH_TEMPLATE([HAVE_SEM_INIT], [Define to 1 if sem_init() exists])
1170 SEM_INIT_LIB=''
1171 AC_CHECK_FUNC(sem_init, ,
1172   AC_CHECK_LIB(pthread, sem_init,
1173         AC_DEFINE(HAVE_SEM_INIT, 1)
1174         SEM_INIT_LIB=-lpthread,
1175   AC_CHECK_LIB(rt, sem_init,
1176         AC_DEFINE(HAVE_SEM_INIT, 1)
1177         SEM_INIT_LIB=-lrt,
1178   AC_CHECK_LIB(posix4, sem_init,
1179         AC_DEFINE(HAVE_SEM_INIT, 1)
1180         SEM_INIT_LIB=-lposix4))))dnl
1181 AC_SUBST(SEM_INIT_LIB)
1182 dnl
1183 dnl Check for unified diff
1184 dnl
1185 AC_MSG_CHECKING(for unified diff option)
1186 if diff -u $0 $0 > /dev/null 2>&1 ; then
1187    UNI_DIFF_OPTS=-u
1188 else
1189    UNI_DIFF_OPTS=-c
1190 fi
1191 AC_MSG_RESULT($UNI_DIFF_OPTS)
1192 AC_SUBST(UNI_DIFF_OPTS)
1193 dnl
1194 dnl We use the EXT2 ioctls only under Linux
1195 dnl
1196 case "$host_os" in
1197 linux*)
1198         AC_DEFINE(HAVE_EXT2_IOCTLS, 1, [Define to 1 if Ext2 ioctls present])
1199         ;;
1200 esac
1201 dnl
1202 dnl OS-specific uncomment control
1203 dnl
1204 LINUX_CMT="#"
1205 CYGWIN_CMT="#"
1206 UNIX_CMT=
1207 case "$host_os" in
1208 linux*)
1209         LINUX_CMT=
1210         ;;
1211 cygwin)
1212         CYGWIN_CMT=
1213         UNIX_CMT="#"
1214         ;;
1215 esac
1216 AC_SUBST(LINUX_CMT)
1217 AC_SUBST(CYGWIN_CMT)
1218 AC_SUBST(UNIX_CMT)
1219 dnl
1220 dnl Linux and Hurd places root files in the / by default
1221 dnl
1222 case "$host_os" in
1223 linux* | gnu* | k*bsd*-gnu)
1224         if test "$prefix" = NONE -a "$root_prefix" = NONE ; then
1225                 root_prefix="";
1226                 AC_MSG_RESULT([On $host_os systems, root_prefix defaults to ''])
1227         fi
1228         ;;
1229 esac
1230 dnl
1231 dnl On Linux/hurd, force the prefix to be /usr
1232 dnl
1233 case "$host_os" in
1234 linux* | gnu* | k*bsd*-gnu)
1235         if test "$prefix" = NONE ; then
1236                 prefix="/usr";
1237                 AC_MSG_RESULT([On $host_os systems, prefix defaults to /usr])
1238                 if test "$mandir" = '${prefix}/man' ; then
1239                         AC_MSG_RESULT([...and mandir defaults to /usr/share/man])
1240                         mandir=/usr/share/man
1241                 fi
1242         fi
1243 ;;
1244 esac
1245 if test "$root_prefix" = NONE ; then
1246         if test "$prefix" = NONE ; then
1247                 root_prefix="$ac_default_prefix"
1248         else
1249                 root_prefix="$prefix"
1250         fi
1251         root_bindir=$bindir
1252         root_sbindir=$sbindir
1253         root_libdir=$libdir
1254         root_sysconfdir=$sysconfdir
1255 else
1256         root_bindir='${root_prefix}/bin'
1257         root_sbindir='${root_prefix}/sbin'
1258         root_libdir='${root_prefix}/lib'
1259         root_sysconfdir='${root_prefix}/etc'
1260 fi
1261 if test "$bindir" != '${exec_prefix}/bin'; then
1262     root_bindir=$bindir
1263     AC_MSG_RESULT([Setting root_bindir to $root_bindir])
1264 fi
1265 if test "$sbindir" != '${exec_prefix}/sbin'; then
1266     root_sbindir=$sbindir
1267     AC_MSG_RESULT([Setting root_sbindir to $root_sbindir])
1268 fi
1269 if test "$libdir" != '${exec_prefix}/lib'; then
1270     root_libdir=$libdir
1271     AC_MSG_RESULT([Setting root_libdir to $root_libdir])
1272 fi
1273 if test "$sysconfdir" != '${prefix}/etc'; then
1274     root_sysconfdir=$sysconfdir
1275     AC_MSG_RESULT([Setting root_sysconfdir to $root_sysconfdir])
1276 fi
1277 AC_SUBST(root_prefix)
1278 AC_SUBST(root_bindir)
1279 AC_SUBST(root_sbindir)
1280 AC_SUBST(root_libdir)
1281 AC_SUBST(root_sysconfdir)
1282 dnl
1283 dnl Allow specification of the multiarch arch
1284 dnl
1285 AC_ARG_WITH([multiarch],
1286 [  --with-multiarch=ARCH specify the multiarch triplet],
1287 if test "$withval" = "lib64"; then
1288     libdir=/usr/lib64
1289     root_libdir=/lib64
1290 else
1291     libdir=$libdir/$withval
1292     root_libdir=$root_libdir/$withval
1293 fi
1294 )dnl
1295 dnl
1296 dnl See if -static works.  This could fail if the linker does not
1297 dnl support -static, or if required external libraries are not available
1298 dnl in static form.
1299 dnl
1300 AC_MSG_CHECKING([whether we can link with -static])
1301 AC_CACHE_VAL(ac_cv_e2fsprogs_use_static,
1302 [SAVE_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -static"
1303 AC_TRY_LINK([#include <stdio.h>],[fflush(stdout);],
1304  ac_cv_e2fsprogs_use_static=yes, ac_cv_e2fsprogs_use_static=no)
1305 LDFLAGS=$SAVE_LDFLAGS])
1306 dnl
1307 dnl Regardless of how the test turns out, Solaris doesn't handle -static
1308 dnl This is caused by the socket library requiring the nsl library, which
1309 dnl requires the -dl library, which only works for dynamically linked
1310 dnl programs.  It basically means you can't have statically linked programs
1311 dnl which use the network under Solaris.
1312 dnl
1313 case "$host_os" in
1314 solaris2.*)
1315         ac_cv_e2fsprogs_use_static=no
1316 ;;
1317 esac
1318 AC_MSG_RESULT($ac_cv_e2fsprogs_use_static)
1319 LDFLAG_STATIC=
1320 if test $ac_cv_e2fsprogs_use_static = yes; then
1321         LDFLAG_STATIC=-static
1322 fi
1323 AC_SUBST(LDFLAG_STATIC)
1324 dnl
1325 dnl Work around mysterious Darwin / GNU libintl problem
1326 dnl (__asm__ redirection doesn't work for some mysterious reason.  Looks like
1327 dnl Apple hacked gcc somehow?)
1328 dnl
1329 case "$host_os" in
1330 darwin*)
1331         AC_MSG_RESULT([Using Apple Darwin / GNU libintl workaround])
1332         AC_DEFINE(_INTL_REDIRECT_MACROS, 1,
1333                 [Define to 1 if Apple Darwin libintl workaround is needed])
1334         ;;
1335 esac
1336 dnl
1337 dnl Make the ss and et directories work correctly.
1338 dnl
1339 SS_DIR=`cd ${srcdir}/lib/ss; pwd`
1340 ET_DIR=`cd ${srcdir}/lib/et; pwd`
1341 AC_SUBST(SS_DIR)
1342 AC_SUBST(ET_DIR)
1343 dnl
1344 dnl Only try to run the test suite if we're not cross compiling.
1345 dnl
1346 if test "$cross_compiling" = yes ; then
1347   DO_TEST_SUITE=
1348 else
1349   DO_TEST_SUITE=check
1350 fi
1351 AC_SUBST(DO_TEST_SUITE)
1352 dnl
1353 dnl Only include the intl include files if we're building with them
1354 dnl
1355 INCLUDES='-I. -I$(top_builddir)/lib -I$(top_srcdir)/lib'
1356 if test -n "$CPPFLAGS" ; then
1357         INCLUDES="$INCLUDES $CPPFLAGS"
1358 fi
1359 if test "$USE_INCLUDED_LIBINTL" = "yes" ; then
1360         INCLUDES=$INCLUDES' -I$(top_builddir)/intl -I$(top_srcdir)/intl'
1361 fi
1362 if test -n "$WITH_DIET_LIBC" ; then
1363         INCLUDES="$INCLUDES -D_REENTRANT"
1364 fi
1365 AC_SUBST(INCLUDES)
1366 AM_MKINSTALLDIRS
1367 dnl
1368 dnl Build CFLAGS
1369 dnl
1370 if test $cross_compiling = no; then
1371    BUILD_CFLAGS="$CFLAGS $CPPFLAGS $INCLUDES -DHAVE_CONFIG_H"
1372    BUILD_LDFLAGS="$LDFLAGS"
1373 fi
1374 AC_SUBST(BUILD_CFLAGS)
1375 AC_SUBST(BUILD_LDFLAGS)
1376 dnl
1377 dnl Make our output files, being sure that we create the some miscellaneous
1378 dnl directories
1379 dnl
1380 test -d lib || mkdir lib
1381 test -d include || mkdir include
1382 test -d include/linux || mkdir include/linux
1383 test -d include/asm || mkdir include/asm
1384 for i in MCONFIG Makefile e2fsprogs.spec \
1385         util/Makefile util/subst.conf util/gen-tarball util/install-symlink \
1386         lib/et/Makefile lib/ss/Makefile lib/e2p/Makefile \
1387         lib/ext2fs/Makefile lib/ext2fs/ext2_types.h \
1388         lib/uuid/Makefile lib/uuid/uuid_types.h \
1389         lib/blkid/Makefile lib/blkid/blkid_types.h lib/quota/Makefile \
1390         lib/ss/ss.pc lib/uuid/uuid.pc lib/et/com_err.pc \
1391         lib/e2p/e2p.pc lib/blkid/blkid.pc lib/ext2fs/ext2fs.pc \
1392         misc/Makefile ext2ed/Makefile e2fsck/Makefile \
1393         debugfs/Makefile tests/Makefile tests/progs/Makefile \
1394         resize/Makefile doc/Makefile intl/Makefile \
1395         intl/libgnuintl.h po/Makefile.in ; do
1396         if test -d `dirname ${srcdir}/$i` ; then
1397                 outlist="$outlist $i"
1398         fi
1399 done
1400 AC_OUTPUT($outlist)
1401 if test -f util/gen-tarball; then chmod +x util/gen-tarball; fi