configure.in

   1 AC_INIT(version.h)
   2 AC_PREREQ(2.50)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_HEADERS([lib/config.h])
   5 AH_BOTTOM([#include "dirpaths.h"])
   6 MCONFIG=./MCONFIG
   7 AC_SUBST_FILE(MCONFIG)
   8 BINARY_TYPE=bin
   9 dnl
  10 dnl This is to figure out the version number and the date....
  11 dnl
  12 E2FSPROGS_VERSION=`grep E2FSPROGS_VERSION ${srcdir}/version.h  \
  13         | awk '{print $3}' | tr \" " " | awk '{print $1}'`
  14 DATE=`grep E2FSPROGS_DATE ${srcdir}/version.h | awk '{print $3}' \
  15         | tr \" " "`
  16 E2FSPROGS_DAY=`echo $DATE | awk -F- '{print $1}'`
  17 MONTH=`echo $DATE | awk -F- '{print $2}'`
  18 YEAR=`echo $DATE | awk -F- '{print $3}'`
  19
  20 if expr $YEAR ">" 1900 > /dev/null ; then
  21         E2FSPROGS_YEAR=$YEAR
  22 elif expr $YEAR ">" 90 >/dev/null ; then
  23         E2FSPROGS_YEAR=19$YEAR
  24 else
  25         E2FSPROGS_YEAR=20$YEAR
  26 fi
  27
  28 case $MONTH in
  29 Jan)    MONTH_NUM=01; E2FSPROGS_MONTH="January" ;;
  30 Feb)    MONTH_NUM=02; E2FSPROGS_MONTH="February" ;;
  31 Mar)    MONTH_NUM=03; E2FSPROGS_MONTH="March" ;;
  32 Apr)    MONTH_NUM=04; E2FSPROGS_MONTH="April" ;;
  33 May)    MONTH_NUM=05; E2FSPROGS_MONTH="May" ;;
  34 Jun)    MONTH_NUM=06; E2FSPROGS_MONTH="June" ;;
  35 Jul)    MONTH_NUM=07; E2FSPROGS_MONTH="July" ;;
  36 Aug)    MONTH_NUM=08; E2FSPROGS_MONTH="August" ;;
  37 Sep)    MONTH_NUM=09; E2FSPROGS_MONTH="September" ;;
  38 Oct)    MONTH_NUM=10; E2FSPROGS_MONTH="October" ;;
  39 Nov)    MONTH_NUM=11; E2FSPROGS_MONTH="November" ;;
  40 Dec)    MONTH_NUM=12; E2FSPROGS_MONTH="December" ;;
  41 *)      AC_MSG_WARN([Unknown month $MONTH??]) ;;
  42 esac
  43
  44 base_ver=`echo $E2FSPROGS_VERSION | \
  45                sed -e 's/-WIP//' -e 's/pre-//' -e 's/-PLUS//'`
  46
  47 date_spec=${E2FSPROGS_YEAR}.${MONTH_NUM}.${E2FSPROGS_DAY}
  48
  49 case $E2FSPROGS_VERSION in
  50 *-WIP|pre-*)
  51         E2FSPROGS_PKGVER="$base_ver~WIP-$E2FSPROGS_YEAR-$MONTH_NUM-$E2FSPROGS_DAY"
  52         ;;
  53 *)
  54         E2FSPROGS_PKGVER="$base_ver"
  55         ;;
  56 esac
  57
  58 unset DATE MONTH YEAR base_ver pre_vers date_spec
  59 AC_MSG_RESULT([Generating configuration file for e2fsprogs version $E2FSPROGS_VERSION])
  60 AC_MSG_RESULT([Release date is ${E2FSPROGS_MONTH}, ${E2FSPROGS_YEAR}])
  61 AC_SUBST(E2FSPROGS_YEAR)
  62 AC_SUBST(E2FSPROGS_MONTH)
  63 AC_SUBST(E2FSPROGS_DAY)
  64 AC_SUBST(E2FSPROGS_VERSION)
  65 AC_SUBST(E2FSPROGS_PKGVER)
  66 AC_CANONICAL_HOST
  67 dnl
  68 dnl Check to see if libdl exists for the sake of dlopen
  69 dnl
  70 DLOPEN_LIB=''
  71 AC_CHECK_LIB(dl, dlopen,
  72 [DLOPEN_LIB=-ldl
  73 AC_DEFINE(HAVE_DLOPEN, 1, [Define to 1 if dlopen/libdl exists])])
  74 AC_SUBST(DLOPEN_LIB)
  75 dnl
  76 dnl Use diet libc
  77 dnl
  78 WITH_DIET_LIBC=
  79 AC_ARG_WITH([diet-libc],
  80 [  --with-diet-libc        use diet libc],
  81 CC="diet cc -nostdinc"
  82 WITH_DIET_LIBC=yes
  83 AC_MSG_RESULT(CC=$CC))dnl
  84 dnl
  85 AC_ARG_WITH([cc],
  86 AC_HELP_STRING([--with-cc],[no longer supported, use CC= instead]),
  87 AC_MSG_ERROR([--with-cc no longer supported; use CC= instead]))
  88 dnl
  89 AC_ARG_WITH([ccopts],
  90 AC_HELP_STRING([--with-ccopts],[no longer supported, use CFLAGS= instead]),
  91 AC_MSG_ERROR([--with-ccopts no longer supported; use CFLAGS= instead]))
  92 dnl
  93 AC_ARG_WITH([ldopts],
  94 AC_HELP_STRING([--with-ldopts],[no longer supported, use LDFLAGS= instead]),
  95 AC_MSG_ERROR([--with-ldopts no longer supported; use LDFLAGS= instead]))
  96 dnl
  97 AC_PROG_CC
  98 if test "$GCC" = yes; then
  99    RDYNAMIC="-rdynamic"
 100    AC_SUBST(RDYNAMIC)
 101 fi
 102 AC_PROG_CPP
 103 dnl
 104 dnl Alpha computers use fast and imprecise floating point code that may
 105 dnl miss exceptions by default. Force sane options if we're using GCC.
 106 AC_MSG_CHECKING(for additional special compiler flags)
 107 if test "$GCC" = yes
 108 then
 109     case "$host_cpu" in
 110         alpha)          addcflags="-mieee" ;;
 111     esac
 112 fi
 113 if test "x$addcflags" != x
 114 then
 115     AC_MSG_RESULT($addcflags)
 116     CFLAGS="$addcflags $CFLAGS"
 117 else
 118     AC_MSG_RESULT([[(none)]])
 119 fi
 120 dnl
 121 dnl Set default values for library extentions.  Will be dealt with after
 122 dnl parsing configuration opions, which may modify these
 123 dnl
 124 LIB_EXT=.a
 125 STATIC_LIB_EXT=.a
 126 PROFILED_LIB_EXT=.a
 127 dnl
 128 dnl Allow separate `root_prefix' to be specified
 129 dnl
 130 AC_ARG_WITH([root-prefix],
 131 [  --with-root-prefix=PREFIX override prefix variable for files to be placed in the root],
 132 root_prefix=$withval,
 133 root_prefix=NONE)dnl
 134 dnl
 135 dnl handle --enable-maintainer-mode
 136 dnl
 137 AC_ARG_ENABLE([maintainer-mode],
 138 [  --enable-maintainer-mode enable makefile rules useful for maintainers],
 139 if test "$enableval" = "no"
 140 then
 141         MAINTAINER_CMT=#
 142         AC_MSG_RESULT([Disabling maintainer mode])
 143 else
 144         MAINTAINER_CMT=
 145         AC_MSG_RESULT([Enabling maintainer mode])
 146 fi
 147 ,
 148 MAINTAINER_CMT=#
 149 AC_MSG_RESULT([Disabling maintainer mode by default])
 150 )
 151 AC_SUBST(MAINTAINER_CMT)
 152 dnl
 153 dnl handle --enable-symlink-install
 154 dnl
 155 AC_ARG_ENABLE([symlink-install],
 156 [  --enable-symlink-install use symlinks when installing instead of hard links],
 157 if test "$enableval" = "no"
 158 then
 159         LINK_INSTALL_FLAGS=-f
 160         AC_MSG_RESULT([Disabling symlinks for install])
 161 else
 162         LINK_INSTALL_FLAGS=-sf
 163         AC_MSG_RESULT([Enabling symlinks for install])
 164 fi
 165 ,
 166 LINK_INSTALL_FLAGS=-f
 167 AC_MSG_RESULT([Disabling symlinks for install by default])
 168 )
 169 AC_SUBST(LINK_INSTALL_FLAGS)
 170 dnl
 171 dnl handle --enable-relative-symlinks
 172 dnl
 173 AC_ARG_ENABLE([symlink-relative-symlinks],
 174 [  --enable-relative-symlinks use relative symlinks when installing],
 175 if test "$enableval" = "no"
 176 then
 177         SYMLINK_RELATIVE=
 178         AC_MSG_RESULT([Disabling relative symlinks for install])
 179 else
 180         SYMLINK_RELATIVE=--relative
 181         AC_MSG_RESULT([Enabling symlinks for install])
 182 fi
 183 ,
 184         SYMLINK_RELATIVE=
 185 AC_MSG_RESULT([Disabling relative symlinks for install by default])
 186 )
 187 AC_SUBST(SYMLINK_RELATIVE)
 188 dnl
 189 dnl handle --enable-symlink-build
 190 dnl
 191 AC_ARG_ENABLE([symlink-build],
 192 [  --enable-symlink-build  use symlinks while building instead of hard links],
 193 if test "$enableval" = "no"
 194 then
 195         LINK_BUILD_FLAGS=
 196         AC_MSG_RESULT([Disabling symlinks for build])
 197 else
 198         LINK_BUILD_FLAGS=-s
 199         AC_MSG_RESULT([Enabling symlinks for build])
 200 fi
 201 ,
 202 LINK_BUILD_FLAGS=
 203 AC_MSG_RESULT([Disabling symlinks for build by default])
 204 )
 205 AC_SUBST(LINK_BUILD_FLAGS)
 206 dnl
 207 dnl handle --enable-verbose-makecmds
 208 dnl
 209 AC_ARG_ENABLE([verbose-makecmds],
 210 [  --enable-verbose-makecmds enable verbose make command output],
 211 if test "$enableval" = "no"
 212 then
 213         AC_MSG_RESULT([Disabling verbose make commands])
 214         E=@echo
 215         Q=@
 216 else
 217         AC_MSG_RESULT([Enabling verbose make commands])
 218         E=@\\#
 219         Q=
 220 fi
 221 ,
 222 AC_MSG_RESULT([Disabling verbose make commands])
 223 E=@echo
 224 Q=@
 225 )
 226 AC_SUBST(E)
 227 AC_SUBST(Q)
 228 dnl
 229 dnl handle --enable-compression
 230 dnl
 231 AC_ARG_ENABLE([compression],
 232 [  --enable-compression   enable EXPERIMENTAL compression support],
 233 if test "$enableval" = "no"
 234 then
 235         AC_MSG_RESULT([Disabling compression support])
 236 else
 237         AC_DEFINE(ENABLE_COMPRESSION, 1,
 238                 [Define to 1 if ext2 compression enabled])
 239         AC_MSG_RESULT([Enabling compression support])
 240         AC_MSG_WARN([Compression support is experimental])
 241 fi
 242 ,
 243 AC_MSG_RESULT([Disabling compression support by default])
 244 )
 245 dnl
 246 dnl handle --enable-htree
 247 dnl
 248 AH_TEMPLATE([ENABLE_HTREE], [Define to 1 if ext3/4 htree support enabled])
 249 AC_ARG_ENABLE([htree],
 250 [  --enable-htree         enable EXPERIMENTAL htree directory support],
 251 if test "$enableval" = "no"
 252 then
 253         HTREE_CMT=#
 254         AC_MSG_RESULT([Disabling htree directory support])
 255 else
 256         HTREE_CMT=
 257         AC_DEFINE(ENABLE_HTREE, 1)
 258         AC_MSG_RESULT([Enabling htree directory support])
 259 fi
 260 ,
 261 HTREE_CMT=
 262 AC_DEFINE(ENABLE_HTREE, 1)
 263 AC_MSG_RESULT([Enabling htree directory support by default])
 264 )
 265 AC_SUBST(HTREE_CMT)
 266 dnl
 267 dnl This needs to be before all of the --enable-*-shlibs options
 268 dnl
 269 E2_PKG_CONFIG_STATIC=--static
 270 LDFLAG_DYNAMIC=
 271 PRIVATE_LIBS_CMT=
 272 dnl
 273 dnl handle --enable-elf-shlibs
 274 dnl
 275 AC_ARG_ENABLE([elf-shlibs],
 276 [  --enable-elf-shlibs    select ELF shared libraries],
 277 if test "$enableval" = "no"
 278 then
 279         ELF_CMT=#
 280         MAKEFILE_ELF=/dev/null
 281         AC_MSG_RESULT([Disabling ELF shared libraries])
 282 else
 283         E2_PKG_CONFIG_STATIC=
 284         ELF_CMT=
 285         MAKEFILE_ELF=$srcdir/lib/Makefile.elf-lib
 286         [case "$host_os" in
 287         solaris2.*)
 288                 MAKEFILE_ELF=$srcdir/lib/Makefile.solaris-lib
 289         ;;
 290         esac]
 291         BINARY_TYPE=elfbin
 292         LIB_EXT=.so
 293         PRIVATE_LIBS_CMT=#
 294         LDFLAG_DYNAMIC=['-Wl,-rpath-link,$(top_builddir)/lib']
 295         AC_MSG_RESULT([Enabling ELF shared libraries])
 296 fi
 297 ,
 298 MAKEFILE_ELF=/dev/null
 299 ELF_CMT=#
 300 AC_MSG_RESULT([Disabling ELF shared libraries by default])
 301 )
 302 AC_SUBST(ELF_CMT)
 303 AC_SUBST_FILE(MAKEFILE_ELF)
 304 dnl
 305 dnl handle --enable-bsd-shlibs
 306 dnl
 307 AC_ARG_ENABLE([bsd-shlibs],
 308 [  --enable-bsd-shlibs    select BSD shared libraries],
 309 if test "$enableval" = "no"
 310 then
 311         BSDLIB_CMT=#
 312         MAKEFILE_BSDLIB=/dev/null
 313         AC_MSG_RESULT([Disabling BSD shared libraries])
 314 else
 315         E2_PKG_CONFIG_STATIC=
 316         BSDLIB_CMT=
 317         MAKEFILE_BSDLIB=$srcdir/lib/Makefile.bsd-lib
 318         LIB_EXT=.so
 319         [case "$host_os" in
 320         darwin*)
 321                 MAKEFILE_BSDLIB=$srcdir/lib/Makefile.darwin-lib
 322                 LIB_EXT=.dylib
 323         ;;
 324         esac]
 325         AC_MSG_RESULT([Enabling BSD shared libraries])
 326 fi
 327 ,
 328 MAKEFILE_BSDLIB=/dev/null
 329 BSDLIB_CMT=#
 330 AC_MSG_RESULT([Disabling BSD shared libraries by default])
 331 )
 332 AC_SUBST(BSDLIB_CMT)
 333 AC_SUBST_FILE(MAKEFILE_BSDLIB)
 334 dnl
 335 dnl handle --enable-profile
 336 dnl
 337 AC_ARG_ENABLE([profile],
 338 [  --enable-profile       build profiling libraries],
 339 if test "$enableval" = "no"
 340 then
 341         PROFILE_CMT=#
 342         MAKEFILE_PROFILE=/dev/null
 343         AC_MSG_RESULT([Disabling profiling libraries])
 344 else
 345         PROFILE_CMT=
 346         MAKEFILE_PROFILE=$srcdir/lib/Makefile.profile
 347         PROFILED_LIB_EXT=_p.a
 348         AC_MSG_RESULT([Building profiling libraries])
 349 fi
 350 ,
 351 PROFILE_CMT=#
 352 MAKEFILE_PROFILE=/dev/null
 353 AC_MSG_RESULT([Disabling profiling libraries by default])
 354 )
 355 AC_SUBST(PROFILE_CMT)
 356 AC_SUBST_FILE(MAKEFILE_PROFILE)
 357 dnl
 358 dnl handle --enable-checker
 359 dnl
 360 AC_ARG_ENABLE([checker],
 361 [  --enable-checker       build checker libraries],
 362 if test "$enableval" = "no"
 363 then
 364         CHECKER_CMT=#
 365         MAKEFILE_CHECKER=/dev/null
 366         AC_MSG_RESULT([Disabling checker libraries])
 367 else
 368         CHECKER_CMT=
 369         MAKEFILE_CHECKER=$srcdir/lib/Makefile.checker
 370         AC_MSG_RESULT([Building checker libraries])
 371 fi
 372 ,
 373 CHECKER_CMT=#
 374 MAKEFILE_CHECKER=/dev/null
 375 AC_MSG_RESULT([Disabling checker libraries by default])
 376 )
 377 AC_SUBST(CHECKER_CMT)
 378 AC_SUBST_FILE(MAKEFILE_CHECKER)
 379 dnl
 380 dnl Substitute library extensions
 381 dnl
 382 AC_SUBST(LIB_EXT)
 383 AC_SUBST(STATIC_LIB_EXT)
 384 AC_SUBST(PROFILED_LIB_EXT)
 385 AC_SUBST(LDFLAG_DYNAMIC)
 386 AC_SUBST(PRIVATE_LIBS_CMT)
 387 dnl
 388 dnl handle --enable-jbd-debug
 389 dnl
 390 AC_ARG_ENABLE([jbd-debug],
 391 [  --enable-jbd-debug     enable journal debugging],
 392 if test "$enableval" = "no"
 393 then
 394         AC_MSG_RESULT([Disabling journal debugging])
 395 else
 396         AC_DEFINE(CONFIG_JBD_DEBUG, 1,
 397                 [Define to 1 if debugging ext3/4 journal code])
 398         AC_MSG_RESULT([Enabling journal debugging])
 399 fi
 400 ,
 401 AC_MSG_RESULT([Disabling journal debugging by default])
 402 )
 403 dnl
 404 dnl handle --enable-blkid-debug
 405 dnl
 406 AC_ARG_ENABLE([blkid-debug],
 407 [  --enable-blkid-debug    enable blkid debugging],
 408 if test "$enableval" = "no"
 409 then
 410         AC_MSG_RESULT([Disabling blkid debugging])
 411 else
 412         AC_DEFINE(CONFIG_BLKID_DEBUG, 1,
 413                 [Define to 1 if debugging the blkid library])
 414         AC_MSG_RESULT([Enabling blkid debugging])
 415 fi
 416 ,
 417 AC_MSG_RESULT([Disabling blkid debugging by default])
 418 )
 419 dnl
 420 dnl handle --enable-testio-debug
 421 dnl
 422 AC_ARG_ENABLE([testio-debug],
 423 [  --disable-testio-debug  disable the use of the test I/O manager for debugging],
 424 AH_TEMPLATE([CONFIG_TESTIO_DEBUG],
 425         [Define to 1 if the testio I/O manager should be enabled])
 426 if test "$enableval" = "no"
 427 then
 428         AC_MSG_RESULT([Disabling testio debugging])
 429         TEST_IO_CMT="#"
 430 else
 431         TEST_IO_CMT=
 432         AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 433         AC_MSG_RESULT([Enabling testio debugging])
 434 fi
 435 ,
 436 AC_MSG_RESULT([Enabling testio debugging by default])
 437 AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 438 TEST_IO_CMT=
 439 )
 440 AC_SUBST(TEST_IO_CMT)
 441 dnl
 442 dnl handle --disable-libuuid
 443 dnl
 444 PKG_PROG_PKG_CONFIG
 445 LIBUUID=
 446 DEPLIBUUID=
 447 STATIC_LIBUUID=
 448 DEPSTATIC_LIBUUID=
 449 PROFILED_LIBUUID=
 450 DEPPROFILED_LIBUUID=
 451 UUID_CMT=
 452 AC_ARG_ENABLE([libuuid],
 453 [  --disable-libuuid      do not build private uuid library],
 454 if test "$enableval" = "no"
 455 then
 456         if test -z "$PKG_CONFIG"; then
 457                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 458         fi
 459
 460         AC_CHECK_LIB(uuid, uuid_generate,
 461                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 462                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`],
 463                 [AC_MSG_ERROR([external uuid library not found])],
 464                 [$LIBUUID])
 465         UUID_CMT=#
 466         AC_MSG_RESULT([Disabling private uuid library])
 467 else
 468         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 469         DEPLIBUUID=$LIBUUID
 470         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 471         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 472         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 473         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 474         AC_MSG_RESULT([Enabling private uuid library])
 475 fi
 476 ,
 477 LIBUUID='$(LIB)/libuuid'$LIB_EXT
 478 DEPLIBUUID=$LIBUUID
 479 STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 480 DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 481 PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 482 DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 483 AC_MSG_RESULT([Enabling private uuid library by default])
 484 )
 485 AC_SUBST(LIBUUID)
 486 AC_SUBST(DEPLIBUUID)
 487 AC_SUBST(STATIC_LIBUUID)
 488 AC_SUBST(DEPSTATIC_LIBUUID)
 489 AC_SUBST(PROFILED_LIBUUID)
 490 AC_SUBST(DEPPROFILED_LIBUUID)
 491 AC_SUBST(UUID_CMT)
 492 dnl
 493 dnl handle --disable-libblkid
 494 dnl
 495 PKG_PROG_PKG_CONFIG
 496 LIBBLKID=
 497 DEPLIBBLKID=
 498 STATIC_LIBBLKID=
 499 DEPSTATIC_LIBBLKID=
 500 PROFILED_LIBBLKID=
 501 DEPPROFILED_LIBBLKID=
 502 BLKID_CMT=
 503 AH_TEMPLATE([CONFIG_BUILD_FINDFS], [Define to 1 to compile findfs])
 504 AC_ARG_ENABLE([libblkid],
 505 [  --disable-libblkid     do not build private blkid library],
 506 if test "$enableval" = "no"
 507 then
 508         if test -z "$PKG_CONFIG"; then
 509                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 510         fi
 511
 512         AC_CHECK_LIB(blkid, blkid_get_cache,
 513                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 514                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`],
 515                 [AC_MSG_ERROR([external blkid library not found])],
 516                 [$LIBBLKID])
 517         BLKID_CMT=#
 518         AC_MSG_RESULT([Disabling private blkid library])
 519 else
 520         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 521         DEPLIBBLKID=$LIBBLKID
 522         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 523         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 524         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 525         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 526         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 527         AC_MSG_RESULT([Enabling private blkid library])
 528 fi
 529 ,
 530 LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 531 DEPLIBBLKID=$LIBBLKID
 532 STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 533 DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 534 PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 535 DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 536 AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 537 AC_MSG_RESULT([Enabling private blkid library by default])
 538 )
 539 AC_SUBST(LIBBLKID)
 540 AC_SUBST(DEPLIBBLKID)
 541 AC_SUBST(STATIC_LIBBLKID)
 542 AC_SUBST(DEPSTATIC_LIBBLKID)
 543 AC_SUBST(PROFILED_LIBBLKID)
 544 AC_SUBST(DEPPROFILED_LIBBLKID)
 545 AC_SUBST(BLKID_CMT)
 546 dnl
 547 dnl handle --enable-quota
 548 dnl
 549 PKG_PROG_PKG_CONFIG
 550 AH_TEMPLATE([CONFIG_QUOTA], [Define to 1 to enable quota support])
 551 AC_ARG_ENABLE([quota],
 552 [  --enable-libquota      enable quota support],
 553 if test "$enableval" = "no"
 554 then
 555         AC_MSG_RESULT([Disabling quota support])
 556 else
 557         AC_DEFINE(CONFIG_QUOTA, 1)
 558         AC_MSG_RESULT([Enabling quota support])
 559 fi
 560 ,
 561 AC_MSG_RESULT([Disabling quota support by default])
 562 )
 563 dnl
 564 dnl Define stuff expected for quota library
 565 dnl
 566 LIBQUOTA='$(LIB)/libquota'$LIB_EXT
 567 DEPLIBQUOTA=$LIBQUOTA
 568 STATIC_LIBQUOTA='$(LIB)/libquota'$STATIC_LIB_EXT
 569 DEPSTATIC_LIBQUOTA=$STATIC_LIBQUOTA
 570 PROFILED_LIBQUOTA='$(LIB)/libquota'$PROFILED_LIB_EXT
 571 DEPPROFILED_LIBQUOTA=$PROFILED_LIBQUOTA
 572 AC_SUBST(LIBQUOTA)
 573 AC_SUBST(DEPLIBQUOTA)
 574 AC_SUBST(STATIC_LIBQUOTA)
 575 AC_SUBST(DEPSTATIC_LIBQUOTA)
 576 AC_SUBST(PROFILED_LIBQUOTA)
 577 AC_SUBST(DEPPROFILED_LIBQUOTA)
 578 AC_SUBST(QUOTA_CMT)
 579 dnl
 580 dnl handle --enable-debugfs
 581 dnl
 582 AC_ARG_ENABLE([debugfs],
 583 [  --disable-debugfs      disable support of debugfs program],
 584 if test "$enableval" = "no"
 585 then
 586         AC_MSG_RESULT([Disabling debugfs support])
 587         DEBUGFS_CMT="#"
 588 else
 589         DEBUGFS_CMT=
 590         AC_MSG_RESULT([Enabling debugfs support])
 591 fi
 592 ,
 593 AC_MSG_RESULT([Enabling debugfs support by default])
 594 DEBUGFS_CMT=
 595 )
 596 AC_SUBST(DEBUGFS_CMT)
 597 dnl
 598 dnl handle --enable-imager
 599 dnl
 600 AC_ARG_ENABLE([imager],
 601 [  --disable-imager       disable support of e2image program],
 602 if test "$enableval" = "no"
 603 then
 604         AC_MSG_RESULT([Disabling e2image support])
 605         IMAGER_CMT="#"
 606 else
 607         IMAGER_CMT=
 608         AC_MSG_RESULT([Enabling e2image support])
 609 fi
 610 ,
 611 AC_MSG_RESULT([Enabling e2image support by default])
 612 IMAGER_CMT=
 613 )
 614 AC_SUBST(IMAGER_CMT)
 615 dnl
 616 dnl handle --enable-resizer
 617 dnl
 618 AC_ARG_ENABLE([resizer],
 619 [  --disable-resizer      disable support of e2resize program],
 620 if test "$enableval" = "no"
 621 then
 622         AC_MSG_RESULT([Disabling e2resize support])
 623         RESIZER_CMT="#"
 624 else
 625         RESIZER_CMT=
 626         AC_MSG_RESULT([Enabling e2resize support])
 627 fi
 628 ,
 629 AC_MSG_RESULT([Enabling e2resize support by default])
 630 RESIZER_CMT=
 631 )
 632 AC_SUBST(RESIZER_CMT)
 633 dnl
 634 dnl handle --enable-defrag
 635 dnl
 636 AC_ARG_ENABLE([defrag],
 637 [  --disable-defrag       disable support of e4defrag program],
 638 if test "$enableval" = "no"
 639 then
 640         AC_MSG_RESULT([Disabling e4defrag support])
 641         DEFRAG_CMT="#"
 642 else
 643         DEFRAG_CMT=
 644         AC_MSG_RESULT([Enabling e4defrag support])
 645 fi
 646 ,
 647 AC_MSG_RESULT([Enabling e4defrag support by default])
 648 DEFRAG_CMT=
 649 )
 650 AC_SUBST(DEFRAG_CMT)
 651 dnl
 652 dnl See whether to install the `fsck' wrapper program (that calls e2fsck)
 653 dnl
 654 AC_ARG_ENABLE([fsck],
 655 [  --enable-fsck           build fsck wrapper program],
 656 [if test "$enableval" = "no"
 657 then
 658         FSCK_PROG='' FSCK_MAN=''
 659         AC_MSG_RESULT([Not building fsck wrapper])
 660 else
 661         FSCK_PROG=fsck FSCK_MAN=fsck.8
 662         AC_MSG_RESULT([Building fsck wrapper])
 663 fi]
 664 ,
 665 [case "$host_os" in
 666   gnu*)
 667     FSCK_PROG='' FSCK_MAN=''
 668     AC_MSG_RESULT([Not building fsck wrapper by default])
 669     ;;
 670   *)
 671     FSCK_PROG=fsck FSCK_MAN=fsck.8
 672     AC_MSG_RESULT([Building fsck wrapper by default])
 673 esac]
 674 )
 675 AC_SUBST(FSCK_PROG)
 676 AC_SUBST(FSCK_MAN)
 677 dnl
 678 dnl See whether to install the `e2initrd-helper' program
 679 dnl
 680 AC_ARG_ENABLE([e2initrd-helper],
 681 [  --enable-e2initrd-helper build e2initrd-helper program],
 682 [if test "$enableval" = "no"
 683 then
 684         E2INITRD_PROG='' E2INITRD_MAN=''
 685         AC_MSG_RESULT([Not building e2initrd helper])
 686 else
 687         E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 688         AC_MSG_RESULT([Building e2initrd helper])
 689 fi]
 690 ,
 691 E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 692 AC_MSG_RESULT([Building e2initrd helper by default])
 693 )
 694 AC_SUBST(E2INITRD_PROG)
 695 AC_SUBST(E2INITRD_MAN)
 696 dnl
 697 dnl
 698 dnl
 699 AC_ARG_ENABLE([tls],
 700 [  --disable-tls           disable use of thread local support],
 701 [if test "$enableval" = "no"
 702 then
 703         try_tls=""
 704         AC_MSG_RESULT([Disabling thread local support])
 705 else
 706         try_tls="yes"
 707         AC_MSG_RESULT([Enabling thread local support])
 708 fi]
 709 ,
 710 if test -n "$WITH_DIET_LIBC"
 711 then
 712         try_tls=""
 713         AC_MSG_RESULT([Diet libc does not support thread local support])
 714 else
 715         try_tls="yes"
 716         AC_MSG_RESULT([Try using thread local support by default])
 717 fi
 718 )
 719 if test "$try_tls" = "yes"
 720 then
 721 AX_TLS
 722 fi
 723 dnl
 724 dnl
 725 dnl
 726 AH_TEMPLATE([USE_UUIDD], [Define to 1 to build uuidd])
 727 AC_ARG_ENABLE([uuidd],
 728 [  --disable-uuidd         disable building the uuid daemon],
 729 [if test "$enableval" = "no"
 730 then
 731         AC_MSG_RESULT([Not building uuidd])
 732         UUIDD_CMT="#"
 733 else
 734         AC_DEFINE(USE_UUIDD, 1)
 735         UUIDD_CMT=""
 736         AC_MSG_RESULT([Building uuidd])
 737 fi]
 738 ,
 739 AC_DEFINE(USE_UUIDD, 1)
 740 UUIDD_CMT=""
 741 AC_MSG_RESULT([Building uuidd by default])
 742 )
 743 AC_SUBST(UUIDD_CMT)
 744 dnl
 745 dnl
 746 dnl
 747 MAKEFILE_LIBRARY=$srcdir/lib/Makefile.library
 748 AC_SUBST_FILE(MAKEFILE_LIBRARY)
 749 dnl
 750 dnl Add internationalization support, using gettext.
 751 dnl
 752 GETTEXT_PACKAGE=e2fsprogs
 753 PACKAGE=e2fsprogs
 754 VERSION="$E2FSPROGS_VERSION"
 755 VERSION=0.14.1
 756 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [package name for gettext])
 757 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [version for gettext])
 758 AC_SUBST(GETTEXT_PACKAGE)
 759 AC_SUBST(PACKAGE)
 760 AC_SUBST(VERSION)
 761
 762 AM_GNU_GETTEXT
 763 dnl
 764 dnl End of configuration options
 765 dnl
 766 AC_SUBST(BINARY_TYPE)
 767 AC_PROG_MAKE_SET
 768 CHECK_GNU_MAKE
 769 AC_PATH_PROG(LN, ln, ln)
 770 AC_PROG_LN_S
 771 AC_PATH_PROG(MV, mv, mv)
 772 AC_PATH_PROG(CP, cp, cp)
 773 AC_PATH_PROG(RM, rm, rm)
 774 AC_PATH_PROG(CHMOD, chmod, :)
 775 AC_PROG_AWK
 776 AC_PROG_EGREP
 777 AC_PATH_PROG(SED, sed, sed)
 778 AC_PATH_PROG(PERL, perl, perl)
 779 AC_PATH_PROG(LDCONFIG, ldconfig, :)
 780 AC_CHECK_TOOL(AR, ar, ar)
 781 AC_CHECK_TOOL(RANLIB, ranlib, :)
 782 AC_CHECK_TOOL(STRIP, strip, :)
 783 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
 784 if test "_$MAKEINFO" = "_"; then
 785     MAKEINFO="@echo Makeinfo is missing. Info documentation will not be built.;true"
 786 else
 787     case "$MAKEINFO" in
 788       */missing.*)
 789         AC_MSG_WARN([
 790 *** Makeinfo is missing. Info documentation will not be built.])
 791         ;;
 792       *)
 793         ;;
 794     esac
 795 fi
 796 AC_SUBST(MAKEINFO)
 797 AC_PROG_INSTALL
 798 # See if we need a separate native compiler.
 799 if test $cross_compiling = no; then
 800   BUILD_CC="$CC"
 801   AC_SUBST(BUILD_CC)
 802 else
 803   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 804 fi
 805 AC_CHECK_HEADERS(m4_flatten([
 806         dirent.h
 807         errno.h
 808         execinfo.h
 809         getopt.h
 810         malloc.h
 811         mntent.h
 812         paths.h
 813         semaphore.h
 814         setjmp.h
 815         signal.h
 816         stdarg.h
 817         stdint.h
 818         stdlib.h
 819         termios.h
 820         termio.h
 821         unistd.h
 822         utime.h
 823         linux/falloc.h
 824         linux/fd.h
 825         linux/major.h
 826         net/if_dl.h
 827         netinet/in.h
 828         sys/disklabel.h
 829         sys/file.h
 830         sys/ioctl.h
 831         sys/mkdev.h
 832         sys/mman.h
 833         sys/prctl.h
 834         sys/queue.h
 835         sys/resource.h
 836         sys/select.h
 837         sys/socket.h
 838         sys/sockio.h
 839         sys/stat.h
 840         sys/syscall.h
 841         sys/sysmacros.h
 842         sys/time.h
 843         sys/types.h
 844         sys/un.h
 845         sys/wait.h
 846 ]))
 847 AC_CHECK_HEADERS(sys/disk.h sys/mount.h,,,
 848 [[
 849 #if HAVE_SYS_QUEUE_H
 850 #include <sys/queue.h>
 851 #endif
 852 ]])
 853 AC_CHECK_HEADERS(net/if.h,,,
 854 [[
 855 #if HAVE_SYS_TYPES_H
 856 #include <sys/types.h>
 857 #endif
 858 #if HAVE_SYS_SOCKET
 859 #include <sys/socket.h>
 860 #endif
 861 ]])
 862 AC_FUNC_VPRINTF
 863 dnl Check to see if dirent has member d_reclen. On cygwin those d_reclen
 864 dnl is not decleared.
 865 AC_CHECK_MEMBER(struct dirent.d_reclen,[AC_DEFINE(HAVE_RECLEN_DIRENT, 1,
 866                        [Define to 1 if dirent has d_reclen])],,
 867                 [#include <dirent.h>])
 868 dnl Check to see if ssize_t was declared
 869 AC_CHECK_TYPE(ssize_t,[AC_DEFINE(HAVE_TYPE_SSIZE_T, 1,
 870                 [Define to 1 if ssize_t declared])],,
 871               [#include <sys/types.h>])
 872 dnl
 873 dnl Check to see if llseek() is declared in unistd.h.  On some libc's
 874 dnl it is, and on others it isn't..... Thank you glibc developers....
 875 dnl
 876 AC_CHECK_DECL(llseek,[AC_DEFINE(HAVE_LLSEEK_PROTOTYPE, 1,
 877                         [Define to 1 if llseek declared in unistd.h])],,
 878               [#include <unistd.h>])
 879 dnl
 880 dnl Check to see if lseek64() is declared in unistd.h.  Glibc's header files
 881 dnl are so convoluted that I can't tell whether it will always be defined,
 882 dnl and if it isn't defined while lseek64 is defined in the library,
 883 dnl disaster will strike.
 884 dnl
 885 dnl Warning!  Use of --enable-gcc-wall may throw off this test.
 886 dnl
 887 dnl
 888 AC_CHECK_DECL(lseek64,[AC_DEFINE(HAVE_LSEEK64_PROTOTYPE, 1,
 889                         [Define to 1 if lseek64 declared in unistd.h])],,
 890                 [#define _LARGEFILE_SOURCE
 891                  #define _LARGEFILE64_SOURCE
 892                  #include <unistd.h>])
 893 dnl
 894 dnl Word sizes...
 895 dnl
 896 AC_CHECK_SIZEOF(short)
 897 AC_CHECK_SIZEOF(int)
 898 AC_CHECK_SIZEOF(long)
 899 AC_CHECK_SIZEOF(long long)
 900 SIZEOF_SHORT=$ac_cv_sizeof_short
 901 SIZEOF_INT=$ac_cv_sizeof_int
 902 SIZEOF_LONG=$ac_cv_sizeof_long
 903 SIZEOF_LONG_LONG=$ac_cv_sizeof_long_long
 904 AC_SUBST(SIZEOF_SHORT)
 905 AC_SUBST(SIZEOF_INT)
 906 AC_SUBST(SIZEOF_LONG)
 907 AC_SUBST(SIZEOF_LONG_LONG)
 908 AC_C_BIGENDIAN
 909 BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
 910 ASM_TYPES_HEADER=./asm_types.h
 911 AC_SUBST_FILE(ASM_TYPES_HEADER)
 912 dnl
 913 dnl Save the configuration #defines needed for the public ext2fs.h
 914 dnl header file
 915 dnl
 916 echo "/* These defines are needed for the public ext2fs.h header file */" \
 917      > public_config.h
 918 if grep HAVE_SYS_TYPES_H confdefs.h > tmp_config.$$; then
 919   uniq tmp_config.$$ >> public_config.h
 920 else
 921   echo "#undef HAVE_SYS_TYPES_H" >> public_config.h
 922 fi
 923 if grep WORDS_BIGENDIAN confdefs.h > tmp_config.$$; then
 924   uniq tmp_config.$$ >> public_config.h
 925 else
 926   echo "#undef WORDS_BIGENDIAN" >> public_config.h
 927 fi
 928 rm -f tmp_config.$$
 929 PUBLIC_CONFIG_HEADER=./public_config.h
 930 AC_SUBST_FILE(PUBLIC_CONFIG_HEADER)
 931 dnl
 932 dnl See if we have inttypes.h and if intptr_t is defined
 933 dnl
 934 AC_CHECK_HEADERS([inttypes.h])
 935 AC_CHECK_TYPES(intptr_t)
 936 dnl
 937 dnl See if struct stat has a st_flags field, in which case we can get file
 938 dnl flags somewhat portably.  Also check for the analogous setter, chflags().
 939 dnl
 940 AC_MSG_CHECKING(whether struct stat has a st_flags field)
 941 AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags,
 942         AC_TRY_COMPILE([#include <sys/stat.h>],
 943                 [struct stat stat; stat.st_flags = 0;],
 944                 [e2fsprogs_cv_struct_st_flags=yes],
 945                 [e2fsprogs_cv_struct_st_flags=no]))
 946 AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags)
 947 if test "$e2fsprogs_cv_struct_st_flags" = yes; then
 948   AC_MSG_CHECKING(whether st_flags field is useful)
 949   AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags_immut,
 950         AC_TRY_COMPILE([#include <sys/stat.h>],
 951                 [struct stat stat; stat.st_flags |= UF_IMMUTABLE;],
 952                 [e2fsprogs_cv_struct_st_flags_immut=yes],
 953                 [e2fsprogs_cv_struct_st_flags_immut=no]))
 954   AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags_immut)
 955   if test "$e2fsprogs_cv_struct_st_flags_immut" = yes; then
 956           AC_DEFINE(HAVE_STAT_FLAGS, 1,
 957                 [Define to 1 if struct stat has st_flags])
 958   fi
 959 fi
 960 dnl
 961 dnl Check for the presence of SA_LEN
 962 dnl
 963 AC_CHECK_MEMBER(struct sockaddr.sa_len,
 964                 AC_DEFINE_UNQUOTED(HAVE_SA_LEN,1,
 965                         [Define to 1 if if struct sockaddr contains sa_len]),,
 966         [#include <sys/types.h>
 967          #include <sys/socket.h>])
 968 dnl
 969 dnl This will add -lblkid to the AC_CHECK_FUNCS search if we are using
 970 dnl the system-provided blkid library
 971 dnl
 972 if test -n "$BLKID_CMT"; then
 973   AC_SEARCH_LIBS([blkid_probe_all], [blkid])
 974 fi
 975 dnl
 976 AC_CHECK_FUNCS(m4_flatten([
 977         __secure_getenv
 978         backtrace
 979         blkid_probe_get_topology
 980         chflags
 981         fallocate
 982         fallocate64
 983         fchown
 984         fdatasync
 985         fstat64
 986         ftruncate64
 987         getdtablesize
 988         getmntinfo
 989         getpwuid_r
 990         getrlimit
 991         getrusage
 992         jrand48
 993         llseek
 994         lseek64
 995         mallinfo
 996         mbstowcs
 997         memalign
 998         mmap
 999         msync
1000         nanosleep
1001         open64
1002         pathconf
1003         posix_fadvise
1004         posix_memalign
1005         prctl
1006         quotactl
1007         setmntent
1008         setresgid
1009         setresuid
1010         srandom
1011         strcasecmp
1012         strdup
1013         strnlen
1014         strptime
1015         strtoull
1016         sync_file_range
1017         sysconf
1018         usleep
1019         utime
1020         valloc
1021 ]))
1022 dnl
1023 dnl Check to see if -lsocket is required (solaris) to make something
1024 dnl that uses socket() to compile; this is needed for the UUID library
1025 dnl
1026 SOCKET_LIB=''
1027 AC_CHECK_LIB(socket, socket, [SOCKET_LIB=-lsocket])
1028 AC_SUBST(SOCKET_LIB)
1029 dnl
1030 dnl See if optreset exists
1031 dnl
1032 AC_MSG_CHECKING(for optreset)
1033 AC_CACHE_VAL(ac_cv_have_optreset,
1034 [AC_EGREP_HEADER(optreset, unistd.h,
1035   ac_cv_have_optreset=yes, ac_cv_have_optreset=no)])dnl
1036 AC_MSG_RESULT($ac_cv_have_optreset)
1037 if test $ac_cv_have_optreset = yes; then
1038   AC_DEFINE(HAVE_OPTRESET, 1, [Define to 1 if optreset for getopt is present])
1039 fi
1040 dnl
1041 dnl Test for sem_init, and which library it might require:
1042 dnl
1043 AH_TEMPLATE([HAVE_SEM_INIT], [Define to 1 if sem_init() exists])
1044 SEM_INIT_LIB=''
1045 AC_CHECK_FUNC(sem_init, ,
1046   AC_CHECK_LIB(pthread, sem_init,
1047         AC_DEFINE(HAVE_SEM_INIT, 1)
1048         SEM_INIT_LIB=-lpthread,
1049   AC_CHECK_LIB(rt, sem_init,
1050         AC_DEFINE(HAVE_SEM_INIT, 1)
1051         SEM_INIT_LIB=-lrt,
1052   AC_CHECK_LIB(posix4, sem_init,
1053         AC_DEFINE(HAVE_SEM_INIT, 1)
1054         SEM_INIT_LIB=-lposix4))))dnl
1055 AC_SUBST(SEM_INIT_LIB)
1056 dnl
1057 dnl Check for unified diff
1058 dnl
1059 AC_MSG_CHECKING(for unified diff option)
1060 if diff -u $0 $0 > /dev/null 2>&1 ; then
1061    UNI_DIFF_OPTS=-u
1062 else
1063    UNI_DIFF_OPTS=-c
1064 fi
1065 AC_MSG_RESULT($UNI_DIFF_OPTS)
1066 AC_SUBST(UNI_DIFF_OPTS)
1067 dnl
1068 dnl We use the EXT2 ioctls only under Linux
1069 dnl
1070 case "$host_os" in
1071 linux*)
1072         AC_DEFINE(HAVE_EXT2_IOCTLS, 1, [Define to 1 if Ext2 ioctls present])
1073         ;;
1074 esac
1075 dnl
1076 dnl OS-specific uncomment control
1077 dnl
1078 LINUX_CMT="#"
1079 CYGWIN_CMT="#"
1080 UNIX_CMT=
1081 case "$host_os" in
1082 linux*)
1083         LINUX_CMT=
1084         ;;
1085 cygwin)
1086         CYGWIN_CMT=
1087         UNIX_CMT="#"
1088         ;;
1089 esac
1090 AC_SUBST(LINUX_CMT)
1091 AC_SUBST(CYGWIN_CMT)
1092 AC_SUBST(UNIX_CMT)
1093 dnl
1094 dnl Linux and Hurd places root files in the / by default
1095 dnl
1096 case "$host_os" in
1097 linux* | gnu* | k*bsd*-gnu)
1098         if test "$prefix" = NONE -a "$root_prefix" = NONE ; then
1099                 root_prefix="";
1100                 AC_MSG_RESULT([On $host_os systems, root_prefix defaults to ''])
1101         fi
1102         ;;
1103 esac
1104 dnl
1105 dnl On Linux/hurd, force the prefix to be /usr
1106 dnl
1107 case "$host_os" in
1108 linux* | gnu* | k*bsd*-gnu)
1109         if test "$prefix" = NONE ; then
1110                 prefix="/usr";
1111                 AC_MSG_RESULT([On $host_os systems, prefix defaults to /usr])
1112                 if test "$mandir" = '${prefix}/man' ; then
1113                         AC_MSG_RESULT([...and mandir defaults to /usr/share/man])
1114                         mandir=/usr/share/man
1115                 fi
1116         fi
1117 ;;
1118 esac
1119 if test "$root_prefix" = NONE ; then
1120         if test "$prefix" = NONE ; then
1121                 root_prefix="$ac_default_prefix"
1122         else
1123                 root_prefix="$prefix"
1124         fi
1125         root_bindir=$bindir
1126         root_sbindir=$sbindir
1127         root_libdir=$libdir
1128         root_sysconfdir=$sysconfdir
1129 else
1130         root_bindir='${root_prefix}/bin'
1131         root_sbindir='${root_prefix}/sbin'
1132         root_libdir='${root_prefix}/lib'
1133         root_sysconfdir='${root_prefix}/etc'
1134 fi
1135 if test "$bindir" != '${exec_prefix}/bin'; then
1136     root_bindir=$bindir
1137     AC_MSG_RESULT([Setting root_bindir to $root_bindir])
1138 fi
1139 if test "$sbindir" != '${exec_prefix}/sbin'; then
1140     root_sbindir=$sbindir
1141     AC_MSG_RESULT([Setting root_sbindir to $root_sbindir])
1142 fi
1143 if test "$libdir" != '${exec_prefix}/lib'; then
1144     root_libdir=$libdir
1145     AC_MSG_RESULT([Setting root_libdir to $root_libdir])
1146 fi
1147 if test "$sysconfdir" != '${prefix}/etc'; then
1148     root_sysconfdir=$sysconfdir
1149     AC_MSG_RESULT([Setting root_sysconfdir to $root_sysconfdir])
1150 fi
1151 AC_SUBST(root_prefix)
1152 AC_SUBST(root_bindir)
1153 AC_SUBST(root_sbindir)
1154 AC_SUBST(root_libdir)
1155 AC_SUBST(root_sysconfdir)
1156 dnl
1157 dnl Allow specification of the multiarch arch
1158 dnl
1159 AC_ARG_WITH([multiarch],
1160 [  --with-multiarch=ARCH specify the multiarch triplet],
1161 libdir=$libdir/$withval
1162 root_libdir=$root_libdir/$withval
1163 )dnl
1164 dnl
1165 dnl See if -static works.
1166 dnl
1167 AC_MSG_CHECKING([whether linker accepts -static])
1168 AC_CACHE_VAL(ac_cv_e2fsprogs_use_static,
1169 [SAVE_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -static"
1170 AC_TRY_LINK([#include <stdio.h>],[fflush(stdout);],
1171  ac_cv_e2fsprogs_use_static=yes, ac_cv_e2fsprogs_use_static=no)
1172 LDFLAGS=$SAVE_LDFLAGS])
1173 dnl
1174 dnl Regardless of how the test turns out, Solaris doesn't handle -static
1175 dnl This is caused by the socket library requiring the nsl library, which
1176 dnl requires the -dl library, which only works for dynamically linked
1177 dnl programs.  It basically means you can't have statically linked programs
1178 dnl which use the network under Solaris.
1179 dnl
1180 case "$host_os" in
1181 solaris2.*)
1182         ac_cv_e2fsprogs_use_static=no
1183 ;;
1184 esac
1185 AC_MSG_RESULT($ac_cv_e2fsprogs_use_static)
1186 LDFLAG_STATIC=
1187 if test $ac_cv_e2fsprogs_use_static = yes; then
1188         LDFLAG_STATIC=-static
1189 fi
1190 AC_SUBST(LDFLAG_STATIC)
1191 dnl
1192 dnl Work around mysterious Darwin / GNU libintl problem
1193 dnl (__asm__ redirection doesn't work for some mysterious reason.  Looks like
1194 dnl Apple hacked gcc somehow?)
1195 dnl
1196 case "$host_os" in
1197 darwin*)
1198         AC_MSG_RESULT([Using Apple Darwin / GNU libintl workaround])
1199         AC_DEFINE(_INTL_REDIRECT_MACROS, 1,
1200                 [Define to 1 if Apple Darwin libintl workaround is needed])
1201         ;;
1202 esac
1203 dnl
1204 dnl Make the ss and et directories work correctly.
1205 dnl
1206 SS_DIR=`cd ${srcdir}/lib/ss; pwd`
1207 ET_DIR=`cd ${srcdir}/lib/et; pwd`
1208 AC_SUBST(SS_DIR)
1209 AC_SUBST(ET_DIR)
1210 dnl
1211 dnl Only try to run the test suite if we're not cross compiling.
1212 dnl
1213 if test "$cross_compiling" = yes ; then
1214   DO_TEST_SUITE=
1215 else
1216   DO_TEST_SUITE=check
1217 fi
1218 AC_SUBST(DO_TEST_SUITE)
1219 dnl
1220 dnl Only include the intl include files if we're building with them
1221 dnl
1222 INCLUDES='-I. -I$(top_builddir)/lib -I$(top_srcdir)/lib'
1223 if test -n "$CPPFLAGS" ; then
1224         INCLUDES="$INCLUDES $CPPFLAGS"
1225 fi
1226 if test "$USE_INCLUDED_LIBINTL" = "yes" ; then
1227         INCLUDES=$INCLUDES' -I$(top_builddir)/intl -I$(top_srcdir)/intl'
1228 fi
1229 AC_SUBST(INCLUDES)
1230 dnl
1231 dnl Build CFLAGS
1232 dnl
1233 if test $cross_compiling = no; then
1234    BUILD_CFLAGS="$CFLAGS"
1235    BUILD_LDFLAGS="$LDFLAGS"
1236 else
1237    BUILD_CFLAGS=
1238    BUILD_LDFLAGS=
1239 fi
1240 AC_SUBST(BUILD_CFLAGS)
1241 AC_SUBST(BUILD_LDFLAGS)
1242 dnl
1243 dnl Make our output files, being sure that we create the some miscellaneous
1244 dnl directories
1245 dnl
1246 test -d lib || mkdir lib
1247 test -d include || mkdir include
1248 test -d include/linux || mkdir include/linux
1249 test -d include/asm || mkdir include/asm
1250 for i in MCONFIG Makefile e2fsprogs.spec \
1251         util/Makefile util/subst.conf util/gen-tarball util/install-symlink \
1252         lib/et/Makefile lib/ss/Makefile lib/e2p/Makefile \
1253         lib/ext2fs/Makefile lib/ext2fs/ext2_types.h \
1254         lib/uuid/Makefile lib/uuid/uuid_types.h \
1255         lib/blkid/Makefile lib/blkid/blkid_types.h lib/quota/Makefile \
1256         lib/ss/ss.pc lib/uuid/uuid.pc lib/et/com_err.pc \
1257         lib/e2p/e2p.pc lib/blkid/blkid.pc lib/ext2fs/ext2fs.pc \
1258         misc/Makefile ext2ed/Makefile e2fsck/Makefile \
1259         debugfs/Makefile tests/Makefile tests/progs/Makefile \
1260         resize/Makefile doc/Makefile intl/Makefile \
1261         intl/libgnuintl.h po/Makefile.in ; do
1262         if test -d `dirname ${srcdir}/$i` ; then
1263                 outlist="$outlist $i"
1264         fi
1265 done
1266 AC_OUTPUT($outlist)
1267 if test -f util/gen-tarball; then chmod +x util/gen-tarball; fi