configure.in

   1 AC_INIT(version.h)
   2 AC_PREREQ(2.54)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_HEADERS([lib/config.h])
   5 AH_BOTTOM([#include <dirpaths.h>])
   6 MCONFIG=./MCONFIG
   7 AC_SUBST_FILE(MCONFIG)
   8 BINARY_TYPE=bin
   9 dnl
  10 dnl This is to figure out the version number and the date....
  11 dnl
  12 E2FSPROGS_VERSION=`grep E2FSPROGS_VERSION ${srcdir}/version.h  \
  13         | awk '{print $3}' | tr \" " " | awk '{print $1}'`
  14 DATE=`grep E2FSPROGS_DATE ${srcdir}/version.h | awk '{print $3}' \
  15         | tr \" " "`
  16 E2FSPROGS_DAY=`echo $DATE | awk -F- '{print $1}'`
  17 MONTH=`echo $DATE | awk -F- '{print $2}'`
  18 YEAR=`echo $DATE | awk -F- '{print $3}'`
  19
  20 if expr $YEAR ">" 1900 > /dev/null ; then
  21         E2FSPROGS_YEAR=$YEAR
  22 elif expr $YEAR ">" 90 >/dev/null ; then
  23         E2FSPROGS_YEAR=19$YEAR
  24 else
  25         E2FSPROGS_YEAR=20$YEAR
  26 fi
  27
  28 case $MONTH in
  29 Jan)    MONTH_NUM=01; E2FSPROGS_MONTH="January" ;;
  30 Feb)    MONTH_NUM=02; E2FSPROGS_MONTH="February" ;;
  31 Mar)    MONTH_NUM=03; E2FSPROGS_MONTH="March" ;;
  32 Apr)    MONTH_NUM=04; E2FSPROGS_MONTH="April" ;;
  33 May)    MONTH_NUM=05; E2FSPROGS_MONTH="May" ;;
  34 Jun)    MONTH_NUM=06; E2FSPROGS_MONTH="June" ;;
  35 Jul)    MONTH_NUM=07; E2FSPROGS_MONTH="July" ;;
  36 Aug)    MONTH_NUM=08; E2FSPROGS_MONTH="August" ;;
  37 Sep)    MONTH_NUM=09; E2FSPROGS_MONTH="September" ;;
  38 Oct)    MONTH_NUM=10; E2FSPROGS_MONTH="October" ;;
  39 Nov)    MONTH_NUM=11; E2FSPROGS_MONTH="November" ;;
  40 Dec)    MONTH_NUM=12; E2FSPROGS_MONTH="December" ;;
  41 *)      AC_MSG_WARN([Unknown month $MONTH??]) ;;
  42 esac
  43
  44 base_ver=`echo $E2FSPROGS_VERSION | \
  45                sed -e 's/-WIP//' -e 's/pre-//' -e 's/-PLUS//'`
  46
  47 date_spec=${E2FSPROGS_YEAR}.${MONTH_NUM}.${E2FSPROGS_DAY}
  48
  49 case $E2FSPROGS_VERSION in
  50 *-WIP|pre-*)
  51         E2FSPROGS_PKGVER="$base_ver~WIP-$E2FSPROGS_YEAR-$MONTH_NUM-$E2FSPROGS_DAY"
  52         ;;
  53 *)
  54         E2FSPROGS_PKGVER="$base_ver"
  55         ;;
  56 esac
  57
  58 unset DATE MONTH YEAR base_ver pre_vers date_spec
  59 AC_MSG_RESULT([Generating configuration file for e2fsprogs version $E2FSPROGS_VERSION])
  60 AC_MSG_RESULT([Release date is ${E2FSPROGS_MONTH}, ${E2FSPROGS_YEAR}])
  61 AC_SUBST(E2FSPROGS_YEAR)
  62 AC_SUBST(E2FSPROGS_MONTH)
  63 AC_SUBST(E2FSPROGS_DAY)
  64 AC_SUBST(E2FSPROGS_VERSION)
  65 AC_SUBST(E2FSPROGS_PKGVER)
  66 dnl
  67 dnl Use diet libc
  68 dnl
  69 WITH_DIET_LIBC=
  70 AC_ARG_WITH([diet-libc],
  71 [  --with-diet-libc        use diet libc],
  72 CC="diet cc -nostdinc"
  73 WITH_DIET_LIBC=yes
  74 if test -z "$LIBS"
  75 then
  76         LIBS="-lcompat"
  77 else
  78         LIBS="$LIBS -lcompat"
  79 fi
  80 AC_MSG_RESULT(CC=$CC))dnl
  81 dnl
  82 AC_CANONICAL_HOST
  83 dnl
  84 dnl Check to see if libdl exists for the sake of dlopen
  85 dnl
  86 DLOPEN_LIB=''
  87 AC_CHECK_LIB(dl, dlopen,
  88 [DLOPEN_LIB=-ldl
  89 AC_DEFINE(HAVE_DLOPEN, 1, [Define to 1 if dlopen/libdl exists])])
  90 AC_SUBST(DLOPEN_LIB)
  91 dnl
  92 AC_ARG_WITH([cc],
  93 AC_HELP_STRING([--with-cc],[no longer supported, use CC= instead]),
  94 AC_MSG_ERROR([--with-cc no longer supported; use CC= instead]))
  95 dnl
  96 AC_ARG_WITH([ccopts],
  97 AC_HELP_STRING([--with-ccopts],[no longer supported, use CFLAGS= instead]),
  98 AC_MSG_ERROR([--with-ccopts no longer supported; use CFLAGS= instead]))
  99 dnl
 100 AC_ARG_WITH([ldopts],
 101 AC_HELP_STRING([--with-ldopts],[no longer supported, use LDFLAGS= instead]),
 102 AC_MSG_ERROR([--with-ldopts no longer supported; use LDFLAGS= instead]))
 103 dnl
 104 AC_PROG_CC
 105 if test "$GCC" = yes; then
 106    RDYNAMIC="-rdynamic"
 107    AC_SUBST(RDYNAMIC)
 108 fi
 109 AC_PROG_CPP
 110 dnl
 111 dnl Alpha computers use fast and imprecise floating point code that may
 112 dnl miss exceptions by default. Force sane options if we're using GCC.
 113 AC_MSG_CHECKING(for additional special compiler flags)
 114 if test "$GCC" = yes
 115 then
 116     case "$host_cpu" in
 117         alpha)          addcflags="-mieee" ;;
 118     esac
 119 fi
 120 if test "x$addcflags" != x
 121 then
 122     AC_MSG_RESULT($addcflags)
 123     CFLAGS="$addcflags $CFLAGS"
 124 else
 125     AC_MSG_RESULT([[(none)]])
 126 fi
 127 AC_USE_SYSTEM_EXTENSIONS
 128 dnl
 129 dnl Set default values for library extentions.  Will be dealt with after
 130 dnl parsing configuration opions, which may modify these
 131 dnl
 132 LIB_EXT=.a
 133 STATIC_LIB_EXT=.a
 134 PROFILED_LIB_EXT=.a
 135 dnl
 136 dnl Allow separate `root_prefix' to be specified
 137 dnl
 138 AC_ARG_WITH([root-prefix],
 139 [  --with-root-prefix=PREFIX override prefix variable for files to be placed in the root],
 140 root_prefix=$withval,
 141 root_prefix=NONE)dnl
 142 dnl
 143 dnl handle --enable-maintainer-mode
 144 dnl
 145 AC_ARG_ENABLE([maintainer-mode],
 146 [  --enable-maintainer-mode enable makefile rules useful for maintainers],
 147 if test "$enableval" = "no"
 148 then
 149         MAINTAINER_CMT=#
 150         AC_MSG_RESULT([Disabling maintainer mode])
 151 else
 152         MAINTAINER_CMT=
 153         AC_MSG_RESULT([Enabling maintainer mode])
 154 fi
 155 ,
 156 MAINTAINER_CMT=#
 157 AC_MSG_RESULT([Disabling maintainer mode by default])
 158 )
 159 AC_SUBST(MAINTAINER_CMT)
 160 dnl
 161 dnl handle --enable-symlink-install
 162 dnl
 163 AC_ARG_ENABLE([symlink-install],
 164 [  --enable-symlink-install use symlinks when installing instead of hard links],
 165 if test "$enableval" = "no"
 166 then
 167         LINK_INSTALL_FLAGS=-f
 168         AC_MSG_RESULT([Disabling symlinks for install])
 169 else
 170         LINK_INSTALL_FLAGS=-sf
 171         AC_MSG_RESULT([Enabling symlinks for install])
 172 fi
 173 ,
 174 LINK_INSTALL_FLAGS=-f
 175 AC_MSG_RESULT([Disabling symlinks for install by default])
 176 )
 177 AC_SUBST(LINK_INSTALL_FLAGS)
 178 dnl
 179 dnl handle --enable-relative-symlinks
 180 dnl
 181 relative_symlink_defined=
 182 AC_ARG_ENABLE([relative-symlinks],
 183 [  --enable-relative-symlinks use relative symlinks when installing],
 184 if test "$enableval" = "no"
 185 then
 186         SYMLINK_RELATIVE=
 187         relative_symlink_defined=yes
 188         AC_MSG_RESULT([Disabling relative symlinks for install])
 189 else
 190         SYMLINK_RELATIVE=--relative
 191         relative_symlink_defined=yes
 192         AC_MSG_RESULT([Enabling relative symlinks for install])
 193 fi)
 194 AC_ARG_ENABLE([symlink-relative-symlinks],,
 195 if test "$enableval" = "no"
 196 then
 197         SYMLINK_RELATIVE=yes
 198         AC_MSG_RESULT([Disabling relative symlinks for install])
 199 else
 200         SYMLINK_RELATIVE=--relative
 201         AC_MSG_RESULT([Enabling relative symlinks for install])
 202 fi
 203 ,
 204 if test -z "$relative_symlink_defined"
 205 then
 206         SYMLINK_RELATIVE=
 207 AC_MSG_RESULT([Disabling relative symlinks for install by default])
 208 fi
 209 )
 210 AC_SUBST(SYMLINK_RELATIVE)
 211 dnl
 212 dnl handle --enable-symlink-build
 213 dnl
 214 AC_ARG_ENABLE([symlink-build],
 215 [  --enable-symlink-build  use symlinks while building instead of hard links],
 216 if test "$enableval" = "no"
 217 then
 218         LINK_BUILD_FLAGS=
 219         AC_MSG_RESULT([Disabling symlinks for build])
 220 else
 221         LINK_BUILD_FLAGS=-s
 222         AC_MSG_RESULT([Enabling symlinks for build])
 223 fi
 224 ,
 225 LINK_BUILD_FLAGS=
 226 AC_MSG_RESULT([Disabling symlinks for build by default])
 227 )
 228 AC_SUBST(LINK_BUILD_FLAGS)
 229 dnl
 230 dnl handle --enable-verbose-makecmds
 231 dnl
 232 AC_ARG_ENABLE([verbose-makecmds],
 233 [  --enable-verbose-makecmds enable verbose make command output],
 234 if test "$enableval" = "no"
 235 then
 236         AC_MSG_RESULT([Disabling verbose make commands])
 237         E=@echo
 238         ES=echo
 239         Q=@
 240 else
 241         AC_MSG_RESULT([Enabling verbose make commands])
 242         E=@\\#
 243         ES=\\#
 244         Q=
 245 fi
 246 ,
 247 AC_MSG_RESULT([Disabling verbose make commands])
 248 E=@echo
 249 ES=echo
 250 Q=@
 251 )
 252 AC_SUBST(E)
 253 AC_SUBST(ES)
 254 AC_SUBST(Q)
 255 dnl
 256 dnl handle --enable-compression
 257 dnl
 258 AC_ARG_ENABLE([compression],
 259 [  --enable-compression   enable EXPERIMENTAL compression support],
 260 if test "$enableval" = "no"
 261 then
 262         AC_MSG_RESULT([Disabling compression support])
 263 else
 264         AC_DEFINE(ENABLE_COMPRESSION, 1,
 265                 [Define to 1 if ext2 compression enabled])
 266         AC_MSG_RESULT([Enabling compression support])
 267         AC_MSG_WARN([Compression support is experimental])
 268 fi
 269 ,
 270 AC_MSG_RESULT([Disabling compression support by default])
 271 )
 272 dnl
 273 dnl handle --enable-htree
 274 dnl
 275 AH_TEMPLATE([ENABLE_HTREE], [Define to 1 if ext3/4 htree support enabled])
 276 AC_ARG_ENABLE([htree],
 277 [  --enable-htree         enable EXPERIMENTAL htree directory support],
 278 if test "$enableval" = "no"
 279 then
 280         HTREE_CMT=#
 281         AC_MSG_RESULT([Disabling htree directory support])
 282 else
 283         HTREE_CMT=
 284         AC_DEFINE(ENABLE_HTREE, 1)
 285         AC_MSG_RESULT([Enabling htree directory support])
 286 fi
 287 ,
 288 HTREE_CMT=
 289 AC_DEFINE(ENABLE_HTREE, 1)
 290 AC_MSG_RESULT([Enabling htree directory support by default])
 291 )
 292 AC_SUBST(HTREE_CMT)
 293 dnl
 294 dnl This needs to be before all of the --enable-*-shlibs options
 295 dnl
 296 E2_PKG_CONFIG_STATIC=--static
 297 LDFLAG_DYNAMIC=
 298 PRIVATE_LIBS_CMT=
 299 dnl
 300 dnl handle --enable-elf-shlibs
 301 dnl
 302 AC_ARG_ENABLE([elf-shlibs],
 303 [  --enable-elf-shlibs    select ELF shared libraries],
 304 if test "$enableval" = "no"
 305 then
 306         ELF_CMT=#
 307         MAKEFILE_ELF=/dev/null
 308         AC_MSG_RESULT([Disabling ELF shared libraries])
 309 else
 310         E2_PKG_CONFIG_STATIC=
 311         ELF_CMT=
 312         MAKEFILE_ELF=$srcdir/lib/Makefile.elf-lib
 313         [case "$host_os" in
 314         solaris2.*)
 315                 MAKEFILE_ELF=$srcdir/lib/Makefile.solaris-lib
 316         ;;
 317         esac]
 318         BINARY_TYPE=elfbin
 319         LIB_EXT=.so
 320         PRIVATE_LIBS_CMT=#
 321         LDFLAG_DYNAMIC=['-Wl,-rpath-link,$(top_builddir)/lib']
 322         AC_MSG_RESULT([Enabling ELF shared libraries])
 323 fi
 324 ,
 325 MAKEFILE_ELF=/dev/null
 326 ELF_CMT=#
 327 AC_MSG_RESULT([Disabling ELF shared libraries by default])
 328 )
 329 AC_SUBST(ELF_CMT)
 330 AC_SUBST_FILE(MAKEFILE_ELF)
 331 dnl
 332 dnl handle --enable-bsd-shlibs
 333 dnl
 334 AC_ARG_ENABLE([bsd-shlibs],
 335 [  --enable-bsd-shlibs    select BSD shared libraries],
 336 if test "$enableval" = "no"
 337 then
 338         BSDLIB_CMT=#
 339         MAKEFILE_BSDLIB=/dev/null
 340         AC_MSG_RESULT([Disabling BSD shared libraries])
 341 else
 342         E2_PKG_CONFIG_STATIC=
 343         BSDLIB_CMT=
 344         MAKEFILE_BSDLIB=$srcdir/lib/Makefile.bsd-lib
 345         LIB_EXT=.so
 346         [case "$host_os" in
 347         darwin*)
 348                 MAKEFILE_BSDLIB=$srcdir/lib/Makefile.darwin-lib
 349                 LIB_EXT=.dylib
 350         ;;
 351         esac]
 352         AC_MSG_RESULT([Enabling BSD shared libraries])
 353 fi
 354 ,
 355 MAKEFILE_BSDLIB=/dev/null
 356 BSDLIB_CMT=#
 357 AC_MSG_RESULT([Disabling BSD shared libraries by default])
 358 )
 359 AC_SUBST(BSDLIB_CMT)
 360 AC_SUBST_FILE(MAKEFILE_BSDLIB)
 361 dnl
 362 dnl handle --enable-profile
 363 dnl
 364 AC_ARG_ENABLE([profile],
 365 [  --enable-profile       build profiling libraries],
 366 if test "$enableval" = "no"
 367 then
 368         PROFILE_CMT=#
 369         MAKEFILE_PROFILE=/dev/null
 370         AC_MSG_RESULT([Disabling profiling libraries])
 371 else
 372         PROFILE_CMT=
 373         MAKEFILE_PROFILE=$srcdir/lib/Makefile.profile
 374         PROFILED_LIB_EXT=_p.a
 375         AC_MSG_RESULT([Building profiling libraries])
 376 fi
 377 ,
 378 PROFILE_CMT=#
 379 MAKEFILE_PROFILE=/dev/null
 380 AC_MSG_RESULT([Disabling profiling libraries by default])
 381 )
 382 AC_SUBST(PROFILE_CMT)
 383 AC_SUBST_FILE(MAKEFILE_PROFILE)
 384 dnl
 385 dnl handle --enable-gcov
 386 dnl
 387 AC_ARG_ENABLE([gcov],
 388 [  --enable-gcov                  build for coverage testing using gcov],
 389 if test "$enableval" = "yes"
 390 then
 391         CFLAGS="-g -fprofile-arcs -ftest-coverage"
 392         LDFLAGS="-fprofile-arcs -ftest-coverage"
 393         AC_MSG_RESULT([Enabling gcov support])
 394 fi
 395 )
 396
 397 dnl
 398 dnl Substitute library extensions
 399 dnl
 400 AC_SUBST(LIB_EXT)
 401 AC_SUBST(STATIC_LIB_EXT)
 402 AC_SUBST(PROFILED_LIB_EXT)
 403 AC_SUBST(LDFLAG_DYNAMIC)
 404 AC_SUBST(PRIVATE_LIBS_CMT)
 405 dnl
 406 dnl handle --enable-jbd-debug
 407 dnl
 408 AC_ARG_ENABLE([jbd-debug],
 409 [  --enable-jbd-debug     enable journal debugging],
 410 if test "$enableval" = "no"
 411 then
 412         AC_MSG_RESULT([Disabling journal debugging])
 413 else
 414         AC_DEFINE(CONFIG_JBD_DEBUG, 1,
 415                 [Define to 1 if debugging ext3/4 journal code])
 416         AC_MSG_RESULT([Enabling journal debugging])
 417 fi
 418 ,
 419 AC_MSG_RESULT([Disabling journal debugging by default])
 420 )
 421 dnl
 422 dnl handle --enable-blkid-debug
 423 dnl
 424 AC_ARG_ENABLE([blkid-debug],
 425 [  --enable-blkid-debug    enable blkid debugging],
 426 if test "$enableval" = "no"
 427 then
 428         AC_MSG_RESULT([Disabling blkid debugging])
 429 else
 430         AC_DEFINE(CONFIG_BLKID_DEBUG, 1,
 431                 [Define to 1 if debugging the blkid library])
 432         AC_MSG_RESULT([Enabling blkid debugging])
 433 fi
 434 ,
 435 AC_MSG_RESULT([Disabling blkid debugging by default])
 436 )
 437 dnl
 438 dnl handle --enable-testio-debug
 439 dnl
 440 AC_ARG_ENABLE([testio-debug],
 441 [  --disable-testio-debug  disable the use of the test I/O manager for debugging],
 442 AH_TEMPLATE([CONFIG_TESTIO_DEBUG],
 443         [Define to 1 if the testio I/O manager should be enabled])
 444 if test "$enableval" = "no"
 445 then
 446         AC_MSG_RESULT([Disabling testio debugging])
 447         TEST_IO_CMT="#"
 448 else
 449         TEST_IO_CMT=
 450         AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 451         AC_MSG_RESULT([Enabling testio debugging])
 452 fi
 453 ,
 454 AC_MSG_RESULT([Enabling testio debugging by default])
 455 AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 456 TEST_IO_CMT=
 457 )
 458 AC_SUBST(TEST_IO_CMT)
 459 dnl
 460 dnl handle --disable-libuuid
 461 dnl
 462 PKG_PROG_PKG_CONFIG
 463 LIBUUID=
 464 DEPLIBUUID=
 465 STATIC_LIBUUID=
 466 DEPSTATIC_LIBUUID=
 467 PROFILED_LIBUUID=
 468 DEPPROFILED_LIBUUID=
 469 UUID_CMT=
 470 AC_ARG_ENABLE([libuuid],
 471 [  --disable-libuuid      do not build private uuid library],
 472 if test "$enableval" = "no"
 473 then
 474         if test -z "$PKG_CONFIG"; then
 475                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 476         fi
 477
 478         AC_CHECK_LIB(uuid, uuid_generate,
 479                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 480                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`],
 481                 [AC_MSG_ERROR([external uuid library not found])])
 482         UUID_CMT=#
 483         AC_MSG_RESULT([Disabling private uuid library])
 484 else
 485         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 486         DEPLIBUUID=$LIBUUID
 487         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 488         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 489         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 490         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 491         AC_MSG_RESULT([Enabling private uuid library])
 492 fi
 493 ,
 494 LIBUUID='$(LIB)/libuuid'$LIB_EXT
 495 DEPLIBUUID=$LIBUUID
 496 STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 497 DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 498 PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 499 DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 500 AC_MSG_RESULT([Enabling private uuid library by default])
 501 )
 502 AC_SUBST(LIBUUID)
 503 AC_SUBST(DEPLIBUUID)
 504 AC_SUBST(STATIC_LIBUUID)
 505 AC_SUBST(DEPSTATIC_LIBUUID)
 506 AC_SUBST(PROFILED_LIBUUID)
 507 AC_SUBST(DEPPROFILED_LIBUUID)
 508 AC_SUBST(UUID_CMT)
 509 dnl
 510 dnl handle --disable-libblkid
 511 dnl
 512 PKG_PROG_PKG_CONFIG
 513 LIBBLKID=
 514 DEPLIBBLKID=
 515 STATIC_LIBBLKID=
 516 DEPSTATIC_LIBBLKID=
 517 PROFILED_LIBBLKID=
 518 DEPPROFILED_LIBBLKID=
 519 BLKID_CMT=
 520 AH_TEMPLATE([CONFIG_BUILD_FINDFS], [Define to 1 to compile findfs])
 521 AC_ARG_ENABLE([libblkid],
 522 [  --disable-libblkid     do not build private blkid library],
 523 if test "$enableval" = "no"
 524 then
 525         if test -z "$PKG_CONFIG"; then
 526                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 527         fi
 528
 529         AC_CHECK_LIB(blkid, blkid_get_cache,
 530                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 531                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`],
 532                 [AC_MSG_ERROR([external blkid library not found])], -luuid)
 533         BLKID_CMT=#
 534         AC_MSG_RESULT([Disabling private blkid library])
 535 else
 536         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 537         DEPLIBBLKID=$LIBBLKID
 538         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 539         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 540         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 541         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 542         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 543         AC_MSG_RESULT([Enabling private blkid library])
 544 fi
 545 ,
 546 LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 547 DEPLIBBLKID=$LIBBLKID
 548 STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 549 DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 550 PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 551 DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 552 AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 553 AC_MSG_RESULT([Enabling private blkid library by default])
 554 )
 555 AC_SUBST(LIBBLKID)
 556 AC_SUBST(DEPLIBBLKID)
 557 AC_SUBST(STATIC_LIBBLKID)
 558 AC_SUBST(DEPSTATIC_LIBBLKID)
 559 AC_SUBST(PROFILED_LIBBLKID)
 560 AC_SUBST(DEPPROFILED_LIBBLKID)
 561 AC_SUBST(BLKID_CMT)
 562 dnl
 563 dnl handle --enable-quota
 564 dnl
 565 QUOTA_MAN_COMMENT='.\"'
 566 QUOTA_CMT=
 567 AC_SUBST(QUOTA_MAN_COMMENT)
 568 PKG_PROG_PKG_CONFIG
 569 AH_TEMPLATE([CONFIG_QUOTA], [Define to 1 to enable quota support])
 570 AC_ARG_ENABLE([quota],
 571 [  --enable-quota         enable quota support],
 572 if test "$enableval" = "no"
 573 then
 574         QUOTA_CMT=#
 575         AC_MSG_RESULT([Disabling quota support])
 576 else
 577         QUOTA_CMT=
 578         AC_DEFINE(CONFIG_QUOTA, 1)
 579         AC_MSG_RESULT([Enabling quota support])
 580         QUOTA_MAN_COMMENT=""
 581         AC_SUBST(QUOTA_MAN_COMMENT)
 582 fi
 583 ,
 584 QUOTA_CMT=#
 585 AC_MSG_RESULT([Disabling quota support by default])
 586 )
 587 dnl
 588 dnl Define stuff expected for quota library
 589 dnl
 590 LIBQUOTA='$(LIB)/libquota'$LIB_EXT
 591 DEPLIBQUOTA=$LIBQUOTA
 592 STATIC_LIBQUOTA='$(LIB)/libquota'$STATIC_LIB_EXT
 593 DEPSTATIC_LIBQUOTA=$STATIC_LIBQUOTA
 594 PROFILED_LIBQUOTA='$(LIB)/libquota'$PROFILED_LIB_EXT
 595 DEPPROFILED_LIBQUOTA=$PROFILED_LIBQUOTA
 596 AC_SUBST(LIBQUOTA)
 597 AC_SUBST(DEPLIBQUOTA)
 598 AC_SUBST(STATIC_LIBQUOTA)
 599 AC_SUBST(DEPSTATIC_LIBQUOTA)
 600 AC_SUBST(PROFILED_LIBQUOTA)
 601 AC_SUBST(DEPPROFILED_LIBQUOTA)
 602 AC_SUBST(QUOTA_CMT)
 603 dnl
 604 dnl handle --disable-backtrace
 605 dnl
 606 AH_TEMPLATE([DISABLE_BACKTRACE], [Define to 1 to disable use of backtrace])
 607 AC_ARG_ENABLE([backtrace],
 608 [  --disable-backtrace    disable use backtrace],
 609 if test "$enableval" = "no"
 610 then
 611         AC_MSG_RESULT([Disabling use of backtrace])
 612         AC_DEFINE(DISABLE_BACKTRACE, 1)
 613 else
 614         AC_MSG_RESULT([Enabling use of backtrace])
 615 fi
 616 ,
 617 AC_MSG_RESULT([Enabling use of backtrace by default])
 618 )
 619 dnl
 620 dnl handle --enable-debugfs
 621 dnl
 622 AC_ARG_ENABLE([debugfs],
 623 [  --disable-debugfs      disable support of debugfs program],
 624 if test "$enableval" = "no"
 625 then
 626         AC_MSG_RESULT([Disabling debugfs support])
 627         DEBUGFS_CMT="#"
 628 else
 629         DEBUGFS_CMT=
 630         AC_MSG_RESULT([Enabling debugfs support])
 631 fi
 632 ,
 633 AC_MSG_RESULT([Enabling debugfs support by default])
 634 DEBUGFS_CMT=
 635 )
 636 AC_SUBST(DEBUGFS_CMT)
 637 dnl
 638 dnl handle --enable-imager
 639 dnl
 640 AC_ARG_ENABLE([imager],
 641 [  --disable-imager       disable support of e2image program],
 642 if test "$enableval" = "no"
 643 then
 644         AC_MSG_RESULT([Disabling e2image support])
 645         IMAGER_CMT="#"
 646 else
 647         IMAGER_CMT=
 648         AC_MSG_RESULT([Enabling e2image support])
 649 fi
 650 ,
 651 AC_MSG_RESULT([Enabling e2image support by default])
 652 IMAGER_CMT=
 653 )
 654 AC_SUBST(IMAGER_CMT)
 655 dnl
 656 dnl handle --enable-resizer
 657 dnl
 658 AC_ARG_ENABLE([resizer],
 659 [  --disable-resizer      disable support of e2resize program],
 660 if test "$enableval" = "no"
 661 then
 662         AC_MSG_RESULT([Disabling e2resize support])
 663         RESIZER_CMT="#"
 664 else
 665         RESIZER_CMT=
 666         AC_MSG_RESULT([Enabling e2resize support])
 667 fi
 668 ,
 669 AC_MSG_RESULT([Enabling e2resize support by default])
 670 RESIZER_CMT=
 671 )
 672 AC_SUBST(RESIZER_CMT)
 673 dnl
 674 dnl handle --enable-defrag
 675 dnl
 676 AC_ARG_ENABLE([defrag],
 677 [  --disable-defrag       disable support of e4defrag program],
 678 if test "$enableval" = "no"
 679 then
 680         AC_MSG_RESULT([Disabling e4defrag support])
 681         DEFRAG_CMT="#"
 682 else
 683         DEFRAG_CMT=
 684         AC_MSG_RESULT([Enabling e4defrag support])
 685 fi
 686 ,
 687 if test -z "$WITH_DIET_LIBC"
 688 then
 689         AC_MSG_RESULT([Enabling e4defrag support by default])
 690         DEFRAG_CMT=
 691 else
 692         AC_MSG_RESULT([Disabling e4defrag support by default])
 693         DEFRAG_CMT="#"
 694 fi
 695 )
 696 AC_SUBST(DEFRAG_CMT)
 697 dnl
 698 dnl See whether to install the `fsck' wrapper program (that calls e2fsck)
 699 dnl
 700 AC_ARG_ENABLE([fsck],
 701 [  --enable-fsck           build fsck wrapper program],
 702 [if test "$enableval" = "no"
 703 then
 704         FSCK_PROG='' FSCK_MAN=''
 705         AC_MSG_RESULT([Not building fsck wrapper])
 706 else
 707         FSCK_PROG=fsck FSCK_MAN=fsck.8
 708         AC_MSG_RESULT([Building fsck wrapper])
 709 fi]
 710 ,
 711 [case "$host_os" in
 712   gnu*)
 713     FSCK_PROG='' FSCK_MAN=''
 714     AC_MSG_RESULT([Not building fsck wrapper by default])
 715     ;;
 716   *)
 717     FSCK_PROG=fsck FSCK_MAN=fsck.8
 718     AC_MSG_RESULT([Building fsck wrapper by default])
 719 esac]
 720 )
 721 AC_SUBST(FSCK_PROG)
 722 AC_SUBST(FSCK_MAN)
 723 dnl
 724 dnl See whether to install the `e2initrd-helper' program
 725 dnl
 726 AC_ARG_ENABLE([e2initrd-helper],
 727 [  --enable-e2initrd-helper build e2initrd-helper program],
 728 [if test "$enableval" = "no"
 729 then
 730         E2INITRD_PROG='' E2INITRD_MAN=''
 731         AC_MSG_RESULT([Not building e2initrd helper])
 732 else
 733         E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 734         AC_MSG_RESULT([Building e2initrd helper])
 735 fi]
 736 ,
 737 E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 738 AC_MSG_RESULT([Building e2initrd helper by default])
 739 )
 740 AC_SUBST(E2INITRD_PROG)
 741 AC_SUBST(E2INITRD_MAN)
 742 dnl
 743 dnl
 744 dnl
 745 AC_ARG_ENABLE([tls],
 746 [  --disable-tls           disable use of thread local support],
 747 [if test "$enableval" = "no"
 748 then
 749         try_tls=""
 750         AC_MSG_RESULT([Disabling thread local support])
 751 else
 752         try_tls="yes"
 753         AC_MSG_RESULT([Enabling thread local support])
 754 fi]
 755 ,
 756 if test -n "$WITH_DIET_LIBC"
 757 then
 758         try_tls=""
 759         AC_MSG_RESULT([Diet libc does not support thread local support])
 760 else
 761         try_tls="yes"
 762         AC_MSG_RESULT([Try using thread local support by default])
 763 fi
 764 )
 765 if test "$try_tls" = "yes"
 766 then
 767 AX_TLS
 768 fi
 769 dnl
 770 dnl
 771 dnl
 772 AH_TEMPLATE([USE_UUIDD], [Define to 1 to build uuidd])
 773 AC_ARG_ENABLE([uuidd],
 774 [  --disable-uuidd         disable building the uuid daemon],
 775 [if test "$enableval" = "no"
 776 then
 777         AC_MSG_RESULT([Not building uuidd])
 778         UUIDD_CMT="#"
 779 else
 780         AC_DEFINE(USE_UUIDD, 1)
 781         UUIDD_CMT=""
 782         AC_MSG_RESULT([Building uuidd])
 783 fi]
 784 ,
 785 AC_DEFINE(USE_UUIDD, 1)
 786 UUIDD_CMT=""
 787 AC_MSG_RESULT([Building uuidd by default])
 788 )
 789 AC_SUBST(UUIDD_CMT)
 790 dnl
 791 dnl
 792 dnl
 793 MAKEFILE_LIBRARY=$srcdir/lib/Makefile.library
 794 AC_SUBST_FILE(MAKEFILE_LIBRARY)
 795 dnl
 796 dnl Add internationalization support, using gettext.
 797 dnl
 798 GETTEXT_PACKAGE=e2fsprogs
 799 PACKAGE=e2fsprogs
 800 VERSION="$E2FSPROGS_VERSION"
 801 VERSION=0.14.1
 802 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [package name for gettext])
 803 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [version for gettext])
 804 AC_SUBST(GETTEXT_PACKAGE)
 805 AC_SUBST(PACKAGE)
 806 AC_SUBST(VERSION)
 807
 808 AM_GNU_GETTEXT
 809 dnl
 810 dnl End of configuration options
 811 dnl
 812 AC_SUBST(BINARY_TYPE)
 813 AC_PROG_MAKE_SET
 814 CHECK_GNU_MAKE
 815 AC_PATH_PROG(LN, ln, ln)
 816 AC_PROG_LN_S
 817 AC_PATH_PROG(MV, mv, mv)
 818 AC_PATH_PROG(CP, cp, cp)
 819 AC_PATH_PROG(RM, rm, rm)
 820 AC_PATH_PROG(CHMOD, chmod, :)
 821 AC_PROG_AWK
 822 AC_PROG_EGREP
 823 AC_PATH_PROG(SED, sed, sed)
 824 AC_PATH_PROG(PERL, perl, perl)
 825 AC_PATH_PROG(LDCONFIG, ldconfig, :)
 826 AC_CHECK_TOOL(AR, ar, ar)
 827 AC_CHECK_TOOL(RANLIB, ranlib, :)
 828 AC_CHECK_TOOL(STRIP, strip, :)
 829 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
 830 if test "_$MAKEINFO" = "_"; then
 831     MAKEINFO="@echo Makeinfo is missing. Info documentation will not be built.;true"
 832 else
 833     case "$MAKEINFO" in
 834       */missing.*)
 835         AC_MSG_WARN([
 836 *** Makeinfo is missing. Info documentation will not be built.])
 837         ;;
 838       *)
 839         ;;
 840     esac
 841 fi
 842 AC_SUBST(MAKEINFO)
 843 AC_PROG_INSTALL
 844 # See if we need a separate native compiler.
 845 if test $cross_compiling = no; then
 846   BUILD_CC="$CC"
 847   AC_SUBST(BUILD_CC)
 848 else
 849   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 850 fi
 851 AC_CHECK_HEADERS(m4_flatten([
 852         dirent.h
 853         errno.h
 854         execinfo.h
 855         getopt.h
 856         malloc.h
 857         mntent.h
 858         paths.h
 859         semaphore.h
 860         setjmp.h
 861         signal.h
 862         stdarg.h
 863         stdint.h
 864         stdlib.h
 865         termios.h
 866         termio.h
 867         unistd.h
 868         utime.h
 869         linux/falloc.h
 870         linux/fd.h
 871         linux/major.h
 872         linux/loop.h
 873         net/if_dl.h
 874         netinet/in.h
 875         sys/disklabel.h
 876         sys/disk.h
 877         sys/file.h
 878         sys/ioctl.h
 879         sys/mkdev.h
 880         sys/mman.h
 881         sys/mount.h
 882         sys/prctl.h
 883         sys/resource.h
 884         sys/select.h
 885         sys/socket.h
 886         sys/sockio.h
 887         sys/stat.h
 888         sys/syscall.h
 889         sys/sysmacros.h
 890         sys/time.h
 891         sys/types.h
 892         sys/un.h
 893         sys/wait.h
 894 ]))
 895 AC_CHECK_HEADERS(net/if.h,,,
 896 [[
 897 #if HAVE_SYS_TYPES_H
 898 #include <sys/types.h>
 899 #endif
 900 #if HAVE_SYS_SOCKET
 901 #include <sys/socket.h>
 902 #endif
 903 ]])
 904 AC_FUNC_VPRINTF
 905 dnl Check to see if dirent has member d_reclen. On cygwin those d_reclen
 906 dnl is not decleared.
 907 AC_CHECK_MEMBER(struct dirent.d_reclen,[AC_DEFINE(HAVE_RECLEN_DIRENT, 1,
 908                        [Define to 1 if dirent has d_reclen])],,
 909                 [#include <dirent.h>])
 910 AC_CHECK_MEMBERS([struct stat.st_atim])
 911 dnl Check to see if ssize_t was declared
 912 AC_CHECK_TYPE(ssize_t,[AC_DEFINE(HAVE_TYPE_SSIZE_T, 1,
 913                 [Define to 1 if ssize_t declared])],,
 914               [#include <sys/types.h>])
 915 dnl
 916 dnl Check to see if llseek() is declared in unistd.h.  On some libc's
 917 dnl it is, and on others it isn't..... Thank you glibc developers....
 918 dnl
 919 AC_CHECK_DECL(llseek,[AC_DEFINE(HAVE_LLSEEK_PROTOTYPE, 1,
 920                         [Define to 1 if llseek declared in unistd.h])],,
 921               [#include <unistd.h>])
 922 dnl
 923 dnl Check to see if lseek64() is declared in unistd.h.  Glibc's header files
 924 dnl are so convoluted that I can't tell whether it will always be defined,
 925 dnl and if it isn't defined while lseek64 is defined in the library,
 926 dnl disaster will strike.
 927 dnl
 928 dnl Warning!  Use of --enable-gcc-wall may throw off this test.
 929 dnl
 930 dnl
 931 AC_CHECK_DECL(lseek64,[AC_DEFINE(HAVE_LSEEK64_PROTOTYPE, 1,
 932                         [Define to 1 if lseek64 declared in unistd.h])],,
 933                 [#define _LARGEFILE_SOURCE
 934                  #define _LARGEFILE64_SOURCE
 935                  #include <unistd.h>])
 936 dnl
 937 dnl Word sizes...
 938 dnl
 939 AC_CHECK_SIZEOF(short)
 940 AC_CHECK_SIZEOF(int)
 941 AC_CHECK_SIZEOF(long)
 942 AC_CHECK_SIZEOF(long long)
 943 AC_CHECK_SIZEOF(off_t)
 944 SIZEOF_SHORT=$ac_cv_sizeof_short
 945 SIZEOF_INT=$ac_cv_sizeof_int
 946 SIZEOF_LONG=$ac_cv_sizeof_long
 947 SIZEOF_LONG_LONG=$ac_cv_sizeof_long_long
 948 SIZEOF_OFF_T=$ac_cv_sizeof_off_t
 949 AC_SUBST(SIZEOF_SHORT)
 950 AC_SUBST(SIZEOF_INT)
 951 AC_SUBST(SIZEOF_LONG)
 952 AC_SUBST(SIZEOF_LONG_LONG)
 953 AC_SUBST(SIZEOF_OFF_T)
 954 AC_C_BIGENDIAN
 955 if test $cross_compiling = no; then
 956   BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
 957 else
 958   CROSS_COMPILE="1" BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
 959 fi
 960 ASM_TYPES_HEADER=./asm_types.h
 961 AC_SUBST_FILE(ASM_TYPES_HEADER)
 962 dnl
 963 dnl Save the configuration #defines needed for the public ext2fs.h
 964 dnl header file
 965 dnl
 966 echo "/* These defines are needed for the public ext2fs.h header file */" \
 967      > public_config.h
 968 if grep HAVE_SYS_TYPES_H confdefs.h > tmp_config.$$; then
 969   uniq tmp_config.$$ >> public_config.h
 970 else
 971   echo "#undef HAVE_SYS_TYPES_H" >> public_config.h
 972 fi
 973 if grep WORDS_BIGENDIAN confdefs.h > tmp_config.$$; then
 974   uniq tmp_config.$$ >> public_config.h
 975 else
 976   echo "#undef WORDS_BIGENDIAN" >> public_config.h
 977 fi
 978 rm -f tmp_config.$$
 979 PUBLIC_CONFIG_HEADER=./public_config.h
 980 AC_SUBST_FILE(PUBLIC_CONFIG_HEADER)
 981 dnl
 982 dnl See if we have inttypes.h and if intptr_t is defined
 983 dnl
 984 AC_CHECK_HEADERS([inttypes.h])
 985 AC_CHECK_TYPES(intptr_t)
 986 dnl
 987 dnl See if struct stat has a st_flags field, in which case we can get file
 988 dnl flags somewhat portably.  Also check for the analogous setter, chflags().
 989 dnl
 990 AC_MSG_CHECKING(whether struct stat has a st_flags field)
 991 AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags,
 992         AC_TRY_COMPILE([#include <sys/stat.h>],
 993                 [struct stat stat; stat.st_flags = 0;],
 994                 [e2fsprogs_cv_struct_st_flags=yes],
 995                 [e2fsprogs_cv_struct_st_flags=no]))
 996 AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags)
 997 if test "$e2fsprogs_cv_struct_st_flags" = yes; then
 998   AC_MSG_CHECKING(whether st_flags field is useful)
 999   AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags_immut,
1000         AC_TRY_COMPILE([#include <sys/stat.h>],
1001                 [struct stat stat; stat.st_flags |= UF_IMMUTABLE;],
1002                 [e2fsprogs_cv_struct_st_flags_immut=yes],
1003                 [e2fsprogs_cv_struct_st_flags_immut=no]))
1004   AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags_immut)
1005   if test "$e2fsprogs_cv_struct_st_flags_immut" = yes; then
1006           AC_DEFINE(HAVE_STAT_FLAGS, 1,
1007                 [Define to 1 if struct stat has st_flags])
1008   fi
1009 fi
1010 dnl
1011 dnl Check for the presence of SA_LEN
1012 dnl
1013 AC_CHECK_MEMBER(struct sockaddr.sa_len,
1014                 AC_DEFINE_UNQUOTED(HAVE_SA_LEN,1,
1015                         [Define to 1 if if struct sockaddr contains sa_len]),,
1016         [#include <sys/types.h>
1017          #include <sys/socket.h>])
1018 dnl
1019 dnl This will add -lblkid to the AC_CHECK_FUNCS search if we are using
1020 dnl the system-provided blkid library
1021 dnl
1022 if test -n "$BLKID_CMT"; then
1023   AC_SEARCH_LIBS([blkid_probe_all], [blkid])
1024 fi
1025 dnl
1026 AC_CHECK_FUNCS(m4_flatten([
1027         __secure_getenv
1028         backtrace
1029         blkid_probe_get_topology
1030         blkid_probe_enable_partitions
1031         chflags
1032         fadvise64
1033         fallocate
1034         fallocate64
1035         fchown
1036         fdatasync
1037         fstat64
1038         ftruncate64
1039         futimes
1040         getcwd
1041         getdtablesize
1042         getmntinfo
1043         getpwuid_r
1044         getrlimit
1045         getrusage
1046         jrand48
1047         llseek
1048         lseek64
1049         mallinfo
1050         mbstowcs
1051         memalign
1052         mempcpy
1053         mmap
1054         msync
1055         nanosleep
1056         open64
1057         pathconf
1058         posix_fadvise
1059         posix_fadvise64
1060         posix_memalign
1061         prctl
1062         pread
1063         pwrite
1064         pread64
1065         pwrite64
1066         secure_getenv
1067         setmntent
1068         setresgid
1069         setresuid
1070         snprintf
1071         srandom
1072         stpcpy
1073         strcasecmp
1074         strdup
1075         strnlen
1076         strptime
1077         strtoull
1078         sync_file_range
1079         sysconf
1080         usleep
1081         utime
1082         valloc
1083 ]))
1084 dnl
1085 dnl Check to see if -lsocket is required (solaris) to make something
1086 dnl that uses socket() to compile; this is needed for the UUID library
1087 dnl
1088 SOCKET_LIB=''
1089 AC_CHECK_LIB(socket, socket, [SOCKET_LIB=-lsocket])
1090 AC_SUBST(SOCKET_LIB)
1091 dnl
1092 dnl See if optreset exists
1093 dnl
1094 AC_MSG_CHECKING(for optreset)
1095 AC_CACHE_VAL(ac_cv_have_optreset,
1096 [AC_EGREP_HEADER(optreset, unistd.h,
1097   ac_cv_have_optreset=yes, ac_cv_have_optreset=no)])dnl
1098 AC_MSG_RESULT($ac_cv_have_optreset)
1099 if test $ac_cv_have_optreset = yes; then
1100   AC_DEFINE(HAVE_OPTRESET, 1, [Define to 1 if optreset for getopt is present])
1101 fi
1102 dnl
1103 dnl Test for sem_init, and which library it might require:
1104 dnl
1105 AH_TEMPLATE([HAVE_SEM_INIT], [Define to 1 if sem_init() exists])
1106 SEM_INIT_LIB=''
1107 AC_CHECK_FUNC(sem_init, ,
1108   AC_CHECK_LIB(pthread, sem_init,
1109         AC_DEFINE(HAVE_SEM_INIT, 1)
1110         SEM_INIT_LIB=-lpthread,
1111   AC_CHECK_LIB(rt, sem_init,
1112         AC_DEFINE(HAVE_SEM_INIT, 1)
1113         SEM_INIT_LIB=-lrt,
1114   AC_CHECK_LIB(posix4, sem_init,
1115         AC_DEFINE(HAVE_SEM_INIT, 1)
1116         SEM_INIT_LIB=-lposix4))))dnl
1117 AC_SUBST(SEM_INIT_LIB)
1118 dnl
1119 dnl Check for unified diff
1120 dnl
1121 AC_MSG_CHECKING(for unified diff option)
1122 if diff -u $0 $0 > /dev/null 2>&1 ; then
1123    UNI_DIFF_OPTS=-u
1124 else
1125    UNI_DIFF_OPTS=-c
1126 fi
1127 AC_MSG_RESULT($UNI_DIFF_OPTS)
1128 AC_SUBST(UNI_DIFF_OPTS)
1129 dnl
1130 dnl We use the EXT2 ioctls only under Linux
1131 dnl
1132 case "$host_os" in
1133 linux*)
1134         AC_DEFINE(HAVE_EXT2_IOCTLS, 1, [Define to 1 if Ext2 ioctls present])
1135         ;;
1136 esac
1137 dnl
1138 dnl OS-specific uncomment control
1139 dnl
1140 LINUX_CMT="#"
1141 CYGWIN_CMT="#"
1142 UNIX_CMT=
1143 case "$host_os" in
1144 linux*)
1145         LINUX_CMT=
1146         ;;
1147 cygwin)
1148         CYGWIN_CMT=
1149         UNIX_CMT="#"
1150         ;;
1151 esac
1152 AC_SUBST(LINUX_CMT)
1153 AC_SUBST(CYGWIN_CMT)
1154 AC_SUBST(UNIX_CMT)
1155 dnl
1156 dnl Linux and Hurd places root files in the / by default
1157 dnl
1158 case "$host_os" in
1159 linux* | gnu* | k*bsd*-gnu)
1160         if test "$prefix" = NONE -a "$root_prefix" = NONE ; then
1161                 root_prefix="";
1162                 AC_MSG_RESULT([On $host_os systems, root_prefix defaults to ''])
1163         fi
1164         ;;
1165 esac
1166 dnl
1167 dnl On Linux/hurd, force the prefix to be /usr
1168 dnl
1169 case "$host_os" in
1170 linux* | gnu* | k*bsd*-gnu)
1171         if test "$prefix" = NONE ; then
1172                 prefix="/usr";
1173                 AC_MSG_RESULT([On $host_os systems, prefix defaults to /usr])
1174                 if test "$mandir" = '${prefix}/man' ; then
1175                         AC_MSG_RESULT([...and mandir defaults to /usr/share/man])
1176                         mandir=/usr/share/man
1177                 fi
1178         fi
1179 ;;
1180 esac
1181 if test "$root_prefix" = NONE ; then
1182         if test "$prefix" = NONE ; then
1183                 root_prefix="$ac_default_prefix"
1184         else
1185                 root_prefix="$prefix"
1186         fi
1187         root_bindir=$bindir
1188         root_sbindir=$sbindir
1189         root_libdir=$libdir
1190         root_sysconfdir=$sysconfdir
1191 else
1192         root_bindir='${root_prefix}/bin'
1193         root_sbindir='${root_prefix}/sbin'
1194         root_libdir='${root_prefix}/lib'
1195         root_sysconfdir='${root_prefix}/etc'
1196 fi
1197 if test "$bindir" != '${exec_prefix}/bin'; then
1198     root_bindir=$bindir
1199     AC_MSG_RESULT([Setting root_bindir to $root_bindir])
1200 fi
1201 if test "$sbindir" != '${exec_prefix}/sbin'; then
1202     root_sbindir=$sbindir
1203     AC_MSG_RESULT([Setting root_sbindir to $root_sbindir])
1204 fi
1205 if test "$libdir" != '${exec_prefix}/lib'; then
1206     root_libdir=$libdir
1207     AC_MSG_RESULT([Setting root_libdir to $root_libdir])
1208 fi
1209 if test "$sysconfdir" != '${prefix}/etc'; then
1210     root_sysconfdir=$sysconfdir
1211     AC_MSG_RESULT([Setting root_sysconfdir to $root_sysconfdir])
1212 fi
1213 AC_SUBST(root_prefix)
1214 AC_SUBST(root_bindir)
1215 AC_SUBST(root_sbindir)
1216 AC_SUBST(root_libdir)
1217 AC_SUBST(root_sysconfdir)
1218 dnl
1219 dnl Allow specification of the multiarch arch
1220 dnl
1221 AC_ARG_WITH([multiarch],
1222 [  --with-multiarch=ARCH specify the multiarch triplet],
1223 if test "$withval" = "lib64"; then
1224     libdir=/usr/lib64
1225     root_libdir=/lib64
1226 else
1227     libdir=$libdir/$withval
1228     root_libdir=$root_libdir/$withval
1229 fi
1230 )dnl
1231 dnl
1232 dnl See if -static works.  This could fail if the linker does not
1233 dnl support -static, or if required external libraries are not available
1234 dnl in static form.
1235 dnl
1236 AC_MSG_CHECKING([whether we can link with -static])
1237 AC_CACHE_VAL(ac_cv_e2fsprogs_use_static,
1238 [SAVE_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -static"
1239 AC_TRY_LINK([#include <stdio.h>],[fflush(stdout);],
1240  ac_cv_e2fsprogs_use_static=yes, ac_cv_e2fsprogs_use_static=no)
1241 LDFLAGS=$SAVE_LDFLAGS])
1242 dnl
1243 dnl Regardless of how the test turns out, Solaris doesn't handle -static
1244 dnl This is caused by the socket library requiring the nsl library, which
1245 dnl requires the -dl library, which only works for dynamically linked
1246 dnl programs.  It basically means you can't have statically linked programs
1247 dnl which use the network under Solaris.
1248 dnl
1249 case "$host_os" in
1250 solaris2.*)
1251         ac_cv_e2fsprogs_use_static=no
1252 ;;
1253 esac
1254 AC_MSG_RESULT($ac_cv_e2fsprogs_use_static)
1255 LDFLAG_STATIC=
1256 if test $ac_cv_e2fsprogs_use_static = yes; then
1257         LDFLAG_STATIC=-static
1258 fi
1259 AC_SUBST(LDFLAG_STATIC)
1260 dnl
1261 dnl Work around mysterious Darwin / GNU libintl problem
1262 dnl (__asm__ redirection doesn't work for some mysterious reason.  Looks like
1263 dnl Apple hacked gcc somehow?)
1264 dnl
1265 case "$host_os" in
1266 darwin*)
1267         AC_MSG_RESULT([Using Apple Darwin / GNU libintl workaround])
1268         AC_DEFINE(_INTL_REDIRECT_MACROS, 1,
1269                 [Define to 1 if Apple Darwin libintl workaround is needed])
1270         ;;
1271 esac
1272 dnl
1273 dnl Make the ss and et directories work correctly.
1274 dnl
1275 SS_DIR=`cd ${srcdir}/lib/ss; pwd`
1276 ET_DIR=`cd ${srcdir}/lib/et; pwd`
1277 AC_SUBST(SS_DIR)
1278 AC_SUBST(ET_DIR)
1279 dnl
1280 dnl Only try to run the test suite if we're not cross compiling.
1281 dnl
1282 if test "$cross_compiling" = yes ; then
1283   DO_TEST_SUITE=
1284 else
1285   DO_TEST_SUITE=check
1286 fi
1287 AC_SUBST(DO_TEST_SUITE)
1288 dnl
1289 dnl Only include the intl include files if we're building with them
1290 dnl
1291 INCLUDES='-I. -I$(top_builddir)/lib -I$(top_srcdir)/lib'
1292 if test -n "$CPPFLAGS" ; then
1293         INCLUDES="$INCLUDES $CPPFLAGS"
1294 fi
1295 if test "$USE_INCLUDED_LIBINTL" = "yes" ; then
1296         INCLUDES=$INCLUDES' -I$(top_builddir)/intl -I$(top_srcdir)/intl'
1297 fi
1298 if test -n "$WITH_DIET_LIBC" ; then
1299         INCLUDES="$INCLUDES -D_REENTRANT"
1300 fi
1301 AC_SUBST(INCLUDES)
1302 AM_MKINSTALLDIRS
1303 dnl
1304 dnl Build CFLAGS
1305 dnl
1306 if test $cross_compiling = no; then
1307    BUILD_CFLAGS="$CFLAGS $CPPFLAGS $INCLUDES -DHAVE_CONFIG_H"
1308    BUILD_LDFLAGS="$LDFLAGS"
1309 else
1310    BUILD_CFLAGS=
1311    BUILD_LDFLAGS=
1312 fi
1313 AC_SUBST(BUILD_CFLAGS)
1314 AC_SUBST(BUILD_LDFLAGS)
1315 dnl
1316 dnl Make our output files, being sure that we create the some miscellaneous
1317 dnl directories
1318 dnl
1319 test -d lib || mkdir lib
1320 test -d include || mkdir include
1321 test -d include/linux || mkdir include/linux
1322 test -d include/asm || mkdir include/asm
1323 for i in MCONFIG Makefile e2fsprogs.spec \
1324         util/Makefile util/subst.conf util/gen-tarball util/install-symlink \
1325         lib/et/Makefile lib/ss/Makefile lib/e2p/Makefile \
1326         lib/ext2fs/Makefile lib/ext2fs/ext2_types.h \
1327         lib/uuid/Makefile lib/uuid/uuid_types.h \
1328         lib/blkid/Makefile lib/blkid/blkid_types.h lib/quota/Makefile \
1329         lib/ss/ss.pc lib/uuid/uuid.pc lib/et/com_err.pc \
1330         lib/e2p/e2p.pc lib/blkid/blkid.pc lib/ext2fs/ext2fs.pc \
1331         misc/Makefile ext2ed/Makefile e2fsck/Makefile \
1332         debugfs/Makefile tests/Makefile tests/progs/Makefile \
1333         resize/Makefile doc/Makefile intl/Makefile \
1334         intl/libgnuintl.h po/Makefile.in ; do
1335         if test -d `dirname ${srcdir}/$i` ; then
1336                 outlist="$outlist $i"
1337         fi
1338 done
1339 AC_OUTPUT($outlist)
1340 if test -f util/gen-tarball; then chmod +x util/gen-tarball; fi