configure.in

   1 AC_INIT(version.h)
   2 AC_PREREQ(2.54)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_HEADERS([lib/config.h])
   5 AH_BOTTOM([#include "dirpaths.h"])
   6 MCONFIG=./MCONFIG
   7 AC_SUBST_FILE(MCONFIG)
   8 BINARY_TYPE=bin
   9 dnl
  10 dnl This is to figure out the version number and the date....
  11 dnl
  12 E2FSPROGS_VERSION=`grep E2FSPROGS_VERSION ${srcdir}/version.h  \
  13         | awk '{print $3}' | tr \" " " | awk '{print $1}'`
  14 DATE=`grep E2FSPROGS_DATE ${srcdir}/version.h | awk '{print $3}' \
  15         | tr \" " "`
  16 E2FSPROGS_DAY=`echo $DATE | awk -F- '{print $1}'`
  17 MONTH=`echo $DATE | awk -F- '{print $2}'`
  18 YEAR=`echo $DATE | awk -F- '{print $3}'`
  19
  20 if expr $YEAR ">" 1900 > /dev/null ; then
  21         E2FSPROGS_YEAR=$YEAR
  22 elif expr $YEAR ">" 90 >/dev/null ; then
  23         E2FSPROGS_YEAR=19$YEAR
  24 else
  25         E2FSPROGS_YEAR=20$YEAR
  26 fi
  27
  28 case $MONTH in
  29 Jan)    MONTH_NUM=01; E2FSPROGS_MONTH="January" ;;
  30 Feb)    MONTH_NUM=02; E2FSPROGS_MONTH="February" ;;
  31 Mar)    MONTH_NUM=03; E2FSPROGS_MONTH="March" ;;
  32 Apr)    MONTH_NUM=04; E2FSPROGS_MONTH="April" ;;
  33 May)    MONTH_NUM=05; E2FSPROGS_MONTH="May" ;;
  34 Jun)    MONTH_NUM=06; E2FSPROGS_MONTH="June" ;;
  35 Jul)    MONTH_NUM=07; E2FSPROGS_MONTH="July" ;;
  36 Aug)    MONTH_NUM=08; E2FSPROGS_MONTH="August" ;;
  37 Sep)    MONTH_NUM=09; E2FSPROGS_MONTH="September" ;;
  38 Oct)    MONTH_NUM=10; E2FSPROGS_MONTH="October" ;;
  39 Nov)    MONTH_NUM=11; E2FSPROGS_MONTH="November" ;;
  40 Dec)    MONTH_NUM=12; E2FSPROGS_MONTH="December" ;;
  41 *)      AC_MSG_WARN([Unknown month $MONTH??]) ;;
  42 esac
  43
  44 base_ver=`echo $E2FSPROGS_VERSION | \
  45                sed -e 's/-WIP//' -e 's/pre-//' -e 's/-PLUS//'`
  46
  47 date_spec=${E2FSPROGS_YEAR}.${MONTH_NUM}.${E2FSPROGS_DAY}
  48
  49 case $E2FSPROGS_VERSION in
  50 *-WIP|pre-*)
  51         E2FSPROGS_PKGVER="$base_ver~WIP-$E2FSPROGS_YEAR-$MONTH_NUM-$E2FSPROGS_DAY"
  52         ;;
  53 *)
  54         E2FSPROGS_PKGVER="$base_ver"
  55         ;;
  56 esac
  57
  58 unset DATE MONTH YEAR base_ver pre_vers date_spec
  59 AC_MSG_RESULT([Generating configuration file for e2fsprogs version $E2FSPROGS_VERSION])
  60 AC_MSG_RESULT([Release date is ${E2FSPROGS_MONTH}, ${E2FSPROGS_YEAR}])
  61 AC_SUBST(E2FSPROGS_YEAR)
  62 AC_SUBST(E2FSPROGS_MONTH)
  63 AC_SUBST(E2FSPROGS_DAY)
  64 AC_SUBST(E2FSPROGS_VERSION)
  65 AC_SUBST(E2FSPROGS_PKGVER)
  66 AC_CANONICAL_HOST
  67 dnl
  68 dnl Check to see if libdl exists for the sake of dlopen
  69 dnl
  70 DLOPEN_LIB=''
  71 AC_CHECK_LIB(dl, dlopen,
  72 [DLOPEN_LIB=-ldl
  73 AC_DEFINE(HAVE_DLOPEN, 1, [Define to 1 if dlopen/libdl exists])])
  74 AC_SUBST(DLOPEN_LIB)
  75 dnl
  76 dnl Use diet libc
  77 dnl
  78 WITH_DIET_LIBC=
  79 AC_ARG_WITH([diet-libc],
  80 [  --with-diet-libc        use diet libc],
  81 CC="diet cc -nostdinc"
  82 WITH_DIET_LIBC=yes
  83 AC_MSG_RESULT(CC=$CC))dnl
  84 dnl
  85 AC_ARG_WITH([cc],
  86 AC_HELP_STRING([--with-cc],[no longer supported, use CC= instead]),
  87 AC_MSG_ERROR([--with-cc no longer supported; use CC= instead]))
  88 dnl
  89 AC_ARG_WITH([ccopts],
  90 AC_HELP_STRING([--with-ccopts],[no longer supported, use CFLAGS= instead]),
  91 AC_MSG_ERROR([--with-ccopts no longer supported; use CFLAGS= instead]))
  92 dnl
  93 AC_ARG_WITH([ldopts],
  94 AC_HELP_STRING([--with-ldopts],[no longer supported, use LDFLAGS= instead]),
  95 AC_MSG_ERROR([--with-ldopts no longer supported; use LDFLAGS= instead]))
  96 dnl
  97 AC_PROG_CC
  98 if test "$GCC" = yes; then
  99    RDYNAMIC="-rdynamic"
 100    AC_SUBST(RDYNAMIC)
 101 fi
 102 AC_PROG_CPP
 103 dnl
 104 dnl Alpha computers use fast and imprecise floating point code that may
 105 dnl miss exceptions by default. Force sane options if we're using GCC.
 106 AC_MSG_CHECKING(for additional special compiler flags)
 107 if test "$GCC" = yes
 108 then
 109     case "$host_cpu" in
 110         alpha)          addcflags="-mieee" ;;
 111     esac
 112 fi
 113 if test "x$addcflags" != x
 114 then
 115     AC_MSG_RESULT($addcflags)
 116     CFLAGS="$addcflags $CFLAGS"
 117 else
 118     AC_MSG_RESULT([[(none)]])
 119 fi
 120 dnl
 121 dnl Set default values for library extentions.  Will be dealt with after
 122 dnl parsing configuration opions, which may modify these
 123 dnl
 124 LIB_EXT=.a
 125 STATIC_LIB_EXT=.a
 126 PROFILED_LIB_EXT=.a
 127 dnl
 128 dnl Allow separate `root_prefix' to be specified
 129 dnl
 130 AC_ARG_WITH([root-prefix],
 131 [  --with-root-prefix=PREFIX override prefix variable for files to be placed in the root],
 132 root_prefix=$withval,
 133 root_prefix=NONE)dnl
 134 dnl
 135 dnl handle --enable-maintainer-mode
 136 dnl
 137 AC_ARG_ENABLE([maintainer-mode],
 138 [  --enable-maintainer-mode enable makefile rules useful for maintainers],
 139 if test "$enableval" = "no"
 140 then
 141         MAINTAINER_CMT=#
 142         AC_MSG_RESULT([Disabling maintainer mode])
 143 else
 144         MAINTAINER_CMT=
 145         AC_MSG_RESULT([Enabling maintainer mode])
 146 fi
 147 ,
 148 MAINTAINER_CMT=#
 149 AC_MSG_RESULT([Disabling maintainer mode by default])
 150 )
 151 AC_SUBST(MAINTAINER_CMT)
 152 dnl
 153 dnl handle --enable-symlink-install
 154 dnl
 155 AC_ARG_ENABLE([symlink-install],
 156 [  --enable-symlink-install use symlinks when installing instead of hard links],
 157 if test "$enableval" = "no"
 158 then
 159         LINK_INSTALL_FLAGS=-f
 160         AC_MSG_RESULT([Disabling symlinks for install])
 161 else
 162         LINK_INSTALL_FLAGS=-sf
 163         AC_MSG_RESULT([Enabling symlinks for install])
 164 fi
 165 ,
 166 LINK_INSTALL_FLAGS=-f
 167 AC_MSG_RESULT([Disabling symlinks for install by default])
 168 )
 169 AC_SUBST(LINK_INSTALL_FLAGS)
 170 dnl
 171 dnl handle --enable-relative-symlinks
 172 dnl
 173 relative_symlink_defined=
 174 AC_ARG_ENABLE([relative-symlinks],
 175 [  --enable-relative-symlinks use relative symlinks when installing],
 176 if test "$enableval" = "no"
 177 then
 178         SYMLINK_RELATIVE=
 179         relative_symlink_defined=yes
 180         AC_MSG_RESULT([Disabling relative symlinks for install])
 181 else
 182         SYMLINK_RELATIVE=--relative
 183         relative_symlink_defined=yes
 184         AC_MSG_RESULT([Enabling relative symlinks for install])
 185 fi)
 186 AC_ARG_ENABLE([symlink-relative-symlinks],,
 187 if test "$enableval" = "no"
 188 then
 189         SYMLINK_RELATIVE=yes
 190         AC_MSG_RESULT([Disabling relative symlinks for install])
 191 else
 192         SYMLINK_RELATIVE=--relative
 193         AC_MSG_RESULT([Enabling relative symlinks for install])
 194 fi
 195 ,
 196 if test -z "$relative_symlink_defined"
 197 then
 198         SYMLINK_RELATIVE=
 199 AC_MSG_RESULT([Disabling relative symlinks for install by default])
 200 fi
 201 )
 202 AC_SUBST(SYMLINK_RELATIVE)
 203 dnl
 204 dnl handle --enable-symlink-build
 205 dnl
 206 AC_ARG_ENABLE([symlink-build],
 207 [  --enable-symlink-build  use symlinks while building instead of hard links],
 208 if test "$enableval" = "no"
 209 then
 210         LINK_BUILD_FLAGS=
 211         AC_MSG_RESULT([Disabling symlinks for build])
 212 else
 213         LINK_BUILD_FLAGS=-s
 214         AC_MSG_RESULT([Enabling symlinks for build])
 215 fi
 216 ,
 217 LINK_BUILD_FLAGS=
 218 AC_MSG_RESULT([Disabling symlinks for build by default])
 219 )
 220 AC_SUBST(LINK_BUILD_FLAGS)
 221 dnl
 222 dnl handle --enable-verbose-makecmds
 223 dnl
 224 AC_ARG_ENABLE([verbose-makecmds],
 225 [  --enable-verbose-makecmds enable verbose make command output],
 226 if test "$enableval" = "no"
 227 then
 228         AC_MSG_RESULT([Disabling verbose make commands])
 229         E=@echo
 230         ES=echo
 231         Q=@
 232 else
 233         AC_MSG_RESULT([Enabling verbose make commands])
 234         E=@\\#
 235         ES=\\#
 236         Q=
 237 fi
 238 ,
 239 AC_MSG_RESULT([Disabling verbose make commands])
 240 E=@echo
 241 ES=echo
 242 Q=@
 243 )
 244 AC_SUBST(E)
 245 AC_SUBST(ES)
 246 AC_SUBST(Q)
 247 dnl
 248 dnl handle --enable-compression
 249 dnl
 250 AC_ARG_ENABLE([compression],
 251 [  --enable-compression   enable EXPERIMENTAL compression support],
 252 if test "$enableval" = "no"
 253 then
 254         AC_MSG_RESULT([Disabling compression support])
 255 else
 256         AC_DEFINE(ENABLE_COMPRESSION, 1,
 257                 [Define to 1 if ext2 compression enabled])
 258         AC_MSG_RESULT([Enabling compression support])
 259         AC_MSG_WARN([Compression support is experimental])
 260 fi
 261 ,
 262 AC_MSG_RESULT([Disabling compression support by default])
 263 )
 264 dnl
 265 dnl handle --enable-htree
 266 dnl
 267 AH_TEMPLATE([ENABLE_HTREE], [Define to 1 if ext3/4 htree support enabled])
 268 AC_ARG_ENABLE([htree],
 269 [  --enable-htree         enable EXPERIMENTAL htree directory support],
 270 if test "$enableval" = "no"
 271 then
 272         HTREE_CMT=#
 273         AC_MSG_RESULT([Disabling htree directory support])
 274 else
 275         HTREE_CMT=
 276         AC_DEFINE(ENABLE_HTREE, 1)
 277         AC_MSG_RESULT([Enabling htree directory support])
 278 fi
 279 ,
 280 HTREE_CMT=
 281 AC_DEFINE(ENABLE_HTREE, 1)
 282 AC_MSG_RESULT([Enabling htree directory support by default])
 283 )
 284 AC_SUBST(HTREE_CMT)
 285 dnl
 286 dnl This needs to be before all of the --enable-*-shlibs options
 287 dnl
 288 E2_PKG_CONFIG_STATIC=--static
 289 LDFLAG_DYNAMIC=
 290 PRIVATE_LIBS_CMT=
 291 dnl
 292 dnl handle --enable-elf-shlibs
 293 dnl
 294 AC_ARG_ENABLE([elf-shlibs],
 295 [  --enable-elf-shlibs    select ELF shared libraries],
 296 if test "$enableval" = "no"
 297 then
 298         ELF_CMT=#
 299         MAKEFILE_ELF=/dev/null
 300         AC_MSG_RESULT([Disabling ELF shared libraries])
 301 else
 302         E2_PKG_CONFIG_STATIC=
 303         ELF_CMT=
 304         MAKEFILE_ELF=$srcdir/lib/Makefile.elf-lib
 305         [case "$host_os" in
 306         solaris2.*)
 307                 MAKEFILE_ELF=$srcdir/lib/Makefile.solaris-lib
 308         ;;
 309         esac]
 310         BINARY_TYPE=elfbin
 311         LIB_EXT=.so
 312         PRIVATE_LIBS_CMT=#
 313         LDFLAG_DYNAMIC=['-Wl,-rpath-link,$(top_builddir)/lib']
 314         AC_MSG_RESULT([Enabling ELF shared libraries])
 315 fi
 316 ,
 317 MAKEFILE_ELF=/dev/null
 318 ELF_CMT=#
 319 AC_MSG_RESULT([Disabling ELF shared libraries by default])
 320 )
 321 AC_SUBST(ELF_CMT)
 322 AC_SUBST_FILE(MAKEFILE_ELF)
 323 dnl
 324 dnl handle --enable-bsd-shlibs
 325 dnl
 326 AC_ARG_ENABLE([bsd-shlibs],
 327 [  --enable-bsd-shlibs    select BSD shared libraries],
 328 if test "$enableval" = "no"
 329 then
 330         BSDLIB_CMT=#
 331         MAKEFILE_BSDLIB=/dev/null
 332         AC_MSG_RESULT([Disabling BSD shared libraries])
 333 else
 334         E2_PKG_CONFIG_STATIC=
 335         BSDLIB_CMT=
 336         MAKEFILE_BSDLIB=$srcdir/lib/Makefile.bsd-lib
 337         LIB_EXT=.so
 338         [case "$host_os" in
 339         darwin*)
 340                 MAKEFILE_BSDLIB=$srcdir/lib/Makefile.darwin-lib
 341                 LIB_EXT=.dylib
 342         ;;
 343         esac]
 344         AC_MSG_RESULT([Enabling BSD shared libraries])
 345 fi
 346 ,
 347 MAKEFILE_BSDLIB=/dev/null
 348 BSDLIB_CMT=#
 349 AC_MSG_RESULT([Disabling BSD shared libraries by default])
 350 )
 351 AC_SUBST(BSDLIB_CMT)
 352 AC_SUBST_FILE(MAKEFILE_BSDLIB)
 353 dnl
 354 dnl handle --enable-profile
 355 dnl
 356 AC_ARG_ENABLE([profile],
 357 [  --enable-profile       build profiling libraries],
 358 if test "$enableval" = "no"
 359 then
 360         PROFILE_CMT=#
 361         MAKEFILE_PROFILE=/dev/null
 362         AC_MSG_RESULT([Disabling profiling libraries])
 363 else
 364         PROFILE_CMT=
 365         MAKEFILE_PROFILE=$srcdir/lib/Makefile.profile
 366         PROFILED_LIB_EXT=_p.a
 367         AC_MSG_RESULT([Building profiling libraries])
 368 fi
 369 ,
 370 PROFILE_CMT=#
 371 MAKEFILE_PROFILE=/dev/null
 372 AC_MSG_RESULT([Disabling profiling libraries by default])
 373 )
 374 AC_SUBST(PROFILE_CMT)
 375 AC_SUBST_FILE(MAKEFILE_PROFILE)
 376 dnl
 377 dnl handle --enable-checker
 378 dnl
 379 AC_ARG_ENABLE([checker],
 380 [  --enable-checker       build checker libraries],
 381 if test "$enableval" = "no"
 382 then
 383         CHECKER_CMT=#
 384         MAKEFILE_CHECKER=/dev/null
 385         AC_MSG_RESULT([Disabling checker libraries])
 386 else
 387         CHECKER_CMT=
 388         MAKEFILE_CHECKER=$srcdir/lib/Makefile.checker
 389         AC_MSG_RESULT([Building checker libraries])
 390 fi
 391 ,
 392 CHECKER_CMT=#
 393 MAKEFILE_CHECKER=/dev/null
 394 AC_MSG_RESULT([Disabling checker libraries by default])
 395 )
 396 AC_SUBST(CHECKER_CMT)
 397 AC_SUBST_FILE(MAKEFILE_CHECKER)
 398 dnl
 399 dnl Substitute library extensions
 400 dnl
 401 AC_SUBST(LIB_EXT)
 402 AC_SUBST(STATIC_LIB_EXT)
 403 AC_SUBST(PROFILED_LIB_EXT)
 404 AC_SUBST(LDFLAG_DYNAMIC)
 405 AC_SUBST(PRIVATE_LIBS_CMT)
 406 dnl
 407 dnl handle --enable-jbd-debug
 408 dnl
 409 AC_ARG_ENABLE([jbd-debug],
 410 [  --enable-jbd-debug     enable journal debugging],
 411 if test "$enableval" = "no"
 412 then
 413         AC_MSG_RESULT([Disabling journal debugging])
 414 else
 415         AC_DEFINE(CONFIG_JBD_DEBUG, 1,
 416                 [Define to 1 if debugging ext3/4 journal code])
 417         AC_MSG_RESULT([Enabling journal debugging])
 418 fi
 419 ,
 420 AC_MSG_RESULT([Disabling journal debugging by default])
 421 )
 422 dnl
 423 dnl handle --enable-blkid-debug
 424 dnl
 425 AC_ARG_ENABLE([blkid-debug],
 426 [  --enable-blkid-debug    enable blkid debugging],
 427 if test "$enableval" = "no"
 428 then
 429         AC_MSG_RESULT([Disabling blkid debugging])
 430 else
 431         AC_DEFINE(CONFIG_BLKID_DEBUG, 1,
 432                 [Define to 1 if debugging the blkid library])
 433         AC_MSG_RESULT([Enabling blkid debugging])
 434 fi
 435 ,
 436 AC_MSG_RESULT([Disabling blkid debugging by default])
 437 )
 438 dnl
 439 dnl handle --enable-testio-debug
 440 dnl
 441 AC_ARG_ENABLE([testio-debug],
 442 [  --disable-testio-debug  disable the use of the test I/O manager for debugging],
 443 AH_TEMPLATE([CONFIG_TESTIO_DEBUG],
 444         [Define to 1 if the testio I/O manager should be enabled])
 445 if test "$enableval" = "no"
 446 then
 447         AC_MSG_RESULT([Disabling testio debugging])
 448         TEST_IO_CMT="#"
 449 else
 450         TEST_IO_CMT=
 451         AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 452         AC_MSG_RESULT([Enabling testio debugging])
 453 fi
 454 ,
 455 AC_MSG_RESULT([Enabling testio debugging by default])
 456 AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 457 TEST_IO_CMT=
 458 )
 459 AC_SUBST(TEST_IO_CMT)
 460 dnl
 461 dnl handle --disable-libuuid
 462 dnl
 463 PKG_PROG_PKG_CONFIG
 464 LIBUUID=
 465 DEPLIBUUID=
 466 STATIC_LIBUUID=
 467 DEPSTATIC_LIBUUID=
 468 PROFILED_LIBUUID=
 469 DEPPROFILED_LIBUUID=
 470 UUID_CMT=
 471 AC_ARG_ENABLE([libuuid],
 472 [  --disable-libuuid      do not build private uuid library],
 473 if test "$enableval" = "no"
 474 then
 475         if test -z "$PKG_CONFIG"; then
 476                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 477         fi
 478
 479         AC_CHECK_LIB(uuid, uuid_generate,
 480                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 481                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`],
 482                 [AC_MSG_ERROR([external uuid library not found])],
 483                 [$LIBUUID])
 484         UUID_CMT=#
 485         AC_MSG_RESULT([Disabling private uuid library])
 486 else
 487         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 488         DEPLIBUUID=$LIBUUID
 489         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 490         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 491         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 492         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 493         AC_MSG_RESULT([Enabling private uuid library])
 494 fi
 495 ,
 496 LIBUUID='$(LIB)/libuuid'$LIB_EXT
 497 DEPLIBUUID=$LIBUUID
 498 STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 499 DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 500 PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 501 DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 502 AC_MSG_RESULT([Enabling private uuid library by default])
 503 )
 504 AC_SUBST(LIBUUID)
 505 AC_SUBST(DEPLIBUUID)
 506 AC_SUBST(STATIC_LIBUUID)
 507 AC_SUBST(DEPSTATIC_LIBUUID)
 508 AC_SUBST(PROFILED_LIBUUID)
 509 AC_SUBST(DEPPROFILED_LIBUUID)
 510 AC_SUBST(UUID_CMT)
 511 dnl
 512 dnl handle --disable-libblkid
 513 dnl
 514 PKG_PROG_PKG_CONFIG
 515 LIBBLKID=
 516 DEPLIBBLKID=
 517 STATIC_LIBBLKID=
 518 DEPSTATIC_LIBBLKID=
 519 PROFILED_LIBBLKID=
 520 DEPPROFILED_LIBBLKID=
 521 BLKID_CMT=
 522 AH_TEMPLATE([CONFIG_BUILD_FINDFS], [Define to 1 to compile findfs])
 523 AC_ARG_ENABLE([libblkid],
 524 [  --disable-libblkid     do not build private blkid library],
 525 if test "$enableval" = "no"
 526 then
 527         if test -z "$PKG_CONFIG"; then
 528                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 529         fi
 530
 531         AC_CHECK_LIB(blkid, blkid_get_cache,
 532                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 533                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`],
 534                 [AC_MSG_ERROR([external blkid library not found])],
 535                 [$LIBBLKID])
 536         BLKID_CMT=#
 537         AC_MSG_RESULT([Disabling private blkid library])
 538 else
 539         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 540         DEPLIBBLKID=$LIBBLKID
 541         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 542         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 543         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 544         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 545         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 546         AC_MSG_RESULT([Enabling private blkid library])
 547 fi
 548 ,
 549 LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 550 DEPLIBBLKID=$LIBBLKID
 551 STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 552 DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 553 PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 554 DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 555 AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 556 AC_MSG_RESULT([Enabling private blkid library by default])
 557 )
 558 AC_SUBST(LIBBLKID)
 559 AC_SUBST(DEPLIBBLKID)
 560 AC_SUBST(STATIC_LIBBLKID)
 561 AC_SUBST(DEPSTATIC_LIBBLKID)
 562 AC_SUBST(PROFILED_LIBBLKID)
 563 AC_SUBST(DEPPROFILED_LIBBLKID)
 564 AC_SUBST(BLKID_CMT)
 565 dnl
 566 dnl handle --enable-quota
 567 dnl
 568 QUOTA_MAN_COMMENT='.\"'
 569 QUOTA_CMT=
 570 AC_SUBST(QUOTA_MAN_COMMENT)
 571 PKG_PROG_PKG_CONFIG
 572 AH_TEMPLATE([CONFIG_QUOTA], [Define to 1 to enable quota support])
 573 AC_ARG_ENABLE([quota],
 574 [  --enable-quota         enable quota support],
 575 if test "$enableval" = "no"
 576 then
 577         QUOTA_CMT=#
 578         AC_MSG_RESULT([Disabling quota support])
 579 else
 580         QUOTA_CMT=
 581         AC_DEFINE(CONFIG_QUOTA, 1)
 582         AC_MSG_RESULT([Enabling quota support])
 583         QUOTA_MAN_COMMENT=""
 584         AC_SUBST(QUOTA_MAN_COMMENT)
 585 fi
 586 ,
 587 QUOTA_CMT=#
 588 AC_MSG_RESULT([Disabling quota support by default])
 589 )
 590 dnl
 591 dnl Define stuff expected for quota library
 592 dnl
 593 LIBQUOTA='$(LIB)/libquota'$LIB_EXT
 594 DEPLIBQUOTA=$LIBQUOTA
 595 STATIC_LIBQUOTA='$(LIB)/libquota'$STATIC_LIB_EXT
 596 DEPSTATIC_LIBQUOTA=$STATIC_LIBQUOTA
 597 PROFILED_LIBQUOTA='$(LIB)/libquota'$PROFILED_LIB_EXT
 598 DEPPROFILED_LIBQUOTA=$PROFILED_LIBQUOTA
 599 AC_SUBST(LIBQUOTA)
 600 AC_SUBST(DEPLIBQUOTA)
 601 AC_SUBST(STATIC_LIBQUOTA)
 602 AC_SUBST(DEPSTATIC_LIBQUOTA)
 603 AC_SUBST(PROFILED_LIBQUOTA)
 604 AC_SUBST(DEPPROFILED_LIBQUOTA)
 605 AC_SUBST(QUOTA_CMT)
 606 dnl
 607 dnl handle --disable-backtrace
 608 dnl
 609 AH_TEMPLATE([DISABLE_BACKTRACE], [Define to 1 to disable use of backtrace])
 610 AC_ARG_ENABLE([backtrace],
 611 [  --disable-backtrace    disable use backtrace],
 612 if test "$enableval" = "no"
 613 then
 614         AC_MSG_RESULT([Disabling use of backtrace])
 615         AC_DEFINE(DISABLE_BACKTRACE, 1)
 616 else
 617         AC_MSG_RESULT([Enabling use of backtrace])
 618 fi
 619 ,
 620 AC_MSG_RESULT([Enabling use of backtrace by default])
 621 )
 622 dnl
 623 dnl handle --enable-debugfs
 624 dnl
 625 AC_ARG_ENABLE([debugfs],
 626 [  --disable-debugfs      disable support of debugfs program],
 627 if test "$enableval" = "no"
 628 then
 629         AC_MSG_RESULT([Disabling debugfs support])
 630         DEBUGFS_CMT="#"
 631 else
 632         DEBUGFS_CMT=
 633         AC_MSG_RESULT([Enabling debugfs support])
 634 fi
 635 ,
 636 AC_MSG_RESULT([Enabling debugfs support by default])
 637 DEBUGFS_CMT=
 638 )
 639 AC_SUBST(DEBUGFS_CMT)
 640 dnl
 641 dnl handle --enable-imager
 642 dnl
 643 AC_ARG_ENABLE([imager],
 644 [  --disable-imager       disable support of e2image program],
 645 if test "$enableval" = "no"
 646 then
 647         AC_MSG_RESULT([Disabling e2image support])
 648         IMAGER_CMT="#"
 649 else
 650         IMAGER_CMT=
 651         AC_MSG_RESULT([Enabling e2image support])
 652 fi
 653 ,
 654 AC_MSG_RESULT([Enabling e2image support by default])
 655 IMAGER_CMT=
 656 )
 657 AC_SUBST(IMAGER_CMT)
 658 dnl
 659 dnl handle --enable-resizer
 660 dnl
 661 AC_ARG_ENABLE([resizer],
 662 [  --disable-resizer      disable support of e2resize program],
 663 if test "$enableval" = "no"
 664 then
 665         AC_MSG_RESULT([Disabling e2resize support])
 666         RESIZER_CMT="#"
 667 else
 668         RESIZER_CMT=
 669         AC_MSG_RESULT([Enabling e2resize support])
 670 fi
 671 ,
 672 AC_MSG_RESULT([Enabling e2resize support by default])
 673 RESIZER_CMT=
 674 )
 675 AC_SUBST(RESIZER_CMT)
 676 dnl
 677 dnl handle --enable-defrag
 678 dnl
 679 AC_ARG_ENABLE([defrag],
 680 [  --disable-defrag       disable support of e4defrag program],
 681 if test "$enableval" = "no"
 682 then
 683         AC_MSG_RESULT([Disabling e4defrag support])
 684         DEFRAG_CMT="#"
 685 else
 686         DEFRAG_CMT=
 687         AC_MSG_RESULT([Enabling e4defrag support])
 688 fi
 689 ,
 690 AC_MSG_RESULT([Enabling e4defrag support by default])
 691 DEFRAG_CMT=
 692 )
 693 AC_SUBST(DEFRAG_CMT)
 694 dnl
 695 dnl See whether to install the `fsck' wrapper program (that calls e2fsck)
 696 dnl
 697 AC_ARG_ENABLE([fsck],
 698 [  --enable-fsck           build fsck wrapper program],
 699 [if test "$enableval" = "no"
 700 then
 701         FSCK_PROG='' FSCK_MAN=''
 702         AC_MSG_RESULT([Not building fsck wrapper])
 703 else
 704         FSCK_PROG=fsck FSCK_MAN=fsck.8
 705         AC_MSG_RESULT([Building fsck wrapper])
 706 fi]
 707 ,
 708 [case "$host_os" in
 709   gnu*)
 710     FSCK_PROG='' FSCK_MAN=''
 711     AC_MSG_RESULT([Not building fsck wrapper by default])
 712     ;;
 713   *)
 714     FSCK_PROG=fsck FSCK_MAN=fsck.8
 715     AC_MSG_RESULT([Building fsck wrapper by default])
 716 esac]
 717 )
 718 AC_SUBST(FSCK_PROG)
 719 AC_SUBST(FSCK_MAN)
 720 dnl
 721 dnl See whether to install the `e2initrd-helper' program
 722 dnl
 723 AC_ARG_ENABLE([e2initrd-helper],
 724 [  --enable-e2initrd-helper build e2initrd-helper program],
 725 [if test "$enableval" = "no"
 726 then
 727         E2INITRD_PROG='' E2INITRD_MAN=''
 728         AC_MSG_RESULT([Not building e2initrd helper])
 729 else
 730         E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 731         AC_MSG_RESULT([Building e2initrd helper])
 732 fi]
 733 ,
 734 E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 735 AC_MSG_RESULT([Building e2initrd helper by default])
 736 )
 737 AC_SUBST(E2INITRD_PROG)
 738 AC_SUBST(E2INITRD_MAN)
 739 dnl
 740 dnl
 741 dnl
 742 AC_ARG_ENABLE([tls],
 743 [  --disable-tls           disable use of thread local support],
 744 [if test "$enableval" = "no"
 745 then
 746         try_tls=""
 747         AC_MSG_RESULT([Disabling thread local support])
 748 else
 749         try_tls="yes"
 750         AC_MSG_RESULT([Enabling thread local support])
 751 fi]
 752 ,
 753 if test -n "$WITH_DIET_LIBC"
 754 then
 755         try_tls=""
 756         AC_MSG_RESULT([Diet libc does not support thread local support])
 757 else
 758         try_tls="yes"
 759         AC_MSG_RESULT([Try using thread local support by default])
 760 fi
 761 )
 762 if test "$try_tls" = "yes"
 763 then
 764 AX_TLS
 765 fi
 766 dnl
 767 dnl
 768 dnl
 769 AH_TEMPLATE([USE_UUIDD], [Define to 1 to build uuidd])
 770 AC_ARG_ENABLE([uuidd],
 771 [  --disable-uuidd         disable building the uuid daemon],
 772 [if test "$enableval" = "no"
 773 then
 774         AC_MSG_RESULT([Not building uuidd])
 775         UUIDD_CMT="#"
 776 else
 777         AC_DEFINE(USE_UUIDD, 1)
 778         UUIDD_CMT=""
 779         AC_MSG_RESULT([Building uuidd])
 780 fi]
 781 ,
 782 AC_DEFINE(USE_UUIDD, 1)
 783 UUIDD_CMT=""
 784 AC_MSG_RESULT([Building uuidd by default])
 785 )
 786 AC_SUBST(UUIDD_CMT)
 787 dnl
 788 dnl handle --disable-mmp
 789 dnl
 790 AH_TEMPLATE([CONFIG_MMP], [Define to 1 to enable mmp support])
 791 AC_ARG_ENABLE([mmp],
 792 [  --disable-mmp           disable support mmp, Multi Mount Protection],
 793 if test "$enableval" = "no"
 794 then
 795         AC_MSG_RESULT([Disabling mmp support])
 796 else
 797         AC_MSG_RESULT([Enabling mmp support])
 798         AC_DEFINE(CONFIG_MMP, 1)
 799 fi
 800 ,
 801 AC_MSG_RESULT([Enabling mmp support by default])
 802 AC_DEFINE(CONFIG_MMP, 1)
 803 )
 804 dnl
 805 dnl handle --disable-bmap-stats
 806 dnl
 807 AH_TEMPLATE([ENABLE_BMAP_STATS], [Define to 1 to enable bitmap stats.])
 808 AC_ARG_ENABLE([bmap-stats],
 809 [  --disable-bmap-stats    disable collection of bitmap stats.],
 810 if test "$enableval" = "no"
 811 then
 812         AC_MSG_RESULT([Disabling bitmap statistics support])
 813 else
 814         AC_MSG_RESULT([Enabling bitmap statistics support])
 815         AC_DEFINE(ENABLE_BMAP_STATS, 1)
 816 fi
 817 ,
 818 AC_MSG_RESULT([Enabling bitmap statistics support by default])
 819 AC_DEFINE(ENABLE_BMAP_STATS, 1)
 820 )
 821 dnl
 822 dnl handle --enable-bmap-stats-ops
 823 dnl
 824 AH_TEMPLATE([ENABLE_BMAP_STATS_OPS], [Define to 1 to enable bitmap stats.])
 825 AC_ARG_ENABLE([bmap-stats-ops],
 826 [  --enable-bmap-stats-ops enable collection of additional bitmap stats],
 827 if test "$enableval" = "no"
 828 then
 829         AC_MSG_RESULT([Disabling additional bitmap statistics])
 830 else
 831         dnl There has to be a better way!
 832         AS_IF([test "x${enable_bmap_stats}" = "xno"],
 833          AC_MSG_FAILURE([Error --enable-bmap-stats-ops requires bmap-stats]))
 834
 835         AC_MSG_RESULT([Enabling additional bitmap statistics])
 836         AC_DEFINE(ENABLE_BMAP_STATS_OPS, 1)
 837 fi
 838 ,
 839 AC_MSG_RESULT([Disabling additional bitmap statistics by default])
 840 )
 841 dnl
 842 dnl
 843 dnl
 844 MAKEFILE_LIBRARY=$srcdir/lib/Makefile.library
 845 AC_SUBST_FILE(MAKEFILE_LIBRARY)
 846 dnl
 847 dnl Add internationalization support, using gettext.
 848 dnl
 849 GETTEXT_PACKAGE=e2fsprogs
 850 PACKAGE=e2fsprogs
 851 VERSION="$E2FSPROGS_VERSION"
 852 VERSION=0.14.1
 853 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [package name for gettext])
 854 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [version for gettext])
 855 AC_SUBST(GETTEXT_PACKAGE)
 856 AC_SUBST(PACKAGE)
 857 AC_SUBST(VERSION)
 858
 859 AM_GNU_GETTEXT
 860 dnl
 861 dnl End of configuration options
 862 dnl
 863 AC_SUBST(BINARY_TYPE)
 864 AC_PROG_MAKE_SET
 865 CHECK_GNU_MAKE
 866 AC_PATH_PROG(LN, ln, ln)
 867 AC_PROG_LN_S
 868 AC_PATH_PROG(MV, mv, mv)
 869 AC_PATH_PROG(CP, cp, cp)
 870 AC_PATH_PROG(RM, rm, rm)
 871 AC_PATH_PROG(CHMOD, chmod, :)
 872 AC_PROG_AWK
 873 AC_PROG_EGREP
 874 AC_PATH_PROG(SED, sed, sed)
 875 AC_PATH_PROG(PERL, perl, perl)
 876 AC_PATH_PROG(LDCONFIG, ldconfig, :)
 877 AC_CHECK_TOOL(AR, ar, ar)
 878 AC_CHECK_TOOL(RANLIB, ranlib, :)
 879 AC_CHECK_TOOL(STRIP, strip, :)
 880 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
 881 if test "_$MAKEINFO" = "_"; then
 882     MAKEINFO="@echo Makeinfo is missing. Info documentation will not be built.;true"
 883 else
 884     case "$MAKEINFO" in
 885       */missing.*)
 886         AC_MSG_WARN([
 887 *** Makeinfo is missing. Info documentation will not be built.])
 888         ;;
 889       *)
 890         ;;
 891     esac
 892 fi
 893 AC_SUBST(MAKEINFO)
 894 AC_PROG_INSTALL
 895 # See if we need a separate native compiler.
 896 if test $cross_compiling = no; then
 897   BUILD_CC="$CC"
 898   AC_SUBST(BUILD_CC)
 899 else
 900   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 901 fi
 902 AC_CHECK_HEADERS(m4_flatten([
 903         dirent.h
 904         errno.h
 905         execinfo.h
 906         getopt.h
 907         malloc.h
 908         mntent.h
 909         paths.h
 910         semaphore.h
 911         setjmp.h
 912         signal.h
 913         stdarg.h
 914         stdint.h
 915         stdlib.h
 916         termios.h
 917         termio.h
 918         unistd.h
 919         utime.h
 920         linux/falloc.h
 921         linux/fd.h
 922         linux/major.h
 923         net/if_dl.h
 924         netinet/in.h
 925         sys/disklabel.h
 926         sys/file.h
 927         sys/ioctl.h
 928         sys/mkdev.h
 929         sys/mman.h
 930         sys/prctl.h
 931         sys/queue.h
 932         sys/resource.h
 933         sys/select.h
 934         sys/socket.h
 935         sys/sockio.h
 936         sys/stat.h
 937         sys/syscall.h
 938         sys/sysmacros.h
 939         sys/time.h
 940         sys/types.h
 941         sys/un.h
 942         sys/wait.h
 943 ]))
 944 AC_CHECK_HEADERS(sys/disk.h sys/mount.h,,,
 945 [[
 946 #if HAVE_SYS_QUEUE_H
 947 #include <sys/queue.h>
 948 #endif
 949 ]])
 950 AC_CHECK_HEADERS(net/if.h,,,
 951 [[
 952 #if HAVE_SYS_TYPES_H
 953 #include <sys/types.h>
 954 #endif
 955 #if HAVE_SYS_SOCKET
 956 #include <sys/socket.h>
 957 #endif
 958 ]])
 959 AC_FUNC_VPRINTF
 960 dnl Check to see if dirent has member d_reclen. On cygwin those d_reclen
 961 dnl is not decleared.
 962 AC_CHECK_MEMBER(struct dirent.d_reclen,[AC_DEFINE(HAVE_RECLEN_DIRENT, 1,
 963                        [Define to 1 if dirent has d_reclen])],,
 964                 [#include <dirent.h>])
 965 dnl Check to see if ssize_t was declared
 966 AC_CHECK_TYPE(ssize_t,[AC_DEFINE(HAVE_TYPE_SSIZE_T, 1,
 967                 [Define to 1 if ssize_t declared])],,
 968               [#include <sys/types.h>])
 969 dnl
 970 dnl Check to see if llseek() is declared in unistd.h.  On some libc's
 971 dnl it is, and on others it isn't..... Thank you glibc developers....
 972 dnl
 973 AC_CHECK_DECL(llseek,[AC_DEFINE(HAVE_LLSEEK_PROTOTYPE, 1,
 974                         [Define to 1 if llseek declared in unistd.h])],,
 975               [#include <unistd.h>])
 976 dnl
 977 dnl Check to see if lseek64() is declared in unistd.h.  Glibc's header files
 978 dnl are so convoluted that I can't tell whether it will always be defined,
 979 dnl and if it isn't defined while lseek64 is defined in the library,
 980 dnl disaster will strike.
 981 dnl
 982 dnl Warning!  Use of --enable-gcc-wall may throw off this test.
 983 dnl
 984 dnl
 985 AC_CHECK_DECL(lseek64,[AC_DEFINE(HAVE_LSEEK64_PROTOTYPE, 1,
 986                         [Define to 1 if lseek64 declared in unistd.h])],,
 987                 [#define _LARGEFILE_SOURCE
 988                  #define _LARGEFILE64_SOURCE
 989                  #include <unistd.h>])
 990 dnl
 991 dnl Word sizes...
 992 dnl
 993 AC_CHECK_SIZEOF(short)
 994 AC_CHECK_SIZEOF(int)
 995 AC_CHECK_SIZEOF(long)
 996 AC_CHECK_SIZEOF(long long)
 997 AC_CHECK_SIZEOF(off_t)
 998 SIZEOF_SHORT=$ac_cv_sizeof_short
 999 SIZEOF_INT=$ac_cv_sizeof_int
1000 SIZEOF_LONG=$ac_cv_sizeof_long
1001 SIZEOF_LONG_LONG=$ac_cv_sizeof_long_long
1002 SIZEOF_OFF_T=$ac_cv_sizeof_off_t
1003 AC_SUBST(SIZEOF_SHORT)
1004 AC_SUBST(SIZEOF_INT)
1005 AC_SUBST(SIZEOF_LONG)
1006 AC_SUBST(SIZEOF_LONG_LONG)
1007 AC_SUBST(SIZEOF_OFF_T)
1008 AC_C_BIGENDIAN
1009 BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
1010 ASM_TYPES_HEADER=./asm_types.h
1011 AC_SUBST_FILE(ASM_TYPES_HEADER)
1012 dnl
1013 dnl Save the configuration #defines needed for the public ext2fs.h
1014 dnl header file
1015 dnl
1016 echo "/* These defines are needed for the public ext2fs.h header file */" \
1017      > public_config.h
1018 if grep HAVE_SYS_TYPES_H confdefs.h > tmp_config.$$; then
1019   uniq tmp_config.$$ >> public_config.h
1020 else
1021   echo "#undef HAVE_SYS_TYPES_H" >> public_config.h
1022 fi
1023 if grep WORDS_BIGENDIAN confdefs.h > tmp_config.$$; then
1024   uniq tmp_config.$$ >> public_config.h
1025 else
1026   echo "#undef WORDS_BIGENDIAN" >> public_config.h
1027 fi
1028 rm -f tmp_config.$$
1029 PUBLIC_CONFIG_HEADER=./public_config.h
1030 AC_SUBST_FILE(PUBLIC_CONFIG_HEADER)
1031 dnl
1032 dnl See if we have inttypes.h and if intptr_t is defined
1033 dnl
1034 AC_CHECK_HEADERS([inttypes.h])
1035 AC_CHECK_TYPES(intptr_t)
1036 dnl
1037 dnl See if struct stat has a st_flags field, in which case we can get file
1038 dnl flags somewhat portably.  Also check for the analogous setter, chflags().
1039 dnl
1040 AC_MSG_CHECKING(whether struct stat has a st_flags field)
1041 AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags,
1042         AC_TRY_COMPILE([#include <sys/stat.h>],
1043                 [struct stat stat; stat.st_flags = 0;],
1044                 [e2fsprogs_cv_struct_st_flags=yes],
1045                 [e2fsprogs_cv_struct_st_flags=no]))
1046 AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags)
1047 if test "$e2fsprogs_cv_struct_st_flags" = yes; then
1048   AC_MSG_CHECKING(whether st_flags field is useful)
1049   AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags_immut,
1050         AC_TRY_COMPILE([#include <sys/stat.h>],
1051                 [struct stat stat; stat.st_flags |= UF_IMMUTABLE;],
1052                 [e2fsprogs_cv_struct_st_flags_immut=yes],
1053                 [e2fsprogs_cv_struct_st_flags_immut=no]))
1054   AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags_immut)
1055   if test "$e2fsprogs_cv_struct_st_flags_immut" = yes; then
1056           AC_DEFINE(HAVE_STAT_FLAGS, 1,
1057                 [Define to 1 if struct stat has st_flags])
1058   fi
1059 fi
1060 dnl
1061 dnl Check for the presence of SA_LEN
1062 dnl
1063 AC_CHECK_MEMBER(struct sockaddr.sa_len,
1064                 AC_DEFINE_UNQUOTED(HAVE_SA_LEN,1,
1065                         [Define to 1 if if struct sockaddr contains sa_len]),,
1066         [#include <sys/types.h>
1067          #include <sys/socket.h>])
1068 dnl
1069 dnl This will add -lblkid to the AC_CHECK_FUNCS search if we are using
1070 dnl the system-provided blkid library
1071 dnl
1072 if test -n "$BLKID_CMT"; then
1073   AC_SEARCH_LIBS([blkid_probe_all], [blkid])
1074 fi
1075 dnl
1076 AC_CHECK_FUNCS(m4_flatten([
1077         __secure_getenv
1078         backtrace
1079         blkid_probe_get_topology
1080         chflags
1081         fallocate
1082         fallocate64
1083         fchown
1084         fdatasync
1085         fstat64
1086         ftruncate64
1087         getdtablesize
1088         getmntinfo
1089         getpwuid_r
1090         getrlimit
1091         getrusage
1092         jrand48
1093         llseek
1094         lseek64
1095         mallinfo
1096         mbstowcs
1097         memalign
1098         mmap
1099         msync
1100         nanosleep
1101         open64
1102         pathconf
1103         posix_fadvise
1104         posix_memalign
1105         prctl
1106         secure_getenv
1107         setmntent
1108         setresgid
1109         setresuid
1110         srandom
1111         strcasecmp
1112         strdup
1113         strnlen
1114         strptime
1115         strtoull
1116         sync_file_range
1117         sysconf
1118         usleep
1119         utime
1120         valloc
1121 ]))
1122 dnl
1123 dnl Check to see if -lsocket is required (solaris) to make something
1124 dnl that uses socket() to compile; this is needed for the UUID library
1125 dnl
1126 SOCKET_LIB=''
1127 AC_CHECK_LIB(socket, socket, [SOCKET_LIB=-lsocket])
1128 AC_SUBST(SOCKET_LIB)
1129 dnl
1130 dnl See if optreset exists
1131 dnl
1132 AC_MSG_CHECKING(for optreset)
1133 AC_CACHE_VAL(ac_cv_have_optreset,
1134 [AC_EGREP_HEADER(optreset, unistd.h,
1135   ac_cv_have_optreset=yes, ac_cv_have_optreset=no)])dnl
1136 AC_MSG_RESULT($ac_cv_have_optreset)
1137 if test $ac_cv_have_optreset = yes; then
1138   AC_DEFINE(HAVE_OPTRESET, 1, [Define to 1 if optreset for getopt is present])
1139 fi
1140 dnl
1141 dnl Test for sem_init, and which library it might require:
1142 dnl
1143 AH_TEMPLATE([HAVE_SEM_INIT], [Define to 1 if sem_init() exists])
1144 SEM_INIT_LIB=''
1145 AC_CHECK_FUNC(sem_init, ,
1146   AC_CHECK_LIB(pthread, sem_init,
1147         AC_DEFINE(HAVE_SEM_INIT, 1)
1148         SEM_INIT_LIB=-lpthread,
1149   AC_CHECK_LIB(rt, sem_init,
1150         AC_DEFINE(HAVE_SEM_INIT, 1)
1151         SEM_INIT_LIB=-lrt,
1152   AC_CHECK_LIB(posix4, sem_init,
1153         AC_DEFINE(HAVE_SEM_INIT, 1)
1154         SEM_INIT_LIB=-lposix4))))dnl
1155 AC_SUBST(SEM_INIT_LIB)
1156 dnl
1157 dnl Check for unified diff
1158 dnl
1159 AC_MSG_CHECKING(for unified diff option)
1160 if diff -u $0 $0 > /dev/null 2>&1 ; then
1161    UNI_DIFF_OPTS=-u
1162 else
1163    UNI_DIFF_OPTS=-c
1164 fi
1165 AC_MSG_RESULT($UNI_DIFF_OPTS)
1166 AC_SUBST(UNI_DIFF_OPTS)
1167 dnl
1168 dnl We use the EXT2 ioctls only under Linux
1169 dnl
1170 case "$host_os" in
1171 linux*)
1172         AC_DEFINE(HAVE_EXT2_IOCTLS, 1, [Define to 1 if Ext2 ioctls present])
1173         ;;
1174 esac
1175 dnl
1176 dnl OS-specific uncomment control
1177 dnl
1178 LINUX_CMT="#"
1179 CYGWIN_CMT="#"
1180 UNIX_CMT=
1181 case "$host_os" in
1182 linux*)
1183         LINUX_CMT=
1184         ;;
1185 cygwin)
1186         CYGWIN_CMT=
1187         UNIX_CMT="#"
1188         ;;
1189 esac
1190 AC_SUBST(LINUX_CMT)
1191 AC_SUBST(CYGWIN_CMT)
1192 AC_SUBST(UNIX_CMT)
1193 dnl
1194 dnl Linux and Hurd places root files in the / by default
1195 dnl
1196 case "$host_os" in
1197 linux* | gnu* | k*bsd*-gnu)
1198         if test "$prefix" = NONE -a "$root_prefix" = NONE ; then
1199                 root_prefix="";
1200                 AC_MSG_RESULT([On $host_os systems, root_prefix defaults to ''])
1201         fi
1202         ;;
1203 esac
1204 dnl
1205 dnl On Linux/hurd, force the prefix to be /usr
1206 dnl
1207 case "$host_os" in
1208 linux* | gnu* | k*bsd*-gnu)
1209         if test "$prefix" = NONE ; then
1210                 prefix="/usr";
1211                 AC_MSG_RESULT([On $host_os systems, prefix defaults to /usr])
1212                 if test "$mandir" = '${prefix}/man' ; then
1213                         AC_MSG_RESULT([...and mandir defaults to /usr/share/man])
1214                         mandir=/usr/share/man
1215                 fi
1216         fi
1217 ;;
1218 esac
1219 if test "$root_prefix" = NONE ; then
1220         if test "$prefix" = NONE ; then
1221                 root_prefix="$ac_default_prefix"
1222         else
1223                 root_prefix="$prefix"
1224         fi
1225         root_bindir=$bindir
1226         root_sbindir=$sbindir
1227         root_libdir=$libdir
1228         root_sysconfdir=$sysconfdir
1229 else
1230         root_bindir='${root_prefix}/bin'
1231         root_sbindir='${root_prefix}/sbin'
1232         root_libdir='${root_prefix}/lib'
1233         root_sysconfdir='${root_prefix}/etc'
1234 fi
1235 if test "$bindir" != '${exec_prefix}/bin'; then
1236     root_bindir=$bindir
1237     AC_MSG_RESULT([Setting root_bindir to $root_bindir])
1238 fi
1239 if test "$sbindir" != '${exec_prefix}/sbin'; then
1240     root_sbindir=$sbindir
1241     AC_MSG_RESULT([Setting root_sbindir to $root_sbindir])
1242 fi
1243 if test "$libdir" != '${exec_prefix}/lib'; then
1244     root_libdir=$libdir
1245     AC_MSG_RESULT([Setting root_libdir to $root_libdir])
1246 fi
1247 if test "$sysconfdir" != '${prefix}/etc'; then
1248     root_sysconfdir=$sysconfdir
1249     AC_MSG_RESULT([Setting root_sysconfdir to $root_sysconfdir])
1250 fi
1251 AC_SUBST(root_prefix)
1252 AC_SUBST(root_bindir)
1253 AC_SUBST(root_sbindir)
1254 AC_SUBST(root_libdir)
1255 AC_SUBST(root_sysconfdir)
1256 dnl
1257 dnl Allow specification of the multiarch arch
1258 dnl
1259 AC_ARG_WITH([multiarch],
1260 [  --with-multiarch=ARCH specify the multiarch triplet],
1261 libdir=$libdir/$withval
1262 root_libdir=$root_libdir/$withval
1263 )dnl
1264 dnl
1265 dnl See if -static works.  This could fail if the linker does not
1266 dnl support -static, or if required external libraries are not available
1267 dnl in static form.
1268 dnl
1269 AC_MSG_CHECKING([whether we can link with -static])
1270 AC_CACHE_VAL(ac_cv_e2fsprogs_use_static,
1271 [SAVE_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -static"
1272 AC_TRY_LINK([#include <stdio.h>],[fflush(stdout);],
1273  ac_cv_e2fsprogs_use_static=yes, ac_cv_e2fsprogs_use_static=no)
1274 LDFLAGS=$SAVE_LDFLAGS])
1275 dnl
1276 dnl Regardless of how the test turns out, Solaris doesn't handle -static
1277 dnl This is caused by the socket library requiring the nsl library, which
1278 dnl requires the -dl library, which only works for dynamically linked
1279 dnl programs.  It basically means you can't have statically linked programs
1280 dnl which use the network under Solaris.
1281 dnl
1282 case "$host_os" in
1283 solaris2.*)
1284         ac_cv_e2fsprogs_use_static=no
1285 ;;
1286 esac
1287 AC_MSG_RESULT($ac_cv_e2fsprogs_use_static)
1288 LDFLAG_STATIC=
1289 if test $ac_cv_e2fsprogs_use_static = yes; then
1290         LDFLAG_STATIC=-static
1291 fi
1292 AC_SUBST(LDFLAG_STATIC)
1293 dnl
1294 dnl Work around mysterious Darwin / GNU libintl problem
1295 dnl (__asm__ redirection doesn't work for some mysterious reason.  Looks like
1296 dnl Apple hacked gcc somehow?)
1297 dnl
1298 case "$host_os" in
1299 darwin*)
1300         AC_MSG_RESULT([Using Apple Darwin / GNU libintl workaround])
1301         AC_DEFINE(_INTL_REDIRECT_MACROS, 1,
1302                 [Define to 1 if Apple Darwin libintl workaround is needed])
1303         ;;
1304 esac
1305 dnl
1306 dnl Make the ss and et directories work correctly.
1307 dnl
1308 SS_DIR=`cd ${srcdir}/lib/ss; pwd`
1309 ET_DIR=`cd ${srcdir}/lib/et; pwd`
1310 AC_SUBST(SS_DIR)
1311 AC_SUBST(ET_DIR)
1312 dnl
1313 dnl Only try to run the test suite if we're not cross compiling.
1314 dnl
1315 if test "$cross_compiling" = yes ; then
1316   DO_TEST_SUITE=
1317 else
1318   DO_TEST_SUITE=check
1319 fi
1320 AC_SUBST(DO_TEST_SUITE)
1321 dnl
1322 dnl Only include the intl include files if we're building with them
1323 dnl
1324 INCLUDES='-I. -I$(top_builddir)/lib -I$(top_srcdir)/lib'
1325 if test -n "$CPPFLAGS" ; then
1326         INCLUDES="$INCLUDES $CPPFLAGS"
1327 fi
1328 if test "$USE_INCLUDED_LIBINTL" = "yes" ; then
1329         INCLUDES=$INCLUDES' -I$(top_builddir)/intl -I$(top_srcdir)/intl'
1330 fi
1331 AC_SUBST(INCLUDES)
1332 dnl
1333 dnl Build CFLAGS
1334 dnl
1335 if test $cross_compiling = no; then
1336    BUILD_CFLAGS="$CFLAGS $CPPFLAGS"
1337    BUILD_LDFLAGS="$LDFLAGS"
1338 else
1339    BUILD_CFLAGS=
1340    BUILD_LDFLAGS=
1341 fi
1342 AC_SUBST(BUILD_CFLAGS)
1343 AC_SUBST(BUILD_LDFLAGS)
1344 dnl
1345 dnl Make our output files, being sure that we create the some miscellaneous
1346 dnl directories
1347 dnl
1348 test -d lib || mkdir lib
1349 test -d include || mkdir include
1350 test -d include/linux || mkdir include/linux
1351 test -d include/asm || mkdir include/asm
1352 for i in MCONFIG Makefile e2fsprogs.spec \
1353         util/Makefile util/subst.conf util/gen-tarball util/install-symlink \
1354         lib/et/Makefile lib/ss/Makefile lib/e2p/Makefile \
1355         lib/ext2fs/Makefile lib/ext2fs/ext2_types.h \
1356         lib/uuid/Makefile lib/uuid/uuid_types.h \
1357         lib/blkid/Makefile lib/blkid/blkid_types.h lib/quota/Makefile \
1358         lib/ss/ss.pc lib/uuid/uuid.pc lib/et/com_err.pc \
1359         lib/e2p/e2p.pc lib/blkid/blkid.pc lib/ext2fs/ext2fs.pc \
1360         misc/Makefile ext2ed/Makefile e2fsck/Makefile \
1361         debugfs/Makefile tests/Makefile tests/progs/Makefile \
1362         resize/Makefile doc/Makefile intl/Makefile \
1363         intl/libgnuintl.h po/Makefile.in ; do
1364         if test -d `dirname ${srcdir}/$i` ; then
1365                 outlist="$outlist $i"
1366         fi
1367 done
1368 AC_OUTPUT($outlist)
1369 if test -f util/gen-tarball; then chmod +x util/gen-tarball; fi