configure.ac

   1 AC_INIT(version.h)
   2 AC_PREREQ(2.54)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_HEADERS([lib/config.h])
   5 AH_BOTTOM([#include <dirpaths.h>])
   6 MCONFIG=./MCONFIG
   7 AC_SUBST_FILE(MCONFIG)
   8 BINARY_TYPE=bin
   9 dnl
  10 dnl This is to figure out the version number and the date....
  11 dnl
  12 E2FSPROGS_VERSION=`grep E2FSPROGS_VERSION ${srcdir}/version.h  \
  13         | awk '{print $3}' | tr \" " " | awk '{print $1}'`
  14 DATE=`grep E2FSPROGS_DATE ${srcdir}/version.h | awk '{print $3}' \
  15         | tr \" " "`
  16 E2FSPROGS_DAY=$(echo $DATE | awk -F- '{print $1}' | sed -e '/^[[1-9]]$/s/^/0/')
  17 MONTH=`echo $DATE | awk -F- '{print $2}'`
  18 YEAR=`echo $DATE | awk -F- '{print $3}'`
  19
  20 if expr $YEAR ">" 1900 > /dev/null ; then
  21         E2FSPROGS_YEAR=$YEAR
  22 elif expr $YEAR ">" 90 >/dev/null ; then
  23         E2FSPROGS_YEAR=19$YEAR
  24 else
  25         E2FSPROGS_YEAR=20$YEAR
  26 fi
  27
  28 case $MONTH in
  29 Jan)    MONTH_NUM=01; E2FSPROGS_MONTH="January" ;;
  30 Feb)    MONTH_NUM=02; E2FSPROGS_MONTH="February" ;;
  31 Mar)    MONTH_NUM=03; E2FSPROGS_MONTH="March" ;;
  32 Apr)    MONTH_NUM=04; E2FSPROGS_MONTH="April" ;;
  33 May)    MONTH_NUM=05; E2FSPROGS_MONTH="May" ;;
  34 Jun)    MONTH_NUM=06; E2FSPROGS_MONTH="June" ;;
  35 Jul)    MONTH_NUM=07; E2FSPROGS_MONTH="July" ;;
  36 Aug)    MONTH_NUM=08; E2FSPROGS_MONTH="August" ;;
  37 Sep)    MONTH_NUM=09; E2FSPROGS_MONTH="September" ;;
  38 Oct)    MONTH_NUM=10; E2FSPROGS_MONTH="October" ;;
  39 Nov)    MONTH_NUM=11; E2FSPROGS_MONTH="November" ;;
  40 Dec)    MONTH_NUM=12; E2FSPROGS_MONTH="December" ;;
  41 *)      AC_MSG_WARN([Unknown month $MONTH??]) ;;
  42 esac
  43
  44 base_ver=`echo $E2FSPROGS_VERSION | \
  45                sed -e 's/-WIP//' -e 's/pre-//' -e 's/-PLUS//'`
  46
  47 date_spec=${E2FSPROGS_YEAR}.${MONTH_NUM}.${E2FSPROGS_DAY}
  48
  49 case $E2FSPROGS_VERSION in
  50 *-WIP|pre-*)
  51         E2FSPROGS_PKGVER="$base_ver~WIP.$date_spec"
  52         ;;
  53 *)
  54         E2FSPROGS_PKGVER="$base_ver"
  55         ;;
  56 esac
  57
  58 unset DATE MONTH YEAR base_ver pre_vers date_spec
  59 AC_MSG_RESULT([Generating configuration file for e2fsprogs version $E2FSPROGS_VERSION])
  60 AC_MSG_RESULT([Release date is ${E2FSPROGS_MONTH}, ${E2FSPROGS_YEAR}])
  61 AC_SUBST(E2FSPROGS_YEAR)
  62 AC_SUBST(E2FSPROGS_MONTH)
  63 AC_SUBST(E2FSPROGS_DAY)
  64 AC_SUBST(E2FSPROGS_VERSION)
  65 AC_SUBST(E2FSPROGS_PKGVER)
  66 dnl
  67 dnl Use diet libc
  68 dnl
  69 WITH_DIET_LIBC=
  70 AC_ARG_WITH([diet-libc],
  71 [  --with-diet-libc        use diet libc],
  72 CC="diet cc -nostdinc"
  73 WITH_DIET_LIBC=yes
  74 if test -z "$LIBS"
  75 then
  76         LIBS="-lcompat"
  77 else
  78         LIBS="$LIBS -lcompat"
  79 fi
  80 AC_MSG_RESULT(CC=$CC))dnl
  81 dnl
  82 AC_CANONICAL_HOST
  83 dnl
  84 dnl Check to see if libdl exists for the sake of dlopen
  85 dnl
  86 DLOPEN_LIB=''
  87 AC_CHECK_LIB(dl, dlopen,
  88 [DLOPEN_LIB=-ldl
  89 AC_DEFINE(HAVE_DLOPEN, 1, [Define to 1 if dlopen/libdl exists])])
  90 AC_SUBST(DLOPEN_LIB)
  91 dnl
  92 AC_ARG_WITH([cc],
  93 AC_HELP_STRING([--with-cc],[no longer supported, use CC= instead]),
  94 AC_MSG_ERROR([--with-cc no longer supported; use CC= instead]))
  95 dnl
  96 AC_ARG_WITH([ccopts],
  97 AC_HELP_STRING([--with-ccopts],[no longer supported, use CFLAGS= instead]),
  98 AC_MSG_ERROR([--with-ccopts no longer supported; use CFLAGS= instead]))
  99 dnl
 100 AC_ARG_WITH([ldopts],
 101 AC_HELP_STRING([--with-ldopts],[no longer supported, use LDFLAGS= instead]),
 102 AC_MSG_ERROR([--with-ldopts no longer supported; use LDFLAGS= instead]))
 103 dnl
 104 AC_PROG_CC
 105 if test "$GCC" = yes; then
 106    RDYNAMIC="-rdynamic"
 107    AC_SUBST(RDYNAMIC)
 108 fi
 109 AC_PROG_CPP
 110 dnl
 111 dnl Alpha computers use fast and imprecise floating point code that may
 112 dnl miss exceptions by default. Force sane options if we're using GCC.
 113 AC_MSG_CHECKING(for additional special compiler flags)
 114 if test "$GCC" = yes
 115 then
 116     case "$host_cpu" in
 117         alpha)          addcflags="-mieee" ;;
 118     esac
 119 fi
 120 if test "x$addcflags" != x
 121 then
 122     AC_MSG_RESULT($addcflags)
 123     CFLAGS="$addcflags $CFLAGS"
 124 else
 125     AC_MSG_RESULT([[(none)]])
 126 fi
 127 AC_USE_SYSTEM_EXTENSIONS
 128 dnl
 129 dnl Set default values for library extentions.  Will be dealt with after
 130 dnl parsing configuration opions, which may modify these
 131 dnl
 132 LIB_EXT=.a
 133 STATIC_LIB_EXT=.a
 134 PROFILED_LIB_EXT=.a
 135 dnl
 136 dnl Allow separate `root_prefix' to be specified
 137 dnl
 138 AC_ARG_WITH([root-prefix],
 139 [  --with-root-prefix=PREFIX override prefix variable for files to be placed in the root],
 140 root_prefix=$withval,
 141 root_prefix=NONE)dnl
 142 dnl
 143 dnl handle --enable-maintainer-mode
 144 dnl
 145 AC_ARG_ENABLE([maintainer-mode],
 146 [  --enable-maintainer-mode enable makefile rules useful for maintainers],
 147 if test "$enableval" = "no"
 148 then
 149         MAINTAINER_CMT=#
 150         AC_MSG_RESULT([Disabling maintainer mode])
 151 else
 152         MAINTAINER_CMT=
 153         AC_MSG_RESULT([Enabling maintainer mode])
 154 fi
 155 ,
 156 MAINTAINER_CMT=#
 157 AC_MSG_RESULT([Disabling maintainer mode by default])
 158 )
 159 AC_SUBST(MAINTAINER_CMT)
 160 dnl
 161 dnl handle --enable-symlink-install
 162 dnl
 163 AC_ARG_ENABLE([symlink-install],
 164 [  --enable-symlink-install use symlinks when installing instead of hard links],
 165 if test "$enableval" = "no"
 166 then
 167         LINK_INSTALL_FLAGS=-f
 168         AC_MSG_RESULT([Disabling symlinks for install])
 169 else
 170         LINK_INSTALL_FLAGS=-sf
 171         AC_MSG_RESULT([Enabling symlinks for install])
 172 fi
 173 ,
 174 LINK_INSTALL_FLAGS=-f
 175 AC_MSG_RESULT([Disabling symlinks for install by default])
 176 )
 177 AC_SUBST(LINK_INSTALL_FLAGS)
 178 dnl
 179 dnl handle --enable-relative-symlinks
 180 dnl
 181 relative_symlink_defined=
 182 AC_ARG_ENABLE([relative-symlinks],
 183 [  --enable-relative-symlinks use relative symlinks when installing],
 184 if test "$enableval" = "no"
 185 then
 186         SYMLINK_RELATIVE=
 187         relative_symlink_defined=yes
 188         AC_MSG_RESULT([Disabling relative symlinks for install])
 189 else
 190         SYMLINK_RELATIVE=--relative
 191         relative_symlink_defined=yes
 192         AC_MSG_RESULT([Enabling relative symlinks for install])
 193 fi)
 194 AC_ARG_ENABLE([symlink-relative-symlinks],,
 195 if test "$enableval" = "no"
 196 then
 197         SYMLINK_RELATIVE=yes
 198         AC_MSG_RESULT([Disabling relative symlinks for install])
 199 else
 200         SYMLINK_RELATIVE=--relative
 201         AC_MSG_RESULT([Enabling relative symlinks for install])
 202 fi
 203 ,
 204 if test -z "$relative_symlink_defined"
 205 then
 206         SYMLINK_RELATIVE=
 207 AC_MSG_RESULT([Disabling relative symlinks for install by default])
 208 fi
 209 )
 210 AC_SUBST(SYMLINK_RELATIVE)
 211 dnl
 212 dnl handle --enable-symlink-build
 213 dnl
 214 AC_ARG_ENABLE([symlink-build],
 215 [  --enable-symlink-build  use symlinks while building instead of hard links],
 216 if test "$enableval" = "no"
 217 then
 218         LINK_BUILD_FLAGS=
 219         AC_MSG_RESULT([Disabling symlinks for build])
 220 else
 221         LINK_BUILD_FLAGS=-s
 222         AC_MSG_RESULT([Enabling symlinks for build])
 223 fi
 224 ,
 225 LINK_BUILD_FLAGS=
 226 AC_MSG_RESULT([Disabling symlinks for build by default])
 227 )
 228 AC_SUBST(LINK_BUILD_FLAGS)
 229 dnl
 230 dnl handle --enable-verbose-makecmds
 231 dnl
 232 AC_ARG_ENABLE([verbose-makecmds],
 233 [  --enable-verbose-makecmds enable verbose make command output],
 234 if test "$enableval" = "no"
 235 then
 236         AC_MSG_RESULT([Disabling verbose make commands])
 237         E=@echo
 238         ES=echo
 239         Q=@
 240 else
 241         AC_MSG_RESULT([Enabling verbose make commands])
 242         E=@\\#
 243         ES=\\#
 244         Q=
 245 fi
 246 ,
 247 AC_MSG_RESULT([Disabling verbose make commands])
 248 E=@echo
 249 ES=echo
 250 Q=@
 251 )
 252 AC_SUBST(E)
 253 AC_SUBST(ES)
 254 AC_SUBST(Q)
 255 dnl
 256 dnl This needs to be before all of the --enable-*-shlibs options
 257 dnl
 258 E2_PKG_CONFIG_STATIC=--static
 259 LDFLAG_DYNAMIC=
 260 PRIVATE_LIBS_CMT=
 261 dnl
 262 dnl handle --enable-elf-shlibs
 263 dnl
 264 AC_ARG_ENABLE([elf-shlibs],
 265 [  --enable-elf-shlibs    select ELF shared libraries],
 266 if test "$enableval" = "no"
 267 then
 268         ELF_CMT=#
 269         MAKEFILE_ELF=/dev/null
 270         AC_MSG_RESULT([Disabling ELF shared libraries])
 271 else
 272         E2_PKG_CONFIG_STATIC=
 273         ELF_CMT=
 274         MAKEFILE_ELF=$srcdir/lib/Makefile.elf-lib
 275         [case "$host_os" in
 276         solaris2.*)
 277                 MAKEFILE_ELF=$srcdir/lib/Makefile.solaris-lib
 278         ;;
 279         esac]
 280         BINARY_TYPE=elfbin
 281         LIB_EXT=.so
 282         PRIVATE_LIBS_CMT=#
 283         LDFLAG_DYNAMIC=['-Wl,-rpath-link,$(top_builddir)/lib']
 284         AC_MSG_RESULT([Enabling ELF shared libraries])
 285 fi
 286 ,
 287 MAKEFILE_ELF=/dev/null
 288 ELF_CMT=#
 289 AC_MSG_RESULT([Disabling ELF shared libraries by default])
 290 )
 291 AC_SUBST(ELF_CMT)
 292 AC_SUBST_FILE(MAKEFILE_ELF)
 293 dnl
 294 dnl handle --enable-bsd-shlibs
 295 dnl
 296 AC_ARG_ENABLE([bsd-shlibs],
 297 [  --enable-bsd-shlibs    select BSD shared libraries],
 298 if test "$enableval" = "no"
 299 then
 300         BSDLIB_CMT=#
 301         MAKEFILE_BSDLIB=/dev/null
 302         AC_MSG_RESULT([Disabling BSD shared libraries])
 303 else
 304         E2_PKG_CONFIG_STATIC=
 305         BSDLIB_CMT=
 306         MAKEFILE_BSDLIB=$srcdir/lib/Makefile.bsd-lib
 307         LIB_EXT=.so
 308         [case "$host_os" in
 309         darwin*)
 310                 MAKEFILE_BSDLIB=$srcdir/lib/Makefile.darwin-lib
 311                 LIB_EXT=.dylib
 312         ;;
 313         esac]
 314         AC_MSG_RESULT([Enabling BSD shared libraries])
 315 fi
 316 ,
 317 MAKEFILE_BSDLIB=/dev/null
 318 BSDLIB_CMT=#
 319 AC_MSG_RESULT([Disabling BSD shared libraries by default])
 320 )
 321 AC_SUBST(BSDLIB_CMT)
 322 AC_SUBST_FILE(MAKEFILE_BSDLIB)
 323 dnl
 324 dnl handle --enable-profile
 325 dnl
 326 AC_ARG_ENABLE([profile],
 327 [  --enable-profile       build profiling libraries],
 328 if test "$enableval" = "no"
 329 then
 330         PROFILE_CMT=#
 331         MAKEFILE_PROFILE=/dev/null
 332         AC_MSG_RESULT([Disabling profiling libraries])
 333 else
 334         PROFILE_CMT=
 335         MAKEFILE_PROFILE=$srcdir/lib/Makefile.profile
 336         PROFILED_LIB_EXT=_p.a
 337         AC_MSG_RESULT([Building profiling libraries])
 338 fi
 339 ,
 340 PROFILE_CMT=#
 341 MAKEFILE_PROFILE=/dev/null
 342 AC_MSG_RESULT([Disabling profiling libraries by default])
 343 )
 344 AC_SUBST(PROFILE_CMT)
 345 AC_SUBST_FILE(MAKEFILE_PROFILE)
 346 dnl
 347 dnl handle --enable-gcov
 348 dnl
 349 AC_ARG_ENABLE([gcov],
 350 [  --enable-gcov                  build for coverage testing using gcov],
 351 if test "$enableval" = "yes"
 352 then
 353         CFLAGS="-g -fprofile-arcs -ftest-coverage"
 354         LDFLAGS="-fprofile-arcs -ftest-coverage"
 355         AC_MSG_RESULT([Enabling gcov support])
 356 fi
 357 )
 358 dnl
 359 dnl handle --enable-hardening
 360 dnl
 361 CFLAGS_SHLIB="${CFLAGS_SHLIB:-$CFLAGS}"
 362 CFLAGS_STLIB="${CFLAGS_STLIB:-$CFLAGS}"
 363 LDFLAGS_SHLIB=${LDFLAGS_SHLIB:-$LDFLAGS}
 364 LDFLAGS_STATIC=${LDFLAGS_STATIC:-$LDFLAGS}
 365 AC_ARG_ENABLE([hardening],
 366 [  --enable-hardening             build for coverage testing using gcov],
 367 if test "$enableval" = "yes"
 368 then
 369         HARDEN_CFLAGS="-D_FORTIFY_SOURCE=2 -fstack-protector-strong"
 370         HARDEN_LDFLAGS=["-Wl,-z,relro -Wl,-z,now"]
 371         CFLAGS="$CFLAGS $HARDEN_CFLAGS -fPIE"
 372         CFLAGS_SHLIB="$CFLAGS_SHLIB $HARDEN_CFLAGS"
 373         CFLAGS_STLIB="$CFLAGS_STLIB $HARDEN_CFLAGS -fPIE"
 374         LDFLAGS="$LDFLAGS $HARDEN_LDFLAGS -fPIE -pie"
 375         LDFLAGS_STATIC="$LDFLAGS_STATIC $HARDEN_LDFLAGS"
 376         LDFLAGS_SHLIB="$LDFLAGS_SHLIB $HARDEN_LDFLAGS"
 377         AC_MSG_RESULT([Enabling hardening support])
 378 fi
 379 )
 380 dnl
 381 dnl Substitute library extensions
 382 dnl
 383 AC_SUBST(LIB_EXT)
 384 AC_SUBST(STATIC_LIB_EXT)
 385 AC_SUBST(PROFILED_LIB_EXT)
 386 AC_SUBST(LDFLAG_DYNAMIC)
 387 AC_SUBST(PRIVATE_LIBS_CMT)
 388 dnl
 389 dnl handle --enable-jbd-debug
 390 dnl
 391 AC_ARG_ENABLE([jbd-debug],
 392 [  --enable-jbd-debug     enable journal debugging],
 393 if test "$enableval" = "no"
 394 then
 395         AC_MSG_RESULT([Disabling journal debugging])
 396 else
 397         AC_DEFINE(CONFIG_JBD_DEBUG, 1,
 398                 [Define to 1 if debugging ext3/4 journal code])
 399         AC_MSG_RESULT([Enabling journal debugging])
 400 fi
 401 ,
 402 AC_MSG_RESULT([Disabling journal debugging by default])
 403 )
 404 dnl
 405 dnl handle --enable-blkid-debug
 406 dnl
 407 AC_ARG_ENABLE([blkid-debug],
 408 [  --enable-blkid-debug    enable blkid debugging],
 409 if test "$enableval" = "no"
 410 then
 411         AC_MSG_RESULT([Disabling blkid debugging])
 412 else
 413         AC_DEFINE(CONFIG_BLKID_DEBUG, 1,
 414                 [Define to 1 if debugging the blkid library])
 415         AC_MSG_RESULT([Enabling blkid debugging])
 416 fi
 417 ,
 418 AC_MSG_RESULT([Disabling blkid debugging by default])
 419 )
 420 dnl
 421 dnl handle --enable-testio-debug
 422 dnl
 423 AC_ARG_ENABLE([testio-debug],
 424 [  --disable-testio-debug  disable the use of the test I/O manager for debugging],
 425 AH_TEMPLATE([CONFIG_TESTIO_DEBUG],
 426         [Define to 1 if the testio I/O manager should be enabled])
 427 if test "$enableval" = "no"
 428 then
 429         AC_MSG_RESULT([Disabling testio debugging])
 430         TEST_IO_CMT="#"
 431 else
 432         TEST_IO_CMT=
 433         AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 434         AC_MSG_RESULT([Enabling testio debugging])
 435 fi
 436 ,
 437 AC_MSG_RESULT([Enabling testio debugging by default])
 438 AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 439 TEST_IO_CMT=
 440 )
 441 AC_SUBST(TEST_IO_CMT)
 442 dnl
 443 dnl handle --disable-libuuid
 444 dnl
 445 PKG_PROG_PKG_CONFIG
 446 LIBUUID=
 447 DEPLIBUUID=
 448 STATIC_LIBUUID=
 449 DEPSTATIC_LIBUUID=
 450 PROFILED_LIBUUID=
 451 DEPPROFILED_LIBUUID=
 452 UUID_CMT=
 453 AC_ARG_ENABLE([libuuid],
 454 [  --enable-libuuid       build and use private uuid library],
 455 if test "$enableval" = "no"
 456 then
 457         if test -z "$PKG_CONFIG"; then
 458                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 459         fi
 460
 461         AC_CHECK_LIB(uuid, uuid_generate,
 462                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 463                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`],
 464                 [AC_MSG_ERROR([external uuid library not found])])
 465         PROFILED_LIBUUID=$LIBUUID
 466         UUID_CMT=#
 467         AC_MSG_RESULT([Disabling private uuid library])
 468 else
 469         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 470         DEPLIBUUID=$LIBUUID
 471         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 472         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 473         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 474         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 475         AC_MSG_RESULT([Enabling private uuid library])
 476 fi
 477 ,
 478 if test -n "$PKG_CONFIG"; then
 479         AC_CHECK_LIB(uuid, uuid_generate,
 480                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 481                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`])
 482 fi
 483 if test -n "$LIBUUID"; then
 484         PROFILED_LIBUUID=$LIBUUID
 485         UUID_CMT=#
 486         AC_MSG_RESULT([Using system uuid by default])
 487 else
 488         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 489         DEPLIBUUID=$LIBUUID
 490         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 491         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 492         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 493         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 494         AC_MSG_RESULT([Enabling private uuid library by default])
 495 fi
 496 )
 497 AC_SUBST(LIBUUID)
 498 AC_SUBST(DEPLIBUUID)
 499 AC_SUBST(STATIC_LIBUUID)
 500 AC_SUBST(DEPSTATIC_LIBUUID)
 501 AC_SUBST(PROFILED_LIBUUID)
 502 AC_SUBST(DEPPROFILED_LIBUUID)
 503 AC_SUBST(UUID_CMT)
 504 dnl
 505 dnl handle --disable-libblkid
 506 dnl
 507 PKG_PROG_PKG_CONFIG
 508 LIBBLKID=
 509 DEPLIBBLKID=
 510 STATIC_LIBBLKID=
 511 DEPSTATIC_LIBBLKID=
 512 PROFILED_LIBBLKID=
 513 DEPPROFILED_LIBBLKID=
 514 BLKID_CMT=
 515 AH_TEMPLATE([CONFIG_BUILD_FINDFS], [Define to 1 to compile findfs])
 516 AC_ARG_ENABLE([libblkid],
 517 [  --enable-libblkid      build and use private blkid library],
 518 if test "$enableval" = "no"
 519 then
 520         if test -z "$PKG_CONFIG"; then
 521                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 522         fi
 523
 524         AC_CHECK_LIB(blkid, blkid_get_cache,
 525                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 526                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`],
 527                 [AC_MSG_ERROR([external blkid library not found])], -luuid)
 528         BLKID_CMT=#
 529         PROFILED_LIBBLKID=$LIBBLKID
 530         AC_MSG_RESULT([Disabling private blkid library])
 531 else
 532         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 533         DEPLIBBLKID=$LIBBLKID
 534         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 535         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 536         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 537         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 538         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 539         AC_MSG_RESULT([Enabling private blkid library])
 540 fi
 541 ,
 542 if test -n "$PKG_CONFIG"; then
 543         AC_CHECK_LIB(blkid, blkid_get_cache,
 544                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 545                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`])
 546 fi
 547 if test -n "$LIBBLKID"; then
 548         BLKID_CMT=#
 549         PROFILED_LIBBLKID=$LIBBLKID
 550         AC_MSG_RESULT([Using system blkid library by default])
 551 else
 552         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 553         DEPLIBBLKID=$LIBBLKID
 554         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 555         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 556         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 557         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 558         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 559         AC_MSG_RESULT([Enabling private blkid library by default])
 560 fi
 561 )
 562 AC_SUBST(LIBBLKID)
 563 AC_SUBST(DEPLIBBLKID)
 564 AC_SUBST(STATIC_LIBBLKID)
 565 AC_SUBST(DEPSTATIC_LIBBLKID)
 566 AC_SUBST(PROFILED_LIBBLKID)
 567 AC_SUBST(DEPPROFILED_LIBBLKID)
 568 AC_SUBST(BLKID_CMT)
 569 dnl
 570 dnl handle --disable-backtrace
 571 dnl
 572 AH_TEMPLATE([DISABLE_BACKTRACE], [Define to 1 to disable use of backtrace])
 573 AC_ARG_ENABLE([backtrace],
 574 [  --disable-backtrace    disable use backtrace],
 575 if test "$enableval" = "no"
 576 then
 577         AC_MSG_RESULT([Disabling use of backtrace])
 578         AC_DEFINE(DISABLE_BACKTRACE, 1)
 579 else
 580         AC_MSG_RESULT([Enabling use of backtrace])
 581 fi
 582 ,
 583 AC_MSG_RESULT([Enabling use of backtrace by default])
 584 )
 585 dnl
 586 dnl handle --enable-debugfs
 587 dnl
 588 AC_ARG_ENABLE([debugfs],
 589 [  --disable-debugfs      disable support of debugfs program],
 590 if test "$enableval" = "no"
 591 then
 592         AC_MSG_RESULT([Disabling debugfs support])
 593         DEBUGFS_CMT="#"
 594 else
 595         DEBUGFS_CMT=
 596         AC_MSG_RESULT([Enabling debugfs support])
 597 fi
 598 ,
 599 AC_MSG_RESULT([Enabling debugfs support by default])
 600 DEBUGFS_CMT=
 601 )
 602 AC_SUBST(DEBUGFS_CMT)
 603 dnl
 604 dnl handle --enable-imager
 605 dnl
 606 AC_ARG_ENABLE([imager],
 607 [  --disable-imager       disable support of e2image program],
 608 if test "$enableval" = "no"
 609 then
 610         AC_MSG_RESULT([Disabling e2image support])
 611         IMAGER_CMT="#"
 612 else
 613         IMAGER_CMT=
 614         AC_MSG_RESULT([Enabling e2image support])
 615 fi
 616 ,
 617 AC_MSG_RESULT([Enabling e2image support by default])
 618 IMAGER_CMT=
 619 )
 620 AC_SUBST(IMAGER_CMT)
 621 dnl
 622 dnl handle --enable-resizer
 623 dnl
 624 AC_ARG_ENABLE([resizer],
 625 [  --disable-resizer      disable support of e2resize program],
 626 if test "$enableval" = "no"
 627 then
 628         AC_MSG_RESULT([Disabling e2resize support])
 629         RESIZER_CMT="#"
 630 else
 631         RESIZER_CMT=
 632         AC_MSG_RESULT([Enabling e2resize support])
 633 fi
 634 ,
 635 AC_MSG_RESULT([Enabling e2resize support by default])
 636 RESIZER_CMT=
 637 )
 638 AC_SUBST(RESIZER_CMT)
 639 dnl
 640 dnl handle --enable-defrag
 641 dnl
 642 AC_ARG_ENABLE([defrag],
 643 [  --disable-defrag       disable support of e4defrag program],
 644 if test "$enableval" = "no"
 645 then
 646         AC_MSG_RESULT([Disabling e4defrag support])
 647         DEFRAG_CMT="#"
 648 else
 649         DEFRAG_CMT=
 650         AC_MSG_RESULT([Enabling e4defrag support])
 651 fi
 652 ,
 653 if test -z "$WITH_DIET_LIBC"
 654 then
 655         AC_MSG_RESULT([Enabling e4defrag support by default])
 656         DEFRAG_CMT=
 657 else
 658         AC_MSG_RESULT([Disabling e4defrag support by default])
 659         DEFRAG_CMT="#"
 660 fi
 661 )
 662 AC_SUBST(DEFRAG_CMT)
 663 dnl
 664 dnl See whether to install the `fsck' wrapper program (that calls e2fsck)
 665 dnl
 666 AC_ARG_ENABLE([fsck],
 667 [  --enable-fsck           build fsck wrapper program],
 668 [if test "$enableval" = "no"
 669 then
 670         FSCK_PROG='' FSCK_MAN=''
 671         AC_MSG_RESULT([Not building fsck wrapper])
 672 else
 673         FSCK_PROG=fsck FSCK_MAN=fsck.8
 674         AC_MSG_RESULT([Building fsck wrapper])
 675 fi]
 676 ,
 677 [case "$host_os" in
 678   gnu*)
 679     FSCK_PROG='' FSCK_MAN=''
 680     AC_MSG_RESULT([Not building fsck wrapper by default])
 681     ;;
 682   *)
 683     FSCK_PROG=fsck FSCK_MAN=fsck.8
 684     AC_MSG_RESULT([Building fsck wrapper by default])
 685 esac]
 686 )
 687 AC_SUBST(FSCK_PROG)
 688 AC_SUBST(FSCK_MAN)
 689 dnl
 690 dnl See whether to install the `e2initrd-helper' program
 691 dnl
 692 AC_ARG_ENABLE([e2initrd-helper],
 693 [  --enable-e2initrd-helper build e2initrd-helper program],
 694 [if test "$enableval" = "no"
 695 then
 696         E2INITRD_PROG='' E2INITRD_MAN=''
 697         AC_MSG_RESULT([Not building e2initrd helper])
 698 else
 699         E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 700         AC_MSG_RESULT([Building e2initrd helper])
 701 fi]
 702 ,
 703 E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 704 AC_MSG_RESULT([Building e2initrd helper by default])
 705 )
 706 AC_SUBST(E2INITRD_PROG)
 707 AC_SUBST(E2INITRD_MAN)
 708 dnl
 709 dnl
 710 dnl
 711 AC_ARG_ENABLE([tls],
 712 [  --disable-tls           disable use of thread local support],
 713 [if test "$enableval" = "no"
 714 then
 715         try_tls=""
 716         AC_MSG_RESULT([Disabling thread local support])
 717 else
 718         try_tls="yes"
 719         AC_MSG_RESULT([Enabling thread local support])
 720 fi]
 721 ,
 722 if test -n "$WITH_DIET_LIBC"
 723 then
 724         try_tls=""
 725         AC_MSG_RESULT([Diet libc does not support thread local support])
 726 else
 727         try_tls="yes"
 728         AC_MSG_RESULT([Try using thread local support by default])
 729 fi
 730 )
 731 if test "$try_tls" = "yes"
 732 then
 733 AX_TLS
 734 fi
 735 dnl
 736 dnl
 737 dnl
 738 AH_TEMPLATE([USE_UUIDD], [Define to 1 to build uuidd])
 739 AC_ARG_ENABLE([uuidd],
 740 [  --disable-uuidd         disable building the uuid daemon],
 741 [if test "$enableval" = "no"
 742 then
 743         AC_MSG_RESULT([Not building uuidd])
 744         UUIDD_CMT="#"
 745 else
 746         AC_DEFINE(USE_UUIDD, 1)
 747         UUIDD_CMT=""
 748         AC_MSG_RESULT([Building uuidd])
 749 fi]
 750 ,
 751 AC_DEFINE(USE_UUIDD, 1)
 752 if test -z "$UUID_CMT"
 753 then
 754         UUIDD_CMT=""
 755         AC_MSG_RESULT([Building uuidd by default])
 756 else
 757         UUIDD_CMT="#"
 758         AC_MSG_RESULT([Disabling uuidd by default])
 759 fi
 760 )
 761 AC_SUBST(UUIDD_CMT)
 762 dnl
 763 dnl handle --disable-mmp
 764 dnl
 765 AH_TEMPLATE([CONFIG_MMP], [Define to 1 to enable mmp support])
 766 AC_ARG_ENABLE([mmp],
 767 [  --disable-mmp           disable support mmp, Multi Mount Protection],
 768 if test "$enableval" = "no"
 769 then
 770         AC_MSG_RESULT([Disabling mmp support])
 771 else
 772         AC_MSG_RESULT([Enabling mmp support])
 773         AC_DEFINE(CONFIG_MMP, 1)
 774 fi
 775 ,
 776 AC_MSG_RESULT([Enabling mmp support by default])
 777 AC_DEFINE(CONFIG_MMP, 1)
 778 )
 779 dnl
 780 dnl handle --disable-bmap-stats
 781 dnl
 782 AH_TEMPLATE([ENABLE_BMAP_STATS], [Define to 1 to enable bitmap stats.])
 783 AC_ARG_ENABLE([bmap-stats],
 784 [  --disable-bmap-stats    disable collection of bitmap stats.],
 785 if test "$enableval" = "no"
 786 then
 787         AC_MSG_RESULT([Disabling bitmap statistics support])
 788 else
 789         AC_MSG_RESULT([Enabling bitmap statistics support])
 790         AC_DEFINE(ENABLE_BMAP_STATS, 1)
 791 fi
 792 ,
 793 AC_MSG_RESULT([Enabling bitmap statistics support by default])
 794 AC_DEFINE(ENABLE_BMAP_STATS, 1)
 795 )
 796 dnl
 797 dnl handle --enable-bmap-stats-ops
 798 dnl
 799 AH_TEMPLATE([ENABLE_BMAP_STATS_OPS], [Define to 1 to enable bitmap stats.])
 800 AC_ARG_ENABLE([bmap-stats-ops],
 801 [  --enable-bmap-stats-ops enable collection of additional bitmap stats],
 802 if test "$enableval" = "no"
 803 then
 804         AC_MSG_RESULT([Disabling additional bitmap statistics])
 805 else
 806         dnl There has to be a better way!
 807         AS_IF([test "x${enable_bmap_stats}" = "xno"],
 808          AC_MSG_FAILURE([Error --enable-bmap-stats-ops requires bmap-stats]))
 809
 810         AC_MSG_RESULT([Enabling additional bitmap statistics])
 811         AC_DEFINE(ENABLE_BMAP_STATS_OPS, 1)
 812 fi
 813 ,
 814 AC_MSG_RESULT([Disabling additional bitmap statistics by default])
 815 )
 816 dnl
 817 dnl
 818 dnl
 819 MAKEFILE_LIBRARY=$srcdir/lib/Makefile.library
 820 AC_SUBST_FILE(MAKEFILE_LIBRARY)
 821 dnl
 822 dnl Add internationalization support, using gettext.
 823 dnl
 824 GETTEXT_PACKAGE=e2fsprogs
 825 PACKAGE=e2fsprogs
 826 VERSION="$E2FSPROGS_VERSION"
 827 VERSION=0.14.1
 828 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [package name for gettext])
 829 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [version for gettext])
 830 AC_SUBST(GETTEXT_PACKAGE)
 831 AC_SUBST(PACKAGE)
 832 AC_SUBST(VERSION)
 833
 834 AM_GNU_GETTEXT
 835 dnl
 836 dnl End of configuration options
 837 dnl
 838 AC_SUBST(BINARY_TYPE)
 839 AC_PROG_MAKE_SET
 840 CHECK_GNU_MAKE
 841 AC_PATH_PROG(LN, ln, ln)
 842 AC_PROG_LN_S
 843 AC_PATH_PROG(MV, mv, mv)
 844 AC_PATH_PROG(CP, cp, cp)
 845 AC_PATH_PROG(RM, rm, rm)
 846 AC_PATH_PROG(CHMOD, chmod, :)
 847 AC_PROG_AWK
 848 AC_PROG_EGREP
 849 AC_PATH_PROG(SED, sed, sed)
 850 AC_PATH_PROG(PERL, perl, perl)
 851 AC_PATH_PROG(LDCONFIG, ldconfig, :)
 852 AC_CHECK_TOOL(AR, ar, ar)
 853 AC_CHECK_TOOL(RANLIB, ranlib, :)
 854 AC_CHECK_TOOL(STRIP, strip, :)
 855 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
 856 if test "_$MAKEINFO" = "_"; then
 857     MAKEINFO="@echo Makeinfo is missing. Info documentation will not be built.;true"
 858 else
 859     case "$MAKEINFO" in
 860       */missing.*)
 861         AC_MSG_WARN([
 862 *** Makeinfo is missing. Info documentation will not be built.])
 863         ;;
 864       *)
 865         ;;
 866     esac
 867 fi
 868 AC_SUBST(MAKEINFO)
 869 AC_PROG_INSTALL
 870 # See if we need a separate native compiler.
 871 if test $cross_compiling = no; then
 872   BUILD_CC="$CC"
 873   AC_SUBST(BUILD_CC)
 874 else
 875   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 876 fi
 877 AC_CHECK_HEADERS(m4_flatten([
 878         dirent.h
 879         errno.h
 880         execinfo.h
 881         getopt.h
 882         malloc.h
 883         mntent.h
 884         paths.h
 885         semaphore.h
 886         setjmp.h
 887         signal.h
 888         stdarg.h
 889         stdint.h
 890         stdlib.h
 891         termios.h
 892         termio.h
 893         unistd.h
 894         utime.h
 895         attr/xattr.h
 896         linux/falloc.h
 897         linux/fd.h
 898         linux/major.h
 899         linux/loop.h
 900         net/if_dl.h
 901         netinet/in.h
 902         sys/acl.h
 903         sys/disklabel.h
 904         sys/disk.h
 905         sys/file.h
 906         sys/ioctl.h
 907         sys/key.h
 908         sys/mkdev.h
 909         sys/mman.h
 910         sys/mount.h
 911         sys/prctl.h
 912         sys/resource.h
 913         sys/select.h
 914         sys/socket.h
 915         sys/sockio.h
 916         sys/stat.h
 917         sys/syscall.h
 918         sys/sysctl.h
 919         sys/sysmacros.h
 920         sys/time.h
 921         sys/types.h
 922         sys/un.h
 923         sys/wait.h
 924 ]))
 925 AC_CHECK_HEADERS(net/if.h,,,
 926 [[
 927 #if HAVE_SYS_TYPES_H
 928 #include <sys/types.h>
 929 #endif
 930 #if HAVE_SYS_SOCKET
 931 #include <sys/socket.h>
 932 #endif
 933 ]])
 934 AC_FUNC_VPRINTF
 935 dnl Check to see if dirent has member d_reclen. On cygwin those d_reclen
 936 dnl is not decleared.
 937 AC_CHECK_MEMBER(struct dirent.d_reclen,[AC_DEFINE(HAVE_RECLEN_DIRENT, 1,
 938                        [Define to 1 if dirent has d_reclen])],,
 939                 [#include <dirent.h>])
 940 AC_CHECK_MEMBERS([struct stat.st_atim])
 941 dnl Check to see if ssize_t was declared
 942 AC_CHECK_TYPE(ssize_t,[AC_DEFINE(HAVE_TYPE_SSIZE_T, 1,
 943                 [Define to 1 if ssize_t declared])],,
 944               [#include <sys/types.h>])
 945 dnl
 946 dnl Check to see if llseek() is declared in unistd.h.  On some libc's
 947 dnl it is, and on others it isn't..... Thank you glibc developers....
 948 dnl
 949 AC_CHECK_DECL(llseek,[AC_DEFINE(HAVE_LLSEEK_PROTOTYPE, 1,
 950                         [Define to 1 if llseek declared in unistd.h])],,
 951               [#include <unistd.h>])
 952 dnl
 953 dnl Check to see if lseek64() is declared in unistd.h.  Glibc's header files
 954 dnl are so convoluted that I can't tell whether it will always be defined,
 955 dnl and if it isn't defined while lseek64 is defined in the library,
 956 dnl disaster will strike.
 957 dnl
 958 dnl Warning!  Use of --enable-gcc-wall may throw off this test.
 959 dnl
 960 dnl
 961 AC_CHECK_DECL(lseek64,[AC_DEFINE(HAVE_LSEEK64_PROTOTYPE, 1,
 962                         [Define to 1 if lseek64 declared in unistd.h])],,
 963                 [#define _LARGEFILE_SOURCE
 964                  #define _LARGEFILE64_SOURCE
 965                  #include <unistd.h>])
 966 dnl
 967 dnl Word sizes...
 968 dnl
 969 AC_CHECK_SIZEOF(short)
 970 AC_CHECK_SIZEOF(int)
 971 AC_CHECK_SIZEOF(long)
 972 AC_CHECK_SIZEOF(long long)
 973 AC_CHECK_SIZEOF(off_t)
 974 AC_CHECK_SIZEOF(time_t)
 975 SIZEOF_SHORT=$ac_cv_sizeof_short
 976 SIZEOF_INT=$ac_cv_sizeof_int
 977 SIZEOF_LONG=$ac_cv_sizeof_long
 978 SIZEOF_LONG_LONG=$ac_cv_sizeof_long_long
 979 SIZEOF_OFF_T=$ac_cv_sizeof_off_t
 980 SIZEOF_TIME_T=$ac_cv_sizeof_time_t
 981 AC_SUBST(SIZEOF_SHORT)
 982 AC_SUBST(SIZEOF_INT)
 983 AC_SUBST(SIZEOF_LONG)
 984 AC_SUBST(SIZEOF_LONG_LONG)
 985 AC_SUBST(SIZEOF_OFF_T)
 986 AC_SUBST(SIZEOF_TIME_T)
 987 AC_C_BIGENDIAN
 988 if test $cross_compiling = no; then
 989   BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
 990 else
 991   CROSS_COMPILE="1" BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
 992 fi
 993 ASM_TYPES_HEADER=./asm_types.h
 994 AC_SUBST_FILE(ASM_TYPES_HEADER)
 995 dnl
 996 dnl Save the configuration #defines needed for the public ext2fs.h
 997 dnl header file
 998 dnl
 999 echo "/* These defines are needed for the public ext2fs.h header file */" \
1000      > public_config.h
1001 if grep HAVE_SYS_TYPES_H confdefs.h > tmp_config.$$; then
1002   uniq tmp_config.$$ >> public_config.h
1003 else
1004   echo "#undef HAVE_SYS_TYPES_H" >> public_config.h
1005 fi
1006 if grep WORDS_BIGENDIAN confdefs.h > tmp_config.$$; then
1007   uniq tmp_config.$$ >> public_config.h
1008 else
1009   echo "#undef WORDS_BIGENDIAN" >> public_config.h
1010 fi
1011 rm -f tmp_config.$$
1012 PUBLIC_CONFIG_HEADER=./public_config.h
1013 AC_SUBST_FILE(PUBLIC_CONFIG_HEADER)
1014 dnl
1015 dnl See if we have inttypes.h and if intptr_t is defined
1016 dnl
1017 AC_CHECK_HEADERS([inttypes.h])
1018 AC_CHECK_TYPES(intptr_t)
1019 dnl
1020 dnl See if struct stat has a st_flags field, in which case we can get file
1021 dnl flags somewhat portably.  Also check for the analogous setter, chflags().
1022 dnl
1023 AC_MSG_CHECKING(whether struct stat has a st_flags field)
1024 AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags,
1025         AC_TRY_COMPILE([#include <sys/stat.h>],
1026                 [struct stat stat; stat.st_flags = 0;],
1027                 [e2fsprogs_cv_struct_st_flags=yes],
1028                 [e2fsprogs_cv_struct_st_flags=no]))
1029 AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags)
1030 if test "$e2fsprogs_cv_struct_st_flags" = yes; then
1031   AC_MSG_CHECKING(whether st_flags field is useful)
1032   AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags_immut,
1033         AC_TRY_COMPILE([#include <sys/stat.h>],
1034                 [struct stat stat; stat.st_flags |= UF_IMMUTABLE;],
1035                 [e2fsprogs_cv_struct_st_flags_immut=yes],
1036                 [e2fsprogs_cv_struct_st_flags_immut=no]))
1037   AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags_immut)
1038   if test "$e2fsprogs_cv_struct_st_flags_immut" = yes; then
1039           AC_DEFINE(HAVE_STAT_FLAGS, 1,
1040                 [Define to 1 if struct stat has st_flags])
1041   fi
1042 fi
1043 dnl
1044 dnl Check for the presence of SA_LEN
1045 dnl
1046 AC_CHECK_MEMBER(struct sockaddr.sa_len,
1047                 AC_DEFINE_UNQUOTED(HAVE_SA_LEN,1,
1048                         [Define to 1 if if struct sockaddr contains sa_len]),,
1049         [#include <sys/types.h>
1050          #include <sys/socket.h>])
1051 dnl
1052 dnl This will add -lblkid to the AC_CHECK_FUNCS search if we are using
1053 dnl the system-provided blkid library
1054 dnl
1055 if test -n "$BLKID_CMT"; then
1056   AC_SEARCH_LIBS([blkid_probe_all], [blkid])
1057 fi
1058 dnl
1059 AC_CHECK_FUNCS(m4_flatten([
1060         __secure_getenv
1061         add_key
1062         backtrace
1063         blkid_probe_get_topology
1064         blkid_probe_enable_partitions
1065         chflags
1066         fadvise64
1067         fallocate
1068         fallocate64
1069         fchown
1070         fdatasync
1071         fstat64
1072         ftruncate64
1073         futimes
1074         getcwd
1075         getdtablesize
1076         getmntinfo
1077         getpwuid_r
1078         getrlimit
1079         getrusage
1080         jrand48
1081         keyctl
1082         llistxattr
1083         llseek
1084         lseek64
1085         mallinfo
1086         mbstowcs
1087         memalign
1088         mempcpy
1089         mmap
1090         msync
1091         nanosleep
1092         open64
1093         pathconf
1094         posix_fadvise
1095         posix_fadvise64
1096         posix_memalign
1097         prctl
1098         pread
1099         pwrite
1100         pread64
1101         pwrite64
1102         secure_getenv
1103         setmntent
1104         setresgid
1105         setresuid
1106         snprintf
1107         srandom
1108         stpcpy
1109         strcasecmp
1110         strdup
1111         strnlen
1112         strptime
1113         strtoull
1114         sync_file_range
1115         sysconf
1116         usleep
1117         utime
1118         utimes
1119         valloc
1120 ]))
1121 dnl
1122 dnl Check to see if -lsocket is required (solaris) to make something
1123 dnl that uses socket() to compile; this is needed for the UUID library
1124 dnl
1125 SOCKET_LIB=''
1126 AC_CHECK_LIB(socket, socket, [SOCKET_LIB=-lsocket])
1127 AC_SUBST(SOCKET_LIB)
1128 dnl
1129 dnl See if libmagic exists
1130 dnl
1131 AC_CHECK_LIB(magic, magic_file, [MAGIC_LIB=-lmagic
1132 AC_CHECK_HEADERS([magic.h])])
1133 if test "$ac_cv_lib_dl_dlopen" = yes ; then
1134    MAGIC_LIB=$DLOPEN_LIB
1135 fi
1136 AC_SUBST(MAGIC_LIB)
1137 dnl
1138 dnl Check to see if the FUSE library is -lfuse or -losxfuse
1139 dnl
1140 FUSE_CMT=
1141 FUSE_LIB=
1142 dnl osxfuse.dylib supersedes fuselib.dylib
1143 AC_ARG_ENABLE([fuse2fs],
1144 [  --disable-fuse2fs      do not build fuse2fs],
1145 if test "$enableval" = "no"
1146 then
1147         FUSE_CMT="#"
1148         AC_MSG_RESULT([Disabling fuse2fs])
1149 else
1150         AC_CHECK_HEADERS([pthread.h fuse.h], [],
1151 [AC_MSG_FAILURE([Cannot find fuse2fs headers.])],
1152 [#define _FILE_OFFSET_BITS      64
1153 #define FUSE_USE_VERSION 29])
1154
1155         AC_PREPROC_IFELSE(
1156 [AC_LANG_PROGRAM([[#define FUSE_USE_VERSION 29
1157 #ifdef __linux__
1158 #include <linux/fs.h>
1159 #include <linux/falloc.h>
1160 #include <linux/xattr.h>
1161 #endif
1162 ]], [])], [], [AC_MSG_FAILURE([Cannot find fuse2fs Linux headers.])])
1163
1164         AC_CHECK_LIB(osxfuse, fuse_main, [FUSE_LIB=-losxfuse],
1165                 [AC_CHECK_LIB(fuse, fuse_main, [FUSE_LIB=-lfuse],
1166                               [AC_MSG_FAILURE([Cannot find fuse library.])])])
1167         AC_MSG_RESULT([Enabling fuse2fs])
1168 fi
1169 ,
1170 AC_CHECK_HEADERS([pthread.h fuse.h], [], [FUSE_CMT="#"],
1171 [#define _FILE_OFFSET_BITS      64
1172 #define FUSE_USE_VERSION 29
1173 #ifdef __linux__
1174 # include <linux/fs.h>
1175 # include <linux/falloc.h>
1176 # include <linux/xattr.h>
1177 #endif])
1178 if test -z "$FUSE_CMT"
1179 then
1180         AC_CHECK_LIB(osxfuse, fuse_main, [FUSE_LIB=-losxfuse],
1181 [AC_CHECK_LIB(fuse, fuse_main, [FUSE_LIB=-lfuse], [FUSE_CMT="#"])])
1182 fi
1183 if test -z "$FUSE_CMT"
1184 then
1185         AC_MSG_RESULT([Enabling fuse2fs by default.])
1186 fi
1187 )
1188 AC_SUBST(FUSE_LIB)
1189 AC_SUBST(FUSE_CMT)
1190 dnl
1191 dnl See if optreset exists
1192 dnl
1193 AC_MSG_CHECKING(for optreset)
1194 AC_CACHE_VAL(ac_cv_have_optreset,
1195 [AC_EGREP_HEADER(optreset, unistd.h,
1196   ac_cv_have_optreset=yes, ac_cv_have_optreset=no)])dnl
1197 AC_MSG_RESULT($ac_cv_have_optreset)
1198 if test $ac_cv_have_optreset = yes; then
1199   AC_DEFINE(HAVE_OPTRESET, 1, [Define to 1 if optreset for getopt is present])
1200 fi
1201 dnl
1202 dnl Test for sem_init, and which library it might require:
1203 dnl
1204 AH_TEMPLATE([HAVE_SEM_INIT], [Define to 1 if sem_init() exists])
1205 SEM_INIT_LIB=''
1206 AC_CHECK_FUNC(sem_init, ,
1207   AC_CHECK_LIB(pthread, sem_init,
1208         AC_DEFINE(HAVE_SEM_INIT, 1)
1209         SEM_INIT_LIB=-lpthread,
1210   AC_CHECK_LIB(rt, sem_init,
1211         AC_DEFINE(HAVE_SEM_INIT, 1)
1212         SEM_INIT_LIB=-lrt,
1213   AC_CHECK_LIB(posix4, sem_init,
1214         AC_DEFINE(HAVE_SEM_INIT, 1)
1215         SEM_INIT_LIB=-lposix4))))dnl
1216 AC_SUBST(SEM_INIT_LIB)
1217 dnl
1218 dnl Check for unified diff
1219 dnl
1220 AC_MSG_CHECKING(for unified diff option)
1221 if diff -u $0 $0 > /dev/null 2>&1 ; then
1222    UNI_DIFF_OPTS=-u
1223 else
1224    UNI_DIFF_OPTS=-c
1225 fi
1226 AC_MSG_RESULT($UNI_DIFF_OPTS)
1227 AC_SUBST(UNI_DIFF_OPTS)
1228 dnl
1229 dnl We use the EXT2 ioctls only under Linux
1230 dnl
1231 case "$host_os" in
1232 linux*)
1233         AC_DEFINE(HAVE_EXT2_IOCTLS, 1, [Define to 1 if Ext2 ioctls present])
1234         ;;
1235 esac
1236 dnl
1237 dnl OS-specific uncomment control
1238 dnl
1239 LINUX_CMT="#"
1240 CYGWIN_CMT="#"
1241 UNIX_CMT=
1242 case "$host_os" in
1243 linux*)
1244         LINUX_CMT=
1245         ;;
1246 cygwin)
1247         CYGWIN_CMT=
1248         UNIX_CMT="#"
1249         ;;
1250 esac
1251 AC_SUBST(LINUX_CMT)
1252 AC_SUBST(CYGWIN_CMT)
1253 AC_SUBST(UNIX_CMT)
1254 dnl
1255 dnl Linux and Hurd places root files in the / by default
1256 dnl
1257 case "$host_os" in
1258 linux* | gnu* | k*bsd*-gnu)
1259         if test "$prefix" = NONE -a "$root_prefix" = NONE ; then
1260                 root_prefix="";
1261                 AC_MSG_RESULT([On $host_os systems, root_prefix defaults to ''])
1262         fi
1263         ;;
1264 esac
1265 dnl
1266 dnl On Linux/hurd, force the prefix to be /usr
1267 dnl
1268 case "$host_os" in
1269 linux* | gnu* | k*bsd*-gnu)
1270         if test "$prefix" = NONE ; then
1271                 prefix="/usr";
1272                 AC_MSG_RESULT([On $host_os systems, prefix defaults to /usr])
1273                 if test "$mandir" = '${prefix}/man' ; then
1274                         AC_MSG_RESULT([...and mandir defaults to /usr/share/man])
1275                         mandir=/usr/share/man
1276                 fi
1277         fi
1278 ;;
1279 esac
1280 if test "$root_prefix" = NONE ; then
1281         if test "$prefix" = NONE ; then
1282                 root_prefix="$ac_default_prefix"
1283         else
1284                 root_prefix="$prefix"
1285         fi
1286         root_bindir=$bindir
1287         root_sbindir=$sbindir
1288         root_libdir=$libdir
1289         root_sysconfdir=$sysconfdir
1290 else
1291         root_bindir='${root_prefix}/bin'
1292         root_sbindir='${root_prefix}/sbin'
1293         root_libdir='${root_prefix}/lib'
1294         root_sysconfdir='${root_prefix}/etc'
1295 fi
1296 if test "$bindir" != '${exec_prefix}/bin'; then
1297     root_bindir=$bindir
1298     AC_MSG_RESULT([Setting root_bindir to $root_bindir])
1299 fi
1300 if test "$sbindir" != '${exec_prefix}/sbin'; then
1301     root_sbindir=$sbindir
1302     AC_MSG_RESULT([Setting root_sbindir to $root_sbindir])
1303 fi
1304 if test "$libdir" != '${exec_prefix}/lib'; then
1305     root_libdir=$libdir
1306     AC_MSG_RESULT([Setting root_libdir to $root_libdir])
1307 fi
1308 if test "$sysconfdir" != '${prefix}/etc'; then
1309     root_sysconfdir=$sysconfdir
1310     AC_MSG_RESULT([Setting root_sysconfdir to $root_sysconfdir])
1311 fi
1312 AC_SUBST(root_prefix)
1313 AC_SUBST(root_bindir)
1314 AC_SUBST(root_sbindir)
1315 AC_SUBST(root_libdir)
1316 AC_SUBST(root_sysconfdir)
1317 dnl
1318 dnl Allow specification of the multiarch arch
1319 dnl
1320 AC_ARG_WITH([multiarch],
1321 [  --with-multiarch=ARCH specify the multiarch triplet],
1322 if test "$withval" = "lib64"; then
1323     libdir=/usr/lib64
1324     root_libdir=/lib64
1325 else
1326     libdir=$libdir/$withval
1327     root_libdir=$root_libdir/$withval
1328 fi
1329 )dnl
1330 dnl
1331 dnl See if -static works.  This could fail if the linker does not
1332 dnl support -static, or if required external libraries are not available
1333 dnl in static form.
1334 dnl
1335 AC_MSG_CHECKING([whether we can link with -static])
1336 AC_CACHE_VAL(ac_cv_e2fsprogs_use_static,
1337 [SAVE_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS_STATIC -static"
1338 AC_TRY_LINK([#include <stdio.h>],[fflush(stdout);],
1339  ac_cv_e2fsprogs_use_static=yes, ac_cv_e2fsprogs_use_static=no)
1340 LDFLAGS=$SAVE_LDFLAGS])
1341 dnl
1342 dnl Regardless of how the test turns out, Solaris doesn't handle -static
1343 dnl This is caused by the socket library requiring the nsl library, which
1344 dnl requires the -dl library, which only works for dynamically linked
1345 dnl programs.  It basically means you can't have statically linked programs
1346 dnl which use the network under Solaris.
1347 dnl
1348 case "$host_os" in
1349 solaris2.*)
1350         ac_cv_e2fsprogs_use_static=no
1351 ;;
1352 esac
1353 AC_MSG_RESULT($ac_cv_e2fsprogs_use_static)
1354 if test $ac_cv_e2fsprogs_use_static = yes; then
1355         LDFLAGS_STATIC="$LDFLAGS_STATIC -static"
1356 fi
1357 AC_SUBST(LDFLAGS_STATIC)
1358 dnl
1359 dnl Work around mysterious Darwin / GNU libintl problem
1360 dnl (__asm__ redirection doesn't work for some mysterious reason.  Looks like
1361 dnl Apple hacked gcc somehow?)
1362 dnl
1363 case "$host_os" in
1364 darwin*)
1365         AC_MSG_RESULT([Using Apple Darwin / GNU libintl workaround])
1366         AC_DEFINE(_INTL_REDIRECT_MACROS, 1,
1367                 [Define to 1 if Apple Darwin libintl workaround is needed])
1368         ;;
1369 esac
1370 dnl
1371 dnl Make the ss and et directories work correctly.
1372 dnl
1373 SS_DIR=`cd ${srcdir}/lib/ss; pwd`
1374 ET_DIR=`cd ${srcdir}/lib/et; pwd`
1375 AC_SUBST(SS_DIR)
1376 AC_SUBST(ET_DIR)
1377 dnl
1378 dnl Only try to run the test suite if we're not cross compiling.
1379 dnl
1380 if test "$cross_compiling" = yes ; then
1381   DO_TEST_SUITE=
1382 else
1383   DO_TEST_SUITE=check
1384 fi
1385 AC_SUBST(DO_TEST_SUITE)
1386 dnl
1387 dnl Only include the intl include files if we're building with them
1388 dnl
1389 INCLUDES='-I. -I$(top_builddir)/lib -I$(top_srcdir)/lib'
1390 if test -n "$CPPFLAGS" ; then
1391         INCLUDES="$INCLUDES $CPPFLAGS"
1392 fi
1393 if test "$USE_INCLUDED_LIBINTL" = "yes" ; then
1394         INCLUDES=$INCLUDES' -I$(top_builddir)/intl -I$(top_srcdir)/intl'
1395 fi
1396 if test -n "$WITH_DIET_LIBC" ; then
1397         INCLUDES="$INCLUDES -D_REENTRANT"
1398 fi
1399 AC_SUBST(INCLUDES)
1400 AM_MKINSTALLDIRS
1401 dnl
1402 dnl Build CFLAGS
1403 dnl
1404 if test $cross_compiling = no; then
1405    BUILD_CFLAGS="$CFLAGS $CPPFLAGS $INCLUDES -DHAVE_CONFIG_H"
1406    BUILD_LDFLAGS="$LDFLAGS"
1407 fi
1408 AC_SUBST(BUILD_CFLAGS)
1409 AC_SUBST(BUILD_LDFLAGS)
1410 dnl
1411 dnl Define CFLAGS and LDFLAGS for shared libraries
1412 dnl
1413 CFLAGS_SHLIB=${CFLAGS_SHLIB:-$CFLAGS}
1414 CFLAGS_STLIB=${CFLAGS_STLIB:-$CFLAGS}
1415 LDFLAGS_SHLIB=${LDFLAGS_SHLIB:-$LDFLAGS}
1416 AC_SUBST(CFLAGS_SHLIB)
1417 AC_SUBST(CFLAGS_STLIB)
1418 AC_SUBST(LDFLAGS_SHLIB)
1419 dnl
1420 dnl Make our output files, being sure that we create the some miscellaneous
1421 dnl directories
1422 dnl
1423 test -d lib || mkdir lib
1424 test -d include || mkdir include
1425 test -d include/linux || mkdir include/linux
1426 test -d include/asm || mkdir include/asm
1427 if test -z "$UUID_CMT" ; then
1428         uuid_out_list="lib/uuid/Makefile lib/uuid/uuid.pc \
1429                 lib/uuid/uuid_types.h"
1430 fi
1431 if test -z "$BLKID_CMT" ; then
1432         blkid_out_list="lib/blkid/Makefile lib/blkid/blkid.pc \
1433                 lib/blkid/blkid_types.h"
1434 fi
1435 for i in MCONFIG Makefile e2fsprogs.spec \
1436         util/Makefile util/subst.conf util/gen-tarball util/install-symlink \
1437         lib/et/Makefile lib/ss/Makefile lib/e2p/Makefile \
1438         lib/ext2fs/Makefile lib/ext2fs/ext2_types.h \
1439         $uuid_out_list $blkid_out_list lib/support/Makefile \
1440         lib/ss/ss.pc lib/et/com_err.pc lib/e2p/e2p.pc lib/ext2fs/ext2fs.pc \
1441         misc/Makefile ext2ed/Makefile e2fsck/Makefile \
1442         debugfs/Makefile tests/Makefile tests/progs/Makefile \
1443         resize/Makefile doc/Makefile intl/Makefile \
1444         intl/libgnuintl.h po/Makefile.in ; do
1445         if test -d `dirname ${srcdir}/$i` ; then
1446                 outlist="$outlist $i"
1447         fi
1448 done
1449 AC_OUTPUT($outlist)
1450 if test -f util/gen-tarball; then chmod +x util/gen-tarball; fi