configure.ac

   1 AC_INIT(version.h)
   2 AC_PREREQ(2.54)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_HEADERS([lib/config.h])
   5 AH_BOTTOM([#include <dirpaths.h>])
   6 MCONFIG=./MCONFIG
   7 AC_SUBST_FILE(MCONFIG)
   8 BINARY_TYPE=bin
   9 dnl
  10 dnl This is to figure out the version number and the date....
  11 dnl
  12 E2FSPROGS_VERSION=`grep E2FSPROGS_VERSION ${srcdir}/version.h  \
  13         | awk '{print $3}' | tr \" " " | awk '{print $1}'`
  14 DATE=`grep E2FSPROGS_DATE ${srcdir}/version.h | awk '{print $3}' \
  15         | tr \" " "`
  16 E2FSPROGS_DAY=$(echo $DATE | awk -F- '{print $1}' | sed -e '/^[[1-9]]$/s/^/0/')
  17 MONTH=`echo $DATE | awk -F- '{print $2}'`
  18 YEAR=`echo $DATE | awk -F- '{print $3}'`
  19
  20 if expr $YEAR ">" 1900 > /dev/null ; then
  21         E2FSPROGS_YEAR=$YEAR
  22 elif expr $YEAR ">" 90 >/dev/null ; then
  23         E2FSPROGS_YEAR=19$YEAR
  24 else
  25         E2FSPROGS_YEAR=20$YEAR
  26 fi
  27
  28 case $MONTH in
  29 Jan)    MONTH_NUM=01; E2FSPROGS_MONTH="January" ;;
  30 Feb)    MONTH_NUM=02; E2FSPROGS_MONTH="February" ;;
  31 Mar)    MONTH_NUM=03; E2FSPROGS_MONTH="March" ;;
  32 Apr)    MONTH_NUM=04; E2FSPROGS_MONTH="April" ;;
  33 May)    MONTH_NUM=05; E2FSPROGS_MONTH="May" ;;
  34 Jun)    MONTH_NUM=06; E2FSPROGS_MONTH="June" ;;
  35 Jul)    MONTH_NUM=07; E2FSPROGS_MONTH="July" ;;
  36 Aug)    MONTH_NUM=08; E2FSPROGS_MONTH="August" ;;
  37 Sep)    MONTH_NUM=09; E2FSPROGS_MONTH="September" ;;
  38 Oct)    MONTH_NUM=10; E2FSPROGS_MONTH="October" ;;
  39 Nov)    MONTH_NUM=11; E2FSPROGS_MONTH="November" ;;
  40 Dec)    MONTH_NUM=12; E2FSPROGS_MONTH="December" ;;
  41 *)      AC_MSG_WARN([Unknown month $MONTH??]) ;;
  42 esac
  43
  44 base_ver=`echo $E2FSPROGS_VERSION | \
  45                sed -e 's/-WIP//' -e 's/pre-//' -e 's/-PLUS//'`
  46
  47 date_spec=${E2FSPROGS_YEAR}.${MONTH_NUM}.${E2FSPROGS_DAY}
  48
  49 case $E2FSPROGS_VERSION in
  50 *-WIP|pre-*)
  51         E2FSPROGS_PKGVER="$base_ver~WIP.$date_spec"
  52         ;;
  53 *)
  54         E2FSPROGS_PKGVER="$base_ver"
  55         ;;
  56 esac
  57
  58 unset DATE MONTH YEAR base_ver pre_vers date_spec
  59 AC_MSG_RESULT([Generating configuration file for e2fsprogs version $E2FSPROGS_VERSION])
  60 AC_MSG_RESULT([Release date is ${E2FSPROGS_MONTH}, ${E2FSPROGS_YEAR}])
  61 AC_SUBST(E2FSPROGS_YEAR)
  62 AC_SUBST(E2FSPROGS_MONTH)
  63 AC_SUBST(E2FSPROGS_DAY)
  64 AC_SUBST(E2FSPROGS_VERSION)
  65 AC_SUBST(E2FSPROGS_PKGVER)
  66 dnl
  67 dnl Use diet libc
  68 dnl
  69 WITH_DIET_LIBC=
  70 AC_ARG_WITH([diet-libc],
  71 [  --with-diet-libc        use diet libc],
  72 CC="diet cc -nostdinc"
  73 WITH_DIET_LIBC=yes
  74 if test -z "$LIBS"
  75 then
  76         LIBS="-lcompat"
  77 else
  78         LIBS="$LIBS -lcompat"
  79 fi
  80 AC_MSG_RESULT(CC=$CC))dnl
  81 dnl
  82 AC_CANONICAL_HOST
  83 dnl
  84 dnl Check to see if libdl exists for the sake of dlopen
  85 dnl
  86 DLOPEN_LIB=''
  87 AC_CHECK_LIB(dl, dlopen,DLOPEN_LIB=-ldl)
  88 AC_SUBST(DLOPEN_LIB)
  89 dnl
  90 AC_ARG_WITH([cc],
  91 AC_HELP_STRING([--with-cc],[no longer supported, use CC= instead]),
  92 AC_MSG_ERROR([--with-cc no longer supported; use CC= instead]))
  93 dnl
  94 AC_ARG_WITH([ccopts],
  95 AC_HELP_STRING([--with-ccopts],[no longer supported, use CFLAGS= instead]),
  96 AC_MSG_ERROR([--with-ccopts no longer supported; use CFLAGS= instead]))
  97 dnl
  98 AC_ARG_WITH([ldopts],
  99 AC_HELP_STRING([--with-ldopts],[no longer supported, use LDFLAGS= instead]),
 100 AC_MSG_ERROR([--with-ldopts no longer supported; use LDFLAGS= instead]))
 101 dnl
 102 AC_PROG_CC
 103 if test "$GCC" = yes; then
 104    RDYNAMIC="-rdynamic"
 105    AC_SUBST(RDYNAMIC)
 106 fi
 107 AC_PROG_CPP
 108 dnl
 109 dnl Alpha computers use fast and imprecise floating point code that may
 110 dnl miss exceptions by default. Force sane options if we're using GCC.
 111 AC_MSG_CHECKING(for additional special compiler flags)
 112 if test "$GCC" = yes
 113 then
 114     case "$host_cpu" in
 115         alpha)          addcflags="-mieee" ;;
 116     esac
 117 fi
 118 if test "x$addcflags" != x
 119 then
 120     AC_MSG_RESULT($addcflags)
 121     CFLAGS="$addcflags $CFLAGS"
 122 else
 123     AC_MSG_RESULT([[(none)]])
 124 fi
 125 AC_USE_SYSTEM_EXTENSIONS
 126 dnl
 127 dnl Set default values for library extensions.  Will be dealt with after
 128 dnl parsing configuration options, which may modify these
 129 dnl
 130 LIB_EXT=.a
 131 STATIC_LIB_EXT=.a
 132 PROFILED_LIB_EXT=.a
 133 dnl
 134 dnl Allow separate `root_prefix' to be specified
 135 dnl
 136 AC_ARG_WITH([root-prefix],
 137 [  --with-root-prefix=PREFIX override prefix variable for files to be placed in the root],
 138 root_prefix=$withval,
 139 root_prefix=NONE)dnl
 140 dnl
 141 dnl handle --enable-maintainer-mode
 142 dnl
 143 AC_ARG_ENABLE([maintainer-mode],
 144 [  --enable-maintainer-mode enable makefile rules useful for maintainers],
 145 if test "$enableval" = "no"
 146 then
 147         MAINTAINER_CMT=#
 148         AC_MSG_RESULT([Disabling maintainer mode])
 149 else
 150         MAINTAINER_CMT=
 151         AC_MSG_RESULT([Enabling maintainer mode])
 152 fi
 153 ,
 154 MAINTAINER_CMT=#
 155 AC_MSG_RESULT([Disabling maintainer mode by default])
 156 )
 157 AC_SUBST(MAINTAINER_CMT)
 158 dnl
 159 dnl handle --enable-symlink-install
 160 dnl
 161 AC_ARG_ENABLE([symlink-install],
 162 [  --enable-symlink-install use symlinks when installing instead of hard links],
 163 if test "$enableval" = "no"
 164 then
 165         LINK_INSTALL_FLAGS=-f
 166         AC_MSG_RESULT([Disabling symlinks for install])
 167 else
 168         LINK_INSTALL_FLAGS=-sf
 169         AC_MSG_RESULT([Enabling symlinks for install])
 170 fi
 171 ,
 172 LINK_INSTALL_FLAGS=-f
 173 AC_MSG_RESULT([Disabling symlinks for install by default])
 174 )
 175 AC_SUBST(LINK_INSTALL_FLAGS)
 176 dnl
 177 dnl handle --enable-relative-symlinks
 178 dnl
 179 relative_symlink_defined=
 180 AC_ARG_ENABLE([relative-symlinks],
 181 [  --enable-relative-symlinks use relative symlinks when installing],
 182 if test "$enableval" = "no"
 183 then
 184         SYMLINK_RELATIVE=
 185         relative_symlink_defined=yes
 186         AC_MSG_RESULT([Disabling relative symlinks for install])
 187 else
 188         SYMLINK_RELATIVE=--relative
 189         relative_symlink_defined=yes
 190         AC_MSG_RESULT([Enabling relative symlinks for install])
 191 fi)
 192 AC_ARG_ENABLE([symlink-relative-symlinks],,
 193 if test "$enableval" = "no"
 194 then
 195         SYMLINK_RELATIVE=yes
 196         AC_MSG_RESULT([Disabling relative symlinks for install])
 197 else
 198         SYMLINK_RELATIVE=--relative
 199         AC_MSG_RESULT([Enabling relative symlinks for install])
 200 fi
 201 ,
 202 if test -z "$relative_symlink_defined"
 203 then
 204         SYMLINK_RELATIVE=
 205 AC_MSG_RESULT([Disabling relative symlinks for install by default])
 206 fi
 207 )
 208 AC_SUBST(SYMLINK_RELATIVE)
 209 dnl
 210 dnl handle --enable-symlink-build
 211 dnl
 212 AC_ARG_ENABLE([symlink-build],
 213 [  --enable-symlink-build  use symlinks while building instead of hard links],
 214 if test "$enableval" = "no"
 215 then
 216         LINK_BUILD_FLAGS=
 217         AC_MSG_RESULT([Disabling symlinks for build])
 218 else
 219         LINK_BUILD_FLAGS=-s
 220         AC_MSG_RESULT([Enabling symlinks for build])
 221 fi
 222 ,
 223 LINK_BUILD_FLAGS=
 224 AC_MSG_RESULT([Disabling symlinks for build by default])
 225 )
 226 AC_SUBST(LINK_BUILD_FLAGS)
 227 dnl
 228 dnl handle --enable-verbose-makecmds
 229 dnl
 230 AC_ARG_ENABLE([verbose-makecmds],
 231 [  --enable-verbose-makecmds enable verbose make command output],
 232 if test "$enableval" = "no"
 233 then
 234         AC_MSG_RESULT([Disabling verbose make commands])
 235         E=@echo
 236         ES=echo
 237         Q=@
 238 else
 239         AC_MSG_RESULT([Enabling verbose make commands])
 240         E=@\\#
 241         ES=\\#
 242         Q=
 243 fi
 244 ,
 245 AC_MSG_RESULT([Disabling verbose make commands])
 246 E=@echo
 247 ES=echo
 248 Q=@
 249 )
 250 AC_SUBST(E)
 251 AC_SUBST(ES)
 252 AC_SUBST(Q)
 253 dnl
 254 dnl This needs to be before all of the --enable-*-shlibs options
 255 dnl
 256 E2_PKG_CONFIG_STATIC=--static
 257 LDFLAG_DYNAMIC=
 258 PRIVATE_LIBS_CMT=
 259 dnl
 260 dnl handle --enable-elf-shlibs
 261 dnl
 262 AC_ARG_ENABLE([elf-shlibs],
 263 [  --enable-elf-shlibs    select ELF shared libraries],
 264 if test "$enableval" = "no"
 265 then
 266         ELF_CMT=#
 267         MAKEFILE_ELF=/dev/null
 268         AC_MSG_RESULT([Disabling ELF shared libraries])
 269 else
 270         E2_PKG_CONFIG_STATIC=
 271         ELF_CMT=
 272         MAKEFILE_ELF=$srcdir/lib/Makefile.elf-lib
 273         [case "$host_os" in
 274         solaris2.*)
 275                 MAKEFILE_ELF=$srcdir/lib/Makefile.solaris-lib
 276         ;;
 277         esac]
 278         BINARY_TYPE=elfbin
 279         LIB_EXT=.so
 280         PRIVATE_LIBS_CMT=#
 281         LDFLAG_DYNAMIC=['-Wl,-rpath-link,$(top_builddir)/lib']
 282         AC_MSG_RESULT([Enabling ELF shared libraries])
 283 fi
 284 ,
 285 MAKEFILE_ELF=/dev/null
 286 ELF_CMT=#
 287 AC_MSG_RESULT([Disabling ELF shared libraries by default])
 288 )
 289 AC_SUBST(ELF_CMT)
 290 AC_SUBST_FILE(MAKEFILE_ELF)
 291 dnl
 292 dnl handle --enable-bsd-shlibs
 293 dnl
 294 AC_ARG_ENABLE([bsd-shlibs],
 295 [  --enable-bsd-shlibs    select BSD shared libraries],
 296 if test "$enableval" = "no"
 297 then
 298         BSDLIB_CMT=#
 299         MAKEFILE_BSDLIB=/dev/null
 300         AC_MSG_RESULT([Disabling BSD shared libraries])
 301 else
 302         E2_PKG_CONFIG_STATIC=
 303         BSDLIB_CMT=
 304         MAKEFILE_BSDLIB=$srcdir/lib/Makefile.bsd-lib
 305         LIB_EXT=.so
 306         [case "$host_os" in
 307         darwin*)
 308                 MAKEFILE_BSDLIB=$srcdir/lib/Makefile.darwin-lib
 309                 LIB_EXT=.dylib
 310         ;;
 311         esac]
 312         AC_MSG_RESULT([Enabling BSD shared libraries])
 313 fi
 314 ,
 315 MAKEFILE_BSDLIB=/dev/null
 316 BSDLIB_CMT=#
 317 AC_MSG_RESULT([Disabling BSD shared libraries by default])
 318 )
 319 AC_SUBST(BSDLIB_CMT)
 320 AC_SUBST_FILE(MAKEFILE_BSDLIB)
 321 dnl
 322 dnl handle --enable-profile
 323 dnl
 324 AC_ARG_ENABLE([profile],
 325 [  --enable-profile       build profiling libraries],
 326 if test "$enableval" = "no"
 327 then
 328         PROFILE_CMT=#
 329         MAKEFILE_PROFILE=/dev/null
 330         AC_MSG_RESULT([Disabling profiling libraries])
 331 else
 332         PROFILE_CMT=
 333         MAKEFILE_PROFILE=$srcdir/lib/Makefile.profile
 334         PROFILED_LIB_EXT=_p.a
 335         AC_MSG_RESULT([Building profiling libraries])
 336 fi
 337 ,
 338 PROFILE_CMT=#
 339 MAKEFILE_PROFILE=/dev/null
 340 AC_MSG_RESULT([Disabling profiling libraries by default])
 341 )
 342 AC_SUBST(PROFILE_CMT)
 343 AC_SUBST_FILE(MAKEFILE_PROFILE)
 344 dnl
 345 dnl handle --enable-gcov
 346 dnl
 347 AC_ARG_ENABLE([gcov],
 348 [  --enable-gcov                  build for coverage testing using gcov],
 349 if test "$enableval" = "yes"
 350 then
 351         CFLAGS="-g -fprofile-arcs -ftest-coverage"
 352         LDFLAGS="-fprofile-arcs -ftest-coverage"
 353         AC_MSG_RESULT([Enabling gcov support])
 354 fi
 355 )
 356 dnl
 357 dnl handle --enable-hardening
 358 dnl
 359 CFLAGS_SHLIB="${CFLAGS_SHLIB:-$CFLAGS}"
 360 CFLAGS_STLIB="${CFLAGS_STLIB:-$CFLAGS}"
 361 LDFLAGS_SHLIB=${LDFLAGS_SHLIB:-$LDFLAGS}
 362 LDFLAGS_STATIC=${LDFLAGS_STATIC:-$LDFLAGS}
 363 AC_ARG_ENABLE([hardening],
 364 [  --enable-hardening             build for coverage testing using gcov],
 365 if test "$enableval" = "yes"
 366 then
 367         HARDEN_CFLAGS="-D_FORTIFY_SOURCE=2 -fstack-protector-strong"
 368         HARDEN_LDFLAGS=["-Wl,-z,relro -Wl,-z,now"]
 369         CFLAGS="$CFLAGS $HARDEN_CFLAGS -fPIE"
 370         CFLAGS_SHLIB="$CFLAGS_SHLIB $HARDEN_CFLAGS"
 371         CFLAGS_STLIB="$CFLAGS_STLIB $HARDEN_CFLAGS -fPIE"
 372         LDFLAGS="$LDFLAGS $HARDEN_LDFLAGS -fPIE -pie"
 373         LDFLAGS_STATIC="$LDFLAGS_STATIC $HARDEN_LDFLAGS"
 374         LDFLAGS_SHLIB="$LDFLAGS_SHLIB $HARDEN_LDFLAGS"
 375         AC_MSG_RESULT([Enabling hardening support])
 376 fi
 377 )
 378 dnl
 379 dnl Substitute library extensions
 380 dnl
 381 AC_SUBST(LIB_EXT)
 382 AC_SUBST(STATIC_LIB_EXT)
 383 AC_SUBST(PROFILED_LIB_EXT)
 384 AC_SUBST(LDFLAG_DYNAMIC)
 385 AC_SUBST(PRIVATE_LIBS_CMT)
 386 dnl
 387 dnl handle --enable-jbd-debug
 388 dnl
 389 AC_ARG_ENABLE([jbd-debug],
 390 [  --enable-jbd-debug     enable journal debugging],
 391 if test "$enableval" = "no"
 392 then
 393         AC_MSG_RESULT([Disabling journal debugging])
 394 else
 395         AC_DEFINE(CONFIG_JBD_DEBUG, 1,
 396                 [Define to 1 if debugging ext3/4 journal code])
 397         AC_MSG_RESULT([Enabling journal debugging])
 398 fi
 399 ,
 400 AC_MSG_RESULT([Disabling journal debugging by default])
 401 )
 402 dnl
 403 dnl handle --enable-blkid-debug
 404 dnl
 405 AC_ARG_ENABLE([blkid-debug],
 406 [  --enable-blkid-debug    enable blkid debugging],
 407 if test "$enableval" = "no"
 408 then
 409         AC_MSG_RESULT([Disabling blkid debugging])
 410 else
 411         AC_DEFINE(CONFIG_BLKID_DEBUG, 1,
 412                 [Define to 1 if debugging the blkid library])
 413         AC_MSG_RESULT([Enabling blkid debugging])
 414 fi
 415 ,
 416 AC_MSG_RESULT([Disabling blkid debugging by default])
 417 )
 418 dnl
 419 dnl handle --enable-testio-debug
 420 dnl
 421 AC_ARG_ENABLE([testio-debug],
 422 [  --disable-testio-debug  disable the use of the test I/O manager for debugging],
 423 AH_TEMPLATE([CONFIG_TESTIO_DEBUG],
 424         [Define to 1 if the testio I/O manager should be enabled])
 425 if test "$enableval" = "no"
 426 then
 427         AC_MSG_RESULT([Disabling testio debugging])
 428         TEST_IO_CMT="#"
 429 else
 430         TEST_IO_CMT=
 431         AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 432         AC_MSG_RESULT([Enabling testio debugging])
 433 fi
 434 ,
 435 AC_MSG_RESULT([Enabling testio debugging by default])
 436 AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 437 TEST_IO_CMT=
 438 )
 439 AC_SUBST(TEST_IO_CMT)
 440 dnl
 441 dnl handle --disable-libuuid
 442 dnl
 443 PKG_PROG_PKG_CONFIG
 444 LIBUUID=
 445 DEPLIBUUID=
 446 STATIC_LIBUUID=
 447 DEPSTATIC_LIBUUID=
 448 PROFILED_LIBUUID=
 449 DEPPROFILED_LIBUUID=
 450 UUID_CMT=
 451 AC_ARG_ENABLE([libuuid],
 452 [  --enable-libuuid       build and use private uuid library],
 453 if test "$enableval" = "no"
 454 then
 455         if test -z "$PKG_CONFIG"; then
 456                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 457         fi
 458
 459         AC_CHECK_LIB(uuid, uuid_generate,
 460                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 461                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`],
 462                 [AC_MSG_ERROR([external uuid library not found])])
 463         PROFILED_LIBUUID=$LIBUUID
 464         UUID_CMT=#
 465         AC_MSG_RESULT([Disabling private uuid library])
 466 else
 467         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 468         DEPLIBUUID=$LIBUUID
 469         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 470         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 471         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 472         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 473         AC_MSG_RESULT([Enabling private uuid library])
 474 fi
 475 ,
 476 if test -n "$PKG_CONFIG"; then
 477         AC_CHECK_LIB(uuid, uuid_generate,
 478                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 479                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`])
 480 fi
 481 if test -n "$LIBUUID"; then
 482         PROFILED_LIBUUID=$LIBUUID
 483         UUID_CMT=#
 484         AC_MSG_RESULT([Using system uuid by default])
 485 else
 486         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 487         DEPLIBUUID=$LIBUUID
 488         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 489         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 490         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 491         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 492         AC_MSG_RESULT([Enabling private uuid library by default])
 493 fi
 494 )
 495 AC_SUBST(LIBUUID)
 496 AC_SUBST(DEPLIBUUID)
 497 AC_SUBST(STATIC_LIBUUID)
 498 AC_SUBST(DEPSTATIC_LIBUUID)
 499 AC_SUBST(PROFILED_LIBUUID)
 500 AC_SUBST(DEPPROFILED_LIBUUID)
 501 AC_SUBST(UUID_CMT)
 502 dnl
 503 dnl handle --disable-libblkid
 504 dnl
 505 PKG_PROG_PKG_CONFIG
 506 LIBBLKID=
 507 DEPLIBBLKID=
 508 STATIC_LIBBLKID=
 509 DEPSTATIC_LIBBLKID=
 510 PROFILED_LIBBLKID=
 511 DEPPROFILED_LIBBLKID=
 512 BLKID_CMT=
 513 AH_TEMPLATE([CONFIG_BUILD_FINDFS], [Define to 1 to compile findfs])
 514 AC_ARG_ENABLE([libblkid],
 515 [  --enable-libblkid      build and use private blkid library],
 516 if test "$enableval" = "no"
 517 then
 518         if test -z "$PKG_CONFIG"; then
 519                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 520         fi
 521
 522         AC_CHECK_LIB(blkid, blkid_get_cache,
 523                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 524                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`],
 525                 [AC_MSG_ERROR([external blkid library not found])], -luuid)
 526         BLKID_CMT=#
 527         PROFILED_LIBBLKID=$LIBBLKID
 528         AC_MSG_RESULT([Disabling private blkid library])
 529 else
 530         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 531         DEPLIBBLKID=$LIBBLKID
 532         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 533         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 534         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 535         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 536         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 537         AC_MSG_RESULT([Enabling private blkid library])
 538 fi
 539 ,
 540 if test -n "$PKG_CONFIG"; then
 541         AC_CHECK_LIB(blkid, blkid_get_cache,
 542                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 543                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`])
 544 fi
 545 if test -n "$LIBBLKID"; then
 546         BLKID_CMT=#
 547         PROFILED_LIBBLKID=$LIBBLKID
 548         AC_MSG_RESULT([Using system blkid library by default])
 549 else
 550         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 551         DEPLIBBLKID=$LIBBLKID
 552         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 553         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 554         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 555         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 556         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 557         AC_MSG_RESULT([Enabling private blkid library by default])
 558 fi
 559 )
 560 AC_SUBST(LIBBLKID)
 561 AC_SUBST(DEPLIBBLKID)
 562 AC_SUBST(STATIC_LIBBLKID)
 563 AC_SUBST(DEPSTATIC_LIBBLKID)
 564 AC_SUBST(PROFILED_LIBBLKID)
 565 AC_SUBST(DEPPROFILED_LIBBLKID)
 566 AC_SUBST(BLKID_CMT)
 567 dnl
 568 dnl handle --enable-subset
 569 dnl
 570 ALL_CMT=
 571 SUBSET_CMT=
 572 AC_ARG_ENABLE([subset],
 573 [  --enable-subset        enable subset-only build],
 574 if test "$enableval" = "no"
 575 then
 576         SUBSET_CMT=#
 577         AC_MSG_RESULT([Disabling subset-only build])
 578 else
 579         ALL_CMT=#
 580         AC_MSG_RESULT([Enabling subset-only-build])
 581 fi
 582 ,)
 583 AC_SUBST(ALL_CMT)
 584 AC_SUBST(SUBSET_CMT)
 585 dnl
 586 dnl handle --disable-backtrace
 587 dnl
 588 AH_TEMPLATE([DISABLE_BACKTRACE], [Define to 1 to disable use of backtrace])
 589 AC_ARG_ENABLE([backtrace],
 590 [  --disable-backtrace    disable use backtrace],
 591 if test "$enableval" = "no"
 592 then
 593         AC_MSG_RESULT([Disabling use of backtrace])
 594         AC_DEFINE(DISABLE_BACKTRACE, 1)
 595 else
 596         AC_MSG_RESULT([Enabling use of backtrace])
 597 fi
 598 ,
 599 AC_MSG_RESULT([Enabling use of backtrace by default])
 600 )
 601 dnl
 602 dnl handle --enable-debugfs
 603 dnl
 604 AC_ARG_ENABLE([debugfs],
 605 [  --disable-debugfs      disable support of debugfs program],
 606 if test "$enableval" = "no"
 607 then
 608         AC_MSG_RESULT([Disabling debugfs support])
 609         DEBUGFS_CMT="#"
 610 else
 611         DEBUGFS_CMT=
 612         AC_MSG_RESULT([Enabling debugfs support])
 613 fi
 614 ,
 615 AC_MSG_RESULT([Enabling debugfs support by default])
 616 DEBUGFS_CMT=
 617 )
 618 AC_SUBST(DEBUGFS_CMT)
 619 dnl
 620 dnl handle --enable-imager
 621 dnl
 622 AC_ARG_ENABLE([imager],
 623 [  --disable-imager       disable support of e2image program],
 624 if test "$enableval" = "no"
 625 then
 626         AC_MSG_RESULT([Disabling e2image support])
 627         IMAGER_CMT="#"
 628 else
 629         IMAGER_CMT=
 630         AC_MSG_RESULT([Enabling e2image support])
 631 fi
 632 ,
 633 AC_MSG_RESULT([Enabling e2image support by default])
 634 IMAGER_CMT=
 635 )
 636 AC_SUBST(IMAGER_CMT)
 637 dnl
 638 dnl handle --enable-resizer
 639 dnl
 640 AC_ARG_ENABLE([resizer],
 641 [  --disable-resizer      disable support of e2resize program],
 642 if test "$enableval" = "no"
 643 then
 644         AC_MSG_RESULT([Disabling e2resize support])
 645         RESIZER_CMT="#"
 646 else
 647         RESIZER_CMT=
 648         AC_MSG_RESULT([Enabling e2resize support])
 649 fi
 650 ,
 651 AC_MSG_RESULT([Enabling e2resize support by default])
 652 RESIZER_CMT=
 653 )
 654 AC_SUBST(RESIZER_CMT)
 655 dnl
 656 dnl handle --enable-defrag
 657 dnl
 658 AC_ARG_ENABLE([defrag],
 659 [  --disable-defrag       disable support of e4defrag program],
 660 if test "$enableval" = "no"
 661 then
 662         AC_MSG_RESULT([Disabling e4defrag support])
 663         DEFRAG_CMT="#"
 664 else
 665         DEFRAG_CMT=
 666         AC_MSG_RESULT([Enabling e4defrag support])
 667 fi
 668 ,
 669 if test -z "$WITH_DIET_LIBC"
 670 then
 671         AC_MSG_RESULT([Enabling e4defrag support by default])
 672         DEFRAG_CMT=
 673 else
 674         AC_MSG_RESULT([Disabling e4defrag support by default])
 675         DEFRAG_CMT="#"
 676 fi
 677 )
 678 AC_SUBST(DEFRAG_CMT)
 679 dnl
 680 dnl See whether to install the `fsck' wrapper program (that calls e2fsck)
 681 dnl
 682 AC_ARG_ENABLE([fsck],
 683 [  --enable-fsck           build fsck wrapper program],
 684 [if test "$enableval" = "no"
 685 then
 686         FSCK_PROG='' FSCK_MAN=''
 687         AC_MSG_RESULT([Not building fsck wrapper])
 688 else
 689         FSCK_PROG=fsck FSCK_MAN=fsck.8
 690         AC_MSG_RESULT([Building fsck wrapper])
 691 fi]
 692 ,
 693 [case "$host_os" in
 694   gnu*)
 695     FSCK_PROG='' FSCK_MAN=''
 696     AC_MSG_RESULT([Not building fsck wrapper by default])
 697     ;;
 698   *)
 699     FSCK_PROG=fsck FSCK_MAN=fsck.8
 700     AC_MSG_RESULT([Building fsck wrapper by default])
 701 esac]
 702 )
 703 AC_SUBST(FSCK_PROG)
 704 AC_SUBST(FSCK_MAN)
 705 dnl
 706 dnl See whether to install the `e2initrd-helper' program
 707 dnl
 708 AC_ARG_ENABLE([e2initrd-helper],
 709 [  --enable-e2initrd-helper build e2initrd-helper program],
 710 [if test "$enableval" = "no"
 711 then
 712         E2INITRD_PROG='' E2INITRD_MAN=''
 713         AC_MSG_RESULT([Not building e2initrd helper])
 714 else
 715         E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 716         AC_MSG_RESULT([Building e2initrd helper])
 717 fi]
 718 ,
 719 E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 720 AC_MSG_RESULT([Building e2initrd helper by default])
 721 )
 722 AC_SUBST(E2INITRD_PROG)
 723 AC_SUBST(E2INITRD_MAN)
 724 dnl
 725 dnl
 726 dnl
 727 AC_ARG_ENABLE([tls],
 728 [  --disable-tls           disable use of thread local support],
 729 [if test "$enableval" = "no"
 730 then
 731         try_tls=""
 732         AC_MSG_RESULT([Disabling thread local support])
 733 else
 734         try_tls="yes"
 735         AC_MSG_RESULT([Enabling thread local support])
 736 fi]
 737 ,
 738 if test -n "$WITH_DIET_LIBC"
 739 then
 740         try_tls=""
 741         AC_MSG_RESULT([Diet libc does not support thread local support])
 742 else
 743         try_tls="yes"
 744         AC_MSG_RESULT([Try using thread local support by default])
 745 fi
 746 )
 747 if test "$try_tls" = "yes"
 748 then
 749 AX_TLS
 750 fi
 751 dnl
 752 dnl
 753 dnl
 754 AH_TEMPLATE([USE_UUIDD], [Define to 1 to build uuidd])
 755 AC_ARG_ENABLE([uuidd],
 756 [  --disable-uuidd         disable building the uuid daemon],
 757 [if test "$enableval" = "no"
 758 then
 759         AC_MSG_RESULT([Not building uuidd])
 760         UUIDD_CMT="#"
 761 else
 762         AC_DEFINE(USE_UUIDD, 1)
 763         UUIDD_CMT=""
 764         AC_MSG_RESULT([Building uuidd])
 765 fi]
 766 ,
 767 AC_DEFINE(USE_UUIDD, 1)
 768 if test -z "$UUID_CMT"
 769 then
 770         UUIDD_CMT=""
 771         AC_MSG_RESULT([Building uuidd by default])
 772 else
 773         UUIDD_CMT="#"
 774         AC_MSG_RESULT([Disabling uuidd by default])
 775 fi
 776 )
 777 AC_SUBST(UUIDD_CMT)
 778 dnl
 779 dnl handle --disable-mmp
 780 dnl
 781 AH_TEMPLATE([CONFIG_MMP], [Define to 1 to enable mmp support])
 782 AC_ARG_ENABLE([mmp],
 783 [  --disable-mmp           disable support mmp, Multi Mount Protection],
 784 if test "$enableval" = "no"
 785 then
 786         AC_MSG_RESULT([Disabling mmp support])
 787 else
 788         AC_MSG_RESULT([Enabling mmp support])
 789         AC_DEFINE(CONFIG_MMP, 1)
 790 fi
 791 ,
 792 AC_MSG_RESULT([Enabling mmp support by default])
 793 AC_DEFINE(CONFIG_MMP, 1)
 794 )
 795 dnl
 796 dnl handle --disable-tdb
 797 dnl
 798 AH_TEMPLATE([CONFIG_TDB], [Define to 1 to enable tdb support])
 799 AC_ARG_ENABLE([tdb],
 800 [  --disable-tdb           disable tdb support],
 801 if test "$enableval" = "no"
 802 then
 803         AC_MSG_RESULT([Disabling tdb support])
 804         TDB_CMT="#"
 805         TDB_MAN_COMMENT='.\"'
 806 else
 807         AC_MSG_RESULT([Enabling tdb support])
 808         AC_DEFINE(CONFIG_TDB, 1)
 809         TDB_CMT=""
 810         TDB_MAN_COMMENT=""
 811 fi
 812 ,
 813 AC_MSG_RESULT([Enabling mmp support by default])
 814 AC_DEFINE(CONFIG_TDB, 1)
 815 TDB_CMT=""
 816 TDB_MAN_COMMENT=""
 817 )
 818 AC_SUBST(TDB_CMT)
 819 AC_SUBST(TDB_MAN_COMMENT)
 820 dnl
 821 dnl handle --disable-bmap-stats
 822 dnl
 823 AH_TEMPLATE([ENABLE_BMAP_STATS], [Define to 1 to enable bitmap stats.])
 824 AC_ARG_ENABLE([bmap-stats],
 825 [  --disable-bmap-stats    disable collection of bitmap stats.],
 826 if test "$enableval" = "no"
 827 then
 828         AC_MSG_RESULT([Disabling bitmap statistics support])
 829 else
 830         AC_MSG_RESULT([Enabling bitmap statistics support])
 831         AC_DEFINE(ENABLE_BMAP_STATS, 1)
 832 fi
 833 ,
 834 AC_MSG_RESULT([Enabling bitmap statistics support by default])
 835 AC_DEFINE(ENABLE_BMAP_STATS, 1)
 836 )
 837 dnl
 838 dnl handle --enable-bmap-stats-ops
 839 dnl
 840 AH_TEMPLATE([ENABLE_BMAP_STATS_OPS], [Define to 1 to enable bitmap stats.])
 841 AC_ARG_ENABLE([bmap-stats-ops],
 842 [  --enable-bmap-stats-ops enable collection of additional bitmap stats],
 843 if test "$enableval" = "no"
 844 then
 845         AC_MSG_RESULT([Disabling additional bitmap statistics])
 846 else
 847         dnl There has to be a better way!
 848         AS_IF([test "x${enable_bmap_stats}" = "xno"],
 849          AC_MSG_FAILURE([Error --enable-bmap-stats-ops requires bmap-stats]))
 850
 851         AC_MSG_RESULT([Enabling additional bitmap statistics])
 852         AC_DEFINE(ENABLE_BMAP_STATS_OPS, 1)
 853 fi
 854 ,
 855 AC_MSG_RESULT([Disabling additional bitmap statistics by default])
 856 )
 857 dnl
 858 dnl
 859 dnl
 860 MAKEFILE_LIBRARY=$srcdir/lib/Makefile.library
 861 AC_SUBST_FILE(MAKEFILE_LIBRARY)
 862 dnl
 863 dnl Add internationalization support, using gettext.
 864 dnl
 865 GETTEXT_PACKAGE=e2fsprogs
 866 PACKAGE=e2fsprogs
 867 VERSION="$E2FSPROGS_VERSION"
 868 VERSION=0.14.1
 869 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [package name for gettext])
 870 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [version for gettext])
 871 AC_SUBST(GETTEXT_PACKAGE)
 872 AC_SUBST(PACKAGE)
 873 AC_SUBST(VERSION)
 874
 875 AM_GNU_GETTEXT
 876 dnl
 877 dnl End of configuration options
 878 dnl
 879 AC_SUBST(BINARY_TYPE)
 880 AC_PROG_MAKE_SET
 881 CHECK_GNU_MAKE
 882 AC_PATH_PROG(LN, ln, ln)
 883 AC_PROG_MKDIR_P
 884 AC_PROG_LN_S
 885 AC_PATH_PROG(MV, mv, mv)
 886 AC_PATH_PROG(CP, cp, cp)
 887 AC_PATH_PROG(RM, rm, rm)
 888 AC_PATH_PROG(CHMOD, chmod, :)
 889 AC_PROG_AWK
 890 AC_PROG_EGREP
 891 AC_PATH_PROG(SED, sed, sed)
 892 AC_PATH_PROG(PERL, perl, perl)
 893 AC_PATH_PROG(LDCONFIG, ldconfig, :)
 894 AC_CHECK_TOOL(AR, ar, ar)
 895 AC_CHECK_TOOL(RANLIB, ranlib, :)
 896 AC_CHECK_TOOL(STRIP, strip, :)
 897 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
 898 if test "_$MAKEINFO" = "_"; then
 899     MAKEINFO="echo Makeinfo is missing. Info documentation will not be built."
 900 else
 901     case "$MAKEINFO" in
 902       */missing.*)
 903         AC_MSG_WARN([
 904 *** Makeinfo is missing. Info documentation will not be built.])
 905         ;;
 906       *)
 907         ;;
 908     esac
 909 fi
 910 AC_SUBST(MAKEINFO)
 911 AC_PROG_INSTALL
 912 # See if we need a separate native compiler.
 913 if test $cross_compiling = no; then
 914   BUILD_CC="$CC"
 915   AC_SUBST(BUILD_CC)
 916 else
 917   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 918 fi
 919 AC_CHECK_HEADERS(m4_flatten([
 920         dirent.h
 921         errno.h
 922         execinfo.h
 923         getopt.h
 924         malloc.h
 925         mntent.h
 926         paths.h
 927         semaphore.h
 928         setjmp.h
 929         signal.h
 930         stdarg.h
 931         stdint.h
 932         stdlib.h
 933         termios.h
 934         termio.h
 935         unistd.h
 936         utime.h
 937         attr/xattr.h
 938         linux/falloc.h
 939         linux/fd.h
 940         linux/fsmap.h
 941         linux/major.h
 942         linux/loop.h
 943         linux/types.h
 944         net/if_dl.h
 945         netinet/in.h
 946         sys/acl.h
 947         sys/disklabel.h
 948         sys/disk.h
 949         sys/file.h
 950         sys/ioctl.h
 951         sys/key.h
 952         sys/mkdev.h
 953         sys/mman.h
 954         sys/mount.h
 955         sys/prctl.h
 956         sys/resource.h
 957         sys/select.h
 958         sys/socket.h
 959         sys/sockio.h
 960         sys/stat.h
 961         sys/syscall.h
 962         sys/sysctl.h
 963         sys/sysmacros.h
 964         sys/time.h
 965         sys/types.h
 966         sys/un.h
 967         sys/wait.h
 968         sys/xattr.h
 969 ]))
 970 dnl Check where to find a dd(1) that supports iflag=fullblock
 971 dnl and oflag=append
 972 AC_MSG_CHECKING([for a dd(1) program that supports iflag=fullblock])
 973 DD=
 974 for i in dd gdd ; do
 975         if "$i" if=/dev/null of=/dev/null count=1 bs=10k 2>/dev/null iflag=fullblock oflag=append ; then
 976                 DD=$i
 977                 break
 978         fi
 979 done
 980 if test -n "$DD" ; then
 981         AC_MSG_RESULT([$DD])
 982 else
 983         AC_MSG_RESULT([not found, using dd])
 984         DD=dd
 985         AC_MSG_WARN([No GNU-compatible dd(1) program found, expect some self-test failures.])
 986 fi
 987 AC_SUBST([DD])
 988
 989 AC_CHECK_HEADERS(net/if.h,,,
 990 [[
 991 #if HAVE_SYS_TYPES_H
 992 #include <sys/types.h>
 993 #endif
 994 #if HAVE_SYS_SOCKET
 995 #include <sys/socket.h>
 996 #endif
 997 ]])
 998 AC_FUNC_VPRINTF
 999 dnl Check to see if dirent has member d_reclen. On cygwin those d_reclen
1000 dnl is not declared.
1001 AC_CHECK_MEMBER(struct dirent.d_reclen,[AC_DEFINE(HAVE_RECLEN_DIRENT, 1,
1002                        [Define to 1 if dirent has d_reclen])],,
1003                 [#include <dirent.h>])
1004 AC_CHECK_MEMBERS([struct stat.st_atim])
1005 dnl Check to see if ssize_t was declared
1006 AC_CHECK_TYPE(ssize_t,[AC_DEFINE(HAVE_TYPE_SSIZE_T, 1,
1007                 [Define to 1 if ssize_t declared])],,
1008               [#include <sys/types.h>])
1009 dnl
1010 dnl Check to see if llseek() is declared in unistd.h.  On some libc's
1011 dnl it is, and on others it isn't..... Thank you glibc developers....
1012 dnl
1013 AC_CHECK_DECL(llseek,[AC_DEFINE(HAVE_LLSEEK_PROTOTYPE, 1,
1014                         [Define to 1 if llseek declared in unistd.h])],,
1015               [#include <unistd.h>])
1016 dnl
1017 dnl Check to see if lseek64() is declared in unistd.h.  Glibc's header files
1018 dnl are so convoluted that I can't tell whether it will always be defined,
1019 dnl and if it isn't defined while lseek64 is defined in the library,
1020 dnl disaster will strike.
1021 dnl
1022 dnl Warning!  Use of --enable-gcc-wall may throw off this test.
1023 dnl
1024 dnl
1025 AC_CHECK_DECL(lseek64,[AC_DEFINE(HAVE_LSEEK64_PROTOTYPE, 1,
1026                         [Define to 1 if lseek64 declared in unistd.h])],,
1027                 [#define _LARGEFILE_SOURCE
1028                  #define _LARGEFILE64_SOURCE
1029                  #include <unistd.h>])
1030 dnl
1031 dnl Word sizes...
1032 dnl
1033 AC_CHECK_SIZEOF(short)
1034 AC_CHECK_SIZEOF(int)
1035 AC_CHECK_SIZEOF(long)
1036 AC_CHECK_SIZEOF(long long)
1037 AC_CHECK_SIZEOF(off_t)
1038 AC_CHECK_SIZEOF(time_t)
1039 SIZEOF_SHORT=$ac_cv_sizeof_short
1040 SIZEOF_INT=$ac_cv_sizeof_int
1041 SIZEOF_LONG=$ac_cv_sizeof_long
1042 SIZEOF_LONG_LONG=$ac_cv_sizeof_long_long
1043 SIZEOF_OFF_T=$ac_cv_sizeof_off_t
1044 SIZEOF_TIME_T=$ac_cv_sizeof_time_t
1045 AC_SUBST(SIZEOF_SHORT)
1046 AC_SUBST(SIZEOF_INT)
1047 AC_SUBST(SIZEOF_LONG)
1048 AC_SUBST(SIZEOF_LONG_LONG)
1049 AC_SUBST(SIZEOF_OFF_T)
1050 AC_SUBST(SIZEOF_TIME_T)
1051 AC_C_BIGENDIAN
1052 if test $cross_compiling = no; then
1053   BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
1054 else
1055   CROSS_COMPILE="1" BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
1056 fi
1057 ASM_TYPES_HEADER=./asm_types.h
1058 AC_SUBST_FILE(ASM_TYPES_HEADER)
1059 dnl
1060 dnl Save the configuration #defines needed for the public ext2fs.h
1061 dnl header file
1062 dnl
1063 echo "/* These defines are needed for the public ext2fs.h header file */" \
1064      > public_config.h
1065 if grep HAVE_SYS_TYPES_H confdefs.h > tmp_config.$$; then
1066   uniq tmp_config.$$ >> public_config.h
1067 else
1068   echo "#undef HAVE_SYS_TYPES_H" >> public_config.h
1069 fi
1070 if grep WORDS_BIGENDIAN confdefs.h > tmp_config.$$; then
1071   uniq tmp_config.$$ >> public_config.h
1072 else
1073   echo "#undef WORDS_BIGENDIAN" >> public_config.h
1074 fi
1075 rm -f tmp_config.$$
1076 PUBLIC_CONFIG_HEADER=./public_config.h
1077 AC_SUBST_FILE(PUBLIC_CONFIG_HEADER)
1078 dnl
1079 dnl See if we have inttypes.h and if intptr_t is defined
1080 dnl
1081 AC_CHECK_HEADERS([inttypes.h])
1082 AC_CHECK_TYPES(intptr_t)
1083 dnl
1084 dnl See if struct stat has a st_flags field, in which case we can get file
1085 dnl flags somewhat portably.  Also check for the analogous setter, chflags().
1086 dnl
1087 AC_MSG_CHECKING(whether struct stat has a st_flags field)
1088 AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags,
1089         AC_TRY_COMPILE([#include <sys/stat.h>],
1090                 [struct stat stat; stat.st_flags = 0;],
1091                 [e2fsprogs_cv_struct_st_flags=yes],
1092                 [e2fsprogs_cv_struct_st_flags=no]))
1093 AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags)
1094 if test "$e2fsprogs_cv_struct_st_flags" = yes; then
1095   AC_MSG_CHECKING(whether st_flags field is useful)
1096   AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags_immut,
1097         AC_TRY_COMPILE([#include <sys/stat.h>],
1098                 [struct stat stat; stat.st_flags |= UF_IMMUTABLE;],
1099                 [e2fsprogs_cv_struct_st_flags_immut=yes],
1100                 [e2fsprogs_cv_struct_st_flags_immut=no]))
1101   AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags_immut)
1102   if test "$e2fsprogs_cv_struct_st_flags_immut" = yes; then
1103           AC_DEFINE(HAVE_STAT_FLAGS, 1,
1104                 [Define to 1 if struct stat has st_flags])
1105   fi
1106 fi
1107 dnl
1108 dnl Check for the presence of SA_LEN
1109 dnl
1110 AC_CHECK_MEMBER(struct sockaddr.sa_len,
1111                 AC_DEFINE_UNQUOTED(HAVE_SA_LEN,1,
1112                         [Define to 1 if if struct sockaddr contains sa_len]),,
1113         [#include <sys/types.h>
1114          #include <sys/socket.h>])
1115 dnl
1116 dnl This will add -lblkid to the AC_CHECK_FUNCS search if we are using
1117 dnl the system-provided blkid library
1118 dnl
1119 if test -n "$BLKID_CMT"; then
1120   AC_SEARCH_LIBS([blkid_probe_all], [blkid])
1121 fi
1122 dnl
1123 if test -n "$DLOPEN_LIB" ; then
1124    ac_cv_func_dlopen=yes
1125 fi
1126 AC_CHECK_FUNCS(m4_flatten([
1127         __secure_getenv
1128         add_key
1129         backtrace
1130         blkid_probe_get_topology
1131         blkid_probe_enable_partitions
1132         chflags
1133         dlopen
1134         fadvise64
1135         fallocate
1136         fallocate64
1137         fchown
1138         fcntl
1139         fdatasync
1140         fstat64
1141         fsync
1142         ftruncate64
1143         futimes
1144         getcwd
1145         getdtablesize
1146         gethostname
1147         getmntinfo
1148         getpwuid_r
1149         getrlimit
1150         getrusage
1151         jrand48
1152         keyctl
1153         llistxattr
1154         llseek
1155         lseek64
1156         mallinfo
1157         mbstowcs
1158         memalign
1159         mempcpy
1160         mmap
1161         msync
1162         nanosleep
1163         open64
1164         pathconf
1165         posix_fadvise
1166         posix_fadvise64
1167         posix_memalign
1168         prctl
1169         pread
1170         pwrite
1171         pread64
1172         pwrite64
1173         secure_getenv
1174         setmntent
1175         setresgid
1176         setresuid
1177         snprintf
1178         srandom
1179         stpcpy
1180         strcasecmp
1181         strdup
1182         strnlen
1183         strptime
1184         strtoull
1185         sync_file_range
1186         sysconf
1187         usleep
1188         utime
1189         utimes
1190         valloc
1191 ]))
1192 dnl
1193 dnl Check to see if -lsocket is required (solaris) to make something
1194 dnl that uses socket() to compile; this is needed for the UUID library
1195 dnl
1196 SOCKET_LIB=''
1197 AC_CHECK_LIB(socket, socket, [SOCKET_LIB=-lsocket])
1198 AC_SUBST(SOCKET_LIB)
1199 dnl
1200 dnl See if libmagic exists
1201 dnl
1202 AC_CHECK_LIB(magic, magic_file, [MAGIC_LIB=-lmagic
1203 AC_CHECK_HEADERS([magic.h])])
1204 if test "$ac_cv_func_dlopen" = yes ; then
1205    MAGIC_LIB=$DLOPEN_LIB
1206 fi
1207 AC_SUBST(MAGIC_LIB)
1208 dnl
1209 dnl Check to see if librt is required for clock_gettime() (glibc < 2.17)
1210 dnl
1211 AC_CHECK_LIB(rt, clock_gettime, [CLOCK_GETTIME_LIB=-lrt])
1212 AC_SUBST(CLOCK_GETTIME_LIB)
1213 dnl
1214 dnl Check to see if the FUSE library is -lfuse or -losxfuse
1215 dnl
1216 FUSE_CMT=
1217 FUSE_LIB=
1218 dnl osxfuse.dylib supersedes fuselib.dylib
1219 AC_ARG_ENABLE([fuse2fs],
1220 [  --disable-fuse2fs      do not build fuse2fs],
1221 if test "$enableval" = "no"
1222 then
1223         FUSE_CMT="#"
1224         AC_MSG_RESULT([Disabling fuse2fs])
1225 else
1226         AC_CHECK_HEADERS([pthread.h fuse.h], [],
1227 [AC_MSG_FAILURE([Cannot find fuse2fs headers.])],
1228 [#define _FILE_OFFSET_BITS      64
1229 #define FUSE_USE_VERSION 29])
1230
1231         AC_PREPROC_IFELSE(
1232 [AC_LANG_PROGRAM([[#define FUSE_USE_VERSION 29
1233 #ifdef __linux__
1234 #include <linux/fs.h>
1235 #include <linux/falloc.h>
1236 #include <linux/xattr.h>
1237 #endif
1238 ]], [])], [], [AC_MSG_FAILURE([Cannot find fuse2fs Linux headers.])])
1239
1240         AC_CHECK_LIB(osxfuse, fuse_main, [FUSE_LIB=-losxfuse],
1241                 [AC_CHECK_LIB(fuse, fuse_main, [FUSE_LIB=-lfuse],
1242                               [AC_MSG_FAILURE([Cannot find fuse library.])])])
1243         AC_MSG_RESULT([Enabling fuse2fs])
1244 fi
1245 ,
1246 AC_CHECK_HEADERS([pthread.h fuse.h], [], [FUSE_CMT="#"],
1247 [#define _FILE_OFFSET_BITS      64
1248 #define FUSE_USE_VERSION 29
1249 #ifdef __linux__
1250 # include <linux/fs.h>
1251 # include <linux/falloc.h>
1252 # include <linux/xattr.h>
1253 #endif])
1254 if test -z "$FUSE_CMT"
1255 then
1256         AC_CHECK_LIB(osxfuse, fuse_main, [FUSE_LIB=-losxfuse],
1257 [AC_CHECK_LIB(fuse, fuse_main, [FUSE_LIB=-lfuse], [FUSE_CMT="#"])])
1258 fi
1259 if test -z "$FUSE_CMT"
1260 then
1261         AC_MSG_RESULT([Enabling fuse2fs by default.])
1262 fi
1263 )
1264 AC_SUBST(FUSE_LIB)
1265 AC_SUBST(FUSE_CMT)
1266 dnl
1267 dnl See if optreset exists
1268 dnl
1269 AC_MSG_CHECKING(for optreset)
1270 AC_CACHE_VAL(ac_cv_have_optreset,
1271 [AC_EGREP_HEADER(optreset, unistd.h,
1272   ac_cv_have_optreset=yes, ac_cv_have_optreset=no)])dnl
1273 AC_MSG_RESULT($ac_cv_have_optreset)
1274 if test $ac_cv_have_optreset = yes; then
1275   AC_DEFINE(HAVE_OPTRESET, 1, [Define to 1 if optreset for getopt is present])
1276 fi
1277 dnl
1278 dnl Test for sem_init, and which library it might require:
1279 dnl
1280 AH_TEMPLATE([HAVE_SEM_INIT], [Define to 1 if sem_init() exists])
1281 SEM_INIT_LIB=''
1282 echo GL_THREADS_API: ${gl_threads_api}
1283 if test "${gl_threads_api}" != none
1284 then
1285   AC_CHECK_FUNC(sem_init, ,
1286     AC_CHECK_LIB(pthread, sem_init,
1287         AC_DEFINE(HAVE_SEM_INIT, 1)
1288         SEM_INIT_LIB=-lpthread,
1289     AC_CHECK_LIB(rt, sem_init,
1290         AC_DEFINE(HAVE_SEM_INIT, 1)
1291         SEM_INIT_LIB=-lrt,
1292     AC_CHECK_LIB(posix4, sem_init,
1293         AC_DEFINE(HAVE_SEM_INIT, 1)
1294         SEM_INIT_LIB=-lposix4))))dnl
1295 fi
1296 AC_SUBST(SEM_INIT_LIB)
1297 dnl
1298 dnl Check for unified diff
1299 dnl
1300 AC_MSG_CHECKING(for unified diff option)
1301 if diff -u $0 $0 > /dev/null 2>&1 ; then
1302    UNI_DIFF_OPTS=-u
1303 else
1304    UNI_DIFF_OPTS=-c
1305 fi
1306 AC_MSG_RESULT($UNI_DIFF_OPTS)
1307 AC_SUBST(UNI_DIFF_OPTS)
1308 dnl
1309 dnl We use the EXT2 ioctls only under Linux
1310 dnl
1311 case "$host_os" in
1312 linux*)
1313         AC_DEFINE(HAVE_EXT2_IOCTLS, 1, [Define to 1 if Ext2 ioctls present])
1314         ;;
1315 esac
1316 dnl
1317 dnl OS-specific uncomment control
1318 dnl
1319 LINUX_CMT="#"
1320 CYGWIN_CMT="#"
1321 UNIX_CMT=
1322 case "$host_os" in
1323 linux*)
1324         LINUX_CMT=
1325         ;;
1326 cygwin)
1327         CYGWIN_CMT=
1328         UNIX_CMT="#"
1329         ;;
1330 esac
1331 AC_SUBST(LINUX_CMT)
1332 AC_SUBST(CYGWIN_CMT)
1333 AC_SUBST(UNIX_CMT)
1334 dnl
1335 dnl Linux and Hurd places root files in the / by default
1336 dnl
1337 case "$host_os" in
1338 linux* | gnu* | k*bsd*-gnu)
1339         if test "$prefix" = NONE -a "$root_prefix" = NONE ; then
1340                 root_prefix="";
1341                 AC_MSG_RESULT([On $host_os systems, root_prefix defaults to ''])
1342         fi
1343         ;;
1344 esac
1345 dnl
1346 dnl On Linux/hurd, force the prefix to be /usr
1347 dnl
1348 case "$host_os" in
1349 linux* | gnu* | k*bsd*-gnu)
1350         if test "$prefix" = NONE ; then
1351                 prefix="/usr";
1352                 AC_MSG_RESULT([On $host_os systems, prefix defaults to /usr])
1353                 if test "$mandir" = '${prefix}/man' ; then
1354                         AC_MSG_RESULT([...and mandir defaults to /usr/share/man])
1355                         mandir=/usr/share/man
1356                 fi
1357         fi
1358 ;;
1359 esac
1360 if test "$root_prefix" = NONE ; then
1361         if test "$prefix" = NONE ; then
1362                 root_prefix="$ac_default_prefix"
1363         else
1364                 root_prefix="$prefix"
1365         fi
1366         root_bindir=$bindir
1367         root_sbindir=$sbindir
1368         root_libdir=$libdir
1369         root_sysconfdir=$sysconfdir
1370 else
1371         root_bindir='${root_prefix}/bin'
1372         root_sbindir='${root_prefix}/sbin'
1373         root_libdir='${root_prefix}/lib'
1374         root_sysconfdir='${root_prefix}/etc'
1375 fi
1376 if test "$bindir" != '${exec_prefix}/bin'; then
1377     root_bindir=$bindir
1378     AC_MSG_RESULT([Setting root_bindir to $root_bindir])
1379 fi
1380 if test "$sbindir" != '${exec_prefix}/sbin'; then
1381     root_sbindir=$sbindir
1382     AC_MSG_RESULT([Setting root_sbindir to $root_sbindir])
1383 fi
1384 if test "$libdir" != '${exec_prefix}/lib'; then
1385     root_libdir=$libdir
1386     AC_MSG_RESULT([Setting root_libdir to $root_libdir])
1387 fi
1388 if test "$sysconfdir" != '${prefix}/etc'; then
1389     root_sysconfdir=$sysconfdir
1390     AC_MSG_RESULT([Setting root_sysconfdir to $root_sysconfdir])
1391 fi
1392 AC_SUBST(root_prefix)
1393 AC_SUBST(root_bindir)
1394 AC_SUBST(root_sbindir)
1395 AC_SUBST(root_libdir)
1396 AC_SUBST(root_sysconfdir)
1397 dnl
1398 dnl Allow specification of the multiarch arch
1399 dnl
1400 AC_ARG_WITH([multiarch],
1401 [  --with-multiarch=ARCH specify the multiarch triplet],
1402 if test "$withval" = "lib64"; then
1403     libdir=/usr/lib64
1404     root_libdir=/lib64
1405 else
1406     libdir=$libdir/$withval
1407     root_libdir=$root_libdir/$withval
1408 fi
1409 )dnl
1410 dnl
1411 dnl See if -static works.  This could fail if the linker does not
1412 dnl support -static, or if required external libraries are not available
1413 dnl in static form.
1414 dnl
1415 AC_MSG_CHECKING([whether we can link with -static])
1416 AC_CACHE_VAL(ac_cv_e2fsprogs_use_static,
1417 [SAVE_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS_STATIC -static"
1418 AC_TRY_LINK([#include <stdio.h>],[fflush(stdout);],
1419  ac_cv_e2fsprogs_use_static=yes, ac_cv_e2fsprogs_use_static=no)
1420 LDFLAGS=$SAVE_LDFLAGS])
1421 dnl
1422 dnl Regardless of how the test turns out, Solaris doesn't handle -static
1423 dnl This is caused by the socket library requiring the nsl library, which
1424 dnl requires the -dl library, which only works for dynamically linked
1425 dnl programs.  It basically means you can't have statically linked programs
1426 dnl which use the network under Solaris.
1427 dnl
1428 case "$host_os" in
1429 solaris2.*)
1430         ac_cv_e2fsprogs_use_static=no
1431 ;;
1432 esac
1433 AC_MSG_RESULT($ac_cv_e2fsprogs_use_static)
1434 if test $ac_cv_e2fsprogs_use_static = yes; then
1435         LDFLAGS_STATIC="$LDFLAGS_STATIC -static"
1436 fi
1437 AC_SUBST(LDFLAGS_STATIC)
1438 dnl
1439 dnl Work around mysterious Darwin / GNU libintl problem
1440 dnl (__asm__ redirection doesn't work for some mysterious reason.  Looks like
1441 dnl Apple hacked gcc somehow?)
1442 dnl
1443 case "$host_os" in
1444 darwin*)
1445         AC_MSG_RESULT([Using Apple Darwin / GNU libintl workaround])
1446         AC_DEFINE(_INTL_REDIRECT_MACROS, 1,
1447                 [Define to 1 if Apple Darwin libintl workaround is needed])
1448         ;;
1449 esac
1450 dnl
1451 dnl Only try to run the test suite if we're not cross compiling.
1452 dnl
1453 if test "$cross_compiling" = yes ; then
1454   DO_TEST_SUITE=
1455 else
1456   DO_TEST_SUITE=check
1457 fi
1458 AC_SUBST(DO_TEST_SUITE)
1459 dnl
1460 dnl Only include the intl include files if we're building with them
1461 dnl
1462 INCLUDES='-I. -I$(top_builddir)/lib -I$(top_srcdir)/lib'
1463 if test -n "$CPPFLAGS" ; then
1464         INCLUDES="$INCLUDES $CPPFLAGS"
1465 fi
1466 if test "$USE_INCLUDED_LIBINTL" = "yes" ; then
1467         INCLUDES=$INCLUDES' -I$(top_builddir)/intl -I$(top_srcdir)/intl'
1468 fi
1469 if test -n "$WITH_DIET_LIBC" ; then
1470         INCLUDES="$INCLUDES -D_REENTRANT"
1471 fi
1472 AC_SUBST(INCLUDES)
1473 dnl
1474 dnl Build CFLAGS
1475 dnl
1476 if test $cross_compiling = no; then
1477    BUILD_CFLAGS="$CFLAGS $CPPFLAGS $INCLUDES -DHAVE_CONFIG_H"
1478    BUILD_LDFLAGS="$LDFLAGS"
1479 fi
1480 AC_SUBST(BUILD_CFLAGS)
1481 AC_SUBST(BUILD_LDFLAGS)
1482 dnl
1483 dnl Define CFLAGS and LDFLAGS for shared libraries
1484 dnl
1485 CFLAGS_SHLIB=${CFLAGS_SHLIB:-$CFLAGS}
1486 CFLAGS_STLIB=${CFLAGS_STLIB:-$CFLAGS}
1487 LDFLAGS_SHLIB=${LDFLAGS_SHLIB:-$LDFLAGS}
1488 AC_SUBST(CFLAGS_SHLIB)
1489 AC_SUBST(CFLAGS_STLIB)
1490 AC_SUBST(LDFLAGS_SHLIB)
1491 dnl
1492 dnl Make our output files, being sure that we create the some miscellaneous
1493 dnl directories
1494 dnl
1495 test -d lib || mkdir lib
1496 test -d include || mkdir include
1497 test -d include/linux || mkdir include/linux
1498 test -d include/asm || mkdir include/asm
1499 if test -z "$UUID_CMT" ; then
1500         uuid_out_list="lib/uuid/Makefile lib/uuid/uuid.pc \
1501                 lib/uuid/uuid_types.h"
1502 fi
1503 if test -z "$BLKID_CMT" ; then
1504         blkid_out_list="lib/blkid/Makefile lib/blkid/blkid.pc \
1505                 lib/blkid/blkid_types.h"
1506 fi
1507 for i in MCONFIG Makefile \
1508         util/Makefile util/subst.conf util/gen-tarball util/install-symlink \
1509         lib/et/Makefile lib/ss/Makefile lib/e2p/Makefile \
1510         lib/ext2fs/Makefile lib/ext2fs/ext2_types.h \
1511         $uuid_out_list $blkid_out_list lib/support/Makefile \
1512         lib/ss/ss.pc lib/et/com_err.pc lib/e2p/e2p.pc lib/ext2fs/ext2fs.pc \
1513         misc/Makefile ext2ed/Makefile e2fsck/Makefile \
1514         debugfs/Makefile tests/Makefile tests/progs/Makefile \
1515         resize/Makefile doc/Makefile intl/Makefile \
1516         intl/libgnuintl.h po/Makefile.in ; do
1517         if test -d `dirname ${srcdir}/$i` ; then
1518                 outlist="$outlist $i"
1519         fi
1520 done
1521 AC_OUTPUT($outlist)
1522 if test -f util/gen-tarball; then chmod +x util/gen-tarball; fi