configure.ac

   1 AC_INIT
   2 AC_CONFIG_SRCDIR([version.h])
   3 AC_PREREQ([2.71])
   4 AC_CONFIG_AUX_DIR(config)
   5 AC_CONFIG_HEADERS([lib/config.h])
   6 AH_BOTTOM([#include <dirpaths.h>])
   7 AC_USE_SYSTEM_EXTENSIONS
   8 MCONFIG=./MCONFIG
   9 AC_SUBST_FILE(MCONFIG)
  10 BINARY_TYPE=bin
  11 dnl
  12 dnl This is to figure out the version number and the date....
  13 dnl
  14 E2FSPROGS_VERSION=`grep E2FSPROGS_VERSION ${srcdir}/version.h  \
  15         | awk '{print $3}' | tr \" " " | awk '{print $1}'`
  16 E2FSPROGS_DATE=`grep E2FSPROGS_DATE ${srcdir}/version.h | awk '{print $3}' \
  17         | tr \" " " | awk '{print $1}'`
  18 E2FSPROGS_DAY=$(echo $E2FSPROGS_DATE | awk -F- '{print $1}' | sed -e '/^[[1-9]]$/s/^/0/')
  19 MONTH=`echo $E2FSPROGS_DATE | awk -F- '{print $2}'`
  20 YEAR=`echo $E2FSPROGS_DATE | awk -F- '{print $3}'`
  21
  22 if expr $YEAR ">" 1900 > /dev/null ; then
  23         E2FSPROGS_YEAR=$YEAR
  24 elif expr $YEAR ">" 90 >/dev/null ; then
  25         E2FSPROGS_YEAR=19$YEAR
  26 else
  27         E2FSPROGS_YEAR=20$YEAR
  28 fi
  29
  30 case $MONTH in
  31 Jan)    MONTH_NUM=01; E2FSPROGS_MONTH="January" ;;
  32 Feb)    MONTH_NUM=02; E2FSPROGS_MONTH="February" ;;
  33 Mar)    MONTH_NUM=03; E2FSPROGS_MONTH="March" ;;
  34 Apr)    MONTH_NUM=04; E2FSPROGS_MONTH="April" ;;
  35 May)    MONTH_NUM=05; E2FSPROGS_MONTH="May" ;;
  36 Jun)    MONTH_NUM=06; E2FSPROGS_MONTH="June" ;;
  37 Jul)    MONTH_NUM=07; E2FSPROGS_MONTH="July" ;;
  38 Aug)    MONTH_NUM=08; E2FSPROGS_MONTH="August" ;;
  39 Sep)    MONTH_NUM=09; E2FSPROGS_MONTH="September" ;;
  40 Oct)    MONTH_NUM=10; E2FSPROGS_MONTH="October" ;;
  41 Nov)    MONTH_NUM=11; E2FSPROGS_MONTH="November" ;;
  42 Dec)    MONTH_NUM=12; E2FSPROGS_MONTH="December" ;;
  43 *)      AC_MSG_WARN([Unknown month $MONTH??]) ;;
  44 esac
  45
  46 base_ver=`echo $E2FSPROGS_VERSION | \
  47                sed -e 's/-WIP//' -e 's/pre-//' -e 's/-PLUS//'`
  48
  49 date_spec=${E2FSPROGS_YEAR}.${MONTH_NUM}.${E2FSPROGS_DAY}
  50
  51 case $E2FSPROGS_VERSION in
  52 *-WIP|pre-*)
  53         E2FSPROGS_PKGVER="$base_ver~WIP.$date_spec"
  54         ;;
  55 *)
  56         E2FSPROGS_PKGVER="$base_ver"
  57         ;;
  58 esac
  59
  60 unset DATE MONTH YEAR base_ver pre_vers date_spec
  61 AC_MSG_RESULT([Generating configuration file for e2fsprogs version $E2FSPROGS_VERSION])
  62 AC_MSG_RESULT([Release date is ${E2FSPROGS_MONTH}, ${E2FSPROGS_YEAR}])
  63 AC_SUBST(E2FSPROGS_YEAR)
  64 AC_SUBST(E2FSPROGS_MONTH)
  65 AC_SUBST(E2FSPROGS_DAY)
  66 AC_SUBST(E2FSPROGS_VERSION)
  67 AC_SUBST(E2FSPROGS_PKGVER)
  68 AC_SUBST(E2FSPROGS_DATE)
  69 dnl
  70 dnl Use diet libc
  71 dnl
  72 WITH_DIET_LIBC=
  73 AC_ARG_WITH([diet-libc],
  74 AS_HELP_STRING([--with-diet-libc],[use diet libc]),
  75 CC="diet cc -nostdinc"
  76 WITH_DIET_LIBC=yes
  77 if test -z "$LIBS"
  78 then
  79         LIBS="-lcompat"
  80 else
  81         LIBS="$LIBS -lcompat"
  82 fi
  83 AC_MSG_RESULT(CC=$CC))dnl
  84 dnl
  85 AC_CANONICAL_HOST
  86 dnl
  87 dnl Check to see if libdl exists for the sake of dlopen
  88 dnl
  89 DLOPEN_LIB=''
  90 AC_CHECK_LIB(dl, dlopen,DLOPEN_LIB=-ldl)
  91 AC_SUBST(DLOPEN_LIB)
  92 dnl
  93 AC_ARG_WITH([cc],
  94 AS_HELP_STRING([--with-cc],[no longer supported, use CC= instead]),
  95 AC_MSG_ERROR([--with-cc no longer supported; use CC= instead]))
  96 dnl
  97 AC_ARG_WITH([ccopts],
  98 AS_HELP_STRING([--with-ccopts],[no longer supported, use CFLAGS= instead]),
  99 AC_MSG_ERROR([--with-ccopts no longer supported; use CFLAGS= instead]))
 100 dnl
 101 AC_ARG_WITH([ldopts],
 102 AS_HELP_STRING([--with-ldopts],[no longer supported, use LDFLAGS= instead]),
 103 AC_MSG_ERROR([--with-ldopts no longer supported; use LDFLAGS= instead]))
 104 dnl
 105 AC_PROG_CC
 106 if test "$GCC" = yes; then
 107    RDYNAMIC="-rdynamic"
 108    AC_SUBST(RDYNAMIC)
 109 fi
 110 AC_PROG_CPP
 111 dnl
 112 dnl Alpha computers use fast and imprecise floating point code that may
 113 dnl miss exceptions by default. Force sane options if we're using GCC.
 114 AC_MSG_CHECKING(for additional special compiler flags)
 115 if test "$GCC" = yes
 116 then
 117     case "$host_cpu" in
 118         alpha)          addcflags="-mieee" ;;
 119     esac
 120 fi
 121 if test "x$addcflags" != x
 122 then
 123     AC_MSG_RESULT($addcflags)
 124     CFLAGS="$addcflags $CFLAGS"
 125 else
 126     AC_MSG_RESULT([[(none)]])
 127 fi
 128 dnl
 129 dnl Set default values for library extensions.  Will be dealt with after
 130 dnl parsing configuration options, which may modify these
 131 dnl
 132 LIB_EXT=.a
 133 STATIC_LIB_EXT=.a
 134 PROFILED_LIB_EXT=.a
 135 dnl
 136 dnl Allow separate `root_prefix' to be specified
 137 dnl
 138 AC_ARG_WITH([root-prefix],
 139 AS_HELP_STRING([--with-root-prefix=PREFIX],[override prefix variable for files to be placed in the root]),
 140 root_prefix=$withval,
 141 root_prefix=NONE)dnl
 142 dnl
 143 dnl handle --enable-maintainer-mode
 144 dnl
 145 AC_ARG_ENABLE([maintainer-mode],
 146 AS_HELP_STRING([--enable-maintainer-mode],[enable makefile rules useful for maintainers]),
 147 if test "$enableval" = "no"
 148 then
 149         MAINTAINER_CMT=#
 150         AC_MSG_RESULT([Disabling maintainer mode])
 151 else
 152         MAINTAINER_CMT=
 153         AC_MSG_RESULT([Enabling maintainer mode])
 154 fi
 155 ,
 156 MAINTAINER_CMT=#
 157 AC_MSG_RESULT([Disabling maintainer mode by default])
 158 )
 159 AC_SUBST(MAINTAINER_CMT)
 160 dnl
 161 dnl handle --enable-symlink-install
 162 dnl
 163 AC_ARG_ENABLE([symlink-install],
 164 AS_HELP_STRING([--enable-symlink-install],[use symlinks when installing instead of hard links]),
 165 if test "$enableval" = "no"
 166 then
 167         LINK_INSTALL_FLAGS=-f
 168         AC_MSG_RESULT([Disabling symlinks for install])
 169 else
 170         LINK_INSTALL_FLAGS=-sf
 171         AC_MSG_RESULT([Enabling symlinks for install])
 172 fi
 173 ,
 174 LINK_INSTALL_FLAGS=-f
 175 AC_MSG_RESULT([Disabling symlinks for install by default])
 176 )
 177 AC_SUBST(LINK_INSTALL_FLAGS)
 178 dnl
 179 dnl handle --enable-relative-symlinks
 180 dnl
 181 relative_symlink_defined=
 182 AC_ARG_ENABLE([relative-symlinks],
 183 AS_HELP_STRING([--enable-relative-symlinks],[use relative symlinks when installing]),
 184 if test "$enableval" = "no"
 185 then
 186         SYMLINK_RELATIVE=
 187         relative_symlink_defined=yes
 188         AC_MSG_RESULT([Disabling relative symlinks for install])
 189 else
 190         SYMLINK_RELATIVE=--relative
 191         relative_symlink_defined=yes
 192         AC_MSG_RESULT([Enabling relative symlinks for install])
 193 fi)
 194 AC_ARG_ENABLE([symlink-relative-symlinks],,
 195 if test "$enableval" = "no"
 196 then
 197         SYMLINK_RELATIVE=yes
 198         AC_MSG_RESULT([Disabling relative symlinks for install])
 199 else
 200         SYMLINK_RELATIVE=--relative
 201         AC_MSG_RESULT([Enabling relative symlinks for install])
 202 fi
 203 ,
 204 if test -z "$relative_symlink_defined"
 205 then
 206         SYMLINK_RELATIVE=
 207 AC_MSG_RESULT([Disabling relative symlinks for install by default])
 208 fi
 209 )
 210 AC_SUBST(SYMLINK_RELATIVE)
 211 dnl
 212 dnl handle --enable-symlink-build
 213 dnl
 214 AC_ARG_ENABLE([symlink-build],
 215 AS_HELP_STRING([--enable-symlink-build],[use symlinks while building instead of hard links]),
 216 if test "$enableval" = "no"
 217 then
 218         LINK_BUILD_FLAGS=
 219         AC_MSG_RESULT([Disabling symlinks for build])
 220 else
 221         LINK_BUILD_FLAGS=-s
 222         AC_MSG_RESULT([Enabling symlinks for build])
 223 fi
 224 ,
 225 LINK_BUILD_FLAGS=
 226 AC_MSG_RESULT([Disabling symlinks for build by default])
 227 )
 228 AC_SUBST(LINK_BUILD_FLAGS)
 229 dnl
 230 dnl handle --enable-verbose-makecmds
 231 dnl
 232 AC_ARG_ENABLE([verbose-makecmds],
 233 AS_HELP_STRING([--enable-verbose-makecmds],[enable verbose make command output]),
 234 if test "$enableval" = "no"
 235 then
 236         AC_MSG_RESULT([Disabling verbose make commands])
 237         E=@echo
 238         ES=echo
 239         Q=@
 240 else
 241         AC_MSG_RESULT([Enabling verbose make commands])
 242         E=@\\#
 243         ES=\\#
 244         Q=
 245 fi
 246 ,
 247 AC_MSG_RESULT([Disabling verbose make commands])
 248 E=@echo
 249 ES=echo
 250 Q=@
 251 )
 252 AC_SUBST(E)
 253 AC_SUBST(ES)
 254 AC_SUBST(Q)
 255 dnl
 256 dnl This needs to be before all of the --enable-*-shlibs options
 257 dnl
 258 E2_PKG_CONFIG_STATIC=--static
 259 LDFLAG_DYNAMIC=
 260 PRIVATE_LIBS_CMT=
 261 dnl
 262 dnl handle --enable-elf-shlibs
 263 dnl
 264 AC_ARG_ENABLE([elf-shlibs],
 265 AS_HELP_STRING([--enable-elf-shlibs],[select ELF shared libraries]),
 266 if test "$enableval" = "no"
 267 then
 268         ELF_CMT=#
 269         MAKEFILE_ELF=/dev/null
 270         AC_MSG_RESULT([Disabling ELF shared libraries])
 271 else
 272         E2_PKG_CONFIG_STATIC=
 273         ELF_CMT=
 274         MAKEFILE_ELF=$srcdir/lib/Makefile.elf-lib
 275         [case "$host_os" in
 276         solaris2.*)
 277                 MAKEFILE_ELF=$srcdir/lib/Makefile.solaris-lib
 278         ;;
 279         esac]
 280         BINARY_TYPE=elfbin
 281         LIB_EXT=.so
 282         PRIVATE_LIBS_CMT=#
 283         LDFLAG_DYNAMIC=['-Wl,-rpath-link,$(top_builddir)/lib']
 284         AC_MSG_RESULT([Enabling ELF shared libraries])
 285 fi
 286 ,
 287 MAKEFILE_ELF=/dev/null
 288 ELF_CMT=#
 289 AC_MSG_RESULT([Disabling ELF shared libraries by default])
 290 )
 291 AC_SUBST(ELF_CMT)
 292 AC_SUBST_FILE(MAKEFILE_ELF)
 293 dnl
 294 dnl handle --enable-bsd-shlibs
 295 dnl
 296 AC_ARG_ENABLE([bsd-shlibs],
 297 AS_HELP_STRING([--enable-bsd-shlibs],[select BSD shared libraries]),
 298 if test "$enableval" = "no"
 299 then
 300         BSDLIB_CMT=#
 301         MAKEFILE_BSDLIB=/dev/null
 302         AC_MSG_RESULT([Disabling BSD shared libraries])
 303 else
 304         E2_PKG_CONFIG_STATIC=
 305         BSDLIB_CMT=
 306         MAKEFILE_BSDLIB=$srcdir/lib/Makefile.bsd-lib
 307         LIB_EXT=.so
 308         [case "$host_os" in
 309         darwin*)
 310                 MAKEFILE_BSDLIB=$srcdir/lib/Makefile.darwin-lib
 311                 LIB_EXT=.dylib
 312         ;;
 313         esac]
 314         AC_MSG_RESULT([Enabling BSD shared libraries])
 315 fi
 316 ,
 317 MAKEFILE_BSDLIB=/dev/null
 318 BSDLIB_CMT=#
 319 AC_MSG_RESULT([Disabling BSD shared libraries by default])
 320 )
 321 AC_SUBST(BSDLIB_CMT)
 322 AC_SUBST_FILE(MAKEFILE_BSDLIB)
 323 dnl
 324 dnl handle --enable-profile
 325 dnl
 326 AC_ARG_ENABLE([profile],
 327 AS_HELP_STRING([--enable-profile],[build profiling libraries]),
 328 if test "$enableval" = "no"
 329 then
 330         PROFILE_CMT=#
 331         MAKEFILE_PROFILE=/dev/null
 332         AC_MSG_RESULT([Disabling profiling libraries])
 333 else
 334         PROFILE_CMT=
 335         MAKEFILE_PROFILE=$srcdir/lib/Makefile.profile
 336         PROFILED_LIB_EXT=_p.a
 337         AC_MSG_RESULT([Building profiling libraries])
 338 fi
 339 ,
 340 PROFILE_CMT=#
 341 MAKEFILE_PROFILE=/dev/null
 342 AC_MSG_RESULT([Disabling profiling libraries by default])
 343 )
 344 AC_SUBST(PROFILE_CMT)
 345 AC_SUBST_FILE(MAKEFILE_PROFILE)
 346 dnl
 347 dnl handle --enable-gcov
 348 dnl
 349 AC_ARG_ENABLE([gcov],
 350 AS_HELP_STRING([--enable-gcov],[build for coverage testing using gcov]),
 351 if test "$enableval" = "yes"
 352 then
 353         CFLAGS="-g -fprofile-arcs -ftest-coverage"
 354         LDFLAGS="-fprofile-arcs -ftest-coverage"
 355         AC_MSG_RESULT([Enabling gcov support])
 356 fi
 357 )
 358 dnl
 359 dnl handle --enable-hardening
 360 dnl
 361 CFLAGS_SHLIB="${CFLAGS_SHLIB:-$CFLAGS}"
 362 CFLAGS_STLIB="${CFLAGS_STLIB:-$CFLAGS}"
 363 LDFLAGS_SHLIB=${LDFLAGS_SHLIB:-$LDFLAGS}
 364 LDFLAGS_STATIC=${LDFLAGS_STATIC:-$LDFLAGS}
 365 AC_ARG_ENABLE([hardening],
 366 AS_HELP_STRING([--enable-hardening],[build for coverage testing using gcov]),
 367 if test "$enableval" = "yes"
 368 then
 369         HARDEN_CFLAGS="-D_FORTIFY_SOURCE=2 -fstack-protector-strong"
 370         HARDEN_LDFLAGS=["-Wl,-z,relro -Wl,-z,now"]
 371         CFLAGS="$CFLAGS $HARDEN_CFLAGS -fPIE"
 372         CFLAGS_SHLIB="$CFLAGS_SHLIB $HARDEN_CFLAGS"
 373         CFLAGS_STLIB="$CFLAGS_STLIB $HARDEN_CFLAGS -fPIE"
 374         LDFLAGS="$LDFLAGS $HARDEN_LDFLAGS -fPIE -pie"
 375         LDFLAGS_STATIC="$LDFLAGS_STATIC $HARDEN_LDFLAGS"
 376         LDFLAGS_SHLIB="$LDFLAGS_SHLIB $HARDEN_LDFLAGS"
 377         AC_MSG_RESULT([Enabling hardening support])
 378 fi
 379 )
 380 dnl
 381 dnl Substitute library extensions
 382 dnl
 383 AC_SUBST(LIB_EXT)
 384 AC_SUBST(STATIC_LIB_EXT)
 385 AC_SUBST(PROFILED_LIB_EXT)
 386 AC_SUBST(LDFLAG_DYNAMIC)
 387 AC_SUBST(PRIVATE_LIBS_CMT)
 388 dnl
 389 dnl handle --enable-jbd-debug
 390 dnl
 391 AC_ARG_ENABLE([jbd-debug],
 392 AS_HELP_STRING([--enable-jbd-debug],[enable journal debugging]),
 393 if test "$enableval" = "no"
 394 then
 395         AC_MSG_RESULT([Disabling journal debugging])
 396 else
 397         AC_DEFINE(CONFIG_JBD_DEBUG, 1,
 398                 [Define to 1 if debugging ext3/4 journal code])
 399         AC_MSG_RESULT([Enabling journal debugging])
 400 fi
 401 ,
 402 AC_MSG_RESULT([Disabling journal debugging by default])
 403 )
 404 dnl
 405 dnl handle --enable-blkid-debug
 406 dnl
 407 AC_ARG_ENABLE([blkid-debug],
 408 AS_HELP_STRING([--enable-blkid-debug],[enable blkid debugging]),
 409 if test "$enableval" = "no"
 410 then
 411         AC_MSG_RESULT([Disabling blkid debugging])
 412 else
 413         AC_DEFINE(CONFIG_BLKID_DEBUG, 1,
 414                 [Define to 1 if debugging the blkid library])
 415         AC_MSG_RESULT([Enabling blkid debugging])
 416 fi
 417 ,
 418 AC_MSG_RESULT([Disabling blkid debugging by default])
 419 )
 420 dnl
 421 dnl handle --enable-testio-debug
 422 dnl
 423 AC_ARG_ENABLE([testio-debug],
 424 AS_HELP_STRING([--disable-testio-debug],[disable the use of the test I/O manager for debugging]),
 425 AH_TEMPLATE([CONFIG_TESTIO_DEBUG],
 426         [Define to 1 if the testio I/O manager should be enabled])
 427 if test "$enableval" = "no"
 428 then
 429         AC_MSG_RESULT([Disabling testio debugging])
 430         TEST_IO_CMT="#"
 431 else
 432         TEST_IO_CMT=
 433         AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 434         AC_MSG_RESULT([Enabling testio debugging])
 435 fi
 436 ,
 437 AC_MSG_RESULT([Enabling testio debugging by default])
 438 AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 439 TEST_IO_CMT=
 440 )
 441 AC_SUBST(TEST_IO_CMT)
 442 dnl
 443 dnl handle --enable-developer-features
 444 dnl
 445 AC_ARG_ENABLE([developer-features],
 446 AS_HELP_STRING([--enable-developer-features],[enable features for use by ext4 developers]),
 447 AH_TEMPLATE([CONFIG_DEVELOPER_FEATURES],
 448         [Define to 1 for features for use by ext4 developers])
 449 if test "$enableval" = "yes"
 450 then
 451         DEV_FEATURES_CMT=
 452         AC_DEFINE(CONFIG_DEVELOPER_FEATURES, 1)
 453         AC_MSG_RESULT([Enabling ext4 developer features])
 454 else
 455         AC_MSG_RESULT([Disabling ext4 developer features])
 456         DEV_FEATURES_CMT="#"
 457 fi
 458 ,
 459 AC_MSG_RESULT([Disabling ext4 developer features by default])
 460 DEV_FEATURES_CMT=
 461 )
 462 AC_SUBST(DEV_FEATURES_CMT)
 463 dnl
 464 dnl handle --disable-libuuid
 465 dnl
 466 PKG_PROG_PKG_CONFIG
 467 LIBUUID=
 468 DEPLIBUUID=
 469 STATIC_LIBUUID=
 470 DEPSTATIC_LIBUUID=
 471 PROFILED_LIBUUID=
 472 DEPPROFILED_LIBUUID=
 473 UUID_CMT=
 474 AC_ARG_ENABLE([libuuid],
 475 AS_HELP_STRING([--enable-libuuid],[build and use private uuid library]),
 476 if test "$enableval" = "no"
 477 then
 478         if test -z "$PKG_CONFIG"; then
 479                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 480         fi
 481
 482         AC_CHECK_LIB(uuid, uuid_generate,
 483                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 484                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`],
 485                 [AC_MSG_ERROR([external uuid library not found])])
 486         PROFILED_LIBUUID=$LIBUUID
 487         UUID_CMT=#
 488         AC_MSG_RESULT([Disabling private uuid library])
 489 else
 490         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 491         DEPLIBUUID=$LIBUUID
 492         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 493         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 494         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 495         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 496         AC_MSG_RESULT([Enabling private uuid library])
 497 fi
 498 ,
 499 if test -n "$PKG_CONFIG"; then
 500         AC_CHECK_LIB(uuid, uuid_generate,
 501                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 502                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`])
 503 fi
 504 if test -n "$LIBUUID"; then
 505         PROFILED_LIBUUID=$LIBUUID
 506         UUID_CMT=#
 507         AC_MSG_RESULT([Using system uuid by default])
 508 else
 509         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 510         DEPLIBUUID=$LIBUUID
 511         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 512         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 513         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 514         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 515         AC_MSG_RESULT([Enabling private uuid library by default])
 516 fi
 517 )
 518 AC_SUBST(LIBUUID)
 519 AC_SUBST(DEPLIBUUID)
 520 AC_SUBST(STATIC_LIBUUID)
 521 AC_SUBST(DEPSTATIC_LIBUUID)
 522 AC_SUBST(PROFILED_LIBUUID)
 523 AC_SUBST(DEPPROFILED_LIBUUID)
 524 AC_SUBST(UUID_CMT)
 525 dnl
 526 dnl handle --disable-libblkid
 527 dnl
 528 PKG_PROG_PKG_CONFIG
 529 LIBBLKID=
 530 DEPLIBBLKID=
 531 STATIC_LIBBLKID=
 532 DEPSTATIC_LIBBLKID=
 533 PROFILED_LIBBLKID=
 534 DEPPROFILED_LIBBLKID=
 535 BLKID_CMT=
 536 AH_TEMPLATE([CONFIG_BUILD_FINDFS], [Define to 1 to compile findfs])
 537 AC_ARG_ENABLE([libblkid],
 538 AS_HELP_STRING([--enable-libblkid],[build and use private blkid library]),
 539 if test "$enableval" = "no"
 540 then
 541         if test -z "$PKG_CONFIG"; then
 542                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 543         fi
 544
 545         AC_CHECK_LIB(blkid, blkid_get_cache,
 546                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 547                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`],
 548                 [AC_MSG_ERROR([external blkid library not found])], -luuid)
 549         BLKID_CMT=#
 550         PROFILED_LIBBLKID=$LIBBLKID
 551         AC_MSG_RESULT([Disabling private blkid library])
 552 else
 553         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 554         DEPLIBBLKID=$LIBBLKID
 555         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 556         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 557         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 558         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 559         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 560         AC_MSG_RESULT([Enabling private blkid library])
 561 fi
 562 ,
 563 if test -n "$PKG_CONFIG"; then
 564         AC_CHECK_LIB(blkid, blkid_get_cache,
 565                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 566                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`])
 567 fi
 568 if test -n "$LIBBLKID"; then
 569         BLKID_CMT=#
 570         PROFILED_LIBBLKID=$LIBBLKID
 571         AC_MSG_RESULT([Using system blkid library by default])
 572 else
 573         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 574         DEPLIBBLKID=$LIBBLKID
 575         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 576         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 577         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 578         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 579         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 580         AC_MSG_RESULT([Enabling private blkid library by default])
 581 fi
 582 )
 583 AC_SUBST(LIBBLKID)
 584 AC_SUBST(DEPLIBBLKID)
 585 AC_SUBST(STATIC_LIBBLKID)
 586 AC_SUBST(DEPSTATIC_LIBBLKID)
 587 AC_SUBST(PROFILED_LIBBLKID)
 588 AC_SUBST(DEPPROFILED_LIBBLKID)
 589 AC_SUBST(BLKID_CMT)
 590 dnl
 591 dnl handle --enable-subset
 592 dnl
 593 ALL_CMT=
 594 SUBSET_CMT=
 595 AC_ARG_ENABLE([subset],
 596 AS_HELP_STRING([--enable-subset],[enable subset-only build]),
 597 if test "$enableval" = "no"
 598 then
 599         SUBSET_CMT=#
 600         AC_MSG_RESULT([Disabling subset-only build])
 601 else
 602         ALL_CMT=#
 603         AC_MSG_RESULT([Enabling subset-only-build])
 604 fi
 605 ,)
 606 AC_SUBST(ALL_CMT)
 607 AC_SUBST(SUBSET_CMT)
 608 dnl
 609 dnl handle --disable-backtrace
 610 dnl
 611 AH_TEMPLATE([DISABLE_BACKTRACE], [Define to 1 to disable use of backtrace])
 612 AC_ARG_ENABLE([backtrace],
 613 AS_HELP_STRING([--disable-backtrace],[disable use backtrace]),
 614 if test "$enableval" = "no"
 615 then
 616         AC_MSG_RESULT([Disabling use of backtrace])
 617         AC_DEFINE(DISABLE_BACKTRACE, 1)
 618 else
 619         AC_MSG_RESULT([Enabling use of backtrace])
 620 fi
 621 ,
 622 AC_MSG_RESULT([Enabling use of backtrace by default])
 623 )
 624 dnl
 625 dnl handle --enable-debugfs
 626 dnl
 627 AC_ARG_ENABLE([debugfs],
 628 AS_HELP_STRING([--disable-debugfs],[disable support of debugfs program]),
 629 if test "$enableval" = "no"
 630 then
 631         AC_MSG_RESULT([Disabling debugfs support])
 632         DEBUGFS_CMT="#"
 633 else
 634         DEBUGFS_CMT=
 635         AC_MSG_RESULT([Enabling debugfs support])
 636 fi
 637 ,
 638 AC_MSG_RESULT([Enabling debugfs support by default])
 639 DEBUGFS_CMT=
 640 )
 641 AC_SUBST(DEBUGFS_CMT)
 642 dnl
 643 dnl handle --enable-imager
 644 dnl
 645 AC_ARG_ENABLE([imager],
 646 AS_HELP_STRING([--disable-imager],[disable support of e2image program]),
 647 if test "$enableval" = "no"
 648 then
 649         AC_MSG_RESULT([Disabling e2image support])
 650         IMAGER_CMT="#"
 651 else
 652         IMAGER_CMT=
 653         AC_MSG_RESULT([Enabling e2image support])
 654 fi
 655 ,
 656 AC_MSG_RESULT([Enabling e2image support by default])
 657 IMAGER_CMT=
 658 )
 659 AC_SUBST(IMAGER_CMT)
 660 dnl
 661 dnl handle --enable-resizer
 662 dnl
 663 AC_ARG_ENABLE([resizer],
 664 AS_HELP_STRING([--disable-resizer],[disable support of e2resize program]),
 665 if test "$enableval" = "no"
 666 then
 667         AC_MSG_RESULT([Disabling e2resize support])
 668         RESIZER_CMT="#"
 669 else
 670         RESIZER_CMT=
 671         AC_MSG_RESULT([Enabling e2resize support])
 672 fi
 673 ,
 674 AC_MSG_RESULT([Enabling e2resize support by default])
 675 RESIZER_CMT=
 676 )
 677 AC_SUBST(RESIZER_CMT)
 678 dnl
 679 dnl handle --enable-defrag
 680 dnl
 681 AC_ARG_ENABLE([defrag],
 682 AS_HELP_STRING([--disable-defrag],[disable support of e4defrag program]),
 683 if test "$enableval" = "no"
 684 then
 685         AC_MSG_RESULT([Disabling e4defrag support])
 686         DEFRAG_CMT="#"
 687 else
 688         DEFRAG_CMT=
 689         AC_MSG_RESULT([Enabling e4defrag support])
 690 fi
 691 ,
 692 if test -z "$WITH_DIET_LIBC"
 693 then
 694         AC_MSG_RESULT([Enabling e4defrag support by default])
 695         DEFRAG_CMT=
 696 else
 697         AC_MSG_RESULT([Disabling e4defrag support by default])
 698         DEFRAG_CMT="#"
 699 fi
 700 )
 701 AC_SUBST(DEFRAG_CMT)
 702 dnl
 703 dnl See whether to install the `fsck' wrapper program (that calls e2fsck)
 704 dnl
 705 AC_ARG_ENABLE([fsck],
 706 AS_HELP_STRING([--enable-fsck],[build fsck wrapper program]),
 707 [if test "$enableval" = "no"
 708 then
 709         FSCK_PROG='' FSCK_MAN=''
 710         AC_MSG_RESULT([Not building fsck wrapper])
 711 else
 712         FSCK_PROG=fsck FSCK_MAN=fsck.8
 713         AC_MSG_RESULT([Building fsck wrapper])
 714 fi]
 715 ,
 716 [case "$host_os" in
 717   gnu*)
 718     FSCK_PROG='' FSCK_MAN=''
 719     AC_MSG_RESULT([Not building fsck wrapper by default])
 720     ;;
 721   *)
 722     FSCK_PROG=fsck FSCK_MAN=fsck.8
 723     AC_MSG_RESULT([Building fsck wrapper by default])
 724 esac]
 725 )
 726 AC_SUBST(FSCK_PROG)
 727 AC_SUBST(FSCK_MAN)
 728 dnl
 729 dnl See whether to install the `e2initrd-helper' program
 730 dnl
 731 AC_ARG_ENABLE([e2initrd-helper],
 732 AS_HELP_STRING([--enable-e2initrd-helper],[build e2initrd-helper program]),
 733 [if test "$enableval" = "no"
 734 then
 735         E2INITRD_PROG='' E2INITRD_MAN=''
 736         AC_MSG_RESULT([Not building e2initrd helper])
 737 else
 738         E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 739         AC_MSG_RESULT([Building e2initrd helper])
 740 fi]
 741 ,
 742 E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 743 AC_MSG_RESULT([Building e2initrd helper by default])
 744 )
 745 AC_SUBST(E2INITRD_PROG)
 746 AC_SUBST(E2INITRD_MAN)
 747 dnl
 748 dnl
 749 dnl
 750 AC_ARG_ENABLE([tls],
 751 AS_HELP_STRING([--disable-tls],[disable use of thread local support]),
 752 [if test "$enableval" = "no"
 753 then
 754         try_tls=""
 755         AC_MSG_RESULT([Disabling thread local support])
 756 else
 757         try_tls="yes"
 758         AC_MSG_RESULT([Enabling thread local support])
 759 fi]
 760 ,
 761 if test -n "$WITH_DIET_LIBC"
 762 then
 763         try_tls=""
 764         AC_MSG_RESULT([Diet libc does not support thread local support])
 765 else
 766         try_tls="yes"
 767         AC_MSG_RESULT([Try using thread local support by default])
 768 fi
 769 )
 770 if test "$try_tls" = "yes"
 771 then
 772 AX_TLS
 773 fi
 774 dnl
 775 dnl
 776 dnl
 777 AC_ARG_WITH([pthread],
 778 AS_HELP_STRING([--without-pthread],[disable use of pthread support]),
 779 [if test "$withval" = "no"
 780 then
 781         try_pthread=""
 782         AC_MSG_RESULT([Disabling pthread support])
 783 else
 784         try_pthread="yes"
 785         AC_MSG_RESULT([Testing for pthread support])
 786 fi]
 787 ,
 788 try_pthread="yes"
 789 AC_MSG_RESULT([Try testing for pthread support by default])
 790 )
 791 if test "$try_pthread" = "yes"
 792 then
 793 AX_PTHREAD
 794 else
 795 test -n "$PTHREAD_CC" || PTHREAD_CC="$CC"
 796 AC_SUBST([PTHREAD_CC])
 797 fi
 798 dnl
 799 dnl
 800 dnl
 801 AH_TEMPLATE([USE_UUIDD], [Define to 1 to build uuidd])
 802 AC_ARG_ENABLE([uuidd],
 803 AS_HELP_STRING([--disable-uuidd],[disable building the uuid daemon]),
 804 [if test "$enableval" = "no"
 805 then
 806         AC_MSG_RESULT([Not building uuidd])
 807         UUIDD_CMT="#"
 808 else
 809         AC_DEFINE(USE_UUIDD, 1)
 810         UUIDD_CMT=""
 811         AC_MSG_RESULT([Building uuidd])
 812 fi]
 813 ,
 814 AC_DEFINE(USE_UUIDD, 1)
 815 if test -z "$UUID_CMT"
 816 then
 817         UUIDD_CMT=""
 818         AC_MSG_RESULT([Building uuidd by default])
 819 else
 820         UUIDD_CMT="#"
 821         AC_MSG_RESULT([Disabling uuidd by default])
 822 fi
 823 )
 824 AC_SUBST(UUIDD_CMT)
 825 dnl
 826 dnl handle --disable-mmp
 827 dnl
 828 AH_TEMPLATE([CONFIG_MMP], [Define to 1 to enable mmp support])
 829 AC_ARG_ENABLE([mmp],
 830 AS_HELP_STRING([--disable-mmp],[disable support mmp, Multi Mount Protection]),
 831 if test "$enableval" = "no"
 832 then
 833         AC_MSG_RESULT([Disabling mmp support])
 834 else
 835         AC_MSG_RESULT([Enabling mmp support])
 836         AC_DEFINE(CONFIG_MMP, 1)
 837 fi
 838 ,
 839 AC_MSG_RESULT([Enabling mmp support by default])
 840 AC_DEFINE(CONFIG_MMP, 1)
 841 )
 842 dnl
 843 dnl handle --disable-tdb
 844 dnl
 845 AH_TEMPLATE([CONFIG_TDB], [Define to 1 to enable tdb support])
 846 AC_ARG_ENABLE([tdb],
 847 AS_HELP_STRING([--disable-tdb],[disable tdb support]),
 848 [
 849 if test "$enableval" = "no"
 850 then
 851         AC_MSG_RESULT([Disabling tdb support])
 852         CONFIG_TDB=0
 853 else
 854         AC_MSG_RESULT([Enabling tdb support])
 855         CONFIG_TDB=1
 856 fi
 857 ]
 858 ,
 859 [
 860 case "$host_os" in
 861 mingw*)
 862         AC_MSG_RESULT([Disabling tdb support by default])
 863         CONFIG_TDB=0
 864         ;;
 865 *)
 866         AC_MSG_RESULT([Enabling tdb support by default])
 867         CONFIG_TDB=1
 868         ;;
 869 esac
 870 ]
 871 )
 872 if test "$CONFIG_TDB" = "1"
 873 then
 874         AC_DEFINE(CONFIG_TDB, 1)
 875         TDB_CMT=""
 876         TDB_MAN_COMMENT=""
 877 else
 878         TDB_CMT="#"
 879         TDB_MAN_COMMENT='.\"'
 880 fi
 881 AC_SUBST(TDB_CMT)
 882 AC_SUBST(TDB_MAN_COMMENT)
 883 dnl
 884 dnl handle --disable-bmap-stats
 885 dnl
 886 AH_TEMPLATE([ENABLE_BMAP_STATS], [Define to 1 to enable bitmap stats.])
 887 AC_ARG_ENABLE([bmap-stats],
 888 AS_HELP_STRING([--disable-bmap-stats],[disable collection of bitmap stats]),
 889 if test "$enableval" = "no"
 890 then
 891         AC_MSG_RESULT([Disabling bitmap statistics support])
 892 else
 893         AC_MSG_RESULT([Enabling bitmap statistics support])
 894         AC_DEFINE(ENABLE_BMAP_STATS, 1)
 895 fi
 896 ,
 897 AC_MSG_RESULT([Enabling bitmap statistics support by default])
 898 AC_DEFINE(ENABLE_BMAP_STATS, 1)
 899 )
 900 dnl
 901 dnl handle --enable-bmap-stats-ops
 902 dnl
 903 AH_TEMPLATE([ENABLE_BMAP_STATS_OPS], [Define to 1 to enable bitmap stats.])
 904 AC_ARG_ENABLE([bmap-stats-ops],
 905 AS_HELP_STRING([--enable-bmap-stats-ops],[enable collection of additional bitmap stats]),
 906 if test "$enableval" = "no"
 907 then
 908         AC_MSG_RESULT([Disabling additional bitmap statistics])
 909 else
 910         dnl There has to be a better way!
 911         AS_IF([test "x${enable_bmap_stats}" = "xno"],
 912          AC_MSG_FAILURE([Error --enable-bmap-stats-ops requires bmap-stats]))
 913
 914         AC_MSG_RESULT([Enabling additional bitmap statistics])
 915         AC_DEFINE(ENABLE_BMAP_STATS_OPS, 1)
 916 fi
 917 ,
 918 AC_MSG_RESULT([Disabling additional bitmap statistics by default])
 919 )
 920 dnl
 921 dnl
 922 dnl
 923 MAKEFILE_LIBRARY=$srcdir/lib/Makefile.library
 924 AC_SUBST_FILE(MAKEFILE_LIBRARY)
 925 dnl
 926 dnl Add internationalization support, using gettext.
 927 dnl
 928 GETTEXT_PACKAGE=e2fsprogs
 929 PACKAGE=e2fsprogs
 930 VERSION="$E2FSPROGS_VERSION"
 931 VERSION=0.14.1
 932 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [package name for gettext])
 933 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [version for gettext])
 934 AC_SUBST(GETTEXT_PACKAGE)
 935 AC_SUBST(PACKAGE)
 936 AC_SUBST(VERSION)
 937
 938 AM_GNU_GETTEXT([external])
 939 dnl
 940 dnl End of configuration options
 941 dnl
 942 AC_SUBST(BINARY_TYPE)
 943 AC_PROG_MAKE_SET
 944 CHECK_GNU_MAKE
 945 AC_PATH_PROG(LN, ln, ln)
 946 AC_PROG_MKDIR_P
 947 dnl
 948 dnl @mkdir_p@ is used by po's Makefile.in
 949 dnl
 950 mkdir_p=$MKDIR_P
 951 AC_SUBST(mkdir_p)
 952 AC_PROG_LN_S
 953 AC_PATH_PROG(MV, mv, mv)
 954 AC_PATH_PROG(CP, cp, cp)
 955 AC_PATH_PROG(RM, rm, rm)
 956 AC_PATH_PROG(CHMOD, chmod, :)
 957 AC_PROG_AWK
 958 AC_PROG_EGREP
 959 AC_PATH_PROG(SED, sed, sed)
 960 AC_PATH_PROG(PERL, perl, perl)
 961 AC_PATH_PROG(LDCONFIG, ldconfig, :)
 962 AC_CHECK_TOOL(AR, ar, ar)
 963 AC_CHECK_TOOL(RANLIB, ranlib, :)
 964 AC_CHECK_TOOL(STRIP, strip, :)
 965 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
 966 if test "_$MAKEINFO" = "_"; then
 967     MAKEINFO="echo Makeinfo is missing. Info documentation will not be built."
 968 else
 969     case "$MAKEINFO" in
 970       */missing.*)
 971         AC_MSG_WARN([
 972 *** Makeinfo is missing. Info documentation will not be built.])
 973         ;;
 974       *)
 975         ;;
 976     esac
 977 fi
 978 AC_SUBST(MAKEINFO)
 979 AC_PROG_INSTALL
 980 # See if we need a separate native compiler.
 981 if test $cross_compiling = no; then
 982   BUILD_CC="$CC"
 983   AC_SUBST(BUILD_CC)
 984 else
 985   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 986 fi
 987 AC_CHECK_HEADERS(m4_flatten([
 988         dirent.h
 989         errno.h
 990         execinfo.h
 991         getopt.h
 992         malloc.h
 993         mntent.h
 994         paths.h
 995         pthread.h
 996         semaphore.h
 997         setjmp.h
 998         signal.h
 999         stdarg.h
1000         stdint.h
1001         stdlib.h
1002         termios.h
1003         termio.h
1004         unistd.h
1005         utime.h
1006         attr/xattr.h
1007         linux/falloc.h
1008         linux/fd.h
1009         linux/fsmap.h
1010         linux/major.h
1011         linux/loop.h
1012         linux/types.h
1013         net/if_dl.h
1014         netinet/in.h
1015         sys/acl.h
1016         sys/disklabel.h
1017         sys/disk.h
1018         sys/file.h
1019         sys/ioctl.h
1020         sys/key.h
1021         sys/mkdev.h
1022         sys/mman.h
1023         sys/mount.h
1024         sys/prctl.h
1025         sys/random.h
1026         sys/resource.h
1027         sys/select.h
1028         sys/socket.h
1029         sys/sockio.h
1030         sys/stat.h
1031         sys/syscall.h
1032         sys/sysmacros.h
1033         sys/time.h
1034         sys/types.h
1035         sys/un.h
1036         sys/wait.h
1037         sys/xattr.h
1038 ]))
1039 case "$host_os" in
1040 mingw*)
1041         # The above checks only detect system headers, not the headers in
1042         # ./include/mingw/, so explicitly define them to be available.
1043         AC_DEFINE(HAVE_LINUX_TYPES_H, 1)
1044         AC_DEFINE(HAVE_SYS_STAT_H, 1)
1045         AC_DEFINE(HAVE_SYS_SYSMACROS_H, 1)
1046         AC_DEFINE(HAVE_SYS_TYPES_H, 1)
1047         AC_DEFINE(HAVE_UNISTD_H, 1)
1048         ;;
1049 esac
1050 dnl Check where to find a dd(1) that supports iflag=fullblock
1051 dnl and oflag=append
1052 AC_MSG_CHECKING([for a dd(1) program that supports iflag=fullblock])
1053 DD=
1054 for i in dd gdd ; do
1055         if "$i" if=/dev/null of=/dev/null count=1 bs=10k 2>/dev/null iflag=fullblock oflag=append ; then
1056                 DD=$i
1057                 break
1058         fi
1059 done
1060 if test -n "$DD" ; then
1061         AC_MSG_RESULT([$DD])
1062 else
1063         AC_MSG_RESULT([not found, using dd])
1064         DD=dd
1065         AC_MSG_WARN([No GNU-compatible dd(1) program found, expect some self-test failures.])
1066 fi
1067 AC_SUBST([DD])
1068
1069 AC_CHECK_HEADERS(net/if.h,,,
1070 [[
1071 #if HAVE_SYS_TYPES_H
1072 #include <sys/types.h>
1073 #endif
1074 #if HAVE_SYS_SOCKET
1075 #include <sys/socket.h>
1076 #endif
1077 ]])
1078 AC_FUNC_VPRINTF
1079 dnl Check to see if dirent has member d_reclen. On cygwin those d_reclen
1080 dnl is not declared.
1081 AC_CHECK_MEMBER(struct dirent.d_reclen,[AC_DEFINE(HAVE_RECLEN_DIRENT, 1,
1082                        [Define to 1 if dirent has d_reclen])],,
1083                 [#include <dirent.h>])
1084 AC_CHECK_MEMBERS([struct stat.st_atim])
1085 dnl Check to see if ssize_t was declared
1086 AC_CHECK_TYPE(ssize_t,[AC_DEFINE(HAVE_TYPE_SSIZE_T, 1,
1087                 [Define to 1 if ssize_t declared])],,
1088               [#include <sys/types.h>])
1089 dnl
1090 dnl Check to see if llseek() is declared in unistd.h.  On some libc's
1091 dnl it is, and on others it isn't..... Thank you glibc developers....
1092 dnl
1093 AC_CHECK_DECL(llseek,[AC_DEFINE(HAVE_LLSEEK_PROTOTYPE, 1,
1094                         [Define to 1 if llseek declared in unistd.h])],,
1095               [#include <unistd.h>])
1096 dnl
1097 dnl Check to see if lseek64() is declared in unistd.h.  Glibc's header files
1098 dnl are so convoluted that I can't tell whether it will always be defined,
1099 dnl and if it isn't defined while lseek64 is defined in the library,
1100 dnl disaster will strike.
1101 dnl
1102 dnl Warning!  Use of --enable-gcc-wall may throw off this test.
1103 dnl
1104 dnl
1105 AC_CHECK_DECL(lseek64,[AC_DEFINE(HAVE_LSEEK64_PROTOTYPE, 1,
1106                         [Define to 1 if lseek64 declared in unistd.h])],,
1107                 [#define _LARGEFILE_SOURCE
1108                  #define _LARGEFILE64_SOURCE
1109                  #include <unistd.h>])
1110 dnl
1111 dnl Word sizes...
1112 dnl
1113 AC_CHECK_SIZEOF(short)
1114 AC_CHECK_SIZEOF(int)
1115 AC_CHECK_SIZEOF(long)
1116 AC_CHECK_SIZEOF(long long)
1117 AC_CHECK_SIZEOF(off_t)
1118 AC_CHECK_SIZEOF(time_t)
1119 SIZEOF_SHORT=$ac_cv_sizeof_short
1120 SIZEOF_INT=$ac_cv_sizeof_int
1121 SIZEOF_LONG=$ac_cv_sizeof_long
1122 SIZEOF_LONG_LONG=$ac_cv_sizeof_long_long
1123 SIZEOF_OFF_T=$ac_cv_sizeof_off_t
1124 SIZEOF_TIME_T=$ac_cv_sizeof_time_t
1125 AC_SUBST(SIZEOF_SHORT)
1126 AC_SUBST(SIZEOF_INT)
1127 AC_SUBST(SIZEOF_LONG)
1128 AC_SUBST(SIZEOF_LONG_LONG)
1129 AC_SUBST(SIZEOF_OFF_T)
1130 AC_SUBST(SIZEOF_TIME_T)
1131 AC_C_BIGENDIAN
1132 if test $cross_compiling = no; then
1133   BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
1134 else
1135   CROSS_COMPILE="1" BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
1136 fi
1137 ASM_TYPES_HEADER=./asm_types.h
1138 AC_SUBST_FILE(ASM_TYPES_HEADER)
1139 dnl
1140 dnl Save the configuration #defines needed for the public ext2fs.h
1141 dnl header file
1142 dnl
1143 echo "/* These defines are needed for the public ext2fs.h header file */" \
1144      > public_config.h
1145 if grep HAVE_SYS_TYPES_H confdefs.h > tmp_config.$$; then
1146   uniq tmp_config.$$ >> public_config.h
1147 else
1148   echo "#undef HAVE_SYS_TYPES_H" >> public_config.h
1149 fi
1150 if grep WORDS_BIGENDIAN confdefs.h > tmp_config.$$; then
1151   uniq tmp_config.$$ >> public_config.h
1152 else
1153   echo "#undef WORDS_BIGENDIAN" >> public_config.h
1154 fi
1155 rm -f tmp_config.$$
1156 PUBLIC_CONFIG_HEADER=./public_config.h
1157 AC_SUBST_FILE(PUBLIC_CONFIG_HEADER)
1158 dnl
1159 dnl See if we have inttypes.h and if intptr_t is defined
1160 dnl
1161 AC_CHECK_HEADERS([inttypes.h])
1162 AC_CHECK_TYPES(intptr_t)
1163 dnl
1164 dnl See if struct stat has a st_flags field, in which case we can get file
1165 dnl flags somewhat portably.  Also check for the analogous setter, chflags().
1166 dnl
1167 AC_MSG_CHECKING(whether struct stat has a st_flags field)
1168 AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags,
1169         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/stat.h>]], [[struct stat stat; stat.st_flags = 0;]])],[e2fsprogs_cv_struct_st_flags=yes],[e2fsprogs_cv_struct_st_flags=no]))
1170 AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags)
1171 if test "$e2fsprogs_cv_struct_st_flags" = yes; then
1172   AC_MSG_CHECKING(whether st_flags field is useful)
1173   AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags_immut,
1174         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/stat.h>]], [[struct stat stat; stat.st_flags |= UF_IMMUTABLE;]])],[e2fsprogs_cv_struct_st_flags_immut=yes],[e2fsprogs_cv_struct_st_flags_immut=no]))
1175   AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags_immut)
1176   if test "$e2fsprogs_cv_struct_st_flags_immut" = yes; then
1177           AC_DEFINE(HAVE_STAT_FLAGS, 1,
1178                 [Define to 1 if struct stat has st_flags])
1179   fi
1180 fi
1181 dnl
1182 dnl Check for the presence of SA_LEN
1183 dnl
1184 AC_CHECK_MEMBER(struct sockaddr.sa_len,
1185                 AC_DEFINE_UNQUOTED(HAVE_SA_LEN,1,
1186                         [Define to 1 if if struct sockaddr contains sa_len]),,
1187         [#include <sys/types.h>
1188          #include <sys/socket.h>])
1189 dnl
1190 dnl If we are using the system-provided blkid library, check for
1191 dnl the functions added after migrating that library to util-linux
1192 dnl
1193 if test -n "$BLKID_CMT"; then
1194   AC_CHECK_LIB(blkid, blkid_probe_get_topology,
1195                       AC_DEFINE(HAVE_BLKID_PROBE_GET_TOPOLOGY, 1,
1196                                 [Define to 1 if blkid has blkid_probe_get_topology]))
1197   AC_CHECK_LIB(blkid, blkid_topology_get_dax,
1198                       AC_DEFINE(HAVE_BLKID_TOPOLOGY_GET_DAX, 1,
1199                                 [Define to 1 if blkid has blkid_topology_get_dax]))
1200   AC_CHECK_LIB(blkid, blkid_probe_enable_partitions,
1201                       AC_DEFINE(HAVE_BLKID_PROBE_ENABLE_PARTITIONS, 1,
1202                                 [Define to 1 if blkid has blkid_probe_enable_partitions]))
1203 fi
1204 dnl
1205 if test -n "$DLOPEN_LIB" ; then
1206    ac_cv_func_dlopen=yes
1207 fi
1208 AC_CHECK_FUNCS(m4_flatten([
1209         __secure_getenv
1210         add_key
1211         backtrace
1212         chflags
1213         dlopen
1214         fadvise64
1215         fallocate
1216         fallocate64
1217         fchown
1218         fcntl
1219         fdatasync
1220         fstat64
1221         fsync
1222         ftruncate64
1223         futimes
1224         getcwd
1225         getdtablesize
1226         getentropy
1227         gethostname
1228         getmntinfo
1229         getpwuid_r
1230         getrandom
1231         getrlimit
1232         getrusage
1233         jrand48
1234         keyctl
1235         llistxattr
1236         llseek
1237         lseek64
1238         mallinfo
1239         mallinfo2
1240         mbstowcs
1241         memalign
1242         mempcpy
1243         mmap
1244         msync
1245         nanosleep
1246         open64
1247         pathconf
1248         posix_fadvise
1249         posix_fadvise64
1250         posix_memalign
1251         prctl
1252         pread
1253         pwrite
1254         pread64
1255         pwrite64
1256         qsort_r
1257         secure_getenv
1258         setmntent
1259         setresgid
1260         setresuid
1261         snprintf
1262         srandom
1263         stpcpy
1264         strcasecmp
1265         strdup
1266         strnlen
1267         strptime
1268         strtoull
1269         sync_file_range
1270         sysconf
1271         usleep
1272         utime
1273         utimes
1274         valloc
1275 ]))
1276 dnl
1277 dnl Check to see if -lsocket is required (solaris) to make something
1278 dnl that uses socket() to compile; this is needed for the UUID library
1279 dnl
1280 SOCKET_LIB=''
1281 AC_CHECK_LIB(socket, socket, [SOCKET_LIB=-lsocket])
1282 AC_SUBST(SOCKET_LIB)
1283 dnl
1284 dnl See if libmagic exists
1285 dnl
1286 AC_CHECK_LIB(magic, magic_file, [MAGIC_LIB=-lmagic
1287 AC_CHECK_HEADERS([magic.h])])
1288 if test "$ac_cv_func_dlopen" = yes ; then
1289    MAGIC_LIB=$DLOPEN_LIB
1290 fi
1291 AC_SUBST(MAGIC_LIB)
1292 dnl
1293 dnl Check to see if librt is required for clock_gettime() (glibc < 2.17)
1294 dnl
1295 AC_CHECK_LIB(rt, clock_gettime, [CLOCK_GETTIME_LIB=-lrt])
1296 AC_SUBST(CLOCK_GETTIME_LIB)
1297 dnl
1298 dnl Check to see if the FUSE library is -lfuse or -losxfuse
1299 dnl
1300 FUSE_CMT=
1301 FUSE_LIB=
1302 dnl osxfuse.dylib supersedes fuselib.dylib
1303 AC_ARG_ENABLE([fuse2fs],
1304 AS_HELP_STRING([--disable-fuse2fs],[do not build fuse2fs]),
1305 if test "$enableval" = "no"
1306 then
1307         FUSE_CMT="#"
1308         AC_MSG_RESULT([Disabling fuse2fs])
1309 else
1310         AC_CHECK_HEADERS([pthread.h fuse.h], [],
1311 [AC_MSG_FAILURE([Cannot find fuse2fs headers.])],
1312 [#define _FILE_OFFSET_BITS      64
1313 #define FUSE_USE_VERSION 29])
1314
1315         AC_PREPROC_IFELSE(
1316 [AC_LANG_PROGRAM([[#define FUSE_USE_VERSION 29
1317 #ifdef __linux__
1318 #include <linux/fs.h>
1319 #include <linux/falloc.h>
1320 #include <linux/xattr.h>
1321 #endif
1322 ]], [])], [], [AC_MSG_FAILURE([Cannot find fuse2fs Linux headers.])])
1323
1324         AC_CHECK_LIB(osxfuse, fuse_main, [FUSE_LIB=-losxfuse],
1325                 [AC_CHECK_LIB(fuse, fuse_main, [FUSE_LIB=-lfuse],
1326                               [AC_MSG_FAILURE([Cannot find fuse library.])])])
1327         AC_MSG_RESULT([Enabling fuse2fs])
1328 fi
1329 ,
1330 AC_CHECK_HEADERS([pthread.h fuse.h], [], [FUSE_CMT="#"],
1331 [#define _FILE_OFFSET_BITS      64
1332 #define FUSE_USE_VERSION 29
1333 #ifdef __linux__
1334 # include <linux/fs.h>
1335 # include <linux/falloc.h>
1336 # include <linux/xattr.h>
1337 #endif])
1338 if test -z "$FUSE_CMT"
1339 then
1340         AC_CHECK_LIB(osxfuse, fuse_main, [FUSE_LIB=-losxfuse],
1341 [AC_CHECK_LIB(fuse, fuse_main, [FUSE_LIB=-lfuse], [FUSE_CMT="#"])])
1342 fi
1343 if test -z "$FUSE_CMT"
1344 then
1345         AC_MSG_RESULT([Enabling fuse2fs by default.])
1346 fi
1347 )
1348 AC_SUBST(FUSE_LIB)
1349 AC_SUBST(FUSE_CMT)
1350 dnl
1351 dnl See if optreset exists
1352 dnl
1353 AC_MSG_CHECKING(for optreset)
1354 AC_CACHE_VAL(ac_cv_have_optreset,
1355 [AC_EGREP_HEADER(optreset, unistd.h,
1356   ac_cv_have_optreset=yes, ac_cv_have_optreset=no)])dnl
1357 AC_MSG_RESULT($ac_cv_have_optreset)
1358 if test $ac_cv_have_optreset = yes; then
1359   AC_DEFINE(HAVE_OPTRESET, 1, [Define to 1 if optreset for getopt is present])
1360 fi
1361 dnl
1362 dnl Test for sem_init, and which library it might require:
1363 dnl
1364 AH_TEMPLATE([HAVE_SEM_INIT], [Define to 1 if sem_init() exists])
1365 SEM_INIT_LIB=''
1366 echo GL_THREADS_API: ${gl_threads_api}
1367 if test "${gl_threads_api}" != none
1368 then
1369   AC_CHECK_FUNC(sem_init, ,
1370     AC_CHECK_LIB(pthread, sem_init,
1371         AC_DEFINE(HAVE_SEM_INIT, 1)
1372         SEM_INIT_LIB=-lpthread,
1373     AC_CHECK_LIB(rt, sem_init,
1374         AC_DEFINE(HAVE_SEM_INIT, 1)
1375         SEM_INIT_LIB=-lrt,
1376     AC_CHECK_LIB(posix4, sem_init,
1377         AC_DEFINE(HAVE_SEM_INIT, 1)
1378         SEM_INIT_LIB=-lposix4))))dnl
1379 fi
1380 AC_SUBST(SEM_INIT_LIB)
1381 dnl
1382 dnl qsort_r detection
1383 dnl
1384 AS_IF([test "$ac_cv_func_qsort_r" != no], [
1385   AC_CACHE_CHECK(whether qsort_r is GNU version, e2_cv_gnu_qsort_r,
1386     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1387 @%:@include <stdlib.h>
1388 void (qsort_r)(void *base, size_t nmemb, size_t size,
1389             int (*compar)(const void *, const void *, void *),
1390             void *arg);
1391 ]], [[ ]])],[e2_cv_gnu_qsort_r=yes],[e2_cv_gnu_qsort_r=no])
1392   ])
1393   AC_CACHE_CHECK(whether qsort_r is BSD version, e2_cv_bsd_qsort_r,
1394     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1395 @%:@include <stdlib.h>
1396 void (qsort_r)(void *base, size_t nmemb, size_t size,
1397              void *arg, int (*compar)(void *, const void *, const void *));
1398 ]], [[ ]])],[e2_cv_bsd_qsort_r=yes],[e2_cv_bsd_qsort_r=no])
1399   ])
1400   AS_CASE("$e2_cv_gnu_qsort_r:$e2_cv_bsd_qsort_r",
1401   [yes:no], [
1402     AC_DEFINE(HAVE_GNU_QSORT_R, 1, [ Define to 1 if you have the GNU-style 'qsort_r' function.])
1403   ],
1404   [no:yes], [
1405     AC_DEFINE(HAVE_BSD_QSORT_R, 1, [ Define to 1 if you have the BSD-style 'qsort_r' function.])
1406   ])
1407 ])
1408 dnl
1409 dnl Check for unified diff
1410 dnl
1411 AC_MSG_CHECKING(for unified diff option)
1412 if diff -u $0 $0 > /dev/null 2>&1 ; then
1413    UNI_DIFF_OPTS=-u
1414 else
1415    UNI_DIFF_OPTS=-c
1416 fi
1417 AC_MSG_RESULT($UNI_DIFF_OPTS)
1418 AC_SUBST(UNI_DIFF_OPTS)
1419 dnl
1420 dnl We use the EXT2 ioctls only under Linux
1421 dnl
1422 case "$host_os" in
1423 linux*)
1424         AC_DEFINE(HAVE_EXT2_IOCTLS, 1, [Define to 1 if Ext2 ioctls present])
1425         ;;
1426 esac
1427 dnl
1428 dnl Check the available mount options
1429 dnl
1430 AX_CHECK_MOUNT_OPT(nosuid)
1431 AX_CHECK_MOUNT_OPT(nodev)
1432 dnl Enable LTO for all packages
1433 dnl
1434 AC_ARG_ENABLE([lto],
1435 AS_HELP_STRING([--enable-lto],[enable link time optimization]),,
1436 enable_lto=no)
1437 if test "$enable_lto" = "yes" || test "$enable_lto" = "probe"; then
1438         AC_MSG_CHECKING([if C compiler supports LTO])
1439         OLD_CFLAGS="$CFLAGS"
1440         OLD_LDFLAGS="$LDFLAGS"
1441         LTO_FLAGS="-g -flto -ffat-lto-objects"
1442         CFLAGS="$CFLAGS $LTO_FLAGS"
1443         LDFLAGS="$LDFLAGS $LTO_FLAGS"
1444         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1445                 [AC_MSG_RESULT([yes])]
1446                 [lto_cflags=$LTO_FLAGS]
1447                 [lto_ldflags=$LTO_FLAGS]
1448                 [AC_PATH_PROG(gcc_ar, gcc-ar,,)]
1449                 [AC_PATH_PROG(gcc_ranlib, gcc-ranlib,,)],
1450                 [AC_MSG_RESULT([no])])
1451         if test -x "$gcc_ar" && test -x "$gcc_ranlib"; then
1452                 have_lto=yes
1453                 AR="${gcc_ar}"
1454                 RANLIB="${gcc_ranlib}"
1455         fi
1456         CFLAGS="${OLD_CFLAGS}"
1457         LDFLAGS="${OLD_LDFLAGS}"
1458         AC_SUBST(have_lto)
1459         AC_SUBST(lto_cflags)
1460         AC_SUBST(lto_ldflags)
1461 fi
1462 if test "$enable_lto" = "yes" && test "$have_lto" != "yes"; then
1463         AC_MSG_ERROR([LTO not supported by compiler.])
1464 fi
1465 dnl
1466 dnl Enable UBSAN for all packages
1467 dnl
1468 AC_ARG_ENABLE([ubsan],
1469 AS_HELP_STRING([--enable-ubsan],[enable undefined behavior sanitizer]),,
1470 enable_ubsan=no)
1471 if test "$enable_ubsan" = "yes" || test "$enable_ubsan" = "probe"; then
1472         AC_MSG_CHECKING([if C compiler supports UBSAN])
1473         OLD_CFLAGS="$CFLAGS"
1474         OLD_LDFLAGS="$LDFLAGS"
1475         UBSAN_FLAGS="-fsanitize=undefined"
1476         CFLAGS="$CFLAGS $UBSAN_FLAGS"
1477         LDFLAGS="$LDFLAGS $UBSAN_FLAGS"
1478         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1479                 [AC_MSG_RESULT([yes])]
1480                 [ubsan_cflags=$UBSAN_FLAGS]
1481                 [ubsan_ldflags=$UBSAN_FLAGS]
1482                 [have_ubsan=yes],
1483                 [AC_MSG_RESULT([no])])
1484         CFLAGS="${OLD_CFLAGS}"
1485         LDFLAGS="${OLD_LDFLAGS}"
1486         AC_SUBST(have_ubsan)
1487         AC_SUBST(ubsan_cflags)
1488         AC_SUBST(ubsan_ldflags)
1489 fi
1490 if test "$enable_ubsan" = "yes" && test "$have_ubsan" != "yes"; then
1491         AC_MSG_ERROR([UBSAN not supported by compiler.])
1492 fi
1493 dnl
1494 dnl Enable ADDRSAN for all packages
1495 dnl
1496 AC_ARG_ENABLE([addrsan],
1497 AS_HELP_STRING([--enable-addrsan],[enable address sanitizer]),,
1498 enable_addrsan=no)
1499 if test "$enable_addrsan" = "yes" || test "$enable_addrsan" = "probe"; then
1500         AC_MSG_CHECKING([if C compiler supports ADDRSAN])
1501         OLD_CFLAGS="$CFLAGS"
1502         OLD_LDFLAGS="$LDFLAGS"
1503         ADDRSAN_FLAGS="-fsanitize=address"
1504         CFLAGS="$CFLAGS $ADDRSAN_FLAGS"
1505         LDFLAGS="$LDFLAGS $ADDRSAN_FLAGS"
1506         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1507                 [AC_MSG_RESULT([yes])]
1508                 [addrsan_cflags=$ADDRSAN_FLAGS]
1509                 [addrsan_ldflags=$ADDRSAN_FLAGS]
1510                 [have_addrsan=yes],
1511                 [AC_MSG_RESULT([no])])
1512         CFLAGS="${OLD_CFLAGS}"
1513         LDFLAGS="${OLD_LDFLAGS}"
1514         AC_SUBST(have_addrsan)
1515         AC_SUBST(addrsan_cflags)
1516         AC_SUBST(addrsan_ldflags)
1517 fi
1518 if test "$enable_addrsan" = "yes" && test "$have_addrsan" != "yes"; then
1519         AC_MSG_ERROR([ADDRSAN not supported by compiler.])
1520 fi
1521 dnl
1522 dnl Enable THREADSAN for all packages
1523 dnl
1524 AC_ARG_ENABLE([threadsan],
1525 AS_HELP_STRING([--enable-threadsan],[enable thread sanitizer]),,
1526 enable_threadsan=no)
1527 if test "$enable_threadsan" = "yes" || test "$enable_threadsan" = "probe"; then
1528         AC_MSG_CHECKING([if C compiler supports THREADSAN])
1529         OLD_CFLAGS="$CFLAGS"
1530         OLD_LDFLAGS="$LDFLAGS"
1531         THREADSAN_FLAGS="-fsanitize=thread"
1532         CFLAGS="$CFLAGS $THREADSAN_FLAGS"
1533         LDFLAGS="$LDFLAGS $THREADSAN_FLAGS"
1534         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1535                 [AC_MSG_RESULT([yes])]
1536                 [threadsan_cflags=$THREADSAN_FLAGS]
1537                 [threadsan_ldflags=$THREADSAN_FLAGS]
1538                 [have_threadsan=yes],
1539                 [AC_MSG_RESULT([no])])
1540         CFLAGS="${OLD_CFLAGS}"
1541         LDFLAGS="${OLD_LDFLAGS}"
1542         AC_SUBST(have_threadsan)
1543         AC_SUBST(threadsan_cflags)
1544         AC_SUBST(threadsan_ldflags)
1545 fi
1546 if test "$enable_threadsan" = "yes" && test "$have_threadsan" != "yes"; then
1547         AC_MSG_ERROR([THREADSAN not supported by compiler.])
1548 fi
1549 if test "$have_threadsan" = "yes" && test "$have_addrsan" = "yes"; then
1550         AC_MSG_WARN([ADDRSAN and THREADSAN are not known to work together.])
1551 fi
1552 dnl
1553 dnl Enable the fuzzer sanitizer for all packages
1554 dnl
1555 FUZZING_CMT="#"
1556 AC_ARG_ENABLE([fuzzing],
1557 AS_HELP_STRING([--enable-fuzzing],[enable fuzzing sanitizer]),,
1558 enable_fuzzing=no)
1559 if test "$enable_fuzzing" = "yes" || test "$enable_fuzzing" = "probe"; then
1560         AC_PROG_CXX
1561         AC_MSG_CHECKING([if C compiler supports fuzzing sanitizer])
1562         AC_LANG_PUSH([C++])
1563         OLD_CXXFLAGS="$CXXFLAGS"
1564         OLD_LDFLAGS="$LDFLAGS"
1565         FUZZER_FLAGS="-fsanitize=fuzzer"
1566         CXXFLAGS="$CXXFLAGS $FUZZER_FLAGS"
1567         LDFLAGS="$LDFLAGS $FUZZER_FLAGS"
1568         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1569                 #include <stddef.h>
1570                 #include <stdint.h>
1571                 ]],
1572                 [ return 0; ])],
1573                 [AC_MSG_RESULT([yes])]
1574                 [fuzzer_cflags=$FUZZER_FLAGS]
1575                 [fuzzer_ldflags=$FUZZER_FLAGS]
1576                 [FUZZING_CMT=]
1577                 [have_fuzzer=yes],
1578                 [AC_MSG_RESULT([no])]
1579                 [AC_MSG_ERROR([fuzzing requested but not available])])
1580         CXXFLAGS="${OLD_CXXFLAGS}"
1581         LDFLAGS="${OLD_LDFLAGS}"
1582         AC_LANG_POP([C++])
1583         AC_SUBST(have_fuzzer)
1584         AC_SUBST(fuzzer_cflags)
1585         AC_SUBST(fuzzer_ldflags)
1586 fi
1587 if test "$enable_fuzzer" = "yes" && test "$have_fuzzer" != "yes"; then
1588         AC_MSG_ERROR([Fuzzing not supported by compiler.])
1589 fi
1590 AC_SUBST(FUZZING_CMT)
1591 dnl
1592 dnl OS-specific uncomment control
1593 dnl
1594 LINUX_CMT="#"
1595 CYGWIN_CMT="#"
1596 UNIX_CMT=
1597 case "$host_os" in
1598 linux*)
1599         LINUX_CMT=
1600         ;;
1601 cygwin)
1602         CYGWIN_CMT=
1603         UNIX_CMT="#"
1604         ;;
1605 esac
1606 AC_SUBST(LINUX_CMT)
1607 AC_SUBST(CYGWIN_CMT)
1608 AC_SUBST(UNIX_CMT)
1609 dnl
1610 dnl e2scrub only builds on linux
1611 dnl
1612 E2SCRUB_CMT="$LINUX_CMT"
1613 AC_SUBST(E2SCRUB_CMT)
1614 dnl
1615 dnl Linux and Hurd places root files in the / by default
1616 dnl
1617 case "$host_os" in
1618 linux* | gnu* | k*bsd*-gnu)
1619         if test "$prefix" = NONE -a "$root_prefix" = NONE ; then
1620                 root_prefix="";
1621                 AC_MSG_RESULT([On $host_os systems, root_prefix defaults to ''])
1622         fi
1623         ;;
1624 esac
1625 dnl
1626 dnl On Linux/hurd, force the prefix to be /usr
1627 dnl
1628 case "$host_os" in
1629 linux* | gnu* | k*bsd*-gnu)
1630         if test "$prefix" = NONE ; then
1631                 prefix="/usr";
1632                 AC_MSG_RESULT([On $host_os systems, prefix defaults to /usr])
1633                 if test "$mandir" = '${prefix}/man' ; then
1634                         AC_MSG_RESULT([...and mandir defaults to /usr/share/man])
1635                         mandir=/usr/share/man
1636                 fi
1637         fi
1638 ;;
1639 esac
1640 if test "$root_prefix" = NONE ; then
1641         if test "$prefix" = NONE ; then
1642                 root_prefix="$ac_default_prefix"
1643         else
1644                 root_prefix="$prefix"
1645         fi
1646         root_bindir=$bindir
1647         root_sbindir=$sbindir
1648         root_libdir=$libdir
1649         root_sysconfdir=$sysconfdir
1650 else
1651         root_bindir='${root_prefix}/bin'
1652         root_sbindir='${root_prefix}/sbin'
1653         root_libdir='${root_prefix}/lib'
1654         root_sysconfdir='${root_prefix}/etc'
1655 fi
1656 if test "$bindir" != '${exec_prefix}/bin'; then
1657     root_bindir=$bindir
1658     AC_MSG_RESULT([Setting root_bindir to $root_bindir])
1659 fi
1660 if test "$sbindir" != '${exec_prefix}/sbin'; then
1661     root_sbindir=$sbindir
1662     AC_MSG_RESULT([Setting root_sbindir to $root_sbindir])
1663 fi
1664 if test "$libdir" != '${exec_prefix}/lib'; then
1665     root_libdir=$libdir
1666     AC_MSG_RESULT([Setting root_libdir to $root_libdir])
1667 fi
1668 if test "$sysconfdir" != '${prefix}/etc'; then
1669     root_sysconfdir=$sysconfdir
1670     AC_MSG_RESULT([Setting root_sysconfdir to $root_sysconfdir])
1671 fi
1672 AC_SUBST(root_prefix)
1673 AC_SUBST(root_bindir)
1674 AC_SUBST(root_sbindir)
1675 AC_SUBST(root_libdir)
1676 AC_SUBST(root_sysconfdir)
1677 dnl
1678 dnl Allow specification of the multiarch arch
1679 dnl
1680 AC_ARG_WITH([multiarch],
1681 AS_HELP_STRING([--with-multiarch=ARCH],[specify the multiarch triplet]),
1682 if test "$withval" = "lib64"; then
1683     libdir=/usr/lib64
1684     root_libdir=/lib64
1685 else
1686     libdir=$libdir/$withval
1687     root_libdir=$root_libdir/$withval
1688 fi
1689 )
1690 dnl
1691 dnl
1692 dnl See if -static works.  This could fail if the linker does not
1693 dnl support -static, or if required external libraries are not available
1694 dnl in static form.
1695 dnl
1696 AC_MSG_CHECKING([whether we can link with -static])
1697 AC_CACHE_VAL(ac_cv_e2fsprogs_use_static,
1698 [SAVE_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS_STATIC -static"
1699 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[fflush(stdout);]])],[ac_cv_e2fsprogs_use_static=yes],[ac_cv_e2fsprogs_use_static=no])
1700 LDFLAGS=$SAVE_LDFLAGS])
1701 dnl
1702 dnl Regardless of how the test turns out, Solaris doesn't handle -static
1703 dnl This is caused by the socket library requiring the nsl library, which
1704 dnl requires the -dl library, which only works for dynamically linked
1705 dnl programs.  It basically means you can't have statically linked programs
1706 dnl which use the network under Solaris.
1707 dnl
1708 case "$host_os" in
1709 solaris2.*)
1710         ac_cv_e2fsprogs_use_static=no
1711 ;;
1712 esac
1713 AC_MSG_RESULT($ac_cv_e2fsprogs_use_static)
1714 if test $ac_cv_e2fsprogs_use_static = yes; then
1715         LDFLAGS_STATIC="$LDFLAGS_STATIC -static"
1716 fi
1717 AC_SUBST(LDFLAGS_STATIC)
1718 dnl
1719 dnl Work around mysterious Darwin / GNU libintl problem
1720 dnl (__asm__ redirection doesn't work for some mysterious reason.  Looks like
1721 dnl Apple hacked gcc somehow?)
1722 dnl
1723 case "$host_os" in
1724 darwin*)
1725         AC_MSG_RESULT([Using Apple Darwin / GNU libintl workaround])
1726         AC_DEFINE(_INTL_REDIRECT_MACROS, 1,
1727                 [Define to 1 if Apple Darwin libintl workaround is needed])
1728         ;;
1729 esac
1730 dnl
1731 dnl Only try to run the test suite if we're not cross compiling.
1732 dnl
1733 if test "$cross_compiling" = yes ; then
1734   DO_TEST_SUITE=
1735 else
1736   DO_TEST_SUITE=check
1737 fi
1738 AC_SUBST(DO_TEST_SUITE)
1739 dnl
1740 dnl Only include the intl include files if we're building with them
1741 dnl
1742 INCLUDES='-I. -I$(top_builddir)/lib -I$(top_srcdir)/lib'
1743 if test -n "$CPPFLAGS" ; then
1744         INCLUDES="$INCLUDES $CPPFLAGS"
1745 fi
1746 if test "$USE_INCLUDED_LIBINTL" = "yes" ; then
1747         INCLUDES=$INCLUDES' -I$(top_builddir)/intl -I$(top_srcdir)/intl'
1748 fi
1749 if test -n "$WITH_DIET_LIBC" ; then
1750         INCLUDES="$INCLUDES -D_REENTRANT"
1751 fi
1752 case "$host_os" in
1753 mingw*)
1754         INCLUDES=$INCLUDES' -I$(top_srcdir)/include/mingw'
1755         ;;
1756 esac
1757 AC_SUBST(INCLUDES)
1758 dnl
1759 dnl Build CFLAGS
1760 dnl
1761 if test $cross_compiling = no; then
1762    BUILD_CFLAGS="$CFLAGS $CPPFLAGS $INCLUDES -DHAVE_CONFIG_H"
1763    BUILD_LDFLAGS="$LDFLAGS"
1764 fi
1765 AC_SUBST(BUILD_CFLAGS)
1766 AC_SUBST(BUILD_LDFLAGS)
1767 dnl
1768 dnl Define CFLAGS and LDFLAGS for shared libraries
1769 dnl
1770 CFLAGS_SHLIB=${CFLAGS_SHLIB:-$CFLAGS}
1771 CFLAGS_STLIB=${CFLAGS_STLIB:-$CFLAGS}
1772 LDFLAGS_SHLIB=${LDFLAGS_SHLIB:-$LDFLAGS}
1773 AC_SUBST(CFLAGS_SHLIB)
1774 AC_SUBST(CFLAGS_STLIB)
1775 AC_SUBST(LDFLAGS_SHLIB)
1776
1777 dnl
1778 dnl Where do udev rules go?
1779 dnl
1780 AC_ARG_WITH([udev_rules_dir],
1781   [AS_HELP_STRING([--with-udev-rules-dir@<:@=DIR@:>@],
1782         [Install udev rules into DIR.])],
1783   [],
1784   [with_udev_rules_dir=yes])
1785 AS_IF([test "x${with_udev_rules_dir}" != "xno"],
1786   [
1787         AS_IF([test "x${with_udev_rules_dir}" = "xyes"],
1788           [
1789                 PKG_CHECK_MODULES([udev], [udev],
1790                   [
1791                         with_udev_rules_dir="$($PKG_CONFIG --variable=udevdir udev)/rules.d"
1792                   ], [
1793                         with_udev_rules_dir=""
1794                   ])
1795           ])
1796         AC_MSG_CHECKING([for udev rules dir])
1797         pkg_udev_rules_dir="${with_udev_rules_dir}"
1798         AS_IF([test -n "${pkg_udev_rules_dir}"],
1799           [
1800                 AC_MSG_RESULT(${pkg_udev_rules_dir})
1801                 have_udev="yes"
1802           ],
1803           [
1804                 AC_MSG_RESULT(no)
1805                 have_udev="no"
1806           ])
1807   ],
1808   [
1809         have_udev="disabled"
1810   ])
1811 AC_SUBST(have_udev)
1812 AC_SUBST(pkg_udev_rules_dir)
1813
1814 dnl
1815 dnl Where do cron jobs go?
1816 dnl
1817 AC_ARG_WITH([crond_dir],
1818   [AS_HELP_STRING([--with-crond-dir@<:@=DIR@:>@],
1819         [Install system crontabs into DIR.])],
1820   [],
1821   [with_crond_dir=yes])
1822 AS_IF([test "x${with_crond_dir}" != "xno"],
1823   [
1824         AS_IF([test "x${with_crond_dir}" = "xyes"],
1825           [
1826                 AS_IF([test -d "/etc/cron.d"],
1827                   [with_crond_dir="/etc/cron.d"],
1828                   [have_crond="no"; with_crond_dir=""])
1829           ])
1830         AC_MSG_CHECKING([for system crontab dir])
1831         crond_dir="${with_crond_dir}"
1832         AS_IF([test -n "${crond_dir}"],
1833           [
1834                 AC_MSG_RESULT(${crond_dir})
1835                 have_crond="yes"
1836           ],
1837           [
1838                 AC_MSG_RESULT(no)
1839                 have_crond="no"
1840           ])
1841   ],
1842   [
1843         have_crond="disabled"
1844   ])
1845 AC_SUBST(have_crond)
1846 AC_SUBST(crond_dir)
1847
1848 dnl
1849 dnl Where do systemd services go?
1850 dnl
1851 AC_ARG_WITH([systemd_unit_dir],
1852   [AS_HELP_STRING([--with-systemd-unit-dir@<:@=DIR@:>@],
1853         [Install systemd system units into DIR.])],
1854   [],
1855   [with_systemd_unit_dir=yes])
1856 AS_IF([test "x${with_systemd_unit_dir}" != "xno"],
1857   [
1858         AS_IF([test "x${with_systemd_unit_dir}" = "xyes"],
1859           [
1860                 PKG_CHECK_MODULES([systemd], [systemd],
1861                   [
1862                         with_systemd_unit_dir="$($PKG_CONFIG --variable=systemdsystemunitdir systemd)"
1863                   ], [
1864                         with_systemd_unit_dir=""
1865                   ])
1866                 m4_pattern_allow([^PKG_(MAJOR|MINOR|BUILD|REVISION)$])
1867           ])
1868         AC_MSG_CHECKING([for systemd system unit dir])
1869         systemd_system_unit_dir="${with_systemd_unit_dir}"
1870         AS_IF([test -n "${systemd_system_unit_dir}"],
1871           [
1872                 AC_MSG_RESULT(${systemd_system_unit_dir})
1873                 have_systemd="yes"
1874           ],
1875           [
1876                 AC_MSG_RESULT(no)
1877                 have_systemd="no"
1878           ])
1879   ],
1880   [
1881         have_systemd="disabled"
1882   ])
1883 AC_SUBST(have_systemd)
1884 AC_SUBST(systemd_system_unit_dir)
1885 dnl Adjust the compiled files if we are on windows vs everywhere else
1886 dnl
1887 OS_IO_FILE=""
1888 [case "$host_os" in
1889   mingw*)
1890     OS_IO_FILE=windows_io
1891   ;;
1892   *)
1893     OS_IO_FILE=unix_io
1894   ;;
1895 esac]
1896 AC_SUBST(OS_IO_FILE)
1897
1898 AC_SYS_LARGEFILE
1899
1900 dnl
1901 dnl Make our output files, being sure that we create the some miscellaneous
1902 dnl directories
1903 dnl
1904 test -d lib || mkdir lib
1905 test -d include || mkdir include
1906 test -d include/linux || mkdir include/linux
1907 test -d include/asm || mkdir include/asm
1908 if test -z "$UUID_CMT" ; then
1909         uuid_out_list="lib/uuid/Makefile lib/uuid/uuid.pc \
1910                 lib/uuid/uuid_types.h"
1911 fi
1912 if test -z "$BLKID_CMT" ; then
1913         blkid_out_list="lib/blkid/Makefile lib/blkid/blkid.pc \
1914                 lib/blkid/blkid_types.h"
1915 fi
1916 for i in MCONFIG Makefile \
1917         util/Makefile util/subst.conf util/gen-tarball util/install-symlink \
1918         lib/et/Makefile lib/ss/Makefile lib/e2p/Makefile \
1919         lib/ext2fs/Makefile lib/ext2fs/ext2_types.h \
1920         $uuid_out_list $blkid_out_list lib/support/Makefile \
1921         lib/ss/ss.pc lib/et/com_err.pc lib/e2p/e2p.pc lib/ext2fs/ext2fs.pc \
1922         misc/Makefile ext2ed/Makefile e2fsck/Makefile \
1923         debugfs/Makefile tests/Makefile tests/progs/Makefile \
1924         tests/fuzz/Makefile resize/Makefile doc/Makefile \
1925         po/Makefile.in scrub/Makefile; do
1926         if test -d `dirname ${srcdir}/$i` ; then
1927                 outlist="$outlist $i"
1928         fi
1929 done
1930 AC_CONFIG_FILES([$outlist])
1931 AC_OUTPUT
1932 if test -f util/gen-tarball; then chmod +x util/gen-tarball; fi