configure.ac

   1 AC_INIT
   2 AC_CONFIG_SRCDIR([version.h])
   3 AC_PREREQ(2.59)
   4 AC_CONFIG_AUX_DIR(config)
   5 AC_CONFIG_HEADERS([lib/config.h])
   6 AH_BOTTOM([#include <dirpaths.h>])
   7 AC_USE_SYSTEM_EXTENSIONS
   8 MCONFIG=./MCONFIG
   9 AC_SUBST_FILE(MCONFIG)
  10 BINARY_TYPE=bin
  11 dnl
  12 dnl This is to figure out the version number and the date....
  13 dnl
  14 E2FSPROGS_VERSION=`grep E2FSPROGS_VERSION ${srcdir}/version.h  \
  15         | awk '{print $3}' | tr \" " " | awk '{print $1}'`
  16 E2FSPROGS_DATE=`grep E2FSPROGS_DATE ${srcdir}/version.h | awk '{print $3}' \
  17         | tr \" " " | awk '{print $1}'`
  18 E2FSPROGS_DAY=$(echo $E2FSPROGS_DATE | awk -F- '{print $1}' | sed -e '/^[[1-9]]$/s/^/0/')
  19 MONTH=`echo $E2FSPROGS_DATE | awk -F- '{print $2}'`
  20 YEAR=`echo $E2FSPROGS_DATE | awk -F- '{print $3}'`
  21
  22 if expr $YEAR ">" 1900 > /dev/null ; then
  23         E2FSPROGS_YEAR=$YEAR
  24 elif expr $YEAR ">" 90 >/dev/null ; then
  25         E2FSPROGS_YEAR=19$YEAR
  26 else
  27         E2FSPROGS_YEAR=20$YEAR
  28 fi
  29
  30 case $MONTH in
  31 Jan)    MONTH_NUM=01; E2FSPROGS_MONTH="January" ;;
  32 Feb)    MONTH_NUM=02; E2FSPROGS_MONTH="February" ;;
  33 Mar)    MONTH_NUM=03; E2FSPROGS_MONTH="March" ;;
  34 Apr)    MONTH_NUM=04; E2FSPROGS_MONTH="April" ;;
  35 May)    MONTH_NUM=05; E2FSPROGS_MONTH="May" ;;
  36 Jun)    MONTH_NUM=06; E2FSPROGS_MONTH="June" ;;
  37 Jul)    MONTH_NUM=07; E2FSPROGS_MONTH="July" ;;
  38 Aug)    MONTH_NUM=08; E2FSPROGS_MONTH="August" ;;
  39 Sep)    MONTH_NUM=09; E2FSPROGS_MONTH="September" ;;
  40 Oct)    MONTH_NUM=10; E2FSPROGS_MONTH="October" ;;
  41 Nov)    MONTH_NUM=11; E2FSPROGS_MONTH="November" ;;
  42 Dec)    MONTH_NUM=12; E2FSPROGS_MONTH="December" ;;
  43 *)      AC_MSG_WARN([Unknown month $MONTH??]) ;;
  44 esac
  45
  46 base_ver=`echo $E2FSPROGS_VERSION | \
  47                sed -e 's/-WIP//' -e 's/pre-//' -e 's/-PLUS//'`
  48
  49 date_spec=${E2FSPROGS_YEAR}.${MONTH_NUM}.${E2FSPROGS_DAY}
  50
  51 case $E2FSPROGS_VERSION in
  52 *-WIP|pre-*)
  53         E2FSPROGS_PKGVER="$base_ver~WIP.$date_spec"
  54         ;;
  55 *)
  56         E2FSPROGS_PKGVER="$base_ver"
  57         ;;
  58 esac
  59
  60 unset DATE MONTH YEAR base_ver pre_vers date_spec
  61 AC_MSG_RESULT([Generating configuration file for e2fsprogs version $E2FSPROGS_VERSION])
  62 AC_MSG_RESULT([Release date is ${E2FSPROGS_MONTH}, ${E2FSPROGS_YEAR}])
  63 AC_SUBST(E2FSPROGS_YEAR)
  64 AC_SUBST(E2FSPROGS_MONTH)
  65 AC_SUBST(E2FSPROGS_DAY)
  66 AC_SUBST(E2FSPROGS_VERSION)
  67 AC_SUBST(E2FSPROGS_PKGVER)
  68 AC_SUBST(E2FSPROGS_DATE)
  69 dnl
  70 dnl Use diet libc
  71 dnl
  72 WITH_DIET_LIBC=
  73 AC_ARG_WITH([diet-libc],
  74 AS_HELP_STRING([--with-diet-libc],[use diet libc]),
  75 CC="diet cc -nostdinc"
  76 WITH_DIET_LIBC=yes
  77 if test -z "$LIBS"
  78 then
  79         LIBS="-lcompat"
  80 else
  81         LIBS="$LIBS -lcompat"
  82 fi
  83 AC_MSG_RESULT(CC=$CC))dnl
  84 dnl
  85 AC_CANONICAL_HOST
  86 dnl
  87 dnl Check to see if libdl exists for the sake of dlopen
  88 dnl
  89 DLOPEN_LIB=''
  90 AC_CHECK_LIB(dl, dlopen,DLOPEN_LIB=-ldl)
  91 AC_SUBST(DLOPEN_LIB)
  92 dnl
  93 AC_ARG_WITH([cc],
  94 AS_HELP_STRING([--with-cc],[no longer supported, use CC= instead]),
  95 AC_MSG_ERROR([--with-cc no longer supported; use CC= instead]))
  96 dnl
  97 AC_ARG_WITH([ccopts],
  98 AS_HELP_STRING([--with-ccopts],[no longer supported, use CFLAGS= instead]),
  99 AC_MSG_ERROR([--with-ccopts no longer supported; use CFLAGS= instead]))
 100 dnl
 101 AC_ARG_WITH([ldopts],
 102 AS_HELP_STRING([--with-ldopts],[no longer supported, use LDFLAGS= instead]),
 103 AC_MSG_ERROR([--with-ldopts no longer supported; use LDFLAGS= instead]))
 104 dnl
 105 AC_PROG_CC
 106 if test "$GCC" = yes; then
 107    RDYNAMIC="-rdynamic"
 108    AC_SUBST(RDYNAMIC)
 109 fi
 110 AC_PROG_CPP
 111 dnl
 112 dnl Alpha computers use fast and imprecise floating point code that may
 113 dnl miss exceptions by default. Force sane options if we're using GCC.
 114 AC_MSG_CHECKING(for additional special compiler flags)
 115 if test "$GCC" = yes
 116 then
 117     case "$host_cpu" in
 118         alpha)          addcflags="-mieee" ;;
 119     esac
 120 fi
 121 if test "x$addcflags" != x
 122 then
 123     AC_MSG_RESULT($addcflags)
 124     CFLAGS="$addcflags $CFLAGS"
 125 else
 126     AC_MSG_RESULT([[(none)]])
 127 fi
 128 dnl
 129 dnl Set default values for library extensions.  Will be dealt with after
 130 dnl parsing configuration options, which may modify these
 131 dnl
 132 LIB_EXT=.a
 133 STATIC_LIB_EXT=.a
 134 PROFILED_LIB_EXT=.a
 135 dnl
 136 dnl Allow separate `root_prefix' to be specified
 137 dnl
 138 AC_ARG_WITH([root-prefix],
 139 AS_HELP_STRING([--with-root-prefix=PREFIX],[override prefix variable for files to be placed in the root]),
 140 root_prefix=$withval,
 141 root_prefix=NONE)dnl
 142 dnl
 143 dnl handle --enable-maintainer-mode
 144 dnl
 145 AC_ARG_ENABLE([maintainer-mode],
 146 AS_HELP_STRING([--enable-maintainer-mode],[enable makefile rules useful for maintainers]),
 147 if test "$enableval" = "no"
 148 then
 149         MAINTAINER_CMT=#
 150         AC_MSG_RESULT([Disabling maintainer mode])
 151 else
 152         MAINTAINER_CMT=
 153         AC_MSG_RESULT([Enabling maintainer mode])
 154 fi
 155 ,
 156 MAINTAINER_CMT=#
 157 AC_MSG_RESULT([Disabling maintainer mode by default])
 158 )
 159 AC_SUBST(MAINTAINER_CMT)
 160 dnl
 161 dnl handle --enable-symlink-install
 162 dnl
 163 AC_ARG_ENABLE([symlink-install],
 164 AS_HELP_STRING([--enable-symlink-install],[use symlinks when installing instead of hard links]),
 165 if test "$enableval" = "no"
 166 then
 167         LINK_INSTALL_FLAGS=-f
 168         AC_MSG_RESULT([Disabling symlinks for install])
 169 else
 170         LINK_INSTALL_FLAGS=-sf
 171         AC_MSG_RESULT([Enabling symlinks for install])
 172 fi
 173 ,
 174 LINK_INSTALL_FLAGS=-f
 175 AC_MSG_RESULT([Disabling symlinks for install by default])
 176 )
 177 AC_SUBST(LINK_INSTALL_FLAGS)
 178 dnl
 179 dnl handle --enable-relative-symlinks
 180 dnl
 181 relative_symlink_defined=
 182 AC_ARG_ENABLE([relative-symlinks],
 183 AS_HELP_STRING([--enable-relative-symlinks],[use relative symlinks when installing]),
 184 if test "$enableval" = "no"
 185 then
 186         SYMLINK_RELATIVE=
 187         relative_symlink_defined=yes
 188         AC_MSG_RESULT([Disabling relative symlinks for install])
 189 else
 190         SYMLINK_RELATIVE=--relative
 191         relative_symlink_defined=yes
 192         AC_MSG_RESULT([Enabling relative symlinks for install])
 193 fi)
 194 AC_ARG_ENABLE([symlink-relative-symlinks],,
 195 if test "$enableval" = "no"
 196 then
 197         SYMLINK_RELATIVE=yes
 198         AC_MSG_RESULT([Disabling relative symlinks for install])
 199 else
 200         SYMLINK_RELATIVE=--relative
 201         AC_MSG_RESULT([Enabling relative symlinks for install])
 202 fi
 203 ,
 204 if test -z "$relative_symlink_defined"
 205 then
 206         SYMLINK_RELATIVE=
 207 AC_MSG_RESULT([Disabling relative symlinks for install by default])
 208 fi
 209 )
 210 AC_SUBST(SYMLINK_RELATIVE)
 211 dnl
 212 dnl handle --enable-symlink-build
 213 dnl
 214 AC_ARG_ENABLE([symlink-build],
 215 AS_HELP_STRING([--enable-symlink-build],[use symlinks while building instead of hard links]),
 216 if test "$enableval" = "no"
 217 then
 218         LINK_BUILD_FLAGS=
 219         AC_MSG_RESULT([Disabling symlinks for build])
 220 else
 221         LINK_BUILD_FLAGS=-s
 222         AC_MSG_RESULT([Enabling symlinks for build])
 223 fi
 224 ,
 225 LINK_BUILD_FLAGS=
 226 AC_MSG_RESULT([Disabling symlinks for build by default])
 227 )
 228 AC_SUBST(LINK_BUILD_FLAGS)
 229 dnl
 230 dnl handle --enable-verbose-makecmds
 231 dnl
 232 AC_ARG_ENABLE([verbose-makecmds],
 233 AS_HELP_STRING([--enable-verbose-makecmds],[enable verbose make command output]),
 234 if test "$enableval" = "no"
 235 then
 236         AC_MSG_RESULT([Disabling verbose make commands])
 237         E=@echo
 238         ES=echo
 239         Q=@
 240 else
 241         AC_MSG_RESULT([Enabling verbose make commands])
 242         E=@\\#
 243         ES=\\#
 244         Q=
 245 fi
 246 ,
 247 AC_MSG_RESULT([Disabling verbose make commands])
 248 E=@echo
 249 ES=echo
 250 Q=@
 251 )
 252 AC_SUBST(E)
 253 AC_SUBST(ES)
 254 AC_SUBST(Q)
 255 dnl
 256 dnl This needs to be before all of the --enable-*-shlibs options
 257 dnl
 258 E2_PKG_CONFIG_STATIC=--static
 259 LDFLAG_DYNAMIC=
 260 PRIVATE_LIBS_CMT=
 261 dnl
 262 dnl handle --enable-elf-shlibs
 263 dnl
 264 AC_ARG_ENABLE([elf-shlibs],
 265 AS_HELP_STRING([--enable-elf-shlibs],[select ELF shared libraries]),
 266 if test "$enableval" = "no"
 267 then
 268         ELF_CMT=#
 269         MAKEFILE_ELF=/dev/null
 270         AC_MSG_RESULT([Disabling ELF shared libraries])
 271 else
 272         E2_PKG_CONFIG_STATIC=
 273         ELF_CMT=
 274         MAKEFILE_ELF=$srcdir/lib/Makefile.elf-lib
 275         [case "$host_os" in
 276         solaris2.*)
 277                 MAKEFILE_ELF=$srcdir/lib/Makefile.solaris-lib
 278         ;;
 279         esac]
 280         BINARY_TYPE=elfbin
 281         LIB_EXT=.so
 282         PRIVATE_LIBS_CMT=#
 283         LDFLAG_DYNAMIC=['-Wl,-rpath-link,$(top_builddir)/lib']
 284         AC_MSG_RESULT([Enabling ELF shared libraries])
 285 fi
 286 ,
 287 MAKEFILE_ELF=/dev/null
 288 ELF_CMT=#
 289 AC_MSG_RESULT([Disabling ELF shared libraries by default])
 290 )
 291 AC_SUBST(ELF_CMT)
 292 AC_SUBST_FILE(MAKEFILE_ELF)
 293 dnl
 294 dnl handle --enable-bsd-shlibs
 295 dnl
 296 AC_ARG_ENABLE([bsd-shlibs],
 297 AS_HELP_STRING([--enable-bsd-shlibs],[select BSD shared libraries]),
 298 if test "$enableval" = "no"
 299 then
 300         BSDLIB_CMT=#
 301         MAKEFILE_BSDLIB=/dev/null
 302         AC_MSG_RESULT([Disabling BSD shared libraries])
 303 else
 304         E2_PKG_CONFIG_STATIC=
 305         BSDLIB_CMT=
 306         MAKEFILE_BSDLIB=$srcdir/lib/Makefile.bsd-lib
 307         LIB_EXT=.so
 308         [case "$host_os" in
 309         darwin*)
 310                 MAKEFILE_BSDLIB=$srcdir/lib/Makefile.darwin-lib
 311                 LIB_EXT=.dylib
 312         ;;
 313         esac]
 314         AC_MSG_RESULT([Enabling BSD shared libraries])
 315 fi
 316 ,
 317 MAKEFILE_BSDLIB=/dev/null
 318 BSDLIB_CMT=#
 319 AC_MSG_RESULT([Disabling BSD shared libraries by default])
 320 )
 321 AC_SUBST(BSDLIB_CMT)
 322 AC_SUBST_FILE(MAKEFILE_BSDLIB)
 323 dnl
 324 dnl handle --enable-profile
 325 dnl
 326 AC_ARG_ENABLE([profile],
 327 AS_HELP_STRING([--enable-profile],[build profiling libraries]),
 328 if test "$enableval" = "no"
 329 then
 330         PROFILE_CMT=#
 331         MAKEFILE_PROFILE=/dev/null
 332         AC_MSG_RESULT([Disabling profiling libraries])
 333 else
 334         PROFILE_CMT=
 335         MAKEFILE_PROFILE=$srcdir/lib/Makefile.profile
 336         PROFILED_LIB_EXT=_p.a
 337         AC_MSG_RESULT([Building profiling libraries])
 338 fi
 339 ,
 340 PROFILE_CMT=#
 341 MAKEFILE_PROFILE=/dev/null
 342 AC_MSG_RESULT([Disabling profiling libraries by default])
 343 )
 344 AC_SUBST(PROFILE_CMT)
 345 AC_SUBST_FILE(MAKEFILE_PROFILE)
 346 dnl
 347 dnl handle --enable-gcov
 348 dnl
 349 AC_ARG_ENABLE([gcov],
 350 AS_HELP_STRING([--enable-gcov],[build for coverage testing using gcov]),
 351 if test "$enableval" = "yes"
 352 then
 353         CFLAGS="-g -fprofile-arcs -ftest-coverage"
 354         LDFLAGS="-fprofile-arcs -ftest-coverage"
 355         AC_MSG_RESULT([Enabling gcov support])
 356 fi
 357 )
 358 dnl
 359 dnl handle --enable-hardening
 360 dnl
 361 CFLAGS_SHLIB="${CFLAGS_SHLIB:-$CFLAGS}"
 362 CFLAGS_STLIB="${CFLAGS_STLIB:-$CFLAGS}"
 363 LDFLAGS_SHLIB=${LDFLAGS_SHLIB:-$LDFLAGS}
 364 LDFLAGS_STATIC=${LDFLAGS_STATIC:-$LDFLAGS}
 365 AC_ARG_ENABLE([hardening],
 366 AS_HELP_STRING([--enable-hardening],[build for coverage testing using gcov]),
 367 if test "$enableval" = "yes"
 368 then
 369         HARDEN_CFLAGS="-D_FORTIFY_SOURCE=2 -fstack-protector-strong"
 370         HARDEN_LDFLAGS=["-Wl,-z,relro -Wl,-z,now"]
 371         CFLAGS="$CFLAGS $HARDEN_CFLAGS -fPIE"
 372         CFLAGS_SHLIB="$CFLAGS_SHLIB $HARDEN_CFLAGS"
 373         CFLAGS_STLIB="$CFLAGS_STLIB $HARDEN_CFLAGS -fPIE"
 374         LDFLAGS="$LDFLAGS $HARDEN_LDFLAGS -fPIE -pie"
 375         LDFLAGS_STATIC="$LDFLAGS_STATIC $HARDEN_LDFLAGS"
 376         LDFLAGS_SHLIB="$LDFLAGS_SHLIB $HARDEN_LDFLAGS"
 377         AC_MSG_RESULT([Enabling hardening support])
 378 fi
 379 )
 380 dnl
 381 dnl Substitute library extensions
 382 dnl
 383 AC_SUBST(LIB_EXT)
 384 AC_SUBST(STATIC_LIB_EXT)
 385 AC_SUBST(PROFILED_LIB_EXT)
 386 AC_SUBST(LDFLAG_DYNAMIC)
 387 AC_SUBST(PRIVATE_LIBS_CMT)
 388 dnl
 389 dnl handle --enable-jbd-debug
 390 dnl
 391 AC_ARG_ENABLE([jbd-debug],
 392 AS_HELP_STRING([--enable-jbd-debug],[enable journal debugging]),
 393 if test "$enableval" = "no"
 394 then
 395         AC_MSG_RESULT([Disabling journal debugging])
 396 else
 397         AC_DEFINE(CONFIG_JBD_DEBUG, 1,
 398                 [Define to 1 if debugging ext3/4 journal code])
 399         AC_MSG_RESULT([Enabling journal debugging])
 400 fi
 401 ,
 402 AC_MSG_RESULT([Disabling journal debugging by default])
 403 )
 404 dnl
 405 dnl handle --enable-blkid-debug
 406 dnl
 407 AC_ARG_ENABLE([blkid-debug],
 408 AS_HELP_STRING([--enable-blkid-debug],[enable blkid debugging]),
 409 if test "$enableval" = "no"
 410 then
 411         AC_MSG_RESULT([Disabling blkid debugging])
 412 else
 413         AC_DEFINE(CONFIG_BLKID_DEBUG, 1,
 414                 [Define to 1 if debugging the blkid library])
 415         AC_MSG_RESULT([Enabling blkid debugging])
 416 fi
 417 ,
 418 AC_MSG_RESULT([Disabling blkid debugging by default])
 419 )
 420 dnl
 421 dnl handle --enable-testio-debug
 422 dnl
 423 AC_ARG_ENABLE([testio-debug],
 424 AS_HELP_STRING([--disable-testio-debug],[disable the use of the test I/O manager for debugging]),
 425 AH_TEMPLATE([CONFIG_TESTIO_DEBUG],
 426         [Define to 1 if the testio I/O manager should be enabled])
 427 if test "$enableval" = "no"
 428 then
 429         AC_MSG_RESULT([Disabling testio debugging])
 430         TEST_IO_CMT="#"
 431 else
 432         TEST_IO_CMT=
 433         AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 434         AC_MSG_RESULT([Enabling testio debugging])
 435 fi
 436 ,
 437 AC_MSG_RESULT([Enabling testio debugging by default])
 438 AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 439 TEST_IO_CMT=
 440 )
 441 AC_SUBST(TEST_IO_CMT)
 442 dnl
 443 dnl handle --enable-developer-features
 444 dnl
 445 AC_ARG_ENABLE([developer-features],
 446 AS_HELP_STRING([--enable-developer-features],[enable features for use by ext4 developers]),
 447 AH_TEMPLATE([CONFIG_DEVELOPER_FEATURES],
 448         [Define to 1 for features for use by ext4 developers])
 449 if test "$enableval" = "yes"
 450 then
 451         DEV_FEATURES_CMT=
 452         AC_DEFINE(CONFIG_DEVELOPER_FEATURES, 1)
 453         AC_MSG_RESULT([Enabling ext4 developer features])
 454 else
 455         AC_MSG_RESULT([Disabling ext4 developer features])
 456         DEV_FEATURES_CMT="#"
 457 fi
 458 ,
 459 AC_MSG_RESULT([Disabling ext4 developer features by default])
 460 DEV_FEATURES_CMT=
 461 )
 462 AC_SUBST(DEV_FEATURES_CMT)
 463 dnl
 464 dnl handle --disable-libuuid
 465 dnl
 466 PKG_PROG_PKG_CONFIG
 467 LIBUUID=
 468 DEPLIBUUID=
 469 STATIC_LIBUUID=
 470 DEPSTATIC_LIBUUID=
 471 PROFILED_LIBUUID=
 472 DEPPROFILED_LIBUUID=
 473 UUID_CMT=
 474 AC_ARG_ENABLE([libuuid],
 475 AS_HELP_STRING([--enable-libuuid],[build and use private uuid library]),
 476 if test "$enableval" = "no"
 477 then
 478         if test -z "$PKG_CONFIG"; then
 479                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 480         fi
 481
 482         AC_CHECK_LIB(uuid, uuid_generate,
 483                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 484                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`],
 485                 [AC_MSG_ERROR([external uuid library not found])])
 486         PROFILED_LIBUUID=$LIBUUID
 487         UUID_CMT=#
 488         AC_MSG_RESULT([Disabling private uuid library])
 489 else
 490         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 491         DEPLIBUUID=$LIBUUID
 492         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 493         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 494         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 495         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 496         AC_MSG_RESULT([Enabling private uuid library])
 497 fi
 498 ,
 499 if test -n "$PKG_CONFIG"; then
 500         AC_CHECK_LIB(uuid, uuid_generate,
 501                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 502                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`])
 503 fi
 504 if test -n "$LIBUUID"; then
 505         PROFILED_LIBUUID=$LIBUUID
 506         UUID_CMT=#
 507         AC_MSG_RESULT([Using system uuid by default])
 508 else
 509         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 510         DEPLIBUUID=$LIBUUID
 511         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 512         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 513         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 514         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 515         AC_MSG_RESULT([Enabling private uuid library by default])
 516 fi
 517 )
 518 AC_SUBST(LIBUUID)
 519 AC_SUBST(DEPLIBUUID)
 520 AC_SUBST(STATIC_LIBUUID)
 521 AC_SUBST(DEPSTATIC_LIBUUID)
 522 AC_SUBST(PROFILED_LIBUUID)
 523 AC_SUBST(DEPPROFILED_LIBUUID)
 524 AC_SUBST(UUID_CMT)
 525 dnl
 526 dnl handle --disable-libblkid
 527 dnl
 528 PKG_PROG_PKG_CONFIG
 529 LIBBLKID=
 530 DEPLIBBLKID=
 531 STATIC_LIBBLKID=
 532 DEPSTATIC_LIBBLKID=
 533 PROFILED_LIBBLKID=
 534 DEPPROFILED_LIBBLKID=
 535 BLKID_CMT=
 536 AH_TEMPLATE([CONFIG_BUILD_FINDFS], [Define to 1 to compile findfs])
 537 AC_ARG_ENABLE([libblkid],
 538 AS_HELP_STRING([--enable-libblkid],[build and use private blkid library]),
 539 if test "$enableval" = "no"
 540 then
 541         if test -z "$PKG_CONFIG"; then
 542                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 543         fi
 544
 545         AC_CHECK_LIB(blkid, blkid_get_cache,
 546                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 547                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`],
 548                 [AC_MSG_ERROR([external blkid library not found])], -luuid)
 549         BLKID_CMT=#
 550         PROFILED_LIBBLKID=$LIBBLKID
 551         AC_MSG_RESULT([Disabling private blkid library])
 552 else
 553         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 554         DEPLIBBLKID=$LIBBLKID
 555         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 556         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 557         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 558         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 559         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 560         AC_MSG_RESULT([Enabling private blkid library])
 561 fi
 562 ,
 563 if test -n "$PKG_CONFIG"; then
 564         AC_CHECK_LIB(blkid, blkid_get_cache,
 565                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 566                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`])
 567 fi
 568 if test -n "$LIBBLKID"; then
 569         BLKID_CMT=#
 570         PROFILED_LIBBLKID=$LIBBLKID
 571         AC_MSG_RESULT([Using system blkid library by default])
 572 else
 573         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 574         DEPLIBBLKID=$LIBBLKID
 575         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 576         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 577         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 578         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 579         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 580         AC_MSG_RESULT([Enabling private blkid library by default])
 581 fi
 582 )
 583 AC_SUBST(LIBBLKID)
 584 AC_SUBST(DEPLIBBLKID)
 585 AC_SUBST(STATIC_LIBBLKID)
 586 AC_SUBST(DEPSTATIC_LIBBLKID)
 587 AC_SUBST(PROFILED_LIBBLKID)
 588 AC_SUBST(DEPPROFILED_LIBBLKID)
 589 AC_SUBST(BLKID_CMT)
 590 dnl
 591 dnl handle --enable-subset
 592 dnl
 593 ALL_CMT=
 594 SUBSET_CMT=
 595 AC_ARG_ENABLE([subset],
 596 AS_HELP_STRING([--enable-subset],[enable subset-only build]),
 597 if test "$enableval" = "no"
 598 then
 599         SUBSET_CMT=#
 600         AC_MSG_RESULT([Disabling subset-only build])
 601 else
 602         ALL_CMT=#
 603         AC_MSG_RESULT([Enabling subset-only-build])
 604 fi
 605 ,)
 606 AC_SUBST(ALL_CMT)
 607 AC_SUBST(SUBSET_CMT)
 608 dnl
 609 dnl handle --disable-backtrace
 610 dnl
 611 AH_TEMPLATE([DISABLE_BACKTRACE], [Define to 1 to disable use of backtrace])
 612 AC_ARG_ENABLE([backtrace],
 613 AS_HELP_STRING([--disable-backtrace],[disable use backtrace]),
 614 if test "$enableval" = "no"
 615 then
 616         AC_MSG_RESULT([Disabling use of backtrace])
 617         AC_DEFINE(DISABLE_BACKTRACE, 1)
 618 else
 619         AC_MSG_RESULT([Enabling use of backtrace])
 620 fi
 621 ,
 622 AC_MSG_RESULT([Enabling use of backtrace by default])
 623 )
 624 dnl
 625 dnl handle --enable-debugfs
 626 dnl
 627 AC_ARG_ENABLE([debugfs],
 628 AS_HELP_STRING([--disable-debugfs],[disable support of debugfs program]),
 629 if test "$enableval" = "no"
 630 then
 631         AC_MSG_RESULT([Disabling debugfs support])
 632         DEBUGFS_CMT="#"
 633 else
 634         DEBUGFS_CMT=
 635         AC_MSG_RESULT([Enabling debugfs support])
 636 fi
 637 ,
 638 AC_MSG_RESULT([Enabling debugfs support by default])
 639 DEBUGFS_CMT=
 640 )
 641 AC_SUBST(DEBUGFS_CMT)
 642 dnl
 643 dnl handle --enable-imager
 644 dnl
 645 AC_ARG_ENABLE([imager],
 646 AS_HELP_STRING([--disable-imager],[disable support of e2image program]),
 647 if test "$enableval" = "no"
 648 then
 649         AC_MSG_RESULT([Disabling e2image support])
 650         IMAGER_CMT="#"
 651 else
 652         IMAGER_CMT=
 653         AC_MSG_RESULT([Enabling e2image support])
 654 fi
 655 ,
 656 AC_MSG_RESULT([Enabling e2image support by default])
 657 IMAGER_CMT=
 658 )
 659 AC_SUBST(IMAGER_CMT)
 660 dnl
 661 dnl handle --enable-resizer
 662 dnl
 663 AC_ARG_ENABLE([resizer],
 664 AS_HELP_STRING([--disable-resizer],[disable support of e2resize program]),
 665 if test "$enableval" = "no"
 666 then
 667         AC_MSG_RESULT([Disabling e2resize support])
 668         RESIZER_CMT="#"
 669 else
 670         RESIZER_CMT=
 671         AC_MSG_RESULT([Enabling e2resize support])
 672 fi
 673 ,
 674 AC_MSG_RESULT([Enabling e2resize support by default])
 675 RESIZER_CMT=
 676 )
 677 AC_SUBST(RESIZER_CMT)
 678 dnl
 679 dnl handle --enable-defrag
 680 dnl
 681 AC_ARG_ENABLE([defrag],
 682 AS_HELP_STRING([--disable-defrag],[disable support of e4defrag program]),
 683 if test "$enableval" = "no"
 684 then
 685         AC_MSG_RESULT([Disabling e4defrag support])
 686         DEFRAG_CMT="#"
 687 else
 688         DEFRAG_CMT=
 689         AC_MSG_RESULT([Enabling e4defrag support])
 690 fi
 691 ,
 692 if test -z "$WITH_DIET_LIBC"
 693 then
 694         AC_MSG_RESULT([Enabling e4defrag support by default])
 695         DEFRAG_CMT=
 696 else
 697         AC_MSG_RESULT([Disabling e4defrag support by default])
 698         DEFRAG_CMT="#"
 699 fi
 700 )
 701 AC_SUBST(DEFRAG_CMT)
 702 dnl
 703 dnl See whether to install the `fsck' wrapper program (that calls e2fsck)
 704 dnl
 705 AC_ARG_ENABLE([fsck],
 706 AS_HELP_STRING([--enable-fsck],[build fsck wrapper program]),
 707 [if test "$enableval" = "no"
 708 then
 709         FSCK_PROG='' FSCK_MAN=''
 710         AC_MSG_RESULT([Not building fsck wrapper])
 711 else
 712         FSCK_PROG=fsck FSCK_MAN=fsck.8
 713         AC_MSG_RESULT([Building fsck wrapper])
 714 fi]
 715 ,
 716 [case "$host_os" in
 717   gnu*)
 718     FSCK_PROG='' FSCK_MAN=''
 719     AC_MSG_RESULT([Not building fsck wrapper by default])
 720     ;;
 721   *)
 722     FSCK_PROG=fsck FSCK_MAN=fsck.8
 723     AC_MSG_RESULT([Building fsck wrapper by default])
 724 esac]
 725 )
 726 AC_SUBST(FSCK_PROG)
 727 AC_SUBST(FSCK_MAN)
 728 dnl
 729 dnl See whether to install the `e2initrd-helper' program
 730 dnl
 731 AC_ARG_ENABLE([e2initrd-helper],
 732 AS_HELP_STRING([--enable-e2initrd-helper],[build e2initrd-helper program]),
 733 [if test "$enableval" = "no"
 734 then
 735         E2INITRD_PROG='' E2INITRD_MAN=''
 736         AC_MSG_RESULT([Not building e2initrd helper])
 737 else
 738         E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 739         AC_MSG_RESULT([Building e2initrd helper])
 740 fi]
 741 ,
 742 E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 743 AC_MSG_RESULT([Building e2initrd helper by default])
 744 )
 745 AC_SUBST(E2INITRD_PROG)
 746 AC_SUBST(E2INITRD_MAN)
 747 dnl
 748 dnl
 749 dnl
 750 AC_ARG_ENABLE([tls],
 751 AS_HELP_STRING([--disable-tls],[disable use of thread local support]),
 752 [if test "$enableval" = "no"
 753 then
 754         try_tls=""
 755         AC_MSG_RESULT([Disabling thread local support])
 756 else
 757         try_tls="yes"
 758         AC_MSG_RESULT([Enabling thread local support])
 759 fi]
 760 ,
 761 if test -n "$WITH_DIET_LIBC"
 762 then
 763         try_tls=""
 764         AC_MSG_RESULT([Diet libc does not support thread local support])
 765 else
 766         try_tls="yes"
 767         AC_MSG_RESULT([Try using thread local support by default])
 768 fi
 769 )
 770 if test "$try_tls" = "yes"
 771 then
 772 AX_TLS
 773 fi
 774 dnl
 775 dnl
 776 dnl
 777 AC_ARG_WITH([pthread],
 778 AS_HELP_STRING([--without-pthread],[disable use of pthread support]),
 779 [if test "$withval" = "no"
 780 then
 781         try_pthread=""
 782         AC_MSG_RESULT([Disabling pthread support])
 783 else
 784         try_pthread="yes"
 785         AC_MSG_RESULT([Testing for pthread support])
 786 fi]
 787 ,
 788 try_pthread="yes"
 789 AC_MSG_RESULT([Try testing for pthread support by default])
 790 )
 791 if test "$try_pthread" = "yes"
 792 then
 793 AX_PTHREAD
 794 else
 795 test -n "$PTHREAD_CC" || PTHREAD_CC="$CC"
 796 AC_SUBST([PTHREAD_CC])
 797 fi
 798 dnl
 799 dnl
 800 dnl
 801 AH_TEMPLATE([USE_UUIDD], [Define to 1 to build uuidd])
 802 AC_ARG_ENABLE([uuidd],
 803 AS_HELP_STRING([--disable-uuidd],[disable building the uuid daemon]),
 804 [if test "$enableval" = "no"
 805 then
 806         AC_MSG_RESULT([Not building uuidd])
 807         UUIDD_CMT="#"
 808 else
 809         AC_DEFINE(USE_UUIDD, 1)
 810         UUIDD_CMT=""
 811         AC_MSG_RESULT([Building uuidd])
 812 fi]
 813 ,
 814 AC_DEFINE(USE_UUIDD, 1)
 815 if test -z "$UUID_CMT"
 816 then
 817         UUIDD_CMT=""
 818         AC_MSG_RESULT([Building uuidd by default])
 819 else
 820         UUIDD_CMT="#"
 821         AC_MSG_RESULT([Disabling uuidd by default])
 822 fi
 823 )
 824 AC_SUBST(UUIDD_CMT)
 825 dnl
 826 dnl handle --disable-mmp
 827 dnl
 828 AH_TEMPLATE([CONFIG_MMP], [Define to 1 to enable mmp support])
 829 AC_ARG_ENABLE([mmp],
 830 AS_HELP_STRING([--disable-mmp],[disable support mmp, Multi Mount Protection]),
 831 if test "$enableval" = "no"
 832 then
 833         AC_MSG_RESULT([Disabling mmp support])
 834 else
 835         AC_MSG_RESULT([Enabling mmp support])
 836         AC_DEFINE(CONFIG_MMP, 1)
 837 fi
 838 ,
 839 AC_MSG_RESULT([Enabling mmp support by default])
 840 AC_DEFINE(CONFIG_MMP, 1)
 841 )
 842 dnl
 843 dnl handle --disable-tdb
 844 dnl
 845 AH_TEMPLATE([CONFIG_TDB], [Define to 1 to enable tdb support])
 846 AC_ARG_ENABLE([tdb],
 847 AS_HELP_STRING([--disable-tdb],[disable tdb support]),
 848 if test "$enableval" = "no"
 849 then
 850         AC_MSG_RESULT([Disabling tdb support])
 851         TDB_CMT="#"
 852         TDB_MAN_COMMENT='.\"'
 853 else
 854         AC_MSG_RESULT([Enabling tdb support])
 855         AC_DEFINE(CONFIG_TDB, 1)
 856         TDB_CMT=""
 857         TDB_MAN_COMMENT=""
 858 fi
 859 ,
 860 AC_MSG_RESULT([Enabling mmp support by default])
 861 AC_DEFINE(CONFIG_TDB, 1)
 862 TDB_CMT=""
 863 TDB_MAN_COMMENT=""
 864 )
 865 AC_SUBST(TDB_CMT)
 866 AC_SUBST(TDB_MAN_COMMENT)
 867 dnl
 868 dnl handle --disable-bmap-stats
 869 dnl
 870 AH_TEMPLATE([ENABLE_BMAP_STATS], [Define to 1 to enable bitmap stats.])
 871 AC_ARG_ENABLE([bmap-stats],
 872 AS_HELP_STRING([--disable-bmap-stats],[disable collection of bitmap stats]),
 873 if test "$enableval" = "no"
 874 then
 875         AC_MSG_RESULT([Disabling bitmap statistics support])
 876 else
 877         AC_MSG_RESULT([Enabling bitmap statistics support])
 878         AC_DEFINE(ENABLE_BMAP_STATS, 1)
 879 fi
 880 ,
 881 AC_MSG_RESULT([Enabling bitmap statistics support by default])
 882 AC_DEFINE(ENABLE_BMAP_STATS, 1)
 883 )
 884 dnl
 885 dnl handle --enable-bmap-stats-ops
 886 dnl
 887 AH_TEMPLATE([ENABLE_BMAP_STATS_OPS], [Define to 1 to enable bitmap stats.])
 888 AC_ARG_ENABLE([bmap-stats-ops],
 889 AS_HELP_STRING([--enable-bmap-stats-ops],[enable collection of additional bitmap stats]),
 890 if test "$enableval" = "no"
 891 then
 892         AC_MSG_RESULT([Disabling additional bitmap statistics])
 893 else
 894         dnl There has to be a better way!
 895         AS_IF([test "x${enable_bmap_stats}" = "xno"],
 896          AC_MSG_FAILURE([Error --enable-bmap-stats-ops requires bmap-stats]))
 897
 898         AC_MSG_RESULT([Enabling additional bitmap statistics])
 899         AC_DEFINE(ENABLE_BMAP_STATS_OPS, 1)
 900 fi
 901 ,
 902 AC_MSG_RESULT([Disabling additional bitmap statistics by default])
 903 )
 904 dnl
 905 dnl
 906 dnl
 907 MAKEFILE_LIBRARY=$srcdir/lib/Makefile.library
 908 AC_SUBST_FILE(MAKEFILE_LIBRARY)
 909 dnl
 910 dnl Add internationalization support, using gettext.
 911 dnl
 912 GETTEXT_PACKAGE=e2fsprogs
 913 PACKAGE=e2fsprogs
 914 VERSION="$E2FSPROGS_VERSION"
 915 VERSION=0.14.1
 916 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [package name for gettext])
 917 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [version for gettext])
 918 AC_SUBST(GETTEXT_PACKAGE)
 919 AC_SUBST(PACKAGE)
 920 AC_SUBST(VERSION)
 921
 922 AM_GNU_GETTEXT([external])
 923 dnl
 924 dnl End of configuration options
 925 dnl
 926 AC_SUBST(BINARY_TYPE)
 927 AC_PROG_MAKE_SET
 928 CHECK_GNU_MAKE
 929 AC_PATH_PROG(LN, ln, ln)
 930 AC_PROG_MKDIR_P
 931 dnl
 932 dnl @mkdir_p@ is used by po's Makefile.in
 933 dnl
 934 mkdir_p=$MKDIR_P
 935 AC_SUBST(mkdir_p)
 936 AC_PROG_LN_S
 937 AC_PATH_PROG(MV, mv, mv)
 938 AC_PATH_PROG(CP, cp, cp)
 939 AC_PATH_PROG(RM, rm, rm)
 940 AC_PATH_PROG(CHMOD, chmod, :)
 941 AC_PROG_AWK
 942 AC_PROG_EGREP
 943 AC_PATH_PROG(SED, sed, sed)
 944 AC_PATH_PROG(PERL, perl, perl)
 945 AC_PATH_PROG(LDCONFIG, ldconfig, :)
 946 AC_CHECK_TOOL(AR, ar, ar)
 947 AC_CHECK_TOOL(RANLIB, ranlib, :)
 948 AC_CHECK_TOOL(STRIP, strip, :)
 949 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
 950 if test "_$MAKEINFO" = "_"; then
 951     MAKEINFO="echo Makeinfo is missing. Info documentation will not be built."
 952 else
 953     case "$MAKEINFO" in
 954       */missing.*)
 955         AC_MSG_WARN([
 956 *** Makeinfo is missing. Info documentation will not be built.])
 957         ;;
 958       *)
 959         ;;
 960     esac
 961 fi
 962 AC_SUBST(MAKEINFO)
 963 AC_PROG_INSTALL
 964 # See if we need a separate native compiler.
 965 if test $cross_compiling = no; then
 966   BUILD_CC="$CC"
 967   AC_SUBST(BUILD_CC)
 968 else
 969   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 970 fi
 971 AC_CHECK_HEADERS(m4_flatten([
 972         attr/xattr.h
 973         dirent.h
 974         errno.h
 975         execinfo.h
 976         getopt.h
 977         malloc.h
 978         mntent.h
 979         paths.h
 980         pthread.h
 981         semaphore.h
 982         setjmp.h
 983         signal.h
 984         stdarg.h
 985         stdint.h
 986         stdlib.h
 987         termios.h
 988         termio.h
 989         unistd.h
 990         utime.h
 991         attr/xattr.h
 992         linux/falloc.h
 993         linux/fd.h
 994         linux/fsmap.h
 995         linux/major.h
 996         linux/loop.h
 997         linux/types.h
 998         net/if_dl.h
 999         netinet/in.h
1000         sys/acl.h
1001         sys/disklabel.h
1002         sys/disk.h
1003         sys/file.h
1004         sys/ioctl.h
1005         sys/key.h
1006         sys/mkdev.h
1007         sys/mman.h
1008         sys/mount.h
1009         sys/prctl.h
1010         sys/random.h
1011         sys/resource.h
1012         sys/select.h
1013         sys/socket.h
1014         sys/sockio.h
1015         sys/stat.h
1016         sys/syscall.h
1017         sys/sysmacros.h
1018         sys/time.h
1019         sys/types.h
1020         sys/un.h
1021         sys/wait.h
1022         sys/xattr.h
1023 ]))
1024 dnl Check where to find a dd(1) that supports iflag=fullblock
1025 dnl and oflag=append
1026 AC_MSG_CHECKING([for a dd(1) program that supports iflag=fullblock])
1027 DD=
1028 for i in dd gdd ; do
1029         if "$i" if=/dev/null of=/dev/null count=1 bs=10k 2>/dev/null iflag=fullblock oflag=append ; then
1030                 DD=$i
1031                 break
1032         fi
1033 done
1034 if test -n "$DD" ; then
1035         AC_MSG_RESULT([$DD])
1036 else
1037         AC_MSG_RESULT([not found, using dd])
1038         DD=dd
1039         AC_MSG_WARN([No GNU-compatible dd(1) program found, expect some self-test failures.])
1040 fi
1041 AC_SUBST([DD])
1042
1043 AC_CHECK_HEADERS(net/if.h,,,
1044 [[
1045 #if HAVE_SYS_TYPES_H
1046 #include <sys/types.h>
1047 #endif
1048 #if HAVE_SYS_SOCKET
1049 #include <sys/socket.h>
1050 #endif
1051 ]])
1052 AC_FUNC_VPRINTF
1053 dnl Check to see if dirent has member d_reclen. On cygwin those d_reclen
1054 dnl is not declared.
1055 AC_CHECK_MEMBER(struct dirent.d_reclen,[AC_DEFINE(HAVE_RECLEN_DIRENT, 1,
1056                        [Define to 1 if dirent has d_reclen])],,
1057                 [#include <dirent.h>])
1058 AC_CHECK_MEMBERS([struct stat.st_atim])
1059 dnl Check to see if ssize_t was declared
1060 AC_CHECK_TYPE(ssize_t,[AC_DEFINE(HAVE_TYPE_SSIZE_T, 1,
1061                 [Define to 1 if ssize_t declared])],,
1062               [#include <sys/types.h>])
1063 dnl
1064 dnl Check to see if llseek() is declared in unistd.h.  On some libc's
1065 dnl it is, and on others it isn't..... Thank you glibc developers....
1066 dnl
1067 AC_CHECK_DECL(llseek,[AC_DEFINE(HAVE_LLSEEK_PROTOTYPE, 1,
1068                         [Define to 1 if llseek declared in unistd.h])],,
1069               [#include <unistd.h>])
1070 dnl
1071 dnl Check to see if lseek64() is declared in unistd.h.  Glibc's header files
1072 dnl are so convoluted that I can't tell whether it will always be defined,
1073 dnl and if it isn't defined while lseek64 is defined in the library,
1074 dnl disaster will strike.
1075 dnl
1076 dnl Warning!  Use of --enable-gcc-wall may throw off this test.
1077 dnl
1078 dnl
1079 AC_CHECK_DECL(lseek64,[AC_DEFINE(HAVE_LSEEK64_PROTOTYPE, 1,
1080                         [Define to 1 if lseek64 declared in unistd.h])],,
1081                 [#define _LARGEFILE_SOURCE
1082                  #define _LARGEFILE64_SOURCE
1083                  #include <unistd.h>])
1084 dnl
1085 dnl Word sizes...
1086 dnl
1087 AC_CHECK_SIZEOF(short)
1088 AC_CHECK_SIZEOF(int)
1089 AC_CHECK_SIZEOF(long)
1090 AC_CHECK_SIZEOF(long long)
1091 AC_CHECK_SIZEOF(off_t)
1092 AC_CHECK_SIZEOF(time_t)
1093 SIZEOF_SHORT=$ac_cv_sizeof_short
1094 SIZEOF_INT=$ac_cv_sizeof_int
1095 SIZEOF_LONG=$ac_cv_sizeof_long
1096 SIZEOF_LONG_LONG=$ac_cv_sizeof_long_long
1097 SIZEOF_OFF_T=$ac_cv_sizeof_off_t
1098 SIZEOF_TIME_T=$ac_cv_sizeof_time_t
1099 AC_SUBST(SIZEOF_SHORT)
1100 AC_SUBST(SIZEOF_INT)
1101 AC_SUBST(SIZEOF_LONG)
1102 AC_SUBST(SIZEOF_LONG_LONG)
1103 AC_SUBST(SIZEOF_OFF_T)
1104 AC_SUBST(SIZEOF_TIME_T)
1105 AC_C_BIGENDIAN
1106 if test $cross_compiling = no; then
1107   BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
1108 else
1109   CROSS_COMPILE="1" BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
1110 fi
1111 ASM_TYPES_HEADER=./asm_types.h
1112 AC_SUBST_FILE(ASM_TYPES_HEADER)
1113 dnl
1114 dnl Save the configuration #defines needed for the public ext2fs.h
1115 dnl header file
1116 dnl
1117 echo "/* These defines are needed for the public ext2fs.h header file */" \
1118      > public_config.h
1119 if grep HAVE_SYS_TYPES_H confdefs.h > tmp_config.$$; then
1120   uniq tmp_config.$$ >> public_config.h
1121 else
1122   echo "#undef HAVE_SYS_TYPES_H" >> public_config.h
1123 fi
1124 if grep WORDS_BIGENDIAN confdefs.h > tmp_config.$$; then
1125   uniq tmp_config.$$ >> public_config.h
1126 else
1127   echo "#undef WORDS_BIGENDIAN" >> public_config.h
1128 fi
1129 rm -f tmp_config.$$
1130 PUBLIC_CONFIG_HEADER=./public_config.h
1131 AC_SUBST_FILE(PUBLIC_CONFIG_HEADER)
1132 dnl
1133 dnl See if we have inttypes.h and if intptr_t is defined
1134 dnl
1135 AC_CHECK_HEADERS([inttypes.h])
1136 AC_CHECK_TYPES(intptr_t)
1137 dnl
1138 dnl See if struct stat has a st_flags field, in which case we can get file
1139 dnl flags somewhat portably.  Also check for the analogous setter, chflags().
1140 dnl
1141 AC_MSG_CHECKING(whether struct stat has a st_flags field)
1142 AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags,
1143         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/stat.h>]], [[struct stat stat; stat.st_flags = 0;]])],[e2fsprogs_cv_struct_st_flags=yes],[e2fsprogs_cv_struct_st_flags=no]))
1144 AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags)
1145 if test "$e2fsprogs_cv_struct_st_flags" = yes; then
1146   AC_MSG_CHECKING(whether st_flags field is useful)
1147   AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags_immut,
1148         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/stat.h>]], [[struct stat stat; stat.st_flags |= UF_IMMUTABLE;]])],[e2fsprogs_cv_struct_st_flags_immut=yes],[e2fsprogs_cv_struct_st_flags_immut=no]))
1149   AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags_immut)
1150   if test "$e2fsprogs_cv_struct_st_flags_immut" = yes; then
1151           AC_DEFINE(HAVE_STAT_FLAGS, 1,
1152                 [Define to 1 if struct stat has st_flags])
1153   fi
1154 fi
1155 dnl
1156 dnl Check for the presence of SA_LEN
1157 dnl
1158 AC_CHECK_MEMBER(struct sockaddr.sa_len,
1159                 AC_DEFINE_UNQUOTED(HAVE_SA_LEN,1,
1160                         [Define to 1 if if struct sockaddr contains sa_len]),,
1161         [#include <sys/types.h>
1162          #include <sys/socket.h>])
1163 dnl
1164 dnl If we are using the system-provided blkid library, check for
1165 dnl the functions added after migrating that library to util-linux
1166 dnl
1167 if test -n "$BLKID_CMT"; then
1168   AC_CHECK_LIB(blkid, blkid_probe_get_topology,
1169                       AC_DEFINE(HAVE_BLKID_PROBE_GET_TOPOLOGY, 1,
1170                                 [Define to 1 if blkid has blkid_probe_get_topology]))
1171   AC_CHECK_LIB(blkid, blkid_topology_get_dax,
1172                       AC_DEFINE(HAVE_BLKID_TOPOLOGY_GET_DAX, 1,
1173                                 [Define to 1 if blkid has blkid_topology_get_dax]))
1174   AC_CHECK_LIB(blkid, blkid_probe_enable_partitions,
1175                       AC_DEFINE(HAVE_BLKID_PROBE_ENABLE_PARTITIONS, 1,
1176                                 [Define to 1 if blkid has blkid_probe_enable_partitions]))
1177 fi
1178 dnl
1179 if test -n "$DLOPEN_LIB" ; then
1180    ac_cv_func_dlopen=yes
1181 fi
1182 AC_CHECK_FUNCS(m4_flatten([
1183         __secure_getenv
1184         add_key
1185         backtrace
1186         chflags
1187         dlopen
1188         fadvise64
1189         fallocate
1190         fallocate64
1191         fchown
1192         fcntl
1193         fdatasync
1194         fstat64
1195         fsync
1196         ftruncate64
1197         futimes
1198         getcwd
1199         getdtablesize
1200         getentropy
1201         gethostname
1202         getmntinfo
1203         getpwuid_r
1204         getrandom
1205         getrlimit
1206         getrusage
1207         jrand48
1208         keyctl
1209         llistxattr
1210         llseek
1211         lseek64
1212         mallinfo
1213         mallinfo2
1214         mbstowcs
1215         memalign
1216         mempcpy
1217         mmap
1218         msync
1219         nanosleep
1220         open64
1221         pathconf
1222         posix_fadvise
1223         posix_fadvise64
1224         posix_memalign
1225         prctl
1226         pread
1227         pwrite
1228         pread64
1229         pwrite64
1230         secure_getenv
1231         setmntent
1232         setresgid
1233         setresuid
1234         snprintf
1235         srandom
1236         stpcpy
1237         strcasecmp
1238         strdup
1239         strnlen
1240         strptime
1241         strtoull
1242         sync_file_range
1243         sysconf
1244         usleep
1245         utime
1246         utimes
1247         valloc
1248 ]))
1249 dnl
1250 dnl Check to see if -lsocket is required (solaris) to make something
1251 dnl that uses socket() to compile; this is needed for the UUID library
1252 dnl
1253 SOCKET_LIB=''
1254 AC_CHECK_LIB(socket, socket, [SOCKET_LIB=-lsocket])
1255 AC_SUBST(SOCKET_LIB)
1256 dnl
1257 dnl See if libmagic exists
1258 dnl
1259 AC_CHECK_LIB(magic, magic_file, [MAGIC_LIB=-lmagic
1260 AC_CHECK_HEADERS([magic.h])])
1261 if test "$ac_cv_func_dlopen" = yes ; then
1262    MAGIC_LIB=$DLOPEN_LIB
1263 fi
1264 AC_SUBST(MAGIC_LIB)
1265 dnl
1266 dnl Check to see if librt is required for clock_gettime() (glibc < 2.17)
1267 dnl
1268 AC_CHECK_LIB(rt, clock_gettime, [CLOCK_GETTIME_LIB=-lrt])
1269 AC_SUBST(CLOCK_GETTIME_LIB)
1270 dnl
1271 dnl Check to see if the FUSE library is -lfuse or -losxfuse
1272 dnl
1273 FUSE_CMT=
1274 FUSE_LIB=
1275 dnl osxfuse.dylib supersedes fuselib.dylib
1276 AC_ARG_ENABLE([fuse2fs],
1277 AS_HELP_STRING([--disable-fuse2fs],[do not build fuse2fs]),
1278 if test "$enableval" = "no"
1279 then
1280         FUSE_CMT="#"
1281         AC_MSG_RESULT([Disabling fuse2fs])
1282 else
1283         AC_CHECK_HEADERS([pthread.h fuse.h], [],
1284 [AC_MSG_FAILURE([Cannot find fuse2fs headers.])],
1285 [#define _FILE_OFFSET_BITS      64
1286 #define FUSE_USE_VERSION 29])
1287
1288         AC_PREPROC_IFELSE(
1289 [AC_LANG_PROGRAM([[#define FUSE_USE_VERSION 29
1290 #ifdef __linux__
1291 #include <linux/fs.h>
1292 #include <linux/falloc.h>
1293 #include <linux/xattr.h>
1294 #endif
1295 ]], [])], [], [AC_MSG_FAILURE([Cannot find fuse2fs Linux headers.])])
1296
1297         AC_CHECK_LIB(osxfuse, fuse_main, [FUSE_LIB=-losxfuse],
1298                 [AC_CHECK_LIB(fuse, fuse_main, [FUSE_LIB=-lfuse],
1299                               [AC_MSG_FAILURE([Cannot find fuse library.])])])
1300         AC_MSG_RESULT([Enabling fuse2fs])
1301 fi
1302 ,
1303 AC_CHECK_HEADERS([pthread.h fuse.h], [], [FUSE_CMT="#"],
1304 [#define _FILE_OFFSET_BITS      64
1305 #define FUSE_USE_VERSION 29
1306 #ifdef __linux__
1307 # include <linux/fs.h>
1308 # include <linux/falloc.h>
1309 # include <linux/xattr.h>
1310 #endif])
1311 if test -z "$FUSE_CMT"
1312 then
1313         AC_CHECK_LIB(osxfuse, fuse_main, [FUSE_LIB=-losxfuse],
1314 [AC_CHECK_LIB(fuse, fuse_main, [FUSE_LIB=-lfuse], [FUSE_CMT="#"])])
1315 fi
1316 if test -z "$FUSE_CMT"
1317 then
1318         AC_MSG_RESULT([Enabling fuse2fs by default.])
1319 fi
1320 )
1321 AC_SUBST(FUSE_LIB)
1322 AC_SUBST(FUSE_CMT)
1323 dnl
1324 dnl See if optreset exists
1325 dnl
1326 AC_MSG_CHECKING(for optreset)
1327 AC_CACHE_VAL(ac_cv_have_optreset,
1328 [AC_EGREP_HEADER(optreset, unistd.h,
1329   ac_cv_have_optreset=yes, ac_cv_have_optreset=no)])dnl
1330 AC_MSG_RESULT($ac_cv_have_optreset)
1331 if test $ac_cv_have_optreset = yes; then
1332   AC_DEFINE(HAVE_OPTRESET, 1, [Define to 1 if optreset for getopt is present])
1333 fi
1334 dnl
1335 dnl Test for sem_init, and which library it might require:
1336 dnl
1337 AH_TEMPLATE([HAVE_SEM_INIT], [Define to 1 if sem_init() exists])
1338 SEM_INIT_LIB=''
1339 echo GL_THREADS_API: ${gl_threads_api}
1340 if test "${gl_threads_api}" != none
1341 then
1342   AC_CHECK_FUNC(sem_init, ,
1343     AC_CHECK_LIB(pthread, sem_init,
1344         AC_DEFINE(HAVE_SEM_INIT, 1)
1345         SEM_INIT_LIB=-lpthread,
1346     AC_CHECK_LIB(rt, sem_init,
1347         AC_DEFINE(HAVE_SEM_INIT, 1)
1348         SEM_INIT_LIB=-lrt,
1349     AC_CHECK_LIB(posix4, sem_init,
1350         AC_DEFINE(HAVE_SEM_INIT, 1)
1351         SEM_INIT_LIB=-lposix4))))dnl
1352 fi
1353 AC_SUBST(SEM_INIT_LIB)
1354 dnl
1355 dnl Check for unified diff
1356 dnl
1357 AC_MSG_CHECKING(for unified diff option)
1358 if diff -u $0 $0 > /dev/null 2>&1 ; then
1359    UNI_DIFF_OPTS=-u
1360 else
1361    UNI_DIFF_OPTS=-c
1362 fi
1363 AC_MSG_RESULT($UNI_DIFF_OPTS)
1364 AC_SUBST(UNI_DIFF_OPTS)
1365 dnl
1366 dnl We use the EXT2 ioctls only under Linux
1367 dnl
1368 case "$host_os" in
1369 linux*)
1370         AC_DEFINE(HAVE_EXT2_IOCTLS, 1, [Define to 1 if Ext2 ioctls present])
1371         ;;
1372 esac
1373 dnl
1374 dnl Check the available mount options
1375 dnl
1376 AX_CHECK_MOUNT_OPT(nosuid)
1377 AX_CHECK_MOUNT_OPT(nodev)
1378 dnl Enable LTO for all packages
1379 dnl
1380 AC_ARG_ENABLE([lto],
1381 AS_HELP_STRING([--enable-lto],[enable link time optimization]),,
1382 enable_lto=no)
1383 if test "$enable_lto" = "yes" || test "$enable_lto" = "probe"; then
1384         AC_MSG_CHECKING([if C compiler supports LTO])
1385         OLD_CFLAGS="$CFLAGS"
1386         OLD_LDFLAGS="$LDFLAGS"
1387         LTO_FLAGS="-g -flto -ffat-lto-objects"
1388         CFLAGS="$CFLAGS $LTO_FLAGS"
1389         LDFLAGS="$LDFLAGS $LTO_FLAGS"
1390         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1391                 [AC_MSG_RESULT([yes])]
1392                 [lto_cflags=$LTO_FLAGS]
1393                 [lto_ldflags=$LTO_FLAGS]
1394                 [AC_PATH_PROG(gcc_ar, gcc-ar,,)]
1395                 [AC_PATH_PROG(gcc_ranlib, gcc-ranlib,,)],
1396                 [AC_MSG_RESULT([no])])
1397         if test -x "$gcc_ar" && test -x "$gcc_ranlib"; then
1398                 have_lto=yes
1399                 AR="${gcc_ar}"
1400                 RANLIB="${gcc_ranlib}"
1401         fi
1402         CFLAGS="${OLD_CFLAGS}"
1403         LDFLAGS="${OLD_LDFLAGS}"
1404         AC_SUBST(have_lto)
1405         AC_SUBST(lto_cflags)
1406         AC_SUBST(lto_ldflags)
1407 fi
1408 if test "$enable_lto" = "yes" && test "$have_lto" != "yes"; then
1409         AC_MSG_ERROR([LTO not supported by compiler.])
1410 fi
1411 dnl
1412 dnl Enable UBSAN for all packages
1413 dnl
1414 AC_ARG_ENABLE([ubsan],
1415 AS_HELP_STRING([--enable-ubsan],[enable undefined behavior sanitizer]),,
1416 enable_ubsan=no)
1417 if test "$enable_ubsan" = "yes" || test "$enable_ubsan" = "probe"; then
1418         AC_MSG_CHECKING([if C compiler supports UBSAN])
1419         OLD_CFLAGS="$CFLAGS"
1420         OLD_LDFLAGS="$LDFLAGS"
1421         UBSAN_FLAGS="-fsanitize=undefined"
1422         CFLAGS="$CFLAGS $UBSAN_FLAGS"
1423         LDFLAGS="$LDFLAGS $UBSAN_FLAGS"
1424         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1425                 [AC_MSG_RESULT([yes])]
1426                 [ubsan_cflags=$UBSAN_FLAGS]
1427                 [ubsan_ldflags=$UBSAN_FLAGS]
1428                 [have_ubsan=yes],
1429                 [AC_MSG_RESULT([no])])
1430         CFLAGS="${OLD_CFLAGS}"
1431         LDFLAGS="${OLD_LDFLAGS}"
1432         AC_SUBST(have_ubsan)
1433         AC_SUBST(ubsan_cflags)
1434         AC_SUBST(ubsan_ldflags)
1435 fi
1436 if test "$enable_ubsan" = "yes" && test "$have_ubsan" != "yes"; then
1437         AC_MSG_ERROR([UBSAN not supported by compiler.])
1438 fi
1439 dnl
1440 dnl Enable ADDRSAN for all packages
1441 dnl
1442 AC_ARG_ENABLE([addrsan],
1443 AS_HELP_STRING([--enable-addrsan],[enable address sanitizer]),,
1444 enable_addrsan=no)
1445 if test "$enable_addrsan" = "yes" || test "$enable_addrsan" = "probe"; then
1446         AC_MSG_CHECKING([if C compiler supports ADDRSAN])
1447         OLD_CFLAGS="$CFLAGS"
1448         OLD_LDFLAGS="$LDFLAGS"
1449         ADDRSAN_FLAGS="-fsanitize=address"
1450         CFLAGS="$CFLAGS $ADDRSAN_FLAGS"
1451         LDFLAGS="$LDFLAGS $ADDRSAN_FLAGS"
1452         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1453                 [AC_MSG_RESULT([yes])]
1454                 [addrsan_cflags=$ADDRSAN_FLAGS]
1455                 [addrsan_ldflags=$ADDRSAN_FLAGS]
1456                 [have_addrsan=yes],
1457                 [AC_MSG_RESULT([no])])
1458         CFLAGS="${OLD_CFLAGS}"
1459         LDFLAGS="${OLD_LDFLAGS}"
1460         AC_SUBST(have_addrsan)
1461         AC_SUBST(addrsan_cflags)
1462         AC_SUBST(addrsan_ldflags)
1463 fi
1464 if test "$enable_addrsan" = "yes" && test "$have_addrsan" != "yes"; then
1465         AC_MSG_ERROR([ADDRSAN not supported by compiler.])
1466 fi
1467 dnl
1468 dnl Enable THREADSAN for all packages
1469 dnl
1470 AC_ARG_ENABLE([threadsan],
1471 AS_HELP_STRING([--enable-threadsan],[enable thread sanitizer]),,
1472 enable_threadsan=no)
1473 if test "$enable_threadsan" = "yes" || test "$enable_threadsan" = "probe"; then
1474         AC_MSG_CHECKING([if C compiler supports THREADSAN])
1475         OLD_CFLAGS="$CFLAGS"
1476         OLD_LDFLAGS="$LDFLAGS"
1477         THREADSAN_FLAGS="-fsanitize=thread"
1478         CFLAGS="$CFLAGS $THREADSAN_FLAGS"
1479         LDFLAGS="$LDFLAGS $THREADSAN_FLAGS"
1480         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1481                 [AC_MSG_RESULT([yes])]
1482                 [threadsan_cflags=$THREADSAN_FLAGS]
1483                 [threadsan_ldflags=$THREADSAN_FLAGS]
1484                 [have_threadsan=yes],
1485                 [AC_MSG_RESULT([no])])
1486         CFLAGS="${OLD_CFLAGS}"
1487         LDFLAGS="${OLD_LDFLAGS}"
1488         AC_SUBST(have_threadsan)
1489         AC_SUBST(threadsan_cflags)
1490         AC_SUBST(threadsan_ldflags)
1491 fi
1492 if test "$enable_threadsan" = "yes" && test "$have_threadsan" != "yes"; then
1493         AC_MSG_ERROR([THREADSAN not supported by compiler.])
1494 fi
1495 if test "$have_threadsan" = "yes" && test "$have_addrsan" = "yes"; then
1496         AC_MSG_WARN([ADDRSAN and THREADSAN are not known to work together.])
1497 fi
1498 dnl
1499 dnl Enable the fuzzer sanitizer for all packages
1500 dnl
1501 FUZZING_CMT="#"
1502 AC_ARG_ENABLE([fuzzing],
1503 AS_HELP_STRING([--enable-fuzzing],[enable fuzzing sanitizer]),,
1504 enable_fuzzing=no)
1505 if test "$enable_fuzzing" = "yes" || test "$enable_fuzzing" = "probe"; then
1506         AC_PROG_CXX
1507         AC_MSG_CHECKING([if C compiler supports fuzzing sanitizer])
1508         AC_LANG_PUSH([C++])
1509         OLD_CXXFLAGS="$CXXFLAGS"
1510         OLD_LDFLAGS="$LDFLAGS"
1511         FUZZER_FLAGS="-fsanitize=fuzzer"
1512         CXXFLAGS="$CXXFLAGS $FUZZER_FLAGS"
1513         LDFLAGS="$LDFLAGS $FUZZER_FLAGS"
1514         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1515                 #include <stddef.h>
1516                 #include <stdint.h>
1517                 ]],
1518                 [ return 0; ])],
1519                 [AC_MSG_RESULT([yes])]
1520                 [fuzzer_cflags=$FUZZER_FLAGS]
1521                 [fuzzer_ldflags=$FUZZER_FLAGS]
1522                 [FUZZING_CMT=]
1523                 [have_fuzzer=yes],
1524                 [AC_MSG_RESULT([no])]
1525                 [AC_MSG_ERROR([fuzzing requested but not available])])
1526         CXXFLAGS="${OLD_CXXFLAGS}"
1527         LDFLAGS="${OLD_LDFLAGS}"
1528         AC_LANG_POP([C++])
1529         AC_SUBST(have_fuzzer)
1530         AC_SUBST(fuzzer_cflags)
1531         AC_SUBST(fuzzer_ldflags)
1532 fi
1533 if test "$enable_fuzzer" = "yes" && test "$have_fuzzer" != "yes"; then
1534         AC_MSG_ERROR([Fuzzing not supported by compiler.])
1535 fi
1536 AC_SUBST(FUZZING_CMT)
1537 dnl
1538 dnl OS-specific uncomment control
1539 dnl
1540 LINUX_CMT="#"
1541 CYGWIN_CMT="#"
1542 UNIX_CMT=
1543 case "$host_os" in
1544 linux*)
1545         LINUX_CMT=
1546         ;;
1547 cygwin)
1548         CYGWIN_CMT=
1549         UNIX_CMT="#"
1550         ;;
1551 esac
1552 AC_SUBST(LINUX_CMT)
1553 AC_SUBST(CYGWIN_CMT)
1554 AC_SUBST(UNIX_CMT)
1555 dnl
1556 dnl e2scrub only builds on linux
1557 dnl
1558 E2SCRUB_CMT="$LINUX_CMT"
1559 AC_SUBST(E2SCRUB_CMT)
1560 dnl
1561 dnl Linux and Hurd places root files in the / by default
1562 dnl
1563 case "$host_os" in
1564 linux* | gnu* | k*bsd*-gnu)
1565         if test "$prefix" = NONE -a "$root_prefix" = NONE ; then
1566                 root_prefix="";
1567                 AC_MSG_RESULT([On $host_os systems, root_prefix defaults to ''])
1568         fi
1569         ;;
1570 esac
1571 dnl
1572 dnl On Linux/hurd, force the prefix to be /usr
1573 dnl
1574 case "$host_os" in
1575 linux* | gnu* | k*bsd*-gnu)
1576         if test "$prefix" = NONE ; then
1577                 prefix="/usr";
1578                 AC_MSG_RESULT([On $host_os systems, prefix defaults to /usr])
1579                 if test "$mandir" = '${prefix}/man' ; then
1580                         AC_MSG_RESULT([...and mandir defaults to /usr/share/man])
1581                         mandir=/usr/share/man
1582                 fi
1583         fi
1584 ;;
1585 esac
1586 if test "$root_prefix" = NONE ; then
1587         if test "$prefix" = NONE ; then
1588                 root_prefix="$ac_default_prefix"
1589         else
1590                 root_prefix="$prefix"
1591         fi
1592         root_bindir=$bindir
1593         root_sbindir=$sbindir
1594         root_libdir=$libdir
1595         root_sysconfdir=$sysconfdir
1596 else
1597         root_bindir='${root_prefix}/bin'
1598         root_sbindir='${root_prefix}/sbin'
1599         root_libdir='${root_prefix}/lib'
1600         root_sysconfdir='${root_prefix}/etc'
1601 fi
1602 if test "$bindir" != '${exec_prefix}/bin'; then
1603     root_bindir=$bindir
1604     AC_MSG_RESULT([Setting root_bindir to $root_bindir])
1605 fi
1606 if test "$sbindir" != '${exec_prefix}/sbin'; then
1607     root_sbindir=$sbindir
1608     AC_MSG_RESULT([Setting root_sbindir to $root_sbindir])
1609 fi
1610 if test "$libdir" != '${exec_prefix}/lib'; then
1611     root_libdir=$libdir
1612     AC_MSG_RESULT([Setting root_libdir to $root_libdir])
1613 fi
1614 if test "$sysconfdir" != '${prefix}/etc'; then
1615     root_sysconfdir=$sysconfdir
1616     AC_MSG_RESULT([Setting root_sysconfdir to $root_sysconfdir])
1617 fi
1618 AC_SUBST(root_prefix)
1619 AC_SUBST(root_bindir)
1620 AC_SUBST(root_sbindir)
1621 AC_SUBST(root_libdir)
1622 AC_SUBST(root_sysconfdir)
1623 dnl
1624 dnl Allow specification of the multiarch arch
1625 dnl
1626 AC_ARG_WITH([multiarch],
1627 AS_HELP_STRING([--with-multiarch=ARCH],[specify the multiarch triplet]),
1628 if test "$withval" = "lib64"; then
1629     libdir=/usr/lib64
1630     root_libdir=/lib64
1631 else
1632     libdir=$libdir/$withval
1633     root_libdir=$root_libdir/$withval
1634 fi
1635 )
1636 dnl
1637 dnl
1638 dnl See if -static works.  This could fail if the linker does not
1639 dnl support -static, or if required external libraries are not available
1640 dnl in static form.
1641 dnl
1642 AC_MSG_CHECKING([whether we can link with -static])
1643 AC_CACHE_VAL(ac_cv_e2fsprogs_use_static,
1644 [SAVE_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS_STATIC -static"
1645 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[fflush(stdout);]])],[ac_cv_e2fsprogs_use_static=yes],[ac_cv_e2fsprogs_use_static=no])
1646 LDFLAGS=$SAVE_LDFLAGS])
1647 dnl
1648 dnl Regardless of how the test turns out, Solaris doesn't handle -static
1649 dnl This is caused by the socket library requiring the nsl library, which
1650 dnl requires the -dl library, which only works for dynamically linked
1651 dnl programs.  It basically means you can't have statically linked programs
1652 dnl which use the network under Solaris.
1653 dnl
1654 case "$host_os" in
1655 solaris2.*)
1656         ac_cv_e2fsprogs_use_static=no
1657 ;;
1658 esac
1659 AC_MSG_RESULT($ac_cv_e2fsprogs_use_static)
1660 if test $ac_cv_e2fsprogs_use_static = yes; then
1661         LDFLAGS_STATIC="$LDFLAGS_STATIC -static"
1662 fi
1663 AC_SUBST(LDFLAGS_STATIC)
1664 dnl
1665 dnl Work around mysterious Darwin / GNU libintl problem
1666 dnl (__asm__ redirection doesn't work for some mysterious reason.  Looks like
1667 dnl Apple hacked gcc somehow?)
1668 dnl
1669 case "$host_os" in
1670 darwin*)
1671         AC_MSG_RESULT([Using Apple Darwin / GNU libintl workaround])
1672         AC_DEFINE(_INTL_REDIRECT_MACROS, 1,
1673                 [Define to 1 if Apple Darwin libintl workaround is needed])
1674         ;;
1675 esac
1676 dnl
1677 dnl Only try to run the test suite if we're not cross compiling.
1678 dnl
1679 if test "$cross_compiling" = yes ; then
1680   DO_TEST_SUITE=
1681 else
1682   DO_TEST_SUITE=check
1683 fi
1684 AC_SUBST(DO_TEST_SUITE)
1685 dnl
1686 dnl Only include the intl include files if we're building with them
1687 dnl
1688 INCLUDES='-I. -I$(top_builddir)/lib -I$(top_srcdir)/lib'
1689 if test -n "$CPPFLAGS" ; then
1690         INCLUDES="$INCLUDES $CPPFLAGS"
1691 fi
1692 if test "$USE_INCLUDED_LIBINTL" = "yes" ; then
1693         INCLUDES=$INCLUDES' -I$(top_builddir)/intl -I$(top_srcdir)/intl'
1694 fi
1695 if test -n "$WITH_DIET_LIBC" ; then
1696         INCLUDES="$INCLUDES -D_REENTRANT"
1697 fi
1698 AC_SUBST(INCLUDES)
1699 dnl
1700 dnl Build CFLAGS
1701 dnl
1702 if test $cross_compiling = no; then
1703    BUILD_CFLAGS="$CFLAGS $CPPFLAGS $INCLUDES -DHAVE_CONFIG_H"
1704    BUILD_LDFLAGS="$LDFLAGS"
1705 fi
1706 AC_SUBST(BUILD_CFLAGS)
1707 AC_SUBST(BUILD_LDFLAGS)
1708 dnl
1709 dnl Define CFLAGS and LDFLAGS for shared libraries
1710 dnl
1711 CFLAGS_SHLIB=${CFLAGS_SHLIB:-$CFLAGS}
1712 CFLAGS_STLIB=${CFLAGS_STLIB:-$CFLAGS}
1713 LDFLAGS_SHLIB=${LDFLAGS_SHLIB:-$LDFLAGS}
1714 AC_SUBST(CFLAGS_SHLIB)
1715 AC_SUBST(CFLAGS_STLIB)
1716 AC_SUBST(LDFLAGS_SHLIB)
1717
1718 dnl
1719 dnl Where do udev rules go?
1720 dnl
1721 AC_ARG_WITH([udev_rules_dir],
1722   [AS_HELP_STRING([--with-udev-rules-dir@<:@=DIR@:>@],
1723         [Install udev rules into DIR.])],
1724   [],
1725   [with_udev_rules_dir=yes])
1726 AS_IF([test "x${with_udev_rules_dir}" != "xno"],
1727   [
1728         AS_IF([test "x${with_udev_rules_dir}" = "xyes"],
1729           [
1730                 PKG_CHECK_MODULES([udev], [udev],
1731                   [
1732                         with_udev_rules_dir="$($PKG_CONFIG --variable=udevdir udev)/rules.d"
1733                   ], [
1734                         with_udev_rules_dir=""
1735                   ])
1736           ])
1737         AC_MSG_CHECKING([for udev rules dir])
1738         pkg_udev_rules_dir="${with_udev_rules_dir}"
1739         AS_IF([test -n "${pkg_udev_rules_dir}"],
1740           [
1741                 AC_MSG_RESULT(${pkg_udev_rules_dir})
1742                 have_udev="yes"
1743           ],
1744           [
1745                 AC_MSG_RESULT(no)
1746                 have_udev="no"
1747           ])
1748   ],
1749   [
1750         have_udev="disabled"
1751   ])
1752 AC_SUBST(have_udev)
1753 AC_SUBST(pkg_udev_rules_dir)
1754
1755 dnl
1756 dnl Where do cron jobs go?
1757 dnl
1758 AC_ARG_WITH([crond_dir],
1759   [AS_HELP_STRING([--with-crond-dir@<:@=DIR@:>@],
1760         [Install system crontabs into DIR.])],
1761   [],
1762   [with_crond_dir=yes])
1763 AS_IF([test "x${with_crond_dir}" != "xno"],
1764   [
1765         AS_IF([test "x${with_crond_dir}" = "xyes"],
1766           [
1767                 AS_IF([test -d "/etc/cron.d"],
1768                   [with_crond_dir="/etc/cron.d"],
1769                   [have_crond="no"; with_crond_dir=""])
1770           ])
1771         AC_MSG_CHECKING([for system crontab dir])
1772         crond_dir="${with_crond_dir}"
1773         AS_IF([test -n "${crond_dir}"],
1774           [
1775                 AC_MSG_RESULT(${crond_dir})
1776                 have_crond="yes"
1777           ],
1778           [
1779                 AC_MSG_RESULT(no)
1780                 have_crond="no"
1781           ])
1782   ],
1783   [
1784         have_crond="disabled"
1785   ])
1786 AC_SUBST(have_crond)
1787 AC_SUBST(crond_dir)
1788
1789 dnl
1790 dnl Where do systemd services go?
1791 dnl
1792 AC_ARG_WITH([systemd_unit_dir],
1793   [AS_HELP_STRING([--with-systemd-unit-dir@<:@=DIR@:>@],
1794         [Install systemd system units into DIR.])],
1795   [],
1796   [with_systemd_unit_dir=yes])
1797 AS_IF([test "x${with_systemd_unit_dir}" != "xno"],
1798   [
1799         AS_IF([test "x${with_systemd_unit_dir}" = "xyes"],
1800           [
1801                 PKG_CHECK_MODULES([systemd], [systemd],
1802                   [
1803                         with_systemd_unit_dir="$($PKG_CONFIG --variable=systemdsystemunitdir systemd)"
1804                   ], [
1805                         with_systemd_unit_dir=""
1806                   ])
1807                 m4_pattern_allow([^PKG_(MAJOR|MINOR|BUILD|REVISION)$])
1808           ])
1809         AC_MSG_CHECKING([for systemd system unit dir])
1810         systemd_system_unit_dir="${with_systemd_unit_dir}"
1811         AS_IF([test -n "${systemd_system_unit_dir}"],
1812           [
1813                 AC_MSG_RESULT(${systemd_system_unit_dir})
1814                 have_systemd="yes"
1815           ],
1816           [
1817                 AC_MSG_RESULT(no)
1818                 have_systemd="no"
1819           ])
1820   ],
1821   [
1822         have_systemd="disabled"
1823   ])
1824 AC_SUBST(have_systemd)
1825 AC_SUBST(systemd_system_unit_dir)
1826 dnl Adjust the compiled files if we are on windows vs everywhere else
1827 dnl
1828 OS_IO_FILE=""
1829 [case "$host_os" in
1830   cigwin*|mingw*|msys*)
1831     OS_IO_FILE=windows_io
1832   ;;
1833   *)
1834     OS_IO_FILE=unix_io
1835   ;;
1836 esac]
1837 AC_SUBST(OS_IO_FILE)
1838 dnl
1839 dnl Make our output files, being sure that we create the some miscellaneous
1840 dnl directories
1841 dnl
1842 test -d lib || mkdir lib
1843 test -d include || mkdir include
1844 test -d include/linux || mkdir include/linux
1845 test -d include/asm || mkdir include/asm
1846 if test -z "$UUID_CMT" ; then
1847         uuid_out_list="lib/uuid/Makefile lib/uuid/uuid.pc \
1848                 lib/uuid/uuid_types.h"
1849 fi
1850 if test -z "$BLKID_CMT" ; then
1851         blkid_out_list="lib/blkid/Makefile lib/blkid/blkid.pc \
1852                 lib/blkid/blkid_types.h"
1853 fi
1854 for i in MCONFIG Makefile \
1855         e2fsprogs-RHEL-6.spec \
1856         e2fsprogs-SUSE_LINUX-11+.spec \
1857         e2fsprogs-RHEL-7+.spec \
1858         util/Makefile util/subst.conf util/gen-tarball util/install-symlink \
1859         lib/et/Makefile lib/ss/Makefile lib/e2p/Makefile \
1860         lib/ext2fs/Makefile lib/ext2fs/ext2_types.h \
1861         $uuid_out_list $blkid_out_list lib/support/Makefile \
1862         lib/ss/ss.pc lib/et/com_err.pc lib/e2p/e2p.pc lib/ext2fs/ext2fs.pc \
1863         misc/Makefile ext2ed/Makefile e2fsck/Makefile \
1864         debugfs/Makefile tests/Makefile tests/progs/Makefile \
1865         tests/fuzz/Makefile resize/Makefile doc/Makefile \
1866         po/Makefile.in scrub/Makefile; do
1867         if test -d `dirname ${srcdir}/$i` ; then
1868                 outlist="$outlist $i"
1869         fi
1870 done
1871 AC_CONFIG_FILES([$outlist])
1872 AC_OUTPUT
1873 if test -f util/gen-tarball; then chmod +x util/gen-tarball; fi