+# LC_DIRECTIO_USE_ITER
+#
+# 3.16 kernel changes direct IO to use iov_iter
+#
+AC_DEFUN([LC_DIRECTIO_USE_ITER], [
+LB_CHECK_COMPILE([if direct IO uses iov_iter],
+direct_io_iter, [
+ #include <linux/fs.h>
+],[
+ struct address_space_operations ops;
+ struct iov_iter *iter = NULL;
+ loff_t offset = 0;
+
+ ops.direct_IO(0, NULL, iter, offset);
+],[
+ AC_DEFINE(HAVE_DIRECTIO_ITER, 1,
+ [direct IO uses iov_iter])
+])
+]) # LC_DIRECTIO_USE_ITER
+
+#
+# LC_HAVE_IOV_ITER_INIT_DIRECTION
+#
+#
+# 3.16 linux commit 71d8e532b1549a478e6a6a8a44f309d050294d00
+# changed iov_iter_init api to start accepting a tag
+# that defines if its a read or write operation
+#
+AC_DEFUN([LC_HAVE_IOV_ITER_INIT_DIRECTION], [
+tmp_flags="$EXTRA_KCFLAGS"
+EXTRA_KCFLAGS="-Werror"
+LB_CHECK_COMPILE([if 'iov_iter_init' takes a tag],
+iter_init, [
+ #include <linux/uio.h>
+ #include <linux/fs.h>
+],[
+ const struct iovec *iov = NULL;
+
+ iov_iter_init(NULL, READ, iov, 1, 0);
+],[
+ AC_DEFINE(HAVE_IOV_ITER_INIT_DIRECTION, 1,
+ [iov_iter_init handles directional tag])
+])
+EXTRA_KCFLAGS="$tmp_flags"
+]) # LC_HAVE_IOV_ITER_INIT_DIRECTION
+
+#
+# LC_HAVE_FILE_OPERATIONS_READ_WRITE_ITER
+#
+# 3.16 introduces [read|write]_iter to struct file_operations
+#
+AC_DEFUN([LC_HAVE_FILE_OPERATIONS_READ_WRITE_ITER], [
+LB_CHECK_COMPILE([if 'file_operations.[read|write]_iter' exist],
+file_function_iter, [
+ #include <linux/fs.h>
+],[
+ ((struct file_operations *)NULL)->read_iter(NULL, NULL);
+ ((struct file_operations *)NULL)->write_iter(NULL, NULL);
+],[
+ AC_DEFINE(HAVE_FILE_OPERATIONS_READ_WRITE_ITER, 1,
+ [file_operations.[read|write]_iter functions exist])
+])
+]) # LC_HAVE_FILE_OPERATIONS_READ_WRITE_ITER
+
+#
+# LC_KEY_MATCH_DATA
+#
+# 3.17 replaces key_type::match with match_preparse
+# and has new struct key_match_data
+#
+AC_DEFUN([LC_KEY_MATCH_DATA], [
+LB_CHECK_COMPILE([if struct key_match field exist],
+key_match, [
+ #include <linux/key-type.h>
+],[
+ struct key_match_data data;
+],[
+ AC_DEFINE(HAVE_KEY_MATCH_DATA, 1,
+ [struct key_match_data exist])
+])
+]) # LC_KEY_MATCH_DATA
+
+#
+# LC_NFS_FILLDIR_USE_CTX
+#
+# 3.18 kernel moved from void cookie to struct dir_context
+#
+AC_DEFUN([LC_NFS_FILLDIR_USE_CTX], [
+tmp_flags="$EXTRA_KCFLAGS"
+EXTRA_KCFLAGS="-Werror"
+LB_CHECK_COMPILE([if filldir_t uses struct dir_context],
+filldir_ctx, [
+ #include <linux/fs.h>
+],[
+ int filldir(struct dir_context *ctx, const char* name,
+ int i, loff_t off, u64 tmp, unsigned temp)
+ {
+ return 0;
+ }
+
+ struct dir_context ctx = {
+ .actor = filldir,
+ };
+
+ ctx.actor(NULL, "test", 0, (loff_t) 0, 0, 0);
+],[
+ AC_DEFINE(HAVE_FILLDIR_USE_CTX, 1,
+ [filldir_t needs struct dir_context as argument])
+])
+EXTRA_KCFLAGS="$tmp_flags"
+]) # LC_NFS_FILLDIR_USE_CTX
+
+#
+# LC_PERCPU_COUNTER_INIT
+#
+# 3.18 For kernels 3.18 and after percpu_counter_init starts
+# to pass a GFP_* memory allocation flag for internal
+# memory allocation purposes.
+#
+AC_DEFUN([LC_PERCPU_COUNTER_INIT], [
+LB_CHECK_COMPILE([if percpu_counter_init uses GFP_* flag as argument],
+percpu_counter_init, [
+ #include <linux/percpu_counter.h>
+],[
+ percpu_counter_init(NULL, 0, GFP_KERNEL);
+],[
+ AC_DEFINE(HAVE_PERCPU_COUNTER_INIT_GFP_FLAG, 1,
+ [percpu_counter_init uses GFP_* flag])
+])
+]) # LC_PERCPU_COUNTER_INIT
+
+#
+# LC_KIOCB_HAS_NBYTES
+#
+# 3.19 kernel removed ki_nbytes from struct kiocb
+#
+AC_DEFUN([LC_KIOCB_HAS_NBYTES], [
+LB_CHECK_COMPILE([if struct kiocb has ki_nbytes field],
+ki_nbytes, [
+ #include <linux/fs.h>
+],[
+ struct kiocb iocb;
+
+ iocb.ki_nbytes = 0;
+],[
+ AC_DEFINE(HAVE_KI_NBYTES, 1, [ki_nbytes field exist])
+])
+]) # LC_KIOCB_HAS_NBYTES
+
+#
+# LC_BACKING_DEV_INFO_REMOVAL
+#
+# 3.20 kernel removed backing_dev_info from address_space
+#
+AC_DEFUN([LC_BACKING_DEV_INFO_REMOVAL], [
+LB_CHECK_COMPILE([if struct address_space has backing_dev_info],
+backing_dev_info, [
+ #include <linux/fs.h>
+],[
+ struct address_space mapping;
+
+ mapping.backing_dev_info = NULL;
+],[
+ AC_DEFINE(HAVE_BACKING_DEV_INFO, 1, [backing_dev_info exist])
+])
+]) # LC_BACKING_DEV_INFO_REMOVAL
+
+#
+# LC_HAVE_BDI_CAP_MAP_COPY
+#
+# 3.20 removed mmap handling for backing devices since
+# it breaks on non-MMU systems. See kernel commit
+# b4caecd48005fbed3949dde6c1cb233142fd69e9
+#
+AC_DEFUN([LC_HAVE_BDI_CAP_MAP_COPY], [
+LB_CHECK_COMPILE([if have 'BDI_CAP_MAP_COPY'],
+bdi_cap_map_copy, [
+ #include <linux/backing-dev.h>
+],[
+ struct backing_dev_info info;
+
+ info.capabilities = BDI_CAP_MAP_COPY;
+],[
+ AC_DEFINE(HAVE_BDI_CAP_MAP_COPY, 1,
+ [BDI_CAP_MAP_COPY exist])
+])
+]) # LC_HAVE_BDI_CAP_MAP_COPY
+
+#
+# LC_CANCEL_DIRTY_PAGE
+#
+# 4.0.0 kernel removed cancel_dirty_page
+#
+AC_DEFUN([LC_CANCEL_DIRTY_PAGE], [
+LB_CHECK_COMPILE([if cancel_dirty_page still exist],
+cancel_dirty_page, [
+ #include <linux/mm.h>
+],[
+ cancel_dirty_page(NULL, PAGE_SIZE);
+],[
+ AC_DEFINE(HAVE_CANCEL_DIRTY_PAGE, 1,
+ [cancel_dirty_page is still available])
+])
+]) # LC_CANCEL_DIRTY_PAGE
+
+#
+# LC_IOV_ITER_RW
+#
+# 4.1 kernel has iov_iter_rw
+#
+AC_DEFUN([LC_IOV_ITER_RW], [
+LB_CHECK_COMPILE([if iov_iter_rw exist],
+iov_iter_rw, [
+ #include <linux/fs.h>
+ #include <linux/uio.h>
+],[
+ struct iov_iter *iter = NULL;
+
+ iov_iter_rw(iter);
+],[
+ AC_DEFINE(HAVE_IOV_ITER_RW, 1,
+ [iov_iter_rw exist])
+])
+]) # LC_IOV_ITER_RW
+
+#
+# LC_HAVE_SYNC_READ_WRITE
+#
+# 4.1 new_sync_[read|write] no longer exported
+#
+AC_DEFUN([LC_HAVE_SYNC_READ_WRITE], [
+LB_CHECK_EXPORT([new_sync_read], [fs/read_write.c],
+ [AC_DEFINE(HAVE_SYNC_READ_WRITE, 1,
+ [new_sync_[read|write] is exported by the kernel])])
+]) # LC_HAVE_SYNC_READ_WRITE
+
+#
+# LC_NEW_CANCEL_DIRTY_PAGE
+#
+# 4.2 kernel has new cancel_dirty_page
+#
+AC_DEFUN([LC_NEW_CANCEL_DIRTY_PAGE], [
+LB_CHECK_COMPILE([if cancel_dirty_page with one argument exist],
+new_cancel_dirty_page, [
+ #include <linux/mm.h>
+],[
+ cancel_dirty_page(NULL);
+],[
+ AC_DEFINE(HAVE_NEW_CANCEL_DIRTY_PAGE, 1,
+ [cancel_dirty_page with one arguement is available])
+])
+]) # LC_NEW_CANCEL_DIRTY_PAGE
+
+#
+# LC_SYMLINK_OPS_USE_NAMEIDATA
+#
+# For the 4.2+ kernels the file system internal symlink api no
+# longer uses struct nameidata as a argument
+#
+AC_DEFUN([LC_SYMLINK_OPS_USE_NAMEIDATA], [
+LB_CHECK_COMPILE([if symlink inode operations have struct nameidata argument],
+symlink_use_nameidata, [
+ #include <linux/namei.h>
+ #include <linux/fs.h>
+],[
+ struct nameidata *nd = NULL;
+
+ ((struct inode_operations *)0)->follow_link(NULL, nd);
+ ((struct inode_operations *)0)->put_link(NULL, nd, NULL);
+],[
+ AC_DEFINE(HAVE_SYMLINK_OPS_USE_NAMEIDATA, 1,
+ [symlink inode operations need struct nameidata argument])
+])
+]) # LC_SYMLINK_OPS_USE_NAMEIDATA
+
+#
+# LC_BIO_ENDIO_USES_ONE_ARG
+#
+# 4.2 kernel bio_endio now only takes one argument
+#
+AC_DEFUN([LC_BIO_ENDIO_USES_ONE_ARG], [
+LB_CHECK_COMPILE([if 'bio_endio' with one argument exist],
+bio_endio, [
+ #include <linux/bio.h>
+],[
+ bio_endio(NULL);
+],[
+ AC_DEFINE(HAVE_BIO_ENDIO_USES_ONE_ARG, 1,
+ [bio_endio takes only one argument])
+])
+]) # LC_BIO_ENDIO_USES_ONE_ARG
+
+#
+# LC_HAVE_LOOP_CTL_GET_FREE
+#
+# 4.x kernel have moved userspace APIs to
+# the separate directory and all of them
+# support LOOP_CTL_GET_FREE
+#
+AC_DEFUN([LC_HAVE_LOOP_CTL_GET_FREE], [
+LB_CHECK_FILE([$LINUX/include/linux/loop.h], [
+ LB_CHECK_COMPILE([if have 'HAVE_LOOP_CTL_GET_FREE'],
+ LOOP_CTL_GET_FREE, [
+ #include <linux/loop.h>
+ ],[
+ int i;
+
+ i = LOOP_CTL_GET_FREE;
+ ],[
+ AC_DEFINE(HAVE_LOOP_CTL_GET_FREE, 1,
+ [LOOP_CTL_GET_FREE exist])
+ ])
+],[
+ AC_DEFINE(HAVE_LOOP_CTL_GET_FREE, 1,
+ [kernel has LOOP_CTL_GET_FREE])
+])
+]) # LC_HAVE_LOOP_CTL_GET_FREE
+
+#
+# LC_HAVE_CACHE_HEAD_HLIST
+#
+# 4.3 kernel swiched to hlist for cache_head
+#
+AC_DEFUN([LC_HAVE_CACHE_HEAD_HLIST], [
+LB_CHECK_COMPILE([if 'struct cache_head' has 'cache_list' field],
+cache_head_has_hlist, [
+ #include <linux/sunrpc/cache.h>
+],[
+ do {} while(sizeof(((struct cache_head *)0)->cache_list));
+],[
+ AC_DEFINE(HAVE_CACHE_HEAD_HLIST, 1,
+ [cache_head has hlist cache_list])
+])
+]) # LC_HAVE_CACHE_HEAD_HLIST
+
+#
+# LC_HAVE_LOCKS_LOCK_FILE_WAIT
+#
+# 4.4 kernel have moved locks API users to
+# locks_lock_inode_wait()
+#
+AC_DEFUN([LC_HAVE_LOCKS_LOCK_FILE_WAIT], [
+LB_CHECK_COMPILE([if 'locks_lock_file_wait' exists],
+locks_lock_file_wait, [
+ #include <linux/fs.h>
+],[
+ locks_lock_file_wait(NULL, NULL);
+],[
+ AC_DEFINE(HAVE_LOCKS_LOCK_FILE_WAIT, 1,
+ [kernel has locks_lock_file_wait])
+])
+]) # LC_HAVE_LOCKS_LOCK_FILE_WAIT
+
+#
+# LC_HAVE_QC_MAKE_REQUEST_FN
+#
+# 4.4 request_queue.make_request_fn defined as function returns with blk_qc_t
+# see kernel commit dece16353ef47d8d33f5302bc158072a9d65e26f
+#
+AC_DEFUN([LC_HAVE_QC_MAKE_REQUEST_FN], [
+LB_CHECK_COMPILE([if 'request_queue.make_request_fn' returns blk_qc_t],
+make_request_fn_blk_qc_t, [
+ #include <linux/blkdev.h>
+],[
+ blk_qc_t ret;
+ make_request_fn *mrf;
+ ret = mrf(NULL, NULL);
+],[
+ AC_DEFINE(HAVE_QC_MAKE_REQUEST_FN, 1,
+ [request_queue.make_request_fn returns blk_qc_t])
+])
+]) # LC_HAVE_QC_MAKE_REQUEST_FN
+
+#