+# LC_INODEOPS_ENHANCED_GETATTR
+#
+# Kernel version 4.11 commit a528d35e8bfcc521d7cb70aaf03e1bd296c8493f
+# expanded getattr to be able to get more stat information.
+#
+AC_DEFUN([LC_INODEOPS_ENHANCED_GETATTR], [
+LB_CHECK_COMPILE([if 'inode_operations' getattr member can gather advance stats],
+getattr_path, [
+ #include <linux/fs.h>
+],[
+ struct path path;
+
+ ((struct inode_operations *)1)->getattr(&path, NULL, 0, 0);
+],[
+ AC_DEFINE(HAVE_INODEOPS_ENHANCED_GETATTR, 1,
+ [inode_operations .getattr member function can gather advance stats])
+])
+]) # LC_INODEOPS_ENHANCED_GETATTR
+
+#
+# LC_VM_OPERATIONS_REMOVE_VMF_ARG
+#
+# Kernel version 4.11 commit 11bac80004499ea59f361ef2a5516c84b6eab675
+# removed struct vm_area_struct as an argument for vm_operations since
+# in the same kernel version struct vma_area_struct was folded into
+# struct vm_fault.
+#
+AC_DEFUN([LC_VM_OPERATIONS_REMOVE_VMF_ARG], [
+LB_CHECK_COMPILE([if 'struct vm_operations' removed struct vm_area_struct],
+vm_operations_no_vm_area_struct, [
+ #include <linux/mm.h>
+],[
+ struct vm_fault vmf;
+
+ ((struct vm_operations_struct *)0)->fault(&vmf);
+ ((struct vm_operations_struct *)0)->page_mkwrite(&vmf);
+],[
+ AC_DEFINE(HAVE_VM_OPS_USE_VM_FAULT_ONLY, 1,
+ ['struct vm_operations' remove struct vm_area_struct argument])
+])
+]) # LC_VM_OPERATIONS_REMOVE_VMF_ARG
+
+#
+# LC_HAVE_KEY_USAGE_REFCOUNT
+#
+# Kernel version 4.11 commit fff292914d3a2f1efd05ca71c2ba72a3c663201e
+# converted key.usage from atomic_t to refcount_t.
+#
+AC_DEFUN([LC_HAVE_KEY_USAGE_REFCOUNT], [
+LB_CHECK_COMPILE([if 'key.usage' is refcount_t],
+key_usage_refcount, [
+ #include <linux/key.h>
+],[
+ struct key key = { };
+
+ refcount_read(&key.usage);
+],[
+ AC_DEFINE(HAVE_KEY_USAGE_REFCOUNT, 1, [key.usage is of type refcount_t])
+])
+]) #LC_HAVE_KEY_USAGE_REFCOUNT
+
+#
+# LC_HAVE_CRYPTO_MAX_ALG_NAME_128
+#
+# Kernel version 4.11 commit f437a3f477cce402dbec6537b29e9e33962c9f73
+# switched CRYPTO_MAX_ALG_NAME from 64 to 128.
+#
+AC_DEFUN([LC_HAVE_CRYPTO_MAX_ALG_NAME_128], [
+LB_CHECK_COMPILE([if 'CRYPTO_MAX_ALG_NAME' is 128],
+crypto_max_alg_name, [
+ #include <linux/crypto.h>
+],[
+ #if CRYPTO_MAX_ALG_NAME != 128
+ exit(1);
+ #endif
+],[
+ AC_DEFINE(HAVE_CRYPTO_MAX_ALG_NAME_128, 1,
+ ['CRYPTO_MAX_ALG_NAME' is 128])
+])
+]) # LC_HAVE_CRYPTO_MAX_ALG_NAME_128
+
+#
+# Kernel version 4.12 commit 47f38c539e9a42344ff5a664942075bd4df93876
+# CURRENT_TIME is not 64 bit time safe so it was replaced with
+# current_time()
+#
+AC_DEFUN([LC_CURRENT_TIME], [
+LB_CHECK_COMPILE([if CURRENT_TIME has been replaced with current_time],
+current_time, [
+ #include <linux/fs.h>
+],[
+ struct iattr attr;
+
+ attr.ia_atime = current_time(NULL);
+],[
+ AC_DEFINE(HAVE_CURRENT_TIME, 1,
+ [current_time() has replaced CURRENT_TIME])
+])
+]) # LIBCFS_CURRENT_TIME
+
+#
+# Kernel version 4.12-rc3 85787090a21eb749d8b347eaf9ff1a455637473c
+# changed struct super_block s_uuid into a proper uuid_t
+#
+AC_DEFUN([LC_SUPER_BLOCK_S_UUID], [
+LB_CHECK_COMPILE([if 'struct super_block' s_uuid is uuid_t],
+super_block_s_uuid, [
+ #include <linux/fs.h>
+],[
+ struct super_block sb;
+
+ uuid_parse(NULL, &sb.s_uuid);
+],[
+ AC_DEFINE(HAVE_S_UUID_AS_UUID_T, 1, ['s_uuid' is an uuid_t])
+])
+]) # LC_SUPER_BLOCK_S_UUID
+
+#
+# LC_SUPER_SETUP_BDI_NAME
+#
+# Kernel version 4.12 commit 9594caf216dc0fe3e318b34af0127276db661241
+# unified bdi handling
+#
+AC_DEFUN([LC_SUPER_SETUP_BDI_NAME], [
+LB_CHECK_COMPILE([if 'super_setup_bdi_name' exist],
+super_setup_bdi_name, [
+ #include <linux/fs.h>
+],[
+ super_setup_bdi_name(NULL, "lustre");
+],[
+ AC_DEFINE(HAVE_SUPER_SETUP_BDI_NAME, 1,
+ ['super_setup_bdi_name' is available])
+])
+]) # LC_SUPER_SETUP_BDI_NAME
+
+#
+# LC_BI_STATUS
+#
+# 4.12 replace bi_error to bi_status
+#
+AC_DEFUN([LC_BI_STATUS], [
+LB_CHECK_COMPILE([if 'bi_status' exist],
+bi_status, [
+ #include <linux/blk_types.h>
+],[
+ ((struct bio *)0)->bi_status = 0;
+],[
+ AC_DEFINE(HAVE_BI_STATUS, 1,
+ ['bi_status' is available])
+])
+]) # LC_BI_STATUS
+
+#
+# LC_BIO_INTEGRITY_ENABLED
+#
+# 4.13 removed bio_integrity_enabled
+#
+AC_DEFUN([LC_BIO_INTEGRITY_ENABLED], [
+LB_CHECK_COMPILE([if 'bio_integrity_enabled' exist],
+bio_integrity_enabled, [
+ #include <linux/bio.h>
+],[
+ bio_integrity_enabled(NULL);
+],[
+ AC_DEFINE(HAVE_BIO_INTEGRITY_ENABLED, 1,
+ ['bio_integrity_enabled' is available])
+])
+]) # LC_BIO_INTEGRITY_ENABLED
+
+#
+# LC_PAGEVEC_INIT_ONE_PARAM
+#
+# 4.14 pagevec_init takes one parameter
+#
+AC_DEFUN([LC_PAGEVEC_INIT_ONE_PARAM], [
+LB_CHECK_COMPILE([if 'pagevec_init' takes one parameter],
+pagevec_init, [
+ #include <linux/pagevec.h>
+],[
+ pagevec_init(NULL);
+],[
+ AC_DEFINE(HAVE_PAGEVEC_INIT_ONE_PARAM, 1,
+ ['pagevec_init' takes one parameter])
+])
+]) # LC_PAGEVEC_INIT_ONE_PARAM
+
+#
+# LC_BI_BDEV
+#
+# 4.14 replaced bi_bdev to bi_disk
+#
+AC_DEFUN([LC_BI_BDEV], [
+LB_CHECK_COMPILE([if 'bi_bdev' exist],
+bi_bdev, [
+ #include <linux/bio.h>
+],[
+ ((struct bio *)0)->bi_bdev = NULL;
+],[
+ AC_DEFINE(HAVE_BI_BDEV, 1,
+ ['bi_bdev' is available])
+])
+]) # LC_BI_BDEV
+
+#
+# LC_I_PAGES
+#
+# kernel 4.17 commit b93b016313b3ba8003c3b8bb71f569af91f19fc7
+#
+AC_DEFUN([LC_I_PAGES], [
+LB_CHECK_COMPILE([if struct address_space has i_pages],
+i_pages, [
+ #include <linux/fs.h>
+],[
+ struct address_space mapping = {};
+ void *i_pages;
+
+ i_pages = &mapping.i_pages;
+],[
+ AC_DEFINE(HAVE_I_PAGES, 1,
+ [struct address_space has i_pages])
+])
+]) # LC_I_PAGES
+
+#
+# LC_VM_FAULT_T
+#
+# kernel 4.17 commit 3d3539018d2cbd12e5af4a132636ee7fd8d43ef0
+# mm: create the new vm_fault_t type
+#
+AC_DEFUN([LC_VM_FAULT_T], [
+LB_CHECK_COMPILE([if vm_fault_t type exists],
+vm_fault_t, [
+ #include <linux/mm_types.h>
+],[
+ vm_fault_t x = VM_FAULT_SIGBUS;
+ (void)x
+],[
+ AC_DEFINE(HAVE_VM_FAULT_T, 1,
+ [if vm_fault_t type exists])
+])
+]) # LC_VM_FAULT_T
+
+#
+# LC_INODE_TIMESPEC64
+#
+# kernel 4.17-rc7 commit 8efd6894ff089adeeac7cb9f32125b85d963d1bc
+# fs: add timespec64_truncate()
+# kernel 4.18 commit 95582b00838837fc07e042979320caf917ce3fe6
+# inode timestamps switched to timespec64
+# kernel 4.19-rc2 commit 976516404ff3fab2a8caa8bd6f5efc1437fed0b8
+# y2038: remove unused time interfaces
+# ...
+# timespec_trunc
+# ...
+# When inode times are timespec64 stop using the deprecated
+# time interfaces.
+#
+AC_DEFUN([LC_INODE_TIMESPEC64], [
+tmp_flags="$EXTRA_KCFLAGS"
+EXTRA_KCFLAGS="-Werror"
+LB_CHECK_COMPILE([if inode timestamps are struct timespec64],
+inode_timespec64, [
+ #include <linux/fs.h>
+],[
+ struct inode *inode = NULL;
+ struct timespec64 ts = {};
+
+ inode->i_atime = timespec64_trunc(ts, 1);
+ (void)inode;
+],[
+ AC_DEFINE(HAVE_INODE_TIMESPEC64, 1,
+ [inode times are using timespec64])
+])
+EXTRA_KCFLAGS="$tmp_flags"
+]) # LC_INODE_TIMESPEC64
+
+#
+# LC_XA_IS_VALUE
+# kernel 4.19-rc6 commit 3159f943aafdbacb2f94c38fdaadabf2bbde2a14
+# xarray: Replace exceptional entries
+# adds xa_is_value
+#
+AC_DEFUN([LC_XA_IS_VALUE], [
+LB_CHECK_COMPILE([xa_is_value exist],
+xa_is_value, [
+ #include <linux/xarray.h>
+],[
+ xa_is_value(NULL);
+],[
+ AC_DEFINE(HAVE_XA_IS_VALUE, 1, [xa_is_value exist])
+])
+]) # LC_XA_IS_VALUE
+
+#
+# LC___XA_SET_MARK
+#
+# kernel 4.20 commit v4.19-rc5-248-g9b89a0355144
+# xarray: Add XArray marks
+#
+AC_DEFUN([LC___XA_SET_MARK], [
+LB_CHECK_COMPILE([if '__xa_set_mark' exists],
+__xa_set_mark, [
+ #include <linux/xarray.h>
+ #include <linux/fs.h>
+],[
+ struct xarray *xa = NULL;
+
+ __xa_set_mark(xa, 0, PAGECACHE_TAG_DIRTY);
+],[
+ AC_DEFINE(HAVE___XA_SET_MARK, 1,
+ [__xa_set_mark exists])
+])
+]) # LC___XA_SET_MARK
+
+#
+# LC_UAPI_LINUX_MOUNT_H
+#
+# kernel 4.20 commit e262e32d6bde0f77fb0c95d977482fc872c51996
+# vfs: Suppress MS_* flag defs within the kernel ...
+#
+AC_DEFUN([LC_UAPI_LINUX_MOUNT_H], [
+tmp_flags="$EXTRA_KCFLAGS"
+EXTRA_KCFLAGS="-Werror"
+LB_CHECK_COMPILE([if MS_RDONLY was moved to uapi/linux/mount.h],
+uapi_linux_mount, [
+ #include <uapi/linux/mount.h>
+],[
+ int x = MS_RDONLY;
+ (void)x;
+],[
+ AC_DEFINE(HAVE_UAPI_LINUX_MOUNT_H, 1,
+ [if MS_RDONLY was moved to uapi/linux/mount.h])
+])
+EXTRA_KCFLAGS="$tmp_flags"
+]) # LC_UAPI_LINUX_MOUNT_H
+
+#
+# LC_HAVE_SUNRPC_CACHE_HASH_LOCK_IS_A_SPINLOCK
+#
+# kernel 4.20 commit 1863d77f15da0addcd293a1719fa5d3ef8cde3ca
+# SUNRPC: Replace the cache_detail->hash_lock with a regular spinlock
+#
+# Now that the reader functions are all RCU protected, use a regular
+# spinlock rather than a reader/writer lock.
+#
+AC_DEFUN([LC_HAVE_SUNRPC_CACHE_HASH_LOCK_IS_A_SPINLOCK], [
+tmp_flags="$EXTRA_KCFLAGS"
+EXTRA_KCFLAGS="-Werror"
+LB_CHECK_COMPILE([if cache_detail->hash_lock is a spinlock],
+hash_lock_isa_spinlock_t, [
+ #include <linux/sunrpc/cache.h>
+],[
+ spinlock_t *lock = &(((struct cache_detail *)0)->hash_lock);
+ spin_lock(lock);
+],[
+ AC_DEFINE(HAVE_CACHE_HASH_SPINLOCK, 1,
+ [if cache_detail->hash_lock is a spinlock])
+])
+EXTRA_KCFLAGS="$tmp_flags"
+]) # LC_HAVE_SUNRPC_CACHE_HASH_LOCK_IS_A_SPINLOCK
+
+#
+# LC_HAS_LINUX_SELINUX_ENABLED
+#
+# kernel 5.1 commit 3d252529480c68bfd6a6774652df7c8968b28e41
+# SELinux: Remove unused selinux_is_enabled
+#
+AC_DEFUN([LC_HAS_LINUX_SELINUX_ENABLED], [
+tmp_flags="$EXTRA_KCFLAGS"
+EXTRA_KCFLAGS="-Werror"
+LB_CHECK_COMPILE([if linux/selinux.h exists],
+selinux_is_enabled, [
+ #include <linux/selinux.h>
+],[
+ bool has_selinux = selinux_is_enabled();
+ (void)has_selinux;
+],[
+ AC_DEFINE(HAVE_LINUX_SELINUX_IS_ENABLED, 1,
+ [if linux/selinux.h exists])
+])
+EXTRA_KCFLAGS="$tmp_flags"
+]) # LC_HAS_LINUX_SELINUX_ENABLED
+
+#
+# LC_ACCOUNT_PAGE_DIRTIED
+#
+# After 5.2 kernel page dirtied is not exported
+#
+AC_DEFUN([LC_ACCOUNT_PAGE_DIRTIED], [
+LB_CHECK_COMPILE([if 'account_page_dirtied' is exported],
+account_page_dirtied, [
+ #include <linux/mm.h>
+],[
+ account_page_dirtied(NULL, NULL);
+],[
+ AC_DEFINE(HAVE_ACCOUNT_PAGE_DIRTIED, 1,
+ [account_page_dirtied is available])
+])
+]) # LC_ACCOUNT_PAGE_DIRTIED
+
+#
+# LC_BIO_BI_PHYS_SEGMENTS
+#
+# kernel 5.3-rc1 commit 14ccb66b3f585b2bc21e7256c96090abed5a512c
+# block: remove the bi_phys_segments field in struct bio
+#
+AC_DEFUN([LC_BIO_BI_PHYS_SEGMENTS], [
+tmp_flags="$EXTRA_KCFLAGS"
+EXTRA_KCFLAGS="-Werror"
+LB_CHECK_COMPILE([if struct bio has bi_phys_segments member],
+bye_bio_bi_phys_segments, [
+ #include <linux/bio.h>
+],[
+ struct bio *bio = NULL;
+ bio->bi_phys_segments++;
+],[
+ AC_DEFINE(HAVE_BIO_BI_PHYS_SEGMENTS, 1,
+ [struct bio has bi_phys_segments member])
+])
+EXTRA_KCFLAGS="$tmp_flags"
+]) # LC_BIO_BI_PHYS_SEGMENTS
+
+#
+# LC_LM_COMPARE_OWNER_EXISTS
+#
+# kernel 5.3-rc3 commit f85d93385e9fe6886a751f647f6812a89bf6bee3
+# locks: Cleanup lm_compare_owner and lm_owner_key
+# removed lm_compare_owner
+#
+AC_DEFUN([LC_LM_COMPARE_OWNER_EXISTS], [
+tmp_flags="$EXTRA_KCFLAGS"
+EXTRA_KCFLAGS="-Werror"
+LB_CHECK_COMPILE([if lock_manager_operations has lm_compare_owner],
+lock_manager_ops_lm_compare_owner, [
+ #include <linux/fs.h>
+],[
+ struct lock_manager_operations lm_ops;
+ lm_ops.lm_compare_owner = NULL;
+],[
+ AC_DEFINE(HAVE_LM_COMPARE_OWNER, 1,
+ [lock_manager_operations has lm_compare_owner])
+])
+EXTRA_KCFLAGS="$tmp_flags"
+]) # LC_LM_COMPARE_OWNER_EXISTS
+
+#