AC_INIT
AC_CANONICAL_SYSTEM

# Copyright (C) 2001  Cluster File Systems, Inc.
#
# This code is issued under the GNU General Public License.
# See the file COPYING in this distribution

# Automake variables.  Steal the version number from lustre.spec.in.
AM_INIT_AUTOMAKE(lustre, builtin([esyscmd], [sed -ne '/^%define version /{ s/.*version //; p; q; }' scripts/lustre.spec.in]))
#AM_MAINTAINER_MODE
AC_PROG_CC
AC_PROG_RANLIB

# 
# Check for required packages

# this doesn't seem to work on older autoconf
# AC_CHECK_LIB(readline, readline,,)

AC_ARG_ENABLE(readline,	[  --enable-readline  use readline library],,
			enable_readline="yes")
 
if test "$enable_readline" = "yes" ; then
   LIBREADLINE="-lreadline -lncurses"
   HAVE_LIBREADLINE="-DHAVE_LIBREADLINE=1"
else 
   LIBREADLINE=""
   HAVE_LIBREADLINE=""
fi
AC_SUBST(LIBREADLINE)
AC_SUBST(HAVE_LIBREADLINE)

# Kernel build environment.
ac_default_prefix=
bindir='${exec_prefix}/usr/bin'
sbindir='${exec_prefix}/usr/sbin'

linuxdir_def=/usr/src/linux
AC_ARG_WITH(linux, [  --with-linux=[path] set path to Linux source (default=/usr/src/linux)], enable_linuxdir=$withval)
AC_ARG_ENABLE(linuxdir, [  --enable-linuxdir=[path] (deprecated) set path to Linux source (default=/usr/src/linux)],, enable_linuxdir=$linuxdir_def)

LINUX=$enable_linuxdir
AC_SUBST(LINUX)

sinclude(archdep.m4)

KINCFLAGS='-I. -I$(top_srcdir)/include -I$(PORTALS)/include -I$(LINUX)/include'
CPPFLAGS="$KINCFLAGS $ARCHCPPFLAGS"

portalsdir_def='$(top_srcdir)/../portals'
AC_ARG_ENABLE(portalsdir, [  --enable-portalsdir=[path] set path to Portals source (default=../portals)],, enable_portalsdir=$portalsdir_def)
PORTALS=$enable_portalsdir
AC_SUBST(PORTALS)

AC_MSG_CHECKING(if make dep has been run in kernel source)
if test -f $LINUX/include/linux/config.h ; then
	AC_MSG_RESULT(yes)
else
	AC_MSG_ERROR(** cannot find $LINUX/include/linux/config.h. Run make dep in $LINUX.)
fi

AC_MSG_CHECKING(if autoconf.h is in kernel source)
if test -f $LINUX/include/linux/autoconf.h ; then
	AC_MSG_RESULT(yes)
else
	AC_MSG_ERROR(** cannot find $LINUX/include/linux/autoconf.h. Run make config in $LINUX.)
fi


AC_MSG_CHECKING(for Linux release)

dnl We need to rid ourselves of the nasty [ ] quotes.
changequote(, )
dnl Get release from version.h
RELEASE="`sed -ne 's/.*UTS_RELEASE[ \"]*\([0-9.a-zA-Z-]*\).*/\1/p' $LINUX/include/linux/version.h`"
changequote([, ])

moduledir='$(libdir)/modules/'$RELEASE/kernel
AC_SUBST(moduledir)

modulefsdir='$(moduledir)/fs/$(PACKAGE)'
AC_SUBST(modulefsdir)

AC_MSG_RESULT($RELEASE)
AC_SUBST(RELEASE)

# Directories for documentation and demos.
docdir='${prefix}/usr/share/doc/$(PACKAGE)'
AC_SUBST(docdir)

demodir='$(docdir)/demo'
AC_SUBST(demodir)

# not needed until the AC_CHECK_LIB(readline) above works
# AM_CONFIG_HEADER(include/config.h)

AC_OUTPUT(Makefile lib/Makefile ldlm/Makefile obdecho/Makefile ptlrpc/Makefile \
	lov/Makefile osc/Makefile mdc/Makefile mds/Makefile ost/Makefile \
	utils/Makefile tests/Makefile obdfilter/Makefile obdclass/Makefile \
	llite/Makefile demos/Makefile doc/Makefile scripts/Makefile \
	scripts/lustre.spec extN/Makefile)