lustre/configure.in

   1 AC_INIT
   2 AC_CANONICAL_SYSTEM
   3
   4 # Copyright (C) 2001  Cluster File Systems, Inc.
   5 #
   6 # This code is issued under the GNU General Public License.
   7 # See the file COPYING in this distribution
   8
   9 # Automake variables.  Steal the version number from lustre.spec.in.
  10 AM_INIT_AUTOMAKE(lustre, builtin([esyscmd], [sed -ne '/^%define version /{ s/.*version //; p; q; }' scripts/lustre.spec.in]))
  11 #AM_MAINTAINER_MODE
  12 AC_PROG_CC
  13 AC_PROG_RANLIB
  14
  15 #
  16 # Check for required packages
  17
  18 # this doesn't seem to work on older autoconf
  19 # AC_CHECK_LIB(readline, readline,,)
  20
  21 AC_ARG_ENABLE(readline, [  --enable-readline  use readline library],,
  22                         enable_readline="yes")
  23
  24 if test "$enable_readline" = "yes" ; then
  25    LIBREADLINE="-lreadline -lncurses"
  26    HAVE_LIBREADLINE="-DHAVE_LIBREADLINE=1"
  27 else
  28    LIBREADLINE=""
  29    HAVE_LIBREADLINE=""
  30 fi
  31 AC_SUBST(LIBREADLINE)
  32 AC_SUBST(HAVE_LIBREADLINE)
  33
  34 # Kernel build environment.
  35 ac_default_prefix=
  36 bindir='${exec_prefix}/usr/bin'
  37 sbindir='${exec_prefix}/usr/sbin'
  38
  39 linuxdir_def=/usr/src/linux
  40 AC_ARG_WITH(linux, [  --with-linux=[path] set path to Linux source (default=/usr/src/linux)], enable_linuxdir=$withval)
  41 AC_ARG_ENABLE(linuxdir, [  --enable-linuxdir=[path] (deprecated) set path to Linux source (default=/usr/src/linux)],, enable_linuxdir=$linuxdir_def)
  42
  43 LINUX=$enable_linuxdir
  44 AC_SUBST(LINUX)
  45
  46 sinclude(archdep.m4)
  47
  48 KINCFLAGS='-I. -I$(top_srcdir)/include -I$(PORTALS)/include -I$(LINUX)/include'
  49 CPPFLAGS="$KINCFLAGS $ARCHCPPFLAGS"
  50
  51 portalsdir_def='$(top_srcdir)/../portals'
  52 AC_ARG_WITH(portals, [  --with-portals=[path] set path to Portals source (default=../portals)], enable_portalsdir=$withval)
  53 AC_ARG_ENABLE(portalsdir, [  --enable-portalsdir=[path] (deprecated) set path to Portals source (default=../portals)],, enable_portalsdir=$portalsdir_def)
  54 PORTALS=$enable_portalsdir
  55 AC_SUBST(PORTALS)
  56
  57 AC_ARG_WITH(portalslib, [  --with-portalslib=[path] set path to Portals library (default=../portals/linux/utils)], enable_portalslib=$withval)
  58 AC_ARG_ENABLE(portalslib, [  --enable-portalslib=[path] (deprecated) set path to Portals lib (default=../portals/linux/utils)],, enable_portalslib='')
  59 if test -z "$enable_portalslib"; then
  60   PORTALSLIB=${PORTALS}/linux/utils
  61 else
  62   PORTALSLIB=${enable_portalslib}
  63 fi
  64 AC_SUBST(PORTALSLIB)
  65
  66 AC_MSG_CHECKING(if make dep has been run in kernel source)
  67 if test -f $LINUX/include/linux/config.h ; then
  68         AC_MSG_RESULT(yes)
  69 else
  70         AC_MSG_ERROR(** cannot find $LINUX/include/linux/config.h. Run make dep in $LINUX.)
  71 fi
  72
  73 AC_MSG_CHECKING(if autoconf.h is in kernel source)
  74 if test -f $LINUX/include/linux/autoconf.h ; then
  75         AC_MSG_RESULT(yes)
  76 else
  77         AC_MSG_ERROR(** cannot find $LINUX/include/linux/autoconf.h. Run make config in $LINUX.)
  78 fi
  79
  80
  81 AC_MSG_CHECKING(for Linux release)
  82
  83 dnl We need to rid ourselves of the nasty [ ] quotes.
  84 changequote(, )
  85 dnl Get release from version.h
  86 RELEASE="`sed -ne 's/.*UTS_RELEASE[ \"]*\([0-9.a-zA-Z-]*\).*/\1/p' $LINUX/include/linux/version.h`"
  87 changequote([, ])
  88
  89 moduledir='$(libdir)/modules/'$RELEASE/kernel
  90 AC_SUBST(moduledir)
  91
  92 modulefsdir='$(moduledir)/fs/$(PACKAGE)'
  93 AC_SUBST(modulefsdir)
  94
  95 AC_MSG_RESULT($RELEASE)
  96 AC_SUBST(RELEASE)
  97
  98 # Directories for documentation and demos.
  99 docdir='${prefix}/usr/share/doc/$(PACKAGE)'
 100 AC_SUBST(docdir)
 101
 102 demodir='$(docdir)/demo'
 103 AC_SUBST(demodir)
 104
 105 # not needed until the AC_CHECK_LIB(readline) above works
 106 # AM_CONFIG_HEADER(include/config.h)
 107
 108 AC_OUTPUT(Makefile lib/Makefile ldlm/Makefile obdecho/Makefile ptlrpc/Makefile \
 109         lov/Makefile osc/Makefile mdc/Makefile mds/Makefile ost/Makefile \
 110         utils/Makefile tests/Makefile obdfilter/Makefile obdclass/Makefile \
 111         llite/Makefile demos/Makefile doc/Makefile scripts/Makefile \
 112         scripts/lustre.spec extN/Makefile)