lustre/autoconf/lustre-core.m4

   1 #
   2 # LC_CONFIG_SRCDIR
   3 #
   4 # Wrapper for AC_CONFIG_SUBDIR
   5 #
   6 AC_DEFUN([LC_CONFIG_SRCDIR], [
   7 AC_CONFIG_SRCDIR([lustre/obdclass/obdo.c])
   8 libcfs_is_module="yes"
   9 ldiskfs_is_ext4="yes"
  10 ])
  11
  12 #
  13 # LC_PATH_DEFAULTS
  14 #
  15 # lustre specific paths
  16 #
  17 AC_DEFUN([LC_PATH_DEFAULTS], [
  18 # ptlrpc kernel build requires this
  19 LUSTRE="$PWD/lustre"
  20 AC_SUBST(LUSTRE)
  21
  22 # mount.lustre
  23 rootsbindir='$(CROSS_PATH)/sbin'
  24 AC_SUBST(rootsbindir)
  25
  26 demodir='$(docdir)/demo'
  27 AC_SUBST(demodir)
  28
  29 pkgexampledir='${pkgdatadir}/examples'
  30 AC_SUBST(pkgexampledir)
  31 ]) # LC_PATH_DEFAULTS
  32
  33 #
  34 # LC_TARGET_SUPPORTED
  35 #
  36 # is the target os supported?
  37 #
  38 AC_DEFUN([LC_TARGET_SUPPORTED], [
  39 case $target_os in
  40         linux*)
  41 $1
  42                 ;;
  43         *)
  44 $2
  45                 ;;
  46 esac
  47 ]) # LC_TARGET_SUPPORTED
  48
  49 #
  50 # LC_CONFIG_OBD_BUFFER_SIZE
  51 #
  52 # the maximum buffer size of lctl ioctls
  53 #
  54 AC_DEFUN([LC_CONFIG_OBD_BUFFER_SIZE], [
  55 AC_MSG_CHECKING([for maximum OBD ioctl size])
  56 AC_ARG_WITH([obd-buffer-size],
  57         AC_HELP_STRING([--with-obd-buffer-size=[size]],
  58                 [set lctl ioctl maximum bytes (default=8192)]),
  59         [OBD_BUFFER_SIZE=$with_obd_buffer_size],
  60         [OBD_BUFFER_SIZE=8192])
  61 AC_MSG_RESULT([$OBD_BUFFER_SIZE bytes])
  62 AC_DEFINE_UNQUOTED(CONFIG_LUSTRE_OBD_MAX_IOCTL_BUFFER, $OBD_BUFFER_SIZE,
  63         [IOCTL Buffer Size])
  64 ]) # LC_CONFIG_OBD_BUFFER_SIZE
  65
  66 #
  67 # LC_GLIBC_SUPPORT_FHANDLES
  68 #
  69 AC_DEFUN([LC_GLIBC_SUPPORT_FHANDLES], [
  70 AC_CHECK_FUNCS([name_to_handle_at],
  71         [AC_DEFINE(HAVE_FHANDLE_GLIBC_SUPPORT, 1,
  72                 [file handle and related syscalls are supported])],
  73         [AC_MSG_WARN([file handle and related syscalls are not supported])])
  74 ]) # LC_GLIBC_SUPPORT_FHANDLES
  75
  76 #
  77 # LC_FUNC_DEV_SET_RDONLY
  78 #
  79 # check whether dev_set_rdonly is exported.  This is needed until we
  80 # have another mechanism to fence IO from the underlying device.
  81 #
  82 AC_DEFUN([LC_FUNC_DEV_SET_RDONLY], [
  83 LB_CHECK_EXPORT([dev_set_rdonly], [block/ll_rw_block.c block/blk-core.c],
  84         [AC_DEFINE(HAVE_DEV_SET_RDONLY, 1,
  85                 [kernel exports dev_set_rdonly])],
  86         [AC_MSG_WARN([kernel missing dev_set_rdonly patch for testing])])
  87 ]) # LC_FUNC_DEV_SET_RDONLY
  88
  89 #
  90 # LC_STACK_SIZE
  91 #
  92 # Ensure stack size big than 8k in Lustre server (all kernels)
  93 #
  94 AC_DEFUN([LC_STACK_SIZE], [
  95 LB_CHECK_COMPILE([if stack size big than 8k],
  96 stack_size_8k, [
  97         #include <linux/thread_info.h>
  98 ], [
  99         #if THREAD_SIZE < 8192
 100         #error "stack size < 8192"
 101         #endif
 102 ], [], [AC_MSG_ERROR([
 103
 104 Lustre requires that Linux is configured with at least a 8KB stack.
 105 ])])
 106 ]) # LC_STACK_SIZE
 107
 108 #
 109 # LC_MDS_MAX_THREADS
 110 #
 111 # Allow the user to set the MDS thread upper limit
 112 #
 113 AC_DEFUN([LC_MDS_MAX_THREADS], [
 114 AC_MSG_CHECKING([for maximum number of MDS threads])
 115 AC_ARG_WITH([mds_max_threads],
 116         AC_HELP_STRING([--with-mds-max-threads=count],
 117                 [maximum threads available on the MDS: (default=512)]),
 118         [AC_DEFINE_UNQUOTED(MDS_MAX_THREADS, $with_mds_max_threads,
 119                 [maximum number of MDS threads])])
 120 AC_MSG_RESULT([$with_mds_max_threads])
 121 ]) # LC_MDS_MAX_THREADS
 122
 123 #
 124 # LC_CONFIG_PINGER
 125 #
 126 # the pinger is temporary, until we have the recovery node in place
 127 #
 128 AC_DEFUN([LC_CONFIG_PINGER], [
 129 AC_MSG_CHECKING([whether to enable Lustre pinger support])
 130 AC_ARG_ENABLE([pinger],
 131         AC_HELP_STRING([--disable-pinger],
 132                 [disable recovery pinger support]),
 133         [], [enable_pinger="yes"])
 134 AC_MSG_RESULT([$enable_pinger])
 135 AS_IF([test "x$enable_pinger" != xno],
 136         [AC_DEFINE(ENABLE_PINGER, 1,[Use the Pinger])])
 137 ]) # LC_CONFIG_PINGER
 138
 139 #
 140 # LC_CONFIG_CHECKSUM
 141 #
 142 # do checksum of bulk data between client and OST
 143 #
 144 AC_DEFUN([LC_CONFIG_CHECKSUM], [
 145 AC_MSG_CHECKING([whether to enable data checksum support])
 146 AC_ARG_ENABLE([checksum],
 147         AC_HELP_STRING([--disable-checksum],
 148                 [disable data checksum support]),
 149         [], [enable_checksum="yes"])
 150 AC_MSG_RESULT([$enable_checksum])
 151 AS_IF([test "x$enable_checksum" != xno],
 152         [AC_DEFINE(ENABLE_CHECKSUM, 1, [do data checksums])])
 153 ]) # LC_CONFIG_CHECKSUM
 154
 155 #
 156 # LC_CONFIG_HEALTH_CHECK_WRITE
 157 #
 158 # Turn off the actual write to the disk
 159 #
 160 AC_DEFUN([LC_CONFIG_HEALTH_CHECK_WRITE], [
 161 AC_MSG_CHECKING([whether to enable a write with the health check])
 162 AC_ARG_ENABLE([health_write],
 163         AC_HELP_STRING([--enable-health_write],
 164                 [enable disk writes when doing health check]),
 165         [], [enable_health_write="no"])
 166 AC_MSG_RESULT([$enable_health_write])
 167 AS_IF([test "x$enable_health_write" != xno],
 168         [AC_DEFINE(USE_HEALTH_CHECK_WRITE, 1, [Write when Checking Health])])
 169 ]) # LC_CONFIG_HEALTH_CHECK_WRITE
 170
 171 #
 172 # LC_CONFIG_LRU_RESIZE
 173 #
 174 AC_DEFUN([LC_CONFIG_LRU_RESIZE], [
 175 AC_MSG_CHECKING([whether to enable lru self-adjusting])
 176 AC_ARG_ENABLE([lru_resize],
 177         AC_HELP_STRING([--enable-lru-resize],
 178                 [enable lru resize support]),
 179         [], [enable_lru_resize="yes"])
 180 AC_MSG_RESULT([$enable_lru_resize])
 181 AS_IF([test "x$enable_lru_resize" != xno],
 182         [AC_DEFINE(HAVE_LRU_RESIZE_SUPPORT, 1, [Enable lru resize support])])
 183 ]) # LC_CONFIG_LRU_RESIZE
 184
 185 #
 186 # LC_QUOTA_CONFIG
 187 #
 188 # Quota support. The kernel must support CONFIG_QUOTA.
 189 #
 190 AC_DEFUN([LC_QUOTA_CONFIG], [
 191 LB_CHECK_CONFIG_IM([QUOTA], [],
 192         [AC_MSG_ERROR([
 193
 194 Lustre quota requires that CONFIG_QUOTA is enabled in your kernel.
 195 ])])
 196 ]) # LC_QUOTA_CONFIG
 197
 198 #
 199 # LC_EXPORT_TRUNCATE_COMPLETE_PAGE
 200 #
 201 # truncate_complete_page() has never been exported from an upstream kernel
 202 # remove_from_page_cache() was exported between 2.6.35 and 2.6.38
 203 # delete_from_page_cache() is exported from 2.6.39
 204 #
 205 AC_DEFUN([LC_EXPORT_TRUNCATE_COMPLETE_PAGE], [
 206 LB_CHECK_EXPORT([truncate_complete_page], [mm/truncate.c],
 207         [AC_DEFINE(HAVE_TRUNCATE_COMPLETE_PAGE, 1,
 208                 [kernel export truncate_complete_page])])
 209 LB_CHECK_EXPORT([remove_from_page_cache], [mm/filemap.c],
 210         [AC_DEFINE(HAVE_REMOVE_FROM_PAGE_CACHE, 1,
 211                 [kernel export remove_from_page_cache])])
 212 LB_CHECK_EXPORT([delete_from_page_cache], [mm/filemap.c],
 213         [AC_DEFINE(HAVE_DELETE_FROM_PAGE_CACHE, 1,
 214                 [kernel export delete_from_page_cache])])
 215 ]) # LC_EXPORT_TRUNCATE_COMPLETE_PAGE
 216
 217 #
 218 # LC_CONFIG_RMTCLIENT
 219 #
 220 dnl FIXME
 221 dnl the AES symbol usually tied with arch, e.g. CRYPTO_AES_586
 222 dnl FIXME
 223 AC_DEFUN([LC_CONFIG_RMTCLIENT], [
 224 LB_CHECK_CONFIG_IM([CRYPTO_AES], [],
 225         [AC_MSG_WARN([
 226
 227 Lustre remote client require that CONFIG_CRYPTO_AES is enabled in your kernel.
 228 ])])
 229 ]) # LC_CONFIG_RMTCLIENT
 230
 231 #
 232 # LC_CONFIG_GSS_KEYRING
 233 #
 234 # default 'auto', tests for dependencies, if found, enables;
 235 # only called if gss is enabled
 236 #
 237 AC_DEFUN([LC_CONFIG_GSS_KEYRING], [
 238 AC_MSG_CHECKING([whether to enable gss keyring backend])
 239 AC_ARG_ENABLE([gss_keyring],
 240         [AC_HELP_STRING([--disable-gss-keyring],
 241                 [disable gss keyring backend])],
 242         [], [enable_gss_keyring="auto"])
 243 AC_MSG_RESULT([$enable_gss_keyring])
 244 AS_IF([test "x$enable_gss_keyring" != xno], [
 245         LB_CHECK_CONFIG_IM([KEYS], [], [
 246                 gss_keyring_conf_test="fail"
 247                 AC_MSG_WARN([
 248
 249 GSS keyring backend require that CONFIG_KEYS be enabled in your kernel.
 250 ])])
 251
 252         AC_CHECK_LIB([keyutils], [keyctl_search], [], [
 253                 gss_keyring_conf_test="fail"
 254                 AC_MSG_WARN([
 255
 256 libkeyutils is not found, which is required by gss keyring backend
 257 ])])
 258
 259         AS_IF([test "x$gss_keyring_conf_test" != xfail], [
 260                 AC_DEFINE([HAVE_GSS_KEYRING], [1],
 261                         [Define this if you enable gss keyring backend])
 262                 enable_gss_keyring="yes"
 263         ], [
 264                 AS_IF([test "x$enable_gss_keyring" = xyes], [
 265                         AC_MSG_ERROR([
 266
 267 Cannot enable gss_keyring. See above for details.
 268 ])
 269                 ], [
 270                         AC_MSG_WARN([
 271
 272 Cannot enable gss keyring. See above for details.
 273 ])
 274                 ])
 275         ])
 276 ])
 277 ]) # LC_CONFIG_GSS_KEYRING
 278
 279 #
 280 # LC_CONFIG_SUNRPC
 281 #
 282 AC_DEFUN([LC_CONFIG_SUNRPC], [
 283 LB_CHECK_CONFIG_IM([SUNRPC], [], [
 284         AS_IF([test "x$sunrpc_required" = xyes], [
 285                 AC_MSG_ERROR([
 286
 287 kernel SUNRPC support is required by using GSS.
 288 ])
 289         ])])
 290 ]) # LC_CONFIG_SUNRPC
 291
 292 #
 293 # LC_CONFIG_GSS (default 'auto' (tests for dependencies, if found, enables))
 294 #
 295 # Build gss and related tools of Lustre. Currently both kernel and user space
 296 # parts are depend on linux platform.
 297 #
 298 AC_DEFUN([LC_CONFIG_GSS], [
 299 AC_MSG_CHECKING([whether to enable gss/krb5 support])
 300 AC_ARG_ENABLE([gss],
 301         [AC_HELP_STRING([--enable-gss], [enable gss/krb5 support])],
 302         [], [enable_gss="auto"])
 303 AC_MSG_RESULT([$enable_gss])
 304
 305 AS_IF([test "x$enable_gss" != xno], [
 306         LC_CONFIG_GSS_KEYRING
 307         sunrpc_required=$enable_gss
 308         LC_CONFIG_SUNRPC
 309         sunrpc_required="no"
 310
 311         LB_CHECK_CONFIG_IM([CRYPTO_MD5], [],
 312                 [AC_MSG_WARN([kernel MD5 support is recommended by using GSS.])])
 313         LB_CHECK_CONFIG_IM([CRYPTO_SHA1], [],
 314                 [AC_MSG_WARN([kernel SHA1 support is recommended by using GSS.])])
 315         LB_CHECK_CONFIG_IM([CRYPTO_SHA256], [],
 316                 [AC_MSG_WARN([kernel SHA256 support is recommended by using GSS.])])
 317         LB_CHECK_CONFIG_IM([CRYPTO_SHA512], [],
 318                 [AC_MSG_WARN([kernel SHA512 support is recommended by using GSS.])])
 319
 320         require_krb5=$enable_gss
 321         AC_KERBEROS_V5
 322         require_krb5="no"
 323
 324         AS_IF([test -n "$KRBDIR"], [
 325                 AC_CHECK_LIB([gssapi], [gss_export_lucid_sec_context], [
 326                         GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssapi"
 327                         gss_conf_test="success"
 328                 ], [
 329                         AC_CHECK_LIB([gssglue], [gss_export_lucid_sec_context], [
 330                                 GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssglue"
 331                                 gss_conf_test="success"
 332                         ], [
 333                                 AS_IF([test "x$enable_gss" = xyes], [
 334                                         AC_MSG_ERROR([
 335
 336 libgssapi or libgssglue is not found, which is required by GSS.
 337 ])
 338                                 ], [
 339                                         AC_MSG_WARN([
 340
 341 libgssapi or libgssglue is not found, which is required by GSS.
 342 ])
 343                                 ])
 344                         ])
 345                 ])
 346                 AC_SUBST(GSSAPI_LIBS)
 347         ])
 348
 349         AS_IF([test "x$gss_conf_test" = xsuccess], [
 350                 AC_DEFINE([HAVE_GSS], [1], [Define this is if you enable gss])
 351                 enable_gss="yes"
 352         ])
 353 ])
 354 ]) # LC_CONFIG_GSS
 355
 356 #
 357 # LC_INODE_PERMISION_2ARGS
 358 #
 359 # up to v2.6.27 had a 3 arg version (inode, mask, nameidata)
 360 # v2.6.27->v2.6.37 had a 2 arg version (inode, mask)
 361 # v2.6.37->v3.0 had a 3 arg version (inode, mask, nameidata)
 362 # v3.1 onward have a 2 arg version (inode, mask)
 363 #
 364 AC_DEFUN([LC_INODE_PERMISION_2ARGS], [
 365 LB_CHECK_COMPILE([if 'inode_operations->permission' has two args],
 366 inode_ops_permission_2args, [
 367         #include <linux/fs.h>
 368 ],[
 369         struct inode *inode __attribute__ ((unused));
 370
 371         inode = NULL;
 372         inode->i_op->permission(NULL, 0);
 373 ],[
 374         AC_DEFINE(HAVE_INODE_PERMISION_2ARGS, 1,
 375                 [inode_operations->permission has two args])
 376 ])
 377 ]) # LC_INODE_PERMISION_2ARGS
 378
 379 #
 380 # LC_BLK_QUEUE_MAX_SEGMENTS
 381 #
 382 # 2.6.32 replaces 2 functions blk_queue_max_phys_segments and blk_queue_max_hw_segments by blk_queue_max_segments
 383 #
 384 AC_DEFUN([LC_BLK_QUEUE_MAX_SEGMENTS], [
 385 LB_CHECK_COMPILE([if 'blk_queue_max_segments' is defined],
 386 blk_queue_max_segments, [
 387         #include <linux/blkdev.h>
 388 ],[
 389         blk_queue_max_segments(NULL, 0);
 390 ],[
 391         AC_DEFINE(HAVE_BLK_QUEUE_MAX_SEGMENTS, 1,
 392                 [blk_queue_max_segments is defined])
 393 ])
 394 ]) # LC_BLK_QUEUE_MAX_SEGMENTS
 395
 396 #
 397 # LC_HAVE_DQUOT_FS_DISK_QUOTA
 398 #
 399 # 2.6.34 has quotactl_ops->[sg]et_dqblk that take struct fs_disk_quota
 400 #
 401 AC_DEFUN([LC_HAVE_DQUOT_FS_DISK_QUOTA], [
 402 tmp_flags="$EXTRA_KCFLAGS"
 403 EXTRA_KCFLAGS="-Werror"
 404 LB_CHECK_COMPILE([if 'quotactl_ops.set_dqblk' takes struct fs_disk_quota],
 405 fs_disk_quota, [
 406         #include <linux/fs.h>
 407         #include <linux/quota.h>
 408 ],[
 409         ((struct quotactl_ops *)0)->set_dqblk(NULL, 0, 0, (struct fs_disk_quota*)0);
 410 ],[
 411         AC_DEFINE(HAVE_DQUOT_FS_DISK_QUOTA, 1,
 412                 [quotactl_ops.set_dqblk takes struct fs_disk_quota])
 413 ],[
 414         LB_CHECK_COMPILE([if 'quotactl_ops.set_dqblk' takes struct kqid & fs_disk_quota],
 415         kqid_fs_disk_quota, [
 416                 #include <linux/fs.h>
 417                 #include <linux/quota.h>
 418         ],[
 419                 ((struct quotactl_ops *)0)->set_dqblk((struct super_block*)0, *((struct kqid*)0), (struct fs_disk_quota*)0);
 420         ],[
 421                 AC_DEFINE(HAVE_DQUOT_FS_DISK_QUOTA, 1,
 422                         [quotactl_ops.set_dqblk takes struct fs_disk_quota])
 423                 AC_DEFINE(HAVE_DQUOT_KQID, 1,
 424                         [quotactl_ops.set_dqblk takes struct kqid])
 425         ])
 426 ])
 427 EXTRA_KCFLAGS="$tmp_flags"
 428 ]) # LC_HAVE_DQUOT_FS_DISK_QUOTA
 429
 430 #
 431 # LC_HAVE_DQUOT_SUSPEND
 432 #
 433 # 2.6.34 has renamed dquot options to dquot_*, check for dquot_suspend
 434 #
 435 AC_DEFUN([LC_HAVE_DQUOT_SUSPEND], [
 436 LB_CHECK_COMPILE([if 'dquot_suspend' is defined],
 437 dquot_suspend, [
 438         #include <linux/quotaops.h>
 439 ],[
 440         dquot_suspend(NULL, -1);
 441 ],[
 442         AC_DEFINE(HAVE_DQUOT_SUSPEND, 1, [dquot_suspend is defined])
 443 ])
 444 ]) # LC_HAVE_DQUOT_SUSPEND
 445
 446 #
 447 # LC_QUOTA64
 448 #
 449 # Check if kernel has been patched for 64-bit quota limits support.
 450 # The upstream version of this patch in RHEL6 2.6.32 kernels introduces
 451 # the constant QFMT_VFS_V1 in include/linux/quota.h, so we can check for
 452 # that in the absence of quotaio_v1.h in the kernel headers.
 453 #
 454 AC_DEFUN([LC_QUOTA64], [
 455 tmp_flags="$EXTRA_KCFLAGS"
 456 EXTRA_KCFLAGS="-I$LINUX/fs"
 457 LB_CHECK_COMPILE([if kernel has 64-bit quota limits support],
 458 quota64, [
 459         #include <linux/kernel.h>
 460         #include <linux/fs.h>
 461         #if defined(HAVE_FS_QUOTA_QUOTAIO_H)
 462         #include <quota/quotaio_v2.h>
 463         struct v2r1_disk_dqblk dqblk_r1;
 464         #else
 465         #include <linux/quota.h>
 466         int ver = QFMT_VFS_V1;
 467         #endif
 468 ], [], [
 469         AC_DEFINE(HAVE_QUOTA64, 1, [have quota64])
 470 ],[
 471         LB_CHECK_FILE([$LINUX/include/linux/lustre_version.h],
 472                 [AC_MSG_ERROR([You have got no 64-bit kernel quota support.])])
 473 ])
 474 EXTRA_KCFLAGS=$tmp_flags
 475 ]) # LC_QUOTA64
 476
 477 #
 478 # LC_HAVE_ADD_WAIT_QUEUE_EXCLUSIVE
 479 #
 480 # 2.6.34 adds __add_wait_queue_exclusive
 481 #
 482 AC_DEFUN([LC_HAVE_ADD_WAIT_QUEUE_EXCLUSIVE], [
 483 LB_CHECK_COMPILE([if '__add_wait_queue_exclusive' exists],
 484 __add_wait_queue_exclusive, [
 485         #include <linux/wait.h>
 486 ],[
 487         wait_queue_head_t queue;
 488         wait_queue_t      wait;
 489         __add_wait_queue_exclusive(&queue, &wait);
 490 ],[
 491         AC_DEFINE(HAVE___ADD_WAIT_QUEUE_EXCLUSIVE, 1,
 492                   [__add_wait_queue_exclusive exists])
 493 ])
 494 ]) # LC_HAVE_ADD_WAIT_QUEUE_EXCLUSIVE
 495
 496 #
 497 # LC_FS_STRUCT_RWLOCK
 498 #
 499 # 2.6.36 fs_struct.lock use spinlock instead of rwlock.
 500 #
 501 AC_DEFUN([LC_FS_STRUCT_RWLOCK], [
 502 LB_CHECK_COMPILE([if 'fs_struct.lock' use rwlock],
 503 fs_struct_rwlock, [
 504         #include <asm/atomic.h>
 505         #include <linux/spinlock.h>
 506         #include <linux/fs_struct.h>
 507 ],[
 508         ((struct fs_struct *)0)->lock = (rwlock_t){ 0 };
 509 ],[
 510         AC_DEFINE(HAVE_FS_STRUCT_RWLOCK, 1, [fs_struct.lock use rwlock])
 511 ])
 512 ]) # LC_FS_STRUCT_RWLOCK
 513
 514 #
 515 # LC_SBOPS_EVICT_INODE
 516 #
 517 # 2.6.36 super_operations add evict_inode method. it hybird of
 518 # delete_inode & clear_inode.
 519 #
 520 AC_DEFUN([LC_SBOPS_EVICT_INODE], [
 521 LB_CHECK_COMPILE([if 'super_operations.evict_inode' exist],
 522 super_ops_evict_inode, [
 523         #include <linux/fs.h>
 524 ],[
 525         ((struct super_operations *)0)->evict_inode(NULL);
 526 ],[
 527         AC_DEFINE(HAVE_SBOPS_EVICT_INODE, 1,
 528                 [super_operations.evict_inode() is exist in kernel])
 529 ])
 530 ]) # LC_SBOPS_EVICT_INODE
 531
 532 #
 533 # LC_FILE_FSYNC
 534 #
 535 # 2.6.35 file_operations.fsync taken 2 arguments.
 536 # 3.0.0 file_operations.fsync takes 4 arguments.
 537 #
 538 AC_DEFUN([LC_FILE_FSYNC], [
 539 LB_CHECK_COMPILE([if 'file_operations.fsync' takes 4 arguments],
 540 file_ops_fsync_4args, [
 541         #include <linux/fs.h>
 542 ],[
 543         ((struct file_operations *)0)->fsync(NULL, 0, 0, 0);
 544 ],[
 545         AC_DEFINE(HAVE_FILE_FSYNC_4ARGS, 1,
 546                 [file_operations.fsync takes 4 arguments])
 547 ],[
 548         LB_CHECK_COMPILE([if 'file_operations.fsync' takes 2 arguments],
 549         file_ops_fsync_2args, [
 550                 #include <linux/fs.h>
 551         ],[
 552                 ((struct file_operations *)0)->fsync(NULL, 0);
 553         ],[
 554                 AC_DEFINE(HAVE_FILE_FSYNC_2ARGS, 1,
 555                         [file_operations.fsync takes 2 arguments])
 556         ])
 557 ])
 558 ]) # LC_FILE_FSYNC
 559
 560 #
 561 # LC_KERNEL_LOCKED
 562 #
 563 # 2.6.37 remove kernel_locked
 564 #
 565 AC_DEFUN([LC_KERNEL_LOCKED], [
 566 LB_CHECK_COMPILE([if 'kernel_locked' is defined],
 567 kernel_locked, [
 568         #include <linux/smp_lock.h>
 569 ],[
 570         kernel_locked();
 571 ],[
 572         AC_DEFINE(HAVE_KERNEL_LOCKED, 1, [kernel_locked is defined])
 573 ])
 574 ]) # LC_KERNEL_LOCKED
 575
 576 #
 577 # LC_D_COMPARE_7ARGS
 578 #
 579 # 2.6.38 dentry_operations.d_compare() taken 7 arguments.
 580 #
 581 AC_DEFUN([LC_D_COMPARE_7ARGS], [
 582 LB_CHECK_COMPILE([if 'dentry_operations.d_compare()' taken 7 arguments],
 583 dentry_ops_d_compare_7arg, [
 584         #include <linux/dcache.h>
 585 ],[
 586         ((struct dentry_operations*)0)->d_compare(NULL,NULL,NULL,NULL,0,NULL,NULL);
 587 ],[
 588         AC_DEFINE(HAVE_D_COMPARE_7ARGS, 1, [d_compare need 7 arguments])
 589 ])
 590 ]) # LC_D_COMPARE_7ARGS
 591
 592 #
 593 # LC_D_DELETE_CONST
 594 #
 595 # 2.6.38 dentry_operations.d_delete() defined 'const' for 1st parameter.
 596 #
 597 AC_DEFUN([LC_D_DELETE_CONST], [
 598 tmp_flags="$EXTRA_KCFLAGS"
 599 EXTRA_KCFLAGS="-Werror"
 600 LB_CHECK_COMPILE([if 'dentry_operations.d_delete()' has const declare on first parameter],
 601 dentry_ops_d_delete_1st_const, [
 602         #include <linux/dcache.h>
 603 ],[
 604         const struct dentry *d = NULL;
 605         ((struct dentry_operations*)0)->d_delete(d);
 606 ],[
 607         AC_DEFINE(HAVE_D_DELETE_CONST, const,
 608                 [d_delete first parameter declared const])
 609 ],[
 610         AC_DEFINE(HAVE_D_DELETE_CONST, [],
 611                 [d_delete first parameter declared is not const])
 612 ])
 613 EXTRA_KCFLAGS="$tmp_flags"
 614 ]) # LC_D_DELETE_CONST
 615
 616 #
 617 # LC_DCACHE_LOCK
 618 #
 619 # 2.6.38 dcache_lock removed. rcu-walk commited.
 620 #
 621 AC_DEFUN([LC_DCACHE_LOCK], [
 622 LB_CHECK_COMPILE([if 'dcache_lock' is exist],
 623 dcache_lock, [
 624         #include <linux/dcache.h>
 625 ],[
 626         spin_lock(&dcache_lock);
 627 ],[
 628         AC_DEFINE(HAVE_DCACHE_LOCK, 1,
 629                 [dcache_lock is exist])
 630 ])
 631 ]) # LC_DCACHE_LOCK
 632
 633 #
 634 # LC_INODE_I_RCU
 635 #
 636 # 2.6.38 inode.i_rcu added.
 637 #
 638 AC_DEFUN([LC_INODE_I_RCU], [
 639 LB_CHECK_COMPILE([if 'inode.i_rcu' exists],
 640 inode_i_rcu, [
 641         #include <linux/fs.h>
 642 ],[
 643         struct inode ino;
 644         struct rcu_head rcu = {};
 645         ino.i_rcu = rcu;
 646 ],[
 647         AC_DEFINE(HAVE_INODE_I_RCU, 1,
 648                 [inode.i_rcu exists])
 649 ])
 650 ]) # LC_INODE_I_RCU
 651
 652 #
 653 # LC_BLKDEV_GET_BY_DEV
 654 #
 655 # 2.6.38 export blkdev_get_by_dev
 656 #
 657 AC_DEFUN([LC_BLKDEV_GET_BY_DEV], [
 658 LB_CHECK_EXPORT([blkdev_get_by_dev], [fs/block_dev.c],
 659         [AC_DEFINE(HAVE_BLKDEV_GET_BY_DEV, 1,
 660                 [blkdev_get_by_dev is exported by the kernel])])
 661 ]) # LC_BLKDEV_GET_BY_DEV
 662
 663 #
 664 # LC_EXPORT_SIMPLE_SETATTR
 665 #
 666 # 2.6.38 export simple_setattr
 667 #
 668 AC_DEFUN([LC_EXPORT_SIMPLE_SETATTR], [
 669 LB_CHECK_EXPORT([simple_setattr], [fs/libfs.c],
 670         [AC_DEFINE(HAVE_SIMPLE_SETATTR, 1,
 671                 [simple_setattr is exported by the kernel])])
 672 ]) # LC_EXPORT_SIMPLE_SETATTR
 673
 674 #
 675 # LC_IOP_TRUNCATE
 676 #
 677 # truncate callback removed since 2.6.39
 678 #
 679 AC_DEFUN([LC_IOP_TRUNCATE], [
 680 LB_CHECK_COMPILE([if 'inode_operations' has '.truncate' member function],
 681 inode_ops_truncate, [
 682         #include <linux/fs.h>
 683 ],[
 684         ((struct inode_operations *)0)->truncate(NULL);
 685 ],[
 686         AC_DEFINE(HAVE_INODEOPS_TRUNCATE, 1,
 687                 [inode_operations has .truncate member function])
 688 ])
 689 ]) # LC_IOP_TRUNCATE
 690
 691 #
 692 # LC_REQUEST_QUEUE_UNPLUG_FN
 693 #
 694 # 2.6.39 remove unplug_fn from request_queue.
 695 #
 696 AC_DEFUN([LC_REQUEST_QUEUE_UNPLUG_FN], [
 697 LB_CHECK_COMPILE([if 'request_queue' has 'unplug_fn' field],
 698 request_queue_unplug_fn, [
 699         #include <linux/blkdev.h>
 700 ],[
 701         do {} while(sizeof(((struct request_queue *)0)->unplug_fn));
 702 ],[
 703         AC_DEFINE(HAVE_REQUEST_QUEUE_UNPLUG_FN, 1,
 704                 [request_queue has unplug_fn field])
 705 ])
 706 ]) # LC_REQUEST_QUEUE_UNPLUG_FN
 707
 708 #
 709 # LC_HAVE_FSTYPE_MOUNT
 710 #
 711 # 2.6.39 replace get_sb with mount in struct file_system_type
 712 #
 713 AC_DEFUN([LC_HAVE_FSTYPE_MOUNT], [
 714 LB_CHECK_COMPILE([if 'file_system_type' has 'mount' field],
 715 file_system_type_mount, [
 716         #include <linux/fs.h>
 717 ],[
 718         struct file_system_type fst;
 719         void *i = (void *) fst.mount;
 720 ],[
 721         AC_DEFINE(HAVE_FSTYPE_MOUNT, 1,
 722                 [struct file_system_type has mount field])
 723 ])
 724 ]) # LC_HAVE_FSTYPE_MOUNT
 725
 726 #
 727 # LC_HAVE_FHANDLE_SYSCALLS
 728 #
 729 # 2.6.39 The open_by_handle_at() and name_to_handle_at() system calls were
 730 # added to Linux kernel 2.6.39.
 731 # Check if client supports these functions
 732 #
 733 AC_DEFUN([LC_HAVE_FHANDLE_SYSCALLS], [
 734 LB_CHECK_CONFIG_IM([FHANDLE],[
 735         AC_DEFINE(HAVE_FHANDLE_SYSCALLS, 1,
 736                 [kernel supports fhandles and related syscalls])
 737         ])
 738 ]) # LC_HAVE_FHANDLE_SYSCALLS
 739
 740 #
 741 # LC_HAVE_INODE_OWNER_OR_CAPABLE
 742 #
 743 # 2.6.39 renames is_owner_or_cap to inode_owner_or_capable
 744 #
 745 AC_DEFUN([LC_HAVE_INODE_OWNER_OR_CAPABLE], [
 746 LB_CHECK_COMPILE([if 'inode_owner_or_capable' exist],
 747 inode_owner_or_capable, [
 748         #include <linux/fs.h>
 749 ],[
 750         inode_owner_or_capable(NULL);
 751 ],[
 752         AC_DEFINE(HAVE_INODE_OWNER_OR_CAPABLE, 1,
 753                 [inode_owner_or_capable exist])
 754 ])
 755 ]) # LC_HAVE_INODE_OWNER_OR_CAPABLE
 756
 757 #
 758 # LC_DIRTY_INODE_WITH_FLAG
 759 #
 760 # 3.0 dirty_inode() has a flag parameter
 761 # see kernel commit aa38572954ade525817fe88c54faebf85e5a61c0
 762 #
 763 AC_DEFUN([LC_DIRTY_INODE_WITH_FLAG], [
 764 LB_CHECK_COMPILE([if 'dirty_inode' super_operation takes flag],
 765 dirty_inode_super_operation_flag, [
 766         #include <linux/fs.h>
 767 ],[
 768         struct inode *inode;
 769         inode->i_sb->s_op->dirty_inode(NULL, 0);
 770 ],[
 771         AC_DEFINE(HAVE_DIRTY_INODE_HAS_FLAG, 1,
 772                 [dirty_inode super_operation takes flag])
 773 ])
 774 ]) # LC_DIRTY_INODE_WITH_FLAG
 775
 776 #
 777 # LC_GENERIC_PERMISSION
 778 #
 779 # 2.6.38 generic_permission taken 4 parameters.
 780 # in fact, it means rcu-walk aware permission bring.
 781 #
 782 # 3.1 generic_permission taken 2 parameters.
 783 # see kernel commit 2830ba7f34ebb27c4e5b8b6ef408cd6d74860890
 784 #
 785 AC_DEFUN([LC_GENERIC_PERMISSION], [
 786 LB_CHECK_COMPILE([if 'generic_permission' take 2 arguments],
 787 generic_permission_2args, [
 788         #include <linux/fs.h>
 789 ],[
 790         generic_permission(NULL, 0);
 791 ],[
 792         AC_DEFINE(HAVE_GENERIC_PERMISSION_2ARGS, 1,
 793                 [generic_permission taken 2 arguments])
 794 ],[
 795         LB_CHECK_COMPILE([if 'generic_permission' take 4 arguments],
 796         generic_permission_4args, [
 797                 #include <linux/fs.h>
 798         ],[
 799                 generic_permission(NULL, 0, 0, NULL);
 800         ],[
 801                 AC_DEFINE(HAVE_GENERIC_PERMISSION_4ARGS, 1,
 802                         [generic_permission taken 4 arguments])
 803         ])
 804 ])
 805 ]) # LC_GENERIC_PERMISSION
 806
 807 #
 808 # LC_LM_XXX_LOCK_MANAGER_OPS
 809 #
 810 # 3.1 renames lock-manager ops(lock_manager_operations) from fl_xxx to lm_xxx
 811 # see kernel commit 8fb47a4fbf858a164e973b8ea8ef5e83e61f2e50
 812 #
 813 AC_DEFUN([LC_LM_XXX_LOCK_MANAGER_OPS], [
 814 LB_CHECK_COMPILE([if 'lock-manager' ops renamed to 'lm_xxx'],
 815 lock_manager_ops_lm_xxx, [
 816         #include <linux/fs.h>
 817 ],[
 818         struct lock_manager_operations lm_ops;
 819         lm_ops.lm_compare_owner = NULL;
 820 ],[
 821         AC_DEFINE(HAVE_LM_XXX_LOCK_MANAGER_OPS, 1,
 822                 [lock-manager ops renamed to lm_xxx])
 823 ])
 824 ]) # LC_LM_XXX_LOCK_MANAGER_OPS
 825
 826 #
 827 # LC_INODE_DIO_WAIT
 828 #
 829 # 3.1 kills inode->i_alloc_sem, use i_dio_count and inode_dio_wait
 830 #     instead.
 831 # see kernel commit bd5fe6c5eb9c548d7f07fe8f89a150bb6705e8e3
 832 #
 833 AC_DEFUN([LC_INODE_DIO_WAIT], [
 834 LB_CHECK_COMPILE([if 'inode->i_alloc_sem' is killed and use inode_dio_wait],
 835 inode_dio_wait, [
 836         #include <linux/fs.h>
 837 ],[
 838         inode_dio_wait((struct inode *)0);
 839 ],[
 840         AC_DEFINE(HAVE_INODE_DIO_WAIT, 1,
 841                 [inode->i_alloc_sem is killed and use inode_dio_wait])
 842 ])
 843 ]) # LC_INODE_DIO_WAIT
 844
 845 #
 846 # LC_IOP_GET_ACL
 847 #
 848 # 3.1 adds get_acl method to inode_operations to read ACL from disk.
 849 # see kernel commit 4e34e719e457f2e031297175410fc0bd4016a085
 850 #
 851 AC_DEFUN([LC_IOP_GET_ACL], [
 852 LB_CHECK_COMPILE([if 'inode_operations' has '.get_acl' member function],
 853 inode_ops_get_acl, [
 854         #include <linux/fs.h>
 855 ],[
 856         struct inode_operations iop;
 857         iop.get_acl = NULL;
 858 ],[
 859         AC_DEFINE(HAVE_IOP_GET_ACL, 1,
 860                 [inode_operations has .get_acl member function])
 861 ])
 862 ]) # LC_IOP_GET_ACL
 863
 864 #
 865 # LC_FILE_LLSEEK_SIZE
 866 #
 867 # 3.1 introduced generic_file_llseek_size()
 868 #
 869 AC_DEFUN([LC_FILE_LLSEEK_SIZE], [
 870 LB_CHECK_EXPORT([generic_file_llseek_size], [fs/read_write.c],
 871         [AC_DEFINE(HAVE_FILE_LLSEEK_SIZE, 1,
 872                 [generic_file_llseek_size is exported by the kernel])])
 873 ]) # LC_FILE_LLSEEK_SIZE
 874
 875 #
 876 # LC_RADIX_EXCEPTION_ENTRY
 877 # 3.1 adds radix_tree_exception_entry.
 878 #
 879 AC_DEFUN([LC_RADIX_EXCEPTION_ENTRY], [
 880 LB_CHECK_COMPILE([radix_tree_exceptional_entry exist],
 881 radix_tree_exceptional_entry, [
 882         #include <linux/radix-tree.h>
 883 ],[
 884         radix_tree_exceptional_entry(NULL);
 885 ],[
 886         AC_DEFINE(HAVE_RADIX_EXCEPTION_ENTRY, 1,
 887                 [radix_tree_exceptional_entry exist])
 888 ])
 889 ]) # LC_RADIX_EXCEPTION_ENTRY
 890
 891 #
 892 # LC_HAVE_VOID_MAKE_REQUEST_FN
 893 #
 894 # 3.2 request_queue.make_request_fn defined as function returns with void
 895 # see kernel commit 5a7bbad27a410350e64a2d7f5ec18fc73836c14f
 896 #
 897 AC_DEFUN([LC_HAVE_VOID_MAKE_REQUEST_FN], [
 898 LB_CHECK_COMPILE([if 'request_queue.make_request_fn' returns void but not int],
 899 make_request_fn_void, [
 900         #include <linux/blkdev.h>
 901 ],[
 902         int ret;
 903         make_request_fn *mrf;
 904         ret = mrf(NULL, NULL);
 905 ],[],[
 906         AC_DEFINE(HAVE_VOID_MAKE_REQUEST_FN, 1,
 907                 [request_queue.make_request_fn returns void but not int])
 908 ])
 909 ]) # LC_HAVE_VOID_MAKE_REQUEST_FN
 910
 911 #
 912 # LC_HAVE_PROTECT_I_NLINK
 913 #
 914 # 3.2 protects inode->i_nlink from direct modification
 915 # see kernel commit a78ef704a8dd430225955f0709b22d4a6ba21deb
 916 # at the same time adds set_nlink(), so checks set_nlink() for it.
 917 #
 918 AC_DEFUN([LC_HAVE_PROTECT_I_NLINK], [
 919 LB_CHECK_COMPILE([if 'inode->i_nlink' is protected from direct modification],
 920 inode_i_nlink_protected, [
 921         #include <linux/fs.h>
 922 ],[
 923         struct inode i;
 924         set_nlink(&i, 1);
 925 ],[
 926         AC_DEFINE(HAVE_PROTECT_I_NLINK, 1,
 927                 [inode->i_nlink is protected from direct modification])
 928 ])
 929 ]) # LC_HAVE_PROTECT_I_NLINK
 930
 931 #
 932 # 2.6.39 security_inode_init_security takes a 'struct qstr' parameter
 933 #
 934 # 3.2 security_inode_init_security takes a callback to set xattrs
 935 #
 936 AC_DEFUN([LC_HAVE_SECURITY_IINITSEC], [
 937 LB_CHECK_COMPILE([if security_inode_init_security takes a callback],
 938 security_inode_init_security_callback, [
 939         #include <linux/security.h>
 940 ],[
 941         security_inode_init_security(NULL, NULL, NULL, (const initxattrs)NULL, NULL);
 942 ],[
 943         AC_DEFINE(HAVE_SECURITY_IINITSEC_CALLBACK, 1,
 944                   [security_inode_init_security takes a callback to set xattrs])
 945 ],[
 946         LB_CHECK_COMPILE([if security_inode_init_security takes a 'struct qstr' parameter],
 947         security_inode_init_security_qstr, [
 948                 #include <linux/security.h>
 949         ],[
 950                 security_inode_init_security(NULL, NULL, (struct qstr *)NULL, NULL, NULL, NULL);
 951         ],[
 952                 AC_DEFINE(HAVE_SECURITY_IINITSEC_QSTR, 1,
 953                           [security_inode_init_security takes a 'struct qstr' parameter])
 954         ])
 955 ])
 956 ]) # LC_HAVE_SECURITY_IINITSEC
 957
 958 #
 959 # LC_HAVE_MIGRATE_HEADER
 960 #
 961 # 3.3 introduces migrate_mode.h and migratepage has 4 args
 962 #
 963 AC_DEFUN([LC_HAVE_MIGRATE_HEADER], [
 964 LB_CHECK_FILE([$LINUX/include/linux/migrate.h], [
 965         AC_DEFINE(HAVE_MIGRATE_H, 1,
 966                 [kernel has include/linux/migrate.h])
 967 ],[
 968         LB_CHECK_FILE([$LINUX/include/linux/migrate_mode.h], [
 969                 AC_DEFINE(HAVE_MIGRATE_MODE_H, 1,
 970                         [kernel has include/linux/migrate_mode.h])
 971         ])
 972 ])
 973 ]) # LC_HAVE_MIGRATE_HEADER
 974
 975 #
 976 # LC_MIGRATEPAGE_4ARGS
 977 #
 978 AC_DEFUN([LC_MIGRATEPAGE_4ARGS], [
 979 LB_CHECK_COMPILE([if 'address_space_operations.migratepage' has 4 args],
 980 address_space_ops_migratepage_4args, [
 981         #include <linux/fs.h>
 982 #ifdef HAVE_MIGRATE_H
 983         #include <linux/migrate.h>
 984 #elif defined(HAVE_MIGRATE_MODE_H)
 985         #include <linux/migrate_mode.h>
 986 #endif
 987 ],[
 988         struct address_space_operations aops;
 989         aops.migratepage(NULL, NULL, NULL, MIGRATE_ASYNC);
 990 ],[
 991         AC_DEFINE(HAVE_MIGRATEPAGE_4ARGS, 1,
 992                 [address_space_operations.migratepage has 4 args])
 993 ])
 994 ]) # LC_MIGRATEPAGE_4ARGS
 995
 996 #
 997 # LC_SUPEROPS_USE_DENTRY
 998 #
 999 # 3.3 switchs super_operations to use dentry as parameter (but not vfsmount)
1000 # see kernel commit 34c80b1d93e6e20ca9dea0baf583a5b5510d92d4
1001 #
1002 AC_DEFUN([LC_SUPEROPS_USE_DENTRY], [
1003 tmp_flags="$EXTRA_KCFLAGS"
1004 EXTRA_KCFLAGS="-Werror"
1005 LB_CHECK_COMPILE([if 'super_operations' use 'dentry' as parameter],
1006 super_ops_dentry, [
1007         #include <linux/fs.h>
1008         int show_options(struct seq_file *seq, struct dentry *root) {
1009                 return 0;
1010         }
1011 ],[
1012         struct super_operations ops;
1013         ops.show_options = show_options;
1014 ],[
1015         AC_DEFINE(HAVE_SUPEROPS_USE_DENTRY, 1,
1016                 [super_operations use dentry as parameter])
1017 ])
1018 EXTRA_KCFLAGS="$tmp_flags"
1019 ]) # LC_SUPEROPS_USE_DENTRY
1020
1021 #
1022 # LC_INODEOPS_USE_UMODE_T
1023 #
1024 # 3.3 switchs inode_operations to use umode_t as parameter (but not int)
1025 # see kernel commit 1a67aafb5f72a436ca044293309fa7e6351d6a35
1026 #
1027 AC_DEFUN([LC_INODEOPS_USE_UMODE_T], [
1028 tmp_flags="$EXTRA_KCFLAGS"
1029 EXTRA_KCFLAGS="-Werror"
1030 LB_CHECK_COMPILE([if 'inode_operations' use 'umode_t' as parameter],
1031 inode_ops_umode_t, [
1032         #include <linux/fs.h>
1033         #include <linux/types.h>
1034         int my_mknod(struct inode *dir, struct dentry *dchild,
1035                      umode_t mode, dev_t dev)
1036         {
1037                 return 0;
1038         }
1039 ],[
1040         struct inode_operations ops;
1041         ops.mknod = my_mknod;
1042 ],[
1043         AC_DEFINE(HAVE_INODEOPS_USE_UMODE_T, 1,
1044                 [inode_operations use umode_t as parameter])
1045 ])
1046 EXTRA_KCFLAGS="$tmp_flags"
1047 ]) # LC_INODEOPS_USE_UMODE_T
1048
1049 #
1050 # LC_KMAP_ATOMIC_HAS_1ARG
1051 #
1052 # 3.4 kmap_atomic removes second argument
1053 # see kernel commit 1ec9c5ddc17aa398f05646abfcbaf315b544e62f
1054 #
1055 AC_DEFUN([LC_KMAP_ATOMIC_HAS_1ARG], [
1056 LB_CHECK_COMPILE([if 'kmap_atomic' has only 1 argument],
1057 kmap_atomic_1arg, [
1058         #include <linux/highmem.h>
1059 ],[
1060         kmap_atomic(NULL);
1061 ],[
1062         AC_DEFINE(HAVE_KMAP_ATOMIC_HAS_1ARG, 1,
1063                 [have kmap_atomic has only 1 argument])
1064 ])
1065 ]) # LC_KMAP_ATOMIC_HAS_1ARG
1066
1067 #
1068 # LC_HAVE_D_MAKE_ROOT
1069 #
1070 # 3.4 converts d_alloc_root to d_make_root
1071 # see kernel commit 32991ab305ace7017c62f8eecbe5eb36dc32e13b
1072 #
1073 AC_DEFUN([LC_HAVE_D_MAKE_ROOT], [
1074 LB_CHECK_COMPILE([if have 'd_make_root'],
1075 d_make_root, [
1076         #include <linux/fs.h>
1077 ],[
1078         d_make_root((struct inode *)NULL);
1079 ],[
1080         AC_DEFINE(HAVE_D_MAKE_ROOT, 1,
1081                 [have d_make_root])
1082 ])
1083 ]) # LC_HAVE_D_MAKE_ROOT
1084
1085 #
1086 # LC_HAVE_CACHE_REGISTER
1087 #
1088 # 3.4 cache_register/cache_unregister are removed
1089 # see kernel commit 2c5f846747526e2b83c5f1b8e69016be0e2e87c0
1090 # Note, since 2.6.37 cache_register_net/cache_unregister_net
1091 # are defined, but not exported.
1092 # 3.3 cache_register_net/cache_unregister_net are
1093 # exported and replacing cache_register/cache_unregister in 3.4
1094 #
1095 AC_DEFUN([LC_HAVE_CACHE_REGISTER], [
1096 LB_CHECK_COMPILE([if have 'cache_register'],
1097 cache_register, [
1098         #include <linux/sunrpc/cache.h>
1099 ],[
1100         cache_register(NULL);
1101 ],[
1102         AC_DEFINE(HAVE_CACHE_REGISTER, 1,
1103                 [have cache_register])
1104 ])
1105 ]) # LC_HAVE_CACHE_REGISTER
1106
1107 #
1108 # LC_HAVE_CLEAR_INODE
1109 #
1110 # 3.5 renames end_writeback() back to clear_inode()...
1111 # see kernel commit dbd5768f87ff6fb0a4fe09c4d7b6c4a24de99430
1112 #
1113 AC_DEFUN([LC_HAVE_CLEAR_INODE], [
1114 LB_CHECK_COMPILE([if have 'clear_inode'],
1115 clear_inode, [
1116         #include <linux/fs.h>
1117 ],[
1118         clear_inode((struct inode *)NULL);
1119 ],[
1120         AC_DEFINE(HAVE_CLEAR_INODE, 1,
1121                 [have clear_inode])
1122 ])
1123 ]) # LC_HAVE_CLEAR_INODE
1124
1125 #
1126 # LC_HAVE_ENCODE_FH_PARENT
1127 #
1128 # 3.5 encode_fh has parent inode passed in directly
1129 # see kernel commit b0b0382b
1130 #
1131 AC_DEFUN([LC_HAVE_ENCODE_FH_PARENT], [
1132 tmp_flags="$EXTRA_KCFLAGS"
1133 EXTRA_KCFLAGS="-Werror"
1134 LB_CHECK_COMPILE([if 'encode_fh' have parent inode as parameter],
1135 encode_fh_parent_inode, [
1136         #include <linux/exportfs.h>
1137         #include <linux/fs.h>
1138         #include <linux/types.h>
1139         int ll_encode_fh(struct inode *i, __u32 *a, int *b, struct inode *p)
1140         {
1141                 return 0;
1142         }
1143 ],[
1144         struct export_operations exp_op;
1145         exp_op.encode_fh = ll_encode_fh;
1146 ],[
1147         AC_DEFINE(HAVE_ENCODE_FH_PARENT, 1,
1148                 [have parent inode as parameter])
1149 ])
1150 EXTRA_KCFLAGS="$tmp_flags"
1151 ]) # LC_HAVE_ENCODE_FH_PARENT
1152
1153 #
1154 # LC_FILE_LLSEEK_SIZE_5ARG
1155 #
1156 # 3.5 has generic_file_llseek_size with 5 args
1157 #
1158 AC_DEFUN([LC_FILE_LLSEEK_SIZE_5ARG], [
1159 LB_CHECK_COMPILE([if Linux kernel has 'generic_file_llseek_size' with 5 args],
1160 generic_file_llseek_size_5args, [
1161         #include <linux/fs.h>
1162 ],[
1163         generic_file_llseek_size(NULL, 0, 0, 0, 0);
1164 ], [
1165         AC_DEFINE(HAVE_FILE_LLSEEK_SIZE_5ARGS, 1,
1166                 [kernel has generic_file_llseek_size with 5 args])
1167 ])
1168 ]) # LC_FILE_LLSEEK_SIZE_5ARG
1169
1170 #
1171 # LC_LLITE_DATA_IS_LIST
1172 #
1173 # 3.6 switch i_dentry/d_alias from list to hlist
1174 #
1175 # In the upstream kernels d_alias first changes
1176 # to a hlist and then in later version, 3.11, gets
1177 # moved to the union d_u. Due to some distros having
1178 # d_alias in the d_u union as a struct list, which
1179 # has never existed upstream stream, we can't test
1180 # if d_alias is a list or hlist directly. If ever
1181 # i_dentry and d_alias even up different combos then
1182 # the build will fail. In that case then we will need
1183 # to separate out the i_dentry and d_alias test below.
1184 #
1185 AC_DEFUN([LC_DATA_FOR_LLITE_IS_LIST], [
1186 tmp_flags="$EXTRA_KCFLAGS"
1187 EXTRA_KCFLAGS="-Werror"
1188 LB_CHECK_COMPILE([if 'i_dentry/d_alias' uses 'list'],
1189 i_dentry_d_alias_list, [
1190         #include <linux/fs.h>
1191 ],[
1192         struct inode inode;
1193         INIT_LIST_HEAD(&inode.i_dentry);
1194 ],[
1195         AC_DEFINE(DATA_FOR_LLITE_IS_LIST, 1,
1196                 [both i_dentry/d_alias uses list])
1197 ])
1198 EXTRA_KCFLAGS="$tmp_flags"
1199 ]) # LC_DATA_FOR_LLITE_IS_LIST
1200
1201 #
1202 # LC_DENTRY_OPEN_USE_PATH
1203 #
1204 # 3.6 dentry_open uses struct path as first argument
1205 # see kernel commit 765927b2
1206 #
1207 AC_DEFUN([LC_DENTRY_OPEN_USE_PATH], [
1208 tmp_flags="$EXTRA_KCFLAGS"
1209 EXTRA_KCFLAGS="-Werror"
1210 LB_CHECK_COMPILE([if 'dentry_open' uses 'struct path' as first argument],
1211 dentry_open_path, [
1212         #include <linux/fs.h>
1213         #include <linux/path.h>
1214 ],[
1215         struct path path;
1216         dentry_open(&path, 0, NULL);
1217 ],[
1218         AC_DEFINE(HAVE_DENTRY_OPEN_USE_PATH, 1,
1219                 [dentry_open uses struct path as first argument])
1220 ])
1221 EXTRA_KCFLAGS="$tmp_flags"
1222 ]) # LC_DENTRY_OPEN_USE_PATH
1223
1224 #
1225 # LC_HAVE_IOP_ATOMIC_OPEN
1226 #
1227 # 3.6 vfs adds iop->atomic_open
1228 #
1229 AC_DEFUN([LC_HAVE_IOP_ATOMIC_OPEN], [
1230 LB_CHECK_COMPILE([if 'iop' has 'atomic_open'],
1231 inode_ops_atomic_open, [
1232         #include <linux/fs.h>
1233 ],[
1234         struct inode_operations iop;
1235         iop.atomic_open = NULL;
1236 ],[
1237         AC_DEFINE(HAVE_IOP_ATOMIC_OPEN, 1,
1238                 [have iop atomic_open])
1239 ])
1240 ]) # LC_HAVE_IOP_ATOMIC_OPEN
1241
1242 #
1243 # LC_HAVE_POSIXACL_USER_NS
1244 #
1245 # 3.7 posix_acl_{to,from}_xattr take struct user_namespace
1246 #
1247 AC_DEFUN([LC_HAVE_POSIXACL_USER_NS], [
1248 LB_CHECK_COMPILE([if 'posix_acl_to_xattr' takes 'struct user_namespace'],
1249 posix_acl_to_xattr_user_namespace, [
1250         #include <linux/fs.h>
1251         #include <linux/posix_acl_xattr.h>
1252 ],[
1253         posix_acl_to_xattr((struct user_namespace *)NULL, NULL, NULL, 0);
1254 ],[
1255         AC_DEFINE(HAVE_POSIXACL_USER_NS, 1,
1256                 [posix_acl_to_xattr takes struct user_namespace])
1257 ])
1258 ]) # LC_HAVE_POSIXACL_USER_NS
1259
1260 #
1261 # LC_HAVE_FILE_F_INODE
1262 #
1263 # 3.8 struct file has new member f_inode
1264 #
1265 AC_DEFUN([LC_HAVE_FILE_F_INODE], [
1266 LB_CHECK_COMPILE([if 'struct file' has member 'f_inode'],
1267 file_f_inode, [
1268         #include <linux/fs.h>
1269 ],[
1270         ((struct file *)0)->f_inode = NULL;
1271 ],[
1272         AC_DEFINE(HAVE_FILE_F_INODE, 1,
1273                 [struct file has member f_inode])
1274 ])
1275 ]) # LC_HAVE_FILE_F_INODE
1276
1277 #
1278 # LC_HAVE_SUNRPC_UPCALL_HAS_3ARGS
1279 #
1280 AC_DEFUN([LC_HAVE_SUNRPC_UPCALL_HAS_3ARGS], [
1281 LB_CHECK_COMPILE([if 'sunrpc_cache_pipe_upcall' takes 3 args],
1282 sunrpc_cache_pipe_upcall_3args, [
1283         #include <linux/sunrpc/cache.h>
1284 ],[
1285         sunrpc_cache_pipe_upcall(NULL, NULL, NULL);
1286 ],[
1287         AC_DEFINE(HAVE_SUNRPC_UPCALL_HAS_3ARGS, 1,
1288                 [sunrpc_cache_pipe_upcall takes 3 args])
1289 ])
1290 ]) # LC_HAVE_SUNRPC_UPCALL_HAS_3ARGS
1291
1292 #
1293 # LC_HAVE_HLIST_FOR_EACH_3ARG
1294 #
1295 # 3.9 uses hlist_for_each_entry with 3 args
1296 # b67bfe0d42cac56c512dd5da4b1b347a23f4b70a
1297 #
1298 AC_DEFUN([LC_HAVE_HLIST_FOR_EACH_3ARG], [
1299 LB_CHECK_COMPILE([if 'hlist_for_each_entry' has 3 args],
1300 hlist_for_each_entry_3args, [
1301         #include <linux/list.h>
1302         #include <linux/fs.h>
1303 ],[
1304         struct hlist_head *head = NULL;
1305         struct inode *inode;
1306
1307         hlist_for_each_entry(inode, head, i_hash) {
1308                 continue;
1309         }
1310 ],[
1311         AC_DEFINE(HAVE_HLIST_FOR_EACH_3ARG, 1,
1312                 [hlist_for_each_entry has 3 args])
1313 ])
1314 ]) # LC_HAVE_HLIST_FOR_EACH_3ARG
1315
1316 #
1317 # LC_HAVE_BIO_END_SECTOR
1318 #
1319 # 3.9 introduces bio_end_sector macro
1320 # f73a1c7d117d07a96d89475066188a2b79e53c48
1321 #
1322 AC_DEFUN([LC_HAVE_BIO_END_SECTOR], [
1323 LB_CHECK_COMPILE([if 'bio_end_sector' is defined],
1324 bio_end_sector, [
1325         #include <linux/bio.h>
1326 ],[
1327         struct bio bio;
1328
1329         bio_end_sector(&bio);
1330 ],[
1331         AC_DEFINE(HAVE_BIO_END_SECTOR, 1,
1332                   [bio_end_sector is defined])
1333 ])
1334 ]) # LC_HAVE_BIO_END_SECTOR
1335
1336 #
1337 # LC_HAVE_REMOVE_PROC_SUBTREE
1338 #
1339 # 3.10 introduced remove_proc_subtree
1340 #
1341 AC_DEFUN([LC_HAVE_REMOVE_PROC_SUBTREE], [
1342 LB_CHECK_COMPILE([if 'remove_proc_subtree' is defined],
1343 remove_proc_subtree, [
1344         #include <linux/proc_fs.h>
1345 ],[
1346         remove_proc_subtree(NULL, NULL);
1347 ], [
1348         AC_DEFINE(HAVE_REMOVE_PROC_SUBTREE, 1,
1349                   [remove_proc_subtree is defined])
1350 ])
1351 ]) # LC_HAVE_REMOVE_PROC_SUBTREE
1352
1353 #
1354 # LC_HAVE_PROC_REMOVE
1355 #
1356 # 3.10 introduced proc_remove
1357 #
1358 AC_DEFUN([LC_HAVE_PROC_REMOVE], [
1359 LB_CHECK_COMPILE([if 'proc_remove' is defined],
1360 proc_remove, [
1361         #include <linux/proc_fs.h>
1362 ],[
1363         proc_remove(NULL);
1364 ], [
1365         AC_DEFINE(HAVE_PROC_REMOVE, 1,
1366                   [proc_remove is defined])
1367 ])
1368 ]) # LC_HAVE_PROC_REMOVE
1369
1370 #
1371 # LC_BLKDEV_RELEASE_RETURN_INT
1372 #
1373 # 3.10 release for block device doesn't return int
1374 #
1375 AC_DEFUN([LC_BLKDEV_RELEASE_RETURN_INT], [
1376 LB_CHECK_COMPILE([if 'block_device_operations' release returns 'int'],
1377 block_device_ops_release_return_int, [
1378         #include <linux/blkdev.h>
1379 ],[
1380         struct block_device_operations fops;
1381         int i __attribute__ ((unused));
1382
1383         i = fops.release(NULL, 0);
1384 ],[
1385         AC_DEFINE(HAVE_BLKDEV_RELEASE_RETURN_INT, 1,
1386                 [block device release returns int])
1387 ])
1388 ]) # LC_BLKDEV_RELEASE_RETURN_INT
1389
1390 #
1391 # LC_INVALIDATE_RANGE
1392 #
1393 # 3.11 invalidatepage requires the length of the range to invalidate
1394 #
1395 AC_DEFUN([LC_INVALIDATE_RANGE], [
1396 LB_CHECK_COMPILE([if 'address_space_operations.invalidatepage' requires 3 arguments],
1397 address_space_ops_invalidatepage_3args, [
1398         #include <linux/fs.h>
1399 ],[
1400         struct address_space_operations a_ops;
1401         a_ops.invalidatepage(NULL, 0, 0);
1402 ],[
1403         AC_DEFINE(HAVE_INVALIDATE_RANGE, 1,
1404                 [address_space_operations.invalidatepage needs 3 arguments])
1405 ])
1406 ]) # LC_INVALIDATE_RANGE
1407
1408 #
1409 # LC_HAVE_DIR_CONTEXT
1410 #
1411 # 3.11 readdir now takes the new struct dir_context
1412 #
1413 AC_DEFUN([LC_HAVE_DIR_CONTEXT], [
1414 LB_CHECK_COMPILE([if 'dir_context' exist],
1415 dir_context, [
1416         #include <linux/fs.h>
1417 ],[
1418         struct dir_context ctx;
1419         ctx.pos = 0;
1420 ],[
1421         AC_DEFINE(HAVE_DIR_CONTEXT, 1,
1422                 [dir_context exist])
1423 ])
1424 ]) # LC_HAVE_DIR_CONTEXT
1425
1426 #
1427 # LC_D_COMPARE_5ARGS
1428 #
1429 # 3.11 dentry_operations.d_compare() taken 5 arguments.
1430 #
1431 AC_DEFUN([LC_D_COMPARE_5ARGS], [
1432 LB_CHECK_COMPILE([if 'd_compare' taken 5 arguments],
1433 d_compare_5args, [
1434         #include <linux/dcache.h>
1435 ],[
1436         ((struct dentry_operations*)0)->d_compare(NULL,NULL,0,NULL,NULL);
1437 ],[
1438         AC_DEFINE(HAVE_D_COMPARE_5ARGS, 1,
1439                 [d_compare need 5 arguments])
1440 ])
1441 ]) # LC_D_COMPARE_5ARGS
1442
1443 #
1444 # LC_HAVE_DCOUNT
1445 #
1446 # 3.11 need to access d_count to get dentry reference count
1447 #
1448 AC_DEFUN([LC_HAVE_DCOUNT], [
1449 LB_CHECK_COMPILE([if 'd_count' exist],
1450 d_count, [
1451         #include <linux/dcache.h>
1452 ],[
1453         struct dentry de;
1454         d_count(&de);
1455 ],[
1456         AC_DEFINE(HAVE_D_COUNT, 1,
1457                 [d_count exist])
1458 ])
1459 ]) # LC_HAVE_DCOUNT
1460
1461 #
1462 # LC_OLDSIZE_TRUNCATE_PAGECACHE
1463 #
1464 # 3.12 truncate_pagecache without oldsize parameter
1465 #
1466 AC_DEFUN([LC_OLDSIZE_TRUNCATE_PAGECACHE], [
1467 LB_CHECK_COMPILE([if 'truncate_pagecache' with 'old_size' parameter],
1468 truncate_pagecache_old_size, [
1469         #include <linux/mm.h>
1470 ],[
1471         truncate_pagecache(NULL, 0, 0);
1472 ],[
1473         AC_DEFINE(HAVE_OLDSIZE_TRUNCATE_PAGECACHE, 1,
1474                 [with oldsize])
1475 ])
1476 ]) # LC_OLDSIZE_TRUNCATE_PAGECACHE
1477
1478 #
1479 # LC_HAVE_DENTRY_D_U_D_ALIAS
1480 #
1481 # 3.11 kernel moved d_alias to the union d_u in struct dentry
1482 #
1483 # Some distros move d_alias to d_u but it is still a struct list
1484 #
1485 AC_DEFUN([LC_HAVE_DENTRY_D_U_D_ALIAS], [
1486 AS_IF([test "x$lb_cv_compile_i_dentry_d_alias_list" = xyes], [
1487         LB_CHECK_COMPILE([if list 'dentry.d_u.d_alias' exist],
1488         d_alias, [
1489                 #include <linux/list.h>
1490                 #include <linux/dcache.h>
1491         ],[
1492                 struct dentry de;
1493                 INIT_LIST_HEAD(&de.d_u.d_alias);
1494         ],[
1495                 AC_DEFINE(HAVE_DENTRY_D_U_D_ALIAS, 1,
1496                         [list dentry.d_u.d_alias exist])
1497         ])
1498 ],[
1499         LB_CHECK_COMPILE([if hlist 'dentry.d_u.d_alias' exist],
1500         d_alias, [
1501                 #include <linux/list.h>
1502                 #include <linux/dcache.h>
1503         ],[
1504                 struct dentry de;
1505                 INIT_HLIST_NODE(&de.d_u.d_alias);
1506         ],[
1507                 AC_DEFINE(HAVE_DENTRY_D_U_D_ALIAS, 1,
1508                         [hlist dentry.d_u.d_alias exist])
1509         ])
1510 ])
1511 ]) # LC_HAVE_DENTRY_D_U_D_ALIAS
1512
1513 #
1514 # LC_HAVE_DENTRY_D_CHILD
1515 #
1516 # 3.11 kernel d_child has been moved out of the union d_u
1517 # in struct dentry
1518 #
1519 AC_DEFUN([LC_HAVE_DENTRY_D_CHILD], [
1520 LB_CHECK_COMPILE([if 'dentry.d_child' exist],
1521 d_child, [
1522         #include <linux/list.h>
1523         #include <linux/dcache.h>
1524 ],[
1525         struct dentry de;
1526         INIT_LIST_HEAD(&de.d_child);
1527 ],[
1528         AC_DEFINE(HAVE_DENTRY_D_CHILD, 1,
1529                 [dentry.d_child exist])
1530 ])
1531 ]) # LC_HAVE_DENTRY_D_CHILD
1532
1533 #
1534 # LC_KIOCB_KI_LEFT
1535 #
1536 # 3.12 ki_left removed from struct kiocb
1537 #
1538 AC_DEFUN([LC_KIOCB_KI_LEFT], [
1539 LB_CHECK_COMPILE([if 'struct kiocb' with 'ki_left' member],
1540 kiocb_ki_left, [
1541         #include <linux/aio.h>
1542 ],[
1543         ((struct kiocb*)0)->ki_left = 0;
1544 ],[
1545         AC_DEFINE(HAVE_KIOCB_KI_LEFT, 1,
1546                 [ki_left exist])
1547 ])
1548 ]) # LC_KIOCB_KI_LEFT
1549
1550 #
1551 # LC_VFS_RENAME_5ARGS
1552 #
1553 # 3.13 has vfs_rename with 5 args
1554 #
1555 AC_DEFUN([LC_VFS_RENAME_5ARGS], [
1556 LB_CHECK_COMPILE([if Linux kernel has 'vfs_rename' with 5 args],
1557 vfs_rename_5args, [
1558         #include <linux/fs.h>
1559 ],[
1560         vfs_rename(NULL, NULL, NULL, NULL, NULL);
1561 ], [
1562         AC_DEFINE(HAVE_VFS_RENAME_5ARGS, 1,
1563                 [kernel has vfs_rename with 5 args])
1564 ])
1565 ]) # LC_VFS_RENAME_5ARGS
1566
1567 #
1568 # LC_VFS_UNLINK_3ARGS
1569 #
1570 # 3.13 has vfs_unlink with 3 args
1571 #
1572 AC_DEFUN([LC_VFS_UNLINK_3ARGS], [
1573 LB_CHECK_COMPILE([if Linux kernel has 'vfs_unlink' with 3 args],
1574 vfs_unlink_3args, [
1575         #include <linux/fs.h>
1576 ],[
1577         vfs_unlink(NULL, NULL, NULL);
1578 ], [
1579         AC_DEFINE(HAVE_VFS_UNLINK_3ARGS, 1,
1580                 [kernel has vfs_unlink with 3 args])
1581 ])
1582 ]) # LC_VFS_UNLINK_3ARGS
1583
1584 #
1585 # LC_HAVE_BVEC_ITER
1586 #
1587 # 3.14 move some of its data in struct bio into the new
1588 # struct bvec_iter
1589 #
1590 AC_DEFUN([LC_HAVE_BVEC_ITER], [
1591 LB_CHECK_COMPILE([if Linux kernel has struct bvec_iter],
1592 have_bvec_iter, [
1593         #include <linux/bio.h>
1594 ],[
1595         struct bvec_iter iter;
1596         iter.bi_bvec_done = 0;
1597 ], [
1598         AC_DEFINE(HAVE_BVEC_ITER, 1,
1599                 [kernel has struct bvec_iter])
1600 ])
1601 ]) # LC_HAVE_BVEC_ITER
1602
1603 #
1604 # LC_HAVE_TRUNCATE_IPAGE_FINAL
1605 #
1606 # 3.14 bring truncate_inode_pages_final for evict_inode
1607 #
1608 AC_DEFUN([LC_HAVE_TRUNCATE_IPAGES_FINAL], [
1609 LB_CHECK_COMPILE([if Linux kernel has truncate_inode_pages_final],
1610 truncate_ipages_final, [
1611         #include <linux/mm.h>
1612 ],[
1613         truncate_inode_pages_final(NULL);
1614 ], [
1615         AC_DEFINE(HAVE_TRUNCATE_INODE_PAGES_FINAL, 1,
1616                 [kernel has truncate_inode_pages_final])
1617 ])
1618 ]) # LC_HAVE_TRUNCATE_IPAGES_FINAL
1619
1620 #
1621 # LC_VFS_RENAME_6ARGS
1622 #
1623 # 3.15 has vfs_rename with 6 args
1624 #
1625 AC_DEFUN([LC_VFS_RENAME_6ARGS], [
1626 LB_CHECK_COMPILE([if Linux kernel has 'vfs_rename' with 6 args],
1627 vfs_rename_6args, [
1628         #include <linux/fs.h>
1629 ],[
1630         vfs_rename(NULL, NULL, NULL, NULL, NULL, NULL);
1631 ], [
1632         AC_DEFINE(HAVE_VFS_RENAME_6ARGS, 1,
1633                 [kernel has vfs_rename with 6 args])
1634 ])
1635 ]) # LC_VFS_RENAME_6ARGS
1636
1637 #
1638 # LC_DIRECTIO_USE_ITER
1639 #
1640 # 3.16 kernel changes direct IO to use iov_iter
1641 #
1642 AC_DEFUN([LC_DIRECTIO_USE_ITER], [
1643 LB_CHECK_COMPILE([if direct IO uses iov_iter],
1644 direct_io_iter, [
1645         #include <linux/fs.h>
1646 ],[
1647         struct address_space_operations ops;
1648         struct iov_iter *iter = NULL;
1649         loff_t offset = 0;
1650
1651         ops.direct_IO(0, NULL, iter, offset);
1652 ],[
1653         AC_DEFINE(HAVE_DIRECTIO_ITER, 1,
1654                 [direct IO uses iov_iter])
1655 ])
1656 ]) # LC_DIRECTIO_USE_ITER
1657
1658 #
1659 # LC_NFS_FILLDIR_USE_CTX
1660 #
1661 # 3.18 kernel moved from void cookie to struct dir_context
1662 #
1663 AC_DEFUN([LC_NFS_FILLDIR_USE_CTX], [
1664 tmp_flags="$EXTRA_KCFLAGS"
1665 EXTRA_KCFLAGS="-Werror"
1666 LB_CHECK_COMPILE([if filldir_t uses struct dir_context],
1667 filldir_ctx, [
1668         #include <linux/fs.h>
1669 ],[
1670         int filldir(struct dir_context *ctx, const char* name,
1671                     int i, loff_t off, u64 tmp, unsigned temp)
1672         {
1673                 return 0;
1674         }
1675
1676         struct dir_context ctx = {
1677                 .actor = filldir,
1678         };
1679
1680         ctx.actor(NULL, "test", 0, (loff_t) 0, 0, 0);
1681 ],[
1682         AC_DEFINE(HAVE_FILLDIR_USE_CTX, 1,
1683                 [filldir_t needs struct dir_context as argument])
1684 ])
1685 EXTRA_KCFLAGS="$tmp_flags"
1686 ]) # LC_NFS_FILLDIR_USE_CTX
1687
1688 #
1689 # LC_KIOCB_HAS_NBYTES
1690 #
1691 # 3.19 kernel removed ki_nbytes from struct kiocb
1692 #
1693 AC_DEFUN([LC_KIOCB_HAS_NBYTES], [
1694 LB_CHECK_COMPILE([if struct kiocb has ki_nbytes field],
1695 ki_nbytes, [
1696         #include <linux/fs.h>
1697 ],[
1698         struct kiocb iocb;
1699
1700         iocb.ki_nbytes = 0;
1701 ],[
1702         AC_DEFINE(HAVE_KI_NBYTES, 1, [ki_nbytes field exist])
1703 ])
1704 ]) # LC_KIOCB_HAS_NBYTES
1705
1706 #
1707 # LC_CANCEL_DIRTY_PAGE
1708 #
1709 # 4.0.0 kernel removed cancle_dirty_page
1710 #
1711 AC_DEFUN([LC_CANCEL_DIRTY_PAGE], [
1712 LB_CHECK_COMPILE([if cancel_dirty_page still exist],
1713 cancel_dirty_page, [
1714         #include <linux/mm.h>
1715 ],[
1716         cancel_dirty_page(NULL, PAGE_SIZE);
1717 ],[
1718         AC_DEFINE(HAVE_CANCEL_DIRTY_PAGE, 1,
1719                 [cancel_dirty_page is still available])
1720 ])
1721 ]) # LC_CANCEL_DIRTY_PAGE
1722
1723 #
1724 # LC_IOV_ITER_RW
1725 #
1726 # 4.1 kernel has iov_iter_rw
1727 #
1728 AC_DEFUN([LC_IOV_ITER_RW], [
1729 LB_CHECK_COMPILE([if iov_iter_rw exist],
1730 iov_iter_rw, [
1731         #include <linux/fs.h>
1732         #include <linux/uio.h>
1733 ],[
1734         struct iov_iter *iter = NULL;
1735
1736         iov_iter_rw(iter);
1737 ],[
1738         AC_DEFINE(HAVE_IOV_ITER_RW, 1,
1739                 [iov_iter_rw exist])
1740 ])
1741 ]) # LC_IOV_ITER_RW
1742
1743 #
1744 # LC_PROG_LINUX
1745 #
1746 # Lustre linux kernel checks
1747 #
1748 AC_DEFUN([LC_PROG_LINUX], [
1749         AC_MSG_NOTICE([Lustre kernel checks
1750 ==============================================================================])
1751
1752         LC_CONFIG_PINGER
1753         LC_CONFIG_CHECKSUM
1754         LC_CONFIG_HEALTH_CHECK_WRITE
1755         LC_CONFIG_LRU_RESIZE
1756         LC_LLITE_LLOOP_MODULE
1757
1758         LC_GLIBC_SUPPORT_FHANDLES
1759         LC_CONFIG_RMTCLIENT
1760         LC_CONFIG_GSS
1761
1762         # 2.6.32
1763         LC_BLK_QUEUE_MAX_SEGMENTS
1764
1765         # 2.6.34
1766         LC_HAVE_DQUOT_FS_DISK_QUOTA
1767         LC_HAVE_DQUOT_SUSPEND
1768         LC_HAVE_ADD_WAIT_QUEUE_EXCLUSIVE
1769
1770         # 2.6.35, 3.0.0
1771         LC_FILE_FSYNC
1772         LC_EXPORT_SIMPLE_SETATTR
1773         LC_EXPORT_TRUNCATE_COMPLETE_PAGE
1774
1775         # 2.6.36
1776         LC_FS_STRUCT_RWLOCK
1777         LC_SBOPS_EVICT_INODE
1778
1779         # 2.6.37
1780         LC_KERNEL_LOCKED
1781
1782         # 2.6.38
1783         LC_BLKDEV_GET_BY_DEV
1784         LC_GENERIC_PERMISSION
1785         LC_DCACHE_LOCK
1786         LC_INODE_I_RCU
1787         LC_D_COMPARE_7ARGS
1788         LC_D_DELETE_CONST
1789
1790         # 2.6.39
1791         LC_REQUEST_QUEUE_UNPLUG_FN
1792         LC_HAVE_FHANDLE_SYSCALLS
1793         LC_HAVE_FSTYPE_MOUNT
1794         LC_IOP_TRUNCATE
1795         LC_HAVE_INODE_OWNER_OR_CAPABLE
1796         LC_HAVE_SECURITY_IINITSEC
1797
1798         # 3.0
1799         LC_DIRTY_INODE_WITH_FLAG
1800
1801         # 3.1
1802         LC_LM_XXX_LOCK_MANAGER_OPS
1803         LC_INODE_DIO_WAIT
1804         LC_IOP_GET_ACL
1805         LC_FILE_LLSEEK_SIZE
1806         LC_INODE_PERMISION_2ARGS
1807         LC_RADIX_EXCEPTION_ENTRY
1808
1809         # 3.2
1810         LC_HAVE_VOID_MAKE_REQUEST_FN
1811         LC_HAVE_PROTECT_I_NLINK
1812
1813         # 3.3
1814         LC_HAVE_MIGRATE_HEADER
1815         LC_MIGRATEPAGE_4ARGS
1816         LC_SUPEROPS_USE_DENTRY
1817         LC_INODEOPS_USE_UMODE_T
1818         LC_HAVE_CACHE_REGISTER
1819
1820         # 3.4
1821         LC_HAVE_D_MAKE_ROOT
1822         LC_KMAP_ATOMIC_HAS_1ARG
1823
1824         # 3.5
1825         LC_HAVE_CLEAR_INODE
1826         LC_HAVE_ENCODE_FH_PARENT
1827         LC_FILE_LLSEEK_SIZE_5ARG
1828
1829         # 3.6
1830         LC_DATA_FOR_LLITE_IS_LIST
1831         LC_DENTRY_OPEN_USE_PATH
1832         LC_HAVE_IOP_ATOMIC_OPEN
1833
1834         # 3.7
1835         LC_HAVE_POSIXACL_USER_NS
1836
1837         # 3.8
1838         LC_HAVE_FILE_F_INODE
1839         LC_HAVE_SUNRPC_UPCALL_HAS_3ARGS
1840
1841         # 3.9
1842         LC_HAVE_HLIST_FOR_EACH_3ARG
1843         LC_HAVE_BIO_END_SECTOR
1844
1845         # 3.10
1846         LC_BLKDEV_RELEASE_RETURN_INT
1847         LC_HAVE_REMOVE_PROC_SUBTREE
1848         LC_HAVE_PROC_REMOVE
1849
1850         # 3.11
1851         LC_INVALIDATE_RANGE
1852         LC_HAVE_DIR_CONTEXT
1853         LC_D_COMPARE_5ARGS
1854         LC_HAVE_DCOUNT
1855         LC_HAVE_DENTRY_D_U_D_ALIAS
1856         LC_HAVE_DENTRY_D_CHILD
1857
1858         # 3.12
1859         LC_OLDSIZE_TRUNCATE_PAGECACHE
1860         LC_KIOCB_KI_LEFT
1861
1862         # 3.13
1863         LC_VFS_RENAME_5ARGS
1864         LC_VFS_UNLINK_3ARGS
1865
1866         # 3.14
1867         LC_HAVE_BVEC_ITER
1868         LC_HAVE_TRUNCATE_IPAGES_FINAL
1869
1870         # 3.15
1871         LC_VFS_RENAME_6ARGS
1872
1873         # 3.16
1874         LC_DIRECTIO_USE_ITER
1875
1876         # 3.18
1877         LC_NFS_FILLDIR_USE_CTX
1878
1879         # 3.19
1880         LC_KIOCB_HAS_NBYTES
1881
1882         # 4.0.0
1883         LC_CANCEL_DIRTY_PAGE
1884
1885         # 4.1.0
1886         LC_IOV_ITER_RW
1887
1888         #
1889         AS_IF([test "x$enable_server" != xno], [
1890                 LC_FUNC_DEV_SET_RDONLY
1891                 LC_STACK_SIZE
1892                 LC_QUOTA64
1893                 LC_QUOTA_CONFIG
1894         ])
1895 ]) # LC_PROG_LINUX
1896
1897 #
1898 # LC_CONFIG_CLIENT
1899 #
1900 # Check whether to build the client side of Lustre
1901 #
1902 AC_DEFUN([LC_CONFIG_CLIENT], [
1903 AC_MSG_CHECKING([whether to build Lustre client support])
1904 AC_ARG_ENABLE([client],
1905         AC_HELP_STRING([--disable-client],
1906                 [disable Lustre client support]),
1907         [], [enable_client="yes"])
1908 AC_MSG_RESULT([$enable_client])
1909 ]) # LC_CONFIG_CLIENT
1910
1911 #
1912 # --enable-mpitests
1913 #
1914 AC_DEFUN([LB_CONFIG_MPITESTS], [
1915 AC_ARG_ENABLE([mpitests],
1916         AC_HELP_STRING([--enable-mpitests=<yes|no|mpicc wrapper>],
1917                        [include mpi tests]), [
1918                 enable_mpitests="yes"
1919                 case $enableval in
1920                 yes)
1921                         MPICC_WRAPPER="mpicc"
1922                         ;;
1923                 no)
1924                         enable_mpitests="no"
1925                         ;;
1926                 *)
1927                         MPICC_WRAPPER=$enableval
1928                         ;;
1929                 esac
1930         ], [
1931                 enable_mpitests="yes"
1932                 MPICC_WRAPPER="mpicc"
1933         ])
1934
1935         if test "x$enable_mpitests" != "xno"; then
1936                 oldcc=$CC
1937                 CC=$MPICC_WRAPPER
1938                 AC_CACHE_CHECK([whether mpitests can be built],
1939                 lb_cv_mpi_tests, [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1940                         #include <mpi.h>
1941                         int main(void) {
1942                                 int flag;
1943                                 MPI_Initialized(&flag);
1944                                 return 0;
1945                         }
1946                 ])], [lb_cv_mpi_tests="yes"], [lb_cv_mpi_tests="no"])
1947                 ])
1948                 enable_mpitests=$lb_cv_mpi_tests
1949                 CC=$oldcc
1950         fi
1951         AC_SUBST(MPICC_WRAPPER)
1952 ]) # LB_CONFIG_MPITESTS
1953
1954 #
1955 # LC_CONFIG_QUOTA
1956 #
1957 # whether to enable quota support global control
1958 #
1959 AC_DEFUN([LC_CONFIG_QUOTA], [
1960 AC_MSG_CHECKING([whether to enable quota support global control])
1961 AC_ARG_ENABLE([quota],
1962         AC_HELP_STRING([--enable-quota],
1963                 [enable quota support]),
1964         [], [enable_quota="yes"])
1965 AS_IF([test "x$enable_quota" = xyes],
1966         [AC_MSG_RESULT([yes])],
1967         [AC_MSG_RESULT([no])])
1968 ]) # LC_CONFIG_QUOTA
1969
1970 #
1971 # LC_QUOTA
1972 #
1973 AC_DEFUN([LC_QUOTA], [
1974 #check global
1975 LC_CONFIG_QUOTA
1976 #check for utils
1977 AS_IF([test "x$enable_quota" != xno -a "x$enable_utils" != xno], [
1978         AC_CHECK_HEADER([sys/quota.h],
1979                 [AC_DEFINE(HAVE_SYS_QUOTA_H, 1,
1980                         [Define to 1 if you have <sys/quota.h>.])],
1981                 [AC_MSG_ERROR([don't find <sys/quota.h> in your system])])
1982 ])
1983 ]) # LC_QUOTA
1984
1985 #
1986 # LC_CONFIG_NODEMAP_PROC_DEBUG
1987 #
1988 # enable nodemap proc file debugging
1989 #
1990 AC_DEFUN([LC_NODEMAP_PROC_DEBUG], [
1991 AC_MSG_CHECKING([whether to enable nodemap proc debug])
1992 AC_ARG_ENABLE([nodemap_proc_debug],
1993         AC_HELP_STRING([--enable-nodemap-proc-debug],
1994                 [enable nodemap proc debug]),
1995         [], [enable_nodemap_proc_debug="no"])
1996 AC_MSG_RESULT([$enable_nodemap_proc_debug])
1997 AS_IF([test "x$enable_nodemap_proc_debug" != xno],
1998         [AC_DEFINE(NODEMAP_PROC_DEBUG, 1,
1999                 [enable nodemap proc debug support])])
2000 ]) # LC_NODEMAP_PROC_DEBUG
2001
2002 #
2003 # LC_LLITE_LLOOP_MODULE
2004 #
2005 # lloop_llite.ko does not currently work with page sizes
2006 # of 64k or larger.
2007 #
2008 AC_DEFUN([LC_LLITE_LLOOP_MODULE], [
2009 LB_CHECK_COMPILE([whether to enable 'llite_lloop' module],
2010 enable_llite_lloop_module, [
2011         #include <asm/page.h>
2012 ],[
2013         #if PAGE_SIZE >= 65536
2014         #error "PAGE_SIZE >= 65536"
2015         #endif
2016 ],
2017         [enable_llite_lloop_module="yes"],
2018         [enable_llite_lloop_module="no"])
2019 ]) # LC_LLITE_LLOOP_MODULE
2020
2021 #
2022 # LC_OSD_ADDON
2023 #
2024 # configure support for optional OSD implementation
2025 #
2026 AC_DEFUN([LC_OSD_ADDON], [
2027 AC_MSG_CHECKING([whether to use OSD addon])
2028 AC_ARG_WITH([osd],
2029         AC_HELP_STRING([--with-osd=path],
2030                 [set path to optional osd]),
2031         [
2032         case "$with_osd" in
2033         no)
2034                 ENABLEOSDADDON=0
2035                 ;;
2036         *)
2037                 OSDADDON="$with_osd"
2038                 ENABLEOSDADDON=1
2039                 ;;
2040         esac
2041         ], [
2042                 ENABLEOSDADDON=0
2043         ])
2044 AS_IF([test $ENABLEOSDADDON -eq 0], [
2045         AC_MSG_RESULT([no])
2046         OSDADDON=""
2047 ], [
2048         OSDMODNAME=$(basename $OSDADDON)
2049         AS_IF([test -e $LUSTRE/$OSDMODNAME], [
2050                 AC_MSG_RESULT([can't link])
2051                 OSDADDON=""
2052         ], [ln -s $OSDADDON $LUSTRE/$OSDMODNAME], [
2053                 AC_MSG_RESULT([$OSDMODNAME])
2054                 OSDADDON="subdir-m += $OSDMODNAME"
2055         ], [
2056                 AC_MSG_RESULT([can't link])
2057                 OSDADDON=""
2058         ])
2059 ])
2060 AC_SUBST(OSDADDON)
2061 ]) # LC_OSD_ADDON
2062
2063 #
2064 # LC_CONFIGURE
2065 #
2066 # other configure checks
2067 #
2068 AC_DEFUN([LC_CONFIGURE], [
2069 AC_MSG_NOTICE([Lustre core checks
2070 ==============================================================================])
2071
2072 LC_CONFIG_OBD_BUFFER_SIZE
2073
2074 AS_IF([test $target_cpu == "i686" -o $target_cpu == "x86_64"],
2075         [CFLAGS="$CFLAGS -Wall -Werror"])
2076
2077 # maximum MDS thread count
2078 LC_MDS_MAX_THREADS
2079
2080 # lustre/utils/gss/gss_util.c
2081 # lustre/utils/gss/gssd_proc.c
2082 # lustre/utils/gss/krb5_util.c
2083 # lustre/utils/llog_reader.c
2084 # lustre/utils/create_iam.c
2085 # lustre/utils/libiam.c
2086 AC_CHECK_HEADERS([netdb.h endian.h])
2087 AC_CHECK_FUNCS([gethostbyname])
2088
2089 # lustre/utils/llverdev.c
2090 AC_CHECK_HEADERS([blkid/blkid.h])
2091
2092 # lustre/utils/llverfs.c
2093 AC_CHECK_HEADERS([ext2fs/ext2fs.h])
2094
2095 SELINUX=""
2096 AC_CHECK_LIB([selinux], [is_selinux_enabled],
2097         [AC_CHECK_HEADERS([selinux/selinux.h],
2098                         [SELINUX="-lselinux"
2099                         AC_DEFINE([HAVE_SELINUX], 1,
2100                                 [support for selinux ])],
2101                         [AC_MSG_WARN([
2102
2103 No libselinux-devel package found, unable to build selinux enabled tools
2104 ])
2105 ])],
2106         [AC_MSG_WARN([
2107
2108 No selinux package found, unable to build selinux enabled tools
2109 ])
2110 ])
2111 AC_SUBST(SELINUX)
2112
2113 # Super safe df
2114 AC_MSG_CHECKING([whether to report minimum OST free space])
2115 AC_ARG_ENABLE([mindf],
2116         AC_HELP_STRING([--enable-mindf],
2117                 [Make statfs report the minimum available space on any single OST instead of the sum of free space on all OSTs]),
2118         [], [enable_mindf="no"])
2119 AC_MSG_RESULT([$enable_mindf])
2120 AS_IF([test "$enable_mindf" = "yes"],
2121         [AC_DEFINE([MIN_DF], 1, [Report minimum OST free space])])
2122
2123 AC_MSG_CHECKING([whether to randomly failing memory alloc])
2124 AC_ARG_ENABLE([fail_alloc],
2125         AC_HELP_STRING([--disable-fail-alloc],
2126                 [disable randomly alloc failure]),
2127         [], [enable_fail_alloc="yes"])
2128 AC_MSG_RESULT([$enable_fail_alloc])
2129 AS_IF([test "x$enable_fail_alloc" != xno],
2130         [AC_DEFINE([RANDOM_FAIL_ALLOC], 1,
2131                 [enable randomly alloc failure])])
2132
2133 AC_MSG_CHECKING([whether to check invariants (expensive cpu-wise)])
2134 AC_ARG_ENABLE([invariants],
2135         AC_HELP_STRING([--enable-invariants],
2136                 [enable invariant checking (cpu intensive)]),
2137         [], [enable_invariants="no"])
2138 AC_MSG_RESULT([$enable_invariants])
2139 AS_IF([test "x$enable_invariants" = xyes],
2140         [AC_DEFINE([CONFIG_LUSTRE_DEBUG_EXPENSIVE_CHECK], 1,
2141                 [enable invariant checking])])
2142
2143 AC_MSG_CHECKING([whether to track references with lu_ref])
2144 AC_ARG_ENABLE([lu_ref],
2145         AC_HELP_STRING([--enable-lu_ref],
2146                 [enable lu_ref reference tracking code]),
2147         [], [enable_lu_ref="no"])
2148 AC_MSG_RESULT([$enable_lu_ref])
2149 AS_IF([test "x$enable_lu_ref" = xyes],
2150         [AC_DEFINE([USE_LU_REF], 1,
2151                 [enable lu_ref reference tracking code])])
2152
2153 AC_MSG_CHECKING([whether to enable page state tracking])
2154 AC_ARG_ENABLE([pgstate-track],
2155         AC_HELP_STRING([--enable-pgstate-track],
2156                 [enable page state tracking]),
2157         [], [enable_pgstat_track="no"])
2158 AC_MSG_RESULT([$enable_pgstat_track])
2159 AS_IF([test "x$enable_pgstat_track" = xyes],
2160         [AC_DEFINE([CONFIG_DEBUG_PAGESTATE_TRACKING], 1,
2161                 [enable page state tracking code])])
2162 ]) # LC_CONFIGURE
2163
2164 #
2165 # LC_CONDITIONALS
2166 #
2167 # AM_CONDITIONALS for lustre
2168 #
2169 AC_DEFUN([LC_CONDITIONALS], [
2170 AM_CONDITIONAL(MPITESTS, test x$enable_mpitests = xyes, Build MPI Tests)
2171 AM_CONDITIONAL(CLIENT, test x$enable_client = xyes)
2172 AM_CONDITIONAL(SERVER, test x$enable_server = xyes)
2173 AM_CONDITIONAL(SPLIT, test x$enable_split = xyes)
2174 AM_CONDITIONAL(BLKID, test x$ac_cv_header_blkid_blkid_h = xyes)
2175 AM_CONDITIONAL(EXT2FS_DEVEL, test x$ac_cv_header_ext2fs_ext2fs_h = xyes)
2176 AM_CONDITIONAL(GSS, test x$enable_gss = xyes)
2177 AM_CONDITIONAL(GSS_KEYRING, test x$enable_gss_keyring = xyes)
2178 AM_CONDITIONAL(GSS_PIPEFS, test x$enable_gss_pipefs = xyes)
2179 AM_CONDITIONAL(LIBPTHREAD, test x$enable_libpthread = xyes)
2180 AM_CONDITIONAL(LLITE_LLOOP, test x$enable_llite_lloop_module = xyes)
2181 ]) # LC_CONDITIONALS
2182
2183 #
2184 # LC_CONFIG_FILES
2185 #
2186 # files that should be generated with AC_OUTPUT
2187 #
2188 AC_DEFUN([LC_CONFIG_FILES],
2189 [AC_CONFIG_FILES([
2190 lustre/Makefile
2191 lustre/autoMakefile
2192 lustre/autoconf/Makefile
2193 lustre/conf/Makefile
2194 lustre/contrib/Makefile
2195 lustre/doc/Makefile
2196 lustre/include/Makefile
2197 lustre/include/lustre_ver.h
2198 lustre/include/lustre/Makefile
2199 lustre/kernel_patches/targets/3.10-rhel7.target
2200 lustre/kernel_patches/targets/2.6-rhel6.6.target
2201 lustre/kernel_patches/targets/2.6-rhel6.target
2202 lustre/kernel_patches/targets/2.6-rhel5.target
2203 lustre/kernel_patches/targets/2.6-sles11.target
2204 lustre/kernel_patches/targets/3.0-sles11.target
2205 lustre/kernel_patches/targets/3.0-sles11sp3.target
2206 lustre/kernel_patches/targets/3.12-sles12.target
2207 lustre/kernel_patches/targets/2.6-fc11.target
2208 lustre/kernel_patches/targets/2.6-fc12.target
2209 lustre/kernel_patches/targets/2.6-fc15.target
2210 lustre/kernel_patches/targets/3.x-fc18.target
2211 lustre/ldlm/Makefile
2212 lustre/fid/Makefile
2213 lustre/fid/autoMakefile
2214 lustre/llite/Makefile
2215 lustre/llite/autoMakefile
2216 lustre/lov/Makefile
2217 lustre/lov/autoMakefile
2218 lustre/mdc/Makefile
2219 lustre/mdc/autoMakefile
2220 lustre/lmv/Makefile
2221 lustre/lmv/autoMakefile
2222 lustre/lfsck/Makefile
2223 lustre/lfsck/autoMakefile
2224 lustre/mdt/Makefile
2225 lustre/mdt/autoMakefile
2226 lustre/mdd/Makefile
2227 lustre/mdd/autoMakefile
2228 lustre/fld/Makefile
2229 lustre/fld/autoMakefile
2230 lustre/obdclass/Makefile
2231 lustre/obdclass/autoMakefile
2232 lustre/obdclass/linux/Makefile
2233 lustre/obdecho/Makefile
2234 lustre/obdecho/autoMakefile
2235 lustre/ofd/Makefile
2236 lustre/ofd/autoMakefile
2237 lustre/osc/Makefile
2238 lustre/osc/autoMakefile
2239 lustre/ost/Makefile
2240 lustre/ost/autoMakefile
2241 lustre/osd-ldiskfs/Makefile
2242 lustre/osd-ldiskfs/autoMakefile
2243 lustre/osd-zfs/Makefile
2244 lustre/osd-zfs/autoMakefile
2245 lustre/mgc/Makefile
2246 lustre/mgc/autoMakefile
2247 lustre/mgs/Makefile
2248 lustre/mgs/autoMakefile
2249 lustre/target/Makefile
2250 lustre/ptlrpc/Makefile
2251 lustre/ptlrpc/autoMakefile
2252 lustre/ptlrpc/gss/Makefile
2253 lustre/ptlrpc/gss/autoMakefile
2254 lustre/quota/Makefile
2255 lustre/quota/autoMakefile
2256 lustre/scripts/Makefile
2257 lustre/tests/Makefile
2258 lustre/tests/mpi/Makefile
2259 lustre/utils/Makefile
2260 lustre/utils/gss/Makefile
2261 lustre/osp/Makefile
2262 lustre/osp/autoMakefile
2263 lustre/lod/Makefile
2264 lustre/lod/autoMakefile
2265 ])
2266 ]) # LC_CONFIG_FILES