lustre/autoconf/lustre-core.m4

   1 #* -*- mode: c; c-basic-offset: 8; indent-tabs-mode: nil; -*-
   2 #* vim:expandtab:shiftwidth=8:tabstop=8:
   3 #
   4 # LC_CONFIG_SRCDIR
   5 #
   6 # Wrapper for AC_CONFIG_SUBDIR
   7 #
   8 AC_DEFUN([LC_CONFIG_SRCDIR],
   9 [AC_CONFIG_SRCDIR([lustre/obdclass/obdo.c])
  10 libcfs_is_module=yes
  11 ldiskfs_is_ext4=yes
  12 ])
  13
  14 #
  15 # LC_PATH_DEFAULTS
  16 #
  17 # lustre specific paths
  18 #
  19 AC_DEFUN([LC_PATH_DEFAULTS],
  20 [# ptlrpc kernel build requires this
  21 LUSTRE="$PWD/lustre"
  22 AC_SUBST(LUSTRE)
  23
  24 # mount.lustre
  25 rootsbindir='/sbin'
  26 AC_SUBST(rootsbindir)
  27
  28 demodir='$(docdir)/demo'
  29 AC_SUBST(demodir)
  30
  31 pkgexampledir='${pkgdatadir}/examples'
  32 AC_SUBST(pkgexampledir)
  33 ])
  34
  35 #
  36 # LC_TARGET_SUPPORTED
  37 #
  38 # is the target os supported?
  39 #
  40 AC_DEFUN([LC_TARGET_SUPPORTED],
  41 [case $target_os in
  42         linux* | darwin*)
  43 $1
  44                 ;;
  45         *)
  46 $2
  47                 ;;
  48 esac
  49 ])
  50
  51 #
  52 # LC_CONFIG_OBD_BUFFER_SIZE
  53 #
  54 # the maximum buffer size of lctl ioctls
  55 #
  56 AC_DEFUN([LC_CONFIG_OBD_BUFFER_SIZE],
  57 [AC_MSG_CHECKING([maximum OBD ioctl size])
  58 AC_ARG_WITH([obd-buffer-size],
  59         AC_HELP_STRING([--with-obd-buffer-size=[size]],
  60                         [set lctl ioctl maximum bytes (default=8192)]),
  61         [
  62                 OBD_BUFFER_SIZE=$with_obd_buffer_size
  63         ],[
  64                 OBD_BUFFER_SIZE=8192
  65         ])
  66 AC_MSG_RESULT([$OBD_BUFFER_SIZE bytes])
  67 AC_DEFINE_UNQUOTED(OBD_MAX_IOCTL_BUFFER, $OBD_BUFFER_SIZE, [IOCTL Buffer Size])
  68 ])
  69
  70 #
  71 # LC_READLINK_SSIZE_T
  72 #
  73 AC_DEFUN([LC_READLINK_SSIZE_T],
  74 [AC_MSG_CHECKING([if readlink returns ssize_t])
  75 AC_TRY_COMPILE([
  76         #include <unistd.h>
  77 ],[
  78         ssize_t readlink(const char *, char *, size_t);
  79 ],[
  80         AC_MSG_RESULT([yes])
  81         AC_DEFINE(HAVE_POSIX_1003_READLINK, 1, [readlink returns ssize_t])
  82 ],[
  83         AC_MSG_RESULT([no])
  84 ])
  85 ])
  86
  87 #
  88 # LC_FUNC_RELEASEPAGE_WITH_GFP
  89 #
  90 # 2.6.9 ->releasepage() takes a gfp_t arg
  91 # This kernel defines gfp_t (HAS_GFP_T) but doesn't use it for this function,
  92 # while others either don't have gfp_t or pass gfp_t as the parameter.
  93 #
  94 AC_DEFUN([LC_FUNC_RELEASEPAGE_WITH_GFP],
  95 [AC_MSG_CHECKING([if releasepage has a gfp_t parameter])
  96 RELEASEPAGE_WITH_GFP="$(grep -c 'releasepage.*gfp_t' $LINUX/include/linux/fs.h)"
  97 if test "$RELEASEPAGE_WITH_GFP" != 0 ; then
  98         AC_DEFINE(HAVE_RELEASEPAGE_WITH_GFP, 1,
  99                   [releasepage with gfp_t parameter])
 100         AC_MSG_RESULT([yes])
 101 else
 102         AC_MSG_RESULT([no])
 103 fi
 104 ])
 105
 106
 107
 108 #
 109 # only for Lustre-patched kernels
 110 #
 111 AC_DEFUN([LC_LUSTRE_VERSION_H],
 112 [LB_CHECK_FILE([$LINUX/include/linux/lustre_version.h],[
 113         rm -f "$LUSTRE/include/linux/lustre_version.h"
 114 ],[
 115         touch "$LUSTRE/include/linux/lustre_version.h"
 116         if test x$enable_server = xyes ; then
 117                 AC_MSG_WARN([Unpatched kernel detected.])
 118                 AC_MSG_WARN([Lustre servers cannot be built with an unpatched kernel;])
 119                 AC_MSG_WARN([disabling server build])
 120                 enable_server='no'
 121         fi
 122 ])
 123 ])
 124
 125 #
 126 # LC_FUNC_DEV_SET_RDONLY
 127 #
 128 # check for the old-style dev_set_rdonly which took an extra "devno" param
 129 # and can only set a single device to discard writes at one time
 130 #
 131 AC_DEFUN([LC_FUNC_DEV_SET_RDONLY],
 132 [AC_MSG_CHECKING([if kernel has new dev_set_rdonly])
 133 LB_LINUX_TRY_COMPILE([
 134         #include <linux/fs.h>
 135         #include <linux/blkdev.h>
 136 ],[
 137         #ifndef HAVE_CLEAR_RDONLY_ON_PUT
 138         #error needs to be patched by lustre kernel patches from Lustre version 1.4.3 or above.
 139         #endif
 140 ],[
 141         AC_MSG_RESULT([yes])
 142         AC_DEFINE(HAVE_DEV_SET_RDONLY, 1, [kernel has new dev_set_rdonly])
 143 ],[
 144         AC_MSG_ERROR([no, Linux kernel source needs to be patches by lustre
 145 kernel patches from Lustre version 1.4.3 or above.])
 146 ])
 147 ])
 148
 149 #
 150 # Ensure stack size big than 8k in Lustre server (all kernels)
 151 #
 152 AC_DEFUN([LC_STACK_SIZE],
 153 [AC_MSG_CHECKING([stack size big than 8k])
 154 LB_LINUX_TRY_COMPILE([
 155         #include <linux/thread_info.h>
 156 ],[
 157         #if THREAD_SIZE < 8192
 158         #error "stack size < 8192"
 159         #endif
 160 ],[
 161         AC_MSG_RESULT(yes)
 162 ],[
 163         AC_MSG_ERROR([Lustre requires that Linux is configured with at least a 8KB stack.])
 164 ])
 165 ])
 166
 167 #
 168 # Allow the user to set the MDS thread upper limit
 169 #
 170 AC_DEFUN([LC_MDS_MAX_THREADS],
 171 [
 172         AC_ARG_WITH([mds_max_threads],
 173         AC_HELP_STRING([--with-mds-max-threads=size],
 174                         [define the maximum number of threads available on the MDS: (default=512)]),
 175         [
 176                 MDS_THREAD_COUNT=$with_mds_max_threads
 177                 AC_DEFINE_UNQUOTED(MDT_MAX_THREADS, $MDS_THREAD_COUNT, [maximum number of mdt threads])
 178         ])
 179 ])
 180
 181 #
 182 # LC_CONFIG_PINGER
 183 #
 184 # the pinger is temporary, until we have the recovery node in place
 185 #
 186 AC_DEFUN([LC_CONFIG_PINGER],
 187 [AC_MSG_CHECKING([whether to enable pinger support])
 188 AC_ARG_ENABLE([pinger],
 189         AC_HELP_STRING([--disable-pinger],
 190                         [disable recovery pinger support]),
 191         [],[enable_pinger='yes'])
 192 AC_MSG_RESULT([$enable_pinger])
 193 if test x$enable_pinger != xno ; then
 194   AC_DEFINE(ENABLE_PINGER, 1, Use the Pinger)
 195 fi
 196 ])
 197
 198 #
 199 # LC_CONFIG_CHECKSUM
 200 #
 201 # do checksum of bulk data between client and OST
 202 #
 203 AC_DEFUN([LC_CONFIG_CHECKSUM],
 204 [AC_MSG_CHECKING([whether to enable data checksum support])
 205 AC_ARG_ENABLE([checksum],
 206        AC_HELP_STRING([--disable-checksum],
 207                        [disable data checksum support]),
 208        [],[enable_checksum='yes'])
 209 AC_MSG_RESULT([$enable_checksum])
 210 if test x$enable_checksum != xno ; then
 211   AC_DEFINE(ENABLE_CHECKSUM, 1, do data checksums)
 212 fi
 213 ])
 214
 215 #
 216 # LC_CONFIG_LIBLUSTRE_RECOVERY
 217 #
 218 AC_DEFUN([LC_CONFIG_LIBLUSTRE_RECOVERY],
 219 [AC_MSG_CHECKING([whether to enable liblustre recovery support])
 220 AC_ARG_ENABLE([liblustre-recovery],
 221         AC_HELP_STRING([--disable-liblustre-recovery],
 222                         [disable liblustre recovery support]),
 223         [],[enable_liblustre_recovery='yes'])
 224 AC_MSG_RESULT([$enable_liblustre_recovery])
 225 if test x$enable_liblustre_recovery != xno ; then
 226   AC_DEFINE(ENABLE_LIBLUSTRE_RECOVERY, 1, Liblustre Can Recover)
 227 fi
 228 ])
 229
 230 #
 231 # LC_CONFIG_HEALTH_CHECK_WRITE
 232 #
 233 # Turn off the actual write to the disk
 234 #
 235 AC_DEFUN([LC_CONFIG_HEALTH_CHECK_WRITE],
 236 [AC_MSG_CHECKING([whether to enable a write with the health check])
 237 AC_ARG_ENABLE([health_write],
 238         AC_HELP_STRING([--enable-health_write],
 239                         [enable disk writes when doing health check]),
 240         [],[enable_health_write='no'])
 241 AC_MSG_RESULT([$enable_health_write])
 242 if test x$enable_health_write != xno ; then
 243   AC_DEFINE(USE_HEALTH_CHECK_WRITE, 1, Write when Checking Health)
 244 fi
 245 ])
 246
 247 AC_DEFUN([LC_CONFIG_LRU_RESIZE],
 248 [AC_MSG_CHECKING([whether to enable lru self-adjusting])
 249 AC_ARG_ENABLE([lru_resize],
 250         AC_HELP_STRING([--enable-lru-resize],
 251                         [enable lru resize support]),
 252         [],[enable_lru_resize='yes'])
 253 AC_MSG_RESULT([$enable_lru_resize])
 254 if test x$enable_lru_resize != xno; then
 255    AC_DEFINE(HAVE_LRU_RESIZE_SUPPORT, 1, [Enable lru resize support])
 256 fi
 257 ])
 258
 259 # whether to enable quota support(kernel modules)
 260 AC_DEFUN([LC_QUOTA_MODULE],
 261 [if test x$enable_quota != xno; then
 262     LB_LINUX_CONFIG([QUOTA],[
 263         enable_quota_module='yes'
 264         AC_DEFINE(HAVE_QUOTA_SUPPORT, 1, [Enable quota support])
 265     ],[
 266         enable_quota_module='no'
 267         AC_MSG_WARN([quota is not enabled because the kernel - lacks quota support])
 268     ])
 269 fi
 270 ])
 271
 272 # truncate_complete_page() was exported from RHEL5/SLES10/SLES11
 273 # remove_from_page_cache() was exported between 2.6.35 and 2.6.38
 274 # delete_from_page_cache() is exported from 2.6.39
 275 AC_DEFUN([LC_EXPORT_TRUNCATE_COMPLETE],
 276          [LB_CHECK_SYMBOL_EXPORT([truncate_complete_page],
 277                                  [mm/truncate.c],
 278                                  [AC_DEFINE(HAVE_TRUNCATE_COMPLETE_PAGE, 1,
 279                                             [kernel export truncate_complete_page])])
 280           LB_CHECK_SYMBOL_EXPORT([remove_from_page_cache],
 281                                  [mm/filemap.c],
 282                                  [AC_DEFINE(HAVE_REMOVE_FROM_PAGE_CACHE, 1,
 283                                             [kernel export remove_from_page_cache])])
 284           LB_CHECK_SYMBOL_EXPORT([delete_from_page_cache],
 285                                  [mm/filemap.c],
 286                                  [AC_DEFINE(HAVE_DELETE_FROM_PAGE_CACHE, 1,
 287                                             [kernel export delete_from_page_cache])])
 288          ])
 289
 290 AC_DEFUN([LC_EXPORT_TRUNCATE_RANGE],
 291 [LB_CHECK_SYMBOL_EXPORT([truncate_inode_pages_range],
 292 [mm/truncate.c],[
 293 AC_DEFINE(HAVE_TRUNCATE_RANGE, 1,
 294             [kernel export truncate_inode_pages_range])
 295 ],[
 296 ])
 297 ])
 298
 299 AC_DEFUN([LC_EXPORT_D_REHASH_COND],
 300 [LB_CHECK_SYMBOL_EXPORT([d_rehash_cond],
 301 [fs/dcache.c],[
 302 AC_DEFINE(HAVE_D_REHASH_COND, 1,
 303             [d_rehash_cond is exported by the kernel])
 304 ],[
 305 ])
 306 ])
 307
 308 AC_DEFUN([LC_EXPORT___D_REHASH],
 309 [LB_CHECK_SYMBOL_EXPORT([__d_rehash],
 310 [fs/dcache.c],[
 311 AC_DEFINE(HAVE___D_REHASH, 1,
 312             [__d_rehash is exported by the kernel])
 313 ],[
 314 ])
 315 ])
 316
 317 # The actual symbol exported varies among architectures, so we need
 318 # to check many symbols (but only in the current architecture.)  No
 319 # matter what symbol is exported, the kernel #defines node_to_cpumask
 320 # to the appropriate function and that's what we use.
 321 AC_DEFUN([LC_EXPORT_NODE_TO_CPUMASK],
 322          [LB_CHECK_SYMBOL_EXPORT([node_to_cpumask],
 323                                  [arch/$LINUX_ARCH/mm/numa.c],
 324                                  [AC_DEFINE(HAVE_NODE_TO_CPUMASK, 1,
 325                                             [node_to_cpumask is exported by
 326                                              the kernel])]) # x86_64
 327           LB_CHECK_SYMBOL_EXPORT([node_to_cpu_mask],
 328                                  [arch/$LINUX_ARCH/kernel/smpboot.c],
 329                                  [AC_DEFINE(HAVE_NODE_TO_CPUMASK, 1,
 330                                             [node_to_cpumask is exported by
 331                                              the kernel])]) # ia64
 332           LB_CHECK_SYMBOL_EXPORT([node_2_cpu_mask],
 333                                  [arch/$LINUX_ARCH/kernel/smpboot.c],
 334                                  [AC_DEFINE(HAVE_NODE_TO_CPUMASK, 1,
 335                                             [node_to_cpumask is exported by
 336                                              the kernel])]) # i386
 337           ])
 338
 339 #
 340 # LC_FUNC_GRAB_CACHE_PAGE_NOWAIT_GFP
 341 #
 342 # Check for our patched grab_cache_page_nowait_gfp() function
 343 # after 2.6.29 we can emulate this using add_to_page_cache_lru()
 344 #
 345 AC_DEFUN([LC_FUNC_GRAB_CACHE_PAGE_NOWAIT_GFP],
 346 [LB_CHECK_SYMBOL_EXPORT([grab_cache_page_nowait_gfp],
 347 [mm/filemap.c],[
 348         AC_DEFINE(HAVE_GRAB_CACHE_PAGE_NOWAIT_GFP, 1,
 349                   [kernel exports grab_cache_page_nowait_gfp])
 350         ],
 351         [LB_CHECK_SYMBOL_EXPORT([add_to_page_cache_lru],
 352         [mm/filemap.c],[
 353                 AC_DEFINE(HAVE_ADD_TO_PAGE_CACHE_LRU, 1,
 354                         [kernel exports add_to_page_cache_lru])
 355         ],[
 356         ])
 357         ])
 358 ])
 359
 360 #
 361 # LC_STRUCT_STATFS
 362 #
 363 # AIX does not have statfs.f_namelen
 364 #
 365 AC_DEFUN([LC_STRUCT_STATFS],
 366 [AC_MSG_CHECKING([if struct statfs has a f_namelen field])
 367 LB_LINUX_TRY_COMPILE([
 368         #include <linux/vfs.h>
 369 ],[
 370         struct statfs sfs;
 371         sfs.f_namelen = 1;
 372 ],[
 373         AC_MSG_RESULT([yes])
 374         AC_DEFINE(HAVE_STATFS_NAMELEN, 1, [struct statfs has a namelen field])
 375 ],[
 376         AC_MSG_RESULT([no])
 377 ])
 378 ])
 379
 380 #
 381 # between 2.6.5 - 2.6.22 filemap_populate is exported in some kernels
 382 #
 383 AC_DEFUN([LC_FILEMAP_POPULATE],
 384 [AC_MSG_CHECKING([for exported filemap_populate])
 385 LB_LINUX_TRY_COMPILE([
 386         #include <asm/page.h>
 387         #include <linux/mm.h>
 388 ],[
 389        filemap_populate(NULL, 0, 0, __pgprot(0), 0, 0);
 390 ],[
 391         AC_MSG_RESULT([yes])
 392         AC_DEFINE(HAVE_FILEMAP_POPULATE, 1, [Kernel exports filemap_populate])
 393 ],[
 394         AC_MSG_RESULT([no])
 395 ])
 396 ])
 397
 398 #
 399 # added in 2.6.15
 400 #
 401 AC_DEFUN([LC_D_ADD_UNIQUE],
 402 [AC_MSG_CHECKING([for d_add_unique])
 403 LB_LINUX_TRY_COMPILE([
 404         #include <linux/dcache.h>
 405 ],[
 406        d_add_unique(NULL, NULL);
 407 ],[
 408         AC_MSG_RESULT([yes])
 409         AC_DEFINE(HAVE_D_ADD_UNIQUE, 1, [Kernel has d_add_unique])
 410 ],[
 411         AC_MSG_RESULT([no])
 412 ])
 413 ])
 414
 415 #
 416 # added in 2.6.17
 417 #
 418 AC_DEFUN([LC_BIT_SPINLOCK_H],
 419 [LB_CHECK_FILE([$LINUX/include/linux/bit_spinlock.h],[
 420         AC_MSG_CHECKING([if bit_spinlock.h can be compiled])
 421         LB_LINUX_TRY_COMPILE([
 422                 #include <asm/processor.h>
 423                 #include <linux/spinlock.h>
 424                 #include <linux/bit_spinlock.h>
 425         ],[],[
 426                 AC_MSG_RESULT([yes])
 427                 AC_DEFINE(HAVE_BIT_SPINLOCK_H, 1, [Kernel has bit_spinlock.h])
 428         ],[
 429                 AC_MSG_RESULT([no])
 430         ])
 431 ],
 432 [])
 433 ])
 434
 435 #
 436 # After 2.6.26 we no longer have xattr_acl.h
 437 #
 438 AC_DEFUN([LC_XATTR_ACL],
 439 [LB_CHECK_FILE([$LINUX/include/linux/xattr_acl.h],[
 440         AC_MSG_CHECKING([if xattr_acl.h can be compiled])
 441         LB_LINUX_TRY_COMPILE([
 442                 #include <linux/xattr_acl.h>
 443         ],[],[
 444                 AC_MSG_RESULT([yes])
 445                 AC_DEFINE(HAVE_XATTR_ACL, 1, [Kernel has xattr_acl])
 446         ],[
 447                 AC_MSG_RESULT([no])
 448         ])
 449 ],
 450 [])
 451 ])
 452
 453 #
 454 # After 2.6.16 the xattr_acl API is removed, and posix_acl is used instead
 455 #
 456 AC_DEFUN([LC_POSIX_ACL_XATTR_H],
 457 [LB_CHECK_FILE([$LINUX/include/linux/posix_acl_xattr.h],[
 458         AC_MSG_CHECKING([if linux/posix_acl_xattr.h can be compiled])
 459         LB_LINUX_TRY_COMPILE([
 460                 #include <linux/fs.h>
 461                 #include <linux/posix_acl_xattr.h>
 462         ],[],[
 463                 AC_MSG_RESULT([yes])
 464                 AC_DEFINE(HAVE_LINUX_POSIX_ACL_XATTR_H, 1, [linux/posix_acl_xattr.h found])
 465
 466         ],[
 467                 AC_MSG_RESULT([no])
 468         ])
 469 $1
 470 ],[
 471         AC_MSG_RESULT([no])
 472 ])
 473 ])
 474
 475 AC_DEFUN([LC_CONST_ACL_SIZE],
 476 [AC_MSG_CHECKING([calc acl size])
 477 tmp_flags="$CFLAGS"
 478 CFLAGS="$CFLAGS -I$LINUX/include -I$LINUX_OBJ/include -I$LINUX_OBJ/include2 -I$LINUX/arch/`uname -m|sed -e 's/ppc.*/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include -include $AUTOCONF_HDIR/autoconf.h $EXTRA_KCFLAGS"
 479 AC_TRY_RUN([
 480         #define __KERNEL__
 481         #include <linux/types.h>
 482         #undef __KERNEL__
 483         // block include
 484         #define __LINUX_POSIX_ACL_H
 485
 486         # ifdef CONFIG_FS_POSIX_ACL
 487         #  ifdef HAVE_XATTR_ACL
 488         #   include <linux/xattr_acl.h>
 489         #  endif
 490         #  ifdef HAVE_LINUX_POSIX_ACL_XATTR_H
 491         #   include <linux/posix_acl_xattr.h>
 492         #  endif
 493         # endif
 494
 495         #include <lustre_acl.h>
 496
 497         #include <stdio.h>
 498
 499         int main(void)
 500         {
 501             int size = mds_xattr_acl_size(LUSTRE_POSIX_ACL_MAX_ENTRIES);
 502             FILE *f = fopen("acl.size","w+");
 503             fprintf(f,"%d", size);
 504             fclose(f);
 505
 506             return 0;
 507         }
 508 ],[
 509         acl_size=`cat acl.size`
 510         AC_MSG_RESULT([ACL size $acl_size])
 511         AC_DEFINE_UNQUOTED(XATTR_ACL_SIZE, AS_TR_SH([$acl_size]), [size of xattr acl])
 512 ],[
 513         AC_ERROR([ACL size can't computed])
 514 ])
 515 CFLAGS="$tmp_flags"
 516 ])
 517
 518 # added in 2.6.16
 519 #
 520 AC_DEFUN([LC_STRUCT_INTENT_FILE],
 521 [AC_MSG_CHECKING([if struct open_intent has a file field])
 522 LB_LINUX_TRY_COMPILE([
 523         #include <linux/fs.h>
 524         #include <linux/namei.h>
 525 ],[
 526         struct open_intent intent;
 527         &intent.file;
 528 ],[
 529         AC_MSG_RESULT([yes])
 530         AC_DEFINE(HAVE_FILE_IN_STRUCT_INTENT, 1, [struct open_intent has a file field])
 531 ],[
 532         AC_MSG_RESULT([no])
 533 ])
 534 ])
 535
 536 #
 537 # LC_CAPA_CRYPTO
 538 #
 539 AC_DEFUN([LC_CAPA_CRYPTO],
 540 [LB_LINUX_CONFIG_IM([CRYPTO],[],[
 541         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO is enabled in your kernel.])
 542 ])
 543 LB_LINUX_CONFIG_IM([CRYPTO_HMAC],[],[
 544         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO_HMAC is enabled in your kernel.])
 545 ])
 546 LB_LINUX_CONFIG_IM([CRYPTO_SHA1],[],[
 547         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO_SHA1 is enabled in your kernel.])
 548 ])
 549 ])
 550
 551 #
 552 # LC_CONFIG_RMTCLIENT
 553 #
 554 dnl FIXME
 555 dnl the AES symbol usually tied with arch, e.g. CRYPTO_AES_586
 556 dnl FIXME
 557 AC_DEFUN([LC_CONFIG_RMTCLIENT],
 558 [LB_LINUX_CONFIG_IM([CRYPTO_AES],[],[
 559         AC_MSG_WARN([Lustre remote client require that CONFIG_CRYPTO_AES is enabled in your kernel.])
 560 ])
 561 ])
 562
 563 #
 564 # LC_CONFIG_GSS_KEYRING (default enabled, if gss is enabled)
 565 #
 566 AC_DEFUN([LC_CONFIG_GSS_KEYRING],
 567 [AC_MSG_CHECKING([whether to enable gss keyring backend])
 568  AC_ARG_ENABLE([gss_keyring],
 569                [AC_HELP_STRING([--disable-gss-keyring],
 570                                [disable gss keyring backend])],
 571                [],[enable_gss_keyring='yes'])
 572  AC_MSG_RESULT([$enable_gss_keyring])
 573
 574  if test x$enable_gss_keyring != xno; then
 575         LB_LINUX_CONFIG_IM([KEYS],[],
 576                            [AC_MSG_ERROR([GSS keyring backend require that CONFIG_KEYS be enabled in your kernel.])])
 577
 578         AC_CHECK_LIB([keyutils], [keyctl_search], [],
 579                      [AC_MSG_ERROR([libkeyutils is not found, which is required by gss keyring backend])],)
 580
 581         AC_DEFINE([HAVE_GSS_KEYRING], [1],
 582                   [Define this if you enable gss keyring backend])
 583  fi
 584 ])
 585
 586 AC_DEFUN([LC_SUNRPC_CACHE],
 587 [AC_MSG_CHECKING([if sunrpc struct cache_head uses kref])
 588 LB_LINUX_TRY_COMPILE([
 589         #include <linux/sunrpc/cache.h>
 590 ],[
 591         struct cache_head ch;
 592         &ch.ref.refcount;
 593 ],[
 594         AC_MSG_RESULT([yes])
 595         AC_DEFINE(HAVE_SUNRPC_CACHE_V2, 1, [sunrpc cache facility v2])
 596 ],[
 597         AC_MSG_RESULT([no])
 598 ])
 599 ])
 600
 601 AC_DEFUN([LC_CONFIG_SUNRPC],
 602 [LB_LINUX_CONFIG_IM([SUNRPC],[],
 603                     [AC_MSG_ERROR([kernel SUNRPC support is required by using GSS.])])
 604  LC_SUNRPC_CACHE
 605 ])
 606
 607 #
 608 # LC_CONFIG_GSS (default disabled)
 609 #
 610 # Build gss and related tools of Lustre. Currently both kernel and user space
 611 # parts are depend on linux platform.
 612 #
 613 AC_DEFUN([LC_CONFIG_GSS],
 614 [AC_MSG_CHECKING([whether to enable gss/krb5 support])
 615  AC_ARG_ENABLE([gss],
 616                [AC_HELP_STRING([--enable-gss], [enable gss/krb5 support])],
 617                [],[enable_gss='no'])
 618  AC_MSG_RESULT([$enable_gss])
 619
 620  if test x$enable_gss == xyes; then
 621         LC_CONFIG_GSS_KEYRING
 622         LC_CONFIG_SUNRPC
 623
 624         AC_DEFINE([HAVE_GSS], [1], [Define this if you enable gss])
 625
 626         LB_LINUX_CONFIG_IM([CRYPTO_MD5],[],
 627                            [AC_MSG_WARN([kernel MD5 support is recommended by using GSS.])])
 628         LB_LINUX_CONFIG_IM([CRYPTO_SHA1],[],
 629                            [AC_MSG_WARN([kernel SHA1 support is recommended by using GSS.])])
 630         LB_LINUX_CONFIG_IM([CRYPTO_SHA256],[],
 631                            [AC_MSG_WARN([kernel SHA256 support is recommended by using GSS.])])
 632         LB_LINUX_CONFIG_IM([CRYPTO_SHA512],[],
 633                            [AC_MSG_WARN([kernel SHA512 support is recommended by using GSS.])])
 634
 635         AC_CHECK_LIB([gssapi], [gss_init_sec_context],
 636                      [GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssapi"],
 637                      [AC_CHECK_LIB([gssglue], [gss_init_sec_context],
 638                                    [GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssglue"],
 639                                    [AC_MSG_ERROR([libgssapi or libgssglue is not found, which is required by GSS.])])],)
 640
 641         AC_SUBST(GSSAPI_LIBS)
 642
 643         AC_KERBEROS_V5
 644  fi
 645 ])
 646
 647 #
 648 # LC_FUNC_HAVE_CAN_SLEEP_ARG
 649 #
 650 # 2.6.5 kernel has third arg can_sleep in fs/locks.c: flock_lock_file_wait()
 651 #
 652 AC_DEFUN([LC_FUNC_HAVE_CAN_SLEEP_ARG],
 653 [AC_MSG_CHECKING([if kernel has third arg can_sleep in fs/locks.c: flock_lock_file_wait()])
 654 LB_LINUX_TRY_COMPILE([
 655         #include <linux/fs.h>
 656 ],[
 657         int cansleep;
 658         struct file *file;
 659         struct file_lock *file_lock;
 660         flock_lock_file_wait(file, file_lock, cansleep);
 661 ],[
 662         AC_DEFINE(HAVE_CAN_SLEEP_ARG, 1,
 663                 [kernel has third arg can_sleep in fs/locks.c: flock_lock_file_wait()])
 664         AC_MSG_RESULT([yes])
 665 ],[
 666         AC_MSG_RESULT([no])
 667 ])
 668 ])
 669
 670 #
 671 # LC_FUNC_F_OP_FLOCK
 672 #
 673 # rhel4.2 kernel has f_op->flock field
 674 #
 675 AC_DEFUN([LC_FUNC_F_OP_FLOCK],
 676 [AC_MSG_CHECKING([if struct file_operations has flock field])
 677 LB_LINUX_TRY_COMPILE([
 678         #include <linux/fs.h>
 679 ],[
 680         struct file_operations ll_file_operations_flock;
 681         ll_file_operations_flock.flock = NULL;
 682 ],[
 683         AC_DEFINE(HAVE_F_OP_FLOCK, 1,
 684                 [struct file_operations has flock field])
 685         AC_MSG_RESULT([yes])
 686 ],[
 687         AC_MSG_RESULT([no])
 688 ])
 689 ])
 690
 691 AC_DEFUN([LC_QUOTA_READ],
 692 [AC_MSG_CHECKING([if kernel supports quota_read])
 693 LB_LINUX_TRY_COMPILE([
 694         #include <linux/fs.h>
 695 ],[
 696         struct super_operations sp;
 697         void *i = (void *)sp.quota_read;
 698 ],[
 699         AC_MSG_RESULT([yes])
 700         AC_DEFINE(KERNEL_SUPPORTS_QUOTA_READ, 1, [quota_read found])
 701 ],[
 702         AC_MSG_RESULT([no])
 703 ])
 704 ])
 705
 706 #
 707 # LC_COOKIE_FOLLOW_LINK
 708 #
 709 # kernel 2.6.13+ ->follow_link returns a cookie
 710 #
 711
 712 AC_DEFUN([LC_COOKIE_FOLLOW_LINK],
 713 [AC_MSG_CHECKING([if inode_operations->follow_link returns a cookie])
 714 LB_LINUX_TRY_COMPILE([
 715         #include <linux/fs.h>
 716         #include <linux/namei.h>
 717 ],[
 718         struct dentry dentry;
 719         struct nameidata nd;
 720
 721         dentry.d_inode->i_op->put_link(&dentry, &nd, NULL);
 722 ],[
 723         AC_DEFINE(HAVE_COOKIE_FOLLOW_LINK, 1, [inode_operations->follow_link returns a cookie])
 724         AC_MSG_RESULT([yes])
 725 ],[
 726         AC_MSG_RESULT([no])
 727 ])
 728 ])
 729
 730 #
 731 # LC_FUNC_RCU
 732 #
 733 # kernels prior than 2.6.0(?) have no RCU supported; in kernel 2.6.5(SUSE),
 734 # call_rcu takes three parameters.
 735 #
 736 AC_DEFUN([LC_FUNC_RCU],
 737 [AC_MSG_CHECKING([if kernel have RCU supported])
 738 LB_LINUX_TRY_COMPILE([
 739         #include <linux/rcupdate.h>
 740 ],[],[
 741         AC_DEFINE(HAVE_RCU, 1, [have RCU defined])
 742         AC_MSG_RESULT([yes])
 743
 744         AC_MSG_CHECKING([if call_rcu takes three parameters])
 745         LB_LINUX_TRY_COMPILE([
 746                 #include <linux/rcupdate.h>
 747         ],[
 748                 struct rcu_head rh;
 749                 call_rcu(&rh, (void (*)(struct rcu_head *))1, NULL);
 750         ],[
 751                 AC_DEFINE(HAVE_CALL_RCU_PARAM, 1, [call_rcu takes three parameters])
 752                 AC_MSG_RESULT([yes])
 753         ],[
 754                 AC_MSG_RESULT([no])
 755         ])
 756
 757 ],[
 758         AC_MSG_RESULT([no])
 759 ])
 760 ])
 761
 762 AC_DEFUN([LC_PERCPU_COUNTER],
 763 [AC_MSG_CHECKING([if have struct percpu_counter defined])
 764 LB_LINUX_TRY_COMPILE([
 765         #include <linux/percpu_counter.h>
 766 ],[],[
 767         AC_DEFINE(HAVE_PERCPU_COUNTER, 1, [percpu_counter found])
 768         AC_MSG_RESULT([yes])
 769
 770         AC_MSG_CHECKING([if percpu_counter_inc takes the 2nd argument])
 771         LB_LINUX_TRY_COMPILE([
 772                 #include <linux/percpu_counter.h>
 773         ],[
 774                 struct percpu_counter c;
 775                 percpu_counter_init(&c, 0);
 776         ],[
 777                 AC_DEFINE(HAVE_PERCPU_2ND_ARG, 1, [percpu_counter_init has two
 778                                                    arguments])
 779                 AC_MSG_RESULT([yes])
 780         ],[
 781                 AC_MSG_RESULT([no])
 782         ])
 783 ],[
 784         AC_MSG_RESULT([no])
 785 ])
 786 ])
 787
 788 AC_DEFUN([LC_TASK_CLENV_STORE],
 789 [
 790         AC_MSG_CHECKING([if we can store cl_env in task_struct])
 791         if test x$have_task_clenv_store != xyes ; then
 792                 LC_TASK_CLENV_TUX_INFO
 793         fi
 794 ])
 795
 796 # ~2.6.11
 797
 798 AC_DEFUN([LC_S_TIME_GRAN],
 799 [AC_MSG_CHECKING([if super block has s_time_gran member])
 800 LB_LINUX_TRY_COMPILE([
 801         #include <linux/fs.h>
 802 ],[
 803         struct super_block sb;
 804
 805         return sb.s_time_gran;
 806 ],[
 807         AC_MSG_RESULT([yes])
 808         AC_DEFINE(HAVE_S_TIME_GRAN, 1, [super block has s_time_gran member])
 809 ],[
 810         AC_MSG_RESULT([no])
 811 ])
 812 ])
 813
 814 AC_DEFUN([LC_SB_TIME_GRAN],
 815 [AC_MSG_CHECKING([if kernel has old get_sb_time_gran])
 816 LB_LINUX_TRY_COMPILE([
 817         #include <linux/fs.h>
 818 ],[
 819         return get_sb_time_gran(NULL);
 820 ],[
 821         AC_MSG_RESULT([yes])
 822         AC_DEFINE(HAVE_SB_TIME_GRAN, 1, [kernel has old get_sb_time_gran])
 823 ],[
 824         AC_MSG_RESULT([no])
 825 ])
 826 ])
 827
 828 # 2.6.12
 829
 830 # ~2.6.12 merge patch from oracle to convert tree_lock from spinlock to rwlock
 831 AC_DEFUN([LC_RW_TREE_LOCK],
 832 [AC_MSG_CHECKING([if kernel has tree_lock as rwlock])
 833 tmp_flags="$EXTRA_KCFLAGS"
 834 EXTRA_KCFLAGS="-Werror"
 835 LB_LINUX_TRY_COMPILE([
 836         #include <linux/fs.h>
 837 ],[
 838         struct address_space a;
 839
 840         write_lock(&a.tree_lock);
 841 ],[
 842         AC_MSG_RESULT([yes])
 843         AC_DEFINE(HAVE_RW_TREE_LOCK, 1, [kernel has tree_lock as rw_lock])
 844 ],[
 845         AC_MSG_RESULT([no])
 846 ])
 847 EXTRA_KCFLAGS="$tmp_flags"
 848 ])
 849
 850 # LC_EXPORT_SYNCHRONIZE_RCU
 851 # after 2.6.12 synchronize_rcu is preferred over synchronize_kernel
 852 AC_DEFUN([LC_EXPORT_SYNCHRONIZE_RCU],
 853 [LB_CHECK_SYMBOL_EXPORT([synchronize_rcu],
 854 [kernel/rcupdate.c],[
 855         AC_DEFINE(HAVE_SYNCHRONIZE_RCU, 1,
 856                 [in 2.6.12 synchronize_rcu preferred over synchronize_kernel])
 857 ],[
 858 ])
 859 ])
 860
 861 # 2.6.15
 862
 863 # LC_INODE_I_MUTEX
 864 # after 2.6.15 inode have i_mutex intead of i_sem
 865 AC_DEFUN([LC_INODE_I_MUTEX],
 866 [AC_MSG_CHECKING([if inode has i_mutex ])
 867 LB_LINUX_TRY_COMPILE([
 868         #include <linux/mutex.h>
 869         #include <linux/fs.h>
 870         #undef i_mutex
 871 ],[
 872         struct inode i;
 873
 874         mutex_unlock(&i.i_mutex);
 875 ],[
 876         AC_MSG_RESULT(yes)
 877         AC_DEFINE(HAVE_INODE_I_MUTEX, 1,
 878                 [after 2.6.15 inode have i_mutex intead of i_sem])
 879 ],[
 880         AC_MSG_RESULT(no)
 881 ])
 882 ])
 883
 884 # 2.6.16
 885
 886 # LC_SECURITY_PLUG  # for SLES10 SP2
 887 # check security plug in sles10 sp2 kernel
 888 AC_DEFUN([LC_SECURITY_PLUG],
 889 [AC_MSG_CHECKING([If kernel has security plug support])
 890 LB_LINUX_TRY_COMPILE([
 891         #include <linux/fs.h>
 892 ],[
 893         struct dentry   *dentry;
 894         struct vfsmount *mnt;
 895         struct iattr    *iattr;
 896
 897         notify_change(dentry, mnt, iattr);
 898 ],[
 899         AC_MSG_RESULT(yes)
 900         AC_DEFINE(HAVE_SECURITY_PLUG, 1,
 901                 [SLES10 SP2 use extra parameter in vfs])
 902 ],[
 903         AC_MSG_RESULT(no)
 904 ])
 905 ])
 906
 907 # 2.6.17
 908
 909 # inode have i_private field since 2.6.17
 910 AC_DEFUN([LC_INODE_IPRIVATE],
 911 [AC_MSG_CHECKING([if inode has a i_private field])
 912 LB_LINUX_TRY_COMPILE([
 913 #include <linux/fs.h>
 914 ],[
 915         struct inode i;
 916         i.i_private = NULL;
 917 ],[
 918         AC_MSG_RESULT(yes)
 919         AC_DEFINE(HAVE_INODE_IPRIVATE, 1,
 920                 [struct inode has i_private field])
 921 ],[
 922         AC_MSG_RESULT(no)
 923 ])
 924 ])
 925
 926 # LC_DQUOTOFF_MUTEX
 927 # after 2.6.17 dquote use mutex instead if semaphore
 928 AC_DEFUN([LC_DQUOTOFF_MUTEX],
 929 [AC_MSG_CHECKING([use dqonoff_mutex])
 930 LB_LINUX_TRY_COMPILE([
 931         #include <linux/mutex.h>
 932         #include <linux/fs.h>
 933         #include <linux/quota.h>
 934 ],[
 935         struct quota_info dq;
 936
 937         mutex_unlock(&dq.dqonoff_mutex);
 938 ],[
 939         AC_MSG_RESULT(yes)
 940         AC_DEFINE(HAVE_DQUOTOFF_MUTEX, 1,
 941                 [after 2.6.17 dquote use mutex instead if semaphore])
 942 ],[
 943         AC_MSG_RESULT(no)
 944 ])
 945 ])
 946
 947 # 2.6.18
 948
 949 # LC_NR_PAGECACHE
 950 # 2.6.18 don't export nr_pagecahe
 951 AC_DEFUN([LC_NR_PAGECACHE],
 952 [AC_MSG_CHECKING([kernel export nr_pagecache])
 953 LB_LINUX_TRY_COMPILE([
 954         #include <linux/pagemap.h>
 955 ],[
 956         return atomic_read(&nr_pagecache);
 957 ],[
 958         AC_MSG_RESULT(yes)
 959         AC_DEFINE(HAVE_NR_PAGECACHE, 1,
 960                 [is kernel export nr_pagecache])
 961 ],[
 962         AC_MSG_RESULT(no)
 963 ])
 964 ])
 965
 966 #
 967 # LC_STATFS_DENTRY_PARAM
 968 # starting from 2.6.18 linux kernel uses dentry instead of
 969 # super_block for first vfs_statfs argument
 970 #
 971 AC_DEFUN([LC_STATFS_DENTRY_PARAM],
 972 [AC_MSG_CHECKING([first vfs_statfs parameter is dentry])
 973 LB_LINUX_TRY_COMPILE([
 974         #include <linux/fs.h>
 975 ],[
 976         int vfs_statfs(struct dentry *, struct kstatfs *);
 977 ],[
 978         AC_DEFINE(HAVE_STATFS_DENTRY_PARAM, 1,
 979                 [first parameter of vfs_statfs is dentry])
 980         AC_MSG_RESULT([yes])
 981 ],[
 982         AC_MSG_RESULT([no])
 983 ])
 984 ])
 985
 986 #
 987 # LC_VFS_KERN_MOUNT
 988 # starting from 2.6.18 kernel don't export do_kern_mount
 989 # and want to use vfs_kern_mount instead.
 990 #
 991 AC_DEFUN([LC_VFS_KERN_MOUNT],
 992 [AC_MSG_CHECKING([vfs_kern_mount exist in kernel])
 993 LB_LINUX_TRY_COMPILE([
 994         #include <linux/mount.h>
 995 ],[
 996         vfs_kern_mount(NULL, 0, NULL, NULL);
 997 ],[
 998         AC_DEFINE(HAVE_VFS_KERN_MOUNT, 1,
 999                 [vfs_kern_mount exist in kernel])
1000         AC_MSG_RESULT([yes])
1001 ],[
1002         AC_MSG_RESULT([no])
1003 ])
1004 ])
1005
1006 #
1007 # LC_INVALIDATEPAGE_RETURN_INT
1008 # 2.6.17 changes return type for invalidatepage to 'void' from 'int'
1009 #
1010 AC_DEFUN([LC_INVALIDATEPAGE_RETURN_INT],
1011 [AC_MSG_CHECKING([invalidatepage has return int])
1012 LB_LINUX_TRY_COMPILE([
1013         #include <linux/buffer_head.h>
1014 ],[
1015         int rc = block_invalidatepage(NULL, 0);
1016 ],[
1017         AC_MSG_RESULT(yes)
1018         AC_DEFINE(HAVE_INVALIDATEPAGE_RETURN_INT, 1,
1019                 [Define if return type of invalidatepage should be int])
1020 ],[
1021         AC_MSG_RESULT(no)
1022 ])
1023 ])
1024
1025 # LC_UMOUNTBEGIN_HAS_VFSMOUNT
1026 # after 2.6.18 umount_begin has different parameters
1027 AC_DEFUN([LC_UMOUNTBEGIN_HAS_VFSMOUNT],
1028 [AC_MSG_CHECKING([if umount_begin needs vfsmount parameter instead of super_block])
1029 tmp_flags="$EXTRA_KCFLAGS"
1030 EXTRA_KCFLAGS="-Werror"
1031 LB_LINUX_TRY_COMPILE([
1032         #include <linux/fs.h>
1033
1034         struct vfsmount;
1035         static void cfg_umount_begin (struct vfsmount *v, int flags)
1036         {
1037                 ;
1038         }
1039
1040         static struct super_operations cfg_super_operations = {
1041                 .umount_begin   = cfg_umount_begin,
1042         };
1043 ],[
1044         cfg_super_operations.umount_begin(NULL,0);
1045 ],[
1046         AC_MSG_RESULT(yes)
1047         AC_DEFINE(HAVE_UMOUNTBEGIN_VFSMOUNT, 1,
1048                 [Define umount_begin need second argument])
1049 ],[
1050         AC_MSG_RESULT(no)
1051 ])
1052 EXTRA_KCFLAGS="$tmp_flags"
1053 ])
1054
1055 # LC_SEQ_LOCK
1056 # after 2.6.18 seq_file has lock intead of sem
1057 AC_DEFUN([LC_SEQ_LOCK],
1058 [AC_MSG_CHECKING([if struct seq_file has lock field])
1059 LB_LINUX_TRY_COMPILE([
1060         #include <linux/seq_file.h>
1061 ],[
1062         struct seq_file seq;
1063
1064         mutex_unlock(&seq.lock);
1065 ],[
1066         AC_MSG_RESULT(yes)
1067         AC_DEFINE(HAVE_SEQ_LOCK, 1,
1068                 [after 2.6.18 seq_file has lock intead of sem])
1069 ],[
1070         AC_MSG_RESULT(NO)
1071 ])
1072 ])
1073
1074 #
1075 # LC_EXPORT_FILEMAP_FDATAWRITE_RANGE
1076 #
1077 # No standard kernels export this
1078 #
1079 AC_DEFUN([LC_EXPORT_FILEMAP_FDATAWRITE_RANGE],
1080 [LB_CHECK_SYMBOL_EXPORT([filemap_fdatawrite_range],
1081 [mm/filemap.c],[
1082 AC_DEFINE(HAVE_FILEMAP_FDATAWRITE_RANGE, 1,
1083             [filemap_fdatawrite_range is exported by the kernel])
1084 ],[
1085 ])
1086 ])
1087
1088 # LC_FLUSH_OWNER_ID
1089 # starting from 2.6.18 the file_operations .flush
1090 # method has a new "fl_owner_t id" parameter
1091 #
1092 AC_DEFUN([LC_FLUSH_OWNER_ID],
1093 [AC_MSG_CHECKING([if file_operations .flush has an fl_owner_t id])
1094 LB_LINUX_TRY_COMPILE([
1095         #include <linux/fs.h>
1096 ],[
1097         struct file_operations *fops = NULL;
1098         fl_owner_t id;
1099         int i;
1100
1101         i = fops->flush(NULL, id);
1102 ],[
1103         AC_DEFINE(HAVE_FLUSH_OWNER_ID, 1,
1104                 [file_operations .flush method has an fl_owner_t id])
1105         AC_MSG_RESULT([yes])
1106 ],[
1107         AC_MSG_RESULT([no])
1108 ])
1109 ])
1110
1111 #
1112 # LC_EXPORT_INVALIDATE_MAPPING_PAGES
1113 #
1114 # SLES9, RHEL4, RHEL5, vanilla 2.6.24 export invalidate_mapping_pages() but
1115 # SLES10 2.6.16 does not, for some reason.  For filter cache invalidation.
1116 #
1117 AC_DEFUN([LC_EXPORT_INVALIDATE_MAPPING_PAGES],
1118     [LB_CHECK_SYMBOL_EXPORT([invalidate_mapping_pages], [mm/truncate.c], [
1119          AC_DEFINE(HAVE_INVALIDATE_MAPPING_PAGES, 1,
1120                         [exported invalidate_mapping_pages])],
1121     [LB_CHECK_SYMBOL_EXPORT([invalidate_inode_pages], [mm/truncate.c], [
1122          AC_DEFINE(HAVE_INVALIDATE_INODE_PAGES, 1,
1123                         [exported invalidate_inode_pages])], [
1124        AC_MSG_ERROR([no way to invalidate pages])
1125   ])
1126     ],[])
1127 ])
1128
1129 #2.6.18 + RHEL5 (fc6)
1130
1131 # RHEL5 in FS-cache patch rename PG_checked flag into PG_fs_misc
1132 AC_DEFUN([LC_PG_FS_MISC],
1133 [AC_MSG_CHECKING([kernel has PG_fs_misc])
1134 LB_LINUX_TRY_COMPILE([
1135         #include <linux/mm.h>
1136         #include <linux/page-flags.h>
1137 ],[
1138         #ifndef PG_fs_misc
1139         #error PG_fs_misc not defined in kernel
1140         #endif
1141 ],[
1142         AC_MSG_RESULT(yes)
1143         AC_DEFINE(HAVE_PG_FS_MISC, 1,
1144                   [is kernel have PG_fs_misc])
1145 ],[
1146         AC_MSG_RESULT(no)
1147 ])
1148 ])
1149
1150 # RHEL5 PageChecked and SetPageChecked defined
1151 AC_DEFUN([LC_PAGE_CHECKED],
1152 [AC_MSG_CHECKING([kernel has PageChecked and SetPageChecked])
1153 LB_LINUX_TRY_COMPILE([
1154 #ifdef HAVE_LINUX_MMTYPES_H
1155         #include <linux/mm_types.h>
1156 #endif
1157         #include <linux/page-flags.h>
1158 ],[
1159         struct page *p;
1160
1161         /* before 2.6.26 this define*/
1162         #ifndef PageChecked
1163         /* 2.6.26 use function instead of define for it */
1164         SetPageChecked(p);
1165         PageChecked(p);
1166         #endif
1167 ],[
1168         AC_MSG_RESULT(yes)
1169         AC_DEFINE(HAVE_PAGE_CHECKED, 1,
1170                   [does kernel have PageChecked and SetPageChecked])
1171 ],[
1172         AC_MSG_RESULT(no)
1173 ])
1174 ])
1175
1176 #
1177 # LC_LINUX_FIEMAP_H
1178 #
1179 # If we have fiemap.h
1180 # after 2.6.27 use fiemap.h in include/linux
1181 #
1182 AC_DEFUN([LC_LINUX_FIEMAP_H],
1183 [LB_CHECK_FILE([$LINUX/include/linux/fiemap.h],[
1184         AC_MSG_CHECKING([if fiemap.h can be compiled])
1185         LB_LINUX_TRY_COMPILE([
1186                 #include <linux/types.h>
1187                 #include <linux/fiemap.h>
1188         ],[],[
1189                 AC_MSG_RESULT([yes])
1190                 AC_DEFINE(HAVE_LINUX_FIEMAP_H, 1, [Kernel has fiemap.h])
1191         ],[
1192                 AC_MSG_RESULT([no])
1193         ])
1194 ],
1195 [])
1196 ])
1197
1198 # 2.6.19
1199
1200 # 2.6.19 API changes
1201 # inode don't have i_blksize field
1202 AC_DEFUN([LC_INODE_BLKSIZE],
1203 [AC_MSG_CHECKING([inode has i_blksize field])
1204 LB_LINUX_TRY_COMPILE([
1205 #include <linux/fs.h>
1206 ],[
1207         struct inode i;
1208         i.i_blksize = 0;
1209 ],[
1210         AC_MSG_RESULT(yes)
1211         AC_DEFINE(HAVE_INODE_BLKSIZE, 1,
1212                 [struct inode has i_blksize field])
1213 ],[
1214         AC_MSG_RESULT(no)
1215 ])
1216 ])
1217
1218 # LC_VFS_READDIR_U64_INO
1219 # 2.6.19 use u64 for inode number instead of inode_t
1220 AC_DEFUN([LC_VFS_READDIR_U64_INO],
1221 [AC_MSG_CHECKING([check vfs_readdir need 64bit inode number])
1222 tmp_flags="$EXTRA_KCFLAGS"
1223 EXTRA_KCFLAGS="-Werror"
1224 LB_LINUX_TRY_COMPILE([
1225 #include <linux/fs.h>
1226         int fillonedir(void * __buf, const char * name, int namlen, loff_t offset,
1227                       u64 ino, unsigned int d_type)
1228         {
1229                 return 0;
1230         }
1231 ],[
1232         filldir_t filter;
1233
1234         filter = fillonedir;
1235         return 1;
1236 ],[
1237         AC_MSG_RESULT(yes)
1238         AC_DEFINE(HAVE_VFS_READDIR_U64_INO, 1,
1239                 [if vfs_readdir need 64bit inode number])
1240 ],[
1241         AC_MSG_RESULT(no)
1242 ])
1243 EXTRA_KCFLAGS="$tmp_flags"
1244 ])
1245
1246 # LC_FILE_WRITEV
1247 # 2.6.19 replaced writev with aio_write
1248 AC_DEFUN([LC_FILE_WRITEV],
1249 [AC_MSG_CHECKING([writev in fops])
1250 LB_LINUX_TRY_COMPILE([
1251         #include <linux/fs.h>
1252 ],[
1253         struct file_operations *fops = NULL;
1254         fops->writev = NULL;
1255 ],[
1256         AC_MSG_RESULT(yes)
1257         AC_DEFINE(HAVE_FILE_WRITEV, 1,
1258                 [use fops->writev])
1259 ],[
1260         AC_MSG_RESULT(no)
1261 ])
1262 ])
1263
1264 # LC_FILE_READV
1265 # 2.6.19 replaced readv with aio_read
1266 AC_DEFUN([LC_FILE_READV],
1267 [AC_MSG_CHECKING([readv in fops])
1268 LB_LINUX_TRY_COMPILE([
1269         #include <linux/fs.h>
1270 ],[
1271         struct file_operations *fops = NULL;
1272         fops->readv = NULL;
1273 ],[
1274         AC_MSG_RESULT(yes)
1275         AC_DEFINE(HAVE_FILE_READV, 1,
1276                 [use fops->readv])
1277 ],[
1278         AC_MSG_RESULT(no)
1279 ])
1280 ])
1281
1282 # 2.6.20
1283
1284 # LC_CANCEL_DIRTY_PAGE
1285 # 2.6.20 introduced cancel_dirty_page instead of clear_page_dirty.
1286 AC_DEFUN([LC_CANCEL_DIRTY_PAGE],
1287         [AC_MSG_CHECKING([kernel has cancel_dirty_page])
1288         # the implementation of cancel_dirty_page in OFED 1.4.1's SLES10 SP2
1289         # backport is broken, so ignore it
1290         if test -f $OFED_BACKPORT_PATH/linux/mm.h &&
1291            test "$(sed -ne '/^static inline void cancel_dirty_page(struct page \*page, unsigned int account_size)$/,/^}$/p' $OFED_BACKPORT_PATH/linux/mm.h | md5sum)" = "c518cb32d6394760c5bca14cb7538d3e  -"; then
1292                 AC_MSG_RESULT(no)
1293         else
1294                 LB_LINUX_TRY_COMPILE([
1295                         #include <linux/mm.h>
1296                         #include <linux/page-flags.h>
1297 ],[
1298                         cancel_dirty_page(NULL, 0);
1299 ],[
1300                         AC_MSG_RESULT(yes)
1301                         AC_DEFINE(HAVE_CANCEL_DIRTY_PAGE, 1,
1302                                   [kernel has cancel_dirty_page instead of clear_page_dirty])
1303 ],[
1304                         AC_MSG_RESULT(no)
1305 ])
1306         fi
1307 ])
1308
1309 # raid5-zerocopy patch
1310
1311 #
1312 # LC_PAGE_CONSTANT
1313 #
1314 # In order to support raid5 zerocopy patch, we have to patch the kernel to make
1315 # it support constant page, which means the page won't be modified during the
1316 # IO.
1317 #
1318 AC_DEFUN([LC_PAGE_CONSTANT],
1319 [AC_MSG_CHECKING([if kernel have PageConstant defined])
1320 LB_LINUX_TRY_COMPILE([
1321         #include <linux/mm.h>
1322         #include <linux/page-flags.h>
1323 ],[
1324         #ifndef PG_constant
1325         #error "Have no raid5 zcopy patch"
1326         #endif
1327 ],[
1328         AC_MSG_RESULT(yes)
1329         AC_DEFINE(HAVE_PAGE_CONSTANT, 1, [kernel have PageConstant supported])
1330 ],[
1331         AC_MSG_RESULT(no);
1332 ])
1333 ])
1334
1335 # 2.6.22
1336
1337 # 2.6.22 lost second parameter for invalidate_bdev
1338 AC_DEFUN([LC_INVALIDATE_BDEV_2ARG],
1339 [AC_MSG_CHECKING([if invalidate_bdev has second argument])
1340 LB_LINUX_TRY_COMPILE([
1341         #include <linux/buffer_head.h>
1342 ],[
1343         invalidate_bdev(NULL,0);
1344 ],[
1345         AC_MSG_RESULT([yes])
1346         AC_DEFINE(HAVE_INVALIDATE_BDEV_2ARG, 1,
1347                 [invalidate_bdev has second argument])
1348 ],[
1349         AC_MSG_RESULT([no])
1350 ])
1351 ])
1352
1353 #
1354 # check for crypto API
1355 #
1356 AC_DEFUN([LC_ASYNC_BLOCK_CIPHER],
1357 [AC_MSG_CHECKING([if kernel has block cipher support])
1358 LB_LINUX_TRY_COMPILE([
1359         #include <linux/err.h>
1360         #include <linux/crypto.h>
1361 ],[
1362         struct crypto_blkcipher *tfm;
1363         tfm = crypto_alloc_blkcipher("aes", 0, 0 );
1364 ],[
1365         AC_MSG_RESULT([yes])
1366         AC_DEFINE(HAVE_ASYNC_BLOCK_CIPHER, 1, [kernel has block cipher support])
1367 ],[
1368         AC_MSG_RESULT([no])
1369 ])
1370 ])
1371
1372 #
1373 # check for struct hash_desc
1374 #
1375 AC_DEFUN([LC_STRUCT_HASH_DESC],
1376 [AC_MSG_CHECKING([if kernel has struct hash_desc])
1377 LB_LINUX_TRY_COMPILE([
1378         #include <linux/err.h>
1379         #include <linux/crypto.h>
1380 ],[
1381         struct hash_desc foo;
1382 ],[
1383         AC_MSG_RESULT([yes])
1384         AC_DEFINE(HAVE_STRUCT_HASH_DESC, 1, [kernel has struct hash_desc])
1385 ],[
1386         AC_MSG_RESULT([no])
1387 ])
1388 ])
1389
1390 #
1391 # check for struct blkcipher_desc
1392 #
1393 AC_DEFUN([LC_STRUCT_BLKCIPHER_DESC],
1394 [AC_MSG_CHECKING([if kernel has struct blkcipher_desc])
1395 LB_LINUX_TRY_COMPILE([
1396         #include <linux/err.h>
1397         #include <linux/crypto.h>
1398 ],[
1399         struct blkcipher_desc foo;
1400 ],[
1401         AC_MSG_RESULT([yes])
1402         AC_DEFINE(HAVE_STRUCT_BLKCIPHER_DESC, 1, [kernel has struct blkcipher_desc])
1403 ],[
1404         AC_MSG_RESULT([no])
1405 ])
1406 ])
1407
1408 #
1409 # 2.6.19 check for FS_RENAME_DOES_D_MOVE flag
1410 #
1411 AC_DEFUN([LC_FS_RENAME_DOES_D_MOVE],
1412 [AC_MSG_CHECKING([if kernel has FS_RENAME_DOES_D_MOVE flag])
1413 LB_LINUX_TRY_COMPILE([
1414         #include <linux/fs.h>
1415 ],[
1416         int v = FS_RENAME_DOES_D_MOVE;
1417 ],[
1418         AC_MSG_RESULT([yes])
1419         AC_DEFINE(HAVE_FS_RENAME_DOES_D_MOVE, 1, [kernel has FS_RENAME_DOES_D_MOVE flag])
1420 ],[
1421         AC_MSG_RESULT([no])
1422 ])
1423 ])
1424
1425 # 2.6.23
1426
1427 # 2.6.23 have return type 'void' for unregister_blkdev
1428 AC_DEFUN([LC_UNREGISTER_BLKDEV_RETURN_INT],
1429 [AC_MSG_CHECKING([if unregister_blkdev return int])
1430 LB_LINUX_TRY_COMPILE([
1431         #include <linux/fs.h>
1432 ],[
1433         int i = unregister_blkdev(0,NULL);
1434 ],[
1435         AC_MSG_RESULT([yes])
1436         AC_DEFINE(HAVE_UNREGISTER_BLKDEV_RETURN_INT, 1,
1437                 [unregister_blkdev return int])
1438 ],[
1439         AC_MSG_RESULT([no])
1440 ])
1441 ])
1442
1443 # 2.6.23 change .sendfile to .splice_read
1444 AC_DEFUN([LC_KERNEL_SPLICE_READ],
1445 [AC_MSG_CHECKING([if kernel has .splice_read])
1446 LB_LINUX_TRY_COMPILE([
1447         #include <linux/fs.h>
1448 ],[
1449         struct file_operations file;
1450
1451         file.splice_read = NULL;
1452 ], [
1453         AC_MSG_RESULT([yes])
1454         AC_DEFINE(HAVE_KERNEL_SPLICE_READ, 1,
1455                 [kernel has .slice_read])
1456 ],[
1457         AC_MSG_RESULT([no])
1458 ])
1459 ])
1460
1461 # 2.6.23 change .sendfile to .splice_read
1462 # RHEL4 (-92 kernel) have both sendfile and .splice_read API
1463 AC_DEFUN([LC_KERNEL_SENDFILE],
1464 [AC_MSG_CHECKING([if kernel has .sendfile])
1465 LB_LINUX_TRY_COMPILE([
1466         #include <linux/fs.h>
1467 ],[
1468         struct file_operations file;
1469
1470         file.sendfile = NULL;
1471 ], [
1472         AC_MSG_RESULT([yes])
1473         AC_DEFINE(HAVE_KERNEL_SENDFILE, 1,
1474                 [kernel has .sendfile])
1475 ],[
1476         AC_MSG_RESULT([no])
1477 ])
1478 ])
1479
1480 # 2.6.23 extract nfs export related data into exportfs.h
1481 AC_DEFUN([LC_HAVE_EXPORTFS_H],
1482 [LB_CHECK_FILE([$LINUX/include/linux/exportfs.h], [
1483         AC_DEFINE(HAVE_LINUX_EXPORTFS_H, 1,
1484                 [kernel has include/exportfs.h])
1485 ],[
1486         AC_MSG_RESULT([no])
1487 ])
1488 ])
1489
1490 # 2.6.23 has new page fault handling API
1491 AC_DEFUN([LC_VM_OP_FAULT],
1492 [AC_MSG_CHECKING([kernel has .fault in vm_operation_struct])
1493 LB_LINUX_TRY_COMPILE([
1494         #include <linux/mm.h>
1495 ],[
1496         struct vm_operations_struct op;
1497
1498         op.fault = NULL;
1499 ], [
1500         AC_MSG_RESULT([yes])
1501         AC_DEFINE(HAVE_VM_OP_FAULT, 1,
1502                 [kernel has .fault in vm_operation_struct])
1503 ],[
1504         AC_MSG_RESULT([no])
1505 ])
1506 ])
1507
1508 # 2.6.23 add code to wait other users to complete before removing procfs entry
1509 AC_DEFUN([LC_PROCFS_USERS],
1510 [AC_MSG_CHECKING([if kernel has pde_users member in procfs entry struct])
1511 LB_LINUX_TRY_COMPILE([
1512         #include <linux/proc_fs.h>
1513 ],[
1514         struct proc_dir_entry pde;
1515
1516         pde.pde_users   = 0;
1517 ],[
1518         AC_MSG_RESULT([yes])
1519         AC_DEFINE(HAVE_PROCFS_USERS, 1,
1520                 [kernel has pde_users member in procfs entry struct])
1521 ],[
1522         AC_MSG_RESULT([no])
1523 ])
1524 ])
1525
1526 # 2.6.23 exports exportfs_decode_fh
1527 AC_DEFUN([LC_EXPORTFS_DECODE_FH],
1528 [LB_CHECK_SYMBOL_EXPORT([exportfs_decode_fh],
1529 [fs/exportfs/expfs.c],[
1530         AC_DEFINE(HAVE_EXPORTFS_DECODE_FH, 1,
1531                 [exportfs_decode_fh has been export])
1532 ],[
1533 ])
1534 ])
1535
1536 # 2.6.24
1537
1538 # 2.6.24 need linux/mm_types.h included
1539 AC_DEFUN([LC_HAVE_MMTYPES_H],
1540 [LB_CHECK_FILE([$LINUX/include/linux/mm_types.h], [
1541         AC_DEFINE(HAVE_LINUX_MMTYPES_H, 1,
1542                 [kernel has include/mm_types.h])
1543 ],[
1544         AC_MSG_RESULT([no])
1545 ])
1546 ])
1547
1548 # 2.6.24 has bio_endio with 2 args
1549 AC_DEFUN([LC_BIO_ENDIO_2ARG],
1550 [AC_MSG_CHECKING([if kernel has bio_endio with 2 args])
1551 LB_LINUX_TRY_COMPILE([
1552         #include <linux/bio.h>
1553 ],[
1554         bio_endio(NULL, 0);
1555 ], [
1556         AC_MSG_RESULT([yes])
1557         AC_DEFINE(HAVE_BIO_ENDIO_2ARG, 1,
1558                 [kernel has bio_endio with 2 args])
1559 ],[
1560         AC_MSG_RESULT([no])
1561 ])
1562 ])
1563
1564 # 2.6.24 has new members in exports struct.
1565 AC_DEFUN([LC_FH_TO_DENTRY],
1566 [AC_MSG_CHECKING([if kernel has .fh_to_dentry member in export_operations struct])
1567 LB_LINUX_TRY_COMPILE([
1568 #ifdef HAVE_LINUX_EXPORTFS_H
1569         #include <linux/exportfs.h>
1570 #else
1571         #include <linux/fs.h>
1572 #endif
1573 ],[
1574         struct export_operations exp;
1575
1576         exp.fh_to_dentry   = NULL;
1577 ], [
1578         AC_MSG_RESULT([yes])
1579         AC_DEFINE(HAVE_FH_TO_DENTRY, 1,
1580                 [kernel has .fh_to_dentry member in export_operations struct])
1581 ],[
1582         AC_MSG_RESULT([no])
1583 ])
1584 ])
1585
1586 # 2.6.24 removes long aged procfs entry -> deleted member
1587 AC_DEFUN([LC_PROCFS_DELETED],
1588 [AC_MSG_CHECKING([if kernel has deleted member in procfs entry struct])
1589 LB_LINUX_TRY_COMPILE([
1590         #include <linux/proc_fs.h>
1591 ],[
1592         struct proc_dir_entry pde;
1593
1594         pde.deleted   = NULL;
1595 ], [
1596         AC_MSG_RESULT([yes])
1597         AC_DEFINE(HAVE_PROCFS_DELETED, 1,
1598                 [kernel has deleted member in procfs entry struct])
1599 ],[
1600         AC_MSG_RESULT([no])
1601 ])
1602 ])
1603
1604 # 2.6.24 has bdi_init()/bdi_destroy() functions.
1605 AC_DEFUN([LC_EXPORT_BDI_INIT],
1606 [LB_CHECK_SYMBOL_EXPORT([bdi_init],
1607 [mm/backing-dev.c],[
1608         AC_DEFINE(HAVE_BDI_INIT, 1,
1609                 [bdi_init/bdi_destroy functions are present])
1610 ],[
1611 ])
1612 ])
1613
1614 # 2.6.25
1615
1616 # 2.6.25 change define to inline
1617 AC_DEFUN([LC_MAPPING_CAP_WRITEBACK_DIRTY],
1618 [AC_MSG_CHECKING([if kernel have mapping_cap_writeback_dirty])
1619 LB_LINUX_TRY_COMPILE([
1620         #include <linux/backing-dev.h>
1621 ],[
1622         #ifndef mapping_cap_writeback_dirty
1623         mapping_cap_writeback_dirty(NULL);
1624         #endif
1625 ],[
1626         AC_MSG_RESULT([yes])
1627         AC_DEFINE(HAVE_MAPPING_CAP_WRITEBACK_DIRTY, 1,
1628                 [kernel have mapping_cap_writeback_dirty])
1629 ],[
1630         AC_MSG_RESULT([no])
1631 ])
1632 ])
1633
1634 # 2.6.26
1635
1636 # 2.6.26 isn't export set_fs_pwd and change paramter in fs struct
1637 AC_DEFUN([LC_FS_STRUCT_USE_PATH],
1638 [AC_MSG_CHECKING([fs_struct use path structure])
1639 LB_LINUX_TRY_COMPILE([
1640         #include <asm/atomic.h>
1641         #include <linux/spinlock.h>
1642         #include <linux/fs_struct.h>
1643 ],[
1644         struct path path;
1645         struct fs_struct fs;
1646
1647         fs.pwd = path;
1648 ], [
1649         AC_MSG_RESULT([yes])
1650         AC_DEFINE(HAVE_FS_STRUCT_USE_PATH, 1,
1651                 [fs_struct use path structure])
1652 ],[
1653         AC_MSG_RESULT([no])
1654 ])
1655 ])
1656
1657 # 2.6.27
1658
1659 AC_DEFUN([LC_INODE_PERMISION_2ARGS],
1660 [AC_MSG_CHECKING([inode_operations->permission has two args])
1661 LB_LINUX_TRY_COMPILE([
1662         #include <linux/fs.h>
1663 ],[
1664         struct inode *inode;
1665
1666         inode->i_op->permission(NULL,0);
1667 ],[
1668         AC_DEFINE(HAVE_INODE_PERMISION_2ARGS, 1,
1669                   [inode_operations->permission has two args])
1670         AC_MSG_RESULT([yes])
1671 ],[
1672         AC_MSG_RESULT([no])
1673 ])
1674 ])
1675
1676 # 2.6.27 has file_remove_suid instead of remove_suid
1677 AC_DEFUN([LC_FILE_REMOVE_SUID],
1678 [AC_MSG_CHECKING([kernel has file_remove_suid])
1679 LB_LINUX_TRY_COMPILE([
1680         #include <linux/fs.h>
1681 ],[
1682         file_remove_suid(NULL);
1683 ],[
1684         AC_DEFINE(HAVE_FILE_REMOVE_SUID, 1,
1685                   [kernel have file_remove_suid])
1686         AC_MSG_RESULT([yes])
1687 ],[
1688         AC_MSG_RESULT([no])
1689 ])
1690 ])
1691
1692 # 2.6.27 have new page locking API
1693 AC_DEFUN([LC_TRYLOCKPAGE],
1694 [AC_MSG_CHECKING([kernel uses trylock_page for page lock])
1695 LB_LINUX_TRY_COMPILE([
1696         #include <linux/pagemap.h>
1697 ],[
1698         trylock_page(NULL);
1699 ],[
1700         AC_DEFINE(HAVE_TRYLOCK_PAGE, 1,
1701                   [kernel uses trylock_page for page lock])
1702         AC_MSG_RESULT([yes])
1703 ],[
1704         AC_MSG_RESULT([no])
1705 ])
1706 ])
1707
1708 # 2.6.27 removed the read_inode from super_operations.
1709 AC_DEFUN([LC_READ_INODE_IN_SBOPS],
1710 [AC_MSG_CHECKING([super_operations has a read_inode field])
1711 LB_LINUX_TRY_COMPILE([
1712         #include <linux/fs.h>
1713 ],[
1714         struct super_operations *sop;
1715         sop->read_inode(NULL);
1716 ],[
1717         AC_DEFINE(HAVE_READ_INODE_IN_SBOPS, 1,
1718                 [super_operations has a read_inode])
1719         AC_MSG_RESULT([yes])
1720 ],[
1721         AC_MSG_RESULT([no])
1722 ])
1723 ])
1724
1725 # 2.6.27 has inode_permission instead of permisson
1726 AC_DEFUN([LC_EXPORT_INODE_PERMISSION],
1727 [LB_CHECK_SYMBOL_EXPORT([inode_permission],
1728 [fs/namei.c],[
1729 AC_DEFINE(HAVE_EXPORT_INODE_PERMISSION, 1,
1730             [inode_permission is exported by the kernel])
1731 ],[
1732 ])
1733 ])
1734
1735 # 2.6.27 use 5th parameter in quota_on for remount.
1736 AC_DEFUN([LC_QUOTA_ON_5ARGS],
1737 [AC_MSG_CHECKING([quota_on needs 5 parameters])
1738 LB_LINUX_TRY_COMPILE([
1739         #include <linux/quota.h>
1740 ],[
1741         struct quotactl_ops *qop;
1742         qop->quota_on(NULL, 0, 0, NULL, 0);
1743 ],[
1744         AC_DEFINE(HAVE_QUOTA_ON_5ARGS, 1,
1745                 [quota_on needs 5 paramters])
1746         AC_MSG_RESULT([yes])
1747 ],[
1748         AC_MSG_RESULT([no])
1749 ])
1750 ])
1751
1752 # 2.6.27 use 3th parameter in quota_off for remount.
1753 AC_DEFUN([LC_QUOTA_OFF_3ARGS],
1754 [AC_MSG_CHECKING([quota_off needs 3 parameters])
1755 LB_LINUX_TRY_COMPILE([
1756         #include <linux/quota.h>
1757 ],[
1758         struct quotactl_ops *qop;
1759         qop->quota_off(NULL, 0, 0);
1760 ],[
1761         AC_DEFINE(HAVE_QUOTA_OFF_3ARGS, 1,
1762                 [quota_off needs 3 paramters])
1763         AC_MSG_RESULT([yes])
1764 ],[
1765         AC_MSG_RESULT([no])
1766 ])
1767 ])
1768
1769 # 2.6.27 has vfs_dq_off inline function.
1770 AC_DEFUN([LC_VFS_DQ_OFF],
1771 [AC_MSG_CHECKING([vfs_dq_off is defined])
1772 LB_LINUX_TRY_COMPILE([
1773         #include <linux/quotaops.h>
1774 ],[
1775         vfs_dq_off(NULL, 0);
1776 ],[
1777         AC_DEFINE(HAVE_VFS_DQ_OFF, 1, [vfs_dq_off is defined])
1778         AC_MSG_RESULT([yes])
1779 ],[
1780         AC_MSG_RESULT([no])
1781 ])
1782 ])
1783
1784 # LC_LOCK_MAP_ACQUIRE
1785 # after 2.6.27 lock_map_acquire replaces lock_acquire
1786 AC_DEFUN([LC_LOCK_MAP_ACQUIRE],
1787 [AC_MSG_CHECKING([if lock_map_acquire is defined])
1788 LB_LINUX_TRY_COMPILE([
1789         #include <linux/lockdep.h>
1790 ],[
1791         lock_map_acquire(NULL);
1792 ],[
1793         AC_MSG_RESULT(yes)
1794         AC_DEFINE(HAVE_LOCK_MAP_ACQUIRE, 1,
1795                 [lock_map_acquire is defined])
1796 ],[
1797         AC_MSG_RESULT(no)
1798 ])
1799 ])
1800
1801 # 2.6.27.15-2 sles11
1802
1803 # 2.6.27 sles11 remove the bi_hw_segments
1804 AC_DEFUN([LC_BI_HW_SEGMENTS],
1805 [AC_MSG_CHECKING([struct bio has a bi_hw_segments field])
1806 LB_LINUX_TRY_COMPILE([
1807         #include <linux/bio.h>
1808 ],[
1809         struct bio io;
1810         io.bi_hw_segments = 0;
1811 ],[
1812         AC_DEFINE(HAVE_BI_HW_SEGMENTS, 1,
1813                 [struct bio has a bi_hw_segments field])
1814         AC_MSG_RESULT([yes])
1815 ],[
1816         AC_MSG_RESULT([no])
1817 ])
1818 ])
1819
1820 #
1821 # 2.6.27 sles11 move the quotaio_v1{2}.h from include/linux to fs
1822 # 2.6.32 move the quotaio_v1{2}.h from fs to fs/quota
1823 AC_DEFUN([LC_HAVE_QUOTAIO_H],
1824 [LB_CHECK_FILE([$LINUX/include/linux/quotaio_v2.h],[
1825         AC_DEFINE(HAVE_QUOTAIO_H, 1,
1826                 [kernel has include/linux/quotaio_v2.h])
1827 ],[LB_CHECK_FILE([$LINUX/fs/quotaio_v2.h],[
1828                AC_DEFINE(HAVE_FS_QUOTAIO_H, 1,
1829                 [kernel has fs/quotaio_v1.h])
1830 ],[LB_CHECK_FILE([$LINUX/fs/quota/quotaio_v2.h],[
1831                AC_DEFINE(HAVE_FS_QUOTA_QUOTAIO_H, 1,
1832                 [kernel has fs/quota/quotaio_v2.h])
1833 ],[
1834         AC_MSG_RESULT([no])
1835 ])
1836 ])
1837 ])
1838 ])
1839
1840 # sles10 sp2 need 5 parameter for vfs_symlink
1841 AC_DEFUN([LC_VFS_SYMLINK_5ARGS],
1842 [AC_MSG_CHECKING([vfs_symlink need 5 parameter])
1843 LB_LINUX_TRY_COMPILE([
1844         #include <linux/fs.h>
1845 ],[
1846         struct inode *dir = NULL;
1847         struct dentry *dentry = NULL;
1848         struct vfsmount *mnt = NULL;
1849         const char * path = NULL;
1850         vfs_symlink(dir, dentry, mnt, path, 0);
1851 ],[
1852         AC_DEFINE(HAVE_VFS_SYMLINK_5ARGS, 1,
1853                 [vfs_symlink need 5 parameteres])
1854         AC_MSG_RESULT([yes])
1855 ],[
1856         AC_MSG_RESULT([no])
1857 ])
1858 ])
1859
1860 # 2.6.27 sles11 has sb_any_quota_active
1861 AC_DEFUN([LC_SB_ANY_QUOTA_ACTIVE],
1862 [AC_MSG_CHECKING([Kernel has sb_any_quota_active])
1863 LB_LINUX_TRY_COMPILE([
1864         #include <linux/quotaops.h>
1865 ],[
1866         sb_any_quota_active(NULL);
1867 ],[
1868         AC_DEFINE(HAVE_SB_ANY_QUOTA_ACTIVE, 1,
1869                 [Kernel has a sb_any_quota_active])
1870         AC_MSG_RESULT([yes])
1871 ],[
1872         AC_MSG_RESULT([no])
1873 ])
1874 ])
1875
1876 # 2.6.27 sles11 has sb_has_quota_active
1877 AC_DEFUN([LC_SB_HAS_QUOTA_ACTIVE],
1878 [AC_MSG_CHECKING([Kernel has sb_has_quota_active])
1879 LB_LINUX_TRY_COMPILE([
1880         #include <linux/quotaops.h>
1881 ],[
1882         sb_has_quota_active(NULL, 0);
1883 ],[
1884         AC_DEFINE(HAVE_SB_HAS_QUOTA_ACTIVE, 1,
1885                 [Kernel has a sb_has_quota_active])
1886         AC_MSG_RESULT([yes])
1887 ],[
1888         AC_MSG_RESULT([no])
1889 ])
1890 ])
1891
1892 # 2.6.27 exported add_to_page_cache_lru.
1893 AC_DEFUN([LC_EXPORT_ADD_TO_PAGE_CACHE_LRU],
1894 [LB_CHECK_SYMBOL_EXPORT([add_to_page_cache_lru],
1895 [mm/filemap.c],[
1896         AC_DEFINE(HAVE_ADD_TO_PAGE_CACHE_LRU, 1,
1897                 [add_to_page_cache_lru functions are present])
1898 ],[
1899 ])
1900 ])
1901
1902 # 2.6.31
1903
1904 # 2.6.30 x86 node_to_cpumask has been removed. must use cpumask_of_node
1905 AC_DEFUN([LC_EXPORT_CPUMASK_OF_NODE],
1906          [LB_CHECK_SYMBOL_EXPORT([node_to_cpumask_map],
1907                                  [arch/$LINUX_ARCH/mm/numa.c],
1908                                  [AC_DEFINE(HAVE_CPUMASK_OF_NODE, 1,
1909                                             [node_to_cpumask_map is exported by
1910                                              the kernel])]) # x86_64
1911          ])
1912
1913 # 2.6.31 replaces blk_queue_hardsect_size by blk_queue_logical_block_size function
1914 AC_DEFUN([LC_BLK_QUEUE_LOG_BLK_SIZE],
1915 [AC_MSG_CHECKING([if blk_queue_logical_block_size is defined])
1916 LB_LINUX_TRY_COMPILE([
1917         #include <linux/blkdev.h>
1918 ],[
1919         blk_queue_logical_block_size(NULL, 0);
1920 ],[
1921         AC_MSG_RESULT(yes)
1922         AC_DEFINE(HAVE_BLK_QUEUE_LOG_BLK_SIZE, 1,
1923                   [blk_queue_logical_block_size is defined])
1924 ],[
1925         AC_MSG_RESULT(no)
1926 ])
1927 ])
1928
1929 # 2.6.32
1930
1931 # 2.6.32 add a limits member in struct request_queue.
1932 AC_DEFUN([LC_REQUEST_QUEUE_LIMITS],
1933 [AC_MSG_CHECKING([if request_queue has a limits field])
1934 LB_LINUX_TRY_COMPILE([
1935         #include <linux/blkdev.h>
1936 ],[
1937         struct request_queue rq;
1938         rq.limits.io_min = 0;
1939 ],[
1940         AC_MSG_RESULT(yes)
1941         AC_DEFINE(HAVE_REQUEST_QUEUE_LIMITS, 1,
1942                   [request_queue has a limits field])
1943 ],[
1944         AC_MSG_RESULT(no)
1945 ])
1946 ])
1947
1948 # 2.6.32 has bdi_register() functions.
1949 AC_DEFUN([LC_EXPORT_BDI_REGISTER],
1950 [LB_CHECK_SYMBOL_EXPORT([bdi_register],
1951 [mm/backing-dev.c],[
1952         AC_DEFINE(HAVE_BDI_REGISTER, 1,
1953                 [bdi_register function is present])
1954 ],[
1955 ])
1956 ])
1957
1958 # 2.6.32 add s_bdi for super block
1959 AC_DEFUN([LC_SB_BDI],
1960 [AC_MSG_CHECKING([if super_block has s_bdi field])
1961 LB_LINUX_TRY_COMPILE([
1962         #include <linux/fs.h>
1963 ],[
1964         struct super_block sb;
1965         sb.s_bdi = NULL;
1966 ],[
1967         AC_MSG_RESULT(yes)
1968         AC_DEFINE(HAVE_SB_BDI, 1,
1969                   [super_block has s_bdi field])
1970 ],[
1971         AC_MSG_RESULT(no)
1972 ])
1973 ])
1974
1975 #  2.6.27.15-2 SuSE 11 sp0 kernels lack the name field for BDI
1976 AC_DEFUN([LC_BDI_NAME],
1977 [AC_MSG_CHECKING([if backing_device_info has name field])
1978 LB_LINUX_TRY_COMPILE([
1979         #include <linux/blkkdev.h>
1980 ],[
1981         struct backing_dev_info bdi;
1982         bdi.name = NULL;
1983 ],[
1984         AC_MSG_RESULT(yes)
1985         AC_DEFINE(HAVE_BDI_NAME, 1,
1986                   [backing_device_info has name field])
1987 ],[
1988         AC_MSG_RESULT(no)
1989 ])
1990 ])
1991
1992 # 2.6.32 removes blk_queue_max_sectors and add blk_queue_max_hw_sectors
1993 # check blk_queue_max_sectors and use it until disappear.
1994 AC_DEFUN([LC_BLK_QUEUE_MAX_SECTORS],
1995 [AC_MSG_CHECKING([if blk_queue_max_sectors is defined])
1996 LB_LINUX_TRY_COMPILE([
1997         #include <linux/blkdev.h>
1998 ],[
1999         blk_queue_max_sectors(NULL, 0);
2000 ],[
2001         AC_MSG_RESULT(yes)
2002         AC_DEFINE(HAVE_BLK_QUEUE_MAX_SECTORS, 1,
2003                   [blk_queue_max_sectors is defined])
2004 ],[
2005         AC_MSG_RESULT(no)
2006 ])
2007 ])
2008
2009 # 2.6.32 replaces 2 functions blk_queue_max_phys_segments and blk_queue_max_hw_segments by blk_queue_max_segments
2010 AC_DEFUN([LC_BLK_QUEUE_MAX_SEGMENTS],
2011 [AC_MSG_CHECKING([if blk_queue_max_segments is defined])
2012 LB_LINUX_TRY_COMPILE([
2013         #include <linux/blkdev.h>
2014 ],[
2015         blk_queue_max_segments(NULL, 0);
2016 ],[
2017         AC_MSG_RESULT(yes)
2018         AC_DEFINE(HAVE_BLK_QUEUE_MAX_SEGMENTS, 1,
2019                   [blk_queue_max_segments is defined])
2020 ],[
2021         AC_MSG_RESULT(no)
2022 ])
2023 ])
2024
2025 #
2026 # LC_QUOTA64
2027 #
2028 # Check if kernel has been patched for 64-bit quota limits support.
2029 # The upstream version of this patch in RHEL6 2.6.32 kernels introduces
2030 # the constant QFMT_VFS_V1 in include/linux/quota.h, so we can check for
2031 # that in the absence of quotaio_v1.h in the kernel headers.
2032 #
2033 AC_DEFUN([LC_QUOTA64],[
2034         AC_MSG_CHECKING([if kernel has 64-bit quota limits support])
2035 tmp_flags="$EXTRA_KCFLAGS"
2036 EXTRA_KCFLAGS="-I$LINUX/fs"
2037         LB_LINUX_TRY_COMPILE([
2038                 #include <linux/kernel.h>
2039                 #include <linux/fs.h>
2040                 #ifdef HAVE_QUOTAIO_H
2041                 # include <linux/quotaio_v2.h>
2042                 int versions[] = V2_INITQVERSIONS_R1;
2043                 struct v2_disk_dqblk_r1 dqblk_r1;
2044                 #elif defined(HAVE_FS_QUOTA_QUOTAIO_H)
2045                 # include <quota/quotaio_v2.h>
2046                 struct v2r1_disk_dqblk dqblk_r1;
2047                 #elif defined(HAVE_FS_QUOTAIO_H)
2048                 # include <quotaio_v2.h>
2049                 struct v2r1_disk_dqblk dqblk_r1;
2050                 #else
2051                 #include <linux/quota.h>
2052                 int ver = QFMT_VFS_V1;
2053                 #endif
2054         ],[],[
2055                 AC_DEFINE(HAVE_QUOTA64, 1, [have quota64])
2056                 AC_MSG_RESULT([yes])
2057         ],[
2058                 LB_CHECK_FILE([$LINUX/include/linux/lustre_version.h],[
2059                         AC_MSG_ERROR([You have got no 64-bit kernel quota support.])
2060                 ],[])
2061                 AC_MSG_RESULT([no])
2062         ])
2063 EXTRA_KCFLAGS=$tmp_flags
2064 ])
2065
2066 # 2.6.32 set_cpus_allowed is no more defined if CONFIG_CPUMASK_OFFSTACK=yes
2067 AC_DEFUN([LC_SET_CPUS_ALLOWED],
2068          [AC_MSG_CHECKING([if kernel defines set_cpus_allowed])
2069           LB_LINUX_TRY_COMPILE(
2070                 [#include <linux/sched.h>],
2071                 [struct task_struct *p = NULL;
2072                  cpumask_t mask = { { 0 } };
2073                  (void) set_cpus_allowed(p, mask);],
2074                 [AC_MSG_RESULT([yes])
2075                  AC_DEFINE(HAVE_SET_CPUS_ALLOWED, 1,
2076                            [set_cpus_allowed is exported by the kernel])],
2077                 [AC_MSG_RESULT([no])] )])
2078
2079 #
2080 # LC_D_OBTAIN_ALIAS
2081 # starting from 2.6.28 kernel replaces d_alloc_anon() with
2082 # d_obtain_alias() for getting anonymous dentries
2083 #
2084 AC_DEFUN([LC_D_OBTAIN_ALIAS],
2085 [AC_MSG_CHECKING([d_obtain_alias exist in kernel])
2086 LB_LINUX_TRY_COMPILE([
2087         #include <linux/dcache.h>
2088 ],[
2089         d_obtain_alias(NULL);
2090 ],[
2091         AC_DEFINE(HAVE_D_OBTAIN_ALIAS, 1,
2092                 [d_obtain_alias exist in kernel])
2093         AC_MSG_RESULT([yes])
2094 ],[
2095         AC_MSG_RESULT([no])
2096 ])
2097 ])
2098
2099 #
2100 # 2.6.38 export blkdev_get_by_dev
2101 #
2102 AC_DEFUN([LC_BLKDEV_GET_BY_DEV],
2103 [LB_CHECK_SYMBOL_EXPORT([blkdev_get_by_dev],
2104 [fs/block_dev.c],[
2105 AC_DEFINE(HAVE_BLKDEV_GET_BY_DEV, 1,
2106             [blkdev_get_by_dev is exported by the kernel])
2107 ],[
2108 ])
2109 ])
2110
2111 #
2112 # 2.6.39 remove unplug_fn from request_queue.
2113 #
2114 AC_DEFUN([LC_REQUEST_QUEUE_UNPLUG_FN],
2115 [AC_MSG_CHECKING([if request_queue has unplug_fn field])
2116 LB_LINUX_TRY_COMPILE([
2117         #include <linux/blkdev.h>
2118 ],[
2119         struct request_queue rq;
2120         memset(rq.unplug_fn, 0, sizeof(rq.unplug_fn));
2121 ],[
2122         AC_DEFINE(HAVE_REQUEST_QUEUE_UNPLUG_FN, 1,
2123                   [request_queue has unplug_fn field]),
2124         AC_MSG_RESULT([yes])
2125 ],[
2126         AC_MSG_RESULT([no])
2127 ])
2128 ])
2129
2130 #
2131 # LC_PROG_LINUX
2132 #
2133 # Lustre linux kernel checks
2134 #
2135 AC_DEFUN([LC_PROG_LINUX],
2136          [LC_LUSTRE_VERSION_H
2137          LC_CONFIG_PINGER
2138          LC_CONFIG_CHECKSUM
2139          LC_CONFIG_LIBLUSTRE_RECOVERY
2140          LC_CONFIG_HEALTH_CHECK_WRITE
2141          LC_CONFIG_LRU_RESIZE
2142          LC_QUOTA_MODULE
2143          LC_LLITE_LLOOP_MODULE
2144
2145          # RHEL4 patches
2146          LC_EXPORT_TRUNCATE_COMPLETE
2147          LC_EXPORT_TRUNCATE_RANGE
2148          LC_EXPORT_D_REHASH_COND
2149          LC_EXPORT___D_REHASH
2150          LC_EXPORT_NODE_TO_CPUMASK
2151
2152          LC_FUNC_GRAB_CACHE_PAGE_NOWAIT_GFP
2153          LC_STRUCT_STATFS
2154          LC_FILEMAP_POPULATE
2155          LC_D_ADD_UNIQUE
2156          LC_BIT_SPINLOCK_H
2157
2158          LC_XATTR_ACL
2159          LC_POSIX_ACL_XATTR_H
2160          LC_CONST_ACL_SIZE
2161
2162          LC_STRUCT_INTENT_FILE
2163
2164          LC_CAPA_CRYPTO
2165          LC_CONFIG_RMTCLIENT
2166          LC_CONFIG_GSS
2167          LC_FUNC_HAVE_CAN_SLEEP_ARG
2168          LC_FUNC_F_OP_FLOCK
2169          LC_QUOTA_READ
2170          LC_COOKIE_FOLLOW_LINK
2171          LC_FUNC_RCU
2172          LC_PERCPU_COUNTER
2173          LC_TASK_CLENV_STORE
2174
2175          # ~2.6.11
2176          LC_S_TIME_GRAN
2177          LC_SB_TIME_GRAN
2178
2179          # 2.6.12
2180          LC_RW_TREE_LOCK
2181          LC_EXPORT_SYNCHRONIZE_RCU
2182
2183          # 2.6.15
2184          LC_INODE_I_MUTEX
2185
2186          # 2.6.16
2187          LC_SECURITY_PLUG  # for SLES10 SP2
2188
2189          # 2.6.17
2190          LC_INODE_IPRIVATE
2191          LC_DQUOTOFF_MUTEX
2192
2193          # 2.6.18
2194          LC_NR_PAGECACHE
2195          LC_STATFS_DENTRY_PARAM
2196          LC_VFS_KERN_MOUNT
2197          LC_INVALIDATEPAGE_RETURN_INT
2198          LC_UMOUNTBEGIN_HAS_VFSMOUNT
2199          LC_SEQ_LOCK
2200          LC_EXPORT_FILEMAP_FDATAWRITE_RANGE
2201          LC_FLUSH_OWNER_ID
2202          if test x$enable_server = xyes ; then
2203                 LC_EXPORT_INVALIDATE_MAPPING_PAGES
2204          fi
2205
2206          #2.6.18 + RHEL5 (fc6)
2207          LC_PG_FS_MISC
2208          LC_PAGE_CHECKED
2209          LC_LINUX_FIEMAP_H
2210
2211          # 2.6.19
2212          LC_INODE_BLKSIZE
2213          LC_VFS_READDIR_U64_INO
2214          LC_FILE_WRITEV
2215          LC_FILE_READV
2216
2217          # 2.6.20
2218          LC_CANCEL_DIRTY_PAGE
2219
2220          # raid5-zerocopy patch
2221          LC_PAGE_CONSTANT
2222
2223          # 2.6.22
2224          LC_INVALIDATE_BDEV_2ARG
2225          LC_ASYNC_BLOCK_CIPHER
2226          LC_STRUCT_HASH_DESC
2227          LC_STRUCT_BLKCIPHER_DESC
2228          LC_FS_RENAME_DOES_D_MOVE
2229
2230          # 2.6.23
2231          LC_UNREGISTER_BLKDEV_RETURN_INT
2232          LC_KERNEL_SPLICE_READ
2233          LC_KERNEL_SENDFILE
2234          LC_HAVE_EXPORTFS_H
2235          LC_VM_OP_FAULT
2236          LC_PROCFS_USERS
2237          LC_EXPORTFS_DECODE_FH
2238
2239          # 2.6.24
2240          LC_HAVE_MMTYPES_H
2241          LC_BIO_ENDIO_2ARG
2242          LC_FH_TO_DENTRY
2243          LC_PROCFS_DELETED
2244          LC_EXPORT_BDI_INIT
2245
2246          #2.6.25
2247          LC_MAPPING_CAP_WRITEBACK_DIRTY
2248
2249          # 2.6.26
2250          LC_FS_STRUCT_USE_PATH
2251
2252          # 2.6.27
2253          LC_INODE_PERMISION_2ARGS
2254          LC_FILE_REMOVE_SUID
2255          LC_TRYLOCKPAGE
2256          LC_READ_INODE_IN_SBOPS
2257          LC_EXPORT_INODE_PERMISSION
2258          LC_QUOTA_ON_5ARGS
2259          LC_QUOTA_OFF_3ARGS
2260          LC_VFS_DQ_OFF
2261          LC_LOCK_MAP_ACQUIRE
2262
2263          # 2.6.27.15-2 sles11
2264          LC_BI_HW_SEGMENTS
2265          LC_HAVE_QUOTAIO_H
2266          LC_VFS_SYMLINK_5ARGS
2267          LC_BDI_NAME
2268          LC_SB_ANY_QUOTA_ACTIVE
2269          LC_SB_HAS_QUOTA_ACTIVE
2270          LC_EXPORT_ADD_TO_PAGE_CACHE_LRU
2271
2272          # 2.6.30
2273          LC_EXPORT_CPUMASK_OF_NODE
2274
2275          # 2.6.31
2276          LC_BLK_QUEUE_LOG_BLK_SIZE
2277
2278          # 2.6.32
2279          LC_REQUEST_QUEUE_LIMITS
2280          LC_EXPORT_BDI_REGISTER
2281          LC_SB_BDI
2282          LC_BLK_QUEUE_MAX_SECTORS
2283          LC_BLK_QUEUE_MAX_SEGMENTS
2284          LC_SET_CPUS_ALLOWED
2285
2286          # 2.6.38
2287          LC_BLKDEV_GET_BY_DEV
2288
2289          # 2.6.39
2290          LC_REQUEST_QUEUE_UNPLUG_FN
2291
2292          #
2293          if test x$enable_server = xyes ; then
2294              AC_DEFINE(HAVE_SERVER_SUPPORT, 1, [support server])
2295              LC_FUNC_DEV_SET_RDONLY
2296              LC_STACK_SIZE
2297              LC_QUOTA64
2298          fi
2299 ])
2300
2301 #
2302 # LC_CONFIG_CLIENT_SERVER
2303 #
2304 # Build client/server sides of Lustre
2305 #
2306 AC_DEFUN([LC_CONFIG_CLIENT_SERVER],
2307 [AC_MSG_CHECKING([whether to build Lustre server support])
2308 AC_ARG_ENABLE([server],
2309         AC_HELP_STRING([--disable-server],
2310                         [disable Lustre server support]),
2311         [],[enable_server='yes'])
2312 AC_MSG_RESULT([$enable_server])
2313
2314 AC_MSG_CHECKING([whether to build Lustre client support])
2315 AC_ARG_ENABLE([client],
2316         AC_HELP_STRING([--disable-client],
2317                         [disable Lustre client support]),
2318         [],[enable_client='yes'])
2319 AC_MSG_RESULT([$enable_client])])
2320
2321 #
2322 # LC_CONFIG_LIBLUSTRE
2323 #
2324 # whether to build liblustre
2325 #
2326 AC_DEFUN([LC_CONFIG_LIBLUSTRE],
2327 [AC_MSG_CHECKING([whether to build Lustre library])
2328 AC_ARG_ENABLE([liblustre],
2329         AC_HELP_STRING([--disable-liblustre],
2330                         [disable building of Lustre library]),
2331         [],[enable_liblustre=$with_sysio])
2332 AC_MSG_RESULT([$enable_liblustre])
2333 # only build sysio if liblustre is built
2334 with_sysio="$enable_liblustre"
2335
2336 AC_MSG_CHECKING([whether to build liblustre tests])
2337 AC_ARG_ENABLE([liblustre-tests],
2338         AC_HELP_STRING([--enable-liblustre-tests],
2339                         [enable liblustre tests, if --disable-tests is used]),
2340         [],[enable_liblustre_tests=$enable_tests])
2341 if test x$enable_liblustre != xyes ; then
2342    enable_liblustre_tests='no'
2343 fi
2344 AC_MSG_RESULT([$enable_liblustre_tests])
2345
2346 AC_MSG_CHECKING([whether to enable liblustre acl])
2347 AC_ARG_ENABLE([liblustre-acl],
2348         AC_HELP_STRING([--disable-liblustre-acl],
2349                         [disable ACL support for liblustre]),
2350         [],[enable_liblustre_acl=yes])
2351 AC_MSG_RESULT([$enable_liblustre_acl])
2352 if test x$enable_liblustre_acl = xyes ; then
2353   AC_DEFINE(LIBLUSTRE_POSIX_ACL, 1, Liblustre Support ACL-enabled MDS)
2354 fi
2355
2356 # 2.6.29 change prepare/commit_write to write_begin/end
2357 AC_DEFUN([LC_WRITE_BEGIN_END],
2358 [AC_MSG_CHECKING([if kernel has .write_begin/end])
2359 LB_LINUX_TRY_COMPILE([
2360         #include <linux/fs.h>
2361         #include <linux/pagemap.h>
2362 #ifdef HAVE_LINUX_MMTYPES_H
2363         #include <linux/mm_types.h>
2364 #endif
2365 ],[
2366         struct address_space_operations aops;
2367         struct page *page;
2368
2369         aops.write_begin = NULL;
2370         aops.write_end = NULL;
2371         page = grab_cache_page_write_begin(NULL, 0, 0);
2372 ], [
2373         AC_MSG_RESULT([yes])
2374         AC_DEFINE(HAVE_KERNEL_WRITE_BEGIN_END, 1,
2375                 [kernel has .write_begin/end])
2376 ],[
2377         AC_MSG_RESULT([no])
2378 ])
2379 ])
2380
2381 # 2.6.29 blkdev_put has 2 arguments
2382 AC_DEFUN([LC_BLKDEV_PUT_2ARGS],
2383 [AC_MSG_CHECKING([blkdev_put needs 2 parameters])
2384 LB_LINUX_TRY_COMPILE([
2385         #include <linux/fs.h>
2386 ],[
2387         blkdev_put(NULL, 0);
2388 ],[
2389         AC_DEFINE(HAVE_BLKDEV_PUT_2ARGS, 1,
2390                 [blkdev_put needs 2 paramters])
2391         AC_MSG_RESULT([yes])
2392 ],[
2393         AC_MSG_RESULT([no])
2394 ])
2395 ])
2396
2397 # 2.6.29 dentry_open has 4 arguments
2398 AC_DEFUN([LC_DENTRY_OPEN_4ARGS],
2399 [AC_MSG_CHECKING([dentry_open needs 4 parameters])
2400 LB_LINUX_TRY_COMPILE([
2401         #include <linux/fs.h>
2402 ],[
2403         dentry_open(NULL, NULL, 0, NULL);
2404 ],[
2405         AC_DEFINE(HAVE_DENTRY_OPEN_4ARGS, 1,
2406                 [dentry_open needs 4 paramters])
2407         AC_MSG_RESULT([yes])
2408 ],[
2409         AC_MSG_RESULT([no])
2410 ])
2411 ])
2412
2413 # 2.6.29 split file and anonymous page queues
2414 AC_DEFUN([LC_PAGEVEC_LRU_ADD_FILE],
2415 [AC_MSG_CHECKING([if kernel has .pagevec_lru_add_file])
2416 LB_LINUX_TRY_COMPILE([
2417         #include <linux/mm.h>
2418         #include <linux/pagevec.h>
2419 ],[
2420         struct pagevec lru_pagevec;
2421
2422         pagevec_init(&lru_pagevec, 0);
2423         pagevec_lru_add_file(&lru_pagevec);
2424 ],[
2425         AC_MSG_RESULT([yes])
2426         AC_DEFINE(HAVE_PAGEVEC_LRU_ADD_FILE, 1,
2427                 [kernel has .pagevec_lru_add_file])
2428 ],[
2429         AC_MSG_RESULT([no])
2430 ])
2431 ])
2432
2433 #
2434 # --enable-mpitest
2435 #
2436 AC_ARG_ENABLE(mpitests,
2437         AC_HELP_STRING([--enable-mpitests=yes|no|mpicc wrapper],
2438                            [include mpi tests]),
2439         [
2440          enable_mpitests=yes
2441          case $enableval in
2442          yes)
2443                 MPICC_WRAPPER=mpicc
2444                 ;;
2445          no)
2446                 enable_mpitests=no
2447                 ;;
2448          *)
2449                 MPICC_WRAPPER=$enableval
2450                  ;;
2451          esac
2452         ],
2453         [
2454         MPICC_WRAPPER=mpicc
2455         enable_mpitests=yes
2456         ]
2457 )
2458
2459 if test x$enable_mpitests != xno; then
2460         AC_MSG_CHECKING([whether mpitests can be built])
2461         oldcc=$CC
2462         CC=$MPICC_WRAPPER
2463         AC_LINK_IFELSE(
2464             [AC_LANG_PROGRAM([[
2465                     #include <mpi.h>
2466                 ]],[[
2467                     int flag;
2468                     MPI_Initialized(&flag);
2469                 ]])],
2470             [
2471                     AC_MSG_RESULT([yes])
2472             ],[
2473                     AC_MSG_RESULT([no])
2474                     enable_mpitests=no
2475         ])
2476         CC=$oldcc
2477 fi
2478 AC_SUBST(MPICC_WRAPPER)
2479
2480 AC_MSG_NOTICE([Enabling Lustre configure options for libsysio])
2481 ac_configure_args="$ac_configure_args --with-lustre-hack --with-sockets"
2482
2483 LC_CONFIG_PINGER
2484 LC_CONFIG_LIBLUSTRE_RECOVERY
2485 ])
2486
2487 #
2488 # LC_CONFIG_QUOTA
2489 #
2490 # whether to enable quota support global control
2491 #
2492 AC_DEFUN([LC_CONFIG_QUOTA],
2493 [AC_ARG_ENABLE([quota],
2494         AC_HELP_STRING([--enable-quota],
2495                         [enable quota support]),
2496         [],[enable_quota='yes'])
2497 ])
2498
2499 AC_DEFUN([LC_QUOTA],
2500 [#check global
2501 LC_CONFIG_QUOTA
2502 #check for utils
2503 AC_CHECK_HEADER(sys/quota.h,
2504                 [AC_DEFINE(HAVE_SYS_QUOTA_H, 1, [Define to 1 if you have <sys/quota.h>.])],
2505                 [AC_MSG_ERROR([don't find <sys/quota.h> in your system])])
2506 ])
2507
2508 #
2509 # LC_CONFIG_SPLIT
2510 #
2511 # whether to enable split support
2512 #
2513 AC_DEFUN([LC_CONFIG_SPLIT],
2514 [AC_MSG_CHECKING([whether to enable split support])
2515 AC_ARG_ENABLE([split],
2516         AC_HELP_STRING([--enable-split],
2517                         [enable split support]),
2518         [],[enable_split='no'])
2519 AC_MSG_RESULT([$enable_split])
2520 if test x$enable_split != xno; then
2521    AC_DEFINE(HAVE_SPLIT_SUPPORT, 1, [enable split support])
2522 fi
2523 ])
2524
2525 AC_DEFUN([LC_TASK_CLENV_TUX_INFO],
2526 [AC_MSG_CHECKING([tux_info])
2527 LB_LINUX_TRY_COMPILE([
2528         #include <linux/sched.h>
2529 ],[
2530         struct task_struct task;
2531         &task.tux_info;
2532 ],[
2533         AC_MSG_RESULT([yes])
2534         AC_DEFINE(LL_TASK_CL_ENV, tux_info, [have tux_info])
2535         have_task_clenv_store='yes'
2536 ],[
2537         AC_MSG_RESULT([no])
2538 ])
2539 ])
2540
2541 #
2542 # LC_LLITE_LLOOP_MODULE
2543 # lloop_llite.ko does not currently work with page sizes
2544 # of 64k or larger.
2545 #
2546 AC_DEFUN([LC_LLITE_LLOOP_MODULE],
2547 [AC_MSG_CHECKING([whether to enable llite_lloop module])
2548 LB_LINUX_TRY_COMPILE([
2549         #include <asm/page.h>
2550 ],[
2551         #if PAGE_SIZE >= 65536
2552         #error "PAGE_SIZE >= 65536"
2553         #endif
2554 ],[
2555         enable_llite_lloop_module='yes'
2556         AC_MSG_RESULT([yes])
2557 ],[
2558         enable_llite_lloop_module='no'
2559         AC_MSG_RESULT([no])
2560 ])
2561 ])
2562
2563 #
2564 # LC_CONFIGURE
2565 #
2566 # other configure checks
2567 #
2568 AC_DEFUN([LC_CONFIGURE],
2569 [LC_CONFIG_OBD_BUFFER_SIZE
2570
2571 if test $target_cpu == "i686" -o $target_cpu == "x86_64"; then
2572         CFLAGS="$CFLAGS -Werror"
2573 fi
2574
2575 # maximum MDS thread count
2576 LC_MDS_MAX_THREADS
2577
2578 # include/liblustre.h
2579 AC_CHECK_HEADERS([sys/user.h sys/vfs.h stdint.h blkid/blkid.h])
2580
2581 # liblustre/llite_lib.h
2582 AC_CHECK_HEADERS([xtio.h file.h])
2583
2584 # liblustre/dir.c
2585 AC_CHECK_HEADERS([linux/types.h sys/types.h linux/unistd.h unistd.h])
2586
2587 # liblustre/lutil.c
2588 AC_CHECK_HEADERS([netinet/in.h arpa/inet.h catamount/data.h])
2589 AC_CHECK_FUNCS([inet_ntoa])
2590
2591 # libsysio/src/readlink.c
2592 LC_READLINK_SSIZE_T
2593
2594 # lvfs/prng.c - depends on linux/types.h from liblustre/dir.c
2595 AC_CHECK_HEADERS([linux/random.h], [], [],
2596                  [#ifdef HAVE_LINUX_TYPES_H
2597                   # include <linux/types.h>
2598                   #endif
2599                  ])
2600
2601 # utils/llverfs.c
2602 AC_CHECK_HEADERS([ext2fs/ext2fs.h])
2603
2604 # check for -lz support
2605 ZLIB=""
2606 AC_CHECK_LIB([z],
2607              [adler32],
2608              [AC_CHECK_HEADERS([zlib.h],
2609                                [ZLIB="-lz"
2610                                 AC_DEFINE([HAVE_ADLER], 1,
2611                                           [support alder32 checksum type])],
2612                                [AC_MSG_WARN([No zlib-devel package found,
2613                                              unable to use adler32 checksum])])],
2614              [AC_MSG_WARN([No zlib package found, unable to use adler32 checksum])]
2615 )
2616 AC_SUBST(ZLIB)
2617
2618 # Super safe df
2619 AC_ARG_ENABLE([mindf],
2620       AC_HELP_STRING([--enable-mindf],
2621                       [Make statfs report the minimum available space on any single OST instead of the sum of free space on all OSTs]),
2622       [],[])
2623 if test "$enable_mindf" = "yes" ;  then
2624       AC_DEFINE([MIN_DF], 1, [Report minimum OST free space])
2625 fi
2626
2627 AC_ARG_ENABLE([fail_alloc],
2628         AC_HELP_STRING([--disable-fail-alloc],
2629                 [disable randomly alloc failure]),
2630         [],[enable_fail_alloc=yes])
2631 AC_MSG_CHECKING([whether to randomly failing memory alloc])
2632 AC_MSG_RESULT([$enable_fail_alloc])
2633 if test x$enable_fail_alloc != xno ; then
2634         AC_DEFINE([RANDOM_FAIL_ALLOC], 1, [enable randomly alloc failure])
2635 fi
2636
2637 AC_ARG_ENABLE([invariants],
2638         AC_HELP_STRING([--enable-invariants],
2639                 [enable invariant checking (cpu intensive)]),
2640         [],[])
2641 AC_MSG_CHECKING([whether to check invariants (expensive cpu-wise)])
2642 AC_MSG_RESULT([$enable_invariants])
2643 if test x$enable_invariants = xyes ; then
2644         AC_DEFINE([INVARIANT_CHECK], 1, [enable invariant checking])
2645 fi
2646
2647 AC_ARG_ENABLE([lu_ref],
2648         AC_HELP_STRING([--enable-lu_ref],
2649                 [enable lu_ref reference tracking code]),
2650         [],[])
2651 AC_MSG_CHECKING([whether to track references with lu_ref])
2652 AC_MSG_RESULT([$enable_lu_ref])
2653 if test x$enable_lu_ref = xyes ; then
2654         AC_DEFINE([USE_LU_REF], 1, [enable lu_ref reference tracking code])
2655 fi
2656
2657 AC_ARG_ENABLE([pgstate-track],
2658               AC_HELP_STRING([--enable-pgstate-track],
2659                              [enable page state tracking]),
2660               [enable_pgstat_track='yes'],[])
2661 AC_MSG_CHECKING([whether to enable page state tracking])
2662 AC_MSG_RESULT([$enable_pgstat_track])
2663 if test x$enable_pgstat_track = xyes ; then
2664         AC_DEFINE([LUSTRE_PAGESTATE_TRACKING], 1,
2665                   [enable page state tracking code])
2666 fi
2667
2668          #2.6.29
2669          LC_WRITE_BEGIN_END
2670          LC_D_OBTAIN_ALIAS
2671          LC_BLKDEV_PUT_2ARGS
2672          LC_DENTRY_OPEN_4ARGS
2673          LC_PAGEVEC_LRU_ADD_FILE
2674
2675 ])
2676
2677 #
2678 # LC_CONDITIONALS
2679 #
2680 # AM_CONDITIONALS for lustre
2681 #
2682 AC_DEFUN([LC_CONDITIONALS],
2683 [AM_CONDITIONAL(LIBLUSTRE, test x$enable_liblustre = xyes)
2684 AM_CONDITIONAL(USE_QUILT, test x$QUILT != xno)
2685 AM_CONDITIONAL(LIBLUSTRE_TESTS, test x$enable_liblustre_tests = xyes)
2686 AM_CONDITIONAL(MPITESTS, test x$enable_mpitests = xyes, Build MPI Tests)
2687 AM_CONDITIONAL(CLIENT, test x$enable_client = xyes)
2688 AM_CONDITIONAL(SERVER, test x$enable_server = xyes)
2689 AM_CONDITIONAL(QUOTA, test x$enable_quota_module = xyes)
2690 AM_CONDITIONAL(SPLIT, test x$enable_split = xyes)
2691 AM_CONDITIONAL(BLKID, test x$ac_cv_header_blkid_blkid_h = xyes)
2692 AM_CONDITIONAL(EXT2FS_DEVEL, test x$ac_cv_header_ext2fs_ext2fs_h = xyes)
2693 AM_CONDITIONAL(GSS, test x$enable_gss = xyes)
2694 AM_CONDITIONAL(GSS_KEYRING, test x$enable_gss_keyring = xyes)
2695 AM_CONDITIONAL(GSS_PIPEFS, test x$enable_gss_pipefs = xyes)
2696 AM_CONDITIONAL(LIBPTHREAD, test x$enable_libpthread = xyes)
2697 AM_CONDITIONAL(LLITE_LLOOP, test x$enable_llite_lloop_module = xyes)
2698 ])
2699
2700 #
2701 # LC_CONFIG_FILES
2702 #
2703 # files that should be generated with AC_OUTPUT
2704 #
2705 AC_DEFUN([LC_CONFIG_FILES],
2706 [AC_CONFIG_FILES([
2707 lustre/Makefile
2708 lustre/autoMakefile
2709 lustre/autoconf/Makefile
2710 lustre/conf/Makefile
2711 lustre/contrib/Makefile
2712 lustre/doc/Makefile
2713 lustre/include/Makefile
2714 lustre/include/lustre_ver.h
2715 lustre/include/linux/Makefile
2716 lustre/include/lustre/Makefile
2717 lustre/kernel_patches/targets/2.6-rhel6.target
2718 lustre/kernel_patches/targets/2.6-rhel5.target
2719 lustre/kernel_patches/targets/2.6-sles10.target
2720 lustre/kernel_patches/targets/2.6-sles11.target
2721 lustre/kernel_patches/targets/2.6-oel5.target
2722 lustre/kernel_patches/targets/2.6-fc11.target
2723 lustre/kernel_patches/targets/2.6-fc12.target
2724 lustre/ldlm/Makefile
2725 lustre/fid/Makefile
2726 lustre/fid/autoMakefile
2727 lustre/liblustre/Makefile
2728 lustre/liblustre/tests/Makefile
2729 lustre/liblustre/tests/mpi/Makefile
2730 lustre/llite/Makefile
2731 lustre/llite/autoMakefile
2732 lustre/lclient/Makefile
2733 lustre/lov/Makefile
2734 lustre/lov/autoMakefile
2735 lustre/lvfs/Makefile
2736 lustre/lvfs/autoMakefile
2737 lustre/mdc/Makefile
2738 lustre/mdc/autoMakefile
2739 lustre/lmv/Makefile
2740 lustre/lmv/autoMakefile
2741 lustre/mds/Makefile
2742 lustre/mds/autoMakefile
2743 lustre/mdt/Makefile
2744 lustre/mdt/autoMakefile
2745 lustre/cmm/Makefile
2746 lustre/cmm/autoMakefile
2747 lustre/mdd/Makefile
2748 lustre/mdd/autoMakefile
2749 lustre/fld/Makefile
2750 lustre/fld/autoMakefile
2751 lustre/obdclass/Makefile
2752 lustre/obdclass/autoMakefile
2753 lustre/obdclass/linux/Makefile
2754 lustre/obdecho/Makefile
2755 lustre/obdecho/autoMakefile
2756 lustre/obdfilter/Makefile
2757 lustre/obdfilter/autoMakefile
2758 lustre/osc/Makefile
2759 lustre/osc/autoMakefile
2760 lustre/ost/Makefile
2761 lustre/ost/autoMakefile
2762 lustre/osd-ldiskfs/Makefile
2763 lustre/osd-ldiskfs/autoMakefile
2764 lustre/mgc/Makefile
2765 lustre/mgc/autoMakefile
2766 lustre/mgs/Makefile
2767 lustre/mgs/autoMakefile
2768 lustre/ptlrpc/Makefile
2769 lustre/ptlrpc/autoMakefile
2770 lustre/ptlrpc/gss/Makefile
2771 lustre/ptlrpc/gss/autoMakefile
2772 lustre/quota/Makefile
2773 lustre/quota/autoMakefile
2774 lustre/scripts/Makefile
2775 lustre/tests/Makefile
2776 lustre/tests/mpi/Makefile
2777 lustre/utils/Makefile
2778 lustre/utils/gss/Makefile
2779 lustre/obdclass/darwin/Makefile
2780 ])
2781 ])