lustre/autoconf/lustre-core.m4

   1 #
   2 # LC_CONFIG_SRCDIR
   3 #
   4 # Wrapper for AC_CONFIG_SUBDIR
   5 #
   6 AC_DEFUN([LC_CONFIG_SRCDIR],
   7 [AC_CONFIG_SRCDIR([lustre/obdclass/obdo.c])
   8 libcfs_is_module=yes
   9 ldiskfs_is_ext4=yes
  10 ])
  11
  12 #
  13 # LC_PATH_DEFAULTS
  14 #
  15 # lustre specific paths
  16 #
  17 AC_DEFUN([LC_PATH_DEFAULTS],
  18 [# ptlrpc kernel build requires this
  19 LUSTRE="$PWD/lustre"
  20 AC_SUBST(LUSTRE)
  21
  22 # mount.lustre
  23 rootsbindir='$(CROSS_PATH)/sbin'
  24 AC_SUBST(rootsbindir)
  25
  26 demodir='$(docdir)/demo'
  27 AC_SUBST(demodir)
  28
  29 pkgexampledir='${pkgdatadir}/examples'
  30 AC_SUBST(pkgexampledir)
  31 ])
  32
  33 #
  34 # LC_TARGET_SUPPORTED
  35 #
  36 # is the target os supported?
  37 #
  38 AC_DEFUN([LC_TARGET_SUPPORTED],
  39 [case $target_os in
  40         linux* | darwin*)
  41 $1
  42                 ;;
  43         *)
  44 $2
  45                 ;;
  46 esac
  47 ])
  48
  49 #
  50 # LC_CONFIG_OBD_BUFFER_SIZE
  51 #
  52 # the maximum buffer size of lctl ioctls
  53 #
  54 AC_DEFUN([LC_CONFIG_OBD_BUFFER_SIZE],
  55 [AC_MSG_CHECKING([maximum OBD ioctl size])
  56 AC_ARG_WITH([obd-buffer-size],
  57         AC_HELP_STRING([--with-obd-buffer-size=[size]],
  58                         [set lctl ioctl maximum bytes (default=8192)]),
  59         [
  60                 OBD_BUFFER_SIZE=$with_obd_buffer_size
  61         ],[
  62                 OBD_BUFFER_SIZE=8192
  63         ])
  64 AC_MSG_RESULT([$OBD_BUFFER_SIZE bytes])
  65 AC_DEFINE_UNQUOTED(CONFIG_LUSTRE_OBD_MAX_IOCTL_BUFFER, $OBD_BUFFER_SIZE, [IOCTL Buffer Size])
  66 ])
  67
  68 #
  69 # LC_READLINK_SSIZE_T
  70 #
  71 AC_DEFUN([LC_READLINK_SSIZE_T],
  72 [AC_MSG_CHECKING([if readlink returns ssize_t])
  73 AC_TRY_COMPILE([
  74         #include <unistd.h>
  75 ],[
  76         ssize_t readlink(const char *, char *, size_t);
  77 ],[
  78         AC_MSG_RESULT([yes])
  79         AC_DEFINE(HAVE_POSIX_1003_READLINK, 1, [readlink returns ssize_t])
  80 ],[
  81         AC_MSG_RESULT([no])
  82 ])
  83 ])
  84
  85 #
  86 # LC_FUNC_DEV_SET_RDONLY
  87 #
  88 # check whether dev_set_rdonly is exported.  This is needed until we
  89 # have another mechanism to fence IO from the underlying device.
  90 #
  91 AC_DEFUN([LC_FUNC_DEV_SET_RDONLY],
  92 [LB_CHECK_SYMBOL_EXPORT([dev_set_rdonly],
  93 [block/ll_rw_block.c,block/blk-core.c],[
  94         AC_DEFINE(HAVE_DEV_SET_RDONLY, 1, [kernel exports dev_set_rdonly])
  95 ],[
  96         AC_MSG_WARN([kernel missing dev_set_rdonly patch for testing])
  97 ])
  98 ])
  99
 100 #
 101 # Ensure stack size big than 8k in Lustre server (all kernels)
 102 #
 103 AC_DEFUN([LC_STACK_SIZE],
 104 [AC_MSG_CHECKING([stack size big than 8k])
 105 LB_LINUX_TRY_COMPILE([
 106         #include <linux/thread_info.h>
 107 ],[
 108         #if THREAD_SIZE < 8192
 109         #error "stack size < 8192"
 110         #endif
 111 ],[
 112         AC_MSG_RESULT(yes)
 113 ],[
 114         AC_MSG_ERROR([Lustre requires that Linux is configured with at least a 8KB stack.])
 115 ])
 116 ])
 117
 118 #
 119 # Allow the user to set the MDS thread upper limit
 120 #
 121 AC_DEFUN([LC_MDS_MAX_THREADS],
 122 [
 123         AC_ARG_WITH([mds_max_threads],
 124         AC_HELP_STRING([--with-mds-max-threads=count],
 125                        [maximum threads available on the MDS: (default=512)]),
 126         [
 127                 MDS_THREAD_COUNT=$with_mds_max_threads
 128                 AC_DEFINE_UNQUOTED(MDS_MAX_THREADS, $MDS_THREAD_COUNT, [maximum number of MDS threads])
 129         ])
 130 ])
 131
 132 #
 133 # LC_CONFIG_PINGER
 134 #
 135 # the pinger is temporary, until we have the recovery node in place
 136 #
 137 AC_DEFUN([LC_CONFIG_PINGER],
 138 [AC_MSG_CHECKING([whether to enable pinger support])
 139 AC_ARG_ENABLE([pinger],
 140         AC_HELP_STRING([--disable-pinger],
 141                         [disable recovery pinger support]),
 142         [],[enable_pinger='yes'])
 143 AC_MSG_RESULT([$enable_pinger])
 144 if test x$enable_pinger != xno ; then
 145   AC_DEFINE(ENABLE_PINGER, 1, Use the Pinger)
 146 fi
 147 ])
 148
 149 #
 150 # LC_CONFIG_CHECKSUM
 151 #
 152 # do checksum of bulk data between client and OST
 153 #
 154 AC_DEFUN([LC_CONFIG_CHECKSUM],
 155 [AC_MSG_CHECKING([whether to enable data checksum support])
 156 AC_ARG_ENABLE([checksum],
 157        AC_HELP_STRING([--disable-checksum],
 158                        [disable data checksum support]),
 159        [],[enable_checksum='yes'])
 160 AC_MSG_RESULT([$enable_checksum])
 161 if test x$enable_checksum != xno ; then
 162   AC_DEFINE(ENABLE_CHECKSUM, 1, do data checksums)
 163 fi
 164 ])
 165
 166 #
 167 # LC_CONFIG_LIBLUSTRE_RECOVERY
 168 #
 169 AC_DEFUN([LC_CONFIG_LIBLUSTRE_RECOVERY],
 170 [AC_MSG_CHECKING([whether to enable liblustre recovery support])
 171 AC_ARG_ENABLE([liblustre-recovery],
 172         AC_HELP_STRING([--disable-liblustre-recovery],
 173                         [disable liblustre recovery support]),
 174         [],[enable_liblustre_recovery='yes'])
 175 AC_MSG_RESULT([$enable_liblustre_recovery])
 176 if test x$enable_liblustre_recovery != xno ; then
 177   AC_DEFINE(ENABLE_LIBLUSTRE_RECOVERY, 1, Liblustre Can Recover)
 178 fi
 179 ])
 180
 181 #
 182 # LC_CONFIG_HEALTH_CHECK_WRITE
 183 #
 184 # Turn off the actual write to the disk
 185 #
 186 AC_DEFUN([LC_CONFIG_HEALTH_CHECK_WRITE],
 187 [AC_MSG_CHECKING([whether to enable a write with the health check])
 188 AC_ARG_ENABLE([health_write],
 189         AC_HELP_STRING([--enable-health_write],
 190                         [enable disk writes when doing health check]),
 191         [],[enable_health_write='no'])
 192 AC_MSG_RESULT([$enable_health_write])
 193 if test x$enable_health_write != xno ; then
 194   AC_DEFINE(USE_HEALTH_CHECK_WRITE, 1, Write when Checking Health)
 195 fi
 196 ])
 197
 198 AC_DEFUN([LC_CONFIG_LRU_RESIZE],
 199 [AC_MSG_CHECKING([whether to enable lru self-adjusting])
 200 AC_ARG_ENABLE([lru_resize],
 201         AC_HELP_STRING([--enable-lru-resize],
 202                         [enable lru resize support]),
 203         [],[enable_lru_resize='yes'])
 204 AC_MSG_RESULT([$enable_lru_resize])
 205 if test x$enable_lru_resize != xno; then
 206    AC_DEFINE(HAVE_LRU_RESIZE_SUPPORT, 1, [Enable lru resize support])
 207 fi
 208 ])
 209
 210 #
 211 # Quota support. The kernel must support CONFIG_QUOTA.
 212 #
 213 AC_DEFUN([LC_QUOTA_CONFIG],
 214 [LB_LINUX_CONFIG_IM([QUOTA],[],[
 215         AC_MSG_ERROR([Lustre quota requires that CONFIG_QUOTA is enabled in your kernel.])
 216         ])
 217 ])
 218
 219 # truncate_complete_page() has never been exported from an upstream kernel
 220 # remove_from_page_cache() was exported between 2.6.35 and 2.6.38
 221 # delete_from_page_cache() is exported from 2.6.39
 222 AC_DEFUN([LC_EXPORT_TRUNCATE_COMPLETE_PAGE],
 223          [LB_CHECK_SYMBOL_EXPORT([truncate_complete_page],
 224                                  [mm/truncate.c],
 225                                  [AC_DEFINE(HAVE_TRUNCATE_COMPLETE_PAGE, 1,
 226                                             [kernel export truncate_complete_page])])
 227           LB_CHECK_SYMBOL_EXPORT([remove_from_page_cache],
 228                                  [mm/filemap.c],
 229                                  [AC_DEFINE(HAVE_REMOVE_FROM_PAGE_CACHE, 1,
 230                                             [kernel export remove_from_page_cache])])
 231           LB_CHECK_SYMBOL_EXPORT([delete_from_page_cache],
 232                                  [mm/filemap.c],
 233                                  [AC_DEFINE(HAVE_DELETE_FROM_PAGE_CACHE, 1,
 234                                             [kernel export delete_from_page_cache])])
 235          ])
 236
 237 #
 238 # LC_CAPA_CRYPTO
 239 #
 240 AC_DEFUN([LC_CAPA_CRYPTO],
 241 [LB_LINUX_CONFIG_IM([CRYPTO],[],[
 242         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO is enabled in your kernel.])
 243 ])
 244 LB_LINUX_CONFIG_IM([CRYPTO_HMAC],[],[
 245         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO_HMAC is enabled in your kernel.])
 246 ])
 247 LB_LINUX_CONFIG_IM([CRYPTO_SHA1],[],[
 248         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO_SHA1 is enabled in your kernel.])
 249 ])
 250 ])
 251
 252 #
 253 # LC_CONFIG_RMTCLIENT
 254 #
 255 dnl FIXME
 256 dnl the AES symbol usually tied with arch, e.g. CRYPTO_AES_586
 257 dnl FIXME
 258 AC_DEFUN([LC_CONFIG_RMTCLIENT],
 259 [LB_LINUX_CONFIG_IM([CRYPTO_AES],[],[
 260         AC_MSG_WARN([Lustre remote client require that CONFIG_CRYPTO_AES is enabled in your kernel.])
 261 ])
 262 ])
 263
 264 #
 265 # LC_CONFIG_GSS_KEYRING (default 'auto', tests for dependencies, if found, enables; only called if gss is enabled)
 266 #
 267 AC_DEFUN([LC_CONFIG_GSS_KEYRING],
 268 [AC_MSG_CHECKING([whether to enable gss keyring backend])
 269  AC_ARG_ENABLE([gss_keyring],
 270                [AC_HELP_STRING([--disable-gss-keyring],
 271                                [disable gss keyring backend])],
 272                [],[enable_gss_keyring='auto'])
 273  AC_MSG_RESULT([$enable_gss_keyring])
 274
 275  if test x$enable_gss_keyring != xno; then
 276         LB_LINUX_CONFIG_IM([KEYS],[],
 277                            [gss_keyring_conf_test='fail';
 278                             AC_MSG_WARN([GSS keyring backend require that CONFIG_KEYS be enabled in your kernel.])])
 279
 280         AC_CHECK_LIB([keyutils], [keyctl_search], [],
 281                      [gss_keyring_conf_test='fail';
 282                       AC_MSG_WARN([libkeyutils is not found, which is required by gss keyring backend])],)
 283
 284         if test x$gss_keyring_conf_test != xfail; then
 285                 AC_DEFINE([HAVE_GSS_KEYRING], [1], [Define this if you enable gss keyring backend])
 286                 enable_gss_keyring='yes'
 287         else
 288                 if test x$enable_gss_keyring == xyes; then
 289                         AC_MSG_ERROR([Cannot enable gss_keyring. See above for details.])
 290                 else
 291                         AC_MSG_WARN([Cannot enable gss keyring.  See above for details.])
 292                 fi
 293         fi
 294  fi
 295 ])
 296
 297 AC_DEFUN([LC_CONFIG_SUNRPC],
 298 [LB_LINUX_CONFIG_IM([SUNRPC],[],
 299                     [if test x$sunrpc_required == xyes; then
 300                          AC_MSG_ERROR([kernel SUNRPC support is required by using GSS.])
 301                      fi])
 302 ])
 303
 304 #
 305 # LC_CONFIG_GSS (default 'auto' (tests for dependencies, if found, enables))
 306 #
 307 # Build gss and related tools of Lustre. Currently both kernel and user space
 308 # parts are depend on linux platform.
 309 #
 310 AC_DEFUN([LC_CONFIG_GSS],
 311 [AC_MSG_CHECKING([whether to enable gss/krb5 support])
 312  AC_ARG_ENABLE([gss],
 313                [AC_HELP_STRING([--enable-gss], [enable gss/krb5 support])],
 314                [],[enable_gss='auto'])
 315  AC_MSG_RESULT([$enable_gss])
 316
 317  if test x$enable_gss != xno; then
 318         LC_CONFIG_GSS_KEYRING
 319         sunrpc_required=$enable_gss
 320         LC_CONFIG_SUNRPC
 321         sunrpc_required=no
 322
 323         LB_LINUX_CONFIG_IM([CRYPTO_MD5],[],
 324                            [AC_MSG_WARN([kernel MD5 support is recommended by using GSS.])])
 325         LB_LINUX_CONFIG_IM([CRYPTO_SHA1],[],
 326                            [AC_MSG_WARN([kernel SHA1 support is recommended by using GSS.])])
 327         LB_LINUX_CONFIG_IM([CRYPTO_SHA256],[],
 328                            [AC_MSG_WARN([kernel SHA256 support is recommended by using GSS.])])
 329         LB_LINUX_CONFIG_IM([CRYPTO_SHA512],[],
 330                            [AC_MSG_WARN([kernel SHA512 support is recommended by using GSS.])])
 331
 332         require_krb5=$enable_gss
 333         AC_KERBEROS_V5
 334         require_krb5=no
 335
 336         if test x$KRBDIR != x; then
 337                 AC_CHECK_LIB([gssapi], [gss_export_lucid_sec_context],
 338                              [GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssapi";
 339                               gss_conf_test='success'],
 340                              [AC_CHECK_LIB([gssglue], [gss_export_lucid_sec_context],
 341                                            [GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssglue";
 342                                             gss_conf_test='success'],
 343                                            [if test x$enable_gss == xyes; then
 344                                                 AC_MSG_ERROR([libgssapi or libgssglue is not found, which is required by GSS.])
 345                                             else
 346                                                 AC_MSG_WARN([libgssapi or libgssglue is not found, which is required by GSS.])
 347                                             fi])],)
 348                 AC_SUBST(GSSAPI_LIBS)
 349         fi
 350
 351         if test x$gss_conf_test == xsuccess; then
 352                 AC_DEFINE([HAVE_GSS], [1], [Define this is if you enable gss])
 353                 enable_gss='yes'
 354         fi
 355
 356  fi
 357 ])
 358
 359 # 2.6.24
 360
 361 # 2.6.24 has bio_endio with 2 args
 362 AC_DEFUN([LC_BIO_ENDIO_2ARG],
 363 [AC_MSG_CHECKING([if kernel has bio_endio with 2 args])
 364 LB_LINUX_TRY_COMPILE([
 365         #include <linux/bio.h>
 366 ],[
 367         bio_endio(NULL, 0);
 368 ], [
 369         AC_MSG_RESULT([yes])
 370         AC_DEFINE(HAVE_BIO_ENDIO_2ARG, 1,
 371                 [kernel has bio_endio with 2 args])
 372 ],[
 373         AC_MSG_RESULT([no])
 374 ])
 375 ])
 376
 377 # 2.6.24 removes long aged procfs entry -> deleted member
 378 AC_DEFUN([LC_PROCFS_DELETED],
 379 [AC_MSG_CHECKING([if kernel has deleted member in procfs entry struct])
 380 LB_LINUX_TRY_COMPILE([
 381         #include <linux/proc_fs.h>
 382 ],[
 383         struct proc_dir_entry pde;
 384
 385         pde.deleted = sizeof(pde);
 386 ], [
 387         AC_MSG_RESULT([yes])
 388         AC_DEFINE(HAVE_PROCFS_DELETED, 1,
 389                 [kernel has deleted member in procfs entry struct])
 390 ],[
 391         AC_MSG_RESULT([no])
 392 ])
 393 ])
 394
 395 #
 396 # 2.6.27
 397 #
 398
 399 # up to v2.6.27 had a 3 arg version (inode, mask, nameidata)
 400 # v2.6.27->v2.6.37 had a 2 arg version (inode, mask)
 401 # v2.6.37->v3.0 had a 3 arg version (inode, mask, nameidata)
 402 # v3.1 onward have a 2 arg version (inode, mask)
 403 AC_DEFUN([LC_INODE_PERMISION_2ARGS],
 404 [AC_MSG_CHECKING([inode_operations->permission has two args])
 405 LB_LINUX_TRY_COMPILE([
 406         #include <linux/fs.h>
 407 ],[
 408         struct inode *inode __attribute__ ((unused));
 409
 410         inode = NULL;
 411         inode->i_op->permission(NULL, 0);
 412 ],[
 413         AC_DEFINE(HAVE_INODE_PERMISION_2ARGS, 1,
 414                   [inode_operations->permission has two args])
 415         AC_MSG_RESULT([yes])
 416 ],[
 417         AC_MSG_RESULT([no])
 418 ])
 419 ])
 420
 421 # 2.6.34 has quotactl_ops->[sg]et_dqblk that take struct fs_disk_quota
 422 AC_DEFUN([LC_HAVE_DQUOT_FS_DISK_QUOTA],
 423 tmp_flags="$EXTRA_KCFLAGS"
 424 EXTRA_KCFLAGS="-Werror"
 425 [AC_MSG_CHECKING([if quotactl_ops.set_dqblk takes struct fs_disk_quota])
 426 LB_LINUX_TRY_COMPILE([
 427         #include <linux/fs.h>
 428         #include <linux/quota.h>
 429 ],[
 430         struct quotactl_ops qops = {};
 431         struct fs_disk_quota fdq;
 432         qops.set_dqblk(NULL, 0, 0, &fdq);
 433 ],[
 434         AC_DEFINE(HAVE_DQUOT_FS_DISK_QUOTA, 1, [quotactl_ops.set_dqblk takes struct fs_disk_quota])
 435         AC_MSG_RESULT([yes])
 436 ],[
 437         AC_MSG_RESULT([no])
 438 ])
 439 EXTRA_KCFLAGS="$tmp_flags"
 440 ])
 441
 442 # 2.6.34 has renamed dquot options to dquot_*, check for dquot_suspend
 443 AC_DEFUN([LC_HAVE_DQUOT_SUSPEND],
 444 [AC_MSG_CHECKING([if dquot_suspend is defined])
 445 LB_LINUX_TRY_COMPILE([
 446         #include <linux/quotaops.h>
 447 ],[
 448         dquot_suspend(NULL, -1);
 449 ],[
 450         AC_DEFINE(HAVE_DQUOT_SUSPEND, 1, [dquot_suspend is defined])
 451         AC_MSG_RESULT([yes])
 452 ],[
 453         AC_MSG_RESULT([no])
 454 ])
 455 ])
 456
 457 # 2.6.27.15-2 sles11
 458
 459 # 2.6.27 sles11 remove the bi_hw_segments
 460 AC_DEFUN([LC_BI_HW_SEGMENTS],
 461 [AC_MSG_CHECKING([struct bio has a bi_hw_segments field])
 462 LB_LINUX_TRY_COMPILE([
 463         #include <linux/bio.h>
 464 ],[
 465         struct bio io;
 466         io.bi_hw_segments = sizeof(io);
 467 ],[
 468         AC_DEFINE(HAVE_BI_HW_SEGMENTS, 1,
 469                 [struct bio has a bi_hw_segments field])
 470         AC_MSG_RESULT([yes])
 471 ],[
 472         AC_MSG_RESULT([no])
 473 ])
 474 ])
 475
 476 #
 477 # 2.6.27 sles11 move the quotaio_v1{2}.h from include/linux to fs
 478 # 2.6.32 move the quotaio_v1{2}.h from fs to fs/quota
 479 AC_DEFUN([LC_HAVE_QUOTAIO_H],
 480 [LB_CHECK_FILE([$LINUX/include/linux/quotaio_v2.h],[
 481         AC_DEFINE(HAVE_QUOTAIO_H, 1,
 482                 [kernel has include/linux/quotaio_v2.h])
 483 ],[LB_CHECK_FILE([$LINUX/fs/quotaio_v2.h],[
 484                AC_DEFINE(HAVE_FS_QUOTAIO_H, 1,
 485                 [kernel has fs/quotaio_v1.h])
 486 ],[LB_CHECK_FILE([$LINUX/fs/quota/quotaio_v2.h],[
 487                AC_DEFINE(HAVE_FS_QUOTA_QUOTAIO_H, 1,
 488                 [kernel has fs/quota/quotaio_v2.h])
 489 ],[
 490         AC_MSG_RESULT([no])
 491 ])
 492 ])
 493 ])
 494 ])
 495
 496 # 2.6.32
 497
 498 # 2.6.32 replaces 2 functions blk_queue_max_phys_segments and blk_queue_max_hw_segments by blk_queue_max_segments
 499 AC_DEFUN([LC_BLK_QUEUE_MAX_SEGMENTS],
 500 [AC_MSG_CHECKING([if blk_queue_max_segments is defined])
 501 LB_LINUX_TRY_COMPILE([
 502         #include <linux/blkdev.h>
 503 ],[
 504         blk_queue_max_segments(NULL, 0);
 505 ],[
 506         AC_MSG_RESULT(yes)
 507         AC_DEFINE(HAVE_BLK_QUEUE_MAX_SEGMENTS, 1,
 508                   [blk_queue_max_segments is defined])
 509 ],[
 510         AC_MSG_RESULT(no)
 511 ])
 512 ])
 513
 514 #
 515 # LC_QUOTA64
 516 #
 517 # Check if kernel has been patched for 64-bit quota limits support.
 518 # The upstream version of this patch in RHEL6 2.6.32 kernels introduces
 519 # the constant QFMT_VFS_V1 in include/linux/quota.h, so we can check for
 520 # that in the absence of quotaio_v1.h in the kernel headers.
 521 #
 522 AC_DEFUN([LC_QUOTA64],[
 523         AC_MSG_CHECKING([if kernel has 64-bit quota limits support])
 524 tmp_flags="$EXTRA_KCFLAGS"
 525 EXTRA_KCFLAGS="-I$LINUX/fs"
 526         LB_LINUX_TRY_COMPILE([
 527                 #include <linux/kernel.h>
 528                 #include <linux/fs.h>
 529                 #if defined(HAVE_FS_QUOTA_QUOTAIO_H)
 530                 # include <quota/quotaio_v2.h>
 531                 struct v2r1_disk_dqblk dqblk_r1;
 532                 #else
 533                 #include <linux/quota.h>
 534                 int ver = QFMT_VFS_V1;
 535                 #endif
 536         ],[],[
 537                 AC_DEFINE(HAVE_QUOTA64, 1, [have quota64])
 538                 AC_MSG_RESULT([yes])
 539         ],[
 540                 LB_CHECK_FILE([$LINUX/include/linux/lustre_version.h],[
 541                         AC_MSG_ERROR([You have got no 64-bit kernel quota support.])
 542                 ],[])
 543                 AC_MSG_RESULT([no])
 544         ])
 545 EXTRA_KCFLAGS=$tmp_flags
 546 ])
 547
 548 #
 549 # 2.6.36 fs_struct.lock use spinlock instead of rwlock.
 550 #
 551 AC_DEFUN([LC_FS_STRUCT_RWLOCK],
 552 [AC_MSG_CHECKING([if fs_struct.lock use rwlock])
 553 LB_LINUX_TRY_COMPILE([
 554         #include <asm/atomic.h>
 555         #include <linux/spinlock.h>
 556         #include <linux/fs_struct.h>
 557 ],[
 558         ((struct fs_struct *)0)->lock = (rwlock_t){ 0 };
 559 ],[
 560         AC_DEFINE(HAVE_FS_STRUCT_RWLOCK, 1,
 561                   [fs_struct.lock use rwlock])
 562         AC_MSG_RESULT([yes])
 563 ],[
 564         AC_MSG_RESULT([no])
 565 ])
 566 ])
 567
 568 #
 569 # 2.6.36 super_operations add evict_inode method. it hybird of
 570 # delete_inode & clear_inode.
 571 #
 572 AC_DEFUN([LC_SBOPS_EVICT_INODE],
 573 [AC_MSG_CHECKING([if super_operations.evict_inode exist])
 574 LB_LINUX_TRY_COMPILE([
 575         #include <linux/fs.h>
 576 ],[
 577         ((struct super_operations *)0)->evict_inode(NULL);
 578 ],[
 579         AC_DEFINE(HAVE_SBOPS_EVICT_INODE, 1,
 580                 [super_operations.evict_inode() is exist in kernel])
 581         AC_MSG_RESULT([yes])
 582 ],[
 583         AC_MSG_RESULT([no])
 584 ])
 585 ])
 586
 587 #
 588 # 2.6.35 file_operations.fsync taken 2 arguments.
 589 # 3.0.0 file_operations.fsync takes 4 arguments.
 590 #
 591 AC_DEFUN([LC_FILE_FSYNC],
 592 [AC_MSG_CHECKING([if file_operations.fsync takes 4 or 2 arguments])
 593 LB_LINUX_TRY_COMPILE([
 594         #include <linux/fs.h>
 595 ],[
 596         ((struct file_operations *)0)->fsync(NULL, 0, 0, 0);
 597 ],[
 598         AC_DEFINE(HAVE_FILE_FSYNC_4ARGS, 1,
 599                 [file_operations.fsync takes 4 arguments])
 600         AC_MSG_RESULT([yes, 4 args])
 601 ],[
 602         LB_LINUX_TRY_COMPILE([
 603                 #include <linux/fs.h>
 604         ],[
 605            ((struct file_operations *)0)->fsync(NULL, 0);
 606         ],[
 607                 AC_DEFINE(HAVE_FILE_FSYNC_2ARGS, 1,
 608                         [file_operations.fsync takes 2 arguments])
 609                 AC_MSG_RESULT([yes, 2 args])
 610         ],[
 611                 AC_MSG_RESULT([no])
 612         ])
 613 ])
 614 ])
 615
 616 #
 617 # 2.6.37 remove kernel_locked
 618 #
 619 AC_DEFUN([LC_KERNEL_LOCKED],
 620 [AC_MSG_CHECKING([if kernel_locked is defined])
 621 LB_LINUX_TRY_COMPILE([
 622         #include <linux/smp_lock.h>
 623 ],[
 624         kernel_locked();
 625 ],[
 626         AC_MSG_RESULT([yes])
 627         AC_DEFINE(HAVE_KERNEL_LOCKED, 1,
 628                 [kernel_locked is defined])
 629 ],[
 630         AC_MSG_RESULT([no])
 631 ])
 632 ])
 633
 634 #
 635 # 2.6.38 dentry_operations.d_compare() taken 7 arguments.
 636 #
 637 AC_DEFUN([LC_D_COMPARE_7ARGS],
 638 [AC_MSG_CHECKING([if d_compare taken 7 arguments])
 639 LB_LINUX_TRY_COMPILE([
 640         #include <linux/dcache.h>
 641 ],[
 642         ((struct dentry_operations*)0)->d_compare(NULL,NULL,NULL,NULL,0,NULL,NULL);
 643 ],[
 644         AC_DEFINE(HAVE_D_COMPARE_7ARGS, 1,
 645                 [d_compare need 7 arguments])
 646         AC_MSG_RESULT([yes])
 647 ],[
 648         AC_MSG_RESULT([no])
 649 ])
 650 ])
 651
 652 #
 653 # 2.6.38 dentry_operations.d_delete() defined 'const' for 1st parameter.
 654 #
 655 AC_DEFUN([LC_D_DELETE_CONST],
 656 [AC_MSG_CHECKING([if d_delete has const declare on first parameter])
 657 tmp_flags="$EXTRA_KCFLAGS"
 658 EXTRA_KCFLAGS="-Werror"
 659 LB_LINUX_TRY_COMPILE([
 660         #include <linux/dcache.h>
 661 ],[
 662         const struct dentry *d = NULL;
 663         ((struct dentry_operations*)0)->d_delete(d);
 664 ],[
 665         AC_DEFINE(HAVE_D_DELETE_CONST, const,
 666                 [d_delete first parameter declared const])
 667         AC_MSG_RESULT([yes])
 668 ],[
 669         AC_DEFINE(HAVE_D_DELETE_CONST, , [])
 670         AC_MSG_RESULT([no])
 671 ])
 672 EXTRA_KCFLAGS="$tmp_flags"
 673 ])
 674
 675 #
 676 # 2.6.38 dcache_lock removed. rcu-walk commited.
 677 #
 678 AC_DEFUN([LC_DCACHE_LOCK],
 679 [AC_MSG_CHECKING([if dcache_lock is exist])
 680 LB_LINUX_TRY_COMPILE([
 681         #include <linux/dcache.h>
 682 ],[
 683         spin_lock(&dcache_lock);
 684 ],[
 685         AC_DEFINE(HAVE_DCACHE_LOCK, 1,
 686                 [dcache_lock is exist])
 687         AC_MSG_RESULT([yes])
 688 ],[
 689         AC_MSG_RESULT([no])
 690 ])
 691 ])
 692
 693 #
 694 # 2.6.38 inode.i_rcu added.
 695 #
 696 AC_DEFUN([LC_INODE_I_RCU],
 697 [AC_MSG_CHECKING([if inode.i_rcu exists])
 698 LB_LINUX_TRY_COMPILE([
 699         #include <linux/fs.h>
 700 ],[
 701         struct inode ino;
 702         struct rcu_head rcu = {};
 703         ino.i_rcu = rcu;
 704 ],[
 705         AC_DEFINE(HAVE_INODE_I_RCU, 1,
 706                 [inode.i_rcu exists])
 707         AC_MSG_RESULT([yes])
 708 ],[
 709         AC_MSG_RESULT([no])
 710 ])
 711 ])
 712
 713 #
 714 # 2.6.38 export blkdev_get_by_dev
 715 #
 716 AC_DEFUN([LC_BLKDEV_GET_BY_DEV],
 717 [LB_CHECK_SYMBOL_EXPORT([blkdev_get_by_dev],
 718 [fs/block_dev.c],[
 719 AC_DEFINE(HAVE_BLKDEV_GET_BY_DEV, 1,
 720             [blkdev_get_by_dev is exported by the kernel])
 721 ],[
 722 ])
 723 ])
 724
 725 #
 726 # 2.6.38 export simple_setattr
 727 #
 728 AC_DEFUN([LC_EXPORT_SIMPLE_SETATTR],
 729 [LB_CHECK_SYMBOL_EXPORT([simple_setattr],
 730 [fs/libfs.c],[
 731 AC_DEFINE(HAVE_SIMPLE_SETATTR, 1,
 732             [simple_setattr is exported by the kernel])
 733 ],[
 734 ])
 735 ])
 736
 737 #
 738 # 2.6.39 remove unplug_fn from request_queue.
 739 #
 740 AC_DEFUN([LC_REQUEST_QUEUE_UNPLUG_FN],
 741 [AC_MSG_CHECKING([if request_queue has unplug_fn field])
 742 LB_LINUX_TRY_COMPILE([
 743         #include <linux/blkdev.h>
 744 ],[
 745         do{ }while(sizeof(((struct request_queue *)0)->unplug_fn));
 746 ],[
 747         AC_DEFINE(HAVE_REQUEST_QUEUE_UNPLUG_FN, 1,
 748                   [request_queue has unplug_fn field])
 749         AC_MSG_RESULT([yes])
 750 ],[
 751         AC_MSG_RESULT([no])
 752 ])
 753 ])
 754
 755 #
 756 # 2.6.39 replace get_sb with mount in struct file_system_type
 757 #
 758 AC_DEFUN([LC_HAVE_FSTYPE_MOUNT],
 759 [AC_MSG_CHECKING([if file_system_type has mount field])
 760 LB_LINUX_TRY_COMPILE([
 761         #include <linux/fs.h>
 762 ],[
 763         struct file_system_type fst;
 764         void *i = (void *) fst.mount;
 765 ],[
 766         AC_DEFINE(HAVE_FSTYPE_MOUNT, 1,
 767                 [struct file_system_type has mount field])
 768         AC_MSG_RESULT([yes])
 769 ],[
 770         AC_MSG_RESULT([no])
 771 ])
 772 ])
 773
 774 #
 775 # 3.0 dirty_inode() has a flag parameter
 776 # see kernel commit aa38572954ade525817fe88c54faebf85e5a61c0
 777 #
 778 AC_DEFUN([LC_DIRTY_INODE_WITH_FLAG],
 779 [AC_MSG_CHECKING([if dirty_inode super_operation takes flag])
 780 LB_LINUX_TRY_COMPILE([
 781         #include <linux/fs.h>
 782 ],[
 783         struct inode *inode;
 784         inode->i_sb->s_op->dirty_inode(NULL, 0);
 785 ],[
 786         AC_DEFINE(HAVE_DIRTY_INODE_HAS_FLAG, 1,
 787                   [dirty_inode super_operation takes flag])
 788         AC_MSG_RESULT([yes])
 789 ],[
 790         AC_MSG_RESULT([no])
 791 ])
 792 ])
 793
 794 #
 795 # 2.6.38 generic_permission taken 4 parameters.
 796 # in fact, it means rcu-walk aware permission bring.
 797 #
 798 # 3.1 generic_permission taken 2 parameters.
 799 # see kernel commit 2830ba7f34ebb27c4e5b8b6ef408cd6d74860890
 800 #
 801 AC_DEFUN([LC_GENERIC_PERMISSION],
 802 [AC_MSG_CHECKING([if generic_permission take 2 or 4 arguments])
 803 LB_LINUX_TRY_COMPILE([
 804         #include <linux/fs.h>
 805 ],[
 806         generic_permission(NULL, 0);
 807 ],[
 808         AC_DEFINE(HAVE_GENERIC_PERMISSION_2ARGS, 1,
 809                   [generic_permission taken 2 arguments])
 810         AC_MSG_RESULT([yes, 2 args])
 811 ],[
 812         LB_LINUX_TRY_COMPILE([
 813                 #include <linux/fs.h>
 814         ],[
 815                 generic_permission(NULL, 0, 0, NULL);
 816         ],[
 817                 AC_DEFINE(HAVE_GENERIC_PERMISSION_4ARGS, 1,
 818                           [generic_permission taken 4 arguments])
 819                 AC_MSG_RESULT([yes, 4 args])
 820         ],[
 821                 AC_MSG_RESULT([no])
 822         ])
 823 ])
 824 ])
 825
 826 #
 827 # 3.1 renames lock-manager ops(lock_manager_operations) from fl_xxx to lm_xxx
 828 # see kernel commit 8fb47a4fbf858a164e973b8ea8ef5e83e61f2e50
 829 #
 830 AC_DEFUN([LC_LM_XXX_LOCK_MANAGER_OPS],
 831 [AC_MSG_CHECKING([if lock-manager ops renamed to lm_xxx])
 832 LB_LINUX_TRY_COMPILE([
 833         #include <linux/fs.h>
 834 ],[
 835         struct lock_manager_operations lm_ops;
 836         lm_ops.lm_compare_owner = NULL;
 837 ],[
 838         AC_DEFINE(HAVE_LM_XXX_LOCK_MANAGER_OPS, 1,
 839                   [lock-manager ops renamed to lm_xxx])
 840         AC_MSG_RESULT([yes])
 841 ],[
 842         AC_MSG_RESULT([no])
 843 ])
 844 ])
 845
 846 #
 847 # 3.1 kills inode->i_alloc_sem, use i_dio_count and inode_dio_wait/
 848 #     inode_dio_done instead.
 849 # see kernel commit bd5fe6c5eb9c548d7f07fe8f89a150bb6705e8e3
 850 #
 851 AC_DEFUN([LC_INODE_DIO_WAIT],
 852 [AC_MSG_CHECKING([if inode->i_alloc_sem is killed and use inode_dio_wait/done.])
 853 LB_LINUX_TRY_COMPILE([
 854         #include <linux/fs.h>
 855 ],[
 856         inode_dio_wait((struct inode *)0);
 857         inode_dio_done((struct inode *)0);
 858 ],[
 859         AC_DEFINE(HAVE_INODE_DIO_WAIT, 1,
 860                   [inode->i_alloc_sem is killed and use inode_dio_wait/done])
 861         AC_MSG_RESULT([yes])
 862 ],[
 863         AC_MSG_RESULT([no])
 864 ])
 865 ])
 866
 867 #
 868 # 3.1 adds get_acl method to inode_operations to read ACL from disk.
 869 # see kernel commit 4e34e719e457f2e031297175410fc0bd4016a085
 870 #
 871 AC_DEFUN([LC_IOP_GET_ACL],
 872 [AC_MSG_CHECKING([inode_operations has .get_acl member function])
 873 LB_LINUX_TRY_COMPILE([
 874         #include <linux/fs.h>
 875 ],[
 876         struct inode_operations iop;
 877         iop.get_acl = NULL;
 878 ],[
 879         AC_DEFINE(HAVE_IOP_GET_ACL, 1,
 880                   [inode_operations has .get_acl member function])
 881         AC_MSG_RESULT([yes])
 882 ],[
 883         AC_MSG_RESULT([no])
 884 ])
 885 ])
 886
 887 #
 888 # 3.1.1 has ext4_blocks_for_truncate
 889 #
 890 AC_DEFUN([LC_BLOCKS_FOR_TRUNCATE],
 891 [AC_MSG_CHECKING([if kernel has ext4_blocks_for_truncate])
 892 LB_LINUX_TRY_COMPILE([
 893         #include <linux/fs.h>
 894         #include "$LINUX/fs/ext4/ext4_jbd2.h"
 895         #include "$LINUX/fs/ext4/truncate.h"
 896 ],[
 897         ext4_blocks_for_truncate(NULL);
 898 ],[
 899         AC_MSG_RESULT([yes])
 900         AC_DEFINE(HAVE_BLOCKS_FOR_TRUNCATE, 1,
 901                   [kernel has ext4_blocks_for_truncate])
 902 ],[
 903         AC_MSG_RESULT([no])
 904 ])
 905 ])
 906
 907 #
 908 # 3.1 introduced generic_file_llseek_size()
 909 #
 910 AC_DEFUN([LC_FILE_LLSEEK_SIZE],
 911         [LB_CHECK_SYMBOL_EXPORT([generic_file_llseek_size],
 912         [fs/read_write.c],
 913         [AC_DEFINE(HAVE_FILE_LLSEEK_SIZE, 1,
 914                    [generic_file_llseek_size is exported by the kernel])])
 915 ])
 916
 917 #
 918 # 3.2 request_queue.make_request_fn defined as function returns with void
 919 # see kernel commit 5a7bbad27a410350e64a2d7f5ec18fc73836c14f
 920 #
 921 AC_DEFUN([LC_HAVE_VOID_MAKE_REQUEST_FN],
 922 [AC_MSG_CHECKING([if request_queue.make_request_fn returns void but not int])
 923 LB_LINUX_TRY_COMPILE([
 924         #include <linux/blkdev.h>
 925 ],[
 926         int ret;
 927         make_request_fn         *mrf;
 928         ret = mrf(NULL, NULL);
 929 ],[
 930         AC_MSG_RESULT([no])
 931 ],[
 932         AC_DEFINE(HAVE_VOID_MAKE_REQUEST_FN, 1,
 933                   [request_queue.make_request_fn returns void but not int])
 934         AC_MSG_RESULT([yes])
 935 ])
 936 ])
 937
 938 #
 939 # 3.2 protects inode->i_nlink from direct modification
 940 # see kernel commit a78ef704a8dd430225955f0709b22d4a6ba21deb
 941 # at the same time adds set_nlink(), so checks set_nlink() for it.
 942 #
 943 AC_DEFUN([LC_HAVE_PROTECT_I_NLINK],
 944 [AC_MSG_CHECKING([if inode->i_nlink is protected from direct modification])
 945 LB_LINUX_TRY_COMPILE([
 946         #include <linux/fs.h>
 947 ],[
 948         struct inode i;
 949         set_nlink(&i, 1);
 950 ],[
 951         AC_DEFINE(HAVE_PROTECT_I_NLINK, 1,
 952                   [inode->i_nlink is protected from direct modification])
 953         AC_MSG_RESULT([yes])
 954 ],[
 955         AC_MSG_RESULT([no])
 956 ])
 957 ])
 958
 959 #
 960 # 3.3 introduces migrate_mode.h and migratepage has 4 args
 961 #
 962 AC_DEFUN([LC_HAVE_MIGRATE_HEADER],
 963 [LB_CHECK_FILE([$LINUX/include/linux/migrate.h],[
 964                 AC_DEFINE(HAVE_MIGRATE_H, 1,
 965                 [kernel has include/linux/migrate.h])
 966 ],[LB_CHECK_FILE([$LINUX/include/linux/migrate_mode.h],[
 967                 AC_DEFINE(HAVE_MIGRATE_MODE_H, 1,
 968                         [kernel has include/linux/migrate_mode.h])
 969 ],[
 970         AC_MSG_RESULT([no])
 971 ])
 972 ])
 973 ])
 974
 975 AC_DEFUN([LC_MIGRATEPAGE_4ARGS],
 976 [AC_MSG_CHECKING([if address_space_operations.migratepage has 4 args])
 977 LB_LINUX_TRY_COMPILE([
 978         #include <linux/fs.h>
 979 #ifdef HAVE_MIGRATE_H
 980         #include <linux/migrate.h>
 981 #elif defined(HAVE_MIGRATE_MODE_H)
 982         #include <linux/migrate_mode.h>
 983 #endif
 984 ],[
 985         struct address_space_operations aops;
 986
 987         aops.migratepage(NULL, NULL, NULL, MIGRATE_ASYNC);
 988 ],[
 989         AC_DEFINE(HAVE_MIGRATEPAGE_4ARGS, 1,
 990                 [address_space_operations.migratepage has 4 args])
 991         AC_MSG_RESULT([yes])
 992 ],[
 993         AC_MSG_RESULT([no])
 994 ])
 995 ])
 996
 997 #
 998 # 3.3 switchs super_operations to use dentry as parameter (but not vfsmount)
 999 # see kernel commit 34c80b1d93e6e20ca9dea0baf583a5b5510d92d4
1000 #
1001 AC_DEFUN([LC_SUPEROPS_USE_DENTRY],
1002 [AC_MSG_CHECKING([if super_operations use dentry as parameter])
1003 tmp_flags="$EXTRA_KCFLAGS"
1004 EXTRA_KCFLAGS="-Werror"
1005 LB_LINUX_TRY_COMPILE([
1006         #include <linux/fs.h>
1007         int show_options(struct seq_file *seq, struct dentry *root){
1008                 return 0;
1009         }
1010 ],[
1011         struct super_operations ops;
1012         ops.show_options = show_options;
1013 ],[
1014         AC_DEFINE(HAVE_SUPEROPS_USE_DENTRY, 1,
1015                   [super_operations use dentry as parameter])
1016         AC_MSG_RESULT([yes])
1017 ],[
1018         AC_MSG_RESULT([no])
1019 ])
1020 EXTRA_KCFLAGS="$tmp_flags"
1021 ])
1022
1023 #
1024 # 3.3 switchs inode_operations to use umode_t as parameter (but not int)
1025 # see kernel commit 1a67aafb5f72a436ca044293309fa7e6351d6a35
1026 #
1027 AC_DEFUN([LC_INODEOPS_USE_UMODE_T],
1028 [AC_MSG_CHECKING([if inode_operations use umode_t as parameter])
1029 tmp_flags="$EXTRA_KCFLAGS"
1030 EXTRA_KCFLAGS="-Werror"
1031 LB_LINUX_TRY_COMPILE([
1032         #include <linux/fs.h>
1033         #include <linux/types.h>
1034         int my_mknod(struct inode *dir, struct dentry *dchild,
1035                      umode_t mode, dev_t dev)
1036         {
1037                 return 0;
1038         }
1039 ],[
1040         struct inode_operations ops;
1041         ops.mknod = my_mknod;
1042 ],[
1043         AC_DEFINE(HAVE_INODEOPS_USE_UMODE_T, 1,
1044                   [inode_operations use umode_t as parameter])
1045         AC_MSG_RESULT([yes])
1046 ],[
1047         AC_MSG_RESULT([no])
1048 ])
1049 EXTRA_KCFLAGS="$tmp_flags"
1050 ])
1051
1052 # 3.4 kmap_atomic removes second argument
1053 # see kernel commit 1ec9c5ddc17aa398f05646abfcbaf315b544e62f
1054 #
1055 AC_DEFUN([LC_KMAP_ATOMIC_HAS_1ARG],
1056 [AC_MSG_CHECKING([if kmap_atomic has only 1 argument])
1057 LB_LINUX_TRY_COMPILE([
1058         #include <linux/highmem.h>
1059 ],[
1060         kmap_atomic(NULL);
1061 ],[
1062         AC_DEFINE(HAVE_KMAP_ATOMIC_HAS_1ARG, 1,
1063                   [have kmap_atomic has only 1 argument])
1064         AC_MSG_RESULT([yes])
1065 ],[
1066         AC_MSG_RESULT([no])
1067 ])
1068 ])
1069
1070 #
1071 # 3.4 switchs touch_atime to struct path
1072 # see kernel commit 68ac1234fb949b66941d94dce4157742799fc581
1073 #
1074 AC_DEFUN([LC_TOUCH_ATIME_1ARG],
1075 [AC_MSG_CHECKING([if touch_atime use one argument])
1076 LB_LINUX_TRY_COMPILE([
1077         #include <linux/fs.h>
1078 ],[
1079         touch_atime((struct path *)NULL);
1080 ],[
1081         AC_DEFINE(HAVE_TOUCH_ATIME_1ARG, 1,
1082                   [touch_atime use one argument])
1083         AC_MSG_RESULT([yes])
1084 ],[
1085         AC_MSG_RESULT([no])
1086 ])
1087 ])
1088
1089 #
1090 # 3.4 converts d_alloc_root to d_make_root
1091 # see kernel commit 32991ab305ace7017c62f8eecbe5eb36dc32e13b
1092 #
1093 AC_DEFUN([LC_HAVE_D_MAKE_ROOT],
1094 [AC_MSG_CHECKING([if have d_make_root])
1095 LB_LINUX_TRY_COMPILE([
1096         #include <linux/fs.h>
1097 ],[
1098         d_make_root((struct inode *)NULL);
1099 ],[
1100         AC_DEFINE(HAVE_D_MAKE_ROOT, 1,
1101                   [have d_make_root])
1102         AC_MSG_RESULT([yes])
1103 ],[
1104         AC_MSG_RESULT([no])
1105 ])
1106 ])
1107
1108 #
1109 # 3.5 renames end_writeback() back to clear_inode()...
1110 # see kernel commit dbd5768f87ff6fb0a4fe09c4d7b6c4a24de99430
1111 #
1112 AC_DEFUN([LC_HAVE_CLEAR_INODE],
1113 [AC_MSG_CHECKING([if have clear_inode])
1114 LB_LINUX_TRY_COMPILE([
1115         #include <linux/fs.h>
1116 ],[
1117         clear_inode((struct inode *)NULL);
1118 ],[
1119         AC_DEFINE(HAVE_CLEAR_INODE, 1,
1120                   [have clear_inode])
1121         AC_MSG_RESULT([yes])
1122 ],[
1123         AC_MSG_RESULT([no])
1124 ])
1125 ])
1126
1127 #
1128 # 3.5 encode_fh has parent inode passed in directly
1129 # see kernel commit b0b0382b
1130 #
1131 AC_DEFUN([LC_HAVE_ENCODE_FH_PARENT],
1132 [AC_MSG_CHECKING([if encode_fh have parent inode as parameter])
1133 tmp_flags="$EXTRA_KCFLAGS"
1134 EXTRA_KCFLAGS="-Werror"
1135 LB_LINUX_TRY_COMPILE([
1136         #include <linux/exportfs.h>
1137         #include <linux/fs.h>
1138         #include <linux/types.h>
1139         int ll_encode_fh(struct inode *i, __u32 *a, int *b, struct inode *p)
1140         {
1141                 return 0;
1142         }
1143 ],[
1144         struct export_operations exp_op;
1145         exp_op.encode_fh = ll_encode_fh;
1146 ],[
1147         AC_DEFINE(HAVE_ENCODE_FH_PARENT, 1,
1148                   [have parent inode as parameter])
1149         AC_MSG_RESULT([yes])
1150 ],[
1151         AC_MSG_RESULT([no])
1152 ])
1153 EXTRA_KCFLAGS="$tmp_flags"
1154 ])
1155
1156 # 3.5 has generic_file_llseek_size with 5 args
1157 AC_DEFUN([LC_FILE_LLSEEK_SIZE_5ARG],
1158 [AC_MSG_CHECKING([if kernel has generic_file_llseek_size with 5 args])
1159 LB_LINUX_TRY_COMPILE([
1160         #include <linux/fs.h>
1161 ],[
1162         generic_file_llseek_size(NULL, 0, 0, 0, 0);
1163 ], [
1164         AC_MSG_RESULT([yes])
1165         AC_DEFINE(HAVE_FILE_LLSEEK_SIZE_5ARGS, 1,
1166                 [kernel has generic_file_llseek_size with 5 args])
1167 ],[
1168         AC_MSG_RESULT([no])
1169 ])
1170 ])
1171
1172 #
1173 # 3.6 switch i_dentry/d_alias from list to hlist
1174 #
1175 AC_DEFUN([LC_HAVE_DENTRY_D_ALIAS_HLIST],
1176 [AC_MSG_CHECKING([if i_dentry/d_alias uses hlist])
1177 tmp_flags="$EXTRA_KCFLAGS"
1178 EXTRA_KCFLAGS="-Werror"
1179 LB_LINUX_TRY_COMPILE([
1180         #include <linux/fs.h>
1181         #include <linux/list.h>
1182 ],[
1183         struct inode inode;
1184         struct dentry dentry;
1185         struct hlist_head head;
1186         struct hlist_node node;
1187         inode.i_dentry = head;
1188         dentry.d_alias = node;
1189 ],[
1190         AC_DEFINE(HAVE_DENTRY_D_ALIAS_HLIST, 1,
1191                   [have i_dentry/d_alias uses hlist])
1192         AC_MSG_RESULT([yes])
1193 ],[
1194         AC_MSG_RESULT([no])
1195 ])
1196 EXTRA_KCFLAGS="$tmp_flags"
1197 ])
1198
1199 #
1200 # 3.6 dentry_open uses struct path as first argument
1201 # see kernel commit 765927b2
1202 #
1203 AC_DEFUN([LC_DENTRY_OPEN_USE_PATH],
1204 [AC_MSG_CHECKING([if dentry_open uses struct path as first argument])
1205 tmp_flags="$EXTRA_KCFLAGS"
1206 EXTRA_KCFLAGS="-Werror"
1207 LB_LINUX_TRY_COMPILE([
1208         #include <linux/fs.h>
1209         #include <linux/path.h>
1210 ],[
1211         struct path path;
1212         dentry_open(&path, 0, NULL);
1213 ],[
1214         AC_DEFINE(HAVE_DENTRY_OPEN_USE_PATH, 1,
1215                   [dentry_open uses struct path as first argument])
1216         AC_MSG_RESULT([yes])
1217 ],[
1218         AC_MSG_RESULT([no])
1219 ])
1220 EXTRA_KCFLAGS="$tmp_flags"
1221 ])
1222
1223 #
1224 # 3.6 vfs adds iop->atomic_open
1225 #
1226 AC_DEFUN([LC_HAVE_IOP_ATOMIC_OPEN],
1227 [AC_MSG_CHECKING([if iop has atomic_open])
1228 LB_LINUX_TRY_COMPILE([
1229         #include <linux/fs.h>
1230 ],[
1231         struct inode_operations iop;
1232         iop.atomic_open = NULL;
1233 ],[
1234         AC_DEFINE(HAVE_IOP_ATOMIC_OPEN, 1,
1235                   [have iop atomic_open])
1236         AC_MSG_RESULT([yes])
1237 ],[
1238         AC_MSG_RESULT([no])
1239 ])
1240 ])
1241
1242 #
1243 # 3.7 posix_acl_{to,from}_xattr take struct user_namespace
1244 #
1245 AC_DEFUN([LC_HAVE_POSIXACL_USER_NS],
1246 [AC_MSG_CHECKING([if posix_acl_to_xattr takes struct user_namespace])
1247 LB_LINUX_TRY_COMPILE([
1248         #include <linux/fs.h>
1249         #include <linux/posix_acl_xattr.h>
1250 ],[
1251         posix_acl_to_xattr((struct user_namespace *)NULL, NULL, NULL, 0);
1252 ],[
1253         AC_DEFINE(HAVE_POSIXACL_USER_NS, 1,
1254                   [posix_acl_to_xattr takes struct user_namespace])
1255         AC_MSG_RESULT([yes])
1256 ],[
1257         AC_MSG_RESULT([no])
1258 ])
1259 ])
1260
1261 #
1262 # 3.9 uses hlist_for_each_entry with 3 args
1263 # b67bfe0d42cac56c512dd5da4b1b347a23f4b70a
1264 #
1265 AC_DEFUN([LC_HAVE_HLIST_FOR_EACH_3ARG],
1266 [AC_MSG_CHECKING([if hlist_for_each_entry has 3 args])
1267 LB_LINUX_TRY_COMPILE([
1268         #include <linux/list.h>
1269         #include <linux/fs.h>
1270 ],[
1271         struct inode *inode;
1272         struct dentry *dentry;
1273         hlist_for_each_entry(dentry, &inode->i_dentry, d_alias) {
1274                 continue;
1275         }
1276 ],[
1277         AC_DEFINE(HAVE_HLIST_FOR_EACH_3ARG, 1, [3 args])
1278         AC_MSG_RESULT([yes])
1279 ],[
1280         AC_MSG_RESULT([no])
1281 ])
1282 ])
1283
1284 #
1285 # 3.9 killed f_vfsmnt by
1286 # 182be684784334598eee1d90274e7f7aa0063616
1287 # replacement is f_path.mnt
1288 #
1289 AC_DEFUN([LC_HAVE_F_PATH_MNT],
1290 [AC_MSG_CHECKING([if struct file has f_path.mnt])
1291 LB_LINUX_TRY_COMPILE([
1292         #include <linux/fs.h>
1293 ],[
1294         struct file *fp = NULL;
1295         struct path  path;
1296
1297         path.mnt = fp->f_path.mnt;
1298 ],[
1299         AC_DEFINE(HAVE_F_PATH_MNT,1,[yes])
1300         AC_MSG_RESULT([yes])
1301 ],[
1302         AC_MSG_RESULT([no])
1303 ])
1304 ])
1305
1306 #
1307 # LC_PROG_LINUX
1308 #
1309 # Lustre linux kernel checks
1310 #
1311 AC_DEFUN([LC_PROG_LINUX],
1312          [
1313          LC_CONFIG_PINGER
1314          LC_CONFIG_CHECKSUM
1315          LC_CONFIG_LIBLUSTRE_RECOVERY
1316          LC_CONFIG_HEALTH_CHECK_WRITE
1317          LC_CONFIG_LRU_RESIZE
1318          LC_LLITE_LLOOP_MODULE
1319
1320          LC_CAPA_CRYPTO
1321          LC_CONFIG_RMTCLIENT
1322          LC_CONFIG_GSS
1323
1324          # 2.6.24
1325          LC_BIO_ENDIO_2ARG
1326          LC_PROCFS_DELETED
1327
1328          # 2.6.27.15-2 sles11
1329          LC_BI_HW_SEGMENTS
1330          LC_HAVE_QUOTAIO_H
1331
1332          # 2.6.32
1333          LC_BLK_QUEUE_MAX_SEGMENTS
1334
1335          # 2.6.34
1336          LC_HAVE_DQUOT_FS_DISK_QUOTA
1337          LC_HAVE_DQUOT_SUSPEND
1338
1339          # 2.6.35, 3.0.0
1340          LC_FILE_FSYNC
1341          LC_EXPORT_SIMPLE_SETATTR
1342          LC_EXPORT_TRUNCATE_COMPLETE_PAGE
1343
1344          # 2.6.36
1345          LC_FS_STRUCT_RWLOCK
1346          LC_SBOPS_EVICT_INODE
1347
1348          # 2.6.37
1349          LC_KERNEL_LOCKED
1350
1351          # 2.6.38
1352          LC_BLKDEV_GET_BY_DEV
1353          LC_GENERIC_PERMISSION
1354          LC_DCACHE_LOCK
1355          LC_INODE_I_RCU
1356          LC_D_COMPARE_7ARGS
1357          LC_D_DELETE_CONST
1358
1359          # 2.6.39
1360          LC_REQUEST_QUEUE_UNPLUG_FN
1361          LC_HAVE_FSTYPE_MOUNT
1362
1363          # 3.0
1364          LC_DIRTY_INODE_WITH_FLAG
1365
1366          # 3.1
1367          LC_LM_XXX_LOCK_MANAGER_OPS
1368          LC_INODE_DIO_WAIT
1369          LC_IOP_GET_ACL
1370          LC_FILE_LLSEEK_SIZE
1371          LC_INODE_PERMISION_2ARGS
1372
1373          # 3.1.1
1374          LC_BLOCKS_FOR_TRUNCATE
1375
1376          # 3.2
1377          LC_HAVE_VOID_MAKE_REQUEST_FN
1378          LC_HAVE_PROTECT_I_NLINK
1379
1380          # 3.3
1381          LC_HAVE_MIGRATE_HEADER
1382          LC_MIGRATEPAGE_4ARGS
1383          LC_SUPEROPS_USE_DENTRY
1384          LC_INODEOPS_USE_UMODE_T
1385
1386          # 3.4
1387          LC_TOUCH_ATIME_1ARG
1388          LC_HAVE_D_MAKE_ROOT
1389          LC_KMAP_ATOMIC_HAS_1ARG
1390
1391          # 3.5
1392          LC_HAVE_CLEAR_INODE
1393          LC_HAVE_ENCODE_FH_PARENT
1394          LC_FILE_LLSEEK_SIZE_5ARG
1395
1396          # 3.6
1397          LC_HAVE_DENTRY_D_ALIAS_HLIST
1398          LC_DENTRY_OPEN_USE_PATH
1399          LC_HAVE_IOP_ATOMIC_OPEN
1400
1401          # 3.7
1402          LC_HAVE_POSIXACL_USER_NS
1403
1404          # 3.9
1405          LC_HAVE_HLIST_FOR_EACH_3ARG
1406          LC_HAVE_F_PATH_MNT
1407
1408          #
1409          if test x$enable_server != xno ; then
1410                 LC_FUNC_DEV_SET_RDONLY
1411                 LC_STACK_SIZE
1412                 LC_QUOTA64
1413                 LC_QUOTA_CONFIG
1414          fi
1415 ])
1416
1417 #
1418 # LC_CONFIG_CLIENT
1419 #
1420 # Check whether to build the client side of Lustre
1421 #
1422 AC_DEFUN([LC_CONFIG_CLIENT],
1423 [AC_MSG_CHECKING([whether to build Lustre client support])
1424 AC_ARG_ENABLE([client],
1425         AC_HELP_STRING([--disable-client],
1426                         [disable Lustre client support]),
1427         [],[enable_client='yes'])
1428 AC_MSG_RESULT([$enable_client])
1429 ])
1430
1431 #
1432 # LC_CONFIG_LIBLUSTRE
1433 #
1434 # whether to build liblustre
1435 #
1436 AC_DEFUN([LC_CONFIG_LIBLUSTRE],
1437 [AC_MSG_CHECKING([whether to build Lustre library])
1438 AC_ARG_ENABLE([liblustre],
1439         AC_HELP_STRING([--disable-liblustre],
1440                         [disable building of Lustre library]),
1441         [],[enable_liblustre=$with_sysio])
1442 AC_MSG_RESULT([$enable_liblustre])
1443 # only build sysio if liblustre is built
1444 with_sysio="$enable_liblustre"
1445
1446 AC_MSG_CHECKING([whether to build liblustre tests])
1447 AC_ARG_ENABLE([liblustre-tests],
1448         AC_HELP_STRING([--enable-liblustre-tests],
1449                         [enable liblustre tests, if --disable-tests is used]),
1450         [],[enable_liblustre_tests=$enable_tests])
1451 if test x$enable_liblustre != xyes ; then
1452    enable_liblustre_tests='no'
1453 fi
1454 AC_MSG_RESULT([$enable_liblustre_tests])
1455
1456 AC_MSG_CHECKING([whether to enable liblustre acl])
1457 AC_ARG_ENABLE([liblustre-acl],
1458         AC_HELP_STRING([--disable-liblustre-acl],
1459                         [disable ACL support for liblustre]),
1460         [],[enable_liblustre_acl=yes])
1461 AC_MSG_RESULT([$enable_liblustre_acl])
1462 if test x$enable_liblustre_acl = xyes ; then
1463   AC_DEFINE(LIBLUSTRE_POSIX_ACL, 1, Liblustre Support ACL-enabled MDS)
1464 fi
1465
1466 #
1467 # --enable-mpitest
1468 #
1469 AC_ARG_ENABLE(mpitests,
1470         AC_HELP_STRING([--enable-mpitests=yes|no|mpicc wrapper],
1471                            [include mpi tests]),
1472         [
1473          enable_mpitests=yes
1474          case $enableval in
1475          yes)
1476                 MPICC_WRAPPER=mpicc
1477                 ;;
1478          no)
1479                 enable_mpitests=no
1480                 ;;
1481          *)
1482                 MPICC_WRAPPER=$enableval
1483                  ;;
1484          esac
1485         ],
1486         [
1487         MPICC_WRAPPER=mpicc
1488         enable_mpitests=yes
1489         ]
1490 )
1491
1492 if test x$enable_mpitests != xno; then
1493         AC_MSG_CHECKING([whether mpitests can be built])
1494         oldcc=$CC
1495         CC=$MPICC_WRAPPER
1496         AC_LINK_IFELSE(
1497             [AC_LANG_PROGRAM([[
1498                     #include <mpi.h>
1499                 ]],[[
1500                     int flag;
1501                     MPI_Initialized(&flag);
1502                 ]])],
1503             [
1504                     AC_MSG_RESULT([yes])
1505             ],[
1506                     AC_MSG_RESULT([no])
1507                     enable_mpitests=no
1508         ])
1509         CC=$oldcc
1510 fi
1511 AC_SUBST(MPICC_WRAPPER)
1512
1513 AC_MSG_NOTICE([Enabling Lustre configure options for libsysio])
1514 ac_configure_args="$ac_configure_args --with-lustre-hack --with-sockets"
1515
1516 LC_CONFIG_PINGER
1517 LC_CONFIG_LIBLUSTRE_RECOVERY
1518 ])
1519
1520 #
1521 # LC_CONFIG_QUOTA
1522 #
1523 # whether to enable quota support global control
1524 #
1525 AC_DEFUN([LC_CONFIG_QUOTA],
1526 [AC_ARG_ENABLE([quota],
1527         AC_HELP_STRING([--enable-quota],
1528                         [enable quota support]),
1529         [],[enable_quota='yes'])
1530 ])
1531
1532 AC_DEFUN([LC_QUOTA],
1533 [#check global
1534 LC_CONFIG_QUOTA
1535 #check for utils
1536 if test x$enable_quota != xno -a x$enable_utils != xno; then
1537 AC_CHECK_HEADER(sys/quota.h,
1538                 [AC_DEFINE(HAVE_SYS_QUOTA_H, 1, [Define to 1 if you have <sys/quota.h>.])],
1539                 [AC_MSG_ERROR([don't find <sys/quota.h> in your system])])
1540 fi
1541 ])
1542
1543 #
1544 # LC_CONFIG_SPLIT
1545 #
1546 # whether to enable split support
1547 #
1548 AC_DEFUN([LC_CONFIG_SPLIT],
1549 [AC_MSG_CHECKING([whether to enable split support])
1550 AC_ARG_ENABLE([split],
1551         AC_HELP_STRING([--enable-split],
1552                         [enable split support]),
1553         [],[enable_split='no'])
1554 AC_MSG_RESULT([$enable_split])
1555 if test x$enable_split != xno; then
1556    AC_DEFINE(HAVE_SPLIT_SUPPORT, 1, [enable split support])
1557 fi
1558 ])
1559
1560 #
1561 # LC_LLITE_LLOOP_MODULE
1562 # lloop_llite.ko does not currently work with page sizes
1563 # of 64k or larger.
1564 #
1565 AC_DEFUN([LC_LLITE_LLOOP_MODULE],
1566 [AC_MSG_CHECKING([whether to enable llite_lloop module])
1567 LB_LINUX_TRY_COMPILE([
1568         #include <asm/page.h>
1569 ],[
1570         #if PAGE_SIZE >= 65536
1571         #error "PAGE_SIZE >= 65536"
1572         #endif
1573 ],[
1574         enable_llite_lloop_module='yes'
1575         AC_MSG_RESULT([yes])
1576 ],[
1577         enable_llite_lloop_module='no'
1578         AC_MSG_RESULT([no])
1579 ])
1580 ])
1581
1582 #
1583 # LC_OSD_ADDON
1584 #
1585 # configure support for optional OSD implementation
1586 #
1587 AC_DEFUN([LC_OSD_ADDON],
1588 [AC_MSG_CHECKING([for osd])
1589 AC_ARG_WITH([osd],
1590         AC_HELP_STRING([--with-osd=path],
1591                        [set path to optional osd]),
1592         [
1593                 case $with_osd in
1594                         no)     ENABLEOSDADDON=0
1595                                 ;;
1596                         *)      OSDADDON="${with_osd}"
1597                                 ENABLEOSDADDON=1
1598                                 ;;
1599                 esac
1600         ], [
1601                 ENABLEOSDADDON=0
1602         ])
1603 if test $ENABLEOSDADDON -eq 0; then
1604         AC_MSG_RESULT([no])
1605         OSDADDON=
1606 else
1607         OSDMODNAME=`basename $OSDADDON`
1608         if test -e $LUSTRE/$OSDMODNAME; then
1609                 AC_MSG_RESULT([can't link])
1610                 OSDADDON=
1611         elif ln -s $OSDADDON $LUSTRE/$OSDMODNAME; then
1612                 AC_MSG_RESULT([$OSDMODNAME])
1613                 OSDADDON="subdir-m += $OSDMODNAME"
1614         else
1615                 AC_MSG_RESULT([can't link])
1616                 OSDADDON=
1617         fi
1618 fi
1619 AC_SUBST(OSDADDON)
1620 ])
1621
1622 #
1623 # LC_CONFIGURE
1624 #
1625 # other configure checks
1626 #
1627 AC_DEFUN([LC_CONFIGURE],
1628 [LC_CONFIG_OBD_BUFFER_SIZE
1629
1630 if test $target_cpu == "i686" -o $target_cpu == "x86_64"; then
1631         CFLAGS="$CFLAGS -Werror"
1632 fi
1633
1634 # maximum MDS thread count
1635 LC_MDS_MAX_THREADS
1636
1637 # include/liblustre.h
1638 AC_CHECK_HEADERS([sys/user.h sys/vfs.h stdint.h blkid/blkid.h])
1639
1640 # liblustre/llite_lib.h
1641 AC_CHECK_HEADERS([xtio.h file.h])
1642
1643 # liblustre/dir.c
1644 AC_CHECK_HEADERS([linux/types.h sys/types.h linux/unistd.h unistd.h])
1645
1646 # liblustre/lutil.c
1647 AC_CHECK_HEADERS([netinet/in.h arpa/inet.h catamount/data.h])
1648 AC_CHECK_FUNCS([inet_ntoa])
1649
1650 # libsysio/src/readlink.c
1651 LC_READLINK_SSIZE_T
1652
1653 # lvfs/prng.c - depends on linux/types.h from liblustre/dir.c
1654 AC_CHECK_HEADERS([linux/random.h], [], [],
1655                  [#ifdef HAVE_LINUX_TYPES_H
1656                   # include <linux/types.h>
1657                   #endif
1658                  ])
1659
1660 # utils/llverfs.c
1661 AC_CHECK_HEADERS([ext2fs/ext2fs.h])
1662
1663 # check for -lz support
1664 ZLIB=""
1665 AC_CHECK_LIB([z],
1666              [adler32],
1667              [AC_CHECK_HEADERS([zlib.h],
1668                                [ZLIB="-lz"
1669                                 AC_DEFINE([HAVE_ADLER], 1,
1670                                           [support alder32 checksum type])],
1671                                [AC_MSG_WARN([No zlib-devel package found,
1672                                              unable to use adler32 checksum])])],
1673              [AC_MSG_WARN([No zlib package found, unable to use adler32 checksum])]
1674 )
1675 AC_SUBST(ZLIB)
1676
1677 SELINUX=""
1678 AC_CHECK_LIB([selinux],
1679                 [is_selinux_enabled],
1680                 [AC_CHECK_HEADERS([selinux.h],
1681                                 [SELINUX="-lselinux"
1682                                 AC_DEFINE([HAVE_SELINUX], 1,
1683                                                 [support for selinux ])],
1684                                 [AC_MSG_WARN([No selinux-devel package found,
1685                                                 unable to build selinux enabled
1686                                                 tools])])],
1687                 [AC_MSG_WARN([No selinux package found, unable to build selinux
1688                                 enabled tools])]
1689 )
1690 AC_SUBST(SELINUX)
1691
1692 # Super safe df
1693 AC_ARG_ENABLE([mindf],
1694       AC_HELP_STRING([--enable-mindf],
1695                       [Make statfs report the minimum available space on any single OST instead of the sum of free space on all OSTs]),
1696       [],[])
1697 if test "$enable_mindf" = "yes" ;  then
1698       AC_DEFINE([MIN_DF], 1, [Report minimum OST free space])
1699 fi
1700
1701 AC_ARG_ENABLE([fail_alloc],
1702         AC_HELP_STRING([--disable-fail-alloc],
1703                 [disable randomly alloc failure]),
1704         [],[enable_fail_alloc=yes])
1705 AC_MSG_CHECKING([whether to randomly failing memory alloc])
1706 AC_MSG_RESULT([$enable_fail_alloc])
1707 if test x$enable_fail_alloc != xno ; then
1708         AC_DEFINE([RANDOM_FAIL_ALLOC], 1, [enable randomly alloc failure])
1709 fi
1710
1711 AC_ARG_ENABLE([invariants],
1712         AC_HELP_STRING([--enable-invariants],
1713                 [enable invariant checking (cpu intensive)]),
1714         [],[])
1715 AC_MSG_CHECKING([whether to check invariants (expensive cpu-wise)])
1716 AC_MSG_RESULT([$enable_invariants])
1717 if test x$enable_invariants = xyes ; then
1718         AC_DEFINE([CONFIG_LUSTRE_DEBUG_EXPENSIVE_CHECK], 1, [enable invariant checking])
1719 fi
1720
1721 AC_ARG_ENABLE([lu_ref],
1722         AC_HELP_STRING([--enable-lu_ref],
1723                 [enable lu_ref reference tracking code]),
1724         [],[])
1725 AC_MSG_CHECKING([whether to track references with lu_ref])
1726 AC_MSG_RESULT([$enable_lu_ref])
1727 if test x$enable_lu_ref = xyes ; then
1728         AC_DEFINE([USE_LU_REF], 1, [enable lu_ref reference tracking code])
1729 fi
1730
1731 AC_ARG_ENABLE([pgstate-track],
1732               AC_HELP_STRING([--enable-pgstate-track],
1733                              [enable page state tracking]),
1734               [enable_pgstat_track='yes'],[])
1735 AC_MSG_CHECKING([whether to enable page state tracking])
1736 AC_MSG_RESULT([$enable_pgstat_track])
1737 if test x$enable_pgstat_track = xyes ; then
1738         AC_DEFINE([CONFIG_DEBUG_PAGESTATE_TRACKING], 1,
1739                   [enable page state tracking code])
1740 fi
1741 ])
1742
1743 #
1744 # LC_CONDITIONALS
1745 #
1746 # AM_CONDITIONALS for lustre
1747 #
1748 AC_DEFUN([LC_CONDITIONALS],
1749 [AM_CONDITIONAL(LIBLUSTRE, test x$enable_liblustre = xyes)
1750 AM_CONDITIONAL(LIBLUSTRE_TESTS, test x$enable_liblustre_tests = xyes)
1751 AM_CONDITIONAL(MPITESTS, test x$enable_mpitests = xyes, Build MPI Tests)
1752 AM_CONDITIONAL(CLIENT, test x$enable_client = xyes)
1753 AM_CONDITIONAL(SERVER, test x$enable_server = xyes)
1754 AM_CONDITIONAL(SPLIT, test x$enable_split = xyes)
1755 AM_CONDITIONAL(BLKID, test x$ac_cv_header_blkid_blkid_h = xyes)
1756 AM_CONDITIONAL(EXT2FS_DEVEL, test x$ac_cv_header_ext2fs_ext2fs_h = xyes)
1757 AM_CONDITIONAL(GSS, test x$enable_gss = xyes)
1758 AM_CONDITIONAL(GSS_KEYRING, test x$enable_gss_keyring = xyes)
1759 AM_CONDITIONAL(GSS_PIPEFS, test x$enable_gss_pipefs = xyes)
1760 AM_CONDITIONAL(LIBPTHREAD, test x$enable_libpthread = xyes)
1761 AM_CONDITIONAL(LLITE_LLOOP, test x$enable_llite_lloop_module = xyes)
1762 ])
1763
1764 #
1765 # LC_CONFIG_FILES
1766 #
1767 # files that should be generated with AC_OUTPUT
1768 #
1769 AC_DEFUN([LC_CONFIG_FILES],
1770 [AC_CONFIG_FILES([
1771 lustre/Makefile
1772 lustre/autoMakefile
1773 lustre/autoconf/Makefile
1774 lustre/conf/Makefile
1775 lustre/contrib/Makefile
1776 lustre/doc/Makefile
1777 lustre/include/Makefile
1778 lustre/include/lustre_ver.h
1779 lustre/include/linux/Makefile
1780 lustre/include/darwin/Makefile
1781 lustre/include/lustre/Makefile
1782 lustre/kernel_patches/targets/2.6-rhel6.target
1783 lustre/kernel_patches/targets/2.6-rhel5.target
1784 lustre/kernel_patches/targets/2.6-sles11.target
1785 lustre/kernel_patches/targets/3.0-sles11.target
1786 lustre/kernel_patches/targets/3.0-sles11sp3.target
1787 lustre/kernel_patches/targets/2.6-fc11.target
1788 lustre/kernel_patches/targets/2.6-fc12.target
1789 lustre/kernel_patches/targets/2.6-fc15.target
1790 lustre/kernel_patches/targets/3.x-fc18.target
1791 lustre/ldlm/Makefile
1792 lustre/fid/Makefile
1793 lustre/fid/autoMakefile
1794 lustre/liblustre/Makefile
1795 lustre/liblustre/tests/Makefile
1796 lustre/liblustre/tests/mpi/Makefile
1797 lustre/llite/Makefile
1798 lustre/llite/autoMakefile
1799 lustre/lclient/Makefile
1800 lustre/lov/Makefile
1801 lustre/lov/autoMakefile
1802 lustre/lvfs/Makefile
1803 lustre/lvfs/autoMakefile
1804 lustre/mdc/Makefile
1805 lustre/mdc/autoMakefile
1806 lustre/lmv/Makefile
1807 lustre/lmv/autoMakefile
1808 lustre/lfsck/Makefile
1809 lustre/lfsck/autoMakefile
1810 lustre/mdt/Makefile
1811 lustre/mdt/autoMakefile
1812 lustre/mdd/Makefile
1813 lustre/mdd/autoMakefile
1814 lustre/fld/Makefile
1815 lustre/fld/autoMakefile
1816 lustre/obdclass/Makefile
1817 lustre/obdclass/autoMakefile
1818 lustre/obdclass/linux/Makefile
1819 lustre/obdecho/Makefile
1820 lustre/obdecho/autoMakefile
1821 lustre/ofd/Makefile
1822 lustre/ofd/autoMakefile
1823 lustre/osc/Makefile
1824 lustre/osc/autoMakefile
1825 lustre/ost/Makefile
1826 lustre/ost/autoMakefile
1827 lustre/osd-ldiskfs/Makefile
1828 lustre/osd-ldiskfs/autoMakefile
1829 lustre/osd-zfs/Makefile
1830 lustre/osd-zfs/autoMakefile
1831 lustre/mgc/Makefile
1832 lustre/mgc/autoMakefile
1833 lustre/mgs/Makefile
1834 lustre/mgs/autoMakefile
1835 lustre/target/Makefile
1836 lustre/ptlrpc/Makefile
1837 lustre/ptlrpc/autoMakefile
1838 lustre/ptlrpc/gss/Makefile
1839 lustre/ptlrpc/gss/autoMakefile
1840 lustre/quota/Makefile
1841 lustre/quota/autoMakefile
1842 lustre/scripts/Makefile
1843 lustre/tests/Makefile
1844 lustre/tests/mpi/Makefile
1845 lustre/utils/Makefile
1846 lustre/utils/gss/Makefile
1847 lustre/osp/Makefile
1848 lustre/osp/autoMakefile
1849 lustre/lod/Makefile
1850 lustre/lod/autoMakefile
1851 lustre/obdclass/darwin/Makefile
1852 ])
1853 ])