lustre/autoconf/lustre-core.m4

   1 #
   2 # LC_CONFIG_SRCDIR
   3 #
   4 # Wrapper for AC_CONFIG_SUBDIR
   5 #
   6 AC_DEFUN([LC_CONFIG_SRCDIR],
   7 [AC_CONFIG_SRCDIR([lustre/obdclass/obdo.c])
   8 libcfs_is_module=yes
   9 ldiskfs_is_ext4=yes
  10 ])
  11
  12 #
  13 # LC_PATH_DEFAULTS
  14 #
  15 # lustre specific paths
  16 #
  17 AC_DEFUN([LC_PATH_DEFAULTS],
  18 [# ptlrpc kernel build requires this
  19 LUSTRE="$PWD/lustre"
  20 AC_SUBST(LUSTRE)
  21
  22 # mount.lustre
  23 rootsbindir='/sbin'
  24 AC_SUBST(rootsbindir)
  25
  26 demodir='$(docdir)/demo'
  27 AC_SUBST(demodir)
  28
  29 pkgexampledir='${pkgdatadir}/examples'
  30 AC_SUBST(pkgexampledir)
  31 ])
  32
  33 #
  34 # LC_TARGET_SUPPORTED
  35 #
  36 # is the target os supported?
  37 #
  38 AC_DEFUN([LC_TARGET_SUPPORTED],
  39 [case $target_os in
  40         linux* | darwin*)
  41 $1
  42                 ;;
  43         *)
  44 $2
  45                 ;;
  46 esac
  47 ])
  48
  49 #
  50 # LC_CONFIG_OBD_BUFFER_SIZE
  51 #
  52 # the maximum buffer size of lctl ioctls
  53 #
  54 AC_DEFUN([LC_CONFIG_OBD_BUFFER_SIZE],
  55 [AC_MSG_CHECKING([maximum OBD ioctl size])
  56 AC_ARG_WITH([obd-buffer-size],
  57         AC_HELP_STRING([--with-obd-buffer-size=[size]],
  58                         [set lctl ioctl maximum bytes (default=8192)]),
  59         [
  60                 OBD_BUFFER_SIZE=$with_obd_buffer_size
  61         ],[
  62                 OBD_BUFFER_SIZE=8192
  63         ])
  64 AC_MSG_RESULT([$OBD_BUFFER_SIZE bytes])
  65 AC_DEFINE_UNQUOTED(OBD_MAX_IOCTL_BUFFER, $OBD_BUFFER_SIZE, [IOCTL Buffer Size])
  66 ])
  67
  68 #
  69 # LC_READLINK_SSIZE_T
  70 #
  71 AC_DEFUN([LC_READLINK_SSIZE_T],
  72 [AC_MSG_CHECKING([if readlink returns ssize_t])
  73 AC_TRY_COMPILE([
  74         #include <unistd.h>
  75 ],[
  76         ssize_t readlink(const char *, char *, size_t);
  77 ],[
  78         AC_MSG_RESULT([yes])
  79         AC_DEFINE(HAVE_POSIX_1003_READLINK, 1, [readlink returns ssize_t])
  80 ],[
  81         AC_MSG_RESULT([no])
  82 ])
  83 ])
  84
  85 #
  86 # LC_FUNC_DEV_SET_RDONLY
  87 #
  88 # check whether dev_set_rdonly is exported.  This is needed until we
  89 # have another mechanism to fence IO from the underlying device.
  90 #
  91 AC_DEFUN([LC_FUNC_DEV_SET_RDONLY],
  92 [LB_CHECK_SYMBOL_EXPORT([dev_set_rdonly],
  93 [block/ll_rw_block.c,block/blk-core.c],[
  94         AC_DEFINE(HAVE_DEV_SET_RDONLY, 1, [kernel exports dev_set_rdonly])
  95 ],[
  96         AC_MSG_WARN([kernel missing dev_set_rdonly patch for testing])
  97 ])
  98 ])
  99
 100 #
 101 # Ensure stack size big than 8k in Lustre server (all kernels)
 102 #
 103 AC_DEFUN([LC_STACK_SIZE],
 104 [AC_MSG_CHECKING([stack size big than 8k])
 105 LB_LINUX_TRY_COMPILE([
 106         #include <linux/thread_info.h>
 107 ],[
 108         #if THREAD_SIZE < 8192
 109         #error "stack size < 8192"
 110         #endif
 111 ],[
 112         AC_MSG_RESULT(yes)
 113 ],[
 114         AC_MSG_ERROR([Lustre requires that Linux is configured with at least a 8KB stack.])
 115 ])
 116 ])
 117
 118 #
 119 # Allow the user to set the MDS thread upper limit
 120 #
 121 AC_DEFUN([LC_MDS_MAX_THREADS],
 122 [
 123         AC_ARG_WITH([mds_max_threads],
 124         AC_HELP_STRING([--with-mds-max-threads=size],
 125                         [define the maximum number of threads available on the MDS: (default=512)]),
 126         [
 127                 MDS_THREAD_COUNT=$with_mds_max_threads
 128                 AC_DEFINE_UNQUOTED(MDT_MAX_THREADS, $MDS_THREAD_COUNT, [maximum number of mdt threads])
 129         ])
 130 ])
 131
 132 #
 133 # LC_CONFIG_PINGER
 134 #
 135 # the pinger is temporary, until we have the recovery node in place
 136 #
 137 AC_DEFUN([LC_CONFIG_PINGER],
 138 [AC_MSG_CHECKING([whether to enable pinger support])
 139 AC_ARG_ENABLE([pinger],
 140         AC_HELP_STRING([--disable-pinger],
 141                         [disable recovery pinger support]),
 142         [],[enable_pinger='yes'])
 143 AC_MSG_RESULT([$enable_pinger])
 144 if test x$enable_pinger != xno ; then
 145   AC_DEFINE(ENABLE_PINGER, 1, Use the Pinger)
 146 fi
 147 ])
 148
 149 #
 150 # LC_CONFIG_CHECKSUM
 151 #
 152 # do checksum of bulk data between client and OST
 153 #
 154 AC_DEFUN([LC_CONFIG_CHECKSUM],
 155 [AC_MSG_CHECKING([whether to enable data checksum support])
 156 AC_ARG_ENABLE([checksum],
 157        AC_HELP_STRING([--disable-checksum],
 158                        [disable data checksum support]),
 159        [],[enable_checksum='yes'])
 160 AC_MSG_RESULT([$enable_checksum])
 161 if test x$enable_checksum != xno ; then
 162   AC_DEFINE(ENABLE_CHECKSUM, 1, do data checksums)
 163 fi
 164 ])
 165
 166 #
 167 # LC_CONFIG_LIBLUSTRE_RECOVERY
 168 #
 169 AC_DEFUN([LC_CONFIG_LIBLUSTRE_RECOVERY],
 170 [AC_MSG_CHECKING([whether to enable liblustre recovery support])
 171 AC_ARG_ENABLE([liblustre-recovery],
 172         AC_HELP_STRING([--disable-liblustre-recovery],
 173                         [disable liblustre recovery support]),
 174         [],[enable_liblustre_recovery='yes'])
 175 AC_MSG_RESULT([$enable_liblustre_recovery])
 176 if test x$enable_liblustre_recovery != xno ; then
 177   AC_DEFINE(ENABLE_LIBLUSTRE_RECOVERY, 1, Liblustre Can Recover)
 178 fi
 179 ])
 180
 181 #
 182 # LC_CONFIG_HEALTH_CHECK_WRITE
 183 #
 184 # Turn off the actual write to the disk
 185 #
 186 AC_DEFUN([LC_CONFIG_HEALTH_CHECK_WRITE],
 187 [AC_MSG_CHECKING([whether to enable a write with the health check])
 188 AC_ARG_ENABLE([health_write],
 189         AC_HELP_STRING([--enable-health_write],
 190                         [enable disk writes when doing health check]),
 191         [],[enable_health_write='no'])
 192 AC_MSG_RESULT([$enable_health_write])
 193 if test x$enable_health_write != xno ; then
 194   AC_DEFINE(USE_HEALTH_CHECK_WRITE, 1, Write when Checking Health)
 195 fi
 196 ])
 197
 198 AC_DEFUN([LC_CONFIG_LRU_RESIZE],
 199 [AC_MSG_CHECKING([whether to enable lru self-adjusting])
 200 AC_ARG_ENABLE([lru_resize],
 201         AC_HELP_STRING([--enable-lru-resize],
 202                         [enable lru resize support]),
 203         [],[enable_lru_resize='yes'])
 204 AC_MSG_RESULT([$enable_lru_resize])
 205 if test x$enable_lru_resize != xno; then
 206    AC_DEFINE(HAVE_LRU_RESIZE_SUPPORT, 1, [Enable lru resize support])
 207 fi
 208 ])
 209
 210 #
 211 # Quota support. The kernel must support CONFIG_QUOTA.
 212 #
 213 AC_DEFUN([LC_QUOTA_CONFIG],
 214 [LB_LINUX_CONFIG_IM([QUOTA],[],[
 215         AC_MSG_ERROR([Lustre quota requires that CONFIG_QUOTA is enabled in your kernel.])
 216         ])
 217 ])
 218
 219 # truncate_complete_page() was exported from RHEL5/SLES10, but not in SLES11 SP0 (2.6.27)
 220 # remove_from_page_cache() was exported between 2.6.35 and 2.6.38
 221 # delete_from_page_cache() is exported from 2.6.39
 222 AC_DEFUN([LC_EXPORT_TRUNCATE_COMPLETE],
 223          [LB_CHECK_SYMBOL_EXPORT([truncate_complete_page],
 224                                  [mm/truncate.c],
 225                                  [AC_DEFINE(HAVE_TRUNCATE_COMPLETE_PAGE, 1,
 226                                             [kernel export truncate_complete_page])])
 227           LB_CHECK_SYMBOL_EXPORT([remove_from_page_cache],
 228                                  [mm/filemap.c],
 229                                  [AC_DEFINE(HAVE_REMOVE_FROM_PAGE_CACHE, 1,
 230                                             [kernel export remove_from_page_cache])])
 231           LB_CHECK_SYMBOL_EXPORT([delete_from_page_cache],
 232                                  [mm/filemap.c],
 233                                  [AC_DEFINE(HAVE_DELETE_FROM_PAGE_CACHE, 1,
 234                                             [kernel export delete_from_page_cache])])
 235          ])
 236
 237 AC_DEFUN([LC_EXPORT_D_REHASH_COND],
 238 [LB_CHECK_SYMBOL_EXPORT([d_rehash_cond],
 239 [fs/dcache.c],[
 240 AC_DEFINE(HAVE_D_REHASH_COND, 1,
 241             [d_rehash_cond is exported by the kernel])
 242 ],[
 243 ])
 244 ])
 245
 246 AC_DEFUN([LC_EXPORT___D_REHASH],
 247 [LB_CHECK_SYMBOL_EXPORT([__d_rehash],
 248 [fs/dcache.c],[
 249 AC_DEFINE(HAVE___D_REHASH, 1,
 250             [__d_rehash is exported by the kernel])
 251 ],[
 252 ])
 253 ])
 254
 255 # The actual symbol exported varies among architectures, so we need
 256 # to check many symbols (but only in the current architecture.)  No
 257 # matter what symbol is exported, the kernel #defines node_to_cpumask
 258 # to the appropriate function and that's what we use.
 259 AC_DEFUN([LC_EXPORT_NODE_TO_CPUMASK],
 260          [LB_CHECK_SYMBOL_EXPORT([node_to_cpumask],
 261                                  [arch/$LINUX_ARCH/mm/numa.c],
 262                                  [AC_DEFINE(HAVE_NODE_TO_CPUMASK, 1,
 263                                             [node_to_cpumask is exported by
 264                                              the kernel])]) # x86_64
 265           LB_CHECK_SYMBOL_EXPORT([node_to_cpu_mask],
 266                                  [arch/$LINUX_ARCH/kernel/smpboot.c],
 267                                  [AC_DEFINE(HAVE_NODE_TO_CPUMASK, 1,
 268                                             [node_to_cpumask is exported by
 269                                              the kernel])]) # ia64
 270           LB_CHECK_SYMBOL_EXPORT([node_2_cpu_mask],
 271                                  [arch/$LINUX_ARCH/kernel/smpboot.c],
 272                                  [AC_DEFINE(HAVE_NODE_TO_CPUMASK, 1,
 273                                             [node_to_cpumask is exported by
 274                                              the kernel])]) # i386
 275           ])
 276
 277 #
 278 #
 279 # between 2.6.5 - 2.6.22 filemap_populate is exported in some kernels
 280 #
 281 AC_DEFUN([LC_FILEMAP_POPULATE],
 282 [AC_MSG_CHECKING([for exported filemap_populate])
 283 LB_LINUX_TRY_COMPILE([
 284         #include <asm/page.h>
 285         #include <linux/mm.h>
 286 ],[
 287        filemap_populate(NULL, 0, 0, __pgprot(0), 0, 0);
 288 ],[
 289         AC_MSG_RESULT([yes])
 290         AC_DEFINE(HAVE_FILEMAP_POPULATE, 1, [Kernel exports filemap_populate])
 291 ],[
 292         AC_MSG_RESULT([no])
 293 ])
 294 ])
 295
 296 #
 297 # added in 2.6.17
 298 #
 299 AC_DEFUN([LC_BIT_SPINLOCK_H],
 300 [LB_CHECK_FILE([$LINUX/include/linux/bit_spinlock.h],[
 301         AC_MSG_CHECKING([if bit_spinlock.h can be compiled])
 302         LB_LINUX_TRY_COMPILE([
 303                 #include <asm/processor.h>
 304                 #include <linux/spinlock.h>
 305                 #include <linux/bit_spinlock.h>
 306         ],[],[
 307                 AC_MSG_RESULT([yes])
 308                 AC_DEFINE(HAVE_BIT_SPINLOCK_H, 1, [Kernel has bit_spinlock.h])
 309         ],[
 310                 AC_MSG_RESULT([no])
 311         ])
 312 ],
 313 [])
 314 ])
 315
 316 #
 317 # LC_CONST_ACL_SIZE
 318 #
 319 AC_DEFUN([LC_CONST_ACL_SIZE],
 320 [AC_MSG_CHECKING([calc acl size])
 321 tmp_flags="$CFLAGS"
 322 CFLAGS="$CFLAGS -I$LINUX/include -I$LINUX_OBJ/include -I$LINUX_OBJ/include2 -I$LINUX/arch/`echo $target_cpu|sed -e 's/powerpc64/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include -include $AUTOCONF_HDIR/autoconf.h $EXTRA_KCFLAGS"
 323 AC_TRY_RUN([
 324         #define __KERNEL__
 325         #include <linux/types.h>
 326         #undef __KERNEL__
 327         // block include
 328         #define __LINUX_POSIX_ACL_H
 329
 330         #ifdef CONFIG_FS_POSIX_ACL
 331         # include <linux/posix_acl_xattr.h>
 332         #endif
 333
 334         #include <stdio.h>
 335
 336         int main(void)
 337         {
 338                 /* LUSTRE_POSIX_ACL_MAX_ENTRIES  = 32 */
 339             int size = posix_acl_xattr_size(32);
 340             FILE *f = fopen("acl.size","w+");
 341             fprintf(f,"%d", size);
 342             fclose(f);
 343
 344             return 0;
 345         }
 346 ],[
 347         acl_size=`cat acl.size`
 348         AC_MSG_RESULT([ACL size $acl_size])
 349         AC_DEFINE_UNQUOTED(XATTR_ACL_SIZE, AS_TR_SH([$acl_size]), [size of xattr acl])
 350 ],[
 351         AC_ERROR([ACL size can't be computed])
 352 ],[
 353         AC_MSG_RESULT([can't check ACL size, make it 260])
 354         AC_DEFINE_UNQUOTED(XATTR_ACL_SIZE,260)
 355 ])
 356 CFLAGS="$tmp_flags"
 357 ])
 358
 359 #
 360 # LC_CAPA_CRYPTO
 361 #
 362 AC_DEFUN([LC_CAPA_CRYPTO],
 363 [LB_LINUX_CONFIG_IM([CRYPTO],[],[
 364         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO is enabled in your kernel.])
 365 ])
 366 LB_LINUX_CONFIG_IM([CRYPTO_HMAC],[],[
 367         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO_HMAC is enabled in your kernel.])
 368 ])
 369 LB_LINUX_CONFIG_IM([CRYPTO_SHA1],[],[
 370         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO_SHA1 is enabled in your kernel.])
 371 ])
 372 ])
 373
 374 #
 375 # LC_CONFIG_RMTCLIENT
 376 #
 377 dnl FIXME
 378 dnl the AES symbol usually tied with arch, e.g. CRYPTO_AES_586
 379 dnl FIXME
 380 AC_DEFUN([LC_CONFIG_RMTCLIENT],
 381 [LB_LINUX_CONFIG_IM([CRYPTO_AES],[],[
 382         AC_MSG_WARN([Lustre remote client require that CONFIG_CRYPTO_AES is enabled in your kernel.])
 383 ])
 384 ])
 385
 386 #
 387 # LC_CONFIG_GSS_KEYRING (default enabled, if gss is enabled)
 388 #
 389 AC_DEFUN([LC_CONFIG_GSS_KEYRING],
 390 [AC_MSG_CHECKING([whether to enable gss keyring backend])
 391  AC_ARG_ENABLE([gss_keyring],
 392                [AC_HELP_STRING([--disable-gss-keyring],
 393                                [disable gss keyring backend])],
 394                [],[enable_gss_keyring='yes'])
 395  AC_MSG_RESULT([$enable_gss_keyring])
 396
 397  if test x$enable_gss_keyring != xno; then
 398         LB_LINUX_CONFIG_IM([KEYS],[],
 399                            [AC_MSG_ERROR([GSS keyring backend require that CONFIG_KEYS be enabled in your kernel.])])
 400
 401         AC_CHECK_LIB([keyutils], [keyctl_search], [],
 402                      [AC_MSG_ERROR([libkeyutils is not found, which is required by gss keyring backend])],)
 403
 404         AC_DEFINE([HAVE_GSS_KEYRING], [1],
 405                   [Define this if you enable gss keyring backend])
 406  fi
 407 ])
 408
 409 AC_DEFUN([LC_CONFIG_SUNRPC],
 410 [LB_LINUX_CONFIG_IM([SUNRPC],[],
 411                     [AC_MSG_ERROR([kernel SUNRPC support is required by using GSS.])])
 412 ])
 413
 414 #
 415 # LC_CONFIG_GSS (default disabled)
 416 #
 417 # Build gss and related tools of Lustre. Currently both kernel and user space
 418 # parts are depend on linux platform.
 419 #
 420 AC_DEFUN([LC_CONFIG_GSS],
 421 [AC_MSG_CHECKING([whether to enable gss/krb5 support])
 422  AC_ARG_ENABLE([gss],
 423                [AC_HELP_STRING([--enable-gss], [enable gss/krb5 support])],
 424                [],[enable_gss='no'])
 425  AC_MSG_RESULT([$enable_gss])
 426
 427  if test x$enable_gss == xyes; then
 428         LC_CONFIG_GSS_KEYRING
 429         LC_CONFIG_SUNRPC
 430
 431         AC_DEFINE([HAVE_GSS], [1], [Define this if you enable gss])
 432
 433         LB_LINUX_CONFIG_IM([CRYPTO_MD5],[],
 434                            [AC_MSG_WARN([kernel MD5 support is recommended by using GSS.])])
 435         LB_LINUX_CONFIG_IM([CRYPTO_SHA1],[],
 436                            [AC_MSG_WARN([kernel SHA1 support is recommended by using GSS.])])
 437         LB_LINUX_CONFIG_IM([CRYPTO_SHA256],[],
 438                            [AC_MSG_WARN([kernel SHA256 support is recommended by using GSS.])])
 439         LB_LINUX_CONFIG_IM([CRYPTO_SHA512],[],
 440                            [AC_MSG_WARN([kernel SHA512 support is recommended by using GSS.])])
 441
 442         AC_CHECK_LIB([gssapi], [gss_init_sec_context],
 443                      [GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssapi"],
 444                      [AC_CHECK_LIB([gssglue], [gss_init_sec_context],
 445                                    [GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssglue"],
 446                                    [AC_MSG_ERROR([libgssapi or libgssglue is not found, which is required by GSS.])])],)
 447
 448         AC_SUBST(GSSAPI_LIBS)
 449
 450         AC_KERBEROS_V5
 451  fi
 452 ])
 453
 454 AC_DEFUN([LC_TASK_CLENV_STORE],
 455 [
 456         AC_MSG_CHECKING([if we can store cl_env in task_struct])
 457         if test x$have_task_clenv_store != xyes ; then
 458                 LC_TASK_CLENV_TUX_INFO
 459         fi
 460 ])
 461
 462 # 2.6.12
 463
 464 # ~2.6.12 merge patch from oracle to convert tree_lock from spinlock to rwlock
 465 # yet tree_lock is converted from rwlock to spin_lock since v2.6.26
 466 AC_DEFUN([LC_RW_TREE_LOCK],
 467 [AC_MSG_CHECKING([if kernel has tree_lock as rwlock])
 468 tmp_flags="$EXTRA_KCFLAGS"
 469 EXTRA_KCFLAGS="-Werror"
 470 LB_LINUX_TRY_COMPILE([
 471         #include <linux/fs.h>
 472 ],[
 473         struct address_space a;
 474
 475         write_lock(&a.tree_lock);
 476 ],[
 477         AC_MSG_RESULT([yes])
 478         AC_DEFINE(HAVE_RW_TREE_LOCK, 1, [kernel has tree_lock as rw_lock])
 479 ],[
 480         AC_MSG_RESULT([no])
 481 ])
 482 EXTRA_KCFLAGS="$tmp_flags"
 483 ])
 484
 485 # 2.6.18
 486
 487 # LC_UMOUNTBEGIN_HAS_VFSMOUNT
 488 # 2.6.18~2.6.25 umount_begin has different parameters
 489 AC_DEFUN([LC_UMOUNTBEGIN_HAS_VFSMOUNT],
 490 [AC_MSG_CHECKING([if umount_begin needs vfsmount parameter instead of super_block])
 491 tmp_flags="$EXTRA_KCFLAGS"
 492 EXTRA_KCFLAGS="-Werror"
 493 LB_LINUX_TRY_COMPILE([
 494         #include <linux/fs.h>
 495
 496         struct vfsmount;
 497         static void cfg_umount_begin (struct vfsmount *v, int flags)
 498         {
 499                 ;
 500         }
 501
 502         static struct super_operations cfg_super_operations = {
 503                 .umount_begin   = cfg_umount_begin,
 504         };
 505 ],[
 506         cfg_super_operations.umount_begin(NULL,0);
 507 ],[
 508         AC_MSG_RESULT(yes)
 509         AC_DEFINE(HAVE_UMOUNTBEGIN_VFSMOUNT, 1,
 510                 [Define umount_begin need second argument])
 511 ],[
 512         AC_MSG_RESULT(no)
 513 ])
 514 EXTRA_KCFLAGS="$tmp_flags"
 515 ])
 516
 517 #2.6.18 + RHEL5 (fc6)
 518
 519 #
 520 # LC_LINUX_FIEMAP_H
 521 #
 522 # fiemap.h is added since v2.6.28
 523 # RHEL5 2.6.18 has it, while SLES10 2.6.27 does not
 524 #
 525 AC_DEFUN([LC_LINUX_FIEMAP_H],
 526 [LB_CHECK_FILE([$LINUX/include/linux/fiemap.h],[
 527         AC_MSG_CHECKING([if fiemap.h can be compiled])
 528         LB_LINUX_TRY_COMPILE([
 529                 #include <linux/types.h>
 530                 #include <linux/fiemap.h>
 531         ],[],[
 532                 AC_MSG_RESULT([yes])
 533                 AC_DEFINE(HAVE_LINUX_FIEMAP_H, 1, [Kernel has fiemap.h])
 534         ],[
 535                 AC_MSG_RESULT([no])
 536         ])
 537 ],
 538 [])
 539 ])
 540
 541 # 2.6.19
 542
 543 # LC_FILE_WRITEV
 544 # 2.6.19 replaced writev with aio_write
 545 AC_DEFUN([LC_FILE_WRITEV],
 546 [AC_MSG_CHECKING([writev in fops])
 547 LB_LINUX_TRY_COMPILE([
 548         #include <linux/fs.h>
 549 ],[
 550         struct file_operations *fops = NULL;
 551         fops->writev = NULL;
 552 ],[
 553         AC_MSG_RESULT(yes)
 554         AC_DEFINE(HAVE_FILE_WRITEV, 1,
 555                 [use fops->writev])
 556 ],[
 557         AC_MSG_RESULT(no)
 558 ])
 559 ])
 560
 561 # LC_FILE_READV
 562 # 2.6.19 replaced readv with aio_read
 563 AC_DEFUN([LC_FILE_READV],
 564 [AC_MSG_CHECKING([readv in fops])
 565 LB_LINUX_TRY_COMPILE([
 566         #include <linux/fs.h>
 567 ],[
 568         struct file_operations *fops = NULL;
 569         fops->readv = NULL;
 570 ],[
 571         AC_MSG_RESULT(yes)
 572         AC_DEFINE(HAVE_FILE_READV, 1,
 573                 [use fops->readv])
 574 ],[
 575         AC_MSG_RESULT(no)
 576 ])
 577 ])
 578
 579 # 2.6.20
 580
 581 # LC_CANCEL_DIRTY_PAGE
 582 # 2.6.20 introduced cancel_dirty_page instead of clear_page_dirty.
 583 AC_DEFUN([LC_CANCEL_DIRTY_PAGE],
 584         [AC_MSG_CHECKING([kernel has cancel_dirty_page])
 585         # the implementation of cancel_dirty_page in OFED 1.4.1's SLES10 SP2
 586         # backport is broken, so ignore it
 587         if test -f $OFED_BACKPORT_PATH/linux/mm.h &&
 588            test "$(sed -ne '/^static inline void cancel_dirty_page(struct page \*page, unsigned int account_size)$/,/^}$/p' $OFED_BACKPORT_PATH/linux/mm.h | md5sum)" = "c518cb32d6394760c5bca14cb7538d3e  -"; then
 589                 AC_MSG_RESULT(no)
 590         else
 591                 LB_LINUX_TRY_COMPILE([
 592                         #include <linux/mm.h>
 593                         #include <linux/page-flags.h>
 594 ],[
 595                         cancel_dirty_page(NULL, 0);
 596 ],[
 597                         AC_MSG_RESULT(yes)
 598                         AC_DEFINE(HAVE_CANCEL_DIRTY_PAGE, 1,
 599                                   [kernel has cancel_dirty_page instead of clear_page_dirty])
 600 ],[
 601                         AC_MSG_RESULT(no)
 602 ])
 603         fi
 604 ])
 605
 606 # raid5-zerocopy patch
 607
 608 #
 609 # LC_PAGE_CONSTANT
 610 #
 611 # In order to support raid5 zerocopy patch, we have to patch the kernel to make
 612 # it support constant page, which means the page won't be modified during the
 613 # IO.
 614 #
 615 AC_DEFUN([LC_PAGE_CONSTANT],
 616 [AC_MSG_CHECKING([if kernel have PageConstant defined])
 617 LB_LINUX_TRY_COMPILE([
 618         #include <linux/mm.h>
 619         #include <linux/page-flags.h>
 620 ],[
 621         #ifndef PG_constant
 622         #error "Have no raid5 zcopy patch"
 623         #endif
 624 ],[
 625         AC_MSG_RESULT(yes)
 626         AC_DEFINE(HAVE_PAGE_CONSTANT, 1, [kernel have PageConstant supported])
 627 ],[
 628         AC_MSG_RESULT(no);
 629 ])
 630 ])
 631
 632 # 2.6.22
 633
 634 # 2.6.22 lost second parameter for invalidate_bdev
 635 AC_DEFUN([LC_INVALIDATE_BDEV_2ARG],
 636 [AC_MSG_CHECKING([if invalidate_bdev has second argument])
 637 LB_LINUX_TRY_COMPILE([
 638         #include <linux/buffer_head.h>
 639 ],[
 640         invalidate_bdev(NULL,0);
 641 ],[
 642         AC_MSG_RESULT([yes])
 643         AC_DEFINE(HAVE_INVALIDATE_BDEV_2ARG, 1,
 644                 [invalidate_bdev has second argument])
 645 ],[
 646         AC_MSG_RESULT([no])
 647 ])
 648 ])
 649
 650 #
 651 # check for crypto API
 652 #
 653 AC_DEFUN([LC_ASYNC_BLOCK_CIPHER],
 654 [AC_MSG_CHECKING([if kernel has block cipher support])
 655 LB_LINUX_TRY_COMPILE([
 656         #include <linux/err.h>
 657         #include <linux/crypto.h>
 658 ],[
 659         struct crypto_blkcipher *tfm;
 660         tfm = crypto_alloc_blkcipher("aes", 0, sizeof(tfm) );
 661 ],[
 662         AC_MSG_RESULT([yes])
 663         AC_DEFINE(HAVE_ASYNC_BLOCK_CIPHER, 1, [kernel has block cipher support])
 664 ],[
 665         AC_MSG_RESULT([no])
 666 ])
 667 ])
 668
 669 #
 670 # check for struct hash_desc
 671 #
 672 AC_DEFUN([LC_STRUCT_HASH_DESC],
 673 [AC_MSG_CHECKING([if kernel has struct hash_desc])
 674 LB_LINUX_TRY_COMPILE([
 675         #include <linux/err.h>
 676         #include <linux/crypto.h>
 677 ],[
 678         struct hash_desc foo __attribute__ ((unused));
 679 ],[
 680         AC_MSG_RESULT([yes])
 681         AC_DEFINE(HAVE_STRUCT_HASH_DESC, 1, [kernel has struct hash_desc])
 682 ],[
 683         AC_MSG_RESULT([no])
 684 ])
 685 ])
 686
 687 #
 688 # check for struct blkcipher_desc
 689 #
 690 AC_DEFUN([LC_STRUCT_BLKCIPHER_DESC],
 691 [AC_MSG_CHECKING([if kernel has struct blkcipher_desc])
 692 LB_LINUX_TRY_COMPILE([
 693         #include <linux/err.h>
 694         #include <linux/crypto.h>
 695 ],[
 696         struct blkcipher_desc foo __attribute__ ((unused));
 697 ],[
 698         AC_MSG_RESULT([yes])
 699         AC_DEFINE(HAVE_STRUCT_BLKCIPHER_DESC, 1, [kernel has struct blkcipher_desc])
 700 ],[
 701         AC_MSG_RESULT([no])
 702 ])
 703 ])
 704
 705 #
 706 # 2.6.19 check for FS_RENAME_DOES_D_MOVE flag
 707 #
 708 AC_DEFUN([LC_FS_RENAME_DOES_D_MOVE],
 709 [AC_MSG_CHECKING([if kernel has FS_RENAME_DOES_D_MOVE flag])
 710 LB_LINUX_TRY_COMPILE([
 711         #include <linux/fs.h>
 712 ],[
 713         int v __attribute__ ((unused));
 714         v = FS_RENAME_DOES_D_MOVE;
 715 ],[
 716         AC_MSG_RESULT([yes])
 717         AC_DEFINE(HAVE_FS_RENAME_DOES_D_MOVE, 1, [kernel has FS_RENAME_DOES_D_MOVE flag])
 718 ],[
 719         AC_MSG_RESULT([no])
 720 ])
 721 ])
 722
 723 # 2.6.23
 724
 725 # 2.6.23 have return type 'void' for unregister_blkdev
 726 AC_DEFUN([LC_UNREGISTER_BLKDEV_RETURN_INT],
 727 [AC_MSG_CHECKING([if unregister_blkdev return int])
 728 LB_LINUX_TRY_COMPILE([
 729         #include <linux/fs.h>
 730 ],[
 731         int i __attribute__ ((unused));
 732         i = unregister_blkdev(0,NULL);
 733 ],[
 734         AC_MSG_RESULT([yes])
 735         AC_DEFINE(HAVE_UNREGISTER_BLKDEV_RETURN_INT, 1,
 736                 [unregister_blkdev return int])
 737 ],[
 738         AC_MSG_RESULT([no])
 739 ])
 740 ])
 741
 742 # 2.6.23 change .sendfile to .splice_read
 743 AC_DEFUN([LC_KERNEL_SPLICE_READ],
 744 [AC_MSG_CHECKING([if kernel has .splice_read])
 745 LB_LINUX_TRY_COMPILE([
 746         #include <linux/fs.h>
 747 ],[
 748         struct file_operations file;
 749
 750         file.splice_read = NULL;
 751 ], [
 752         AC_MSG_RESULT([yes])
 753         AC_DEFINE(HAVE_KERNEL_SPLICE_READ, 1,
 754                 [kernel has .slice_read])
 755 ],[
 756         AC_MSG_RESULT([no])
 757 ])
 758 ])
 759
 760 # 2.6.23 change .sendfile to .splice_read
 761 # RHEL4 (-92 kernel) have both sendfile and .splice_read API
 762 AC_DEFUN([LC_KERNEL_SENDFILE],
 763 [AC_MSG_CHECKING([if kernel has .sendfile])
 764 LB_LINUX_TRY_COMPILE([
 765         #include <linux/fs.h>
 766 ],[
 767         struct file_operations file;
 768
 769         file.sendfile = NULL;
 770 ], [
 771         AC_MSG_RESULT([yes])
 772         AC_DEFINE(HAVE_KERNEL_SENDFILE, 1,
 773                 [kernel has .sendfile])
 774 ],[
 775         AC_MSG_RESULT([no])
 776 ])
 777 ])
 778
 779 # 2.6.23 extract nfs export related data into exportfs.h
 780 AC_DEFUN([LC_HAVE_EXPORTFS_H],
 781 [LB_CHECK_FILE([$LINUX/include/linux/exportfs.h], [
 782         AC_DEFINE(HAVE_LINUX_EXPORTFS_H, 1,
 783                 [kernel has include/exportfs.h])
 784 ],[
 785         AC_MSG_RESULT([no])
 786 ])
 787 ])
 788
 789 # 2.6.23 has new page fault handling API
 790 AC_DEFUN([LC_VM_OP_FAULT],
 791 [AC_MSG_CHECKING([kernel has .fault in vm_operation_struct])
 792 LB_LINUX_TRY_COMPILE([
 793         #include <linux/mm.h>
 794 ],[
 795         struct vm_operations_struct op;
 796
 797         op.fault = NULL;
 798 ], [
 799         AC_MSG_RESULT([yes])
 800         AC_DEFINE(HAVE_VM_OP_FAULT, 1,
 801                 [kernel has .fault in vm_operation_struct])
 802 ],[
 803         AC_MSG_RESULT([no])
 804 ])
 805 ])
 806
 807 # 2.6.23 add code to wait other users to complete before removing procfs entry
 808 AC_DEFUN([LC_PROCFS_USERS],
 809 [AC_MSG_CHECKING([if kernel has pde_users member in procfs entry struct])
 810 LB_LINUX_TRY_COMPILE([
 811         #include <linux/proc_fs.h>
 812 ],[
 813         struct proc_dir_entry pde;
 814
 815         pde.pde_users   = 0;
 816 ],[
 817         AC_MSG_RESULT([yes])
 818         AC_DEFINE(HAVE_PROCFS_USERS, 1,
 819                 [kernel has pde_users member in procfs entry struct])
 820 ],[
 821         LB_LINUX_TRY_COMPILE([
 822                 #include "$LINUX/fs/proc/internal.h"
 823         ],[
 824                 struct proc_dir_entry_aux pde_aux;
 825
 826                 pde_aux.pde_users = 0;
 827         ],[
 828                 AC_MSG_RESULT([yes])
 829                 AC_DEFINE(HAVE_PROCFS_USERS, 1,
 830                         [kernel has pde_users member in proc_dir_entry_aux])
 831         ],[
 832                 AC_MSG_RESULT([no])
 833         ])
 834 ])
 835 ])
 836
 837 # 2.6.23 exports exportfs_decode_fh
 838 AC_DEFUN([LC_EXPORTFS_DECODE_FH],
 839 [LB_CHECK_SYMBOL_EXPORT([exportfs_decode_fh],
 840 [fs/exportfs/expfs.c],[
 841         AC_DEFINE(HAVE_EXPORTFS_DECODE_FH, 1,
 842                 [exportfs_decode_fh has been export])
 843 ],[
 844 ])
 845 ])
 846
 847 # 2.6.24
 848
 849 # 2.6.24 need linux/mm_types.h included
 850 AC_DEFUN([LC_HAVE_MMTYPES_H],
 851 [LB_CHECK_FILE([$LINUX/include/linux/mm_types.h], [
 852         AC_DEFINE(HAVE_LINUX_MMTYPES_H, 1,
 853                 [kernel has include/mm_types.h])
 854 ],[
 855         AC_MSG_RESULT([no])
 856 ])
 857 ])
 858
 859 # 2.6.24 has bio_endio with 2 args
 860 AC_DEFUN([LC_BIO_ENDIO_2ARG],
 861 [AC_MSG_CHECKING([if kernel has bio_endio with 2 args])
 862 LB_LINUX_TRY_COMPILE([
 863         #include <linux/bio.h>
 864 ],[
 865         bio_endio(NULL, 0);
 866 ], [
 867         AC_MSG_RESULT([yes])
 868         AC_DEFINE(HAVE_BIO_ENDIO_2ARG, 1,
 869                 [kernel has bio_endio with 2 args])
 870 ],[
 871         AC_MSG_RESULT([no])
 872 ])
 873 ])
 874
 875 # 2.6.24 has new members in exports struct.
 876 AC_DEFUN([LC_FH_TO_DENTRY],
 877 [AC_MSG_CHECKING([if kernel has .fh_to_dentry member in export_operations struct])
 878 LB_LINUX_TRY_COMPILE([
 879         #include <linux/fs.h>
 880 #ifdef HAVE_LINUX_EXPORTFS_H
 881         #include <linux/exportfs.h>
 882 #endif
 883 ],[
 884         do{ }while(sizeof(((struct export_operations *)0)->fh_to_dentry));
 885 ], [
 886         AC_MSG_RESULT([yes])
 887         AC_DEFINE(HAVE_FH_TO_DENTRY, 1,
 888                 [kernel has .fh_to_dentry member in export_operations struct])
 889 ],[
 890         AC_MSG_RESULT([no])
 891 ])
 892 ])
 893
 894 # 2.6.24 removes long aged procfs entry -> deleted member
 895 AC_DEFUN([LC_PROCFS_DELETED],
 896 [AC_MSG_CHECKING([if kernel has deleted member in procfs entry struct])
 897 LB_LINUX_TRY_COMPILE([
 898         #include <linux/proc_fs.h>
 899 ],[
 900         struct proc_dir_entry pde;
 901
 902         pde.deleted = sizeof(pde);
 903 ], [
 904         AC_MSG_RESULT([yes])
 905         AC_DEFINE(HAVE_PROCFS_DELETED, 1,
 906                 [kernel has deleted member in procfs entry struct])
 907 ],[
 908         AC_MSG_RESULT([no])
 909 ])
 910 ])
 911
 912 # 2.6.24 has bdi_init()/bdi_destroy() functions.
 913 AC_DEFUN([LC_EXPORT_BDI_INIT],
 914 [LB_CHECK_SYMBOL_EXPORT([bdi_init],
 915 [mm/backing-dev.c],[
 916         AC_DEFINE(HAVE_BDI_INIT, 1,
 917                 [bdi_init/bdi_destroy functions are present])
 918 ],[
 919 ])
 920 ])
 921
 922 # 2.6.26
 923
 924 # 2.6.26 isn't export set_fs_pwd and change paramter in fs struct
 925 AC_DEFUN([LC_FS_STRUCT_USE_PATH],
 926 [AC_MSG_CHECKING([fs_struct use path structure])
 927 LB_LINUX_TRY_COMPILE([
 928         #include <asm/atomic.h>
 929         #include <linux/spinlock.h>
 930         #include <linux/fs_struct.h>
 931 ],[
 932         struct fs_struct fs;
 933
 934         fs.pwd = *((struct path *)sizeof(fs));
 935 ], [
 936         AC_MSG_RESULT([yes])
 937         AC_DEFINE(HAVE_FS_STRUCT_USE_PATH, 1,
 938                 [fs_struct use path structure])
 939 ],[
 940         AC_MSG_RESULT([no])
 941 ])
 942 ])
 943
 944 #
 945 # 2.6.27
 946 #
 947
 948 # LC_SECURITY_PLUG  # for SLES10 SP2 (2.6.27)
 949 # check security plug in sles10 sp2 kernel
 950 AC_DEFUN([LC_SECURITY_PLUG],
 951 [AC_MSG_CHECKING([If kernel has security plug support])
 952 LB_LINUX_TRY_COMPILE([
 953         #include <linux/fs.h>
 954         #include <linux/stddef.h>
 955 ],[
 956         notify_change(NULL, NULL, NULL);
 957 ],[
 958         AC_MSG_RESULT(yes)
 959         AC_DEFINE(HAVE_SECURITY_PLUG, 1,
 960                 [SLES10 SP2 use extra parameter in vfs])
 961 ],[
 962         AC_MSG_RESULT(no)
 963 ])
 964 ])
 965
 966 AC_DEFUN([LC_PGMKWRITE_USE_VMFAULT],
 967 [AC_MSG_CHECKING([kernel .page_mkwrite uses struct vm_fault *])
 968 tmp_flags="$EXTRA_KCFLAGS"
 969 EXTRA_KCFLAGS="-Werror"
 970 LB_LINUX_TRY_COMPILE([
 971         #include <linux/mm.h>
 972 ],[
 973         ((struct vm_operations_struct *)0)->page_mkwrite((struct vm_area_struct *)0, (struct vm_fault *)0);
 974 ], [
 975         AC_MSG_RESULT([yes])
 976         AC_DEFINE(HAVE_PGMKWRITE_USE_VMFAULT, 1,
 977                 [kernel vm_operation_struct.page_mkwrite uses struct vm_fault * as second parameter])
 978 ],[
 979         AC_MSG_RESULT([no])
 980 ])
 981 EXTRA_KCFLAGS="$tmp_flags"
 982 ])
 983
 984 AC_DEFUN([LC_PGMKWRITE_COMPACT],
 985 [AC_MSG_CHECKING([if kernel .page_mkwrite is located in vm_operation_struct._pmkw])
 986 tmp_flags="$EXTRA_KCFLAGS"
 987 EXTRA_KCFLAGS="-Werror"
 988 LB_LINUX_TRY_COMPILE([
 989         #include <linux/mm.h>
 990 ],[
 991         struct vm_operations_struct *vm_ops;
 992
 993         vm_ops = NULL;
 994         vm_ops->_pmkw.page_mkwrite(NULL, NULL);
 995 ], [
 996         AC_MSG_RESULT([yes])
 997         AC_DEFINE(HAVE_PGMKWRITE_COMPACT, 1,
 998                 [kernel .page_mkwrite is located in vm_operation_struct._pmkw])
 999 ],[
1000         AC_MSG_RESULT([no])
1001 ])
1002 EXTRA_KCFLAGS="$tmp_flags"
1003 ])
1004
1005 AC_DEFUN([LC_INODE_PERMISION_2ARGS],
1006 [AC_MSG_CHECKING([inode_operations->permission has two args])
1007 LB_LINUX_TRY_COMPILE([
1008         #include <linux/fs.h>
1009 ],[
1010         struct inode *inode __attribute__ ((unused));
1011
1012         inode = NULL;
1013         inode->i_op->permission(NULL, 0);
1014 ],[
1015         AC_DEFINE(HAVE_INODE_PERMISION_2ARGS, 1,
1016                   [inode_operations->permission has two args])
1017         AC_MSG_RESULT([yes])
1018 ],[
1019         AC_MSG_RESULT([no])
1020 ])
1021 ])
1022
1023 # 2.6.27 have new page locking API
1024 AC_DEFUN([LC_TRYLOCKPAGE],
1025 [AC_MSG_CHECKING([kernel uses trylock_page for page lock])
1026 LB_LINUX_TRY_COMPILE([
1027         #include <linux/pagemap.h>
1028 ],[
1029         trylock_page(NULL);
1030 ],[
1031         AC_DEFINE(HAVE_TRYLOCK_PAGE, 1,
1032                   [kernel uses trylock_page for page lock])
1033         AC_MSG_RESULT([yes])
1034 ],[
1035         AC_MSG_RESULT([no])
1036 ])
1037 ])
1038
1039 # 2.6.27 removed the read_inode from super_operations.
1040 AC_DEFUN([LC_READ_INODE_IN_SBOPS],
1041 [AC_MSG_CHECKING([super_operations has a read_inode field])
1042 LB_LINUX_TRY_COMPILE([
1043         #include <linux/fs.h>
1044 ],[
1045         struct super_operations *sop;
1046         sop->read_inode(NULL);
1047 ],[
1048         AC_DEFINE(HAVE_READ_INODE_IN_SBOPS, 1,
1049                 [super_operations has a read_inode])
1050         AC_MSG_RESULT([yes])
1051 ],[
1052         AC_MSG_RESULT([no])
1053 ])
1054 ])
1055
1056 # 2.6.27 has inode_permission instead of permisson
1057 AC_DEFUN([LC_EXPORT_INODE_PERMISSION],
1058 [LB_CHECK_SYMBOL_EXPORT([inode_permission],
1059 [fs/namei.c],[
1060 AC_DEFINE(HAVE_EXPORT_INODE_PERMISSION, 1,
1061             [inode_permission is exported by the kernel])
1062 ],[
1063 ])
1064 ])
1065
1066 # 2.6.27 use 5th parameter in quota_on for remount.
1067 AC_DEFUN([LC_QUOTA_ON_5ARGS],
1068 [AC_MSG_CHECKING([quota_on needs 5 parameters])
1069 LB_LINUX_TRY_COMPILE([
1070         #include <linux/fs.h>
1071         #include <linux/quota.h>
1072 ],[
1073         struct quotactl_ops *qop = NULL;
1074         qop->quota_on(NULL, 0, 0, NULL, 0);
1075 ],[
1076         AC_DEFINE(HAVE_QUOTA_ON_5ARGS, 1,
1077                 [quota_on needs 5 paramters])
1078         AC_MSG_RESULT([yes])
1079 ],[
1080         AC_MSG_RESULT([no])
1081 ])
1082 ])
1083
1084 # 2.6.27 use 3th parameter in quota_off for remount.
1085 AC_DEFUN([LC_QUOTA_OFF_3ARGS],
1086 [AC_MSG_CHECKING([quota_off needs 3 parameters])
1087 LB_LINUX_TRY_COMPILE([
1088         #include <linux/fs.h>
1089         #include <linux/quota.h>
1090 ],[
1091         struct quotactl_ops *qop = NULL;
1092         qop->quota_off(NULL, 0, 0);
1093 ],[
1094         AC_DEFINE(HAVE_QUOTA_OFF_3ARGS, 1,
1095                 [quota_off needs 3 paramters])
1096         AC_MSG_RESULT([yes])
1097 ],[
1098         AC_MSG_RESULT([no])
1099 ])
1100 ])
1101
1102 # 2.6.27 has vfs_dq_off inline function.
1103 AC_DEFUN([LC_VFS_DQ_OFF],
1104 [AC_MSG_CHECKING([vfs_dq_off is defined])
1105 LB_LINUX_TRY_COMPILE([
1106         #include <linux/quotaops.h>
1107 ],[
1108         vfs_dq_off(NULL, 0);
1109 ],[
1110         AC_DEFINE(HAVE_VFS_DQ_OFF, 1, [vfs_dq_off is defined])
1111         AC_MSG_RESULT([yes])
1112 ],[
1113         AC_MSG_RESULT([no])
1114 ])
1115 ])
1116
1117 # LC_LOCK_MAP_ACQUIRE
1118 # after 2.6.27 lock_map_acquire replaces lock_acquire
1119 AC_DEFUN([LC_LOCK_MAP_ACQUIRE],
1120 [AC_MSG_CHECKING([if lock_map_acquire is defined])
1121 LB_LINUX_TRY_COMPILE([
1122         #include <linux/lockdep.h>
1123 ],[
1124         lock_map_acquire(NULL);
1125 ],[
1126         AC_MSG_RESULT(yes)
1127         AC_DEFINE(HAVE_LOCK_MAP_ACQUIRE, 1,
1128                 [lock_map_acquire is defined])
1129 ],[
1130         AC_MSG_RESULT(no)
1131 ])
1132 ])
1133
1134 # 2.6.27.15-2 sles11
1135
1136 # 2.6.27 sles11 remove the bi_hw_segments
1137 AC_DEFUN([LC_BI_HW_SEGMENTS],
1138 [AC_MSG_CHECKING([struct bio has a bi_hw_segments field])
1139 LB_LINUX_TRY_COMPILE([
1140         #include <linux/bio.h>
1141 ],[
1142         struct bio io;
1143         io.bi_hw_segments = sizeof(io);
1144 ],[
1145         AC_DEFINE(HAVE_BI_HW_SEGMENTS, 1,
1146                 [struct bio has a bi_hw_segments field])
1147         AC_MSG_RESULT([yes])
1148 ],[
1149         AC_MSG_RESULT([no])
1150 ])
1151 ])
1152
1153 #
1154 # 2.6.27 sles11 move the quotaio_v1{2}.h from include/linux to fs
1155 # 2.6.32 move the quotaio_v1{2}.h from fs to fs/quota
1156 AC_DEFUN([LC_HAVE_QUOTAIO_H],
1157 [LB_CHECK_FILE([$LINUX/include/linux/quotaio_v2.h],[
1158         AC_DEFINE(HAVE_QUOTAIO_H, 1,
1159                 [kernel has include/linux/quotaio_v2.h])
1160 ],[LB_CHECK_FILE([$LINUX/fs/quotaio_v2.h],[
1161                AC_DEFINE(HAVE_FS_QUOTAIO_H, 1,
1162                 [kernel has fs/quotaio_v1.h])
1163 ],[LB_CHECK_FILE([$LINUX/fs/quota/quotaio_v2.h],[
1164                AC_DEFINE(HAVE_FS_QUOTA_QUOTAIO_H, 1,
1165                 [kernel has fs/quota/quotaio_v2.h])
1166 ],[
1167         AC_MSG_RESULT([no])
1168 ])
1169 ])
1170 ])
1171 ])
1172
1173 # 2.6.27 sles11 has sb_any_quota_active
1174 AC_DEFUN([LC_SB_ANY_QUOTA_ACTIVE],
1175 [AC_MSG_CHECKING([Kernel has sb_any_quota_active])
1176 LB_LINUX_TRY_COMPILE([
1177         #include <linux/quotaops.h>
1178 ],[
1179         sb_any_quota_active(NULL);
1180 ],[
1181         AC_DEFINE(HAVE_SB_ANY_QUOTA_ACTIVE, 1,
1182                 [Kernel has a sb_any_quota_active])
1183         AC_MSG_RESULT([yes])
1184 ],[
1185         AC_MSG_RESULT([no])
1186 ])
1187 ])
1188
1189 # 2.6.27 sles11 has sb_has_quota_active
1190 AC_DEFUN([LC_SB_HAS_QUOTA_ACTIVE],
1191 [AC_MSG_CHECKING([Kernel has sb_has_quota_active])
1192 LB_LINUX_TRY_COMPILE([
1193         #include <linux/quotaops.h>
1194 ],[
1195         sb_has_quota_active(NULL, 0);
1196 ],[
1197         AC_DEFINE(HAVE_SB_HAS_QUOTA_ACTIVE, 1,
1198                 [Kernel has a sb_has_quota_active])
1199         AC_MSG_RESULT([yes])
1200 ],[
1201         AC_MSG_RESULT([no])
1202 ])
1203 ])
1204
1205 # 2.6.27 exported add_to_page_cache_lru.
1206 AC_DEFUN([LC_EXPORT_ADD_TO_PAGE_CACHE_LRU],
1207 [LB_CHECK_SYMBOL_EXPORT([add_to_page_cache_lru],
1208 [mm/filemap.c],[
1209         AC_DEFINE(HAVE_ADD_TO_PAGE_CACHE_LRU, 1,
1210                 [add_to_page_cache_lru functions are present])
1211 ],[
1212 ])
1213 ])
1214
1215 #
1216 # 2.6.29 introduce sb_any_quota_loaded.
1217 #
1218 AC_DEFUN([LC_SB_ANY_QUOTA_LOADED],
1219 [AC_MSG_CHECKING([Kernel has sb_any_quota_loaded])
1220 LB_LINUX_TRY_COMPILE([
1221         #include <linux/quotaops.h>
1222 ],[
1223         sb_any_quota_loaded(NULL);
1224 ],[
1225         AC_DEFINE(HAVE_SB_ANY_QUOTA_LOADED, 1,
1226                 [Kernel has a sb_any_quota_loaded])
1227         AC_MSG_RESULT([yes])
1228 ],[
1229         AC_MSG_RESULT([no])
1230 ])
1231 ])
1232
1233 # 2.6.30 x86 node_to_cpumask has been removed. must use cpumask_of_node
1234 AC_DEFUN([LC_EXPORT_CPUMASK_OF_NODE],
1235          [LB_CHECK_SYMBOL_EXPORT([node_to_cpumask_map],
1236                                  [arch/$LINUX_ARCH/mm/numa.c],
1237                                  [AC_DEFINE(HAVE_CPUMASK_OF_NODE, 1,
1238                                             [node_to_cpumask_map is exported by
1239                                              the kernel])]) # x86_64
1240          ])
1241
1242 # 2.6.31 replaces blk_queue_hardsect_size by blk_queue_logical_block_size function
1243 AC_DEFUN([LC_BLK_QUEUE_LOG_BLK_SIZE],
1244 [AC_MSG_CHECKING([if blk_queue_logical_block_size is defined])
1245 LB_LINUX_TRY_COMPILE([
1246         #include <linux/blkdev.h>
1247 ],[
1248         blk_queue_logical_block_size(NULL, 0);
1249 ],[
1250         AC_MSG_RESULT(yes)
1251         AC_DEFINE(HAVE_BLK_QUEUE_LOG_BLK_SIZE, 1,
1252                   [blk_queue_logical_block_size is defined])
1253 ],[
1254         AC_MSG_RESULT(no)
1255 ])
1256 ])
1257
1258 # 2.6.32
1259
1260 # 2.6.32 introduced inode_newsize_ok
1261 AC_DEFUN([LC_VFS_INODE_NEWSIZE_OK],
1262 [AC_MSG_CHECKING([if inode_newsize_ok is defined])
1263 LB_LINUX_TRY_COMPILE([
1264         #include <linux/fs.h>
1265 ],[
1266         return inode_newsize_ok(NULL, 0);
1267 ],[
1268         AC_MSG_RESULT(yes)
1269         AC_DEFINE(HAVE_VFS_INODE_NEWSIZE_OK, 1,
1270                   [inode_newsize_ok is defined])
1271 ],[
1272         AC_MSG_RESULT(no)
1273 ])
1274 ])
1275
1276 # 2.6.32 changes cache_detail's member cache_request to cache_upcall
1277 # in kernel commit bc74b4f5e63a09fb78e245794a0de1e5a2716bbe
1278 AC_DEFUN([LC_CACHE_UPCALL],
1279 [AC_MSG_CHECKING([if cache_detail has cache_upcall field])
1280         LB_LINUX_TRY_COMPILE([
1281                 #include <linux/sunrpc/cache.h>
1282         ],[
1283                 struct cache_detail cd;
1284                 cd.cache_upcall = NULL;
1285         ],[
1286                 AC_MSG_RESULT(yes)
1287                 AC_DEFINE(HAVE_CACHE_UPCALL, 1,
1288                           [cache_detail has cache_upcall field])
1289         ],[
1290                 AC_MSG_RESULT(no)
1291         ])
1292 ])
1293
1294 # 2.6.32 add a limits member in struct request_queue.
1295 AC_DEFUN([LC_REQUEST_QUEUE_LIMITS],
1296 [AC_MSG_CHECKING([if request_queue has a limits field])
1297 LB_LINUX_TRY_COMPILE([
1298         #include <linux/blkdev.h>
1299 ],[
1300         struct request_queue rq;
1301         rq.limits.io_min = 0;
1302 ],[
1303         AC_MSG_RESULT(yes)
1304         AC_DEFINE(HAVE_REQUEST_QUEUE_LIMITS, 1,
1305                   [request_queue has a limits field])
1306 ],[
1307         AC_MSG_RESULT(no)
1308 ])
1309 ])
1310
1311 # 2.6.32 has bdi_register() functions.
1312 AC_DEFUN([LC_EXPORT_BDI_REGISTER],
1313 [LB_CHECK_SYMBOL_EXPORT([bdi_register],
1314 [mm/backing-dev.c],[
1315         AC_DEFINE(HAVE_BDI_REGISTER, 1,
1316                 [bdi_register function is present])
1317 ],[
1318 ])
1319 ])
1320
1321 # 2.6.32 add s_bdi for super block
1322 AC_DEFUN([LC_SB_BDI],
1323 [AC_MSG_CHECKING([if super_block has s_bdi field])
1324 LB_LINUX_TRY_COMPILE([
1325         #include <linux/fs.h>
1326 ],[
1327         struct super_block sb;
1328         sb.s_bdi = NULL;
1329 ],[
1330         AC_MSG_RESULT(yes)
1331         AC_DEFINE(HAVE_SB_BDI, 1,
1332                   [super_block has s_bdi field])
1333 ],[
1334         AC_MSG_RESULT(no)
1335 ])
1336 ])
1337
1338 #  2.6.27.15-2 SuSE 11 sp0 kernels lack the name field for BDI
1339 AC_DEFUN([LC_BDI_NAME],
1340 [AC_MSG_CHECKING([if backing_device_info has name field])
1341 LB_LINUX_TRY_COMPILE([
1342         #include <linux/blkdev.h>
1343 ],[
1344         struct backing_dev_info bdi;
1345         bdi.name = NULL;
1346 ],[
1347         AC_MSG_RESULT(yes)
1348         AC_DEFINE(HAVE_BDI_NAME, 1,
1349                   [backing_device_info has name field])
1350 ],[
1351         AC_MSG_RESULT(no)
1352 ])
1353 ])
1354
1355 # 2.6.32 removes blk_queue_max_sectors and add blk_queue_max_hw_sectors
1356 # check blk_queue_max_sectors and use it until disappear.
1357 AC_DEFUN([LC_BLK_QUEUE_MAX_SECTORS],
1358 [AC_MSG_CHECKING([if blk_queue_max_sectors is defined])
1359 LB_LINUX_TRY_COMPILE([
1360         #include <linux/blkdev.h>
1361 ],[
1362         blk_queue_max_sectors(NULL, 0);
1363 ],[
1364         AC_MSG_RESULT(yes)
1365         AC_DEFINE(HAVE_BLK_QUEUE_MAX_SECTORS, 1,
1366                   [blk_queue_max_sectors is defined])
1367 ],[
1368         AC_MSG_RESULT(no)
1369 ])
1370 ])
1371
1372 # 2.6.32 replaces 2 functions blk_queue_max_phys_segments and blk_queue_max_hw_segments by blk_queue_max_segments
1373 AC_DEFUN([LC_BLK_QUEUE_MAX_SEGMENTS],
1374 [AC_MSG_CHECKING([if blk_queue_max_segments is defined])
1375 LB_LINUX_TRY_COMPILE([
1376         #include <linux/blkdev.h>
1377 ],[
1378         blk_queue_max_segments(NULL, 0);
1379 ],[
1380         AC_MSG_RESULT(yes)
1381         AC_DEFINE(HAVE_BLK_QUEUE_MAX_SEGMENTS, 1,
1382                   [blk_queue_max_segments is defined])
1383 ],[
1384         AC_MSG_RESULT(no)
1385 ])
1386 ])
1387
1388 #
1389 # LC_QUOTA64
1390 #
1391 # Check if kernel has been patched for 64-bit quota limits support.
1392 # The upstream version of this patch in RHEL6 2.6.32 kernels introduces
1393 # the constant QFMT_VFS_V1 in include/linux/quota.h, so we can check for
1394 # that in the absence of quotaio_v1.h in the kernel headers.
1395 #
1396 AC_DEFUN([LC_QUOTA64],[
1397         AC_MSG_CHECKING([if kernel has 64-bit quota limits support])
1398 tmp_flags="$EXTRA_KCFLAGS"
1399 EXTRA_KCFLAGS="-I$LINUX/fs"
1400         LB_LINUX_TRY_COMPILE([
1401                 #include <linux/kernel.h>
1402                 #include <linux/fs.h>
1403                 #ifdef HAVE_QUOTAIO_H
1404                 # include <linux/quotaio_v2.h>
1405                 int versions[] = V2_INITQVERSIONS_R1;
1406                 struct v2_disk_dqblk_r1 dqblk_r1;
1407                 #elif defined(HAVE_FS_QUOTA_QUOTAIO_H)
1408                 # include <quota/quotaio_v2.h>
1409                 struct v2r1_disk_dqblk dqblk_r1;
1410                 #elif defined(HAVE_FS_QUOTAIO_H)
1411                 # include <quotaio_v2.h>
1412                 struct v2r1_disk_dqblk dqblk_r1;
1413                 #else
1414                 #include <linux/quota.h>
1415                 int ver = QFMT_VFS_V1;
1416                 #endif
1417         ],[],[
1418                 AC_DEFINE(HAVE_QUOTA64, 1, [have quota64])
1419                 AC_MSG_RESULT([yes])
1420         ],[
1421                 LB_CHECK_FILE([$LINUX/include/linux/lustre_version.h],[
1422                         AC_MSG_ERROR([You have got no 64-bit kernel quota support.])
1423                 ],[])
1424                 AC_MSG_RESULT([no])
1425         ])
1426 EXTRA_KCFLAGS=$tmp_flags
1427 ])
1428
1429 # 2.6.32 set_cpus_allowed is no more defined if CONFIG_CPUMASK_OFFSTACK=yes
1430 AC_DEFUN([LC_SET_CPUS_ALLOWED],
1431          [AC_MSG_CHECKING([if kernel defines set_cpus_allowed])
1432           LB_LINUX_TRY_COMPILE(
1433                 [#include <linux/sched.h>],
1434                 [struct task_struct *p = NULL;
1435                  cpumask_t mask = { { 0 } };
1436                  (void) set_cpus_allowed(p, mask);],
1437                 [AC_MSG_RESULT([yes])
1438                  AC_DEFINE(HAVE_SET_CPUS_ALLOWED, 1,
1439                            [set_cpus_allowed is exported by the kernel])],
1440                 [AC_MSG_RESULT([no])] )])
1441
1442 # 2.6.32 introduces selinux_is_enabled()
1443 AC_DEFUN([LC_SELINUX_IS_ENABLED],
1444 [AC_MSG_CHECKING([if selinux_is_enabled is available])
1445 LB_LINUX_TRY_COMPILE([
1446         #include <linux/selinux.h>
1447 ],[
1448         selinux_is_enabled();
1449 ],[
1450         AC_MSG_RESULT([yes])
1451         AC_DEFINE(HAVE_SELINUX_IS_ENABLED, 1,
1452                 [selinux_is_enabled is defined])
1453 ],[
1454         AC_MSG_RESULT([no])
1455 ])
1456 ])
1457
1458 #
1459 # LC_D_OBTAIN_ALIAS
1460 # starting from 2.6.28 kernel replaces d_alloc_anon() with
1461 # d_obtain_alias() for getting anonymous dentries
1462 # RHEL5(2.6.18) has d_obtain_alias but SLES11SP0(2.6.27) not
1463 #
1464 AC_DEFUN([LC_D_OBTAIN_ALIAS],
1465 [AC_MSG_CHECKING([d_obtain_alias exist in kernel])
1466 LB_LINUX_TRY_COMPILE([
1467         #include <linux/dcache.h>
1468 ],[
1469         d_obtain_alias(NULL);
1470 ],[
1471         AC_DEFINE(HAVE_D_OBTAIN_ALIAS, 1,
1472                 [d_obtain_alias exist in kernel])
1473         AC_MSG_RESULT([yes])
1474 ],[
1475         AC_MSG_RESULT([no])
1476 ])
1477 ])
1478
1479 #
1480 # LC_EXPORT_GENERIC_ERROR_REMOVE_PAGE
1481 #
1482 AC_DEFUN([LC_EXPORT_GENERIC_ERROR_REMOVE_PAGE],
1483          [LB_CHECK_SYMBOL_EXPORT(
1484                         [generic_error_remove_page],
1485                         [mm/truncate.c],
1486                         [AC_DEFINE(HAS_GENERIC_ERROR_REMOVE_PAGE, 1,
1487                                 [kernel export generic_error_remove_page])],
1488                         [])
1489          ]
1490 )
1491
1492 # 2.6.32 if kernel export access_process_vm().
1493 AC_DEFUN([LC_EXPORT_ACCESS_PROCESS_VM],
1494         [LB_CHECK_SYMBOL_EXPORT([access_process_vm],
1495                         [mm/memory.c],
1496                         [AC_DEFINE(HAVE_ACCESS_PROCESS_VM, 1,
1497                                 [access_process_vm function is present])],
1498                         [])
1499         ]
1500 )
1501
1502 #
1503 # 2.6.36 fs_struct.lock use spinlock instead of rwlock.
1504 #
1505 AC_DEFUN([LC_FS_STRUCT_RWLOCK],
1506 [AC_MSG_CHECKING([if fs_struct.lock use rwlock])
1507 LB_LINUX_TRY_COMPILE([
1508         #include <asm/atomic.h>
1509         #include <linux/spinlock.h>
1510         #include <linux/fs_struct.h>
1511 ],[
1512         ((struct fs_struct *)0)->lock = (rwlock_t){ 0 };
1513 ],[
1514         AC_DEFINE(HAVE_FS_STRUCT_RWLOCK, 1,
1515                   [fs_struct.lock use rwlock])
1516         AC_MSG_RESULT([yes])
1517 ],[
1518         AC_MSG_RESULT([no])
1519 ])
1520 ])
1521
1522 #
1523 # 2.6.36 super_operations add evict_inode method. it hybird of
1524 # delete_inode & clear_inode.
1525 #
1526 AC_DEFUN([LC_SBOPS_EVICT_INODE],
1527 [AC_MSG_CHECKING([if super_operations.evict_inode exist])
1528 LB_LINUX_TRY_COMPILE([
1529         #include <linux/fs.h>
1530 ],[
1531         ((struct super_operations *)0)->evict_inode(NULL);
1532 ],[
1533         AC_DEFINE(HAVE_SBOPS_EVICT_INODE, 1,
1534                 [super_operations.evict_inode() is exist in kernel])
1535         AC_MSG_RESULT([yes])
1536 ],[
1537         AC_MSG_RESULT([no])
1538 ])
1539 ])
1540
1541 #
1542 # 2.6.35 file_operations.fsync taken 2 arguments.
1543 # 3.0.0 file_operations.fsync takes 4 arguments.
1544 #
1545 AC_DEFUN([LC_FILE_FSYNC],
1546 [AC_MSG_CHECKING([if file_operations.fsync takes 4 or 2 arguments])
1547 LB_LINUX_TRY_COMPILE([
1548         #include <linux/fs.h>
1549 ],[
1550         ((struct file_operations *)0)->fsync(NULL, 0, 0, 0);
1551 ],[
1552         AC_DEFINE(HAVE_FILE_FSYNC_4ARGS, 1,
1553                 [file_operations.fsync takes 4 arguments])
1554         AC_MSG_RESULT([yes, 4 args])
1555 ],[
1556         LB_LINUX_TRY_COMPILE([
1557                 #include <linux/fs.h>
1558         ],[
1559            ((struct file_operations *)0)->fsync(NULL, 0);
1560         ],[
1561                 AC_DEFINE(HAVE_FILE_FSYNC_2ARGS, 1,
1562                         [file_operations.fsync takes 2 arguments])
1563                 AC_MSG_RESULT([yes, 2 args])
1564         ],[
1565                 AC_MSG_RESULT([no])
1566         ])
1567 ])
1568 ])
1569
1570 #
1571 # 2.6.37 remove kernel_locked
1572 #
1573 AC_DEFUN([LC_KERNEL_LOCKED],
1574 [AC_MSG_CHECKING([if kernel_locked is defined])
1575 LB_LINUX_TRY_COMPILE([
1576         #include <linux/smp_lock.h>
1577 ],[
1578         kernel_locked();
1579 ],[
1580         AC_MSG_RESULT([yes])
1581         AC_DEFINE(HAVE_KERNEL_LOCKED, 1,
1582                 [kernel_locked is defined])
1583 ],[
1584         AC_MSG_RESULT([no])
1585 ])
1586 ])
1587
1588 #
1589 # 2.6.38 dentry_operations.d_compare() taken 7 arguments.
1590 #
1591 AC_DEFUN([LC_D_COMPARE_7ARGS],
1592 [AC_MSG_CHECKING([if d_compare taken 7 arguments])
1593 LB_LINUX_TRY_COMPILE([
1594         #include <linux/dcache.h>
1595 ],[
1596         ((struct dentry_operations*)0)->d_compare(NULL,NULL,NULL,NULL,0,NULL,NULL);
1597 ],[
1598         AC_DEFINE(HAVE_D_COMPARE_7ARGS, 1,
1599                 [d_compare need 7 arguments])
1600         AC_MSG_RESULT([yes])
1601 ],[
1602         AC_MSG_RESULT([no])
1603 ])
1604 ])
1605
1606 #
1607 # 2.6.38 dentry_operations.d_delete() defined 'const' for 1st parameter.
1608 #
1609 AC_DEFUN([LC_D_DELETE_CONST],
1610 [AC_MSG_CHECKING([if d_delete has const declare on first parameter])
1611 tmp_flags="$EXTRA_KCFLAGS"
1612 EXTRA_KCFLAGS="-Werror"
1613 LB_LINUX_TRY_COMPILE([
1614         #include <linux/dcache.h>
1615 ],[
1616         const struct dentry *d = NULL;
1617         ((struct dentry_operations*)0)->d_delete(d);
1618 ],[
1619         AC_DEFINE(HAVE_D_DELETE_CONST, const,
1620                 [d_delete first parameter declared const])
1621         AC_MSG_RESULT([yes])
1622 ],[
1623         AC_DEFINE(HAVE_D_DELETE_CONST, , [])
1624         AC_MSG_RESULT([no])
1625 ])
1626 EXTRA_KCFLAGS="$tmp_flags"
1627 ])
1628
1629 #
1630 # 2.6.38 dcache_lock removed. rcu-walk commited.
1631 #
1632 AC_DEFUN([LC_DCACHE_LOCK],
1633 [AC_MSG_CHECKING([if dcache_lock is exist])
1634 LB_LINUX_TRY_COMPILE([
1635         #include <linux/dcache.h>
1636 ],[
1637         spin_lock(&dcache_lock);
1638 ],[
1639         AC_DEFINE(HAVE_DCACHE_LOCK, 1,
1640                 [dcache_lock is exist])
1641         AC_MSG_RESULT([yes])
1642 ],[
1643         AC_MSG_RESULT([no])
1644 ])
1645 ])
1646
1647 #
1648 # 2.6.38 export blkdev_get_by_dev
1649 #
1650 AC_DEFUN([LC_BLKDEV_GET_BY_DEV],
1651 [LB_CHECK_SYMBOL_EXPORT([blkdev_get_by_dev],
1652 [fs/block_dev.c],[
1653 AC_DEFINE(HAVE_BLKDEV_GET_BY_DEV, 1,
1654             [blkdev_get_by_dev is exported by the kernel])
1655 ],[
1656 ])
1657 ])
1658
1659 #
1660 # 2.6.38 vfsmount.mnt_count doesn't use atomic_t
1661 #
1662 # 3.3 starts hiding vfsmount guts series (move from include/linux/mount.h to
1663 # fs/mount.h, see kernel commit 7d6fec45a5131918b51dcd76da52f2ec86a85be6)
1664 #
1665 AC_DEFUN([LC_ATOMIC_MNT_COUNT],
1666 [AC_MSG_CHECKING([if vfsmount guts is hidden, or vfsmount.mnt_count is atomic_t.])
1667 LB_LINUX_TRY_COMPILE([
1668         #include <linux/fs.h>
1669         #include <../fs/mount.h>
1670 ],[
1671         struct mount *mnt =  real_mount((struct vfsmount *)0);
1672 ],[
1673         AC_DEFINE(HAVE_HIDE_VFSMOUNT_GUTS, 1,
1674                   [hide vfsmount guts in fs/mount.h])
1675         AC_MSG_RESULT([yes, hide vfsmount guts in fs/mount.h])
1676 ],[
1677         LB_LINUX_TRY_COMPILE([
1678                 #include <asm/atomic.h>
1679                 #include <linux/fs.h>
1680                 #include <linux/mount.h>
1681         ],[
1682                 ((struct vfsmount *)0)->mnt_count = ((atomic_t) { 0 });
1683         ],[
1684                 AC_DEFINE(HAVE_ATOMIC_MNT_COUNT, 1,
1685                         [vfsmount.mnt_count is atomic_t])
1686                 AC_MSG_RESULT([yes, vfsmount.mnt_count is atomic_t])
1687         ],[
1688                 AC_MSG_RESULT([no])
1689         ])
1690 ])
1691 ])
1692
1693 #
1694 # 2.6.38 use path as 4th parameter in quota_on.
1695 #
1696 AC_DEFUN([LC_QUOTA_ON_USE_PATH],
1697 [AC_MSG_CHECKING([quota_on use path as parameter])
1698 tmp_flags="$EXTRA_KCFLAGS"
1699 EXTRA_KCFLAGS="-Werror"
1700 LB_LINUX_TRY_COMPILE([
1701         #include <linux/fs.h>
1702         #include <linux/quota.h>
1703 ],[
1704         ((struct quotactl_ops *)0)->quota_on(NULL, 0, 0, ((struct path*)0));
1705 ],[
1706         AC_DEFINE(HAVE_QUOTA_ON_USE_PATH, 1,
1707                 [quota_on use path as 4th paramter])
1708         AC_MSG_RESULT([yes])
1709 ],[
1710         AC_MSG_RESULT([no])
1711 ])
1712 EXTRA_KCFLAGS="$tmp_flags"
1713 ])
1714
1715 #
1716 # 2.6.38 export simple_setattr
1717 #
1718 AC_DEFUN([LC_EXPORT_SIMPLE_SETATTR],
1719 [LB_CHECK_SYMBOL_EXPORT([simple_setattr],
1720 [fs/libfs.c],[
1721 AC_DEFINE(HAVE_SIMPLE_SETATTR, 1,
1722             [simple_setattr is exported by the kernel])
1723 ],[
1724 ])
1725 ])
1726
1727 #
1728 # 2.6.39 remove unplug_fn from request_queue.
1729 #
1730 AC_DEFUN([LC_REQUEST_QUEUE_UNPLUG_FN],
1731 [AC_MSG_CHECKING([if request_queue has unplug_fn field])
1732 LB_LINUX_TRY_COMPILE([
1733         #include <linux/blkdev.h>
1734 ],[
1735         do{ }while(sizeof(((struct request_queue *)0)->unplug_fn));
1736 ],[
1737         AC_DEFINE(HAVE_REQUEST_QUEUE_UNPLUG_FN, 1,
1738                   [request_queue has unplug_fn field])
1739         AC_MSG_RESULT([yes])
1740 ],[
1741         AC_MSG_RESULT([no])
1742 ])
1743 ])
1744
1745 #
1746 # 2.6.39 replace get_sb with mount in struct file_system_type
1747 #
1748 AC_DEFUN([LC_HAVE_FSTYPE_MOUNT],
1749 [AC_MSG_CHECKING([if file_system_type has mount field])
1750 LB_LINUX_TRY_COMPILE([
1751         #include <linux/fs.h>
1752 ],[
1753         struct file_system_type fst;
1754         void *i = (void *) fst.mount;
1755 ],[
1756         AC_DEFINE(HAVE_FSTYPE_MOUNT, 1,
1757                 [struct file_system_type has mount field])
1758         AC_MSG_RESULT([yes])
1759 ],[
1760         AC_MSG_RESULT([no])
1761 ])
1762 ])
1763
1764 #
1765 # 2.6.38 generic_permission taken 4 parameters.
1766 # in fact, it means rcu-walk aware permission bring.
1767 #
1768 # 3.1 generic_permission taken 2 parameters.
1769 # see kernel commit 2830ba7f34ebb27c4e5b8b6ef408cd6d74860890
1770 #
1771 AC_DEFUN([LC_GENERIC_PERMISSION],
1772 [AC_MSG_CHECKING([if generic_permission take 2 or 4 arguments])
1773 LB_LINUX_TRY_COMPILE([
1774         #include <linux/fs.h>
1775 ],[
1776         generic_permission(NULL, 0);
1777 ],[
1778         AC_DEFINE(HAVE_GENERIC_PERMISSION_2ARGS, 1,
1779                   [generic_permission taken 2 arguments])
1780         AC_MSG_RESULT([yes, 2 args])
1781 ],[
1782         LB_LINUX_TRY_COMPILE([
1783                 #include <linux/fs.h>
1784         ],[
1785                 generic_permission(NULL, 0, 0, NULL);
1786         ],[
1787                 AC_DEFINE(HAVE_GENERIC_PERMISSION_4ARGS, 1,
1788                           [generic_permission taken 4 arguments])
1789                 AC_MSG_RESULT([yes, 4 args])
1790         ],[
1791                 AC_MSG_RESULT([no])
1792         ])
1793 ])
1794 ])
1795
1796 #
1797 # 3.1 renames lock-manager ops(lock_manager_operations) from fl_xxx to lm_xxx
1798 # see kernel commit 8fb47a4fbf858a164e973b8ea8ef5e83e61f2e50
1799 #
1800 AC_DEFUN([LC_LM_XXX_LOCK_MANAGER_OPS],
1801 [AC_MSG_CHECKING([if lock-manager ops renamed to lm_xxx])
1802 LB_LINUX_TRY_COMPILE([
1803         #include <linux/fs.h>
1804 ],[
1805         struct lock_manager_operations lm_ops;
1806         lm_ops.lm_compare_owner = NULL;
1807 ],[
1808         AC_DEFINE(HAVE_LM_XXX_LOCK_MANAGER_OPS, 1,
1809                   [lock-manager ops renamed to lm_xxx])
1810         AC_MSG_RESULT([yes])
1811 ],[
1812         AC_MSG_RESULT([no])
1813 ])
1814 ])
1815
1816 #
1817 # 3.1 kills inode->i_alloc_sem, use i_dio_count and inode_dio_wait/
1818 #     inode_dio_done instead.
1819 # see kernel commit bd5fe6c5eb9c548d7f07fe8f89a150bb6705e8e3
1820 #
1821 AC_DEFUN([LC_INODE_DIO_WAIT],
1822 [AC_MSG_CHECKING([if inode->i_alloc_sem is killed and use inode_dio_wait/done.])
1823 LB_LINUX_TRY_COMPILE([
1824         #include <linux/fs.h>
1825 ],[
1826         inode_dio_wait((struct inode *)0);
1827         inode_dio_done((struct inode *)0);
1828 ],[
1829         AC_DEFINE(HAVE_INODE_DIO_WAIT, 1,
1830                   [inode->i_alloc_sem is killed and use inode_dio_wait/done])
1831         AC_MSG_RESULT([yes])
1832 ],[
1833         AC_MSG_RESULT([no])
1834 ])
1835 ])
1836
1837 #
1838 # 3.1 adds get_acl method to inode_operations to read ACL from disk.
1839 # see kernel commit 4e34e719e457f2e031297175410fc0bd4016a085
1840 #
1841 AC_DEFUN([LC_IOP_GET_ACL],
1842 [AC_MSG_CHECKING([inode_operations has .get_acl member function])
1843 LB_LINUX_TRY_COMPILE([
1844         #include <linux/fs.h>
1845 ],[
1846         struct inode_operations iop;
1847         iop.get_acl = NULL;
1848 ],[
1849         AC_DEFINE(HAVE_IOP_GET_ACL, 1,
1850                   [inode_operations has .get_acl member function])
1851         AC_MSG_RESULT([yes])
1852 ],[
1853         AC_MSG_RESULT([no])
1854 ])
1855 ])
1856
1857 #
1858 # 3.1.1 has ext4_blocks_for_truncate
1859 #
1860 AC_DEFUN([LC_BLOCKS_FOR_TRUNCATE],
1861 [AC_MSG_CHECKING([if kernel has ext4_blocks_for_truncate])
1862 LB_LINUX_TRY_COMPILE([
1863         #include <linux/fs.h>
1864         #include "$LINUX/fs/ext4/ext4_jbd2.h"
1865         #include "$LINUX/fs/ext4/truncate.h"
1866 ],[
1867         ext4_blocks_for_truncate(NULL);
1868 ],[
1869         AC_MSG_RESULT([yes])
1870         AC_DEFINE(HAVE_BLOCKS_FOR_TRUNCATE, 1,
1871                   [kernel has ext4_blocks_for_truncate])
1872 ],[
1873         AC_MSG_RESULT([no])
1874 ])
1875 ])
1876
1877 #
1878 # 3.2 request_queue.make_request_fn defined as function returns with void
1879 # see kernel commit 5a7bbad27a410350e64a2d7f5ec18fc73836c14f
1880 #
1881 AC_DEFUN([LC_HAVE_VOID_MAKE_REQUEST_FN],
1882 [AC_MSG_CHECKING([if request_queue.make_request_fn returns void but not int])
1883 LB_LINUX_TRY_COMPILE([
1884         #include <linux/blkdev.h>
1885 ],[
1886         int ret;
1887         make_request_fn         *mrf;
1888         ret = mrf(NULL, NULL);
1889 ],[
1890         AC_MSG_RESULT([no])
1891 ],[
1892         AC_DEFINE(HAVE_VOID_MAKE_REQUEST_FN, 1,
1893                   [request_queue.make_request_fn returns void but not int])
1894         AC_MSG_RESULT([yes])
1895 ])
1896 ])
1897
1898 #
1899 # 3.2 protects inode->i_nlink from direct modification
1900 # see kernel commit a78ef704a8dd430225955f0709b22d4a6ba21deb
1901 # at the same time adds set_nlink(), so checks set_nlink() for it.
1902 #
1903 AC_DEFUN([LC_HAVE_PROTECT_I_NLINK],
1904 [AC_MSG_CHECKING([if inode->i_nlink is protected from direct modification])
1905 LB_LINUX_TRY_COMPILE([
1906         #include <linux/fs.h>
1907 ],[
1908         struct inode i;
1909         set_nlink(&i, 1);
1910 ],[
1911         AC_DEFINE(HAVE_PROTECT_I_NLINK, 1,
1912                   [inode->i_nlink is protected from direct modification])
1913         AC_MSG_RESULT([yes])
1914 ],[
1915         AC_MSG_RESULT([no])
1916 ])
1917 ])
1918
1919 #
1920 # 3.3 introduces migrate_mode.h and migratepage has 4 args
1921 #
1922 AC_DEFUN([LC_HAVE_MIGRATE_HEADER],
1923 [LB_CHECK_FILE([$LINUX/include/linux/migrate.h],[
1924                 AC_DEFINE(HAVE_MIGRATE_H, 1,
1925                 [kernel has include/linux/migrate.h])
1926 ],[LB_CHECK_FILE([$LINUX/include/linux/migrate_mode.h],[
1927                 AC_DEFINE(HAVE_MIGRATE_MODE_H, 1,
1928                         [kernel has include/linux/migrate_mode.h])
1929 ],[
1930         AC_MSG_RESULT([no])
1931 ])
1932 ])
1933 ])
1934
1935 AC_DEFUN([LC_MIGRATEPAGE_4ARGS],
1936 [AC_MSG_CHECKING([if address_space_operations.migratepage has 4 args])
1937 LB_LINUX_TRY_COMPILE([
1938         #include <linux/fs.h>
1939 #ifdef HAVE_MIGRATE_H
1940         #include <linux/migrate.h>
1941 #elif defined(HAVE_MIGRATE_MODE_H)
1942         #include <linux/migrate_mode.h>
1943 #endif
1944 ],[
1945         struct address_space_operations aops;
1946
1947         aops.migratepage(NULL, NULL, NULL, MIGRATE_ASYNC);
1948 ],[
1949         AC_DEFINE(HAVE_MIGRATEPAGE_4ARGS, 1,
1950                 [address_space_operations.migratepage has 4 args])
1951         AC_MSG_RESULT([yes])
1952 ],[
1953         AC_MSG_RESULT([no])
1954 ])
1955 ])
1956
1957 #
1958 # 3.3 switchs super_operations to use dentry as parameter (but not vfsmount)
1959 # see kernel commit 34c80b1d93e6e20ca9dea0baf583a5b5510d92d4
1960 #
1961 AC_DEFUN([LC_SUPEROPS_USE_DENTRY],
1962 [AC_MSG_CHECKING([if super_operations use dentry as parameter])
1963 tmp_flags="$EXTRA_KCFLAGS"
1964 EXTRA_KCFLAGS="-Werror"
1965 LB_LINUX_TRY_COMPILE([
1966         #include <linux/fs.h>
1967         int show_options(struct seq_file *seq, struct dentry *root){
1968                 return 0;
1969         }
1970 ],[
1971         struct super_operations ops;
1972         ops.show_options = show_options;
1973 ],[
1974         AC_DEFINE(HAVE_SUPEROPS_USE_DENTRY, 1,
1975                   [super_operations use dentry as parameter])
1976         AC_MSG_RESULT([yes])
1977 ],[
1978         AC_MSG_RESULT([no])
1979 ])
1980 EXTRA_KCFLAGS="$tmp_flags"
1981 ])
1982
1983 #
1984 # 3.3 switchs inode_operations to use umode_t as parameter (but not int)
1985 # see kernel commit 1a67aafb5f72a436ca044293309fa7e6351d6a35
1986 #
1987 AC_DEFUN([LC_INODEOPS_USE_UMODE_T],
1988 [AC_MSG_CHECKING([if inode_operations use umode_t as parameter])
1989 tmp_flags="$EXTRA_KCFLAGS"
1990 EXTRA_KCFLAGS="-Werror"
1991 LB_LINUX_TRY_COMPILE([
1992         #include <linux/fs.h>
1993         #include <linux/types.h>
1994         int my_mknod(struct inode *dir, struct dentry *dchild,
1995                      umode_t mode, dev_t dev)
1996         {
1997                 return 0;
1998         }
1999 ],[
2000         struct inode_operations ops;
2001         ops.mknod = my_mknod;
2002 ],[
2003         AC_DEFINE(HAVE_INODEOPS_USE_UMODE_T, 1,
2004                   [inode_operations use umode_t as parameter])
2005         AC_MSG_RESULT([yes])
2006 ],[
2007         AC_MSG_RESULT([no])
2008 ])
2009 EXTRA_KCFLAGS="$tmp_flags"
2010 ])
2011
2012 #
2013 # 3.4 switchs touch_atime to struct path
2014 # see kernel commit 68ac1234fb949b66941d94dce4157742799fc581
2015 #
2016 AC_DEFUN([LC_TOUCH_ATIME_1ARG],
2017 [AC_MSG_CHECKING([if touch_atime use one argument])
2018 LB_LINUX_TRY_COMPILE([
2019         #include <linux/fs.h>
2020 ],[
2021         touch_atime((struct path *)NULL);
2022 ],[
2023         AC_DEFINE(HAVE_TOUCH_ATIME_1ARG, 1,
2024                   [touch_atime use one argument])
2025         AC_MSG_RESULT([yes])
2026 ],[
2027         AC_MSG_RESULT([no])
2028 ])
2029 ])
2030
2031 #
2032 # LC_PROG_LINUX
2033 #
2034 # Lustre linux kernel checks
2035 #
2036 AC_DEFUN([LC_PROG_LINUX],
2037          [
2038          LC_CONFIG_PINGER
2039          LC_CONFIG_CHECKSUM
2040          LC_CONFIG_LIBLUSTRE_RECOVERY
2041          LC_CONFIG_HEALTH_CHECK_WRITE
2042          LC_CONFIG_LRU_RESIZE
2043          LC_LLITE_LLOOP_MODULE
2044
2045          # RHEL4 patches
2046          LC_EXPORT_TRUNCATE_COMPLETE
2047          LC_EXPORT_D_REHASH_COND
2048          LC_EXPORT___D_REHASH
2049          LC_EXPORT_NODE_TO_CPUMASK
2050
2051          LC_FILEMAP_POPULATE
2052          LC_BIT_SPINLOCK_H
2053
2054          LC_CONST_ACL_SIZE
2055
2056          LC_CAPA_CRYPTO
2057          LC_CONFIG_RMTCLIENT
2058          LC_CONFIG_GSS
2059          LC_TASK_CLENV_STORE
2060
2061          # 2.6.12
2062          LC_RW_TREE_LOCK
2063
2064          # 2.6.18
2065          LC_UMOUNTBEGIN_HAS_VFSMOUNT
2066
2067          #2.6.18 + RHEL5 (fc6)
2068          LC_LINUX_FIEMAP_H
2069
2070          # 2.6.19
2071          LC_FILE_WRITEV
2072          LC_FILE_READV
2073
2074          # 2.6.20
2075          LC_CANCEL_DIRTY_PAGE
2076
2077          # raid5-zerocopy patch
2078          LC_PAGE_CONSTANT
2079
2080          # 2.6.22
2081          LC_INVALIDATE_BDEV_2ARG
2082          LC_ASYNC_BLOCK_CIPHER
2083          LC_STRUCT_HASH_DESC
2084          LC_STRUCT_BLKCIPHER_DESC
2085          LC_FS_RENAME_DOES_D_MOVE
2086
2087          # 2.6.23
2088          LC_UNREGISTER_BLKDEV_RETURN_INT
2089          LC_KERNEL_SPLICE_READ
2090          LC_KERNEL_SENDFILE
2091          LC_HAVE_EXPORTFS_H
2092          LC_VM_OP_FAULT
2093          LC_PROCFS_USERS
2094          LC_EXPORTFS_DECODE_FH
2095
2096          # 2.6.24
2097          LC_HAVE_MMTYPES_H
2098          LC_BIO_ENDIO_2ARG
2099          LC_FH_TO_DENTRY
2100          LC_PROCFS_DELETED
2101          LC_EXPORT_BDI_INIT
2102
2103          # 2.6.26
2104          LC_FS_STRUCT_USE_PATH
2105
2106          # 2.6.27
2107          LC_SECURITY_PLUG  # for SLES10 SP2
2108          LC_PGMKWRITE_USE_VMFAULT
2109          LC_PGMKWRITE_COMPACT
2110          LC_INODE_PERMISION_2ARGS
2111          LC_TRYLOCKPAGE
2112          LC_READ_INODE_IN_SBOPS
2113          LC_EXPORT_INODE_PERMISSION
2114          LC_QUOTA_ON_5ARGS
2115          LC_QUOTA_OFF_3ARGS
2116          LC_VFS_DQ_OFF
2117          LC_LOCK_MAP_ACQUIRE
2118
2119          # 2.6.27.15-2 sles11
2120          LC_BI_HW_SEGMENTS
2121          LC_HAVE_QUOTAIO_H
2122          LC_BDI_NAME
2123          LC_SB_ANY_QUOTA_ACTIVE
2124          LC_SB_HAS_QUOTA_ACTIVE
2125          LC_EXPORT_ADD_TO_PAGE_CACHE_LRU
2126
2127          # 2.6.29
2128          LC_SB_ANY_QUOTA_LOADED
2129
2130          # 2.6.30
2131          LC_EXPORT_CPUMASK_OF_NODE
2132
2133          # 2.6.31
2134          LC_BLK_QUEUE_LOG_BLK_SIZE
2135
2136          # 2.6.32
2137          LC_REQUEST_QUEUE_LIMITS
2138          LC_EXPORT_BDI_REGISTER
2139          LC_SB_BDI
2140          LC_BLK_QUEUE_MAX_SECTORS
2141          LC_BLK_QUEUE_MAX_SEGMENTS
2142          LC_SET_CPUS_ALLOWED
2143          LC_CACHE_UPCALL
2144          LC_EXPORT_GENERIC_ERROR_REMOVE_PAGE
2145          LC_SELINUX_IS_ENABLED
2146          LC_EXPORT_ACCESS_PROCESS_VM
2147          LC_VFS_INODE_NEWSIZE_OK
2148
2149          # 2.6.35, 3.0.0
2150          LC_FILE_FSYNC
2151          LC_EXPORT_SIMPLE_SETATTR
2152
2153          # 2.6.36
2154          LC_FS_STRUCT_RWLOCK
2155          LC_SBOPS_EVICT_INODE
2156
2157          # 2.6.37
2158          LC_KERNEL_LOCKED
2159
2160          # 2.6.38
2161          LC_ATOMIC_MNT_COUNT
2162          LC_BLKDEV_GET_BY_DEV
2163          LC_GENERIC_PERMISSION
2164          LC_QUOTA_ON_USE_PATH
2165          LC_DCACHE_LOCK
2166          LC_D_COMPARE_7ARGS
2167          LC_D_DELETE_CONST
2168
2169          # 2.6.39
2170          LC_REQUEST_QUEUE_UNPLUG_FN
2171          LC_HAVE_FSTYPE_MOUNT
2172
2173          # 3.1
2174          LC_LM_XXX_LOCK_MANAGER_OPS
2175          LC_INODE_DIO_WAIT
2176          LC_IOP_GET_ACL
2177
2178          # 3.1.1
2179          LC_BLOCKS_FOR_TRUNCATE
2180
2181          # 3.2
2182          LC_HAVE_VOID_MAKE_REQUEST_FN
2183          LC_HAVE_PROTECT_I_NLINK
2184
2185          # 3.3
2186          LC_HAVE_MIGRATE_HEADER
2187          LC_MIGRATEPAGE_4ARGS
2188          LC_SUPEROPS_USE_DENTRY
2189          LC_INODEOPS_USE_UMODE_T
2190
2191          # 3.4
2192          LC_TOUCH_ATIME_1ARG
2193
2194          #
2195          if test x$enable_server = xyes ; then
2196              AC_DEFINE(HAVE_SERVER_SUPPORT, 1, [support server])
2197              LC_FUNC_DEV_SET_RDONLY
2198              LC_STACK_SIZE
2199              LC_QUOTA64
2200              LC_QUOTA_CONFIG
2201          fi
2202 ])
2203
2204 #
2205 # LC_CONFIG_CLIENT_SERVER
2206 #
2207 # Build client/server sides of Lustre
2208 #
2209 AC_DEFUN([LC_CONFIG_CLIENT_SERVER],
2210 [AC_MSG_CHECKING([whether to build Lustre server support])
2211 AC_ARG_ENABLE([server],
2212         AC_HELP_STRING([--disable-server],
2213                         [disable Lustre server support]),
2214         [],[enable_server='yes'])
2215 AC_MSG_RESULT([$enable_server])
2216
2217 AC_MSG_CHECKING([whether to build Lustre client support])
2218 AC_ARG_ENABLE([client],
2219         AC_HELP_STRING([--disable-client],
2220                         [disable Lustre client support]),
2221         [],[enable_client='yes'])
2222 AC_MSG_RESULT([$enable_client])])
2223
2224 #
2225 # LC_CONFIG_LIBLUSTRE
2226 #
2227 # whether to build liblustre
2228 #
2229 AC_DEFUN([LC_CONFIG_LIBLUSTRE],
2230 [AC_MSG_CHECKING([whether to build Lustre library])
2231 AC_ARG_ENABLE([liblustre],
2232         AC_HELP_STRING([--disable-liblustre],
2233                         [disable building of Lustre library]),
2234         [],[enable_liblustre=$with_sysio])
2235 AC_MSG_RESULT([$enable_liblustre])
2236 # only build sysio if liblustre is built
2237 with_sysio="$enable_liblustre"
2238
2239 AC_MSG_CHECKING([whether to build liblustre tests])
2240 AC_ARG_ENABLE([liblustre-tests],
2241         AC_HELP_STRING([--enable-liblustre-tests],
2242                         [enable liblustre tests, if --disable-tests is used]),
2243         [],[enable_liblustre_tests=$enable_tests])
2244 if test x$enable_liblustre != xyes ; then
2245    enable_liblustre_tests='no'
2246 fi
2247 AC_MSG_RESULT([$enable_liblustre_tests])
2248
2249 AC_MSG_CHECKING([whether to enable liblustre acl])
2250 AC_ARG_ENABLE([liblustre-acl],
2251         AC_HELP_STRING([--disable-liblustre-acl],
2252                         [disable ACL support for liblustre]),
2253         [],[enable_liblustre_acl=yes])
2254 AC_MSG_RESULT([$enable_liblustre_acl])
2255 if test x$enable_liblustre_acl = xyes ; then
2256   AC_DEFINE(LIBLUSTRE_POSIX_ACL, 1, Liblustre Support ACL-enabled MDS)
2257 fi
2258
2259 # 2.6.29 change prepare/commit_write to write_begin/end
2260 AC_DEFUN([LC_WRITE_BEGIN_END],
2261 [AC_MSG_CHECKING([if kernel has .write_begin/end])
2262 LB_LINUX_TRY_COMPILE([
2263         #include <linux/fs.h>
2264         #include <linux/pagemap.h>
2265 #ifdef HAVE_LINUX_MMTYPES_H
2266         #include <linux/mm_types.h>
2267 #endif
2268 ],[
2269         struct address_space_operations aops;
2270         struct page *page;
2271
2272         aops.write_begin = NULL;
2273         aops.write_end = NULL;
2274         page = grab_cache_page_write_begin(NULL, 0, 0);
2275 ], [
2276         AC_MSG_RESULT([yes])
2277         AC_DEFINE(HAVE_KERNEL_WRITE_BEGIN_END, 1,
2278                 [kernel has .write_begin/end])
2279 ],[
2280         AC_MSG_RESULT([no])
2281 ])
2282 ])
2283
2284 # 2.6.29 blkdev_put has 2 arguments
2285 AC_DEFUN([LC_BLKDEV_PUT_2ARGS],
2286 [AC_MSG_CHECKING([blkdev_put needs 2 parameters])
2287 LB_LINUX_TRY_COMPILE([
2288         #include <linux/fs.h>
2289 ],[
2290         blkdev_put(NULL, 0);
2291 ],[
2292         AC_DEFINE(HAVE_BLKDEV_PUT_2ARGS, 1,
2293                 [blkdev_put needs 2 paramters])
2294         AC_MSG_RESULT([yes])
2295 ],[
2296         AC_MSG_RESULT([no])
2297 ])
2298 ])
2299
2300 # 2.6.29 dentry_open has 4 arguments
2301 AC_DEFUN([LC_DENTRY_OPEN_4ARGS],
2302 [AC_MSG_CHECKING([dentry_open needs 4 parameters])
2303 LB_LINUX_TRY_COMPILE([
2304         #include <linux/fs.h>
2305 ],[
2306         dentry_open(NULL, NULL, 0, NULL);
2307 ],[
2308         AC_DEFINE(HAVE_DENTRY_OPEN_4ARGS, 1,
2309                 [dentry_open needs 4 paramters])
2310         AC_MSG_RESULT([yes])
2311 ],[
2312         AC_MSG_RESULT([no])
2313 ])
2314 ])
2315
2316 # 2.6.29 split file and anonymous page queues
2317 AC_DEFUN([LC_PAGEVEC_LRU_ADD_FILE],
2318 [AC_MSG_CHECKING([if kernel has .pagevec_lru_add_file])
2319 LB_LINUX_TRY_COMPILE([
2320         #include <linux/mm.h>
2321         #include <linux/pagevec.h>
2322 ],[
2323         struct pagevec lru_pagevec;
2324
2325         pagevec_init(&lru_pagevec, 0);
2326         pagevec_lru_add_file(&lru_pagevec);
2327 ],[
2328         AC_MSG_RESULT([yes])
2329         AC_DEFINE(HAVE_PAGEVEC_LRU_ADD_FILE, 1,
2330                 [kernel has .pagevec_lru_add_file])
2331 ],[
2332         AC_MSG_RESULT([no])
2333 ])
2334 ])
2335
2336 #
2337 # --enable-mpitest
2338 #
2339 AC_ARG_ENABLE(mpitests,
2340         AC_HELP_STRING([--enable-mpitests=yes|no|mpicc wrapper],
2341                            [include mpi tests]),
2342         [
2343          enable_mpitests=yes
2344          case $enableval in
2345          yes)
2346                 MPICC_WRAPPER=mpicc
2347                 ;;
2348          no)
2349                 enable_mpitests=no
2350                 ;;
2351          *)
2352                 MPICC_WRAPPER=$enableval
2353                  ;;
2354          esac
2355         ],
2356         [
2357         MPICC_WRAPPER=mpicc
2358         enable_mpitests=yes
2359         ]
2360 )
2361
2362 if test x$enable_mpitests != xno; then
2363         AC_MSG_CHECKING([whether mpitests can be built])
2364         oldcc=$CC
2365         CC=$MPICC_WRAPPER
2366         AC_LINK_IFELSE(
2367             [AC_LANG_PROGRAM([[
2368                     #include <mpi.h>
2369                 ]],[[
2370                     int flag;
2371                     MPI_Initialized(&flag);
2372                 ]])],
2373             [
2374                     AC_MSG_RESULT([yes])
2375             ],[
2376                     AC_MSG_RESULT([no])
2377                     enable_mpitests=no
2378         ])
2379         CC=$oldcc
2380 fi
2381 AC_SUBST(MPICC_WRAPPER)
2382
2383 AC_MSG_NOTICE([Enabling Lustre configure options for libsysio])
2384 ac_configure_args="$ac_configure_args --with-lustre-hack --with-sockets"
2385
2386 LC_CONFIG_PINGER
2387 LC_CONFIG_LIBLUSTRE_RECOVERY
2388 ])
2389
2390 #
2391 # LC_CONFIG_QUOTA
2392 #
2393 # whether to enable quota support global control
2394 #
2395 AC_DEFUN([LC_CONFIG_QUOTA],
2396 [AC_ARG_ENABLE([quota],
2397         AC_HELP_STRING([--enable-quota],
2398                         [enable quota support]),
2399         [],[enable_quota='yes'])
2400 ])
2401
2402 AC_DEFUN([LC_QUOTA],
2403 [#check global
2404 LC_CONFIG_QUOTA
2405 #check for utils
2406 AC_CHECK_HEADER(sys/quota.h,
2407                 [AC_DEFINE(HAVE_SYS_QUOTA_H, 1, [Define to 1 if you have <sys/quota.h>.])],
2408                 [AC_MSG_ERROR([don't find <sys/quota.h> in your system])])
2409 ])
2410
2411 #
2412 # LC_CONFIG_SPLIT
2413 #
2414 # whether to enable split support
2415 #
2416 AC_DEFUN([LC_CONFIG_SPLIT],
2417 [AC_MSG_CHECKING([whether to enable split support])
2418 AC_ARG_ENABLE([split],
2419         AC_HELP_STRING([--enable-split],
2420                         [enable split support]),
2421         [],[enable_split='no'])
2422 AC_MSG_RESULT([$enable_split])
2423 if test x$enable_split != xno; then
2424    AC_DEFINE(HAVE_SPLIT_SUPPORT, 1, [enable split support])
2425 fi
2426 ])
2427
2428 # RHEL5(2.6.18) has tux_info
2429 AC_DEFUN([LC_TASK_CLENV_TUX_INFO],
2430 [AC_MSG_CHECKING([tux_info])
2431 LB_LINUX_TRY_COMPILE([
2432         #include <linux/sched.h>
2433 ],[
2434         struct task_struct task;
2435         &task.tux_info;
2436 ],[
2437         AC_MSG_RESULT([yes])
2438         AC_DEFINE(LL_TASK_CL_ENV, tux_info, [have tux_info])
2439         have_task_clenv_store='yes'
2440 ],[
2441         AC_MSG_RESULT([no])
2442 ])
2443 ])
2444
2445 #
2446 # LC_LLITE_LLOOP_MODULE
2447 # lloop_llite.ko does not currently work with page sizes
2448 # of 64k or larger.
2449 #
2450 AC_DEFUN([LC_LLITE_LLOOP_MODULE],
2451 [AC_MSG_CHECKING([whether to enable llite_lloop module])
2452 LB_LINUX_TRY_COMPILE([
2453         #include <asm/page.h>
2454 ],[
2455         #if PAGE_SIZE >= 65536
2456         #error "PAGE_SIZE >= 65536"
2457         #endif
2458 ],[
2459         enable_llite_lloop_module='yes'
2460         AC_MSG_RESULT([yes])
2461 ],[
2462         enable_llite_lloop_module='no'
2463         AC_MSG_RESULT([no])
2464 ])
2465 ])
2466
2467 #
2468 # LC_OSD_ADDON
2469 #
2470 # configure support for optional OSD implementation
2471 #
2472 AC_DEFUN([LC_OSD_ADDON],
2473 [AC_MSG_CHECKING([for osd])
2474 AC_ARG_WITH([osd],
2475         AC_HELP_STRING([--with-osd=path],
2476                        [set path to optional osd]),
2477         [
2478                 case $with_osd in
2479                         no)     ENABLEOSDADDON=0
2480                                 ;;
2481                         *)      OSDADDON="${with_osd}"
2482                                 ENABLEOSDADDON=1
2483                                 ;;
2484                 esac
2485         ], [
2486                 ENABLEOSDADDON=0
2487         ])
2488 if test $ENABLEOSDADDON -eq 0; then
2489         AC_MSG_RESULT([no])
2490         OSDADDON=
2491 else
2492         OSDMODNAME=`basename $OSDADDON`
2493         if test -e $LUSTRE/$OSDMODNAME; then
2494                 AC_MSG_RESULT([can't link])
2495                 OSDADDON=
2496         elif ln -s $OSDADDON $LUSTRE/$OSDMODNAME; then
2497                 AC_MSG_RESULT([$OSDMODNAME])
2498                 OSDADDON="subdir-m += $OSDMODNAME"
2499         else
2500                 AC_MSG_RESULT([can't link])
2501                 OSDADDON=
2502         fi
2503 fi
2504 AC_SUBST(OSDADDON)
2505 ])
2506
2507 #
2508 # LC_CONFIGURE
2509 #
2510 # other configure checks
2511 #
2512 AC_DEFUN([LC_CONFIGURE],
2513 [LC_CONFIG_OBD_BUFFER_SIZE
2514
2515 if test $target_cpu == "i686" -o $target_cpu == "x86_64"; then
2516         CFLAGS="$CFLAGS -Werror"
2517 fi
2518
2519 # maximum MDS thread count
2520 LC_MDS_MAX_THREADS
2521
2522 # include/liblustre.h
2523 AC_CHECK_HEADERS([sys/user.h sys/vfs.h stdint.h blkid/blkid.h])
2524
2525 # liblustre/llite_lib.h
2526 AC_CHECK_HEADERS([xtio.h file.h])
2527
2528 # liblustre/dir.c
2529 AC_CHECK_HEADERS([linux/types.h sys/types.h linux/unistd.h unistd.h])
2530
2531 # liblustre/lutil.c
2532 AC_CHECK_HEADERS([netinet/in.h arpa/inet.h catamount/data.h])
2533 AC_CHECK_FUNCS([inet_ntoa])
2534
2535 # libsysio/src/readlink.c
2536 LC_READLINK_SSIZE_T
2537
2538 # lvfs/prng.c - depends on linux/types.h from liblustre/dir.c
2539 AC_CHECK_HEADERS([linux/random.h], [], [],
2540                  [#ifdef HAVE_LINUX_TYPES_H
2541                   # include <linux/types.h>
2542                   #endif
2543                  ])
2544
2545 # utils/llverfs.c
2546 AC_CHECK_HEADERS([ext2fs/ext2fs.h])
2547
2548 # check for -lz support
2549 ZLIB=""
2550 AC_CHECK_LIB([z],
2551              [adler32],
2552              [AC_CHECK_HEADERS([zlib.h],
2553                                [ZLIB="-lz"
2554                                 AC_DEFINE([HAVE_ADLER], 1,
2555                                           [support alder32 checksum type])],
2556                                [AC_MSG_WARN([No zlib-devel package found,
2557                                              unable to use adler32 checksum])])],
2558              [AC_MSG_WARN([No zlib package found, unable to use adler32 checksum])]
2559 )
2560 AC_SUBST(ZLIB)
2561
2562 # Super safe df
2563 AC_ARG_ENABLE([mindf],
2564       AC_HELP_STRING([--enable-mindf],
2565                       [Make statfs report the minimum available space on any single OST instead of the sum of free space on all OSTs]),
2566       [],[])
2567 if test "$enable_mindf" = "yes" ;  then
2568       AC_DEFINE([MIN_DF], 1, [Report minimum OST free space])
2569 fi
2570
2571 AC_ARG_ENABLE([fail_alloc],
2572         AC_HELP_STRING([--disable-fail-alloc],
2573                 [disable randomly alloc failure]),
2574         [],[enable_fail_alloc=yes])
2575 AC_MSG_CHECKING([whether to randomly failing memory alloc])
2576 AC_MSG_RESULT([$enable_fail_alloc])
2577 if test x$enable_fail_alloc != xno ; then
2578         AC_DEFINE([RANDOM_FAIL_ALLOC], 1, [enable randomly alloc failure])
2579 fi
2580
2581 AC_ARG_ENABLE([invariants],
2582         AC_HELP_STRING([--enable-invariants],
2583                 [enable invariant checking (cpu intensive)]),
2584         [],[])
2585 AC_MSG_CHECKING([whether to check invariants (expensive cpu-wise)])
2586 AC_MSG_RESULT([$enable_invariants])
2587 if test x$enable_invariants = xyes ; then
2588         AC_DEFINE([INVARIANT_CHECK], 1, [enable invariant checking])
2589 fi
2590
2591 AC_ARG_ENABLE([lu_ref],
2592         AC_HELP_STRING([--enable-lu_ref],
2593                 [enable lu_ref reference tracking code]),
2594         [],[])
2595 AC_MSG_CHECKING([whether to track references with lu_ref])
2596 AC_MSG_RESULT([$enable_lu_ref])
2597 if test x$enable_lu_ref = xyes ; then
2598         AC_DEFINE([USE_LU_REF], 1, [enable lu_ref reference tracking code])
2599 fi
2600
2601 AC_ARG_ENABLE([pgstate-track],
2602               AC_HELP_STRING([--enable-pgstate-track],
2603                              [enable page state tracking]),
2604               [enable_pgstat_track='yes'],[])
2605 AC_MSG_CHECKING([whether to enable page state tracking])
2606 AC_MSG_RESULT([$enable_pgstat_track])
2607 if test x$enable_pgstat_track = xyes ; then
2608         AC_DEFINE([LUSTRE_PAGESTATE_TRACKING], 1,
2609                   [enable page state tracking code])
2610 fi
2611
2612          #2.6.29
2613          LC_WRITE_BEGIN_END
2614          LC_D_OBTAIN_ALIAS
2615          LC_BLKDEV_PUT_2ARGS
2616          LC_DENTRY_OPEN_4ARGS
2617          LC_PAGEVEC_LRU_ADD_FILE
2618
2619 ])
2620
2621 #
2622 # LC_CONDITIONALS
2623 #
2624 # AM_CONDITIONALS for lustre
2625 #
2626 AC_DEFUN([LC_CONDITIONALS],
2627 [AM_CONDITIONAL(LIBLUSTRE, test x$enable_liblustre = xyes)
2628 AM_CONDITIONAL(USE_QUILT, test x$QUILT != xno)
2629 AM_CONDITIONAL(LIBLUSTRE_TESTS, test x$enable_liblustre_tests = xyes)
2630 AM_CONDITIONAL(MPITESTS, test x$enable_mpitests = xyes, Build MPI Tests)
2631 AM_CONDITIONAL(CLIENT, test x$enable_client = xyes)
2632 AM_CONDITIONAL(SERVER, test x$enable_server = xyes)
2633 AM_CONDITIONAL(SPLIT, test x$enable_split = xyes)
2634 AM_CONDITIONAL(BLKID, test x$ac_cv_header_blkid_blkid_h = xyes)
2635 AM_CONDITIONAL(EXT2FS_DEVEL, test x$ac_cv_header_ext2fs_ext2fs_h = xyes)
2636 AM_CONDITIONAL(GSS, test x$enable_gss = xyes)
2637 AM_CONDITIONAL(GSS_KEYRING, test x$enable_gss_keyring = xyes)
2638 AM_CONDITIONAL(GSS_PIPEFS, test x$enable_gss_pipefs = xyes)
2639 AM_CONDITIONAL(LIBPTHREAD, test x$enable_libpthread = xyes)
2640 AM_CONDITIONAL(LLITE_LLOOP, test x$enable_llite_lloop_module = xyes)
2641 ])
2642
2643 #
2644 # LC_CONFIG_FILES
2645 #
2646 # files that should be generated with AC_OUTPUT
2647 #
2648 AC_DEFUN([LC_CONFIG_FILES],
2649 [AC_CONFIG_FILES([
2650 lustre/Makefile
2651 lustre/autoMakefile
2652 lustre/autoconf/Makefile
2653 lustre/conf/Makefile
2654 lustre/contrib/Makefile
2655 lustre/doc/Makefile
2656 lustre/include/Makefile
2657 lustre/include/lustre_ver.h
2658 lustre/include/linux/Makefile
2659 lustre/include/darwin/Makefile
2660 lustre/include/lustre/Makefile
2661 lustre/kernel_patches/targets/2.6-rhel6.target
2662 lustre/kernel_patches/targets/2.6-rhel5.target
2663 lustre/kernel_patches/targets/2.6-sles10.target
2664 lustre/kernel_patches/targets/2.6-sles11.target
2665 lustre/kernel_patches/targets/3.0-sles11.target
2666 lustre/kernel_patches/targets/2.6-oel5.target
2667 lustre/kernel_patches/targets/2.6-fc11.target
2668 lustre/kernel_patches/targets/2.6-fc12.target
2669 lustre/kernel_patches/targets/2.6-fc15.target
2670 lustre/ldlm/Makefile
2671 lustre/fid/Makefile
2672 lustre/fid/autoMakefile
2673 lustre/liblustre/Makefile
2674 lustre/liblustre/tests/Makefile
2675 lustre/liblustre/tests/mpi/Makefile
2676 lustre/llite/Makefile
2677 lustre/llite/autoMakefile
2678 lustre/lclient/Makefile
2679 lustre/lov/Makefile
2680 lustre/lov/autoMakefile
2681 lustre/lvfs/Makefile
2682 lustre/lvfs/autoMakefile
2683 lustre/mdc/Makefile
2684 lustre/mdc/autoMakefile
2685 lustre/lmv/Makefile
2686 lustre/lmv/autoMakefile
2687 lustre/mdt/Makefile
2688 lustre/mdt/autoMakefile
2689 lustre/mdd/Makefile
2690 lustre/mdd/autoMakefile
2691 lustre/fld/Makefile
2692 lustre/fld/autoMakefile
2693 lustre/obdclass/Makefile
2694 lustre/obdclass/autoMakefile
2695 lustre/obdclass/linux/Makefile
2696 lustre/obdecho/Makefile
2697 lustre/obdecho/autoMakefile
2698 lustre/ofd/Makefile
2699 lustre/ofd/autoMakefile
2700 lustre/osc/Makefile
2701 lustre/osc/autoMakefile
2702 lustre/ost/Makefile
2703 lustre/ost/autoMakefile
2704 lustre/osd-ldiskfs/Makefile
2705 lustre/osd-ldiskfs/autoMakefile
2706 lustre/osd-zfs/Makefile
2707 lustre/osd-zfs/autoMakefile
2708 lustre/mgc/Makefile
2709 lustre/mgc/autoMakefile
2710 lustre/mgs/Makefile
2711 lustre/mgs/autoMakefile
2712 lustre/target/Makefile
2713 lustre/ptlrpc/Makefile
2714 lustre/ptlrpc/autoMakefile
2715 lustre/ptlrpc/gss/Makefile
2716 lustre/ptlrpc/gss/autoMakefile
2717 lustre/quota/Makefile
2718 lustre/quota/autoMakefile
2719 lustre/scripts/Makefile
2720 lustre/tests/Makefile
2721 lustre/tests/mpi/Makefile
2722 lustre/utils/Makefile
2723 lustre/utils/gss/Makefile
2724 lustre/osp/Makefile
2725 lustre/osp/autoMakefile
2726 lustre/lod/Makefile
2727 lustre/lod/autoMakefile
2728 lustre/obdclass/darwin/Makefile
2729 ])
2730 ])