lustre/autoconf/lustre-core.m4

   1 #
   2 # LC_CONFIG_SRCDIR
   3 #
   4 # Wrapper for AC_CONFIG_SUBDIR
   5 #
   6 AC_DEFUN([LC_CONFIG_SRCDIR], [
   7 AC_CONFIG_SRCDIR([lustre/obdclass/obdo.c])
   8 ldiskfs_is_ext4="yes"
   9 ])
  10
  11 #
  12 # LC_PATH_DEFAULTS
  13 #
  14 # lustre specific paths
  15 #
  16 AC_DEFUN([LC_PATH_DEFAULTS], [
  17 # ptlrpc kernel build requires this
  18 LUSTRE="$PWD/lustre"
  19 AC_SUBST(LUSTRE)
  20
  21 # mount.lustre
  22 rootsbindir='/sbin'
  23 AC_SUBST(rootsbindir)
  24
  25 demodir='$(docdir)/demo'
  26 AC_SUBST(demodir)
  27
  28 pkgexampledir='${pkgdatadir}/examples'
  29 AC_SUBST(pkgexampledir)
  30 ]) # LC_PATH_DEFAULTS
  31
  32 #
  33 # LC_TARGET_SUPPORTED
  34 #
  35 # is the target os supported?
  36 #
  37 AC_DEFUN([LC_TARGET_SUPPORTED], [
  38 case $target_os in
  39         linux*)
  40 $1
  41                 ;;
  42         *)
  43 $2
  44                 ;;
  45 esac
  46 ]) # LC_TARGET_SUPPORTED
  47
  48 #
  49 # LC_GLIBC_SUPPORT_FHANDLES
  50 #
  51 AC_DEFUN([LC_GLIBC_SUPPORT_FHANDLES], [
  52 AC_CHECK_FUNCS([name_to_handle_at],
  53         [AC_DEFINE(HAVE_FHANDLE_GLIBC_SUPPORT, 1,
  54                 [file handle and related syscalls are supported])],
  55         [AC_MSG_WARN([file handle and related syscalls are not supported])])
  56 ]) # LC_GLIBC_SUPPORT_FHANDLES
  57
  58 #
  59 # LC_GLIBC_SUPPORT_COPY_FILE_RANGE
  60 #
  61 AC_DEFUN([LC_GLIBC_SUPPORT_COPY_FILE_RANGE], [
  62 AC_CHECK_FUNCS([copy_file_range],
  63         [AC_DEFINE(HAVE_COPY_FILE_RANGE, 1,
  64                 [copy_file_range() is supported])],
  65         [AC_MSG_WARN([copy_file_range() is not supported])])
  66 ]) # LC_GLIBC_SUPPORT_COPY_FILE_RANGE
  67
  68 #
  69 # LC_STACK_SIZE
  70 #
  71 # Ensure the stack size is at least 8k in Lustre server (all kernels)
  72 #
  73 AC_DEFUN([LC_STACK_SIZE], [
  74 LB_CHECK_COMPILE([if stack size is at least 8k],
  75 stack_size_8k, [
  76         #include <linux/thread_info.h>
  77 ], [
  78         #if THREAD_SIZE < 8192
  79         #error "stack size < 8192"
  80         #endif
  81 ], [], [AC_MSG_ERROR([
  82
  83 Lustre requires that Linux is configured with at least a 8KB stack.
  84 ])])
  85 ]) # LC_STACK_SIZE
  86
  87 #
  88 # LC_MDS_MAX_THREADS
  89 #
  90 # Allow the user to set the MDS thread upper limit
  91 #
  92 AC_DEFUN([LC_MDS_MAX_THREADS], [
  93 AC_MSG_CHECKING([for maximum number of MDS threads])
  94 AC_ARG_WITH([mds_max_threads],
  95         AC_HELP_STRING([--with-mds-max-threads=count],
  96                 [maximum threads available on the MDS: (default=512)]),
  97         [AC_DEFINE_UNQUOTED(MDS_MAX_THREADS, $with_mds_max_threads,
  98                 [maximum number of MDS threads])])
  99 AC_MSG_RESULT([$with_mds_max_threads])
 100 ]) # LC_MDS_MAX_THREADS
 101
 102 #
 103 # LC_CONFIG_PINGER
 104 #
 105 # the pinger is temporary, until we have the recovery node in place
 106 #
 107 AC_DEFUN([LC_CONFIG_PINGER], [
 108 AC_MSG_CHECKING([whether to enable Lustre pinger support])
 109 AC_ARG_ENABLE([pinger],
 110         AC_HELP_STRING([--disable-pinger],
 111                 [disable recovery pinger support]),
 112         [], [enable_pinger="yes"])
 113 AC_MSG_RESULT([$enable_pinger])
 114 AS_IF([test "x$enable_pinger" != xno],
 115         [AC_DEFINE(CONFIG_LUSTRE_FS_PINGER, 1,[Use the Pinger])])
 116 ]) # LC_CONFIG_PINGER
 117
 118 #
 119 # LC_CONFIG_CHECKSUM
 120 #
 121 # do checksum of bulk data between client and OST
 122 #
 123 AC_DEFUN([LC_CONFIG_CHECKSUM], [
 124 AC_MSG_CHECKING([whether to enable data checksum support])
 125 AC_ARG_ENABLE([checksum],
 126         AC_HELP_STRING([--disable-checksum],
 127                 [disable data checksum support]),
 128         [], [enable_checksum="yes"])
 129 AC_MSG_RESULT([$enable_checksum])
 130 AS_IF([test "x$enable_checksum" != xno],
 131         [AC_DEFINE(ENABLE_CHECKSUM, 1, [do data checksums])])
 132 ]) # LC_CONFIG_CHECKSUM
 133
 134 #
 135 # LC_CONFIG_FLOCK
 136 #
 137 # enable distributed flock by default
 138 #
 139 AC_DEFUN([LC_CONFIG_FLOCK], [
 140 AC_MSG_CHECKING([whether to enable flock by default])
 141 AC_ARG_ENABLE([flock],
 142         AC_HELP_STRING([--disable-flock],
 143                 [disable flock by default]),
 144         [], [enable_flock="yes"])
 145 AC_MSG_RESULT([$enable_flock])
 146 AS_IF([test "x$enable_flock" != xno],
 147         [AC_DEFINE(ENABLE_FLOCK, 1, [enable flock by default])])
 148 ]) # LC_CONFIG_FLOCK
 149
 150 #
 151 # LC_CONFIG_HEALTH_CHECK_WRITE
 152 #
 153 # Turn off the actual write to the disk
 154 #
 155 AC_DEFUN([LC_CONFIG_HEALTH_CHECK_WRITE], [
 156 AC_MSG_CHECKING([whether to enable a write with the health check])
 157 AC_ARG_ENABLE([health_write],
 158         AC_HELP_STRING([--enable-health_write],
 159                 [enable disk writes when doing health check]),
 160         [], [enable_health_write="no"])
 161 AC_MSG_RESULT([$enable_health_write])
 162 AS_IF([test "x$enable_health_write" != xno],
 163         [AC_DEFINE(USE_HEALTH_CHECK_WRITE, 1, [Write when Checking Health])])
 164 ]) # LC_CONFIG_HEALTH_CHECK_WRITE
 165
 166 #
 167 # LC_CONFIG_LRU_RESIZE
 168 #
 169 AC_DEFUN([LC_CONFIG_LRU_RESIZE], [
 170 AC_MSG_CHECKING([whether to enable lru self-adjusting])
 171 AC_ARG_ENABLE([lru_resize],
 172         AC_HELP_STRING([--enable-lru-resize],
 173                 [enable lru resize support]),
 174         [], [enable_lru_resize="yes"])
 175 AC_MSG_RESULT([$enable_lru_resize])
 176 AS_IF([test "x$enable_lru_resize" != xno],
 177         [AC_DEFINE(HAVE_LRU_RESIZE_SUPPORT, 1, [Enable lru resize support])])
 178 ]) # LC_CONFIG_LRU_RESIZE
 179
 180 #
 181 # LC_QUOTA_CONFIG
 182 #
 183 # Quota support. The kernel must support CONFIG_QUOTA.
 184 #
 185 AC_DEFUN([LC_QUOTA_CONFIG], [
 186 LB_CHECK_CONFIG_IM([QUOTA], [],
 187         [AC_MSG_ERROR([
 188
 189 Lustre quota requires that CONFIG_QUOTA is enabled in your kernel.
 190 ])])
 191 ]) # LC_QUOTA_CONFIG
 192
 193 #
 194 # LC_CONFIG_FHANDLE
 195 #
 196 # fhandle kernel support for open_by_handle_at() and name_to_handle_at()
 197 # system calls. The kernel must support CONFIG_FHANDLE.
 198 #
 199 AC_DEFUN([LC_CONFIG_FHANDLE], [
 200 LB_CHECK_CONFIG_IM([FHANDLE], [],
 201         [AC_MSG_ERROR([
 202
 203 Lustre fid handling requires that CONFIG_FHANDLE is enabled in your kernel.
 204 ])])
 205 ]) # LC_CONFIG_FHANDLE
 206
 207 #
 208 # LC_POSIX_ACL_CONFIG
 209 #
 210 # POSIX ACL support.
 211 #
 212 AC_DEFUN([LC_POSIX_ACL_CONFIG], [
 213 LB_CHECK_CONFIG_IM([FS_POSIX_ACL],
 214         [AC_DEFINE(CONFIG_LUSTRE_FS_POSIX_ACL, 1, [Enable POSIX acl])
 215 ], [ ])
 216 ]) # LC_POSIX_ACL_CONFIG
 217
 218 LB_CHECK_CONFIG_IM([CRYPTO_MD5], [],
 219                 [AC_MSG_WARN([kernel MD5 support is recommended by using GSS.])])
 220
 221 #
 222 # LC_CONFIG_GSS_KEYRING
 223 #
 224 # default 'auto', tests for dependencies, if found, enables;
 225 # only called if gss is enabled
 226 #
 227 AC_DEFUN([LC_CONFIG_GSS_KEYRING], [
 228 AC_MSG_CHECKING([whether to enable gss keyring backend])
 229 AC_ARG_ENABLE([gss_keyring],
 230         [AC_HELP_STRING([--disable-gss-keyring],
 231                 [disable gss keyring backend])],
 232         [], [enable_gss_keyring="auto"])
 233 AC_MSG_RESULT([$enable_gss_keyring])
 234 AS_IF([test "x$enable_gss_keyring" != xno], [
 235         LB_CHECK_CONFIG_IM([KEYS], [], [
 236                 gss_keyring_conf_test="fail"
 237                 AC_MSG_WARN([GSS keyring backend requires that CONFIG_KEYS be enabled in your kernel.])])
 238
 239         AC_CHECK_LIB([keyutils], [keyctl_search], [], [
 240                 gss_keyring_conf_test="fail"
 241                 AC_MSG_WARN([GSS keyring backend requires libkeyutils])])
 242
 243         AS_IF([test "x$gss_keyring_conf_test" != xfail], [
 244                 AC_DEFINE([HAVE_GSS_KEYRING], [1],
 245                         [Define this if you enable gss keyring backend])
 246                 enable_gss_keyring="yes"
 247         ], [
 248                 AS_IF([test "x$enable_gss_keyring" = xyes], [
 249                         AC_MSG_ERROR([Cannot enable gss_keyring. See above for details.])
 250                 ])
 251         ])
 252 ])
 253 ]) # LC_CONFIG_GSS_KEYRING
 254
 255 #
 256 # LC_KEY_TYPE_INSTANTIATE_2ARGS
 257 #
 258 # rhel7 key_type->instantiate takes 2 args (struct key, struct key_preparsed_payload)
 259 #
 260 AC_DEFUN([LC_KEY_TYPE_INSTANTIATE_2ARGS], [
 261 LB_CHECK_COMPILE([if 'key_type->instantiate' has two args],
 262 key_type_instantiate_2args, [
 263         #include <linux/key-type.h>
 264 ],[
 265         ((struct key_type *)0)->instantiate(0, NULL);
 266 ],[
 267         AC_DEFINE(HAVE_KEY_TYPE_INSTANTIATE_2ARGS, 1,
 268                 [key_type->instantiate has two args])
 269 ])
 270 ]) # LC_KEY_TYPE_INSTANTIATE_2ARGS
 271
 272 #
 273 # LC_CONFIG_SUNRPC
 274 #
 275 AC_DEFUN([LC_CONFIG_SUNRPC], [
 276 LB_CHECK_CONFIG_IM([SUNRPC], [], [
 277         AS_IF([test "x$sunrpc_required" = xyes], [
 278                 AC_MSG_ERROR([
 279
 280 kernel SUNRPC support is required by using GSS.
 281 ])
 282         ])])
 283 ]) # LC_CONFIG_SUNRPC
 284
 285 #
 286 # LC_CONFIG_GSS (default 'auto' (tests for dependencies, if found, enables))
 287 #
 288 # Build gss and related tools of Lustre. Currently both kernel and user space
 289 # parts are depend on linux platform.
 290 #
 291 AC_DEFUN([LC_CONFIG_GSS], [
 292 AC_MSG_CHECKING([whether to enable gss support])
 293 AC_ARG_ENABLE([gss],
 294         [AC_HELP_STRING([--enable-gss], [enable gss support])],
 295         [], [enable_gss="auto"])
 296 AC_MSG_RESULT([$enable_gss])
 297
 298 AC_ARG_VAR([TEST_JOBS],
 299     [simultaneous jobs during configure (defaults to $(nproc))])
 300 if test "x$ac_cv_env_TEST_JOBS_set" != "xset"; then
 301         TEST_JOBS=${TEST_JOBS:-$(nproc)}
 302 fi
 303 AC_SUBST(TEST_JOBS)
 304
 305 AC_ARG_VAR([TEST_DIR],
 306     [location of temporary parallel configure tests (defaults to $PWD/lb2)])
 307         TEST_DIR=${TEST_DIR:-$PWD/_lpb}
 308 AC_SUBST(TEST_DIR)
 309
 310 AS_IF([test "x$enable_gss" != xno], [
 311         LC_CONFIG_GSS_KEYRING
 312         LC_KEY_TYPE_INSTANTIATE_2ARGS
 313         sunrpc_required=$enable_gss
 314         LC_CONFIG_SUNRPC
 315         sunrpc_required="no"
 316
 317         LB_CHECK_CONFIG_IM([CRYPTO_MD5], [],
 318                 [AC_MSG_WARN([kernel MD5 support is recommended by using GSS.])])
 319         LB_CHECK_CONFIG_IM([CRYPTO_SHA1], [],
 320                 [AC_MSG_WARN([kernel SHA1 support is recommended by using GSS.])])
 321         LB_CHECK_CONFIG_IM([CRYPTO_SHA256], [],
 322                 [AC_MSG_WARN([kernel SHA256 support is recommended by using GSS.])])
 323         LB_CHECK_CONFIG_IM([CRYPTO_SHA512], [],
 324                 [AC_MSG_WARN([kernel SHA512 support is recommended by using GSS.])])
 325
 326         require_krb5=$enable_gss
 327         AC_KERBEROS_V5
 328         require_krb5="no"
 329
 330         AS_IF([test -n "$KRBDIR"], [
 331                 gss_conf_test="success"
 332         ], [
 333                 gss_conf_test="failure"
 334         ])
 335
 336         AS_IF([test "x$gss_conf_test" = xsuccess && test "x$enable_gss" != xno], [
 337                 AC_DEFINE([HAVE_GSS], [1], [Define this is if you enable gss])
 338                 enable_gss="yes"
 339         ], [
 340                 enable_gss_keyring="no"
 341                 enable_gss="no"
 342         ])
 343
 344         enable_ssk=$enable_gss
 345 ], [
 346         enable_gss_keyring="no"
 347 ])
 348 ]) # LC_CONFIG_GSS
 349
 350 # LC_OPENSSL_SSK
 351 #
 352 # OpenSSL 1.0+ return int for HMAC functions but older SLES11 versions do not
 353 AC_DEFUN([LC_OPENSSL_SSK], [
 354 AC_MSG_CHECKING([whether OpenSSL has functions needed for SSK])
 355 AS_IF([test "x$enable_ssk" != xno], [
 356 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 357         #include <openssl/hmac.h>
 358         #include <openssl/evp.h>
 359
 360         int main(void) {
 361                 int rc;
 362                 rc = HMAC_Init_ex(NULL, "test", 4, EVP_md_null(), NULL);
 363         }
 364 ])],[AC_DEFINE(HAVE_OPENSSL_SSK, 1,
 365                [OpenSSL HMAC functions needed for SSK])],
 366         [enable_ssk="no"])
 367 ])
 368 AC_MSG_RESULT([$enable_ssk])
 369 ]) # LC_OPENSSL_SSK
 370
 371 # LC_OPENSSL_GETSEPOL
 372 #
 373 # OpenSSL is needed for l_getsepol
 374 AC_DEFUN([LC_OPENSSL_GETSEPOL], [
 375 AC_MSG_CHECKING([whether openssl-devel is present])
 376 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 377         #include <openssl/evp.h>
 378
 379         int main(void) {
 380                 EVP_MD_CTX *mdctx = EVP_MD_CTX_create();
 381         }
 382 ])],[
 383         AC_DEFINE(HAVE_OPENSSL_GETSEPOL, 1, [openssl-devel is present])
 384         enable_getsepol="yes"
 385
 386 ],[
 387         enable_getsepol="no"
 388         AC_MSG_WARN([
 389
 390 No openssl-devel headers found, unable to build l_getsepol and SELinux status checking
 391 ])
 392 ])
 393 AC_MSG_RESULT([$enable_getsepol])
 394 ]) # LC_OPENSSL_GETSEPOL
 395
 396 # LC_HAVE_LIBAIO
 397 AC_DEFUN([LC_HAVE_LIBAIO], [
 398         AC_CHECK_HEADER([libaio.h],
 399                 enable_libaio="yes",
 400                 AC_MSG_WARN([libaio is not installed in the system]))
 401 ]) # LC_HAVE_LIBAIO
 402
 403 AC_DEFUN([LC_HAVE_PROJECT_QUOTA], [
 404 LB_CHECK_COMPILE([if get_projid exists],
 405 get_projid, [
 406         struct inode;
 407         #include <linux/quota.h>
 408 ],[
 409         struct dquot_operations ops = { };
 410
 411         ops.get_projid(NULL, NULL);
 412 ],[
 413         AC_DEFINE(HAVE_PROJECT_QUOTA, 1,
 414                 [get_projid function exists])
 415 ])
 416 ]) # LC_HAVE_PROJECT_QUOTA
 417
 418 #
 419 # LC_INVALIDATE_RANGE
 420 #
 421 # 3.11 invalidatepage requires the length of the range to invalidate
 422 #
 423 AC_DEFUN([LC_INVALIDATE_RANGE], [
 424 LB_CHECK_COMPILE([if 'address_space_operations.invalidatepage' requires 3 arguments],
 425 address_space_ops_invalidatepage_3args, [
 426         #include <linux/fs.h>
 427 ],[
 428         struct address_space_operations a_ops;
 429         a_ops.invalidatepage(NULL, 0, 0);
 430 ],[
 431         AC_DEFINE(HAVE_INVALIDATE_RANGE, 1,
 432                 [address_space_operations.invalidatepage needs 3 arguments])
 433 ])
 434 ]) # LC_INVALIDATE_RANGE
 435
 436 #
 437 # LC_HAVE_DIR_CONTEXT
 438 #
 439 # 3.11 readdir now takes the new struct dir_context
 440 #
 441 AC_DEFUN([LC_HAVE_DIR_CONTEXT], [
 442 LB_CHECK_COMPILE([if 'dir_context' exist],
 443 dir_context, [
 444         #include <linux/fs.h>
 445 ],[
 446 #ifdef FMODE_KABI_ITERATE
 447 #error "back to use readdir in kabi_extand mode"
 448 #else
 449         struct dir_context ctx;
 450
 451         ctx.pos = 0;
 452 #endif
 453 ],[
 454         AC_DEFINE(HAVE_DIR_CONTEXT, 1,
 455                 [dir_context exist])
 456 ])
 457 ]) # LC_HAVE_DIR_CONTEXT
 458
 459 #
 460 # LC_D_COMPARE_5ARGS
 461 #
 462 # 3.11 dentry_operations.d_compare() taken 5 arguments.
 463 #
 464 AC_DEFUN([LC_D_COMPARE_5ARGS], [
 465 LB_CHECK_COMPILE([if 'd_compare' taken 5 arguments],
 466 d_compare_5args, [
 467         #include <linux/dcache.h>
 468 ],[
 469         ((struct dentry_operations*)0)->d_compare(NULL,NULL,0,NULL,NULL);
 470 ],[
 471         AC_DEFINE(HAVE_D_COMPARE_5ARGS, 1,
 472                 [d_compare need 5 arguments])
 473 ])
 474 ]) # LC_D_COMPARE_5ARGS
 475
 476 #
 477 # LC_HAVE_DCOUNT
 478 #
 479 # 3.11 need to access d_count to get dentry reference count
 480 #
 481 AC_DEFUN([LC_HAVE_DCOUNT], [
 482 LB_CHECK_COMPILE([if 'd_count' exists],
 483 d_count, [
 484         #include <linux/dcache.h>
 485 ],[
 486         struct dentry de = { };
 487         int count;
 488
 489         count = d_count(&de);
 490 ],[
 491         AC_DEFINE(HAVE_D_COUNT, 1,
 492                 [d_count exist])
 493 ])
 494 ]) # LC_HAVE_DCOUNT
 495
 496 #
 497 # LC_PID_NS_FOR_CHILDREN
 498 #
 499 # 3.11 replaces pid_ns by pid_ns_for_children in struct nsproxy
 500 #
 501 AC_DEFUN([LC_PID_NS_FOR_CHILDREN], [
 502 LB_CHECK_COMPILE([if 'struct nsproxy' has 'pid_ns_for_children'],
 503 pid_ns_for_children, [
 504         #include <linux/nsproxy.h>
 505 ],[
 506         struct nsproxy ns;
 507         ns.pid_ns_for_children = NULL;
 508 ],[
 509         AC_DEFINE(HAVE_PID_NS_FOR_CHILDREN, 1,
 510                   ['struct nsproxy' has 'pid_ns_for_children'])
 511 ])
 512 ]) # LC_PID_NS_FOR_CHILDREN
 513
 514 #
 515 # LC_OLDSIZE_TRUNCATE_PAGECACHE
 516 #
 517 # 3.12 truncate_pagecache without oldsize parameter
 518 #
 519 AC_DEFUN([LC_OLDSIZE_TRUNCATE_PAGECACHE], [
 520 LB_CHECK_COMPILE([if 'truncate_pagecache' with 'old_size' parameter],
 521 truncate_pagecache_old_size, [
 522         #include <linux/mm.h>
 523 ],[
 524         truncate_pagecache(NULL, 0, 0);
 525 ],[
 526         AC_DEFINE(HAVE_OLDSIZE_TRUNCATE_PAGECACHE, 1,
 527                 [with oldsize])
 528 ])
 529 ]) # LC_OLDSIZE_TRUNCATE_PAGECACHE
 530
 531 #
 532 # LC_PTR_ERR_OR_ZERO
 533 #
 534 # For some reason SLES11SP4 is missing the PTR_ERR_OR_ZERO macro
 535 # It was added to linux kernel 3.12
 536 #
 537 AC_DEFUN([LC_PTR_ERR_OR_ZERO_MISSING], [
 538 LB_CHECK_COMPILE([if 'PTR_ERR_OR_ZERO' is missing],
 539 is_err_or_null, [
 540         #include <linux/err.h>
 541 ],[
 542         if (PTR_ERR_OR_ZERO(NULL)) return 0;
 543 ],[
 544         AC_DEFINE(HAVE_PTR_ERR_OR_ZERO, 1,
 545                 ['PTR_ERR_OR_ZERO' exist])
 546 ])
 547 ]) # LC_PTR_ERR_OR_ZERO_MISSING
 548
 549 #
 550 # LC_HAVE_DENTRY_D_U_D_ALIAS
 551 #
 552 # 3.11 kernel moved d_alias to the union d_u in struct dentry
 553 #
 554 # Some distros move d_alias to d_u but it is still a struct list
 555 #
 556 AC_DEFUN([LC_HAVE_DENTRY_D_U_D_ALIAS], [
 557 AS_IF([test "x$lb_cv_compile_i_dentry_d_alias_list" = xyes], [
 558         LB_CHECK_COMPILE([if list 'dentry.d_u.d_alias' exist],
 559         d_alias, [
 560                 #include <linux/list.h>
 561                 #include <linux/dcache.h>
 562         ],[
 563                 struct dentry de;
 564                 INIT_LIST_HEAD(&de.d_u.d_alias);
 565         ],[
 566                 AC_DEFINE(HAVE_DENTRY_D_U_D_ALIAS, 1,
 567                         [list dentry.d_u.d_alias exist])
 568         ])
 569 ],[
 570         LB_CHECK_COMPILE([if hlist 'dentry.d_u.d_alias' exist],
 571         d_alias, [
 572                 #include <linux/list.h>
 573                 #include <linux/dcache.h>
 574         ],[
 575                 struct dentry de;
 576                 INIT_HLIST_NODE(&de.d_u.d_alias);
 577         ],[
 578                 AC_DEFINE(HAVE_DENTRY_D_U_D_ALIAS, 1,
 579                         [hlist dentry.d_u.d_alias exist])
 580         ])
 581 ])
 582 ]) # LC_HAVE_DENTRY_D_U_D_ALIAS
 583
 584 #
 585 # LC_HAVE_DENTRY_D_CHILD
 586 #
 587 # 3.11 kernel d_child has been moved out of the union d_u
 588 # in struct dentry
 589 #
 590 AC_DEFUN([LC_HAVE_DENTRY_D_CHILD], [
 591 LB_CHECK_COMPILE([if 'dentry.d_child' exist],
 592 d_child, [
 593         #include <linux/list.h>
 594         #include <linux/dcache.h>
 595 ],[
 596         struct dentry de;
 597         INIT_LIST_HEAD(&de.d_child);
 598 ],[
 599         AC_DEFINE(HAVE_DENTRY_D_CHILD, 1,
 600                 [dentry.d_child exist])
 601 ])
 602 ]) # LC_HAVE_DENTRY_D_CHILD
 603
 604 #
 605 # LC_KIOCB_KI_LEFT
 606 #
 607 # 3.12 ki_left removed from struct kiocb
 608 #
 609 AC_DEFUN([LC_KIOCB_KI_LEFT], [
 610 LB_CHECK_COMPILE([if 'struct kiocb' with 'ki_left' member],
 611 kiocb_ki_left, [
 612         #include <linux/aio.h>
 613 ],[
 614         ((struct kiocb*)0)->ki_left = 0;
 615 ],[
 616         AC_DEFINE(HAVE_KIOCB_KI_LEFT, 1,
 617                 [ki_left exist])
 618 ])
 619 ]) # LC_KIOCB_KI_LEFT
 620
 621 #
 622 # LC_VFS_RENAME_5ARGS
 623 #
 624 # 3.13 has vfs_rename with 5 args
 625 #
 626 AC_DEFUN([LC_VFS_RENAME_5ARGS], [
 627 LB_CHECK_COMPILE([if Linux kernel has 'vfs_rename' with 5 args],
 628 vfs_rename_5args, [
 629         #include <linux/fs.h>
 630 ],[
 631         vfs_rename(NULL, NULL, NULL, NULL, NULL);
 632 ], [
 633         AC_DEFINE(HAVE_VFS_RENAME_5ARGS, 1,
 634                 [kernel has vfs_rename with 5 args])
 635 ])
 636 ]) # LC_VFS_RENAME_5ARGS
 637
 638 #
 639 # LC_VFS_UNLINK_3ARGS
 640 #
 641 # 3.13 has vfs_unlink with 3 args
 642 #
 643 AC_DEFUN([LC_VFS_UNLINK_3ARGS], [
 644 LB_CHECK_COMPILE([if Linux kernel has 'vfs_unlink' with 3 args],
 645 vfs_unlink_3args, [
 646         #include <linux/fs.h>
 647 ],[
 648         vfs_unlink(NULL, NULL, NULL);
 649 ], [
 650         AC_DEFINE(HAVE_VFS_UNLINK_3ARGS, 1,
 651                 [kernel has vfs_unlink with 3 args])
 652 ])
 653 ]) # LC_VFS_UNLINK_3ARGS
 654
 655 # LC_HAVE_D_IS_POSITIVE
 656 #
 657 # Kernel version 3.13 b18825a7c8e37a7cf6abb97a12a6ad71af160de7
 658 # d_is_positive is added
 659 #
 660 AC_DEFUN([LC_HAVE_D_IS_POSITIVE], [
 661 LB_CHECK_COMPILE([if 'd_is_positive' exist],
 662 d_is_positive, [
 663         #include <linux/dcache.h>
 664 ],[
 665         d_is_positive(NULL);
 666 ],[
 667         AC_DEFINE(HAVE_D_IS_POSITIVE, 1,
 668                 ['d_is_positive' is available])
 669 ])
 670 ]) # LC_HAVE_D_IS_POSITIVE
 671
 672 #
 673 # LC_HAVE_BVEC_ITER
 674 #
 675 # 3.14 move some of its data in struct bio into the new
 676 # struct bvec_iter
 677 #
 678 AC_DEFUN([LC_HAVE_BVEC_ITER], [
 679 LB_CHECK_COMPILE([if Linux kernel has struct bvec_iter],
 680 have_bvec_iter, [
 681         #include <linux/bio.h>
 682 ],[
 683         struct bvec_iter iter;
 684
 685         iter.bi_bvec_done = 0;
 686 ], [
 687         AC_DEFINE(HAVE_BVEC_ITER, 1,
 688                 [kernel has struct bvec_iter])
 689 ])
 690 ]) # LC_HAVE_BVEC_ITER
 691
 692 #
 693 # LC_IOP_SET_ACL
 694 #
 695 # 3.14 adds set_acl method to inode_operations
 696 # see kernel commit 893d46e443346370cd4ea81d9d35f72952c62a37
 697 #
 698 AC_DEFUN([LC_IOP_SET_ACL], [
 699 LB_CHECK_COMPILE([if 'inode_operations' has '.set_acl' member function],
 700 inode_ops_set_acl, [
 701         #include <linux/fs.h>
 702 ],[
 703         struct inode_operations iop;
 704         iop.set_acl = NULL;
 705 ],[
 706         AC_DEFINE(HAVE_IOP_SET_ACL, 1,
 707                 [inode_operations has .set_acl member function])
 708 ])
 709 ]) # LC_IOP_SET_ACL
 710
 711 #
 712 # LC_HAVE_TRUNCATE_IPAGE_FINAL
 713 #
 714 # 3.14 bring truncate_inode_pages_final for evict_inode
 715 #
 716 AC_DEFUN([LC_HAVE_TRUNCATE_IPAGES_FINAL], [
 717 LB_CHECK_COMPILE([if Linux kernel has truncate_inode_pages_final],
 718 truncate_ipages_final, [
 719         #include <linux/mm.h>
 720 ],[
 721         truncate_inode_pages_final(NULL);
 722 ], [
 723         AC_DEFINE(HAVE_TRUNCATE_INODE_PAGES_FINAL, 1,
 724                 [kernel has truncate_inode_pages_final])
 725 ])
 726 ]) # LC_HAVE_TRUNCATE_IPAGES_FINAL
 727
 728 #
 729 # LC_IOPS_RENAME_WITH_FLAGS
 730 #
 731 # 3.14 has inode_operations->rename with 5 args
 732 # commit 520c8b16505236fc82daa352e6c5e73cd9870cff
 733 #
 734 AC_DEFUN([LC_IOPS_RENAME_WITH_FLAGS], [
 735 LB_CHECK_COMPILE([if 'inode_operations->rename' taken flags as argument],
 736 iops_rename_with_flags, [
 737         #include <linux/fs.h>
 738 ],[
 739         struct inode *i1 = NULL, *i2 = NULL;
 740         struct dentry *d1 = NULL, *d2 = NULL;
 741         int rc;
 742         rc = ((struct inode_operations *)0)->rename(i1, d1, i2, d2, 0);
 743 ], [
 744         AC_DEFINE(HAVE_IOPS_RENAME_WITH_FLAGS, 1,
 745                 [inode_operations->rename need flags as argument])
 746 ])
 747 ]) # LC_IOPS_RENAME_WITH_FLAGS
 748
 749 #
 750 # LC_VFS_RENAME_6ARGS
 751 #
 752 # 3.15 has vfs_rename with 6 args
 753 #
 754 AC_DEFUN([LC_VFS_RENAME_6ARGS], [
 755 LB_CHECK_COMPILE([if Linux kernel has 'vfs_rename' with 6 args],
 756 vfs_rename_6args, [
 757         #include <linux/fs.h>
 758 ],[
 759         vfs_rename(NULL, NULL, NULL, NULL, NULL, NULL);
 760 ], [
 761         AC_DEFINE(HAVE_VFS_RENAME_6ARGS, 1,
 762                 [kernel has vfs_rename with 6 args])
 763 ])
 764 ]) # LC_VFS_RENAME_6ARGS
 765
 766 #
 767 # LC_DIRECTIO_USE_ITER
 768 #
 769 # 3.16 kernel changes direct IO to use iov_iter
 770 #
 771 AC_DEFUN([LC_DIRECTIO_USE_ITER], [
 772 LB_CHECK_COMPILE([if direct IO uses iov_iter],
 773 direct_io_iter, [
 774         #include <linux/fs.h>
 775 ],[
 776         struct address_space_operations ops = { };
 777         struct iov_iter *iter = NULL;
 778         loff_t offset = 0;
 779
 780         ops.direct_IO(0, NULL, iter, offset);
 781 ],[
 782         AC_DEFINE(HAVE_DIRECTIO_ITER, 1,
 783                 [direct IO uses iov_iter])
 784 ])
 785 ]) # LC_DIRECTIO_USE_ITER
 786
 787 #
 788 # LC_HAVE_IOV_ITER_INIT_DIRECTION
 789 #
 790 #
 791 # 3.16 linux commit 71d8e532b1549a478e6a6a8a44f309d050294d00
 792 #      changed iov_iter_init api to start accepting a tag
 793 #      that defines if its a read or write operation
 794 #
 795 AC_DEFUN([LC_HAVE_IOV_ITER_INIT_DIRECTION], [
 796 tmp_flags="$EXTRA_KCFLAGS"
 797 EXTRA_KCFLAGS="-Werror"
 798 LB_CHECK_COMPILE([if 'iov_iter_init' takes a tag],
 799 iter_init, [
 800         #include <linux/uio.h>
 801         #include <linux/fs.h>
 802 ],[
 803         const struct iovec *iov = NULL;
 804
 805         iov_iter_init(NULL, READ, iov, 1, 0);
 806 ],[
 807         AC_DEFINE(HAVE_IOV_ITER_INIT_DIRECTION, 1,
 808                 [iov_iter_init handles directional tag])
 809 ])
 810 EXTRA_KCFLAGS="$tmp_flags"
 811 ]) # LC_HAVE_IOV_ITER_INIT_DIRECTION
 812
 813 #
 814 # LC_HAVE_IOV_ITER_TRUNCATE
 815 #
 816 #
 817 # 3.16 introduces a new API iov_iter_truncate()
 818 #
 819 AC_DEFUN([LC_HAVE_IOV_ITER_TRUNCATE], [
 820 tmp_flags="$EXTRA_KCFLAGS"
 821 EXTRA_KCFLAGS="-Werror"
 822 LB_CHECK_COMPILE([if 'iov_iter_truncate' exists ],
 823 iter_truncate, [
 824         #include <linux/uio.h>
 825         #include <linux/fs.h>
 826 ],[
 827         struct iov_iter *i = NULL;
 828
 829         iov_iter_truncate(i, 0);
 830 ],[
 831         AC_DEFINE(HAVE_IOV_ITER_TRUNCATE, 1, [iov_iter_truncate exists])
 832 ])
 833 EXTRA_KCFLAGS="$tmp_flags"
 834 ]) # LC_HAVE_IOV_ITER_TRUNCATE
 835
 836 #
 837 # LC_HAVE_FILE_OPERATIONS_READ_WRITE_ITER
 838 #
 839 # 3.16 introduces [read|write]_iter to struct file_operations
 840 #
 841 AC_DEFUN([LC_HAVE_FILE_OPERATIONS_READ_WRITE_ITER], [
 842 LB_CHECK_COMPILE([if 'file_operations.[read|write]_iter' exist],
 843 file_function_iter, [
 844         #include <linux/fs.h>
 845 ],[
 846         ((struct file_operations *)NULL)->read_iter(NULL, NULL);
 847         ((struct file_operations *)NULL)->write_iter(NULL, NULL);
 848 ],[
 849         AC_DEFINE(HAVE_FILE_OPERATIONS_READ_WRITE_ITER, 1,
 850                 [file_operations.[read|write]_iter functions exist])
 851 ])
 852 ]) # LC_HAVE_FILE_OPERATIONS_READ_WRITE_ITER
 853
 854 #
 855 # LC_HAVE_INTERVAL_BLK_INTEGRITY
 856 #
 857 # 3.17 replace sector_size with interval in struct blk_integrity
 858 #
 859 AC_DEFUN([LC_HAVE_INTERVAL_BLK_INTEGRITY], [
 860 LB_CHECK_COMPILE([if 'blk_integrity.interval' exist],
 861 interval_blk_integrity, [
 862         #include <linux/blkdev.h>
 863 ],[
 864         ((struct blk_integrity *)0)->interval = 0;
 865 ],[
 866         AC_DEFINE(HAVE_INTERVAL_BLK_INTEGRITY, 1,
 867                 [blk_integrity.interval exist])
 868 ])
 869 ]) # LC_HAVE_INTERVAL_BLK_INTEGRITY
 870
 871 #
 872 # LC_KEY_MATCH_DATA
 873 #
 874 # 3.17  replaces key_type::match with match_preparse
 875 #       and has new struct key_match_data
 876 #
 877 AC_DEFUN([LC_KEY_MATCH_DATA], [
 878 LB_CHECK_COMPILE([if struct key_match field exist],
 879 key_match, [
 880         #include <linux/key-type.h>
 881 ],[
 882         struct key_match_data data;
 883
 884         data.raw_data = NULL;
 885 ],[
 886         AC_DEFINE(HAVE_KEY_MATCH_DATA, 1,
 887                 [struct key_match_data exist])
 888 ])
 889 ]) # LC_KEY_MATCH_DATA
 890
 891 #
 892 # LC_NFS_FILLDIR_USE_CTX
 893 #
 894 # 3.18 kernel moved from void cookie to struct dir_context
 895 #
 896 AC_DEFUN([LC_NFS_FILLDIR_USE_CTX], [
 897 tmp_flags="$EXTRA_KCFLAGS"
 898 EXTRA_KCFLAGS="-Werror"
 899 LB_CHECK_COMPILE([if filldir_t uses struct dir_context],
 900 filldir_ctx, [
 901         #include <linux/fs.h>
 902 ],[
 903         int filldir(struct dir_context *ctx, const char* name,
 904                     int i, loff_t off, u64 tmp, unsigned temp)
 905         {
 906                 return 0;
 907         }
 908
 909         struct dir_context ctx = {
 910                 .actor = filldir,
 911         };
 912
 913         ctx.actor(NULL, "test", 0, (loff_t) 0, 0, 0);
 914 ],[
 915         AC_DEFINE(HAVE_FILLDIR_USE_CTX, 1,
 916                 [filldir_t needs struct dir_context as argument])
 917 ])
 918 EXTRA_KCFLAGS="$tmp_flags"
 919 ]) # LC_NFS_FILLDIR_USE_CTX
 920
 921 #
 922 # LC_PERCPU_COUNTER_INIT
 923 #
 924 # 3.18  For kernels 3.18 and after percpu_counter_init starts
 925 #       to pass a GFP_* memory allocation flag for internal
 926 #       memory allocation purposes.
 927 #
 928 AC_DEFUN([LC_PERCPU_COUNTER_INIT], [
 929 LB_CHECK_COMPILE([if percpu_counter_init uses GFP_* flag as argument],
 930 percpu_counter_init, [
 931         #include <linux/percpu_counter.h>
 932 ],[
 933         percpu_counter_init(NULL, 0, GFP_KERNEL);
 934 ],[
 935         AC_DEFINE(HAVE_PERCPU_COUNTER_INIT_GFP_FLAG, 1,
 936                 [percpu_counter_init uses GFP_* flag])
 937 ])
 938 ]) # LC_PERCPU_COUNTER_INIT
 939
 940 #
 941 # LC_KIOCB_HAS_NBYTES
 942 #
 943 # 3.19 kernel removed ki_nbytes from struct kiocb
 944 #
 945 AC_DEFUN([LC_KIOCB_HAS_NBYTES], [
 946 LB_CHECK_COMPILE([if struct kiocb has ki_nbytes field],
 947 ki_nbytes, [
 948         #include <linux/fs.h>
 949 ],[
 950         struct kiocb iocb = { };
 951
 952         iocb.ki_nbytes = 0;
 953 ],[
 954         AC_DEFINE(HAVE_KI_NBYTES, 1, [ki_nbytes field exist])
 955 ])
 956 ]) # LC_KIOCB_HAS_NBYTES
 957
 958 #
 959 # LC_HAVE_DQUOT_QC_DQBLK
 960 #
 961 # 3.19 has quotactl_ops->[sg]et_dqblk that take struct kqid and qc_dqblk
 962 # Added in commit 14bf61ffe
 963 #
 964 AC_DEFUN([LC_HAVE_DQUOT_QC_DQBLK], [
 965 tmp_flags="$EXTRA_KCFLAGS"
 966 EXTRA_KCFLAGS="-Werror"
 967 LB_CHECK_COMPILE([if 'quotactl_ops.set_dqblk' takes struct qc_dqblk],
 968 qc_dqblk, [
 969         #include <linux/fs.h>
 970         #include <linux/quota.h>
 971 ],[
 972         ((struct quotactl_ops *)0)->set_dqblk(NULL, *((struct kqid*)0), (struct qc_dqblk*)0);
 973 ],[
 974         AC_DEFINE(HAVE_DQUOT_QC_DQBLK, 1,
 975                 [quotactl_ops.set_dqblk takes struct qc_dqblk])
 976         AC_DEFINE(HAVE_DQUOT_KQID, 1,
 977                 [quotactl_ops.set_dqblk takes struct kqid])
 978 ])
 979 EXTRA_KCFLAGS="$tmp_flags"
 980 ]) # LC_HAVE_DQUOT_QC_DQBLK
 981
 982 #
 983 # LC_HAVE_AIO_COMPLETE
 984 #
 985 # 3.19 kernel makes aio_complete() static
 986 #
 987 AC_DEFUN([LC_HAVE_AIO_COMPLETE], [
 988 LB_CHECK_COMPILE([if kernel has exported aio_complete() ],
 989 aio_complete, [
 990         #include <linux/aio.h>
 991 ],[
 992         aio_complete(NULL, 0, 0);
 993 ],[
 994         AC_DEFINE(HAVE_AIO_COMPLETE, 1, [aio_complete defined])
 995 ])
 996 ]) # LC_HAVE_AIO_COMPLETE
 997
 998 #
 999 # LC_BACKING_DEV_INFO_REMOVAL
1000 #
1001 # 3.20 kernel removed backing_dev_info from address_space
1002 #
1003 AC_DEFUN([LC_BACKING_DEV_INFO_REMOVAL], [
1004 LB_CHECK_COMPILE([if struct address_space has backing_dev_info],
1005 backing_dev_info, [
1006         #include <linux/fs.h>
1007 ],[
1008         struct address_space mapping;
1009
1010         mapping.backing_dev_info = NULL;
1011 ],[
1012         AC_DEFINE(HAVE_BACKING_DEV_INFO, 1, [backing_dev_info exist])
1013 ])
1014 ]) # LC_BACKING_DEV_INFO_REMOVAL
1015
1016 #
1017 # LC_HAVE_BDI_CAP_MAP_COPY
1018 #
1019 # 3.20  removed mmap handling for backing devices since
1020 #       it breaks on non-MMU systems. See kernel commit
1021 #       b4caecd48005fbed3949dde6c1cb233142fd69e9
1022 #
1023 AC_DEFUN([LC_HAVE_BDI_CAP_MAP_COPY], [
1024 LB_CHECK_COMPILE([if have 'BDI_CAP_MAP_COPY'],
1025 bdi_cap_map_copy, [
1026         #include <linux/backing-dev.h>
1027 ],[
1028         struct backing_dev_info info;
1029
1030         info.capabilities = BDI_CAP_MAP_COPY;
1031 ],[
1032         AC_DEFINE(HAVE_BDI_CAP_MAP_COPY, 1,
1033                 [BDI_CAP_MAP_COPY exist])
1034 ])
1035 ]) # LC_HAVE_BDI_CAP_MAP_COPY
1036
1037 #
1038 # LC_IOV_ITER_RW
1039 #
1040 # 4.1 kernel has iov_iter_rw
1041 #
1042 AC_DEFUN([LC_IOV_ITER_RW], [
1043 LB_CHECK_COMPILE([if iov_iter_rw exist],
1044 iov_iter_rw, [
1045         #include <linux/fs.h>
1046         #include <linux/uio.h>
1047 ],[
1048         struct iov_iter *iter = NULL;
1049
1050         iov_iter_rw(iter);
1051 ],[
1052         AC_DEFINE(HAVE_IOV_ITER_RW, 1,
1053                 [iov_iter_rw exist])
1054 ])
1055 ]) # LC_IOV_ITER_RW
1056
1057 #
1058 # LC_HAVE_SYNC_READ_WRITE
1059 #
1060 # 4.1 new_sync_[read|write] no longer exported
1061 #
1062 AC_DEFUN([LC_HAVE_SYNC_READ_WRITE], [
1063 LB_CHECK_EXPORT([new_sync_read], [fs/read_write.c],
1064         [AC_DEFINE(HAVE_SYNC_READ_WRITE, 1,
1065                         [new_sync_[read|write] is exported by the kernel])])
1066 ]) # LC_HAVE_SYNC_READ_WRITE
1067
1068 #
1069 # LC_HAVE___BI_CNT
1070 #
1071 # 4.1 redefined bi_cnt as __bi_cnt in commit dac56212e8127dbc0
1072 #
1073 AC_DEFUN([LC_HAVE___BI_CNT], [
1074 LB_CHECK_COMPILE([if Linux kernel has __bi_cnt in struct bio],
1075 have___bi_cnt, [
1076         #include <asm/atomic.h>
1077         #include <linux/bio.h>
1078         #include <linux/blk_types.h>
1079 ],[
1080         struct bio bio = { };
1081         int cnt;
1082         cnt = atomic_read(&bio.__bi_cnt);
1083 ], [
1084         AC_DEFINE(HAVE___BI_CNT, 1,
1085                 [struct bio has __bi_cnt])
1086 ])
1087 ]) # LC_HAVE___BI_CNT
1088
1089 #
1090 # LC_SYMLINK_OPS_USE_NAMEIDATA
1091 #
1092 # For the 4.2+ kernels the file system internal symlink api no
1093 # longer uses struct nameidata as a argument
1094 #
1095 AC_DEFUN([LC_SYMLINK_OPS_USE_NAMEIDATA], [
1096 LB_CHECK_COMPILE([if symlink inode operations have struct nameidata argument],
1097 symlink_use_nameidata, [
1098         #include <linux/namei.h>
1099         #include <linux/fs.h>
1100 ],[
1101         struct nameidata *nd = NULL;
1102
1103         ((struct inode_operations *)0)->follow_link(NULL, nd);
1104         ((struct inode_operations *)0)->put_link(NULL, nd, NULL);
1105 ],[
1106         AC_DEFINE(HAVE_SYMLINK_OPS_USE_NAMEIDATA, 1,
1107                 [symlink inode operations need struct nameidata argument])
1108 ])
1109 ]) # LC_SYMLINK_OPS_USE_NAMEIDATA
1110
1111 #
1112 # LC_BIO_ENDIO_USES_ONE_ARG
1113 #
1114 # 4.2 kernel bio_endio now only takes one argument
1115 #
1116 AC_DEFUN([LC_BIO_ENDIO_USES_ONE_ARG], [
1117 LB_CHECK_COMPILE([if 'bio_endio' with one argument exist],
1118 bio_endio, [
1119         #include <linux/bio.h>
1120 ],[
1121         bio_endio(NULL);
1122 ],[
1123         AC_DEFINE(HAVE_BIO_ENDIO_USES_ONE_ARG, 1,
1124                 [bio_endio takes only one argument])
1125 ])
1126 ]) # LC_BIO_ENDIO_USES_ONE_ARG
1127
1128 #
1129 # LC_ACCOUNT_PAGE_DIRTIED_3ARGS
1130 #
1131 # 4.2 [to 4.5] kernel page dirtied takes 3 arguments
1132 #
1133 AC_DEFUN([LC_ACCOUNT_PAGE_DIRTIED_3ARGS], [
1134 LB_CHECK_COMPILE([if 'account_page_dirtied' with 3 args exists],
1135 account_page_dirtied, [
1136         #include <linux/mm.h>
1137 ],[
1138         account_page_dirtied(NULL, NULL, NULL);
1139 ],[
1140         AC_DEFINE(HAVE_ACCOUNT_PAGE_DIRTIED_3ARGS, 1,
1141                 [account_page_dirtied takes three arguments])
1142 ])
1143 ]) # LC_ACCOUNT_PAGE_DIRTIED_3ARGS
1144
1145 #
1146 # LC_HAVE_INTERVAL_EXP_BLK_INTEGRITY
1147 #
1148 # 4.3 replace interval with interval_exp in 'struct blk_integrity'
1149 # 'struct blk_integrity_profile' is also added in this version,
1150 # thus use this to determine whether 'struct blk_integrity' has profile
1151 #
1152 AC_DEFUN([LC_HAVE_INTERVAL_EXP_BLK_INTEGRITY], [
1153 LB_CHECK_COMPILE([if 'blk_integrity.interval_exp' exist],
1154 blk_integrity_interval_exp, [
1155         #include <linux/blkdev.h>
1156 ],[
1157         ((struct blk_integrity *)0)->interval_exp = 0;
1158 ],[
1159         AC_DEFINE(HAVE_INTERVAL_EXP_BLK_INTEGRITY, 1,
1160                 [blk_integrity.interval_exp exist])
1161 ])
1162 ]) # LC_HAVE_INTERVAL_EXP_BLK_INTEGRITY
1163
1164 #
1165 # LC_HAVE_CACHE_HEAD_HLIST
1166 #
1167 # 4.3 kernel swiched to hlist for cache_head
1168 #
1169 AC_DEFUN([LC_HAVE_CACHE_HEAD_HLIST], [
1170 LB_CHECK_COMPILE([if 'struct cache_head' has 'cache_list' field],
1171 cache_head_has_hlist, [
1172         #include <linux/sunrpc/cache.h>
1173 ],[
1174         do {} while(sizeof(((struct cache_head *)0)->cache_list));
1175 ],[
1176         AC_DEFINE(HAVE_CACHE_HEAD_HLIST, 1,
1177                 [cache_head has hlist cache_list])
1178 ])
1179 ]) # LC_HAVE_CACHE_HEAD_HLIST
1180
1181 #
1182 # LC_HAVE_XATTR_HANDLER_SIMPLIFIED
1183 #
1184 # Kernel version 4.3 commit e409de992e3ea3674393465f07cc71c948edd87a
1185 # simplified xattr_handler handling by passing in the handler pointer
1186 #
1187 AC_DEFUN([LC_HAVE_XATTR_HANDLER_SIMPLIFIED], [
1188 tmp_flags="$EXTRA_KCFLAGS"
1189 EXTRA_KCFLAGS="-Werror"
1190 LB_CHECK_COMPILE([if 'struct xattr_handler' functions pass in handler pointer],
1191 xattr_handler_simplified, [
1192         #include <linux/xattr.h>
1193 ],[
1194         struct xattr_handler handler;
1195
1196         ((struct xattr_handler *)0)->get(&handler, NULL, NULL, NULL, 0);
1197         ((struct xattr_handler *)0)->set(&handler, NULL, NULL, NULL, 0, 0);
1198 ],[
1199         AC_DEFINE(HAVE_XATTR_HANDLER_SIMPLIFIED, 1, [handler pointer is parameter])
1200 ])
1201 EXTRA_KCFLAGS="$tmp_flags"
1202 ]) # LC_HAVE_XATTR_HANDLER_SIMPLIFIED
1203
1204 #
1205 # LC_HAVE_BIP_ITER_BIO_INTEGRITY_PAYLOAD
1206 #
1207 # 4.3 replace interval with interval_exp in 'struct blk_integrity'.
1208 #
1209 AC_DEFUN([LC_HAVE_BIP_ITER_BIO_INTEGRITY_PAYLOAD], [
1210 LB_CHECK_COMPILE([if 'bio_integrity_payload.bip_iter' exist],
1211 bio_integrity_payload_bip_iter, [
1212         #include <linux/bio.h>
1213 ],[
1214         ((struct bio_integrity_payload *)0)->bip_iter.bi_size = 0;
1215 ],[
1216         AC_DEFINE(HAVE_BIP_ITER_BIO_INTEGRITY_PAYLOAD, 1,
1217                 [bio_integrity_payload.bip_iter exist])
1218 ])
1219 ]) # LC_HAVE_BIP_ITER_BIO_INTEGRITY_PAYLOAD
1220
1221 #
1222 # LC_BIO_INTEGRITY_PREP_FN
1223 #
1224 # Lustre kernel patch extents bio_integrity_prep to accept optional
1225 # generate/verify_fn as extra args.
1226 #
1227 AC_DEFUN([LC_BIO_INTEGRITY_PREP_FN], [
1228 LB_CHECK_COMPILE([if 'bio_integrity_prep_fn' exists],
1229 bio_integrity_prep_fn, [
1230         #include <linux/bio.h>
1231 ],[
1232         bio_integrity_prep_fn(NULL, NULL, NULL);
1233 ],[
1234         AC_DEFINE(HAVE_BIO_INTEGRITY_PREP_FN, 1,
1235                 [kernel has bio_integrity_prep_fn])
1236         AC_SUBST(PATCHED_INTEGRITY_INTF)
1237 ],[
1238         AC_SUBST(PATCHED_INTEGRITY_INTF, [#])
1239 ])
1240 ]) # LC_BIO_INTEGRITY_PREP_FN
1241
1242 #
1243 # LC_HAVE_BI_OPF
1244 #
1245 # 4.4/4.8 redefined bi_rw as bi_opf (SLES12/kernel commit 4382e33ad37486)
1246 #
1247 AC_DEFUN([LC_HAVE_BI_OPF], [
1248 LB_CHECK_COMPILE([if Linux kernel has bi_opf in struct bio],
1249 have_bi_opf, [
1250         #include <linux/bio.h>
1251 ],[
1252         struct bio bio;
1253
1254         bio.bi_opf = 0;
1255 ], [
1256         AC_DEFINE(HAVE_BI_OPF, 1,
1257                 [struct bio has bi_opf])
1258 ])
1259 ]) # LC_HAVE_BI_OPF
1260
1261 #
1262 # LC_HAVE_SUBMIT_BIO_2ARGS
1263 #
1264 # 4.4 removed an argument from submit_bio
1265 #
1266 AC_DEFUN([LC_HAVE_SUBMIT_BIO_2ARGS], [
1267 LB_CHECK_COMPILE([if submit_bio takes two arguments],
1268 have_submit_bio_2args, [
1269         #include <linux/bio.h>
1270 ],[
1271         struct bio bio;
1272         submit_bio(READ, &bio);
1273 ], [
1274         AC_DEFINE(HAVE_SUBMIT_BIO_2ARGS, 1,
1275                 [submit_bio takes two arguments])
1276 ])
1277 ]) # LC_HAVE_SUBMIT_BIO_2_ARGS
1278
1279 #
1280 # LC_HAVE_CLEAN_BDEV_ALIASES
1281 #
1282 # 4.4/4.9 unmap_underlying_metadata was replaced by clean_bdev_aliases
1283 # (SLES12/kernel commit 29f3ad7d8380364c)
1284 #
1285 AC_DEFUN([LC_HAVE_CLEAN_BDEV_ALIASES], [
1286 LB_CHECK_COMPILE([if kernel has clean_bdev_aliases],
1287 have_clean_bdev_aliases, [
1288         #include <linux/buffer_head.h>
1289 ],[
1290         struct block_device bdev;
1291         clean_bdev_aliases(&bdev,1,1);
1292 ], [
1293         AC_DEFINE(HAVE_CLEAN_BDEV_ALIASES, 1,
1294                 [kernel has clean_bdev_aliases])
1295 ])
1296 ]) # LC_HAVE_CLEAN_BDEV_ALIASES
1297
1298 #
1299 # LC_HAVE_LOCKS_LOCK_FILE_WAIT
1300 #
1301 # 4.4 kernel have moved locks API users to
1302 # locks_lock_inode_wait()
1303 #
1304 AC_DEFUN([LC_HAVE_LOCKS_LOCK_FILE_WAIT], [
1305 LB_CHECK_COMPILE([if 'locks_lock_file_wait' exists],
1306 locks_lock_file_wait, [
1307         #include <linux/fs.h>
1308 ],[
1309         locks_lock_file_wait(NULL, NULL);
1310 ],[
1311         AC_DEFINE(HAVE_LOCKS_LOCK_FILE_WAIT, 1,
1312                 [kernel has locks_lock_file_wait])
1313 ])
1314 ]) # LC_HAVE_LOCKS_LOCK_FILE_WAIT
1315
1316 #
1317 # LC_HAVE_KEY_PAYLOAD_DATA_ARRAY
1318 #
1319 # 4.4 kernel merged type-specific data with the payload data for keys
1320 #
1321 AC_DEFUN([LC_HAVE_KEY_PAYLOAD_DATA_ARRAY], [
1322 LB_CHECK_COMPILE([if 'struct key' has 'payload.data' as an array],
1323 key_payload_data_array, [
1324         #include <linux/key.h>
1325 ],[
1326         struct key key = { };
1327
1328         key.payload.data[0] = NULL;
1329 ],[
1330         AC_DEFINE(HAVE_KEY_PAYLOAD_DATA_ARRAY, 1, [payload.data is an array])
1331 ])
1332 ]) #LC_HAVE_KEY_PAYLOAD_DATA_ARRAY
1333
1334 #
1335 # LC_HAVE_XATTR_HANDLER_NAME
1336 #
1337 # Kernel version 4.4 commit 98e9cb5711c68223f0e4d5201b9a6add255ec550
1338 # add a name member to struct xattr_handler
1339 #
1340 AC_DEFUN([LC_HAVE_XATTR_HANDLER_NAME], [
1341 tmp_flags="$EXTRA_KCFLAGS"
1342 EXTRA_KCFLAGS="-Werror"
1343 LB_CHECK_COMPILE([if 'struct xattr_handler' has a name member],
1344 xattr_handler_name, [
1345         #include <linux/xattr.h>
1346 ],[
1347         ((struct xattr_handler *)NULL)->name = NULL;
1348 ],[
1349         AC_DEFINE(HAVE_XATTR_HANDLER_NAME, 1, [xattr_handler has a name member])
1350 ])
1351 EXTRA_KCFLAGS="$tmp_flags"
1352 ]) # LC_HAVE_XATTR_HANDLER_NAME
1353
1354 #
1355 # LC_HAVE_FILE_DENTRY
1356 #
1357 # 4.5 adds wrapper file_dentry
1358 #
1359 AC_DEFUN([LC_HAVE_FILE_DENTRY], [
1360 LB_CHECK_COMPILE([if Linux kernel has 'file_dentry'],
1361 file_dentry, [
1362         #include <linux/fs.h>
1363 ],[
1364         file_dentry(NULL);
1365 ], [
1366         AC_DEFINE(HAVE_FILE_DENTRY, 1,
1367                 [kernel has file_dentry])
1368 ])
1369 ]) # LC_HAVE_FILE_DENTRY
1370
1371 #
1372 # LC_HAVE_INODE_LOCK
1373 #
1374 # 4.5 introduced inode_lock
1375 #
1376 AC_DEFUN([LC_HAVE_INODE_LOCK], [
1377 LB_CHECK_COMPILE([if 'inode_lock' is defined],
1378 inode_lock, [
1379         #include <linux/fs.h>
1380 ],[
1381         inode_lock(NULL);
1382 ], [
1383         AC_DEFINE(HAVE_INODE_LOCK, 1,
1384                   [inode_lock is defined])
1385 ])
1386 ]) # LC_HAVE_INODE_LOCK
1387
1388 #
1389 # LC_HAVE_IOP_GET_LINK
1390 #
1391 # 4.5 vfs replaced iop->follow_link with
1392 # iop->get_link
1393 #
1394 AC_DEFUN([LC_HAVE_IOP_GET_LINK], [
1395 LB_CHECK_COMPILE([if 'iop' has 'get_link'],
1396 inode_ops_get_link, [
1397         #include <linux/fs.h>
1398 ],[
1399         struct inode_operations iop;
1400         iop.get_link = NULL;
1401 ],[
1402         AC_DEFINE(HAVE_IOP_GET_LINK, 1,
1403                 [have iop get_link])
1404 ])
1405 ]) # LC_HAVE_IOP_GET_LINK
1406
1407 #
1408 # LC_HAVE_IN_COMPAT_SYSCALL
1409 #
1410 # 4.6 renamed is_compat_task to in_compat_syscall
1411 #
1412 AC_DEFUN([LC_HAVE_IN_COMPAT_SYSCALL], [
1413 LB_CHECK_COMPILE([if 'in_compat_syscall' is defined],
1414 in_compat_syscall, [
1415         #include <linux/compat.h>
1416 ],[
1417         in_compat_syscall();
1418 ],[
1419         AC_DEFINE(HAVE_IN_COMPAT_SYSCALL, 1,
1420                 [have in_compat_syscall])
1421 ])
1422 ]) # LC_HAVE_IN_COMPAT_SYSCALL
1423
1424 #
1425 # LC_HAVE_XATTR_HANDLER_INODE_PARAM
1426 #
1427 # Kernel version 4.6 commit b296821a7c42fa58baa17513b2b7b30ae66f3336
1428 # and commit 5930122683dff58f0846b0f0405b4bd598a3ba6a added inode parameter
1429 # to xattr_handler functions
1430 #
1431 AC_DEFUN([LC_HAVE_XATTR_HANDLER_INODE_PARAM], [
1432 tmp_flags="$EXTRA_KCFLAGS"
1433 EXTRA_KCFLAGS="-Werror"
1434 LB_CHECK_COMPILE([if 'struct xattr_handler' functions have inode parameter],
1435 xattr_handler_inode_param, [
1436         #include <linux/xattr.h>
1437 ],[
1438         const struct xattr_handler handler;
1439
1440         ((struct xattr_handler *)0)->get(&handler, NULL, NULL, NULL, NULL, 0);
1441         ((struct xattr_handler *)0)->set(&handler, NULL, NULL, NULL, NULL, 0, 0);
1442 ],[
1443         AC_DEFINE(HAVE_XATTR_HANDLER_INODE_PARAM, 1, [needs inode parameter])
1444 ])
1445 EXTRA_KCFLAGS="$tmp_flags"
1446 ]) # LC_HAVE_XATTR_HANDLER_INODE_PARAM
1447
1448 #
1449 # LC_D_IN_LOOKUP
1450 #
1451 # Kernel version 4.6 commit 85c7f81041d57cfe9dc97f4680d5586b54534a39
1452 # introduced parallel lookups in the VFS layer. The inline function
1453 # d_in_lookup was added to notify when the same item was being queried
1454 # at the same time.
1455 #
1456 AC_DEFUN([LC_D_IN_LOOKUP], [
1457 tmp_flags="$EXTRA_KCFLAGS"
1458 EXTRA_KCFLAGS="-Werror"
1459 LB_CHECK_COMPILE([if 'd_in_lookup' is defined],
1460 d_in_lookup, [
1461         #include <linux/dcache.h>
1462 ],[
1463         d_in_lookup(NULL);
1464 ],[
1465         AC_DEFINE(HAVE_D_IN_LOOKUP, 1, [d_in_lookup is defined])
1466 ])
1467 EXTRA_KCFLAGS="$tmp_flags"
1468 ]) # LC_D_IN_LOOKUP
1469
1470 #
1471 # LC_LOCK_PAGE_MEMCG
1472 #
1473 # Kernel version 4.6 adds lock_page_memcg
1474 #
1475 AC_DEFUN([LC_LOCK_PAGE_MEMCG], [
1476 LB_CHECK_COMPILE([if 'lock_page_memcg' is defined],
1477 lock_page_memcg, [
1478         #include <linux/memcontrol.h>
1479 ],[
1480         lock_page_memcg(NULL);
1481 ],[
1482         AC_DEFINE(HAVE_LOCK_PAGE_MEMCG, 1,
1483                 [lock_page_memcg is defined])
1484 ])
1485 ]) # LC_LOCK_PAGE_MEMCG
1486
1487 #
1488 # LC_DIRECTIO_2ARGS
1489 #
1490 # Kernel version 4.7 commit c8b8e32d700fe943a935e435ae251364d016c497
1491 # direct-io: eliminate the offset argument to ->direct_IO
1492 #
1493 AC_DEFUN([LC_DIRECTIO_2ARGS], [
1494 LB_CHECK_COMPILE([if '->direct_IO()' taken 2 arguments],
1495 direct_io_2args, [
1496         #include <linux/fs.h>
1497 ],[
1498         struct address_space_operations ops = { };
1499         struct iov_iter *iter = NULL;
1500         struct kiocb *iocb = NULL;
1501         int rc;
1502
1503         rc = ops.direct_IO(iocb, iter);
1504 ],[
1505         AC_DEFINE(HAVE_DIRECTIO_2ARGS, 1,
1506                 [direct_IO need 2 arguments])
1507 ])
1508 ]) # LC_DIRECTIO_2ARGS
1509
1510 #
1511 # LC_GENERIC_WRITE_SYNC_2ARGS
1512 #
1513 # Kernel version 4.7 commit dde0c2e79848298cc25621ad080d47f94dbd7cce
1514 # fs: add IOCB_SYNC and IOCB_DSYNC
1515 #
1516 AC_DEFUN([LC_GENERIC_WRITE_SYNC_2ARGS], [
1517 LB_CHECK_COMPILE([if 'generic_write_sync()' taken 2 arguments],
1518 generic_write_sync_2args, [
1519         #include <linux/fs.h>
1520 ],[
1521         struct kiocb *iocb = NULL;
1522         ssize_t rc;
1523
1524         rc = generic_write_sync(iocb, 0);
1525 ],[
1526         AC_DEFINE(HAVE_GENERIC_WRITE_SYNC_2ARGS, 1,
1527                 [generic_write_sync need 2 arguments])
1528 ])
1529 ]) # LC_GENERIC_WRITE_SYNC_2ARGS
1530
1531 #
1532 # LC_FOP_ITERATE_SHARED
1533 #
1534 # Kernel v4.6-rc3-29-g6192269 adds iterate_shared method to file_operations
1535 #
1536 AC_DEFUN([LC_FOP_ITERATE_SHARED], [
1537 LB_CHECK_COMPILE([if 'file_operations' has 'iterate_shared'],
1538 fop_iterate_shared, [
1539         #include <linux/fs.h>
1540 ],[
1541         struct file_operations fop;
1542         fop.iterate_shared = NULL;
1543 ],[
1544         AC_DEFINE(HAVE_FOP_ITERATE_SHARED, 1,
1545                 [file_operations has iterate_shared])
1546 ])
1547 ]) # LC_FOP_ITERATE_SHARED
1548
1549 #
1550 # LC_EXPORT_DEFAULT_FILE_SPLICE_READ
1551 #
1552 # 4.8-rc8 commit 82c156f853840645604acd7c2cebcb75ed1b6652 switched
1553 # generic_file_splice_read() to using ->read_iter. We can test this
1554 # change since default_file_splice_read() is no longer exported.
1555 #
1556 AC_DEFUN([LC_EXPORT_DEFAULT_FILE_SPLICE_READ], [
1557 LB_CHECK_EXPORT([default_file_splice_read], [fs/splice.c],
1558         [AC_DEFINE(HAVE_DEFAULT_FILE_SPLICE_READ_EXPORT, 1,
1559                         [default_file_splice_read is exported])])
1560 ]) # LC_EXPORT_DEFAULT_FILE_SPLCE_READ
1561
1562 #
1563 # LC_HAVE_POSIX_ACL_VALID_USER_NS
1564 #
1565 # 4.8 posix_acl_valid takes struct user_namespace
1566 #
1567 AC_DEFUN([LC_HAVE_POSIX_ACL_VALID_USER_NS], [
1568 LB_CHECK_COMPILE([if 'posix_acl_valid' takes 'struct user_namespace'],
1569 posix_acl_valid, [
1570         #include <linux/fs.h>
1571         #include <linux/posix_acl.h>
1572 ],[
1573         posix_acl_valid((struct user_namespace*)NULL, (const struct posix_acl*)NULL);
1574 ],[
1575         AC_DEFINE(HAVE_POSIX_ACL_VALID_USER_NS, 1,
1576                 [posix_acl_valid takes struct user_namespace])
1577 ])
1578 ]) # LC_HAVE_POSIX_ACL_VALID_USER_NS
1579
1580 #
1581 # LC_D_COMPARE_4ARGS
1582 #
1583 # Kernel version 4.8 commit 6fa67e707559303e086303aeecc9e8b91ef497d5
1584 # get rid of 'parent' argument of ->d_compare()
1585 #
1586 AC_DEFUN([LC_D_COMPARE_4ARGS], [
1587 LB_CHECK_COMPILE([if 'd_compare' taken 4 arguments],
1588 d_compare_4args, [
1589         #include <linux/dcache.h>
1590 ],[
1591         ((struct dentry_operations*)0)->d_compare(NULL,0,NULL,NULL);
1592 ],[
1593         AC_DEFINE(HAVE_D_COMPARE_4ARGS, 1,
1594                 [d_compare need 4 arguments])
1595 ])
1596 ]) # LC_D_COMPARE_4ARGS
1597
1598 #
1599 # LC_FULL_NAME_HASH_3ARGS
1600 #
1601 # Kernel version 4.8 commit 8387ff2577eb9ed245df9a39947f66976c6bcd02
1602 # vfs: make the string hashes salt the hash
1603 #
1604 AC_DEFUN([LC_FULL_NAME_HASH_3ARGS], [
1605 LB_CHECK_COMPILE([if 'full_name_hash' taken 3 arguments],
1606 full_name_hash_3args, [
1607         #include <linux/stringhash.h>
1608 ],[
1609         unsigned int hash;
1610         hash = full_name_hash(NULL,NULL,0);
1611 ],[
1612         AC_DEFINE(HAVE_FULL_NAME_HASH_3ARGS, 1,
1613                 [full_name_hash need 3 arguments])
1614 ])
1615 ]) # LC_FULL_NAME_HASH_3ARGS
1616
1617 #
1618 # LC_STRUCT_POSIX_ACL_XATTR
1619 #
1620 # Kernel version 4.8 commit 2211d5ba5c6c4e972ba6dbc912b2897425ea6621
1621 # posix_acl: xattr representation cleanups
1622 #
1623 AC_DEFUN([LC_STRUCT_POSIX_ACL_XATTR], [
1624 LB_CHECK_COMPILE([if 'struct posix_acl_xattr_{header,entry}' defined],
1625 struct_posix_acl_xattr, [
1626         #include <linux/fs.h>
1627         #include <linux/posix_acl_xattr.h>
1628 ],[
1629         struct posix_acl_xattr_header *h = NULL;
1630         struct posix_acl_xattr_entry  *e;
1631         e = (void *)(h + 1);
1632 ],[
1633         AC_DEFINE(HAVE_STRUCT_POSIX_ACL_XATTR, 1,
1634                 [struct posix_acl_xattr_{header,entry} defined])
1635 ])
1636 ]) # LC_STRUCT_POSIX_ACL_XATTR
1637
1638 #
1639 # LC_IOP_XATTR
1640 #
1641 # Kernel version 4.8 commit fd50ecaddf8372a1d96e0daeaac0f93cf04e4d42
1642 # removed {get,set,remove}xattr inode operations
1643 #
1644 AC_DEFUN([LC_IOP_XATTR], [
1645 LB_CHECK_COMPILE([if 'inode_operations' has {get,set,remove}xattr members],
1646 inode_ops_xattr, [
1647         #include <linux/fs.h>
1648 ],[
1649         struct inode_operations iop;
1650         iop.setxattr = NULL;
1651         iop.getxattr = NULL;
1652         iop.removexattr = NULL;
1653 ],[
1654         AC_DEFINE(HAVE_IOP_XATTR, 1,
1655                 [inode_operations has {get,set,remove}xattr members])
1656 ])
1657 ]) # LC_IOP_XATTR
1658
1659 #
1660 # LC_GROUP_INFO_GID
1661 #
1662 # Kernel version 4.9 commit 81243eacfa400f5f7b89f4c2323d0de9982bb0fb
1663 # cred: simpler, 1D supplementary groups
1664 #
1665 AC_DEFUN([LC_GROUP_INFO_GID], [
1666 LB_CHECK_COMPILE([if 'struct group_info' has member 'gid'],
1667 group_info_gid, [
1668         #include <linux/cred.h>
1669 ],[
1670         kgid_t *p;
1671         p = ((struct group_info *)0)->gid;
1672 ],[
1673         AC_DEFINE(HAVE_GROUP_INFO_GID, 1,
1674                 [struct group_info has member gid])
1675 ])
1676 ]) # LC_GROUP_INFO_GID
1677
1678 #
1679 # LC_VFS_SETXATTR
1680 #
1681 # Kernel version 4.9 commit 5d6c31910bc0713e37628dc0ce677dcb13c8ccf4
1682 # added __vfs_{get,set,remove}xattr helpers
1683 #
1684 AC_DEFUN([LC_VFS_SETXATTR], [
1685 LB_CHECK_COMPILE([if '__vfs_setxattr' helper is available],
1686 vfs_setxattr, [
1687         #include <linux/xattr.h>
1688 ],[
1689         __vfs_setxattr(NULL, NULL, NULL, NULL, 0, 0);
1690 ],[
1691         AC_DEFINE(HAVE_VFS_SETXATTR, 1,
1692                 ['__vfs_setxattr is available])
1693 ])
1694 ]) # LC_VFS_SETXATTR
1695
1696 #
1697 # LC_POSIX_ACL_UPDATE_MODE
1698 #
1699 # Kernel version 4.9 commit 073931017b49d9458aa351605b43a7e34598caef
1700 # posix_acl: Clear SGID bit when setting file permissions
1701 #
1702 AC_DEFUN([LC_POSIX_ACL_UPDATE_MODE], [
1703 LB_CHECK_COMPILE([if 'posix_acl_update_mode' exists],
1704 posix_acl_update_mode, [
1705         #include <linux/fs.h>
1706         #include <linux/posix_acl.h>
1707 ],[
1708         posix_acl_update_mode(NULL, NULL, NULL);
1709 ],[
1710         AC_DEFINE(HAVE_POSIX_ACL_UPDATE_MODE, 1,
1711                 ['posix_acl_update_mode' is available])
1712 ])
1713 ]) # LC_POSIX_ACL_UPDATE_MODE
1714
1715 #
1716 # LC_IOP_GENERIC_READLINK
1717 #
1718 # Kernel version 4.10 commit dfeef68862edd7d4bafe68ef7aeb5f658ef24bb5
1719 # removed generic_readlink from individual file systems
1720 #
1721 AC_DEFUN([LC_IOP_GENERIC_READLINK], [
1722 LB_CHECK_COMPILE([if 'generic_readlink' still exist],
1723 inode_ops_readlink, [
1724         #include <linux/fs.h>
1725 ],[
1726         struct inode_operations iop;
1727         iop.readlink = generic_readlink;
1728 ],[
1729         AC_DEFINE(HAVE_IOP_GENERIC_READLINK, 1,
1730                 [generic_readlink has been removed])
1731 ])
1732 ]) # LC_IOP_GENERIC_READLINK
1733
1734 #
1735 # LC_HAVE_VM_FAULT_ADDRESS
1736 #
1737 # Kernel version 4.10 commit 1a29d85eb0f19b7d8271923d8917d7b4f5540b3e
1738 # removed virtual_address field. Need to use address field instead
1739 #
1740 AC_DEFUN([LC_HAVE_VM_FAULT_ADDRESS], [
1741 LB_CHECK_COMPILE([if 'struct vm_fault' replaced virtual_address with address field],
1742 vm_fault_address, [
1743         #include <linux/mm.h>
1744 ],[
1745         struct vm_fault vmf;
1746         vmf.address = NULL;
1747 ],[
1748         AC_DEFINE(HAVE_VM_FAULT_ADDRESS, 1,
1749                 [virtual_address has been replaced by address field])
1750 ])
1751 ]) # LC_HAVE_VM_FAULT_ADDRESS
1752
1753 #
1754 # LC_INODEOPS_ENHANCED_GETATTR
1755 #
1756 # Kernel version 4.11 commit a528d35e8bfcc521d7cb70aaf03e1bd296c8493f
1757 # expanded getattr to be able to get more stat information.
1758 #
1759 AC_DEFUN([LC_INODEOPS_ENHANCED_GETATTR], [
1760 LB_CHECK_COMPILE([if 'inode_operations' getattr member can gather advance stats],
1761 getattr_path, [
1762         #include <linux/fs.h>
1763 ],[
1764         struct path path;
1765
1766         ((struct inode_operations *)1)->getattr(&path, NULL, 0, 0);
1767 ],[
1768         AC_DEFINE(HAVE_INODEOPS_ENHANCED_GETATTR, 1,
1769                 [inode_operations .getattr member function can gather advance stats])
1770 ])
1771 ]) # LC_INODEOPS_ENHANCED_GETATTR
1772
1773 #
1774 # LC_VM_OPERATIONS_REMOVE_VMF_ARG
1775 #
1776 # Kernel version 4.11 commit 11bac80004499ea59f361ef2a5516c84b6eab675
1777 # removed struct vm_area_struct as an argument for vm_operations since
1778 # in the same kernel version struct vma_area_struct was folded into
1779 # struct vm_fault.
1780 #
1781 AC_DEFUN([LC_VM_OPERATIONS_REMOVE_VMF_ARG], [
1782 LB_CHECK_COMPILE([if 'struct vm_operations' removed struct vm_area_struct],
1783 vm_operations_no_vm_area_struct, [
1784         #include <linux/mm.h>
1785 ],[
1786         struct vm_fault vmf;
1787
1788         ((struct vm_operations_struct *)0)->fault(&vmf);
1789         ((struct vm_operations_struct *)0)->page_mkwrite(&vmf);
1790 ],[
1791         AC_DEFINE(HAVE_VM_OPS_USE_VM_FAULT_ONLY, 1,
1792                 ['struct vm_operations' remove struct vm_area_struct argument])
1793 ])
1794 ]) # LC_VM_OPERATIONS_REMOVE_VMF_ARG
1795
1796 #
1797 # LC_HAVE_KEY_USAGE_REFCOUNT
1798 #
1799 # Kernel version 4.11 commit fff292914d3a2f1efd05ca71c2ba72a3c663201e
1800 # converted key.usage from atomic_t to refcount_t.
1801 #
1802 AC_DEFUN([LC_HAVE_KEY_USAGE_REFCOUNT], [
1803 LB_CHECK_COMPILE([if 'key.usage' is refcount_t],
1804 key_usage_refcount, [
1805         #include <linux/key.h>
1806 ],[
1807         struct key key = { };
1808
1809         refcount_read(&key.usage);
1810 ],[
1811         AC_DEFINE(HAVE_KEY_USAGE_REFCOUNT, 1, [key.usage is of type refcount_t])
1812 ])
1813 ]) #LC_HAVE_KEY_USAGE_REFCOUNT
1814
1815 #
1816 # LC_HAVE_CRYPTO_MAX_ALG_NAME_128
1817 #
1818 # Kernel version 4.11 commit f437a3f477cce402dbec6537b29e9e33962c9f73
1819 # switched CRYPTO_MAX_ALG_NAME from 64 to 128.
1820 #
1821 AC_DEFUN([LC_HAVE_CRYPTO_MAX_ALG_NAME_128], [
1822 LB_CHECK_COMPILE([if 'CRYPTO_MAX_ALG_NAME' is 128],
1823 crypto_max_alg_name, [
1824         #include <linux/crypto.h>
1825 ],[
1826         #if CRYPTO_MAX_ALG_NAME != 128
1827         exit(1);
1828         #endif
1829 ],[
1830         AC_DEFINE(HAVE_CRYPTO_MAX_ALG_NAME_128, 1,
1831                 ['CRYPTO_MAX_ALG_NAME' is 128])
1832 ])
1833 ]) # LC_HAVE_CRYPTO_MAX_ALG_NAME_128
1834
1835 #
1836 # Kernel version 4.12 commit 47f38c539e9a42344ff5a664942075bd4df93876
1837 # CURRENT_TIME is not 64 bit time safe so it was replaced with
1838 # current_time()
1839 #
1840 AC_DEFUN([LC_CURRENT_TIME], [
1841 LB_CHECK_COMPILE([if CURRENT_TIME has been replaced with current_time],
1842 current_time, [
1843         #include <linux/fs.h>
1844 ],[
1845         struct iattr attr;
1846
1847         attr.ia_atime = current_time(NULL);
1848 ],[
1849         AC_DEFINE(HAVE_CURRENT_TIME, 1,
1850                 [current_time() has replaced CURRENT_TIME])
1851 ])
1852 ]) # LIBCFS_CURRENT_TIME
1853
1854 #
1855 # Kernel version 4.12-rc3 85787090a21eb749d8b347eaf9ff1a455637473c
1856 # changed struct super_block s_uuid into a proper uuid_t
1857 #
1858 AC_DEFUN([LC_SUPER_BLOCK_S_UUID], [
1859 LB_CHECK_COMPILE([if 'struct super_block' s_uuid is uuid_t],
1860 super_block_s_uuid, [
1861         #include <linux/fs.h>
1862 ],[
1863         struct super_block sb;
1864
1865         uuid_parse(NULL, &sb.s_uuid);
1866 ],[
1867         AC_DEFINE(HAVE_S_UUID_AS_UUID_T, 1, ['s_uuid' is an uuid_t])
1868 ])
1869 ]) # LC_SUPER_BLOCK_S_UUID
1870
1871 #
1872 # LC_SUPER_SETUP_BDI_NAME
1873 #
1874 # Kernel version 4.12 commit 9594caf216dc0fe3e318b34af0127276db661241
1875 # unified bdi handling
1876 #
1877 AC_DEFUN([LC_SUPER_SETUP_BDI_NAME], [
1878 LB_CHECK_COMPILE([if 'super_setup_bdi_name' exist],
1879 super_setup_bdi_name, [
1880         #include <linux/fs.h>
1881 ],[
1882         super_setup_bdi_name(NULL, "lustre");
1883 ],[
1884         AC_DEFINE(HAVE_SUPER_SETUP_BDI_NAME, 1,
1885                 ['super_setup_bdi_name' is available])
1886 ])
1887 ]) # LC_SUPER_SETUP_BDI_NAME
1888
1889 #
1890 # LC_BI_STATUS
1891 #
1892 # 4.12 replace bi_error to bi_status
1893 #
1894 AC_DEFUN([LC_BI_STATUS], [
1895 LB_CHECK_COMPILE([if 'bi_status' exist],
1896 bi_status, [
1897         #include <linux/blk_types.h>
1898 ],[
1899         ((struct bio *)0)->bi_status = 0;
1900 ],[
1901         AC_DEFINE(HAVE_BI_STATUS, 1,
1902                 ['bi_status' is available])
1903 ])
1904 ]) # LC_BI_STATUS
1905
1906 #
1907 # LC_BIO_INTEGRITY_ENABLED
1908 #
1909 # 4.13 removed bio_integrity_enabled
1910 #
1911 AC_DEFUN([LC_BIO_INTEGRITY_ENABLED], [
1912 LB_CHECK_COMPILE([if 'bio_integrity_enabled' exist],
1913 bio_integrity_enabled, [
1914         #include <linux/bio.h>
1915 ],[
1916         bio_integrity_enabled(NULL);
1917 ],[
1918         AC_DEFINE(HAVE_BIO_INTEGRITY_ENABLED, 1,
1919                 ['bio_integrity_enabled' is available])
1920 ])
1921 ]) # LC_BIO_INTEGRITY_ENABLED
1922
1923 #
1924 # LC_PAGEVEC_INIT_ONE_PARAM
1925 #
1926 # 4.14 pagevec_init takes one parameter
1927 #
1928 AC_DEFUN([LC_PAGEVEC_INIT_ONE_PARAM], [
1929 LB_CHECK_COMPILE([if 'pagevec_init' takes one parameter],
1930 pagevec_init, [
1931         #include <linux/pagevec.h>
1932 ],[
1933         pagevec_init(NULL);
1934 ],[
1935         AC_DEFINE(HAVE_PAGEVEC_INIT_ONE_PARAM, 1,
1936                 ['pagevec_init' takes one parameter])
1937 ])
1938 ]) # LC_PAGEVEC_INIT_ONE_PARAM
1939
1940 #
1941 # LC_BI_BDEV
1942 #
1943 # 4.14 replaced bi_bdev to bi_disk
1944 #
1945 AC_DEFUN([LC_BI_BDEV], [
1946 LB_CHECK_COMPILE([if 'bi_bdev' exist],
1947 bi_bdev, [
1948         #include <linux/bio.h>
1949 ],[
1950         ((struct bio *)0)->bi_bdev = NULL;
1951 ],[
1952         AC_DEFINE(HAVE_BI_BDEV, 1,
1953                 ['bi_bdev' is available])
1954 ])
1955 ]) # LC_BI_BDEV
1956
1957 #
1958 # LC_IS_ENCRYPTED
1959 #
1960 # 4.14 introduced IS_ENCRYPTED and S_ENCRYPTED
1961 #
1962 AC_DEFUN([LC_IS_ENCRYPTED], [
1963 LB_CHECK_COMPILE([if IS_ENCRYPTED is defined],
1964 is_encrypted, [
1965         #include <linux/fs.h>
1966 ],[
1967         IS_ENCRYPTED((struct inode *)0);
1968 ],[
1969         has_is_encrypted="yes"
1970 ])
1971 ]) # LC_IS_ENCRYPTED
1972
1973 #
1974 # LC_I_PAGES
1975 #
1976 # kernel 4.17 commit b93b016313b3ba8003c3b8bb71f569af91f19fc7
1977 #
1978 AC_DEFUN([LC_I_PAGES], [
1979 LB_CHECK_COMPILE([if struct address_space has i_pages],
1980 i_pages, [
1981         #include <linux/fs.h>
1982 ],[
1983         struct address_space mapping = {};
1984         void *i_pages;
1985
1986         i_pages = &mapping.i_pages;
1987 ],[
1988         AC_DEFINE(HAVE_I_PAGES, 1,
1989                 [struct address_space has i_pages])
1990 ])
1991 ]) # LC_I_PAGES
1992
1993 #
1994 # LC_VM_FAULT_T
1995 #
1996 # kernel 4.17 commit 3d3539018d2cbd12e5af4a132636ee7fd8d43ef0
1997 # mm: create the new vm_fault_t type
1998 #
1999 AC_DEFUN([LC_VM_FAULT_T], [
2000 LB_CHECK_COMPILE([if vm_fault_t type exists],
2001 vm_fault_t, [
2002         #include <linux/mm_types.h>
2003 ],[
2004         vm_fault_t x = VM_FAULT_SIGBUS;
2005         (void)x
2006 ],[
2007         AC_DEFINE(HAVE_VM_FAULT_T, 1,
2008                 [if vm_fault_t type exists])
2009 ])
2010 ]) # LC_VM_FAULT_T
2011
2012 #
2013 # LC_VM_FAULT_RETRY
2014 #
2015 # kernel 4.17 commit 3d3539018d2cbd12e5af4a132636ee7fd8d43ef0
2016 # mm: VM_FAULT_RETRY is defined in enum vm_fault_reason
2017 #
2018 AC_DEFUN([LC_VM_FAULT_RETRY], [
2019 LB_CHECK_COMPILE([if VM_FAULT_RETRY is defined],
2020 VM_FAULT_RETRY, [
2021         #include <linux/mm.h>
2022 ],[
2023         #ifndef VM_FAULT_RETRY
2024                 vm_fault_t x;
2025                 x = VM_FAULT_RETRY;
2026         #endif
2027 ],[
2028         AC_DEFINE(HAVE_VM_FAULT_RETRY, 1,
2029                 [if VM_FAULT_RETRY is defined])
2030 ])
2031 ]) # LC_VM_FAULT_RETRY
2032
2033 #
2034 # LC_INODE_TIMESPEC64
2035 #
2036 # kernel 4.17-rc7 commit 8efd6894ff089adeeac7cb9f32125b85d963d1bc
2037 # fs: add timespec64_truncate()
2038 # kernel 4.18 commit 95582b00838837fc07e042979320caf917ce3fe6
2039 # inode timestamps switched to timespec64
2040 # kernel 4.19-rc2 commit 976516404ff3fab2a8caa8bd6f5efc1437fed0b8
2041 # y2038: remove unused time interfaces
2042 # ...
2043 #  timespec_trunc
2044 # ...
2045 # When inode times are timespec64 stop using the deprecated
2046 # time interfaces.
2047 #
2048 # kernel v5.5-rc1-6-gba70609d5ec6 ba70609d5ec664a8f36ba1c857fcd97a478adf79
2049 # fs: Delete timespec64_trunc()
2050 #
2051 AC_DEFUN([LC_INODE_TIMESPEC64], [
2052 tmp_flags="$EXTRA_KCFLAGS"
2053 EXTRA_KCFLAGS="-Werror"
2054 LB_CHECK_COMPILE([if inode timestamps are struct timespec64],
2055 inode_timespec64, [
2056         #include <linux/fs.h>
2057 ],[
2058         struct inode *inode = NULL;
2059         struct timespec64 ts = {0, 1};
2060
2061         inode->i_atime = ts;
2062         (void)inode;
2063 ],[
2064         AC_DEFINE(HAVE_INODE_TIMESPEC64, 1,
2065                 [inode times are using timespec64])
2066 ])
2067 EXTRA_KCFLAGS="$tmp_flags"
2068 ]) # LC_INODE_TIMESPEC64
2069
2070 #
2071 # LC___XA_SET_MARK
2072 #
2073 # kernel 4.20 commit v4.19-rc5-248-g9b89a0355144
2074 # xarray: Add XArray marks - replaced radix_tree_tag_set
2075 #
2076 AC_DEFUN([LC___XA_SET_MARK], [
2077 tmp_flags="$EXTRA_KCFLAGS"
2078 EXTRA_KCFLAGS="-Werror"
2079 LB_CHECK_COMPILE([if '__xa_set_mark' exists],
2080 __xa_set_mark, [
2081         #include <linux/fs.h>
2082         #include <linux/radix-tree.h>
2083 ],[
2084         radix_tree_tag_set(NULL, 0, PAGECACHE_TAG_DIRTY);
2085 ],[
2086         AC_DEFINE(HAVE_RADIX_TREE_TAG_SET, 1,
2087                 [__xa_set_mark exists])
2088 ])
2089 EXTRA_KCFLAGS="$tmp_flags"
2090 ]) # LC___XA_SET_MARK
2091
2092 #
2093 # LC_UAPI_LINUX_MOUNT_H
2094 #
2095 # kernel 4.20 commit e262e32d6bde0f77fb0c95d977482fc872c51996
2096 # vfs: Suppress MS_* flag defs within the kernel ...
2097 #
2098 AC_DEFUN([LC_UAPI_LINUX_MOUNT_H], [
2099 tmp_flags="$EXTRA_KCFLAGS"
2100 EXTRA_KCFLAGS="-Werror"
2101 LB_CHECK_COMPILE([if MS_RDONLY was moved to uapi/linux/mount.h],
2102 uapi_linux_mount, [
2103         #include <uapi/linux/mount.h>
2104 ],[
2105         int x = MS_RDONLY;
2106         (void)x;
2107 ],[
2108         AC_DEFINE(HAVE_UAPI_LINUX_MOUNT_H, 1,
2109                 [if MS_RDONLY was moved to uapi/linux/mount.h])
2110 ])
2111 EXTRA_KCFLAGS="$tmp_flags"
2112 ]) # LC_UAPI_LINUX_MOUNT_H
2113
2114 #
2115 # LC_HAVE_SUNRPC_CACHE_HASH_LOCK_IS_A_SPINLOCK
2116 #
2117 # kernel 4.20 commit 1863d77f15da0addcd293a1719fa5d3ef8cde3ca
2118 # SUNRPC: Replace the cache_detail->hash_lock with a regular spinlock
2119 #
2120 # Now that the reader functions are all RCU protected, use a regular
2121 # spinlock rather than a reader/writer lock.
2122 #
2123 AC_DEFUN([LC_HAVE_SUNRPC_CACHE_HASH_LOCK_IS_A_SPINLOCK], [
2124 tmp_flags="$EXTRA_KCFLAGS"
2125 EXTRA_KCFLAGS="-Werror"
2126 LB_CHECK_COMPILE([if cache_detail->hash_lock is a spinlock],
2127 hash_lock_isa_spinlock_t, [
2128         #include <linux/sunrpc/cache.h>
2129 ],[
2130         spinlock_t *lock = &(((struct cache_detail *)0)->hash_lock);
2131         spin_lock(lock);
2132 ],[
2133         AC_DEFINE(HAVE_CACHE_HASH_SPINLOCK, 1,
2134                 [if cache_detail->hash_lock is a spinlock])
2135 ])
2136 EXTRA_KCFLAGS="$tmp_flags"
2137 ]) # LC_HAVE_SUNRPC_CACHE_HASH_LOCK_IS_A_SPINLOCK
2138
2139 #
2140 # LC_HAS_LINUX_SELINUX_ENABLED
2141 #
2142 # kernel 5.1 commit 3d252529480c68bfd6a6774652df7c8968b28e41
2143 # SELinux: Remove unused selinux_is_enabled
2144 #
2145 AC_DEFUN([LC_HAS_LINUX_SELINUX_ENABLED], [
2146 tmp_flags="$EXTRA_KCFLAGS"
2147 EXTRA_KCFLAGS="-Werror"
2148 LB_CHECK_COMPILE([if linux/selinux.h exists],
2149 selinux_is_enabled, [
2150         #include <linux/selinux.h>
2151 ],[
2152         bool has_selinux = selinux_is_enabled();
2153         (void)has_selinux;
2154 ],[
2155         AC_DEFINE(HAVE_LINUX_SELINUX_IS_ENABLED, 1,
2156                 [if linux/selinux.h exists])
2157 ])
2158 EXTRA_KCFLAGS="$tmp_flags"
2159 ]) # LC_HAS_LINUX_SELINUX_ENABLED
2160
2161 #
2162 # LB_HAVE_BVEC_ITER_ALL
2163 #
2164 # kernel 5.1 commit 6dc4f100c175dd0511ae8674786e7c9006cdfbfa
2165 # block: allow bio_for_each_segment_all() to iterate over multi-page bvec
2166 #
2167 AC_DEFUN([LB_HAVE_BVEC_ITER_ALL], [
2168 tmp_flags="$EXTRA_KCFLAGS"
2169 EXTRA_KCFLAGS="-Werror"
2170 LB_CHECK_COMPILE([if bvec_iter_all exists for multi-page bvec iternation],
2171 ext4fs_dirhash, [
2172         #include <linux/bvec.h>
2173 ],[
2174         struct bvec_iter_all iter;
2175         (void)iter;
2176 ],[
2177         AC_DEFINE(HAVE_BVEC_ITER_ALL, 1,
2178                 [if bvec_iter_all exists for multi-page bvec iternation])
2179 ])
2180 EXTRA_KCFLAGS="$tmp_flags"
2181 ]) # LB_HAVE_BVEC_ITER_ALL
2182
2183 #
2184 # LC_ACCOUNT_PAGE_DIRTIED
2185 #
2186 # After 5.2 kernel page dirtied is not exported
2187 #
2188 AC_DEFUN([LC_ACCOUNT_PAGE_DIRTIED], [
2189 LB_CHECK_EXPORT([account_page_dirtied], [mm/page-writeback.c],
2190         [AC_DEFINE(HAVE_ACCOUNT_PAGE_DIRTIED_EXPORT, 1,
2191                         [account_page_dirtied is exported])])
2192 ]) # LC_ACCOUNT_PAGE_DIRTIED
2193
2194 #
2195 # LC_KEYRING_SEARCH_4ARGS
2196 #
2197 # Kernel 5.2 commit dcf49dbc8077
2198 # keys: Add a 'recurse' flag for keyring searches
2199 #
2200 AC_DEFUN([LC_KEYRING_SEARCH_4ARGS], [
2201 LB_CHECK_COMPILE([if 'keyring_search' has 4 args],
2202 keyring_search_4args, [
2203         #include <linux/key.h>
2204 ],[
2205         key_ref_t keyring;
2206         keyring_search(keyring, NULL, NULL, false);
2207 ],[
2208         AC_DEFINE(HAVE_KEYRING_SEARCH_4ARGS, 1,
2209                 [keyring_search has 4 args])
2210 ])
2211 ]) # LC_KEYRING_SEARCH_4ARGS
2212
2213 #
2214 # LC_BIO_BI_PHYS_SEGMENTS
2215 #
2216 # kernel 5.3-rc1 commit 14ccb66b3f585b2bc21e7256c96090abed5a512c
2217 # block: remove the bi_phys_segments field in struct bio
2218 #
2219 AC_DEFUN([LC_BIO_BI_PHYS_SEGMENTS], [
2220 tmp_flags="$EXTRA_KCFLAGS"
2221 EXTRA_KCFLAGS="-Werror"
2222 LB_CHECK_COMPILE([if struct bio has bi_phys_segments member],
2223 bye_bio_bi_phys_segments, [
2224         #include <linux/bio.h>
2225 ],[
2226         struct bio *bio = NULL;
2227         bio->bi_phys_segments++;
2228 ],[
2229         AC_DEFINE(HAVE_BIO_BI_PHYS_SEGMENTS, 1,
2230                 [struct bio has bi_phys_segments member])
2231 ])
2232 EXTRA_KCFLAGS="$tmp_flags"
2233 ]) # LC_BIO_BI_PHYS_SEGMENTS
2234
2235 #
2236 # LC_LM_COMPARE_OWNER_EXISTS
2237 #
2238 # kernel 5.3-rc3 commit f85d93385e9fe6886a751f647f6812a89bf6bee3
2239 # locks: Cleanup lm_compare_owner and lm_owner_key
2240 # removed lm_compare_owner
2241 #
2242 AC_DEFUN([LC_LM_COMPARE_OWNER_EXISTS], [
2243 tmp_flags="$EXTRA_KCFLAGS"
2244 EXTRA_KCFLAGS="-Werror"
2245 LB_CHECK_COMPILE([if lock_manager_operations has lm_compare_owner],
2246 lock_manager_ops_lm_compare_owner, [
2247         #include <linux/fs.h>
2248 ],[
2249         struct lock_manager_operations lm_ops;
2250         lm_ops.lm_compare_owner = NULL;
2251 ],[
2252         AC_DEFINE(HAVE_LM_COMPARE_OWNER, 1,
2253                 [lock_manager_operations has lm_compare_owner])
2254 ])
2255 EXTRA_KCFLAGS="$tmp_flags"
2256 ]) # LC_LM_COMPARE_OWNER_EXISTS
2257
2258 AC_DEFUN([LC_PROG_LINUX_SRC], [])
2259 AC_DEFUN([LC_PROG_LINUX_RESULTS], [])
2260
2261 #
2262 # LC_FSCRYPT_SUPPORT
2263 #
2264 # 5.4 introduced fscrypt encryption policies v2
2265 #
2266 AC_DEFUN([LC_FSCRYPT_SUPPORT], [
2267 LB_CHECK_COMPILE([for fscrypt in-kernel support],
2268 fscrypt_support, [
2269         #define __FS_HAS_ENCRYPTION 0
2270         #include <linux/fscrypt.h>
2271 ],[
2272         fscrypt_ioctl_get_policy_ex(NULL, NULL);
2273 ],[
2274         dnl When Lustre supports file name encryption, restore "yes" value
2275         dnl for has_fscrypt_support and remove warning message.
2276         has_fscrypt_support="no"
2277         AC_MSG_WARN([
2278 This version of Lustre lacks file name encryption support,
2279 so it cannot make use of in-kernel fscrypt.
2280 Will use embedded llcrypt if possible.])
2281 ])
2282 ]) # LC_FSCRYPT_SUPPORT
2283
2284 #
2285 # LC_PROG_LINUX
2286 #
2287 # Lustre linux kernel checks
2288 #
2289 AC_DEFUN([LC_PROG_LINUX], [
2290         AC_MSG_NOTICE([Lustre kernel checks
2291 ==============================================================================])
2292
2293         LC_CONFIG_PINGER
2294         LC_CONFIG_CHECKSUM
2295         LC_CONFIG_FLOCK
2296         LC_CONFIG_HEALTH_CHECK_WRITE
2297         LC_CONFIG_LRU_RESIZE
2298         LC_CONFIG_FHANDLE
2299         LC_CONFIG_GSS
2300
2301         LC_GLIBC_SUPPORT_FHANDLES
2302         LC_GLIBC_SUPPORT_COPY_FILE_RANGE
2303         LC_OPENSSL_SSK
2304         LC_OPENSSL_GETSEPOL
2305
2306         # 3.10
2307         LC_HAVE_PROJECT_QUOTA
2308
2309         # 3.11
2310         LC_INVALIDATE_RANGE
2311         LC_HAVE_DIR_CONTEXT
2312         LC_D_COMPARE_5ARGS
2313         LC_HAVE_DCOUNT
2314         LC_HAVE_DENTRY_D_U_D_ALIAS
2315         LC_HAVE_DENTRY_D_CHILD
2316         LC_PID_NS_FOR_CHILDREN
2317
2318         # 3.12
2319         LC_OLDSIZE_TRUNCATE_PAGECACHE
2320         LC_PTR_ERR_OR_ZERO_MISSING
2321         LC_KIOCB_KI_LEFT
2322
2323         # 3.13
2324         LC_VFS_RENAME_5ARGS
2325         LC_VFS_UNLINK_3ARGS
2326         LC_HAVE_D_IS_POSITIVE
2327
2328         # 3.14
2329         LC_HAVE_BVEC_ITER
2330         LC_HAVE_TRUNCATE_IPAGES_FINAL
2331         LC_IOPS_RENAME_WITH_FLAGS
2332         LC_IOP_SET_ACL
2333
2334         # 3.15
2335         LC_VFS_RENAME_6ARGS
2336
2337         # 3.16
2338         LC_DIRECTIO_USE_ITER
2339         LC_HAVE_IOV_ITER_INIT_DIRECTION
2340         LC_HAVE_IOV_ITER_TRUNCATE
2341         LC_HAVE_FILE_OPERATIONS_READ_WRITE_ITER
2342
2343         # 3.17
2344         LC_HAVE_INTERVAL_BLK_INTEGRITY
2345         LC_KEY_MATCH_DATA
2346
2347         # 3.18
2348         LC_PERCPU_COUNTER_INIT
2349         LC_NFS_FILLDIR_USE_CTX
2350
2351         # 3.19
2352         LC_KIOCB_HAS_NBYTES
2353         LC_HAVE_DQUOT_QC_DQBLK
2354         LC_HAVE_AIO_COMPLETE
2355
2356         # 3.20
2357         LC_BACKING_DEV_INFO_REMOVAL
2358         LC_HAVE_BDI_CAP_MAP_COPY
2359
2360         # 4.1.0
2361         LC_IOV_ITER_RW
2362         LC_HAVE_SYNC_READ_WRITE
2363         LC_HAVE___BI_CNT
2364
2365         # 4.2
2366         LC_BIO_ENDIO_USES_ONE_ARG
2367         LC_SYMLINK_OPS_USE_NAMEIDATA
2368         LC_ACCOUNT_PAGE_DIRTIED_3ARGS
2369
2370         # 4.3
2371         LC_HAVE_INTERVAL_EXP_BLK_INTEGRITY
2372         LC_HAVE_BIP_ITER_BIO_INTEGRITY_PAYLOAD
2373         LC_HAVE_CACHE_HEAD_HLIST
2374         LC_HAVE_XATTR_HANDLER_SIMPLIFIED
2375
2376         # 4.4
2377         LC_HAVE_LOCKS_LOCK_FILE_WAIT
2378         LC_HAVE_KEY_PAYLOAD_DATA_ARRAY
2379         LC_HAVE_XATTR_HANDLER_NAME
2380         LC_HAVE_BI_OPF
2381         LC_HAVE_SUBMIT_BIO_2ARGS
2382         LC_HAVE_CLEAN_BDEV_ALIASES
2383
2384         # 4.5
2385         LC_HAVE_FILE_DENTRY
2386
2387         # 4.5
2388         LC_HAVE_INODE_LOCK
2389         LC_HAVE_IOP_GET_LINK
2390
2391         # 4.6
2392         LC_HAVE_IN_COMPAT_SYSCALL
2393         LC_HAVE_XATTR_HANDLER_INODE_PARAM
2394         LC_LOCK_PAGE_MEMCG
2395
2396         # 4.7
2397         LC_D_IN_LOOKUP
2398         LC_DIRECTIO_2ARGS
2399         LC_GENERIC_WRITE_SYNC_2ARGS
2400         LC_FOP_ITERATE_SHARED
2401
2402         # 4.8
2403         LC_EXPORT_DEFAULT_FILE_SPLICE_READ
2404         LC_HAVE_POSIX_ACL_VALID_USER_NS
2405         LC_D_COMPARE_4ARGS
2406         LC_FULL_NAME_HASH_3ARGS
2407         LC_STRUCT_POSIX_ACL_XATTR
2408         LC_IOP_XATTR
2409
2410         # 4.9
2411         LC_GROUP_INFO_GID
2412         LC_VFS_SETXATTR
2413         LC_POSIX_ACL_UPDATE_MODE
2414
2415         # 4.10
2416         LC_IOP_GENERIC_READLINK
2417         LC_HAVE_VM_FAULT_ADDRESS
2418
2419         # 4.11
2420         LC_INODEOPS_ENHANCED_GETATTR
2421         LC_VM_OPERATIONS_REMOVE_VMF_ARG
2422         LC_HAVE_KEY_USAGE_REFCOUNT
2423         LC_HAVE_CRYPTO_MAX_ALG_NAME_128
2424
2425         # 4.12
2426         LC_CURRENT_TIME
2427         LC_SUPER_BLOCK_S_UUID
2428         LC_SUPER_SETUP_BDI_NAME
2429         LC_BI_STATUS
2430
2431         # 4.13
2432         LC_BIO_INTEGRITY_ENABLED
2433
2434         # 4.14
2435         LC_PAGEVEC_INIT_ONE_PARAM
2436         LC_BI_BDEV
2437
2438         # 4.17
2439         LC_VM_FAULT_T
2440         LC_VM_FAULT_RETRY
2441         LC_I_PAGES
2442
2443         # 4.18
2444         LC_INODE_TIMESPEC64
2445
2446         # 4.20
2447         LC___XA_SET_MARK
2448         LC_UAPI_LINUX_MOUNT_H
2449         LC_HAVE_SUNRPC_CACHE_HASH_LOCK_IS_A_SPINLOCK
2450
2451         # 5.1
2452         LC_HAS_LINUX_SELINUX_ENABLED
2453         LB_HAVE_BVEC_ITER_ALL
2454
2455         # 5.2
2456         LC_ACCOUNT_PAGE_DIRTIED
2457         LC_KEYRING_SEARCH_4ARGS
2458
2459         # 5.3
2460         LC_BIO_BI_PHYS_SEGMENTS
2461         LC_LM_COMPARE_OWNER_EXISTS
2462
2463         # kernel patch to extend integrity interface
2464         LC_BIO_INTEGRITY_PREP_FN
2465
2466         #
2467         AS_IF([test "x$enable_server" != xno], [
2468                 LC_STACK_SIZE
2469                 LC_QUOTA_CONFIG
2470         ])
2471         LC_POSIX_ACL_CONFIG
2472 ]) # LC_PROG_LINUX
2473
2474 #
2475 # LC_CONFIG_CLIENT
2476 #
2477 # Check whether to build the client side of Lustre
2478 #
2479 AC_DEFUN([LC_CONFIG_CLIENT], [
2480 AC_MSG_CHECKING([whether to build Lustre client support])
2481 AC_ARG_ENABLE([client],
2482         AC_HELP_STRING([--disable-client],
2483                 [disable Lustre client support]),
2484         [], [enable_client="yes"])
2485 AC_MSG_RESULT([$enable_client])
2486 ]) # LC_CONFIG_CLIENT
2487
2488 #
2489 # --enable-mpitests
2490 #
2491 AC_DEFUN([LB_CONFIG_MPITESTS], [
2492 AC_ARG_ENABLE([mpitests],
2493         AC_HELP_STRING([--enable-mpitests=<yes|no|mpicc wrapper>],
2494                        [include mpi tests]), [
2495                 enable_mpitests="yes"
2496                 case $enableval in
2497                 yes)
2498                         MPICC_WRAPPER="mpicc"
2499                         MPI_BIN=$(eval which $MPICC_WRAPPER | xargs dirname)
2500                         ;;
2501                 no)
2502                         enable_mpitests="no"
2503                         MPI_BIN=""
2504                         ;;
2505                 *)
2506                         MPICC_WRAPPER=$enableval
2507                         MPI_BIN=$(eval echo $MPICC_WRAPPER | xargs dirname)
2508                         ;;
2509                 esac
2510         ], [
2511                 enable_mpitests="yes"
2512                 MPICC_WRAPPER="mpicc"
2513                 MPI_BIN=$(eval which $MPICC_WRAPPER | xargs dirname)
2514         ])
2515
2516         if test "x$enable_mpitests" != "xno"; then
2517                 oldcc=$CC
2518                 CC=$MPICC_WRAPPER
2519                 AC_CACHE_CHECK([whether mpitests can be built],
2520                 lb_cv_mpi_tests, [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2521                         #include <mpi.h>
2522                         int main(void) {
2523                                 int flag;
2524                                 MPI_Initialized(&flag);
2525                                 return 0;
2526                         }
2527                 ])], [lb_cv_mpi_tests="yes"], [lb_cv_mpi_tests="no"])
2528                 ])
2529                 enable_mpitests=$lb_cv_mpi_tests
2530                 CC=$oldcc
2531         fi
2532         AC_SUBST(MPI_BIN)
2533         AC_SUBST(MPICC_WRAPPER)
2534 ]) # LB_CONFIG_MPITESTS
2535
2536 #
2537 # LC_CONFIG_QUOTA
2538 #
2539 # whether to enable quota support global control
2540 #
2541 AC_DEFUN([LC_CONFIG_QUOTA], [
2542 AC_MSG_CHECKING([whether to enable quota support global control])
2543 AC_ARG_ENABLE([quota],
2544         AC_HELP_STRING([--enable-quota],
2545                 [enable quota support]),
2546         [], [enable_quota="yes"])
2547 AS_IF([test "x$enable_quota" = xyes],
2548         [AC_MSG_RESULT([yes])],
2549         [AC_MSG_RESULT([no])])
2550 ]) # LC_CONFIG_QUOTA
2551
2552 #
2553 # LC_QUOTA
2554 #
2555 AC_DEFUN([LC_QUOTA], [
2556 #check global
2557 LC_CONFIG_QUOTA
2558 #check for utils
2559 AS_IF([test "x$enable_quota" != xno -a "x$enable_utils" != xno], [
2560         AC_CHECK_HEADER([sys/quota.h],
2561                 [AC_DEFINE(HAVE_SYS_QUOTA_H, 1,
2562                         [Define to 1 if you have <sys/quota.h>.])],
2563                 [AC_MSG_ERROR([don't find <sys/quota.h> in your system])])
2564 ])
2565 ]) # LC_QUOTA
2566
2567 #
2568 # LC_OSD_ADDON
2569 #
2570 # configure support for optional OSD implementation
2571 #
2572 AC_DEFUN([LC_OSD_ADDON], [
2573 AC_MSG_CHECKING([whether to use OSD addon])
2574 AC_ARG_WITH([osd],
2575         AC_HELP_STRING([--with-osd=path],
2576                 [set path to optional osd]),
2577         [
2578         case "$with_osd" in
2579         no)
2580                 ENABLEOSDADDON=0
2581                 ;;
2582         *)
2583                 OSDADDON="$with_osd"
2584                 ENABLEOSDADDON=1
2585                 ;;
2586         esac
2587         ], [
2588                 ENABLEOSDADDON=0
2589         ])
2590 AS_IF([test $ENABLEOSDADDON -eq 0], [
2591         AC_MSG_RESULT([no])
2592         OSDADDON=""
2593 ], [
2594         OSDMODNAME=$(basename $OSDADDON)
2595         AS_IF([test -e $LUSTRE/$OSDMODNAME], [
2596                 AC_MSG_RESULT([can't link])
2597                 OSDADDON=""
2598         ], [ln -s $OSDADDON $LUSTRE/$OSDMODNAME], [
2599                 AC_MSG_RESULT([$OSDMODNAME])
2600                 OSDADDON="obj-m += $OSDMODNAME/"
2601         ], [
2602                 AC_MSG_RESULT([can't link])
2603                 OSDADDON=""
2604         ])
2605 ])
2606 AC_SUBST(OSDADDON)
2607 ]) # LC_OSD_ADDON
2608
2609 #
2610 # LC_CONFIG_CRYPTO
2611 #
2612 # Check whether to enable Lustre client crypto
2613 #
2614 AC_DEFUN([LC_CONFIG_CRYPTO], [
2615 AC_MSG_CHECKING([whether to enable Lustre client crypto])
2616 AC_ARG_ENABLE([crypto],
2617         AC_HELP_STRING([--enable-crypto],
2618                 [enable Lustre client crypto]),
2619         [], [enable_crypto="auto"])
2620 AS_IF([test "x$enable_crypto" != xno -a "x$enable_dist" = xno], [
2621         AC_MSG_RESULT(
2622         )
2623         LC_IS_ENCRYPTED
2624         LC_FSCRYPT_SUPPORT])
2625 AS_IF([test "x$has_fscrypt_support" = xyes], [
2626         AC_DEFINE(HAVE_LUSTRE_CRYPTO, 1, [Enable Lustre client crypto via in-kernel fscrypt])
2627         enable_crypto=yes],
2628         [AS_IF([test "x$has_is_encrypted" = xyes], [
2629               AC_DEFINE(HAVE_LUSTRE_CRYPTO, 1, [Enable Lustre client crypto via embedded llcrypt])
2630               AC_DEFINE(CONFIG_LL_ENCRYPTION, 1, [embedded llcrypt])
2631               enable_crypto=yes
2632               enable_llcrypt=yes], [
2633               AS_IF([test "x$enable_crypto" = xyes],
2634                     [AC_MSG_ERROR([Lustre client crypto cannot be enabled because of lack of encryption support in your kernel.])])
2635               AS_IF([test "x$enable_crypto" != xno -a "x$enable_dist" = xno],
2636                     [AC_MSG_WARN(Lustre client crypto cannot be enabled because of lack of encryption support in your kernel.)])
2637               enable_crypto=no])])
2638 AS_IF([test "x$enable_dist" != xno], [
2639         enable_crypto=yes
2640         enable_llcrypt=yes])
2641 AC_MSG_RESULT([$enable_crypto])
2642 ]) # LC_CONFIG_CRYPTO
2643
2644 #
2645 # LC_CONFIGURE
2646 #
2647 # other configure checks
2648 #
2649 AC_DEFUN([LC_CONFIGURE], [
2650 AC_MSG_NOTICE([Lustre core checks
2651 ==============================================================================])
2652
2653 AS_IF([test $target_cpu == "i686" -o $target_cpu == "x86_64"],
2654         [CFLAGS="$CFLAGS -Wall -Werror"])
2655
2656 # maximum MDS thread count
2657 LC_MDS_MAX_THREADS
2658
2659 # lustre/utils/gss/gss_util.c
2660 # lustre/utils/gss/gssd_proc.c
2661 # lustre/utils/gss/krb5_util.c
2662 # lustre/utils/llog_reader.c
2663 # lustre/utils/create_iam.c
2664 # lustre/utils/libiam.c
2665 AC_CHECK_HEADERS([netdb.h endian.h])
2666 AC_CHECK_FUNCS([gethostbyname])
2667
2668 # lustre/utils/llverfs.c lustre/utils/libmount_utils_ldiskfs.c
2669 AC_CHECK_HEADERS([ext2fs/ext2fs.h], [], [
2670         AS_IF([test "x$enable_utils" = xyes -a "x$enable_ldiskfs" = xyes], [
2671                 AC_MSG_ERROR([
2672 ext2fs.h not found. Please install e2fsprogs development package.
2673                 ])
2674         ])
2675 ])
2676
2677 # lustre/tests/statx_test.c
2678 AC_CHECK_FUNCS([statx])
2679
2680 # lustre/utils/lfs.c
2681 AS_IF([test "$enable_dist" = "no"], [
2682                 AC_CHECK_LIB([z], [crc32], [
2683                                  AC_CHECK_HEADER([zlib.h], [], [
2684                                                  AC_MSG_ERROR([zlib.h not found.])])
2685                                  ], [
2686                                  AC_MSG_ERROR([
2687                 zlib library not found. Please install zlib development package.])
2688                 ])
2689 ])
2690
2691 SELINUX=""
2692
2693 AC_CHECK_LIB([selinux], [is_selinux_enabled],
2694         [AC_CHECK_HEADERS([selinux/selinux.h],
2695                         [SELINUX="-lselinux"
2696                         AC_DEFINE([HAVE_SELINUX], 1,
2697                                 [support for selinux ])],
2698                         [AC_MSG_WARN([
2699
2700 No libselinux-devel package found, unable to build selinux enabled tools
2701 ])
2702 ])],
2703         [AC_MSG_WARN([
2704
2705 No selinux package found, unable to build selinux enabled tools
2706 ])
2707 ])
2708 AC_SUBST(SELINUX)
2709
2710 AC_CHECK_LIB([keyutils], [add_key])
2711
2712 # Super safe df
2713 AC_MSG_CHECKING([whether to report minimum OST free space])
2714 AC_ARG_ENABLE([mindf],
2715         AC_HELP_STRING([--enable-mindf],
2716                 [Make statfs report the minimum available space on any single OST instead of the sum of free space on all OSTs]),
2717         [], [enable_mindf="no"])
2718 AC_MSG_RESULT([$enable_mindf])
2719 AS_IF([test "$enable_mindf" = "yes"],
2720         [AC_DEFINE([MIN_DF], 1, [Report minimum OST free space])])
2721
2722 AC_MSG_CHECKING([whether to randomly failing memory alloc])
2723 AC_ARG_ENABLE([fail_alloc],
2724         AC_HELP_STRING([--disable-fail-alloc],
2725                 [disable randomly alloc failure]),
2726         [], [enable_fail_alloc="yes"])
2727 AC_MSG_RESULT([$enable_fail_alloc])
2728 AS_IF([test "x$enable_fail_alloc" != xno],
2729         [AC_DEFINE([RANDOM_FAIL_ALLOC], 1,
2730                 [enable randomly alloc failure])])
2731
2732 AC_MSG_CHECKING([whether to check invariants (expensive cpu-wise)])
2733 AC_ARG_ENABLE([invariants],
2734         AC_HELP_STRING([--enable-invariants],
2735                 [enable invariant checking (cpu intensive)]),
2736         [], [enable_invariants="no"])
2737 AC_MSG_RESULT([$enable_invariants])
2738 AS_IF([test "x$enable_invariants" = xyes],
2739         [AC_DEFINE([CONFIG_LUSTRE_DEBUG_EXPENSIVE_CHECK], 1,
2740                 [enable invariant checking])])
2741
2742 AC_MSG_CHECKING([whether to track references with lu_ref])
2743 AC_ARG_ENABLE([lu_ref],
2744         AC_HELP_STRING([--enable-lu_ref],
2745                 [enable lu_ref reference tracking code]),
2746         [], [enable_lu_ref="no"])
2747 AC_MSG_RESULT([$enable_lu_ref])
2748 AS_IF([test "x$enable_lu_ref" = xyes],
2749         [AC_DEFINE([USE_LU_REF], 1,
2750                 [enable lu_ref reference tracking code])])
2751
2752 AC_MSG_CHECKING([whether to enable page state tracking])
2753 AC_ARG_ENABLE([pgstate-track],
2754         AC_HELP_STRING([--enable-pgstate-track],
2755                 [enable page state tracking]),
2756         [], [enable_pgstat_track="no"])
2757 AC_MSG_RESULT([$enable_pgstat_track])
2758 AS_IF([test "x$enable_pgstat_track" = xyes],
2759         [AC_DEFINE([CONFIG_DEBUG_PAGESTATE_TRACKING], 1,
2760                 [enable page state tracking code])])
2761
2762 PKG_PROG_PKG_CONFIG
2763 AC_MSG_CHECKING([systemd unit file directory])
2764 AC_ARG_WITH([systemdsystemunitdir],
2765         [AS_HELP_STRING([--with-systemdsystemunitdir=DIR],
2766                 [Directory for systemd service files])],
2767         [], [with_systemdsystemunitdir=auto])
2768 AS_IF([test "x$with_systemdsystemunitdir" = "xyes" -o "x$with_systemdsystemunitdir" = "xauto"],
2769         [def_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
2770         AS_IF([test "x$def_systemdsystemunitdir" = "x"],
2771                 [AS_IF([test "x$with_systemdsystemunitdir" = "xyes"],
2772                 [AC_MSG_ERROR([systemd support requested but pkg-config unable to query systemd package])])
2773                 with_systemdsystemunitdir=no],
2774         [with_systemdsystemunitdir="$def_systemdsystemunitdir"])])
2775 AS_IF([test "x$with_systemdsystemunitdir" != "xno"],
2776         [AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])])
2777 AC_MSG_RESULT([$with_systemdsystemunitdir])
2778
2779 AC_MSG_CHECKING([bash-completion directory])
2780 AC_ARG_WITH([bash-completion-dir],
2781         AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
2782                 [Install the bash auto-completion script in this directory.]),
2783         [],
2784         [with_bash_completion_dir=yes])
2785 AS_IF([test "x$with_bash_completion_dir" = "xyes"], [
2786         BASH_COMPLETION_DIR="`pkg-config --variable=completionsdir bash-completion`"
2787         AS_IF([test "x$BASH_COMPLETION_DIR" = "x"], [
2788                 [BASH_COMPLETION_DIR="/usr/share/bash-completion/completions"]
2789         ])
2790 ], [
2791         BASH_COMPLETION_DIR="$with_bash_completion_dir"
2792 ])
2793 AC_SUBST([BASH_COMPLETION_DIR])
2794 AC_MSG_RESULT([$BASH_COMPLETION_DIR])
2795 ]) # LC_CONFIGURE
2796
2797 #
2798 # LC_CONDITIONALS
2799 #
2800 # AM_CONDITIONALS for lustre
2801 #
2802 AC_DEFUN([LC_CONDITIONALS], [
2803 AM_CONDITIONAL(MPITESTS, test x$enable_mpitests = xyes, Build MPI Tests)
2804 AM_CONDITIONAL(CLIENT, test x$enable_client = xyes)
2805 AM_CONDITIONAL(SERVER, test x$enable_server = xyes)
2806 AM_CONDITIONAL(SPLIT, test x$enable_split = xyes)
2807 AM_CONDITIONAL(EXT2FS_DEVEL, test x$ac_cv_header_ext2fs_ext2fs_h = xyes)
2808 AM_CONDITIONAL(GSS, test x$enable_gss = xyes)
2809 AM_CONDITIONAL(GSS_KEYRING, test x$enable_gss_keyring = xyes)
2810 AM_CONDITIONAL(GSS_PIPEFS, test x$enable_gss_pipefs = xyes)
2811 AM_CONDITIONAL(GSS_SSK, test x$enable_ssk = xyes)
2812 AM_CONDITIONAL(LIBPTHREAD, test x$enable_libpthread = xyes)
2813 AM_CONDITIONAL(HAVE_SYSTEMD, test "x$with_systemdsystemunitdir" != "xno")
2814 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, test "x$with_bash_completion_dir" != "xno")
2815 AM_CONDITIONAL(XATTR_HANDLER, test "x$lb_cv_compile_xattr_handler_flags" = xyes)
2816 AM_CONDITIONAL(SELINUX, test "$SELINUX" = "-lselinux")
2817 AM_CONDITIONAL(GETSEPOL, test x$enable_getsepol = xyes)
2818 AM_CONDITIONAL(LLCRYPT, test x$enable_llcrypt = xyes)
2819 AM_CONDITIONAL(LIBAIO, test x$enable_libaio = xyes)
2820 ]) # LC_CONDITIONALS
2821
2822 #
2823 # LC_CONFIG_FILES
2824 #
2825 # files that should be generated with AC_OUTPUT
2826 #
2827 AC_DEFUN([LC_CONFIG_FILES],
2828 [AC_CONFIG_FILES([
2829 lustre/Makefile
2830 lustre/autoMakefile
2831 lustre/autoconf/Makefile
2832 lustre/conf/Makefile
2833 lustre/conf/resource/Makefile
2834 lustre/contrib/Makefile
2835 lustre/doc/Makefile
2836 lustre/include/Makefile
2837 lustre/include/lustre/Makefile
2838 lustre/include/uapi/linux/lustre/Makefile
2839 lustre/kernel_patches/targets/4.18-rhel8.2.target
2840 lustre/kernel_patches/targets/4.18-rhel8.1.target
2841 lustre/kernel_patches/targets/4.18-rhel8.target
2842 lustre/kernel_patches/targets/3.10-rhel7.9.target
2843 lustre/kernel_patches/targets/3.10-rhel7.8.target
2844 lustre/kernel_patches/targets/3.10-rhel7.7.target
2845 lustre/kernel_patches/targets/3.10-rhel7.6.target
2846 lustre/kernel_patches/targets/3.10-rhel7.5.target
2847 lustre/kernel_patches/targets/4.14-rhel7.5.target
2848 lustre/kernel_patches/targets/4.14-rhel7.6.target
2849 lustre/kernel_patches/targets/4.12-sles12sp4.target
2850 lustre/kernel_patches/targets/4.12-sles12sp5.target
2851 lustre/kernel_patches/targets/4.12-sles15sp1.target
2852 lustre/kernel_patches/targets/3.x-fc18.target
2853 lustre/ldlm/Makefile
2854 lustre/fid/Makefile
2855 lustre/fid/autoMakefile
2856 lustre/llite/Makefile
2857 lustre/llite/autoMakefile
2858 lustre/lov/Makefile
2859 lustre/lov/autoMakefile
2860 lustre/mdc/Makefile
2861 lustre/mdc/autoMakefile
2862 lustre/lmv/Makefile
2863 lustre/lmv/autoMakefile
2864 lustre/lfsck/Makefile
2865 lustre/lfsck/autoMakefile
2866 lustre/mdt/Makefile
2867 lustre/mdt/autoMakefile
2868 lustre/mdd/Makefile
2869 lustre/mdd/autoMakefile
2870 lustre/fld/Makefile
2871 lustre/fld/autoMakefile
2872 lustre/obdclass/Makefile
2873 lustre/obdclass/autoMakefile
2874 lustre/obdecho/Makefile
2875 lustre/obdecho/autoMakefile
2876 lustre/ofd/Makefile
2877 lustre/ofd/autoMakefile
2878 lustre/osc/Makefile
2879 lustre/osc/autoMakefile
2880 lustre/ost/Makefile
2881 lustre/ost/autoMakefile
2882 lustre/osd-ldiskfs/Makefile
2883 lustre/osd-ldiskfs/autoMakefile
2884 lustre/osd-zfs/Makefile
2885 lustre/osd-zfs/autoMakefile
2886 lustre/mgc/Makefile
2887 lustre/mgc/autoMakefile
2888 lustre/mgs/Makefile
2889 lustre/mgs/autoMakefile
2890 lustre/target/Makefile
2891 lustre/ptlrpc/Makefile
2892 lustre/ptlrpc/autoMakefile
2893 lustre/ptlrpc/gss/Makefile
2894 lustre/ptlrpc/gss/autoMakefile
2895 lustre/quota/Makefile
2896 lustre/quota/autoMakefile
2897 lustre/scripts/Makefile
2898 lustre/scripts/systemd/Makefile
2899 lustre/tests/Makefile
2900 lustre/tests/mpi/Makefile
2901 lustre/tests/kernel/Makefile
2902 lustre/tests/kernel/autoMakefile
2903 lustre/utils/Makefile
2904 lustre/utils/gss/Makefile
2905 lustre/osp/Makefile
2906 lustre/osp/autoMakefile
2907 lustre/lod/Makefile
2908 lustre/lod/autoMakefile
2909 ])
2910 ]) # LC_CONFIG_FILES