lustre/autoconf/lustre-core.m4

   1 #
   2 # LC_CONFIG_SRCDIR
   3 #
   4 # Wrapper for AC_CONFIG_SUBDIR
   5 #
   6 AC_DEFUN([LC_CONFIG_SRCDIR], [
   7 AC_CONFIG_SRCDIR([lustre/obdclass/obdo.c])
   8 libcfs_is_module="yes"
   9 ldiskfs_is_ext4="yes"
  10 ])
  11
  12 #
  13 # LC_PATH_DEFAULTS
  14 #
  15 # lustre specific paths
  16 #
  17 AC_DEFUN([LC_PATH_DEFAULTS], [
  18 # ptlrpc kernel build requires this
  19 LUSTRE="$PWD/lustre"
  20 AC_SUBST(LUSTRE)
  21
  22 # mount.lustre
  23 rootsbindir='$(CROSS_PATH)/sbin'
  24 AC_SUBST(rootsbindir)
  25
  26 demodir='$(docdir)/demo'
  27 AC_SUBST(demodir)
  28
  29 pkgexampledir='${pkgdatadir}/examples'
  30 AC_SUBST(pkgexampledir)
  31 ]) # LC_PATH_DEFAULTS
  32
  33 #
  34 # LC_TARGET_SUPPORTED
  35 #
  36 # is the target os supported?
  37 #
  38 AC_DEFUN([LC_TARGET_SUPPORTED], [
  39 case $target_os in
  40         linux*)
  41 $1
  42                 ;;
  43         *)
  44 $2
  45                 ;;
  46 esac
  47 ]) # LC_TARGET_SUPPORTED
  48
  49 #
  50 # LC_CONFIG_OBD_BUFFER_SIZE
  51 #
  52 # the maximum buffer size of lctl ioctls
  53 #
  54 AC_DEFUN([LC_CONFIG_OBD_BUFFER_SIZE], [
  55 AC_MSG_CHECKING([for maximum OBD ioctl size])
  56 AC_ARG_WITH([obd-buffer-size],
  57         AC_HELP_STRING([--with-obd-buffer-size=[size]],
  58                 [set lctl ioctl maximum bytes (default=8192)]),
  59         [OBD_BUFFER_SIZE=$with_obd_buffer_size],
  60         [OBD_BUFFER_SIZE=8192])
  61 AC_MSG_RESULT([$OBD_BUFFER_SIZE bytes])
  62 AC_DEFINE_UNQUOTED(CONFIG_LUSTRE_OBD_MAX_IOCTL_BUFFER, $OBD_BUFFER_SIZE,
  63         [IOCTL Buffer Size])
  64 ]) # LC_CONFIG_OBD_BUFFER_SIZE
  65
  66 #
  67 # LC_GLIBC_SUPPORT_FHANDLES
  68 #
  69 AC_DEFUN([LC_GLIBC_SUPPORT_FHANDLES], [
  70 AC_CHECK_FUNCS([name_to_handle_at],
  71         [AC_DEFINE(HAVE_FHANDLE_GLIBC_SUPPORT, 1,
  72                 [file handle and related syscalls are supported])],
  73         [AC_MSG_WARN([file handle and related syscalls are not supported])])
  74 ]) # LC_GLIBC_SUPPORT_FHANDLES
  75
  76 #
  77 # LC_FUNC_DEV_SET_RDONLY
  78 #
  79 # check whether dev_set_rdonly is exported.  This is needed until we
  80 # have another mechanism to fence IO from the underlying device.
  81 #
  82 AC_DEFUN([LC_FUNC_DEV_SET_RDONLY], [
  83 LB_CHECK_EXPORT([dev_set_rdonly], [block/ll_rw_block.c block/blk-core.c],
  84         [AC_DEFINE(HAVE_DEV_SET_RDONLY, 1,
  85                 [kernel exports dev_set_rdonly])],
  86         [AC_MSG_WARN([kernel missing dev_set_rdonly patch for testing])])
  87 ]) # LC_FUNC_DEV_SET_RDONLY
  88
  89 #
  90 # LC_STACK_SIZE
  91 #
  92 # Ensure stack size big than 8k in Lustre server (all kernels)
  93 #
  94 AC_DEFUN([LC_STACK_SIZE], [
  95 LB_CHECK_COMPILE([if stack size big than 8k],
  96 stack_size_8k, [
  97         #include <linux/thread_info.h>
  98 ], [
  99         #if THREAD_SIZE < 8192
 100         #error "stack size < 8192"
 101         #endif
 102 ], [], [AC_MSG_ERROR([
 103
 104 Lustre requires that Linux is configured with at least a 8KB stack.
 105 ])])
 106 ]) # LC_STACK_SIZE
 107
 108 #
 109 # LC_MDS_MAX_THREADS
 110 #
 111 # Allow the user to set the MDS thread upper limit
 112 #
 113 AC_DEFUN([LC_MDS_MAX_THREADS], [
 114 AC_MSG_CHECKING([for maximum number of MDS threads])
 115 AC_ARG_WITH([mds_max_threads],
 116         AC_HELP_STRING([--with-mds-max-threads=count],
 117                 [maximum threads available on the MDS: (default=512)]),
 118         [AC_DEFINE_UNQUOTED(MDS_MAX_THREADS, $with_mds_max_threads,
 119                 [maximum number of MDS threads])])
 120 AC_MSG_RESULT([$with_mds_max_threads])
 121 ]) # LC_MDS_MAX_THREADS
 122
 123 #
 124 # LC_CONFIG_PINGER
 125 #
 126 # the pinger is temporary, until we have the recovery node in place
 127 #
 128 AC_DEFUN([LC_CONFIG_PINGER], [
 129 AC_MSG_CHECKING([whether to enable Lustre pinger support])
 130 AC_ARG_ENABLE([pinger],
 131         AC_HELP_STRING([--disable-pinger],
 132                 [disable recovery pinger support]),
 133         [], [enable_pinger="yes"])
 134 AC_MSG_RESULT([$enable_pinger])
 135 AS_IF([test "x$enable_pinger" != xno],
 136         [AC_DEFINE(ENABLE_PINGER, 1,[Use the Pinger])])
 137 ]) # LC_CONFIG_PINGER
 138
 139 #
 140 # LC_CONFIG_CHECKSUM
 141 #
 142 # do checksum of bulk data between client and OST
 143 #
 144 AC_DEFUN([LC_CONFIG_CHECKSUM], [
 145 AC_MSG_CHECKING([whether to enable data checksum support])
 146 AC_ARG_ENABLE([checksum],
 147         AC_HELP_STRING([--disable-checksum],
 148                 [disable data checksum support]),
 149         [], [enable_checksum="yes"])
 150 AC_MSG_RESULT([$enable_checksum])
 151 AS_IF([test "x$enable_checksum" != xno],
 152         [AC_DEFINE(ENABLE_CHECKSUM, 1, [do data checksums])])
 153 ]) # LC_CONFIG_CHECKSUM
 154
 155 #
 156 # LC_CONFIG_HEALTH_CHECK_WRITE
 157 #
 158 # Turn off the actual write to the disk
 159 #
 160 AC_DEFUN([LC_CONFIG_HEALTH_CHECK_WRITE], [
 161 AC_MSG_CHECKING([whether to enable a write with the health check])
 162 AC_ARG_ENABLE([health_write],
 163         AC_HELP_STRING([--enable-health_write],
 164                 [enable disk writes when doing health check]),
 165         [], [enable_health_write="no"])
 166 AC_MSG_RESULT([$enable_health_write])
 167 AS_IF([test "x$enable_health_write" != xno],
 168         [AC_DEFINE(USE_HEALTH_CHECK_WRITE, 1, [Write when Checking Health])])
 169 ]) # LC_CONFIG_HEALTH_CHECK_WRITE
 170
 171 #
 172 # LC_CONFIG_LRU_RESIZE
 173 #
 174 AC_DEFUN([LC_CONFIG_LRU_RESIZE], [
 175 AC_MSG_CHECKING([whether to enable lru self-adjusting])
 176 AC_ARG_ENABLE([lru_resize],
 177         AC_HELP_STRING([--enable-lru-resize],
 178                 [enable lru resize support]),
 179         [], [enable_lru_resize="yes"])
 180 AC_MSG_RESULT([$enable_lru_resize])
 181 AS_IF([test "x$enable_lru_resize" != xno],
 182         [AC_DEFINE(HAVE_LRU_RESIZE_SUPPORT, 1, [Enable lru resize support])])
 183 ]) # LC_CONFIG_LRU_RESIZE
 184
 185 #
 186 # LC_QUOTA_CONFIG
 187 #
 188 # Quota support. The kernel must support CONFIG_QUOTA.
 189 #
 190 AC_DEFUN([LC_QUOTA_CONFIG], [
 191 LB_CHECK_CONFIG_IM([QUOTA], [],
 192         [AC_MSG_ERROR([
 193
 194 Lustre quota requires that CONFIG_QUOTA is enabled in your kernel.
 195 ])])
 196 ]) # LC_QUOTA_CONFIG
 197
 198 #
 199 # LC_EXPORT_TRUNCATE_COMPLETE_PAGE
 200 #
 201 # truncate_complete_page() has never been exported from an upstream kernel
 202 # remove_from_page_cache() was exported between 2.6.35 and 2.6.38
 203 # delete_from_page_cache() is exported from 2.6.39
 204 #
 205 AC_DEFUN([LC_EXPORT_TRUNCATE_COMPLETE_PAGE], [
 206 LB_CHECK_EXPORT([truncate_complete_page], [mm/truncate.c],
 207         [AC_DEFINE(HAVE_TRUNCATE_COMPLETE_PAGE, 1,
 208                 [kernel export truncate_complete_page])])
 209 LB_CHECK_EXPORT([remove_from_page_cache], [mm/filemap.c],
 210         [AC_DEFINE(HAVE_REMOVE_FROM_PAGE_CACHE, 1,
 211                 [kernel export remove_from_page_cache])])
 212 LB_CHECK_EXPORT([delete_from_page_cache], [mm/filemap.c],
 213         [AC_DEFINE(HAVE_DELETE_FROM_PAGE_CACHE, 1,
 214                 [kernel export delete_from_page_cache])])
 215 ]) # LC_EXPORT_TRUNCATE_COMPLETE_PAGE
 216
 217 #
 218 # LC_CAPA_CRYPTO
 219 #
 220 AC_DEFUN([LC_CAPA_CRYPTO], [
 221 LB_CHECK_CONFIG_IM([CRYPTO], [],
 222         [AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO is enabled in your kernel.])])
 223 LB_CHECK_CONFIG_IM([CRYPTO_HMAC], [],
 224         [AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO_HMAC is enabled in your kernel.])])
 225 LB_CHECK_CONFIG_IM([CRYPTO_SHA1], [],
 226         [AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO_SHA1 is enabled in your kernel.])])
 227 ]) # LC_CAPA_CRYPTO
 228
 229 #
 230 # LC_CONFIG_RMTCLIENT
 231 #
 232 dnl FIXME
 233 dnl the AES symbol usually tied with arch, e.g. CRYPTO_AES_586
 234 dnl FIXME
 235 AC_DEFUN([LC_CONFIG_RMTCLIENT], [
 236 LB_CHECK_CONFIG_IM([CRYPTO_AES], [],
 237         [AC_MSG_WARN([
 238
 239 Lustre remote client require that CONFIG_CRYPTO_AES is enabled in your kernel.
 240 ])])
 241 ]) # LC_CONFIG_RMTCLIENT
 242
 243 #
 244 # LC_CONFIG_GSS_KEYRING
 245 #
 246 # default 'auto', tests for dependencies, if found, enables;
 247 # only called if gss is enabled
 248 #
 249 AC_DEFUN([LC_CONFIG_GSS_KEYRING], [
 250 AC_MSG_CHECKING([whether to enable gss keyring backend])
 251 AC_ARG_ENABLE([gss_keyring],
 252         [AC_HELP_STRING([--disable-gss-keyring],
 253                 [disable gss keyring backend])],
 254         [], [enable_gss_keyring="auto"])
 255 AC_MSG_RESULT([$enable_gss_keyring])
 256 AS_IF([test "x$enable_gss_keyring" != xno], [
 257         LB_CHECK_CONFIG_IM([KEYS], [], [
 258                 gss_keyring_conf_test="fail"
 259                 AC_MSG_WARN([
 260
 261 GSS keyring backend require that CONFIG_KEYS be enabled in your kernel.
 262 ])])
 263
 264         AC_CHECK_LIB([keyutils], [keyctl_search], [], [
 265                 gss_keyring_conf_test="fail"
 266                 AC_MSG_WARN([
 267
 268 libkeyutils is not found, which is required by gss keyring backend
 269 ])])
 270
 271         AS_IF([test "x$gss_keyring_conf_test" != xfail], [
 272                 AC_DEFINE([HAVE_GSS_KEYRING], [1],
 273                         [Define this if you enable gss keyring backend])
 274                 enable_gss_keyring="yes"
 275         ], [
 276                 AS_IF([test "x$enable_gss_keyring" = xyes], [
 277                         AC_MSG_ERROR([
 278
 279 Cannot enable gss_keyring. See above for details.
 280 ])
 281                 ], [
 282                         AC_MSG_WARN([
 283
 284 Cannot enable gss keyring. See above for details.
 285 ])
 286                 ])
 287         ])
 288 ])
 289 ]) # LC_CONFIG_GSS_KEYRING
 290
 291 #
 292 # LC_CONFIG_SUNRPC
 293 #
 294 AC_DEFUN([LC_CONFIG_SUNRPC], [
 295 LB_CHECK_CONFIG_IM([SUNRPC], [], [
 296         AS_IF([test "x$sunrpc_required" = xyes], [
 297                 AC_MSG_ERROR([
 298
 299 kernel SUNRPC support is required by using GSS.
 300 ])
 301         ])])
 302 ]) # LC_CONFIG_SUNRPC
 303
 304 #
 305 # LC_CONFIG_GSS (default 'auto' (tests for dependencies, if found, enables))
 306 #
 307 # Build gss and related tools of Lustre. Currently both kernel and user space
 308 # parts are depend on linux platform.
 309 #
 310 AC_DEFUN([LC_CONFIG_GSS], [
 311 AC_MSG_CHECKING([whether to enable gss/krb5 support])
 312 AC_ARG_ENABLE([gss],
 313         [AC_HELP_STRING([--enable-gss], [enable gss/krb5 support])],
 314         [], [enable_gss="auto"])
 315 AC_MSG_RESULT([$enable_gss])
 316
 317 AS_IF([test "x$enable_gss" != xno], [
 318         LC_CONFIG_GSS_KEYRING
 319         sunrpc_required=$enable_gss
 320         LC_CONFIG_SUNRPC
 321         sunrpc_required="no"
 322
 323         LB_CHECK_CONFIG_IM([CRYPTO_MD5], [],
 324                 [AC_MSG_WARN([kernel MD5 support is recommended by using GSS.])])
 325         LB_CHECK_CONFIG_IM([CRYPTO_SHA1], [],
 326                 [AC_MSG_WARN([kernel SHA1 support is recommended by using GSS.])])
 327         LB_CHECK_CONFIG_IM([CRYPTO_SHA256], [],
 328                 [AC_MSG_WARN([kernel SHA256 support is recommended by using GSS.])])
 329         LB_CHECK_CONFIG_IM([CRYPTO_SHA512], [],
 330                 [AC_MSG_WARN([kernel SHA512 support is recommended by using GSS.])])
 331
 332         require_krb5=$enable_gss
 333         AC_KERBEROS_V5
 334         require_krb5="no"
 335
 336         AS_IF([test -n "$KRBDIR"], [
 337                 AC_CHECK_LIB([gssapi], [gss_export_lucid_sec_context], [
 338                         GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssapi"
 339                         gss_conf_test="success"
 340                 ], [
 341                         AC_CHECK_LIB([gssglue], [gss_export_lucid_sec_context], [
 342                                 GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssglue"
 343                                 gss_conf_test="success"
 344                         ], [
 345                                 AS_IF([test "x$enable_gss" = xyes], [
 346                                         AC_MSG_ERROR([
 347
 348 libgssapi or libgssglue is not found, which is required by GSS.
 349 ])
 350                                 ], [
 351                                         AC_MSG_WARN([
 352
 353 libgssapi or libgssglue is not found, which is required by GSS.
 354 ])
 355                                 ])
 356                         ])
 357                 ])
 358                 AC_SUBST(GSSAPI_LIBS)
 359         ])
 360
 361         AS_IF([test "x$gss_conf_test" = xsuccess], [
 362                 AC_DEFINE([HAVE_GSS], [1], [Define this is if you enable gss])
 363                 enable_gss="yes"
 364         ])
 365 ])
 366 ]) # LC_CONFIG_GSS
 367
 368 #
 369 # LC_INODE_PERMISION_2ARGS
 370 #
 371 # up to v2.6.27 had a 3 arg version (inode, mask, nameidata)
 372 # v2.6.27->v2.6.37 had a 2 arg version (inode, mask)
 373 # v2.6.37->v3.0 had a 3 arg version (inode, mask, nameidata)
 374 # v3.1 onward have a 2 arg version (inode, mask)
 375 #
 376 AC_DEFUN([LC_INODE_PERMISION_2ARGS], [
 377 LB_CHECK_COMPILE([if 'inode_operations->permission' has two args],
 378 inode_ops_permission_2args, [
 379         #include <linux/fs.h>
 380 ],[
 381         struct inode *inode __attribute__ ((unused));
 382
 383         inode = NULL;
 384         inode->i_op->permission(NULL, 0);
 385 ],[
 386         AC_DEFINE(HAVE_INODE_PERMISION_2ARGS, 1,
 387                 [inode_operations->permission has two args])
 388 ])
 389 ]) # LC_INODE_PERMISION_2ARGS
 390
 391 #
 392 # LC_BLK_QUEUE_MAX_SEGMENTS
 393 #
 394 # 2.6.32 replaces 2 functions blk_queue_max_phys_segments and blk_queue_max_hw_segments by blk_queue_max_segments
 395 #
 396 AC_DEFUN([LC_BLK_QUEUE_MAX_SEGMENTS], [
 397 LB_CHECK_COMPILE([if 'blk_queue_max_segments' is defined],
 398 blk_queue_max_segments, [
 399         #include <linux/blkdev.h>
 400 ],[
 401         blk_queue_max_segments(NULL, 0);
 402 ],[
 403         AC_DEFINE(HAVE_BLK_QUEUE_MAX_SEGMENTS, 1,
 404                 [blk_queue_max_segments is defined])
 405 ])
 406 ]) # LC_BLK_QUEUE_MAX_SEGMENTS
 407
 408 #
 409 # LC_HAVE_DQUOT_FS_DISK_QUOTA
 410 #
 411 # 2.6.34 has quotactl_ops->[sg]et_dqblk that take struct fs_disk_quota
 412 #
 413 AC_DEFUN([LC_HAVE_DQUOT_FS_DISK_QUOTA], [
 414 tmp_flags="$EXTRA_KCFLAGS"
 415 EXTRA_KCFLAGS="-Werror"
 416 LB_CHECK_COMPILE([if 'quotactl_ops.set_dqblk' takes struct fs_disk_quota],
 417 fs_disk_quota, [
 418         #include <linux/fs.h>
 419         #include <linux/quota.h>
 420 ],[
 421         ((struct quotactl_ops *)0)->set_dqblk(NULL, 0, 0, (struct fs_disk_quota*)0);
 422 ],[
 423         AC_DEFINE(HAVE_DQUOT_FS_DISK_QUOTA, 1,
 424                 [quotactl_ops.set_dqblk takes struct fs_disk_quota])
 425 ],[
 426         LB_CHECK_COMPILE([if 'quotactl_ops.set_dqblk' takes struct kqid & fs_disk_quota],
 427         kqid_fs_disk_quota, [
 428                 #include <linux/fs.h>
 429                 #include <linux/quota.h>
 430         ],[
 431                 ((struct quotactl_ops *)0)->set_dqblk((struct super_block*)0, *((struct kqid*)0), (struct fs_disk_quota*)0);
 432         ],[
 433                 AC_DEFINE(HAVE_DQUOT_FS_DISK_QUOTA, 1,
 434                         [quotactl_ops.set_dqblk takes struct fs_disk_quota])
 435                 AC_DEFINE(HAVE_DQUOT_KQID, 1,
 436                         [quotactl_ops.set_dqblk takes struct kqid])
 437         ])
 438 ])
 439 EXTRA_KCFLAGS="$tmp_flags"
 440 ]) # LC_HAVE_DQUOT_FS_DISK_QUOTA
 441
 442 #
 443 # LC_HAVE_DQUOT_SUSPEND
 444 #
 445 # 2.6.34 has renamed dquot options to dquot_*, check for dquot_suspend
 446 #
 447 AC_DEFUN([LC_HAVE_DQUOT_SUSPEND], [
 448 LB_CHECK_COMPILE([if 'dquot_suspend' is defined],
 449 dquot_suspend, [
 450         #include <linux/quotaops.h>
 451 ],[
 452         dquot_suspend(NULL, -1);
 453 ],[
 454         AC_DEFINE(HAVE_DQUOT_SUSPEND, 1, [dquot_suspend is defined])
 455 ])
 456 ]) # LC_HAVE_DQUOT_SUSPEND
 457
 458 #
 459 # LC_QUOTA64
 460 #
 461 # Check if kernel has been patched for 64-bit quota limits support.
 462 # The upstream version of this patch in RHEL6 2.6.32 kernels introduces
 463 # the constant QFMT_VFS_V1 in include/linux/quota.h, so we can check for
 464 # that in the absence of quotaio_v1.h in the kernel headers.
 465 #
 466 AC_DEFUN([LC_QUOTA64], [
 467 tmp_flags="$EXTRA_KCFLAGS"
 468 EXTRA_KCFLAGS="-I$LINUX/fs"
 469 LB_CHECK_COMPILE([if kernel has 64-bit quota limits support],
 470 quota64, [
 471         #include <linux/kernel.h>
 472         #include <linux/fs.h>
 473         #if defined(HAVE_FS_QUOTA_QUOTAIO_H)
 474         #include <quota/quotaio_v2.h>
 475         struct v2r1_disk_dqblk dqblk_r1;
 476         #else
 477         #include <linux/quota.h>
 478         int ver = QFMT_VFS_V1;
 479         #endif
 480 ], [], [
 481         AC_DEFINE(HAVE_QUOTA64, 1, [have quota64])
 482 ],[
 483         LB_CHECK_FILE([$LINUX/include/linux/lustre_version.h],
 484                 [AC_MSG_ERROR([You have got no 64-bit kernel quota support.])])
 485 ])
 486 EXTRA_KCFLAGS=$tmp_flags
 487 ]) # LC_QUOTA64
 488
 489 #
 490 # LC_HAVE_ADD_WAIT_QUEUE_EXCLUSIVE
 491 #
 492 # 2.6.34 adds __add_wait_queue_exclusive
 493 #
 494 AC_DEFUN([LC_HAVE_ADD_WAIT_QUEUE_EXCLUSIVE], [
 495 LB_CHECK_COMPILE([if '__add_wait_queue_exclusive' exists],
 496 __add_wait_queue_exclusive, [
 497         #include <linux/wait.h>
 498 ],[
 499         wait_queue_head_t queue;
 500         wait_queue_t      wait;
 501         __add_wait_queue_exclusive(&queue, &wait);
 502 ],[
 503         AC_DEFINE(HAVE___ADD_WAIT_QUEUE_EXCLUSIVE, 1,
 504                   [__add_wait_queue_exclusive exists])
 505 ])
 506 ]) # LC_HAVE_ADD_WAIT_QUEUE_EXCLUSIVE
 507
 508 #
 509 # LC_FS_STRUCT_RWLOCK
 510 #
 511 # 2.6.36 fs_struct.lock use spinlock instead of rwlock.
 512 #
 513 AC_DEFUN([LC_FS_STRUCT_RWLOCK], [
 514 LB_CHECK_COMPILE([if 'fs_struct.lock' use rwlock],
 515 fs_struct_rwlock, [
 516         #include <asm/atomic.h>
 517         #include <linux/spinlock.h>
 518         #include <linux/fs_struct.h>
 519 ],[
 520         ((struct fs_struct *)0)->lock = (rwlock_t){ 0 };
 521 ],[
 522         AC_DEFINE(HAVE_FS_STRUCT_RWLOCK, 1, [fs_struct.lock use rwlock])
 523 ])
 524 ]) # LC_FS_STRUCT_RWLOCK
 525
 526 #
 527 # LC_SBOPS_EVICT_INODE
 528 #
 529 # 2.6.36 super_operations add evict_inode method. it hybird of
 530 # delete_inode & clear_inode.
 531 #
 532 AC_DEFUN([LC_SBOPS_EVICT_INODE], [
 533 LB_CHECK_COMPILE([if 'super_operations.evict_inode' exist],
 534 super_ops_evict_inode, [
 535         #include <linux/fs.h>
 536 ],[
 537         ((struct super_operations *)0)->evict_inode(NULL);
 538 ],[
 539         AC_DEFINE(HAVE_SBOPS_EVICT_INODE, 1,
 540                 [super_operations.evict_inode() is exist in kernel])
 541 ])
 542 ]) # LC_SBOPS_EVICT_INODE
 543
 544 #
 545 # LC_FILE_FSYNC
 546 #
 547 # 2.6.35 file_operations.fsync taken 2 arguments.
 548 # 3.0.0 file_operations.fsync takes 4 arguments.
 549 #
 550 AC_DEFUN([LC_FILE_FSYNC], [
 551 LB_CHECK_COMPILE([if 'file_operations.fsync' takes 4 arguments],
 552 file_ops_fsync_4args, [
 553         #include <linux/fs.h>
 554 ],[
 555         ((struct file_operations *)0)->fsync(NULL, 0, 0, 0);
 556 ],[
 557         AC_DEFINE(HAVE_FILE_FSYNC_4ARGS, 1,
 558                 [file_operations.fsync takes 4 arguments])
 559 ],[
 560         LB_CHECK_COMPILE([if 'file_operations.fsync' takes 2 arguments],
 561         file_ops_fsync_2args, [
 562                 #include <linux/fs.h>
 563         ],[
 564                 ((struct file_operations *)0)->fsync(NULL, 0);
 565         ],[
 566                 AC_DEFINE(HAVE_FILE_FSYNC_2ARGS, 1,
 567                         [file_operations.fsync takes 2 arguments])
 568         ])
 569 ])
 570 ]) # LC_FILE_FSYNC
 571
 572 #
 573 # LC_KERNEL_LOCKED
 574 #
 575 # 2.6.37 remove kernel_locked
 576 #
 577 AC_DEFUN([LC_KERNEL_LOCKED], [
 578 LB_CHECK_COMPILE([if 'kernel_locked' is defined],
 579 kernel_locked, [
 580         #include <linux/smp_lock.h>
 581 ],[
 582         kernel_locked();
 583 ],[
 584         AC_DEFINE(HAVE_KERNEL_LOCKED, 1, [kernel_locked is defined])
 585 ])
 586 ]) # LC_KERNEL_LOCKED
 587
 588 #
 589 # LC_D_COMPARE_7ARGS
 590 #
 591 # 2.6.38 dentry_operations.d_compare() taken 7 arguments.
 592 #
 593 AC_DEFUN([LC_D_COMPARE_7ARGS], [
 594 LB_CHECK_COMPILE([if 'dentry_operations.d_compare()' taken 7 arguments],
 595 dentry_ops_d_compare_7arg, [
 596         #include <linux/dcache.h>
 597 ],[
 598         ((struct dentry_operations*)0)->d_compare(NULL,NULL,NULL,NULL,0,NULL,NULL);
 599 ],[
 600         AC_DEFINE(HAVE_D_COMPARE_7ARGS, 1, [d_compare need 7 arguments])
 601 ])
 602 ]) # LC_D_COMPARE_7ARGS
 603
 604 #
 605 # LC_D_DELETE_CONST
 606 #
 607 # 2.6.38 dentry_operations.d_delete() defined 'const' for 1st parameter.
 608 #
 609 AC_DEFUN([LC_D_DELETE_CONST], [
 610 tmp_flags="$EXTRA_KCFLAGS"
 611 EXTRA_KCFLAGS="-Werror"
 612 LB_CHECK_COMPILE([if 'dentry_operations.d_delete()' has const declare on first parameter],
 613 dentry_ops_d_delete_1st_const, [
 614         #include <linux/dcache.h>
 615 ],[
 616         const struct dentry *d = NULL;
 617         ((struct dentry_operations*)0)->d_delete(d);
 618 ],[
 619         AC_DEFINE(HAVE_D_DELETE_CONST, const,
 620                 [d_delete first parameter declared const])
 621 ],[
 622         AC_DEFINE(HAVE_D_DELETE_CONST, [],
 623                 [d_delete first parameter declared is not const])
 624 ])
 625 EXTRA_KCFLAGS="$tmp_flags"
 626 ]) # LC_D_DELETE_CONST
 627
 628 #
 629 # LC_DCACHE_LOCK
 630 #
 631 # 2.6.38 dcache_lock removed. rcu-walk commited.
 632 #
 633 AC_DEFUN([LC_DCACHE_LOCK], [
 634 LB_CHECK_COMPILE([if 'dcache_lock' is exist],
 635 dcache_lock, [
 636         #include <linux/dcache.h>
 637 ],[
 638         spin_lock(&dcache_lock);
 639 ],[
 640         AC_DEFINE(HAVE_DCACHE_LOCK, 1,
 641                 [dcache_lock is exist])
 642 ])
 643 ]) # LC_DCACHE_LOCK
 644
 645 #
 646 # LC_INODE_I_RCU
 647 #
 648 # 2.6.38 inode.i_rcu added.
 649 #
 650 AC_DEFUN([LC_INODE_I_RCU], [
 651 LB_CHECK_COMPILE([if 'inode.i_rcu' exists],
 652 inode_i_rcu, [
 653         #include <linux/fs.h>
 654 ],[
 655         struct inode ino;
 656         struct rcu_head rcu = {};
 657         ino.i_rcu = rcu;
 658 ],[
 659         AC_DEFINE(HAVE_INODE_I_RCU, 1,
 660                 [inode.i_rcu exists])
 661 ])
 662 ]) # LC_INODE_I_RCU
 663
 664 #
 665 # LC_BLKDEV_GET_BY_DEV
 666 #
 667 # 2.6.38 export blkdev_get_by_dev
 668 #
 669 AC_DEFUN([LC_BLKDEV_GET_BY_DEV], [
 670 LB_CHECK_EXPORT([blkdev_get_by_dev], [fs/block_dev.c],
 671         [AC_DEFINE(HAVE_BLKDEV_GET_BY_DEV, 1,
 672                 [blkdev_get_by_dev is exported by the kernel])])
 673 ]) # LC_BLKDEV_GET_BY_DEV
 674
 675 #
 676 # LC_EXPORT_SIMPLE_SETATTR
 677 #
 678 # 2.6.38 export simple_setattr
 679 #
 680 AC_DEFUN([LC_EXPORT_SIMPLE_SETATTR], [
 681 LB_CHECK_EXPORT([simple_setattr], [fs/libfs.c],
 682         [AC_DEFINE(HAVE_SIMPLE_SETATTR, 1,
 683                 [simple_setattr is exported by the kernel])])
 684 ]) # LC_EXPORT_SIMPLE_SETATTR
 685
 686 #
 687 # LC_IOP_TRUNCATE
 688 #
 689 # truncate callback removed since 2.6.39
 690 #
 691 AC_DEFUN([LC_IOP_TRUNCATE], [
 692 LB_CHECK_COMPILE([if 'inode_operations' has '.truncate' member function],
 693 inode_ops_truncate, [
 694         #include <linux/fs.h>
 695 ],[
 696         ((struct inode_operations *)0)->truncate(NULL);
 697 ],[
 698         AC_DEFINE(HAVE_INODEOPS_TRUNCATE, 1,
 699                 [inode_operations has .truncate member function])
 700 ])
 701 ]) # LC_IOP_TRUNCATE
 702
 703 #
 704 # LC_REQUEST_QUEUE_UNPLUG_FN
 705 #
 706 # 2.6.39 remove unplug_fn from request_queue.
 707 #
 708 AC_DEFUN([LC_REQUEST_QUEUE_UNPLUG_FN], [
 709 LB_CHECK_COMPILE([if 'request_queue' has 'unplug_fn' field],
 710 request_queue_unplug_fn, [
 711         #include <linux/blkdev.h>
 712 ],[
 713         do {} while(sizeof(((struct request_queue *)0)->unplug_fn));
 714 ],[
 715         AC_DEFINE(HAVE_REQUEST_QUEUE_UNPLUG_FN, 1,
 716                 [request_queue has unplug_fn field])
 717 ])
 718 ]) # LC_REQUEST_QUEUE_UNPLUG_FN
 719
 720 #
 721 # LC_HAVE_FSTYPE_MOUNT
 722 #
 723 # 2.6.39 replace get_sb with mount in struct file_system_type
 724 #
 725 AC_DEFUN([LC_HAVE_FSTYPE_MOUNT], [
 726 LB_CHECK_COMPILE([if 'file_system_type' has 'mount' field],
 727 file_system_type_mount, [
 728         #include <linux/fs.h>
 729 ],[
 730         struct file_system_type fst;
 731         void *i = (void *) fst.mount;
 732 ],[
 733         AC_DEFINE(HAVE_FSTYPE_MOUNT, 1,
 734                 [struct file_system_type has mount field])
 735 ])
 736 ]) # LC_HAVE_FSTYPE_MOUNT
 737
 738 #
 739 # LC_HAVE_FHANDLE_SYSCALLS
 740 #
 741 # 2.6.39 The open_by_handle_at() and name_to_handle_at() system calls were
 742 # added to Linux kernel 2.6.39.
 743 # Check if client supports these functions
 744 #
 745 AC_DEFUN([LC_HAVE_FHANDLE_SYSCALLS], [
 746 LB_CHECK_CONFIG_IM([FHANDLE],[
 747         AC_DEFINE(HAVE_FHANDLE_SYSCALLS, 1,
 748                 [kernel supports fhandles and related syscalls])
 749         ])
 750 ]) # LC_HAVE_FHANDLE_SYSCALLS
 751
 752 #
 753 # LC_HAVE_INODE_OWNER_OR_CAPABLE
 754 #
 755 # 2.6.39 renames is_owner_or_cap to inode_owner_or_capable
 756 #
 757 AC_DEFUN([LC_HAVE_INODE_OWNER_OR_CAPABLE], [
 758 LB_CHECK_COMPILE([if 'inode_owner_or_capable' exist],
 759 inode_owner_or_capable, [
 760         #include <linux/fs.h>
 761 ],[
 762         inode_owner_or_capable(NULL);
 763 ],[
 764         AC_DEFINE(HAVE_INODE_OWNER_OR_CAPABLE, 1,
 765                 [inode_owner_or_capable exist])
 766 ])
 767 ]) # LC_HAVE_INODE_OWNER_OR_CAPABLE
 768
 769 #
 770 # LC_DIRTY_INODE_WITH_FLAG
 771 #
 772 # 3.0 dirty_inode() has a flag parameter
 773 # see kernel commit aa38572954ade525817fe88c54faebf85e5a61c0
 774 #
 775 AC_DEFUN([LC_DIRTY_INODE_WITH_FLAG], [
 776 LB_CHECK_COMPILE([if 'dirty_inode' super_operation takes flag],
 777 dirty_inode_super_operation_flag, [
 778         #include <linux/fs.h>
 779 ],[
 780         struct inode *inode;
 781         inode->i_sb->s_op->dirty_inode(NULL, 0);
 782 ],[
 783         AC_DEFINE(HAVE_DIRTY_INODE_HAS_FLAG, 1,
 784                 [dirty_inode super_operation takes flag])
 785 ])
 786 ]) # LC_DIRTY_INODE_WITH_FLAG
 787
 788 #
 789 # LC_GENERIC_PERMISSION
 790 #
 791 # 2.6.38 generic_permission taken 4 parameters.
 792 # in fact, it means rcu-walk aware permission bring.
 793 #
 794 # 3.1 generic_permission taken 2 parameters.
 795 # see kernel commit 2830ba7f34ebb27c4e5b8b6ef408cd6d74860890
 796 #
 797 AC_DEFUN([LC_GENERIC_PERMISSION], [
 798 LB_CHECK_COMPILE([if 'generic_permission' take 2 arguments],
 799 generic_permission_2args, [
 800         #include <linux/fs.h>
 801 ],[
 802         generic_permission(NULL, 0);
 803 ],[
 804         AC_DEFINE(HAVE_GENERIC_PERMISSION_2ARGS, 1,
 805                 [generic_permission taken 2 arguments])
 806 ],[
 807         LB_CHECK_COMPILE([if 'generic_permission' take 4 arguments],
 808         generic_permission_4args, [
 809                 #include <linux/fs.h>
 810         ],[
 811                 generic_permission(NULL, 0, 0, NULL);
 812         ],[
 813                 AC_DEFINE(HAVE_GENERIC_PERMISSION_4ARGS, 1,
 814                         [generic_permission taken 4 arguments])
 815         ])
 816 ])
 817 ]) # LC_GENERIC_PERMISSION
 818
 819 #
 820 # LC_LM_XXX_LOCK_MANAGER_OPS
 821 #
 822 # 3.1 renames lock-manager ops(lock_manager_operations) from fl_xxx to lm_xxx
 823 # see kernel commit 8fb47a4fbf858a164e973b8ea8ef5e83e61f2e50
 824 #
 825 AC_DEFUN([LC_LM_XXX_LOCK_MANAGER_OPS], [
 826 LB_CHECK_COMPILE([if 'lock-manager' ops renamed to 'lm_xxx'],
 827 lock_manager_ops_lm_xxx, [
 828         #include <linux/fs.h>
 829 ],[
 830         struct lock_manager_operations lm_ops;
 831         lm_ops.lm_compare_owner = NULL;
 832 ],[
 833         AC_DEFINE(HAVE_LM_XXX_LOCK_MANAGER_OPS, 1,
 834                 [lock-manager ops renamed to lm_xxx])
 835 ])
 836 ]) # LC_LM_XXX_LOCK_MANAGER_OPS
 837
 838 #
 839 # LC_INODE_DIO_WAIT
 840 #
 841 # 3.1 kills inode->i_alloc_sem, use i_dio_count and inode_dio_wait/
 842 #     inode_dio_done instead.
 843 # see kernel commit bd5fe6c5eb9c548d7f07fe8f89a150bb6705e8e3
 844 #
 845 AC_DEFUN([LC_INODE_DIO_WAIT], [
 846 LB_CHECK_COMPILE([if 'inode->i_alloc_sem' is killed and use inode_dio_wait/done],
 847 inode_dio_wait, [
 848         #include <linux/fs.h>
 849 ],[
 850         inode_dio_wait((struct inode *)0);
 851         inode_dio_done((struct inode *)0);
 852 ],[
 853         AC_DEFINE(HAVE_INODE_DIO_WAIT, 1,
 854                 [inode->i_alloc_sem is killed and use inode_dio_wait/done])
 855 ])
 856 ]) # LC_INODE_DIO_WAIT
 857
 858 #
 859 # LC_IOP_GET_ACL
 860 #
 861 # 3.1 adds get_acl method to inode_operations to read ACL from disk.
 862 # see kernel commit 4e34e719e457f2e031297175410fc0bd4016a085
 863 #
 864 AC_DEFUN([LC_IOP_GET_ACL], [
 865 LB_CHECK_COMPILE([if 'inode_operations' has '.get_acl' member function],
 866 inode_ops_get_acl, [
 867         #include <linux/fs.h>
 868 ],[
 869         struct inode_operations iop;
 870         iop.get_acl = NULL;
 871 ],[
 872         AC_DEFINE(HAVE_IOP_GET_ACL, 1,
 873                 [inode_operations has .get_acl member function])
 874 ])
 875 ]) # LC_IOP_GET_ACL
 876
 877 #
 878 # LC_FILE_LLSEEK_SIZE
 879 #
 880 # 3.1 introduced generic_file_llseek_size()
 881 #
 882 AC_DEFUN([LC_FILE_LLSEEK_SIZE], [
 883 LB_CHECK_EXPORT([generic_file_llseek_size], [fs/read_write.c],
 884         [AC_DEFINE(HAVE_FILE_LLSEEK_SIZE, 1,
 885                 [generic_file_llseek_size is exported by the kernel])])
 886 ]) # LC_FILE_LLSEEK_SIZE
 887
 888 #
 889 # LC_RADIX_EXCEPTION_ENTRY
 890 # 3.1 adds radix_tree_exception_entry.
 891 #
 892 AC_DEFUN([LC_RADIX_EXCEPTION_ENTRY], [
 893 LB_CHECK_COMPILE([radix_tree_exceptional_entry exist],
 894 radix_tree_exceptional_entry, [
 895         #include <linux/radix-tree.h>
 896 ],[
 897         radix_tree_exceptional_entry(NULL);
 898 ],[
 899         AC_DEFINE(HAVE_RADIX_EXCEPTION_ENTRY, 1,
 900                 [radix_tree_exceptional_entry exist])
 901 ])
 902 ]) # LC_RADIX_EXCEPTION_ENTRY
 903
 904 #
 905 # LC_HAVE_VOID_MAKE_REQUEST_FN
 906 #
 907 # 3.2 request_queue.make_request_fn defined as function returns with void
 908 # see kernel commit 5a7bbad27a410350e64a2d7f5ec18fc73836c14f
 909 #
 910 AC_DEFUN([LC_HAVE_VOID_MAKE_REQUEST_FN], [
 911 LB_CHECK_COMPILE([if 'request_queue.make_request_fn' returns void but not int],
 912 make_request_fn_void, [
 913         #include <linux/blkdev.h>
 914 ],[
 915         int ret;
 916         make_request_fn *mrf;
 917         ret = mrf(NULL, NULL);
 918 ],[],[
 919         AC_DEFINE(HAVE_VOID_MAKE_REQUEST_FN, 1,
 920                 [request_queue.make_request_fn returns void but not int])
 921 ])
 922 ]) # LC_HAVE_VOID_MAKE_REQUEST_FN
 923
 924 #
 925 # LC_HAVE_PROTECT_I_NLINK
 926 #
 927 # 3.2 protects inode->i_nlink from direct modification
 928 # see kernel commit a78ef704a8dd430225955f0709b22d4a6ba21deb
 929 # at the same time adds set_nlink(), so checks set_nlink() for it.
 930 #
 931 AC_DEFUN([LC_HAVE_PROTECT_I_NLINK], [
 932 LB_CHECK_COMPILE([if 'inode->i_nlink' is protected from direct modification],
 933 inode_i_nlink_protected, [
 934         #include <linux/fs.h>
 935 ],[
 936         struct inode i;
 937         set_nlink(&i, 1);
 938 ],[
 939         AC_DEFINE(HAVE_PROTECT_I_NLINK, 1,
 940                 [inode->i_nlink is protected from direct modification])
 941 ])
 942 ]) # LC_HAVE_PROTECT_I_NLINK
 943
 944 #
 945 # LC_HAVE_MIGRATE_HEADER
 946 #
 947 # 3.3 introduces migrate_mode.h and migratepage has 4 args
 948 #
 949 AC_DEFUN([LC_HAVE_MIGRATE_HEADER], [
 950 LB_CHECK_FILE([$LINUX/include/linux/migrate.h], [
 951         AC_DEFINE(HAVE_MIGRATE_H, 1,
 952                 [kernel has include/linux/migrate.h])
 953 ],[
 954         LB_CHECK_FILE([$LINUX/include/linux/migrate_mode.h], [
 955                 AC_DEFINE(HAVE_MIGRATE_MODE_H, 1,
 956                         [kernel has include/linux/migrate_mode.h])
 957         ])
 958 ])
 959 ]) # LC_HAVE_MIGRATE_HEADER
 960
 961 #
 962 # LC_MIGRATEPAGE_4ARGS
 963 #
 964 AC_DEFUN([LC_MIGRATEPAGE_4ARGS], [
 965 LB_CHECK_COMPILE([if 'address_space_operations.migratepage' has 4 args],
 966 address_space_ops_migratepage_4args, [
 967         #include <linux/fs.h>
 968 #ifdef HAVE_MIGRATE_H
 969         #include <linux/migrate.h>
 970 #elif defined(HAVE_MIGRATE_MODE_H)
 971         #include <linux/migrate_mode.h>
 972 #endif
 973 ],[
 974         struct address_space_operations aops;
 975         aops.migratepage(NULL, NULL, NULL, MIGRATE_ASYNC);
 976 ],[
 977         AC_DEFINE(HAVE_MIGRATEPAGE_4ARGS, 1,
 978                 [address_space_operations.migratepage has 4 args])
 979 ])
 980 ]) # LC_MIGRATEPAGE_4ARGS
 981
 982 #
 983 # LC_SUPEROPS_USE_DENTRY
 984 #
 985 # 3.3 switchs super_operations to use dentry as parameter (but not vfsmount)
 986 # see kernel commit 34c80b1d93e6e20ca9dea0baf583a5b5510d92d4
 987 #
 988 AC_DEFUN([LC_SUPEROPS_USE_DENTRY], [
 989 tmp_flags="$EXTRA_KCFLAGS"
 990 EXTRA_KCFLAGS="-Werror"
 991 LB_CHECK_COMPILE([if 'super_operations' use 'dentry' as parameter],
 992 super_ops_dentry, [
 993         #include <linux/fs.h>
 994         int show_options(struct seq_file *seq, struct dentry *root) {
 995                 return 0;
 996         }
 997 ],[
 998         struct super_operations ops;
 999         ops.show_options = show_options;
1000 ],[
1001         AC_DEFINE(HAVE_SUPEROPS_USE_DENTRY, 1,
1002                 [super_operations use dentry as parameter])
1003 ])
1004 EXTRA_KCFLAGS="$tmp_flags"
1005 ]) # LC_SUPEROPS_USE_DENTRY
1006
1007 #
1008 # LC_INODEOPS_USE_UMODE_T
1009 #
1010 # 3.3 switchs inode_operations to use umode_t as parameter (but not int)
1011 # see kernel commit 1a67aafb5f72a436ca044293309fa7e6351d6a35
1012 #
1013 AC_DEFUN([LC_INODEOPS_USE_UMODE_T], [
1014 tmp_flags="$EXTRA_KCFLAGS"
1015 EXTRA_KCFLAGS="-Werror"
1016 LB_CHECK_COMPILE([if 'inode_operations' use 'umode_t' as parameter],
1017 inode_ops_umode_t, [
1018         #include <linux/fs.h>
1019         #include <linux/types.h>
1020         int my_mknod(struct inode *dir, struct dentry *dchild,
1021                      umode_t mode, dev_t dev)
1022         {
1023                 return 0;
1024         }
1025 ],[
1026         struct inode_operations ops;
1027         ops.mknod = my_mknod;
1028 ],[
1029         AC_DEFINE(HAVE_INODEOPS_USE_UMODE_T, 1,
1030                 [inode_operations use umode_t as parameter])
1031 ])
1032 EXTRA_KCFLAGS="$tmp_flags"
1033 ]) # LC_INODEOPS_USE_UMODE_T
1034
1035 #
1036 # LC_KMAP_ATOMIC_HAS_1ARG
1037 #
1038 # 3.4 kmap_atomic removes second argument
1039 # see kernel commit 1ec9c5ddc17aa398f05646abfcbaf315b544e62f
1040 #
1041 AC_DEFUN([LC_KMAP_ATOMIC_HAS_1ARG], [
1042 LB_CHECK_COMPILE([if 'kmap_atomic' has only 1 argument],
1043 kmap_atomic_1arg, [
1044         #include <linux/highmem.h>
1045 ],[
1046         kmap_atomic(NULL);
1047 ],[
1048         AC_DEFINE(HAVE_KMAP_ATOMIC_HAS_1ARG, 1,
1049                 [have kmap_atomic has only 1 argument])
1050 ])
1051 ]) # LC_KMAP_ATOMIC_HAS_1ARG
1052
1053 #
1054 # LC_HAVE_D_MAKE_ROOT
1055 #
1056 # 3.4 converts d_alloc_root to d_make_root
1057 # see kernel commit 32991ab305ace7017c62f8eecbe5eb36dc32e13b
1058 #
1059 AC_DEFUN([LC_HAVE_D_MAKE_ROOT], [
1060 LB_CHECK_COMPILE([if have 'd_make_root'],
1061 d_make_root, [
1062         #include <linux/fs.h>
1063 ],[
1064         d_make_root((struct inode *)NULL);
1065 ],[
1066         AC_DEFINE(HAVE_D_MAKE_ROOT, 1,
1067                 [have d_make_root])
1068 ])
1069 ]) # LC_HAVE_D_MAKE_ROOT
1070
1071 #
1072 # LC_HAVE_CACHE_REGISTER
1073 #
1074 # 3.4 cache_register/cache_unregister are removed
1075 # see kernel commit 2c5f846747526e2b83c5f1b8e69016be0e2e87c0
1076 # Note, since 2.6.37 cache_register_net/cache_unregister_net
1077 # are defined, but not exported.
1078 # 3.3 cache_register_net/cache_unregister_net are
1079 # exported and replacing cache_register/cache_unregister in 3.4
1080 #
1081 AC_DEFUN([LC_HAVE_CACHE_REGISTER], [
1082 LB_CHECK_COMPILE([if have 'cache_register'],
1083 cache_register, [
1084         #include <linux/sunrpc/cache.h>
1085 ],[
1086         cache_register(NULL);
1087 ],[
1088         AC_DEFINE(HAVE_CACHE_REGISTER, 1,
1089                 [have cache_register])
1090 ])
1091 ]) # LC_HAVE_CACHE_REGISTER
1092
1093 #
1094 # LC_HAVE_CLEAR_INODE
1095 #
1096 # 3.5 renames end_writeback() back to clear_inode()...
1097 # see kernel commit dbd5768f87ff6fb0a4fe09c4d7b6c4a24de99430
1098 #
1099 AC_DEFUN([LC_HAVE_CLEAR_INODE], [
1100 LB_CHECK_COMPILE([if have 'clear_inode'],
1101 clear_inode, [
1102         #include <linux/fs.h>
1103 ],[
1104         clear_inode((struct inode *)NULL);
1105 ],[
1106         AC_DEFINE(HAVE_CLEAR_INODE, 1,
1107                 [have clear_inode])
1108 ])
1109 ]) # LC_HAVE_CLEAR_INODE
1110
1111 #
1112 # LC_HAVE_ENCODE_FH_PARENT
1113 #
1114 # 3.5 encode_fh has parent inode passed in directly
1115 # see kernel commit b0b0382b
1116 #
1117 AC_DEFUN([LC_HAVE_ENCODE_FH_PARENT], [
1118 tmp_flags="$EXTRA_KCFLAGS"
1119 EXTRA_KCFLAGS="-Werror"
1120 LB_CHECK_COMPILE([if 'encode_fh' have parent inode as parameter],
1121 encode_fh_parent_inode, [
1122         #include <linux/exportfs.h>
1123         #include <linux/fs.h>
1124         #include <linux/types.h>
1125         int ll_encode_fh(struct inode *i, __u32 *a, int *b, struct inode *p)
1126         {
1127                 return 0;
1128         }
1129 ],[
1130         struct export_operations exp_op;
1131         exp_op.encode_fh = ll_encode_fh;
1132 ],[
1133         AC_DEFINE(HAVE_ENCODE_FH_PARENT, 1,
1134                 [have parent inode as parameter])
1135 ])
1136 EXTRA_KCFLAGS="$tmp_flags"
1137 ]) # LC_HAVE_ENCODE_FH_PARENT
1138
1139 #
1140 # LC_FILE_LLSEEK_SIZE_5ARG
1141 #
1142 # 3.5 has generic_file_llseek_size with 5 args
1143 #
1144 AC_DEFUN([LC_FILE_LLSEEK_SIZE_5ARG], [
1145 LB_CHECK_COMPILE([if Linux kernel has 'generic_file_llseek_size' with 5 args],
1146 generic_file_llseek_size_5args, [
1147         #include <linux/fs.h>
1148 ],[
1149         generic_file_llseek_size(NULL, 0, 0, 0, 0);
1150 ], [
1151         AC_DEFINE(HAVE_FILE_LLSEEK_SIZE_5ARGS, 1,
1152                 [kernel has generic_file_llseek_size with 5 args])
1153 ])
1154 ]) # LC_FILE_LLSEEK_SIZE_5ARG
1155
1156 #
1157 # LC_HAVE_DENTRY_D_ALIAS_HLIST
1158 #
1159 # 3.6 switch i_dentry/d_alias from list to hlist
1160 #
1161 AC_DEFUN([LC_HAVE_DENTRY_D_ALIAS_HLIST], [
1162 tmp_flags="$EXTRA_KCFLAGS"
1163 EXTRA_KCFLAGS="-Werror"
1164 LB_CHECK_COMPILE([if 'i_dentry/d_alias' uses 'hlist'],
1165 i_dentry_d_alias_hlist, [
1166         #include <linux/fs.h>
1167         #include <linux/list.h>
1168 ],[
1169         struct inode inode;
1170         struct dentry dentry;
1171         struct hlist_head head;
1172         struct hlist_node node;
1173         inode.i_dentry = head;
1174         dentry.d_alias = node;
1175 ],[
1176         AC_DEFINE(HAVE_DENTRY_D_ALIAS_HLIST, 1,
1177                 [have i_dentry/d_alias uses hlist])
1178 ])
1179 EXTRA_KCFLAGS="$tmp_flags"
1180 ]) # LC_HAVE_DENTRY_D_ALIAS_HLIST
1181
1182 #
1183 # LC_DENTRY_OPEN_USE_PATH
1184 #
1185 # 3.6 dentry_open uses struct path as first argument
1186 # see kernel commit 765927b2
1187 #
1188 AC_DEFUN([LC_DENTRY_OPEN_USE_PATH], [
1189 tmp_flags="$EXTRA_KCFLAGS"
1190 EXTRA_KCFLAGS="-Werror"
1191 LB_CHECK_COMPILE([if 'dentry_open' uses 'struct path' as first argument],
1192 dentry_open_path, [
1193         #include <linux/fs.h>
1194         #include <linux/path.h>
1195 ],[
1196         struct path path;
1197         dentry_open(&path, 0, NULL);
1198 ],[
1199         AC_DEFINE(HAVE_DENTRY_OPEN_USE_PATH, 1,
1200                 [dentry_open uses struct path as first argument])
1201 ])
1202 EXTRA_KCFLAGS="$tmp_flags"
1203 ]) # LC_DENTRY_OPEN_USE_PATH
1204
1205 #
1206 # LC_HAVE_IOP_ATOMIC_OPEN
1207 #
1208 # 3.6 vfs adds iop->atomic_open
1209 #
1210 AC_DEFUN([LC_HAVE_IOP_ATOMIC_OPEN], [
1211 LB_CHECK_COMPILE([if 'iop' has 'atomic_open'],
1212 inode_ops_atomic_open, [
1213         #include <linux/fs.h>
1214 ],[
1215         struct inode_operations iop;
1216         iop.atomic_open = NULL;
1217 ],[
1218         AC_DEFINE(HAVE_IOP_ATOMIC_OPEN, 1,
1219                 [have iop atomic_open])
1220 ])
1221 ]) # LC_HAVE_IOP_ATOMIC_OPEN
1222
1223 #
1224 # LC_HAVE_POSIXACL_USER_NS
1225 #
1226 # 3.7 posix_acl_{to,from}_xattr take struct user_namespace
1227 #
1228 AC_DEFUN([LC_HAVE_POSIXACL_USER_NS], [
1229 LB_CHECK_COMPILE([if 'posix_acl_to_xattr' takes 'struct user_namespace'],
1230 posix_acl_to_xattr_user_namespace, [
1231         #include <linux/fs.h>
1232         #include <linux/posix_acl_xattr.h>
1233 ],[
1234         posix_acl_to_xattr((struct user_namespace *)NULL, NULL, NULL, 0);
1235 ],[
1236         AC_DEFINE(HAVE_POSIXACL_USER_NS, 1,
1237                 [posix_acl_to_xattr takes struct user_namespace])
1238 ])
1239 ]) # LC_HAVE_POSIXACL_USER_NS
1240
1241 #
1242 # LC_HAVE_FILE_F_INODE
1243 #
1244 # 3.8 struct file has new member f_inode
1245 #
1246 AC_DEFUN([LC_HAVE_FILE_F_INODE], [
1247 LB_CHECK_COMPILE([if 'struct file' has member 'f_inode'],
1248 file_f_inode, [
1249         #include <linux/fs.h>
1250 ],[
1251         ((struct file *)0)->f_inode = NULL;
1252 ],[
1253         AC_DEFINE(HAVE_FILE_F_INODE, 1,
1254                 [struct file has member f_inode])
1255 ])
1256 ]) # LC_HAVE_FILE_F_INODE
1257
1258 #
1259 # LC_HAVE_SUNRPC_UPCALL_HAS_3ARGS
1260 #
1261 AC_DEFUN([LC_HAVE_SUNRPC_UPCALL_HAS_3ARGS], [
1262 LB_CHECK_COMPILE([if 'sunrpc_cache_pipe_upcall' takes 3 args],
1263 sunrpc_cache_pipe_upcall_3args, [
1264         #include <linux/sunrpc/cache.h>
1265 ],[
1266         sunrpc_cache_pipe_upcall(NULL, NULL, NULL);
1267 ],[
1268         AC_DEFINE(HAVE_SUNRPC_UPCALL_HAS_3ARGS, 1,
1269                 [sunrpc_cache_pipe_upcall takes 3 args])
1270 ])
1271 ]) # LC_HAVE_SUNRPC_UPCALL_HAS_3ARGS
1272
1273 #
1274 # LC_HAVE_HLIST_FOR_EACH_3ARG
1275 #
1276 # 3.9 uses hlist_for_each_entry with 3 args
1277 # b67bfe0d42cac56c512dd5da4b1b347a23f4b70a
1278 #
1279 AC_DEFUN([LC_HAVE_HLIST_FOR_EACH_3ARG], [
1280 LB_CHECK_COMPILE([if 'hlist_for_each_entry' has 3 args],
1281 hlist_for_each_entry_3args, [
1282         #include <linux/list.h>
1283         #include <linux/fs.h>
1284 ],[
1285         struct inode *inode;
1286         struct dentry *dentry;
1287         hlist_for_each_entry(dentry, &inode->i_dentry, d_alias) {
1288                 continue;
1289         }
1290 ],[
1291         AC_DEFINE(HAVE_HLIST_FOR_EACH_3ARG, 1,
1292                 [hlist_for_each_entry has 3 args])
1293 ])
1294 ]) # LC_HAVE_HLIST_FOR_EACH_3ARG
1295
1296 #
1297 # LC_HAVE_BIO_END_SECTOR
1298 #
1299 # 3.9 introduces bio_end_sector macro
1300 # f73a1c7d117d07a96d89475066188a2b79e53c48
1301 #
1302 AC_DEFUN([LC_HAVE_BIO_END_SECTOR], [
1303 LB_CHECK_COMPILE([if 'bio_end_sector' is defined],
1304 bio_end_sector, [
1305         #include <linux/bio.h>
1306 ],[
1307         struct bio bio;
1308
1309         bio_end_sector(&bio);
1310 ],[
1311         AC_DEFINE(HAVE_BIO_END_SECTOR, 1,
1312                   [bio_end_sector is defined])
1313 ])
1314 ]) # LC_HAVE_BIO_END_SECTOR
1315
1316 #
1317 # LC_HAVE_REMOVE_PROC_SUBTREE
1318 #
1319 # 3.10 introduced remove_proc_subtree
1320 #
1321 AC_DEFUN([LC_HAVE_REMOVE_PROC_SUBTREE], [
1322 LB_CHECK_COMPILE([if 'remove_proc_subtree' is defined],
1323 remove_proc_subtree, [
1324         #include <linux/proc_fs.h>
1325 ],[
1326         remove_proc_subtree(NULL, NULL);
1327 ], [
1328         AC_DEFINE(HAVE_REMOVE_PROC_SUBTREE, 1,
1329                   [remove_proc_subtree is defined])
1330 ])
1331 ]) # LC_HAVE_REMOVE_PROC_SUBTREE
1332
1333 #
1334 # LC_HAVE_PROC_REMOVE
1335 #
1336 # 3.10 introduced proc_remove
1337 #
1338 AC_DEFUN([LC_HAVE_PROC_REMOVE], [
1339 LB_CHECK_COMPILE([if 'proc_remove' is defined],
1340 proc_remove, [
1341         #include <linux/proc_fs.h>
1342 ],[
1343         proc_remove(NULL);
1344 ], [
1345         AC_DEFINE(HAVE_PROC_REMOVE, 1,
1346                   [proc_remove is defined])
1347 ])
1348 ]) # LC_HAVE_PROC_REMOVE
1349
1350 #
1351 # LC_BLKDEV_RELEASE_RETURN_INT
1352 #
1353 # 3.10 release for block device doesn't return int
1354 #
1355 AC_DEFUN([LC_BLKDEV_RELEASE_RETURN_INT], [
1356 LB_CHECK_COMPILE([if 'block_device_operations' release returns 'int'],
1357 block_device_ops_release_return_int, [
1358         #include <linux/blkdev.h>
1359 ],[
1360         struct block_device_operations fops;
1361         int i __attribute__ ((unused));
1362
1363         i = fops.release(NULL, 0);
1364 ],[
1365         AC_DEFINE(HAVE_BLKDEV_RELEASE_RETURN_INT, 1,
1366                 [block device release returns int])
1367 ])
1368 ]) # LC_BLKDEV_RELEASE_RETURN_INT
1369
1370 #
1371 # LC_INVALIDATE_RANGE
1372 #
1373 # 3.11 invalidatepage requires the length of the range to invalidate
1374 #
1375 AC_DEFUN([LC_INVALIDATE_RANGE], [
1376 LB_CHECK_COMPILE([if 'address_space_operations.invalidatepage' requires 3 arguments],
1377 address_space_ops_invalidatepage_3args, [
1378         #include <linux/fs.h>
1379 ],[
1380         struct address_space_operations a_ops;
1381         a_ops.invalidatepage(NULL, 0, 0);
1382 ],[
1383         AC_DEFINE(HAVE_INVALIDATE_RANGE, 1,
1384                 [address_space_operations.invalidatepage needs 3 arguments])
1385 ])
1386 ]) # LC_INVALIDATE_RANGE
1387
1388 #
1389 # LC_HAVE_DIR_CONTEXT
1390 #
1391 # 3.11 readdir now takes the new struct dir_context
1392 #
1393 AC_DEFUN([LC_HAVE_DIR_CONTEXT], [
1394 LB_CHECK_COMPILE([if 'dir_context' exist],
1395 dir_context, [
1396         #include <linux/fs.h>
1397 ],[
1398         struct dir_context ctx;
1399         ctx.pos = 0;
1400 ],[
1401         AC_DEFINE(HAVE_DIR_CONTEXT, 1,
1402                 [dir_context exist])
1403 ])
1404 ]) # LC_HAVE_DIR_CONTEXT
1405
1406 #
1407 # LC_D_COMPARE_5ARGS
1408 #
1409 # 3.11 dentry_operations.d_compare() taken 5 arguments.
1410 #
1411 AC_DEFUN([LC_D_COMPARE_5ARGS], [
1412 LB_CHECK_COMPILE([if 'd_compare' taken 5 arguments],
1413 d_compare_5args, [
1414         #include <linux/dcache.h>
1415 ],[
1416         ((struct dentry_operations*)0)->d_compare(NULL,NULL,0,NULL,NULL);
1417 ],[
1418         AC_DEFINE(HAVE_D_COMPARE_5ARGS, 1,
1419                 [d_compare need 5 arguments])
1420 ])
1421 ]) # LC_D_COMPARE_5ARGS
1422
1423 #
1424 # LC_HAVE_DCOUNT
1425 #
1426 # 3.11 need to access d_count to get dentry reference count
1427 #
1428 AC_DEFUN([LC_HAVE_DCOUNT], [
1429 LB_CHECK_COMPILE([if 'd_count' exist],
1430 d_count, [
1431         #include <linux/dcache.h>
1432 ],[
1433         struct dentry de;
1434         d_count(&de);
1435 ],[
1436         AC_DEFINE(HAVE_D_COUNT, 1,
1437                 [d_count exist])
1438 ])
1439 ]) # LC_HAVE_DCOUNT
1440
1441 #
1442 # LC_OLDSIZE_TRUNCATE_PAGECACHE
1443 #
1444 # 3.12 truncate_pagecache without oldsize parameter
1445 #
1446 AC_DEFUN([LC_OLDSIZE_TRUNCATE_PAGECACHE], [
1447 LB_CHECK_COMPILE([if 'truncate_pagecache' with 'old_size' parameter],
1448 truncate_pagecache_old_size, [
1449         #include <linux/mm.h>
1450 ],[
1451         truncate_pagecache(NULL, 0, 0);
1452 ],[
1453         AC_DEFINE(HAVE_OLDSIZE_TRUNCATE_PAGECACHE, 1,
1454                 [with oldsize])
1455 ])
1456 ]) # LC_OLDSIZE_TRUNCATE_PAGECACHE
1457
1458 #
1459 # LC_KIOCB_KI_LEFT
1460 #
1461 # 3.12 ki_left removed from struct kiocb
1462 #
1463 AC_DEFUN([LC_KIOCB_KI_LEFT], [
1464 LB_CHECK_COMPILE([if 'struct kiocb' with 'ki_left' member],
1465 kiocb_ki_left, [
1466         #include <linux/aio.h>
1467 ],[
1468         ((struct kiocb*)0)->ki_left = 0;
1469 ],[
1470         AC_DEFINE(HAVE_KIOCB_KI_LEFT, 1,
1471                 [ki_left exist])
1472 ])
1473 ]) # LC_KIOCB_KI_LEFT
1474
1475 #
1476 # LC_VFS_RENAME_5ARGS
1477 #
1478 # 3.13 has vfs_rename with 5 args
1479 #
1480 AC_DEFUN([LC_VFS_RENAME_5ARGS], [
1481 LB_CHECK_COMPILE([if Linux kernel has 'vfs_rename' with 5 args],
1482 vfs_rename_5args, [
1483         #include <linux/fs.h>
1484 ],[
1485         vfs_rename(NULL, NULL, NULL, NULL, NULL);
1486 ], [
1487         AC_DEFINE(HAVE_VFS_RENAME_5ARGS, 1,
1488                 [kernel has vfs_rename with 5 args])
1489 ])
1490 ]) # LC_VFS_RENAME_5ARGS
1491
1492 #
1493 # LC_VFS_UNLINK_3ARGS
1494 #
1495 # 3.13 has vfs_unlink with 3 args
1496 #
1497 AC_DEFUN([LC_VFS_UNLINK_3ARGS], [
1498 LB_CHECK_COMPILE([if Linux kernel has 'vfs_unlink' with 3 args],
1499 vfs_unlink_3args, [
1500         #include <linux/fs.h>
1501 ],[
1502         vfs_unlink(NULL, NULL, NULL);
1503 ], [
1504         AC_DEFINE(HAVE_VFS_UNLINK_3ARGS, 1,
1505                 [kernel has vfs_unlink with 3 args])
1506 ])
1507 ]) # LC_VFS_UNLINK_3ARGS
1508
1509 #
1510 # LC_HAVE_BVEC_ITER
1511 #
1512 # 3.14 move some of its data in struct bio into the new
1513 # struct bvec_iter
1514 #
1515 AC_DEFUN([LC_HAVE_BVEC_ITER], [
1516 LB_CHECK_COMPILE([if Linux kernel has struct bvec_iter],
1517 have_bvec_iter, [
1518         #include <linux/bio.h>
1519 ],[
1520         struct bvec_iter iter;
1521         iter.bi_bvec_done = 0;
1522 ], [
1523         AC_DEFINE(HAVE_BVEC_ITER, 1,
1524                 [kernel has struct bvec_iter])
1525 ])
1526 ]) # LC_HAVE_BVEC_ITER
1527
1528 #
1529 # LC_HAVE_TRUNCATE_IPAGE_FINAL
1530 #
1531 # 3.14 bring truncate_inode_pages_final for evict_inode
1532 #
1533 AC_DEFUN([LC_HAVE_TRUNCATE_IPAGES_FINAL], [
1534 LB_CHECK_COMPILE([if Linux kernel has truncate_inode_pages_final],
1535 truncate_ipages_final, [
1536         #include <linux/mm.h>
1537 ],[
1538         truncate_inode_pages_final(NULL);
1539 ], [
1540         AC_DEFINE(HAVE_TRUNCATE_INODE_PAGES_FINAL, 1,
1541                 [kernel has truncate_inode_pages_final])
1542 ])
1543 ]) # LC_HAVE_TRUNCATE_IPAGES_FINAL
1544 #
1545 # LC_VFS_RENAME_6ARGS
1546 #
1547 # 3.15 has vfs_rename with 6 args
1548 #
1549 AC_DEFUN([LC_VFS_RENAME_6ARGS], [
1550 LB_CHECK_COMPILE([if Linux kernel has 'vfs_rename' with 6 args],
1551 vfs_rename_6args, [
1552         #include <linux/fs.h>
1553 ],[
1554         vfs_rename(NULL, NULL, NULL, NULL, NULL, NULL);
1555 ], [
1556         AC_DEFINE(HAVE_VFS_RENAME_6ARGS, 1,
1557                 [kernel has vfs_rename with 6 args])
1558 ])
1559 ]) # LC_VFS_RENAME_6ARGS
1560
1561 #
1562 # LC_PROG_LINUX
1563 #
1564 # Lustre linux kernel checks
1565 #
1566 AC_DEFUN([LC_PROG_LINUX], [
1567         AC_MSG_NOTICE([Lustre kernel checks
1568 ==============================================================================])
1569
1570         LC_CONFIG_PINGER
1571         LC_CONFIG_CHECKSUM
1572         LC_CONFIG_HEALTH_CHECK_WRITE
1573         LC_CONFIG_LRU_RESIZE
1574         LC_LLITE_LLOOP_MODULE
1575
1576         LC_GLIBC_SUPPORT_FHANDLES
1577         LC_CAPA_CRYPTO
1578         LC_CONFIG_RMTCLIENT
1579         LC_CONFIG_GSS
1580
1581         # 2.6.32
1582         LC_BLK_QUEUE_MAX_SEGMENTS
1583
1584         # 2.6.34
1585         LC_HAVE_DQUOT_FS_DISK_QUOTA
1586         LC_HAVE_DQUOT_SUSPEND
1587         LC_HAVE_ADD_WAIT_QUEUE_EXCLUSIVE
1588
1589         # 2.6.35, 3.0.0
1590         LC_FILE_FSYNC
1591         LC_EXPORT_SIMPLE_SETATTR
1592         LC_EXPORT_TRUNCATE_COMPLETE_PAGE
1593
1594         # 2.6.36
1595         LC_FS_STRUCT_RWLOCK
1596         LC_SBOPS_EVICT_INODE
1597
1598         # 2.6.37
1599         LC_KERNEL_LOCKED
1600
1601         # 2.6.38
1602         LC_BLKDEV_GET_BY_DEV
1603         LC_GENERIC_PERMISSION
1604         LC_DCACHE_LOCK
1605         LC_INODE_I_RCU
1606         LC_D_COMPARE_7ARGS
1607         LC_D_DELETE_CONST
1608
1609         # 2.6.39
1610         LC_REQUEST_QUEUE_UNPLUG_FN
1611         LC_HAVE_FHANDLE_SYSCALLS
1612         LC_HAVE_FSTYPE_MOUNT
1613         LC_IOP_TRUNCATE
1614         LC_HAVE_INODE_OWNER_OR_CAPABLE
1615
1616         # 3.0
1617         LC_DIRTY_INODE_WITH_FLAG
1618
1619         # 3.1
1620         LC_LM_XXX_LOCK_MANAGER_OPS
1621         LC_INODE_DIO_WAIT
1622         LC_IOP_GET_ACL
1623         LC_FILE_LLSEEK_SIZE
1624         LC_INODE_PERMISION_2ARGS
1625         LC_RADIX_EXCEPTION_ENTRY
1626
1627         # 3.2
1628         LC_HAVE_VOID_MAKE_REQUEST_FN
1629         LC_HAVE_PROTECT_I_NLINK
1630
1631         # 3.3
1632         LC_HAVE_MIGRATE_HEADER
1633         LC_MIGRATEPAGE_4ARGS
1634         LC_SUPEROPS_USE_DENTRY
1635         LC_INODEOPS_USE_UMODE_T
1636         LC_HAVE_CACHE_REGISTER
1637
1638         # 3.4
1639         LC_HAVE_D_MAKE_ROOT
1640         LC_KMAP_ATOMIC_HAS_1ARG
1641
1642         # 3.5
1643         LC_HAVE_CLEAR_INODE
1644         LC_HAVE_ENCODE_FH_PARENT
1645         LC_FILE_LLSEEK_SIZE_5ARG
1646
1647         # 3.6
1648         LC_HAVE_DENTRY_D_ALIAS_HLIST
1649         LC_DENTRY_OPEN_USE_PATH
1650         LC_HAVE_IOP_ATOMIC_OPEN
1651
1652         # 3.7
1653         LC_HAVE_POSIXACL_USER_NS
1654
1655         # 3.8
1656         LC_HAVE_FILE_F_INODE
1657         LC_HAVE_SUNRPC_UPCALL_HAS_3ARGS
1658
1659         # 3.9
1660         LC_HAVE_HLIST_FOR_EACH_3ARG
1661         LC_HAVE_BIO_END_SECTOR
1662
1663         # 3.10
1664         LC_BLKDEV_RELEASE_RETURN_INT
1665         LC_HAVE_REMOVE_PROC_SUBTREE
1666         LC_HAVE_PROC_REMOVE
1667
1668         # 3.11
1669         LC_INVALIDATE_RANGE
1670         LC_HAVE_DIR_CONTEXT
1671         LC_D_COMPARE_5ARGS
1672         LC_HAVE_DCOUNT
1673
1674         # 3.12
1675         LC_OLDSIZE_TRUNCATE_PAGECACHE
1676         LC_KIOCB_KI_LEFT
1677
1678         # 3.13
1679         LC_VFS_RENAME_5ARGS
1680         LC_VFS_UNLINK_3ARGS
1681
1682         # 3.14
1683         LC_HAVE_BVEC_ITER
1684         LC_HAVE_TRUNCATE_IPAGES_FINAL
1685
1686         # 3.15
1687         LC_VFS_RENAME_6ARGS
1688
1689         #
1690         AS_IF([test "x$enable_server" != xno], [
1691                 LC_FUNC_DEV_SET_RDONLY
1692                 LC_STACK_SIZE
1693                 LC_QUOTA64
1694                 LC_QUOTA_CONFIG
1695         ])
1696 ]) # LC_PROG_LINUX
1697
1698 #
1699 # LC_CONFIG_CLIENT
1700 #
1701 # Check whether to build the client side of Lustre
1702 #
1703 AC_DEFUN([LC_CONFIG_CLIENT], [
1704 AC_MSG_CHECKING([whether to build Lustre client support])
1705 AC_ARG_ENABLE([client],
1706         AC_HELP_STRING([--disable-client],
1707                 [disable Lustre client support]),
1708         [], [enable_client="yes"])
1709 AC_MSG_RESULT([$enable_client])
1710 ]) # LC_CONFIG_CLIENT
1711
1712 #
1713 # --enable-mpitests
1714 #
1715 AC_DEFUN([LB_CONFIG_MPITESTS], [
1716 AC_ARG_ENABLE([mpitests],
1717         AC_HELP_STRING([--enable-mpitests=<yes|no|mpicc wrapper>],
1718                        [include mpi tests]), [
1719                 enable_mpitests="yes"
1720                 case $enableval in
1721                 yes)
1722                         MPICC_WRAPPER="mpicc"
1723                         ;;
1724                 no)
1725                         enable_mpitests="no"
1726                         ;;
1727                 *)
1728                         MPICC_WRAPPER=$enableval
1729                         ;;
1730                 esac
1731         ], [
1732                 enable_mpitests="yes"
1733                 MPICC_WRAPPER="mpicc"
1734         ])
1735
1736         if test "x$enable_mpitests" != "xno"; then
1737                 oldcc=$CC
1738                 CC=$MPICC_WRAPPER
1739                 AC_CACHE_CHECK([whether mpitests can be built],
1740                 lb_cv_mpi_tests, [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1741                         #include <mpi.h>
1742                         int main(void) {
1743                                 int flag;
1744                                 MPI_Initialized(&flag);
1745                                 return 0;
1746                         }
1747                 ])], [lb_cv_mpi_tests="yes"], [lb_cv_mpi_tests="no"
1748                         enable_mpitests=$lb_cv_mpi_tests])
1749                 ])
1750                 CC=$oldcc
1751         fi
1752         AC_SUBST(MPICC_WRAPPER)
1753 ]) # LB_CONFIG_MPITESTS
1754
1755 #
1756 # LC_CONFIG_QUOTA
1757 #
1758 # whether to enable quota support global control
1759 #
1760 AC_DEFUN([LC_CONFIG_QUOTA], [
1761 AC_MSG_CHECKING([whether to enable quota support global control])
1762 AC_ARG_ENABLE([quota],
1763         AC_HELP_STRING([--enable-quota],
1764                 [enable quota support]),
1765         [], [enable_quota="yes"])
1766 AS_IF([test "x$enable_quota" = xyes],
1767         [AC_MSG_RESULT([yes])],
1768         [AC_MSG_RESULT([no])])
1769 ]) # LC_CONFIG_QUOTA
1770
1771 #
1772 # LC_QUOTA
1773 #
1774 AC_DEFUN([LC_QUOTA], [
1775 #check global
1776 LC_CONFIG_QUOTA
1777 #check for utils
1778 AS_IF([test "x$enable_quota" != xno -a "x$enable_utils" != xno], [
1779         AC_CHECK_HEADER([sys/quota.h],
1780                 [AC_DEFINE(HAVE_SYS_QUOTA_H, 1,
1781                         [Define to 1 if you have <sys/quota.h>.])],
1782                 [AC_MSG_ERROR([don't find <sys/quota.h> in your system])])
1783 ])
1784 ]) # LC_QUOTA
1785
1786 #
1787 # LC_CONFIG_NODEMAP_PROC_DEBUG
1788 #
1789 # enable nodemap proc file debugging
1790 #
1791 AC_DEFUN([LC_NODEMAP_PROC_DEBUG], [
1792 AC_MSG_CHECKING([whether to enable nodemap proc debug])
1793 AC_ARG_ENABLE([nodemap_proc_debug],
1794         AC_HELP_STRING([--enable-nodemap-proc-debug],
1795                 [enable nodemap proc debug]),
1796         [], [enable_nodemap_proc_debug="no"])
1797 AC_MSG_RESULT([$enable_nodemap_proc_debug])
1798 AS_IF([test "x$enable_nodemap_proc_debug" != xno],
1799         [AC_DEFINE(NODEMAP_PROC_DEBUG, 1,
1800                 [enable nodemap proc debug support])])
1801 ]) # LC_NODEMAP_PROC_DEBUG
1802
1803 #
1804 # LC_LLITE_LLOOP_MODULE
1805 #
1806 # lloop_llite.ko does not currently work with page sizes
1807 # of 64k or larger.
1808 #
1809 AC_DEFUN([LC_LLITE_LLOOP_MODULE], [
1810 LB_CHECK_COMPILE([whether to enable 'llite_lloop' module],
1811 enable_llite_lloop_module, [
1812         #include <asm/page.h>
1813 ],[
1814         #if PAGE_SIZE >= 65536
1815         #error "PAGE_SIZE >= 65536"
1816         #endif
1817 ],
1818         [enable_llite_lloop_module="yes"],
1819         [enable_llite_lloop_module="no"])
1820 ]) # LC_LLITE_LLOOP_MODULE
1821
1822 #
1823 # LC_OSD_ADDON
1824 #
1825 # configure support for optional OSD implementation
1826 #
1827 AC_DEFUN([LC_OSD_ADDON], [
1828 AC_MSG_CHECKING([whether to use OSD addon])
1829 AC_ARG_WITH([osd],
1830         AC_HELP_STRING([--with-osd=path],
1831                 [set path to optional osd]),
1832         [
1833         case "$with_osd" in
1834         no)
1835                 ENABLEOSDADDON=0
1836                 ;;
1837         *)
1838                 OSDADDON="$with_osd"
1839                 ENABLEOSDADDON=1
1840                 ;;
1841         esac
1842         ], [
1843                 ENABLEOSDADDON=0
1844         ])
1845 AS_IF([test $ENABLEOSDADDON -eq 0], [
1846         AC_MSG_RESULT([no])
1847         OSDADDON=""
1848 ], [
1849         OSDMODNAME=$(basename $OSDADDON)
1850         AS_IF([test -e $LUSTRE/$OSDMODNAME], [
1851                 AC_MSG_RESULT([can't link])
1852                 OSDADDON=""
1853         ], [ln -s $OSDADDON $LUSTRE/$OSDMODNAME], [
1854                 AC_MSG_RESULT([$OSDMODNAME])
1855                 OSDADDON="subdir-m += $OSDMODNAME"
1856         ], [
1857                 AC_MSG_RESULT([can't link])
1858                 OSDADDON=""
1859         ])
1860 ])
1861 AC_SUBST(OSDADDON)
1862 ]) # LC_OSD_ADDON
1863
1864 #
1865 # LC_CONFIGURE
1866 #
1867 # other configure checks
1868 #
1869 AC_DEFUN([LC_CONFIGURE], [
1870 AC_MSG_NOTICE([Lustre core checks
1871 ==============================================================================])
1872
1873 LC_CONFIG_OBD_BUFFER_SIZE
1874
1875 AS_IF([test $target_cpu == "i686" -o $target_cpu == "x86_64"],
1876         [CFLAGS="$CFLAGS -Werror"])
1877
1878 # maximum MDS thread count
1879 LC_MDS_MAX_THREADS
1880
1881 # lustre/utils/llverdev.c
1882 AC_CHECK_HEADERS([blkid/blkid.h])
1883
1884 # libcfs/include/libcfs/linux/linux-prim.h, ...
1885 AC_CHECK_HEADERS([linux/types.h sys/types.h linux/unistd.h unistd.h])
1886
1887 # libcfs/include/libcfs/linux/linux-prim.h
1888 AC_CHECK_HEADERS([linux/random.h], [], [],
1889                  [#ifdef HAVE_LINUX_TYPES_H
1890                   #include <linux/types.h>
1891                   #endif
1892                  ])
1893
1894 # utils/llverfs.c
1895 AC_CHECK_HEADERS([ext2fs/ext2fs.h])
1896
1897 SELINUX=""
1898 AC_CHECK_LIB([selinux], [is_selinux_enabled],
1899         [AC_CHECK_HEADERS([selinux/selinux.h],
1900                         [SELINUX="-lselinux"
1901                         AC_DEFINE([HAVE_SELINUX], 1,
1902                                 [support for selinux ])],
1903                         [AC_MSG_WARN([
1904
1905 No libselinux-devel package found, unable to build selinux enabled tools
1906 ])
1907 ])],
1908         [AC_MSG_WARN([
1909
1910 No selinux package found, unable to build selinux enabled tools
1911 ])
1912 ])
1913 AC_SUBST(SELINUX)
1914
1915 # Super safe df
1916 AC_MSG_CHECKING([whether to report minimum OST free space])
1917 AC_ARG_ENABLE([mindf],
1918         AC_HELP_STRING([--enable-mindf],
1919                 [Make statfs report the minimum available space on any single OST instead of the sum of free space on all OSTs]),
1920         [], [enable_mindf="no"])
1921 AC_MSG_RESULT([$enable_mindf])
1922 AS_IF([test "$enable_mindf" = "yes"],
1923         [AC_DEFINE([MIN_DF], 1, [Report minimum OST free space])])
1924
1925 AC_MSG_CHECKING([whether to randomly failing memory alloc])
1926 AC_ARG_ENABLE([fail_alloc],
1927         AC_HELP_STRING([--disable-fail-alloc],
1928                 [disable randomly alloc failure]),
1929         [], [enable_fail_alloc="yes"])
1930 AC_MSG_RESULT([$enable_fail_alloc])
1931 AS_IF([test "x$enable_fail_alloc" != xno],
1932         [AC_DEFINE([RANDOM_FAIL_ALLOC], 1,
1933                 [enable randomly alloc failure])])
1934
1935 AC_MSG_CHECKING([whether to check invariants (expensive cpu-wise)])
1936 AC_ARG_ENABLE([invariants],
1937         AC_HELP_STRING([--enable-invariants],
1938                 [enable invariant checking (cpu intensive)]),
1939         [], [enable_invariants="no"])
1940 AC_MSG_RESULT([$enable_invariants])
1941 AS_IF([test "x$enable_invariants" = xyes],
1942         [AC_DEFINE([CONFIG_LUSTRE_DEBUG_EXPENSIVE_CHECK], 1,
1943                 [enable invariant checking])])
1944
1945 AC_MSG_CHECKING([whether to track references with lu_ref])
1946 AC_ARG_ENABLE([lu_ref],
1947         AC_HELP_STRING([--enable-lu_ref],
1948                 [enable lu_ref reference tracking code]),
1949         [], [enable_lu_ref="no"])
1950 AC_MSG_RESULT([$enable_lu_ref])
1951 AS_IF([test "x$enable_lu_ref" = xyes],
1952         [AC_DEFINE([USE_LU_REF], 1,
1953                 [enable lu_ref reference tracking code])])
1954
1955 AC_MSG_CHECKING([whether to enable page state tracking])
1956 AC_ARG_ENABLE([pgstate-track],
1957         AC_HELP_STRING([--enable-pgstate-track],
1958                 [enable page state tracking]),
1959         [], [enable_pgstat_track="no"])
1960 AC_MSG_RESULT([$enable_pgstat_track])
1961 AS_IF([test "x$enable_pgstat_track" = xyes],
1962         [AC_DEFINE([CONFIG_DEBUG_PAGESTATE_TRACKING], 1,
1963                 [enable page state tracking code])])
1964 ]) # LC_CONFIGURE
1965
1966 #
1967 # LC_CONDITIONALS
1968 #
1969 # AM_CONDITIONALS for lustre
1970 #
1971 AC_DEFUN([LC_CONDITIONALS], [
1972 AM_CONDITIONAL(LIBLUSTRE, false)
1973 AM_CONDITIONAL(MPITESTS, test x$enable_mpitests = xyes, Build MPI Tests)
1974 AM_CONDITIONAL(CLIENT, test x$enable_client = xyes)
1975 AM_CONDITIONAL(SERVER, test x$enable_server = xyes)
1976 AM_CONDITIONAL(SPLIT, test x$enable_split = xyes)
1977 AM_CONDITIONAL(BLKID, test x$ac_cv_header_blkid_blkid_h = xyes)
1978 AM_CONDITIONAL(EXT2FS_DEVEL, test x$ac_cv_header_ext2fs_ext2fs_h = xyes)
1979 AM_CONDITIONAL(GSS, test x$enable_gss = xyes)
1980 AM_CONDITIONAL(GSS_KEYRING, test x$enable_gss_keyring = xyes)
1981 AM_CONDITIONAL(GSS_PIPEFS, test x$enable_gss_pipefs = xyes)
1982 AM_CONDITIONAL(LIBPTHREAD, test x$enable_libpthread = xyes)
1983 AM_CONDITIONAL(LLITE_LLOOP, test x$enable_llite_lloop_module = xyes)
1984 ]) # LC_CONDITIONALS
1985
1986 #
1987 # LC_CONFIG_FILES
1988 #
1989 # files that should be generated with AC_OUTPUT
1990 #
1991 AC_DEFUN([LC_CONFIG_FILES],
1992 [AC_CONFIG_FILES([
1993 lustre/Makefile
1994 lustre/autoMakefile
1995 lustre/autoconf/Makefile
1996 lustre/conf/Makefile
1997 lustre/contrib/Makefile
1998 lustre/doc/Makefile
1999 lustre/include/Makefile
2000 lustre/include/lustre_ver.h
2001 lustre/include/lustre/Makefile
2002 lustre/kernel_patches/targets/3.10-rhel7.target
2003 lustre/kernel_patches/targets/2.6-rhel6.6.target
2004 lustre/kernel_patches/targets/2.6-rhel6.target
2005 lustre/kernel_patches/targets/2.6-rhel5.target
2006 lustre/kernel_patches/targets/2.6-sles11.target
2007 lustre/kernel_patches/targets/3.0-sles11.target
2008 lustre/kernel_patches/targets/3.0-sles11sp3.target
2009 lustre/kernel_patches/targets/2.6-fc11.target
2010 lustre/kernel_patches/targets/2.6-fc12.target
2011 lustre/kernel_patches/targets/2.6-fc15.target
2012 lustre/kernel_patches/targets/3.x-fc18.target
2013 lustre/ldlm/Makefile
2014 lustre/fid/Makefile
2015 lustre/fid/autoMakefile
2016 lustre/llite/Makefile
2017 lustre/llite/autoMakefile
2018 lustre/lov/Makefile
2019 lustre/lov/autoMakefile
2020 lustre/mdc/Makefile
2021 lustre/mdc/autoMakefile
2022 lustre/lmv/Makefile
2023 lustre/lmv/autoMakefile
2024 lustre/lfsck/Makefile
2025 lustre/lfsck/autoMakefile
2026 lustre/mdt/Makefile
2027 lustre/mdt/autoMakefile
2028 lustre/mdd/Makefile
2029 lustre/mdd/autoMakefile
2030 lustre/fld/Makefile
2031 lustre/fld/autoMakefile
2032 lustre/obdclass/Makefile
2033 lustre/obdclass/autoMakefile
2034 lustre/obdclass/linux/Makefile
2035 lustre/obdecho/Makefile
2036 lustre/obdecho/autoMakefile
2037 lustre/ofd/Makefile
2038 lustre/ofd/autoMakefile
2039 lustre/osc/Makefile
2040 lustre/osc/autoMakefile
2041 lustre/ost/Makefile
2042 lustre/ost/autoMakefile
2043 lustre/osd-ldiskfs/Makefile
2044 lustre/osd-ldiskfs/autoMakefile
2045 lustre/osd-zfs/Makefile
2046 lustre/osd-zfs/autoMakefile
2047 lustre/mgc/Makefile
2048 lustre/mgc/autoMakefile
2049 lustre/mgs/Makefile
2050 lustre/mgs/autoMakefile
2051 lustre/target/Makefile
2052 lustre/ptlrpc/Makefile
2053 lustre/ptlrpc/autoMakefile
2054 lustre/ptlrpc/gss/Makefile
2055 lustre/ptlrpc/gss/autoMakefile
2056 lustre/quota/Makefile
2057 lustre/quota/autoMakefile
2058 lustre/scripts/Makefile
2059 lustre/tests/Makefile
2060 lustre/tests/mpi/Makefile
2061 lustre/utils/Makefile
2062 lustre/utils/gss/Makefile
2063 lustre/osp/Makefile
2064 lustre/osp/autoMakefile
2065 lustre/lod/Makefile
2066 lustre/lod/autoMakefile
2067 ])
2068 ]) # LC_CONFIG_FILES