Whamcloud - gitweb
8e12090fcf622c61116b4e0045106351ed97098b
[fs/lustre-release.git] / lustre / autoconf / lustre-core.m4
1 #
2 # LC_CONFIG_SRCDIR
3 #
4 # Wrapper for AC_CONFIG_SUBDIR
5 #
6 AC_DEFUN([LC_CONFIG_SRCDIR], [
7 AC_CONFIG_SRCDIR([lustre/obdclass/obdo.c])
8 libcfs_is_module="yes"
9 ldiskfs_is_ext4="yes"
10 ])
11
12 #
13 # LC_PATH_DEFAULTS
14 #
15 # lustre specific paths
16 #
17 AC_DEFUN([LC_PATH_DEFAULTS], [
18 # ptlrpc kernel build requires this
19 LUSTRE="$PWD/lustre"
20 AC_SUBST(LUSTRE)
21
22 # mount.lustre
23 rootsbindir='$(CROSS_PATH)/sbin'
24 AC_SUBST(rootsbindir)
25
26 demodir='$(docdir)/demo'
27 AC_SUBST(demodir)
28
29 pkgexampledir='${pkgdatadir}/examples'
30 AC_SUBST(pkgexampledir)
31 ]) # LC_PATH_DEFAULTS
32
33 #
34 # LC_TARGET_SUPPORTED
35 #
36 # is the target os supported?
37 #
38 AC_DEFUN([LC_TARGET_SUPPORTED], [
39 case $target_os in
40         linux* | darwin*)
41 $1
42                 ;;
43         *)
44 $2
45                 ;;
46 esac
47 ]) # LC_TARGET_SUPPORTED
48
49 #
50 # LC_CONFIG_OBD_BUFFER_SIZE
51 #
52 # the maximum buffer size of lctl ioctls
53 #
54 AC_DEFUN([LC_CONFIG_OBD_BUFFER_SIZE], [
55 AC_MSG_CHECKING([for maximum OBD ioctl size])
56 AC_ARG_WITH([obd-buffer-size],
57         AC_HELP_STRING([--with-obd-buffer-size=[size]],
58                 [set lctl ioctl maximum bytes (default=8192)]),
59         [OBD_BUFFER_SIZE=$with_obd_buffer_size],
60         [OBD_BUFFER_SIZE=8192])
61 AC_MSG_RESULT([$OBD_BUFFER_SIZE bytes])
62 AC_DEFINE_UNQUOTED(CONFIG_LUSTRE_OBD_MAX_IOCTL_BUFFER, $OBD_BUFFER_SIZE,
63         [IOCTL Buffer Size])
64 ]) # LC_CONFIG_OBD_BUFFER_SIZE
65
66 #
67 # LC_GLIBC_SUPPORT_FHANDLES
68 #
69 AC_DEFUN([LC_GLIBC_SUPPORT_FHANDLES], [
70 AC_CHECK_FUNCS([name_to_handle_at],
71         [AC_DEFINE(HAVE_FHANDLE_GLIBC_SUPPORT, 1,
72                 [file handle and related syscalls are supported])],
73         [AC_MSG_WARN([file handle and related syscalls are not supported])])
74 ]) # LC_GLIBC_SUPPORT_FHANDLES
75
76 #
77 # LC_FUNC_DEV_SET_RDONLY
78 #
79 # check whether dev_set_rdonly is exported.  This is needed until we
80 # have another mechanism to fence IO from the underlying device.
81 #
82 AC_DEFUN([LC_FUNC_DEV_SET_RDONLY], [
83 LB_CHECK_EXPORT([dev_set_rdonly], [block/ll_rw_block.c block/blk-core.c],
84         [AC_DEFINE(HAVE_DEV_SET_RDONLY, 1,
85                 [kernel exports dev_set_rdonly])],
86         [AC_MSG_WARN([kernel missing dev_set_rdonly patch for testing])])
87 ]) # LC_FUNC_DEV_SET_RDONLY
88
89 #
90 # LC_STACK_SIZE
91 #
92 # Ensure stack size big than 8k in Lustre server (all kernels)
93 #
94 AC_DEFUN([LC_STACK_SIZE], [
95 LB_CHECK_COMPILE([if stack size big than 8k],
96 stack_size_8k, [
97         #include <linux/thread_info.h>
98 ], [
99         #if THREAD_SIZE < 8192
100         #error "stack size < 8192"
101         #endif
102 ], [], [AC_MSG_ERROR([
103
104 Lustre requires that Linux is configured with at least a 8KB stack.
105 ])])
106 ]) # LC_STACK_SIZE
107
108 #
109 # LC_MDS_MAX_THREADS
110 #
111 # Allow the user to set the MDS thread upper limit
112 #
113 AC_DEFUN([LC_MDS_MAX_THREADS], [
114 AC_MSG_CHECKING([for maximum number of MDS threads])
115 AC_ARG_WITH([mds_max_threads],
116         AC_HELP_STRING([--with-mds-max-threads=count],
117                 [maximum threads available on the MDS: (default=512)]),
118         [AC_DEFINE_UNQUOTED(MDS_MAX_THREADS, $with_mds_max_threads,
119                 [maximum number of MDS threads])])
120 AC_MSG_RESULT([$with_mds_max_threads])
121 ]) # LC_MDS_MAX_THREADS
122
123 #
124 # LC_CONFIG_PINGER
125 #
126 # the pinger is temporary, until we have the recovery node in place
127 #
128 AC_DEFUN([LC_CONFIG_PINGER], [
129 AC_MSG_CHECKING([whether to enable Lustre pinger support])
130 AC_ARG_ENABLE([pinger],
131         AC_HELP_STRING([--disable-pinger],
132                 [disable recovery pinger support]),
133         [], [enable_pinger="yes"])
134 AC_MSG_RESULT([$enable_pinger])
135 AS_IF([test "x$enable_pinger" != xno],
136         [AC_DEFINE(ENABLE_PINGER, 1,[Use the Pinger])])
137 ]) # LC_CONFIG_PINGER
138
139 #
140 # LC_CONFIG_CHECKSUM
141 #
142 # do checksum of bulk data between client and OST
143 #
144 AC_DEFUN([LC_CONFIG_CHECKSUM], [
145 AC_MSG_CHECKING([whether to enable data checksum support])
146 AC_ARG_ENABLE([checksum],
147         AC_HELP_STRING([--disable-checksum],
148                 [disable data checksum support]),
149         [], [enable_checksum="yes"])
150 AC_MSG_RESULT([$enable_checksum])
151 AS_IF([test "x$enable_checksum" != xno],
152         [AC_DEFINE(ENABLE_CHECKSUM, 1, [do data checksums])])
153 ]) # LC_CONFIG_CHECKSUM
154
155 #
156 # LC_CONFIG_HEALTH_CHECK_WRITE
157 #
158 # Turn off the actual write to the disk
159 #
160 AC_DEFUN([LC_CONFIG_HEALTH_CHECK_WRITE], [
161 AC_MSG_CHECKING([whether to enable a write with the health check])
162 AC_ARG_ENABLE([health_write],
163         AC_HELP_STRING([--enable-health_write],
164                 [enable disk writes when doing health check]),
165         [], [enable_health_write="no"])
166 AC_MSG_RESULT([$enable_health_write])
167 AS_IF([test "x$enable_health_write" != xno],
168         [AC_DEFINE(USE_HEALTH_CHECK_WRITE, 1, [Write when Checking Health])])
169 ]) # LC_CONFIG_HEALTH_CHECK_WRITE
170
171 #
172 # LC_CONFIG_LRU_RESIZE
173 #
174 AC_DEFUN([LC_CONFIG_LRU_RESIZE], [
175 AC_MSG_CHECKING([whether to enable lru self-adjusting])
176 AC_ARG_ENABLE([lru_resize],
177         AC_HELP_STRING([--enable-lru-resize],
178                 [enable lru resize support]),
179         [], [enable_lru_resize="yes"])
180 AC_MSG_RESULT([$enable_lru_resize])
181 AS_IF([test "x$enable_lru_resize" != xno],
182         [AC_DEFINE(HAVE_LRU_RESIZE_SUPPORT, 1, [Enable lru resize support])])
183 ]) # LC_CONFIG_LRU_RESIZE
184
185 #
186 # LC_QUOTA_CONFIG
187 #
188 # Quota support. The kernel must support CONFIG_QUOTA.
189 #
190 AC_DEFUN([LC_QUOTA_CONFIG], [
191 LB_CHECK_CONFIG_IM([QUOTA], [],
192         [AC_MSG_ERROR([
193
194 Lustre quota requires that CONFIG_QUOTA is enabled in your kernel.
195 ])])
196 ]) # LC_QUOTA_CONFIG
197
198 #
199 # LC_EXPORT_TRUNCATE_COMPLETE_PAGE
200 #
201 # truncate_complete_page() has never been exported from an upstream kernel
202 # remove_from_page_cache() was exported between 2.6.35 and 2.6.38
203 # delete_from_page_cache() is exported from 2.6.39
204 #
205 AC_DEFUN([LC_EXPORT_TRUNCATE_COMPLETE_PAGE], [
206 LB_CHECK_EXPORT([truncate_complete_page], [mm/truncate.c],
207         [AC_DEFINE(HAVE_TRUNCATE_COMPLETE_PAGE, 1,
208                 [kernel export truncate_complete_page])])
209 LB_CHECK_EXPORT([remove_from_page_cache], [mm/filemap.c],
210         [AC_DEFINE(HAVE_REMOVE_FROM_PAGE_CACHE, 1,
211                 [kernel export remove_from_page_cache])])
212 LB_CHECK_EXPORT([delete_from_page_cache], [mm/filemap.c],
213         [AC_DEFINE(HAVE_DELETE_FROM_PAGE_CACHE, 1,
214                 [kernel export delete_from_page_cache])])
215 ]) # LC_EXPORT_TRUNCATE_COMPLETE_PAGE
216
217 #
218 # LC_CAPA_CRYPTO
219 #
220 AC_DEFUN([LC_CAPA_CRYPTO], [
221 LB_CHECK_CONFIG_IM([CRYPTO], [],
222         [AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO is enabled in your kernel.])])
223 LB_CHECK_CONFIG_IM([CRYPTO_HMAC], [],
224         [AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO_HMAC is enabled in your kernel.])])
225 LB_CHECK_CONFIG_IM([CRYPTO_SHA1], [],
226         [AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO_SHA1 is enabled in your kernel.])])
227 ]) # LC_CAPA_CRYPTO
228
229 #
230 # LC_CONFIG_RMTCLIENT
231 #
232 dnl FIXME
233 dnl the AES symbol usually tied with arch, e.g. CRYPTO_AES_586
234 dnl FIXME
235 AC_DEFUN([LC_CONFIG_RMTCLIENT], [
236 LB_CHECK_CONFIG_IM([CRYPTO_AES], [],
237         [AC_MSG_WARN([
238
239 Lustre remote client require that CONFIG_CRYPTO_AES is enabled in your kernel.
240 ])])
241 ]) # LC_CONFIG_RMTCLIENT
242
243 #
244 # LC_CONFIG_GSS_KEYRING
245 #
246 # default 'auto', tests for dependencies, if found, enables;
247 # only called if gss is enabled
248 #
249 AC_DEFUN([LC_CONFIG_GSS_KEYRING], [
250 AC_MSG_CHECKING([whether to enable gss keyring backend])
251 AC_ARG_ENABLE([gss_keyring],
252         [AC_HELP_STRING([--disable-gss-keyring],
253                 [disable gss keyring backend])],
254         [], [enable_gss_keyring="auto"])
255 AC_MSG_RESULT([$enable_gss_keyring])
256 AS_IF([test "x$enable_gss_keyring" != xno], [
257         LB_CHECK_CONFIG_IM([KEYS], [], [
258                 gss_keyring_conf_test="fail"
259                 AC_MSG_WARN([
260
261 GSS keyring backend require that CONFIG_KEYS be enabled in your kernel.
262 ])])
263
264         AC_CHECK_LIB([keyutils], [keyctl_search], [], [
265                 gss_keyring_conf_test="fail"
266                 AC_MSG_WARN([
267
268 libkeyutils is not found, which is required by gss keyring backend
269 ])])
270
271         AS_IF([test "x$gss_keyring_conf_test" != xfail], [
272                 AC_DEFINE([HAVE_GSS_KEYRING], [1],
273                         [Define this if you enable gss keyring backend])
274                 enable_gss_keyring="yes"
275         ], [
276                 AS_IF([test "x$enable_gss_keyring" = xyes], [
277                         AC_MSG_ERROR([
278
279 Cannot enable gss_keyring. See above for details.
280 ])
281                 ], [
282                         AC_MSG_WARN([
283
284 Cannot enable gss keyring. See above for details.
285 ])
286                 ])
287         ])
288 ])
289 ]) # LC_CONFIG_GSS_KEYRING
290
291 #
292 # LC_CONFIG_SUNRPC
293 #
294 AC_DEFUN([LC_CONFIG_SUNRPC], [
295 LB_CHECK_CONFIG_IM([SUNRPC], [], [
296         AS_IF([test "x$sunrpc_required" = xyes], [
297                 AC_MSG_ERROR([
298
299 kernel SUNRPC support is required by using GSS.
300 ])
301         ])])
302 ]) # LC_CONFIG_SUNRPC
303
304 #
305 # LC_CONFIG_GSS (default 'auto' (tests for dependencies, if found, enables))
306 #
307 # Build gss and related tools of Lustre. Currently both kernel and user space
308 # parts are depend on linux platform.
309 #
310 AC_DEFUN([LC_CONFIG_GSS], [
311 AC_MSG_CHECKING([whether to enable gss/krb5 support])
312 AC_ARG_ENABLE([gss],
313         [AC_HELP_STRING([--enable-gss], [enable gss/krb5 support])],
314         [], [enable_gss="auto"])
315 AC_MSG_RESULT([$enable_gss])
316
317 AS_IF([test "x$enable_gss" != xno], [
318         LC_CONFIG_GSS_KEYRING
319         sunrpc_required=$enable_gss
320         LC_CONFIG_SUNRPC
321         sunrpc_required="no"
322
323         LB_CHECK_CONFIG_IM([CRYPTO_MD5], [],
324                 [AC_MSG_WARN([kernel MD5 support is recommended by using GSS.])])
325         LB_CHECK_CONFIG_IM([CRYPTO_SHA1], [],
326                 [AC_MSG_WARN([kernel SHA1 support is recommended by using GSS.])])
327         LB_CHECK_CONFIG_IM([CRYPTO_SHA256], [],
328                 [AC_MSG_WARN([kernel SHA256 support is recommended by using GSS.])])
329         LB_CHECK_CONFIG_IM([CRYPTO_SHA512], [],
330                 [AC_MSG_WARN([kernel SHA512 support is recommended by using GSS.])])
331
332         require_krb5=$enable_gss
333         AC_KERBEROS_V5
334         require_krb5="no"
335
336         AS_IF([test -n "$KRBDIR"], [
337                 AC_CHECK_LIB([gssapi], [gss_export_lucid_sec_context], [
338                         GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssapi"
339                         gss_conf_test="success"
340                 ], [
341                         AC_CHECK_LIB([gssglue], [gss_export_lucid_sec_context], [
342                                 GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssglue"
343                                 gss_conf_test="success"
344                         ], [
345                                 AS_IF([test "x$enable_gss" = xyes], [
346                                         AC_MSG_ERROR([
347
348 libgssapi or libgssglue is not found, which is required by GSS.
349 ])
350                                 ], [
351                                         AC_MSG_WARN([
352
353 libgssapi or libgssglue is not found, which is required by GSS.
354 ])
355                                 ])
356                         ])
357                 ])
358                 AC_SUBST(GSSAPI_LIBS)
359         ])
360
361         AS_IF([test "x$gss_conf_test" = xsuccess], [
362                 AC_DEFINE([HAVE_GSS], [1], [Define this is if you enable gss])
363                 enable_gss="yes"
364         ])
365 ])
366 ]) # LC_CONFIG_GSS
367
368 #
369 # LC_INODE_PERMISION_2ARGS
370 #
371 # up to v2.6.27 had a 3 arg version (inode, mask, nameidata)
372 # v2.6.27->v2.6.37 had a 2 arg version (inode, mask)
373 # v2.6.37->v3.0 had a 3 arg version (inode, mask, nameidata)
374 # v3.1 onward have a 2 arg version (inode, mask)
375 #
376 AC_DEFUN([LC_INODE_PERMISION_2ARGS], [
377 LB_CHECK_COMPILE([if 'inode_operations->permission' has two args],
378 inode_ops_permission_2args, [
379         #include <linux/fs.h>
380 ],[
381         struct inode *inode __attribute__ ((unused));
382
383         inode = NULL;
384         inode->i_op->permission(NULL, 0);
385 ],[
386         AC_DEFINE(HAVE_INODE_PERMISION_2ARGS, 1,
387                 [inode_operations->permission has two args])
388 ])
389 ]) # LC_INODE_PERMISION_2ARGS
390
391 #
392 # LC_BLK_QUEUE_MAX_SEGMENTS
393 #
394 # 2.6.32 replaces 2 functions blk_queue_max_phys_segments and blk_queue_max_hw_segments by blk_queue_max_segments
395 #
396 AC_DEFUN([LC_BLK_QUEUE_MAX_SEGMENTS], [
397 LB_CHECK_COMPILE([if 'blk_queue_max_segments' is defined],
398 blk_queue_max_segments, [
399         #include <linux/blkdev.h>
400 ],[
401         blk_queue_max_segments(NULL, 0);
402 ],[
403         AC_DEFINE(HAVE_BLK_QUEUE_MAX_SEGMENTS, 1,
404                 [blk_queue_max_segments is defined])
405 ])
406 ]) # LC_BLK_QUEUE_MAX_SEGMENTS
407
408 #
409 # LC_HAVE_DQUOT_FS_DISK_QUOTA
410 #
411 # 2.6.34 has quotactl_ops->[sg]et_dqblk that take struct fs_disk_quota
412 #
413 AC_DEFUN([LC_HAVE_DQUOT_FS_DISK_QUOTA], [
414 tmp_flags="$EXTRA_KCFLAGS"
415 EXTRA_KCFLAGS="-Werror"
416 LB_CHECK_COMPILE([if 'quotactl_ops.set_dqblk' takes struct fs_disk_quota],
417 fs_disk_quota, [
418         #include <linux/fs.h>
419         #include <linux/quota.h>
420 ],[
421         ((struct quotactl_ops *)0)->set_dqblk(NULL, 0, 0, (struct fs_disk_quota*)0);
422 ],[
423         AC_DEFINE(HAVE_DQUOT_FS_DISK_QUOTA, 1,
424                 [quotactl_ops.set_dqblk takes struct fs_disk_quota])
425 ],[
426         LB_CHECK_COMPILE([if 'quotactl_ops.set_dqblk' takes struct kqid & fs_disk_quota],
427         kqid_fs_disk_quota, [
428                 #include <linux/fs.h>
429                 #include <linux/quota.h>
430         ],[
431                 ((struct quotactl_ops *)0)->set_dqblk((struct super_block*)0, *((struct kqid*)0), (struct fs_disk_quota*)0);
432         ],[
433                 AC_DEFINE(HAVE_DQUOT_FS_DISK_QUOTA, 1,
434                         [quotactl_ops.set_dqblk takes struct fs_disk_quota])
435                 AC_DEFINE(HAVE_DQUOT_KQID, 1,
436                         [quotactl_ops.set_dqblk takes struct kqid])
437         ])
438 ])
439 EXTRA_KCFLAGS="$tmp_flags"
440 ]) # LC_HAVE_DQUOT_FS_DISK_QUOTA
441
442 #
443 # LC_HAVE_DQUOT_SUSPEND
444 #
445 # 2.6.34 has renamed dquot options to dquot_*, check for dquot_suspend
446 #
447 AC_DEFUN([LC_HAVE_DQUOT_SUSPEND], [
448 LB_CHECK_COMPILE([if 'dquot_suspend' is defined],
449 dquot_suspend, [
450         #include <linux/quotaops.h>
451 ],[
452         dquot_suspend(NULL, -1);
453 ],[
454         AC_DEFINE(HAVE_DQUOT_SUSPEND, 1, [dquot_suspend is defined])
455 ])
456 ]) # LC_HAVE_DQUOT_SUSPEND
457
458 #
459 # LC_QUOTA64
460 #
461 # Check if kernel has been patched for 64-bit quota limits support.
462 # The upstream version of this patch in RHEL6 2.6.32 kernels introduces
463 # the constant QFMT_VFS_V1 in include/linux/quota.h, so we can check for
464 # that in the absence of quotaio_v1.h in the kernel headers.
465 #
466 AC_DEFUN([LC_QUOTA64], [
467 tmp_flags="$EXTRA_KCFLAGS"
468 EXTRA_KCFLAGS="-I$LINUX/fs"
469 LB_CHECK_COMPILE([if kernel has 64-bit quota limits support],
470 quota64, [
471         #include <linux/kernel.h>
472         #include <linux/fs.h>
473         #if defined(HAVE_FS_QUOTA_QUOTAIO_H)
474         #include <quota/quotaio_v2.h>
475         struct v2r1_disk_dqblk dqblk_r1;
476         #else
477         #include <linux/quota.h>
478         int ver = QFMT_VFS_V1;
479         #endif
480 ], [], [
481         AC_DEFINE(HAVE_QUOTA64, 1, [have quota64])
482 ],[
483         LB_CHECK_FILE([$LINUX/include/linux/lustre_version.h],
484                 [AC_MSG_ERROR([You have got no 64-bit kernel quota support.])])
485 ])
486 EXTRA_KCFLAGS=$tmp_flags
487 ]) # LC_QUOTA64
488
489 #
490 # LC_FS_STRUCT_RWLOCK
491 #
492 # 2.6.36 fs_struct.lock use spinlock instead of rwlock.
493 #
494 AC_DEFUN([LC_FS_STRUCT_RWLOCK], [
495 LB_CHECK_COMPILE([if 'fs_struct.lock' use rwlock],
496 fs_struct_rwlock, [
497         #include <asm/atomic.h>
498         #include <linux/spinlock.h>
499         #include <linux/fs_struct.h>
500 ],[
501         ((struct fs_struct *)0)->lock = (rwlock_t){ 0 };
502 ],[
503         AC_DEFINE(HAVE_FS_STRUCT_RWLOCK, 1, [fs_struct.lock use rwlock])
504 ])
505 ]) # LC_FS_STRUCT_RWLOCK
506
507 #
508 # LC_SBOPS_EVICT_INODE
509 #
510 # 2.6.36 super_operations add evict_inode method. it hybird of
511 # delete_inode & clear_inode.
512 #
513 AC_DEFUN([LC_SBOPS_EVICT_INODE], [
514 LB_CHECK_COMPILE([if 'super_operations.evict_inode' exist],
515 super_ops_evict_inode, [
516         #include <linux/fs.h>
517 ],[
518         ((struct super_operations *)0)->evict_inode(NULL);
519 ],[
520         AC_DEFINE(HAVE_SBOPS_EVICT_INODE, 1,
521                 [super_operations.evict_inode() is exist in kernel])
522 ])
523 ]) # LC_SBOPS_EVICT_INODE
524
525 #
526 # LC_FILE_FSYNC
527 #
528 # 2.6.35 file_operations.fsync taken 2 arguments.
529 # 3.0.0 file_operations.fsync takes 4 arguments.
530 #
531 AC_DEFUN([LC_FILE_FSYNC], [
532 LB_CHECK_COMPILE([if 'file_operations.fsync' takes 4 arguments],
533 file_ops_fsync_4args, [
534         #include <linux/fs.h>
535 ],[
536         ((struct file_operations *)0)->fsync(NULL, 0, 0, 0);
537 ],[
538         AC_DEFINE(HAVE_FILE_FSYNC_4ARGS, 1,
539                 [file_operations.fsync takes 4 arguments])
540 ],[
541         LB_CHECK_COMPILE([if 'file_operations.fsync' takes 2 arguments],
542         file_ops_fsync_2args, [
543                 #include <linux/fs.h>
544         ],[
545                 ((struct file_operations *)0)->fsync(NULL, 0);
546         ],[
547                 AC_DEFINE(HAVE_FILE_FSYNC_2ARGS, 1,
548                         [file_operations.fsync takes 2 arguments])
549         ])
550 ])
551 ]) # LC_FILE_FSYNC
552
553 #
554 # LC_KERNEL_LOCKED
555 #
556 # 2.6.37 remove kernel_locked
557 #
558 AC_DEFUN([LC_KERNEL_LOCKED], [
559 LB_CHECK_COMPILE([if 'kernel_locked' is defined],
560 kernel_locked, [
561         #include <linux/smp_lock.h>
562 ],[
563         kernel_locked();
564 ],[
565         AC_DEFINE(HAVE_KERNEL_LOCKED, 1, [kernel_locked is defined])
566 ])
567 ]) # LC_KERNEL_LOCKED
568
569 #
570 # LC_D_COMPARE_7ARGS
571 #
572 # 2.6.38 dentry_operations.d_compare() taken 7 arguments.
573 #
574 AC_DEFUN([LC_D_COMPARE_7ARGS], [
575 LB_CHECK_COMPILE([if 'dentry_operations.d_compare()' taken 7 arguments],
576 dentry_ops_d_compare_7arg, [
577         #include <linux/dcache.h>
578 ],[
579         ((struct dentry_operations*)0)->d_compare(NULL,NULL,NULL,NULL,0,NULL,NULL);
580 ],[
581         AC_DEFINE(HAVE_D_COMPARE_7ARGS, 1, [d_compare need 7 arguments])
582 ])
583 ]) # LC_D_COMPARE_7ARGS
584
585 #
586 # LC_D_DELETE_CONST
587 #
588 # 2.6.38 dentry_operations.d_delete() defined 'const' for 1st parameter.
589 #
590 AC_DEFUN([LC_D_DELETE_CONST], [
591 tmp_flags="$EXTRA_KCFLAGS"
592 EXTRA_KCFLAGS="-Werror"
593 LB_CHECK_COMPILE([if 'dentry_operations.d_delete()' has const declare on first parameter],
594 dentry_ops_d_delete_1st_const, [
595         #include <linux/dcache.h>
596 ],[
597         const struct dentry *d = NULL;
598         ((struct dentry_operations*)0)->d_delete(d);
599 ],[
600         AC_DEFINE(HAVE_D_DELETE_CONST, const,
601                 [d_delete first parameter declared const])
602 ],[
603         AC_DEFINE(HAVE_D_DELETE_CONST, [],
604                 [d_delete first parameter declared is not const])
605 ])
606 EXTRA_KCFLAGS="$tmp_flags"
607 ]) # LC_D_DELETE_CONST
608
609 #
610 # LC_DCACHE_LOCK
611 #
612 # 2.6.38 dcache_lock removed. rcu-walk commited.
613 #
614 AC_DEFUN([LC_DCACHE_LOCK], [
615 LB_CHECK_COMPILE([if 'dcache_lock' is exist],
616 dcache_lock, [
617         #include <linux/dcache.h>
618 ],[
619         spin_lock(&dcache_lock);
620 ],[
621         AC_DEFINE(HAVE_DCACHE_LOCK, 1,
622                 [dcache_lock is exist])
623 ])
624 ]) # LC_DCACHE_LOCK
625
626 #
627 # LC_INODE_I_RCU
628 #
629 # 2.6.38 inode.i_rcu added.
630 #
631 AC_DEFUN([LC_INODE_I_RCU], [
632 LB_CHECK_COMPILE([if 'inode.i_rcu' exists],
633 inode_i_rcu, [
634         #include <linux/fs.h>
635 ],[
636         struct inode ino;
637         struct rcu_head rcu = {};
638         ino.i_rcu = rcu;
639 ],[
640         AC_DEFINE(HAVE_INODE_I_RCU, 1,
641                 [inode.i_rcu exists])
642 ])
643 ]) # LC_INODE_I_RCU
644
645 #
646 # LC_BLKDEV_GET_BY_DEV
647 #
648 # 2.6.38 export blkdev_get_by_dev
649 #
650 AC_DEFUN([LC_BLKDEV_GET_BY_DEV], [
651 LB_CHECK_EXPORT([blkdev_get_by_dev], [fs/block_dev.c],
652         [AC_DEFINE(HAVE_BLKDEV_GET_BY_DEV, 1,
653                 [blkdev_get_by_dev is exported by the kernel])])
654 ]) # LC_BLKDEV_GET_BY_DEV
655
656 #
657 # LC_EXPORT_SIMPLE_SETATTR
658 #
659 # 2.6.38 export simple_setattr
660 #
661 AC_DEFUN([LC_EXPORT_SIMPLE_SETATTR], [
662 LB_CHECK_EXPORT([simple_setattr], [fs/libfs.c],
663         [AC_DEFINE(HAVE_SIMPLE_SETATTR, 1,
664                 [simple_setattr is exported by the kernel])])
665 ]) # LC_EXPORT_SIMPLE_SETATTR
666
667 #
668 # LC_IOP_TRUNCATE
669 #
670 # truncate callback removed since 2.6.39
671 #
672 AC_DEFUN([LC_IOP_TRUNCATE], [
673 LB_CHECK_COMPILE([if 'inode_operations' has '.truncate' member function],
674 inode_ops_truncate, [
675         #include <linux/fs.h>
676 ],[
677         ((struct inode_operations *)0)->truncate(NULL);
678 ],[
679         AC_DEFINE(HAVE_INODEOPS_TRUNCATE, 1,
680                 [inode_operations has .truncate member function])
681 ])
682 ]) # LC_IOP_TRUNCATE
683
684 #
685 # LC_REQUEST_QUEUE_UNPLUG_FN
686 #
687 # 2.6.39 remove unplug_fn from request_queue.
688 #
689 AC_DEFUN([LC_REQUEST_QUEUE_UNPLUG_FN], [
690 LB_CHECK_COMPILE([if 'request_queue' has 'unplug_fn' field],
691 request_queue_unplug_fn, [
692         #include <linux/blkdev.h>
693 ],[
694         do {} while(sizeof(((struct request_queue *)0)->unplug_fn));
695 ],[
696         AC_DEFINE(HAVE_REQUEST_QUEUE_UNPLUG_FN, 1,
697                 [request_queue has unplug_fn field])
698 ])
699 ]) # LC_REQUEST_QUEUE_UNPLUG_FN
700
701 #
702 # LC_HAVE_FSTYPE_MOUNT
703 #
704 # 2.6.39 replace get_sb with mount in struct file_system_type
705 #
706 AC_DEFUN([LC_HAVE_FSTYPE_MOUNT], [
707 LB_CHECK_COMPILE([if 'file_system_type' has 'mount' field],
708 file_system_type_mount, [
709         #include <linux/fs.h>
710 ],[
711         struct file_system_type fst;
712         void *i = (void *) fst.mount;
713 ],[
714         AC_DEFINE(HAVE_FSTYPE_MOUNT, 1,
715                 [struct file_system_type has mount field])
716 ])
717 ]) # LC_HAVE_FSTYPE_MOUNT
718
719 #
720 # LC_HAVE_FHANDLE_SYSCALLS
721 #
722 # 2.6.39 The open_by_handle_at() and name_to_handle_at() system calls were
723 # added to Linux kernel 2.6.39.
724 # Check if client supports these functions
725 #
726 AC_DEFUN([LC_HAVE_FHANDLE_SYSCALLS], [
727 LB_CHECK_CONFIG_IM([FHANDLE],[
728         AC_DEFINE(HAVE_FHANDLE_SYSCALLS, 1,
729                 [kernel supports fhandles and related syscalls])
730         ])
731 ]) # LC_HAVE_FHANDLE_SYSCALLS
732
733 #
734 # LC_HAVE_INODE_OWNER_OR_CAPABLE
735 #
736 # 2.6.39 renames is_owner_or_cap to inode_owner_or_capable
737 #
738 AC_DEFUN([LC_HAVE_INODE_OWNER_OR_CAPABLE], [
739 LB_CHECK_COMPILE([if 'inode_owner_or_capable' exist],
740 inode_owner_or_capable, [
741         #include <linux/fs.h>
742 ],[
743         inode_owner_or_capable(NULL);
744 ],[
745         AC_DEFINE(HAVE_INODE_OWNER_OR_CAPABLE, 1,
746                 [inode_owner_or_capable exist])
747 ])
748 ]) # LC_HAVE_INODE_OWNER_OR_CAPABLE
749
750 #
751 # LC_DIRTY_INODE_WITH_FLAG
752 #
753 # 3.0 dirty_inode() has a flag parameter
754 # see kernel commit aa38572954ade525817fe88c54faebf85e5a61c0
755 #
756 AC_DEFUN([LC_DIRTY_INODE_WITH_FLAG], [
757 LB_CHECK_COMPILE([if 'dirty_inode' super_operation takes flag],
758 dirty_inode_super_operation_flag, [
759         #include <linux/fs.h>
760 ],[
761         struct inode *inode;
762         inode->i_sb->s_op->dirty_inode(NULL, 0);
763 ],[
764         AC_DEFINE(HAVE_DIRTY_INODE_HAS_FLAG, 1,
765                 [dirty_inode super_operation takes flag])
766 ])
767 ]) # LC_DIRTY_INODE_WITH_FLAG
768
769 #
770 # LC_GENERIC_PERMISSION
771 #
772 # 2.6.38 generic_permission taken 4 parameters.
773 # in fact, it means rcu-walk aware permission bring.
774 #
775 # 3.1 generic_permission taken 2 parameters.
776 # see kernel commit 2830ba7f34ebb27c4e5b8b6ef408cd6d74860890
777 #
778 AC_DEFUN([LC_GENERIC_PERMISSION], [
779 LB_CHECK_COMPILE([if 'generic_permission' take 2 arguments],
780 generic_permission_2args, [
781         #include <linux/fs.h>
782 ],[
783         generic_permission(NULL, 0);
784 ],[
785         AC_DEFINE(HAVE_GENERIC_PERMISSION_2ARGS, 1,
786                 [generic_permission taken 2 arguments])
787 ],[
788         LB_CHECK_COMPILE([if 'generic_permission' take 4 arguments],
789         generic_permission_4args, [
790                 #include <linux/fs.h>
791         ],[
792                 generic_permission(NULL, 0, 0, NULL);
793         ],[
794                 AC_DEFINE(HAVE_GENERIC_PERMISSION_4ARGS, 1,
795                         [generic_permission taken 4 arguments])
796         ])
797 ])
798 ]) # LC_GENERIC_PERMISSION
799
800 #
801 # LC_LM_XXX_LOCK_MANAGER_OPS
802 #
803 # 3.1 renames lock-manager ops(lock_manager_operations) from fl_xxx to lm_xxx
804 # see kernel commit 8fb47a4fbf858a164e973b8ea8ef5e83e61f2e50
805 #
806 AC_DEFUN([LC_LM_XXX_LOCK_MANAGER_OPS], [
807 LB_CHECK_COMPILE([if 'lock-manager' ops renamed to 'lm_xxx'],
808 lock_manager_ops_lm_xxx, [
809         #include <linux/fs.h>
810 ],[
811         struct lock_manager_operations lm_ops;
812         lm_ops.lm_compare_owner = NULL;
813 ],[
814         AC_DEFINE(HAVE_LM_XXX_LOCK_MANAGER_OPS, 1,
815                 [lock-manager ops renamed to lm_xxx])
816 ])
817 ]) # LC_LM_XXX_LOCK_MANAGER_OPS
818
819 #
820 # LC_INODE_DIO_WAIT
821 #
822 # 3.1 kills inode->i_alloc_sem, use i_dio_count and inode_dio_wait/
823 #     inode_dio_done instead.
824 # see kernel commit bd5fe6c5eb9c548d7f07fe8f89a150bb6705e8e3
825 #
826 AC_DEFUN([LC_INODE_DIO_WAIT], [
827 LB_CHECK_COMPILE([if 'inode->i_alloc_sem' is killed and use inode_dio_wait/done],
828 inode_dio_wait, [
829         #include <linux/fs.h>
830 ],[
831         inode_dio_wait((struct inode *)0);
832         inode_dio_done((struct inode *)0);
833 ],[
834         AC_DEFINE(HAVE_INODE_DIO_WAIT, 1,
835                 [inode->i_alloc_sem is killed and use inode_dio_wait/done])
836 ])
837 ]) # LC_INODE_DIO_WAIT
838
839 #
840 # LC_IOP_GET_ACL
841 #
842 # 3.1 adds get_acl method to inode_operations to read ACL from disk.
843 # see kernel commit 4e34e719e457f2e031297175410fc0bd4016a085
844 #
845 AC_DEFUN([LC_IOP_GET_ACL], [
846 LB_CHECK_COMPILE([if 'inode_operations' has '.get_acl' member function],
847 inode_ops_get_acl, [
848         #include <linux/fs.h>
849 ],[
850         struct inode_operations iop;
851         iop.get_acl = NULL;
852 ],[
853         AC_DEFINE(HAVE_IOP_GET_ACL, 1,
854                 [inode_operations has .get_acl member function])
855 ])
856 ]) # LC_IOP_GET_ACL
857
858 #
859 # LC_FILE_LLSEEK_SIZE
860 #
861 # 3.1 introduced generic_file_llseek_size()
862 #
863 AC_DEFUN([LC_FILE_LLSEEK_SIZE], [
864 LB_CHECK_EXPORT([generic_file_llseek_size], [fs/read_write.c],
865         [AC_DEFINE(HAVE_FILE_LLSEEK_SIZE, 1,
866                 [generic_file_llseek_size is exported by the kernel])])
867 ]) # LC_FILE_LLSEEK_SIZE
868
869 #
870 # LC_RADIX_EXCEPTION_ENTRY
871 # 3.1 adds radix_tree_exception_entry.
872 #
873 AC_DEFUN([LC_RADIX_EXCEPTION_ENTRY], [
874 LB_CHECK_COMPILE([radix_tree_exceptional_entry exist],
875 radix_tree_exceptional_entry, [
876         #include <linux/radix-tree.h>
877 ],[
878         radix_tree_exceptional_entry(NULL);
879 ],[
880         AC_DEFINE(HAVE_RADIX_EXCEPTION_ENTRY, 1,
881                 [radix_tree_exceptional_entry exist])
882 ])
883 ]) # LC_RADIX_EXCEPTION_ENTRY
884
885 #
886 # LC_HAVE_VOID_MAKE_REQUEST_FN
887 #
888 # 3.2 request_queue.make_request_fn defined as function returns with void
889 # see kernel commit 5a7bbad27a410350e64a2d7f5ec18fc73836c14f
890 #
891 AC_DEFUN([LC_HAVE_VOID_MAKE_REQUEST_FN], [
892 LB_CHECK_COMPILE([if 'request_queue.make_request_fn' returns void but not int],
893 make_request_fn_void, [
894         #include <linux/blkdev.h>
895 ],[
896         int ret;
897         make_request_fn *mrf;
898         ret = mrf(NULL, NULL);
899 ],[],[
900         AC_DEFINE(HAVE_VOID_MAKE_REQUEST_FN, 1,
901                 [request_queue.make_request_fn returns void but not int])
902 ])
903 ]) # LC_HAVE_VOID_MAKE_REQUEST_FN
904
905 #
906 # LC_HAVE_PROTECT_I_NLINK
907 #
908 # 3.2 protects inode->i_nlink from direct modification
909 # see kernel commit a78ef704a8dd430225955f0709b22d4a6ba21deb
910 # at the same time adds set_nlink(), so checks set_nlink() for it.
911 #
912 AC_DEFUN([LC_HAVE_PROTECT_I_NLINK], [
913 LB_CHECK_COMPILE([if 'inode->i_nlink' is protected from direct modification],
914 inode_i_nlink_protected, [
915         #include <linux/fs.h>
916 ],[
917         struct inode i;
918         set_nlink(&i, 1);
919 ],[
920         AC_DEFINE(HAVE_PROTECT_I_NLINK, 1,
921                 [inode->i_nlink is protected from direct modification])
922 ])
923 ]) # LC_HAVE_PROTECT_I_NLINK
924
925 #
926 # LC_HAVE_MIGRATE_HEADER
927 #
928 # 3.3 introduces migrate_mode.h and migratepage has 4 args
929 #
930 AC_DEFUN([LC_HAVE_MIGRATE_HEADER], [
931 LB_CHECK_FILE([$LINUX/include/linux/migrate.h], [
932         AC_DEFINE(HAVE_MIGRATE_H, 1,
933                 [kernel has include/linux/migrate.h])
934 ],[
935         LB_CHECK_FILE([$LINUX/include/linux/migrate_mode.h], [
936                 AC_DEFINE(HAVE_MIGRATE_MODE_H, 1,
937                         [kernel has include/linux/migrate_mode.h])
938         ])
939 ])
940 ]) # LC_HAVE_MIGRATE_HEADER
941
942 #
943 # LC_MIGRATEPAGE_4ARGS
944 #
945 AC_DEFUN([LC_MIGRATEPAGE_4ARGS], [
946 LB_CHECK_COMPILE([if 'address_space_operations.migratepage' has 4 args],
947 address_space_ops_migratepage_4args, [
948         #include <linux/fs.h>
949 #ifdef HAVE_MIGRATE_H
950         #include <linux/migrate.h>
951 #elif defined(HAVE_MIGRATE_MODE_H)
952         #include <linux/migrate_mode.h>
953 #endif
954 ],[
955         struct address_space_operations aops;
956         aops.migratepage(NULL, NULL, NULL, MIGRATE_ASYNC);
957 ],[
958         AC_DEFINE(HAVE_MIGRATEPAGE_4ARGS, 1,
959                 [address_space_operations.migratepage has 4 args])
960 ])
961 ]) # LC_MIGRATEPAGE_4ARGS
962
963 #
964 # LC_SUPEROPS_USE_DENTRY
965 #
966 # 3.3 switchs super_operations to use dentry as parameter (but not vfsmount)
967 # see kernel commit 34c80b1d93e6e20ca9dea0baf583a5b5510d92d4
968 #
969 AC_DEFUN([LC_SUPEROPS_USE_DENTRY], [
970 tmp_flags="$EXTRA_KCFLAGS"
971 EXTRA_KCFLAGS="-Werror"
972 LB_CHECK_COMPILE([if 'super_operations' use 'dentry' as parameter],
973 super_ops_dentry, [
974         #include <linux/fs.h>
975         int show_options(struct seq_file *seq, struct dentry *root) {
976                 return 0;
977         }
978 ],[
979         struct super_operations ops;
980         ops.show_options = show_options;
981 ],[
982         AC_DEFINE(HAVE_SUPEROPS_USE_DENTRY, 1,
983                 [super_operations use dentry as parameter])
984 ])
985 EXTRA_KCFLAGS="$tmp_flags"
986 ]) # LC_SUPEROPS_USE_DENTRY
987
988 #
989 # LC_INODEOPS_USE_UMODE_T
990 #
991 # 3.3 switchs inode_operations to use umode_t as parameter (but not int)
992 # see kernel commit 1a67aafb5f72a436ca044293309fa7e6351d6a35
993 #
994 AC_DEFUN([LC_INODEOPS_USE_UMODE_T], [
995 tmp_flags="$EXTRA_KCFLAGS"
996 EXTRA_KCFLAGS="-Werror"
997 LB_CHECK_COMPILE([if 'inode_operations' use 'umode_t' as parameter],
998 inode_ops_umode_t, [
999         #include <linux/fs.h>
1000         #include <linux/types.h>
1001         int my_mknod(struct inode *dir, struct dentry *dchild,
1002                      umode_t mode, dev_t dev)
1003         {
1004                 return 0;
1005         }
1006 ],[
1007         struct inode_operations ops;
1008         ops.mknod = my_mknod;
1009 ],[
1010         AC_DEFINE(HAVE_INODEOPS_USE_UMODE_T, 1,
1011                 [inode_operations use umode_t as parameter])
1012 ])
1013 EXTRA_KCFLAGS="$tmp_flags"
1014 ]) # LC_INODEOPS_USE_UMODE_T
1015
1016 #
1017 # LC_KMAP_ATOMIC_HAS_1ARG
1018 #
1019 # 3.4 kmap_atomic removes second argument
1020 # see kernel commit 1ec9c5ddc17aa398f05646abfcbaf315b544e62f
1021 #
1022 AC_DEFUN([LC_KMAP_ATOMIC_HAS_1ARG], [
1023 LB_CHECK_COMPILE([if 'kmap_atomic' has only 1 argument],
1024 kmap_atomic_1arg, [
1025         #include <linux/highmem.h>
1026 ],[
1027         kmap_atomic(NULL);
1028 ],[
1029         AC_DEFINE(HAVE_KMAP_ATOMIC_HAS_1ARG, 1,
1030                 [have kmap_atomic has only 1 argument])
1031 ])
1032 ]) # LC_KMAP_ATOMIC_HAS_1ARG
1033
1034 #
1035 # LC_HAVE_D_MAKE_ROOT
1036 #
1037 # 3.4 converts d_alloc_root to d_make_root
1038 # see kernel commit 32991ab305ace7017c62f8eecbe5eb36dc32e13b
1039 #
1040 AC_DEFUN([LC_HAVE_D_MAKE_ROOT], [
1041 LB_CHECK_COMPILE([if have 'd_make_root'],
1042 d_make_root, [
1043         #include <linux/fs.h>
1044 ],[
1045         d_make_root((struct inode *)NULL);
1046 ],[
1047         AC_DEFINE(HAVE_D_MAKE_ROOT, 1,
1048                 [have d_make_root])
1049 ])
1050 ]) # LC_HAVE_D_MAKE_ROOT
1051
1052 #
1053 # LC_HAVE_CACHE_REGISTER
1054 #
1055 # 3.4 cache_register/cache_unregister are removed
1056 # see kernel commit 2c5f846747526e2b83c5f1b8e69016be0e2e87c0
1057 # Note, since 2.6.37 cache_register_net/cache_unregister_net
1058 # are defined, but not exported.
1059 # 3.3 cache_register_net/cache_unregister_net are
1060 # exported and replacing cache_register/cache_unregister in 3.4
1061 #
1062 AC_DEFUN([LC_HAVE_CACHE_REGISTER], [
1063 LB_CHECK_COMPILE([if have 'cache_register'],
1064 cache_register, [
1065         #include <linux/sunrpc/cache.h>
1066 ],[
1067         cache_register(NULL);
1068 ],[
1069         AC_DEFINE(HAVE_CACHE_REGISTER, 1,
1070                 [have cache_register])
1071 ])
1072 ]) # LC_HAVE_CACHE_REGISTER
1073
1074 #
1075 # LC_HAVE_CLEAR_INODE
1076 #
1077 # 3.5 renames end_writeback() back to clear_inode()...
1078 # see kernel commit dbd5768f87ff6fb0a4fe09c4d7b6c4a24de99430
1079 #
1080 AC_DEFUN([LC_HAVE_CLEAR_INODE], [
1081 LB_CHECK_COMPILE([if have 'clear_inode'],
1082 clear_inode, [
1083         #include <linux/fs.h>
1084 ],[
1085         clear_inode((struct inode *)NULL);
1086 ],[
1087         AC_DEFINE(HAVE_CLEAR_INODE, 1,
1088                 [have clear_inode])
1089 ])
1090 ]) # LC_HAVE_CLEAR_INODE
1091
1092 #
1093 # LC_HAVE_ENCODE_FH_PARENT
1094 #
1095 # 3.5 encode_fh has parent inode passed in directly
1096 # see kernel commit b0b0382b
1097 #
1098 AC_DEFUN([LC_HAVE_ENCODE_FH_PARENT], [
1099 tmp_flags="$EXTRA_KCFLAGS"
1100 EXTRA_KCFLAGS="-Werror"
1101 LB_CHECK_COMPILE([if 'encode_fh' have parent inode as parameter],
1102 encode_fh_parent_inode, [
1103         #include <linux/exportfs.h>
1104         #include <linux/fs.h>
1105         #include <linux/types.h>
1106         int ll_encode_fh(struct inode *i, __u32 *a, int *b, struct inode *p)
1107         {
1108                 return 0;
1109         }
1110 ],[
1111         struct export_operations exp_op;
1112         exp_op.encode_fh = ll_encode_fh;
1113 ],[
1114         AC_DEFINE(HAVE_ENCODE_FH_PARENT, 1,
1115                 [have parent inode as parameter])
1116 ])
1117 EXTRA_KCFLAGS="$tmp_flags"
1118 ]) # LC_HAVE_ENCODE_FH_PARENT
1119
1120 #
1121 # LC_FILE_LLSEEK_SIZE_5ARG
1122 #
1123 # 3.5 has generic_file_llseek_size with 5 args
1124 #
1125 AC_DEFUN([LC_FILE_LLSEEK_SIZE_5ARG], [
1126 LB_CHECK_COMPILE([if Linux kernel has 'generic_file_llseek_size' with 5 args],
1127 generic_file_llseek_size_5args, [
1128         #include <linux/fs.h>
1129 ],[
1130         generic_file_llseek_size(NULL, 0, 0, 0, 0);
1131 ], [
1132         AC_DEFINE(HAVE_FILE_LLSEEK_SIZE_5ARGS, 1,
1133                 [kernel has generic_file_llseek_size with 5 args])
1134 ])
1135 ]) # LC_FILE_LLSEEK_SIZE_5ARG
1136
1137 #
1138 # LC_HAVE_DENTRY_D_ALIAS_HLIST
1139 #
1140 # 3.6 switch i_dentry/d_alias from list to hlist
1141 #
1142 AC_DEFUN([LC_HAVE_DENTRY_D_ALIAS_HLIST], [
1143 tmp_flags="$EXTRA_KCFLAGS"
1144 EXTRA_KCFLAGS="-Werror"
1145 LB_CHECK_COMPILE([if 'i_dentry/d_alias' uses 'hlist'],
1146 i_dentry_d_alias_hlist, [
1147         #include <linux/fs.h>
1148         #include <linux/list.h>
1149 ],[
1150         struct inode inode;
1151         struct dentry dentry;
1152         struct hlist_head head;
1153         struct hlist_node node;
1154         inode.i_dentry = head;
1155         dentry.d_alias = node;
1156 ],[
1157         AC_DEFINE(HAVE_DENTRY_D_ALIAS_HLIST, 1,
1158                 [have i_dentry/d_alias uses hlist])
1159 ])
1160 EXTRA_KCFLAGS="$tmp_flags"
1161 ]) # LC_HAVE_DENTRY_D_ALIAS_HLIST
1162
1163 #
1164 # LC_DENTRY_OPEN_USE_PATH
1165 #
1166 # 3.6 dentry_open uses struct path as first argument
1167 # see kernel commit 765927b2
1168 #
1169 AC_DEFUN([LC_DENTRY_OPEN_USE_PATH], [
1170 tmp_flags="$EXTRA_KCFLAGS"
1171 EXTRA_KCFLAGS="-Werror"
1172 LB_CHECK_COMPILE([if 'dentry_open' uses 'struct path' as first argument],
1173 dentry_open_path, [
1174         #include <linux/fs.h>
1175         #include <linux/path.h>
1176 ],[
1177         struct path path;
1178         dentry_open(&path, 0, NULL);
1179 ],[
1180         AC_DEFINE(HAVE_DENTRY_OPEN_USE_PATH, 1,
1181                 [dentry_open uses struct path as first argument])
1182 ])
1183 EXTRA_KCFLAGS="$tmp_flags"
1184 ]) # LC_DENTRY_OPEN_USE_PATH
1185
1186 #
1187 # LC_HAVE_IOP_ATOMIC_OPEN
1188 #
1189 # 3.6 vfs adds iop->atomic_open
1190 #
1191 AC_DEFUN([LC_HAVE_IOP_ATOMIC_OPEN], [
1192 LB_CHECK_COMPILE([if 'iop' has 'atomic_open'],
1193 inode_ops_atomic_open, [
1194         #include <linux/fs.h>
1195 ],[
1196         struct inode_operations iop;
1197         iop.atomic_open = NULL;
1198 ],[
1199         AC_DEFINE(HAVE_IOP_ATOMIC_OPEN, 1,
1200                 [have iop atomic_open])
1201 ])
1202 ]) # LC_HAVE_IOP_ATOMIC_OPEN
1203
1204 #
1205 # LC_HAVE_POSIXACL_USER_NS
1206 #
1207 # 3.7 posix_acl_{to,from}_xattr take struct user_namespace
1208 #
1209 AC_DEFUN([LC_HAVE_POSIXACL_USER_NS], [
1210 LB_CHECK_COMPILE([if 'posix_acl_to_xattr' takes 'struct user_namespace'],
1211 posix_acl_to_xattr_user_namespace, [
1212         #include <linux/fs.h>
1213         #include <linux/posix_acl_xattr.h>
1214 ],[
1215         posix_acl_to_xattr((struct user_namespace *)NULL, NULL, NULL, 0);
1216 ],[
1217         AC_DEFINE(HAVE_POSIXACL_USER_NS, 1,
1218                 [posix_acl_to_xattr takes struct user_namespace])
1219 ])
1220 ]) # LC_HAVE_POSIXACL_USER_NS
1221
1222 #
1223 # LC_HAVE_FILE_F_INODE
1224 #
1225 # 3.8 struct file has new member f_inode
1226 #
1227 AC_DEFUN([LC_HAVE_FILE_F_INODE], [
1228 LB_CHECK_COMPILE([if 'struct file' has memeber 'f_inode'],
1229 file_f_inode, [
1230         #include <linux/fs.h>
1231 ],[
1232         ((struct file *)0)->f_inode = NULL;
1233 ],[
1234         AC_DEFINE(HAVE_FILE_F_INODE, 1,
1235                 [struct file has memeber f_inode])
1236 ])
1237 ]) # LC_HAVE_FILE_F_INODE
1238
1239 #
1240 # LC_HAVE_SUNRPC_UPCALL_HAS_3ARGS
1241 #
1242 AC_DEFUN([LC_HAVE_SUNRPC_UPCALL_HAS_3ARGS], [
1243 LB_CHECK_COMPILE([if 'sunrpc_cache_pipe_upcall' takes 3 args],
1244 sunrpc_cache_pipe_upcall_3args, [
1245         #include <linux/sunrpc/cache.h>
1246 ],[
1247         sunrpc_cache_pipe_upcall(NULL, NULL, NULL);
1248 ],[
1249         AC_DEFINE(HAVE_SUNRPC_UPCALL_HAS_3ARGS, 1,
1250                 [sunrpc_cache_pipe_upcall takes 3 args])
1251 ])
1252 ]) # LC_HAVE_SUNRPC_UPCALL_HAS_3ARGS
1253
1254 #
1255 # LC_HAVE_HLIST_FOR_EACH_3ARG
1256 #
1257 # 3.9 uses hlist_for_each_entry with 3 args
1258 # b67bfe0d42cac56c512dd5da4b1b347a23f4b70a
1259 #
1260 AC_DEFUN([LC_HAVE_HLIST_FOR_EACH_3ARG], [
1261 LB_CHECK_COMPILE([if 'hlist_for_each_entry' has 3 args],
1262 hlist_for_each_entry_3args, [
1263         #include <linux/list.h>
1264         #include <linux/fs.h>
1265 ],[
1266         struct inode *inode;
1267         struct dentry *dentry;
1268         hlist_for_each_entry(dentry, &inode->i_dentry, d_alias) {
1269                 continue;
1270         }
1271 ],[
1272         AC_DEFINE(HAVE_HLIST_FOR_EACH_3ARG, 1,
1273                 [hlist_for_each_entry has 3 args])
1274 ])
1275 ]) # LC_HAVE_HLIST_FOR_EACH_3ARG
1276
1277 #
1278 # LC_HAVE_ONLY_PROCFS_SEQ
1279 #
1280 # 3.10+ only supports procfs seq_files handling
1281 #
1282 AC_DEFUN([LC_HAVE_ONLY_PROCFS_SEQ], [
1283 LB_CHECK_COMPILE([if procfs only supports using 'seq_files'],
1284 only_procfs_seq_files, [
1285         #include <linux/proc_fs.h>
1286 ],[
1287         ((struct proc_dir_entry *)0)->write_proc(NULL, NULL, 0, NULL);
1288 ], [], [
1289         AC_DEFINE(HAVE_ONLY_PROCFS_SEQ, 1,
1290                 [only seq_files supported])
1291 ])
1292 ]) # LC_HAVE_ONLY_PROCFS_SEQ
1293
1294 #
1295 # LC_BLKDEV_RELEASE_RETURN_INT
1296 #
1297 # 3.10 release for block device doesn't return int
1298 #
1299 AC_DEFUN([LC_BLKDEV_RELEASE_RETURN_INT], [
1300 LB_CHECK_COMPILE([if 'block_device_operations' release returns 'int'],
1301 block_device_ops_release_return_int, [
1302         #include <linux/blkdev.h>
1303 ],[
1304         struct block_device_operations fops;
1305         int i __attribute__ ((unused));
1306
1307         i = fops.release(NULL, 0);
1308 ],[
1309         AC_DEFINE(HAVE_BLKDEV_RELEASE_RETURN_INT, 1,
1310                 [block device release returns int])
1311 ])
1312 ]) # LC_BLKDEV_RELEASE_RETURN_INT
1313
1314 #
1315 # LC_INVALIDATE_RANGE
1316 #
1317 # 3.11 invalidatepage requires the length of the range to invalidate
1318 #
1319 AC_DEFUN([LC_INVALIDATE_RANGE], [
1320 LB_CHECK_COMPILE([if 'address_space_operations.invalidatepage' requires 3 arguments],
1321 address_space_ops_invalidatepage_3args, [
1322         #include <linux/fs.h>
1323 ],[
1324         struct address_space_operations a_ops;
1325         a_ops.invalidatepage(NULL, 0, 0);
1326 ],[
1327         AC_DEFINE(HAVE_INVALIDATE_RANGE, 1,
1328                 [address_space_operations.invalidatepage needs 3 arguments])
1329 ])
1330 ]) # LC_INVALIDATE_RANGE
1331
1332 #
1333 # LC_HAVE_DIR_CONTEXT
1334 #
1335 # 3.11 readdir now takes the new struct dir_context
1336 #
1337 AC_DEFUN([LC_HAVE_DIR_CONTEXT], [
1338 LB_CHECK_COMPILE([if 'dir_context' exist],
1339 dir_context, [
1340         #include <linux/fs.h>
1341 ],[
1342         struct dir_context ctx;
1343         ctx.pos = 0;
1344 ],[
1345         AC_DEFINE(HAVE_DIR_CONTEXT, 1,
1346                 [dir_context exist])
1347 ])
1348 ]) # LC_HAVE_DIR_CONTEXT
1349
1350 #
1351 # LC_D_COMPARE_5ARGS
1352 #
1353 # 3.11 dentry_operations.d_compare() taken 5 arguments.
1354 #
1355 AC_DEFUN([LC_D_COMPARE_5ARGS], [
1356 LB_CHECK_COMPILE([if 'd_compare' taken 5 arguments],
1357 d_compare_5args, [
1358         #include <linux/dcache.h>
1359 ],[
1360         ((struct dentry_operations*)0)->d_compare(NULL,NULL,0,NULL,NULL);
1361 ],[
1362         AC_DEFINE(HAVE_D_COMPARE_5ARGS, 1,
1363                 [d_compare need 5 arguments])
1364 ])
1365 ]) # LC_D_COMPARE_5ARGS
1366
1367 #
1368 # LC_HAVE_DCOUNT
1369 #
1370 # 3.11 need to access d_count to get dentry reference count
1371 #
1372 AC_DEFUN([LC_HAVE_DCOUNT], [
1373 LB_CHECK_COMPILE([if 'd_count' exist],
1374 d_count, [
1375         #include <linux/dcache.h>
1376 ],[
1377         struct dentry de;
1378         d_count(&de);
1379 ],[
1380         AC_DEFINE(HAVE_D_COUNT, 1,
1381                 [d_count exist])
1382 ])
1383 ]) # LC_HAVE_DCOUNT
1384
1385 #
1386 # LC_OLDSIZE_TRUNCATE_PAGECACHE
1387 #
1388 # 3.12 truncate_pagecache without oldsize parameter
1389 #
1390 AC_DEFUN([LC_OLDSIZE_TRUNCATE_PAGECACHE], [
1391 LB_CHECK_COMPILE([if 'truncate_pagecache' with 'old_size' parameter],
1392 truncate_pagecache_old_size, [
1393         #include <linux/mm.h>
1394 ],[
1395         truncate_pagecache(NULL, 0, 0);
1396 ],[
1397         AC_DEFINE(HAVE_OLDSIZE_TRUNCATE_PAGECACHE, 1,
1398                 [with oldsize])
1399 ])
1400 ]) # LC_OLDSIZE_TRUNCATE_PAGECACHE
1401
1402 #
1403 # LC_KIOCB_KI_LEFT
1404 #
1405 # 3.12 ki_left removed from struct kiocb
1406 #
1407 AC_DEFUN([LC_KIOCB_KI_LEFT], [
1408 LB_CHECK_COMPILE([if 'struct kiocb' with 'ki_left' member],
1409 kiocb_ki_left, [
1410         #include <linux/aio.h>
1411 ],[
1412         ((struct kiocb*)0)->ki_left = 0;
1413 ],[
1414         AC_DEFINE(HAVE_KIOCB_KI_LEFT, 1,
1415                 [ki_left exist])
1416 ])
1417 ]) # LC_KIOCB_KI_LEFT
1418
1419 #
1420 # LC_VFS_RENAME_5ARGS
1421 #
1422 # 3.13 has vfs_renane with 5 args
1423 #
1424 AC_DEFUN([LC_VFS_RENAME_5ARGS], [
1425 LB_CHECK_COMPILE([if Linux kernel has 'vfs_rename' with 5 args],
1426 vfs_rename_5args, [
1427         #include <linux/fs.h>
1428 ],[
1429         vfs_rename(NULL, NULL, NULL, NULL, NULL);
1430 ], [
1431         AC_DEFINE(HAVE_VFS_RENAME_5ARGS, 1,
1432                 [kernel has vfs_rename with 5 args])
1433 ])
1434 ]) # LC_VFS_RENAME_5ARGS
1435
1436 #
1437 # LC_VFS_UNLINK_3ARGS
1438 #
1439 # 3.13 has vfs_renane with 3 args
1440 #
1441 AC_DEFUN([LC_VFS_UNLINK_3ARGS], [
1442 LB_CHECK_COMPILE([if Linux kernel has 'vfs_unlink' with 3 args],
1443 vfs_unlink_3args, [
1444         #include <linux/fs.h>
1445 ],[
1446         vfs_unlink(NULL, NULL, NULL);
1447 ], [
1448         AC_DEFINE(HAVE_VFS_UNLINK_3ARGS, 1,
1449                 [kernel has vfs_unlink with 3 args])
1450 ])
1451 ]) # LC_VFS_UNLINK_3ARGS
1452
1453 #
1454 # LC_HAVE_BVEC_ITER
1455 #
1456 # 3.14 move some of its data in struct bio into the new
1457 # struct bvec_iter
1458 #
1459 AC_DEFUN([LC_HAVE_BVEC_ITER], [
1460 LB_CHECK_COMPILE([if Linux kernel has struct bvec_iter],
1461 have_bvec_iter, [
1462         #include <linux/bio.h>
1463 ],[
1464         struct bvec_iter iter;
1465         iter.bi_bvec_done = 0;
1466 ], [
1467         AC_DEFINE(HAVE_BVEC_ITER, 1,
1468                 [kernel has struct bvec_iter])
1469 ])
1470 ]) # LC_HAVE_BVEC_ITER
1471
1472 #
1473 # LC_PROG_LINUX
1474 #
1475 # Lustre linux kernel checks
1476 #
1477 AC_DEFUN([LC_PROG_LINUX], [
1478         AC_MSG_NOTICE([Lustre kernel checks
1479 ==============================================================================])
1480
1481         LC_CONFIG_PINGER
1482         LC_CONFIG_CHECKSUM
1483         LC_CONFIG_HEALTH_CHECK_WRITE
1484         LC_CONFIG_LRU_RESIZE
1485         LC_LLITE_LLOOP_MODULE
1486
1487         LC_GLIBC_SUPPORT_FHANDLES
1488         LC_CAPA_CRYPTO
1489         LC_CONFIG_RMTCLIENT
1490         LC_CONFIG_GSS
1491
1492         # 2.6.32
1493         LC_BLK_QUEUE_MAX_SEGMENTS
1494
1495         # 2.6.34
1496         LC_HAVE_DQUOT_FS_DISK_QUOTA
1497         LC_HAVE_DQUOT_SUSPEND
1498
1499         # 2.6.35, 3.0.0
1500         LC_FILE_FSYNC
1501         LC_EXPORT_SIMPLE_SETATTR
1502         LC_EXPORT_TRUNCATE_COMPLETE_PAGE
1503
1504         # 2.6.36
1505         LC_FS_STRUCT_RWLOCK
1506         LC_SBOPS_EVICT_INODE
1507
1508         # 2.6.37
1509         LC_KERNEL_LOCKED
1510
1511         # 2.6.38
1512         LC_BLKDEV_GET_BY_DEV
1513         LC_GENERIC_PERMISSION
1514         LC_DCACHE_LOCK
1515         LC_INODE_I_RCU
1516         LC_D_COMPARE_7ARGS
1517         LC_D_DELETE_CONST
1518
1519         # 2.6.39
1520         LC_REQUEST_QUEUE_UNPLUG_FN
1521         LC_HAVE_FHANDLE_SYSCALLS
1522         LC_HAVE_FSTYPE_MOUNT
1523         LC_IOP_TRUNCATE
1524         LC_HAVE_INODE_OWNER_OR_CAPABLE
1525
1526         # 3.0
1527         LC_DIRTY_INODE_WITH_FLAG
1528
1529         # 3.1
1530         LC_LM_XXX_LOCK_MANAGER_OPS
1531         LC_INODE_DIO_WAIT
1532         LC_IOP_GET_ACL
1533         LC_FILE_LLSEEK_SIZE
1534         LC_INODE_PERMISION_2ARGS
1535         LC_RADIX_EXCEPTION_ENTRY
1536
1537         # 3.2
1538         LC_HAVE_VOID_MAKE_REQUEST_FN
1539         LC_HAVE_PROTECT_I_NLINK
1540
1541         # 3.3
1542         LC_HAVE_MIGRATE_HEADER
1543         LC_MIGRATEPAGE_4ARGS
1544         LC_SUPEROPS_USE_DENTRY
1545         LC_INODEOPS_USE_UMODE_T
1546         LC_HAVE_CACHE_REGISTER
1547
1548         # 3.4
1549         LC_HAVE_D_MAKE_ROOT
1550         LC_KMAP_ATOMIC_HAS_1ARG
1551
1552         # 3.5
1553         LC_HAVE_CLEAR_INODE
1554         LC_HAVE_ENCODE_FH_PARENT
1555         LC_FILE_LLSEEK_SIZE_5ARG
1556
1557         # 3.6
1558         LC_HAVE_DENTRY_D_ALIAS_HLIST
1559         LC_DENTRY_OPEN_USE_PATH
1560         LC_HAVE_IOP_ATOMIC_OPEN
1561
1562         # 3.7
1563         LC_HAVE_POSIXACL_USER_NS
1564
1565         # 3.8
1566         LC_HAVE_FILE_F_INODE
1567         LC_HAVE_SUNRPC_UPCALL_HAS_3ARGS
1568
1569         # 3.9
1570         LC_HAVE_HLIST_FOR_EACH_3ARG
1571
1572         # 3.10
1573         LC_HAVE_ONLY_PROCFS_SEQ
1574         LC_BLKDEV_RELEASE_RETURN_INT
1575
1576         # 3.11
1577         LC_INVALIDATE_RANGE
1578         LC_HAVE_DIR_CONTEXT
1579         LC_D_COMPARE_5ARGS
1580         LC_HAVE_DCOUNT
1581
1582         # 3.12
1583         LC_OLDSIZE_TRUNCATE_PAGECACHE
1584         LC_KIOCB_KI_LEFT
1585
1586         # 3.13
1587         LC_VFS_RENAME_5ARGS
1588         LC_VFS_UNLINK_3ARGS
1589
1590         # 3.14
1591         LC_HAVE_BVEC_ITER
1592
1593         #
1594         AS_IF([test "x$enable_server" != xno], [
1595                 LC_FUNC_DEV_SET_RDONLY
1596                 LC_STACK_SIZE
1597                 LC_QUOTA64
1598                 LC_QUOTA_CONFIG
1599         ])
1600 ]) # LC_PROG_LINUX
1601
1602 #
1603 # LC_CONFIG_CLIENT
1604 #
1605 # Check whether to build the client side of Lustre
1606 #
1607 AC_DEFUN([LC_CONFIG_CLIENT], [
1608 AC_MSG_CHECKING([whether to build Lustre client support])
1609 AC_ARG_ENABLE([client],
1610         AC_HELP_STRING([--disable-client],
1611                 [disable Lustre client support]),
1612         [], [enable_client="yes"])
1613 AC_MSG_RESULT([$enable_client])
1614 ]) # LC_CONFIG_CLIENT
1615
1616 #
1617 # --enable-mpitests
1618 #
1619 AC_DEFUN([LB_CONFIG_MPITESTS], [
1620 AC_ARG_ENABLE([mpitests],
1621         AC_HELP_STRING([--enable-mpitests=<yes|no|mpicc wrapper>],
1622                        [include mpi tests]), [
1623                 enable_mpitests="yes"
1624                 case $enableval in
1625                 yes)
1626                         MPICC_WRAPPER="mpicc"
1627                         ;;
1628                 no)
1629                         enable_mpitests="no"
1630                         ;;
1631                 *)
1632                         MPICC_WRAPPER=$enableval
1633                         ;;
1634                 esac
1635         ], [
1636                 enable_mpitests="yes"
1637                 MPICC_WRAPPER="mpicc"
1638         ])
1639
1640         if test "x$enable_mpitests" != "xno"; then
1641                 oldcc=$CC
1642                 CC=$MPICC_WRAPPER
1643                 AC_CACHE_CHECK([whether mpitests can be built],
1644                 lb_cv_mpi_tests, [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1645                         #include <mpi.h>
1646                         int main(void) {
1647                                 int flag;
1648                                 MPI_Initialized(&flag);
1649                                 return 0;
1650                         }
1651                 ])], [lb_cv_mpi_tests="yes"], [lb_cv_mpi_tests="no"
1652                         enable_mpitests=$lb_cv_mpi_tests])
1653                 ])
1654                 CC=$oldcc
1655         fi
1656         AC_SUBST(MPICC_WRAPPER)
1657 ]) # LB_CONFIG_MPITESTS
1658
1659 #
1660 # LC_CONFIG_QUOTA
1661 #
1662 # whether to enable quota support global control
1663 #
1664 AC_DEFUN([LC_CONFIG_QUOTA], [
1665 AC_MSG_CHECKING([whether to enable quota support global control])
1666 AC_ARG_ENABLE([quota],
1667         AC_HELP_STRING([--enable-quota],
1668                 [enable quota support]),
1669         [], [enable_quota="yes"])
1670 AS_IF([test "x$enable_quota" = xyes],
1671         [AC_MSG_RESULT([yes])],
1672         [AC_MSG_RESULT([no])])
1673 ]) # LC_CONFIG_QUOTA
1674
1675 #
1676 # LC_QUOTA
1677 #
1678 AC_DEFUN([LC_QUOTA], [
1679 #check global
1680 LC_CONFIG_QUOTA
1681 #check for utils
1682 AS_IF([test "x$enable_quota" != xno -a "x$enable_utils" != xno], [
1683         AC_CHECK_HEADER([sys/quota.h],
1684                 [AC_DEFINE(HAVE_SYS_QUOTA_H, 1,
1685                         [Define to 1 if you have <sys/quota.h>.])],
1686                 [AC_MSG_ERROR([don't find <sys/quota.h> in your system])])
1687 ])
1688 ]) # LC_QUOTA
1689
1690 #
1691 # LC_CONFIG_SPLIT
1692 #
1693 # whether to enable split support
1694 #
1695 AC_DEFUN([LC_CONFIG_SPLIT], [
1696 AC_MSG_CHECKING([whether to enable split support])
1697 AC_ARG_ENABLE([split],
1698         AC_HELP_STRING([--enable-split],
1699                 [enable split support]),
1700         [], [enable_split='no'])
1701 AC_MSG_RESULT([$enable_split])
1702 AS_IF([test "x$enable_split" != xno],
1703     [AC_DEFINE(HAVE_SPLIT_SUPPORT, 1, [enable split support])])
1704 ]) # LC_CONFIG_SPLIT
1705
1706 #
1707 # LC_CONFIG_NODEMAP_PROC_DEBUG
1708 #
1709 # enable nodemap proc file debugging
1710 #
1711 AC_DEFUN([LC_NODEMAP_PROC_DEBUG], [
1712 AC_MSG_CHECKING([whether to enable nodemap proc debug])
1713 AC_ARG_ENABLE([nodemap_proc_debug],
1714         AC_HELP_STRING([--enable-nodemap-proc-debug],
1715                 [enable nodemap proc debug]),
1716         [], [enable_nodemap_proc_debug="no"])
1717 AC_MSG_RESULT([$enable_nodemap_proc_debug])
1718 AS_IF([test "x$enable_nodemap_proc_debug" != xno],
1719         [AC_DEFINE(NODEMAP_PROC_DEBUG, 1,
1720                 [enable nodemap proc debug support])])
1721 ]) # LC_NODEMAP_PROC_DEBUG
1722
1723 #
1724 # LC_LLITE_LLOOP_MODULE
1725 #
1726 # lloop_llite.ko does not currently work with page sizes
1727 # of 64k or larger.
1728 #
1729 AC_DEFUN([LC_LLITE_LLOOP_MODULE], [
1730 LB_CHECK_COMPILE([whether to enable 'llite_lloop' module],
1731 enable_llite_lloop_module, [
1732         #include <asm/page.h>
1733 ],[
1734         #if PAGE_SIZE >= 65536
1735         #error "PAGE_SIZE >= 65536"
1736         #endif
1737 ],
1738         [enable_llite_lloop_module="yes"],
1739         [enable_llite_lloop_module="no"])
1740 ]) # LC_LLITE_LLOOP_MODULE
1741
1742 #
1743 # LC_OSD_ADDON
1744 #
1745 # configure support for optional OSD implementation
1746 #
1747 AC_DEFUN([LC_OSD_ADDON], [
1748 AC_MSG_CHECKING([whether to use OSD addon])
1749 AC_ARG_WITH([osd],
1750         AC_HELP_STRING([--with-osd=path],
1751                 [set path to optional osd]),
1752         [
1753         case "$with_osd" in
1754         no)
1755                 ENABLEOSDADDON=0
1756                 ;;
1757         *)
1758                 OSDADDON="$with_osd"
1759                 ENABLEOSDADDON=1
1760                 ;;
1761         esac
1762         ], [
1763                 ENABLEOSDADDON=0
1764         ])
1765 AS_IF([test $ENABLEOSDADDON -eq 0], [
1766         AC_MSG_RESULT([no])
1767         OSDADDON=""
1768 ], [
1769         OSDMODNAME=$(basename $OSDADDON)
1770         AS_IF([test -e $LUSTRE/$OSDMODNAME], [
1771                 AC_MSG_RESULT([can't link])
1772                 OSDADDON=""
1773         ], [ln -s $OSDADDON $LUSTRE/$OSDMODNAME], [
1774                 AC_MSG_RESULT([$OSDMODNAME])
1775                 OSDADDON="subdir-m += $OSDMODNAME"
1776         ], [
1777                 AC_MSG_RESULT([can't link])
1778                 OSDADDON=""
1779         ])
1780 ])
1781 AC_SUBST(OSDADDON)
1782 ]) # LC_OSD_ADDON
1783
1784 #
1785 # LC_CONFIGURE
1786 #
1787 # other configure checks
1788 #
1789 AC_DEFUN([LC_CONFIGURE], [
1790 AC_MSG_NOTICE([Lustre core checks
1791 ==============================================================================])
1792
1793 LC_CONFIG_OBD_BUFFER_SIZE
1794
1795 AS_IF([test $target_cpu == "i686" -o $target_cpu == "x86_64"],
1796         [CFLAGS="$CFLAGS -Werror"])
1797
1798 # maximum MDS thread count
1799 LC_MDS_MAX_THREADS
1800
1801 # libcfs/include/libcfs/posix/libcfs.h
1802 # lustre/utils/llverdev.c
1803 AC_CHECK_HEADERS([sys/user.h sys/vfs.h stdint.h blkid/blkid.h])
1804
1805 # libcfs/include/libcfs/linux/linux-prim.h, ...
1806 AC_CHECK_HEADERS([linux/types.h sys/types.h linux/unistd.h unistd.h])
1807
1808 # libcfs/libcfs/user-tcpip.c
1809 AC_CHECK_HEADERS([netinet/in.h])
1810 AC_CHECK_FUNCS([inet_ntoa])
1811
1812 # libcfs/include/libcfs/linux/linux-prim.h
1813 AC_CHECK_HEADERS([linux/random.h], [], [],
1814                  [#ifdef HAVE_LINUX_TYPES_H
1815                   #include <linux/types.h>
1816                   #endif
1817                  ])
1818
1819 # utils/llverfs.c
1820 AC_CHECK_HEADERS([ext2fs/ext2fs.h])
1821
1822 SELINUX=""
1823 AC_CHECK_LIB([selinux], [is_selinux_enabled],
1824         [AC_CHECK_HEADERS([selinux.h],
1825                         [SELINUX="-lselinux"
1826                         AC_DEFINE([HAVE_SELINUX], 1,
1827                                 [support for selinux ])],
1828                         [AC_MSG_WARN([
1829
1830 No selinux-devel package found, unable to build selinux enabled tools
1831 ])
1832 ])],
1833         [AC_MSG_WARN([
1834
1835 No selinux package found, unable to build selinux enabled tools
1836 ])
1837 ])
1838 AC_SUBST(SELINUX)
1839
1840 # Super safe df
1841 AC_MSG_CHECKING([whether to report minimum OST free space])
1842 AC_ARG_ENABLE([mindf],
1843         AC_HELP_STRING([--enable-mindf],
1844                 [Make statfs report the minimum available space on any single OST instead of the sum of free space on all OSTs]),
1845         [], [enable_mindf="no"])
1846 AC_MSG_RESULT([$enable_mindf])
1847 AS_IF([test "$enable_mindf" = "yes"],
1848         [AC_DEFINE([MIN_DF], 1, [Report minimum OST free space])])
1849
1850 AC_MSG_CHECKING([whether to randomly failing memory alloc])
1851 AC_ARG_ENABLE([fail_alloc],
1852         AC_HELP_STRING([--disable-fail-alloc],
1853                 [disable randomly alloc failure]),
1854         [], [enable_fail_alloc="yes"])
1855 AC_MSG_RESULT([$enable_fail_alloc])
1856 AS_IF([test "x$enable_fail_alloc" != xno],
1857         [AC_DEFINE([RANDOM_FAIL_ALLOC], 1,
1858                 [enable randomly alloc failure])])
1859
1860 AC_MSG_CHECKING([whether to check invariants (expensive cpu-wise)])
1861 AC_ARG_ENABLE([invariants],
1862         AC_HELP_STRING([--enable-invariants],
1863                 [enable invariant checking (cpu intensive)]),
1864         [], [enable_invariants="no"])
1865 AC_MSG_RESULT([$enable_invariants])
1866 AS_IF([test "x$enable_invariants" = xyes],
1867         [AC_DEFINE([CONFIG_LUSTRE_DEBUG_EXPENSIVE_CHECK], 1,
1868                 [enable invariant checking])])
1869
1870 AC_MSG_CHECKING([whether to track references with lu_ref])
1871 AC_ARG_ENABLE([lu_ref],
1872         AC_HELP_STRING([--enable-lu_ref],
1873                 [enable lu_ref reference tracking code]),
1874         [], [enable_lu_ref="no"])
1875 AC_MSG_RESULT([$enable_lu_ref])
1876 AS_IF([test "x$enable_lu_ref" = xyes],
1877         [AC_DEFINE([USE_LU_REF], 1,
1878                 [enable lu_ref reference tracking code])])
1879
1880 AC_MSG_CHECKING([whether to enable page state tracking])
1881 AC_ARG_ENABLE([pgstate-track],
1882         AC_HELP_STRING([--enable-pgstate-track],
1883                 [enable page state tracking]),
1884         [], [enable_pgstat_track="no"])
1885 AC_MSG_RESULT([$enable_pgstat_track])
1886 AS_IF([test "x$enable_pgstat_track" = xyes],
1887         [AC_DEFINE([CONFIG_DEBUG_PAGESTATE_TRACKING], 1,
1888                 [enable page state tracking code])])
1889 ]) # LC_CONFIGURE
1890
1891 #
1892 # LC_CONDITIONALS
1893 #
1894 # AM_CONDITIONALS for lustre
1895 #
1896 AC_DEFUN([LC_CONDITIONALS], [
1897 AM_CONDITIONAL(LIBLUSTRE, false)
1898 AM_CONDITIONAL(MPITESTS, test x$enable_mpitests = xyes, Build MPI Tests)
1899 AM_CONDITIONAL(CLIENT, test x$enable_client = xyes)
1900 AM_CONDITIONAL(SERVER, test x$enable_server = xyes)
1901 AM_CONDITIONAL(SPLIT, test x$enable_split = xyes)
1902 AM_CONDITIONAL(BLKID, test x$ac_cv_header_blkid_blkid_h = xyes)
1903 AM_CONDITIONAL(EXT2FS_DEVEL, test x$ac_cv_header_ext2fs_ext2fs_h = xyes)
1904 AM_CONDITIONAL(GSS, test x$enable_gss = xyes)
1905 AM_CONDITIONAL(GSS_KEYRING, test x$enable_gss_keyring = xyes)
1906 AM_CONDITIONAL(GSS_PIPEFS, test x$enable_gss_pipefs = xyes)
1907 AM_CONDITIONAL(LIBPTHREAD, test x$enable_libpthread = xyes)
1908 AM_CONDITIONAL(LLITE_LLOOP, test x$enable_llite_lloop_module = xyes)
1909 ]) # LC_CONDITIONALS
1910
1911 #
1912 # LC_CONFIG_FILES
1913 #
1914 # files that should be generated with AC_OUTPUT
1915 #
1916 AC_DEFUN([LC_CONFIG_FILES],
1917 [AC_CONFIG_FILES([
1918 lustre/Makefile
1919 lustre/autoMakefile
1920 lustre/autoconf/Makefile
1921 lustre/conf/Makefile
1922 lustre/contrib/Makefile
1923 lustre/doc/Makefile
1924 lustre/include/Makefile
1925 lustre/include/lustre_ver.h
1926 lustre/include/linux/Makefile
1927 lustre/include/darwin/Makefile
1928 lustre/include/lustre/Makefile
1929 lustre/kernel_patches/targets/3.10-rhel7.target
1930 lustre/kernel_patches/targets/2.6-rhel6.target
1931 lustre/kernel_patches/targets/2.6-rhel5.target
1932 lustre/kernel_patches/targets/2.6-sles11.target
1933 lustre/kernel_patches/targets/3.0-sles11.target
1934 lustre/kernel_patches/targets/3.0-sles11sp3.target
1935 lustre/kernel_patches/targets/2.6-fc11.target
1936 lustre/kernel_patches/targets/2.6-fc12.target
1937 lustre/kernel_patches/targets/2.6-fc15.target
1938 lustre/kernel_patches/targets/3.x-fc18.target
1939 lustre/ldlm/Makefile
1940 lustre/fid/Makefile
1941 lustre/fid/autoMakefile
1942 lustre/llite/Makefile
1943 lustre/llite/autoMakefile
1944 lustre/lclient/Makefile
1945 lustre/lov/Makefile
1946 lustre/lov/autoMakefile
1947 lustre/mdc/Makefile
1948 lustre/mdc/autoMakefile
1949 lustre/lmv/Makefile
1950 lustre/lmv/autoMakefile
1951 lustre/lfsck/Makefile
1952 lustre/lfsck/autoMakefile
1953 lustre/mdt/Makefile
1954 lustre/mdt/autoMakefile
1955 lustre/nodemap/Makefile
1956 lustre/nodemap/autoMakefile
1957 lustre/mdd/Makefile
1958 lustre/mdd/autoMakefile
1959 lustre/fld/Makefile
1960 lustre/fld/autoMakefile
1961 lustre/obdclass/Makefile
1962 lustre/obdclass/autoMakefile
1963 lustre/obdclass/linux/Makefile
1964 lustre/obdecho/Makefile
1965 lustre/obdecho/autoMakefile
1966 lustre/ofd/Makefile
1967 lustre/ofd/autoMakefile
1968 lustre/osc/Makefile
1969 lustre/osc/autoMakefile
1970 lustre/ost/Makefile
1971 lustre/ost/autoMakefile
1972 lustre/osd-ldiskfs/Makefile
1973 lustre/osd-ldiskfs/autoMakefile
1974 lustre/osd-zfs/Makefile
1975 lustre/osd-zfs/autoMakefile
1976 lustre/mgc/Makefile
1977 lustre/mgc/autoMakefile
1978 lustre/mgs/Makefile
1979 lustre/mgs/autoMakefile
1980 lustre/target/Makefile
1981 lustre/ptlrpc/Makefile
1982 lustre/ptlrpc/autoMakefile
1983 lustre/ptlrpc/gss/Makefile
1984 lustre/ptlrpc/gss/autoMakefile
1985 lustre/quota/Makefile
1986 lustre/quota/autoMakefile
1987 lustre/scripts/Makefile
1988 lustre/tests/Makefile
1989 lustre/tests/mpi/Makefile
1990 lustre/utils/Makefile
1991 lustre/utils/gss/Makefile
1992 lustre/osp/Makefile
1993 lustre/osp/autoMakefile
1994 lustre/lod/Makefile
1995 lustre/lod/autoMakefile
1996 lustre/obdclass/darwin/Makefile
1997 ])
1998 ]) # LC_CONFIG_FILES