lustre/autoconf/lustre-core.m4

   1 #
   2 # LC_CONFIG_SRCDIR
   3 #
   4 # Wrapper for AC_CONFIG_SUBDIR
   5 #
   6 AC_DEFUN([LC_CONFIG_SRCDIR],
   7 [AC_CONFIG_SRCDIR([lustre/obdclass/obdo.c])
   8 libcfs_is_module=yes
   9 ldiskfs_is_ext4=yes
  10 ])
  11
  12 #
  13 # LC_PATH_DEFAULTS
  14 #
  15 # lustre specific paths
  16 #
  17 AC_DEFUN([LC_PATH_DEFAULTS],
  18 [# ptlrpc kernel build requires this
  19 LUSTRE="$PWD/lustre"
  20 AC_SUBST(LUSTRE)
  21
  22 # mount.lustre
  23 rootsbindir='$(CROSS_PATH)/sbin'
  24 AC_SUBST(rootsbindir)
  25
  26 demodir='$(docdir)/demo'
  27 AC_SUBST(demodir)
  28
  29 pkgexampledir='${pkgdatadir}/examples'
  30 AC_SUBST(pkgexampledir)
  31 ])
  32
  33 #
  34 # LC_TARGET_SUPPORTED
  35 #
  36 # is the target os supported?
  37 #
  38 AC_DEFUN([LC_TARGET_SUPPORTED],
  39 [case $target_os in
  40         linux* | darwin*)
  41 $1
  42                 ;;
  43         *)
  44 $2
  45                 ;;
  46 esac
  47 ])
  48
  49 #
  50 # LC_CONFIG_OBD_BUFFER_SIZE
  51 #
  52 # the maximum buffer size of lctl ioctls
  53 #
  54 AC_DEFUN([LC_CONFIG_OBD_BUFFER_SIZE],
  55 [AC_MSG_CHECKING([maximum OBD ioctl size])
  56 AC_ARG_WITH([obd-buffer-size],
  57         AC_HELP_STRING([--with-obd-buffer-size=[size]],
  58                         [set lctl ioctl maximum bytes (default=8192)]),
  59         [
  60                 OBD_BUFFER_SIZE=$with_obd_buffer_size
  61         ],[
  62                 OBD_BUFFER_SIZE=8192
  63         ])
  64 AC_MSG_RESULT([$OBD_BUFFER_SIZE bytes])
  65 AC_DEFINE_UNQUOTED(CONFIG_LUSTRE_OBD_MAX_IOCTL_BUFFER, $OBD_BUFFER_SIZE, [IOCTL Buffer Size])
  66 ])
  67
  68 #
  69 # LC_READLINK_SSIZE_T
  70 #
  71 AC_DEFUN([LC_READLINK_SSIZE_T],
  72 [AC_MSG_CHECKING([if readlink returns ssize_t])
  73 AC_TRY_COMPILE([
  74         #include <unistd.h>
  75 ],[
  76         ssize_t readlink(const char *, char *, size_t);
  77 ],[
  78         AC_MSG_RESULT([yes])
  79         AC_DEFINE(HAVE_POSIX_1003_READLINK, 1, [readlink returns ssize_t])
  80 ],[
  81         AC_MSG_RESULT([no])
  82 ])
  83 ])
  84
  85 #
  86 # LC_FUNC_DEV_SET_RDONLY
  87 #
  88 # check whether dev_set_rdonly is exported.  This is needed until we
  89 # have another mechanism to fence IO from the underlying device.
  90 #
  91 AC_DEFUN([LC_FUNC_DEV_SET_RDONLY],
  92 [LB_CHECK_SYMBOL_EXPORT([dev_set_rdonly],
  93 [block/ll_rw_block.c,block/blk-core.c],[
  94         AC_DEFINE(HAVE_DEV_SET_RDONLY, 1, [kernel exports dev_set_rdonly])
  95 ],[
  96         AC_MSG_WARN([kernel missing dev_set_rdonly patch for testing])
  97 ])
  98 ])
  99
 100 #
 101 # Ensure stack size big than 8k in Lustre server (all kernels)
 102 #
 103 AC_DEFUN([LC_STACK_SIZE],
 104 [AC_MSG_CHECKING([stack size big than 8k])
 105 LB_LINUX_TRY_COMPILE([
 106         #include <linux/thread_info.h>
 107 ],[
 108         #if THREAD_SIZE < 8192
 109         #error "stack size < 8192"
 110         #endif
 111 ],[
 112         AC_MSG_RESULT(yes)
 113 ],[
 114         AC_MSG_ERROR([Lustre requires that Linux is configured with at least a 8KB stack.])
 115 ])
 116 ])
 117
 118 #
 119 # Allow the user to set the MDS thread upper limit
 120 #
 121 AC_DEFUN([LC_MDS_MAX_THREADS],
 122 [
 123         AC_ARG_WITH([mds_max_threads],
 124         AC_HELP_STRING([--with-mds-max-threads=count],
 125                        [maximum threads available on the MDS: (default=512)]),
 126         [
 127                 MDS_THREAD_COUNT=$with_mds_max_threads
 128                 AC_DEFINE_UNQUOTED(MDS_MAX_THREADS, $MDS_THREAD_COUNT, [maximum number of MDS threads])
 129         ])
 130 ])
 131
 132 #
 133 # LC_CONFIG_PINGER
 134 #
 135 # the pinger is temporary, until we have the recovery node in place
 136 #
 137 AC_DEFUN([LC_CONFIG_PINGER],
 138 [AC_MSG_CHECKING([whether to enable pinger support])
 139 AC_ARG_ENABLE([pinger],
 140         AC_HELP_STRING([--disable-pinger],
 141                         [disable recovery pinger support]),
 142         [],[enable_pinger='yes'])
 143 AC_MSG_RESULT([$enable_pinger])
 144 if test x$enable_pinger != xno ; then
 145   AC_DEFINE(ENABLE_PINGER, 1, Use the Pinger)
 146 fi
 147 ])
 148
 149 #
 150 # LC_CONFIG_CHECKSUM
 151 #
 152 # do checksum of bulk data between client and OST
 153 #
 154 AC_DEFUN([LC_CONFIG_CHECKSUM],
 155 [AC_MSG_CHECKING([whether to enable data checksum support])
 156 AC_ARG_ENABLE([checksum],
 157        AC_HELP_STRING([--disable-checksum],
 158                        [disable data checksum support]),
 159        [],[enable_checksum='yes'])
 160 AC_MSG_RESULT([$enable_checksum])
 161 if test x$enable_checksum != xno ; then
 162   AC_DEFINE(ENABLE_CHECKSUM, 1, do data checksums)
 163 fi
 164 ])
 165
 166 #
 167 # LC_CONFIG_LIBLUSTRE_RECOVERY
 168 #
 169 AC_DEFUN([LC_CONFIG_LIBLUSTRE_RECOVERY],
 170 [AC_MSG_CHECKING([whether to enable liblustre recovery support])
 171 AC_ARG_ENABLE([liblustre-recovery],
 172         AC_HELP_STRING([--disable-liblustre-recovery],
 173                         [disable liblustre recovery support]),
 174         [],[enable_liblustre_recovery='yes'])
 175 AC_MSG_RESULT([$enable_liblustre_recovery])
 176 if test x$enable_liblustre_recovery != xno ; then
 177   AC_DEFINE(ENABLE_LIBLUSTRE_RECOVERY, 1, Liblustre Can Recover)
 178 fi
 179 ])
 180
 181 #
 182 # LC_CONFIG_HEALTH_CHECK_WRITE
 183 #
 184 # Turn off the actual write to the disk
 185 #
 186 AC_DEFUN([LC_CONFIG_HEALTH_CHECK_WRITE],
 187 [AC_MSG_CHECKING([whether to enable a write with the health check])
 188 AC_ARG_ENABLE([health_write],
 189         AC_HELP_STRING([--enable-health_write],
 190                         [enable disk writes when doing health check]),
 191         [],[enable_health_write='no'])
 192 AC_MSG_RESULT([$enable_health_write])
 193 if test x$enable_health_write != xno ; then
 194   AC_DEFINE(USE_HEALTH_CHECK_WRITE, 1, Write when Checking Health)
 195 fi
 196 ])
 197
 198 AC_DEFUN([LC_CONFIG_LRU_RESIZE],
 199 [AC_MSG_CHECKING([whether to enable lru self-adjusting])
 200 AC_ARG_ENABLE([lru_resize],
 201         AC_HELP_STRING([--enable-lru-resize],
 202                         [enable lru resize support]),
 203         [],[enable_lru_resize='yes'])
 204 AC_MSG_RESULT([$enable_lru_resize])
 205 if test x$enable_lru_resize != xno; then
 206    AC_DEFINE(HAVE_LRU_RESIZE_SUPPORT, 1, [Enable lru resize support])
 207 fi
 208 ])
 209
 210 #
 211 # Quota support. The kernel must support CONFIG_QUOTA.
 212 #
 213 AC_DEFUN([LC_QUOTA_CONFIG],
 214 [LB_LINUX_CONFIG_IM([QUOTA],[],[
 215         AC_MSG_ERROR([Lustre quota requires that CONFIG_QUOTA is enabled in your kernel.])
 216         ])
 217 ])
 218
 219 # truncate_complete_page() has never been exported from an upstream kernel
 220 # remove_from_page_cache() was exported between 2.6.35 and 2.6.38
 221 # delete_from_page_cache() is exported from 2.6.39
 222 AC_DEFUN([LC_EXPORT_TRUNCATE_COMPLETE_PAGE],
 223          [LB_CHECK_SYMBOL_EXPORT([truncate_complete_page],
 224                                  [mm/truncate.c],
 225                                  [AC_DEFINE(HAVE_TRUNCATE_COMPLETE_PAGE, 1,
 226                                             [kernel export truncate_complete_page])])
 227           LB_CHECK_SYMBOL_EXPORT([remove_from_page_cache],
 228                                  [mm/filemap.c],
 229                                  [AC_DEFINE(HAVE_REMOVE_FROM_PAGE_CACHE, 1,
 230                                             [kernel export remove_from_page_cache])])
 231           LB_CHECK_SYMBOL_EXPORT([delete_from_page_cache],
 232                                  [mm/filemap.c],
 233                                  [AC_DEFINE(HAVE_DELETE_FROM_PAGE_CACHE, 1,
 234                                             [kernel export delete_from_page_cache])])
 235          ])
 236
 237 #
 238 # LC_CAPA_CRYPTO
 239 #
 240 AC_DEFUN([LC_CAPA_CRYPTO],
 241 [LB_LINUX_CONFIG_IM([CRYPTO],[],[
 242         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO is enabled in your kernel.])
 243 ])
 244 LB_LINUX_CONFIG_IM([CRYPTO_HMAC],[],[
 245         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO_HMAC is enabled in your kernel.])
 246 ])
 247 LB_LINUX_CONFIG_IM([CRYPTO_SHA1],[],[
 248         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO_SHA1 is enabled in your kernel.])
 249 ])
 250 ])
 251
 252 #
 253 # LC_CONFIG_RMTCLIENT
 254 #
 255 dnl FIXME
 256 dnl the AES symbol usually tied with arch, e.g. CRYPTO_AES_586
 257 dnl FIXME
 258 AC_DEFUN([LC_CONFIG_RMTCLIENT],
 259 [LB_LINUX_CONFIG_IM([CRYPTO_AES],[],[
 260         AC_MSG_WARN([Lustre remote client require that CONFIG_CRYPTO_AES is enabled in your kernel.])
 261 ])
 262 ])
 263
 264 #
 265 # LC_CONFIG_GSS_KEYRING (default enabled, if gss is enabled)
 266 #
 267 AC_DEFUN([LC_CONFIG_GSS_KEYRING],
 268 [AC_MSG_CHECKING([whether to enable gss keyring backend])
 269  AC_ARG_ENABLE([gss_keyring],
 270                [AC_HELP_STRING([--disable-gss-keyring],
 271                                [disable gss keyring backend])],
 272                [],[enable_gss_keyring='yes'])
 273  AC_MSG_RESULT([$enable_gss_keyring])
 274
 275  if test x$enable_gss_keyring != xno; then
 276         LB_LINUX_CONFIG_IM([KEYS],[],
 277                            [AC_MSG_ERROR([GSS keyring backend require that CONFIG_KEYS be enabled in your kernel.])])
 278
 279         AC_CHECK_LIB([keyutils], [keyctl_search], [],
 280                      [AC_MSG_ERROR([libkeyutils is not found, which is required by gss keyring backend])],)
 281
 282         AC_DEFINE([HAVE_GSS_KEYRING], [1],
 283                   [Define this if you enable gss keyring backend])
 284  fi
 285 ])
 286
 287 AC_DEFUN([LC_CONFIG_SUNRPC],
 288 [LB_LINUX_CONFIG_IM([SUNRPC],[],
 289                     [AC_MSG_ERROR([kernel SUNRPC support is required by using GSS.])])
 290 ])
 291
 292 #
 293 # LC_CONFIG_GSS (default disabled)
 294 #
 295 # Build gss and related tools of Lustre. Currently both kernel and user space
 296 # parts are depend on linux platform.
 297 #
 298 AC_DEFUN([LC_CONFIG_GSS],
 299 [AC_MSG_CHECKING([whether to enable gss/krb5 support])
 300  AC_ARG_ENABLE([gss],
 301                [AC_HELP_STRING([--enable-gss], [enable gss/krb5 support])],
 302                [],[enable_gss='no'])
 303  AC_MSG_RESULT([$enable_gss])
 304
 305  if test x$enable_gss == xyes; then
 306         LC_CONFIG_GSS_KEYRING
 307         LC_CONFIG_SUNRPC
 308
 309         AC_DEFINE([HAVE_GSS], [1], [Define this if you enable gss])
 310
 311         LB_LINUX_CONFIG_IM([CRYPTO_MD5],[],
 312                            [AC_MSG_WARN([kernel MD5 support is recommended by using GSS.])])
 313         LB_LINUX_CONFIG_IM([CRYPTO_SHA1],[],
 314                            [AC_MSG_WARN([kernel SHA1 support is recommended by using GSS.])])
 315         LB_LINUX_CONFIG_IM([CRYPTO_SHA256],[],
 316                            [AC_MSG_WARN([kernel SHA256 support is recommended by using GSS.])])
 317         LB_LINUX_CONFIG_IM([CRYPTO_SHA512],[],
 318                            [AC_MSG_WARN([kernel SHA512 support is recommended by using GSS.])])
 319
 320         AC_CHECK_LIB([gssapi], [gss_export_lucid_sec_context],
 321                      [GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssapi"],
 322                      [AC_CHECK_LIB([gssglue], [gss_export_lucid_sec_context],
 323                                    [GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssglue"],
 324                                    [AC_MSG_ERROR([libgssapi or libgssglue is not found, which is required by GSS.])])],)
 325
 326         AC_SUBST(GSSAPI_LIBS)
 327
 328         AC_KERBEROS_V5
 329  fi
 330 ])
 331
 332 # 2.6.12
 333
 334 # ~2.6.12 merge patch from oracle to convert tree_lock from spinlock to rwlock
 335 # yet tree_lock is converted from rwlock to spin_lock since v2.6.26
 336 AC_DEFUN([LC_RW_TREE_LOCK],
 337 [AC_MSG_CHECKING([if kernel has tree_lock as rwlock])
 338 tmp_flags="$EXTRA_KCFLAGS"
 339 EXTRA_KCFLAGS="-Werror"
 340 LB_LINUX_TRY_COMPILE([
 341         #include <linux/fs.h>
 342 ],[
 343         struct address_space a;
 344
 345         write_lock(&a.tree_lock);
 346 ],[
 347         AC_MSG_RESULT([yes])
 348         AC_DEFINE(HAVE_RW_TREE_LOCK, 1, [kernel has tree_lock as rw_lock])
 349 ],[
 350         AC_MSG_RESULT([no])
 351 ])
 352 EXTRA_KCFLAGS="$tmp_flags"
 353 ])
 354
 355 #2.6.18 + RHEL5 (fc6)
 356
 357 # raid5-zerocopy patch
 358
 359 #
 360 # LC_PAGE_CONSTANT
 361 #
 362 # In order to support raid5 zerocopy patch, we have to patch the kernel to make
 363 # it support constant page, which means the page won't be modified during the
 364 # IO.
 365 #
 366 AC_DEFUN([LC_PAGE_CONSTANT],
 367 [AC_MSG_CHECKING([if kernel have PageConstant defined])
 368 LB_LINUX_TRY_COMPILE([
 369         #include <linux/mm.h>
 370         #include <linux/page-flags.h>
 371 ],[
 372         #ifndef PG_constant
 373         #error "Have no raid5 zcopy patch"
 374         #endif
 375 ],[
 376         AC_MSG_RESULT(yes)
 377         AC_DEFINE(HAVE_PAGE_CONSTANT, 1, [kernel have PageConstant supported])
 378 ],[
 379         AC_MSG_RESULT(no);
 380 ])
 381 ])
 382
 383 # 2.6.22
 384
 385 #
 386 # 2.6.19 check for FS_RENAME_DOES_D_MOVE flag
 387 #
 388 AC_DEFUN([LC_FS_RENAME_DOES_D_MOVE],
 389 [AC_MSG_CHECKING([if kernel has FS_RENAME_DOES_D_MOVE flag])
 390 LB_LINUX_TRY_COMPILE([
 391         #include <linux/fs.h>
 392 ],[
 393         int v __attribute__ ((unused));
 394         v = FS_RENAME_DOES_D_MOVE;
 395 ],[
 396         AC_MSG_RESULT([yes])
 397         AC_DEFINE(HAVE_FS_RENAME_DOES_D_MOVE, 1, [kernel has FS_RENAME_DOES_D_MOVE flag])
 398 ],[
 399         AC_MSG_RESULT([no])
 400 ])
 401 ])
 402
 403 # 2.6.24
 404
 405 # 2.6.24 has bio_endio with 2 args
 406 AC_DEFUN([LC_BIO_ENDIO_2ARG],
 407 [AC_MSG_CHECKING([if kernel has bio_endio with 2 args])
 408 LB_LINUX_TRY_COMPILE([
 409         #include <linux/bio.h>
 410 ],[
 411         bio_endio(NULL, 0);
 412 ], [
 413         AC_MSG_RESULT([yes])
 414         AC_DEFINE(HAVE_BIO_ENDIO_2ARG, 1,
 415                 [kernel has bio_endio with 2 args])
 416 ],[
 417         AC_MSG_RESULT([no])
 418 ])
 419 ])
 420
 421 # 2.6.24 removes long aged procfs entry -> deleted member
 422 AC_DEFUN([LC_PROCFS_DELETED],
 423 [AC_MSG_CHECKING([if kernel has deleted member in procfs entry struct])
 424 LB_LINUX_TRY_COMPILE([
 425         #include <linux/proc_fs.h>
 426 ],[
 427         struct proc_dir_entry pde;
 428
 429         pde.deleted = sizeof(pde);
 430 ], [
 431         AC_MSG_RESULT([yes])
 432         AC_DEFINE(HAVE_PROCFS_DELETED, 1,
 433                 [kernel has deleted member in procfs entry struct])
 434 ],[
 435         AC_MSG_RESULT([no])
 436 ])
 437 ])
 438
 439 # 2.6.26
 440
 441 # 2.6.26 isn't export set_fs_pwd and change paramter in fs struct
 442 AC_DEFUN([LC_FS_STRUCT_USE_PATH],
 443 [AC_MSG_CHECKING([fs_struct use path structure])
 444 LB_LINUX_TRY_COMPILE([
 445         #include <asm/atomic.h>
 446         #include <linux/spinlock.h>
 447         #include <linux/fs_struct.h>
 448 ],[
 449         struct fs_struct fs;
 450
 451         fs.pwd = *((struct path *)sizeof(fs));
 452 ], [
 453         AC_MSG_RESULT([yes])
 454         AC_DEFINE(HAVE_FS_STRUCT_USE_PATH, 1,
 455                 [fs_struct use path structure])
 456 ],[
 457         AC_MSG_RESULT([no])
 458 ])
 459 ])
 460
 461 #
 462 # 2.6.27
 463 #
 464
 465 # LC_SECURITY_PLUG  # for SLES10 SP2 (2.6.27)
 466 # check security plug in sles10 sp2 kernel
 467 AC_DEFUN([LC_SECURITY_PLUG],
 468 [AC_MSG_CHECKING([If kernel has security plug support])
 469 LB_LINUX_TRY_COMPILE([
 470         #include <linux/fs.h>
 471         #include <linux/stddef.h>
 472 ],[
 473         notify_change(NULL, NULL, NULL);
 474 ],[
 475         AC_MSG_RESULT(yes)
 476         AC_DEFINE(HAVE_SECURITY_PLUG, 1,
 477                 [SLES10 SP2 use extra parameter in vfs])
 478 ],[
 479         AC_MSG_RESULT(no)
 480 ])
 481 ])
 482
 483 AC_DEFUN([LC_INODE_PERMISION_2ARGS],
 484 [AC_MSG_CHECKING([inode_operations->permission has two args])
 485 LB_LINUX_TRY_COMPILE([
 486         #include <linux/fs.h>
 487 ],[
 488         struct inode *inode __attribute__ ((unused));
 489
 490         inode = NULL;
 491         inode->i_op->permission(NULL, 0);
 492 ],[
 493         AC_DEFINE(HAVE_INODE_PERMISION_2ARGS, 1,
 494                   [inode_operations->permission has two args])
 495         AC_MSG_RESULT([yes])
 496 ],[
 497         AC_MSG_RESULT([no])
 498 ])
 499 ])
 500
 501 # 2.6.27 use 5th parameter in quota_on for remount.
 502 AC_DEFUN([LC_QUOTA_ON_5ARGS],
 503 [AC_MSG_CHECKING([quota_on needs 5 parameters])
 504 LB_LINUX_TRY_COMPILE([
 505         #include <linux/fs.h>
 506         #include <linux/quota.h>
 507 ],[
 508         struct quotactl_ops *qop = NULL;
 509         qop->quota_on(NULL, 0, 0, NULL, 0);
 510 ],[
 511         AC_DEFINE(HAVE_QUOTA_ON_5ARGS, 1,
 512                 [quota_on needs 5 paramters])
 513         AC_MSG_RESULT([yes])
 514 ],[
 515         AC_MSG_RESULT([no])
 516 ])
 517 ])
 518
 519 # 2.6.27 use 3th parameter in quota_off for remount.
 520 AC_DEFUN([LC_QUOTA_OFF_3ARGS],
 521 [AC_MSG_CHECKING([quota_off needs 3 parameters])
 522 LB_LINUX_TRY_COMPILE([
 523         #include <linux/fs.h>
 524         #include <linux/quota.h>
 525 ],[
 526         struct quotactl_ops *qop = NULL;
 527         qop->quota_off(NULL, 0, 0);
 528 ],[
 529         AC_DEFINE(HAVE_QUOTA_OFF_3ARGS, 1,
 530                 [quota_off needs 3 paramters])
 531         AC_MSG_RESULT([yes])
 532 ],[
 533         AC_MSG_RESULT([no])
 534 ])
 535 ])
 536
 537 # 2.6.34 has quotactl_ops->[sg]et_dqblk that take struct fs_disk_quota
 538 AC_DEFUN([LC_HAVE_DQUOT_FS_DISK_QUOTA],
 539 tmp_flags="$EXTRA_KCFLAGS"
 540 EXTRA_KCFLAGS="-Werror"
 541 [AC_MSG_CHECKING([if quotactl_ops.set_dqblk takes struct fs_disk_quota])
 542 LB_LINUX_TRY_COMPILE([
 543         #include <linux/fs.h>
 544         #include <linux/quota.h>
 545 ],[
 546         struct quotactl_ops qops = {};
 547         struct fs_disk_quota fdq;
 548         qops.set_dqblk(NULL, 0, 0, &fdq);
 549 ],[
 550         AC_DEFINE(HAVE_DQUOT_FS_DISK_QUOTA, 1, [quotactl_ops.set_dqblk takes struct fs_disk_quota])
 551         AC_MSG_RESULT([yes])
 552 ],[
 553         AC_MSG_RESULT([no])
 554 ])
 555 EXTRA_KCFLAGS="$tmp_flags"
 556 ])
 557
 558 # 2.6.34 has renamed dquot options to dquot_*, check for dquot_suspend
 559 AC_DEFUN([LC_HAVE_DQUOT_SUSPEND],
 560 [AC_MSG_CHECKING([if dquot_suspend is defined])
 561 LB_LINUX_TRY_COMPILE([
 562         #include <linux/quotaops.h>
 563 ],[
 564         dquot_suspend(NULL, -1);
 565 ],[
 566         AC_DEFINE(HAVE_DQUOT_SUSPEND, 1, [dquot_suspend is defined])
 567         AC_MSG_RESULT([yes])
 568 ],[
 569         AC_MSG_RESULT([no])
 570 ])
 571 ])
 572
 573 # 2.6.27.15-2 sles11
 574
 575 # 2.6.27 sles11 remove the bi_hw_segments
 576 AC_DEFUN([LC_BI_HW_SEGMENTS],
 577 [AC_MSG_CHECKING([struct bio has a bi_hw_segments field])
 578 LB_LINUX_TRY_COMPILE([
 579         #include <linux/bio.h>
 580 ],[
 581         struct bio io;
 582         io.bi_hw_segments = sizeof(io);
 583 ],[
 584         AC_DEFINE(HAVE_BI_HW_SEGMENTS, 1,
 585                 [struct bio has a bi_hw_segments field])
 586         AC_MSG_RESULT([yes])
 587 ],[
 588         AC_MSG_RESULT([no])
 589 ])
 590 ])
 591
 592 #
 593 # 2.6.27 sles11 move the quotaio_v1{2}.h from include/linux to fs
 594 # 2.6.32 move the quotaio_v1{2}.h from fs to fs/quota
 595 AC_DEFUN([LC_HAVE_QUOTAIO_H],
 596 [LB_CHECK_FILE([$LINUX/include/linux/quotaio_v2.h],[
 597         AC_DEFINE(HAVE_QUOTAIO_H, 1,
 598                 [kernel has include/linux/quotaio_v2.h])
 599 ],[LB_CHECK_FILE([$LINUX/fs/quotaio_v2.h],[
 600                AC_DEFINE(HAVE_FS_QUOTAIO_H, 1,
 601                 [kernel has fs/quotaio_v1.h])
 602 ],[LB_CHECK_FILE([$LINUX/fs/quota/quotaio_v2.h],[
 603                AC_DEFINE(HAVE_FS_QUOTA_QUOTAIO_H, 1,
 604                 [kernel has fs/quota/quotaio_v2.h])
 605 ],[
 606         AC_MSG_RESULT([no])
 607 ])
 608 ])
 609 ])
 610 ])
 611
 612 # 2.6.32
 613
 614 # 2.6.32 replaces 2 functions blk_queue_max_phys_segments and blk_queue_max_hw_segments by blk_queue_max_segments
 615 AC_DEFUN([LC_BLK_QUEUE_MAX_SEGMENTS],
 616 [AC_MSG_CHECKING([if blk_queue_max_segments is defined])
 617 LB_LINUX_TRY_COMPILE([
 618         #include <linux/blkdev.h>
 619 ],[
 620         blk_queue_max_segments(NULL, 0);
 621 ],[
 622         AC_MSG_RESULT(yes)
 623         AC_DEFINE(HAVE_BLK_QUEUE_MAX_SEGMENTS, 1,
 624                   [blk_queue_max_segments is defined])
 625 ],[
 626         AC_MSG_RESULT(no)
 627 ])
 628 ])
 629
 630 #
 631 # LC_QUOTA64
 632 #
 633 # Check if kernel has been patched for 64-bit quota limits support.
 634 # The upstream version of this patch in RHEL6 2.6.32 kernels introduces
 635 # the constant QFMT_VFS_V1 in include/linux/quota.h, so we can check for
 636 # that in the absence of quotaio_v1.h in the kernel headers.
 637 #
 638 AC_DEFUN([LC_QUOTA64],[
 639         AC_MSG_CHECKING([if kernel has 64-bit quota limits support])
 640 tmp_flags="$EXTRA_KCFLAGS"
 641 EXTRA_KCFLAGS="-I$LINUX/fs"
 642         LB_LINUX_TRY_COMPILE([
 643                 #include <linux/kernel.h>
 644                 #include <linux/fs.h>
 645                 #if defined(HAVE_FS_QUOTA_QUOTAIO_H)
 646                 # include <quota/quotaio_v2.h>
 647                 struct v2r1_disk_dqblk dqblk_r1;
 648                 #else
 649                 #include <linux/quota.h>
 650                 int ver = QFMT_VFS_V1;
 651                 #endif
 652         ],[],[
 653                 AC_DEFINE(HAVE_QUOTA64, 1, [have quota64])
 654                 AC_MSG_RESULT([yes])
 655         ],[
 656                 LB_CHECK_FILE([$LINUX/include/linux/lustre_version.h],[
 657                         AC_MSG_ERROR([You have got no 64-bit kernel quota support.])
 658                 ],[])
 659                 AC_MSG_RESULT([no])
 660         ])
 661 EXTRA_KCFLAGS=$tmp_flags
 662 ])
 663
 664 #
 665 # 2.6.36 fs_struct.lock use spinlock instead of rwlock.
 666 #
 667 AC_DEFUN([LC_FS_STRUCT_RWLOCK],
 668 [AC_MSG_CHECKING([if fs_struct.lock use rwlock])
 669 LB_LINUX_TRY_COMPILE([
 670         #include <asm/atomic.h>
 671         #include <linux/spinlock.h>
 672         #include <linux/fs_struct.h>
 673 ],[
 674         ((struct fs_struct *)0)->lock = (rwlock_t){ 0 };
 675 ],[
 676         AC_DEFINE(HAVE_FS_STRUCT_RWLOCK, 1,
 677                   [fs_struct.lock use rwlock])
 678         AC_MSG_RESULT([yes])
 679 ],[
 680         AC_MSG_RESULT([no])
 681 ])
 682 ])
 683
 684 #
 685 # 2.6.36 super_operations add evict_inode method. it hybird of
 686 # delete_inode & clear_inode.
 687 #
 688 AC_DEFUN([LC_SBOPS_EVICT_INODE],
 689 [AC_MSG_CHECKING([if super_operations.evict_inode exist])
 690 LB_LINUX_TRY_COMPILE([
 691         #include <linux/fs.h>
 692 ],[
 693         ((struct super_operations *)0)->evict_inode(NULL);
 694 ],[
 695         AC_DEFINE(HAVE_SBOPS_EVICT_INODE, 1,
 696                 [super_operations.evict_inode() is exist in kernel])
 697         AC_MSG_RESULT([yes])
 698 ],[
 699         AC_MSG_RESULT([no])
 700 ])
 701 ])
 702
 703 #
 704 # 2.6.35 file_operations.fsync taken 2 arguments.
 705 # 3.0.0 file_operations.fsync takes 4 arguments.
 706 #
 707 AC_DEFUN([LC_FILE_FSYNC],
 708 [AC_MSG_CHECKING([if file_operations.fsync takes 4 or 2 arguments])
 709 LB_LINUX_TRY_COMPILE([
 710         #include <linux/fs.h>
 711 ],[
 712         ((struct file_operations *)0)->fsync(NULL, 0, 0, 0);
 713 ],[
 714         AC_DEFINE(HAVE_FILE_FSYNC_4ARGS, 1,
 715                 [file_operations.fsync takes 4 arguments])
 716         AC_MSG_RESULT([yes, 4 args])
 717 ],[
 718         LB_LINUX_TRY_COMPILE([
 719                 #include <linux/fs.h>
 720         ],[
 721            ((struct file_operations *)0)->fsync(NULL, 0);
 722         ],[
 723                 AC_DEFINE(HAVE_FILE_FSYNC_2ARGS, 1,
 724                         [file_operations.fsync takes 2 arguments])
 725                 AC_MSG_RESULT([yes, 2 args])
 726         ],[
 727                 AC_MSG_RESULT([no])
 728         ])
 729 ])
 730 ])
 731
 732 #
 733 # 2.6.37 remove kernel_locked
 734 #
 735 AC_DEFUN([LC_KERNEL_LOCKED],
 736 [AC_MSG_CHECKING([if kernel_locked is defined])
 737 LB_LINUX_TRY_COMPILE([
 738         #include <linux/smp_lock.h>
 739 ],[
 740         kernel_locked();
 741 ],[
 742         AC_MSG_RESULT([yes])
 743         AC_DEFINE(HAVE_KERNEL_LOCKED, 1,
 744                 [kernel_locked is defined])
 745 ],[
 746         AC_MSG_RESULT([no])
 747 ])
 748 ])
 749
 750 #
 751 # 2.6.38 dentry_operations.d_compare() taken 7 arguments.
 752 #
 753 AC_DEFUN([LC_D_COMPARE_7ARGS],
 754 [AC_MSG_CHECKING([if d_compare taken 7 arguments])
 755 LB_LINUX_TRY_COMPILE([
 756         #include <linux/dcache.h>
 757 ],[
 758         ((struct dentry_operations*)0)->d_compare(NULL,NULL,NULL,NULL,0,NULL,NULL);
 759 ],[
 760         AC_DEFINE(HAVE_D_COMPARE_7ARGS, 1,
 761                 [d_compare need 7 arguments])
 762         AC_MSG_RESULT([yes])
 763 ],[
 764         AC_MSG_RESULT([no])
 765 ])
 766 ])
 767
 768 #
 769 # 2.6.38 dentry_operations.d_delete() defined 'const' for 1st parameter.
 770 #
 771 AC_DEFUN([LC_D_DELETE_CONST],
 772 [AC_MSG_CHECKING([if d_delete has const declare on first parameter])
 773 tmp_flags="$EXTRA_KCFLAGS"
 774 EXTRA_KCFLAGS="-Werror"
 775 LB_LINUX_TRY_COMPILE([
 776         #include <linux/dcache.h>
 777 ],[
 778         const struct dentry *d = NULL;
 779         ((struct dentry_operations*)0)->d_delete(d);
 780 ],[
 781         AC_DEFINE(HAVE_D_DELETE_CONST, const,
 782                 [d_delete first parameter declared const])
 783         AC_MSG_RESULT([yes])
 784 ],[
 785         AC_DEFINE(HAVE_D_DELETE_CONST, , [])
 786         AC_MSG_RESULT([no])
 787 ])
 788 EXTRA_KCFLAGS="$tmp_flags"
 789 ])
 790
 791 #
 792 # 2.6.38 dcache_lock removed. rcu-walk commited.
 793 #
 794 AC_DEFUN([LC_DCACHE_LOCK],
 795 [AC_MSG_CHECKING([if dcache_lock is exist])
 796 LB_LINUX_TRY_COMPILE([
 797         #include <linux/dcache.h>
 798 ],[
 799         spin_lock(&dcache_lock);
 800 ],[
 801         AC_DEFINE(HAVE_DCACHE_LOCK, 1,
 802                 [dcache_lock is exist])
 803         AC_MSG_RESULT([yes])
 804 ],[
 805         AC_MSG_RESULT([no])
 806 ])
 807 ])
 808
 809 #
 810 # 2.6.38 inode.i_rcu added.
 811 #
 812 AC_DEFUN([LC_INODE_I_RCU],
 813 [AC_MSG_CHECKING([if inode.i_rcu exists])
 814 LB_LINUX_TRY_COMPILE([
 815         #include <linux/fs.h>
 816 ],[
 817         struct inode ino;
 818         struct rcu_head rcu = {};
 819         ino.i_rcu = rcu;
 820 ],[
 821         AC_DEFINE(HAVE_INODE_I_RCU, 1,
 822                 [inode.i_rcu exists])
 823         AC_MSG_RESULT([yes])
 824 ],[
 825         AC_MSG_RESULT([no])
 826 ])
 827 ])
 828
 829 #
 830 # 2.6.38 export blkdev_get_by_dev
 831 #
 832 AC_DEFUN([LC_BLKDEV_GET_BY_DEV],
 833 [LB_CHECK_SYMBOL_EXPORT([blkdev_get_by_dev],
 834 [fs/block_dev.c],[
 835 AC_DEFINE(HAVE_BLKDEV_GET_BY_DEV, 1,
 836             [blkdev_get_by_dev is exported by the kernel])
 837 ],[
 838 ])
 839 ])
 840
 841 #
 842 # 2.6.38 use path as 4th parameter in quota_on.
 843 #
 844 AC_DEFUN([LC_QUOTA_ON_USE_PATH],
 845 [AC_MSG_CHECKING([quota_on use path as parameter])
 846 tmp_flags="$EXTRA_KCFLAGS"
 847 EXTRA_KCFLAGS="-Werror"
 848 LB_LINUX_TRY_COMPILE([
 849         #include <linux/fs.h>
 850         #include <linux/quota.h>
 851 ],[
 852         ((struct quotactl_ops *)0)->quota_on(NULL, 0, 0, ((struct path*)0));
 853 ],[
 854         AC_DEFINE(HAVE_QUOTA_ON_USE_PATH, 1,
 855                 [quota_on use path as 4th paramter])
 856         AC_MSG_RESULT([yes])
 857 ],[
 858         AC_MSG_RESULT([no])
 859 ])
 860 EXTRA_KCFLAGS="$tmp_flags"
 861 ])
 862
 863 #
 864 # 2.6.38 export simple_setattr
 865 #
 866 AC_DEFUN([LC_EXPORT_SIMPLE_SETATTR],
 867 [LB_CHECK_SYMBOL_EXPORT([simple_setattr],
 868 [fs/libfs.c],[
 869 AC_DEFINE(HAVE_SIMPLE_SETATTR, 1,
 870             [simple_setattr is exported by the kernel])
 871 ],[
 872 ])
 873 ])
 874
 875 #
 876 # 2.6.39 remove unplug_fn from request_queue.
 877 #
 878 AC_DEFUN([LC_REQUEST_QUEUE_UNPLUG_FN],
 879 [AC_MSG_CHECKING([if request_queue has unplug_fn field])
 880 LB_LINUX_TRY_COMPILE([
 881         #include <linux/blkdev.h>
 882 ],[
 883         do{ }while(sizeof(((struct request_queue *)0)->unplug_fn));
 884 ],[
 885         AC_DEFINE(HAVE_REQUEST_QUEUE_UNPLUG_FN, 1,
 886                   [request_queue has unplug_fn field])
 887         AC_MSG_RESULT([yes])
 888 ],[
 889         AC_MSG_RESULT([no])
 890 ])
 891 ])
 892
 893 #
 894 # 2.6.39 replace get_sb with mount in struct file_system_type
 895 #
 896 AC_DEFUN([LC_HAVE_FSTYPE_MOUNT],
 897 [AC_MSG_CHECKING([if file_system_type has mount field])
 898 LB_LINUX_TRY_COMPILE([
 899         #include <linux/fs.h>
 900 ],[
 901         struct file_system_type fst;
 902         void *i = (void *) fst.mount;
 903 ],[
 904         AC_DEFINE(HAVE_FSTYPE_MOUNT, 1,
 905                 [struct file_system_type has mount field])
 906         AC_MSG_RESULT([yes])
 907 ],[
 908         AC_MSG_RESULT([no])
 909 ])
 910 ])
 911
 912 #
 913 # 3.0 dirty_inode() has a flag parameter
 914 # see kernel commit aa38572954ade525817fe88c54faebf85e5a61c0
 915 #
 916 AC_DEFUN([LC_DIRTY_INODE_WITH_FLAG],
 917 [AC_MSG_CHECKING([if dirty_inode super_operation takes flag])
 918 LB_LINUX_TRY_COMPILE([
 919         #include <linux/fs.h>
 920 ],[
 921         struct inode *inode;
 922         inode->i_sb->s_op->dirty_inode(NULL, 0);
 923 ],[
 924         AC_DEFINE(HAVE_DIRTY_INODE_HAS_FLAG, 1,
 925                   [dirty_inode super_operation takes flag])
 926         AC_MSG_RESULT([yes])
 927 ],[
 928         AC_MSG_RESULT([no])
 929 ])
 930 ])
 931
 932 #
 933 # 2.6.38 generic_permission taken 4 parameters.
 934 # in fact, it means rcu-walk aware permission bring.
 935 #
 936 # 3.1 generic_permission taken 2 parameters.
 937 # see kernel commit 2830ba7f34ebb27c4e5b8b6ef408cd6d74860890
 938 #
 939 AC_DEFUN([LC_GENERIC_PERMISSION],
 940 [AC_MSG_CHECKING([if generic_permission take 2 or 4 arguments])
 941 LB_LINUX_TRY_COMPILE([
 942         #include <linux/fs.h>
 943 ],[
 944         generic_permission(NULL, 0);
 945 ],[
 946         AC_DEFINE(HAVE_GENERIC_PERMISSION_2ARGS, 1,
 947                   [generic_permission taken 2 arguments])
 948         AC_MSG_RESULT([yes, 2 args])
 949 ],[
 950         LB_LINUX_TRY_COMPILE([
 951                 #include <linux/fs.h>
 952         ],[
 953                 generic_permission(NULL, 0, 0, NULL);
 954         ],[
 955                 AC_DEFINE(HAVE_GENERIC_PERMISSION_4ARGS, 1,
 956                           [generic_permission taken 4 arguments])
 957                 AC_MSG_RESULT([yes, 4 args])
 958         ],[
 959                 AC_MSG_RESULT([no])
 960         ])
 961 ])
 962 ])
 963
 964 #
 965 # 3.1 renames lock-manager ops(lock_manager_operations) from fl_xxx to lm_xxx
 966 # see kernel commit 8fb47a4fbf858a164e973b8ea8ef5e83e61f2e50
 967 #
 968 AC_DEFUN([LC_LM_XXX_LOCK_MANAGER_OPS],
 969 [AC_MSG_CHECKING([if lock-manager ops renamed to lm_xxx])
 970 LB_LINUX_TRY_COMPILE([
 971         #include <linux/fs.h>
 972 ],[
 973         struct lock_manager_operations lm_ops;
 974         lm_ops.lm_compare_owner = NULL;
 975 ],[
 976         AC_DEFINE(HAVE_LM_XXX_LOCK_MANAGER_OPS, 1,
 977                   [lock-manager ops renamed to lm_xxx])
 978         AC_MSG_RESULT([yes])
 979 ],[
 980         AC_MSG_RESULT([no])
 981 ])
 982 ])
 983
 984 #
 985 # 3.1 kills inode->i_alloc_sem, use i_dio_count and inode_dio_wait/
 986 #     inode_dio_done instead.
 987 # see kernel commit bd5fe6c5eb9c548d7f07fe8f89a150bb6705e8e3
 988 #
 989 AC_DEFUN([LC_INODE_DIO_WAIT],
 990 [AC_MSG_CHECKING([if inode->i_alloc_sem is killed and use inode_dio_wait/done.])
 991 LB_LINUX_TRY_COMPILE([
 992         #include <linux/fs.h>
 993 ],[
 994         inode_dio_wait((struct inode *)0);
 995         inode_dio_done((struct inode *)0);
 996 ],[
 997         AC_DEFINE(HAVE_INODE_DIO_WAIT, 1,
 998                   [inode->i_alloc_sem is killed and use inode_dio_wait/done])
 999         AC_MSG_RESULT([yes])
1000 ],[
1001         AC_MSG_RESULT([no])
1002 ])
1003 ])
1004
1005 #
1006 # 3.1 adds get_acl method to inode_operations to read ACL from disk.
1007 # see kernel commit 4e34e719e457f2e031297175410fc0bd4016a085
1008 #
1009 AC_DEFUN([LC_IOP_GET_ACL],
1010 [AC_MSG_CHECKING([inode_operations has .get_acl member function])
1011 LB_LINUX_TRY_COMPILE([
1012         #include <linux/fs.h>
1013 ],[
1014         struct inode_operations iop;
1015         iop.get_acl = NULL;
1016 ],[
1017         AC_DEFINE(HAVE_IOP_GET_ACL, 1,
1018                   [inode_operations has .get_acl member function])
1019         AC_MSG_RESULT([yes])
1020 ],[
1021         AC_MSG_RESULT([no])
1022 ])
1023 ])
1024
1025 #
1026 # 3.1.1 has ext4_blocks_for_truncate
1027 #
1028 AC_DEFUN([LC_BLOCKS_FOR_TRUNCATE],
1029 [AC_MSG_CHECKING([if kernel has ext4_blocks_for_truncate])
1030 LB_LINUX_TRY_COMPILE([
1031         #include <linux/fs.h>
1032         #include "$LINUX/fs/ext4/ext4_jbd2.h"
1033         #include "$LINUX/fs/ext4/truncate.h"
1034 ],[
1035         ext4_blocks_for_truncate(NULL);
1036 ],[
1037         AC_MSG_RESULT([yes])
1038         AC_DEFINE(HAVE_BLOCKS_FOR_TRUNCATE, 1,
1039                   [kernel has ext4_blocks_for_truncate])
1040 ],[
1041         AC_MSG_RESULT([no])
1042 ])
1043 ])
1044
1045 #
1046 # 3.1 introduced generic_file_llseek_size()
1047 #
1048 AC_DEFUN([LC_FILE_LLSEEK_SIZE],
1049         [LB_CHECK_SYMBOL_EXPORT([generic_file_llseek_size],
1050         [fs/read_write.c],
1051         [AC_DEFINE(HAVE_FILE_LLSEEK_SIZE, 1,
1052                    [generic_file_llseek_size is exported by the kernel])])
1053 ])
1054
1055 #
1056 # 3.2 request_queue.make_request_fn defined as function returns with void
1057 # see kernel commit 5a7bbad27a410350e64a2d7f5ec18fc73836c14f
1058 #
1059 AC_DEFUN([LC_HAVE_VOID_MAKE_REQUEST_FN],
1060 [AC_MSG_CHECKING([if request_queue.make_request_fn returns void but not int])
1061 LB_LINUX_TRY_COMPILE([
1062         #include <linux/blkdev.h>
1063 ],[
1064         int ret;
1065         make_request_fn         *mrf;
1066         ret = mrf(NULL, NULL);
1067 ],[
1068         AC_MSG_RESULT([no])
1069 ],[
1070         AC_DEFINE(HAVE_VOID_MAKE_REQUEST_FN, 1,
1071                   [request_queue.make_request_fn returns void but not int])
1072         AC_MSG_RESULT([yes])
1073 ])
1074 ])
1075
1076 #
1077 # 3.2 protects inode->i_nlink from direct modification
1078 # see kernel commit a78ef704a8dd430225955f0709b22d4a6ba21deb
1079 # at the same time adds set_nlink(), so checks set_nlink() for it.
1080 #
1081 AC_DEFUN([LC_HAVE_PROTECT_I_NLINK],
1082 [AC_MSG_CHECKING([if inode->i_nlink is protected from direct modification])
1083 LB_LINUX_TRY_COMPILE([
1084         #include <linux/fs.h>
1085 ],[
1086         struct inode i;
1087         set_nlink(&i, 1);
1088 ],[
1089         AC_DEFINE(HAVE_PROTECT_I_NLINK, 1,
1090                   [inode->i_nlink is protected from direct modification])
1091         AC_MSG_RESULT([yes])
1092 ],[
1093         AC_MSG_RESULT([no])
1094 ])
1095 ])
1096
1097 #
1098 # 3.3 introduces migrate_mode.h and migratepage has 4 args
1099 #
1100 AC_DEFUN([LC_HAVE_MIGRATE_HEADER],
1101 [LB_CHECK_FILE([$LINUX/include/linux/migrate.h],[
1102                 AC_DEFINE(HAVE_MIGRATE_H, 1,
1103                 [kernel has include/linux/migrate.h])
1104 ],[LB_CHECK_FILE([$LINUX/include/linux/migrate_mode.h],[
1105                 AC_DEFINE(HAVE_MIGRATE_MODE_H, 1,
1106                         [kernel has include/linux/migrate_mode.h])
1107 ],[
1108         AC_MSG_RESULT([no])
1109 ])
1110 ])
1111 ])
1112
1113 AC_DEFUN([LC_MIGRATEPAGE_4ARGS],
1114 [AC_MSG_CHECKING([if address_space_operations.migratepage has 4 args])
1115 LB_LINUX_TRY_COMPILE([
1116         #include <linux/fs.h>
1117 #ifdef HAVE_MIGRATE_H
1118         #include <linux/migrate.h>
1119 #elif defined(HAVE_MIGRATE_MODE_H)
1120         #include <linux/migrate_mode.h>
1121 #endif
1122 ],[
1123         struct address_space_operations aops;
1124
1125         aops.migratepage(NULL, NULL, NULL, MIGRATE_ASYNC);
1126 ],[
1127         AC_DEFINE(HAVE_MIGRATEPAGE_4ARGS, 1,
1128                 [address_space_operations.migratepage has 4 args])
1129         AC_MSG_RESULT([yes])
1130 ],[
1131         AC_MSG_RESULT([no])
1132 ])
1133 ])
1134
1135 #
1136 # 3.3 switchs super_operations to use dentry as parameter (but not vfsmount)
1137 # see kernel commit 34c80b1d93e6e20ca9dea0baf583a5b5510d92d4
1138 #
1139 AC_DEFUN([LC_SUPEROPS_USE_DENTRY],
1140 [AC_MSG_CHECKING([if super_operations use dentry as parameter])
1141 tmp_flags="$EXTRA_KCFLAGS"
1142 EXTRA_KCFLAGS="-Werror"
1143 LB_LINUX_TRY_COMPILE([
1144         #include <linux/fs.h>
1145         int show_options(struct seq_file *seq, struct dentry *root){
1146                 return 0;
1147         }
1148 ],[
1149         struct super_operations ops;
1150         ops.show_options = show_options;
1151 ],[
1152         AC_DEFINE(HAVE_SUPEROPS_USE_DENTRY, 1,
1153                   [super_operations use dentry as parameter])
1154         AC_MSG_RESULT([yes])
1155 ],[
1156         AC_MSG_RESULT([no])
1157 ])
1158 EXTRA_KCFLAGS="$tmp_flags"
1159 ])
1160
1161 #
1162 # 3.3 switchs inode_operations to use umode_t as parameter (but not int)
1163 # see kernel commit 1a67aafb5f72a436ca044293309fa7e6351d6a35
1164 #
1165 AC_DEFUN([LC_INODEOPS_USE_UMODE_T],
1166 [AC_MSG_CHECKING([if inode_operations use umode_t as parameter])
1167 tmp_flags="$EXTRA_KCFLAGS"
1168 EXTRA_KCFLAGS="-Werror"
1169 LB_LINUX_TRY_COMPILE([
1170         #include <linux/fs.h>
1171         #include <linux/types.h>
1172         int my_mknod(struct inode *dir, struct dentry *dchild,
1173                      umode_t mode, dev_t dev)
1174         {
1175                 return 0;
1176         }
1177 ],[
1178         struct inode_operations ops;
1179         ops.mknod = my_mknod;
1180 ],[
1181         AC_DEFINE(HAVE_INODEOPS_USE_UMODE_T, 1,
1182                   [inode_operations use umode_t as parameter])
1183         AC_MSG_RESULT([yes])
1184 ],[
1185         AC_MSG_RESULT([no])
1186 ])
1187 EXTRA_KCFLAGS="$tmp_flags"
1188 ])
1189
1190 # 3.4 kmap_atomic removes second argument
1191 # see kernel commit 1ec9c5ddc17aa398f05646abfcbaf315b544e62f
1192 #
1193 AC_DEFUN([LC_KMAP_ATOMIC_HAS_1ARG],
1194 [AC_MSG_CHECKING([if kmap_atomic has only 1 argument])
1195 LB_LINUX_TRY_COMPILE([
1196         #include <linux/highmem.h>
1197 ],[
1198         kmap_atomic(NULL);
1199 ],[
1200         AC_DEFINE(HAVE_KMAP_ATOMIC_HAS_1ARG, 1,
1201                   [have kmap_atomic has only 1 argument])
1202         AC_MSG_RESULT([yes])
1203 ],[
1204         AC_MSG_RESULT([no])
1205 ])
1206 ])
1207
1208 #
1209 # 3.4 switchs touch_atime to struct path
1210 # see kernel commit 68ac1234fb949b66941d94dce4157742799fc581
1211 #
1212 AC_DEFUN([LC_TOUCH_ATIME_1ARG],
1213 [AC_MSG_CHECKING([if touch_atime use one argument])
1214 LB_LINUX_TRY_COMPILE([
1215         #include <linux/fs.h>
1216 ],[
1217         touch_atime((struct path *)NULL);
1218 ],[
1219         AC_DEFINE(HAVE_TOUCH_ATIME_1ARG, 1,
1220                   [touch_atime use one argument])
1221         AC_MSG_RESULT([yes])
1222 ],[
1223         AC_MSG_RESULT([no])
1224 ])
1225 ])
1226
1227 #
1228 # 3.4 converts d_alloc_root to d_make_root
1229 # see kernel commit 32991ab305ace7017c62f8eecbe5eb36dc32e13b
1230 #
1231 AC_DEFUN([LC_HAVE_D_MAKE_ROOT],
1232 [AC_MSG_CHECKING([if have d_make_root])
1233 LB_LINUX_TRY_COMPILE([
1234         #include <linux/fs.h>
1235 ],[
1236         d_make_root((struct inode *)NULL);
1237 ],[
1238         AC_DEFINE(HAVE_D_MAKE_ROOT, 1,
1239                   [have d_make_root])
1240         AC_MSG_RESULT([yes])
1241 ],[
1242         AC_MSG_RESULT([no])
1243 ])
1244 ])
1245
1246 #
1247 # 3.5 renames end_writeback() back to clear_inode()...
1248 # see kernel commit dbd5768f87ff6fb0a4fe09c4d7b6c4a24de99430
1249 #
1250 AC_DEFUN([LC_HAVE_CLEAR_INODE],
1251 [AC_MSG_CHECKING([if have clear_inode])
1252 LB_LINUX_TRY_COMPILE([
1253         #include <linux/fs.h>
1254 ],[
1255         clear_inode((struct inode *)NULL);
1256 ],[
1257         AC_DEFINE(HAVE_CLEAR_INODE, 1,
1258                   [have clear_inode])
1259         AC_MSG_RESULT([yes])
1260 ],[
1261         AC_MSG_RESULT([no])
1262 ])
1263 ])
1264
1265 #
1266 # 3.5 encode_fh has parent inode passed in directly
1267 # see kernel commit b0b0382b
1268 #
1269 AC_DEFUN([LC_HAVE_ENCODE_FH_PARENT],
1270 [AC_MSG_CHECKING([if encode_fh have parent inode as parameter])
1271 tmp_flags="$EXTRA_KCFLAGS"
1272 EXTRA_KCFLAGS="-Werror"
1273 LB_LINUX_TRY_COMPILE([
1274         #include <linux/exportfs.h>
1275         #include <linux/fs.h>
1276         #include <linux/types.h>
1277         int ll_encode_fh(struct inode *i, __u32 *a, int *b, struct inode *p)
1278         {
1279                 return 0;
1280         }
1281 ],[
1282         struct export_operations exp_op;
1283         exp_op.encode_fh = ll_encode_fh;
1284 ],[
1285         AC_DEFINE(HAVE_ENCODE_FH_PARENT, 1,
1286                   [have parent inode as parameter])
1287         AC_MSG_RESULT([yes])
1288 ],[
1289         AC_MSG_RESULT([no])
1290 ])
1291 EXTRA_KCFLAGS="$tmp_flags"
1292 ])
1293
1294 # 3.5 has generic_file_llseek_size with 5 args
1295 AC_DEFUN([LC_FILE_LLSEEK_SIZE_5ARG],
1296 [AC_MSG_CHECKING([if kernel has generic_file_llseek_size with 5 args])
1297 LB_LINUX_TRY_COMPILE([
1298         #include <linux/fs.h>
1299 ],[
1300         generic_file_llseek_size(NULL, 0, 0, 0, 0);
1301 ], [
1302         AC_MSG_RESULT([yes])
1303         AC_DEFINE(HAVE_FILE_LLSEEK_SIZE_5ARGS, 1,
1304                 [kernel has generic_file_llseek_size with 5 args])
1305 ],[
1306         AC_MSG_RESULT([no])
1307 ])
1308 ])
1309
1310 #
1311 # 3.6 switch i_dentry/d_alias from list to hlist
1312 #
1313 AC_DEFUN([LC_HAVE_DENTRY_D_ALIAS_HLIST],
1314 [AC_MSG_CHECKING([if i_dentry/d_alias uses hlist])
1315 tmp_flags="$EXTRA_KCFLAGS"
1316 EXTRA_KCFLAGS="-Werror"
1317 LB_LINUX_TRY_COMPILE([
1318         #include <linux/fs.h>
1319         #include <linux/list.h>
1320 ],[
1321         struct inode inode;
1322         struct dentry dentry;
1323         struct hlist_head head;
1324         struct hlist_node node;
1325         inode.i_dentry = head;
1326         dentry.d_alias = node;
1327 ],[
1328         AC_DEFINE(HAVE_DENTRY_D_ALIAS_HLIST, 1,
1329                   [have i_dentry/d_alias uses hlist])
1330         AC_MSG_RESULT([yes])
1331 ],[
1332         AC_MSG_RESULT([no])
1333 ])
1334 EXTRA_KCFLAGS="$tmp_flags"
1335 ])
1336
1337 #
1338 # 3.6 dentry_open uses struct path as first argument
1339 # see kernel commit 765927b2
1340 #
1341 AC_DEFUN([LC_DENTRY_OPEN_USE_PATH],
1342 [AC_MSG_CHECKING([if dentry_open uses struct path as first argument])
1343 tmp_flags="$EXTRA_KCFLAGS"
1344 EXTRA_KCFLAGS="-Werror"
1345 LB_LINUX_TRY_COMPILE([
1346         #include <linux/fs.h>
1347         #include <linux/path.h>
1348 ],[
1349         struct path path;
1350         dentry_open(&path, 0, NULL);
1351 ],[
1352         AC_DEFINE(HAVE_DENTRY_OPEN_USE_PATH, 1,
1353                   [dentry_open uses struct path as first argument])
1354         AC_MSG_RESULT([yes])
1355 ],[
1356         AC_MSG_RESULT([no])
1357 ])
1358 EXTRA_KCFLAGS="$tmp_flags"
1359 ])
1360
1361 #
1362 # 3.6 vfs adds iop->atomic_open
1363 #
1364 AC_DEFUN([LC_HAVE_IOP_ATOMIC_OPEN],
1365 [AC_MSG_CHECKING([if iop has atomic_open])
1366 LB_LINUX_TRY_COMPILE([
1367         #include <linux/fs.h>
1368 ],[
1369         struct inode_operations iop;
1370         iop.atomic_open = NULL;
1371 ],[
1372         AC_DEFINE(HAVE_IOP_ATOMIC_OPEN, 1,
1373                   [have iop atomic_open])
1374         AC_MSG_RESULT([yes])
1375 ],[
1376         AC_MSG_RESULT([no])
1377 ])
1378 ])
1379
1380 #
1381 # 3.7 posix_acl_{to,from}_xattr take struct user_namespace
1382 #
1383 AC_DEFUN([LC_HAVE_POSIXACL_USER_NS],
1384 [AC_MSG_CHECKING([if posix_acl_to_xattr takes struct user_namespace])
1385 LB_LINUX_TRY_COMPILE([
1386         #include <linux/fs.h>
1387         #include <linux/posix_acl_xattr.h>
1388 ],[
1389         posix_acl_to_xattr((struct user_namespace *)NULL, NULL, NULL, 0);
1390 ],[
1391         AC_DEFINE(HAVE_POSIXACL_USER_NS, 1,
1392                   [posix_acl_to_xattr takes struct user_namespace])
1393         AC_MSG_RESULT([yes])
1394 ],[
1395         AC_MSG_RESULT([no])
1396 ])
1397 ])
1398
1399 #
1400 # 3.9 uses hlist_for_each_entry with 3 args
1401 # b67bfe0d42cac56c512dd5da4b1b347a23f4b70a
1402 #
1403 AC_DEFUN([LC_HAVE_HLIST_FOR_EACH_3ARG],
1404 [AC_MSG_CHECKING([if hlist_for_each_entry has 3 args])
1405 LB_LINUX_TRY_COMPILE([
1406         #include <linux/list.h>
1407         #include <linux/fs.h>
1408 ],[
1409         struct inode *inode;
1410         struct dentry *dentry;
1411         hlist_for_each_entry(dentry, &inode->i_dentry, d_alias) {
1412                 continue;
1413         }
1414 ],[
1415         AC_DEFINE(HAVE_HLIST_FOR_EACH_3ARG, 1, [3 args])
1416         AC_MSG_RESULT([yes])
1417 ],[
1418         AC_MSG_RESULT([no])
1419 ])
1420 ])
1421
1422 #
1423 # 3.9 killed f_vfsmnt by
1424 # 182be684784334598eee1d90274e7f7aa0063616
1425 # replacement is f_path.mnt
1426 #
1427 AC_DEFUN([LC_HAVE_F_PATH_MNT],
1428 [AC_MSG_CHECKING([if struct file has f_path.mnt])
1429 LB_LINUX_TRY_COMPILE([
1430         #include <linux/fs.h>
1431 ],[
1432         struct file *fp = NULL;
1433         struct path  path;
1434
1435         path.mnt = fp->f_path.mnt;
1436 ],[
1437         AC_DEFINE(HAVE_F_PATH_MNT,1,[yes])
1438         AC_MSG_RESULT([yes])
1439 ],[
1440         AC_MSG_RESULT([no])
1441 ])
1442 ])
1443
1444 #
1445 # LC_PROG_LINUX
1446 #
1447 # Lustre linux kernel checks
1448 #
1449 AC_DEFUN([LC_PROG_LINUX],
1450          [
1451          LC_CONFIG_PINGER
1452          LC_CONFIG_CHECKSUM
1453          LC_CONFIG_LIBLUSTRE_RECOVERY
1454          LC_CONFIG_HEALTH_CHECK_WRITE
1455          LC_CONFIG_LRU_RESIZE
1456          LC_LLITE_LLOOP_MODULE
1457
1458          LC_CAPA_CRYPTO
1459          LC_CONFIG_RMTCLIENT
1460          LC_CONFIG_GSS
1461
1462          # 2.6.12
1463          LC_RW_TREE_LOCK
1464
1465          # raid5-zerocopy patch
1466          LC_PAGE_CONSTANT
1467
1468          # 2.6.22
1469          LC_FS_RENAME_DOES_D_MOVE
1470
1471          # 2.6.24
1472          LC_BIO_ENDIO_2ARG
1473          LC_PROCFS_DELETED
1474
1475          # 2.6.26
1476          LC_FS_STRUCT_USE_PATH
1477
1478          # 2.6.27
1479          LC_SECURITY_PLUG  # for SLES10 SP2
1480          LC_INODE_PERMISION_2ARGS
1481          LC_QUOTA_ON_5ARGS
1482          LC_QUOTA_OFF_3ARGS
1483
1484          # 2.6.27.15-2 sles11
1485          LC_BI_HW_SEGMENTS
1486          LC_HAVE_QUOTAIO_H
1487
1488          # 2.6.32
1489          LC_BLK_QUEUE_MAX_SEGMENTS
1490
1491          # 2.6.34
1492          LC_HAVE_DQUOT_FS_DISK_QUOTA
1493          LC_HAVE_DQUOT_SUSPEND
1494
1495          # 2.6.35, 3.0.0
1496          LC_FILE_FSYNC
1497          LC_EXPORT_SIMPLE_SETATTR
1498          LC_EXPORT_TRUNCATE_COMPLETE_PAGE
1499
1500          # 2.6.36
1501          LC_FS_STRUCT_RWLOCK
1502          LC_SBOPS_EVICT_INODE
1503
1504          # 2.6.37
1505          LC_KERNEL_LOCKED
1506
1507          # 2.6.38
1508          LC_BLKDEV_GET_BY_DEV
1509          LC_GENERIC_PERMISSION
1510          LC_QUOTA_ON_USE_PATH
1511          LC_DCACHE_LOCK
1512          LC_INODE_I_RCU
1513          LC_D_COMPARE_7ARGS
1514          LC_D_DELETE_CONST
1515
1516          # 2.6.39
1517          LC_REQUEST_QUEUE_UNPLUG_FN
1518          LC_HAVE_FSTYPE_MOUNT
1519
1520          # 3.0
1521          LC_DIRTY_INODE_WITH_FLAG
1522
1523          # 3.1
1524          LC_LM_XXX_LOCK_MANAGER_OPS
1525          LC_INODE_DIO_WAIT
1526          LC_IOP_GET_ACL
1527          LC_FILE_LLSEEK_SIZE
1528
1529          # 3.1.1
1530          LC_BLOCKS_FOR_TRUNCATE
1531
1532          # 3.2
1533          LC_HAVE_VOID_MAKE_REQUEST_FN
1534          LC_HAVE_PROTECT_I_NLINK
1535
1536          # 3.3
1537          LC_HAVE_MIGRATE_HEADER
1538          LC_MIGRATEPAGE_4ARGS
1539          LC_SUPEROPS_USE_DENTRY
1540          LC_INODEOPS_USE_UMODE_T
1541
1542          # 3.4
1543          LC_TOUCH_ATIME_1ARG
1544          LC_HAVE_D_MAKE_ROOT
1545          LC_KMAP_ATOMIC_HAS_1ARG
1546
1547          # 3.5
1548          LC_HAVE_CLEAR_INODE
1549          LC_HAVE_ENCODE_FH_PARENT
1550          LC_FILE_LLSEEK_SIZE_5ARG
1551
1552          # 3.6
1553          LC_HAVE_DENTRY_D_ALIAS_HLIST
1554          LC_DENTRY_OPEN_USE_PATH
1555          LC_HAVE_IOP_ATOMIC_OPEN
1556
1557          # 3.7
1558          LC_HAVE_POSIXACL_USER_NS
1559
1560          # 3.9
1561          LC_HAVE_HLIST_FOR_EACH_3ARG
1562          LC_HAVE_F_PATH_MNT
1563
1564          #
1565          if test x$enable_server = xyes ; then
1566                 AC_DEFINE(HAVE_SERVER_SUPPORT, 1, [support server])
1567                 LC_FUNC_DEV_SET_RDONLY
1568                 LC_STACK_SIZE
1569                 LC_QUOTA64
1570                 LC_QUOTA_CONFIG
1571          fi
1572 ])
1573
1574 #
1575 # LC_CONFIG_CLIENT_SERVER
1576 #
1577 # Build client/server sides of Lustre
1578 #
1579 AC_DEFUN([LC_CONFIG_CLIENT_SERVER],
1580 [AC_MSG_CHECKING([whether to build Lustre server support])
1581 AC_ARG_ENABLE([server],
1582         AC_HELP_STRING([--disable-server],
1583                         [disable Lustre server support]),
1584         [],[enable_server='yes'])
1585 AC_MSG_RESULT([$enable_server])
1586
1587 AC_MSG_CHECKING([whether to build Lustre client support])
1588 AC_ARG_ENABLE([client],
1589         AC_HELP_STRING([--disable-client],
1590                         [disable Lustre client support]),
1591         [],[enable_client='yes'])
1592 AC_MSG_RESULT([$enable_client])])
1593
1594 #
1595 # LC_CONFIG_LIBLUSTRE
1596 #
1597 # whether to build liblustre
1598 #
1599 AC_DEFUN([LC_CONFIG_LIBLUSTRE],
1600 [AC_MSG_CHECKING([whether to build Lustre library])
1601 AC_ARG_ENABLE([liblustre],
1602         AC_HELP_STRING([--disable-liblustre],
1603                         [disable building of Lustre library]),
1604         [],[enable_liblustre=$with_sysio])
1605 AC_MSG_RESULT([$enable_liblustre])
1606 # only build sysio if liblustre is built
1607 with_sysio="$enable_liblustre"
1608
1609 AC_MSG_CHECKING([whether to build liblustre tests])
1610 AC_ARG_ENABLE([liblustre-tests],
1611         AC_HELP_STRING([--enable-liblustre-tests],
1612                         [enable liblustre tests, if --disable-tests is used]),
1613         [],[enable_liblustre_tests=$enable_tests])
1614 if test x$enable_liblustre != xyes ; then
1615    enable_liblustre_tests='no'
1616 fi
1617 AC_MSG_RESULT([$enable_liblustre_tests])
1618
1619 AC_MSG_CHECKING([whether to enable liblustre acl])
1620 AC_ARG_ENABLE([liblustre-acl],
1621         AC_HELP_STRING([--disable-liblustre-acl],
1622                         [disable ACL support for liblustre]),
1623         [],[enable_liblustre_acl=yes])
1624 AC_MSG_RESULT([$enable_liblustre_acl])
1625 if test x$enable_liblustre_acl = xyes ; then
1626   AC_DEFINE(LIBLUSTRE_POSIX_ACL, 1, Liblustre Support ACL-enabled MDS)
1627 fi
1628
1629 #
1630 # --enable-mpitest
1631 #
1632 AC_ARG_ENABLE(mpitests,
1633         AC_HELP_STRING([--enable-mpitests=yes|no|mpicc wrapper],
1634                            [include mpi tests]),
1635         [
1636          enable_mpitests=yes
1637          case $enableval in
1638          yes)
1639                 MPICC_WRAPPER=mpicc
1640                 ;;
1641          no)
1642                 enable_mpitests=no
1643                 ;;
1644          *)
1645                 MPICC_WRAPPER=$enableval
1646                  ;;
1647          esac
1648         ],
1649         [
1650         MPICC_WRAPPER=mpicc
1651         enable_mpitests=yes
1652         ]
1653 )
1654
1655 if test x$enable_mpitests != xno; then
1656         AC_MSG_CHECKING([whether mpitests can be built])
1657         oldcc=$CC
1658         CC=$MPICC_WRAPPER
1659         AC_LINK_IFELSE(
1660             [AC_LANG_PROGRAM([[
1661                     #include <mpi.h>
1662                 ]],[[
1663                     int flag;
1664                     MPI_Initialized(&flag);
1665                 ]])],
1666             [
1667                     AC_MSG_RESULT([yes])
1668             ],[
1669                     AC_MSG_RESULT([no])
1670                     enable_mpitests=no
1671         ])
1672         CC=$oldcc
1673 fi
1674 AC_SUBST(MPICC_WRAPPER)
1675
1676 AC_MSG_NOTICE([Enabling Lustre configure options for libsysio])
1677 ac_configure_args="$ac_configure_args --with-lustre-hack --with-sockets"
1678
1679 LC_CONFIG_PINGER
1680 LC_CONFIG_LIBLUSTRE_RECOVERY
1681 ])
1682
1683 #
1684 # LC_CONFIG_QUOTA
1685 #
1686 # whether to enable quota support global control
1687 #
1688 AC_DEFUN([LC_CONFIG_QUOTA],
1689 [AC_ARG_ENABLE([quota],
1690         AC_HELP_STRING([--enable-quota],
1691                         [enable quota support]),
1692         [],[enable_quota='yes'])
1693 ])
1694
1695 AC_DEFUN([LC_QUOTA],
1696 [#check global
1697 LC_CONFIG_QUOTA
1698 #check for utils
1699 AC_CHECK_HEADER(sys/quota.h,
1700                 [AC_DEFINE(HAVE_SYS_QUOTA_H, 1, [Define to 1 if you have <sys/quota.h>.])],
1701                 [AC_MSG_ERROR([don't find <sys/quota.h> in your system])])
1702 ])
1703
1704 #
1705 # LC_CONFIG_SPLIT
1706 #
1707 # whether to enable split support
1708 #
1709 AC_DEFUN([LC_CONFIG_SPLIT],
1710 [AC_MSG_CHECKING([whether to enable split support])
1711 AC_ARG_ENABLE([split],
1712         AC_HELP_STRING([--enable-split],
1713                         [enable split support]),
1714         [],[enable_split='no'])
1715 AC_MSG_RESULT([$enable_split])
1716 if test x$enable_split != xno; then
1717    AC_DEFINE(HAVE_SPLIT_SUPPORT, 1, [enable split support])
1718 fi
1719 ])
1720
1721 #
1722 # LC_LLITE_LLOOP_MODULE
1723 # lloop_llite.ko does not currently work with page sizes
1724 # of 64k or larger.
1725 #
1726 AC_DEFUN([LC_LLITE_LLOOP_MODULE],
1727 [AC_MSG_CHECKING([whether to enable llite_lloop module])
1728 LB_LINUX_TRY_COMPILE([
1729         #include <asm/page.h>
1730 ],[
1731         #if PAGE_SIZE >= 65536
1732         #error "PAGE_SIZE >= 65536"
1733         #endif
1734 ],[
1735         enable_llite_lloop_module='yes'
1736         AC_MSG_RESULT([yes])
1737 ],[
1738         enable_llite_lloop_module='no'
1739         AC_MSG_RESULT([no])
1740 ])
1741 ])
1742
1743 #
1744 # LC_OSD_ADDON
1745 #
1746 # configure support for optional OSD implementation
1747 #
1748 AC_DEFUN([LC_OSD_ADDON],
1749 [AC_MSG_CHECKING([for osd])
1750 AC_ARG_WITH([osd],
1751         AC_HELP_STRING([--with-osd=path],
1752                        [set path to optional osd]),
1753         [
1754                 case $with_osd in
1755                         no)     ENABLEOSDADDON=0
1756                                 ;;
1757                         *)      OSDADDON="${with_osd}"
1758                                 ENABLEOSDADDON=1
1759                                 ;;
1760                 esac
1761         ], [
1762                 ENABLEOSDADDON=0
1763         ])
1764 if test $ENABLEOSDADDON -eq 0; then
1765         AC_MSG_RESULT([no])
1766         OSDADDON=
1767 else
1768         OSDMODNAME=`basename $OSDADDON`
1769         if test -e $LUSTRE/$OSDMODNAME; then
1770                 AC_MSG_RESULT([can't link])
1771                 OSDADDON=
1772         elif ln -s $OSDADDON $LUSTRE/$OSDMODNAME; then
1773                 AC_MSG_RESULT([$OSDMODNAME])
1774                 OSDADDON="subdir-m += $OSDMODNAME"
1775         else
1776                 AC_MSG_RESULT([can't link])
1777                 OSDADDON=
1778         fi
1779 fi
1780 AC_SUBST(OSDADDON)
1781 ])
1782
1783 #
1784 # LC_CONFIGURE
1785 #
1786 # other configure checks
1787 #
1788 AC_DEFUN([LC_CONFIGURE],
1789 [LC_CONFIG_OBD_BUFFER_SIZE
1790
1791 if test $target_cpu == "i686" -o $target_cpu == "x86_64"; then
1792         CFLAGS="$CFLAGS -Werror"
1793 fi
1794
1795 # maximum MDS thread count
1796 LC_MDS_MAX_THREADS
1797
1798 # include/liblustre.h
1799 AC_CHECK_HEADERS([sys/user.h sys/vfs.h stdint.h blkid/blkid.h])
1800
1801 # liblustre/llite_lib.h
1802 AC_CHECK_HEADERS([xtio.h file.h])
1803
1804 # liblustre/dir.c
1805 AC_CHECK_HEADERS([linux/types.h sys/types.h linux/unistd.h unistd.h])
1806
1807 # liblustre/lutil.c
1808 AC_CHECK_HEADERS([netinet/in.h arpa/inet.h catamount/data.h])
1809 AC_CHECK_FUNCS([inet_ntoa])
1810
1811 # libsysio/src/readlink.c
1812 LC_READLINK_SSIZE_T
1813
1814 # lvfs/prng.c - depends on linux/types.h from liblustre/dir.c
1815 AC_CHECK_HEADERS([linux/random.h], [], [],
1816                  [#ifdef HAVE_LINUX_TYPES_H
1817                   # include <linux/types.h>
1818                   #endif
1819                  ])
1820
1821 # utils/llverfs.c
1822 AC_CHECK_HEADERS([ext2fs/ext2fs.h])
1823
1824 # check for -lz support
1825 ZLIB=""
1826 AC_CHECK_LIB([z],
1827              [adler32],
1828              [AC_CHECK_HEADERS([zlib.h],
1829                                [ZLIB="-lz"
1830                                 AC_DEFINE([HAVE_ADLER], 1,
1831                                           [support alder32 checksum type])],
1832                                [AC_MSG_WARN([No zlib-devel package found,
1833                                              unable to use adler32 checksum])])],
1834              [AC_MSG_WARN([No zlib package found, unable to use adler32 checksum])]
1835 )
1836 AC_SUBST(ZLIB)
1837
1838 SELINUX=""
1839 AC_CHECK_LIB([selinux],
1840                 [is_selinux_enabled],
1841                 [AC_CHECK_HEADERS([selinux.h],
1842                                 [SELINUX="-lselinux"
1843                                 AC_DEFINE([HAVE_SELINUX], 1,
1844                                                 [support for selinux ])],
1845                                 [AC_MSG_WARN([No selinux-devel package found,
1846                                                 unable to build selinux enabled
1847                                                 tools])])],
1848                 [AC_MSG_WARN([No selinux package found, unable to build selinux
1849                                 enabled tools])]
1850 )
1851 AC_SUBST(SELINUX)
1852
1853 # Super safe df
1854 AC_ARG_ENABLE([mindf],
1855       AC_HELP_STRING([--enable-mindf],
1856                       [Make statfs report the minimum available space on any single OST instead of the sum of free space on all OSTs]),
1857       [],[])
1858 if test "$enable_mindf" = "yes" ;  then
1859       AC_DEFINE([MIN_DF], 1, [Report minimum OST free space])
1860 fi
1861
1862 AC_ARG_ENABLE([fail_alloc],
1863         AC_HELP_STRING([--disable-fail-alloc],
1864                 [disable randomly alloc failure]),
1865         [],[enable_fail_alloc=yes])
1866 AC_MSG_CHECKING([whether to randomly failing memory alloc])
1867 AC_MSG_RESULT([$enable_fail_alloc])
1868 if test x$enable_fail_alloc != xno ; then
1869         AC_DEFINE([RANDOM_FAIL_ALLOC], 1, [enable randomly alloc failure])
1870 fi
1871
1872 AC_ARG_ENABLE([invariants],
1873         AC_HELP_STRING([--enable-invariants],
1874                 [enable invariant checking (cpu intensive)]),
1875         [],[])
1876 AC_MSG_CHECKING([whether to check invariants (expensive cpu-wise)])
1877 AC_MSG_RESULT([$enable_invariants])
1878 if test x$enable_invariants = xyes ; then
1879         AC_DEFINE([CONFIG_LUSTRE_DEBUG_EXPENSIVE_CHECK], 1, [enable invariant checking])
1880 fi
1881
1882 AC_ARG_ENABLE([lu_ref],
1883         AC_HELP_STRING([--enable-lu_ref],
1884                 [enable lu_ref reference tracking code]),
1885         [],[])
1886 AC_MSG_CHECKING([whether to track references with lu_ref])
1887 AC_MSG_RESULT([$enable_lu_ref])
1888 if test x$enable_lu_ref = xyes ; then
1889         AC_DEFINE([USE_LU_REF], 1, [enable lu_ref reference tracking code])
1890 fi
1891
1892 AC_ARG_ENABLE([pgstate-track],
1893               AC_HELP_STRING([--enable-pgstate-track],
1894                              [enable page state tracking]),
1895               [enable_pgstat_track='yes'],[])
1896 AC_MSG_CHECKING([whether to enable page state tracking])
1897 AC_MSG_RESULT([$enable_pgstat_track])
1898 if test x$enable_pgstat_track = xyes ; then
1899         AC_DEFINE([CONFIG_DEBUG_PAGESTATE_TRACKING], 1,
1900                   [enable page state tracking code])
1901 fi
1902 ])
1903
1904 #
1905 # LC_CONDITIONALS
1906 #
1907 # AM_CONDITIONALS for lustre
1908 #
1909 AC_DEFUN([LC_CONDITIONALS],
1910 [AM_CONDITIONAL(LIBLUSTRE, test x$enable_liblustre = xyes)
1911 AM_CONDITIONAL(USE_QUILT, test x$QUILT != xno)
1912 AM_CONDITIONAL(LIBLUSTRE_TESTS, test x$enable_liblustre_tests = xyes)
1913 AM_CONDITIONAL(MPITESTS, test x$enable_mpitests = xyes, Build MPI Tests)
1914 AM_CONDITIONAL(CLIENT, test x$enable_client = xyes)
1915 AM_CONDITIONAL(SERVER, test x$enable_server = xyes)
1916 AM_CONDITIONAL(SPLIT, test x$enable_split = xyes)
1917 AM_CONDITIONAL(BLKID, test x$ac_cv_header_blkid_blkid_h = xyes)
1918 AM_CONDITIONAL(EXT2FS_DEVEL, test x$ac_cv_header_ext2fs_ext2fs_h = xyes)
1919 AM_CONDITIONAL(GSS, test x$enable_gss = xyes)
1920 AM_CONDITIONAL(GSS_KEYRING, test x$enable_gss_keyring = xyes)
1921 AM_CONDITIONAL(GSS_PIPEFS, test x$enable_gss_pipefs = xyes)
1922 AM_CONDITIONAL(LIBPTHREAD, test x$enable_libpthread = xyes)
1923 AM_CONDITIONAL(LLITE_LLOOP, test x$enable_llite_lloop_module = xyes)
1924 ])
1925
1926 #
1927 # LC_CONFIG_FILES
1928 #
1929 # files that should be generated with AC_OUTPUT
1930 #
1931 AC_DEFUN([LC_CONFIG_FILES],
1932 [AC_CONFIG_FILES([
1933 lustre/Makefile
1934 lustre/autoMakefile
1935 lustre/autoconf/Makefile
1936 lustre/conf/Makefile
1937 lustre/contrib/Makefile
1938 lustre/doc/Makefile
1939 lustre/include/Makefile
1940 lustre/include/lustre_ver.h
1941 lustre/include/linux/Makefile
1942 lustre/include/darwin/Makefile
1943 lustre/include/lustre/Makefile
1944 lustre/kernel_patches/targets/2.6-rhel6.target
1945 lustre/kernel_patches/targets/2.6-rhel5.target
1946 lustre/kernel_patches/targets/2.6-sles11.target
1947 lustre/kernel_patches/targets/3.0-sles11.target
1948 lustre/kernel_patches/targets/2.6-fc11.target
1949 lustre/kernel_patches/targets/2.6-fc12.target
1950 lustre/kernel_patches/targets/2.6-fc15.target
1951 lustre/kernel_patches/targets/3.x-fc18.target
1952 lustre/ldlm/Makefile
1953 lustre/fid/Makefile
1954 lustre/fid/autoMakefile
1955 lustre/liblustre/Makefile
1956 lustre/liblustre/tests/Makefile
1957 lustre/liblustre/tests/mpi/Makefile
1958 lustre/llite/Makefile
1959 lustre/llite/autoMakefile
1960 lustre/lclient/Makefile
1961 lustre/lov/Makefile
1962 lustre/lov/autoMakefile
1963 lustre/lvfs/Makefile
1964 lustre/lvfs/autoMakefile
1965 lustre/mdc/Makefile
1966 lustre/mdc/autoMakefile
1967 lustre/lmv/Makefile
1968 lustre/lmv/autoMakefile
1969 lustre/lfsck/Makefile
1970 lustre/lfsck/autoMakefile
1971 lustre/mdt/Makefile
1972 lustre/mdt/autoMakefile
1973 lustre/mdd/Makefile
1974 lustre/mdd/autoMakefile
1975 lustre/fld/Makefile
1976 lustre/fld/autoMakefile
1977 lustre/obdclass/Makefile
1978 lustre/obdclass/autoMakefile
1979 lustre/obdclass/linux/Makefile
1980 lustre/obdecho/Makefile
1981 lustre/obdecho/autoMakefile
1982 lustre/ofd/Makefile
1983 lustre/ofd/autoMakefile
1984 lustre/osc/Makefile
1985 lustre/osc/autoMakefile
1986 lustre/ost/Makefile
1987 lustre/ost/autoMakefile
1988 lustre/osd-ldiskfs/Makefile
1989 lustre/osd-ldiskfs/autoMakefile
1990 lustre/osd-zfs/Makefile
1991 lustre/osd-zfs/autoMakefile
1992 lustre/mgc/Makefile
1993 lustre/mgc/autoMakefile
1994 lustre/mgs/Makefile
1995 lustre/mgs/autoMakefile
1996 lustre/target/Makefile
1997 lustre/ptlrpc/Makefile
1998 lustre/ptlrpc/autoMakefile
1999 lustre/ptlrpc/gss/Makefile
2000 lustre/ptlrpc/gss/autoMakefile
2001 lustre/quota/Makefile
2002 lustre/quota/autoMakefile
2003 lustre/scripts/Makefile
2004 lustre/tests/Makefile
2005 lustre/tests/mpi/Makefile
2006 lustre/utils/Makefile
2007 lustre/utils/gss/Makefile
2008 lustre/osp/Makefile
2009 lustre/osp/autoMakefile
2010 lustre/lod/Makefile
2011 lustre/lod/autoMakefile
2012 lustre/obdclass/darwin/Makefile
2013 ])
2014 ])