lustre/autoconf/lustre-core.m4

   1 #
   2 # LC_CONFIG_SRCDIR
   3 #
   4 # Wrapper for AC_CONFIG_SUBDIR
   5 #
   6 AC_DEFUN([LC_CONFIG_SRCDIR],
   7 [AC_CONFIG_SRCDIR([lustre/obdclass/obdo.c])
   8 libcfs_is_module=yes
   9 ldiskfs_is_ext4=yes
  10 ])
  11
  12 #
  13 # LC_PATH_DEFAULTS
  14 #
  15 # lustre specific paths
  16 #
  17 AC_DEFUN([LC_PATH_DEFAULTS],
  18 [# ptlrpc kernel build requires this
  19 LUSTRE="$PWD/lustre"
  20 AC_SUBST(LUSTRE)
  21
  22 # mount.lustre
  23 rootsbindir='/sbin'
  24 AC_SUBST(rootsbindir)
  25
  26 demodir='$(docdir)/demo'
  27 AC_SUBST(demodir)
  28
  29 pkgexampledir='${pkgdatadir}/examples'
  30 AC_SUBST(pkgexampledir)
  31 ])
  32
  33 #
  34 # LC_TARGET_SUPPORTED
  35 #
  36 # is the target os supported?
  37 #
  38 AC_DEFUN([LC_TARGET_SUPPORTED],
  39 [case $target_os in
  40         linux* | darwin*)
  41 $1
  42                 ;;
  43         *)
  44 $2
  45                 ;;
  46 esac
  47 ])
  48
  49 #
  50 # LC_CONFIG_OBD_BUFFER_SIZE
  51 #
  52 # the maximum buffer size of lctl ioctls
  53 #
  54 AC_DEFUN([LC_CONFIG_OBD_BUFFER_SIZE],
  55 [AC_MSG_CHECKING([maximum OBD ioctl size])
  56 AC_ARG_WITH([obd-buffer-size],
  57         AC_HELP_STRING([--with-obd-buffer-size=[size]],
  58                         [set lctl ioctl maximum bytes (default=8192)]),
  59         [
  60                 OBD_BUFFER_SIZE=$with_obd_buffer_size
  61         ],[
  62                 OBD_BUFFER_SIZE=8192
  63         ])
  64 AC_MSG_RESULT([$OBD_BUFFER_SIZE bytes])
  65 AC_DEFINE_UNQUOTED(OBD_MAX_IOCTL_BUFFER, $OBD_BUFFER_SIZE, [IOCTL Buffer Size])
  66 ])
  67
  68 #
  69 # LC_READLINK_SSIZE_T
  70 #
  71 AC_DEFUN([LC_READLINK_SSIZE_T],
  72 [AC_MSG_CHECKING([if readlink returns ssize_t])
  73 AC_TRY_COMPILE([
  74         #include <unistd.h>
  75 ],[
  76         ssize_t readlink(const char *, char *, size_t);
  77 ],[
  78         AC_MSG_RESULT([yes])
  79         AC_DEFINE(HAVE_POSIX_1003_READLINK, 1, [readlink returns ssize_t])
  80 ],[
  81         AC_MSG_RESULT([no])
  82 ])
  83 ])
  84
  85 #
  86 # LC_FUNC_DEV_SET_RDONLY
  87 #
  88 # check whether dev_set_rdonly is exported.  This is needed until we
  89 # have another mechanism to fence IO from the underlying device.
  90 #
  91 AC_DEFUN([LC_FUNC_DEV_SET_RDONLY],
  92 [LB_CHECK_SYMBOL_EXPORT([dev_set_rdonly],
  93 [block/ll_rw_block.c,block/blk-core.c],[
  94         AC_DEFINE(HAVE_DEV_SET_RDONLY, 1, [kernel exports dev_set_rdonly])
  95 ],[
  96         AC_MSG_WARN([kernel missing dev_set_rdonly patch for testing])
  97 ])
  98 ])
  99
 100 #
 101 # Ensure stack size big than 8k in Lustre server (all kernels)
 102 #
 103 AC_DEFUN([LC_STACK_SIZE],
 104 [AC_MSG_CHECKING([stack size big than 8k])
 105 LB_LINUX_TRY_COMPILE([
 106         #include <linux/thread_info.h>
 107 ],[
 108         #if THREAD_SIZE < 8192
 109         #error "stack size < 8192"
 110         #endif
 111 ],[
 112         AC_MSG_RESULT(yes)
 113 ],[
 114         AC_MSG_ERROR([Lustre requires that Linux is configured with at least a 8KB stack.])
 115 ])
 116 ])
 117
 118 #
 119 # Allow the user to set the MDS thread upper limit
 120 #
 121 AC_DEFUN([LC_MDS_MAX_THREADS],
 122 [
 123         AC_ARG_WITH([mds_max_threads],
 124         AC_HELP_STRING([--with-mds-max-threads=size],
 125                         [define the maximum number of threads available on the MDS: (default=512)]),
 126         [
 127                 MDS_THREAD_COUNT=$with_mds_max_threads
 128                 AC_DEFINE_UNQUOTED(MDT_MAX_THREADS, $MDS_THREAD_COUNT, [maximum number of mdt threads])
 129         ])
 130 ])
 131
 132 #
 133 # LC_CONFIG_PINGER
 134 #
 135 # the pinger is temporary, until we have the recovery node in place
 136 #
 137 AC_DEFUN([LC_CONFIG_PINGER],
 138 [AC_MSG_CHECKING([whether to enable pinger support])
 139 AC_ARG_ENABLE([pinger],
 140         AC_HELP_STRING([--disable-pinger],
 141                         [disable recovery pinger support]),
 142         [],[enable_pinger='yes'])
 143 AC_MSG_RESULT([$enable_pinger])
 144 if test x$enable_pinger != xno ; then
 145   AC_DEFINE(ENABLE_PINGER, 1, Use the Pinger)
 146 fi
 147 ])
 148
 149 #
 150 # LC_CONFIG_CHECKSUM
 151 #
 152 # do checksum of bulk data between client and OST
 153 #
 154 AC_DEFUN([LC_CONFIG_CHECKSUM],
 155 [AC_MSG_CHECKING([whether to enable data checksum support])
 156 AC_ARG_ENABLE([checksum],
 157        AC_HELP_STRING([--disable-checksum],
 158                        [disable data checksum support]),
 159        [],[enable_checksum='yes'])
 160 AC_MSG_RESULT([$enable_checksum])
 161 if test x$enable_checksum != xno ; then
 162   AC_DEFINE(ENABLE_CHECKSUM, 1, do data checksums)
 163 fi
 164 ])
 165
 166 #
 167 # LC_CONFIG_LIBLUSTRE_RECOVERY
 168 #
 169 AC_DEFUN([LC_CONFIG_LIBLUSTRE_RECOVERY],
 170 [AC_MSG_CHECKING([whether to enable liblustre recovery support])
 171 AC_ARG_ENABLE([liblustre-recovery],
 172         AC_HELP_STRING([--disable-liblustre-recovery],
 173                         [disable liblustre recovery support]),
 174         [],[enable_liblustre_recovery='yes'])
 175 AC_MSG_RESULT([$enable_liblustre_recovery])
 176 if test x$enable_liblustre_recovery != xno ; then
 177   AC_DEFINE(ENABLE_LIBLUSTRE_RECOVERY, 1, Liblustre Can Recover)
 178 fi
 179 ])
 180
 181 #
 182 # LC_CONFIG_HEALTH_CHECK_WRITE
 183 #
 184 # Turn off the actual write to the disk
 185 #
 186 AC_DEFUN([LC_CONFIG_HEALTH_CHECK_WRITE],
 187 [AC_MSG_CHECKING([whether to enable a write with the health check])
 188 AC_ARG_ENABLE([health_write],
 189         AC_HELP_STRING([--enable-health_write],
 190                         [enable disk writes when doing health check]),
 191         [],[enable_health_write='no'])
 192 AC_MSG_RESULT([$enable_health_write])
 193 if test x$enable_health_write != xno ; then
 194   AC_DEFINE(USE_HEALTH_CHECK_WRITE, 1, Write when Checking Health)
 195 fi
 196 ])
 197
 198 AC_DEFUN([LC_CONFIG_LRU_RESIZE],
 199 [AC_MSG_CHECKING([whether to enable lru self-adjusting])
 200 AC_ARG_ENABLE([lru_resize],
 201         AC_HELP_STRING([--enable-lru-resize],
 202                         [enable lru resize support]),
 203         [],[enable_lru_resize='yes'])
 204 AC_MSG_RESULT([$enable_lru_resize])
 205 if test x$enable_lru_resize != xno; then
 206    AC_DEFINE(HAVE_LRU_RESIZE_SUPPORT, 1, [Enable lru resize support])
 207 fi
 208 ])
 209
 210 #
 211 # Quota support. The kernel must support CONFIG_QUOTA.
 212 #
 213 AC_DEFUN([LC_QUOTA_CONFIG],
 214 [LB_LINUX_CONFIG_IM([QUOTA],[],[
 215         AC_MSG_ERROR([Lustre quota requires that CONFIG_QUOTA is enabled in your kernel.])
 216         ])
 217 ])
 218
 219 # truncate_complete_page() was exported from RHEL5/SLES10, but not in SLES11 SP0 (2.6.27)
 220 # remove_from_page_cache() was exported between 2.6.35 and 2.6.38
 221 # delete_from_page_cache() is exported from 2.6.39
 222 AC_DEFUN([LC_EXPORT_TRUNCATE_COMPLETE],
 223          [LB_CHECK_SYMBOL_EXPORT([truncate_complete_page],
 224                                  [mm/truncate.c],
 225                                  [AC_DEFINE(HAVE_TRUNCATE_COMPLETE_PAGE, 1,
 226                                             [kernel export truncate_complete_page])])
 227           LB_CHECK_SYMBOL_EXPORT([remove_from_page_cache],
 228                                  [mm/filemap.c],
 229                                  [AC_DEFINE(HAVE_REMOVE_FROM_PAGE_CACHE, 1,
 230                                             [kernel export remove_from_page_cache])])
 231           LB_CHECK_SYMBOL_EXPORT([delete_from_page_cache],
 232                                  [mm/filemap.c],
 233                                  [AC_DEFINE(HAVE_DELETE_FROM_PAGE_CACHE, 1,
 234                                             [kernel export delete_from_page_cache])])
 235          ])
 236
 237 AC_DEFUN([LC_EXPORT_D_REHASH_COND],
 238 [LB_CHECK_SYMBOL_EXPORT([d_rehash_cond],
 239 [fs/dcache.c],[
 240 AC_DEFINE(HAVE_D_REHASH_COND, 1,
 241             [d_rehash_cond is exported by the kernel])
 242 ],[
 243 ])
 244 ])
 245
 246 AC_DEFUN([LC_EXPORT___D_REHASH],
 247 [LB_CHECK_SYMBOL_EXPORT([__d_rehash],
 248 [fs/dcache.c],[
 249 AC_DEFINE(HAVE___D_REHASH, 1,
 250             [__d_rehash is exported by the kernel])
 251 ],[
 252 ])
 253 ])
 254
 255 # The actual symbol exported varies among architectures, so we need
 256 # to check many symbols (but only in the current architecture.)  No
 257 # matter what symbol is exported, the kernel #defines node_to_cpumask
 258 # to the appropriate function and that's what we use.
 259 AC_DEFUN([LC_EXPORT_NODE_TO_CPUMASK],
 260          [LB_CHECK_SYMBOL_EXPORT([node_to_cpumask],
 261                                  [arch/$LINUX_ARCH/mm/numa.c],
 262                                  [AC_DEFINE(HAVE_NODE_TO_CPUMASK, 1,
 263                                             [node_to_cpumask is exported by
 264                                              the kernel])]) # x86_64
 265           LB_CHECK_SYMBOL_EXPORT([node_to_cpu_mask],
 266                                  [arch/$LINUX_ARCH/kernel/smpboot.c],
 267                                  [AC_DEFINE(HAVE_NODE_TO_CPUMASK, 1,
 268                                             [node_to_cpumask is exported by
 269                                              the kernel])]) # ia64
 270           LB_CHECK_SYMBOL_EXPORT([node_2_cpu_mask],
 271                                  [arch/$LINUX_ARCH/kernel/smpboot.c],
 272                                  [AC_DEFINE(HAVE_NODE_TO_CPUMASK, 1,
 273                                             [node_to_cpumask is exported by
 274                                              the kernel])]) # i386
 275           ])
 276
 277 #
 278 #
 279 # between 2.6.5 - 2.6.22 filemap_populate is exported in some kernels
 280 #
 281 AC_DEFUN([LC_FILEMAP_POPULATE],
 282 [AC_MSG_CHECKING([for exported filemap_populate])
 283 LB_LINUX_TRY_COMPILE([
 284         #include <asm/page.h>
 285         #include <linux/mm.h>
 286 ],[
 287        filemap_populate(NULL, 0, 0, __pgprot(0), 0, 0);
 288 ],[
 289         AC_MSG_RESULT([yes])
 290         AC_DEFINE(HAVE_FILEMAP_POPULATE, 1, [Kernel exports filemap_populate])
 291 ],[
 292         AC_MSG_RESULT([no])
 293 ])
 294 ])
 295
 296 #
 297 # added in 2.6.17
 298 #
 299 AC_DEFUN([LC_BIT_SPINLOCK_H],
 300 [LB_CHECK_FILE([$LINUX/include/linux/bit_spinlock.h],[
 301         AC_MSG_CHECKING([if bit_spinlock.h can be compiled])
 302         LB_LINUX_TRY_COMPILE([
 303                 #include <asm/processor.h>
 304                 #include <linux/spinlock.h>
 305                 #include <linux/bit_spinlock.h>
 306         ],[],[
 307                 AC_MSG_RESULT([yes])
 308                 AC_DEFINE(HAVE_BIT_SPINLOCK_H, 1, [Kernel has bit_spinlock.h])
 309         ],[
 310                 AC_MSG_RESULT([no])
 311         ])
 312 ],
 313 [])
 314 ])
 315
 316 #
 317 # LC_CONST_ACL_SIZE
 318 #
 319 AC_DEFUN([LC_CONST_ACL_SIZE],
 320 [AC_MSG_CHECKING([calc acl size])
 321 tmp_flags="$CFLAGS"
 322 CFLAGS="$CFLAGS -I$LINUX/include -I$LINUX_OBJ/include -I$LINUX_OBJ/include2 -I$LINUX/arch/`echo $target_cpu|sed -e 's/powerpc64/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include -include $AUTOCONF_HDIR/autoconf.h $EXTRA_KCFLAGS"
 323 AC_TRY_RUN([
 324         #define __KERNEL__
 325         #include <linux/types.h>
 326         #undef __KERNEL__
 327         // block include
 328         #define __LINUX_POSIX_ACL_H
 329
 330         #ifdef CONFIG_FS_POSIX_ACL
 331         # include <linux/posix_acl_xattr.h>
 332         #endif
 333
 334         #include <stdio.h>
 335
 336         int main(void)
 337         {
 338                 /* LUSTRE_POSIX_ACL_MAX_ENTRIES  = 32 */
 339             int size = posix_acl_xattr_size(32);
 340             FILE *f = fopen("acl.size","w+");
 341             fprintf(f,"%d", size);
 342             fclose(f);
 343
 344             return 0;
 345         }
 346 ],[
 347         acl_size=`cat acl.size`
 348         AC_MSG_RESULT([ACL size $acl_size])
 349         AC_DEFINE_UNQUOTED(XATTR_ACL_SIZE, AS_TR_SH([$acl_size]), [size of xattr acl])
 350 ],[
 351         AC_ERROR([ACL size can't be computed])
 352 ],[
 353         AC_MSG_RESULT([can't check ACL size, make it 260])
 354         AC_DEFINE_UNQUOTED(XATTR_ACL_SIZE,260)
 355 ])
 356 CFLAGS="$tmp_flags"
 357 ])
 358
 359 #
 360 # LC_CAPA_CRYPTO
 361 #
 362 AC_DEFUN([LC_CAPA_CRYPTO],
 363 [LB_LINUX_CONFIG_IM([CRYPTO],[],[
 364         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO is enabled in your kernel.])
 365 ])
 366 LB_LINUX_CONFIG_IM([CRYPTO_HMAC],[],[
 367         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO_HMAC is enabled in your kernel.])
 368 ])
 369 LB_LINUX_CONFIG_IM([CRYPTO_SHA1],[],[
 370         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO_SHA1 is enabled in your kernel.])
 371 ])
 372 ])
 373
 374 #
 375 # LC_CONFIG_RMTCLIENT
 376 #
 377 dnl FIXME
 378 dnl the AES symbol usually tied with arch, e.g. CRYPTO_AES_586
 379 dnl FIXME
 380 AC_DEFUN([LC_CONFIG_RMTCLIENT],
 381 [LB_LINUX_CONFIG_IM([CRYPTO_AES],[],[
 382         AC_MSG_WARN([Lustre remote client require that CONFIG_CRYPTO_AES is enabled in your kernel.])
 383 ])
 384 ])
 385
 386 #
 387 # LC_CONFIG_GSS_KEYRING (default enabled, if gss is enabled)
 388 #
 389 AC_DEFUN([LC_CONFIG_GSS_KEYRING],
 390 [AC_MSG_CHECKING([whether to enable gss keyring backend])
 391  AC_ARG_ENABLE([gss_keyring],
 392                [AC_HELP_STRING([--disable-gss-keyring],
 393                                [disable gss keyring backend])],
 394                [],[enable_gss_keyring='yes'])
 395  AC_MSG_RESULT([$enable_gss_keyring])
 396
 397  if test x$enable_gss_keyring != xno; then
 398         LB_LINUX_CONFIG_IM([KEYS],[],
 399                            [AC_MSG_ERROR([GSS keyring backend require that CONFIG_KEYS be enabled in your kernel.])])
 400
 401         AC_CHECK_LIB([keyutils], [keyctl_search], [],
 402                      [AC_MSG_ERROR([libkeyutils is not found, which is required by gss keyring backend])],)
 403
 404         AC_DEFINE([HAVE_GSS_KEYRING], [1],
 405                   [Define this if you enable gss keyring backend])
 406  fi
 407 ])
 408
 409 AC_DEFUN([LC_CONFIG_SUNRPC],
 410 [LB_LINUX_CONFIG_IM([SUNRPC],[],
 411                     [AC_MSG_ERROR([kernel SUNRPC support is required by using GSS.])])
 412 ])
 413
 414 #
 415 # LC_CONFIG_GSS (default disabled)
 416 #
 417 # Build gss and related tools of Lustre. Currently both kernel and user space
 418 # parts are depend on linux platform.
 419 #
 420 AC_DEFUN([LC_CONFIG_GSS],
 421 [AC_MSG_CHECKING([whether to enable gss/krb5 support])
 422  AC_ARG_ENABLE([gss],
 423                [AC_HELP_STRING([--enable-gss], [enable gss/krb5 support])],
 424                [],[enable_gss='no'])
 425  AC_MSG_RESULT([$enable_gss])
 426
 427  if test x$enable_gss == xyes; then
 428         LC_CONFIG_GSS_KEYRING
 429         LC_CONFIG_SUNRPC
 430
 431         AC_DEFINE([HAVE_GSS], [1], [Define this if you enable gss])
 432
 433         LB_LINUX_CONFIG_IM([CRYPTO_MD5],[],
 434                            [AC_MSG_WARN([kernel MD5 support is recommended by using GSS.])])
 435         LB_LINUX_CONFIG_IM([CRYPTO_SHA1],[],
 436                            [AC_MSG_WARN([kernel SHA1 support is recommended by using GSS.])])
 437         LB_LINUX_CONFIG_IM([CRYPTO_SHA256],[],
 438                            [AC_MSG_WARN([kernel SHA256 support is recommended by using GSS.])])
 439         LB_LINUX_CONFIG_IM([CRYPTO_SHA512],[],
 440                            [AC_MSG_WARN([kernel SHA512 support is recommended by using GSS.])])
 441
 442         AC_CHECK_LIB([gssapi], [gss_init_sec_context],
 443                      [GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssapi"],
 444                      [AC_CHECK_LIB([gssglue], [gss_init_sec_context],
 445                                    [GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssglue"],
 446                                    [AC_MSG_ERROR([libgssapi or libgssglue is not found, which is required by GSS.])])],)
 447
 448         AC_SUBST(GSSAPI_LIBS)
 449
 450         AC_KERBEROS_V5
 451  fi
 452 ])
 453
 454 AC_DEFUN([LC_TASK_CLENV_STORE],
 455 [
 456         AC_MSG_CHECKING([if we can store cl_env in task_struct])
 457         if test x$have_task_clenv_store != xyes ; then
 458                 LC_TASK_CLENV_TUX_INFO
 459         fi
 460 ])
 461
 462 # 2.6.12
 463
 464 # ~2.6.12 merge patch from oracle to convert tree_lock from spinlock to rwlock
 465 # yet tree_lock is converted from rwlock to spin_lock since v2.6.26
 466 AC_DEFUN([LC_RW_TREE_LOCK],
 467 [AC_MSG_CHECKING([if kernel has tree_lock as rwlock])
 468 tmp_flags="$EXTRA_KCFLAGS"
 469 EXTRA_KCFLAGS="-Werror"
 470 LB_LINUX_TRY_COMPILE([
 471         #include <linux/fs.h>
 472 ],[
 473         struct address_space a;
 474
 475         write_lock(&a.tree_lock);
 476 ],[
 477         AC_MSG_RESULT([yes])
 478         AC_DEFINE(HAVE_RW_TREE_LOCK, 1, [kernel has tree_lock as rw_lock])
 479 ],[
 480         AC_MSG_RESULT([no])
 481 ])
 482 EXTRA_KCFLAGS="$tmp_flags"
 483 ])
 484
 485 # 2.6.18
 486
 487 # LC_UMOUNTBEGIN_HAS_VFSMOUNT
 488 # 2.6.18~2.6.25 umount_begin has different parameters
 489 AC_DEFUN([LC_UMOUNTBEGIN_HAS_VFSMOUNT],
 490 [AC_MSG_CHECKING([if umount_begin needs vfsmount parameter instead of super_block])
 491 tmp_flags="$EXTRA_KCFLAGS"
 492 EXTRA_KCFLAGS="-Werror"
 493 LB_LINUX_TRY_COMPILE([
 494         #include <linux/fs.h>
 495
 496         struct vfsmount;
 497         static void cfg_umount_begin (struct vfsmount *v, int flags)
 498         {
 499                 ;
 500         }
 501
 502         static struct super_operations cfg_super_operations = {
 503                 .umount_begin   = cfg_umount_begin,
 504         };
 505 ],[
 506         cfg_super_operations.umount_begin(NULL,0);
 507 ],[
 508         AC_MSG_RESULT(yes)
 509         AC_DEFINE(HAVE_UMOUNTBEGIN_VFSMOUNT, 1,
 510                 [Define umount_begin need second argument])
 511 ],[
 512         AC_MSG_RESULT(no)
 513 ])
 514 EXTRA_KCFLAGS="$tmp_flags"
 515 ])
 516
 517 #2.6.18 + RHEL5 (fc6)
 518
 519 #
 520 # LC_LINUX_FIEMAP_H
 521 #
 522 # fiemap.h is added since v2.6.28
 523 # RHEL5 2.6.18 has it, while SLES10 2.6.27 does not
 524 #
 525 AC_DEFUN([LC_LINUX_FIEMAP_H],
 526 [LB_CHECK_FILE([$LINUX/include/linux/fiemap.h],[
 527         AC_MSG_CHECKING([if fiemap.h can be compiled])
 528         LB_LINUX_TRY_COMPILE([
 529                 #include <linux/types.h>
 530                 #include <linux/fiemap.h>
 531         ],[],[
 532                 AC_MSG_RESULT([yes])
 533                 AC_DEFINE(HAVE_LINUX_FIEMAP_H, 1, [Kernel has fiemap.h])
 534         ],[
 535                 AC_MSG_RESULT([no])
 536         ])
 537 ],
 538 [])
 539 ])
 540
 541 # 2.6.19
 542
 543 # LC_FILE_WRITEV
 544 # 2.6.19 replaced writev with aio_write
 545 AC_DEFUN([LC_FILE_WRITEV],
 546 [AC_MSG_CHECKING([writev in fops])
 547 LB_LINUX_TRY_COMPILE([
 548         #include <linux/fs.h>
 549 ],[
 550         struct file_operations *fops = NULL;
 551         fops->writev = NULL;
 552 ],[
 553         AC_MSG_RESULT(yes)
 554         AC_DEFINE(HAVE_FILE_WRITEV, 1,
 555                 [use fops->writev])
 556 ],[
 557         AC_MSG_RESULT(no)
 558 ])
 559 ])
 560
 561 # LC_FILE_READV
 562 # 2.6.19 replaced readv with aio_read
 563 AC_DEFUN([LC_FILE_READV],
 564 [AC_MSG_CHECKING([readv in fops])
 565 LB_LINUX_TRY_COMPILE([
 566         #include <linux/fs.h>
 567 ],[
 568         struct file_operations *fops = NULL;
 569         fops->readv = NULL;
 570 ],[
 571         AC_MSG_RESULT(yes)
 572         AC_DEFINE(HAVE_FILE_READV, 1,
 573                 [use fops->readv])
 574 ],[
 575         AC_MSG_RESULT(no)
 576 ])
 577 ])
 578
 579 # 2.6.20
 580
 581 # LC_CANCEL_DIRTY_PAGE
 582 # 2.6.20 introduced cancel_dirty_page instead of clear_page_dirty.
 583 AC_DEFUN([LC_CANCEL_DIRTY_PAGE],
 584         [AC_MSG_CHECKING([kernel has cancel_dirty_page])
 585         # the implementation of cancel_dirty_page in OFED 1.4.1's SLES10 SP2
 586         # backport is broken, so ignore it
 587         if test -f $OFED_BACKPORT_PATH/linux/mm.h &&
 588            test "$(sed -ne '/^static inline void cancel_dirty_page(struct page \*page, unsigned int account_size)$/,/^}$/p' $OFED_BACKPORT_PATH/linux/mm.h | md5sum)" = "c518cb32d6394760c5bca14cb7538d3e  -"; then
 589                 AC_MSG_RESULT(no)
 590         else
 591                 LB_LINUX_TRY_COMPILE([
 592                         #include <linux/mm.h>
 593                         #include <linux/page-flags.h>
 594 ],[
 595                         cancel_dirty_page(NULL, 0);
 596 ],[
 597                         AC_MSG_RESULT(yes)
 598                         AC_DEFINE(HAVE_CANCEL_DIRTY_PAGE, 1,
 599                                   [kernel has cancel_dirty_page instead of clear_page_dirty])
 600 ],[
 601                         AC_MSG_RESULT(no)
 602 ])
 603         fi
 604 ])
 605
 606 # raid5-zerocopy patch
 607
 608 #
 609 # LC_PAGE_CONSTANT
 610 #
 611 # In order to support raid5 zerocopy patch, we have to patch the kernel to make
 612 # it support constant page, which means the page won't be modified during the
 613 # IO.
 614 #
 615 AC_DEFUN([LC_PAGE_CONSTANT],
 616 [AC_MSG_CHECKING([if kernel have PageConstant defined])
 617 LB_LINUX_TRY_COMPILE([
 618         #include <linux/mm.h>
 619         #include <linux/page-flags.h>
 620 ],[
 621         #ifndef PG_constant
 622         #error "Have no raid5 zcopy patch"
 623         #endif
 624 ],[
 625         AC_MSG_RESULT(yes)
 626         AC_DEFINE(HAVE_PAGE_CONSTANT, 1, [kernel have PageConstant supported])
 627 ],[
 628         AC_MSG_RESULT(no);
 629 ])
 630 ])
 631
 632 # 2.6.22
 633
 634 # 2.6.22 lost second parameter for invalidate_bdev
 635 AC_DEFUN([LC_INVALIDATE_BDEV_2ARG],
 636 [AC_MSG_CHECKING([if invalidate_bdev has second argument])
 637 LB_LINUX_TRY_COMPILE([
 638         #include <linux/buffer_head.h>
 639 ],[
 640         invalidate_bdev(NULL,0);
 641 ],[
 642         AC_MSG_RESULT([yes])
 643         AC_DEFINE(HAVE_INVALIDATE_BDEV_2ARG, 1,
 644                 [invalidate_bdev has second argument])
 645 ],[
 646         AC_MSG_RESULT([no])
 647 ])
 648 ])
 649
 650 #
 651 # check for crypto API
 652 #
 653 AC_DEFUN([LC_ASYNC_BLOCK_CIPHER],
 654 [AC_MSG_CHECKING([if kernel has block cipher support])
 655 LB_LINUX_TRY_COMPILE([
 656         #include <linux/err.h>
 657         #include <linux/crypto.h>
 658 ],[
 659         struct crypto_blkcipher *tfm;
 660         tfm = crypto_alloc_blkcipher("aes", 0, sizeof(tfm) );
 661 ],[
 662         AC_MSG_RESULT([yes])
 663         AC_DEFINE(HAVE_ASYNC_BLOCK_CIPHER, 1, [kernel has block cipher support])
 664 ],[
 665         AC_MSG_RESULT([no])
 666 ])
 667 ])
 668
 669 #
 670 # check for struct hash_desc
 671 #
 672 AC_DEFUN([LC_STRUCT_HASH_DESC],
 673 [AC_MSG_CHECKING([if kernel has struct hash_desc])
 674 LB_LINUX_TRY_COMPILE([
 675         #include <linux/err.h>
 676         #include <linux/crypto.h>
 677 ],[
 678         struct hash_desc foo __attribute__ ((unused));
 679 ],[
 680         AC_MSG_RESULT([yes])
 681         AC_DEFINE(HAVE_STRUCT_HASH_DESC, 1, [kernel has struct hash_desc])
 682 ],[
 683         AC_MSG_RESULT([no])
 684 ])
 685 ])
 686
 687 #
 688 # check for struct blkcipher_desc
 689 #
 690 AC_DEFUN([LC_STRUCT_BLKCIPHER_DESC],
 691 [AC_MSG_CHECKING([if kernel has struct blkcipher_desc])
 692 LB_LINUX_TRY_COMPILE([
 693         #include <linux/err.h>
 694         #include <linux/crypto.h>
 695 ],[
 696         struct blkcipher_desc foo __attribute__ ((unused));
 697 ],[
 698         AC_MSG_RESULT([yes])
 699         AC_DEFINE(HAVE_STRUCT_BLKCIPHER_DESC, 1, [kernel has struct blkcipher_desc])
 700 ],[
 701         AC_MSG_RESULT([no])
 702 ])
 703 ])
 704
 705 #
 706 # 2.6.19 check for FS_RENAME_DOES_D_MOVE flag
 707 #
 708 AC_DEFUN([LC_FS_RENAME_DOES_D_MOVE],
 709 [AC_MSG_CHECKING([if kernel has FS_RENAME_DOES_D_MOVE flag])
 710 LB_LINUX_TRY_COMPILE([
 711         #include <linux/fs.h>
 712 ],[
 713         int v __attribute__ ((unused));
 714         v = FS_RENAME_DOES_D_MOVE;
 715 ],[
 716         AC_MSG_RESULT([yes])
 717         AC_DEFINE(HAVE_FS_RENAME_DOES_D_MOVE, 1, [kernel has FS_RENAME_DOES_D_MOVE flag])
 718 ],[
 719         AC_MSG_RESULT([no])
 720 ])
 721 ])
 722
 723 # 2.6.23
 724
 725 # 2.6.23 have return type 'void' for unregister_blkdev
 726 AC_DEFUN([LC_UNREGISTER_BLKDEV_RETURN_INT],
 727 [AC_MSG_CHECKING([if unregister_blkdev return int])
 728 LB_LINUX_TRY_COMPILE([
 729         #include <linux/fs.h>
 730 ],[
 731         int i __attribute__ ((unused));
 732         i = unregister_blkdev(0,NULL);
 733 ],[
 734         AC_MSG_RESULT([yes])
 735         AC_DEFINE(HAVE_UNREGISTER_BLKDEV_RETURN_INT, 1,
 736                 [unregister_blkdev return int])
 737 ],[
 738         AC_MSG_RESULT([no])
 739 ])
 740 ])
 741
 742 # 2.6.23 change .sendfile to .splice_read
 743 AC_DEFUN([LC_KERNEL_SPLICE_READ],
 744 [AC_MSG_CHECKING([if kernel has .splice_read])
 745 LB_LINUX_TRY_COMPILE([
 746         #include <linux/fs.h>
 747 ],[
 748         struct file_operations file;
 749
 750         file.splice_read = NULL;
 751 ], [
 752         AC_MSG_RESULT([yes])
 753         AC_DEFINE(HAVE_KERNEL_SPLICE_READ, 1,
 754                 [kernel has .slice_read])
 755 ],[
 756         AC_MSG_RESULT([no])
 757 ])
 758 ])
 759
 760 # 2.6.23 change .sendfile to .splice_read
 761 # RHEL4 (-92 kernel) have both sendfile and .splice_read API
 762 AC_DEFUN([LC_KERNEL_SENDFILE],
 763 [AC_MSG_CHECKING([if kernel has .sendfile])
 764 LB_LINUX_TRY_COMPILE([
 765         #include <linux/fs.h>
 766 ],[
 767         struct file_operations file;
 768
 769         file.sendfile = NULL;
 770 ], [
 771         AC_MSG_RESULT([yes])
 772         AC_DEFINE(HAVE_KERNEL_SENDFILE, 1,
 773                 [kernel has .sendfile])
 774 ],[
 775         AC_MSG_RESULT([no])
 776 ])
 777 ])
 778
 779 # 2.6.23 extract nfs export related data into exportfs.h
 780 AC_DEFUN([LC_HAVE_EXPORTFS_H],
 781 [LB_CHECK_FILE([$LINUX/include/linux/exportfs.h], [
 782         AC_DEFINE(HAVE_LINUX_EXPORTFS_H, 1,
 783                 [kernel has include/exportfs.h])
 784 ],[
 785         AC_MSG_RESULT([no])
 786 ])
 787 ])
 788
 789 # 2.6.23 has new page fault handling API
 790 AC_DEFUN([LC_VM_OP_FAULT],
 791 [AC_MSG_CHECKING([kernel has .fault in vm_operation_struct])
 792 LB_LINUX_TRY_COMPILE([
 793         #include <linux/mm.h>
 794 ],[
 795         struct vm_operations_struct op;
 796
 797         op.fault = NULL;
 798 ], [
 799         AC_MSG_RESULT([yes])
 800         AC_DEFINE(HAVE_VM_OP_FAULT, 1,
 801                 [kernel has .fault in vm_operation_struct])
 802 ],[
 803         AC_MSG_RESULT([no])
 804 ])
 805 ])
 806
 807 # 2.6.23 add code to wait other users to complete before removing procfs entry
 808 AC_DEFUN([LC_PROCFS_USERS],
 809 [AC_MSG_CHECKING([if kernel has pde_users member in procfs entry struct])
 810 LB_LINUX_TRY_COMPILE([
 811         #include <linux/proc_fs.h>
 812 ],[
 813         struct proc_dir_entry pde;
 814
 815         pde.pde_users   = 0;
 816 ],[
 817         AC_MSG_RESULT([yes])
 818         AC_DEFINE(HAVE_PROCFS_USERS, 1,
 819                 [kernel has pde_users member in procfs entry struct])
 820 ],[
 821         LB_LINUX_TRY_COMPILE([
 822                 #include "$LINUX/fs/proc/internal.h"
 823         ],[
 824                 struct proc_dir_entry_aux pde_aux;
 825
 826                 pde_aux.pde_users = 0;
 827         ],[
 828                 AC_MSG_RESULT([yes])
 829                 AC_DEFINE(HAVE_PROCFS_USERS, 1,
 830                         [kernel has pde_users member in proc_dir_entry_aux])
 831         ],[
 832                 AC_MSG_RESULT([no])
 833         ])
 834 ])
 835 ])
 836
 837 # 2.6.23 exports exportfs_decode_fh
 838 AC_DEFUN([LC_EXPORTFS_DECODE_FH],
 839 [LB_CHECK_SYMBOL_EXPORT([exportfs_decode_fh],
 840 [fs/exportfs/expfs.c],[
 841         AC_DEFINE(HAVE_EXPORTFS_DECODE_FH, 1,
 842                 [exportfs_decode_fh has been export])
 843 ],[
 844 ])
 845 ])
 846
 847 # 2.6.24
 848
 849 # 2.6.24 need linux/mm_types.h included
 850 AC_DEFUN([LC_HAVE_MMTYPES_H],
 851 [LB_CHECK_FILE([$LINUX/include/linux/mm_types.h], [
 852         AC_DEFINE(HAVE_LINUX_MMTYPES_H, 1,
 853                 [kernel has include/mm_types.h])
 854 ],[
 855         AC_MSG_RESULT([no])
 856 ])
 857 ])
 858
 859 # 2.6.24 has bio_endio with 2 args
 860 AC_DEFUN([LC_BIO_ENDIO_2ARG],
 861 [AC_MSG_CHECKING([if kernel has bio_endio with 2 args])
 862 LB_LINUX_TRY_COMPILE([
 863         #include <linux/bio.h>
 864 ],[
 865         bio_endio(NULL, 0);
 866 ], [
 867         AC_MSG_RESULT([yes])
 868         AC_DEFINE(HAVE_BIO_ENDIO_2ARG, 1,
 869                 [kernel has bio_endio with 2 args])
 870 ],[
 871         AC_MSG_RESULT([no])
 872 ])
 873 ])
 874
 875 # 2.6.24 has new members in exports struct.
 876 AC_DEFUN([LC_FH_TO_DENTRY],
 877 [AC_MSG_CHECKING([if kernel has .fh_to_dentry member in export_operations struct])
 878 LB_LINUX_TRY_COMPILE([
 879         #include <linux/fs.h>
 880 #ifdef HAVE_LINUX_EXPORTFS_H
 881         #include <linux/exportfs.h>
 882 #endif
 883 ],[
 884         do{ }while(sizeof(((struct export_operations *)0)->fh_to_dentry));
 885 ], [
 886         AC_MSG_RESULT([yes])
 887         AC_DEFINE(HAVE_FH_TO_DENTRY, 1,
 888                 [kernel has .fh_to_dentry member in export_operations struct])
 889 ],[
 890         AC_MSG_RESULT([no])
 891 ])
 892 ])
 893
 894 # 2.6.24 removes long aged procfs entry -> deleted member
 895 AC_DEFUN([LC_PROCFS_DELETED],
 896 [AC_MSG_CHECKING([if kernel has deleted member in procfs entry struct])
 897 LB_LINUX_TRY_COMPILE([
 898         #include <linux/proc_fs.h>
 899 ],[
 900         struct proc_dir_entry pde;
 901
 902         pde.deleted = sizeof(pde);
 903 ], [
 904         AC_MSG_RESULT([yes])
 905         AC_DEFINE(HAVE_PROCFS_DELETED, 1,
 906                 [kernel has deleted member in procfs entry struct])
 907 ],[
 908         AC_MSG_RESULT([no])
 909 ])
 910 ])
 911
 912 # 2.6.24 has bdi_init()/bdi_destroy() functions.
 913 AC_DEFUN([LC_EXPORT_BDI_INIT],
 914 [LB_CHECK_SYMBOL_EXPORT([bdi_init],
 915 [mm/backing-dev.c],[
 916         AC_DEFINE(HAVE_BDI_INIT, 1,
 917                 [bdi_init/bdi_destroy functions are present])
 918 ],[
 919 ])
 920 ])
 921
 922 # 2.6.26
 923
 924 # 2.6.26 isn't export set_fs_pwd and change paramter in fs struct
 925 AC_DEFUN([LC_FS_STRUCT_USE_PATH],
 926 [AC_MSG_CHECKING([fs_struct use path structure])
 927 LB_LINUX_TRY_COMPILE([
 928         #include <asm/atomic.h>
 929         #include <linux/spinlock.h>
 930         #include <linux/fs_struct.h>
 931 ],[
 932         struct fs_struct fs;
 933
 934         fs.pwd = *((struct path *)sizeof(fs));
 935 ], [
 936         AC_MSG_RESULT([yes])
 937         AC_DEFINE(HAVE_FS_STRUCT_USE_PATH, 1,
 938                 [fs_struct use path structure])
 939 ],[
 940         AC_MSG_RESULT([no])
 941 ])
 942 ])
 943
 944 #
 945 # 2.6.27
 946 #
 947
 948 # LC_SECURITY_PLUG  # for SLES10 SP2 (2.6.27)
 949 # check security plug in sles10 sp2 kernel
 950 AC_DEFUN([LC_SECURITY_PLUG],
 951 [AC_MSG_CHECKING([If kernel has security plug support])
 952 LB_LINUX_TRY_COMPILE([
 953         #include <linux/fs.h>
 954         #include <linux/stddef.h>
 955 ],[
 956         notify_change(NULL, NULL, NULL);
 957 ],[
 958         AC_MSG_RESULT(yes)
 959         AC_DEFINE(HAVE_SECURITY_PLUG, 1,
 960                 [SLES10 SP2 use extra parameter in vfs])
 961 ],[
 962         AC_MSG_RESULT(no)
 963 ])
 964 ])
 965
 966 AC_DEFUN([LC_PGMKWRITE_USE_VMFAULT],
 967 [AC_MSG_CHECKING([kernel .page_mkwrite uses struct vm_fault *])
 968 tmp_flags="$EXTRA_KCFLAGS"
 969 EXTRA_KCFLAGS="-Werror"
 970 LB_LINUX_TRY_COMPILE([
 971         #include <linux/mm.h>
 972 ],[
 973         ((struct vm_operations_struct *)0)->page_mkwrite((struct vm_area_struct *)0, (struct vm_fault *)0);
 974 ], [
 975         AC_MSG_RESULT([yes])
 976         AC_DEFINE(HAVE_PGMKWRITE_USE_VMFAULT, 1,
 977                 [kernel vm_operation_struct.page_mkwrite uses struct vm_fault * as second parameter])
 978 ],[
 979         AC_MSG_RESULT([no])
 980 ])
 981 EXTRA_KCFLAGS="$tmp_flags"
 982 ])
 983
 984 AC_DEFUN([LC_PGMKWRITE_COMPACT],
 985 [AC_MSG_CHECKING([if kernel .page_mkwrite is located in vm_operation_struct._pmkw])
 986 tmp_flags="$EXTRA_KCFLAGS"
 987 EXTRA_KCFLAGS="-Werror"
 988 LB_LINUX_TRY_COMPILE([
 989         #include <linux/mm.h>
 990 ],[
 991         struct vm_operations_struct *vm_ops;
 992
 993         vm_ops = NULL;
 994         vm_ops->_pmkw.page_mkwrite(NULL, NULL);
 995 ], [
 996         AC_MSG_RESULT([yes])
 997         AC_DEFINE(HAVE_PGMKWRITE_COMPACT, 1,
 998                 [kernel .page_mkwrite is located in vm_operation_struct._pmkw])
 999 ],[
1000         AC_MSG_RESULT([no])
1001 ])
1002 EXTRA_KCFLAGS="$tmp_flags"
1003 ])
1004
1005 AC_DEFUN([LC_INODE_PERMISION_2ARGS],
1006 [AC_MSG_CHECKING([inode_operations->permission has two args])
1007 LB_LINUX_TRY_COMPILE([
1008         #include <linux/fs.h>
1009 ],[
1010         struct inode *inode __attribute__ ((unused));
1011
1012         inode = NULL;
1013         inode->i_op->permission(NULL, 0);
1014 ],[
1015         AC_DEFINE(HAVE_INODE_PERMISION_2ARGS, 1,
1016                   [inode_operations->permission has two args])
1017         AC_MSG_RESULT([yes])
1018 ],[
1019         AC_MSG_RESULT([no])
1020 ])
1021 ])
1022
1023 # 2.6.27 have new page locking API
1024 AC_DEFUN([LC_TRYLOCKPAGE],
1025 [AC_MSG_CHECKING([kernel uses trylock_page for page lock])
1026 LB_LINUX_TRY_COMPILE([
1027         #include <linux/pagemap.h>
1028 ],[
1029         trylock_page(NULL);
1030 ],[
1031         AC_DEFINE(HAVE_TRYLOCK_PAGE, 1,
1032                   [kernel uses trylock_page for page lock])
1033         AC_MSG_RESULT([yes])
1034 ],[
1035         AC_MSG_RESULT([no])
1036 ])
1037 ])
1038
1039 # 2.6.27 removed the read_inode from super_operations.
1040 AC_DEFUN([LC_READ_INODE_IN_SBOPS],
1041 [AC_MSG_CHECKING([super_operations has a read_inode field])
1042 LB_LINUX_TRY_COMPILE([
1043         #include <linux/fs.h>
1044 ],[
1045         struct super_operations *sop;
1046         sop->read_inode(NULL);
1047 ],[
1048         AC_DEFINE(HAVE_READ_INODE_IN_SBOPS, 1,
1049                 [super_operations has a read_inode])
1050         AC_MSG_RESULT([yes])
1051 ],[
1052         AC_MSG_RESULT([no])
1053 ])
1054 ])
1055
1056 # 2.6.27 has inode_permission instead of permisson
1057 AC_DEFUN([LC_EXPORT_INODE_PERMISSION],
1058 [LB_CHECK_SYMBOL_EXPORT([inode_permission],
1059 [fs/namei.c],[
1060 AC_DEFINE(HAVE_EXPORT_INODE_PERMISSION, 1,
1061             [inode_permission is exported by the kernel])
1062 ],[
1063 ])
1064 ])
1065
1066 # 2.6.27 use 5th parameter in quota_on for remount.
1067 AC_DEFUN([LC_QUOTA_ON_5ARGS],
1068 [AC_MSG_CHECKING([quota_on needs 5 parameters])
1069 LB_LINUX_TRY_COMPILE([
1070         #include <linux/fs.h>
1071         #include <linux/quota.h>
1072 ],[
1073         struct quotactl_ops *qop = NULL;
1074         qop->quota_on(NULL, 0, 0, NULL, 0);
1075 ],[
1076         AC_DEFINE(HAVE_QUOTA_ON_5ARGS, 1,
1077                 [quota_on needs 5 paramters])
1078         AC_MSG_RESULT([yes])
1079 ],[
1080         AC_MSG_RESULT([no])
1081 ])
1082 ])
1083
1084 # 2.6.27 use 3th parameter in quota_off for remount.
1085 AC_DEFUN([LC_QUOTA_OFF_3ARGS],
1086 [AC_MSG_CHECKING([quota_off needs 3 parameters])
1087 LB_LINUX_TRY_COMPILE([
1088         #include <linux/fs.h>
1089         #include <linux/quota.h>
1090 ],[
1091         struct quotactl_ops *qop = NULL;
1092         qop->quota_off(NULL, 0, 0);
1093 ],[
1094         AC_DEFINE(HAVE_QUOTA_OFF_3ARGS, 1,
1095                 [quota_off needs 3 paramters])
1096         AC_MSG_RESULT([yes])
1097 ],[
1098         AC_MSG_RESULT([no])
1099 ])
1100 ])
1101
1102 # 2.6.27 has vfs_dq_off inline function.
1103 AC_DEFUN([LC_VFS_DQ_OFF],
1104 [AC_MSG_CHECKING([vfs_dq_off is defined])
1105 LB_LINUX_TRY_COMPILE([
1106         #include <linux/quotaops.h>
1107 ],[
1108         vfs_dq_off(NULL, 0);
1109 ],[
1110         AC_DEFINE(HAVE_VFS_DQ_OFF, 1, [vfs_dq_off is defined])
1111         AC_MSG_RESULT([yes])
1112 ],[
1113         AC_MSG_RESULT([no])
1114 ])
1115 ])
1116
1117 # LC_LOCK_MAP_ACQUIRE
1118 # after 2.6.27 lock_map_acquire replaces lock_acquire
1119 AC_DEFUN([LC_LOCK_MAP_ACQUIRE],
1120 [AC_MSG_CHECKING([if lock_map_acquire is defined])
1121 LB_LINUX_TRY_COMPILE([
1122         #include <linux/lockdep.h>
1123 ],[
1124         lock_map_acquire(NULL);
1125 ],[
1126         AC_MSG_RESULT(yes)
1127         AC_DEFINE(HAVE_LOCK_MAP_ACQUIRE, 1,
1128                 [lock_map_acquire is defined])
1129 ],[
1130         AC_MSG_RESULT(no)
1131 ])
1132 ])
1133
1134 # 2.6.27.15-2 sles11
1135
1136 # 2.6.27 sles11 remove the bi_hw_segments
1137 AC_DEFUN([LC_BI_HW_SEGMENTS],
1138 [AC_MSG_CHECKING([struct bio has a bi_hw_segments field])
1139 LB_LINUX_TRY_COMPILE([
1140         #include <linux/bio.h>
1141 ],[
1142         struct bio io;
1143         io.bi_hw_segments = sizeof(io);
1144 ],[
1145         AC_DEFINE(HAVE_BI_HW_SEGMENTS, 1,
1146                 [struct bio has a bi_hw_segments field])
1147         AC_MSG_RESULT([yes])
1148 ],[
1149         AC_MSG_RESULT([no])
1150 ])
1151 ])
1152
1153 #
1154 # 2.6.27 sles11 move the quotaio_v1{2}.h from include/linux to fs
1155 # 2.6.32 move the quotaio_v1{2}.h from fs to fs/quota
1156 AC_DEFUN([LC_HAVE_QUOTAIO_H],
1157 [LB_CHECK_FILE([$LINUX/include/linux/quotaio_v2.h],[
1158         AC_DEFINE(HAVE_QUOTAIO_H, 1,
1159                 [kernel has include/linux/quotaio_v2.h])
1160 ],[LB_CHECK_FILE([$LINUX/fs/quotaio_v2.h],[
1161                AC_DEFINE(HAVE_FS_QUOTAIO_H, 1,
1162                 [kernel has fs/quotaio_v1.h])
1163 ],[LB_CHECK_FILE([$LINUX/fs/quota/quotaio_v2.h],[
1164                AC_DEFINE(HAVE_FS_QUOTA_QUOTAIO_H, 1,
1165                 [kernel has fs/quota/quotaio_v2.h])
1166 ],[
1167         AC_MSG_RESULT([no])
1168 ])
1169 ])
1170 ])
1171 ])
1172
1173 # 2.6.27 sles11 has sb_any_quota_active
1174 AC_DEFUN([LC_SB_ANY_QUOTA_ACTIVE],
1175 [AC_MSG_CHECKING([Kernel has sb_any_quota_active])
1176 LB_LINUX_TRY_COMPILE([
1177         #include <linux/quotaops.h>
1178 ],[
1179         sb_any_quota_active(NULL);
1180 ],[
1181         AC_DEFINE(HAVE_SB_ANY_QUOTA_ACTIVE, 1,
1182                 [Kernel has a sb_any_quota_active])
1183         AC_MSG_RESULT([yes])
1184 ],[
1185         AC_MSG_RESULT([no])
1186 ])
1187 ])
1188
1189 # 2.6.27 sles11 has sb_has_quota_active
1190 AC_DEFUN([LC_SB_HAS_QUOTA_ACTIVE],
1191 [AC_MSG_CHECKING([Kernel has sb_has_quota_active])
1192 LB_LINUX_TRY_COMPILE([
1193         #include <linux/quotaops.h>
1194 ],[
1195         sb_has_quota_active(NULL, 0);
1196 ],[
1197         AC_DEFINE(HAVE_SB_HAS_QUOTA_ACTIVE, 1,
1198                 [Kernel has a sb_has_quota_active])
1199         AC_MSG_RESULT([yes])
1200 ],[
1201         AC_MSG_RESULT([no])
1202 ])
1203 ])
1204
1205 # 2.6.27 exported add_to_page_cache_lru.
1206 AC_DEFUN([LC_EXPORT_ADD_TO_PAGE_CACHE_LRU],
1207 [LB_CHECK_SYMBOL_EXPORT([add_to_page_cache_lru],
1208 [mm/filemap.c],[
1209         AC_DEFINE(HAVE_ADD_TO_PAGE_CACHE_LRU, 1,
1210                 [add_to_page_cache_lru functions are present])
1211 ],[
1212 ])
1213 ])
1214
1215 #
1216 # 2.6.29 introduce sb_any_quota_loaded.
1217 #
1218 AC_DEFUN([LC_SB_ANY_QUOTA_LOADED],
1219 [AC_MSG_CHECKING([Kernel has sb_any_quota_loaded])
1220 LB_LINUX_TRY_COMPILE([
1221         #include <linux/quotaops.h>
1222 ],[
1223         sb_any_quota_loaded(NULL);
1224 ],[
1225         AC_DEFINE(HAVE_SB_ANY_QUOTA_LOADED, 1,
1226                 [Kernel has a sb_any_quota_loaded])
1227         AC_MSG_RESULT([yes])
1228 ],[
1229         AC_MSG_RESULT([no])
1230 ])
1231 ])
1232
1233 # 2.6.30 x86 node_to_cpumask has been removed. must use cpumask_of_node
1234 AC_DEFUN([LC_EXPORT_CPUMASK_OF_NODE],
1235          [LB_CHECK_SYMBOL_EXPORT([node_to_cpumask_map],
1236                                  [arch/$LINUX_ARCH/mm/numa.c],
1237                                  [AC_DEFINE(HAVE_CPUMASK_OF_NODE, 1,
1238                                             [node_to_cpumask_map is exported by
1239                                              the kernel])]) # x86_64
1240          ])
1241
1242
1243 # 2.6.31 replaces blk_queue_hardsect_size by blk_queue_logical_block_size function
1244 AC_DEFUN([LC_BLK_QUEUE_LOG_BLK_SIZE],
1245 [AC_MSG_CHECKING([if blk_queue_logical_block_size is defined])
1246 LB_LINUX_TRY_COMPILE([
1247         #include <linux/blkdev.h>
1248 ],[
1249         blk_queue_logical_block_size(NULL, 0);
1250 ],[
1251         AC_MSG_RESULT(yes)
1252         AC_DEFINE(HAVE_BLK_QUEUE_LOG_BLK_SIZE, 1,
1253                   [blk_queue_logical_block_size is defined])
1254 ],[
1255         AC_MSG_RESULT(no)
1256 ])
1257 ])
1258
1259 # 2.6.32
1260
1261 # 2.6.32 introduced inode_newsize_ok
1262 AC_DEFUN([LC_VFS_INODE_NEWSIZE_OK],
1263 [AC_MSG_CHECKING([if inode_newsize_ok is defined])
1264 LB_LINUX_TRY_COMPILE([
1265         #include <linux/fs.h>
1266 ],[
1267         return inode_newsize_ok(NULL, 0);
1268 ],[
1269         AC_MSG_RESULT(yes)
1270         AC_DEFINE(HAVE_VFS_INODE_NEWSIZE_OK, 1,
1271                   [inode_newsize_ok is defined])
1272 ],[
1273         AC_MSG_RESULT(no)
1274 ])
1275 ])
1276
1277 # 2.6.32 changes cache_detail's member cache_request to cache_upcall
1278 # in kernel commit bc74b4f5e63a09fb78e245794a0de1e5a2716bbe
1279 AC_DEFUN([LC_CACHE_UPCALL],
1280 [AC_MSG_CHECKING([if cache_detail has cache_upcall field])
1281         LB_LINUX_TRY_COMPILE([
1282                 #include <linux/sunrpc/cache.h>
1283         ],[
1284                 struct cache_detail cd;
1285                 cd.cache_upcall = NULL;
1286         ],[
1287                 AC_MSG_RESULT(yes)
1288                 AC_DEFINE(HAVE_CACHE_UPCALL, 1,
1289                           [cache_detail has cache_upcall field])
1290         ],[
1291                 AC_MSG_RESULT(no)
1292         ])
1293 ])
1294
1295 # 2.6.32 add a limits member in struct request_queue.
1296 AC_DEFUN([LC_REQUEST_QUEUE_LIMITS],
1297 [AC_MSG_CHECKING([if request_queue has a limits field])
1298 LB_LINUX_TRY_COMPILE([
1299         #include <linux/blkdev.h>
1300 ],[
1301         struct request_queue rq;
1302         rq.limits.io_min = 0;
1303 ],[
1304         AC_MSG_RESULT(yes)
1305         AC_DEFINE(HAVE_REQUEST_QUEUE_LIMITS, 1,
1306                   [request_queue has a limits field])
1307 ],[
1308         AC_MSG_RESULT(no)
1309 ])
1310 ])
1311
1312 # 2.6.32 has bdi_register() functions.
1313 AC_DEFUN([LC_EXPORT_BDI_REGISTER],
1314 [LB_CHECK_SYMBOL_EXPORT([bdi_register],
1315 [mm/backing-dev.c],[
1316         AC_DEFINE(HAVE_BDI_REGISTER, 1,
1317                 [bdi_register function is present])
1318 ],[
1319 ])
1320 ])
1321
1322 # 2.6.32 add s_bdi for super block
1323 AC_DEFUN([LC_SB_BDI],
1324 [AC_MSG_CHECKING([if super_block has s_bdi field])
1325 LB_LINUX_TRY_COMPILE([
1326         #include <linux/fs.h>
1327 ],[
1328         struct super_block sb;
1329         sb.s_bdi = NULL;
1330 ],[
1331         AC_MSG_RESULT(yes)
1332         AC_DEFINE(HAVE_SB_BDI, 1,
1333                   [super_block has s_bdi field])
1334 ],[
1335         AC_MSG_RESULT(no)
1336 ])
1337 ])
1338
1339 #  2.6.27.15-2 SuSE 11 sp0 kernels lack the name field for BDI
1340 AC_DEFUN([LC_BDI_NAME],
1341 [AC_MSG_CHECKING([if backing_device_info has name field])
1342 LB_LINUX_TRY_COMPILE([
1343         #include <linux/blkdev.h>
1344 ],[
1345         struct backing_dev_info bdi;
1346         bdi.name = NULL;
1347 ],[
1348         AC_MSG_RESULT(yes)
1349         AC_DEFINE(HAVE_BDI_NAME, 1,
1350                   [backing_device_info has name field])
1351 ],[
1352         AC_MSG_RESULT(no)
1353 ])
1354 ])
1355
1356 # 2.6.32 removes blk_queue_max_sectors and add blk_queue_max_hw_sectors
1357 # check blk_queue_max_sectors and use it until disappear.
1358 AC_DEFUN([LC_BLK_QUEUE_MAX_SECTORS],
1359 [AC_MSG_CHECKING([if blk_queue_max_sectors is defined])
1360 LB_LINUX_TRY_COMPILE([
1361         #include <linux/blkdev.h>
1362 ],[
1363         blk_queue_max_sectors(NULL, 0);
1364 ],[
1365         AC_MSG_RESULT(yes)
1366         AC_DEFINE(HAVE_BLK_QUEUE_MAX_SECTORS, 1,
1367                   [blk_queue_max_sectors is defined])
1368 ],[
1369         AC_MSG_RESULT(no)
1370 ])
1371 ])
1372
1373 # 2.6.32 replaces 2 functions blk_queue_max_phys_segments and blk_queue_max_hw_segments by blk_queue_max_segments
1374 AC_DEFUN([LC_BLK_QUEUE_MAX_SEGMENTS],
1375 [AC_MSG_CHECKING([if blk_queue_max_segments is defined])
1376 LB_LINUX_TRY_COMPILE([
1377         #include <linux/blkdev.h>
1378 ],[
1379         blk_queue_max_segments(NULL, 0);
1380 ],[
1381         AC_MSG_RESULT(yes)
1382         AC_DEFINE(HAVE_BLK_QUEUE_MAX_SEGMENTS, 1,
1383                   [blk_queue_max_segments is defined])
1384 ],[
1385         AC_MSG_RESULT(no)
1386 ])
1387 ])
1388
1389 #
1390 # LC_QUOTA64
1391 #
1392 # Check if kernel has been patched for 64-bit quota limits support.
1393 # The upstream version of this patch in RHEL6 2.6.32 kernels introduces
1394 # the constant QFMT_VFS_V1 in include/linux/quota.h, so we can check for
1395 # that in the absence of quotaio_v1.h in the kernel headers.
1396 #
1397 AC_DEFUN([LC_QUOTA64],[
1398         AC_MSG_CHECKING([if kernel has 64-bit quota limits support])
1399 tmp_flags="$EXTRA_KCFLAGS"
1400 EXTRA_KCFLAGS="-I$LINUX/fs"
1401         LB_LINUX_TRY_COMPILE([
1402                 #include <linux/kernel.h>
1403                 #include <linux/fs.h>
1404                 #ifdef HAVE_QUOTAIO_H
1405                 # include <linux/quotaio_v2.h>
1406                 int versions[] = V2_INITQVERSIONS_R1;
1407                 struct v2_disk_dqblk_r1 dqblk_r1;
1408                 #elif defined(HAVE_FS_QUOTA_QUOTAIO_H)
1409                 # include <quota/quotaio_v2.h>
1410                 struct v2r1_disk_dqblk dqblk_r1;
1411                 #elif defined(HAVE_FS_QUOTAIO_H)
1412                 # include <quotaio_v2.h>
1413                 struct v2r1_disk_dqblk dqblk_r1;
1414                 #else
1415                 #include <linux/quota.h>
1416                 int ver = QFMT_VFS_V1;
1417                 #endif
1418         ],[],[
1419                 AC_DEFINE(HAVE_QUOTA64, 1, [have quota64])
1420                 AC_MSG_RESULT([yes])
1421         ],[
1422                 LB_CHECK_FILE([$LINUX/include/linux/lustre_version.h],[
1423                         AC_MSG_ERROR([You have got no 64-bit kernel quota support.])
1424                 ],[])
1425                 AC_MSG_RESULT([no])
1426         ])
1427 EXTRA_KCFLAGS=$tmp_flags
1428 ])
1429
1430 # 2.6.32 set_cpus_allowed is no more defined if CONFIG_CPUMASK_OFFSTACK=yes
1431 AC_DEFUN([LC_SET_CPUS_ALLOWED],
1432          [AC_MSG_CHECKING([if kernel defines set_cpus_allowed])
1433           LB_LINUX_TRY_COMPILE(
1434                 [#include <linux/sched.h>],
1435                 [struct task_struct *p = NULL;
1436                  cpumask_t mask = { { 0 } };
1437                  (void) set_cpus_allowed(p, mask);],
1438                 [AC_MSG_RESULT([yes])
1439                  AC_DEFINE(HAVE_SET_CPUS_ALLOWED, 1,
1440                            [set_cpus_allowed is exported by the kernel])],
1441                 [AC_MSG_RESULT([no])] )])
1442
1443 # 2.6.32 introduces selinux_is_enabled()
1444 AC_DEFUN([LC_SELINUX_IS_ENABLED],
1445 [AC_MSG_CHECKING([if selinux_is_enabled is available])
1446 LB_LINUX_TRY_COMPILE([
1447         #include <linux/selinux.h>
1448 ],[
1449         selinux_is_enabled();
1450 ],[
1451         AC_MSG_RESULT([yes])
1452         AC_DEFINE(HAVE_SELINUX_IS_ENABLED, 1,
1453                 [selinux_is_enabled is defined])
1454 ],[
1455         AC_MSG_RESULT([no])
1456 ])
1457 ])
1458
1459 #
1460 # LC_D_OBTAIN_ALIAS
1461 # starting from 2.6.28 kernel replaces d_alloc_anon() with
1462 # d_obtain_alias() for getting anonymous dentries
1463 # RHEL5(2.6.18) has d_obtain_alias but SLES11SP0(2.6.27) not
1464 #
1465 AC_DEFUN([LC_D_OBTAIN_ALIAS],
1466 [AC_MSG_CHECKING([d_obtain_alias exist in kernel])
1467 LB_LINUX_TRY_COMPILE([
1468         #include <linux/dcache.h>
1469 ],[
1470         d_obtain_alias(NULL);
1471 ],[
1472         AC_DEFINE(HAVE_D_OBTAIN_ALIAS, 1,
1473                 [d_obtain_alias exist in kernel])
1474         AC_MSG_RESULT([yes])
1475 ],[
1476         AC_MSG_RESULT([no])
1477 ])
1478 ])
1479
1480 #
1481 # LC_EXPORT_GENERIC_ERROR_REMOVE_PAGE
1482 #
1483 AC_DEFUN([LC_EXPORT_GENERIC_ERROR_REMOVE_PAGE],
1484          [LB_CHECK_SYMBOL_EXPORT(
1485                         [generic_error_remove_page],
1486                         [mm/truncate.c],
1487                         [AC_DEFINE(HAS_GENERIC_ERROR_REMOVE_PAGE, 1,
1488                                 [kernel export generic_error_remove_page])],
1489                         [])
1490          ]
1491 )
1492
1493 # 2.6.32 if kernel export access_process_vm().
1494 AC_DEFUN([LC_EXPORT_ACCESS_PROCESS_VM],
1495         [LB_CHECK_SYMBOL_EXPORT([access_process_vm],
1496                         [mm/memory.c],
1497                         [AC_DEFINE(HAVE_ACCESS_PROCESS_VM, 1,
1498                                 [access_process_vm function is present])],
1499                         [])
1500         ]
1501 )
1502
1503 #
1504 # 2.6.36 fs_struct.lock use spinlock instead of rwlock.
1505 #
1506 AC_DEFUN([LC_FS_STRUCT_RWLOCK],
1507 [AC_MSG_CHECKING([if fs_struct.lock use rwlock])
1508 LB_LINUX_TRY_COMPILE([
1509         #include <asm/atomic.h>
1510         #include <linux/spinlock.h>
1511         #include <linux/fs_struct.h>
1512 ],[
1513         ((struct fs_struct *)0)->lock = (rwlock_t){ 0 };
1514 ],[
1515         AC_DEFINE(HAVE_FS_STRUCT_RWLOCK, 1,
1516                   [fs_struct.lock use rwlock])
1517         AC_MSG_RESULT([yes])
1518 ],[
1519         AC_MSG_RESULT([no])
1520 ])
1521 ])
1522
1523 #
1524 # 2.6.36 super_operations add evict_inode method. it hybird of
1525 # delete_inode & clear_inode.
1526 #
1527 AC_DEFUN([LC_SBOPS_EVICT_INODE],
1528 [AC_MSG_CHECKING([if super_operations.evict_inode exist])
1529 LB_LINUX_TRY_COMPILE([
1530         #include <linux/fs.h>
1531 ],[
1532         ((struct super_operations *)0)->evict_inode(NULL);
1533 ],[
1534         AC_DEFINE(HAVE_SBOPS_EVICT_INODE, 1,
1535                 [super_operations.evict_inode() is exist in kernel])
1536         AC_MSG_RESULT([yes])
1537 ],[
1538         AC_MSG_RESULT([no])
1539 ])
1540 ])
1541
1542 #
1543 # 2.6.35 file_operations.fsync taken 2 arguments.
1544 # 3.0.0 file_operations.fsync takes 4 arguments.
1545 #
1546 AC_DEFUN([LC_FILE_FSYNC],
1547 [AC_MSG_CHECKING([if file_operations.fsync takes 4 or 2 arguments])
1548 LB_LINUX_TRY_COMPILE([
1549         #include <linux/fs.h>
1550 ],[
1551         ((struct file_operations *)0)->fsync(NULL, 0, 0, 0);
1552 ],[
1553         AC_DEFINE(HAVE_FILE_FSYNC_4ARGS, 1,
1554                 [file_operations.fsync takes 4 arguments])
1555         AC_MSG_RESULT([yes, 4 args])
1556 ],[
1557         LB_LINUX_TRY_COMPILE([
1558                 #include <linux/fs.h>
1559         ],[
1560            ((struct file_operations *)0)->fsync(NULL, 0);
1561         ],[
1562                 AC_DEFINE(HAVE_FILE_FSYNC_2ARGS, 1,
1563                         [file_operations.fsync takes 2 arguments])
1564                 AC_MSG_RESULT([yes, 2 args])
1565         ],[
1566                 AC_MSG_RESULT([no])
1567         ])
1568 ])
1569 ])
1570
1571 #
1572 # 2.6.37 remove kernel_locked
1573 #
1574 AC_DEFUN([LC_KERNEL_LOCKED],
1575 [AC_MSG_CHECKING([if kernel_locked is defined])
1576 LB_LINUX_TRY_COMPILE([
1577         #include <linux/smp_lock.h>
1578 ],[
1579         kernel_locked();
1580 ],[
1581         AC_MSG_RESULT([yes])
1582         AC_DEFINE(HAVE_KERNEL_LOCKED, 1,
1583                 [kernel_locked is defined])
1584 ],[
1585         AC_MSG_RESULT([no])
1586 ])
1587 ])
1588
1589 #
1590 # 2.6.38 dentry_operations.d_compare() taken 7 arguments.
1591 #
1592 AC_DEFUN([LC_D_COMPARE_7ARGS],
1593 [AC_MSG_CHECKING([if d_compare taken 7 arguments])
1594 LB_LINUX_TRY_COMPILE([
1595         #include <linux/dcache.h>
1596 ],[
1597         ((struct dentry_operations*)0)->d_compare(NULL,NULL,NULL,NULL,0,NULL,NULL);
1598 ],[
1599         AC_DEFINE(HAVE_D_COMPARE_7ARGS, 1,
1600                 [d_compare need 7 arguments])
1601         AC_MSG_RESULT([yes])
1602 ],[
1603         AC_MSG_RESULT([no])
1604 ])
1605 ])
1606
1607 #
1608 # 2.6.38 dentry_operations.d_delete() defined 'const' for 1st parameter.
1609 #
1610 AC_DEFUN([LC_D_DELETE_CONST],
1611 [AC_MSG_CHECKING([if d_delete has const declare on first parameter])
1612 tmp_flags="$EXTRA_KCFLAGS"
1613 EXTRA_KCFLAGS="-Werror"
1614 LB_LINUX_TRY_COMPILE([
1615         #include <linux/dcache.h>
1616 ],[
1617         const struct dentry *d = NULL;
1618         ((struct dentry_operations*)0)->d_delete(d);
1619 ],[
1620         AC_DEFINE(HAVE_D_DELETE_CONST, const,
1621                 [d_delete first parameter declared const])
1622         AC_MSG_RESULT([yes])
1623 ],[
1624         AC_DEFINE(HAVE_D_DELETE_CONST, , [])
1625         AC_MSG_RESULT([no])
1626 ])
1627 EXTRA_KCFLAGS="$tmp_flags"
1628 ])
1629
1630 #
1631 # 2.6.38 dcache_lock removed. rcu-walk commited.
1632 #
1633 AC_DEFUN([LC_DCACHE_LOCK],
1634 [AC_MSG_CHECKING([if dcache_lock is exist])
1635 LB_LINUX_TRY_COMPILE([
1636         #include <linux/dcache.h>
1637 ],[
1638         spin_lock(&dcache_lock);
1639 ],[
1640         AC_DEFINE(HAVE_DCACHE_LOCK, 1,
1641                 [dcache_lock is exist])
1642         AC_MSG_RESULT([yes])
1643 ],[
1644         AC_MSG_RESULT([no])
1645 ])
1646 ])
1647
1648 #
1649 # 2.6.38 export blkdev_get_by_dev
1650 #
1651 AC_DEFUN([LC_BLKDEV_GET_BY_DEV],
1652 [LB_CHECK_SYMBOL_EXPORT([blkdev_get_by_dev],
1653 [fs/block_dev.c],[
1654 AC_DEFINE(HAVE_BLKDEV_GET_BY_DEV, 1,
1655             [blkdev_get_by_dev is exported by the kernel])
1656 ],[
1657 ])
1658 ])
1659
1660 #
1661 # 2.6.38 vfsmount.mnt_count doesn't use atomic_t
1662 #
1663 # 3.3 starts hiding vfsmount guts series (move from include/linux/mount.h to
1664 # fs/mount.h, see kernel commit 7d6fec45a5131918b51dcd76da52f2ec86a85be6)
1665 #
1666 AC_DEFUN([LC_ATOMIC_MNT_COUNT],
1667 [AC_MSG_CHECKING([if vfsmount guts is hidden, or vfsmount.mnt_count is atomic_t.])
1668 LB_LINUX_TRY_COMPILE([
1669         #include <linux/fs.h>
1670         #include <../fs/mount.h>
1671 ],[
1672         struct mount *mnt =  real_mount((struct vfsmount *)0);
1673 ],[
1674         AC_DEFINE(HAVE_HIDE_VFSMOUNT_GUTS, 1,
1675                   [hide vfsmount guts in fs/mount.h])
1676         AC_MSG_RESULT([yes, hide vfsmount guts in fs/mount.h])
1677 ],[
1678         LB_LINUX_TRY_COMPILE([
1679                 #include <asm/atomic.h>
1680                 #include <linux/fs.h>
1681                 #include <linux/mount.h>
1682         ],[
1683                 ((struct vfsmount *)0)->mnt_count = ((atomic_t) { 0 });
1684         ],[
1685                 AC_DEFINE(HAVE_ATOMIC_MNT_COUNT, 1,
1686                         [vfsmount.mnt_count is atomic_t])
1687                 AC_MSG_RESULT([yes, vfsmount.mnt_count is atomic_t])
1688         ],[
1689                 AC_MSG_RESULT([no])
1690         ])
1691 ])
1692 ])
1693
1694 #
1695 # 2.6.38 use path as 4th parameter in quota_on.
1696 #
1697 AC_DEFUN([LC_QUOTA_ON_USE_PATH],
1698 [AC_MSG_CHECKING([quota_on use path as parameter])
1699 tmp_flags="$EXTRA_KCFLAGS"
1700 EXTRA_KCFLAGS="-Werror"
1701 LB_LINUX_TRY_COMPILE([
1702         #include <linux/fs.h>
1703         #include <linux/quota.h>
1704 ],[
1705         ((struct quotactl_ops *)0)->quota_on(NULL, 0, 0, ((struct path*)0));
1706 ],[
1707         AC_DEFINE(HAVE_QUOTA_ON_USE_PATH, 1,
1708                 [quota_on use path as 4th paramter])
1709         AC_MSG_RESULT([yes])
1710 ],[
1711         AC_MSG_RESULT([no])
1712 ])
1713 EXTRA_KCFLAGS="$tmp_flags"
1714 ])
1715
1716 #
1717 # 2.6.38 export simple_setattr
1718 #
1719 AC_DEFUN([LC_EXPORT_SIMPLE_SETATTR],
1720 [LB_CHECK_SYMBOL_EXPORT([simple_setattr],
1721 [fs/libfs.c],[
1722 AC_DEFINE(HAVE_SIMPLE_SETATTR, 1,
1723             [simple_setattr is exported by the kernel])
1724 ],[
1725 ])
1726 ])
1727
1728 #
1729 # 2.6.39 remove unplug_fn from request_queue.
1730 #
1731 AC_DEFUN([LC_REQUEST_QUEUE_UNPLUG_FN],
1732 [AC_MSG_CHECKING([if request_queue has unplug_fn field])
1733 LB_LINUX_TRY_COMPILE([
1734         #include <linux/blkdev.h>
1735 ],[
1736         do{ }while(sizeof(((struct request_queue *)0)->unplug_fn));
1737 ],[
1738         AC_DEFINE(HAVE_REQUEST_QUEUE_UNPLUG_FN, 1,
1739                   [request_queue has unplug_fn field])
1740         AC_MSG_RESULT([yes])
1741 ],[
1742         AC_MSG_RESULT([no])
1743 ])
1744 ])
1745
1746 #
1747 # 2.6.39 replace get_sb with mount in struct file_system_type
1748 #
1749 AC_DEFUN([LC_HAVE_FSTYPE_MOUNT],
1750 [AC_MSG_CHECKING([if file_system_type has mount field])
1751 LB_LINUX_TRY_COMPILE([
1752         #include <linux/fs.h>
1753 ],[
1754         struct file_system_type fst;
1755         void *i = (void *) fst.mount;
1756 ],[
1757         AC_DEFINE(HAVE_FSTYPE_MOUNT, 1,
1758                 [struct file_system_type has mount field])
1759         AC_MSG_RESULT([yes])
1760 ],[
1761         AC_MSG_RESULT([no])
1762 ])
1763 ])
1764
1765 #
1766 # 2.6.38 generic_permission taken 4 parameters.
1767 # in fact, it means rcu-walk aware permission bring.
1768 #
1769 # 3.1 generic_permission taken 2 parameters.
1770 # see kernel commit 2830ba7f34ebb27c4e5b8b6ef408cd6d74860890
1771 #
1772 AC_DEFUN([LC_GENERIC_PERMISSION],
1773 [AC_MSG_CHECKING([if generic_permission take 2 or 4 arguments])
1774 LB_LINUX_TRY_COMPILE([
1775         #include <linux/fs.h>
1776 ],[
1777         generic_permission(NULL, 0);
1778 ],[
1779         AC_DEFINE(HAVE_GENERIC_PERMISSION_2ARGS, 1,
1780                   [generic_permission taken 2 arguments])
1781         AC_MSG_RESULT([yes, 2 args])
1782 ],[
1783         LB_LINUX_TRY_COMPILE([
1784                 #include <linux/fs.h>
1785         ],[
1786                 generic_permission(NULL, 0, 0, NULL);
1787         ],[
1788                 AC_DEFINE(HAVE_GENERIC_PERMISSION_4ARGS, 1,
1789                           [generic_permission taken 4 arguments])
1790                 AC_MSG_RESULT([yes, 4 args])
1791         ],[
1792                 AC_MSG_RESULT([no])
1793         ])
1794 ])
1795 ])
1796
1797 #
1798 # 3.1 renames lock-manager ops(lock_manager_operations) from fl_xxx to lm_xxx
1799 # see kernel commit 8fb47a4fbf858a164e973b8ea8ef5e83e61f2e50
1800 #
1801 AC_DEFUN([LC_LM_XXX_LOCK_MANAGER_OPS],
1802 [AC_MSG_CHECKING([if lock-manager ops renamed to lm_xxx])
1803 LB_LINUX_TRY_COMPILE([
1804         #include <linux/fs.h>
1805 ],[
1806         struct lock_manager_operations lm_ops;
1807         lm_ops.lm_compare_owner = NULL;
1808 ],[
1809         AC_DEFINE(HAVE_LM_XXX_LOCK_MANAGER_OPS, 1,
1810                   [lock-manager ops renamed to lm_xxx])
1811         AC_MSG_RESULT([yes])
1812 ],[
1813         AC_MSG_RESULT([no])
1814 ])
1815 ])
1816
1817 #
1818 # 3.1 kills inode->i_alloc_sem, use i_dio_count and inode_dio_wait/
1819 #     inode_dio_done instead.
1820 # see kernel commit bd5fe6c5eb9c548d7f07fe8f89a150bb6705e8e3
1821 #
1822 AC_DEFUN([LC_INODE_DIO_WAIT],
1823 [AC_MSG_CHECKING([if inode->i_alloc_sem is killed and use inode_dio_wait/done.])
1824 LB_LINUX_TRY_COMPILE([
1825         #include <linux/fs.h>
1826 ],[
1827         inode_dio_wait((struct inode *)0);
1828         inode_dio_done((struct inode *)0);
1829 ],[
1830         AC_DEFINE(HAVE_INODE_DIO_WAIT, 1,
1831                   [inode->i_alloc_sem is killed and use inode_dio_wait/done])
1832         AC_MSG_RESULT([yes])
1833 ],[
1834         AC_MSG_RESULT([no])
1835 ])
1836 ])
1837
1838 #
1839 # 3.1 adds get_acl method to inode_operations to read ACL from disk.
1840 # see kernel commit 4e34e719e457f2e031297175410fc0bd4016a085
1841 #
1842 AC_DEFUN([LC_IOP_GET_ACL],
1843 [AC_MSG_CHECKING([inode_operations has .get_acl member function])
1844 LB_LINUX_TRY_COMPILE([
1845         #include <linux/fs.h>
1846 ],[
1847         struct inode_operations iop;
1848         iop.get_acl = NULL;
1849 ],[
1850         AC_DEFINE(HAVE_IOP_GET_ACL, 1,
1851                   [inode_operations has .get_acl member function])
1852         AC_MSG_RESULT([yes])
1853 ],[
1854         AC_MSG_RESULT([no])
1855 ])
1856 ])
1857
1858 #
1859 # 3.1.1 has ext4_blocks_for_truncate
1860 #
1861 AC_DEFUN([LC_BLOCKS_FOR_TRUNCATE],
1862 [AC_MSG_CHECKING([if kernel has ext4_blocks_for_truncate])
1863 LB_LINUX_TRY_COMPILE([
1864         #include <linux/fs.h>
1865         #include "$LINUX/fs/ext4/ext4_jbd2.h"
1866         #include "$LINUX/fs/ext4/truncate.h"
1867 ],[
1868         ext4_blocks_for_truncate(NULL);
1869 ],[
1870         AC_MSG_RESULT([yes])
1871         AC_DEFINE(HAVE_BLOCKS_FOR_TRUNCATE, 1,
1872                   [kernel has ext4_blocks_for_truncate])
1873 ],[
1874         AC_MSG_RESULT([no])
1875 ])
1876 ])
1877
1878 #
1879 # 3.1 introduced generic_file_llseek_size()
1880 #
1881 AC_DEFUN([LC_FILE_LLSEEK_SIZE],
1882         [LB_CHECK_SYMBOL_EXPORT([generic_file_llseek_size],
1883         [fs/read_write.c],
1884         [AC_DEFINE(HAVE_FILE_LLSEEK_SIZE, 1,
1885                    [generic_file_llseek_size is exported by the kernel])])
1886 ])
1887
1888 #
1889 # 3.2 request_queue.make_request_fn defined as function returns with void
1890 # see kernel commit 5a7bbad27a410350e64a2d7f5ec18fc73836c14f
1891 #
1892 AC_DEFUN([LC_HAVE_VOID_MAKE_REQUEST_FN],
1893 [AC_MSG_CHECKING([if request_queue.make_request_fn returns void but not int])
1894 LB_LINUX_TRY_COMPILE([
1895         #include <linux/blkdev.h>
1896 ],[
1897         int ret;
1898         make_request_fn         *mrf;
1899         ret = mrf(NULL, NULL);
1900 ],[
1901         AC_MSG_RESULT([no])
1902 ],[
1903         AC_DEFINE(HAVE_VOID_MAKE_REQUEST_FN, 1,
1904                   [request_queue.make_request_fn returns void but not int])
1905         AC_MSG_RESULT([yes])
1906 ])
1907 ])
1908
1909 #
1910 # 3.2 protects inode->i_nlink from direct modification
1911 # see kernel commit a78ef704a8dd430225955f0709b22d4a6ba21deb
1912 # at the same time adds set_nlink(), so checks set_nlink() for it.
1913 #
1914 AC_DEFUN([LC_HAVE_PROTECT_I_NLINK],
1915 [AC_MSG_CHECKING([if inode->i_nlink is protected from direct modification])
1916 LB_LINUX_TRY_COMPILE([
1917         #include <linux/fs.h>
1918 ],[
1919         struct inode i;
1920         set_nlink(&i, 1);
1921 ],[
1922         AC_DEFINE(HAVE_PROTECT_I_NLINK, 1,
1923                   [inode->i_nlink is protected from direct modification])
1924         AC_MSG_RESULT([yes])
1925 ],[
1926         AC_MSG_RESULT([no])
1927 ])
1928 ])
1929
1930 #
1931 # 3.3 introduces migrate_mode.h and migratepage has 4 args
1932 #
1933 AC_DEFUN([LC_HAVE_MIGRATE_HEADER],
1934 [LB_CHECK_FILE([$LINUX/include/linux/migrate.h],[
1935                 AC_DEFINE(HAVE_MIGRATE_H, 1,
1936                 [kernel has include/linux/migrate.h])
1937 ],[LB_CHECK_FILE([$LINUX/include/linux/migrate_mode.h],[
1938                 AC_DEFINE(HAVE_MIGRATE_MODE_H, 1,
1939                         [kernel has include/linux/migrate_mode.h])
1940 ],[
1941         AC_MSG_RESULT([no])
1942 ])
1943 ])
1944 ])
1945
1946 AC_DEFUN([LC_MIGRATEPAGE_4ARGS],
1947 [AC_MSG_CHECKING([if address_space_operations.migratepage has 4 args])
1948 LB_LINUX_TRY_COMPILE([
1949         #include <linux/fs.h>
1950 #ifdef HAVE_MIGRATE_H
1951         #include <linux/migrate.h>
1952 #elif defined(HAVE_MIGRATE_MODE_H)
1953         #include <linux/migrate_mode.h>
1954 #endif
1955 ],[
1956         struct address_space_operations aops;
1957
1958         aops.migratepage(NULL, NULL, NULL, MIGRATE_ASYNC);
1959 ],[
1960         AC_DEFINE(HAVE_MIGRATEPAGE_4ARGS, 1,
1961                 [address_space_operations.migratepage has 4 args])
1962         AC_MSG_RESULT([yes])
1963 ],[
1964         AC_MSG_RESULT([no])
1965 ])
1966 ])
1967
1968 #
1969 # 3.3 switchs super_operations to use dentry as parameter (but not vfsmount)
1970 # see kernel commit 34c80b1d93e6e20ca9dea0baf583a5b5510d92d4
1971 #
1972 AC_DEFUN([LC_SUPEROPS_USE_DENTRY],
1973 [AC_MSG_CHECKING([if super_operations use dentry as parameter])
1974 tmp_flags="$EXTRA_KCFLAGS"
1975 EXTRA_KCFLAGS="-Werror"
1976 LB_LINUX_TRY_COMPILE([
1977         #include <linux/fs.h>
1978         int show_options(struct seq_file *seq, struct dentry *root){
1979                 return 0;
1980         }
1981 ],[
1982         struct super_operations ops;
1983         ops.show_options = show_options;
1984 ],[
1985         AC_DEFINE(HAVE_SUPEROPS_USE_DENTRY, 1,
1986                   [super_operations use dentry as parameter])
1987         AC_MSG_RESULT([yes])
1988 ],[
1989         AC_MSG_RESULT([no])
1990 ])
1991 EXTRA_KCFLAGS="$tmp_flags"
1992 ])
1993
1994 #
1995 # 3.3 switchs inode_operations to use umode_t as parameter (but not int)
1996 # see kernel commit 1a67aafb5f72a436ca044293309fa7e6351d6a35
1997 #
1998 AC_DEFUN([LC_INODEOPS_USE_UMODE_T],
1999 [AC_MSG_CHECKING([if inode_operations use umode_t as parameter])
2000 tmp_flags="$EXTRA_KCFLAGS"
2001 EXTRA_KCFLAGS="-Werror"
2002 LB_LINUX_TRY_COMPILE([
2003         #include <linux/fs.h>
2004         #include <linux/types.h>
2005         int my_mknod(struct inode *dir, struct dentry *dchild,
2006                      umode_t mode, dev_t dev)
2007         {
2008                 return 0;
2009         }
2010 ],[
2011         struct inode_operations ops;
2012         ops.mknod = my_mknod;
2013 ],[
2014         AC_DEFINE(HAVE_INODEOPS_USE_UMODE_T, 1,
2015                   [inode_operations use umode_t as parameter])
2016         AC_MSG_RESULT([yes])
2017 ],[
2018         AC_MSG_RESULT([no])
2019 ])
2020 EXTRA_KCFLAGS="$tmp_flags"
2021 ])
2022
2023 # 3.4 kmap_atomic removes second argument
2024 # see kernel commit 1ec9c5ddc17aa398f05646abfcbaf315b544e62f
2025 #
2026 AC_DEFUN([LC_KMAP_ATOMIC_HAS_1ARG],
2027 [AC_MSG_CHECKING([if kmap_atomic has only 1 argument])
2028 LB_LINUX_TRY_COMPILE([
2029         #include <linux/highmem.h>
2030 ],[
2031         kmap_atomic(NULL);
2032 ],[
2033         AC_DEFINE(HAVE_KMAP_ATOMIC_HAS_1ARG, 1,
2034                   [have kmap_atomic has only 1 argument])
2035         AC_MSG_RESULT([yes])
2036 ],[
2037         AC_MSG_RESULT([no])
2038 ])
2039 ])
2040
2041 #
2042 # 3.4 switchs touch_atime to struct path
2043 # see kernel commit 68ac1234fb949b66941d94dce4157742799fc581
2044 #
2045 AC_DEFUN([LC_TOUCH_ATIME_1ARG],
2046 [AC_MSG_CHECKING([if touch_atime use one argument])
2047 LB_LINUX_TRY_COMPILE([
2048         #include <linux/fs.h>
2049 ],[
2050         touch_atime((struct path *)NULL);
2051 ],[
2052         AC_DEFINE(HAVE_TOUCH_ATIME_1ARG, 1,
2053                   [touch_atime use one argument])
2054         AC_MSG_RESULT([yes])
2055 ],[
2056         AC_MSG_RESULT([no])
2057 ])
2058 ])
2059
2060 #
2061 # 3.4 converts d_alloc_root to d_make_root
2062 # see kernel commit 32991ab305ace7017c62f8eecbe5eb36dc32e13b
2063 #
2064 AC_DEFUN([LC_HAVE_D_MAKE_ROOT],
2065 [AC_MSG_CHECKING([if have d_make_root])
2066 LB_LINUX_TRY_COMPILE([
2067         #include <linux/fs.h>
2068 ],[
2069         d_make_root((struct inode *)NULL);
2070 ],[
2071         AC_DEFINE(HAVE_D_MAKE_ROOT, 1,
2072                   [have d_make_root])
2073         AC_MSG_RESULT([yes])
2074 ],[
2075         AC_MSG_RESULT([no])
2076 ])
2077 ])
2078
2079 #
2080 # 3.5 renames end_writeback() back to clear_inode()...
2081 # see kernel commit dbd5768f87ff6fb0a4fe09c4d7b6c4a24de99430
2082 #
2083 AC_DEFUN([LC_HAVE_CLEAR_INODE],
2084 [AC_MSG_CHECKING([if have clear_inode])
2085 LB_LINUX_TRY_COMPILE([
2086         #include <linux/fs.h>
2087 ],[
2088         clear_inode((struct inode *)NULL);
2089 ],[
2090         AC_DEFINE(HAVE_CLEAR_INODE, 1,
2091                   [have clear_inode])
2092         AC_MSG_RESULT([yes])
2093 ],[
2094         AC_MSG_RESULT([no])
2095 ])
2096 ])
2097
2098 #
2099 # 3.5 encode_fh has parent inode passed in directly
2100 # see kernel commit b0b0382b
2101 #
2102 AC_DEFUN([LC_HAVE_ENCODE_FH_PARENT],
2103 [AC_MSG_CHECKING([if encode_fh have parent inode as parameter])
2104 tmp_flags="$EXTRA_KCFLAGS"
2105 EXTRA_KCFLAGS="-Werror"
2106 LB_LINUX_TRY_COMPILE([
2107         #include <linux/exportfs.h>
2108         #include <linux/fs.h>
2109         #include <linux/types.h>
2110         int ll_encode_fh(struct inode *i, __u32 *a, int *b, struct inode *p)
2111         {
2112                 return 0;
2113         }
2114 ],[
2115         struct export_operations exp_op;
2116         exp_op.encode_fh = ll_encode_fh;
2117 ],[
2118         AC_DEFINE(HAVE_ENCODE_FH_PARENT, 1,
2119                   [have parent inode as parameter])
2120         AC_MSG_RESULT([yes])
2121 ],[
2122         AC_MSG_RESULT([no])
2123 ])
2124 EXTRA_KCFLAGS="$tmp_flags"
2125 ])
2126
2127 #
2128 # 3.6 switch i_dentry/d_alias from list to hlist
2129 #
2130 AC_DEFUN([LC_HAVE_DENTRY_D_ALIAS_HLIST],
2131 [AC_MSG_CHECKING([if i_dentry/d_alias uses hlist])
2132 tmp_flags="$EXTRA_KCFLAGS"
2133 EXTRA_KCFLAGS="-Werror"
2134 LB_LINUX_TRY_COMPILE([
2135         #include <linux/fs.h>
2136         #include <linux/list.h>
2137 ],[
2138         struct inode inode;
2139         struct dentry dentry;
2140         struct hlist_head head;
2141         struct hlist_node node;
2142         inode.i_dentry = head;
2143         dentry.d_alias = node;
2144 ],[
2145         AC_DEFINE(HAVE_DENTRY_D_ALIAS_HLIST, 1,
2146                   [have i_dentry/d_alias uses hlist])
2147         AC_MSG_RESULT([yes])
2148 ],[
2149         AC_MSG_RESULT([no])
2150 ])
2151 EXTRA_KCFLAGS="$tmp_flags"
2152 ])
2153
2154 #
2155 # 3.6 dentry_open uses struct path as first argument
2156 # see kernel commit 765927b2
2157 #
2158 AC_DEFUN([LC_DENTRY_OPEN_USE_PATH],
2159 [AC_MSG_CHECKING([if dentry_open uses struct path as first argument])
2160 tmp_flags="$EXTRA_KCFLAGS"
2161 EXTRA_KCFLAGS="-Werror"
2162 LB_LINUX_TRY_COMPILE([
2163         #include <linux/fs.h>
2164         #include <linux/path.h>
2165 ],[
2166         struct path path;
2167         dentry_open(&path, 0, NULL);
2168 ],[
2169         AC_DEFINE(HAVE_DENTRY_OPEN_USE_PATH, 1,
2170                   [dentry_open uses struct path as first argument])
2171         AC_MSG_RESULT([yes])
2172 ],[
2173         AC_MSG_RESULT([no])
2174 ])
2175 EXTRA_KCFLAGS="$tmp_flags"
2176 ])
2177
2178 #
2179 # LC_PROG_LINUX
2180 #
2181 # Lustre linux kernel checks
2182 #
2183 AC_DEFUN([LC_PROG_LINUX],
2184          [
2185          LC_CONFIG_PINGER
2186          LC_CONFIG_CHECKSUM
2187          LC_CONFIG_LIBLUSTRE_RECOVERY
2188          LC_CONFIG_HEALTH_CHECK_WRITE
2189          LC_CONFIG_LRU_RESIZE
2190          LC_LLITE_LLOOP_MODULE
2191
2192          # RHEL4 patches
2193          LC_EXPORT_TRUNCATE_COMPLETE
2194          LC_EXPORT_D_REHASH_COND
2195          LC_EXPORT___D_REHASH
2196          LC_EXPORT_NODE_TO_CPUMASK
2197
2198          LC_FILEMAP_POPULATE
2199          LC_BIT_SPINLOCK_H
2200
2201          LC_CONST_ACL_SIZE
2202
2203          LC_CAPA_CRYPTO
2204          LC_CONFIG_RMTCLIENT
2205          LC_CONFIG_GSS
2206          LC_TASK_CLENV_STORE
2207
2208          # 2.6.12
2209          LC_RW_TREE_LOCK
2210
2211          # 2.6.18
2212          LC_UMOUNTBEGIN_HAS_VFSMOUNT
2213
2214          #2.6.18 + RHEL5 (fc6)
2215          LC_LINUX_FIEMAP_H
2216
2217          # 2.6.19
2218          LC_FILE_WRITEV
2219          LC_FILE_READV
2220
2221          # 2.6.20
2222          LC_CANCEL_DIRTY_PAGE
2223
2224          # raid5-zerocopy patch
2225          LC_PAGE_CONSTANT
2226
2227          # 2.6.22
2228          LC_INVALIDATE_BDEV_2ARG
2229          LC_ASYNC_BLOCK_CIPHER
2230          LC_STRUCT_HASH_DESC
2231          LC_STRUCT_BLKCIPHER_DESC
2232          LC_FS_RENAME_DOES_D_MOVE
2233
2234          # 2.6.23
2235          LC_UNREGISTER_BLKDEV_RETURN_INT
2236          LC_KERNEL_SPLICE_READ
2237          LC_KERNEL_SENDFILE
2238          LC_HAVE_EXPORTFS_H
2239          LC_VM_OP_FAULT
2240          LC_PROCFS_USERS
2241          LC_EXPORTFS_DECODE_FH
2242
2243          # 2.6.24
2244          LC_HAVE_MMTYPES_H
2245          LC_BIO_ENDIO_2ARG
2246          LC_FH_TO_DENTRY
2247          LC_PROCFS_DELETED
2248          LC_EXPORT_BDI_INIT
2249
2250          # 2.6.26
2251          LC_FS_STRUCT_USE_PATH
2252
2253          # 2.6.27
2254          LC_SECURITY_PLUG  # for SLES10 SP2
2255          LC_PGMKWRITE_USE_VMFAULT
2256          LC_PGMKWRITE_COMPACT
2257          LC_INODE_PERMISION_2ARGS
2258          LC_TRYLOCKPAGE
2259          LC_READ_INODE_IN_SBOPS
2260          LC_EXPORT_INODE_PERMISSION
2261          LC_QUOTA_ON_5ARGS
2262          LC_QUOTA_OFF_3ARGS
2263          LC_VFS_DQ_OFF
2264          LC_LOCK_MAP_ACQUIRE
2265
2266          # 2.6.27.15-2 sles11
2267          LC_BI_HW_SEGMENTS
2268          LC_HAVE_QUOTAIO_H
2269          LC_BDI_NAME
2270          LC_SB_ANY_QUOTA_ACTIVE
2271          LC_SB_HAS_QUOTA_ACTIVE
2272          LC_EXPORT_ADD_TO_PAGE_CACHE_LRU
2273
2274          # 2.6.29
2275          LC_SB_ANY_QUOTA_LOADED
2276
2277          # 2.6.30
2278          LC_EXPORT_CPUMASK_OF_NODE
2279
2280          # 2.6.31
2281          LC_BLK_QUEUE_LOG_BLK_SIZE
2282
2283          # 2.6.32
2284          LC_REQUEST_QUEUE_LIMITS
2285          LC_EXPORT_BDI_REGISTER
2286          LC_SB_BDI
2287          LC_BLK_QUEUE_MAX_SECTORS
2288          LC_BLK_QUEUE_MAX_SEGMENTS
2289          LC_SET_CPUS_ALLOWED
2290          LC_CACHE_UPCALL
2291          LC_EXPORT_GENERIC_ERROR_REMOVE_PAGE
2292          LC_SELINUX_IS_ENABLED
2293          LC_EXPORT_ACCESS_PROCESS_VM
2294          LC_VFS_INODE_NEWSIZE_OK
2295
2296          # 2.6.35, 3.0.0
2297          LC_FILE_FSYNC
2298          LC_EXPORT_SIMPLE_SETATTR
2299
2300          # 2.6.36
2301          LC_FS_STRUCT_RWLOCK
2302          LC_SBOPS_EVICT_INODE
2303
2304          # 2.6.37
2305          LC_KERNEL_LOCKED
2306
2307          # 2.6.38
2308          LC_ATOMIC_MNT_COUNT
2309          LC_BLKDEV_GET_BY_DEV
2310          LC_GENERIC_PERMISSION
2311          LC_QUOTA_ON_USE_PATH
2312          LC_DCACHE_LOCK
2313          LC_D_COMPARE_7ARGS
2314          LC_D_DELETE_CONST
2315
2316          # 2.6.39
2317          LC_REQUEST_QUEUE_UNPLUG_FN
2318          LC_HAVE_FSTYPE_MOUNT
2319
2320          # 3.1
2321          LC_LM_XXX_LOCK_MANAGER_OPS
2322          LC_INODE_DIO_WAIT
2323          LC_IOP_GET_ACL
2324          LC_FILE_LLSEEK_SIZE
2325
2326          # 3.1.1
2327          LC_BLOCKS_FOR_TRUNCATE
2328
2329          # 3.2
2330          LC_HAVE_VOID_MAKE_REQUEST_FN
2331          LC_HAVE_PROTECT_I_NLINK
2332
2333          # 3.3
2334          LC_HAVE_MIGRATE_HEADER
2335          LC_MIGRATEPAGE_4ARGS
2336          LC_SUPEROPS_USE_DENTRY
2337          LC_INODEOPS_USE_UMODE_T
2338
2339          # 3.4
2340          LC_TOUCH_ATIME_1ARG
2341          LC_HAVE_D_MAKE_ROOT
2342          LC_KMAP_ATOMIC_HAS_1ARG
2343
2344          # 3.5
2345          LC_HAVE_CLEAR_INODE
2346          LC_HAVE_ENCODE_FH_PARENT
2347
2348          # 3.6
2349          LC_HAVE_DENTRY_D_ALIAS_HLIST
2350          LC_DENTRY_OPEN_USE_PATH
2351
2352          #
2353          if test x$enable_server = xyes ; then
2354                 AC_DEFINE(HAVE_SERVER_SUPPORT, 1, [support server])
2355                 LC_FUNC_DEV_SET_RDONLY
2356                 LC_STACK_SIZE
2357                 LC_QUOTA64
2358                 LC_QUOTA_CONFIG
2359          fi
2360 ])
2361
2362 #
2363 # LC_CONFIG_CLIENT_SERVER
2364 #
2365 # Build client/server sides of Lustre
2366 #
2367 AC_DEFUN([LC_CONFIG_CLIENT_SERVER],
2368 [AC_MSG_CHECKING([whether to build Lustre server support])
2369 AC_ARG_ENABLE([server],
2370         AC_HELP_STRING([--disable-server],
2371                         [disable Lustre server support]),
2372         [],[enable_server='yes'])
2373 AC_MSG_RESULT([$enable_server])
2374
2375 AC_MSG_CHECKING([whether to build Lustre client support])
2376 AC_ARG_ENABLE([client],
2377         AC_HELP_STRING([--disable-client],
2378                         [disable Lustre client support]),
2379         [],[enable_client='yes'])
2380 AC_MSG_RESULT([$enable_client])])
2381
2382 #
2383 # LC_CONFIG_LIBLUSTRE
2384 #
2385 # whether to build liblustre
2386 #
2387 AC_DEFUN([LC_CONFIG_LIBLUSTRE],
2388 [AC_MSG_CHECKING([whether to build Lustre library])
2389 AC_ARG_ENABLE([liblustre],
2390         AC_HELP_STRING([--disable-liblustre],
2391                         [disable building of Lustre library]),
2392         [],[enable_liblustre=$with_sysio])
2393 AC_MSG_RESULT([$enable_liblustre])
2394 # only build sysio if liblustre is built
2395 with_sysio="$enable_liblustre"
2396
2397 AC_MSG_CHECKING([whether to build liblustre tests])
2398 AC_ARG_ENABLE([liblustre-tests],
2399         AC_HELP_STRING([--enable-liblustre-tests],
2400                         [enable liblustre tests, if --disable-tests is used]),
2401         [],[enable_liblustre_tests=$enable_tests])
2402 if test x$enable_liblustre != xyes ; then
2403    enable_liblustre_tests='no'
2404 fi
2405 AC_MSG_RESULT([$enable_liblustre_tests])
2406
2407 AC_MSG_CHECKING([whether to enable liblustre acl])
2408 AC_ARG_ENABLE([liblustre-acl],
2409         AC_HELP_STRING([--disable-liblustre-acl],
2410                         [disable ACL support for liblustre]),
2411         [],[enable_liblustre_acl=yes])
2412 AC_MSG_RESULT([$enable_liblustre_acl])
2413 if test x$enable_liblustre_acl = xyes ; then
2414   AC_DEFINE(LIBLUSTRE_POSIX_ACL, 1, Liblustre Support ACL-enabled MDS)
2415 fi
2416
2417 # 2.6.29 change prepare/commit_write to write_begin/end
2418 AC_DEFUN([LC_WRITE_BEGIN_END],
2419 [AC_MSG_CHECKING([if kernel has .write_begin/end])
2420 LB_LINUX_TRY_COMPILE([
2421         #include <linux/fs.h>
2422         #include <linux/pagemap.h>
2423 #ifdef HAVE_LINUX_MMTYPES_H
2424         #include <linux/mm_types.h>
2425 #endif
2426 ],[
2427         struct address_space_operations aops;
2428         struct page *page;
2429
2430         aops.write_begin = NULL;
2431         aops.write_end = NULL;
2432         page = grab_cache_page_write_begin(NULL, 0, 0);
2433 ], [
2434         AC_MSG_RESULT([yes])
2435         AC_DEFINE(HAVE_KERNEL_WRITE_BEGIN_END, 1,
2436                 [kernel has .write_begin/end])
2437 ],[
2438         AC_MSG_RESULT([no])
2439 ])
2440 ])
2441
2442 # 2.6.29 blkdev_put has 2 arguments
2443 AC_DEFUN([LC_BLKDEV_PUT_2ARGS],
2444 [AC_MSG_CHECKING([blkdev_put needs 2 parameters])
2445 LB_LINUX_TRY_COMPILE([
2446         #include <linux/fs.h>
2447 ],[
2448         blkdev_put(NULL, 0);
2449 ],[
2450         AC_DEFINE(HAVE_BLKDEV_PUT_2ARGS, 1,
2451                 [blkdev_put needs 2 paramters])
2452         AC_MSG_RESULT([yes])
2453 ],[
2454         AC_MSG_RESULT([no])
2455 ])
2456 ])
2457
2458 # 2.6.29 dentry_open has 4 arguments
2459 AC_DEFUN([LC_DENTRY_OPEN_4ARGS],
2460 [AC_MSG_CHECKING([dentry_open needs 4 parameters])
2461 LB_LINUX_TRY_COMPILE([
2462         #include <linux/fs.h>
2463 ],[
2464         dentry_open(NULL, NULL, 0, NULL);
2465 ],[
2466         AC_DEFINE(HAVE_DENTRY_OPEN_4ARGS, 1,
2467                 [dentry_open needs 4 paramters])
2468         AC_MSG_RESULT([yes])
2469 ],[
2470         AC_MSG_RESULT([no])
2471 ])
2472 ])
2473
2474 # 2.6.29 split file and anonymous page queues
2475 AC_DEFUN([LC_PAGEVEC_LRU_ADD_FILE],
2476 [AC_MSG_CHECKING([if kernel has .pagevec_lru_add_file])
2477 LB_LINUX_TRY_COMPILE([
2478         #include <linux/mm.h>
2479         #include <linux/pagevec.h>
2480 ],[
2481         struct pagevec lru_pagevec;
2482
2483         pagevec_init(&lru_pagevec, 0);
2484         pagevec_lru_add_file(&lru_pagevec);
2485 ],[
2486         AC_MSG_RESULT([yes])
2487         AC_DEFINE(HAVE_PAGEVEC_LRU_ADD_FILE, 1,
2488                 [kernel has .pagevec_lru_add_file])
2489 ],[
2490         AC_MSG_RESULT([no])
2491 ])
2492 ])
2493
2494 #
2495 # --enable-mpitest
2496 #
2497 AC_ARG_ENABLE(mpitests,
2498         AC_HELP_STRING([--enable-mpitests=yes|no|mpicc wrapper],
2499                            [include mpi tests]),
2500         [
2501          enable_mpitests=yes
2502          case $enableval in
2503          yes)
2504                 MPICC_WRAPPER=mpicc
2505                 ;;
2506          no)
2507                 enable_mpitests=no
2508                 ;;
2509          *)
2510                 MPICC_WRAPPER=$enableval
2511                  ;;
2512          esac
2513         ],
2514         [
2515         MPICC_WRAPPER=mpicc
2516         enable_mpitests=yes
2517         ]
2518 )
2519
2520 if test x$enable_mpitests != xno; then
2521         AC_MSG_CHECKING([whether mpitests can be built])
2522         oldcc=$CC
2523         CC=$MPICC_WRAPPER
2524         AC_LINK_IFELSE(
2525             [AC_LANG_PROGRAM([[
2526                     #include <mpi.h>
2527                 ]],[[
2528                     int flag;
2529                     MPI_Initialized(&flag);
2530                 ]])],
2531             [
2532                     AC_MSG_RESULT([yes])
2533             ],[
2534                     AC_MSG_RESULT([no])
2535                     enable_mpitests=no
2536         ])
2537         CC=$oldcc
2538 fi
2539 AC_SUBST(MPICC_WRAPPER)
2540
2541 AC_MSG_NOTICE([Enabling Lustre configure options for libsysio])
2542 ac_configure_args="$ac_configure_args --with-lustre-hack --with-sockets"
2543
2544 LC_CONFIG_PINGER
2545 LC_CONFIG_LIBLUSTRE_RECOVERY
2546 ])
2547
2548 #
2549 # LC_CONFIG_QUOTA
2550 #
2551 # whether to enable quota support global control
2552 #
2553 AC_DEFUN([LC_CONFIG_QUOTA],
2554 [AC_ARG_ENABLE([quota],
2555         AC_HELP_STRING([--enable-quota],
2556                         [enable quota support]),
2557         [],[enable_quota='yes'])
2558 ])
2559
2560 AC_DEFUN([LC_QUOTA],
2561 [#check global
2562 LC_CONFIG_QUOTA
2563 #check for utils
2564 AC_CHECK_HEADER(sys/quota.h,
2565                 [AC_DEFINE(HAVE_SYS_QUOTA_H, 1, [Define to 1 if you have <sys/quota.h>.])],
2566                 [AC_MSG_ERROR([don't find <sys/quota.h> in your system])])
2567 ])
2568
2569 #
2570 # LC_CONFIG_SPLIT
2571 #
2572 # whether to enable split support
2573 #
2574 AC_DEFUN([LC_CONFIG_SPLIT],
2575 [AC_MSG_CHECKING([whether to enable split support])
2576 AC_ARG_ENABLE([split],
2577         AC_HELP_STRING([--enable-split],
2578                         [enable split support]),
2579         [],[enable_split='no'])
2580 AC_MSG_RESULT([$enable_split])
2581 if test x$enable_split != xno; then
2582    AC_DEFINE(HAVE_SPLIT_SUPPORT, 1, [enable split support])
2583 fi
2584 ])
2585
2586 # RHEL5(2.6.18) has tux_info
2587 AC_DEFUN([LC_TASK_CLENV_TUX_INFO],
2588 [AC_MSG_CHECKING([tux_info])
2589 LB_LINUX_TRY_COMPILE([
2590         #include <linux/sched.h>
2591 ],[
2592         struct task_struct task;
2593         &task.tux_info;
2594 ],[
2595         AC_MSG_RESULT([yes])
2596         AC_DEFINE(LL_TASK_CL_ENV, tux_info, [have tux_info])
2597         have_task_clenv_store='yes'
2598 ],[
2599         AC_MSG_RESULT([no])
2600 ])
2601 ])
2602
2603 #
2604 # LC_LLITE_LLOOP_MODULE
2605 # lloop_llite.ko does not currently work with page sizes
2606 # of 64k or larger.
2607 #
2608 AC_DEFUN([LC_LLITE_LLOOP_MODULE],
2609 [AC_MSG_CHECKING([whether to enable llite_lloop module])
2610 LB_LINUX_TRY_COMPILE([
2611         #include <asm/page.h>
2612 ],[
2613         #if PAGE_SIZE >= 65536
2614         #error "PAGE_SIZE >= 65536"
2615         #endif
2616 ],[
2617         enable_llite_lloop_module='yes'
2618         AC_MSG_RESULT([yes])
2619 ],[
2620         enable_llite_lloop_module='no'
2621         AC_MSG_RESULT([no])
2622 ])
2623 ])
2624
2625 #
2626 # LC_OSD_ADDON
2627 #
2628 # configure support for optional OSD implementation
2629 #
2630 AC_DEFUN([LC_OSD_ADDON],
2631 [AC_MSG_CHECKING([for osd])
2632 AC_ARG_WITH([osd],
2633         AC_HELP_STRING([--with-osd=path],
2634                        [set path to optional osd]),
2635         [
2636                 case $with_osd in
2637                         no)     ENABLEOSDADDON=0
2638                                 ;;
2639                         *)      OSDADDON="${with_osd}"
2640                                 ENABLEOSDADDON=1
2641                                 ;;
2642                 esac
2643         ], [
2644                 ENABLEOSDADDON=0
2645         ])
2646 if test $ENABLEOSDADDON -eq 0; then
2647         AC_MSG_RESULT([no])
2648         OSDADDON=
2649 else
2650         OSDMODNAME=`basename $OSDADDON`
2651         if test -e $LUSTRE/$OSDMODNAME; then
2652                 AC_MSG_RESULT([can't link])
2653                 OSDADDON=
2654         elif ln -s $OSDADDON $LUSTRE/$OSDMODNAME; then
2655                 AC_MSG_RESULT([$OSDMODNAME])
2656                 OSDADDON="subdir-m += $OSDMODNAME"
2657         else
2658                 AC_MSG_RESULT([can't link])
2659                 OSDADDON=
2660         fi
2661 fi
2662 AC_SUBST(OSDADDON)
2663 ])
2664
2665 #
2666 # LC_CONFIGURE
2667 #
2668 # other configure checks
2669 #
2670 AC_DEFUN([LC_CONFIGURE],
2671 [LC_CONFIG_OBD_BUFFER_SIZE
2672
2673 if test $target_cpu == "i686" -o $target_cpu == "x86_64"; then
2674         CFLAGS="$CFLAGS -Werror"
2675 fi
2676
2677 # maximum MDS thread count
2678 LC_MDS_MAX_THREADS
2679
2680 # include/liblustre.h
2681 AC_CHECK_HEADERS([sys/user.h sys/vfs.h stdint.h blkid/blkid.h])
2682
2683 # liblustre/llite_lib.h
2684 AC_CHECK_HEADERS([xtio.h file.h])
2685
2686 # liblustre/dir.c
2687 AC_CHECK_HEADERS([linux/types.h sys/types.h linux/unistd.h unistd.h])
2688
2689 # liblustre/lutil.c
2690 AC_CHECK_HEADERS([netinet/in.h arpa/inet.h catamount/data.h])
2691 AC_CHECK_FUNCS([inet_ntoa])
2692
2693 # libsysio/src/readlink.c
2694 LC_READLINK_SSIZE_T
2695
2696 # lvfs/prng.c - depends on linux/types.h from liblustre/dir.c
2697 AC_CHECK_HEADERS([linux/random.h], [], [],
2698                  [#ifdef HAVE_LINUX_TYPES_H
2699                   # include <linux/types.h>
2700                   #endif
2701                  ])
2702
2703 # utils/llverfs.c
2704 AC_CHECK_HEADERS([ext2fs/ext2fs.h])
2705
2706 # check for -lz support
2707 ZLIB=""
2708 AC_CHECK_LIB([z],
2709              [adler32],
2710              [AC_CHECK_HEADERS([zlib.h],
2711                                [ZLIB="-lz"
2712                                 AC_DEFINE([HAVE_ADLER], 1,
2713                                           [support alder32 checksum type])],
2714                                [AC_MSG_WARN([No zlib-devel package found,
2715                                              unable to use adler32 checksum])])],
2716              [AC_MSG_WARN([No zlib package found, unable to use adler32 checksum])]
2717 )
2718 AC_SUBST(ZLIB)
2719
2720 # Super safe df
2721 AC_ARG_ENABLE([mindf],
2722       AC_HELP_STRING([--enable-mindf],
2723                       [Make statfs report the minimum available space on any single OST instead of the sum of free space on all OSTs]),
2724       [],[])
2725 if test "$enable_mindf" = "yes" ;  then
2726       AC_DEFINE([MIN_DF], 1, [Report minimum OST free space])
2727 fi
2728
2729 AC_ARG_ENABLE([fail_alloc],
2730         AC_HELP_STRING([--disable-fail-alloc],
2731                 [disable randomly alloc failure]),
2732         [],[enable_fail_alloc=yes])
2733 AC_MSG_CHECKING([whether to randomly failing memory alloc])
2734 AC_MSG_RESULT([$enable_fail_alloc])
2735 if test x$enable_fail_alloc != xno ; then
2736         AC_DEFINE([RANDOM_FAIL_ALLOC], 1, [enable randomly alloc failure])
2737 fi
2738
2739 AC_ARG_ENABLE([invariants],
2740         AC_HELP_STRING([--enable-invariants],
2741                 [enable invariant checking (cpu intensive)]),
2742         [],[])
2743 AC_MSG_CHECKING([whether to check invariants (expensive cpu-wise)])
2744 AC_MSG_RESULT([$enable_invariants])
2745 if test x$enable_invariants = xyes ; then
2746         AC_DEFINE([INVARIANT_CHECK], 1, [enable invariant checking])
2747 fi
2748
2749 AC_ARG_ENABLE([lu_ref],
2750         AC_HELP_STRING([--enable-lu_ref],
2751                 [enable lu_ref reference tracking code]),
2752         [],[])
2753 AC_MSG_CHECKING([whether to track references with lu_ref])
2754 AC_MSG_RESULT([$enable_lu_ref])
2755 if test x$enable_lu_ref = xyes ; then
2756         AC_DEFINE([USE_LU_REF], 1, [enable lu_ref reference tracking code])
2757 fi
2758
2759 AC_ARG_ENABLE([pgstate-track],
2760               AC_HELP_STRING([--enable-pgstate-track],
2761                              [enable page state tracking]),
2762               [enable_pgstat_track='yes'],[])
2763 AC_MSG_CHECKING([whether to enable page state tracking])
2764 AC_MSG_RESULT([$enable_pgstat_track])
2765 if test x$enable_pgstat_track = xyes ; then
2766         AC_DEFINE([CONFIG_DEBUG_PAGESTATE_TRACKING], 1,
2767                   [enable page state tracking code])
2768 fi
2769
2770          #2.6.29
2771          LC_WRITE_BEGIN_END
2772          LC_D_OBTAIN_ALIAS
2773          LC_BLKDEV_PUT_2ARGS
2774          LC_DENTRY_OPEN_4ARGS
2775          LC_PAGEVEC_LRU_ADD_FILE
2776
2777 ])
2778
2779 #
2780 # LC_CONDITIONALS
2781 #
2782 # AM_CONDITIONALS for lustre
2783 #
2784 AC_DEFUN([LC_CONDITIONALS],
2785 [AM_CONDITIONAL(LIBLUSTRE, test x$enable_liblustre = xyes)
2786 AM_CONDITIONAL(USE_QUILT, test x$QUILT != xno)
2787 AM_CONDITIONAL(LIBLUSTRE_TESTS, test x$enable_liblustre_tests = xyes)
2788 AM_CONDITIONAL(MPITESTS, test x$enable_mpitests = xyes, Build MPI Tests)
2789 AM_CONDITIONAL(CLIENT, test x$enable_client = xyes)
2790 AM_CONDITIONAL(SERVER, test x$enable_server = xyes)
2791 AM_CONDITIONAL(SPLIT, test x$enable_split = xyes)
2792 AM_CONDITIONAL(BLKID, test x$ac_cv_header_blkid_blkid_h = xyes)
2793 AM_CONDITIONAL(EXT2FS_DEVEL, test x$ac_cv_header_ext2fs_ext2fs_h = xyes)
2794 AM_CONDITIONAL(GSS, test x$enable_gss = xyes)
2795 AM_CONDITIONAL(GSS_KEYRING, test x$enable_gss_keyring = xyes)
2796 AM_CONDITIONAL(GSS_PIPEFS, test x$enable_gss_pipefs = xyes)
2797 AM_CONDITIONAL(LIBPTHREAD, test x$enable_libpthread = xyes)
2798 AM_CONDITIONAL(LLITE_LLOOP, test x$enable_llite_lloop_module = xyes)
2799 ])
2800
2801 #
2802 # LC_CONFIG_FILES
2803 #
2804 # files that should be generated with AC_OUTPUT
2805 #
2806 AC_DEFUN([LC_CONFIG_FILES],
2807 [AC_CONFIG_FILES([
2808 lustre/Makefile
2809 lustre/autoMakefile
2810 lustre/autoconf/Makefile
2811 lustre/conf/Makefile
2812 lustre/contrib/Makefile
2813 lustre/doc/Makefile
2814 lustre/include/Makefile
2815 lustre/include/lustre_ver.h
2816 lustre/include/linux/Makefile
2817 lustre/include/darwin/Makefile
2818 lustre/include/lustre/Makefile
2819 lustre/kernel_patches/targets/2.6-rhel6.target
2820 lustre/kernel_patches/targets/2.6-rhel5.target
2821 lustre/kernel_patches/targets/2.6-sles10.target
2822 lustre/kernel_patches/targets/2.6-sles11.target
2823 lustre/kernel_patches/targets/3.0-sles11.target
2824 lustre/kernel_patches/targets/2.6-oel5.target
2825 lustre/kernel_patches/targets/2.6-fc11.target
2826 lustre/kernel_patches/targets/2.6-fc12.target
2827 lustre/kernel_patches/targets/2.6-fc15.target
2828 lustre/ldlm/Makefile
2829 lustre/fid/Makefile
2830 lustre/fid/autoMakefile
2831 lustre/liblustre/Makefile
2832 lustre/liblustre/tests/Makefile
2833 lustre/liblustre/tests/mpi/Makefile
2834 lustre/llite/Makefile
2835 lustre/llite/autoMakefile
2836 lustre/lclient/Makefile
2837 lustre/lov/Makefile
2838 lustre/lov/autoMakefile
2839 lustre/lvfs/Makefile
2840 lustre/lvfs/autoMakefile
2841 lustre/mdc/Makefile
2842 lustre/mdc/autoMakefile
2843 lustre/lmv/Makefile
2844 lustre/lmv/autoMakefile
2845 lustre/mdt/Makefile
2846 lustre/mdt/autoMakefile
2847 lustre/mdd/Makefile
2848 lustre/mdd/autoMakefile
2849 lustre/fld/Makefile
2850 lustre/fld/autoMakefile
2851 lustre/obdclass/Makefile
2852 lustre/obdclass/autoMakefile
2853 lustre/obdclass/linux/Makefile
2854 lustre/obdecho/Makefile
2855 lustre/obdecho/autoMakefile
2856 lustre/ofd/Makefile
2857 lustre/ofd/autoMakefile
2858 lustre/osc/Makefile
2859 lustre/osc/autoMakefile
2860 lustre/ost/Makefile
2861 lustre/ost/autoMakefile
2862 lustre/osd-ldiskfs/Makefile
2863 lustre/osd-ldiskfs/autoMakefile
2864 lustre/osd-zfs/Makefile
2865 lustre/osd-zfs/autoMakefile
2866 lustre/mgc/Makefile
2867 lustre/mgc/autoMakefile
2868 lustre/mgs/Makefile
2869 lustre/mgs/autoMakefile
2870 lustre/target/Makefile
2871 lustre/ptlrpc/Makefile
2872 lustre/ptlrpc/autoMakefile
2873 lustre/ptlrpc/gss/Makefile
2874 lustre/ptlrpc/gss/autoMakefile
2875 lustre/quota/Makefile
2876 lustre/quota/autoMakefile
2877 lustre/scripts/Makefile
2878 lustre/tests/Makefile
2879 lustre/tests/mpi/Makefile
2880 lustre/utils/Makefile
2881 lustre/utils/gss/Makefile
2882 lustre/osp/Makefile
2883 lustre/osp/autoMakefile
2884 lustre/lod/Makefile
2885 lustre/lod/autoMakefile
2886 lustre/obdclass/darwin/Makefile
2887 ])
2888 ])