lustre/autoconf/kerberos5.m4

   1 dnl Checks for Kerberos
   2 dnl NOTE: while we intend to do generic gss-api, currently we
   3 dnl have a requirement to get an initial Kerberos machine
   4 dnl credential.  Thus, the requirement for Kerberos.
   5 dnl The Kerberos gssapi library will be dynamically loaded?
   6 AC_DEFUN([AC_KERBEROS_V5],[
   7   AC_MSG_CHECKING(for Kerberos v5)
   8   AC_ARG_WITH(krb5,
   9   [AC_HELP_STRING([--with-krb5=DIR], [use Kerberos v5 installation in DIR])],
  10   [ case "$withval" in
  11     yes|no)
  12        krb5_with=""
  13        ;;
  14     *)
  15        krb5_with="$withval"
  16        ;;
  17     esac ]
  18   )
  19
  20   for dir in $krb5_with /usr /usr/kerberos /usr/local /usr/local/krb5 \
  21              /usr/krb5 /usr/heimdal /usr/local/heimdal /usr/athena ; do
  22     dnl This ugly hack brought on by the split installation of
  23     dnl MIT Kerberos on Fedora Core 1
  24     K5CONFIG=""
  25     if test -f $dir/bin/krb5-config; then
  26       K5CONFIG=$dir/bin/krb5-config
  27     elif test -f "/usr/kerberos/bin/krb5-config"; then
  28       K5CONFIG="/usr/kerberos/bin/krb5-config"
  29     elif test -f "/usr/lib/mit/bin/krb5-config"; then
  30       K5CONFIG="/usr/lib/mit/bin/krb5-config"
  31     fi
  32     if test "$K5CONFIG" != ""; then
  33       KRBCFLAGS=`$K5CONFIG --cflags`
  34       KRBLIBS=`$K5CONFIG --libs gssapi`
  35       K5VERS=`$K5CONFIG --version | head -n 1 | awk '{split($(4),v,"."); if (v@<:@"3"@:>@ == "") v@<:@"3"@:>@ = "0"; print v@<:@"1"@:>@v@<:@"2"@:>@v@<:@"3"@:>@ }'`
  36       AC_DEFINE_UNQUOTED(KRB5_VERSION, $K5VERS, [Define this as the Kerberos version number])
  37       if test -f $dir/include/gssapi/gssapi_krb5.h -a \
  38                 \( -f $dir/lib/libgssapi_krb5.a -o \
  39                    -f $dir/lib64/libgssapi_krb5.a -o \
  40                    -f $dir/lib64/libgssapi_krb5.so -o \
  41                    -f $dir/lib/x86_64-linux-gnu/libgssapi_krb5.so -o \
  42                    -f $dir/lib/libgssapi_krb5.so \) ; then
  43          KRBDIR="$dir"
  44   dnl If we are using MIT K5 1.3.1 and before, we *MUST* use the
  45   dnl private function (gss_krb5_ccache_name) to get correct
  46   dnl behavior of changing the ccache used by gssapi.
  47   dnl Starting in 1.3.2, we *DO NOT* want to use
  48   dnl gss_krb5_ccache_name, instead we want to set KRB5CCNAME
  49   dnl to get gssapi to use a different ccache
  50          if test $K5VERS -le 131; then
  51            AC_DEFINE(USE_GSS_KRB5_CCACHE_NAME, 1, [Define this if the private function, gss_krb5_cache_name, must be used to tell the Kerberos library which credentials cache to use. Otherwise, this is done by setting the KRB5CCNAME environment variable])
  52          fi
  53          gssapi_lib=gssapi_krb5
  54          break
  55       dnl The following ugly hack brought on by the split installation
  56       dnl of Heimdal Kerberos on SuSe
  57       elif test \( -f $dir/include/heim_err.h -o\
  58                  -f $dir/include/heimdal/heim_err.h \) -a \
  59                 -f $dir/lib/libroken.a; then
  60          AC_DEFINE(HAVE_HEIMDAL, 1, [Define this if you have Heimdal Kerberos libraries])
  61          KRBDIR="$dir"
  62          gssapi_lib=gssapi
  63         break
  64       fi
  65     fi
  66   done
  67   dnl We didn't find a usable Kerberos environment
  68   if test "x$require_krb5" = "xyes" -a "x$KRBDIR" = "x"; then
  69     if test "x$krb5_with" = "x"; then
  70       AC_MSG_ERROR([
  71
  72 Kerberos v5 with GSS support not found: consider --disable-gss or --with-krb5=
  73 ])
  74     else
  75       AC_MSG_ERROR([
  76
  77 Kerberos v5 with GSS support not found at $krb5_with
  78 ])
  79     fi
  80   fi
  81
  82   if test "x$KRBDIR" != "x"; then
  83
  84     AC_MSG_RESULT($KRBDIR)
  85
  86     dnl Check if -rpath=$(KRBDIR)/lib is needed
  87     echo "The current KRBDIR is $KRBDIR"
  88     if test "$KRBDIR/lib" = "/lib" -o "$KRBDIR/lib" = "/usr/lib" \
  89          -o "$KRBDIR/lib" = "//lib" -o "$KRBDIR/lib" = "/usr//lib" ; then
  90       KRBLDFLAGS="";
  91     elif /sbin/ldconfig -p | grep > /dev/null "=> $KRBDIR/lib/"; then
  92       KRBLDFLAGS="";
  93     else
  94       KRBLDFLAGS="-Wl,-rpath=$KRBDIR/lib"
  95     fi
  96
  97     dnl Now check for functions within gssapi library
  98     AC_CHECK_LIB($gssapi_lib, gss_krb5_export_lucid_sec_context,
  99       AC_DEFINE(HAVE_LUCID_CONTEXT_SUPPORT, 1, [Define this if the Kerberos GSS library supports gss_krb5_export_lucid_sec_context]), ,$KRBLIBS)
 100     AC_CHECK_LIB($gssapi_lib, gss_krb5_set_allowable_enctypes,
 101       AC_DEFINE(HAVE_SET_ALLOWABLE_ENCTYPES, 1, [Define this if the Kerberos GSS library supports gss_krb5_set_allowable_enctypes]), ,$KRBLIBS)
 102     AC_CHECK_LIB($gssapi_lib, gss_krb5_ccache_name,
 103       AC_DEFINE(HAVE_GSS_KRB5_CCACHE_NAME, 1, [Define this if the Kerberos GSS library supports gss_krb5_ccache_name]), ,$KRBLIBS)
 104
 105     dnl Check for newer error message facility
 106     AC_CHECK_LIB($gssapi_lib, krb5_get_error_message,
 107       AC_DEFINE(HAVE_KRB5_GET_ERROR_MESSAGE, 1, [Define this if the function krb5_get_error_message is available]), ,$KRBLIBS)
 108
 109     dnl Check for function to specify addressless tickets
 110     AC_CHECK_LIB($gssapi_lib, krb5_get_init_creds_opt_set_addressless,
 111       AC_DEFINE(HAVE_KRB5_GET_INIT_CREDS_OPT_SET_ADDRESSLESS, 1, [Define this if the function krb5_get_init_creds_opt_set_addressless is available]), ,$KRBLIBS)
 112
 113     dnl Check for krb5int_derive_key
 114     AC_CHECK_LIB($gssapi_lib, krb5int_derive_key,
 115       [HAVE_KRB5INT_DERIVE_KEY=1; AC_DEFINE(HAVE_KRB5INT_DERIVE_KEY, 1, [Define this if the function krb5int_derive_key is available])], ,$KRBLIBS)
 116
 117     dnl Version 1.15 introduced aes-sha2 support, which changes the
 118     dnl number of paramters of function krb5int_derive_key.
 119     if test $K5VERS -ge 1150; then
 120        AC_DEFINE(HAVE_AES_SHA2_SUPPORT, 1,
 121                 [aes-sha2 is supported by krb5])
 122     fi
 123
 124     dnl Check for krb5_derive_key
 125     AC_CHECK_LIB($gssapi_lib, krb5_derive_key,
 126       [HAVE_KRB5_DERIVE_KEY=1; AC_DEFINE(HAVE_KRB5_DERIVE_KEY, 1, [Define this if the function krb5_derive_key is available])], ,$KRBLIBS)
 127
 128     AS_IF([test "x$HAVE_KRB5INT_DERIVE_KEY" = "x1" -o "x$HAVE_KRB5_DERIVE_KEY" = "x1"],
 129           [AC_DEFINE(HAVE_KRB5, 1, [Define this if you have MIT Kerberos libraries])],
 130           [KRBDIR=""; AC_MSG_WARN([
 131
 132 Disable gss/krb5 due to missing both
 133 krb5int_derive_key and krb5_derive_key functions!
 134 ])
 135     ])
 136
 137         dnl Version 1.18 removed support for all DES3 enctypes (des3-cbc-raw,
 138         dnl des3-hmac-sha1, des3-cbc-sha1-kd).
 139         AC_MSG_CHECKING([for DES3 enctype support by krb5])
 140         if test $K5VERS -lt 1180; then
 141                 AC_DEFINE(HAVE_DES3_SUPPORT, 1,
 142                           [DES3 enctype is supported by krb5])
 143                 AC_MSG_RESULT([yes])
 144         else
 145                 AC_MSG_RESULT([no])
 146         fi
 147
 148     dnl If they specified a directory and it didn't work, give them a warning
 149     if test "x$krb5_with" != "x" -a "$krb5_with" != "$KRBDIR"; then
 150       AC_MSG_WARN([
 151
 152 Using $KRBDIR instead of requested value of $krb5_with for Kerberos!
 153 ])
 154     fi
 155
 156     AC_SUBST([KRBDIR])
 157     AC_SUBST([KRBLIBS])
 158     AC_SUBST([KRBCFLAGS])
 159     AC_SUBST([KRBLDFLAGS])
 160     AC_SUBST([K5VERS])
 161
 162   else
 163     AC_MSG_RESULT([not found!])
 164   fi # "x$KRBDIR" != "x"
 165
 166 ])