lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD],
   7 [AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                        [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19         AC_DEFINE_UNQUOTED(LNET_MAX_PAYLOAD, $LNET_MAX_PAYLOAD,
  20                            [Max LNET payload])
  21 ])
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION],
  29 [AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ])
  43
  44 #
  45 # LN_CONFIG_CDEBUG
  46 #
  47 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
  48 #
  49 AC_DEFUN([LN_CONFIG_CDEBUG],
  50 [
  51 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
  52 AC_ARG_ENABLE([libcfs_cdebug],
  53         AC_HELP_STRING([--disable-libcfs-cdebug],
  54                         [disable libcfs CDEBUG, CWARN]),
  55         [],[enable_libcfs_cdebug='yes'])
  56 AC_MSG_RESULT([$enable_libcfs_cdebug])
  57 if test x$enable_libcfs_cdebug = xyes; then
  58    AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])
  59 else
  60    AC_DEFINE(CDEBUG_ENABLED, 0, [disable libcfs CDEBUG, CWARN])
  61 fi
  62
  63 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
  64 AC_ARG_ENABLE([libcfs_trace],
  65         AC_HELP_STRING([--disable-libcfs-trace],
  66                         [disable libcfs ENTRY/EXIT]),
  67         [],[enable_libcfs_trace='yes'])
  68 AC_MSG_RESULT([$enable_libcfs_trace])
  69 if test x$enable_libcfs_trace = xyes; then
  70    AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])
  71 else
  72    AC_DEFINE(CDEBUG_ENTRY_EXIT, 0, [disable libcfs ENTRY/EXIT])
  73 fi
  74
  75 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
  76 AC_ARG_ENABLE([libcfs_assert],
  77         AC_HELP_STRING([--disable-libcfs-assert],
  78                         [disable libcfs LASSERT, LASSERTF]),
  79         [],[enable_libcfs_assert='yes'])
  80 AC_MSG_RESULT([$enable_libcfs_assert])
  81 if test x$enable_libcfs_assert = xyes; then
  82    AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])
  83 fi
  84 ])
  85
  86 #
  87 # LN_CONFIG_AFFINITY
  88 #
  89 # check if cpu affinity is available/wanted
  90 #
  91 AC_DEFUN([LN_CONFIG_AFFINITY],
  92 [AC_ARG_ENABLE([affinity],
  93         AC_HELP_STRING([--disable-affinity],
  94                        [disable process/irq affinity]),
  95         [],[enable_affinity='yes'])
  96
  97 AC_MSG_CHECKING([for CPU affinity support])
  98 if test x$enable_affinity = xno ; then
  99         AC_MSG_RESULT([no (by request)])
 100 else
 101         LB_LINUX_TRY_COMPILE([
 102                 #include <linux/sched.h>
 103         ],[
 104                 struct task_struct t;
 105                 #if HAVE_CPUMASK_T
 106                 cpumask_t     m;
 107                 #else
 108                 unsigned long m;
 109                 #endif
 110                 set_cpus_allowed(&t, m);
 111         ],[
 112                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
 113                 AC_MSG_RESULT([yes])
 114         ],[
 115                 AC_MSG_RESULT([no (no kernel support)])
 116         ])
 117 fi
 118 ])
 119
 120 #
 121 # LN_CONFIG_PORTALS
 122 #
 123 # configure support for Portals
 124 #
 125 AC_DEFUN([LN_CONFIG_PORTALS],
 126 [AC_MSG_CHECKING([for portals])
 127 AC_ARG_WITH([portals],
 128         AC_HELP_STRING([--with-portals=path],
 129                        [set path to portals]),
 130         [
 131                 case $with_portals in
 132                         no)     ENABLEPORTALS=0
 133                                 ;;
 134                         *)      PORTALS="${with_portals}"
 135                                 ENABLEPORTALS=1
 136                                 ;;
 137                 esac
 138         ], [
 139                 ENABLEPORTALS=0
 140         ])
 141 PTLLNDCPPFLAGS=""
 142 if test $ENABLEPORTALS -eq 0; then
 143         AC_MSG_RESULT([no])
 144 elif test ! \( -f ${PORTALS}/include/portals/p30.h \); then
 145         AC_MSG_RESULT([no])
 146         AC_MSG_ERROR([bad --with-portals path])
 147 else
 148         AC_MSG_RESULT([$PORTALS])
 149         PTLLNDCPPFLAGS="-I${PORTALS}/include"
 150 fi
 151 AC_SUBST(PTLLNDCPPFLAGS)
 152 ])
 153
 154 #
 155 # LN_CONFIG_BACKOFF
 156 #
 157 # check if tunable tcp backoff is available/wanted
 158 #
 159 AC_DEFUN([LN_CONFIG_BACKOFF],
 160 [AC_MSG_CHECKING([for tunable backoff TCP support])
 161 AC_ARG_ENABLE([backoff],
 162        AC_HELP_STRING([--disable-backoff],
 163                       [disable socknal tunable backoff]),
 164        [],[enable_backoff='yes'])
 165 if test x$enable_backoff = xno ; then
 166        AC_MSG_RESULT([no (by request)])
 167 else
 168        BOCD="`grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h`"
 169        if test "$BOCD" != 0 ; then
 170                AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
 171                AC_MSG_RESULT(yes)
 172        else
 173                AC_MSG_RESULT([no (no kernel support)])
 174        fi
 175 fi
 176 ])
 177
 178 #
 179 # LN_CONFIG_PANIC_DUMPLOG
 180 #
 181 # check if tunable panic_dumplog is wanted
 182 #
 183 AC_DEFUN([LN_CONFIG_PANIC_DUMPLOG],
 184 [AC_MSG_CHECKING([for tunable panic_dumplog support])
 185 AC_ARG_ENABLE([panic_dumplog],
 186        AC_HELP_STRING([--enable-panic_dumplog],
 187                       [enable panic_dumplog]),
 188        [],[enable_panic_dumplog='no'])
 189 if test x$enable_panic_dumplog = xyes ; then
 190        AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])
 191        AC_MSG_RESULT([yes (by request)])
 192 else
 193        AC_MSG_RESULT([no])
 194 fi
 195 ])
 196
 197 #
 198 # LN_CONFIG_PTLLND
 199 #
 200 # configure support for Portals LND
 201 #
 202 AC_DEFUN([LN_CONFIG_PTLLND],
 203 [
 204 if test -z "$ENABLEPORTALS"; then
 205         LN_CONFIG_PORTALS
 206 fi
 207
 208 AC_MSG_CHECKING([whether to build the kernel portals LND])
 209
 210 PTLLND=""
 211 if test $ENABLEPORTALS -ne 0; then
 212         AC_MSG_RESULT([yes])
 213         PTLLND="ptllnd"
 214 else
 215         AC_MSG_RESULT([no])
 216 fi
 217 AC_SUBST(PTLLND)
 218 ])
 219
 220 #
 221 # LN_CONFIG_UPTLLND
 222 #
 223 # configure support for Portals LND
 224 #
 225 AC_DEFUN([LN_CONFIG_UPTLLND],
 226 [
 227 if test -z "$ENABLEPORTALS"; then
 228         LN_CONFIG_PORTALS
 229 fi
 230
 231 AC_MSG_CHECKING([whether to build the userspace portals LND])
 232
 233 UPTLLND=""
 234 if test $ENABLEPORTALS -ne 0; then
 235         AC_MSG_RESULT([yes])
 236         UPTLLND="ptllnd"
 237 else
 238         AC_MSG_RESULT([no])
 239 fi
 240 AC_SUBST(UPTLLND)
 241 ])
 242
 243 #
 244 # LN_CONFIG_USOCKLND
 245 #
 246 # configure support for userspace TCP/IP LND
 247 #
 248 AC_DEFUN([LN_CONFIG_USOCKLND],
 249 [AC_MSG_CHECKING([whether to build usocklnd])
 250 AC_ARG_ENABLE([usocklnd],
 251         AC_HELP_STRING([--disable-usocklnd],
 252                         [disable usocklnd]),
 253         [],[enable_usocklnd='yes'])
 254
 255 if test x$enable_usocklnd = xyes ; then
 256         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 257                 AC_MSG_RESULT([yes])
 258                 USOCKLND="usocklnd"
 259         else
 260                 AC_MSG_RESULT([no (libpthread not present or disabled)])
 261                 USOCKLND=""
 262         fi
 263 else
 264         AC_MSG_RESULT([no (disabled explicitly)])
 265         USOCKLND=""
 266 fi
 267 AC_SUBST(USOCKLND)
 268 ])
 269
 270 #
 271 # LN_CONFIG_QUADRICS
 272 #
 273 # check if quadrics support is in this kernel
 274 #
 275 AC_DEFUN([LN_CONFIG_QUADRICS],
 276 [AC_MSG_CHECKING([for QsNet sources])
 277 AC_ARG_WITH([qsnet],
 278         AC_HELP_STRING([--with-qsnet=path],
 279                        [set path to qsnet source (default=$LINUX)]),
 280         [QSNET=$with_qsnet],
 281         [QSNET=$LINUX])
 282 AC_MSG_RESULT([$QSNET])
 283
 284 AC_MSG_CHECKING([if quadrics kernel headers are present])
 285 if test -d $QSNET/drivers/net/qsnet ; then
 286         AC_MSG_RESULT([yes])
 287         QSWLND="qswlnd"
 288         AC_MSG_CHECKING([for multirail EKC])
 289         if test -f $QSNET/include/elan/epcomms.h; then
 290                 AC_MSG_RESULT([supported])
 291                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 292         else
 293                 AC_MSG_RESULT([not supported])
 294                 AC_MSG_ERROR([Need multirail EKC])
 295         fi
 296
 297         if test x$QSNET = x$LINUX ; then
 298                 LB_LINUX_CONFIG([QSNET],[],[
 299                         LB_LINUX_CONFIG([QSNET_MODULE],[],[
 300                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
 301                                 QSWLND=""
 302                                 QSWCPPFLAGS=""
 303                         ])
 304                 ])
 305         fi
 306 else
 307         AC_MSG_RESULT([no])
 308         QSWLND=""
 309         QSWCPPFLAGS=""
 310 fi
 311 AC_SUBST(QSWCPPFLAGS)
 312 AC_SUBST(QSWLND)
 313 ])
 314
 315 #
 316 # LN_CONFIG_GM
 317 #
 318 # check if GM support is available
 319 #
 320 AC_DEFUN([LN_CONFIG_GM],[
 321 AC_MSG_CHECKING([whether to enable GM support])
 322 AC_ARG_WITH([gm],
 323         AC_HELP_STRING([--with-gm=path-to-gm-source-tree],
 324                        [build gmlnd against path]),
 325         [
 326                 case $with_gm in
 327                 no)    ENABLE_GM=0
 328                        ;;
 329                 *)     ENABLE_GM=1
 330                        GM_SRC="$with_gm"
 331                        ;;
 332                 esac
 333         ],[
 334                 ENABLE_GM=0
 335         ])
 336 AC_ARG_WITH([gm-install],
 337         AC_HELP_STRING([--with-gm-install=path-to-gm-install-tree],
 338                        [say where GM has been installed]),
 339         [
 340                 GM_INSTALL=$with_gm_install
 341         ],[
 342                 GM_INSTALL="/opt/gm"
 343         ])
 344 if test $ENABLE_GM -eq 0; then
 345         AC_MSG_RESULT([no])
 346 else
 347         AC_MSG_RESULT([yes])
 348
 349         GMLND="gmlnd"
 350         GMCPPFLAGS="-I$GM_SRC/include -I$GM_SRC/drivers -I$GM_SRC/drivers/linux/gm"
 351
 352         if test -f $GM_INSTALL/lib/libgm.a -o \
 353                 -f $GM_INSTALL/lib64/libgm.a; then
 354                 GMLIBS="-L$GM_INSTALL/lib -L$GM_INSTALL/lib64"
 355         else
 356                 AC_MSG_ERROR([Cant find GM libraries under $GM_INSTALL])
 357         fi
 358
 359         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 360         EXTRA_KCFLAGS="$GMCPPFLAGS -DGM_KERNEL $EXTRA_KCFLAGS"
 361
 362         AC_MSG_CHECKING([that code using GM compiles with given path])
 363         LB_LINUX_TRY_COMPILE([
 364                 #define GM_STRONG_TYPES 1
 365                 #ifdef VERSION
 366                 #undef VERSION
 367                 #endif
 368                 #include "gm.h"
 369                 #include "gm_internal.h"
 370         ],[
 371                 struct gm_port *port = NULL;
 372                 gm_recv_event_t *rxevent = gm_blocking_receive_no_spin(port);
 373                 return 0;
 374         ],[
 375                 AC_MSG_RESULT([yes])
 376         ],[
 377                 AC_MSG_RESULT([no])
 378                 AC_MSG_ERROR([Bad --with-gm path])
 379         ])
 380
 381         AC_MSG_CHECKING([that GM has gm_register_memory_ex_phys()])
 382         LB_LINUX_TRY_COMPILE([
 383                 #define GM_STRONG_TYPES 1
 384                 #ifdef VERSION
 385                 #undef VERSION
 386                 #endif
 387                 #include "gm.h"
 388                 #include "gm_internal.h"
 389         ],[
 390                 gm_status_t     gmrc;
 391                 struct gm_port *port = NULL;
 392                 gm_u64_t        phys = 0;
 393                 gm_up_t         pvma = 0;
 394
 395                 gmrc = gm_register_memory_ex_phys(port, phys, 100, pvma);
 396                 return 0;
 397         ],[
 398                 AC_MSG_RESULT([yes])
 399         ],[
 400                 AC_MSG_RESULT([no.
 401 Please patch the GM sources as follows...
 402     cd $GM_SRC
 403     patch -p0 < $PWD/lnet/klnds/gmlnd/gm-reg-phys.patch
 404 ...then rebuild and re-install them])
 405                 AC_MSG_ERROR([Can't build GM without gm_register_memory_ex_phys()])
 406         ])
 407
 408         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 409 fi
 410 AC_SUBST(GMCPPFLAGS)
 411 AC_SUBST(GMLIBS)
 412 AC_SUBST(GMLND)
 413 ])
 414
 415
 416 #
 417 # LN_CONFIG_MX
 418 #
 419 AC_DEFUN([LN_CONFIG_MX],
 420 [AC_MSG_CHECKING([whether to enable Myrinet MX support])
 421 # set default
 422 MXPATH="/opt/mx"
 423 AC_ARG_WITH([mx],
 424        AC_HELP_STRING([--with-mx=path],
 425                       [build mxlnd against path]),
 426        [
 427                case $with_mx in
 428                yes)    ENABLEMX=2
 429                        ;;
 430                no)     ENABLEMX=0
 431                        ;;
 432                *)      MXPATH=$with_mx
 433                        ENABLEMX=3
 434                        ;;
 435                esac
 436        ],[
 437                ENABLEMX=1
 438        ])
 439 if test $ENABLEMX -eq 0; then
 440        AC_MSG_RESULT([disabled])
 441 elif test ! \( -f ${MXPATH}/include/myriexpress.h -a \
 442               -f ${MXPATH}/include/mx_kernel_api.h -a \
 443               -f ${MXPATH}/include/mx_pin.h \); then
 444        AC_MSG_RESULT([no])
 445        case $ENABLEMX in
 446        1) ;;
 447        2) AC_MSG_ERROR([Myrinet MX kernel headers not present]);;
 448        3) AC_MSG_ERROR([bad --with-mx path]);;
 449        *) AC_MSG_ERROR([internal error]);;
 450        esac
 451 else
 452        MXCPPFLAGS="-I$MXPATH/include"
 453        EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 454        EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
 455        MXLIBS="-L$MXPATH/lib"
 456        LB_LINUX_TRY_COMPILE([
 457                #define MX_KERNEL 1
 458                #include <mx_extensions.h>
 459                #include <myriexpress.h>
 460        ],[
 461                mx_endpoint_t   end;
 462                mx_status_t     status;
 463                mx_request_t    request;
 464                int             result;
 465
 466                mx_init();
 467                mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
 468                mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
 469                mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
 470                mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
 471                return 0;
 472        ],[
 473                AC_MSG_RESULT([yes])
 474                MXLND="mxlnd"
 475        ],[
 476                AC_MSG_RESULT([no])
 477                case $ENABLEMX in
 478                1) ;;
 479                2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]);;
 480                3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]);;
 481                *) AC_MSG_ERROR([internal error]);;
 482                esac
 483                MXLND=""
 484                MXCPPFLAGS=""
 485        ])
 486        EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 487 fi
 488 AC_SUBST(MXCPPFLAGS)
 489 AC_SUBST(MXLIBS)
 490 AC_SUBST(MXLND)
 491 ])
 492
 493
 494
 495 #
 496 # LN_CONFIG_O2IB
 497 #
 498 AC_DEFUN([LN_CONFIG_O2IB],[
 499 AC_MSG_CHECKING([whether to enable OpenIB gen2 support])
 500 # set default
 501 O2IBPATH="$LINUX/drivers/infiniband"
 502 AC_ARG_WITH([o2ib],
 503         AC_HELP_STRING([--with-o2ib=path],
 504                        [build o2iblnd against path]),
 505         [
 506                 case $with_o2ib in
 507                 yes)    ENABLEO2IB=2
 508                         ;;
 509                 no)     ENABLEO2IB=0
 510                         ;;
 511                 *)      O2IBPATH=$with_o2ib
 512                         ENABLEO2IB=3
 513                         ;;
 514                 esac
 515         ],[
 516                 ENABLEO2IB=1
 517         ])
 518 if test $ENABLEO2IB -eq 0; then
 519         AC_MSG_RESULT([disabled])
 520 elif test ! \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 521                -f ${O2IBPATH}/include/rdma/ib_cm.h -a\
 522                -f ${O2IBPATH}/include/rdma/ib_verbs.h -a\
 523                -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 524         AC_MSG_RESULT([no])
 525         case $ENABLEO2IB in
 526         1) ;;
 527         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 528         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 529         *) AC_MSG_ERROR([internal error]);;
 530         esac
 531 else
 532         O2IBCPPFLAGS="-I$O2IBPATH/include"
 533         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 534         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $O2IBCPPFLAGS"
 535         EXTRA_LNET_INCLUDE="$O2IBCPPFLAGS $EXTRA_LNET_INCLUDE"
 536         LB_LINUX_TRY_COMPILE([
 537                 #include <linux/version.h>
 538                 #include <linux/pci.h>
 539                 #if !HAVE_GFP_T
 540                 typedef int gfp_t;
 541                 #endif
 542                 #include <rdma/rdma_cm.h>
 543                 #include <rdma/ib_cm.h>
 544                 #include <rdma/ib_verbs.h>
 545                 #include <rdma/ib_fmr_pool.h>
 546         ],[
 547                 struct rdma_cm_id          *cm_id;
 548                 struct rdma_conn_param      conn_param;
 549                 struct ib_device_attr       device_attr;
 550                 struct ib_qp_attr           qp_attr;
 551                 struct ib_pool_fmr          pool_fmr;
 552                 enum   ib_cm_rej_reason     rej_reason;
 553
 554                 cm_id = rdma_create_id(NULL, NULL, RDMA_PS_TCP);
 555                 return PTR_ERR(cm_id);
 556         ],[
 557                 AC_MSG_RESULT([yes])
 558                 O2IBLND="o2iblnd"
 559         ],[
 560                 AC_MSG_RESULT([no])
 561                 case $ENABLEO2IB in
 562                 1) ;;
 563                 2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]);;
 564                 3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]);;
 565                 *) AC_MSG_ERROR([internal error]);;
 566                 esac
 567                 O2IBLND=""
 568                 O2IBCPPFLAGS=""
 569         ])
 570
 571 # version checking is a hack and isn't reliable, we need verify it
 572 # with each new ofed release
 573
 574         IB_DMA_MAP="`grep -c ib_dma_map_single ${O2IBPATH}/include/rdma/ib_verbs.h`"
 575         if test "$IB_DMA_MAP" != 0 ; then
 576                 IB_COMP_VECT="`grep -c comp_vector ${O2IBPATH}/include/rdma/ib_verbs.h`"
 577                 if test "$IB_COMP_VECT" != 0 ; then
 578                         IBLND_OFED_VERSION="1025"
 579                 else
 580                         IBLND_OFED_VERSION="1020"
 581                 fi
 582         else
 583                 IBLND_OFED_VERSION="1010"
 584         fi
 585
 586         AC_DEFINE_UNQUOTED(IBLND_OFED_VERSION, $IBLND_OFED_VERSION,
 587                            [OFED version])
 588
 589         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 590 fi
 591
 592 AC_SUBST(EXTRA_LNET_INCLUDE)
 593 AC_SUBST(O2IBCPPFLAGS)
 594 AC_SUBST(O2IBLND)
 595 ])
 596
 597 #
 598 # LN_CONFIG_OPENIB
 599 #
 600 # check for OpenIB in the kernel
 601 AC_DEFUN([LN_CONFIG_OPENIB],[
 602 AC_MSG_CHECKING([whether to enable OpenIB support])
 603 # set default
 604 OPENIBPATH="$LINUX/drivers/infiniband"
 605 AC_ARG_WITH([openib],
 606         AC_HELP_STRING([--with-openib=path],
 607                        [build openiblnd against path]),
 608         [
 609                 case $with_openib in
 610                 yes)    ENABLEOPENIB=2
 611                         ;;
 612                 no)     ENABLEOPENIB=0
 613                         ;;
 614                 *)      OPENIBPATH="$with_openib"
 615                         ENABLEOPENIB=3
 616                         ;;
 617                 esac
 618         ],[
 619                 ENABLEOPENIB=1
 620         ])
 621 if test $ENABLEOPENIB -eq 0; then
 622         AC_MSG_RESULT([disabled])
 623 elif test ! \( -f ${OPENIBPATH}/include/ts_ib_core.h -a \
 624                -f ${OPENIBPATH}/include/ts_ib_cm.h -a\
 625                -f ${OPENIBPATH}/include/ts_ib_sa_client.h \); then
 626         AC_MSG_RESULT([no])
 627         case $ENABLEOPENIB in
 628         1) ;;
 629         2) AC_MSG_ERROR([kernel OpenIB headers not present]);;
 630         3) AC_MSG_ERROR([bad --with-openib path]);;
 631         *) AC_MSG_ERROR([internal error]);;
 632         esac
 633 else
 634         case $ENABLEOPENIB in
 635         1|2) OPENIBCPPFLAGS="-I$OPENIBPATH/include -DIN_TREE_BUILD";;
 636         3)   OPENIBCPPFLAGS="-I$OPENIBPATH/include";;
 637         *)   AC_MSG_RESULT([no])
 638              AC_MSG_ERROR([internal error]);;
 639         esac
 640         OPENIBCPPFLAGS="$OPENIBCPPFLAGS -DIB_NTXRXPARAMS=4"
 641         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 642         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $OPENIBCPPFLAGS"
 643         LB_LINUX_TRY_COMPILE([
 644                 #include <ts_ib_core.h>
 645                 #include <ts_ib_cm.h>
 646                 #include <ts_ib_sa_client.h>
 647         ],[
 648                 struct ib_device_properties dev_props;
 649                 struct ib_cm_active_param   cm_active_params;
 650                 tTS_IB_CLIENT_QUERY_TID     tid;
 651                 int                         enum1 = IB_QP_ATTRIBUTE_STATE;
 652                 int                         enum2 = IB_ACCESS_LOCAL_WRITE;
 653                 int                         enum3 = IB_CQ_CALLBACK_INTERRUPT;
 654                 int                         enum4 = IB_CQ_PROVIDER_REARM;
 655                 return 0;
 656         ],[
 657                 AC_MSG_RESULT([yes])
 658                 OPENIBLND="openiblnd"
 659         ],[
 660                 AC_MSG_RESULT([no])
 661                 case $ENABLEOPENIB in
 662                 1) ;;
 663                 2) AC_MSG_ERROR([can't compile with kernel OpenIB headers]);;
 664                 3) AC_MSG_ERROR([can't compile with OpenIB headers under $OPENIBPATH]);;
 665                 *) AC_MSG_ERROR([internal error]);;
 666                 esac
 667                 OPENIBLND=""
 668                 OPENIBCPPFLAGS=""
 669         ])
 670         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 671 fi
 672 AC_SUBST(OPENIBCPPFLAGS)
 673 AC_SUBST(OPENIBLND)
 674 ])
 675
 676 #
 677 # LN_CONFIG_CIBLND
 678 #
 679 AC_DEFUN([LN_CONFIG_CIB],[
 680 AC_MSG_CHECKING([whether to enable Cisco/TopSpin IB support])
 681 # set default
 682 CIBPATH=""
 683 CIBLND=""
 684 AC_ARG_WITH([cib],
 685         AC_HELP_STRING([--with-cib=path],
 686                        [build ciblnd against path]),
 687         [
 688                 case $with_cib in
 689                 no)     AC_MSG_RESULT([no]);;
 690                 *)      CIBPATH="$with_cib"
 691                         if test -d "$CIBPATH"; then
 692                                 AC_MSG_RESULT([yes])
 693                         else
 694                                 AC_MSG_RESULT([no])
 695                                 AC_MSG_ERROR([No directory $CIBPATH])
 696                         fi;;
 697                 esac
 698         ],[
 699                 AC_MSG_RESULT([no])
 700         ])
 701 if test -n "$CIBPATH"; then
 702         CIBCPPFLAGS="-I${CIBPATH}/ib/ts_api_ng/include -I${CIBPATH}/all/kernel_services/include -DUSING_TSAPI"
 703         CIBCPPFLAGS="$CIBCPPFLAGS -DIB_NTXRXPARAMS=3"
 704         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 705         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $CIBCPPFLAGS"
 706         LB_LINUX_TRY_COMPILE([
 707                 #include <ts_ib_core.h>
 708                 #include <ts_ib_cm.h>
 709                 #include <ts_ib_sa_client.h>
 710         ],[
 711                 struct ib_device_properties dev_props;
 712                 struct ib_cm_active_param   cm_active_params;
 713                 tTS_IB_CLIENT_QUERY_TID     tid;
 714                 int                         enum1 = TS_IB_QP_ATTRIBUTE_STATE;
 715                 int                         enum2 = TS_IB_ACCESS_LOCAL_WRITE;
 716                 int                         enum3 = TS_IB_CQ_CALLBACK_INTERRUPT;
 717                 int                         enum4 = TS_IB_CQ_PROVIDER_REARM;
 718                 return 0;
 719         ],[
 720                 CIBLND="ciblnd"
 721         ],[
 722                 AC_MSG_ERROR([can't compile ciblnd with given path])
 723                 CIBCPPFLAGS=""
 724         ])
 725         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 726 fi
 727 AC_SUBST(CIBCPPFLAGS)
 728 AC_SUBST(CIBLND)
 729 ])
 730
 731 #
 732 # LN_CONFIG_IIB
 733 #
 734 # check for infinicon infiniband support
 735 #
 736 AC_DEFUN([LN_CONFIG_IIB],[
 737 AC_MSG_CHECKING([whether to enable Infinicon support])
 738 # set default
 739 IIBPATH="/usr/include"
 740 AC_ARG_WITH([iib],
 741         AC_HELP_STRING([--with-iib=path],
 742                        [build iiblnd against path]),
 743         [
 744                 case $with_iib in
 745                 yes)    ENABLEIIB=2
 746                         ;;
 747                 no)     ENABLEIIB=0
 748                         ;;
 749                 *)      IIBPATH="${with_iib}/include"
 750                         ENABLEIIB=3
 751                         ;;
 752                 esac
 753         ],[
 754                 ENABLEIIB=1
 755         ])
 756 if test $ENABLEIIB -eq 0; then
 757         AC_MSG_RESULT([disabled])
 758 elif test ! \( -f ${IIBPATH}/linux/iba/ibt.h \); then
 759         AC_MSG_RESULT([no])
 760         case $ENABLEIIB in
 761         1) ;;
 762         2) AC_MSG_ERROR([default Infinicon headers not present]);;
 763         3) AC_MSG_ERROR([bad --with-iib path]);;
 764         *) AC_MSG_ERROR([internal error]);;
 765         esac
 766 else
 767         IIBCPPFLAGS="-I$IIBPATH"
 768         if test $IIBPATH != "/usr/include"; then
 769                 # we need /usr/include come what may
 770                 IIBCPPFLAGS="$IIBCPPFLAGS -I/usr/include"
 771         fi
 772         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 773         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $IIBCPPFLAGS"
 774         LB_LINUX_TRY_COMPILE([
 775                 #include <linux/iba/ibt.h>
 776         ],[
 777                 IBT_INTERFACE_UNION interfaces;
 778                 FSTATUS             rc;
 779
 780                  rc = IbtGetInterfaceByVersion(IBT_INTERFACE_VERSION_2,
 781                                                &interfaces);
 782
 783                 return rc == FSUCCESS ? 0 : 1;
 784         ],[
 785                 AC_MSG_RESULT([yes])
 786                 IIBLND="iiblnd"
 787         ],[
 788                 AC_MSG_RESULT([no])
 789                 case $ENABLEIIB in
 790                 1) ;;
 791                 2) AC_MSG_ERROR([can't compile with default Infinicon headers]);;
 792                 3) AC_MSG_ERROR([can't compile with Infinicon headers under $IIBPATH]);;
 793                 *) AC_MSG_ERROR([internal error]);;
 794                 esac
 795                 IIBLND=""
 796                 IIBCPPFLAGS=""
 797         ])
 798         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 799 fi
 800 AC_SUBST(IIBCPPFLAGS)
 801 AC_SUBST(IIBLND)
 802 ])
 803
 804 #
 805 # LN_CONFIG_VIB
 806 #
 807 # check for Voltaire infiniband support
 808 #
 809 AC_DEFUN([LN_CONFIG_VIB],
 810 [AC_MSG_CHECKING([whether to enable Voltaire IB support])
 811 VIBPATH=""
 812 AC_ARG_WITH([vib],
 813         AC_HELP_STRING([--with-vib=path],
 814                        [build viblnd against path]),
 815         [
 816                 case $with_vib in
 817                 no)     AC_MSG_RESULT([no]);;
 818                 *)      VIBPATH="${with_vib}/src/nvigor/ib-code"
 819                         if test -d "$with_vib" -a -d "$VIBPATH"; then
 820                                 AC_MSG_RESULT([yes])
 821                         else
 822                                 AC_MSG_RESULT([no])
 823                                 AC_MSG_ERROR([No directory $VIBPATH])
 824                         fi;;
 825                 esac
 826         ],[
 827                 AC_MSG_RESULT([no])
 828         ])
 829 if test -z "$VIBPATH"; then
 830         VIBLND=""
 831 else
 832         VIBCPPFLAGS="-I${VIBPATH}/include -I${VIBPATH}/cm"
 833         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 834         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 835         LB_LINUX_TRY_COMPILE([
 836                 #include <linux/list.h>
 837                 #include <asm/byteorder.h>
 838                 #ifdef __BIG_ENDIAN
 839                 # define CPU_BE 1
 840                 # define CPU_LE 0
 841                 #endif
 842                 #ifdef __LITTLE_ENDIAN
 843                 # define CPU_BE 0
 844                 # define CPU_LE 1
 845                 #endif
 846                 #include <vverbs.h>
 847                 #include <ib-cm.h>
 848                 #include <ibat.h>
 849         ],[
 850                 vv_hca_h_t       kib_hca;
 851                 vv_return_t      vvrc;
 852                 cm_cep_handle_t  cep;
 853                 ibat_arp_data_t  arp_data;
 854                 ibat_stat_t      ibatrc;
 855
 856                 vvrc = vv_hca_open("ANY_HCA", NULL, &kib_hca);
 857                 cep = cm_create_cep(cm_cep_transp_rc);
 858                 ibatrc = ibat_get_ib_data((uint32_t)0, (uint32_t)0,
 859                                           ibat_paths_primary, &arp_data,
 860                                           (ibat_get_ib_data_reply_fn_t)NULL,
 861                                           NULL, 0);
 862                 return 0;
 863         ],[
 864                 VIBLND="viblnd"
 865         ],[
 866                 AC_MSG_ERROR([can't compile viblnd with given path])
 867         ])
 868         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 869 fi
 870 if test -n "$VIBLND"; then
 871         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 872         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 873         AC_MSG_CHECKING([if Voltaire still uses void * sg addresses])
 874         LB_LINUX_TRY_COMPILE([
 875                 #include <linux/list.h>
 876                 #include <asm/byteorder.h>
 877                 #ifdef __BIG_ENDIAN
 878                 # define CPU_BE 1
 879                 # define CPU_LE 0
 880                 #endif
 881                 #ifdef __LITTLE_ENDIAN
 882                 # define CPU_BE 0
 883                 # define CPU_LE 1
 884                 #endif
 885                 #include <vverbs.h>
 886                 #include <ib-cm.h>
 887                 #include <ibat.h>
 888         ],[
 889                 vv_scatgat_t  sg;
 890
 891                 return &sg.v_address[3] == NULL;
 892         ],[
 893                 AC_MSG_RESULT([yes])
 894                 VIBCPPFLAGS="$VIBCPPFLAGS -DIBNAL_VOIDSTAR_SGADDR=1"
 895         ],[
 896                 AC_MSG_RESULT([no])
 897         ])
 898         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 899 fi
 900 AC_SUBST(VIBCPPFLAGS)
 901 AC_SUBST(VIBLND)
 902 ])
 903
 904 #
 905 # LN_CONFIG_RALND
 906 #
 907 # check whether to use the RapidArray lnd
 908 #
 909 AC_DEFUN([LN_CONFIG_RALND],
 910 [#### Rapid Array
 911 AC_MSG_CHECKING([if RapidArray kernel headers are present])
 912 # placeholder
 913 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 914 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 915 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 916 LB_LINUX_TRY_COMPILE([
 917         #include <linux/types.h>
 918         #include <rapl.h>
 919 ],[
 920         RAP_RETURN          rc;
 921         RAP_PVOID           dev_handle;
 922
 923         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 924
 925         return rc == RAP_SUCCESS ? 0 : 1;
 926 ],[
 927         AC_MSG_RESULT([yes])
 928         RALND="ralnd"
 929 ],[
 930         AC_MSG_RESULT([no])
 931         RALND=""
 932         RACPPFLAGS=""
 933 ])
 934 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 935 AC_SUBST(RACPPFLAGS)
 936 AC_SUBST(RALND)
 937 ])
 938
 939 #
 940 # LN_STRUCT_PAGE_LIST
 941 #
 942 # 2.6.4 no longer has page->list
 943 #
 944 AC_DEFUN([LN_STRUCT_PAGE_LIST],
 945 [AC_MSG_CHECKING([if struct page has a list field])
 946 LB_LINUX_TRY_COMPILE([
 947         #include <linux/mm.h>
 948 ],[
 949         struct page page;
 950         &page.list;
 951 ],[
 952         AC_MSG_RESULT([yes])
 953         AC_DEFINE(HAVE_PAGE_LIST, 1, [struct page has a list field])
 954 ],[
 955         AC_MSG_RESULT([no])
 956 ])
 957 ])
 958
 959 #
 960 # LN_STRUCT_SIGHAND
 961 #
 962 # red hat 2.4 adds sighand to struct task_struct
 963 #
 964 AC_DEFUN([LN_STRUCT_SIGHAND],
 965 [AC_MSG_CHECKING([if task_struct has a sighand field])
 966 LB_LINUX_TRY_COMPILE([
 967         #include <linux/sched.h>
 968 ],[
 969         struct task_struct p;
 970         p.sighand = NULL;
 971 ],[
 972         AC_DEFINE(CONFIG_RH_2_4_20, 1, [this kernel contains Red Hat 2.4.20 patches])
 973         AC_MSG_RESULT([yes])
 974 ],[
 975         AC_MSG_RESULT([no])
 976 ])
 977 ])
 978
 979 #
 980 # LN_FUNC_CPU_ONLINE
 981 #
 982 # cpu_online is different in rh 2.4, vanilla 2.4, and 2.6
 983 #
 984 AC_DEFUN([LN_FUNC_CPU_ONLINE],
 985 [AC_MSG_CHECKING([if kernel defines cpu_online()])
 986 LB_LINUX_TRY_COMPILE([
 987         #include <linux/sched.h>
 988 ],[
 989         cpu_online(0);
 990 ],[
 991         AC_MSG_RESULT([yes])
 992         AC_DEFINE(HAVE_CPU_ONLINE, 1, [cpu_online found])
 993 ],[
 994         AC_MSG_RESULT([no])
 995 ])
 996 ])
 997
 998 #
 999 # LN_TYPE_GFP_T
1000 #
1001 # check if gfp_t is typedef-ed
1002 #
1003 AC_DEFUN([LN_TYPE_GFP_T],
1004 [AC_MSG_CHECKING([if kernel defines gfp_t])
1005 LB_LINUX_TRY_COMPILE([
1006         #include <linux/gfp.h>
1007 ],[
1008         return sizeof(gfp_t);
1009 ],[
1010         AC_MSG_RESULT([yes])
1011         AC_DEFINE(HAVE_GFP_T, 1, [gfp_t found])
1012 ],[
1013         AC_MSG_RESULT([no])
1014 ])
1015 ])
1016
1017 #
1018 # LN_TYPE_CPUMASK_T
1019 #
1020 # same goes for cpumask_t
1021 #
1022 AC_DEFUN([LN_TYPE_CPUMASK_T],
1023 [AC_MSG_CHECKING([if kernel defines cpumask_t])
1024 LB_LINUX_TRY_COMPILE([
1025         #include <linux/sched.h>
1026 ],[
1027         return sizeof (cpumask_t);
1028 ],[
1029         AC_MSG_RESULT([yes])
1030         AC_DEFINE(HAVE_CPUMASK_T, 1, [cpumask_t found])
1031 ],[
1032         AC_MSG_RESULT([no])
1033 ])
1034 ])
1035
1036 #
1037 # LN_FUNC_SHOW_TASK
1038 #
1039 # we export show_task(), but not all kernels have it (yet)
1040 #
1041 AC_DEFUN([LN_FUNC_SHOW_TASK],
1042 [LB_CHECK_SYMBOL_EXPORT([show_task],
1043 [kernel/ksyms.c kernel/sched.c],[
1044 AC_DEFINE(HAVE_SHOW_TASK, 1, [show_task is exported])
1045 ],[
1046 ])
1047 ])
1048
1049 # LN_TASKLIST_LOCK
1050 # 2.6.18 remove tasklist_lock export
1051 AC_DEFUN([LN_TASKLIST_LOCK],
1052 [LB_CHECK_SYMBOL_EXPORT([tasklist_lock],
1053 [kernel/fork.c],[
1054 AC_DEFINE(HAVE_TASKLIST_LOCK, 1,
1055          [tasklist_lock exported])
1056 ],[
1057 ])
1058 ])
1059
1060 # 2.6.19 API changes
1061 # kmem_cache_destroy(cachep) return void instead of
1062 # int
1063 AC_DEFUN([LN_KMEM_CACHE_DESTROY_INT],
1064 [AC_MSG_CHECKING([kmem_cache_destroy(cachep) return int])
1065 LB_LINUX_TRY_COMPILE([
1066         #include <linux/slab.h>
1067 ],[
1068         int i = kmem_cache_destroy(NULL);
1069 ],[
1070         AC_MSG_RESULT(yes)
1071         AC_DEFINE(HAVE_KMEM_CACHE_DESTROY_INT, 1,
1072                 [kmem_cache_destroy(cachep) return int])
1073 ],[
1074         AC_MSG_RESULT(NO)
1075 ])
1076 ])
1077
1078 # 2.6.19 API change
1079 #panic_notifier_list use atomic_notifier operations
1080 #
1081 AC_DEFUN([LN_ATOMIC_PANIC_NOTIFIER],
1082 [AC_MSG_CHECKING([panic_notifier_list is atomic])
1083 LB_LINUX_TRY_COMPILE([
1084         #include <linux/notifier.h>
1085         #include <linux/kernel.h>
1086 ],[
1087         struct atomic_notifier_head panic_notifier_list;
1088 ],[
1089         AC_MSG_RESULT(yes)
1090         AC_DEFINE(HAVE_ATOMIC_PANIC_NOTIFIER, 1,
1091                 [panic_notifier_list is atomic_notifier_head])
1092 ],[
1093         AC_MSG_RESULT(NO)
1094 ])
1095 ])
1096
1097 # 2.6.20 API change INIT_WORK use 2 args and not
1098 # store data inside
1099 AC_DEFUN([LN_3ARGS_INIT_WORK],
1100 [AC_MSG_CHECKING([check INIT_WORK want 3 args])
1101 LB_LINUX_TRY_COMPILE([
1102         #include <linux/workqueue.h>
1103 ],[
1104         struct work_struct work;
1105
1106         INIT_WORK(&work, NULL, NULL);
1107 ],[
1108         AC_MSG_RESULT(yes)
1109         AC_DEFINE(HAVE_3ARGS_INIT_WORK, 1,
1110                   [INIT_WORK use 3 args and store data inside])
1111 ],[
1112         AC_MSG_RESULT(NO)
1113 ])
1114 ])
1115
1116 # 2.6.21 api change. 'register_sysctl_table' use only one argument,
1117 # instead of more old which need two.
1118 AC_DEFUN([LN_2ARGS_REGISTER_SYSCTL],
1119 [AC_MSG_CHECKING([check register_sysctl_table want 2 args])
1120 LB_LINUX_TRY_COMPILE([
1121         #include <linux/sysctl.h>
1122 ],[
1123         return register_sysctl_table(NULL,0);
1124 ],[
1125         AC_MSG_RESULT(yes)
1126         AC_DEFINE(HAVE_2ARGS_REGISTER_SYSCTL, 1,
1127                   [register_sysctl_table want 2 args])
1128 ],[
1129         AC_MSG_RESULT(NO)
1130 ])
1131 ])
1132
1133 # 2.6.21 marks kmem_cache_t deprecated and uses struct kmem_cache
1134 # instead
1135 AC_DEFUN([LN_KMEM_CACHE],
1136 [AC_MSG_CHECKING([check kernel has struct kmem_cache])
1137 tmp_flags="$EXTRA_KCFLAGS"
1138 EXTRA_KCFLAGS="-Werror"
1139 LB_LINUX_TRY_COMPILE([
1140         #include <linux/slab.h>
1141         typedef struct kmem_cache cache_t;
1142 ],[
1143         cache_t *cachep = NULL;
1144
1145         kmem_cache_alloc(cachep, 0);
1146 ],[
1147         AC_MSG_RESULT(yes)
1148         AC_DEFINE(HAVE_KMEM_CACHE, 1,
1149                   [kernel has struct kmem_cache])
1150 ],[
1151         AC_MSG_RESULT(NO)
1152 ])
1153 EXTRA_KCFLAGS="$tmp_flags"
1154 ])
1155 # 2.6.23 lost dtor argument
1156 AC_DEFUN([LN_KMEM_CACHE_CREATE_DTOR],
1157 [AC_MSG_CHECKING([check kmem_cache_create has dtor argument])
1158 LB_LINUX_TRY_COMPILE([
1159         #include <linux/slab.h>
1160 ],[
1161         kmem_cache_create(NULL, 0, 0, 0, NULL, NULL);
1162 ],[
1163         AC_MSG_RESULT(yes)
1164         AC_DEFINE(HAVE_KMEM_CACHE_CREATE_DTOR, 1,
1165                   [kmem_cache_create has dtor argument])
1166 ],[
1167         AC_MSG_RESULT(NO)
1168 ])
1169 ])
1170
1171 # asm/segment.h does not exist on all architectures.
1172 # e.g. the file is empty for ia64 and does not exist for PPC.
1173 AC_DEFUN([LC_SEGMENT_H],
1174          [LB_CHECK_FILE([$LINUX/include/asm/segment.h],
1175                         [AC_MSG_CHECKING([if asm/segment.h is present])
1176                          LB_LINUX_TRY_COMPILE([#include <asm/segment.h>], [],
1177                                               [AC_MSG_RESULT([yes])
1178                                                AC_DEFINE(HAVE_SEGMENT_H, 1,
1179                                                          [asm/segment.h exists])],
1180                                               [AC_MSG_RESULT([no])])])
1181 ]) # LC_SEGMENT_H
1182
1183 #
1184 # LN_PROG_LINUX
1185 #
1186 # LNet linux kernel checks
1187 #
1188 AC_DEFUN([LN_PROG_LINUX],
1189 [
1190 LN_FUNC_CPU_ONLINE
1191 LN_TYPE_GFP_T
1192 LN_TYPE_CPUMASK_T
1193 LN_CONFIG_AFFINITY
1194 LN_CONFIG_BACKOFF
1195 LN_CONFIG_PANIC_DUMPLOG
1196 LN_CONFIG_QUADRICS
1197 LN_CONFIG_GM
1198 LN_CONFIG_OPENIB
1199 LN_CONFIG_CIB
1200 LN_CONFIG_VIB
1201 LN_CONFIG_IIB
1202 LN_CONFIG_O2IB
1203 LN_CONFIG_RALND
1204 LN_CONFIG_PTLLND
1205 LN_CONFIG_MX
1206
1207 LN_STRUCT_PAGE_LIST
1208 LN_STRUCT_SIGHAND
1209 LN_FUNC_SHOW_TASK
1210 # 2.6.18
1211 LN_TASKLIST_LOCK
1212 # 2.6.19
1213 LN_KMEM_CACHE_DESTROY_INT
1214 LN_ATOMIC_PANIC_NOTIFIER
1215 # 2.6.20
1216 LN_3ARGS_INIT_WORK
1217 # 2.6.21
1218 LN_2ARGS_REGISTER_SYSCTL
1219 LN_KMEM_CACHE
1220 # 2.6.23
1221 LN_KMEM_CACHE_CREATE_DTOR
1222 # PPC/PPC64 support
1223 LC_SEGMENT_H
1224 ])
1225
1226 #
1227 # LN_PROG_DARWIN
1228 #
1229 # Darwin checks
1230 #
1231 AC_DEFUN([LN_PROG_DARWIN],
1232 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
1233 ])
1234
1235 #
1236 # LN_PATH_DEFAULTS
1237 #
1238 # default paths for installed files
1239 #
1240 AC_DEFUN([LN_PATH_DEFAULTS],
1241 [
1242 ])
1243
1244 #
1245 # LN_CONFIGURE
1246 #
1247 # other configure checks
1248 #
1249 AC_DEFUN([LN_CONFIGURE],
1250 [# lnet/utils/portals.c
1251 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
1252 AC_CHECK_FUNCS([gethostbyname socket connect])
1253
1254 # lnet/utils/debug.c
1255 AC_CHECK_HEADERS([linux/version.h])
1256
1257 AC_CHECK_TYPE([spinlock_t],
1258         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
1259         [],
1260         [#include <linux/spinlock.h>])
1261
1262 # lnet/utils/wirecheck.c
1263 AC_CHECK_FUNCS([strnlen])
1264
1265 # --------  Check for required packages  --------------
1266
1267 #
1268 # LC_CONFIG_READLINE
1269 #
1270 # Build with readline
1271 #
1272 AC_MSG_CHECKING([whether to enable readline support])
1273 AC_ARG_ENABLE(readline,
1274         AC_HELP_STRING([--disable-readline],
1275                         [disable readline support]),
1276         [],[enable_readline='yes'])
1277 AC_MSG_RESULT([$enable_readline])
1278
1279 # -------- check for readline if enabled ----
1280 if test x$enable_readline = xyes ; then
1281         LIBS_save="$LIBS"
1282         LIBS="-lncurses $LIBS"
1283         AC_CHECK_LIB([readline],[readline],[
1284         LIBREADLINE="-lreadline -lncurses"
1285         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
1286         ],[
1287         LIBREADLINE=""
1288         ])
1289         LIBS="$LIBS_save"
1290 else
1291         LIBREADLINE=""
1292 fi
1293 AC_SUBST(LIBREADLINE)
1294
1295 AC_MSG_CHECKING([if efence debugging support is requested])
1296 AC_ARG_ENABLE(efence,
1297         AC_HELP_STRING([--enable-efence],
1298                         [use efence library]),
1299         [],[enable_efence='no'])
1300 AC_MSG_RESULT([$enable_efence])
1301 if test "$enable_efence" = "yes" ; then
1302         LIBEFENCE="-lefence"
1303         AC_DEFINE(HAVE_LIBEFENCE, 1, [libefence support is requested])
1304 else
1305         LIBEFENCE=""
1306 fi
1307 AC_SUBST(LIBEFENCE)
1308
1309 # -------- enable acceptor libwrap (TCP wrappers) support? -------
1310 AC_MSG_CHECKING([if libwrap support is requested])
1311 AC_ARG_ENABLE([libwrap],
1312         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
1313         [case "${enableval}" in
1314                 yes) enable_libwrap=yes ;;
1315                 no) enable_libwrap=no ;;
1316                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
1317         esac],[enable_libwrap=no])
1318 AC_MSG_RESULT([$enable_libwrap])
1319 if test x$enable_libwrap = xyes ; then
1320         LIBWRAP="-lwrap"
1321         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
1322 else
1323         LIBWRAP=""
1324 fi
1325 AC_SUBST(LIBWRAP)
1326
1327 # -------- check for -lpthread support ----
1328 AC_MSG_CHECKING([whether to use libpthread for lnet library])
1329 AC_ARG_ENABLE([libpthread],
1330         AC_HELP_STRING([--disable-libpthread],
1331                 [disable libpthread]),
1332         [],[enable_libpthread=yes])
1333 if test "$enable_libpthread" = "yes" ; then
1334         AC_CHECK_LIB([pthread], [pthread_create],
1335                 [ENABLE_LIBPTHREAD="yes"],
1336                 [ENABLE_LIBPTHREAD="no"])
1337         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
1338                 AC_MSG_RESULT([$ENABLE_LIBPTHREAD])
1339                 PTHREAD_LIBS="-lpthread"
1340                 AC_DEFINE([HAVE_LIBPTHREAD], 1, [use libpthread])
1341         else
1342                 PTHREAD_LIBS=""
1343                 AC_MSG_RESULT([no libpthread is found])
1344         fi
1345         AC_SUBST(PTHREAD_LIBS)
1346 else
1347         AC_MSG_RESULT([no (disabled explicitly)])
1348         ENABLE_LIBPTHREAD="no"
1349 fi
1350 AC_SUBST(ENABLE_LIBPTHREAD)
1351
1352 # ----------------------------------------
1353 # some tests for catamount-like systems
1354 # ----------------------------------------
1355 AC_ARG_ENABLE([sysio_init],
1356         AC_HELP_STRING([--disable-sysio-init],
1357                 [call sysio init functions when initializing liblustre]),
1358         [],[enable_sysio_init=yes])
1359 AC_MSG_CHECKING([whether to initialize libsysio])
1360 AC_MSG_RESULT([$enable_sysio_init])
1361 if test x$enable_sysio_init != xno ; then
1362         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
1363 fi
1364
1365 AC_ARG_ENABLE([urandom],
1366         AC_HELP_STRING([--disable-urandom],
1367                 [disable use of /dev/urandom for liblustre]),
1368         [],[enable_urandom=yes])
1369 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
1370 AC_MSG_RESULT([$enable_urandom])
1371 if test x$enable_urandom != xno ; then
1372         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
1373 fi
1374
1375 # -------- check for -lcap support ----
1376 if test x$enable_liblustre = xyes ; then
1377         AC_CHECK_LIB([cap], [cap_get_proc],
1378                 [
1379                         CAP_LIBS="-lcap"
1380                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
1381                 ],
1382                 [
1383                         CAP_LIBS=""
1384                 ])
1385         AC_SUBST(CAP_LIBS)
1386
1387 fi
1388
1389 LN_CONFIG_MAX_PAYLOAD
1390 LN_CONFIG_UPTLLND
1391 LN_CONFIG_USOCKLND
1392 ])
1393
1394 #
1395 # LN_CONDITIONALS
1396 #
1397 # AM_CONDITOINAL defines for lnet
1398 #
1399 AC_DEFUN([LN_CONDITIONALS],
1400 [AM_CONDITIONAL(BUILD_QSWLND, test x$QSWLND = "xqswlnd")
1401 AM_CONDITIONAL(BUILD_GMLND, test x$GMLND = "xgmlnd")
1402 AM_CONDITIONAL(BUILD_MXLND, test x$MXLND = "xmxlnd")
1403 AM_CONDITIONAL(BUILD_O2IBLND, test x$O2IBLND = "xo2iblnd")
1404 AM_CONDITIONAL(BUILD_OPENIBLND, test x$OPENIBLND = "xopeniblnd")
1405 AM_CONDITIONAL(BUILD_CIBLND, test x$CIBLND = "xciblnd")
1406 AM_CONDITIONAL(BUILD_IIBLND, test x$IIBLND = "xiiblnd")
1407 AM_CONDITIONAL(BUILD_VIBLND, test x$VIBLND = "xviblnd")
1408 AM_CONDITIONAL(BUILD_RALND, test x$RALND = "xralnd")
1409 AM_CONDITIONAL(BUILD_PTLLND, test x$PTLLND = "xptllnd")
1410 AM_CONDITIONAL(BUILD_UPTLLND, test x$UPTLLND = "xptllnd")
1411 AM_CONDITIONAL(BUILD_USOCKLND, test x$USOCKLND = "xusocklnd")
1412 ])
1413
1414 #
1415 # LN_CONFIG_FILES
1416 #
1417 # files that should be generated with AC_OUTPUT
1418 #
1419 AC_DEFUN([LN_CONFIG_FILES],
1420 [AC_CONFIG_FILES([
1421 lnet/Kernelenv
1422 lnet/Makefile
1423 lnet/autoMakefile
1424 lnet/autoconf/Makefile
1425 lnet/doc/Makefile
1426 lnet/include/Makefile
1427 lnet/include/libcfs/Makefile
1428 lnet/include/libcfs/linux/Makefile
1429 lnet/include/lnet/Makefile
1430 lnet/include/lnet/linux/Makefile
1431 lnet/klnds/Makefile
1432 lnet/klnds/autoMakefile
1433 lnet/klnds/gmlnd/Makefile
1434 lnet/klnds/mxlnd/autoMakefile
1435 lnet/klnds/mxlnd/Makefile
1436 lnet/klnds/gmlnd/autoMakefile
1437 lnet/klnds/openiblnd/Makefile
1438 lnet/klnds/openiblnd/autoMakefile
1439 lnet/klnds/o2iblnd/Makefile
1440 lnet/klnds/o2iblnd/autoMakefile
1441 lnet/klnds/ciblnd/Makefile
1442 lnet/klnds/ciblnd/autoMakefile
1443 lnet/klnds/iiblnd/Makefile
1444 lnet/klnds/iiblnd/autoMakefile
1445 lnet/klnds/viblnd/Makefile
1446 lnet/klnds/viblnd/autoMakefile
1447 lnet/klnds/qswlnd/Makefile
1448 lnet/klnds/qswlnd/autoMakefile
1449 lnet/klnds/ralnd/Makefile
1450 lnet/klnds/ralnd/autoMakefile
1451 lnet/klnds/socklnd/Makefile
1452 lnet/klnds/socklnd/autoMakefile
1453 lnet/klnds/ptllnd/Makefile
1454 lnet/klnds/ptllnd/autoMakefile
1455 lnet/libcfs/Makefile
1456 lnet/libcfs/autoMakefile
1457 lnet/libcfs/linux/Makefile
1458 lnet/lnet/Makefile
1459 lnet/lnet/autoMakefile
1460 lnet/selftest/Makefile
1461 lnet/selftest/autoMakefile
1462 lnet/ulnds/Makefile
1463 lnet/ulnds/autoMakefile
1464 lnet/ulnds/socklnd/Makefile
1465 lnet/ulnds/ptllnd/Makefile
1466 lnet/utils/Makefile
1467 ])
1468 case $lb_target_os in
1469         darwin)
1470                 AC_CONFIG_FILES([
1471 lnet/include/libcfs/darwin/Makefile
1472 lnet/include/lnet/darwin/Makefile
1473 lnet/libcfs/darwin/Makefile
1474 ])
1475                 ;;
1476 esac
1477 ])