lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD],
   7 [AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                        [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19         AC_DEFINE_UNQUOTED(LNET_MAX_PAYLOAD, $LNET_MAX_PAYLOAD,
  20                            [Max LNET payload])
  21 ])
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION],
  29 [AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ])
  43
  44 #
  45 # LN_CONFIG_AFFINITY
  46 #
  47 # check if cpu affinity is available/wanted
  48 #
  49 AC_DEFUN([LN_CONFIG_AFFINITY],
  50 [AC_ARG_ENABLE([affinity],
  51         AC_HELP_STRING([--disable-affinity],
  52                        [disable process/irq affinity]),
  53         [],[enable_affinity='yes'])
  54
  55 AC_MSG_CHECKING([for CPU affinity support])
  56 if test x$enable_affinity = xno ; then
  57         AC_MSG_RESULT([no (by request)])
  58 else
  59         LB_LINUX_TRY_COMPILE([
  60                 #include <linux/sched.h>
  61         ],[
  62                 struct task_struct t;
  63                 #if HAVE_CPUMASK_T
  64                 cpumask_t     m;
  65                 #else
  66                 unsigned long m;
  67                 #endif
  68                 set_cpus_allowed(&t, m);
  69         ],[
  70                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
  71                 AC_MSG_RESULT([yes])
  72         ],[
  73                 AC_MSG_RESULT([no (no kernel support)])
  74         ])
  75 fi
  76 ])
  77
  78 #
  79 # LN_CONFIG_PORTALS
  80 #
  81 # configure support for Portals
  82 #
  83 AC_DEFUN([LN_CONFIG_PORTALS],
  84 [AC_MSG_CHECKING([for portals])
  85 AC_ARG_WITH([portals],
  86         AC_HELP_STRING([--with-portals=path],
  87                        [set path to portals]),
  88         [
  89                 case $with_portals in
  90                         no)     ENABLEPORTALS=0
  91                                 ;;
  92                         *)      PORTALS="${with_portals}"
  93                                 ENABLEPORTALS=1
  94                                 ;;
  95                 esac
  96         ], [
  97                 ENABLEPORTALS=0
  98         ])
  99 PTLLNDCPPFLAGS=""
 100 if test $ENABLEPORTALS -eq 0; then
 101         AC_MSG_RESULT([no])
 102 elif test ! \( -f ${PORTALS}/include/portals/p30.h \); then
 103         AC_MSG_RESULT([no])
 104         AC_MSG_ERROR([bad --with-portals path])
 105 else
 106         AC_MSG_RESULT([$PORTALS])
 107         PTLLNDCPPFLAGS="-I${PORTALS}/include"
 108 fi
 109 AC_SUBST(PTLLNDCPPFLAGS)
 110 ])
 111
 112 #
 113 # LN_CONFIG_BACKOFF
 114 #
 115 # check if tunable tcp backoff is available/wanted
 116 #
 117 AC_DEFUN([LN_CONFIG_BACKOFF],
 118 [AC_MSG_CHECKING([for tunable backoff TCP support])
 119 AC_ARG_ENABLE([backoff],
 120        AC_HELP_STRING([--disable-backoff],
 121                       [disable socknal tunable backoff]),
 122        [],[enable_backoff='yes'])
 123 if test x$enable_backoff = xno ; then
 124        AC_MSG_RESULT([no (by request)])
 125 else
 126        BOCD="`grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h`"
 127        if test "$BOCD" != 0 ; then
 128                AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
 129                AC_MSG_RESULT(yes)
 130                if grep rto_max $LINUX/include/linux/tcp.h|grep -q __u16; then
 131                    AC_DEFINE(SOCKNAL_BACKOFF_MS, 1, [tunable backoff TCP in ms])
 132                fi
 133        else
 134                AC_MSG_RESULT([no (no kernel support)])
 135        fi
 136 fi
 137 ])
 138
 139
 140 #
 141 # LN_CONFIG_PTLLND
 142 #
 143 # configure support for Portals LND
 144 #
 145 AC_DEFUN([LN_CONFIG_PTLLND],
 146 [
 147 if test -z "$ENABLEPORTALS"; then
 148         LN_CONFIG_PORTALS
 149 fi
 150
 151 AC_MSG_CHECKING([whether to build the kernel portals LND])
 152
 153 PTLLND=""
 154 if test $ENABLEPORTALS -ne 0; then
 155         AC_MSG_RESULT([yes])
 156         PTLLND="ptllnd"
 157 else
 158         AC_MSG_RESULT([no])
 159 fi
 160 AC_SUBST(PTLLND)
 161 ])
 162
 163 #
 164 # LN_CONFIG_UPTLLND
 165 #
 166 # configure support for Portals LND
 167 #
 168 AC_DEFUN([LN_CONFIG_UPTLLND],
 169 [
 170 if test -z "$ENABLEPORTALS"; then
 171         LN_CONFIG_PORTALS
 172 fi
 173
 174 AC_MSG_CHECKING([whether to build the userspace portals LND])
 175
 176 UPTLLND=""
 177 if test $ENABLEPORTALS -ne 0; then
 178         AC_MSG_RESULT([yes])
 179         UPTLLND="ptllnd"
 180 else
 181         AC_MSG_RESULT([no])
 182 fi
 183 AC_SUBST(UPTLLND)
 184 ])
 185
 186 #
 187 # LN_CONFIG_USOCKLND
 188 #
 189 # configure support for userspace TCP/IP LND
 190 #
 191 AC_DEFUN([LN_CONFIG_USOCKLND],
 192 [AC_MSG_CHECKING([whether to build usocklnd])
 193 AC_ARG_ENABLE([usocklnd],
 194         AC_HELP_STRING([--disable-usocklnd],
 195                         [disable usocklnd]),
 196         [],[enable_usocklnd='yes'])
 197
 198 if test x$enable_usocklnd = xyes ; then
 199         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 200                 AC_MSG_RESULT([yes])
 201                 USOCKLND="usocklnd"
 202         else
 203                 AC_MSG_RESULT([no (libpthread not present or disabled)])
 204                 USOCKLND=""
 205         fi
 206 else
 207         AC_MSG_RESULT([no (disabled explicitly)])
 208         USOCKLND=""
 209 fi
 210 AC_SUBST(USOCKLND)
 211 ])
 212
 213 #
 214 # LN_CONFIG_QUADRICS
 215 #
 216 # check if quadrics support is in this kernel
 217 #
 218 AC_DEFUN([LN_CONFIG_QUADRICS],
 219 [AC_MSG_CHECKING([for QsNet sources])
 220 AC_ARG_WITH([qsnet],
 221         AC_HELP_STRING([--with-qsnet=path],
 222                        [set path to qsnet source (default=$LINUX)]),
 223         [QSNET=$with_qsnet],
 224         [QSNET=$LINUX])
 225 AC_MSG_RESULT([$QSNET])
 226
 227 AC_MSG_CHECKING([if quadrics kernel headers are present])
 228 if test -d $QSNET/drivers/net/qsnet ; then
 229         AC_MSG_RESULT([yes])
 230         QSWLND="qswlnd"
 231         AC_MSG_CHECKING([for multirail EKC])
 232         if test -f $QSNET/include/elan/epcomms.h; then
 233                 AC_MSG_RESULT([supported])
 234                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 235         else
 236                 AC_MSG_RESULT([not supported])
 237                 AC_MSG_ERROR([Need multirail EKC])
 238         fi
 239
 240         if test x$QSNET = x$LINUX ; then
 241                 LB_LINUX_CONFIG([QSNET],[],[
 242                         LB_LINUX_CONFIG([QSNET_MODULE],[],[
 243                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
 244                                 QSWLND=""
 245                                 QSWCPPFLAGS=""
 246                         ])
 247                 ])
 248         fi
 249 else
 250         AC_MSG_RESULT([no])
 251         QSWLND=""
 252         QSWCPPFLAGS=""
 253 fi
 254 AC_SUBST(QSWCPPFLAGS)
 255 AC_SUBST(QSWLND)
 256 ])
 257
 258 #
 259 # LN_CONFIG_GM
 260 #
 261 # check if GM support is available
 262 #
 263 AC_DEFUN([LN_CONFIG_GM],[
 264 AC_MSG_CHECKING([whether to enable GM support])
 265 AC_ARG_WITH([gm],
 266         AC_HELP_STRING([--with-gm=path-to-gm-source-tree],
 267                        [build gmlnd against path]),
 268         [
 269                 case $with_gm in
 270                 no)    ENABLE_GM=0
 271                        ;;
 272                 *)     ENABLE_GM=1
 273                        GM_SRC="$with_gm"
 274                        ;;
 275                 esac
 276         ],[
 277                 ENABLE_GM=0
 278         ])
 279 AC_ARG_WITH([gm-install],
 280         AC_HELP_STRING([--with-gm-install=path-to-gm-install-tree],
 281                        [say where GM has been installed]),
 282         [
 283                 GM_INSTALL=$with_gm_install
 284         ],[
 285                 GM_INSTALL="/opt/gm"
 286         ])
 287 if test $ENABLE_GM -eq 0; then
 288         AC_MSG_RESULT([no])
 289 else
 290         AC_MSG_RESULT([yes])
 291
 292         GMLND="gmlnd"
 293         GMCPPFLAGS="-I$GM_SRC/include -I$GM_SRC/drivers -I$GM_SRC/drivers/linux/gm"
 294
 295         if test -f $GM_INSTALL/lib/libgm.a -o \
 296                 -f $GM_INSTALL/lib64/libgm.a; then
 297                 GMLIBS="-L$GM_INSTALL/lib -L$GM_INSTALL/lib64"
 298         else
 299                 AC_MSG_ERROR([Cant find GM libraries under $GM_INSTALL])
 300         fi
 301
 302         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 303         EXTRA_KCFLAGS="$GMCPPFLAGS -DGM_KERNEL $EXTRA_KCFLAGS"
 304
 305         AC_MSG_CHECKING([that code using GM compiles with given path])
 306         LB_LINUX_TRY_COMPILE([
 307                 #define GM_STRONG_TYPES 1
 308                 #ifdef VERSION
 309                 #undef VERSION
 310                 #endif
 311                 #include "gm.h"
 312                 #include "gm_internal.h"
 313         ],[
 314                 struct gm_port *port = NULL;
 315                 gm_recv_event_t *rxevent = gm_blocking_receive_no_spin(port);
 316                 return 0;
 317         ],[
 318                 AC_MSG_RESULT([yes])
 319         ],[
 320                 AC_MSG_RESULT([no])
 321                 AC_MSG_ERROR([Bad --with-gm path])
 322         ])
 323
 324         AC_MSG_CHECKING([that GM has gm_register_memory_ex_phys()])
 325         LB_LINUX_TRY_COMPILE([
 326                 #define GM_STRONG_TYPES 1
 327                 #ifdef VERSION
 328                 #undef VERSION
 329                 #endif
 330                 #include "gm.h"
 331                 #include "gm_internal.h"
 332         ],[
 333                 gm_status_t     gmrc;
 334                 struct gm_port *port = NULL;
 335                 gm_u64_t        phys = 0;
 336                 gm_up_t         pvma = 0;
 337
 338                 gmrc = gm_register_memory_ex_phys(port, phys, 100, pvma);
 339                 return 0;
 340         ],[
 341                 AC_MSG_RESULT([yes])
 342         ],[
 343                 AC_MSG_RESULT([no.
 344 Please patch the GM sources as follows...
 345     cd $GM_SRC
 346     patch -p0 < $PWD/lnet/klnds/gmlnd/gm-reg-phys.patch
 347 ...then rebuild and re-install them])
 348                 AC_MSG_ERROR([Can't build GM without gm_register_memory_ex_phys()])
 349         ])
 350
 351         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 352 fi
 353 AC_SUBST(GMCPPFLAGS)
 354 AC_SUBST(GMLIBS)
 355 AC_SUBST(GMLND)
 356 ])
 357
 358
 359 #
 360 # LN_CONFIG_MX
 361 #
 362 AC_DEFUN([LN_CONFIG_MX],
 363 [AC_MSG_CHECKING([whether to enable Myrinet MX support])
 364 # set default
 365 MXPATH="/opt/mx"
 366 AC_ARG_WITH([mx],
 367        AC_HELP_STRING([--with-mx=path],
 368                       [build mxlnd against path]),
 369        [
 370                case $with_mx in
 371                yes)    ENABLEMX=2
 372                        ;;
 373                no)     ENABLEMX=0
 374                        ;;
 375                *)      MXPATH=$with_mx
 376                        ENABLEMX=3
 377                        ;;
 378                esac
 379        ],[
 380                ENABLEMX=1
 381        ])
 382 if test $ENABLEMX -eq 0; then
 383        AC_MSG_RESULT([disabled])
 384 elif test ! \( -f ${MXPATH}/include/myriexpress.h -a \
 385               -f ${MXPATH}/include/mx_kernel_api.h -a \
 386               -f ${MXPATH}/include/mx_pin.h \); then
 387        AC_MSG_RESULT([no])
 388        case $ENABLEMX in
 389        1) ;;
 390        2) AC_MSG_ERROR([Myrinet MX kernel headers not present]);;
 391        3) AC_MSG_ERROR([bad --with-mx path]);;
 392        *) AC_MSG_ERROR([internal error]);;
 393        esac
 394 else
 395        MXCPPFLAGS="-I$MXPATH/include"
 396        EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 397        EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
 398        MXLIBS="-L$MXPATH/lib"
 399        LB_LINUX_TRY_COMPILE([
 400                #define MX_KERNEL 1
 401                #include <mx_extensions.h>
 402                #include <myriexpress.h>
 403        ],[
 404                mx_endpoint_t   end;
 405                mx_status_t     status;
 406                mx_request_t    request;
 407                int             result;
 408
 409                mx_init();
 410                mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
 411                mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
 412                mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
 413                mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
 414                return 0;
 415        ],[
 416                AC_MSG_RESULT([yes])
 417                MXLND="mxlnd"
 418        ],[
 419                AC_MSG_RESULT([no])
 420                case $ENABLEMX in
 421                1) ;;
 422                2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]);;
 423                3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]);;
 424                *) AC_MSG_ERROR([internal error]);;
 425                esac
 426                MXLND=""
 427                MXCPPFLAGS=""
 428        ])
 429        EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 430 fi
 431 AC_SUBST(MXCPPFLAGS)
 432 AC_SUBST(MXLIBS)
 433 AC_SUBST(MXLND)
 434 ])
 435
 436
 437
 438 #
 439 # LN_CONFIG_O2IB
 440 #
 441 AC_DEFUN([LN_CONFIG_O2IB],[
 442 AC_MSG_CHECKING([whether to enable OpenIB gen2 support])
 443 # set default
 444 AC_ARG_WITH([o2ib],
 445         AC_HELP_STRING([--with-o2ib=path],
 446                        [build o2iblnd against path]),
 447         [
 448                 case $with_o2ib in
 449                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 450                         ENABLEO2IB=2
 451                         ;;
 452                 no)     ENABLEO2IB=0
 453                         ;;
 454                 *)      O2IBPATHS=$with_o2ib
 455                         ENABLEO2IB=3
 456                         ;;
 457                 esac
 458         ],[
 459                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 460                 ENABLEO2IB=1
 461         ])
 462 if test $ENABLEO2IB -eq 0; then
 463         AC_MSG_RESULT([disabled])
 464 else
 465         o2ib_found=false
 466
 467         for O2IBPATH in $O2IBPATHS; do
 468                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 469                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 470                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 471                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 472                         o2ib_found=true
 473                         break
 474                 fi
 475         done
 476
 477         if ! $o2ib_found; then
 478                 AC_MSG_RESULT([no])
 479                 case $ENABLEO2IB in
 480                         1) ;;
 481                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 482                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 483                         *) AC_MSG_ERROR([internal error]);;
 484                 esac
 485         else
 486                 # figure out whether the kernel has an infiniband stack
 487                 # configured
 488                 LB_LINUX_CONFIG_IM([INFINIBAND],[
 489                         CONFIG_INFINIBAND_MODULE_defined=true
 490                 ],[
 491                         CONFIG_INFINIBAND_MODULE_defined=false
 492                 ])
 493                 # at this point we know that the user either explicitly
 494                 # requested o2ib support or didn't explicitly disable it so
 495                 # make sure the kernel's CONFIG_INFINIBAND variable is set
 496                 # appropriately.
 497                 #
 498                 # possible error conditions are:
 499                 # 1) --with-o2ib[=yes] (implies in kernel since no path was
 500                 #    given) and kernel not configured for IB
 501                 # 2) --with-o2ib=/path and kernel is configured for IB
 502                 #
 503                 if test "$O2IBPATH" = "$LINUX" -o "$O2IBPATH" = "$LINUX/drivers/infiniband"; then
 504                         # infiniband stack is in the kernel
 505                         if test $ENABLEO2IB -eq 1 -o $ENABLEO2IB -eq 2 && ! $CONFIG_INFINIBAND_MODULE_defined; then
 506                                 # case #1
 507                                 AC_MSG_ERROR([Kernel supplied OFED drivers are being requested however the kernel is NOT configured to build OFED modules.  Please specify --with-o2ib=<path_to_ofed> or rebuild the kernel with Infiniband enabled.])
 508                         fi
 509                 else
 510                         # had to be a specified path with --with-o2ib=/path
 511                         if $CONFIG_INFINIBAND_MODULE_defined; then
 512                                 # case #2
 513                                 AC_MSG_ERROR([External OFED source has been specified but the kernel is configured to build OFED modules as well.  Remove --with-o2ib from the configuration or rebuild the kernel without Infiniband.])
 514                         fi
 515                 fi
 516                 if $o2ib_found; then
 517                 O2IBCPPFLAGS="-I$O2IBPATH/include"
 518                 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 519                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $O2IBCPPFLAGS"
 520                 EXTRA_LNET_INCLUDE="$O2IBCPPFLAGS $EXTRA_LNET_INCLUDE"
 521                 LB_LINUX_TRY_COMPILE([
 522                         #include <linux/version.h>
 523                         #include <linux/pci.h>
 524                         #if !HAVE_GFP_T
 525                         typedef int gfp_t;
 526                         #endif
 527                         #include <rdma/rdma_cm.h>
 528                         #include <rdma/ib_cm.h>
 529                         #include <rdma/ib_verbs.h>
 530                         #include <rdma/ib_fmr_pool.h>
 531                 ],[
 532                         struct rdma_cm_id          *cm_id;
 533                         struct rdma_conn_param      conn_param;
 534                         struct ib_device_attr       device_attr;
 535                         struct ib_qp_attr           qp_attr;
 536                         struct ib_pool_fmr          pool_fmr;
 537                         enum   ib_cm_rej_reason     rej_reason;
 538
 539                         cm_id = rdma_create_id(NULL, NULL, RDMA_PS_TCP);
 540                         return PTR_ERR(cm_id);
 541                 ],[
 542                         AC_MSG_RESULT([yes])
 543                         O2IBLND="o2iblnd"
 544                 ],[
 545                         AC_MSG_RESULT([no])
 546                         case $ENABLEO2IB in
 547                         1) ;;
 548                         2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]);;
 549                         3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]);;
 550                         *) AC_MSG_ERROR([internal error]);;
 551                         esac
 552                         O2IBLND=""
 553                         O2IBCPPFLAGS=""
 554                 ])
 555                 # we know at this point that the found OFED source is good
 556                 O2IB_SYMVER=""
 557                 if test $ENABLEO2IB -eq 3 ; then
 558                         # OFED default rpm not handle sles10 Modules.symvers name
 559                         for name in Module.symvers Modules.symvers; do
 560                                 if test -f $O2IBPATH/$name; then
 561                                         O2IB_SYMVER=$name;
 562                                         break;
 563                                 fi
 564                         done
 565                         if test -n $O2IB_SYMVER ; then
 566                                 AC_MSG_NOTICE([adding $O2IBPATH/$O2IB_SYMVER to $PWD/$SYMVERFILE])
 567                                 # strip out the existing symbols versions first
 568                                 egrep -v $(echo $(awk '{ print $2 }' $O2IBPATH/$O2IB_SYMVER) | tr ' ' '|') $PWD/$SYMVERFILE > $PWD/$SYMVERFILE.old
 569                                 cat $PWD/$SYMVERFILE.old $O2IBPATH/$O2IB_SYMVER > $PWD/$SYMVERFILE
 570                         else
 571                                 AC_MSG_ERROR([an external source tree was specified for o2iblnd however I could not find a $O2IBPATH/Module.symvers there])
 572                         fi
 573                 fi
 574
 575                 LB_LINUX_TRY_COMPILE([
 576                         #include <linux/version.h>
 577                         #include <linux/pci.h>
 578                         #if !HAVE_GFP_T
 579                         typedef int gfp_t;
 580                         #endif
 581                         #include <rdma/ib_verbs.h>
 582                 ],[
 583                         ib_dma_map_single(NULL, NULL, 0, 0);
 584                         return 0;
 585                 ],[
 586                         AC_MSG_RESULT(yes)
 587                         AC_DEFINE(HAVE_OFED_IB_DMA_MAP, 1,
 588                                   [ib_dma_map_single defined])
 589                 ],[
 590                         AC_MSG_RESULT(NO)
 591                 ])
 592
 593                 LB_LINUX_TRY_COMPILE([
 594                         #include <linux/version.h>
 595                         #include <linux/pci.h>
 596                         #if !HAVE_GFP_T
 597                         typedef int gfp_t;
 598                         #endif
 599                         #include <rdma/ib_verbs.h>
 600                 ],[
 601                         ib_create_cq(NULL, NULL, NULL, NULL, 0, 0);
 602                         return 0;
 603                 ],[
 604                         AC_MSG_RESULT(yes)
 605                         AC_DEFINE(HAVE_OFED_IB_COMP_VECTOR, 1,
 606                                   [has completion vector])
 607                 ],[
 608                         AC_MSG_RESULT(NO)
 609                 ])
 610
 611                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 612         fi
 613         fi
 614 fi
 615
 616 AC_SUBST(EXTRA_LNET_INCLUDE)
 617 AC_SUBST(O2IBCPPFLAGS)
 618 AC_SUBST(O2IBLND)
 619 ])
 620
 621 #
 622 # LN_CONFIG_OPENIB
 623 #
 624 # check for OpenIB in the kernel
 625 AC_DEFUN([LN_CONFIG_OPENIB],[
 626 AC_MSG_CHECKING([whether to enable OpenIB support])
 627 # set default
 628 OPENIBPATH="$LINUX/drivers/infiniband"
 629 AC_ARG_WITH([openib],
 630         AC_HELP_STRING([--with-openib=path],
 631                        [build openiblnd against path]),
 632         [
 633                 case $with_openib in
 634                 yes)    ENABLEOPENIB=2
 635                         ;;
 636                 no)     ENABLEOPENIB=0
 637                         ;;
 638                 *)      OPENIBPATH="$with_openib"
 639                         ENABLEOPENIB=3
 640                         ;;
 641                 esac
 642         ],[
 643                 ENABLEOPENIB=1
 644         ])
 645 if test $ENABLEOPENIB -eq 0; then
 646         AC_MSG_RESULT([disabled])
 647 elif test ! \( -f ${OPENIBPATH}/include/ts_ib_core.h -a \
 648                -f ${OPENIBPATH}/include/ts_ib_cm.h -a \
 649                -f ${OPENIBPATH}/include/ts_ib_sa_client.h \); then
 650         AC_MSG_RESULT([no])
 651         case $ENABLEOPENIB in
 652         1) ;;
 653         2) AC_MSG_ERROR([kernel OpenIB headers not present]);;
 654         3) AC_MSG_ERROR([bad --with-openib path]);;
 655         *) AC_MSG_ERROR([internal error]);;
 656         esac
 657 else
 658         case $ENABLEOPENIB in
 659         1|2) OPENIBCPPFLAGS="-I$OPENIBPATH/include -DIN_TREE_BUILD";;
 660         3)   OPENIBCPPFLAGS="-I$OPENIBPATH/include";;
 661         *)   AC_MSG_RESULT([no])
 662              AC_MSG_ERROR([internal error]);;
 663         esac
 664         OPENIBCPPFLAGS="$OPENIBCPPFLAGS -DIB_NTXRXPARAMS=4"
 665         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 666         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $OPENIBCPPFLAGS"
 667         LB_LINUX_TRY_COMPILE([
 668                 #include <ts_ib_core.h>
 669                 #include <ts_ib_cm.h>
 670                 #include <ts_ib_sa_client.h>
 671         ],[
 672                 struct ib_device_properties dev_props;
 673                 struct ib_cm_active_param   cm_active_params;
 674                 tTS_IB_CLIENT_QUERY_TID     tid;
 675                 int                         enum1 = IB_QP_ATTRIBUTE_STATE;
 676                 int                         enum2 = IB_ACCESS_LOCAL_WRITE;
 677                 int                         enum3 = IB_CQ_CALLBACK_INTERRUPT;
 678                 int                         enum4 = IB_CQ_PROVIDER_REARM;
 679                 return 0;
 680         ],[
 681                 AC_MSG_RESULT([yes])
 682                 OPENIBLND="openiblnd"
 683         ],[
 684                 AC_MSG_RESULT([no])
 685                 case $ENABLEOPENIB in
 686                 1) ;;
 687                 2) AC_MSG_ERROR([can't compile with kernel OpenIB headers]);;
 688                 3) AC_MSG_ERROR([can't compile with OpenIB headers under $OPENIBPATH]);;
 689                 *) AC_MSG_ERROR([internal error]);;
 690                 esac
 691                 OPENIBLND=""
 692                 OPENIBCPPFLAGS=""
 693         ])
 694         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 695 fi
 696 AC_SUBST(OPENIBCPPFLAGS)
 697 AC_SUBST(OPENIBLND)
 698 ])
 699
 700 #
 701 # LN_CONFIG_CIBLND
 702 #
 703 AC_DEFUN([LN_CONFIG_CIB],[
 704 AC_MSG_CHECKING([whether to enable Cisco/TopSpin IB support])
 705 # set default
 706 CIBPATH=""
 707 CIBLND=""
 708 AC_ARG_WITH([cib],
 709         AC_HELP_STRING([--with-cib=path],
 710                        [build ciblnd against path]),
 711         [
 712                 case $with_cib in
 713                 no)     AC_MSG_RESULT([no]);;
 714                 *)      CIBPATH="$with_cib"
 715                         if test -d "$CIBPATH"; then
 716                                 AC_MSG_RESULT([yes])
 717                         else
 718                                 AC_MSG_RESULT([no])
 719                                 AC_MSG_ERROR([No directory $CIBPATH])
 720                         fi;;
 721                 esac
 722         ],[
 723                 AC_MSG_RESULT([no])
 724         ])
 725 if test -n "$CIBPATH"; then
 726         CIBCPPFLAGS="-I${CIBPATH}/ib/ts_api_ng/include -I${CIBPATH}/all/kernel_services/include -DUSING_TSAPI"
 727         CIBCPPFLAGS="$CIBCPPFLAGS -DIB_NTXRXPARAMS=3"
 728         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 729         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $CIBCPPFLAGS"
 730         LB_LINUX_TRY_COMPILE([
 731                 #include <ts_ib_core.h>
 732                 #include <ts_ib_cm.h>
 733                 #include <ts_ib_sa_client.h>
 734         ],[
 735                 struct ib_device_properties dev_props;
 736                 struct ib_cm_active_param   cm_active_params;
 737                 tTS_IB_CLIENT_QUERY_TID     tid;
 738                 int                         enum1 = TS_IB_QP_ATTRIBUTE_STATE;
 739                 int                         enum2 = TS_IB_ACCESS_LOCAL_WRITE;
 740                 int                         enum3 = TS_IB_CQ_CALLBACK_INTERRUPT;
 741                 int                         enum4 = TS_IB_CQ_PROVIDER_REARM;
 742                 return 0;
 743         ],[
 744                 CIBLND="ciblnd"
 745         ],[
 746                 AC_MSG_ERROR([can't compile ciblnd with given path])
 747                 CIBCPPFLAGS=""
 748         ])
 749         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 750 fi
 751 AC_SUBST(CIBCPPFLAGS)
 752 AC_SUBST(CIBLND)
 753 ])
 754
 755 #
 756 # LN_CONFIG_IIB
 757 #
 758 # check for infinicon infiniband support
 759 #
 760 AC_DEFUN([LN_CONFIG_IIB],[
 761 AC_MSG_CHECKING([whether to enable Infinicon support])
 762 # set default
 763 IIBPATH="/usr/include"
 764 AC_ARG_WITH([iib],
 765         AC_HELP_STRING([--with-iib=path],
 766                        [build iiblnd against path]),
 767         [
 768                 case $with_iib in
 769                 yes)    ENABLEIIB=2
 770                         ;;
 771                 no)     ENABLEIIB=0
 772                         ;;
 773                 *)      IIBPATH="${with_iib}/include"
 774                         ENABLEIIB=3
 775                         ;;
 776                 esac
 777         ],[
 778                 ENABLEIIB=1
 779         ])
 780 if test $ENABLEIIB -eq 0; then
 781         AC_MSG_RESULT([disabled])
 782 elif test ! \( -f ${IIBPATH}/linux/iba/ibt.h \); then
 783         AC_MSG_RESULT([no])
 784         case $ENABLEIIB in
 785         1) ;;
 786         2) AC_MSG_ERROR([default Infinicon headers not present]);;
 787         3) AC_MSG_ERROR([bad --with-iib path]);;
 788         *) AC_MSG_ERROR([internal error]);;
 789         esac
 790 else
 791         IIBCPPFLAGS="-I$IIBPATH"
 792         if test $IIBPATH != "/usr/include"; then
 793                 # we need /usr/include come what may
 794                 IIBCPPFLAGS="$IIBCPPFLAGS -I/usr/include"
 795         fi
 796         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 797         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $IIBCPPFLAGS"
 798         LB_LINUX_TRY_COMPILE([
 799                 #include <linux/iba/ibt.h>
 800         ],[
 801                 IBT_INTERFACE_UNION interfaces;
 802                 FSTATUS             rc;
 803
 804                  rc = IbtGetInterfaceByVersion(IBT_INTERFACE_VERSION_2,
 805                                                &interfaces);
 806
 807                 return rc == FSUCCESS ? 0 : 1;
 808         ],[
 809                 AC_MSG_RESULT([yes])
 810                 IIBLND="iiblnd"
 811         ],[
 812                 AC_MSG_RESULT([no])
 813                 case $ENABLEIIB in
 814                 1) ;;
 815                 2) AC_MSG_ERROR([can't compile with default Infinicon headers]);;
 816                 3) AC_MSG_ERROR([can't compile with Infinicon headers under $IIBPATH]);;
 817                 *) AC_MSG_ERROR([internal error]);;
 818                 esac
 819                 IIBLND=""
 820                 IIBCPPFLAGS=""
 821         ])
 822         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 823 fi
 824 AC_SUBST(IIBCPPFLAGS)
 825 AC_SUBST(IIBLND)
 826 ])
 827
 828 #
 829 # LN_CONFIG_VIB
 830 #
 831 # check for Voltaire infiniband support
 832 #
 833 AC_DEFUN([LN_CONFIG_VIB],
 834 [AC_MSG_CHECKING([whether to enable Voltaire IB support])
 835 VIBPATH=""
 836 AC_ARG_WITH([vib],
 837         AC_HELP_STRING([--with-vib=path],
 838                        [build viblnd against path]),
 839         [
 840                 case $with_vib in
 841                 no)     AC_MSG_RESULT([no]);;
 842                 *)      VIBPATH="${with_vib}/src/nvigor/ib-code"
 843                         if test -d "$with_vib" -a -d "$VIBPATH"; then
 844                                 AC_MSG_RESULT([yes])
 845                         else
 846                                 AC_MSG_RESULT([no])
 847                                 AC_MSG_ERROR([No directory $VIBPATH])
 848                         fi;;
 849                 esac
 850         ],[
 851                 AC_MSG_RESULT([no])
 852         ])
 853 if test -z "$VIBPATH"; then
 854         VIBLND=""
 855 else
 856         VIBCPPFLAGS="-I${VIBPATH}/include -I${VIBPATH}/cm"
 857         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 858         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 859         LB_LINUX_TRY_COMPILE([
 860                 #include <linux/list.h>
 861                 #include <asm/byteorder.h>
 862                 #ifdef __BIG_ENDIAN
 863                 # define CPU_BE 1
 864                 # define CPU_LE 0
 865                 #endif
 866                 #ifdef __LITTLE_ENDIAN
 867                 # define CPU_BE 0
 868                 # define CPU_LE 1
 869                 #endif
 870                 #include <vverbs.h>
 871                 #include <ib-cm.h>
 872                 #include <ibat.h>
 873         ],[
 874                 vv_hca_h_t       kib_hca;
 875                 vv_return_t      vvrc;
 876                 cm_cep_handle_t  cep;
 877                 ibat_arp_data_t  arp_data;
 878                 ibat_stat_t      ibatrc;
 879
 880                 vvrc = vv_hca_open("ANY_HCA", NULL, &kib_hca);
 881                 cep = cm_create_cep(cm_cep_transp_rc);
 882                 ibatrc = ibat_get_ib_data((uint32_t)0, (uint32_t)0,
 883                                           ibat_paths_primary, &arp_data,
 884                                           (ibat_get_ib_data_reply_fn_t)NULL,
 885                                           NULL, 0);
 886                 return 0;
 887         ],[
 888                 VIBLND="viblnd"
 889         ],[
 890                 AC_MSG_ERROR([can't compile viblnd with given path])
 891         ])
 892         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 893 fi
 894 if test -n "$VIBLND"; then
 895         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 896         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 897         AC_MSG_CHECKING([if Voltaire still uses void * sg addresses])
 898         LB_LINUX_TRY_COMPILE([
 899                 #include <linux/list.h>
 900                 #include <asm/byteorder.h>
 901                 #ifdef __BIG_ENDIAN
 902                 # define CPU_BE 1
 903                 # define CPU_LE 0
 904                 #endif
 905                 #ifdef __LITTLE_ENDIAN
 906                 # define CPU_BE 0
 907                 # define CPU_LE 1
 908                 #endif
 909                 #include <vverbs.h>
 910                 #include <ib-cm.h>
 911                 #include <ibat.h>
 912         ],[
 913                 vv_scatgat_t  sg;
 914
 915                 return &sg.v_address[3] == NULL;
 916         ],[
 917                 AC_MSG_RESULT([yes])
 918                 VIBCPPFLAGS="$VIBCPPFLAGS -DIBNAL_VOIDSTAR_SGADDR=1"
 919         ],[
 920                 AC_MSG_RESULT([no])
 921         ])
 922         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 923 fi
 924 AC_SUBST(VIBCPPFLAGS)
 925 AC_SUBST(VIBLND)
 926 ])
 927
 928 #
 929 # LN_CONFIG_RALND
 930 #
 931 # check whether to use the RapidArray lnd
 932 #
 933 AC_DEFUN([LN_CONFIG_RALND],
 934 [#### Rapid Array
 935 AC_MSG_CHECKING([if RapidArray kernel headers are present])
 936 # placeholder
 937 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 938 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 939 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 940 LB_LINUX_TRY_COMPILE([
 941         #include <linux/types.h>
 942         #include <rapl.h>
 943 ],[
 944         RAP_RETURN          rc;
 945         RAP_PVOID           dev_handle;
 946
 947         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 948
 949         return rc == RAP_SUCCESS ? 0 : 1;
 950 ],[
 951         AC_MSG_RESULT([yes])
 952         RALND="ralnd"
 953 ],[
 954         AC_MSG_RESULT([no])
 955         RALND=""
 956         RACPPFLAGS=""
 957 ])
 958 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 959 AC_SUBST(RACPPFLAGS)
 960 AC_SUBST(RALND)
 961 ])
 962
 963
 964
 965 #
 966 # LN_PROG_LINUX
 967 #
 968 # LNet linux kernel checks
 969 #
 970 AC_DEFUN([LN_PROG_LINUX],
 971 [
 972 LN_CONFIG_AFFINITY
 973 LN_CONFIG_BACKOFF
 974 LN_CONFIG_QUADRICS
 975 LN_CONFIG_GM
 976 LN_CONFIG_OPENIB
 977 LN_CONFIG_CIB
 978 LN_CONFIG_VIB
 979 LN_CONFIG_IIB
 980 LN_CONFIG_O2IB
 981 LN_CONFIG_RALND
 982 LN_CONFIG_PTLLND
 983 LN_CONFIG_MX
 984 ])
 985
 986 #
 987 # LN_PROG_DARWIN
 988 #
 989 # Darwin checks
 990 #
 991 AC_DEFUN([LN_PROG_DARWIN],
 992 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 993 ])
 994
 995 #
 996 # LN_PATH_DEFAULTS
 997 #
 998 # default paths for installed files
 999 #
1000 AC_DEFUN([LN_PATH_DEFAULTS],
1001 [
1002 ])
1003
1004 #
1005 # LN_CONFIGURE
1006 #
1007 # other configure checks
1008 #
1009 AC_DEFUN([LN_CONFIGURE],
1010 [# lnet/utils/portals.c
1011 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
1012 AC_CHECK_FUNCS([gethostbyname socket connect])
1013
1014 # lnet/utils/debug.c
1015 AC_CHECK_HEADERS([linux/version.h])
1016
1017 AC_CHECK_TYPE([spinlock_t],
1018         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
1019         [],
1020         [#include <linux/spinlock.h>])
1021
1022 # lnet/utils/wirecheck.c
1023 AC_CHECK_FUNCS([strnlen])
1024
1025 # --------  Check for required packages  --------------
1026
1027 #
1028 # LC_CONFIG_READLINE
1029 #
1030 # Build with readline
1031 #
1032 AC_MSG_CHECKING([whether to enable readline support])
1033 AC_ARG_ENABLE(readline,
1034         AC_HELP_STRING([--disable-readline],
1035                         [disable readline support]),
1036         [],[enable_readline='yes'])
1037 AC_MSG_RESULT([$enable_readline])
1038
1039 # -------- check for readline if enabled ----
1040 if test x$enable_readline = xyes ; then
1041         LIBS_save="$LIBS"
1042         LIBS="-lncurses $LIBS"
1043         AC_CHECK_LIB([readline],[readline],[
1044         LIBREADLINE="-lreadline -lncurses"
1045         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
1046         ],[
1047         LIBREADLINE=""
1048         ])
1049         LIBS="$LIBS_save"
1050 else
1051         LIBREADLINE=""
1052 fi
1053 AC_SUBST(LIBREADLINE)
1054
1055 # -------- enable acceptor libwrap (TCP wrappers) support? -------
1056 AC_MSG_CHECKING([if libwrap support is requested])
1057 AC_ARG_ENABLE([libwrap],
1058         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
1059         [case "${enableval}" in
1060                 yes) enable_libwrap=yes ;;
1061                 no) enable_libwrap=no ;;
1062                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
1063         esac],[enable_libwrap=no])
1064 AC_MSG_RESULT([$enable_libwrap])
1065 if test x$enable_libwrap = xyes ; then
1066         LIBWRAP="-lwrap"
1067         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
1068 else
1069         LIBWRAP=""
1070 fi
1071 AC_SUBST(LIBWRAP)
1072
1073 # ----------------------------------------
1074 # some tests for catamount-like systems
1075 # ----------------------------------------
1076 AC_ARG_ENABLE([sysio_init],
1077         AC_HELP_STRING([--disable-sysio-init],
1078                 [call sysio init functions when initializing liblustre]),
1079         [],[enable_sysio_init=yes])
1080 AC_MSG_CHECKING([whether to initialize libsysio])
1081 AC_MSG_RESULT([$enable_sysio_init])
1082 if test x$enable_sysio_init != xno ; then
1083         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
1084 fi
1085
1086 AC_ARG_ENABLE([urandom],
1087         AC_HELP_STRING([--disable-urandom],
1088                 [disable use of /dev/urandom for liblustre]),
1089         [],[enable_urandom=yes])
1090 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
1091 AC_MSG_RESULT([$enable_urandom])
1092 if test x$enable_urandom != xno ; then
1093         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
1094 fi
1095
1096 # -------- check for -lcap support ----
1097 if test x$enable_liblustre = xyes ; then
1098         AC_CHECK_LIB([cap], [cap_get_proc],
1099                 [
1100                         CAP_LIBS="-lcap"
1101                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
1102                 ],
1103                 [
1104                         CAP_LIBS=""
1105                 ])
1106         AC_SUBST(CAP_LIBS)
1107
1108 fi
1109
1110 LN_CONFIG_MAX_PAYLOAD
1111 LN_CONFIG_UPTLLND
1112 LN_CONFIG_USOCKLND
1113 ])
1114
1115 #
1116 # LN_CONDITIONALS
1117 #
1118 # AM_CONDITOINAL defines for lnet
1119 #
1120 AC_DEFUN([LN_CONDITIONALS],
1121 [AM_CONDITIONAL(BUILD_QSWLND, test x$QSWLND = "xqswlnd")
1122 AM_CONDITIONAL(BUILD_GMLND, test x$GMLND = "xgmlnd")
1123 AM_CONDITIONAL(BUILD_MXLND, test x$MXLND = "xmxlnd")
1124 AM_CONDITIONAL(BUILD_O2IBLND, test x$O2IBLND = "xo2iblnd")
1125 AM_CONDITIONAL(BUILD_OPENIBLND, test x$OPENIBLND = "xopeniblnd")
1126 AM_CONDITIONAL(BUILD_CIBLND, test x$CIBLND = "xciblnd")
1127 AM_CONDITIONAL(BUILD_IIBLND, test x$IIBLND = "xiiblnd")
1128 AM_CONDITIONAL(BUILD_VIBLND, test x$VIBLND = "xviblnd")
1129 AM_CONDITIONAL(BUILD_RALND, test x$RALND = "xralnd")
1130 AM_CONDITIONAL(BUILD_PTLLND, test x$PTLLND = "xptllnd")
1131 AM_CONDITIONAL(BUILD_UPTLLND, test x$UPTLLND = "xptllnd")
1132 AM_CONDITIONAL(BUILD_USOCKLND, test x$USOCKLND = "xusocklnd")
1133 ])
1134
1135 #
1136 # LN_CONFIG_FILES
1137 #
1138 # files that should be generated with AC_OUTPUT
1139 #
1140 AC_DEFUN([LN_CONFIG_FILES],
1141 [AC_CONFIG_FILES([
1142 lnet/Kernelenv
1143 lnet/Makefile
1144 lnet/autoMakefile
1145 lnet/autoconf/Makefile
1146 lnet/doc/Makefile
1147 lnet/include/Makefile
1148 lnet/include/lnet/Makefile
1149 lnet/include/lnet/linux/Makefile
1150 lnet/klnds/Makefile
1151 lnet/klnds/autoMakefile
1152 lnet/klnds/gmlnd/Makefile
1153 lnet/klnds/mxlnd/autoMakefile
1154 lnet/klnds/mxlnd/Makefile
1155 lnet/klnds/gmlnd/autoMakefile
1156 lnet/klnds/openiblnd/Makefile
1157 lnet/klnds/openiblnd/autoMakefile
1158 lnet/klnds/o2iblnd/Makefile
1159 lnet/klnds/o2iblnd/autoMakefile
1160 lnet/klnds/ciblnd/Makefile
1161 lnet/klnds/ciblnd/autoMakefile
1162 lnet/klnds/iiblnd/Makefile
1163 lnet/klnds/iiblnd/autoMakefile
1164 lnet/klnds/viblnd/Makefile
1165 lnet/klnds/viblnd/autoMakefile
1166 lnet/klnds/qswlnd/Makefile
1167 lnet/klnds/qswlnd/autoMakefile
1168 lnet/klnds/ralnd/Makefile
1169 lnet/klnds/ralnd/autoMakefile
1170 lnet/klnds/socklnd/Makefile
1171 lnet/klnds/socklnd/autoMakefile
1172 lnet/klnds/ptllnd/Makefile
1173 lnet/klnds/ptllnd/autoMakefile
1174 lnet/lnet/Makefile
1175 lnet/lnet/autoMakefile
1176 lnet/selftest/Makefile
1177 lnet/selftest/autoMakefile
1178 lnet/ulnds/Makefile
1179 lnet/ulnds/autoMakefile
1180 lnet/ulnds/socklnd/Makefile
1181 lnet/ulnds/ptllnd/Makefile
1182 lnet/utils/Makefile
1183 ])
1184 case $lb_target_os in
1185         darwin)
1186                 AC_CONFIG_FILES([
1187 lnet/include/lnet/darwin/Makefile
1188 ])
1189                 ;;
1190 esac
1191 ])