lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD],
   7 [AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                        [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19         AC_DEFINE_UNQUOTED(LNET_MAX_PAYLOAD, $LNET_MAX_PAYLOAD,
  20                            [Max LNET payload])
  21 ])
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION],
  29 [AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ])
  43
  44 #
  45 # LN_CONFIG_AFFINITY
  46 #
  47 # check if cpu affinity is available/wanted
  48 #
  49 AC_DEFUN([LN_CONFIG_AFFINITY],
  50 [AC_ARG_ENABLE([affinity],
  51         AC_HELP_STRING([--disable-affinity],
  52                        [disable process/irq affinity]),
  53         [],[enable_affinity='yes'])
  54
  55 AC_MSG_CHECKING([for CPU affinity support])
  56 if test x$enable_affinity = xno ; then
  57         AC_MSG_RESULT([no (by request)])
  58 else
  59         LB_LINUX_TRY_COMPILE([
  60                 #include <linux/sched.h>
  61         ],[
  62                 struct task_struct t;
  63                 #if HAVE_CPUMASK_T
  64                 cpumask_t     m;
  65                 #else
  66                 unsigned long m;
  67                 #endif
  68                 set_cpus_allowed(&t, m);
  69         ],[
  70                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
  71                 AC_MSG_RESULT([yes])
  72         ],[
  73                 AC_MSG_RESULT([no (no kernel support)])
  74         ])
  75 fi
  76 ])
  77
  78 #
  79 # LN_CONFIG_PORTALS
  80 #
  81 # configure support for Portals
  82 #
  83 AC_DEFUN([LN_CONFIG_PORTALS],
  84 [AC_MSG_CHECKING([for portals])
  85 AC_ARG_WITH([portals],
  86         AC_HELP_STRING([--with-portals=path],
  87                        [set path to portals]),
  88         [
  89                 case $with_portals in
  90                         no)     ENABLEPORTALS=0
  91                                 ;;
  92                         *)      PORTALS="${with_portals}"
  93                                 ENABLEPORTALS=1
  94                                 ;;
  95                 esac
  96         ], [
  97                 ENABLEPORTALS=0
  98         ])
  99 PTLLNDCPPFLAGS=""
 100 if test $ENABLEPORTALS -eq 0; then
 101         AC_MSG_RESULT([no])
 102 elif test ! \( -f ${PORTALS}/include/portals/p30.h \); then
 103         AC_MSG_RESULT([no])
 104         AC_MSG_ERROR([bad --with-portals path])
 105 else
 106         AC_MSG_RESULT([$PORTALS])
 107         PTLLNDCPPFLAGS="-I${PORTALS}/include"
 108 fi
 109 AC_SUBST(PTLLNDCPPFLAGS)
 110 ])
 111
 112 #
 113 # LN_CONFIG_BACKOFF
 114 #
 115 # check if tunable tcp backoff is available/wanted
 116 #
 117 AC_DEFUN([LN_CONFIG_BACKOFF],
 118 [AC_MSG_CHECKING([for tunable backoff TCP support])
 119 AC_ARG_ENABLE([backoff],
 120        AC_HELP_STRING([--disable-backoff],
 121                       [disable socknal tunable backoff]),
 122        [],[enable_backoff='yes'])
 123 if test x$enable_backoff = xno ; then
 124        AC_MSG_RESULT([no (by request)])
 125 else
 126        BOCD="`grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h`"
 127        if test "$BOCD" != 0 ; then
 128                AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
 129                AC_MSG_RESULT(yes)
 130                if grep rto_max $LINUX/include/linux/tcp.h|grep -q __u16; then
 131                    AC_DEFINE(SOCKNAL_BACKOFF_MS, 1, [tunable backoff TCP in ms])
 132                fi
 133        else
 134                AC_MSG_RESULT([no (no kernel support)])
 135        fi
 136 fi
 137 ])
 138
 139
 140 #
 141 # LN_CONFIG_PTLLND
 142 #
 143 # configure support for Portals LND
 144 #
 145 AC_DEFUN([LN_CONFIG_PTLLND],
 146 [
 147 if test -z "$ENABLEPORTALS"; then
 148         LN_CONFIG_PORTALS
 149 fi
 150
 151 AC_MSG_CHECKING([whether to build the kernel portals LND])
 152
 153 PTLLND=""
 154 if test $ENABLEPORTALS -ne 0; then
 155         AC_MSG_RESULT([yes])
 156         PTLLND="ptllnd"
 157 else
 158         AC_MSG_RESULT([no])
 159 fi
 160 AC_SUBST(PTLLND)
 161 ])
 162
 163 #
 164 # LN_CONFIG_UPTLLND
 165 #
 166 # configure support for Portals LND
 167 #
 168 AC_DEFUN([LN_CONFIG_UPTLLND],
 169 [
 170 if test -z "$ENABLEPORTALS"; then
 171         LN_CONFIG_PORTALS
 172 fi
 173
 174 AC_MSG_CHECKING([whether to build the userspace portals LND])
 175
 176 UPTLLND=""
 177 if test $ENABLEPORTALS -ne 0; then
 178         AC_MSG_RESULT([yes])
 179         UPTLLND="ptllnd"
 180 else
 181         AC_MSG_RESULT([no])
 182 fi
 183 AC_SUBST(UPTLLND)
 184 ])
 185
 186 #
 187 # LN_CONFIG_USOCKLND
 188 #
 189 # configure support for userspace TCP/IP LND
 190 #
 191 AC_DEFUN([LN_CONFIG_USOCKLND],
 192 [AC_MSG_CHECKING([whether to build usocklnd])
 193 AC_ARG_ENABLE([usocklnd],
 194         AC_HELP_STRING([--disable-usocklnd],
 195                         [disable usocklnd]),
 196         [],[enable_usocklnd='yes'])
 197
 198 if test x$enable_usocklnd = xyes ; then
 199         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 200                 AC_MSG_RESULT([yes])
 201                 USOCKLND="usocklnd"
 202         else
 203                 AC_MSG_RESULT([no (libpthread not present or disabled)])
 204                 USOCKLND=""
 205         fi
 206 else
 207         AC_MSG_RESULT([no (disabled explicitly)])
 208         USOCKLND=""
 209 fi
 210 AC_SUBST(USOCKLND)
 211 ])
 212
 213 #
 214 # LN_CONFIG_QUADRICS
 215 #
 216 # check if quadrics support is in this kernel
 217 #
 218 AC_DEFUN([LN_CONFIG_QUADRICS],
 219 [AC_MSG_CHECKING([for QsNet sources])
 220 AC_ARG_WITH([qsnet],
 221         AC_HELP_STRING([--with-qsnet=path],
 222                        [set path to qsnet source (default=$LINUX)]),
 223         [QSNET=$with_qsnet],
 224         [QSNET=$LINUX])
 225 AC_MSG_RESULT([$QSNET])
 226
 227 AC_MSG_CHECKING([if quadrics kernel headers are present])
 228 if test -d $QSNET/drivers/net/qsnet ; then
 229         AC_MSG_RESULT([yes])
 230         QSWLND="qswlnd"
 231         AC_MSG_CHECKING([for multirail EKC])
 232         if test -f $QSNET/include/elan/epcomms.h; then
 233                 AC_MSG_RESULT([supported])
 234                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 235         else
 236                 AC_MSG_RESULT([not supported])
 237                 AC_MSG_ERROR([Need multirail EKC])
 238         fi
 239
 240         if test x$QSNET = x$LINUX ; then
 241                 LB_LINUX_CONFIG([QSNET],[],[
 242                         LB_LINUX_CONFIG([QSNET_MODULE],[],[
 243                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
 244                                 QSWLND=""
 245                                 QSWCPPFLAGS=""
 246                         ])
 247                 ])
 248         fi
 249 else
 250         AC_MSG_RESULT([no])
 251         QSWLND=""
 252         QSWCPPFLAGS=""
 253 fi
 254 AC_SUBST(QSWCPPFLAGS)
 255 AC_SUBST(QSWLND)
 256 ])
 257
 258 #
 259 # LN_CONFIG_GM
 260 #
 261 # check if GM support is available
 262 #
 263 AC_DEFUN([LN_CONFIG_GM],[
 264 AC_MSG_CHECKING([whether to enable GM support])
 265 AC_ARG_WITH([gm],
 266         AC_HELP_STRING([--with-gm=path-to-gm-source-tree],
 267                        [build gmlnd against path]),
 268         [
 269                 case $with_gm in
 270                 no)    ENABLE_GM=0
 271                        ;;
 272                 *)     ENABLE_GM=1
 273                        GM_SRC="$with_gm"
 274                        ;;
 275                 esac
 276         ],[
 277                 ENABLE_GM=0
 278         ])
 279 AC_ARG_WITH([gm-install],
 280         AC_HELP_STRING([--with-gm-install=path-to-gm-install-tree],
 281                        [say where GM has been installed]),
 282         [
 283                 GM_INSTALL=$with_gm_install
 284         ],[
 285                 GM_INSTALL="/opt/gm"
 286         ])
 287 if test $ENABLE_GM -eq 0; then
 288         AC_MSG_RESULT([no])
 289 else
 290         AC_MSG_RESULT([yes])
 291
 292         GMLND="gmlnd"
 293         GMCPPFLAGS="-I$GM_SRC/include -I$GM_SRC/drivers -I$GM_SRC/drivers/linux/gm"
 294
 295         if test -f $GM_INSTALL/lib/libgm.a -o \
 296                 -f $GM_INSTALL/lib64/libgm.a; then
 297                 GMLIBS="-L$GM_INSTALL/lib -L$GM_INSTALL/lib64"
 298         else
 299                 AC_MSG_ERROR([Cant find GM libraries under $GM_INSTALL])
 300         fi
 301
 302         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 303         EXTRA_KCFLAGS="$GMCPPFLAGS -DGM_KERNEL $EXTRA_KCFLAGS"
 304
 305         AC_MSG_CHECKING([that code using GM compiles with given path])
 306         LB_LINUX_TRY_COMPILE([
 307                 #define GM_STRONG_TYPES 1
 308                 #ifdef VERSION
 309                 #undef VERSION
 310                 #endif
 311                 #include "gm.h"
 312                 #include "gm_internal.h"
 313         ],[
 314                 struct gm_port *port = NULL;
 315                 gm_recv_event_t *rxevent = gm_blocking_receive_no_spin(port);
 316                 return 0;
 317         ],[
 318                 AC_MSG_RESULT([yes])
 319         ],[
 320                 AC_MSG_RESULT([no])
 321                 AC_MSG_ERROR([Bad --with-gm path])
 322         ])
 323
 324         AC_MSG_CHECKING([that GM has gm_register_memory_ex_phys()])
 325         LB_LINUX_TRY_COMPILE([
 326                 #define GM_STRONG_TYPES 1
 327                 #ifdef VERSION
 328                 #undef VERSION
 329                 #endif
 330                 #include "gm.h"
 331                 #include "gm_internal.h"
 332         ],[
 333                 gm_status_t     gmrc;
 334                 struct gm_port *port = NULL;
 335                 gm_u64_t        phys = 0;
 336                 gm_up_t         pvma = 0;
 337
 338                 gmrc = gm_register_memory_ex_phys(port, phys, 100, pvma);
 339                 return 0;
 340         ],[
 341                 AC_MSG_RESULT([yes])
 342         ],[
 343                 AC_MSG_RESULT([no.
 344 Please patch the GM sources as follows...
 345     cd $GM_SRC
 346     patch -p0 < $PWD/lnet/klnds/gmlnd/gm-reg-phys.patch
 347 ...then rebuild and re-install them])
 348                 AC_MSG_ERROR([Can't build GM without gm_register_memory_ex_phys()])
 349         ])
 350
 351         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 352 fi
 353 AC_SUBST(GMCPPFLAGS)
 354 AC_SUBST(GMLIBS)
 355 AC_SUBST(GMLND)
 356 ])
 357
 358
 359 #
 360 # LN_CONFIG_MX
 361 #
 362 AC_DEFUN([LN_CONFIG_MX],
 363 [AC_MSG_CHECKING([whether to enable Myrinet MX support])
 364 # set default
 365 MXPATH="/opt/mx"
 366 AC_ARG_WITH([mx],
 367        AC_HELP_STRING([--with-mx=path],
 368                       [build mxlnd against path]),
 369        [
 370                case $with_mx in
 371                yes)    ENABLEMX=2
 372                        ;;
 373                no)     ENABLEMX=0
 374                        ;;
 375                *)      MXPATH=$with_mx
 376                        ENABLEMX=3
 377                        ;;
 378                esac
 379        ],[
 380                ENABLEMX=1
 381        ])
 382 if test $ENABLEMX -eq 0; then
 383        AC_MSG_RESULT([disabled])
 384 elif test ! \( -f ${MXPATH}/include/myriexpress.h -a \
 385               -f ${MXPATH}/include/mx_kernel_api.h -a \
 386               -f ${MXPATH}/include/mx_pin.h \); then
 387        AC_MSG_RESULT([no])
 388        case $ENABLEMX in
 389        1) ;;
 390        2) AC_MSG_ERROR([Myrinet MX kernel headers not present]);;
 391        3) AC_MSG_ERROR([bad --with-mx path]);;
 392        *) AC_MSG_ERROR([internal error]);;
 393        esac
 394 else
 395        MXCPPFLAGS="-I$MXPATH/include"
 396        EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 397        EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
 398        MXLIBS="-L$MXPATH/lib"
 399        LB_LINUX_TRY_COMPILE([
 400                #define MX_KERNEL 1
 401                #include <mx_extensions.h>
 402                #include <myriexpress.h>
 403        ],[
 404                mx_endpoint_t   end;
 405                mx_status_t     status;
 406                mx_request_t    request;
 407                int             result;
 408
 409                mx_init();
 410                mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
 411                mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
 412                mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
 413                mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
 414                return 0;
 415        ],[
 416                AC_MSG_RESULT([yes])
 417                MXLND="mxlnd"
 418        ],[
 419                AC_MSG_RESULT([no])
 420                case $ENABLEMX in
 421                1) ;;
 422                2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]);;
 423                3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]);;
 424                *) AC_MSG_ERROR([internal error]);;
 425                esac
 426                MXLND=""
 427                MXCPPFLAGS=""
 428        ])
 429        EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 430 fi
 431 AC_SUBST(MXCPPFLAGS)
 432 AC_SUBST(MXLIBS)
 433 AC_SUBST(MXLND)
 434 ])
 435
 436
 437
 438 #
 439 # LN_CONFIG_O2IB
 440 #
 441 AC_DEFUN([LN_CONFIG_O2IB],[
 442 AC_MSG_CHECKING([whether to enable OpenIB gen2 support])
 443 # set default
 444 AC_ARG_WITH([o2ib],
 445         AC_HELP_STRING([--with-o2ib=path],
 446                        [build o2iblnd against path]),
 447         [
 448                 case $with_o2ib in
 449                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 450                         ENABLEO2IB=2
 451                         ;;
 452                 no)     ENABLEO2IB=0
 453                         ;;
 454                 *)      O2IBPATHS=$with_o2ib
 455                         ENABLEO2IB=3
 456                         ;;
 457                 esac
 458         ],[
 459                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 460                 ENABLEO2IB=1
 461         ])
 462 if test $ENABLEO2IB -eq 0; then
 463         AC_MSG_RESULT([disabled])
 464 else
 465         o2ib_found=false
 466         for O2IBPATH in $O2IBPATHS; do
 467                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 468                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 469                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 470                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 471                         o2ib_found=true
 472                         break
 473                 fi
 474         done
 475         if ! $o2ib_found; then
 476                 AC_MSG_RESULT([no])
 477                 case $ENABLEO2IB in
 478                         1) ;;
 479                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 480                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 481                         *) AC_MSG_ERROR([internal error]);;
 482                 esac
 483         else
 484                 O2IBCPPFLAGS="-I$O2IBPATH/include"
 485                 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 486                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $O2IBCPPFLAGS"
 487                 EXTRA_LNET_INCLUDE="$O2IBCPPFLAGS $EXTRA_LNET_INCLUDE"
 488                 LB_LINUX_TRY_COMPILE([
 489                         #include <linux/version.h>
 490                         #include <linux/pci.h>
 491                         #if !HAVE_GFP_T
 492                         typedef int gfp_t;
 493                         #endif
 494                         #include <rdma/rdma_cm.h>
 495                         #include <rdma/ib_cm.h>
 496                         #include <rdma/ib_verbs.h>
 497                         #include <rdma/ib_fmr_pool.h>
 498                 ],[
 499                         struct rdma_cm_id          *cm_id;
 500                         struct rdma_conn_param      conn_param;
 501                         struct ib_device_attr       device_attr;
 502                         struct ib_qp_attr           qp_attr;
 503                         struct ib_pool_fmr          pool_fmr;
 504                         enum   ib_cm_rej_reason     rej_reason;
 505
 506                         cm_id = rdma_create_id(NULL, NULL, RDMA_PS_TCP);
 507                         return PTR_ERR(cm_id);
 508                 ],[
 509                         AC_MSG_RESULT([yes])
 510                         O2IBLND="o2iblnd"
 511                 ],[
 512                         AC_MSG_RESULT([no])
 513                         case $ENABLEO2IB in
 514                         1) ;;
 515                         2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]);;
 516                         3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]);;
 517                         *) AC_MSG_ERROR([internal error]);;
 518                         esac
 519                         O2IBLND=""
 520                         O2IBCPPFLAGS=""
 521                 ])
 522                 # we know at this point that the found OFED source is good
 523                 O2IB_SYMVER=""
 524                 if test $ENABLEO2IB -eq 3 ; then
 525                         # OFED default rpm not handle sles10 Modules.symvers name
 526                         for name in Module.symvers Modules.symvers; do
 527                                 if test -f $O2IBPATH/$name; then
 528                                         O2IB_SYMVER=$name;
 529                                         break;
 530                                 fi
 531                         done
 532                         if test -n $O2IB_SYMVER ; then
 533                                 AC_MSG_NOTICE([adding $O2IBPATH/$O2IB_SYMVER to $PWD/$SYMVERFILE])
 534                                 # strip out the existing symbols versions first
 535                                 egrep -v $(echo $(awk '{ print $2 }' $O2IBPATH/$O2IB_SYMVER) | tr ' ' '|') $PWD/$SYMVERFILE > $PWD/$SYMVERFILE.old
 536                                 cat $PWD/$SYMVERFILE.old $O2IBPATH/$O2IB_SYMVER > $PWD/$SYMVERFILE
 537                         else
 538                                 AC_MSG_ERROR([an external source tree was specified for o2iblnd however I could not find a $O2IBPATH/Module.symvers there])
 539                         fi
 540                 fi
 541
 542                 LB_LINUX_TRY_COMPILE([
 543                         #include <linux/version.h>
 544                         #include <linux/pci.h>
 545                         #if !HAVE_GFP_T
 546                         typedef int gfp_t;
 547                         #endif
 548                         #include <rdma/ib_verbs.h>
 549                 ],[
 550                         ib_dma_map_single(NULL, NULL, 0, 0);
 551                         return 0;
 552                 ],[
 553                         AC_MSG_RESULT(yes)
 554                         AC_DEFINE(HAVE_OFED_IB_DMA_MAP, 1,
 555                                   [ib_dma_map_single defined])
 556                 ],[
 557                         AC_MSG_RESULT(no)
 558                 ])
 559
 560                 LB_LINUX_TRY_COMPILE([
 561                         #include <linux/version.h>
 562                         #include <linux/pci.h>
 563                         #if !HAVE_GFP_T
 564                         typedef int gfp_t;
 565                         #endif
 566                         #include <rdma/ib_verbs.h>
 567                 ],[
 568                         ib_create_cq(NULL, NULL, NULL, NULL, 0, 0);
 569                         return 0;
 570                 ],[
 571                         AC_MSG_RESULT(yes)
 572                         AC_DEFINE(HAVE_OFED_IB_COMP_VECTOR, 1,
 573                                   [has completion vector])
 574                 ],[
 575                         AC_MSG_RESULT(no)
 576                 ])
 577
 578                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 579         fi
 580 fi
 581
 582 AC_SUBST(EXTRA_LNET_INCLUDE)
 583 AC_SUBST(O2IBCPPFLAGS)
 584 AC_SUBST(O2IBLND)
 585 ])
 586
 587 #
 588 # LN_CONFIG_OPENIB
 589 #
 590 # check for OpenIB in the kernel
 591 AC_DEFUN([LN_CONFIG_OPENIB],[
 592 AC_MSG_CHECKING([whether to enable OpenIB support])
 593 # set default
 594 OPENIBPATH="$LINUX/drivers/infiniband"
 595 AC_ARG_WITH([openib],
 596         AC_HELP_STRING([--with-openib=path],
 597                        [build openiblnd against path]),
 598         [
 599                 case $with_openib in
 600                 yes)    ENABLEOPENIB=2
 601                         ;;
 602                 no)     ENABLEOPENIB=0
 603                         ;;
 604                 *)      OPENIBPATH="$with_openib"
 605                         ENABLEOPENIB=3
 606                         ;;
 607                 esac
 608         ],[
 609                 ENABLEOPENIB=1
 610         ])
 611 if test $ENABLEOPENIB -eq 0; then
 612         AC_MSG_RESULT([disabled])
 613 elif test ! \( -f ${OPENIBPATH}/include/ts_ib_core.h -a \
 614                -f ${OPENIBPATH}/include/ts_ib_cm.h -a \
 615                -f ${OPENIBPATH}/include/ts_ib_sa_client.h \); then
 616         AC_MSG_RESULT([no])
 617         case $ENABLEOPENIB in
 618         1) ;;
 619         2) AC_MSG_ERROR([kernel OpenIB headers not present]);;
 620         3) AC_MSG_ERROR([bad --with-openib path]);;
 621         *) AC_MSG_ERROR([internal error]);;
 622         esac
 623 else
 624         case $ENABLEOPENIB in
 625         1|2) OPENIBCPPFLAGS="-I$OPENIBPATH/include -DIN_TREE_BUILD";;
 626         3)   OPENIBCPPFLAGS="-I$OPENIBPATH/include";;
 627         *)   AC_MSG_RESULT([no])
 628              AC_MSG_ERROR([internal error]);;
 629         esac
 630         OPENIBCPPFLAGS="$OPENIBCPPFLAGS -DIB_NTXRXPARAMS=4"
 631         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 632         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $OPENIBCPPFLAGS"
 633         LB_LINUX_TRY_COMPILE([
 634                 #include <ts_ib_core.h>
 635                 #include <ts_ib_cm.h>
 636                 #include <ts_ib_sa_client.h>
 637         ],[
 638                 struct ib_device_properties dev_props;
 639                 struct ib_cm_active_param   cm_active_params;
 640                 tTS_IB_CLIENT_QUERY_TID     tid;
 641                 int                         enum1 = IB_QP_ATTRIBUTE_STATE;
 642                 int                         enum2 = IB_ACCESS_LOCAL_WRITE;
 643                 int                         enum3 = IB_CQ_CALLBACK_INTERRUPT;
 644                 int                         enum4 = IB_CQ_PROVIDER_REARM;
 645                 return 0;
 646         ],[
 647                 AC_MSG_RESULT([yes])
 648                 OPENIBLND="openiblnd"
 649         ],[
 650                 AC_MSG_RESULT([no])
 651                 case $ENABLEOPENIB in
 652                 1) ;;
 653                 2) AC_MSG_ERROR([can't compile with kernel OpenIB headers]);;
 654                 3) AC_MSG_ERROR([can't compile with OpenIB headers under $OPENIBPATH]);;
 655                 *) AC_MSG_ERROR([internal error]);;
 656                 esac
 657                 OPENIBLND=""
 658                 OPENIBCPPFLAGS=""
 659         ])
 660         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 661 fi
 662 AC_SUBST(OPENIBCPPFLAGS)
 663 AC_SUBST(OPENIBLND)
 664 ])
 665
 666 #
 667 # LN_CONFIG_CIBLND
 668 #
 669 AC_DEFUN([LN_CONFIG_CIB],[
 670 AC_MSG_CHECKING([whether to enable Cisco/TopSpin IB support])
 671 # set default
 672 CIBPATH=""
 673 CIBLND=""
 674 AC_ARG_WITH([cib],
 675         AC_HELP_STRING([--with-cib=path],
 676                        [build ciblnd against path]),
 677         [
 678                 case $with_cib in
 679                 no)     AC_MSG_RESULT([no]);;
 680                 *)      CIBPATH="$with_cib"
 681                         if test -d "$CIBPATH"; then
 682                                 AC_MSG_RESULT([yes])
 683                         else
 684                                 AC_MSG_RESULT([no])
 685                                 AC_MSG_ERROR([No directory $CIBPATH])
 686                         fi;;
 687                 esac
 688         ],[
 689                 AC_MSG_RESULT([no])
 690         ])
 691 if test -n "$CIBPATH"; then
 692         CIBCPPFLAGS="-I${CIBPATH}/ib/ts_api_ng/include -I${CIBPATH}/all/kernel_services/include -DUSING_TSAPI"
 693         CIBCPPFLAGS="$CIBCPPFLAGS -DIB_NTXRXPARAMS=3"
 694         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 695         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $CIBCPPFLAGS"
 696         LB_LINUX_TRY_COMPILE([
 697                 #include <ts_ib_core.h>
 698                 #include <ts_ib_cm.h>
 699                 #include <ts_ib_sa_client.h>
 700         ],[
 701                 struct ib_device_properties dev_props;
 702                 struct ib_cm_active_param   cm_active_params;
 703                 tTS_IB_CLIENT_QUERY_TID     tid;
 704                 int                         enum1 = TS_IB_QP_ATTRIBUTE_STATE;
 705                 int                         enum2 = TS_IB_ACCESS_LOCAL_WRITE;
 706                 int                         enum3 = TS_IB_CQ_CALLBACK_INTERRUPT;
 707                 int                         enum4 = TS_IB_CQ_PROVIDER_REARM;
 708                 return 0;
 709         ],[
 710                 CIBLND="ciblnd"
 711         ],[
 712                 AC_MSG_ERROR([can't compile ciblnd with given path])
 713                 CIBCPPFLAGS=""
 714         ])
 715         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 716 fi
 717 AC_SUBST(CIBCPPFLAGS)
 718 AC_SUBST(CIBLND)
 719 ])
 720
 721 #
 722 # LN_CONFIG_IIB
 723 #
 724 # check for infinicon infiniband support
 725 #
 726 AC_DEFUN([LN_CONFIG_IIB],[
 727 AC_MSG_CHECKING([whether to enable Infinicon support])
 728 # set default
 729 IIBPATH="/usr/include"
 730 AC_ARG_WITH([iib],
 731         AC_HELP_STRING([--with-iib=path],
 732                        [build iiblnd against path]),
 733         [
 734                 case $with_iib in
 735                 yes)    ENABLEIIB=2
 736                         ;;
 737                 no)     ENABLEIIB=0
 738                         ;;
 739                 *)      IIBPATH="${with_iib}/include"
 740                         ENABLEIIB=3
 741                         ;;
 742                 esac
 743         ],[
 744                 ENABLEIIB=1
 745         ])
 746 if test $ENABLEIIB -eq 0; then
 747         AC_MSG_RESULT([disabled])
 748 elif test ! \( -f ${IIBPATH}/linux/iba/ibt.h \); then
 749         AC_MSG_RESULT([no])
 750         case $ENABLEIIB in
 751         1) ;;
 752         2) AC_MSG_ERROR([default Infinicon headers not present]);;
 753         3) AC_MSG_ERROR([bad --with-iib path]);;
 754         *) AC_MSG_ERROR([internal error]);;
 755         esac
 756 else
 757         IIBCPPFLAGS="-I$IIBPATH"
 758         if test $IIBPATH != "/usr/include"; then
 759                 # we need /usr/include come what may
 760                 IIBCPPFLAGS="$IIBCPPFLAGS -I/usr/include"
 761         fi
 762         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 763         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $IIBCPPFLAGS"
 764         LB_LINUX_TRY_COMPILE([
 765                 #include <linux/iba/ibt.h>
 766         ],[
 767                 IBT_INTERFACE_UNION interfaces;
 768                 FSTATUS             rc;
 769
 770                  rc = IbtGetInterfaceByVersion(IBT_INTERFACE_VERSION_2,
 771                                                &interfaces);
 772
 773                 return rc == FSUCCESS ? 0 : 1;
 774         ],[
 775                 AC_MSG_RESULT([yes])
 776                 IIBLND="iiblnd"
 777         ],[
 778                 AC_MSG_RESULT([no])
 779                 case $ENABLEIIB in
 780                 1) ;;
 781                 2) AC_MSG_ERROR([can't compile with default Infinicon headers]);;
 782                 3) AC_MSG_ERROR([can't compile with Infinicon headers under $IIBPATH]);;
 783                 *) AC_MSG_ERROR([internal error]);;
 784                 esac
 785                 IIBLND=""
 786                 IIBCPPFLAGS=""
 787         ])
 788         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 789 fi
 790 AC_SUBST(IIBCPPFLAGS)
 791 AC_SUBST(IIBLND)
 792 ])
 793
 794 #
 795 # LN_CONFIG_VIB
 796 #
 797 # check for Voltaire infiniband support
 798 #
 799 AC_DEFUN([LN_CONFIG_VIB],
 800 [AC_MSG_CHECKING([whether to enable Voltaire IB support])
 801 VIBPATH=""
 802 AC_ARG_WITH([vib],
 803         AC_HELP_STRING([--with-vib=path],
 804                        [build viblnd against path]),
 805         [
 806                 case $with_vib in
 807                 no)     AC_MSG_RESULT([no]);;
 808                 *)      VIBPATH="${with_vib}/src/nvigor/ib-code"
 809                         if test -d "$with_vib" -a -d "$VIBPATH"; then
 810                                 AC_MSG_RESULT([yes])
 811                         else
 812                                 AC_MSG_RESULT([no])
 813                                 AC_MSG_ERROR([No directory $VIBPATH])
 814                         fi;;
 815                 esac
 816         ],[
 817                 AC_MSG_RESULT([no])
 818         ])
 819 if test -z "$VIBPATH"; then
 820         VIBLND=""
 821 else
 822         VIBCPPFLAGS="-I${VIBPATH}/include -I${VIBPATH}/cm"
 823         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 824         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 825         LB_LINUX_TRY_COMPILE([
 826                 #include <linux/list.h>
 827                 #include <asm/byteorder.h>
 828                 #ifdef __BIG_ENDIAN
 829                 # define CPU_BE 1
 830                 # define CPU_LE 0
 831                 #endif
 832                 #ifdef __LITTLE_ENDIAN
 833                 # define CPU_BE 0
 834                 # define CPU_LE 1
 835                 #endif
 836                 #include <vverbs.h>
 837                 #include <ib-cm.h>
 838                 #include <ibat.h>
 839         ],[
 840                 vv_hca_h_t       kib_hca;
 841                 vv_return_t      vvrc;
 842                 cm_cep_handle_t  cep;
 843                 ibat_arp_data_t  arp_data;
 844                 ibat_stat_t      ibatrc;
 845
 846                 vvrc = vv_hca_open("ANY_HCA", NULL, &kib_hca);
 847                 cep = cm_create_cep(cm_cep_transp_rc);
 848                 ibatrc = ibat_get_ib_data((uint32_t)0, (uint32_t)0,
 849                                           ibat_paths_primary, &arp_data,
 850                                           (ibat_get_ib_data_reply_fn_t)NULL,
 851                                           NULL, 0);
 852                 return 0;
 853         ],[
 854                 VIBLND="viblnd"
 855         ],[
 856                 AC_MSG_ERROR([can't compile viblnd with given path])
 857         ])
 858         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 859 fi
 860 if test -n "$VIBLND"; then
 861         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 862         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 863         AC_MSG_CHECKING([if Voltaire still uses void * sg addresses])
 864         LB_LINUX_TRY_COMPILE([
 865                 #include <linux/list.h>
 866                 #include <asm/byteorder.h>
 867                 #ifdef __BIG_ENDIAN
 868                 # define CPU_BE 1
 869                 # define CPU_LE 0
 870                 #endif
 871                 #ifdef __LITTLE_ENDIAN
 872                 # define CPU_BE 0
 873                 # define CPU_LE 1
 874                 #endif
 875                 #include <vverbs.h>
 876                 #include <ib-cm.h>
 877                 #include <ibat.h>
 878         ],[
 879                 vv_scatgat_t  sg;
 880
 881                 return &sg.v_address[3] == NULL;
 882         ],[
 883                 AC_MSG_RESULT([yes])
 884                 VIBCPPFLAGS="$VIBCPPFLAGS -DIBNAL_VOIDSTAR_SGADDR=1"
 885         ],[
 886                 AC_MSG_RESULT([no])
 887         ])
 888         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 889 fi
 890 AC_SUBST(VIBCPPFLAGS)
 891 AC_SUBST(VIBLND)
 892 ])
 893
 894 #
 895 # LN_CONFIG_RALND
 896 #
 897 # check whether to use the RapidArray lnd
 898 #
 899 AC_DEFUN([LN_CONFIG_RALND],
 900 [#### Rapid Array
 901 AC_MSG_CHECKING([if RapidArray kernel headers are present])
 902 # placeholder
 903 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 904 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 905 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 906 LB_LINUX_TRY_COMPILE([
 907         #include <linux/types.h>
 908         #include <rapl.h>
 909 ],[
 910         RAP_RETURN          rc;
 911         RAP_PVOID           dev_handle;
 912
 913         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 914
 915         return rc == RAP_SUCCESS ? 0 : 1;
 916 ],[
 917         AC_MSG_RESULT([yes])
 918         RALND="ralnd"
 919 ],[
 920         AC_MSG_RESULT([no])
 921         RALND=""
 922         RACPPFLAGS=""
 923 ])
 924 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 925 AC_SUBST(RACPPFLAGS)
 926 AC_SUBST(RALND)
 927 ])
 928
 929
 930
 931 #
 932 # LN_PROG_LINUX
 933 #
 934 # LNet linux kernel checks
 935 #
 936 AC_DEFUN([LN_PROG_LINUX],
 937 [
 938 LN_CONFIG_AFFINITY
 939 LN_CONFIG_BACKOFF
 940 LN_CONFIG_QUADRICS
 941 LN_CONFIG_GM
 942 LN_CONFIG_OPENIB
 943 LN_CONFIG_CIB
 944 LN_CONFIG_VIB
 945 LN_CONFIG_IIB
 946 LN_CONFIG_O2IB
 947 LN_CONFIG_RALND
 948 LN_CONFIG_PTLLND
 949 LN_CONFIG_MX
 950 ])
 951
 952 #
 953 # LN_PROG_DARWIN
 954 #
 955 # Darwin checks
 956 #
 957 AC_DEFUN([LN_PROG_DARWIN],
 958 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 959 ])
 960
 961 #
 962 # LN_PATH_DEFAULTS
 963 #
 964 # default paths for installed files
 965 #
 966 AC_DEFUN([LN_PATH_DEFAULTS],
 967 [
 968 ])
 969
 970 #
 971 # LN_CONFIGURE
 972 #
 973 # other configure checks
 974 #
 975 AC_DEFUN([LN_CONFIGURE],
 976 [# lnet/utils/portals.c
 977 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
 978 AC_CHECK_FUNCS([gethostbyname socket connect])
 979
 980 # lnet/utils/debug.c
 981 AC_CHECK_HEADERS([linux/version.h])
 982
 983 AC_CHECK_TYPE([spinlock_t],
 984         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
 985         [],
 986         [#include <linux/spinlock.h>])
 987
 988 # lnet/utils/wirecheck.c
 989 AC_CHECK_FUNCS([strnlen])
 990
 991 # --------  Check for required packages  --------------
 992
 993 #
 994 # LC_CONFIG_READLINE
 995 #
 996 # Build with readline
 997 #
 998 AC_MSG_CHECKING([whether to enable readline support])
 999 AC_ARG_ENABLE(readline,
1000         AC_HELP_STRING([--disable-readline],
1001                         [disable readline support]),
1002         [],[enable_readline='yes'])
1003 AC_MSG_RESULT([$enable_readline])
1004
1005 # -------- check for readline if enabled ----
1006 if test x$enable_readline = xyes ; then
1007         LIBS_save="$LIBS"
1008         LIBS="-lncurses $LIBS"
1009         AC_CHECK_LIB([readline],[readline],[
1010         LIBREADLINE="-lreadline -lncurses"
1011         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
1012         ],[
1013         LIBREADLINE=""
1014         ])
1015         LIBS="$LIBS_save"
1016 else
1017         LIBREADLINE=""
1018 fi
1019 AC_SUBST(LIBREADLINE)
1020
1021 # -------- enable acceptor libwrap (TCP wrappers) support? -------
1022 AC_MSG_CHECKING([if libwrap support is requested])
1023 AC_ARG_ENABLE([libwrap],
1024         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
1025         [case "${enableval}" in
1026                 yes) enable_libwrap=yes ;;
1027                 no) enable_libwrap=no ;;
1028                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
1029         esac],[enable_libwrap=no])
1030 AC_MSG_RESULT([$enable_libwrap])
1031 if test x$enable_libwrap = xyes ; then
1032         LIBWRAP="-lwrap"
1033         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
1034 else
1035         LIBWRAP=""
1036 fi
1037 AC_SUBST(LIBWRAP)
1038
1039 # ----------------------------------------
1040 # some tests for catamount-like systems
1041 # ----------------------------------------
1042 AC_ARG_ENABLE([sysio_init],
1043         AC_HELP_STRING([--disable-sysio-init],
1044                 [call sysio init functions when initializing liblustre]),
1045         [],[enable_sysio_init=yes])
1046 AC_MSG_CHECKING([whether to initialize libsysio])
1047 AC_MSG_RESULT([$enable_sysio_init])
1048 if test x$enable_sysio_init != xno ; then
1049         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
1050 fi
1051
1052 AC_ARG_ENABLE([urandom],
1053         AC_HELP_STRING([--disable-urandom],
1054                 [disable use of /dev/urandom for liblustre]),
1055         [],[enable_urandom=yes])
1056 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
1057 AC_MSG_RESULT([$enable_urandom])
1058 if test x$enable_urandom != xno ; then
1059         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
1060 fi
1061
1062 # -------- check for -lcap support ----
1063 if test x$enable_liblustre = xyes ; then
1064         AC_CHECK_LIB([cap], [cap_get_proc],
1065                 [
1066                         CAP_LIBS="-lcap"
1067                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
1068                 ],
1069                 [
1070                         CAP_LIBS=""
1071                 ])
1072         AC_SUBST(CAP_LIBS)
1073
1074 fi
1075
1076 LN_CONFIG_MAX_PAYLOAD
1077 LN_CONFIG_UPTLLND
1078 LN_CONFIG_USOCKLND
1079 ])
1080
1081 #
1082 # LN_CONDITIONALS
1083 #
1084 # AM_CONDITOINAL defines for lnet
1085 #
1086 AC_DEFUN([LN_CONDITIONALS],
1087 [AM_CONDITIONAL(BUILD_QSWLND, test x$QSWLND = "xqswlnd")
1088 AM_CONDITIONAL(BUILD_GMLND, test x$GMLND = "xgmlnd")
1089 AM_CONDITIONAL(BUILD_MXLND, test x$MXLND = "xmxlnd")
1090 AM_CONDITIONAL(BUILD_O2IBLND, test x$O2IBLND = "xo2iblnd")
1091 AM_CONDITIONAL(BUILD_OPENIBLND, test x$OPENIBLND = "xopeniblnd")
1092 AM_CONDITIONAL(BUILD_CIBLND, test x$CIBLND = "xciblnd")
1093 AM_CONDITIONAL(BUILD_IIBLND, test x$IIBLND = "xiiblnd")
1094 AM_CONDITIONAL(BUILD_VIBLND, test x$VIBLND = "xviblnd")
1095 AM_CONDITIONAL(BUILD_RALND, test x$RALND = "xralnd")
1096 AM_CONDITIONAL(BUILD_PTLLND, test x$PTLLND = "xptllnd")
1097 AM_CONDITIONAL(BUILD_UPTLLND, test x$UPTLLND = "xptllnd")
1098 AM_CONDITIONAL(BUILD_USOCKLND, test x$USOCKLND = "xusocklnd")
1099 ])
1100
1101 #
1102 # LN_CONFIG_FILES
1103 #
1104 # files that should be generated with AC_OUTPUT
1105 #
1106 AC_DEFUN([LN_CONFIG_FILES],
1107 [AC_CONFIG_FILES([
1108 lnet/Kernelenv
1109 lnet/Makefile
1110 lnet/autoMakefile
1111 lnet/autoconf/Makefile
1112 lnet/doc/Makefile
1113 lnet/include/Makefile
1114 lnet/include/lnet/Makefile
1115 lnet/include/lnet/linux/Makefile
1116 lnet/klnds/Makefile
1117 lnet/klnds/autoMakefile
1118 lnet/klnds/gmlnd/Makefile
1119 lnet/klnds/mxlnd/autoMakefile
1120 lnet/klnds/mxlnd/Makefile
1121 lnet/klnds/gmlnd/autoMakefile
1122 lnet/klnds/openiblnd/Makefile
1123 lnet/klnds/openiblnd/autoMakefile
1124 lnet/klnds/o2iblnd/Makefile
1125 lnet/klnds/o2iblnd/autoMakefile
1126 lnet/klnds/ciblnd/Makefile
1127 lnet/klnds/ciblnd/autoMakefile
1128 lnet/klnds/iiblnd/Makefile
1129 lnet/klnds/iiblnd/autoMakefile
1130 lnet/klnds/viblnd/Makefile
1131 lnet/klnds/viblnd/autoMakefile
1132 lnet/klnds/qswlnd/Makefile
1133 lnet/klnds/qswlnd/autoMakefile
1134 lnet/klnds/ralnd/Makefile
1135 lnet/klnds/ralnd/autoMakefile
1136 lnet/klnds/socklnd/Makefile
1137 lnet/klnds/socklnd/autoMakefile
1138 lnet/klnds/ptllnd/Makefile
1139 lnet/klnds/ptllnd/autoMakefile
1140 lnet/lnet/Makefile
1141 lnet/lnet/autoMakefile
1142 lnet/selftest/Makefile
1143 lnet/selftest/autoMakefile
1144 lnet/ulnds/Makefile
1145 lnet/ulnds/autoMakefile
1146 lnet/ulnds/socklnd/Makefile
1147 lnet/ulnds/ptllnd/Makefile
1148 lnet/utils/Makefile
1149 ])
1150 case $lb_target_os in
1151         darwin)
1152                 AC_CONFIG_FILES([
1153 lnet/include/lnet/darwin/Makefile
1154 ])
1155                 ;;
1156 esac
1157 ])